m4/warnings.m4

   1 # warnings.m4 serial 5
   2 dnl Copyright (C) 2008-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Simon Josefsson
   8
   9 # gl_AS_VAR_APPEND(VAR, VALUE)
  10 # ----------------------------
  11 # Provide the functionality of AS_VAR_APPEND if Autoconf does not have it.
  12 m4_ifdef([AS_VAR_APPEND],
  13 [m4_copy([AS_VAR_APPEND], [gl_AS_VAR_APPEND])],
  14 [m4_define([gl_AS_VAR_APPEND],
  15 [AS_VAR_SET([$1], [AS_VAR_GET([$1])$2])])])
  16
  17 # gl_WARN_ADD(PARAMETER, [VARIABLE = WARN_CFLAGS])
  18 # ------------------------------------------------
  19 # Adds parameter to WARN_CFLAGS if the compiler supports it.  For example,
  20 # gl_WARN_ADD([-Wparentheses]).
  21 AC_DEFUN([gl_WARN_ADD],
  22 dnl FIXME: gl_Warn must be used unquoted until we can assume
  23 dnl autoconf 2.64 or newer.
  24 [AS_VAR_PUSHDEF([gl_Warn], [gl_cv_warn_$1])dnl
  25 AC_CACHE_CHECK([whether compiler handles $1], m4_defn([gl_Warn]), [
  26   gl_save_CPPFLAGS="$CPPFLAGS"
  27   CPPFLAGS="${CPPFLAGS} $1"
  28   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([])],
  29                     [AS_VAR_SET(gl_Warn, [yes])],
  30                     [AS_VAR_SET(gl_Warn, [no])])
  31   CPPFLAGS="$gl_save_CPPFLAGS"
  32 ])
  33 AS_VAR_IF(gl_Warn, [yes],
  34   [gl_AS_VAR_APPEND(m4_if([$2], [], [[WARN_CFLAGS]], [[$2]]), [" $1"])])
  35 AS_VAR_POPDEF([gl_Warn])dnl
  36 m4_ifval([$2], [AS_LITERAL_IF([$2], [AC_SUBST([$2])], [])])dnl
  37 ])