configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it under
  12 the terms of the GNU Lesser General Public License as published by the
  13 Free Software Foundation; either version 3, or (at your option) any
  14 later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but WITHOUT
  17 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  19 License for more details.
  20
  21 You should have received a copy of the GNU Lesser General Public
  22 License along with GUILE; see the file COPYING.LESSER.  If not, write
  23 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  24 Floor, Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.61)
  29
  30 dnl  `patsubst' here deletes the newline which "echo" prints.  We can't use
  31 dnl  "echo -n" since -n is not portable (see autoconf manual "Limitations of
  32 dnl  Builtins"), in particular on solaris it results in a literal "-n" in
  33 dnl  the output.
  34 dnl
  35 AC_INIT(patsubst(m4_esyscmd(. ./GUILE-VERSION && echo ${PACKAGE}),[
  36 ]),
  37         patsubst(m4_esyscmd(. ./GUILE-VERSION && echo ${GUILE_VERSION}),[
  38 ]),
  39         [bug-guile@gnu.org])
  40 AC_CONFIG_AUX_DIR([build-aux])
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR(GUILE-VERSION)
  43
  44 AM_INIT_AUTOMAKE([gnu no-define check-news -Wall -Wno-override])
  45
  46 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  47 AC_CONFIG_SRCDIR([GUILE-VERSION])
  48
  49 . $srcdir/GUILE-VERSION
  50
  51 AC_CONFIG_HEADERS([config.h])
  52 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  53
  54 #--------------------------------------------------------------------
  55 #
  56 # Independent Subdirectories
  57 #
  58 #--------------------------------------------------------------------
  59
  60 AC_CONFIG_SUBDIRS(guile-readline)
  61
  62 #--------------------------------------------------------------------
  63
  64 AC_LANG([C])
  65
  66 dnl Some more checks for Win32
  67 AC_CANONICAL_HOST
  68
  69 AC_LIBTOOL_WIN32_DLL
  70
  71 AC_PROG_INSTALL
  72 AC_PROG_CC
  73 gl_EARLY
  74 AC_PROG_CPP
  75 AC_PROG_AWK
  76
  77 dnl Gnulib.
  78 gl_INIT
  79
  80 AC_PROG_CC_C89
  81
  82 # for per-target cflags in the libguile subdir
  83 AM_PROG_CC_C_O
  84
  85 AC_LIBTOOL_DLOPEN
  86 AC_PROG_LIBTOOL
  87 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  88   [AC_MSG_ERROR([libltdl not found.  See README.])])
  89 AC_CHECK_HEADER([ltdl.h], [],
  90   [AC_MSG_ERROR([<ltdl.h> not found.  See README.])])
  91
  92 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  93 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  94
  95 AM_PATH_LISPDIR
  96
  97 #--------------------------------------------------------------------
  98 #
  99 # User options (after above tests that may set default CFLAGS etc.)
 100 #
 101 #--------------------------------------------------------------------
 102
 103 GUILE_ERROR_ON_WARNING="yes"
 104
 105 AC_ARG_ENABLE(error-on-warning,
 106   [  --enable-error-on-warning    treat compile warnings as errors],
 107   [case "${enableval}" in
 108      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 109      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 110      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 111    esac])
 112
 113 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
 114 AC_ARG_ENABLE(debug-freelist,
 115   [  --enable-debug-freelist include garbage collector freelist debugging code],
 116   if test "$enable_debug_freelist" = y \
 117      || test "$enable_debug_freelist" = yes; then
 118     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 119   fi)
 120
 121 AC_ARG_ENABLE(debug-malloc,
 122   [  --enable-debug-malloc   include malloc debugging code],
 123   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 124     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 125       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 126   fi)
 127
 128 SCM_I_GSC_GUILE_DEBUG=0
 129 AC_ARG_ENABLE(guile-debug,
 130   [AS_HELP_STRING([--enable-guile-debug],
 131                   [include internal debugging functions])],
 132   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 133     SCM_I_GSC_GUILE_DEBUG=1
 134   fi)
 135
 136 AC_ARG_ENABLE(posix,
 137   [  --disable-posix         omit posix interfaces],,
 138   enable_posix=yes)
 139
 140 AC_ARG_ENABLE(networking,
 141   [  --disable-networking    omit networking interfaces],,
 142   enable_networking=yes)
 143
 144 AC_ARG_ENABLE(regex,
 145   [  --disable-regex         omit regular expression interfaces],,
 146   enable_regex=yes)
 147
 148 AC_ARG_ENABLE([discouraged],
 149   AS_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 150
 151 if test "$enable_discouraged" = no; then
 152   SCM_I_GSC_ENABLE_DISCOURAGED=0
 153 else
 154   SCM_I_GSC_ENABLE_DISCOURAGED=1
 155 fi
 156
 157 AC_ARG_ENABLE([deprecated],
 158   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 159
 160 if test "$enable_deprecated" = no; then
 161   SCM_I_GSC_ENABLE_DEPRECATED=0
 162   warn_default=no
 163 else
 164   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 165     warn_default=summary
 166   elif test "$enable_deprecated" = shutup; then
 167     warn_default=no
 168   else
 169     warn_default=$enable_deprecated
 170   fi
 171   SCM_I_GSC_ENABLE_DEPRECATED=1
 172 fi
 173 AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 174 [Define this to control the default warning level for deprecated features.])
 175
 176 AC_ARG_ENABLE(elisp,
 177   [  --disable-elisp         omit Emacs Lisp support],,
 178   enable_elisp=yes)
 179
 180 dnl  Added the following configure option in January 2008 following
 181 dnl  investigation of problems with "64" system and library calls on
 182 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 183 dnl  system has stat64, it will have all the other 64 APIs too; but on
 184 dnl  Darwin, stat64 is there but other APIs are missing.
 185 dnl
 186 dnl  It also appears, from the Darwin docs, that most system call APIs
 187 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 188 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 189 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 190 dnl
 191 dnl  A similar problem has been reported for HP-UX:
 192 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 193 dnl
 194 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 195 dnl  better than no Guile at all, we provide this option to suppress
 196 dnl  trying to use "64" calls.
 197 dnl
 198 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 199 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 200 dnl  missing out on that.  If so, someone can work on that in the future.
 201 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 202 dnl  wasn't building before.
 203 AC_MSG_CHECKING([whether to use system and library "64" calls])
 204 AC_ARG_WITH([64-calls],
 205   AS_HELP_STRING([--without-64-calls],
 206                  [don't attempt to use system and library calls with "64" in their names]),
 207   [use_64_calls=$withval],
 208   [use_64_calls=yes
 209    case $host in
 210      *-apple-darwin* )
 211        use_64_calls=no
 212        ;;
 213      powerpc-ibm-aix* )
 214        use_64_calls=no
 215        ;;
 216    esac])
 217 AC_MSG_RESULT($use_64_calls)
 218 case "$use_64_calls" in
 219   y* )
 220     AC_DEFINE(GUILE_USE_64_CALLS, 1,
 221       [Define to 1 in order to try to use "64" versions of system and library calls.])
 222     ;;
 223 esac
 224
 225 #--------------------------------------------------------------------
 226
 227 dnl Check for dynamic linking
 228
 229 use_modules=yes
 230 AC_ARG_WITH(modules,
 231 [  --with-modules[=FILES]  Add support for dynamic modules],
 232 use_modules="$withval")
 233 test -z "$use_modules" && use_modules=yes
 234 DLPREOPEN=
 235 if test "$use_modules" != no; then
 236   if test "$use_modules" = yes; then
 237     DLPREOPEN="-dlpreopen force"
 238   else
 239     DLPREOPEN="-export-dynamic"
 240     for module in $use_modules; do
 241       DLPREOPEN="$DLPREOPEN -dlopen $module"
 242     done
 243   fi
 244 fi
 245
 246 dnl files which are destined for separate modules.
 247
 248 if test "$use_modules" != no; then
 249    AC_LIBOBJ([dynl])
 250 fi
 251
 252 if test "$enable_posix" = yes; then
 253    AC_LIBOBJ([filesys])
 254    AC_LIBOBJ([posix])
 255    AC_DEFINE(HAVE_POSIX, 1,
 256      [Define this if you want support for POSIX system calls in Guile.])
 257 fi
 258
 259 if test "$enable_networking" = yes; then
 260    AC_LIBOBJ([net_db])
 261    AC_LIBOBJ([socket])
 262    AC_DEFINE(HAVE_NETWORKING, 1,
 263      [Define this if you want support for networking in Guile.])
 264 fi
 265
 266 if test "$enable_debug_malloc" = yes; then
 267    AC_LIBOBJ([debug-malloc])
 268 fi
 269
 270 if test "$enable_elisp" = yes; then
 271   SCM_I_GSC_ENABLE_ELISP=1
 272 else
 273   SCM_I_GSC_ENABLE_ELISP=0
 274 fi
 275 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 276
 277 AC_C_CONST
 278
 279 # "volatile" is used in a couple of tests below.
 280 AC_C_VOLATILE
 281
 282 AC_C_INLINE
 283 if test "$ac_cv_c_inline" != no; then
 284   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 285 else
 286   SCM_I_GSC_C_INLINE=NULL
 287 fi
 288 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 289
 290 AC_C_BIGENDIAN
 291
 292 AC_C_LABELS_AS_VALUES
 293
 294 AC_CHECK_SIZEOF(char)
 295 AC_CHECK_SIZEOF(unsigned char)
 296 AC_CHECK_SIZEOF(short)
 297 AC_CHECK_SIZEOF(unsigned short)
 298 AC_CHECK_SIZEOF(int)
 299 AC_CHECK_SIZEOF(unsigned int)
 300 AC_CHECK_SIZEOF(long)
 301 AC_CHECK_SIZEOF(unsigned long)
 302 AC_CHECK_SIZEOF(size_t)
 303 AC_CHECK_SIZEOF(long long)
 304 AC_CHECK_SIZEOF(unsigned long long)
 305 AC_CHECK_SIZEOF(__int64)
 306 AC_CHECK_SIZEOF(unsigned __int64)
 307 AC_CHECK_SIZEOF(void *)
 308 AC_CHECK_SIZEOF(intptr_t)
 309 AC_CHECK_SIZEOF(uintptr_t)
 310 AC_CHECK_SIZEOF(ptrdiff_t)
 311 AC_CHECK_SIZEOF(size_t)
 312 AC_CHECK_SIZEOF(off_t)
 313
 314 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 315   AC_MSG_ERROR(sizes of long and void* are not identical)
 316 fi
 317
 318 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 319   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 320 else
 321   SCM_I_GSC_T_PTRDIFF='"long"'
 322 fi
 323 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 324
 325 AC_CHECK_HEADERS([stdint.h])
 326 AC_CHECK_HEADERS([inttypes.h])
 327
 328 AC_CHECK_SIZEOF(intmax_t)
 329
 330 SCM_I_GSC_NEEDS_STDINT_H=0
 331 SCM_I_GSC_NEEDS_INTTYPES_H=0
 332
 333 ### intptr and uintptr (try not to use inttypes if we don't have to)
 334 if test "$ac_cv_header_inttypes_h" = yes; then
 335   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 336     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 337 #include <stdio.h>])
 338     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 339       SCM_I_GSC_NEEDS_INTTYPES_H=1
 340     fi
 341   fi
 342   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 343     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 344 #include <stdio.h>])
 345     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 346       SCM_I_GSC_NEEDS_INTTYPES_H=1
 347     fi
 348   fi
 349 fi
 350
 351 ### See what's provided by stdint.h
 352 if test "$ac_cv_header_stdint_h" = yes; then
 353    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 354    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 355    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 356    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 357    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 358    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 359    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 360    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 361    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 362    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 363 fi
 364
 365 # so we don't get confused by the cache (wish there was a better way
 366 # to check particular headers for the same type...)
 367
 368 unset ac_cv_type_int8_t
 369 unset ac_cv_type_uint8_t
 370 unset ac_cv_type_int16_t
 371 unset ac_cv_type_uint16_t
 372 unset ac_cv_type_int32_t
 373 unset ac_cv_type_uint32_t
 374 unset ac_cv_type_int64_t
 375 unset ac_cv_type_uint64_t
 376 unset ac_cv_type_intmax_t
 377 unset ac_cv_type_uintmax_t
 378
 379 ### See what's provided by inttypes.h
 380 if test "$ac_cv_header_inttypes_h" = yes; then
 381   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 382   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 383   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 384   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 385   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 386   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 387   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 388   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 389   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 390   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 391 fi
 392
 393 # Try hard to find definitions for some required scm_t_*int* types.
 394
 395 ### Required type scm_t_int8
 396 if test "$scm_stdint_has_int8"; then
 397   SCM_I_GSC_T_INT8='"int8_t"'
 398   SCM_I_GSC_NEEDS_STDINT_H=1
 399 elif test "$scm_inttypes_has_int8"; then
 400   SCM_I_GSC_T_INT8='"int8_t"'
 401   SCM_I_GSC_NEEDS_INTTYPES_H=1
 402 elif test "$ac_cv_sizeof_char" -eq 1; then
 403   SCM_I_GSC_T_INT8='"signed char"'
 404 else
 405   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 406 fi
 407 AC_SUBST([SCM_I_GSC_T_INT8])
 408
 409 ### Required type scm_t_uint8
 410 if test "$scm_stdint_has_uint8"; then
 411   SCM_I_GSC_T_UINT8='"uint8_t"'
 412   SCM_I_GSC_NEEDS_STDINT_H=1
 413 elif test "$scm_inttypes_has_uint8"; then
 414   SCM_I_GSC_T_UINT8='"uint8_t"'
 415   SCM_I_GSC_NEEDS_INTTYPES_H=1
 416 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 417   SCM_I_GSC_T_UINT8='"unsigned char"'
 418 else
 419   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 420 fi
 421 AC_SUBST([SCM_I_GSC_T_UINT8])
 422
 423 ### Required type scm_t_int16 (ANSI C says int or short might work)
 424 if test "$scm_stdint_has_int16"; then
 425   SCM_I_GSC_T_INT16='"int16_t"'
 426   SCM_I_GSC_NEEDS_STDINT_H=1
 427 elif test "$scm_inttypes_has_int16"; then
 428   SCM_I_GSC_T_INT16='"int16_t"'
 429   SCM_I_GSC_NEEDS_INTTYPES_H=1
 430 elif test "$ac_cv_sizeof_int" -eq 2; then
 431   SCM_I_GSC_T_INT16='"int"'
 432 elif test "$ac_cv_sizeof_short" -eq 2; then
 433   SCM_I_GSC_T_INT16='"short"'
 434 else
 435   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 436 fi
 437 AC_SUBST([SCM_I_GSC_T_INT16])
 438
 439 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 440 if test "$scm_stdint_has_uint16"; then
 441   SCM_I_GSC_T_UINT16='"uint16_t"'
 442   SCM_I_GSC_NEEDS_STDINT_H=1
 443 elif test "$scm_inttypes_has_uint16"; then
 444   SCM_I_GSC_T_UINT16='"uint16_t"'
 445   SCM_I_GSC_NEEDS_INTTYPES_H=1
 446 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 447   SCM_I_GSC_T_UINT16='"unsigned int"'
 448 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 449   SCM_I_GSC_T_UINT16='"unsigned short"'
 450 else
 451   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 452 fi
 453 AC_SUBST([SCM_I_GSC_T_UINT16])
 454
 455
 456 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 457 if test "$scm_stdint_has_int32"; then
 458   SCM_I_GSC_T_INT32='"int32_t"'
 459   SCM_I_GSC_NEEDS_STDINT_H=1
 460 elif test "$scm_inttypes_has_int32"; then
 461   SCM_I_GSC_T_INT32='"int32_t"'
 462   SCM_I_GSC_NEEDS_INTTYPES_H=1
 463 elif test "$ac_cv_sizeof_int" -eq 4; then
 464   SCM_I_GSC_T_INT32='"int"'
 465 elif test "$ac_cv_sizeof_long" -eq 4; then
 466   SCM_I_GSC_T_INT32='"long"'
 467 elif test "$ac_cv_sizeof_short" -eq 4; then
 468   SCM_I_GSC_T_INT32='"short"'
 469 else
 470   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 471 fi
 472 AC_SUBST([SCM_I_GSC_T_INT32])
 473
 474 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 475 if test "$scm_stdint_has_uint32"; then
 476   SCM_I_GSC_T_UINT32='"uint32_t"'
 477   SCM_I_GSC_NEEDS_STDINT_H=1
 478 elif test "$scm_inttypes_has_uint32"; then
 479   SCM_I_GSC_T_UINT32='"uint32_t"'
 480   SCM_I_GSC_NEEDS_INTTYPES_H=1
 481 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 482   SCM_I_GSC_T_UINT32='"unsigned int"'
 483 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 484   SCM_I_GSC_T_UINT32='"unsigned long"'
 485 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 486   SCM_I_GSC_T_UINT32='"unsigned short"'
 487 else
 488   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 489 fi
 490 AC_SUBST([SCM_I_GSC_T_UINT32])
 491
 492 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 493 ### Also try 'long long' and '__int64' if we have it.
 494 SCM_I_GSC_T_INT64=0
 495 if test "$scm_stdint_has_int64"; then
 496   SCM_I_GSC_T_INT64='"int64_t"'
 497   SCM_I_GSC_NEEDS_STDINT_H=1
 498 elif test "$scm_inttypes_has_int64"; then
 499   SCM_I_GSC_T_INT64='"int64_t"'
 500   SCM_I_GSC_NEEDS_INTTYPES_H=1
 501 elif test "$ac_cv_sizeof_int" -eq 8; then
 502   SCM_I_GSC_T_INT64='"int"'
 503 elif test "$ac_cv_sizeof_long" -eq 8; then
 504   SCM_I_GSC_T_INT64='"long"'
 505 elif test "$ac_cv_sizeof_short" -eq 8; then
 506   SCM_I_GSC_T_INT64='"short"'
 507 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 508   SCM_I_GSC_T_INT64='"long long"'
 509 elif test "$ac_cv_sizeof___int64" -eq 8; then
 510   SCM_I_GSC_T_INT64='"__int64"'
 511 else
 512   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 513 fi
 514 AC_SUBST([SCM_I_GSC_T_INT64])
 515
 516
 517 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 518 ### Also try 'long long' and '__int64' if we have it.
 519 SCM_I_GSC_T_UINT64=0
 520 if test "$scm_stdint_has_uint64"; then
 521   SCM_I_GSC_T_UINT64='"uint64_t"'
 522   SCM_I_GSC_NEEDS_STDINT_H=1
 523 elif test "$scm_inttypes_has_uint64"; then
 524   SCM_I_GSC_T_UINT64='"uint64_t"'
 525   SCM_I_GSC_NEEDS_INTTYPES_H=1
 526 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 527   SCM_I_GSC_T_UINT64='"unsigned int"'
 528 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 529   SCM_I_GSC_T_UINT64='"unsigned long"'
 530 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 531   SCM_I_GSC_T_UINT64='"unsigned short"'
 532 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 533   SCM_I_GSC_T_UINT64='"unsigned long long"'
 534 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 535   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 536 else
 537   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 538 fi
 539 AC_SUBST([SCM_I_GSC_T_UINT64])
 540
 541 ### Required type scm_t_intmax
 542 ###
 543 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 544 ### none of them is available, we use 'long'.
 545 ###
 546 SCM_I_GSC_T_INTMAX=0
 547 if test "$scm_stdint_has_intmax"; then
 548   SCM_I_GSC_T_INTMAX='"intmax_t"'
 549   SCM_I_GSC_NEEDS_STDINT_H=1
 550 elif test "$scm_inttypes_has_intmax"; then
 551   SCM_I_GSC_T_INTMAX='"intmax_t"'
 552   SCM_I_GSC_NEEDS_INTTYPES_H=1
 553 elif test "$ac_cv_sizeof___int64" -ne 0; then
 554   SCM_I_GSC_T_INTMAX='"__int64"'
 555 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 556   SCM_I_GSC_T_INTMAX='"long long"'
 557 else
 558   SCM_I_GSC_T_INTMAX='"long"'
 559 fi
 560 AC_SUBST([SCM_I_GSC_T_INTMAX])
 561
 562 ### Required type scm_t_uintmax
 563 ###
 564 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 565 ### this order.  When none of them is available, we use 'unsigned long'.
 566 ###
 567 SCM_I_GSC_T_UINTMAX=0
 568 if test "$scm_stdint_has_uintmax"; then
 569   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 570   SCM_I_GSC_NEEDS_STDINT_H=1
 571 elif test "$scm_inttypes_has_uintmax"; then
 572   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 573   SCM_I_GSC_NEEDS_INTTYPES_H=1
 574 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 575   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 576 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 577   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 578 else
 579   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 580 fi
 581 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 582
 583
 584 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 585 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 586
 587 AC_HEADER_STDC
 588 AC_HEADER_TIME
 589 AC_HEADER_SYS_WAIT
 590 AC_HEADER_DIRENT
 591
 592 # Reason for checking:
 593 #
 594 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 595 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 596 #
 597 AC_CHECK_MEMBER([struct dirent64.d_name],
 598   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 599   [ #ifndef _LARGEFILE64_SOURCE
 600     # define _LARGEFILE64_SOURCE
 601     #endif
 602
 603     /* Per Autoconf manual.  */
 604     #include <sys/types.h>
 605     #ifdef HAVE_DIRENT_H
 606     # include <dirent.h>
 607     #else
 608     # define dirent direct
 609     # ifdef HAVE_SYS_NDIR_H
 610     #  include <sys/ndir.h>
 611     # endif
 612     # ifdef HAVE_SYS_DIR_H
 613     #  include <sys/dir.h>
 614     # endif
 615     # ifdef HAVE_NDIR_H
 616     #  include <ndir.h>
 617     # endif
 618     #endif ])
 619 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 620
 621 # Reasons for testing:
 622 #   complex.h - new in C99
 623 #   fenv.h - available in C99, but not older systems
 624 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 625 #     this file instead of <fenv.h>
 626 #   process.h - mingw specific
 627 #   langinfo.h, nl_types.h - SuS v2
 628 #
 629 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 630 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 631 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 632 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 633 direct.h langinfo.h nl_types.h machine/fpu.h])
 634
 635 # "complex double" is new in C99, and "complex" is only a keyword if
 636 # <complex.h> is included
 637 AC_CHECK_TYPES(complex double,,,
 638 [#if HAVE_COMPLEX_H
 639 #include <complex.h>
 640 #endif])
 641
 642 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 643 # when testing.
 644 AC_CHECK_TYPE(socklen_t, ,
 645   [AC_DEFINE_UNQUOTED(socklen_t, int,
 646                       [Define to `int' if <sys/socket.h> does not define.])],
 647   [#if HAVE_SYS_TYPES_H
 648 #include <sys/types.h>
 649 #endif
 650 #include <sys/socket.h>
 651 ])
 652 AC_CHECK_TYPE(struct ip_mreq)
 653
 654 GUILE_HEADER_LIBC_WITH_UNISTD
 655
 656 AC_TYPE_GETGROUPS
 657 AC_TYPE_SIGNAL
 658 AC_TYPE_MODE_T
 659
 660 # On mingw -lm is empty, so this test is unnecessary, but it's
 661 # harmless so we don't hard-code to suppress it.
 662 #
 663 AC_CHECK_LIB(m, cos)
 664
 665 AC_CHECK_FUNCS(gethostbyname)
 666 if test $ac_cv_func_gethostbyname = no; then
 667     AC_CHECK_LIB(nsl, gethostbyname)
 668 fi
 669
 670 AC_CHECK_FUNCS(connect)
 671 if test $ac_cv_func_connect = no; then
 672     AC_CHECK_LIB(socket, connect)
 673 fi
 674
 675 dnl
 676 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 677 dnl
 678 EXTRA_DEFS=""
 679 case $host in
 680   *-*-mingw*)
 681     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 682       [Define if you have the <winsock2.h> header file.])])
 683     AC_CHECK_LIB(ws2_32, main)
 684     AC_LIBOBJ([win32-uname])
 685     AC_LIBOBJ([win32-dirent])
 686     if test "$enable_networking" = yes ; then
 687       AC_LIBOBJ([win32-socket])
 688     fi
 689     if test "$enable_shared" = yes ; then
 690       EXTRA_DEFS="-DSCM_IMPORT"
 691       AC_DEFINE(USE_DLL_IMPORT, 1,
 692         [Define if you need additional CPP macros on Win32 platforms.])
 693     fi
 694     ;;
 695 esac
 696 AC_SUBST(EXTRA_DEFS)
 697
 698 # Reasons for testing:
 699 #   crt_externs.h - Darwin specific
 700 #
 701 AC_CHECK_HEADERS([assert.h crt_externs.h])
 702
 703 # Reasons for testing:
 704 #   DINFINITY - OSF specific
 705 #   DQNAN - OSF specific
 706 #       (DINFINITY and DQNAN are actually global variables, not functions)
 707 #   chsize - an MS-DOS-ism, found in mingw
 708 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 709 #       for gcc to provide the "complex double" type but the system to not
 710 #       have functions like cexp and clog
 711 #   clog10 - not in mingw (though others like clog and csqrt are)
 712 #   fesetround - available in C99, but not older systems
 713 #   ftruncate - posix, but probably not older systems (current mingw
 714 #               has it as an inline for chsize)
 715 #   ioctl - not in mingw.
 716 #   gmtime_r - recent posix, not on old systems
 717 #   pipe - not in mingw
 718 #   _pipe - specific to mingw, taking 3 args
 719 #   readdir_r - recent posix, not on old systems
 720 #   readdir64_r - not available on HP-UX 11.11
 721 #   stat64 - SuS largefile stuff, not on old systems
 722 #   sysconf - not on old systems
 723 #   truncate - not in mingw
 724 #   isblank - available as a GNU extension or in C99
 725 #   _NSGetEnviron - Darwin specific
 726 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 727 #   nl_langinfo - X/Open, not available on Windows.
 728 #
 729 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo])
 730
 731 # Reasons for testing:
 732 #   netdb.h - not in mingw
 733 #   sys/param.h - not in mingw
 734 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 735 #       check this specifically, we need it for the timespec test below.
 736 #   sethostname - the function itself check because it's not in mingw,
 737 #       the DECL is checked because Solaris 10 doens't have in any header
 738 #   xlocale.h - needed on Darwin for the `locale_t' API
 739 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 740 #       declaration isn't anywhere.
 741 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 742 #       only with `_XOPEN_SOURCE' or some such.
 743 #
 744 AC_CHECK_HEADERS(crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h xlocale.h)
 745 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 746 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 747
 748 # crypt() may or may not be available, for instance in some countries there
 749 # are restrictions on cryptography.
 750 #
 751 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 752 # -lcrypt library (eg. Debian GNU/Linux).
 753 #
 754 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 755 # be careful to avoid -lcrypt in this case, since libtool will see there's
 756 # only a static libcrypt and decide to build only a static libguile.
 757 #
 758 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 759 # libraries already in that list.
 760 #
 761 AC_SEARCH_LIBS(crypt, crypt,
 762   [AC_DEFINE(HAVE_CRYPT,1,
 763              [Define to 1 if you have the `crypt' function.])])
 764
 765 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 766 # work; in the reported cases so far, 1.0fi works well instead.  According
 767 # to the C99 spec, the complex.h header must provide a working definition
 768 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 769 # is a workaround for the failure of some systems to conform to C99.
 770 if test "$ac_cv_type_complex_double" = yes; then
 771   AC_MSG_CHECKING([for i])
 772   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 773 #if HAVE_COMPLEX_H
 774 #include <complex.h>
 775 #endif
 776 complex double z;
 777 ]], [[
 778 z = _Complex_I;
 779 ]])],
 780     [AC_DEFINE(GUILE_I,_Complex_I,[The imaginary unit (positive square root of -1).])
 781      AC_MSG_RESULT([_Complex_I])],
 782     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 783 #if HAVE_COMPLEX_H
 784 #include <complex.h>
 785 #endif
 786 complex double z;
 787 ]],[[
 788 z = 1.0fi;
 789 ]])],
 790   [AC_DEFINE(GUILE_I,1.0fi)
 791    AC_MSG_RESULT([1.0fi])],
 792   [ac_cv_type_complex_double=no
 793    AC_MSG_RESULT([not available])])])
 794 fi
 795
 796 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 797 # csqrt(-i) returned a negative real part, when it should be positive
 798 # for the principal root.
 799 #
 800 if test "$ac_cv_type_complex_double" = yes; then
 801
 802   AC_CACHE_CHECK([whether csqrt is usable],
 803     guile_cv_use_csqrt,
 804     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 805 #include <complex.h>
 806 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 807    constant, we want to test libc. */
 808 volatile complex double z = - _Complex_I;
 809 int
 810 main (void)
 811 {
 812   z = csqrt (z);
 813   if (creal (z) > 0.0)
 814     return 0;  /* good */
 815   else
 816     return 1;  /* bad */
 817 }]])],
 818     [guile_cv_use_csqrt=yes],
 819     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 820     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 821   case $guile_cv_use_csqrt in
 822     yes*)
 823       AC_DEFINE(HAVE_USABLE_CSQRT, 1, [Define to 1 if csqrt is bug-free])
 824       ;;
 825   esac
 826 fi
 827
 828
 829 dnl GMP tests
 830 AC_LIB_LINKFLAGS(gmp)
 831 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 832   [AC_MSG_ERROR([GNU MP not found, see README])])
 833
 834 # mpz_import is a macro so we need to include <gmp.h>
 835 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gmp.h>]],
 836                                 [[mpz_import (0, 0, 0, 0, 0, 0, 0); ]])],
 837   [],
 838   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see README])])
 839
 840 dnl GNU libunistring tests.
 841 if test "x$LTLIBUNISTRING" != "x"; then
 842    LIBS="$LTLIBUNISTRING $LIBS"
 843 else
 844    AC_MSG_ERROR([GNU libunistring is required, please install it.])
 845 fi
 846
 847 dnl i18n tests
 848 #AC_CHECK_HEADERS([libintl.h])
 849 #AC_CHECK_FUNCS(gettext)
 850 #if test $ac_cv_func_gettext = no; then
 851 #   AC_CHECK_LIB(intl, gettext)
 852 #fi
 853 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 854 AM_GNU_GETTEXT([external], [need-ngettext])
 855
 856 ### Some systems don't declare some functions.  On such systems, we
 857 ### need to at least provide our own K&R-style declarations.
 858
 859 ### GUILE_FUNC_DECLARED(function, headerfile)
 860
 861 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 862 ### not there, #define MISSING_FUNCTION_DECL.
 863 AC_DEFUN([GUILE_FUNC_DECLARED], [
 864   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 865     AC_EGREP_HEADER($1, $2,
 866                     guile_cv_func_$1_declared=yes,
 867                     guile_cv_func_$1_declared=no))
 868   if test [x$guile_cv_func_]$1[_declared] = xno; then
 869     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 870       [Define if the operating system supplies $1 without declaring it.])
 871   fi
 872 ])
 873
 874 GUILE_FUNC_DECLARED(sleep, unistd.h)
 875 GUILE_FUNC_DECLARED(usleep, unistd.h)
 876
 877 AC_CHECK_DECLS([strptime],,,
 878 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 879 #include <time.h>])
 880
 881 ### On some systems usleep has no return value.  If it does have one,
 882 ### we'd like to return it; otherwise, we'll fake it.
 883 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 884   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 885                    unistd.h,
 886                    [guile_cv_func_usleep_return_type=void],
 887                    [guile_cv_func_usleep_return_type=int])])
 888 case "$guile_cv_func_usleep_return_type" in
 889   "void" )
 890     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 891       [Define if the system headers declare usleep to return void.])
 892   ;;
 893 esac
 894
 895 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 896 if test -n "$have_sys_un_h" ; then
 897   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 898     [Define if the system supports Unix-domain (file-domain) sockets.])
 899 fi
 900
 901 AC_CHECK_FUNCS(getrlimit setrlimit)
 902
 903 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 904
 905 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 906                setnetent    getnetent    endnetent    dnl
 907                setprotoent  getprotoent  endprotoent  dnl
 908                setservent   getservent   endservent   dnl
 909                getnetbyaddr getnetbyname dnl
 910                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 911                inet_pton inet_ntop)
 912
 913 # struct sockaddr field sin_len is only present on BSD systems.
 914 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 915 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 916 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 917 [#ifdef HAVE_SYS_TYPES_H
 918 #include <sys/types.h>
 919 #endif
 920 #include <netinet/in.h>])
 921
 922 AC_MSG_CHECKING(for __libc_stack_end)
 923 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 924 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 925 extern char *__libc_stack_end;]],
 926    [[printf("%p", (char*) __libc_stack_end);]])],
 927    [guile_cv_have_libc_stack_end=yes],
 928    [guile_cv_have_libc_stack_end=no])])
 929 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 930
 931 if test $guile_cv_have_libc_stack_end = yes; then
 932   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 933            [Define if you have the __libc_stack_end variable.])
 934 fi
 935
 936 dnl Some systems do not declare this.  Some systems do declare it, as a
 937 dnl macro.  With cygwin it may be in a DLL.
 938
 939 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 940 AC_CACHE_VAL(guile_cv_have_h_errno,
 941   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 942                                       [[int a = h_errno;]])],
 943   [guile_cv_have_h_errno=yes],
 944   [guile_cv_have_h_errno=no])])
 945 AC_MSG_RESULT($guile_cv_have_h_errno)
 946 if test $guile_cv_have_h_errno = yes; then
 947   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 948 fi
 949
 950 AC_MSG_CHECKING(whether uint32_t is defined)
 951 AC_CACHE_VAL(guile_cv_have_uint32_t,
 952   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 953                    #if HAVE_STDINT_H
 954                    #include <stdint.h>
 955                    #endif
 956                    #ifndef HAVE_NETDB_H
 957                    #include <netdb.h>
 958                    #endif]],
 959                    [[uint32_t a;]])],
 960                    [guile_cv_have_uint32_t=yes],
 961                    [guile_cv_have_uint32_t=no])])
 962 AC_MSG_RESULT($guile_cv_have_uint32_t)
 963 if test $guile_cv_have_uint32_t = yes; then
 964   AC_DEFINE(HAVE_UINT32_T, 1,
 965     [Define if uint32_t typedef is defined when netdb.h is include.])
 966 fi
 967
 968 AC_MSG_CHECKING(for working IPv6 support)
 969 AC_CACHE_VAL(guile_cv_have_ipv6,
 970 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 971 #ifdef HAVE_SYS_TYPES_H
 972 #include <sys/types.h>
 973 #endif
 974 #include <netinet/in.h>
 975 #include <sys/socket.h>]],
 976 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
 977 [guile_cv_have_ipv6=yes],
 978 [guile_cv_have_ipv6=no])])
 979 AC_MSG_RESULT($guile_cv_have_ipv6)
 980 if test $guile_cv_have_ipv6 = yes; then
 981   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 982 fi
 983
 984 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 985 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 986 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 987 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 988 #ifdef HAVE_SYS_TYPES_H
 989 #include <sys/types.h>
 990 #endif
 991 #include <netinet/in.h>]],
 992 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
 993 [guile_cv_have_sin6_scope_id=yes],
 994 [guile_cv_have_sin6_scope_id=no])])
 995 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 996 if test $guile_cv_have_sin6_scope_id = yes; then
 997   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 998     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 999 fi
1000
1001 # struct sockaddr_in6 field sin_len is only present on BSD systems
1002 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1003 [#ifdef HAVE_SYS_TYPES_H
1004 #include <sys/types.h>
1005 #endif
1006 #include <netinet/in.h>])
1007
1008 AC_MSG_CHECKING(whether localtime caches TZ)
1009 AC_CACHE_VAL(guile_cv_localtime_cache,
1010 [if test x$ac_cv_func_tzset = xyes; then
1011 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1012 #if STDC_HEADERS
1013 # include <stdlib.h>
1014 #endif
1015 extern char **environ;
1016 unset_TZ ()
1017 {
1018   char **from, **to;
1019   for (to = from = environ; (*to = *from); from++)
1020     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1021       to++;
1022 }
1023 char TZ_GMT0[] = "TZ=GMT0";
1024 char TZ_PST8[] = "TZ=PST8";
1025 main()
1026 {
1027   time_t now = time ((time_t *) 0);
1028   int hour_GMT0, hour_unset;
1029   if (putenv (TZ_GMT0) != 0)
1030     exit (1);
1031   hour_GMT0 = localtime (&now)->tm_hour;
1032   unset_TZ ();
1033   hour_unset = localtime (&now)->tm_hour;
1034   if (putenv (TZ_PST8) != 0)
1035     exit (1);
1036   if (localtime (&now)->tm_hour == hour_GMT0)
1037     exit (1);
1038   unset_TZ ();
1039   if (localtime (&now)->tm_hour != hour_unset)
1040     exit (1);
1041   exit (0);
1042 }]])],
1043 [guile_cv_localtime_cache=no],
1044 [guile_cv_localtime_cache=yes],
1045 [# If we have tzset, assume the worst when cross-compiling.
1046 guile_cv_localtime_cache=yes])
1047 else
1048         # If we lack tzset, report that localtime does not cache TZ,
1049         # since we can't invalidate the cache if we don't have tzset.
1050         guile_cv_localtime_cache=no
1051 fi])dnl
1052 AC_MSG_RESULT($guile_cv_localtime_cache)
1053 if test $guile_cv_localtime_cache = yes; then
1054   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
1055 fi
1056
1057 dnl Test whether system calls are restartable by default on the
1058 dnl current system.  If they are not, we put a loop around every system
1059 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
1060 dnl change from the default behaviour.  On the other hand, if signals
1061 dnl are restartable then the loop is not installed and when libguile
1062 dnl initialises it also resets the behaviour of each signal to cause a
1063 dnl restart (in case a different runtime had a different default
1064 dnl behaviour for some reason: e.g., different versions of linux seem
1065 dnl to behave differently.)
1066
1067 AC_SYS_RESTARTABLE_SYSCALLS
1068
1069 if test "$enable_regex" = yes; then
1070    if test "$ac_cv_header_regex_h" = yes ||
1071       test "$ac_cv_header_rxposix_h" = yes ||
1072       test "$ac_cv_header_rx_rxposix_h" = yes; then
1073      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1074      [AC_CHECK_LIB(rx, main)
1075       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1076      [AC_CHECK_LIB(regex, main)
1077       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1078      )
1079      dnl The following should not be necessary, but for some reason
1080      dnl autoheader misses it if we don't include it!
1081      if test "$ac_cv_func_regcomp_norx" = yes ||
1082         test "$ac_cv_func_regcomp_regex" = yes ||
1083         test "$ac_cv_func_regcomp_rx" = yes; then
1084        AC_DEFINE(HAVE_REGCOMP, 1,
1085          [This is included as part of a workaround for a autoheader bug.])
1086      fi
1087    fi
1088 fi
1089
1090 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
1091
1092 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
1093
1094 # Reasons for testing:
1095 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1096 #                                older systems
1097 #   sincos - GLIBC extension
1098 #
1099 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1100
1101 # C99 specifies isinf and isnan as macros.
1102 # HP-UX provides only macros, no functions.
1103 # glibc 2.3.2 provides both macros and functions.
1104 # IRIX 6.5 and Solaris 8 only provide functions.
1105 #
1106 # The following tests detect isinf and isnan either as functions or as
1107 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1108 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1109 #
1110 AC_MSG_CHECKING([for isinf])
1111 AC_LINK_IFELSE(AC_LANG_SOURCE(
1112 [[#include <math.h>
1113 volatile double x = 0.0;
1114 int main () { return (isinf(x) != 0); }]]),
1115   [AC_MSG_RESULT([yes])
1116    AC_DEFINE(HAVE_ISINF, 1,
1117              [Define to 1 if you have the `isinf' macro or function.])],
1118   [AC_MSG_RESULT([no])])
1119 AC_MSG_CHECKING([for isnan])
1120 AC_LINK_IFELSE(AC_LANG_SOURCE(
1121 [[#include <math.h>
1122 volatile double x = 0.0;
1123 int main () { return (isnan(x) != 0); }]]),
1124   [AC_MSG_RESULT([yes])
1125    AC_DEFINE(HAVE_ISNAN, 1,
1126              [Define to 1 if you have the `isnan' macro or function.])],
1127   [AC_MSG_RESULT([no])])
1128
1129 # Reasons for checking:
1130 #
1131 #     st_rdev
1132 #     st_blksize
1133 #     st_blocks   not in mingw
1134 #     tm_gmtoff   BSD+GNU, not in C99
1135 #
1136 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1137 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1138 #
1139 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks])
1140
1141 AC_STRUCT_TIMEZONE
1142 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1143 [#include <time.h>
1144 #ifdef TIME_WITH_SYS_TIME
1145 # include <sys/time.h>
1146 # include <time.h>
1147 #else
1148 # if HAVE_SYS_TIME_H
1149 #  include <sys/time.h>
1150 # else
1151 #  include <time.h>
1152 # endif
1153 #endif
1154 ])
1155 GUILE_STRUCT_UTIMBUF
1156
1157
1158 #--------------------------------------------------------------------
1159 #
1160 # Which way does the stack grow?
1161 #
1162 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1163 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1164 # very similar code, so in future we could look at using that.
1165 #
1166 # An important detail is that the code involves find_stack_direction
1167 # calling _itself_ - which means that find_stack_direction (or at
1168 # least the second find_stack_direction() call) cannot be inlined.
1169 # If the code could be inlined, that might cause the test to give
1170 # an incorrect answer.
1171 #--------------------------------------------------------------------
1172
1173 SCM_I_GSC_STACK_GROWS_UP=0
1174 AC_RUN_IFELSE([AC_LANG_SOURCE(
1175 [AC_INCLUDES_DEFAULT
1176 int
1177 find_stack_direction ()
1178 {
1179   static char *addr = 0;
1180   auto char dummy;
1181   if (addr == 0)
1182     {
1183       addr = &dummy;
1184       return find_stack_direction ();
1185     }
1186   else
1187     return (&dummy > addr) ? 1 : -1;
1188 }
1189
1190 int
1191 main ()
1192 {
1193   return find_stack_direction () < 0;
1194 }])],
1195                [SCM_I_GSC_STACK_GROWS_UP=1],
1196                [],
1197                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1198
1199 AC_CHECK_SIZEOF(float)
1200 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1201     AC_DEFINE(SCM_SINGLES, 1,
1202               [Define this if floats are the same size as longs.])
1203 fi
1204
1205 AC_MSG_CHECKING(for struct linger)
1206 AC_CACHE_VAL(scm_cv_struct_linger,
1207         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1208 #include <sys/types.h>
1209 #include <sys/socket.h>]],
1210                           [[struct linger lgr;  lgr.l_linger = 100]])],
1211                           [scm_cv_struct_linger="yes"],
1212                           [scm_cv_struct_linger="no"]))
1213 AC_MSG_RESULT($scm_cv_struct_linger)
1214 if test $scm_cv_struct_linger = yes; then
1215         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
1216           [Define this if your system defines struct linger, for use with the
1217            getsockopt and setsockopt system calls.])
1218 fi
1219
1220
1221 # On mingw, struct timespec is in <pthread.h>.
1222 #
1223 AC_MSG_CHECKING(for struct timespec)
1224 AC_CACHE_VAL(scm_cv_struct_timespec,
1225         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1226 #include <time.h>
1227 #if HAVE_PTHREAD_H
1228 #include <pthread.h>
1229 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1230           [scm_cv_struct_timespec="yes"],
1231           [scm_cv_struct_timespec="no"]))
1232 AC_MSG_RESULT($scm_cv_struct_timespec)
1233 if test $scm_cv_struct_timespec = yes; then
1234   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
1235     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1236 fi
1237
1238 #--------------------------------------------------------------------
1239 #
1240 # Flags for thread support
1241 #
1242 #--------------------------------------------------------------------
1243
1244 SCM_I_GSC_USE_PTHREAD_THREADS=0
1245 SCM_I_GSC_USE_NULL_THREADS=0
1246 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1247 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1248
1249 ### What thread package has the user asked for?
1250 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1251             , with_threads=yes)
1252
1253 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1254 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1255
1256 case "$with_threads" in
1257   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1258
1259     build_pthread_support="yes"
1260
1261     ACX_PTHREAD(CC="$PTHREAD_CC"
1262       LIBS="$PTHREAD_LIBS $LIBS"
1263       SCM_I_GSC_USE_PTHREAD_THREADS=1
1264       with_threads="pthreads",
1265       with_threads="null")
1266
1267     old_CFLAGS="$CFLAGS"
1268     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1269
1270     # Reasons for testing:
1271     #     pthread_getattr_np - "np" meaning "non portable" says it
1272     #         all; not present on MacOS X or Solaris 10
1273     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1274     #         all; specific to MacOS X
1275     #     pthread_sigmask - not available on mingw
1276     #
1277     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1278
1279     # On past versions of Solaris, believe 8 through 10 at least, you
1280     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1281     # This is contrary to POSIX:
1282     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1283     # Check here if this style is required.
1284     #
1285     # glibc (2.3.6 at least) works both with or without braces, so the
1286     # test checks whether it works without.
1287     #
1288
1289     if test "$GCC" = "yes"; then
1290       # Since GCC only issues a warning for missing braces, so we need
1291       # `-Werror' to catch it.
1292       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1293     fi
1294
1295     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1296       guile_cv_need_braces_on_pthread_once_init,
1297       [AC_COMPILE_IFELSE([#include <pthread.h>
1298          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1299         [guile_cv_need_braces_on_pthread_once_init=no],
1300         [guile_cv_need_braces_on_pthread_once_init=yes])])
1301     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1302       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1303     fi
1304
1305     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1306     # 6.5.30m with GCC 3.3.
1307     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1308       guile_cv_need_braces_on_pthread_mutex_initializer,
1309       [AC_COMPILE_IFELSE([#include <pthread.h>
1310          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1311         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1312         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1313     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1314       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1315     fi
1316
1317     CFLAGS="$old_CFLAGS"
1318
1319     # On Solaris, sched_yield lives in -lrt.
1320     AC_SEARCH_LIBS(sched_yield, rt)
1321
1322   ;;
1323 esac
1324
1325 case "$with_threads" in
1326   "pthreads")
1327   ;;
1328   "no" | "null")
1329     SCM_I_GSC_USE_NULL_THREADS=1
1330     with_threads="null-threads"
1331   ;;
1332   * )
1333     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1334   ;;
1335 esac
1336
1337 AC_MSG_CHECKING(what kind of threads to support)
1338 AC_MSG_RESULT($with_threads)
1339
1340 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1341   [test "x$build_pthread_support" = "xyes"])
1342
1343
1344 ## Check whether pthread_attr_getstack works for the main thread
1345
1346 if test "$with_threads" = pthreads; then
1347
1348 AC_MSG_CHECKING(whether pthread_attr_getstack works for the main thread)
1349 old_CFLAGS="$CFLAGS"
1350 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1351 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1352 #if HAVE_PTHREAD_ATTR_GETSTACK
1353 #include <pthread.h>
1354
1355 int main ()
1356 {
1357   pthread_attr_t attr;
1358   void *start, *end;
1359   size_t size;
1360
1361   pthread_getattr_np (pthread_self (), &attr);
1362   pthread_attr_getstack (&attr, &start, &size);
1363   end = (char *)start + size;
1364
1365   if ((void *)&attr < start || (void *)&attr >= end)
1366     return 1;
1367   else
1368     return 0;
1369 }
1370 #else
1371 int main ()
1372 {
1373   return 1;
1374 }
1375 #endif
1376 ]])],
1377 [works=yes
1378 AC_DEFINE(PTHREAD_ATTR_GETSTACK_WORKS, [1], [Define when pthread_att_get_stack works for the main thread])],
1379 [works=no],
1380 [])
1381 CFLAGS="$old_CFLAGS"
1382 AC_MSG_RESULT($works)
1383
1384 fi # with_threads=pthreads
1385
1386
1387 ## Cross building
1388 if test "$cross_compiling" = "yes"; then
1389   AC_MSG_CHECKING(cc for build)
1390   ## /usr/bin/cc still uses wrong assembler
1391   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1392   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1393 else
1394   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1395 fi
1396
1397 ## AC_MSG_CHECKING("if we are cross compiling")
1398 ## AC_MSG_RESULT($cross_compiling)
1399 if test "$cross_compiling" = "yes"; then
1400    AC_MSG_RESULT($CC_FOR_BUILD)
1401 fi
1402
1403 ## No need as yet to be more elaborate
1404 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1405
1406 AC_SUBST(cross_compiling)
1407 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1408 AC_SUBST(CCLD_FOR_BUILD)
1409
1410 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1411 ## --HOST is the platform that PACKAGE is compiled for.
1412 HOST_CC="$CC_FOR_BUILD"
1413 AC_SUBST(HOST_CC)
1414
1415 if test "$cross_compiling" = "yes"; then
1416   AC_MSG_CHECKING(guile for build)
1417   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1418 else
1419   GUILE_FOR_BUILD='$(preinstguile)'
1420 fi
1421
1422 ## AC_MSG_CHECKING("if we are cross compiling")
1423 ## AC_MSG_RESULT($cross_compiling)
1424 if test "$cross_compiling" = "yes"; then
1425    AC_MSG_RESULT($GUILE_FOR_BUILD)
1426 fi
1427 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1428 AC_SUBST(GUILE_FOR_BUILD)
1429
1430 ## If we're using GCC, ask for aggressive warnings.
1431 case "$GCC" in
1432   yes )
1433     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1434     ## much stuff with generic function pointers for that to really be
1435     ## less than exasperating.
1436     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1437     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1438     GCC_CFLAGS="-Wall -Wmissing-prototypes"
1439     # Do this here so we don't screw up any of the tests above that might
1440     # not be "warning free"
1441     if test "${GUILE_ERROR_ON_WARNING}" = yes
1442     then
1443         GCC_CFLAGS="${GCC_CFLAGS} -Werror"
1444         enable_compile_warnings=no
1445     fi
1446     ;;
1447 esac
1448
1449 AC_SUBST(GCC_CFLAGS)
1450
1451 ## If we're creating a shared library (using libtool!), then we'll
1452 ## need to generate a list of .lo files corresponding to the .o files
1453 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1454 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1455
1456 ## We also need to create corresponding .doc and .x files
1457 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1458 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1459
1460 AC_SUBST(GUILE_MAJOR_VERSION)
1461 AC_SUBST(GUILE_MINOR_VERSION)
1462 AC_SUBST(GUILE_MICRO_VERSION)
1463 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1464 AC_SUBST(GUILE_VERSION)
1465
1466 #######################################################################
1467 # library versioning
1468
1469 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1470 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1471 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1472 AC_SUBST(LIBGUILE_INTERFACE)
1473
1474 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1475 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1476 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1477 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1478 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1479
1480 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1481 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1482 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1483 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1484 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1485
1486 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1487 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1488 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1489 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1490 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1491
1492 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1493 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1494 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1495 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1496 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1497
1498 AC_SUBST(LIBGUILE_I18N_MAJOR)
1499 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1500 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1501 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1502 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1503
1504
1505 #######################################################################
1506
1507 dnl Tell guile-config what flags guile users should compile and link with.
1508 GUILE_LIBS="$LDFLAGS $LIBS"
1509 GUILE_CFLAGS="$CPPFLAGS $PTHREAD_CFLAGS"
1510 AC_SUBST(GUILE_LIBS)
1511 AC_SUBST(GUILE_CFLAGS)
1512
1513 AC_SUBST(AWK)
1514 AC_SUBST(LIBLOBJS)
1515 AC_SUBST(EXTRA_DOT_DOC_FILES)
1516 AC_SUBST(EXTRA_DOT_X_FILES)
1517
1518 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1519 top_builddir_absolute=`pwd`
1520 AC_SUBST(top_builddir_absolute)
1521 top_srcdir_absolute=`(cd $srcdir && pwd)`
1522 AC_SUBST(top_srcdir_absolute)
1523
1524 dnl We need `sitedir' in `guile-1.8.pc'.
1525 dnl Note: `sitedir' must be kept in sync with `GUILE_SITE_DIR' in `guile.m4'.
1526 pkgdatadir="$datadir/guile"
1527 sitedir="$pkgdatadir/site"
1528 AC_SUBST([sitedir])
1529
1530 # Additional SCM_I_GSC definitions are above.
1531 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1532 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1533 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1534 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1535 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1536 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1537 AC_SUBST([SCM_I_GSC_C_INLINE])
1538 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1539
1540 AC_CONFIG_FILES([
1541   Makefile
1542   am/Makefile
1543   lib/Makefile
1544   benchmark-suite/Makefile
1545   doc/Makefile
1546   doc/goops/Makefile
1547   doc/r5rs/Makefile
1548   doc/ref/Makefile
1549   doc/tutorial/Makefile
1550   emacs/Makefile
1551   examples/Makefile
1552   lang/Makefile
1553   libguile/Makefile
1554   srfi/Makefile
1555   test-suite/Makefile
1556   test-suite/standalone/Makefile
1557   meta/Makefile
1558   module/Makefile
1559   testsuite/Makefile
1560 ])
1561
1562 AC_CONFIG_FILES([meta/guile-1.8.pc])
1563 AC_CONFIG_FILES([meta/guile-1.8-uninstalled.pc])
1564 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1565 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1566 AC_CONFIG_FILES([meta/guile], [chmod +x meta/guile])
1567 AC_CONFIG_FILES([meta/uninstalled-env], [chmod +x meta/uninstalled-env])
1568 AC_CONFIG_FILES([meta/gdb-uninstalled-guile], [chmod +x meta/gdb-uninstalled-guile])
1569 AC_CONFIG_FILES([libguile/guile-snarf],
1570                 [chmod +x libguile/guile-snarf])
1571 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1572                 [chmod +x libguile/guile-doc-snarf])
1573 AC_CONFIG_FILES([libguile/guile-func-name-check],
1574                 [chmod +x libguile/guile-func-name-check])
1575 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1576                 [chmod +x libguile/guile-snarf-docs])
1577 AC_CONFIG_FILES([test-suite/standalone/test-use-srfi],
1578                 [chmod +x test-suite/standalone/test-use-srfi])
1579 AC_CONFIG_FILES([test-suite/standalone/test-fast-slot-ref],
1580                 [chmod +x test-suite/standalone/test-fast-slot-ref])
1581
1582 AC_OUTPUT
1583
1584 dnl Local Variables:
1585 dnl comment-start: "dnl "
1586 dnl comment-end: ""
1587 dnl comment-start-skip: "\\bdnl\\b\\s *"
1588 dnl End: