configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.61)
  29
  30 dnl  `patsubst' here deletes the newline which "echo" prints.  We can't use
  31 dnl  "echo -n" since -n is not portable (see autoconf manual "Limitations of
  32 dnl  Builtins"), in particular on solaris it results in a literal "-n" in
  33 dnl  the output.
  34 dnl
  35 AC_INIT(patsubst(m4_esyscmd(. ./GUILE-VERSION && echo ${PACKAGE}),[
  36 ]),
  37         patsubst(m4_esyscmd(. ./GUILE-VERSION && echo ${GUILE_VERSION}),[
  38 ]),
  39         [bug-guile@gnu.org])
  40 AC_CONFIG_AUX_DIR([build-aux])
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR(GUILE-VERSION)
  43
  44 AM_INIT_AUTOMAKE([gnu no-define check-news -Wall -Wno-override])
  45
  46 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  47 AC_CONFIG_SRCDIR([GUILE-VERSION])
  48
  49 . $srcdir/GUILE-VERSION
  50
  51 AM_MAINTAINER_MODE
  52 AC_CONFIG_HEADERS([config.h])
  53 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  54
  55 #--------------------------------------------------------------------
  56 #
  57 # Independent Subdirectories
  58 #
  59 #--------------------------------------------------------------------
  60
  61 AC_CONFIG_SUBDIRS(guile-readline)
  62
  63 #--------------------------------------------------------------------
  64
  65 AC_LANG([C])
  66
  67 dnl Some more checks for Win32
  68 AC_CANONICAL_HOST
  69
  70 AC_LIBTOOL_WIN32_DLL
  71
  72 AC_PROG_INSTALL
  73 AC_PROG_CC
  74 gl_EARLY
  75 AC_PROG_CPP
  76 AC_PROG_AWK
  77
  78 dnl Gnulib.
  79 gl_INIT
  80
  81 AC_PROG_CC_C89
  82
  83 # for per-target cflags in the libguile subdir
  84 AM_PROG_CC_C_O
  85
  86 AC_LIBTOOL_DLOPEN
  87 AC_PROG_LIBTOOL
  88 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  89   [AC_MSG_ERROR([libltdl not found.  See README.])])
  90
  91 AC_SUBST(DLPREOPEN)
  92
  93 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  94 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  95
  96 AM_PATH_LISPDIR
  97
  98 #--------------------------------------------------------------------
  99 #
 100 # User options (after above tests that may set default CFLAGS etc.)
 101 #
 102 #--------------------------------------------------------------------
 103
 104 GUILE_ERROR_ON_WARNING="yes"
 105
 106 AC_ARG_ENABLE(error-on-warning,
 107   [  --enable-error-on-warning    treat compile warnings as errors],
 108   [case "${enableval}" in
 109      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 110      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 111      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 112    esac])
 113
 114 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
 115 AC_ARG_ENABLE(debug-freelist,
 116   [  --enable-debug-freelist include garbage collector freelist debugging code],
 117   if test "$enable_debug_freelist" = y \
 118      || test "$enable_debug_freelist" = yes; then
 119     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 120   fi)
 121
 122 AC_ARG_ENABLE(debug-malloc,
 123   [  --enable-debug-malloc   include malloc debugging code],
 124   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 125     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 126       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 127   fi)
 128
 129 SCM_I_GSC_GUILE_DEBUG=0
 130 AC_ARG_ENABLE(guile-debug,
 131   [AS_HELP_STRING([--enable-guile-debug],
 132                   [include internal debugging functions])],
 133   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 134     SCM_I_GSC_GUILE_DEBUG=1
 135   fi)
 136
 137 AC_ARG_ENABLE(posix,
 138   [  --disable-posix         omit posix interfaces],,
 139   enable_posix=yes)
 140
 141 AC_ARG_ENABLE(networking,
 142   [  --disable-networking    omit networking interfaces],,
 143   enable_networking=yes)
 144
 145 AC_ARG_ENABLE(regex,
 146   [  --disable-regex         omit regular expression interfaces],,
 147   enable_regex=yes)
 148
 149 AC_ARG_ENABLE([discouraged],
 150   AS_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 151
 152 if test "$enable_discouraged" = no; then
 153   SCM_I_GSC_ENABLE_DISCOURAGED=0
 154 else
 155   SCM_I_GSC_ENABLE_DISCOURAGED=1
 156 fi
 157
 158 AC_ARG_ENABLE([deprecated],
 159   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 160
 161 if test "$enable_deprecated" = no; then
 162   SCM_I_GSC_ENABLE_DEPRECATED=0
 163 else
 164   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 165     warn_default=summary
 166   elif test "$enable_deprecated" = shutup; then
 167     warn_default=no
 168   else
 169     warn_default=$enable_deprecated
 170   fi
 171   SCM_I_GSC_ENABLE_DEPRECATED=1
 172   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 173   [Define this to control the default warning level for deprecated features.])
 174 fi
 175
 176 AC_ARG_ENABLE(elisp,
 177   [  --disable-elisp         omit Emacs Lisp support],,
 178   enable_elisp=yes)
 179
 180 dnl  Added the following configure option in January 2008 following
 181 dnl  investigation of problems with "64" system and library calls on
 182 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 183 dnl  system has stat64, it will have all the other 64 APIs too; but on
 184 dnl  Darwin, stat64 is there but other APIs are missing.
 185 dnl
 186 dnl  It also appears, from the Darwin docs, that most system call APIs
 187 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 188 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 189 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 190 dnl
 191 dnl  A similar problem has been reported for HP-UX:
 192 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 193 dnl
 194 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 195 dnl  better than no Guile at all, we provide this option to suppress
 196 dnl  trying to use "64" calls.
 197 dnl
 198 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 199 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 200 dnl  missing out on that.  If so, someone can work on that in the future.
 201 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 202 dnl  wasn't building before.
 203 AC_MSG_CHECKING([whether to use system and library "64" calls])
 204 AC_ARG_WITH([64-calls],
 205   AS_HELP_STRING([--without-64-calls],
 206                  [don't attempt to use system and library calls with "64" in their names]),
 207   [use_64_calls=$withval],
 208   [use_64_calls=yes
 209    case $host in
 210      *-apple-darwin* )
 211        use_64_calls=no
 212        ;;
 213      powerpc-ibm-aix* )
 214        use_64_calls=no
 215        ;;
 216    esac])
 217 AC_MSG_RESULT($use_64_calls)
 218 case "$use_64_calls" in
 219   y* )
 220     AC_DEFINE(GUILE_USE_64_CALLS, 1,
 221       [Define to 1 in order to try to use "64" versions of system and library calls.])
 222     ;;
 223 esac
 224
 225 #--------------------------------------------------------------------
 226
 227 dnl Check for dynamic linking
 228
 229 use_modules=yes
 230 AC_ARG_WITH(modules,
 231 [  --with-modules[=FILES]  Add support for dynamic modules],
 232 use_modules="$withval")
 233 test -z "$use_modules" && use_modules=yes
 234 DLPREOPEN=
 235 if test "$use_modules" != no; then
 236   if test "$use_modules" = yes; then
 237     DLPREOPEN="-dlpreopen force"
 238   else
 239     DLPREOPEN="-export-dynamic"
 240     for module in $use_modules; do
 241       DLPREOPEN="$DLPREOPEN -dlopen $module"
 242     done
 243   fi
 244 fi
 245
 246 dnl files which are destined for separate modules.
 247
 248 if test "$use_modules" != no; then
 249    AC_LIBOBJ([dynl])
 250 fi
 251
 252 if test "$enable_posix" = yes; then
 253    AC_LIBOBJ([filesys])
 254    AC_LIBOBJ([posix])
 255    AC_DEFINE(HAVE_POSIX, 1,
 256      [Define this if you want support for POSIX system calls in Guile.])
 257 fi
 258
 259 if test "$enable_networking" = yes; then
 260    AC_LIBOBJ([net_db])
 261    AC_LIBOBJ([socket])
 262    AC_DEFINE(HAVE_NETWORKING, 1,
 263      [Define this if you want support for networking in Guile.])
 264 fi
 265
 266 if test "$enable_debug_malloc" = yes; then
 267    AC_LIBOBJ([debug-malloc])
 268 fi
 269
 270 if test "$enable_elisp" = yes; then
 271   SCM_I_GSC_ENABLE_ELISP=1
 272 else
 273   SCM_I_GSC_ENABLE_ELISP=0
 274 fi
 275 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 276
 277 AC_C_CONST
 278
 279 # "volatile" is used in a couple of tests below.
 280 AC_C_VOLATILE
 281
 282 AC_C_INLINE
 283 if test "$ac_cv_c_inline" != no; then
 284   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 285 else
 286   SCM_I_GSC_C_INLINE=NULL
 287 fi
 288 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 289
 290 AC_C_BIGENDIAN
 291
 292 AC_CHECK_SIZEOF(char)
 293 AC_CHECK_SIZEOF(unsigned char)
 294 AC_CHECK_SIZEOF(short)
 295 AC_CHECK_SIZEOF(unsigned short)
 296 AC_CHECK_SIZEOF(int)
 297 AC_CHECK_SIZEOF(unsigned int)
 298 AC_CHECK_SIZEOF(long)
 299 AC_CHECK_SIZEOF(unsigned long)
 300 AC_CHECK_SIZEOF(size_t)
 301 AC_CHECK_SIZEOF(long long)
 302 AC_CHECK_SIZEOF(unsigned long long)
 303 AC_CHECK_SIZEOF(__int64)
 304 AC_CHECK_SIZEOF(unsigned __int64)
 305 AC_CHECK_SIZEOF(void *)
 306 AC_CHECK_SIZEOF(intptr_t)
 307 AC_CHECK_SIZEOF(uintptr_t)
 308 AC_CHECK_SIZEOF(ptrdiff_t)
 309 AC_CHECK_SIZEOF(size_t)
 310 AC_CHECK_SIZEOF(off_t)
 311
 312 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 313   AC_MSG_ERROR(sizes of long and void* are not identical)
 314 fi
 315
 316 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 317   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 318 else
 319   SCM_I_GSC_T_PTRDIFF='"long"'
 320 fi
 321 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 322
 323 AC_CHECK_HEADERS([stdint.h])
 324 AC_CHECK_HEADERS([inttypes.h])
 325
 326 AC_CHECK_SIZEOF(intmax_t)
 327
 328 SCM_I_GSC_NEEDS_STDINT_H=0
 329 SCM_I_GSC_NEEDS_INTTYPES_H=0
 330
 331 ### intptr and uintptr (try not to use inttypes if we don't have to)
 332 if test "$ac_cv_header_inttypes_h" = yes; then
 333   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 334     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 335 #include <stdio.h>])
 336     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 337       SCM_I_GSC_NEEDS_INTTYPES_H=1
 338     fi
 339   fi
 340   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 341     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 342 #include <stdio.h>])
 343     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 344       SCM_I_GSC_NEEDS_INTTYPES_H=1
 345     fi
 346   fi
 347 fi
 348
 349 ### See what's provided by stdint.h
 350 if test "$ac_cv_header_stdint_h" = yes; then
 351    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 352    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 353    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 354    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 355    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 356    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 357    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 358    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 359    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 360    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 361 fi
 362
 363 # so we don't get confused by the cache (wish there was a better way
 364 # to check particular headers for the same type...)
 365
 366 unset ac_cv_type_int8_t
 367 unset ac_cv_type_uint8_t
 368 unset ac_cv_type_int16_t
 369 unset ac_cv_type_uint16_t
 370 unset ac_cv_type_int32_t
 371 unset ac_cv_type_uint32_t
 372 unset ac_cv_type_int64_t
 373 unset ac_cv_type_uint64_t
 374 unset ac_cv_type_intmax_t
 375 unset ac_cv_type_uintmax_t
 376
 377 ### See what's provided by inttypes.h
 378 if test "$ac_cv_header_inttypes_h" = yes; then
 379   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 380   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 381   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 382   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 383   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 384   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 385   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 386   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 387   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 388   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 389 fi
 390
 391 # Try hard to find definitions for some required scm_t_*int* types.
 392
 393 ### Required type scm_t_int8
 394 if test "$scm_stdint_has_int8"; then
 395   SCM_I_GSC_T_INT8='"int8_t"'
 396   SCM_I_GSC_NEEDS_STDINT_H=1
 397 elif test "$scm_inttypes_has_int8"; then
 398   SCM_I_GSC_T_INT8='"int8_t"'
 399   SCM_I_GSC_NEEDS_INTTYPES_H=1
 400 elif test "$ac_cv_sizeof_char" -eq 1; then
 401   SCM_I_GSC_T_INT8='"signed char"'
 402 else
 403   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 404 fi
 405 AC_SUBST([SCM_I_GSC_T_INT8])
 406
 407 ### Required type scm_t_uint8
 408 if test "$scm_stdint_has_uint8"; then
 409   SCM_I_GSC_T_UINT8='"uint8_t"'
 410   SCM_I_GSC_NEEDS_STDINT_H=1
 411 elif test "$scm_inttypes_has_uint8"; then
 412   SCM_I_GSC_T_UINT8='"uint8_t"'
 413   SCM_I_GSC_NEEDS_INTTYPES_H=1
 414 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 415   SCM_I_GSC_T_UINT8='"unsigned char"'
 416 else
 417   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 418 fi
 419 AC_SUBST([SCM_I_GSC_T_UINT8])
 420
 421 ### Required type scm_t_int16 (ANSI C says int or short might work)
 422 if test "$scm_stdint_has_int16"; then
 423   SCM_I_GSC_T_INT16='"int16_t"'
 424   SCM_I_GSC_NEEDS_STDINT_H=1
 425 elif test "$scm_inttypes_has_int16"; then
 426   SCM_I_GSC_T_INT16='"int16_t"'
 427   SCM_I_GSC_NEEDS_INTTYPES_H=1
 428 elif test "$ac_cv_sizeof_int" -eq 2; then
 429   SCM_I_GSC_T_INT16='"int"'
 430 elif test "$ac_cv_sizeof_short" -eq 2; then
 431   SCM_I_GSC_T_INT16='"short"'
 432 else
 433   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 434 fi
 435 AC_SUBST([SCM_I_GSC_T_INT16])
 436
 437 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 438 if test "$scm_stdint_has_uint16"; then
 439   SCM_I_GSC_T_UINT16='"uint16_t"'
 440   SCM_I_GSC_NEEDS_STDINT_H=1
 441 elif test "$scm_inttypes_has_uint16"; then
 442   SCM_I_GSC_T_UINT16='"uint16_t"'
 443   SCM_I_GSC_NEEDS_INTTYPES_H=1
 444 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 445   SCM_I_GSC_T_UINT16='"unsigned int"'
 446 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 447   SCM_I_GSC_T_UINT16='"unsigned short"'
 448 else
 449   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 450 fi
 451 AC_SUBST([SCM_I_GSC_T_UINT16])
 452
 453
 454 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 455 if test "$scm_stdint_has_int32"; then
 456   SCM_I_GSC_T_INT32='"int32_t"'
 457   SCM_I_GSC_NEEDS_STDINT_H=1
 458 elif test "$scm_inttypes_has_int32"; then
 459   SCM_I_GSC_T_INT32='"int32_t"'
 460   SCM_I_GSC_NEEDS_INTTYPES_H=1
 461 elif test "$ac_cv_sizeof_int" -eq 4; then
 462   SCM_I_GSC_T_INT32='"int"'
 463 elif test "$ac_cv_sizeof_long" -eq 4; then
 464   SCM_I_GSC_T_INT32='"long"'
 465 elif test "$ac_cv_sizeof_short" -eq 4; then
 466   SCM_I_GSC_T_INT32='"short"'
 467 else
 468   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 469 fi
 470 AC_SUBST([SCM_I_GSC_T_INT32])
 471
 472 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 473 if test "$scm_stdint_has_uint32"; then
 474   SCM_I_GSC_T_UINT32='"uint32_t"'
 475   SCM_I_GSC_NEEDS_STDINT_H=1
 476 elif test "$scm_inttypes_has_uint32"; then
 477   SCM_I_GSC_T_UINT32='"uint32_t"'
 478   SCM_I_GSC_NEEDS_INTTYPES_H=1
 479 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 480   SCM_I_GSC_T_UINT32='"unsigned int"'
 481 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 482   SCM_I_GSC_T_UINT32='"unsigned long"'
 483 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 484   SCM_I_GSC_T_UINT32='"unsigned short"'
 485 else
 486   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 487 fi
 488 AC_SUBST([SCM_I_GSC_T_UINT32])
 489
 490 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 491 ### Also try 'long long' and '__int64' if we have it.
 492 SCM_I_GSC_T_INT64=0
 493 if test "$scm_stdint_has_int64"; then
 494   SCM_I_GSC_T_INT64='"int64_t"'
 495   SCM_I_GSC_NEEDS_STDINT_H=1
 496 elif test "$scm_inttypes_has_int64"; then
 497   SCM_I_GSC_T_INT64='"int64_t"'
 498   SCM_I_GSC_NEEDS_INTTYPES_H=1
 499 elif test "$ac_cv_sizeof_int" -eq 8; then
 500   SCM_I_GSC_T_INT64='"int"'
 501 elif test "$ac_cv_sizeof_long" -eq 8; then
 502   SCM_I_GSC_T_INT64='"long"'
 503 elif test "$ac_cv_sizeof_short" -eq 8; then
 504   SCM_I_GSC_T_INT64='"short"'
 505 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 506   SCM_I_GSC_T_INT64='"long long"'
 507 elif test "$ac_cv_sizeof___int64" -eq 8; then
 508   SCM_I_GSC_T_INT64='"__int64"'
 509 else
 510   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 511 fi
 512 AC_SUBST([SCM_I_GSC_T_INT64])
 513
 514
 515 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 516 ### Also try 'long long' and '__int64' if we have it.
 517 SCM_I_GSC_T_UINT64=0
 518 if test "$scm_stdint_has_uint64"; then
 519   SCM_I_GSC_T_UINT64='"uint64_t"'
 520   SCM_I_GSC_NEEDS_STDINT_H=1
 521 elif test "$scm_inttypes_has_uint64"; then
 522   SCM_I_GSC_T_UINT64='"uint64_t"'
 523   SCM_I_GSC_NEEDS_INTTYPES_H=1
 524 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 525   SCM_I_GSC_T_UINT64='"unsigned int"'
 526 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 527   SCM_I_GSC_T_UINT64='"unsigned long"'
 528 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 529   SCM_I_GSC_T_UINT64='"unsigned short"'
 530 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 531   SCM_I_GSC_T_UINT64='"unsigned long long"'
 532 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 533   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 534 else
 535   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 536 fi
 537 AC_SUBST([SCM_I_GSC_T_UINT64])
 538
 539 ### Required type scm_t_intmax
 540 ###
 541 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 542 ### none of them is available, we use 'long'.
 543 ###
 544 SCM_I_GSC_T_INTMAX=0
 545 if test "$scm_stdint_has_intmax"; then
 546   SCM_I_GSC_T_INTMAX='"intmax_t"'
 547   SCM_I_GSC_NEEDS_STDINT_H=1
 548 elif test "$scm_inttypes_has_intmax"; then
 549   SCM_I_GSC_T_INTMAX='"intmax_t"'
 550   SCM_I_GSC_NEEDS_INTTYPES_H=1
 551 elif test "$ac_cv_sizeof___int64" -ne 0; then
 552   SCM_I_GSC_T_INTMAX='"__int64"'
 553 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 554   SCM_I_GSC_T_INTMAX='"long long"'
 555 else
 556   SCM_I_GSC_T_INTMAX='"long"'
 557 fi
 558 AC_SUBST([SCM_I_GSC_T_INTMAX])
 559
 560 ### Required type scm_t_uintmax
 561 ###
 562 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 563 ### this order.  When none of them is available, we use 'unsigned long'.
 564 ###
 565 SCM_I_GSC_T_UINTMAX=0
 566 if test "$scm_stdint_has_uintmax"; then
 567   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 568   SCM_I_GSC_NEEDS_STDINT_H=1
 569 elif test "$scm_inttypes_has_uintmax"; then
 570   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 571   SCM_I_GSC_NEEDS_INTTYPES_H=1
 572 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 573   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 574 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 575   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 576 else
 577   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 578 fi
 579 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 580
 581
 582 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 583 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 584
 585 AC_HEADER_STDC
 586 AC_HEADER_TIME
 587 AC_HEADER_SYS_WAIT
 588 AC_HEADER_DIRENT
 589
 590 # Reason for checking:
 591 #
 592 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 593 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 594 #
 595 AC_CHECK_MEMBER([struct dirent64.d_name],
 596   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 597   [ #ifndef _LARGEFILE64_SOURCE
 598     # define _LARGEFILE64_SOURCE
 599     #endif
 600
 601     /* Per Autoconf manual.  */
 602     #include <sys/types.h>
 603     #ifdef HAVE_DIRENT_H
 604     # include <dirent.h>
 605     #else
 606     # define dirent direct
 607     # ifdef HAVE_SYS_NDIR_H
 608     #  include <sys/ndir.h>
 609     # endif
 610     # ifdef HAVE_SYS_DIR_H
 611     #  include <sys/dir.h>
 612     # endif
 613     # ifdef HAVE_NDIR_H
 614     #  include <ndir.h>
 615     # endif
 616     #endif ])
 617 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 618
 619 # Reasons for testing:
 620 #   complex.h - new in C99
 621 #   fenv.h - available in C99, but not older systems
 622 #   process.h - mingw specific
 623 #   langinfo.h, nl_types.h - SuS v2
 624 #
 625 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 626 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 627 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 628 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 629 direct.h langinfo.h nl_types.h])
 630
 631 # "complex double" is new in C99, and "complex" is only a keyword if
 632 # <complex.h> is included
 633 AC_CHECK_TYPES(complex double,,,
 634 [#if HAVE_COMPLEX_H
 635 #include <complex.h>
 636 #endif])
 637
 638 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 639 # when testing.
 640 AC_CHECK_TYPE(socklen_t, ,
 641   [AC_DEFINE_UNQUOTED(socklen_t, int,
 642                       [Define to `int' if <sys/socket.h> does not define.])],
 643   [#if HAVE_SYS_TYPES_H
 644 #include <sys/types.h>
 645 #endif
 646 #include <sys/socket.h>
 647 ])
 648 AC_CHECK_TYPE(struct ip_mreq)
 649
 650 GUILE_HEADER_LIBC_WITH_UNISTD
 651
 652 AC_TYPE_GETGROUPS
 653 AC_TYPE_SIGNAL
 654 AC_TYPE_MODE_T
 655
 656 # On mingw -lm is empty, so this test is unnecessary, but it's
 657 # harmless so we don't hard-code to suppress it.
 658 #
 659 AC_CHECK_LIB(m, cos)
 660
 661 AC_CHECK_FUNCS(gethostbyname)
 662 if test $ac_cv_func_gethostbyname = no; then
 663     AC_CHECK_LIB(nsl, gethostbyname)
 664 fi
 665
 666 AC_CHECK_FUNCS(connect)
 667 if test $ac_cv_func_connect = no; then
 668     AC_CHECK_LIB(socket, connect)
 669 fi
 670
 671 dnl
 672 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 673 dnl
 674 EXTRA_DEFS=""
 675 case $host in
 676   *-*-mingw*)
 677     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 678       [Define if you have the <winsock2.h> header file.])])
 679     AC_CHECK_LIB(ws2_32, main)
 680     AC_LIBOBJ([win32-uname])
 681     AC_LIBOBJ([win32-dirent])
 682     if test "$enable_networking" = yes ; then
 683       AC_LIBOBJ([win32-socket])
 684     fi
 685     if test "$enable_shared" = yes ; then
 686       EXTRA_DEFS="-DSCM_IMPORT"
 687       AC_DEFINE(USE_DLL_IMPORT, 1,
 688         [Define if you need additional CPP macros on Win32 platforms.])
 689     fi
 690     ;;
 691 esac
 692 AC_SUBST(EXTRA_DEFS)
 693
 694 # Reasons for testing:
 695 #   crt_externs.h - Darwin specific
 696 #
 697 AC_CHECK_HEADERS([assert.h crt_externs.h])
 698
 699 # Reasons for testing:
 700 #   DINFINITY - OSF specific
 701 #   DQNAN - OSF specific
 702 #       (DINFINITY and DQNAN are actually global variables, not functions)
 703 #   chsize - an MS-DOS-ism, found in mingw
 704 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 705 #       for gcc to provide the "complex double" type but the system to not
 706 #       have functions like cexp and clog
 707 #   clog10 - not in mingw (though others like clog and csqrt are)
 708 #   fesetround - available in C99, but not older systems
 709 #   ftruncate - posix, but probably not older systems (current mingw
 710 #               has it as an inline for chsize)
 711 #   ioctl - not in mingw.
 712 #   gmtime_r - recent posix, not on old systems
 713 #   pipe - not in mingw
 714 #   _pipe - specific to mingw, taking 3 args
 715 #   readdir_r - recent posix, not on old systems
 716 #   readdir64_r - not available on HP-UX 11.11
 717 #   stat64 - SuS largefile stuff, not on old systems
 718 #   sysconf - not on old systems
 719 #   truncate - not in mingw
 720 #   isblank - available as a GNU extension or in C99
 721 #   _NSGetEnviron - Darwin specific
 722 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 723 #   nl_langinfo - X/Open, not available on Windows.
 724 #
 725 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo])
 726
 727 # Reasons for testing:
 728 #   netdb.h - not in mingw
 729 #   sys/param.h - not in mingw
 730 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 731 #       check this specifically, we need it for the timespec test below.
 732 #   sethostname - the function itself check because it's not in mingw,
 733 #       the DECL is checked because Solaris 10 doens't have in any header
 734 #   xlocale.h - needed on Darwin for the `locale_t' API
 735 #
 736 AC_CHECK_HEADERS(crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h xlocale.h)
 737 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 738 AC_CHECK_DECLS([sethostname])
 739
 740 # crypt() may or may not be available, for instance in some countries there
 741 # are restrictions on cryptography.
 742 #
 743 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 744 # -lcrypt library (eg. Debian GNU/Linux).
 745 #
 746 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 747 # be careful to avoid -lcrypt in this case, since libtool will see there's
 748 # only a static libcrypt and decide to build only a static libguile.
 749 #
 750 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 751 # libraries already in that list.
 752 #
 753 AC_SEARCH_LIBS(crypt, crypt,
 754   [AC_DEFINE(HAVE_CRYPT,1,
 755              [Define to 1 if you have the `crypt' function.])])
 756
 757 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 758 # work; in the reported cases so far, 1.0fi works well instead.  According
 759 # to the C99 spec, the complex.h header must provide a working definition
 760 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 761 # is a workaround for the failure of some systems to conform to C99.
 762 if test "$ac_cv_type_complex_double" = yes; then
 763   AC_MSG_CHECKING([for i])
 764   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 765 #if HAVE_COMPLEX_H
 766 #include <complex.h>
 767 #endif
 768 complex double z;
 769 ]], [[
 770 z = _Complex_I;
 771 ]])],
 772     [AC_DEFINE(GUILE_I,_Complex_I,[The imaginary unit (positive square root of -1).])
 773      AC_MSG_RESULT([_Complex_I])],
 774     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 775 #if HAVE_COMPLEX_H
 776 #include <complex.h>
 777 #endif
 778 complex double z;
 779 ]],[[
 780 z = 1.0fi;
 781 ]])],
 782   [AC_DEFINE(GUILE_I,1.0fi)
 783    AC_MSG_RESULT([1.0fi])],
 784   [ac_cv_type_complex_double=no
 785    AC_MSG_RESULT([not available])])])
 786 fi
 787
 788 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 789 # csqrt(-i) returned a negative real part, when it should be positive
 790 # for the principal root.
 791 #
 792 if test "$ac_cv_type_complex_double" = yes; then
 793
 794   AC_CACHE_CHECK([whether csqrt is usable],
 795     guile_cv_use_csqrt,
 796     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 797 #include <complex.h>
 798 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 799    constant, we want to test libc. */
 800 volatile complex double z = - _Complex_I;
 801 int
 802 main (void)
 803 {
 804   z = csqrt (z);
 805   if (creal (z) > 0.0)
 806     return 0;  /* good */
 807   else
 808     return 1;  /* bad */
 809 }]])],
 810     [guile_cv_use_csqrt=yes],
 811     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 812     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 813   case $guile_cv_use_csqrt in
 814     yes*)
 815       AC_DEFINE(HAVE_USABLE_CSQRT, 1, [Define to 1 if csqrt is bug-free])
 816       ;;
 817   esac
 818 fi
 819
 820
 821 dnl GMP tests
 822 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 823   [AC_MSG_ERROR([GNU MP not found, see README])])
 824
 825 # mpz_import is a macro so we need to include <gmp.h>
 826 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gmp.h>]],
 827                                 [[mpz_import (0, 0, 0, 0, 0, 0, 0); ]])],
 828   [],
 829   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see README])])
 830
 831 dnl i18n tests
 832 #AC_CHECK_HEADERS([libintl.h])
 833 #AC_CHECK_FUNCS(gettext)
 834 #if test $ac_cv_func_gettext = no; then
 835 #   AC_CHECK_LIB(intl, gettext)
 836 #fi
 837 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 838 AM_GNU_GETTEXT([external], [need-ngettext])
 839
 840 ### Some systems don't declare some functions.  On such systems, we
 841 ### need to at least provide our own K&R-style declarations.
 842
 843 ### GUILE_FUNC_DECLARED(function, headerfile)
 844
 845 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 846 ### not there, #define MISSING_FUNCTION_DECL.
 847 AC_DEFUN([GUILE_FUNC_DECLARED], [
 848   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 849     AC_EGREP_HEADER($1, $2,
 850                     guile_cv_func_$1_declared=yes,
 851                     guile_cv_func_$1_declared=no))
 852   if test [x$guile_cv_func_]$1[_declared] = xno; then
 853     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 854       [Define if the operating system supplies $1 without declaring it.])
 855   fi
 856 ])
 857
 858 GUILE_FUNC_DECLARED(sleep, unistd.h)
 859 GUILE_FUNC_DECLARED(usleep, unistd.h)
 860
 861 AC_CHECK_DECLS([strptime],,,
 862 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 863 #include <time.h>])
 864
 865 ### On some systems usleep has no return value.  If it does have one,
 866 ### we'd like to return it; otherwise, we'll fake it.
 867 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 868   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 869                    unistd.h,
 870                    [guile_cv_func_usleep_return_type=void],
 871                    [guile_cv_func_usleep_return_type=int])])
 872 case "$guile_cv_func_usleep_return_type" in
 873   "void" )
 874     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 875       [Define if the system headers declare usleep to return void.])
 876   ;;
 877 esac
 878
 879 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 880 if test -n "$have_sys_un_h" ; then
 881   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 882     [Define if the system supports Unix-domain (file-domain) sockets.])
 883 fi
 884
 885 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 886
 887 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 888                setnetent    getnetent    endnetent    dnl
 889                setprotoent  getprotoent  endprotoent  dnl
 890                setservent   getservent   endservent   dnl
 891                getnetbyaddr getnetbyname dnl
 892                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 893                inet_pton inet_ntop)
 894
 895 # struct sockaddr field sin_len is only present on BSD systems.
 896 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 897 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 898 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 899 [#ifdef HAVE_SYS_TYPES_H
 900 #include <sys/types.h>
 901 #endif
 902 #include <netinet/in.h>])
 903
 904 AC_MSG_CHECKING(for __libc_stack_end)
 905 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 906 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 907 extern char *__libc_stack_end;]],
 908    [[printf("%p", (char*) __libc_stack_end);]])],
 909    [guile_cv_have_libc_stack_end=yes],
 910    [guile_cv_have_libc_stack_end=no])])
 911 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 912
 913 if test $guile_cv_have_libc_stack_end = yes; then
 914   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 915            [Define if you have the __libc_stack_end variable.])
 916 fi
 917
 918 dnl Some systems do not declare this.  Some systems do declare it, as a
 919 dnl macro.  With cygwin it may be in a DLL.
 920
 921 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 922 AC_CACHE_VAL(guile_cv_have_h_errno,
 923   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 924                                       [[int a = h_errno;]])],
 925   [guile_cv_have_h_errno=yes],
 926   [guile_cv_have_h_errno=no])])
 927 AC_MSG_RESULT($guile_cv_have_h_errno)
 928 if test $guile_cv_have_h_errno = yes; then
 929   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 930 fi
 931
 932 AC_MSG_CHECKING(whether uint32_t is defined)
 933 AC_CACHE_VAL(guile_cv_have_uint32_t,
 934   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 935                    #if HAVE_STDINT_H
 936                    #include <stdint.h>
 937                    #endif
 938                    #ifndef HAVE_NETDB_H
 939                    #include <netdb.h>
 940                    #endif]],
 941                    [[uint32_t a;]])],
 942                    [guile_cv_have_uint32_t=yes],
 943                    [guile_cv_have_uint32_t=no])])
 944 AC_MSG_RESULT($guile_cv_have_uint32_t)
 945 if test $guile_cv_have_uint32_t = yes; then
 946   AC_DEFINE(HAVE_UINT32_T, 1,
 947     [Define if uint32_t typedef is defined when netdb.h is include.])
 948 fi
 949
 950 AC_MSG_CHECKING(for working IPv6 support)
 951 AC_CACHE_VAL(guile_cv_have_ipv6,
 952 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 953 #ifdef HAVE_SYS_TYPES_H
 954 #include <sys/types.h>
 955 #endif
 956 #include <netinet/in.h>
 957 #include <sys/socket.h>]],
 958 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
 959 [guile_cv_have_ipv6=yes],
 960 [guile_cv_have_ipv6=no])])
 961 AC_MSG_RESULT($guile_cv_have_ipv6)
 962 if test $guile_cv_have_ipv6 = yes; then
 963   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 964 fi
 965
 966 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 967 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 968 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 969 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 970 #ifdef HAVE_SYS_TYPES_H
 971 #include <sys/types.h>
 972 #endif
 973 #include <netinet/in.h>]],
 974 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
 975 [guile_cv_have_sin6_scope_id=yes],
 976 [guile_cv_have_sin6_scope_id=no])])
 977 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 978 if test $guile_cv_have_sin6_scope_id = yes; then
 979   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 980     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 981 fi
 982
 983 # struct sockaddr_in6 field sin_len is only present on BSD systems
 984 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 985 [#ifdef HAVE_SYS_TYPES_H
 986 #include <sys/types.h>
 987 #endif
 988 #include <netinet/in.h>])
 989
 990 AC_MSG_CHECKING(whether localtime caches TZ)
 991 AC_CACHE_VAL(guile_cv_localtime_cache,
 992 [if test x$ac_cv_func_tzset = xyes; then
 993 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
 994 #if STDC_HEADERS
 995 # include <stdlib.h>
 996 #endif
 997 extern char **environ;
 998 unset_TZ ()
 999 {
1000   char **from, **to;
1001   for (to = from = environ; (*to = *from); from++)
1002     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1003       to++;
1004 }
1005 char TZ_GMT0[] = "TZ=GMT0";
1006 char TZ_PST8[] = "TZ=PST8";
1007 main()
1008 {
1009   time_t now = time ((time_t *) 0);
1010   int hour_GMT0, hour_unset;
1011   if (putenv (TZ_GMT0) != 0)
1012     exit (1);
1013   hour_GMT0 = localtime (&now)->tm_hour;
1014   unset_TZ ();
1015   hour_unset = localtime (&now)->tm_hour;
1016   if (putenv (TZ_PST8) != 0)
1017     exit (1);
1018   if (localtime (&now)->tm_hour == hour_GMT0)
1019     exit (1);
1020   unset_TZ ();
1021   if (localtime (&now)->tm_hour != hour_unset)
1022     exit (1);
1023   exit (0);
1024 }]])],
1025 [guile_cv_localtime_cache=no],
1026 [guile_cv_localtime_cache=yes],
1027 [# If we have tzset, assume the worst when cross-compiling.
1028 guile_cv_localtime_cache=yes])
1029 else
1030         # If we lack tzset, report that localtime does not cache TZ,
1031         # since we can't invalidate the cache if we don't have tzset.
1032         guile_cv_localtime_cache=no
1033 fi])dnl
1034 AC_MSG_RESULT($guile_cv_localtime_cache)
1035 if test $guile_cv_localtime_cache = yes; then
1036   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
1037 fi
1038
1039 dnl Test whether system calls are restartable by default on the
1040 dnl current system.  If they are not, we put a loop around every system
1041 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
1042 dnl change from the default behaviour.  On the other hand, if signals
1043 dnl are restartable then the loop is not installed and when libguile
1044 dnl initialises it also resets the behaviour of each signal to cause a
1045 dnl restart (in case a different runtime had a different default
1046 dnl behaviour for some reason: e.g., different versions of linux seem
1047 dnl to behave differently.)
1048
1049 AC_SYS_RESTARTABLE_SYSCALLS
1050
1051 if test "$enable_regex" = yes; then
1052    if test "$ac_cv_header_regex_h" = yes ||
1053       test "$ac_cv_header_rxposix_h" = yes ||
1054       test "$ac_cv_header_rx_rxposix_h" = yes; then
1055      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1056      [AC_CHECK_LIB(rx, main)
1057       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1058      [AC_CHECK_LIB(regex, main)
1059       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1060      )
1061      dnl The following should not be necessary, but for some reason
1062      dnl autoheader misses it if we don't include it!
1063      if test "$ac_cv_func_regcomp_norx" = yes ||
1064         test "$ac_cv_func_regcomp_regex" = yes ||
1065         test "$ac_cv_func_regcomp_rx" = yes; then
1066        AC_DEFINE(HAVE_REGCOMP, 1,
1067          [This is included as part of a workaround for a autoheader bug.])
1068      fi
1069    fi
1070 fi
1071
1072 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
1073
1074 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
1075
1076 # Reasons for testing:
1077 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1078 #                                older systems
1079 #   sincos - GLIBC extension
1080 #
1081 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1082
1083 # C99 specifies isinf and isnan as macros.
1084 # HP-UX provides only macros, no functions.
1085 # glibc 2.3.2 provides both macros and functions.
1086 # IRIX 6.5 and Solaris 8 only provide functions.
1087 #
1088 # The following tests detect isinf and isnan either as functions or as
1089 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1090 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1091 #
1092 AC_MSG_CHECKING([for isinf])
1093 AC_LINK_IFELSE(AC_LANG_SOURCE(
1094 [[#include <math.h>
1095 volatile double x = 0.0;
1096 int main () { return (isinf(x) != 0); }]]),
1097   [AC_MSG_RESULT([yes])
1098    AC_DEFINE(HAVE_ISINF, 1,
1099              [Define to 1 if you have the `isinf' macro or function.])],
1100   [AC_MSG_RESULT([no])])
1101 AC_MSG_CHECKING([for isnan])
1102 AC_LINK_IFELSE(AC_LANG_SOURCE(
1103 [[#include <math.h>
1104 volatile double x = 0.0;
1105 int main () { return (isnan(x) != 0); }]]),
1106   [AC_MSG_RESULT([yes])
1107    AC_DEFINE(HAVE_ISNAN, 1,
1108              [Define to 1 if you have the `isnan' macro or function.])],
1109   [AC_MSG_RESULT([no])])
1110
1111 # Reasons for checking:
1112 #
1113 #     st_rdev
1114 #     st_blksize
1115 #     st_blocks   not in mingw
1116 #     tm_gmtoff   BSD+GNU, not in C99
1117 #
1118 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1119 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1120 #
1121 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks])
1122
1123 AC_STRUCT_TIMEZONE
1124 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1125 [#include <time.h>
1126 #ifdef TIME_WITH_SYS_TIME
1127 # include <sys/time.h>
1128 # include <time.h>
1129 #else
1130 # if HAVE_SYS_TIME_H
1131 #  include <sys/time.h>
1132 # else
1133 #  include <time.h>
1134 # endif
1135 #endif
1136 ])
1137 GUILE_STRUCT_UTIMBUF
1138
1139
1140 #--------------------------------------------------------------------
1141 #
1142 # Which way does the stack grow?
1143 #
1144 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1145 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1146 # very similar code, so in future we could look at using that.
1147 #
1148 # An important detail is that the code involves find_stack_direction
1149 # calling _itself_ - which means that find_stack_direction (or at
1150 # least the second find_stack_direction() call) cannot be inlined.
1151 # If the code could be inlined, that might cause the test to give
1152 # an incorrect answer.
1153 #--------------------------------------------------------------------
1154
1155 SCM_I_GSC_STACK_GROWS_UP=0
1156 AC_RUN_IFELSE([AC_LANG_SOURCE(
1157 [AC_INCLUDES_DEFAULT
1158 int
1159 find_stack_direction ()
1160 {
1161   static char *addr = 0;
1162   auto char dummy;
1163   if (addr == 0)
1164     {
1165       addr = &dummy;
1166       return find_stack_direction ();
1167     }
1168   else
1169     return (&dummy > addr) ? 1 : -1;
1170 }
1171
1172 int
1173 main ()
1174 {
1175   return find_stack_direction () < 0;
1176 }])],
1177                [SCM_I_GSC_STACK_GROWS_UP=1],
1178                [],
1179                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1180
1181 AC_CHECK_SIZEOF(float)
1182 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1183     AC_DEFINE(SCM_SINGLES, 1,
1184               [Define this if floats are the same size as longs.])
1185 fi
1186
1187 AC_MSG_CHECKING(for struct linger)
1188 AC_CACHE_VAL(scm_cv_struct_linger,
1189         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1190 #include <sys/types.h>
1191 #include <sys/socket.h>]],
1192                           [[struct linger lgr;  lgr.l_linger = 100]])],
1193                           [scm_cv_struct_linger="yes"],
1194                           [scm_cv_struct_linger="no"]))
1195 AC_MSG_RESULT($scm_cv_struct_linger)
1196 if test $scm_cv_struct_linger = yes; then
1197         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
1198           [Define this if your system defines struct linger, for use with the
1199            getsockopt and setsockopt system calls.])
1200 fi
1201
1202
1203 # On mingw, struct timespec is in <pthread.h>.
1204 #
1205 AC_MSG_CHECKING(for struct timespec)
1206 AC_CACHE_VAL(scm_cv_struct_timespec,
1207         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1208 #include <time.h>
1209 #if HAVE_PTHREAD_H
1210 #include <pthread.h>
1211 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1212           [scm_cv_struct_timespec="yes"],
1213           [scm_cv_struct_timespec="no"]))
1214 AC_MSG_RESULT($scm_cv_struct_timespec)
1215 if test $scm_cv_struct_timespec = yes; then
1216   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
1217     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1218 fi
1219
1220 #--------------------------------------------------------------------
1221 #
1222 # Flags for thread support
1223 #
1224 #--------------------------------------------------------------------
1225
1226 SCM_I_GSC_USE_PTHREAD_THREADS=0
1227 SCM_I_GSC_USE_NULL_THREADS=0
1228 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1229 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1230
1231 ### What thread package has the user asked for?
1232 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1233             , with_threads=yes)
1234
1235 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1236 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1237
1238 case "$with_threads" in
1239   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1240
1241     build_pthread_support="yes"
1242
1243     ACX_PTHREAD(CC="$PTHREAD_CC"
1244       LIBS="$PTHREAD_LIBS $LIBS"
1245       SCM_I_GSC_USE_PTHREAD_THREADS=1
1246       with_threads="pthreads",
1247       with_threads="null")
1248
1249     old_CFLAGS="$CFLAGS"
1250     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1251
1252     # Reasons for testing:
1253     #     pthread_getattr_np - "np" meaning "non portable" says it
1254     #         all; not present on MacOS X or Solaris 10
1255     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1256     #         all; specific to MacOS X
1257     #     pthread_sigmask - not available on mingw
1258     #
1259     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1260
1261     # On past versions of Solaris, believe 8 through 10 at least, you
1262     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1263     # This is contrary to POSIX:
1264     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1265     # Check here if this style is required.
1266     #
1267     # glibc (2.3.6 at least) works both with or without braces, so the
1268     # test checks whether it works without.
1269     #
1270
1271     if test "$GCC" = "yes"; then
1272       # Since GCC only issues a warning for missing braces, so we need
1273       # `-Werror' to catch it.
1274       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1275     fi
1276
1277     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1278       guile_cv_need_braces_on_pthread_once_init,
1279       [AC_COMPILE_IFELSE([#include <pthread.h>
1280          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1281         [guile_cv_need_braces_on_pthread_once_init=no],
1282         [guile_cv_need_braces_on_pthread_once_init=yes])])
1283     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1284       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1285     fi
1286
1287     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1288     # 6.5.30m with GCC 3.3.
1289     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1290       guile_cv_need_braces_on_pthread_mutex_initializer,
1291       [AC_COMPILE_IFELSE([#include <pthread.h>
1292          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1293         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1294         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1295     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1296       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1297     fi
1298
1299     CFLAGS="$old_CFLAGS"
1300
1301     # On Solaris, sched_yield lives in -lrt.
1302     AC_SEARCH_LIBS(sched_yield, rt)
1303
1304   ;;
1305 esac
1306
1307 case "$with_threads" in
1308   "pthreads")
1309   ;;
1310   "no" | "null")
1311     SCM_I_GSC_USE_NULL_THREADS=1
1312     with_threads="null-threads"
1313   ;;
1314   * )
1315     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1316   ;;
1317 esac
1318
1319 AC_MSG_CHECKING(what kind of threads to support)
1320 AC_MSG_RESULT($with_threads)
1321
1322 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1323   [test "x$build_pthread_support" = "xyes"])
1324
1325
1326 ## Check whether pthread_attr_getstack works for the main thread
1327
1328 if test "$with_threads" = pthreads; then
1329
1330 AC_MSG_CHECKING(whether pthread_attr_getstack works for the main thread)
1331 old_CFLAGS="$CFLAGS"
1332 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1333 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1334 #if HAVE_PTHREAD_ATTR_GETSTACK
1335 #include <pthread.h>
1336
1337 int main ()
1338 {
1339   pthread_attr_t attr;
1340   void *start, *end;
1341   size_t size;
1342
1343   pthread_getattr_np (pthread_self (), &attr);
1344   pthread_attr_getstack (&attr, &start, &size);
1345   end = (char *)start + size;
1346
1347   if ((void *)&attr < start || (void *)&attr >= end)
1348     return 1;
1349   else
1350     return 0;
1351 }
1352 #else
1353 int main ()
1354 {
1355   return 1;
1356 }
1357 #endif
1358 ]])],
1359 [works=yes
1360 AC_DEFINE(PTHREAD_ATTR_GETSTACK_WORKS, [1], [Define when pthread_att_get_stack works for the main thread])],
1361 [works=no],
1362 [])
1363 CFLAGS="$old_CFLAGS"
1364 AC_MSG_RESULT($works)
1365
1366 fi # with_threads=pthreads
1367
1368
1369 ## Cross building
1370 if test "$cross_compiling" = "yes"; then
1371   AC_MSG_CHECKING(cc for build)
1372   ## /usr/bin/cc still uses wrong assembler
1373   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1374   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1375 else
1376   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1377 fi
1378
1379 ## AC_MSG_CHECKING("if we are cross compiling")
1380 ## AC_MSG_RESULT($cross_compiling)
1381 if test "$cross_compiling" = "yes"; then
1382    AC_MSG_RESULT($CC_FOR_BUILD)
1383 fi
1384
1385 ## No need as yet to be more elaborate
1386 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1387
1388 AC_SUBST(cross_compiling)
1389 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1390 AC_SUBST(CCLD_FOR_BUILD)
1391
1392 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1393 ## --HOST is the platform that PACKAGE is compiled for.
1394 HOST_CC="$CC_FOR_BUILD"
1395 AC_SUBST(HOST_CC)
1396
1397 if test "$cross_compiling" = "yes"; then
1398   AC_MSG_CHECKING(guile for build)
1399   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1400 else
1401   GUILE_FOR_BUILD='$(preinstguile)'
1402 fi
1403
1404 ## AC_MSG_CHECKING("if we are cross compiling")
1405 ## AC_MSG_RESULT($cross_compiling)
1406 if test "$cross_compiling" = "yes"; then
1407    AC_MSG_RESULT($GUILE_FOR_BUILD)
1408 fi
1409 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1410 AC_SUBST(GUILE_FOR_BUILD)
1411
1412 ## If we're using GCC, ask for aggressive warnings.
1413 case "$GCC" in
1414   yes )
1415     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1416     ## much stuff with generic function pointers for that to really be
1417     ## less than exasperating.
1418     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1419     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1420     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1421     # Do this here so we don't screw up any of the tests above that might
1422     # not be "warning free"
1423     if test "${GUILE_ERROR_ON_WARNING}" = yes
1424     then
1425         CFLAGS="${CFLAGS} -Werror"
1426         enable_compile_warnings=no
1427     fi
1428     ;;
1429 esac
1430
1431 ## If we're creating a shared library (using libtool!), then we'll
1432 ## need to generate a list of .lo files corresponding to the .o files
1433 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1434 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1435
1436 ## We also need to create corresponding .doc and .x files
1437 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1438 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1439
1440 AC_SUBST(GUILE_MAJOR_VERSION)
1441 AC_SUBST(GUILE_MINOR_VERSION)
1442 AC_SUBST(GUILE_MICRO_VERSION)
1443 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1444 AC_SUBST(GUILE_VERSION)
1445
1446 #######################################################################
1447 # library versioning
1448
1449 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1450 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1451 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1452 AC_SUBST(LIBGUILE_INTERFACE)
1453
1454 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1455 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1456 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1457 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1458 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1459
1460 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1461 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1462 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1463 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1464 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1465
1466 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1467 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1468 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1469 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1470 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1471
1472 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1473 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1474 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1475 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1476 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1477
1478 AC_SUBST(LIBGUILE_I18N_MAJOR)
1479 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1480 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1481 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1482 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1483
1484
1485 #######################################################################
1486
1487 dnl Tell guile-config what flags guile users should compile and link with.
1488 GUILE_LIBS="$LDFLAGS $LIBS"
1489 GUILE_CFLAGS="$CPPFLAGS $PTHREAD_CFLAGS"
1490 AC_SUBST(GUILE_LIBS)
1491 AC_SUBST(GUILE_CFLAGS)
1492
1493 AC_SUBST(AWK)
1494 AC_SUBST(LIBLOBJS)
1495 AC_SUBST(EXTRA_DOT_DOC_FILES)
1496 AC_SUBST(EXTRA_DOT_X_FILES)
1497
1498 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1499 top_builddir_absolute=`pwd`
1500 AC_SUBST(top_builddir_absolute)
1501 top_srcdir_absolute=`(cd $srcdir && pwd)`
1502 AC_SUBST(top_srcdir_absolute)
1503
1504 dnl We need `sitedir' in `guile-1.8.pc'.
1505 dnl Note: `sitedir' must be kept in sync with `GUILE_SITE_DIR' in `guile.m4'.
1506 pkgdatadir="$datadir/guile"
1507 sitedir="$pkgdatadir/site"
1508 AC_SUBST([sitedir])
1509
1510 # Additional SCM_I_GSC definitions are above.
1511 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1512 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1513 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1514 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1515 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1516 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1517 AC_SUBST([SCM_I_GSC_C_INLINE])
1518 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1519
1520 AC_CONFIG_FILES([
1521   Makefile
1522   am/Makefile
1523   lib/Makefile
1524   benchmark-suite/Makefile
1525   doc/Makefile
1526   doc/goops/Makefile
1527   doc/r5rs/Makefile
1528   doc/ref/Makefile
1529   doc/tutorial/Makefile
1530   emacs/Makefile
1531   examples/Makefile
1532   examples/box-dynamic-module/Makefile
1533   examples/box-dynamic/Makefile
1534   examples/box-module/Makefile
1535   examples/box/Makefile
1536   examples/modules/Makefile
1537   examples/safe/Makefile
1538   examples/scripts/Makefile
1539   guile-config/Makefile
1540   ice-9/Makefile
1541   ice-9/debugger/Makefile
1542   ice-9/debugging/Makefile
1543   lang/Makefile
1544   lang/elisp/Makefile
1545   lang/elisp/internals/Makefile
1546   lang/elisp/primitives/Makefile
1547   libguile/Makefile
1548   oop/Makefile
1549   oop/goops/Makefile
1550   scripts/Makefile
1551   srfi/Makefile
1552   test-suite/Makefile
1553   test-suite/standalone/Makefile
1554 ])
1555
1556 AC_CONFIG_FILES([guile-1.8.pc])
1557 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1558 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1559 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1560 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1561 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1562 AC_CONFIG_FILES([libguile/guile-snarf],
1563                 [chmod +x libguile/guile-snarf])
1564 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1565                 [chmod +x libguile/guile-doc-snarf])
1566 AC_CONFIG_FILES([libguile/guile-func-name-check],
1567                 [chmod +x libguile/guile-func-name-check])
1568 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1569                 [chmod +x libguile/guile-snarf-docs])
1570
1571 AC_OUTPUT
1572
1573 dnl Local Variables:
1574 dnl comment-start: "dnl "
1575 dnl comment-end: ""
1576 dnl comment-start-skip: "\\bdnl\\b\\s *"
1577 dnl End: