configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.61)
  29
  30 dnl  `patsubst' here deletes the newline which "echo" prints.  We can't use
  31 dnl  "echo -n" since -n is not portable (see autoconf manual "Limitations of
  32 dnl  Builtins"), in particular on solaris it results in a literal "-n" in
  33 dnl  the output.
  34 dnl
  35 AC_INIT(patsubst(m4_esyscmd(. ./GUILE-VERSION && echo ${PACKAGE}),[
  36 ]),
  37         patsubst(m4_esyscmd(. ./GUILE-VERSION && echo ${GUILE_VERSION}),[
  38 ]),
  39         [bug-guile@gnu.org])
  40 AC_CONFIG_AUX_DIR([build-aux])
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR(GUILE-VERSION)
  43
  44 AM_INIT_AUTOMAKE([gnu no-define check-news -Wall -Wno-override])
  45
  46 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  47 AC_CONFIG_SRCDIR([GUILE-VERSION])
  48
  49 . $srcdir/GUILE-VERSION
  50
  51 AC_CONFIG_HEADERS([config.h])
  52 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  53
  54 #--------------------------------------------------------------------
  55 #
  56 # Independent Subdirectories
  57 #
  58 #--------------------------------------------------------------------
  59
  60 AC_CONFIG_SUBDIRS(guile-readline)
  61
  62 #--------------------------------------------------------------------
  63
  64 AC_LANG([C])
  65
  66 dnl Some more checks for Win32
  67 AC_CANONICAL_HOST
  68
  69 AC_LIBTOOL_WIN32_DLL
  70
  71 AC_PROG_INSTALL
  72 AC_PROG_CC
  73 gl_EARLY
  74 AC_PROG_CPP
  75 AC_PROG_AWK
  76
  77 dnl Gnulib.
  78 gl_INIT
  79
  80 AC_PROG_CC_C89
  81
  82 # for per-target cflags in the libguile subdir
  83 AM_PROG_CC_C_O
  84
  85 AC_LIBTOOL_DLOPEN
  86 AC_PROG_LIBTOOL
  87 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  88   [AC_MSG_ERROR([libltdl not found.  See README.])])
  89 AC_CHECK_HEADER([ltdl.h], [],
  90   [AC_MSG_ERROR([<ltdl.h> not found.  See README.])])
  91
  92 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  93 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  94
  95 AM_PATH_LISPDIR
  96
  97 #--------------------------------------------------------------------
  98 #
  99 # User options (after above tests that may set default CFLAGS etc.)
 100 #
 101 #--------------------------------------------------------------------
 102
 103 GUILE_ERROR_ON_WARNING="yes"
 104
 105 AC_ARG_ENABLE(error-on-warning,
 106   [  --enable-error-on-warning    treat compile warnings as errors],
 107   [case "${enableval}" in
 108      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 109      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 110      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 111    esac])
 112
 113 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
 114 AC_ARG_ENABLE(debug-freelist,
 115   [  --enable-debug-freelist include garbage collector freelist debugging code],
 116   if test "$enable_debug_freelist" = y \
 117      || test "$enable_debug_freelist" = yes; then
 118     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 119   fi)
 120
 121 AC_ARG_ENABLE(debug-malloc,
 122   [  --enable-debug-malloc   include malloc debugging code],
 123   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 124     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 125       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 126   fi)
 127
 128 SCM_I_GSC_GUILE_DEBUG=0
 129 AC_ARG_ENABLE(guile-debug,
 130   [AS_HELP_STRING([--enable-guile-debug],
 131                   [include internal debugging functions])],
 132   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 133     SCM_I_GSC_GUILE_DEBUG=1
 134   fi)
 135
 136 AC_ARG_ENABLE(posix,
 137   [  --disable-posix         omit posix interfaces],,
 138   enable_posix=yes)
 139
 140 AC_ARG_ENABLE(networking,
 141   [  --disable-networking    omit networking interfaces],,
 142   enable_networking=yes)
 143
 144 AC_ARG_ENABLE(regex,
 145   [  --disable-regex         omit regular expression interfaces],,
 146   enable_regex=yes)
 147
 148 AC_ARG_ENABLE([discouraged],
 149   AS_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 150
 151 if test "$enable_discouraged" = no; then
 152   SCM_I_GSC_ENABLE_DISCOURAGED=0
 153 else
 154   SCM_I_GSC_ENABLE_DISCOURAGED=1
 155 fi
 156
 157 AC_ARG_ENABLE([deprecated],
 158   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 159
 160 if test "$enable_deprecated" = no; then
 161   SCM_I_GSC_ENABLE_DEPRECATED=0
 162   warn_default=no
 163 else
 164   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 165     warn_default=summary
 166   elif test "$enable_deprecated" = shutup; then
 167     warn_default=no
 168   else
 169     warn_default=$enable_deprecated
 170   fi
 171   SCM_I_GSC_ENABLE_DEPRECATED=1
 172 fi
 173 AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 174 [Define this to control the default warning level for deprecated features.])
 175
 176 AC_ARG_ENABLE(elisp,
 177   [  --disable-elisp         omit Emacs Lisp support],,
 178   enable_elisp=yes)
 179
 180 dnl  Added the following configure option in January 2008 following
 181 dnl  investigation of problems with "64" system and library calls on
 182 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 183 dnl  system has stat64, it will have all the other 64 APIs too; but on
 184 dnl  Darwin, stat64 is there but other APIs are missing.
 185 dnl
 186 dnl  It also appears, from the Darwin docs, that most system call APIs
 187 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 188 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 189 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 190 dnl
 191 dnl  A similar problem has been reported for HP-UX:
 192 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 193 dnl
 194 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 195 dnl  better than no Guile at all, we provide this option to suppress
 196 dnl  trying to use "64" calls.
 197 dnl
 198 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 199 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 200 dnl  missing out on that.  If so, someone can work on that in the future.
 201 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 202 dnl  wasn't building before.
 203 AC_MSG_CHECKING([whether to use system and library "64" calls])
 204 AC_ARG_WITH([64-calls],
 205   AS_HELP_STRING([--without-64-calls],
 206                  [don't attempt to use system and library calls with "64" in their names]),
 207   [use_64_calls=$withval],
 208   [use_64_calls=yes
 209    case $host in
 210      *-apple-darwin* )
 211        use_64_calls=no
 212        ;;
 213      powerpc-ibm-aix* )
 214        use_64_calls=no
 215        ;;
 216    esac])
 217 AC_MSG_RESULT($use_64_calls)
 218 case "$use_64_calls" in
 219   y* )
 220     AC_DEFINE(GUILE_USE_64_CALLS, 1,
 221       [Define to 1 in order to try to use "64" versions of system and library calls.])
 222     ;;
 223 esac
 224
 225 #--------------------------------------------------------------------
 226
 227 dnl Check for dynamic linking
 228
 229 use_modules=yes
 230 AC_ARG_WITH(modules,
 231 [  --with-modules[=FILES]  Add support for dynamic modules],
 232 use_modules="$withval")
 233 test -z "$use_modules" && use_modules=yes
 234 DLPREOPEN=
 235 if test "$use_modules" != no; then
 236   if test "$use_modules" = yes; then
 237     DLPREOPEN="-dlpreopen force"
 238   else
 239     DLPREOPEN="-export-dynamic"
 240     for module in $use_modules; do
 241       DLPREOPEN="$DLPREOPEN -dlopen $module"
 242     done
 243   fi
 244 fi
 245
 246 dnl files which are destined for separate modules.
 247
 248 if test "$use_modules" != no; then
 249    AC_LIBOBJ([dynl])
 250 fi
 251
 252 if test "$enable_posix" = yes; then
 253    AC_LIBOBJ([filesys])
 254    AC_LIBOBJ([posix])
 255    AC_DEFINE(HAVE_POSIX, 1,
 256      [Define this if you want support for POSIX system calls in Guile.])
 257 fi
 258
 259 if test "$enable_networking" = yes; then
 260    AC_LIBOBJ([net_db])
 261    AC_LIBOBJ([socket])
 262    AC_DEFINE(HAVE_NETWORKING, 1,
 263      [Define this if you want support for networking in Guile.])
 264 fi
 265
 266 if test "$enable_debug_malloc" = yes; then
 267    AC_LIBOBJ([debug-malloc])
 268 fi
 269
 270 if test "$enable_elisp" = yes; then
 271   SCM_I_GSC_ENABLE_ELISP=1
 272 else
 273   SCM_I_GSC_ENABLE_ELISP=0
 274 fi
 275 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 276
 277 AC_C_CONST
 278
 279 # "volatile" is used in a couple of tests below.
 280 AC_C_VOLATILE
 281
 282 AC_C_INLINE
 283 if test "$ac_cv_c_inline" != no; then
 284   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 285 else
 286   SCM_I_GSC_C_INLINE=NULL
 287 fi
 288 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 289
 290 AC_C_BIGENDIAN
 291
 292 AC_C_LABELS_AS_VALUES
 293
 294 AC_CHECK_SIZEOF(char)
 295 AC_CHECK_SIZEOF(unsigned char)
 296 AC_CHECK_SIZEOF(short)
 297 AC_CHECK_SIZEOF(unsigned short)
 298 AC_CHECK_SIZEOF(int)
 299 AC_CHECK_SIZEOF(unsigned int)
 300 AC_CHECK_SIZEOF(long)
 301 AC_CHECK_SIZEOF(unsigned long)
 302 AC_CHECK_SIZEOF(size_t)
 303 AC_CHECK_SIZEOF(long long)
 304 AC_CHECK_SIZEOF(unsigned long long)
 305 AC_CHECK_SIZEOF(__int64)
 306 AC_CHECK_SIZEOF(unsigned __int64)
 307 AC_CHECK_SIZEOF(void *)
 308 AC_CHECK_SIZEOF(intptr_t)
 309 AC_CHECK_SIZEOF(uintptr_t)
 310 AC_CHECK_SIZEOF(ptrdiff_t)
 311 AC_CHECK_SIZEOF(size_t)
 312 AC_CHECK_SIZEOF(off_t)
 313
 314 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 315   AC_MSG_ERROR(sizes of long and void* are not identical)
 316 fi
 317
 318 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 319   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 320 else
 321   SCM_I_GSC_T_PTRDIFF='"long"'
 322 fi
 323 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 324
 325 AC_CHECK_HEADERS([stdint.h])
 326 AC_CHECK_HEADERS([inttypes.h])
 327
 328 AC_CHECK_SIZEOF(intmax_t)
 329
 330 SCM_I_GSC_NEEDS_STDINT_H=0
 331 SCM_I_GSC_NEEDS_INTTYPES_H=0
 332
 333 ### intptr and uintptr (try not to use inttypes if we don't have to)
 334 if test "$ac_cv_header_inttypes_h" = yes; then
 335   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 336     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 337 #include <stdio.h>])
 338     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 339       SCM_I_GSC_NEEDS_INTTYPES_H=1
 340     fi
 341   fi
 342   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 343     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 344 #include <stdio.h>])
 345     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 346       SCM_I_GSC_NEEDS_INTTYPES_H=1
 347     fi
 348   fi
 349 fi
 350
 351 ### See what's provided by stdint.h
 352 if test "$ac_cv_header_stdint_h" = yes; then
 353    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 354    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 355    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 356    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 357    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 358    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 359    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 360    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 361    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 362    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 363 fi
 364
 365 # so we don't get confused by the cache (wish there was a better way
 366 # to check particular headers for the same type...)
 367
 368 unset ac_cv_type_int8_t
 369 unset ac_cv_type_uint8_t
 370 unset ac_cv_type_int16_t
 371 unset ac_cv_type_uint16_t
 372 unset ac_cv_type_int32_t
 373 unset ac_cv_type_uint32_t
 374 unset ac_cv_type_int64_t
 375 unset ac_cv_type_uint64_t
 376 unset ac_cv_type_intmax_t
 377 unset ac_cv_type_uintmax_t
 378
 379 ### See what's provided by inttypes.h
 380 if test "$ac_cv_header_inttypes_h" = yes; then
 381   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 382   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 383   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 384   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 385   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 386   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 387   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 388   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 389   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 390   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 391 fi
 392
 393 # Try hard to find definitions for some required scm_t_*int* types.
 394
 395 ### Required type scm_t_int8
 396 if test "$scm_stdint_has_int8"; then
 397   SCM_I_GSC_T_INT8='"int8_t"'
 398   SCM_I_GSC_NEEDS_STDINT_H=1
 399 elif test "$scm_inttypes_has_int8"; then
 400   SCM_I_GSC_T_INT8='"int8_t"'
 401   SCM_I_GSC_NEEDS_INTTYPES_H=1
 402 elif test "$ac_cv_sizeof_char" -eq 1; then
 403   SCM_I_GSC_T_INT8='"signed char"'
 404 else
 405   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 406 fi
 407 AC_SUBST([SCM_I_GSC_T_INT8])
 408
 409 ### Required type scm_t_uint8
 410 if test "$scm_stdint_has_uint8"; then
 411   SCM_I_GSC_T_UINT8='"uint8_t"'
 412   SCM_I_GSC_NEEDS_STDINT_H=1
 413 elif test "$scm_inttypes_has_uint8"; then
 414   SCM_I_GSC_T_UINT8='"uint8_t"'
 415   SCM_I_GSC_NEEDS_INTTYPES_H=1
 416 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 417   SCM_I_GSC_T_UINT8='"unsigned char"'
 418 else
 419   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 420 fi
 421 AC_SUBST([SCM_I_GSC_T_UINT8])
 422
 423 ### Required type scm_t_int16 (ANSI C says int or short might work)
 424 if test "$scm_stdint_has_int16"; then
 425   SCM_I_GSC_T_INT16='"int16_t"'
 426   SCM_I_GSC_NEEDS_STDINT_H=1
 427 elif test "$scm_inttypes_has_int16"; then
 428   SCM_I_GSC_T_INT16='"int16_t"'
 429   SCM_I_GSC_NEEDS_INTTYPES_H=1
 430 elif test "$ac_cv_sizeof_int" -eq 2; then
 431   SCM_I_GSC_T_INT16='"int"'
 432 elif test "$ac_cv_sizeof_short" -eq 2; then
 433   SCM_I_GSC_T_INT16='"short"'
 434 else
 435   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 436 fi
 437 AC_SUBST([SCM_I_GSC_T_INT16])
 438
 439 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 440 if test "$scm_stdint_has_uint16"; then
 441   SCM_I_GSC_T_UINT16='"uint16_t"'
 442   SCM_I_GSC_NEEDS_STDINT_H=1
 443 elif test "$scm_inttypes_has_uint16"; then
 444   SCM_I_GSC_T_UINT16='"uint16_t"'
 445   SCM_I_GSC_NEEDS_INTTYPES_H=1
 446 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 447   SCM_I_GSC_T_UINT16='"unsigned int"'
 448 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 449   SCM_I_GSC_T_UINT16='"unsigned short"'
 450 else
 451   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 452 fi
 453 AC_SUBST([SCM_I_GSC_T_UINT16])
 454
 455
 456 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 457 if test "$scm_stdint_has_int32"; then
 458   SCM_I_GSC_T_INT32='"int32_t"'
 459   SCM_I_GSC_NEEDS_STDINT_H=1
 460 elif test "$scm_inttypes_has_int32"; then
 461   SCM_I_GSC_T_INT32='"int32_t"'
 462   SCM_I_GSC_NEEDS_INTTYPES_H=1
 463 elif test "$ac_cv_sizeof_int" -eq 4; then
 464   SCM_I_GSC_T_INT32='"int"'
 465 elif test "$ac_cv_sizeof_long" -eq 4; then
 466   SCM_I_GSC_T_INT32='"long"'
 467 elif test "$ac_cv_sizeof_short" -eq 4; then
 468   SCM_I_GSC_T_INT32='"short"'
 469 else
 470   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 471 fi
 472 AC_SUBST([SCM_I_GSC_T_INT32])
 473
 474 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 475 if test "$scm_stdint_has_uint32"; then
 476   SCM_I_GSC_T_UINT32='"uint32_t"'
 477   SCM_I_GSC_NEEDS_STDINT_H=1
 478 elif test "$scm_inttypes_has_uint32"; then
 479   SCM_I_GSC_T_UINT32='"uint32_t"'
 480   SCM_I_GSC_NEEDS_INTTYPES_H=1
 481 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 482   SCM_I_GSC_T_UINT32='"unsigned int"'
 483 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 484   SCM_I_GSC_T_UINT32='"unsigned long"'
 485 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 486   SCM_I_GSC_T_UINT32='"unsigned short"'
 487 else
 488   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 489 fi
 490 AC_SUBST([SCM_I_GSC_T_UINT32])
 491
 492 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 493 ### Also try 'long long' and '__int64' if we have it.
 494 SCM_I_GSC_T_INT64=0
 495 if test "$scm_stdint_has_int64"; then
 496   SCM_I_GSC_T_INT64='"int64_t"'
 497   SCM_I_GSC_NEEDS_STDINT_H=1
 498 elif test "$scm_inttypes_has_int64"; then
 499   SCM_I_GSC_T_INT64='"int64_t"'
 500   SCM_I_GSC_NEEDS_INTTYPES_H=1
 501 elif test "$ac_cv_sizeof_int" -eq 8; then
 502   SCM_I_GSC_T_INT64='"int"'
 503 elif test "$ac_cv_sizeof_long" -eq 8; then
 504   SCM_I_GSC_T_INT64='"long"'
 505 elif test "$ac_cv_sizeof_short" -eq 8; then
 506   SCM_I_GSC_T_INT64='"short"'
 507 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 508   SCM_I_GSC_T_INT64='"long long"'
 509 elif test "$ac_cv_sizeof___int64" -eq 8; then
 510   SCM_I_GSC_T_INT64='"__int64"'
 511 else
 512   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 513 fi
 514 AC_SUBST([SCM_I_GSC_T_INT64])
 515
 516
 517 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 518 ### Also try 'long long' and '__int64' if we have it.
 519 SCM_I_GSC_T_UINT64=0
 520 if test "$scm_stdint_has_uint64"; then
 521   SCM_I_GSC_T_UINT64='"uint64_t"'
 522   SCM_I_GSC_NEEDS_STDINT_H=1
 523 elif test "$scm_inttypes_has_uint64"; then
 524   SCM_I_GSC_T_UINT64='"uint64_t"'
 525   SCM_I_GSC_NEEDS_INTTYPES_H=1
 526 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 527   SCM_I_GSC_T_UINT64='"unsigned int"'
 528 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 529   SCM_I_GSC_T_UINT64='"unsigned long"'
 530 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 531   SCM_I_GSC_T_UINT64='"unsigned short"'
 532 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 533   SCM_I_GSC_T_UINT64='"unsigned long long"'
 534 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 535   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 536 else
 537   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 538 fi
 539 AC_SUBST([SCM_I_GSC_T_UINT64])
 540
 541 ### Required type scm_t_intmax
 542 ###
 543 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 544 ### none of them is available, we use 'long'.
 545 ###
 546 SCM_I_GSC_T_INTMAX=0
 547 if test "$scm_stdint_has_intmax"; then
 548   SCM_I_GSC_T_INTMAX='"intmax_t"'
 549   SCM_I_GSC_NEEDS_STDINT_H=1
 550 elif test "$scm_inttypes_has_intmax"; then
 551   SCM_I_GSC_T_INTMAX='"intmax_t"'
 552   SCM_I_GSC_NEEDS_INTTYPES_H=1
 553 elif test "$ac_cv_sizeof___int64" -ne 0; then
 554   SCM_I_GSC_T_INTMAX='"__int64"'
 555 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 556   SCM_I_GSC_T_INTMAX='"long long"'
 557 else
 558   SCM_I_GSC_T_INTMAX='"long"'
 559 fi
 560 AC_SUBST([SCM_I_GSC_T_INTMAX])
 561
 562 ### Required type scm_t_uintmax
 563 ###
 564 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 565 ### this order.  When none of them is available, we use 'unsigned long'.
 566 ###
 567 SCM_I_GSC_T_UINTMAX=0
 568 if test "$scm_stdint_has_uintmax"; then
 569   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 570   SCM_I_GSC_NEEDS_STDINT_H=1
 571 elif test "$scm_inttypes_has_uintmax"; then
 572   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 573   SCM_I_GSC_NEEDS_INTTYPES_H=1
 574 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 575   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 576 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 577   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 578 else
 579   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 580 fi
 581 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 582
 583
 584 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 585 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 586
 587 AC_HEADER_STDC
 588 AC_HEADER_TIME
 589 AC_HEADER_SYS_WAIT
 590 AC_HEADER_DIRENT
 591
 592 # Reason for checking:
 593 #
 594 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 595 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 596 #
 597 AC_CHECK_MEMBER([struct dirent64.d_name],
 598   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 599   [ #ifndef _LARGEFILE64_SOURCE
 600     # define _LARGEFILE64_SOURCE
 601     #endif
 602
 603     /* Per Autoconf manual.  */
 604     #include <sys/types.h>
 605     #ifdef HAVE_DIRENT_H
 606     # include <dirent.h>
 607     #else
 608     # define dirent direct
 609     # ifdef HAVE_SYS_NDIR_H
 610     #  include <sys/ndir.h>
 611     # endif
 612     # ifdef HAVE_SYS_DIR_H
 613     #  include <sys/dir.h>
 614     # endif
 615     # ifdef HAVE_NDIR_H
 616     #  include <ndir.h>
 617     # endif
 618     #endif ])
 619 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 620
 621 # Reasons for testing:
 622 #   complex.h - new in C99
 623 #   fenv.h - available in C99, but not older systems
 624 #   process.h - mingw specific
 625 #   langinfo.h, nl_types.h - SuS v2
 626 #
 627 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 628 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 629 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 630 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 631 direct.h langinfo.h nl_types.h])
 632
 633 # "complex double" is new in C99, and "complex" is only a keyword if
 634 # <complex.h> is included
 635 AC_CHECK_TYPES(complex double,,,
 636 [#if HAVE_COMPLEX_H
 637 #include <complex.h>
 638 #endif])
 639
 640 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 641 # when testing.
 642 AC_CHECK_TYPE(socklen_t, ,
 643   [AC_DEFINE_UNQUOTED(socklen_t, int,
 644                       [Define to `int' if <sys/socket.h> does not define.])],
 645   [#if HAVE_SYS_TYPES_H
 646 #include <sys/types.h>
 647 #endif
 648 #include <sys/socket.h>
 649 ])
 650 AC_CHECK_TYPE(struct ip_mreq)
 651
 652 GUILE_HEADER_LIBC_WITH_UNISTD
 653
 654 AC_TYPE_GETGROUPS
 655 AC_TYPE_SIGNAL
 656 AC_TYPE_MODE_T
 657
 658 # On mingw -lm is empty, so this test is unnecessary, but it's
 659 # harmless so we don't hard-code to suppress it.
 660 #
 661 AC_CHECK_LIB(m, cos)
 662
 663 AC_CHECK_FUNCS(gethostbyname)
 664 if test $ac_cv_func_gethostbyname = no; then
 665     AC_CHECK_LIB(nsl, gethostbyname)
 666 fi
 667
 668 AC_CHECK_FUNCS(connect)
 669 if test $ac_cv_func_connect = no; then
 670     AC_CHECK_LIB(socket, connect)
 671 fi
 672
 673 dnl
 674 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 675 dnl
 676 EXTRA_DEFS=""
 677 case $host in
 678   *-*-mingw*)
 679     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 680       [Define if you have the <winsock2.h> header file.])])
 681     AC_CHECK_LIB(ws2_32, main)
 682     AC_LIBOBJ([win32-uname])
 683     AC_LIBOBJ([win32-dirent])
 684     if test "$enable_networking" = yes ; then
 685       AC_LIBOBJ([win32-socket])
 686     fi
 687     if test "$enable_shared" = yes ; then
 688       EXTRA_DEFS="-DSCM_IMPORT"
 689       AC_DEFINE(USE_DLL_IMPORT, 1,
 690         [Define if you need additional CPP macros on Win32 platforms.])
 691     fi
 692     ;;
 693 esac
 694 AC_SUBST(EXTRA_DEFS)
 695
 696 # Reasons for testing:
 697 #   crt_externs.h - Darwin specific
 698 #
 699 AC_CHECK_HEADERS([assert.h crt_externs.h])
 700
 701 # Reasons for testing:
 702 #   DINFINITY - OSF specific
 703 #   DQNAN - OSF specific
 704 #       (DINFINITY and DQNAN are actually global variables, not functions)
 705 #   chsize - an MS-DOS-ism, found in mingw
 706 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 707 #       for gcc to provide the "complex double" type but the system to not
 708 #       have functions like cexp and clog
 709 #   clog10 - not in mingw (though others like clog and csqrt are)
 710 #   fesetround - available in C99, but not older systems
 711 #   ftruncate - posix, but probably not older systems (current mingw
 712 #               has it as an inline for chsize)
 713 #   ioctl - not in mingw.
 714 #   gmtime_r - recent posix, not on old systems
 715 #   pipe - not in mingw
 716 #   _pipe - specific to mingw, taking 3 args
 717 #   readdir_r - recent posix, not on old systems
 718 #   readdir64_r - not available on HP-UX 11.11
 719 #   stat64 - SuS largefile stuff, not on old systems
 720 #   sysconf - not on old systems
 721 #   truncate - not in mingw
 722 #   isblank - available as a GNU extension or in C99
 723 #   _NSGetEnviron - Darwin specific
 724 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 725 #   nl_langinfo - X/Open, not available on Windows.
 726 #
 727 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo])
 728
 729 # Reasons for testing:
 730 #   netdb.h - not in mingw
 731 #   sys/param.h - not in mingw
 732 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 733 #       check this specifically, we need it for the timespec test below.
 734 #   sethostname - the function itself check because it's not in mingw,
 735 #       the DECL is checked because Solaris 10 doens't have in any header
 736 #   xlocale.h - needed on Darwin for the `locale_t' API
 737 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 738 #       declaration isn't anywhere.
 739 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 740 #       only with `_XOPEN_SOURCE' or some such.
 741 #
 742 AC_CHECK_HEADERS(crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h xlocale.h)
 743 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 744 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 745
 746 # crypt() may or may not be available, for instance in some countries there
 747 # are restrictions on cryptography.
 748 #
 749 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 750 # -lcrypt library (eg. Debian GNU/Linux).
 751 #
 752 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 753 # be careful to avoid -lcrypt in this case, since libtool will see there's
 754 # only a static libcrypt and decide to build only a static libguile.
 755 #
 756 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 757 # libraries already in that list.
 758 #
 759 AC_SEARCH_LIBS(crypt, crypt,
 760   [AC_DEFINE(HAVE_CRYPT,1,
 761              [Define to 1 if you have the `crypt' function.])])
 762
 763 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 764 # work; in the reported cases so far, 1.0fi works well instead.  According
 765 # to the C99 spec, the complex.h header must provide a working definition
 766 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 767 # is a workaround for the failure of some systems to conform to C99.
 768 if test "$ac_cv_type_complex_double" = yes; then
 769   AC_MSG_CHECKING([for i])
 770   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 771 #if HAVE_COMPLEX_H
 772 #include <complex.h>
 773 #endif
 774 complex double z;
 775 ]], [[
 776 z = _Complex_I;
 777 ]])],
 778     [AC_DEFINE(GUILE_I,_Complex_I,[The imaginary unit (positive square root of -1).])
 779      AC_MSG_RESULT([_Complex_I])],
 780     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 781 #if HAVE_COMPLEX_H
 782 #include <complex.h>
 783 #endif
 784 complex double z;
 785 ]],[[
 786 z = 1.0fi;
 787 ]])],
 788   [AC_DEFINE(GUILE_I,1.0fi)
 789    AC_MSG_RESULT([1.0fi])],
 790   [ac_cv_type_complex_double=no
 791    AC_MSG_RESULT([not available])])])
 792 fi
 793
 794 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 795 # csqrt(-i) returned a negative real part, when it should be positive
 796 # for the principal root.
 797 #
 798 if test "$ac_cv_type_complex_double" = yes; then
 799
 800   AC_CACHE_CHECK([whether csqrt is usable],
 801     guile_cv_use_csqrt,
 802     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 803 #include <complex.h>
 804 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 805    constant, we want to test libc. */
 806 volatile complex double z = - _Complex_I;
 807 int
 808 main (void)
 809 {
 810   z = csqrt (z);
 811   if (creal (z) > 0.0)
 812     return 0;  /* good */
 813   else
 814     return 1;  /* bad */
 815 }]])],
 816     [guile_cv_use_csqrt=yes],
 817     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 818     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 819   case $guile_cv_use_csqrt in
 820     yes*)
 821       AC_DEFINE(HAVE_USABLE_CSQRT, 1, [Define to 1 if csqrt is bug-free])
 822       ;;
 823   esac
 824 fi
 825
 826
 827 dnl GMP tests
 828 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 829   [AC_MSG_ERROR([GNU MP not found, see README])])
 830
 831 # mpz_import is a macro so we need to include <gmp.h>
 832 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gmp.h>]],
 833                                 [[mpz_import (0, 0, 0, 0, 0, 0, 0); ]])],
 834   [],
 835   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see README])])
 836
 837 dnl i18n tests
 838 #AC_CHECK_HEADERS([libintl.h])
 839 #AC_CHECK_FUNCS(gettext)
 840 #if test $ac_cv_func_gettext = no; then
 841 #   AC_CHECK_LIB(intl, gettext)
 842 #fi
 843 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 844 AM_GNU_GETTEXT([external], [need-ngettext])
 845
 846 ### Some systems don't declare some functions.  On such systems, we
 847 ### need to at least provide our own K&R-style declarations.
 848
 849 ### GUILE_FUNC_DECLARED(function, headerfile)
 850
 851 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 852 ### not there, #define MISSING_FUNCTION_DECL.
 853 AC_DEFUN([GUILE_FUNC_DECLARED], [
 854   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 855     AC_EGREP_HEADER($1, $2,
 856                     guile_cv_func_$1_declared=yes,
 857                     guile_cv_func_$1_declared=no))
 858   if test [x$guile_cv_func_]$1[_declared] = xno; then
 859     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 860       [Define if the operating system supplies $1 without declaring it.])
 861   fi
 862 ])
 863
 864 GUILE_FUNC_DECLARED(sleep, unistd.h)
 865 GUILE_FUNC_DECLARED(usleep, unistd.h)
 866
 867 AC_CHECK_DECLS([strptime],,,
 868 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 869 #include <time.h>])
 870
 871 ### On some systems usleep has no return value.  If it does have one,
 872 ### we'd like to return it; otherwise, we'll fake it.
 873 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 874   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 875                    unistd.h,
 876                    [guile_cv_func_usleep_return_type=void],
 877                    [guile_cv_func_usleep_return_type=int])])
 878 case "$guile_cv_func_usleep_return_type" in
 879   "void" )
 880     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 881       [Define if the system headers declare usleep to return void.])
 882   ;;
 883 esac
 884
 885 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 886 if test -n "$have_sys_un_h" ; then
 887   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 888     [Define if the system supports Unix-domain (file-domain) sockets.])
 889 fi
 890
 891 AC_CHECK_FUNCS(getrlimit setrlimit)
 892
 893 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 894
 895 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 896                setnetent    getnetent    endnetent    dnl
 897                setprotoent  getprotoent  endprotoent  dnl
 898                setservent   getservent   endservent   dnl
 899                getnetbyaddr getnetbyname dnl
 900                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 901                inet_pton inet_ntop)
 902
 903 # struct sockaddr field sin_len is only present on BSD systems.
 904 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 905 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 906 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 907 [#ifdef HAVE_SYS_TYPES_H
 908 #include <sys/types.h>
 909 #endif
 910 #include <netinet/in.h>])
 911
 912 AC_MSG_CHECKING(for __libc_stack_end)
 913 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 914 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 915 extern char *__libc_stack_end;]],
 916    [[printf("%p", (char*) __libc_stack_end);]])],
 917    [guile_cv_have_libc_stack_end=yes],
 918    [guile_cv_have_libc_stack_end=no])])
 919 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 920
 921 if test $guile_cv_have_libc_stack_end = yes; then
 922   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 923            [Define if you have the __libc_stack_end variable.])
 924 fi
 925
 926 dnl Some systems do not declare this.  Some systems do declare it, as a
 927 dnl macro.  With cygwin it may be in a DLL.
 928
 929 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 930 AC_CACHE_VAL(guile_cv_have_h_errno,
 931   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 932                                       [[int a = h_errno;]])],
 933   [guile_cv_have_h_errno=yes],
 934   [guile_cv_have_h_errno=no])])
 935 AC_MSG_RESULT($guile_cv_have_h_errno)
 936 if test $guile_cv_have_h_errno = yes; then
 937   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 938 fi
 939
 940 AC_MSG_CHECKING(whether uint32_t is defined)
 941 AC_CACHE_VAL(guile_cv_have_uint32_t,
 942   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 943                    #if HAVE_STDINT_H
 944                    #include <stdint.h>
 945                    #endif
 946                    #ifndef HAVE_NETDB_H
 947                    #include <netdb.h>
 948                    #endif]],
 949                    [[uint32_t a;]])],
 950                    [guile_cv_have_uint32_t=yes],
 951                    [guile_cv_have_uint32_t=no])])
 952 AC_MSG_RESULT($guile_cv_have_uint32_t)
 953 if test $guile_cv_have_uint32_t = yes; then
 954   AC_DEFINE(HAVE_UINT32_T, 1,
 955     [Define if uint32_t typedef is defined when netdb.h is include.])
 956 fi
 957
 958 AC_MSG_CHECKING(for working IPv6 support)
 959 AC_CACHE_VAL(guile_cv_have_ipv6,
 960 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 961 #ifdef HAVE_SYS_TYPES_H
 962 #include <sys/types.h>
 963 #endif
 964 #include <netinet/in.h>
 965 #include <sys/socket.h>]],
 966 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
 967 [guile_cv_have_ipv6=yes],
 968 [guile_cv_have_ipv6=no])])
 969 AC_MSG_RESULT($guile_cv_have_ipv6)
 970 if test $guile_cv_have_ipv6 = yes; then
 971   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 972 fi
 973
 974 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 975 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 976 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 977 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 978 #ifdef HAVE_SYS_TYPES_H
 979 #include <sys/types.h>
 980 #endif
 981 #include <netinet/in.h>]],
 982 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
 983 [guile_cv_have_sin6_scope_id=yes],
 984 [guile_cv_have_sin6_scope_id=no])])
 985 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 986 if test $guile_cv_have_sin6_scope_id = yes; then
 987   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 988     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 989 fi
 990
 991 # struct sockaddr_in6 field sin_len is only present on BSD systems
 992 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 993 [#ifdef HAVE_SYS_TYPES_H
 994 #include <sys/types.h>
 995 #endif
 996 #include <netinet/in.h>])
 997
 998 AC_MSG_CHECKING(whether localtime caches TZ)
 999 AC_CACHE_VAL(guile_cv_localtime_cache,
1000 [if test x$ac_cv_func_tzset = xyes; then
1001 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1002 #if STDC_HEADERS
1003 # include <stdlib.h>
1004 #endif
1005 extern char **environ;
1006 unset_TZ ()
1007 {
1008   char **from, **to;
1009   for (to = from = environ; (*to = *from); from++)
1010     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1011       to++;
1012 }
1013 char TZ_GMT0[] = "TZ=GMT0";
1014 char TZ_PST8[] = "TZ=PST8";
1015 main()
1016 {
1017   time_t now = time ((time_t *) 0);
1018   int hour_GMT0, hour_unset;
1019   if (putenv (TZ_GMT0) != 0)
1020     exit (1);
1021   hour_GMT0 = localtime (&now)->tm_hour;
1022   unset_TZ ();
1023   hour_unset = localtime (&now)->tm_hour;
1024   if (putenv (TZ_PST8) != 0)
1025     exit (1);
1026   if (localtime (&now)->tm_hour == hour_GMT0)
1027     exit (1);
1028   unset_TZ ();
1029   if (localtime (&now)->tm_hour != hour_unset)
1030     exit (1);
1031   exit (0);
1032 }]])],
1033 [guile_cv_localtime_cache=no],
1034 [guile_cv_localtime_cache=yes],
1035 [# If we have tzset, assume the worst when cross-compiling.
1036 guile_cv_localtime_cache=yes])
1037 else
1038         # If we lack tzset, report that localtime does not cache TZ,
1039         # since we can't invalidate the cache if we don't have tzset.
1040         guile_cv_localtime_cache=no
1041 fi])dnl
1042 AC_MSG_RESULT($guile_cv_localtime_cache)
1043 if test $guile_cv_localtime_cache = yes; then
1044   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
1045 fi
1046
1047 dnl Test whether system calls are restartable by default on the
1048 dnl current system.  If they are not, we put a loop around every system
1049 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
1050 dnl change from the default behaviour.  On the other hand, if signals
1051 dnl are restartable then the loop is not installed and when libguile
1052 dnl initialises it also resets the behaviour of each signal to cause a
1053 dnl restart (in case a different runtime had a different default
1054 dnl behaviour for some reason: e.g., different versions of linux seem
1055 dnl to behave differently.)
1056
1057 AC_SYS_RESTARTABLE_SYSCALLS
1058
1059 if test "$enable_regex" = yes; then
1060    if test "$ac_cv_header_regex_h" = yes ||
1061       test "$ac_cv_header_rxposix_h" = yes ||
1062       test "$ac_cv_header_rx_rxposix_h" = yes; then
1063      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1064      [AC_CHECK_LIB(rx, main)
1065       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1066      [AC_CHECK_LIB(regex, main)
1067       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1068      )
1069      dnl The following should not be necessary, but for some reason
1070      dnl autoheader misses it if we don't include it!
1071      if test "$ac_cv_func_regcomp_norx" = yes ||
1072         test "$ac_cv_func_regcomp_regex" = yes ||
1073         test "$ac_cv_func_regcomp_rx" = yes; then
1074        AC_DEFINE(HAVE_REGCOMP, 1,
1075          [This is included as part of a workaround for a autoheader bug.])
1076      fi
1077    fi
1078 fi
1079
1080 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
1081
1082 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
1083
1084 # Reasons for testing:
1085 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1086 #                                older systems
1087 #   sincos - GLIBC extension
1088 #
1089 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1090
1091 # C99 specifies isinf and isnan as macros.
1092 # HP-UX provides only macros, no functions.
1093 # glibc 2.3.2 provides both macros and functions.
1094 # IRIX 6.5 and Solaris 8 only provide functions.
1095 #
1096 # The following tests detect isinf and isnan either as functions or as
1097 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1098 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1099 #
1100 AC_MSG_CHECKING([for isinf])
1101 AC_LINK_IFELSE(AC_LANG_SOURCE(
1102 [[#include <math.h>
1103 volatile double x = 0.0;
1104 int main () { return (isinf(x) != 0); }]]),
1105   [AC_MSG_RESULT([yes])
1106    AC_DEFINE(HAVE_ISINF, 1,
1107              [Define to 1 if you have the `isinf' macro or function.])],
1108   [AC_MSG_RESULT([no])])
1109 AC_MSG_CHECKING([for isnan])
1110 AC_LINK_IFELSE(AC_LANG_SOURCE(
1111 [[#include <math.h>
1112 volatile double x = 0.0;
1113 int main () { return (isnan(x) != 0); }]]),
1114   [AC_MSG_RESULT([yes])
1115    AC_DEFINE(HAVE_ISNAN, 1,
1116              [Define to 1 if you have the `isnan' macro or function.])],
1117   [AC_MSG_RESULT([no])])
1118
1119 # Reasons for checking:
1120 #
1121 #     st_rdev
1122 #     st_blksize
1123 #     st_blocks   not in mingw
1124 #     tm_gmtoff   BSD+GNU, not in C99
1125 #
1126 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1127 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1128 #
1129 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks])
1130
1131 AC_STRUCT_TIMEZONE
1132 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1133 [#include <time.h>
1134 #ifdef TIME_WITH_SYS_TIME
1135 # include <sys/time.h>
1136 # include <time.h>
1137 #else
1138 # if HAVE_SYS_TIME_H
1139 #  include <sys/time.h>
1140 # else
1141 #  include <time.h>
1142 # endif
1143 #endif
1144 ])
1145 GUILE_STRUCT_UTIMBUF
1146
1147
1148 #--------------------------------------------------------------------
1149 #
1150 # Which way does the stack grow?
1151 #
1152 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1153 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1154 # very similar code, so in future we could look at using that.
1155 #
1156 # An important detail is that the code involves find_stack_direction
1157 # calling _itself_ - which means that find_stack_direction (or at
1158 # least the second find_stack_direction() call) cannot be inlined.
1159 # If the code could be inlined, that might cause the test to give
1160 # an incorrect answer.
1161 #--------------------------------------------------------------------
1162
1163 SCM_I_GSC_STACK_GROWS_UP=0
1164 AC_RUN_IFELSE([AC_LANG_SOURCE(
1165 [AC_INCLUDES_DEFAULT
1166 int
1167 find_stack_direction ()
1168 {
1169   static char *addr = 0;
1170   auto char dummy;
1171   if (addr == 0)
1172     {
1173       addr = &dummy;
1174       return find_stack_direction ();
1175     }
1176   else
1177     return (&dummy > addr) ? 1 : -1;
1178 }
1179
1180 int
1181 main ()
1182 {
1183   return find_stack_direction () < 0;
1184 }])],
1185                [SCM_I_GSC_STACK_GROWS_UP=1],
1186                [],
1187                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1188
1189 AC_CHECK_SIZEOF(float)
1190 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1191     AC_DEFINE(SCM_SINGLES, 1,
1192               [Define this if floats are the same size as longs.])
1193 fi
1194
1195 AC_MSG_CHECKING(for struct linger)
1196 AC_CACHE_VAL(scm_cv_struct_linger,
1197         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1198 #include <sys/types.h>
1199 #include <sys/socket.h>]],
1200                           [[struct linger lgr;  lgr.l_linger = 100]])],
1201                           [scm_cv_struct_linger="yes"],
1202                           [scm_cv_struct_linger="no"]))
1203 AC_MSG_RESULT($scm_cv_struct_linger)
1204 if test $scm_cv_struct_linger = yes; then
1205         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
1206           [Define this if your system defines struct linger, for use with the
1207            getsockopt and setsockopt system calls.])
1208 fi
1209
1210
1211 # On mingw, struct timespec is in <pthread.h>.
1212 #
1213 AC_MSG_CHECKING(for struct timespec)
1214 AC_CACHE_VAL(scm_cv_struct_timespec,
1215         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1216 #include <time.h>
1217 #if HAVE_PTHREAD_H
1218 #include <pthread.h>
1219 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1220           [scm_cv_struct_timespec="yes"],
1221           [scm_cv_struct_timespec="no"]))
1222 AC_MSG_RESULT($scm_cv_struct_timespec)
1223 if test $scm_cv_struct_timespec = yes; then
1224   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
1225     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1226 fi
1227
1228 #--------------------------------------------------------------------
1229 #
1230 # Flags for thread support
1231 #
1232 #--------------------------------------------------------------------
1233
1234 SCM_I_GSC_USE_PTHREAD_THREADS=0
1235 SCM_I_GSC_USE_NULL_THREADS=0
1236 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1237 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1238
1239 ### What thread package has the user asked for?
1240 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1241             , with_threads=yes)
1242
1243 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1244 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1245
1246 case "$with_threads" in
1247   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1248
1249     build_pthread_support="yes"
1250
1251     ACX_PTHREAD(CC="$PTHREAD_CC"
1252       LIBS="$PTHREAD_LIBS $LIBS"
1253       SCM_I_GSC_USE_PTHREAD_THREADS=1
1254       with_threads="pthreads",
1255       with_threads="null")
1256
1257     old_CFLAGS="$CFLAGS"
1258     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1259
1260     # Reasons for testing:
1261     #     pthread_getattr_np - "np" meaning "non portable" says it
1262     #         all; not present on MacOS X or Solaris 10
1263     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1264     #         all; specific to MacOS X
1265     #     pthread_sigmask - not available on mingw
1266     #
1267     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1268
1269     # On past versions of Solaris, believe 8 through 10 at least, you
1270     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1271     # This is contrary to POSIX:
1272     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1273     # Check here if this style is required.
1274     #
1275     # glibc (2.3.6 at least) works both with or without braces, so the
1276     # test checks whether it works without.
1277     #
1278
1279     if test "$GCC" = "yes"; then
1280       # Since GCC only issues a warning for missing braces, so we need
1281       # `-Werror' to catch it.
1282       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1283     fi
1284
1285     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1286       guile_cv_need_braces_on_pthread_once_init,
1287       [AC_COMPILE_IFELSE([#include <pthread.h>
1288          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1289         [guile_cv_need_braces_on_pthread_once_init=no],
1290         [guile_cv_need_braces_on_pthread_once_init=yes])])
1291     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1292       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1293     fi
1294
1295     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1296     # 6.5.30m with GCC 3.3.
1297     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1298       guile_cv_need_braces_on_pthread_mutex_initializer,
1299       [AC_COMPILE_IFELSE([#include <pthread.h>
1300          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1301         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1302         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1303     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1304       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1305     fi
1306
1307     CFLAGS="$old_CFLAGS"
1308
1309     # On Solaris, sched_yield lives in -lrt.
1310     AC_SEARCH_LIBS(sched_yield, rt)
1311
1312   ;;
1313 esac
1314
1315 case "$with_threads" in
1316   "pthreads")
1317   ;;
1318   "no" | "null")
1319     SCM_I_GSC_USE_NULL_THREADS=1
1320     with_threads="null-threads"
1321   ;;
1322   * )
1323     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1324   ;;
1325 esac
1326
1327 AC_MSG_CHECKING(what kind of threads to support)
1328 AC_MSG_RESULT($with_threads)
1329
1330 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1331   [test "x$build_pthread_support" = "xyes"])
1332
1333
1334 ## Check whether pthread_attr_getstack works for the main thread
1335
1336 if test "$with_threads" = pthreads; then
1337
1338 AC_MSG_CHECKING(whether pthread_attr_getstack works for the main thread)
1339 old_CFLAGS="$CFLAGS"
1340 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1341 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1342 #if HAVE_PTHREAD_ATTR_GETSTACK
1343 #include <pthread.h>
1344
1345 int main ()
1346 {
1347   pthread_attr_t attr;
1348   void *start, *end;
1349   size_t size;
1350
1351   pthread_getattr_np (pthread_self (), &attr);
1352   pthread_attr_getstack (&attr, &start, &size);
1353   end = (char *)start + size;
1354
1355   if ((void *)&attr < start || (void *)&attr >= end)
1356     return 1;
1357   else
1358     return 0;
1359 }
1360 #else
1361 int main ()
1362 {
1363   return 1;
1364 }
1365 #endif
1366 ]])],
1367 [works=yes
1368 AC_DEFINE(PTHREAD_ATTR_GETSTACK_WORKS, [1], [Define when pthread_att_get_stack works for the main thread])],
1369 [works=no],
1370 [])
1371 CFLAGS="$old_CFLAGS"
1372 AC_MSG_RESULT($works)
1373
1374 fi # with_threads=pthreads
1375
1376
1377 ## Cross building
1378 if test "$cross_compiling" = "yes"; then
1379   AC_MSG_CHECKING(cc for build)
1380   ## /usr/bin/cc still uses wrong assembler
1381   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1382   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1383 else
1384   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1385 fi
1386
1387 ## AC_MSG_CHECKING("if we are cross compiling")
1388 ## AC_MSG_RESULT($cross_compiling)
1389 if test "$cross_compiling" = "yes"; then
1390    AC_MSG_RESULT($CC_FOR_BUILD)
1391 fi
1392
1393 ## No need as yet to be more elaborate
1394 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1395
1396 AC_SUBST(cross_compiling)
1397 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1398 AC_SUBST(CCLD_FOR_BUILD)
1399
1400 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1401 ## --HOST is the platform that PACKAGE is compiled for.
1402 HOST_CC="$CC_FOR_BUILD"
1403 AC_SUBST(HOST_CC)
1404
1405 if test "$cross_compiling" = "yes"; then
1406   AC_MSG_CHECKING(guile for build)
1407   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1408 else
1409   GUILE_FOR_BUILD='$(preinstguile)'
1410 fi
1411
1412 ## AC_MSG_CHECKING("if we are cross compiling")
1413 ## AC_MSG_RESULT($cross_compiling)
1414 if test "$cross_compiling" = "yes"; then
1415    AC_MSG_RESULT($GUILE_FOR_BUILD)
1416 fi
1417 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1418 AC_SUBST(GUILE_FOR_BUILD)
1419
1420 ## If we're using GCC, ask for aggressive warnings.
1421 case "$GCC" in
1422   yes )
1423     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1424     ## much stuff with generic function pointers for that to really be
1425     ## less than exasperating.
1426     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1427     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1428     GCC_CFLAGS="-Wall -Wmissing-prototypes"
1429     # Do this here so we don't screw up any of the tests above that might
1430     # not be "warning free"
1431     if test "${GUILE_ERROR_ON_WARNING}" = yes
1432     then
1433         GCC_CFLAGS="${GCC_CFLAGS} -Werror"
1434         enable_compile_warnings=no
1435     fi
1436     ;;
1437 esac
1438
1439 AC_SUBST(GCC_CFLAGS)
1440
1441 ## If we're creating a shared library (using libtool!), then we'll
1442 ## need to generate a list of .lo files corresponding to the .o files
1443 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1444 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1445
1446 ## We also need to create corresponding .doc and .x files
1447 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1448 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1449
1450 AC_SUBST(GUILE_MAJOR_VERSION)
1451 AC_SUBST(GUILE_MINOR_VERSION)
1452 AC_SUBST(GUILE_MICRO_VERSION)
1453 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1454 AC_SUBST(GUILE_VERSION)
1455
1456 #######################################################################
1457 # library versioning
1458
1459 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1460 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1461 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1462 AC_SUBST(LIBGUILE_INTERFACE)
1463
1464 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1465 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1466 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1467 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1468 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1469
1470 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1471 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1472 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1473 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1474 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1475
1476 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1477 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1478 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1479 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1480 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1481
1482 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1483 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1484 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1485 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1486 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1487
1488 AC_SUBST(LIBGUILE_I18N_MAJOR)
1489 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1490 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1491 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1492 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1493
1494
1495 #######################################################################
1496
1497 dnl Tell guile-config what flags guile users should compile and link with.
1498 GUILE_LIBS="$LDFLAGS $LIBS"
1499 GUILE_CFLAGS="$CPPFLAGS $PTHREAD_CFLAGS"
1500 AC_SUBST(GUILE_LIBS)
1501 AC_SUBST(GUILE_CFLAGS)
1502
1503 AC_SUBST(AWK)
1504 AC_SUBST(LIBLOBJS)
1505 AC_SUBST(EXTRA_DOT_DOC_FILES)
1506 AC_SUBST(EXTRA_DOT_X_FILES)
1507
1508 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1509 top_builddir_absolute=`pwd`
1510 AC_SUBST(top_builddir_absolute)
1511 top_srcdir_absolute=`(cd $srcdir && pwd)`
1512 AC_SUBST(top_srcdir_absolute)
1513
1514 dnl We need `sitedir' in `guile-1.8.pc'.
1515 dnl Note: `sitedir' must be kept in sync with `GUILE_SITE_DIR' in `guile.m4'.
1516 pkgdatadir="$datadir/guile"
1517 sitedir="$pkgdatadir/site"
1518 AC_SUBST([sitedir])
1519
1520 # Additional SCM_I_GSC definitions are above.
1521 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1522 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1523 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1524 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1525 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1526 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1527 AC_SUBST([SCM_I_GSC_C_INLINE])
1528 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1529
1530 AC_CONFIG_FILES([
1531   Makefile
1532   am/Makefile
1533   lib/Makefile
1534   benchmark-suite/Makefile
1535   doc/Makefile
1536   doc/goops/Makefile
1537   doc/r5rs/Makefile
1538   doc/ref/Makefile
1539   doc/tutorial/Makefile
1540   emacs/Makefile
1541   examples/Makefile
1542   lang/Makefile
1543   libguile/Makefile
1544   srfi/Makefile
1545   test-suite/Makefile
1546   test-suite/standalone/Makefile
1547   meta/Makefile
1548   module/Makefile
1549   testsuite/Makefile
1550 ])
1551
1552 AC_CONFIG_FILES([meta/guile-1.8.pc])
1553 AC_CONFIG_FILES([meta/guile-1.8-uninstalled.pc])
1554 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1555 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1556 AC_CONFIG_FILES([meta/guile], [chmod +x meta/guile])
1557 AC_CONFIG_FILES([meta/uninstalled-env], [chmod +x meta/uninstalled-env])
1558 AC_CONFIG_FILES([meta/gdb-uninstalled-guile], [chmod +x meta/gdb-uninstalled-guile])
1559 AC_CONFIG_FILES([libguile/guile-snarf],
1560                 [chmod +x libguile/guile-snarf])
1561 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1562                 [chmod +x libguile/guile-doc-snarf])
1563 AC_CONFIG_FILES([libguile/guile-func-name-check],
1564                 [chmod +x libguile/guile-func-name-check])
1565 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1566                 [chmod +x libguile/guile-snarf-docs])
1567 AC_CONFIG_FILES([test-suite/standalone/test-use-srfi],
1568                 [chmod +x test-suite/standalone/test-use-srfi])
1569 AC_CONFIG_FILES([test-suite/standalone/test-fast-slot-ref],
1570                 [chmod +x test-suite/standalone/test-fast-slot-ref])
1571
1572 AC_OUTPUT
1573
1574 dnl Local Variables:
1575 dnl comment-start: "dnl "
1576 dnl comment-end: ""
1577 dnl comment-start-skip: "\\bdnl\\b\\s *"
1578 dnl End: