configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_PREREQ(2.53)
  24
  25 AC_INIT
  26 AC_CONFIG_SRCDIR([Makefile.in])
  27 . $srcdir/GUILE-VERSION
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  29 AM_MAINTAINER_MODE
  30 AM_CONFIG_HEADER(libguile/scmconfig.h)
  31
  32 #--------------------------------------------------------------------
  33 #
  34 # Independent Subdirectories
  35 #
  36 #--------------------------------------------------------------------
  37
  38 AC_CONFIG_SUBDIRS(guile-readline)
  39
  40 #--------------------------------------------------------------------
  41 #
  42 # User options
  43 #
  44 #--------------------------------------------------------------------
  45
  46 AC_ARG_ENABLE(error-on-warning,
  47   [  --enable-error-on-warning    treat compile warnings as errors],
  48   [case "${enableval}" in
  49      yes | y) CFLAGS="${CFLAGS} -Werror"; enable_compile_warnings=no ;;
  50      no | n)  ;;
  51      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  52    esac])
  53
  54
  55 AC_ARG_ENABLE(debug-freelist,
  56   [  --enable-debug-freelist include garbage collector freelist debugging code],
  57   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  58     AC_DEFINE(GUILE_DEBUG_FREELIST, 1,
  59       [Define this if you want to debug the free list (helps w/ GC bugs).])
  60   fi)
  61
  62 AC_ARG_ENABLE(debug-malloc,
  63   [  --enable-debug-malloc   include malloc debugging code],
  64   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  65     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
  66       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
  67   fi)
  68
  69 AC_ARG_ENABLE(guile-debug,
  70   [  --enable-guile-debug    include internal debugging functions],
  71   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  72     AC_DEFINE(GUILE_DEBUG, 1,
  73       [Define this to include various undocumented functions used to debug.])
  74   fi)
  75
  76 AC_ARG_ENABLE(arrays,
  77   [  --disable-arrays        omit array and uniform array support],,
  78   enable_arrays=yes)
  79
  80 AC_ARG_ENABLE(posix,
  81   [  --disable-posix         omit posix interfaces],,
  82   enable_posix=yes)
  83
  84 AC_ARG_ENABLE(networking,
  85   [  --disable-networking    omit networking interfaces],,
  86   enable_networking=yes)
  87
  88 AC_ARG_ENABLE(regex,
  89   [  --disable-regex         omit regular expression interfaces],,
  90   enable_regex=yes)
  91
  92 AC_ARG_ENABLE(htmldoc,
  93   [  --enable-htmldoc        build HTML documentation as well as Info],
  94   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  95      htmldoc_enabled=yes
  96      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  97      if test "$TEXI2HTML" = "not found"; then
  98        echo
  99        echo Building HTML documentation requires the \`texi2html\' program,
 100        echo which appears not to be present on your machine.
 101        echo
 102        echo \`texi2html\' is available from
 103        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
 104        echo
 105        echo In the meantime, to build the guile-doc distribution
 106        echo without HTML enabled, please rerun \`./configure\' without
 107        echo the \`--enable-htmldoc\' option.
 108        exit -1
 109      fi
 110    fi])
 111
 112 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
 113
 114 AC_ARG_ENABLE(deprecated,
 115   [  --disable-deprecated    omit deprecated features])
 116
 117 AH_TEMPLATE([SCM_ENABLE_DEPRECATED],
 118   [Define this to 1 if you want to include deprecated features.])
 119
 120 if test "$enable_deprecated" = no; then
 121   AC_DEFINE(SCM_ENABLE_DEPRECATED, 0)
 122 else
 123   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 124     warn_default=summary
 125   elif test "$enable_deprecated" = shutup; then
 126     warn_default=no
 127   else
 128     warn_default=$enable_deprecated
 129   fi
 130   AC_DEFINE(SCM_ENABLE_DEPRECATED, 1)
 131   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 132   [Define this to control the default warning level for deprecated features.])
 133 fi
 134
 135 dnl The --disable-debug used to control these two.  But now they are
 136 dnl a required part of the distribution.
 137 AC_DEFINE(DEBUG_EXTENSIONS, 1,
 138   [Define if you want support for debugging Scheme programs.])
 139 AC_DEFINE(READER_EXTENSIONS, 1,
 140   [Define if you want support for debugging Scheme programs.])
 141
 142 AC_ARG_ENABLE(elisp,
 143   [  --disable-elisp         omit Emacs Lisp support],,
 144   enable_elisp=yes)
 145
 146 #--------------------------------------------------------------------
 147
 148 dnl Some more checks for Win32
 149 AC_CYGWIN
 150 AC_MINGW32
 151 AC_LIBTOOL_WIN32_DLL
 152
 153 AC_LIBLTDL_CONVENIENCE
 154 AC_CONFIG_SUBDIRS(libltdl)
 155
 156 AC_PROG_INSTALL
 157 AC_PROG_CC
 158 AC_PROG_CPP
 159 AC_LIBTOOL_DLOPEN
 160
 161 AC_AIX
 162 AC_ISC_POSIX
 163 AC_MINIX
 164
 165 AM_PROG_CC_STDC
 166
 167 ## Needed for building DLLs on Cygwin, before AM_PROG_LIBTOOL
 168 AC_LIBTOOL_WIN32_DLL
 169 AM_PROG_LIBTOOL
 170
 171 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
 172 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
 173
 174 dnl Check for dynamic linking
 175
 176 use_modules=yes
 177 AC_ARG_WITH(modules,
 178 [  --with-modules[=FILES]  Add support for dynamic modules],
 179 use_modules="$withval")
 180 test -z "$use_modules" && use_modules=yes
 181 DLPREOPEN=
 182 if test "$use_modules" != no; then
 183   AC_DEFINE(DYNAMIC_LINKING, 1,
 184     [Define if you want support for dynamic linking.])
 185   if test "$use_modules" = yes; then
 186     DLPREOPEN="-dlpreopen force"
 187   else
 188     DLPREOPEN="-export-dynamic"
 189     for module in $use_modules; do
 190       DLPREOPEN="$DLPREOPEN -dlopen $module"
 191     done
 192   fi
 193 fi
 194
 195 dnl files which are destined for separate modules.
 196
 197 if test "$use_modules" != no; then
 198    AC_LIBOBJ([dynl])
 199 fi
 200
 201 if test "$enable_arrays" = yes; then
 202    AC_LIBOBJ([ramap])
 203    AC_LIBOBJ([unif])
 204    AC_DEFINE(HAVE_ARRAYS, 1,
 205      [Define this if you want support for arrays and uniform arrays.])
 206 fi
 207
 208 if test "$enable_posix" = yes; then
 209    AC_LIBOBJ([filesys])
 210    AC_LIBOBJ([posix])
 211    AC_DEFINE(HAVE_POSIX, 1,
 212      [Define this if you want support for POSIX system calls in Guile.])
 213 fi
 214
 215 if test "$enable_networking" = yes; then
 216    AC_LIBOBJ([net_db])
 217    AC_LIBOBJ([socket])
 218    AC_DEFINE(HAVE_NETWORKING, 1,
 219      [Define this if you want support for networking in Guile.])
 220 fi
 221
 222 if test "$enable_debug_malloc" = yes; then
 223    AC_LIBOBJ([debug-malloc])
 224 fi
 225
 226 if test "$enable_elisp" = yes; then
 227    AC_DEFINE(SCM_ENABLE_ELISP, 1,
 228      [Define this if you want Elisp support (in addition to Scheme).])
 229 fi
 230
 231
 232 AC_C_CONST
 233 AC_C_INLINE
 234 AC_C_BIGENDIAN
 235
 236 if test "$ac_cv_c_inline" != no; then
 237   AC_DEFINE(HAVE_INLINE, 1,
 238     [Define if the compiler supports inline functions.])
 239 fi
 240
 241 AC_CHECK_SIZEOF(short)
 242 AC_CHECK_SIZEOF(int)
 243 AC_CHECK_SIZEOF(long)
 244 AC_CHECK_SIZEOF(size_t)
 245
 246 dnl Check for integral types that can represent the range of pointers.
 247 dnl If these types don't exist on this platform, they are replaced by
 248 dnl "unsigned long" and "long", respectively.
 249
 250 AC_CHECK_HEADERS(stdint.h)
 251 AC_CHECK_HEADERS(inttypes.h)
 252 AC_CHECK_SIZEOF(uintptr_t)
 253 AC_CHECK_SIZEOF(ptrdiff_t)
 254
 255 AC_CHECK_SIZEOF(long long)
 256
 257 AC_CHECK_SIZEOF(void *)
 258
 259 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 260   AC_MSG_ERROR(sizes of long and void* are not identical)
 261 fi
 262
 263 AC_HEADER_STDC
 264 AC_HEADER_DIRENT
 265 AC_HEADER_TIME
 266 AC_HEADER_SYS_WAIT
 267 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h direct.h)
 268 GUILE_HEADER_LIBC_WITH_UNISTD
 269
 270 AC_TYPE_GETGROUPS
 271 AC_TYPE_SIGNAL
 272 AC_TYPE_MODE_T
 273
 274 AC_CHECK_LIB(m, main)
 275 AC_CHECK_FUNCS(gethostbyname)
 276 if test $ac_cv_func_gethostbyname = no; then
 277     AC_CHECK_LIB(nsl, gethostbyname)
 278 fi
 279
 280 AC_CHECK_FUNCS(connect)
 281 if test $ac_cv_func_connect = no; then
 282     AC_CHECK_LIB(socket, connect)
 283 fi
 284
 285 dnl
 286 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 287 dnl
 288 EXTRA_DEFS=""
 289 if test "$MINGW32" = "yes" ; then
 290     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 291       [Define if you have the <winsock2.h> header file.])])
 292     AC_CHECK_LIB(ws2_32, main)
 293     AC_LIBOBJ([win32-uname])
 294     AC_LIBOBJ([win32-dirent])
 295     if test "$enable_networking" = yes ; then
 296       AC_LIBOBJ([win32-socket])
 297     fi
 298     if test "$enable_shared" = yes ; then
 299       EXTRA_DEFS="-DSCM_IMPORT"
 300       AC_DEFINE(USE_DLL_IMPORT, 1,
 301         [Define if you need additional CPP macros on Win32 platforms.])
 302     fi
 303     if test x"$enable_ltdl_install" = x"yes" ; then
 304       INCLTDL="-DLIBLTDL_DLL_IMPORT $INCLTDL"
 305     fi
 306 fi
 307 AC_SUBST(EXTRA_DEFS)
 308
 309 AC_SUBST(INCLTDL)
 310 AC_SUBST(LIBLTDL)
 311 AC_SUBST(DLPREOPEN)
 312
 313 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer)
 314
 315 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 316 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 317 AC_CHECK_LIB(crypt, crypt)
 318
 319 ### Some systems don't declare some functions.  On such systems, we
 320 ### need to at least provide our own K&R-style declarations.
 321
 322 ### GUILE_FUNC_DECLARED(function, headerfile)
 323
 324 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 325 ### not there, #define MISSING_FUNCTION_DECL.
 326 AC_DEFUN(GUILE_FUNC_DECLARED, [
 327   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 328     AC_EGREP_HEADER($1, $2,
 329                     guile_cv_func_$1_declared=yes,
 330                     guile_cv_func_$1_declared=no))
 331   if test [x$guile_cv_func_]$1[_declared] = xno; then
 332     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 333       [Define if the operating system supplies $1 without declaring it.])
 334   fi
 335 ])
 336
 337 GUILE_FUNC_DECLARED(strptime, time.h)
 338 GUILE_FUNC_DECLARED(sleep, unistd.h)
 339 GUILE_FUNC_DECLARED(usleep, unistd.h)
 340
 341 ### On some systems usleep has no return value.  If it does have one,
 342 ### we'd like to return it; otherwise, we'll fake it.
 343 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 344   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 345                    unistd.h,
 346                    [guile_cv_func_usleep_return_type=void],
 347                    [guile_cv_func_usleep_return_type=int])])
 348 case "$guile_cv_func_usleep_return_type" in
 349   "void" )
 350     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 351       [Define if the system headers declare usleep to return void.])
 352   ;;
 353 esac
 354
 355 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 356 if test -n "$have_sys_un_h" ; then
 357   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 358     [Define if the system supports Unix-domain (file-domain) sockets.])
 359 fi
 360
 361 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 362
 363 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 364                setnetent    getnetent    endnetent    dnl
 365                setprotoent  getprotoent  endprotoent  dnl
 366                setservent   getservent   endservent   dnl
 367                getnetbyaddr getnetbyname dnl
 368                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 369                inet_pton inet_ntop)
 370
 371 AC_MSG_CHECKING(for __libc_stack_end)
 372 AC_TRY_LINK([extern char *__libc_stack_end;],
 373             [char *p = __libc_stack_end;],
 374             have_libc_stack_end=yes,
 375             have_libc_stack_end=no)
 376 AC_MSG_RESULT($have_libc_stack_end)
 377
 378 if test $have_libc_stack_end = yes; then
 379   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 380            [Define if you have the __libc_stack_end variable.])
 381 fi
 382
 383 dnl Some systems do not declare this.  Some systems do declare it, as a
 384 dnl macro.  With cygwin it may be in a DLL.
 385
 386 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 387 AC_CACHE_VAL(guile_cv_have_h_errno,
 388 [AC_TRY_COMPILE([#include <netdb.h>],
 389 [int a = h_errno;],
 390 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 391 AC_MSG_RESULT($guile_cv_have_h_errno)
 392 if test $guile_cv_have_h_errno = yes; then
 393   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 394 fi
 395
 396 AC_MSG_CHECKING(whether uint32_t is defined)
 397 AC_CACHE_VAL(guile_cv_have_uint32_t,
 398   [AC_TRY_COMPILE([#include <sys/types.h>
 399                    #if HAVE_STDINT_H
 400                    #include <stdint.h>
 401                    #endif
 402                    #ifndef __MINGW32__
 403                    #include <netdb.h>
 404                    #endif],
 405                   [uint32_t a;],
 406                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 407 AC_MSG_RESULT($guile_cv_have_uint32_t)
 408 if test $guile_cv_have_uint32_t = yes; then
 409   AC_DEFINE(HAVE_UINT32_T, 1,
 410     [Define if uint32_t typedef is defined when netdb.h is include.])
 411 fi
 412
 413 AC_MSG_CHECKING(for working IPv6 support)
 414 AC_CACHE_VAL(guile_cv_have_ipv6,
 415 [AC_TRY_COMPILE([
 416 #ifdef HAVE_SYS_TYPES_H
 417 #include <sys/types.h>
 418 #endif
 419 #include <netinet/in.h>
 420 #include <sys/socket.h>],
 421 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 422 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 423 AC_MSG_RESULT($guile_cv_have_ipv6)
 424 if test $guile_cv_have_ipv6 = yes; then
 425   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 426 fi
 427
 428 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 429 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 430 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 431 [AC_TRY_COMPILE([
 432 #ifdef HAVE_SYS_TYPES_H
 433 #include <sys/types.h>
 434 #endif
 435 #include <netinet/in.h>],
 436 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 437 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 438 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 439 if test $guile_cv_have_sin6_scope_id = yes; then
 440   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 441     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 442 fi
 443
 444 AC_MSG_CHECKING(whether localtime caches TZ)
 445 AC_CACHE_VAL(guile_cv_localtime_cache,
 446 [if test x$ac_cv_func_tzset = xyes; then
 447 AC_TRY_RUN([#include <time.h>
 448 #if STDC_HEADERS
 449 # include <stdlib.h>
 450 #endif
 451 extern char **environ;
 452 unset_TZ ()
 453 {
 454   char **from, **to;
 455   for (to = from = environ; (*to = *from); from++)
 456     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 457       to++;
 458 }
 459 char TZ_GMT0[] = "TZ=GMT0";
 460 char TZ_PST8[] = "TZ=PST8";
 461 main()
 462 {
 463   time_t now = time ((time_t *) 0);
 464   int hour_GMT0, hour_unset;
 465   if (putenv (TZ_GMT0) != 0)
 466     exit (1);
 467   hour_GMT0 = localtime (&now)->tm_hour;
 468   unset_TZ ();
 469   hour_unset = localtime (&now)->tm_hour;
 470   if (putenv (TZ_PST8) != 0)
 471     exit (1);
 472   if (localtime (&now)->tm_hour == hour_GMT0)
 473     exit (1);
 474   unset_TZ ();
 475   if (localtime (&now)->tm_hour != hour_unset)
 476     exit (1);
 477   exit (0);
 478 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 479 [# If we have tzset, assume the worst when cross-compiling.
 480 guile_cv_localtime_cache=yes])
 481 else
 482         # If we lack tzset, report that localtime does not cache TZ,
 483         # since we can't invalidate the cache if we don't have tzset.
 484         guile_cv_localtime_cache=no
 485 fi])dnl
 486 AC_MSG_RESULT($guile_cv_localtime_cache)
 487 if test $guile_cv_localtime_cache = yes; then
 488   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 489 fi
 490
 491 dnl Test whether system calls are restartable by default on the
 492 dnl current system.  If they are not, we put a loop around every system
 493 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 494 dnl change from the default behaviour.  On the other hand, if signals
 495 dnl are restartable then the loop is not installed and when libguile
 496 dnl initialises it also resets the behaviour of each signal to cause a
 497 dnl restart (in case a different runtime had a different default
 498 dnl behaviour for some reason: e.g., different versions of linux seem
 499 dnl to behave differently.)
 500
 501 AC_SYS_RESTARTABLE_SYSCALLS
 502
 503 if test "$enable_regex" = yes; then
 504    if test "$ac_cv_header_regex_h" = yes ||
 505       test "$ac_cv_header_rxposix_h" = yes ||
 506       test "$ac_cv_header_rx_rxposix_h" = yes; then
 507      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 508      [AC_CHECK_LIB(rx, main)
 509       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 510      [AC_CHECK_LIB(regex, main)
 511       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 512      )
 513      dnl The following should not be necessary, but for some reason
 514      dnl autoheader misses it if we don't include it!
 515      if test "$ac_cv_func_regcomp_norx" = yes ||
 516         test "$ac_cv_func_regcomp_regex" = yes ||
 517         test "$ac_cv_func_regcomp_rx" = yes; then
 518        AC_DEFINE(HAVE_REGCOMP, 1,
 519          [This is included as part of a workaround for a autoheader bug.])
 520      fi
 521    fi
 522 fi
 523
 524 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 525
 526 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 527
 528 AC_CHECK_FUNCS(finite isinf isnan copysign)
 529
 530 # When testing for the presence of alloca, we need to add alloca.o
 531 # explicitly to LIBOBJS to make sure that it is translated to
 532 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 533 AC_FUNC_ALLOCA
 534 if test "$ALLOCA" = "alloca.o"; then AC_LIBOBJ([alloca]); fi
 535
 536 AC_CHECK_MEMBERS([struct stat.st_rdev])
 537 AC_CHECK_MEMBERS([struct stat.st_blksize])
 538
 539 AC_STRUCT_ST_BLOCKS
 540
 541 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 542   [AC_TRY_CPP([#include <sys/stat.h>
 543                #ifndef S_ISLNK
 544                #error no S_ISLNK
 545                #endif],
 546                ac_cv_macro_S_ISLNK=yes,
 547                ac_cv_macro_S_ISLNK=no)])
 548 if test $ac_cv_macro_S_ISLNK = yes; then
 549   AC_DEFINE(HAVE_S_ISLNK, 1,
 550     [Define this if your system defines S_ISLNK in sys/stat.h.])
 551 fi
 552
 553 AC_STRUCT_TIMEZONE
 554 GUILE_STRUCT_UTIMBUF
 555
 556 #--------------------------------------------------------------------
 557 #
 558 # Which way does the stack grow?
 559 #
 560 #--------------------------------------------------------------------
 561
 562 AC_TRY_RUN(aux (l) unsigned long l;
 563              { int x; exit (l >= ((unsigned long)&x)); }
 564            main () { int q; aux((unsigned long)&q); },
 565            [AC_DEFINE([SCM_STACK_GROWS_UP], 1,
 566               [Define this if a callee's stack frame has a higher address
 567                than the caller's stack frame.  On most machines, this is
 568                not the case.])],
 569            [],
 570            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in)])
 571
 572 AH_TEMPLATE([SCM_SINGLES],
 573   [Define this if floats are the same size as longs.])
 574
 575 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 576     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 577                 [guile_cv_type_float_fits_long=yes],
 578                 [guile_cv_type_float_fits_long=no],
 579                 [guile_cv_type_float_fits_long=guess-yes])])
 580 case $guile_cv_type_float_fits_long in
 581   "yes" )
 582     AC_DEFINE(SCM_SINGLES)
 583   ;;
 584   "guess-yes" )
 585     AC_DEFINE(SCM_SINGLES)
 586     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 587     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 588   ;;
 589 esac
 590
 591
 592 AC_MSG_CHECKING(for struct linger)
 593 AC_CACHE_VAL(scm_cv_struct_linger,
 594         AC_TRY_COMPILE([
 595 #include <sys/types.h>
 596 #include <sys/socket.h>],
 597                         [struct linger lgr;  lgr.l_linger = 100],
 598                         scm_cv_struct_linger="yes",
 599                         scm_cv_struct_linger="no"))
 600 AC_MSG_RESULT($scm_cv_struct_linger)
 601 if test $scm_cv_struct_linger = yes; then
 602         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 603           [Define this if your system defines struct linger, for use with the
 604            getsockopt and setsockopt system calls.])
 605 fi
 606
 607
 608 AC_MSG_CHECKING(for struct timespec)
 609 AC_CACHE_VAL(scm_cv_struct_timespec,
 610         AC_TRY_COMPILE([
 611 #include <time.h>],
 612                         [struct timespec t;  t.tv_nsec = 100],
 613                         scm_cv_struct_timespec="yes",
 614                         scm_cv_struct_timespec="no"))
 615 AC_MSG_RESULT($scm_cv_struct_timespec)
 616 if test $scm_cv_struct_timespec = yes; then
 617   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 618     [Define this if your system defines struct timespec via <time.h>.])
 619 fi
 620
 621 #--------------------------------------------------------------------
 622 #
 623 # Flags for thread support
 624 #
 625 #--------------------------------------------------------------------
 626
 627 ### What thread package has the user asked for?
 628 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 629             , with_threads=no)
 630
 631 ### Turn $with_threads into either the name of a threads package, like
 632 ### `qt', or `no', meaning that threads should not be supported.
 633 AC_MSG_CHECKING(whether to support threads)
 634 case "$with_threads" in
 635   "yes" | "qt" | "coop" | "")
 636     with_threads=qt
 637   ;;
 638   "no" )
 639   ;;
 640   * )
 641     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 642   ;;
 643 esac
 644 AC_MSG_RESULT($with_threads)
 645
 646 ## Make sure the threads package we've chosen is actually supported on
 647 ## the present platform.
 648 case "${with_threads}" in
 649   "qt" )
 650     ## This configures the QuickThreads package, and sets or clears
 651     ## the THREAD_PACKAGE variable if qthreads don't configure
 652     ## correctly.
 653     QTHREADS_CONFIGURE
 654    ;;
 655 esac
 656
 657 ## If we're using threads, bring in some other parts of Guile which
 658 ## work with them.
 659 if test "${THREAD_PACKAGE}" != "" ; then
 660   AC_DEFINE(USE_THREADS, 1, [Define if using any sort of threads.])
 661
 662   ## Include the Guile thread interface in the library...
 663   AC_LIBOBJ([threads])
 664
 665   ## ... and tell it which package to talk to.
 666   case "${THREAD_PACKAGE}" in
 667     "QT" )
 668       AC_DEFINE(USE_COOP_THREADS, 1,
 669         [Define if using cooperative multithreading.])
 670     ;;
 671     * )
 672       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 673     ;;
 674   esac
 675
 676   ## Bring in scm_internal_select, if appropriate.
 677   if test $ac_cv_func_gettimeofday = yes &&
 678      test $ac_cv_func_select = yes; then
 679     AC_DEFINE(GUILE_ISELECT, 1, [Define to implement scm_internal_select.])
 680   fi
 681
 682   AC_ARG_ENABLE(linuxthreads,
 683   [  --disable-linuxthreads  disable linuxthreads workaround],,
 684   enable_linuxthreads=yes)
 685
 686   ## Workaround for linuxthreads (optionally disabled)
 687   if test $host_os = linux-gnu -a "$enable_linuxthreads" = yes; then
 688     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1,
 689       [Define to enable workaround for COOP-linuxthreads compatibility.])
 690     AC_CHECK_LIB(pthread, main)
 691   fi
 692 fi
 693
 694 ## Cross building
 695 if test "$cross_compiling" = "yes"; then
 696   AC_MSG_CHECKING(cc for build)
 697   ## /usr/bin/cc still uses wrong assembler
 698   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
 699   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
 700 else
 701   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
 702 fi
 703 AC_ARG_WITH(cc-for-build,
 704   [  --with-cc-for-build=CC  native C compiler, to be used during build])
 705 test -n "$with_cc_for_build" && CC_FOR_BUILD="$with_cc_for_build"
 706
 707 ## AC_MSG_CHECKING("if we are cross compiling")
 708 ## AC_MSG_RESULT($cross_compiling)
 709 if test "$cross_compiling" = "yes"; then
 710    AC_MSG_RESULT($CC_FOR_BUILD)
 711 fi
 712
 713 ## No need as yet to be more elaborate
 714 CCLD_FOR_BUILD="$CC_FOR_BUILD"
 715
 716 AC_SUBST(cross_compiling)
 717 AC_SUBST(CC_FOR_BUILD)
 718 AC_SUBST(CCLD_FOR_BUILD)
 719
 720 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
 721 ## --HOST is the platform that PACKAGE is compiled for.
 722 HOST_CC="$CC_FOR_BUILD"
 723 AC_SUBST(HOST_CC)
 724
 725 if test "$cross_compiling" = "yes"; then
 726   AC_MSG_CHECKING(guile for build)
 727   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
 728 else
 729   GUILE_FOR_BUILD='$(preinstguile)'
 730 fi
 731 AC_ARG_WITH(guile-for-build,
 732   [  --with-guile-for-build=guile  native guile executable, to be used during build])
 733 test -n "$with_guile_for_build" && GUILE_FOR_BUILD="$with_guile_for_build"
 734
 735 ## AC_MSG_CHECKING("if we are cross compiling")
 736 ## AC_MSG_RESULT($cross_compiling)
 737 if test "$cross_compiling" = "yes"; then
 738    AC_MSG_RESULT($GUILE_FOR_BUILD)
 739 fi
 740 AC_SUBST(GUILE_FOR_BUILD)
 741
 742 ## If we're using GCC, ask for aggressive warnings.
 743 case "$GCC" in
 744   yes )
 745     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 746     ## much stuff with generic function pointers for that to really be
 747     ## less than exasperating.
 748     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 749     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 750     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 751 esac
 752
 753 AC_PROG_AWK
 754
 755 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
 756 ## -- I'm disabling it for now in the hopes that the newer autoconf
 757 ## will DTRT -- if not, we need to fix up the sed command to match the
 758 ## others...
 759 ##
 760 ## Remove fileblocks.o from the object list.  This file gets added by
 761 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
 762 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
 763
 764 ## If we're creating a shared library (using libtool!), then we'll
 765 ## need to generate a list of .lo files corresponding to the .o files
 766 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 767 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
 768
 769 ## We also need to create corresponding .doc and .x files
 770 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
 771 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
 772
 773 AC_SUBST(GUILE_MAJOR_VERSION)
 774 AC_SUBST(GUILE_MINOR_VERSION)
 775 AC_SUBST(GUILE_MICRO_VERSION)
 776 AC_SUBST(GUILE_VERSION)
 777
 778 #######################################################################
 779 # library versioning
 780
 781 AC_SUBST(LIBQTHREADS_INTERFACE_CURRENT)
 782 AC_SUBST(LIBQTHREADS_INTERFACE_REVISION)
 783 AC_SUBST(LIBQTHREADS_INTERFACE_AGE)
 784 AC_SUBST(LIBQTHREADS_INTERFACE)
 785
 786 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
 787 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
 788 AC_SUBST(LIBGUILE_INTERFACE_AGE)
 789 AC_SUBST(LIBGUILE_INTERFACE)
 790
 791 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
 792 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
 793 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
 794 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
 795
 796 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
 797 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
 798 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
 799 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
 800
 801 #######################################################################
 802
 803 dnl Tell guile-config what flags guile users should link against.
 804 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 805 AC_SUBST(GUILE_LIBS)
 806
 807 AC_SUBST(AWK)
 808 AC_SUBST(LIBLOBJS)
 809 AC_SUBST(EXTRA_DOT_DOC_FILES)
 810 AC_SUBST(EXTRA_DOT_X_FILES)
 811
 812 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
 813 top_builddir_absolute=`pwd`
 814 AC_SUBST(top_builddir_absolute)
 815 top_srcdir_absolute=`(cd $srcdir ; pwd)`
 816 AC_SUBST(top_srcdir_absolute)
 817
 818 AC_CONFIG_FILES([
 819   Makefile
 820   am/Makefile
 821   libguile/Makefile
 822   libguile/guile-snarf
 823   libguile/guile-doc-snarf
 824   libguile/guile-func-name-check
 825   libguile/guile-snarf-docs
 826   libguile/version.h
 827   ice-9/Makefile
 828   lang/Makefile
 829   lang/elisp/Makefile
 830   lang/elisp/internals/Makefile
 831   lang/elisp/primitives/Makefile
 832   oop/Makefile
 833   oop/goops/Makefile
 834   scripts/Makefile
 835   srfi/Makefile
 836   qt/Makefile
 837   qt/qt.h
 838   qt/md/Makefile
 839   qt/time/Makefile
 840   guile-config/Makefile
 841   doc/Makefile
 842   doc/ref/Makefile
 843   doc/tutorial/Makefile
 844   doc/goops/Makefile
 845   doc/r5rs/Makefile
 846   examples/Makefile
 847   examples/scripts/Makefile
 848   examples/box/Makefile
 849   examples/box-module/Makefile
 850   examples/box-dynamic/Makefile
 851   examples/box-dynamic-module/Makefile
 852   examples/modules/Makefile
 853   examples/safe/Makefile
 854   test-suite/Makefile
 855   check-guile
 856   benchmark-suite/Makefile
 857   benchmark-guile
 858   guile-tools
 859   pre-inst-guile])
 860
 861 AC_CONFIG_COMMANDS(default,
 862   [ chmod +x libguile/guile-snarf \
 863              libguile/guile-doc-snarf \
 864              libguile/guile-func-name-check \
 865              libguile/guile-snarf-docs \
 866              check-guile \
 867              benchmark-guile \
 868              guile-tools \
 869              pre-inst-guile])
 870
 871 AC_OUTPUT
 872
 873 dnl Local Variables:
 874 dnl comment-start: "dnl "
 875 dnl comment-end: ""
 876 dnl comment-start-skip: "\\bdnl\\b\\s *"
 877 dnl End: