configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   8   2007, 2008, 2009, 2010, 2011, 2012, 2013, 2014 Free Software Foundation, Inc.
   9
  10 This file is part of GUILE
  11
  12 GUILE is free software; you can redistribute it and/or modify it under
  13 the terms of the GNU Lesser General Public License as published by the
  14 Free Software Foundation; either version 3, or (at your option) any
  15 later version.
  16
  17 GUILE is distributed in the hope that it will be useful, but WITHOUT
  18 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  19 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  20 License for more details.
  21
  22 You should have received a copy of the GNU Lesser General Public
  23 License along with GUILE; see the file COPYING.LESSER.  If not, write
  24 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  25 Floor, Boston, MA 02110-1301, USA.
  26
  27 ]])
  28
  29 AC_PREREQ(2.61)
  30
  31 AC_INIT([GNU Guile],
  32         m4_esyscmd([build-aux/git-version-gen --match v2.0.\* .tarball-version]),
  33         [bug-guile@gnu.org])
  34 AC_CONFIG_AUX_DIR([build-aux])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_CONFIG_SRCDIR(GUILE-VERSION)
  37
  38 dnl Use `serial-tests' so the output `check-guile' is not hidden
  39 dnl (`parallel-tests' is the default in Automake 1.13.)
  40 dnl `serial-tests' was introduced in Automake 1.12.
  41 AM_INIT_AUTOMAKE([1.12 gnu no-define -Wall -Wno-override \
  42   serial-tests color-tests dist-xz])
  43 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  44
  45 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  46 AC_CONFIG_SRCDIR([GUILE-VERSION])
  47
  48 . $srcdir/GUILE-VERSION
  49 GUILE_VERSION="$PACKAGE_VERSION"
  50
  51 AC_CONFIG_HEADERS([config.h])
  52 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  53
  54 dnl We require the pkg.m4 set of macros from pkg-config.
  55 dnl Make sure it's available.
  56 m4_pattern_forbid([PKG_CHECK_MODULES])
  57
  58 #--------------------------------------------------------------------
  59
  60 AC_LANG([C])
  61
  62 dnl Some more checks for Win32
  63 AC_CANONICAL_HOST
  64
  65 AC_LIBTOOL_WIN32_DLL
  66
  67 AC_PROG_INSTALL
  68 AC_PROG_CC
  69 gl_EARLY
  70 AC_PROG_CPP
  71 AC_PROG_SED
  72 AC_PROG_AWK
  73 AC_PROG_LN_S
  74 AM_PROG_AR
  75
  76 dnl Gnulib.
  77 gl_INIT
  78
  79 dnl We provide our own lib/glthread/lock.h, so let other Gnulib modules
  80 dnl know that we have it.  This allows them to be compiled with adequate
  81 dnl locking support.  See <http://bugs.gnu.org/14404>.
  82 AC_DEFINE([GNULIB_LOCK], [1],
  83   [Define to allow Gnulib modules to use Guile's locks.])
  84
  85
  86 AC_PROG_CC_C89
  87
  88 # for per-target cflags in the libguile subdir
  89 AM_PROG_CC_C_O
  90
  91 AC_LIBTOOL_DLOPEN
  92 AC_PROG_LIBTOOL
  93
  94 AM_CONDITIONAL([HAVE_SHARED_LIBRARIES], [test "x$enable_shared" = "xyes"])
  95
  96 dnl Check for libltdl.
  97 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  98   [lt_dlopenext ("foo");])
  99 if test "x$HAVE_LIBLTDL" != "xyes"; then
 100   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
 101 fi
 102
 103 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
 104 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
 105
 106 AM_PATH_LISPDIR
 107
 108 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
 109   [Define to the host's GNU triplet.])
 110
 111 #--------------------------------------------------------------------
 112 #
 113 # User options (after above tests that may set default CFLAGS etc.)
 114 #
 115 #--------------------------------------------------------------------
 116
 117 GUILE_ERROR_ON_WARNING="no"
 118
 119 AC_ARG_ENABLE(error-on-warning,
 120   [  --enable-error-on-warning    treat compile warnings as errors],
 121   [case "${enableval}" in
 122      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 123      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 124      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 125    esac])
 126
 127 AC_ARG_ENABLE(debug-malloc,
 128   [  --enable-debug-malloc   include malloc debugging code],
 129   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 130     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 131       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 132   fi)
 133
 134 SCM_I_GSC_GUILE_DEBUG=0
 135 AC_ARG_ENABLE(guile-debug,
 136   [AS_HELP_STRING([--enable-guile-debug],
 137                   [include internal debugging functions])],
 138   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 139     SCM_I_GSC_GUILE_DEBUG=1
 140   fi)
 141
 142 AC_ARG_ENABLE(posix,
 143   [  --disable-posix         omit non-essential POSIX interfaces],,
 144   enable_posix=yes)
 145
 146 AC_ARG_ENABLE(networking,
 147   [  --disable-networking    omit networking interfaces],,
 148   enable_networking=yes)
 149
 150 AC_ARG_ENABLE(regex,
 151   [  --disable-regex         omit regular expression interfaces],,
 152   enable_regex=yes)
 153
 154 AC_ARG_ENABLE([deprecated],
 155   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 156
 157 if test "$enable_deprecated" = no; then
 158   SCM_I_GSC_ENABLE_DEPRECATED=0
 159   warn_default=no
 160 else
 161   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 162     warn_default=summary
 163   elif test "$enable_deprecated" = shutup; then
 164     warn_default=no
 165   else
 166     warn_default=$enable_deprecated
 167   fi
 168   SCM_I_GSC_ENABLE_DEPRECATED=1
 169 fi
 170 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 171 [Define this to control the default warning level for deprecated features.])
 172
 173 dnl  Added the following configure option in January 2008 following
 174 dnl  investigation of problems with "64" system and library calls on
 175 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 176 dnl  system has stat64, it will have all the other 64 APIs too; but on
 177 dnl  Darwin, stat64 is there but other APIs are missing.
 178 dnl
 179 dnl  It also appears, from the Darwin docs, that most system call APIs
 180 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 181 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 182 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 183 dnl
 184 dnl  A similar problem has been reported for HP-UX:
 185 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 186 dnl
 187 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 188 dnl  better than no Guile at all, we provide this option to suppress
 189 dnl  trying to use "64" calls.
 190 dnl
 191 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 192 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 193 dnl  missing out on that.  If so, someone can work on that in the future.
 194 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 195 dnl  wasn't building before.
 196 AC_MSG_CHECKING([whether to use system and library "64" calls])
 197 AC_ARG_WITH([64-calls],
 198   AS_HELP_STRING([--without-64-calls],
 199                  [don't attempt to use system and library calls with "64" in their names]),
 200   [use_64_calls=$withval],
 201   [use_64_calls=yes
 202    case $host in
 203      *-apple-darwin* )
 204        use_64_calls=no
 205        ;;
 206      powerpc-ibm-aix* )
 207        use_64_calls=no
 208        ;;
 209    esac])
 210 AC_MSG_RESULT($use_64_calls)
 211 case "$use_64_calls" in
 212   y* )
 213     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 214       [Define to 1 in order to try to use "64" versions of system and library calls.])
 215     ;;
 216 esac
 217
 218 #--------------------------------------------------------------------
 219
 220 dnl Check for dynamic linking
 221
 222 use_modules=yes
 223 AC_ARG_WITH(modules,
 224 [  --with-modules[=FILES]  Add support for dynamic modules],
 225 use_modules="$withval")
 226 test -z "$use_modules" && use_modules=yes
 227 DLPREOPEN=
 228 if test "$use_modules" != no; then
 229   if test "$use_modules" = yes; then
 230     DLPREOPEN="-dlpreopen force"
 231   else
 232     DLPREOPEN="-export-dynamic"
 233     for module in $use_modules; do
 234       DLPREOPEN="$DLPREOPEN -dlopen $module"
 235     done
 236   fi
 237 fi
 238
 239 dnl files which are destined for separate modules.
 240
 241 if test "$use_modules" != no; then
 242    AC_LIBOBJ([dynl])
 243    AC_DEFINE([HAVE_MODULES], 1,
 244      [Define this if you want support for dynamically loaded modules in Guile.])
 245 fi
 246
 247 if test "$enable_posix" = yes; then
 248    AC_LIBOBJ([posix])
 249    AC_DEFINE([HAVE_POSIX], 1,
 250      [Define this if you want support for non-essential POSIX system calls in Guile.])
 251 fi
 252
 253 if test "$enable_networking" = yes; then
 254    AC_LIBOBJ([net_db])
 255    AC_LIBOBJ([socket])
 256    AC_DEFINE([HAVE_NETWORKING], 1,
 257      [Define this if you want support for networking in Guile.])
 258 fi
 259
 260 if test "$enable_debug_malloc" = yes; then
 261    AC_LIBOBJ([debug-malloc])
 262 fi
 263
 264 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 265
 266 AC_C_CONST
 267
 268 # "volatile" is used in a couple of tests below.
 269 AC_C_VOLATILE
 270
 271 AC_C_INLINE
 272 if test "$ac_cv_c_inline" != no; then
 273   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 274 else
 275   SCM_I_GSC_C_INLINE=NULL
 276 fi
 277 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 278
 279 AC_C_BIGENDIAN
 280
 281 AC_C_LABELS_AS_VALUES
 282
 283 AC_CHECK_SIZEOF(char)
 284 AC_CHECK_SIZEOF(unsigned char)
 285 AC_CHECK_SIZEOF(short)
 286 AC_CHECK_SIZEOF(unsigned short)
 287 AC_CHECK_SIZEOF(int)
 288 AC_CHECK_SIZEOF(unsigned int)
 289 AC_CHECK_SIZEOF(long)
 290 AC_CHECK_SIZEOF(unsigned long)
 291 AC_CHECK_SIZEOF(size_t)
 292 AC_CHECK_SIZEOF(long long)
 293 AC_CHECK_SIZEOF(unsigned long long)
 294 AC_CHECK_SIZEOF(__int64)
 295 AC_CHECK_SIZEOF(unsigned __int64)
 296 AC_CHECK_SIZEOF(void *)
 297 AC_CHECK_SIZEOF(intptr_t)
 298 AC_CHECK_SIZEOF(uintptr_t)
 299 AC_CHECK_SIZEOF(ptrdiff_t)
 300 AC_CHECK_SIZEOF(size_t)
 301 AC_CHECK_SIZEOF(off_t)
 302
 303 if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then
 304   AC_MSG_ERROR(long does not fit into a void*)
 305 fi
 306
 307 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 308   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 309 else
 310   SCM_I_GSC_T_PTRDIFF='"long"'
 311 fi
 312 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 313
 314 AC_CHECK_HEADERS([stdint.h])
 315 AC_CHECK_HEADERS([inttypes.h])
 316
 317 AC_CHECK_SIZEOF(intmax_t)
 318
 319 SCM_I_GSC_NEEDS_STDINT_H=0
 320 SCM_I_GSC_NEEDS_INTTYPES_H=0
 321
 322 ### intptr and uintptr (try not to use inttypes if we don't have to)
 323 if test "$ac_cv_header_inttypes_h" = yes; then
 324   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 325     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 326 #include <stdio.h>])
 327     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 328       SCM_I_GSC_NEEDS_INTTYPES_H=1
 329     fi
 330   fi
 331   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 332     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 333 #include <stdio.h>])
 334     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 335       SCM_I_GSC_NEEDS_INTTYPES_H=1
 336     fi
 337   fi
 338 fi
 339
 340 ### See what's provided by stdint.h
 341 if test "$ac_cv_header_stdint_h" = yes; then
 342    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 343    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 344    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 345    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 346    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 347    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 348    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 349    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 350    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 351    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 352    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 353    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 354 fi
 355
 356 # so we don't get confused by the cache (wish there was a better way
 357 # to check particular headers for the same type...)
 358
 359 unset ac_cv_type_int8_t
 360 unset ac_cv_type_uint8_t
 361 unset ac_cv_type_int16_t
 362 unset ac_cv_type_uint16_t
 363 unset ac_cv_type_int32_t
 364 unset ac_cv_type_uint32_t
 365 unset ac_cv_type_int64_t
 366 unset ac_cv_type_uint64_t
 367 unset ac_cv_type_intmax_t
 368 unset ac_cv_type_uintmax_t
 369
 370 ### See what's provided by inttypes.h
 371 if test "$ac_cv_header_inttypes_h" = yes; then
 372   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 373   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 374   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 375   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 376   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 377   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 378   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 379   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 380   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 381   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 382   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 383   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 384 fi
 385
 386 # Try hard to find definitions for some required scm_t_*int* types.
 387
 388 ### Required type scm_t_int8
 389 if test "$scm_stdint_has_int8"; then
 390   SCM_I_GSC_T_INT8='"int8_t"'
 391   SCM_I_GSC_NEEDS_STDINT_H=1
 392 elif test "$scm_inttypes_has_int8"; then
 393   SCM_I_GSC_T_INT8='"int8_t"'
 394   SCM_I_GSC_NEEDS_INTTYPES_H=1
 395 elif test "$ac_cv_sizeof_char" -eq 1; then
 396   SCM_I_GSC_T_INT8='"signed char"'
 397 else
 398   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 399 fi
 400 AC_SUBST([SCM_I_GSC_T_INT8])
 401
 402 ### Required type scm_t_uint8
 403 if test "$scm_stdint_has_uint8"; then
 404   SCM_I_GSC_T_UINT8='"uint8_t"'
 405   SCM_I_GSC_NEEDS_STDINT_H=1
 406 elif test "$scm_inttypes_has_uint8"; then
 407   SCM_I_GSC_T_UINT8='"uint8_t"'
 408   SCM_I_GSC_NEEDS_INTTYPES_H=1
 409 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 410   SCM_I_GSC_T_UINT8='"unsigned char"'
 411 else
 412   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 413 fi
 414 AC_SUBST([SCM_I_GSC_T_UINT8])
 415
 416 ### Required type scm_t_int16 (ANSI C says int or short might work)
 417 if test "$scm_stdint_has_int16"; then
 418   SCM_I_GSC_T_INT16='"int16_t"'
 419   SCM_I_GSC_NEEDS_STDINT_H=1
 420 elif test "$scm_inttypes_has_int16"; then
 421   SCM_I_GSC_T_INT16='"int16_t"'
 422   SCM_I_GSC_NEEDS_INTTYPES_H=1
 423 elif test "$ac_cv_sizeof_int" -eq 2; then
 424   SCM_I_GSC_T_INT16='"int"'
 425 elif test "$ac_cv_sizeof_short" -eq 2; then
 426   SCM_I_GSC_T_INT16='"short"'
 427 else
 428   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 429 fi
 430 AC_SUBST([SCM_I_GSC_T_INT16])
 431
 432 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 433 if test "$scm_stdint_has_uint16"; then
 434   SCM_I_GSC_T_UINT16='"uint16_t"'
 435   SCM_I_GSC_NEEDS_STDINT_H=1
 436 elif test "$scm_inttypes_has_uint16"; then
 437   SCM_I_GSC_T_UINT16='"uint16_t"'
 438   SCM_I_GSC_NEEDS_INTTYPES_H=1
 439 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 440   SCM_I_GSC_T_UINT16='"unsigned int"'
 441 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 442   SCM_I_GSC_T_UINT16='"unsigned short"'
 443 else
 444   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 445 fi
 446 AC_SUBST([SCM_I_GSC_T_UINT16])
 447
 448
 449 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 450 if test "$scm_stdint_has_int32"; then
 451   SCM_I_GSC_T_INT32='"int32_t"'
 452   SCM_I_GSC_NEEDS_STDINT_H=1
 453 elif test "$scm_inttypes_has_int32"; then
 454   SCM_I_GSC_T_INT32='"int32_t"'
 455   SCM_I_GSC_NEEDS_INTTYPES_H=1
 456 elif test "$ac_cv_sizeof_int" -eq 4; then
 457   SCM_I_GSC_T_INT32='"int"'
 458 elif test "$ac_cv_sizeof_long" -eq 4; then
 459   SCM_I_GSC_T_INT32='"long"'
 460 elif test "$ac_cv_sizeof_short" -eq 4; then
 461   SCM_I_GSC_T_INT32='"short"'
 462 else
 463   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 464 fi
 465 AC_SUBST([SCM_I_GSC_T_INT32])
 466
 467 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 468 if test "$scm_stdint_has_uint32"; then
 469   SCM_I_GSC_T_UINT32='"uint32_t"'
 470   SCM_I_GSC_NEEDS_STDINT_H=1
 471 elif test "$scm_inttypes_has_uint32"; then
 472   SCM_I_GSC_T_UINT32='"uint32_t"'
 473   SCM_I_GSC_NEEDS_INTTYPES_H=1
 474 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 475   SCM_I_GSC_T_UINT32='"unsigned int"'
 476 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 477   SCM_I_GSC_T_UINT32='"unsigned long"'
 478 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 479   SCM_I_GSC_T_UINT32='"unsigned short"'
 480 else
 481   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 482 fi
 483 AC_SUBST([SCM_I_GSC_T_UINT32])
 484
 485 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 486 ### Also try 'long long' and '__int64' if we have it.
 487 SCM_I_GSC_T_INT64=0
 488 if test "$scm_stdint_has_int64"; then
 489   SCM_I_GSC_T_INT64='"int64_t"'
 490   SCM_I_GSC_NEEDS_STDINT_H=1
 491 elif test "$scm_inttypes_has_int64"; then
 492   SCM_I_GSC_T_INT64='"int64_t"'
 493   SCM_I_GSC_NEEDS_INTTYPES_H=1
 494 elif test "$ac_cv_sizeof_int" -eq 8; then
 495   SCM_I_GSC_T_INT64='"int"'
 496 elif test "$ac_cv_sizeof_long" -eq 8; then
 497   SCM_I_GSC_T_INT64='"long"'
 498 elif test "$ac_cv_sizeof_short" -eq 8; then
 499   SCM_I_GSC_T_INT64='"short"'
 500 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 501   SCM_I_GSC_T_INT64='"long long"'
 502 elif test "$ac_cv_sizeof___int64" -eq 8; then
 503   SCM_I_GSC_T_INT64='"__int64"'
 504 else
 505   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 506 fi
 507 AC_SUBST([SCM_I_GSC_T_INT64])
 508
 509
 510 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 511 ### Also try 'long long' and '__int64' if we have it.
 512 SCM_I_GSC_T_UINT64=0
 513 if test "$scm_stdint_has_uint64"; then
 514   SCM_I_GSC_T_UINT64='"uint64_t"'
 515   SCM_I_GSC_NEEDS_STDINT_H=1
 516 elif test "$scm_inttypes_has_uint64"; then
 517   SCM_I_GSC_T_UINT64='"uint64_t"'
 518   SCM_I_GSC_NEEDS_INTTYPES_H=1
 519 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 520   SCM_I_GSC_T_UINT64='"unsigned int"'
 521 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 522   SCM_I_GSC_T_UINT64='"unsigned long"'
 523 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 524   SCM_I_GSC_T_UINT64='"unsigned short"'
 525 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 526   SCM_I_GSC_T_UINT64='"unsigned long long"'
 527 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 528   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 529 else
 530   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 531 fi
 532 AC_SUBST([SCM_I_GSC_T_UINT64])
 533
 534 ### Required type scm_t_intmax
 535 ###
 536 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 537 ### none of them is available, we use 'long'.
 538 ###
 539 SCM_I_GSC_T_INTMAX=0
 540 if test "$scm_stdint_has_intmax"; then
 541   SCM_I_GSC_T_INTMAX='"intmax_t"'
 542   SCM_I_GSC_NEEDS_STDINT_H=1
 543 elif test "$scm_inttypes_has_intmax"; then
 544   SCM_I_GSC_T_INTMAX='"intmax_t"'
 545   SCM_I_GSC_NEEDS_INTTYPES_H=1
 546 elif test "$ac_cv_sizeof___int64" -ne 0; then
 547   SCM_I_GSC_T_INTMAX='"__int64"'
 548 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 549   SCM_I_GSC_T_INTMAX='"long long"'
 550 else
 551   SCM_I_GSC_T_INTMAX='"long"'
 552 fi
 553 AC_SUBST([SCM_I_GSC_T_INTMAX])
 554
 555 ### Required type scm_t_uintmax
 556 ###
 557 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 558 ### this order.  When none of them is available, we use 'unsigned long'.
 559 ###
 560 SCM_I_GSC_T_UINTMAX=0
 561 if test "$scm_stdint_has_uintmax"; then
 562   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 563   SCM_I_GSC_NEEDS_STDINT_H=1
 564 elif test "$scm_inttypes_has_uintmax"; then
 565   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 566   SCM_I_GSC_NEEDS_INTTYPES_H=1
 567 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 568   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 569 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 570   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 571 else
 572   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 573 fi
 574 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 575
 576 ### Required type scm_t_intptr
 577 ###
 578 SCM_I_GSC_T_INTPTR=0
 579 if test "$scm_stdint_has_intptr"; then
 580   SCM_I_GSC_T_INTPTR='"intptr_t"'
 581   SCM_I_GSC_NEEDS_STDINT_H=1
 582 elif test "$scm_inttypes_has_intptr"; then
 583   SCM_I_GSC_T_INTPTR='"intptr_t"'
 584   SCM_I_GSC_NEEDS_INTTYPES_H=1
 585 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 586   SCM_I_GSC_T_INTPTR='"int"'
 587 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 588   SCM_I_GSC_T_INTPTR='"long"'
 589 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 590   SCM_I_GSC_T_INTPTR='"long long"'
 591 else
 592   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 593 fi
 594 AC_SUBST([SCM_I_GSC_T_INTPTR])
 595
 596 ### Required type scm_t_uintptr
 597 ###
 598 SCM_I_GSC_T_UINTPTR=0
 599 if test "$scm_stdint_has_uintptr"; then
 600   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 601   SCM_I_GSC_NEEDS_STDINT_H=1
 602 elif test "$scm_inttypes_has_uintptr"; then
 603   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 604   SCM_I_GSC_NEEDS_INTTYPES_H=1
 605 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 606   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 607 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 608   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 609 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 610   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 611 else
 612   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 613 fi
 614 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 615
 616
 617 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 618 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 619
 620 AC_HEADER_STDC
 621 AC_HEADER_TIME
 622 AC_HEADER_SYS_WAIT
 623 AC_HEADER_DIRENT
 624
 625 # Reason for checking:
 626 #
 627 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 628 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 629 #
 630 AC_CHECK_MEMBER([struct dirent64.d_name],
 631   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 632   [ #ifndef _LARGEFILE64_SOURCE
 633     # define _LARGEFILE64_SOURCE
 634     #endif
 635
 636     /* Per Autoconf manual.  */
 637     #include <sys/types.h>
 638     #ifdef HAVE_DIRENT_H
 639     # include <dirent.h>
 640     #else
 641     # define dirent direct
 642     # ifdef HAVE_SYS_NDIR_H
 643     #  include <sys/ndir.h>
 644     # endif
 645     # ifdef HAVE_SYS_DIR_H
 646     #  include <sys/dir.h>
 647     # endif
 648     # ifdef HAVE_NDIR_H
 649     #  include <ndir.h>
 650     # endif
 651     #endif ])
 652 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 653
 654 # Reasons for testing:
 655 #   complex.h - new in C99
 656 #   fenv.h - available in C99, but not older systems
 657 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 658 #     this file instead of <fenv.h>
 659 #   process.h - mingw specific
 660 #   sched.h - missing on MinGW
 661 #   sys/sendfile.h - non-POSIX, found in glibc
 662 #
 663 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h memory.h process.h string.h \
 664 sys/dir.h sys/ioctl.h sys/select.h \
 665 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 666 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 667 direct.h machine/fpu.h sched.h sys/sendfile.h])
 668
 669 # "complex double" is new in C99, and "complex" is only a keyword if
 670 # <complex.h> is included
 671 AC_CHECK_TYPES(complex double,,,
 672 [#if HAVE_COMPLEX_H
 673 #include <complex.h>
 674 #endif])
 675
 676 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 677 # when testing.
 678 AC_CHECK_TYPE(socklen_t, ,
 679   [AC_DEFINE_UNQUOTED([socklen_t], int,
 680                       [Define to `int' if <sys/socket.h> does not define.])],
 681   [#if HAVE_SYS_TYPES_H
 682 #include <sys/types.h>
 683 #endif
 684 #include <sys/socket.h>
 685 ])
 686
 687 AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>])
 688
 689 GUILE_HEADER_LIBC_WITH_UNISTD
 690
 691 AC_TYPE_GETGROUPS
 692 AC_TYPE_SIGNAL
 693 AC_TYPE_MODE_T
 694
 695 # On mingw -lm is empty, so this test is unnecessary, but it's
 696 # harmless so we don't hard-code to suppress it.
 697 #
 698 AC_CHECK_LIB(m, cos)
 699
 700 AC_CHECK_FUNCS(gethostbyname)
 701 if test $ac_cv_func_gethostbyname = no; then
 702     AC_CHECK_LIB(nsl, gethostbyname)
 703 fi
 704
 705 AC_CHECK_FUNCS(connect)
 706 if test $ac_cv_func_connect = no; then
 707     AC_CHECK_LIB(socket, connect)
 708 fi
 709
 710 dnl
 711 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 712 dnl
 713 EXTRA_DEFS=""
 714 case $host in
 715   *-*-mingw*)
 716     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 717       [Define if you have the <winsock2.h> header file.])])
 718     AC_CHECK_LIB(ws2_32, main)
 719     AC_LIBOBJ([win32-uname])
 720     if test "$enable_shared" = yes ; then
 721       EXTRA_DEFS="-DSCM_IMPORT"
 722       AC_DEFINE([USE_DLL_IMPORT], 1,
 723         [Define if you need additional CPP macros on Win32 platforms.])
 724     fi
 725     ;;
 726 esac
 727 AC_SUBST(EXTRA_DEFS)
 728
 729 # Reasons for testing:
 730 #   crt_externs.h - Darwin specific
 731 #
 732 AC_CHECK_HEADERS([assert.h crt_externs.h])
 733
 734 # Reasons for testing:
 735 #   DINFINITY - OSF specific
 736 #   DQNAN - OSF specific
 737 #       (DINFINITY and DQNAN are actually global variables, not functions)
 738 #   chsize - an MS-DOS-ism, found in mingw
 739 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 740 #       for gcc to provide the "complex double" type but the system to not
 741 #       have functions like cexp and clog
 742 #   clog10 - not in mingw (though others like clog and csqrt are)
 743 #   fesetround - available in C99, but not older systems
 744 #   ftruncate - posix, but probably not older systems (current mingw
 745 #               has it as an inline for chsize)
 746 #   ioctl - not in mingw.
 747 #   gmtime_r - recent posix, not on old systems
 748 #   readdir_r - recent posix, not on old systems
 749 #   readdir64_r - not available on HP-UX 11.11
 750 #   stat64 - SuS largefile stuff, not on old systems
 751 #   sysconf - not on old systems
 752 #   truncate - not in mingw
 753 #   isblank - available as a GNU extension or in C99
 754 #   _NSGetEnviron - Darwin specific
 755 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 756 #   fork - unavailable on Windows
 757 #   utimensat - posix.1-2008
 758 #   sched_getaffinity, sched_setaffinity - GNU extensions (glibc)
 759 #   sendfile - non-POSIX, found in glibc
 760 #
 761 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid         \
 762   fesetround ftime ftruncate fchown fchmod getcwd geteuid getsid        \
 763   gettimeofday gmtime_r ioctl lstat mkdir mknod nice                    \
 764   readdir_r readdir64_r readlink rename rmdir setegid seteuid           \
 765   setlocale setpgid setsid sigaction siginterrupt stat64                \
 766   strptime symlink sync sysconf tcgetpgrp tcsetpgrp uname waitpid       \
 767   strdup system usleep atexit on_exit chown link fcntl ttyname getpwent \
 768   getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp  \
 769   index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron     \
 770   strcoll strcoll_l newlocale utimensat sched_getaffinity               \
 771   sched_setaffinity sendfile])
 772
 773 AM_CONDITIONAL([BUILD_ICE_9_POPEN],
 774   [test "x$enable_posix" = "xyes" && test "x$ac_cv_func_fork" = "xyes"])
 775
 776 # Reasons for testing:
 777 #   netdb.h - not in mingw
 778 #   sys/param.h - not in mingw
 779 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 780 #       check this specifically, we need it for the timespec test below.
 781 #   pthread_np.h - available on FreeBSD
 782 #   sethostname - the function itself check because it's not in mingw,
 783 #       the DECL is checked because Solaris 10 doens't have in any header
 784 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 785 #       declaration isn't anywhere.
 786 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 787 #       only with `_XOPEN_SOURCE' or some such.
 788 #
 789 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h pthread_np.h sys/param.h sys/resource.h sys/file.h sys/mman.h])
 790 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 791 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 792
 793 # crypt() may or may not be available, for instance in some countries there
 794 # are restrictions on cryptography.
 795 #
 796 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 797 # -lcrypt library (eg. Debian GNU/Linux).
 798 #
 799 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 800 # be careful to avoid -lcrypt in this case, since libtool will see there's
 801 # only a static libcrypt and decide to build only a static libguile.
 802 #
 803 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 804 # libraries already in that list.
 805 #
 806 AC_SEARCH_LIBS(crypt, crypt,
 807   [AC_DEFINE([HAVE_CRYPT],1,
 808              [Define to 1 if you have the `crypt' function.])])
 809
 810 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 811 # work; in the reported cases so far, 1.0fi works well instead.  According
 812 # to the C99 spec, the complex.h header must provide a working definition
 813 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 814 # is a workaround for the failure of some systems to conform to C99.
 815 if test "$ac_cv_type_complex_double" = yes; then
 816   AC_MSG_CHECKING([for i])
 817   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 818 #if HAVE_COMPLEX_H
 819 #include <complex.h>
 820 #endif
 821 complex double z;
 822 ]], [[
 823 z = _Complex_I;
 824 ]])],
 825     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 826      AC_MSG_RESULT([_Complex_I])],
 827     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 828 #if HAVE_COMPLEX_H
 829 #include <complex.h>
 830 #endif
 831 complex double z;
 832 ]],[[
 833 z = 1.0fi;
 834 ]])],
 835   [AC_DEFINE([GUILE_I],1.0fi)
 836    AC_MSG_RESULT([1.0fi])],
 837   [ac_cv_type_complex_double=no
 838    AC_MSG_RESULT([not available])])])
 839 fi
 840
 841 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 842 # csqrt(-i) returned a negative real part, when it should be positive
 843 # for the principal root.
 844 #
 845 if test "$ac_cv_type_complex_double" = yes; then
 846
 847   AC_CACHE_CHECK([whether csqrt is usable],
 848     guile_cv_use_csqrt,
 849     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 850 #include <complex.h>
 851 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 852    constant, we want to test libc. */
 853 volatile complex double z = - _Complex_I;
 854 int
 855 main (void)
 856 {
 857   z = csqrt (z);
 858   if (creal (z) > 0.0)
 859     return 0;  /* good */
 860   else
 861     return 1;  /* bad */
 862 }]])],
 863     [guile_cv_use_csqrt=yes],
 864     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 865     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 866   case $guile_cv_use_csqrt in
 867     yes*)
 868       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 869       ;;
 870   esac
 871 fi
 872
 873 AC_CACHE_SAVE
 874
 875 dnl GMP tests
 876 AC_LIB_HAVE_LINKFLAGS([gmp],
 877   [],
 878   [#include <gmp.h>],
 879   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 880
 881 if test "x$HAVE_LIBGMP" != "xyes"; then
 882   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 883 fi
 884
 885 dnl `mpz_inits' and `mpz_clears' appeared in GMP 5.0.0.
 886 save_CPPFLAGS="$CPPFLAGS"
 887 if test "x$LIBGMP_PREFIX" != "x"; then
 888    CPPFLAGS="-I$LIBGMP_PREFIX $CPPFLAGS"
 889 fi
 890 AC_CHECK_DECLS([mpz_inits], [], [], [[#include <gmp.h>]])
 891 CPPFLAGS="$save_CPPFLAGS"
 892
 893 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 894 if test "x$LTLIBUNISTRING" = "x"; then
 895   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 896 fi
 897
 898 GUILE_LIBUNISTRING_WITH_ICONV_SUPPORT
 899 if test "x$ac_cv_libunistring_with_iconv_support" != "xyes"; then
 900   AC_MSG_ERROR([No iconv support.  Please recompile libunistring with iconv enabled.])
 901 fi
 902
 903 dnl Libffi is needed to compile Guile's foreign function interface, but its
 904 dnl interface isn't exposed in Guile's API.
 905 PKG_CHECK_MODULES(LIBFFI, libffi)
 906 AC_SUBST(LIBFFI_CFLAGS)
 907 AC_SUBST(LIBFFI_LIBS)
 908
 909 dnl figure out approriate ffi type for size_t
 910 AC_CHECK_SIZEOF(size_t)
 911 AC_CHECK_SIZEOF(ssize_t)
 912 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 913 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 914 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 915                    [ffi type for size_t])
 916 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 917                    [ffi type for ssize_t])
 918
 919 dnl i18n tests
 920 #AC_CHECK_HEADERS([libintl.h])
 921 #AC_CHECK_FUNCS(gettext)
 922 #if test $ac_cv_func_gettext = no; then
 923 #   AC_CHECK_LIB(intl, gettext)
 924 #fi
 925 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 926 AM_GNU_GETTEXT([external], [need-ngettext])
 927
 928 ### Some systems don't declare some functions.  On such systems, we
 929 ### need to at least provide our own K&R-style declarations.
 930
 931 ### GUILE_FUNC_DECLARED(function, headerfile)
 932
 933 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 934 ### not there, #define MISSING_FUNCTION_DECL.
 935 AC_DEFUN([GUILE_FUNC_DECLARED], [
 936   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 937     AC_EGREP_HEADER($1, $2,
 938                     guile_cv_func_$1_declared=yes,
 939                     guile_cv_func_$1_declared=no))
 940   if test [x$guile_cv_func_]$1[_declared] = xno; then
 941     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 942       [Define if the operating system supplies $1 without declaring it.])
 943   fi
 944 ])
 945
 946 GUILE_FUNC_DECLARED(sleep, unistd.h)
 947 GUILE_FUNC_DECLARED(usleep, unistd.h)
 948
 949 AC_CHECK_DECLS([getlogin, alarm])
 950
 951 AC_CHECK_DECLS([strptime],,,
 952 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 953 #include <time.h>])
 954
 955 ### On some systems usleep has no return value.  If it does have one,
 956 ### we'd like to return it; otherwise, we'll fake it.
 957 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 958   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 959                    unistd.h,
 960                    [guile_cv_func_usleep_return_type=void],
 961                    [guile_cv_func_usleep_return_type=int])])
 962 case "$guile_cv_func_usleep_return_type" in
 963   "void" )
 964     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 965       [Define if the system headers declare usleep to return void.])
 966   ;;
 967 esac
 968
 969 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 970 if test -n "$have_sys_un_h" ; then
 971   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 972     [Define if the system supports Unix-domain (file-domain) sockets.])
 973 fi
 974
 975 AC_CHECK_FUNCS(getrlimit setrlimit)
 976
 977 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 978
 979 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 980                setnetent    getnetent    endnetent    dnl
 981                setprotoent  getprotoent  endprotoent  dnl
 982                setservent   getservent   endservent   dnl
 983                getnetbyaddr getnetbyname dnl
 984                inet_lnaof inet_makeaddr inet_netof hstrerror)
 985
 986 AC_CHECK_MEMBERS([struct sockaddr_in.sin_len],,,
 987 [#ifdef HAVE_SYS_TYPES_H
 988 #include <sys/types.h>
 989 #endif
 990 #include <netinet/in.h>])
 991
 992 AC_MSG_CHECKING(for __libc_stack_end)
 993 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 994 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 995 extern char *__libc_stack_end;]],
 996    [[printf("%p", (char*) __libc_stack_end);]])],
 997    [guile_cv_have_libc_stack_end=yes],
 998    [guile_cv_have_libc_stack_end=no])])
 999 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
1000
1001 if test $guile_cv_have_libc_stack_end = yes; then
1002   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
1003            [Define if you have the __libc_stack_end variable.])
1004 fi
1005
1006 dnl Some systems do not declare this.  Some systems do declare it, as a
1007 dnl macro.  With cygwin it may be in a DLL.
1008
1009 AC_MSG_CHECKING(whether netdb.h declares h_errno)
1010 AC_CACHE_VAL(guile_cv_have_h_errno,
1011   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1012                                       [[int a = h_errno;]])],
1013   [guile_cv_have_h_errno=yes],
1014   [guile_cv_have_h_errno=no])])
1015 AC_MSG_RESULT($guile_cv_have_h_errno)
1016 if test $guile_cv_have_h_errno = yes; then
1017   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
1018 fi
1019
1020 AC_MSG_CHECKING(whether uint32_t is defined)
1021 AC_CACHE_VAL(guile_cv_have_uint32_t,
1022   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1023                    #if HAVE_STDINT_H
1024                    #include <stdint.h>
1025                    #endif
1026                    #ifndef HAVE_NETDB_H
1027                    #include <netdb.h>
1028                    #endif]],
1029                    [[uint32_t a;]])],
1030                    [guile_cv_have_uint32_t=yes],
1031                    [guile_cv_have_uint32_t=no])])
1032 AC_MSG_RESULT($guile_cv_have_uint32_t)
1033 if test $guile_cv_have_uint32_t = yes; then
1034   AC_DEFINE([HAVE_UINT32_T], 1,
1035     [Define if uint32_t typedef is defined when netdb.h is include.])
1036 fi
1037
1038 AC_MSG_CHECKING(for working IPv6 support)
1039 AC_CACHE_VAL(guile_cv_have_ipv6,
1040 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1041 #ifdef HAVE_SYS_TYPES_H
1042 #include <sys/types.h>
1043 #endif
1044 #include <netinet/in.h>
1045 #include <sys/socket.h>]],
1046 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1047 [guile_cv_have_ipv6=yes],
1048 [guile_cv_have_ipv6=no])])
1049 AC_MSG_RESULT($guile_cv_have_ipv6)
1050 if test $guile_cv_have_ipv6 = yes; then
1051   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1052 fi
1053
1054 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1055 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1056 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1057 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1058 #ifdef HAVE_SYS_TYPES_H
1059 #include <sys/types.h>
1060 #endif
1061 #include <netinet/in.h>]],
1062 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1063 [guile_cv_have_sin6_scope_id=yes],
1064 [guile_cv_have_sin6_scope_id=no])])
1065 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1066 if test $guile_cv_have_sin6_scope_id = yes; then
1067   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1068     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1069 fi
1070
1071 # struct sockaddr_in6 field sin_len is only present on BSD systems
1072 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1073 [#ifdef HAVE_SYS_TYPES_H
1074 #include <sys/types.h>
1075 #endif
1076 #include <netinet/in.h>])
1077
1078 AC_MSG_CHECKING(whether localtime caches TZ)
1079 AC_CACHE_VAL(guile_cv_localtime_cache,
1080 [if test x$ac_cv_func_tzset = xyes; then
1081 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1082 #if STDC_HEADERS
1083 # include <stdlib.h>
1084 #endif
1085 extern char **environ;
1086 unset_TZ ()
1087 {
1088   char **from, **to;
1089   for (to = from = environ; (*to = *from); from++)
1090     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1091       to++;
1092 }
1093 char TZ_GMT0[] = "TZ=GMT0";
1094 char TZ_PST8[] = "TZ=PST8";
1095 main()
1096 {
1097   time_t now = time ((time_t *) 0);
1098   int hour_GMT0, hour_unset;
1099   if (putenv (TZ_GMT0) != 0)
1100     exit (1);
1101   hour_GMT0 = localtime (&now)->tm_hour;
1102   unset_TZ ();
1103   hour_unset = localtime (&now)->tm_hour;
1104   if (putenv (TZ_PST8) != 0)
1105     exit (1);
1106   if (localtime (&now)->tm_hour == hour_GMT0)
1107     exit (1);
1108   unset_TZ ();
1109   if (localtime (&now)->tm_hour != hour_unset)
1110     exit (1);
1111   exit (0);
1112 }]])],
1113 [guile_cv_localtime_cache=no],
1114 [guile_cv_localtime_cache=yes],
1115 [# If we have tzset, assume the worst when cross-compiling.
1116 guile_cv_localtime_cache=yes])
1117 else
1118         # If we lack tzset, report that localtime does not cache TZ,
1119         # since we can't invalidate the cache if we don't have tzset.
1120         guile_cv_localtime_cache=no
1121 fi])dnl
1122 AC_MSG_RESULT($guile_cv_localtime_cache)
1123 if test $guile_cv_localtime_cache = yes; then
1124   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1125 fi
1126
1127 if test "$enable_regex" = yes; then
1128    AC_LIBOBJ([regex-posix])
1129    AC_DEFINE([ENABLE_REGEX], 1, [Define when regex support is enabled.])
1130 fi
1131
1132 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1133
1134 # Reasons for testing:
1135 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1136 #                                older systems
1137 #   sincos - GLIBC extension
1138 #
1139 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1140
1141 # C99 specifies isinf and isnan as macros.
1142 # HP-UX provides only macros, no functions.
1143 # glibc 2.3.2 provides both macros and functions.
1144 # IRIX 6.5 and Solaris 8 only provide functions.
1145 #
1146 # The following tests detect isinf and isnan either as functions or as
1147 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1148 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1149 #
1150 AC_MSG_CHECKING([for isinf])
1151 AC_LINK_IFELSE([AC_LANG_SOURCE(
1152 [[#include <math.h>
1153 volatile double x = 0.0;
1154 int main () { return (isinf(x) != 0); }]])],
1155   [AC_MSG_RESULT([yes])
1156    AC_DEFINE([HAVE_ISINF], 1,
1157              [Define to 1 if you have the `isinf' macro or function.])],
1158   [AC_MSG_RESULT([no])])
1159 AC_MSG_CHECKING([for isnan])
1160 AC_LINK_IFELSE([AC_LANG_SOURCE([[
1161 #include <math.h>
1162 volatile double x = 0.0;
1163 int main () { return (isnan(x) != 0); }]])],
1164   [AC_MSG_RESULT([yes])
1165    AC_DEFINE([HAVE_ISNAN], 1,
1166              [Define to 1 if you have the `isnan' macro or function.])],
1167   [AC_MSG_RESULT([no])])
1168
1169 # Reasons for checking:
1170 #
1171 #     st_rdev
1172 #     st_blksize
1173 #     st_blocks   not in mingw
1174 #     tm_gmtoff   BSD+GNU, not in C99
1175 #
1176 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1177 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1178 #
1179 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1180                  [#define _GNU_SOURCE
1181 AC_INCLUDES_DEFAULT
1182 ])
1183
1184 AC_STRUCT_TIMEZONE
1185 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1186 [#include <time.h>
1187 #ifdef TIME_WITH_SYS_TIME
1188 # include <sys/time.h>
1189 # include <time.h>
1190 #else
1191 # if HAVE_SYS_TIME_H
1192 #  include <sys/time.h>
1193 # else
1194 #  include <time.h>
1195 # endif
1196 #endif
1197 ])
1198 GUILE_STRUCT_UTIMBUF
1199
1200
1201 #--------------------------------------------------------------------
1202 #
1203 # What values do the iconv error handlers have?
1204 #
1205 # The only place that we need iconv in our public interfaces is for
1206 # the error handlers, which are just ints.  So we weaken our
1207 # dependency by looking up those values at configure-time.
1208 #--------------------------------------------------------------------
1209 GUILE_UNISTRING_ICONVEH_VALUES
1210
1211 #--------------------------------------------------------------------
1212 #
1213 # Which way does the stack grow?
1214 #
1215 # Following code comes from Autoconf 2.69's internal _AC_LIBOBJ_ALLOCA
1216 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1217 # very similar code, so in future we could look at using that.
1218 #
1219 # An important detail is that the code involves find_stack_direction
1220 # calling _itself_ - which means that find_stack_direction (or at
1221 # least the second find_stack_direction() call) cannot be inlined.
1222 # If the code could be inlined, that might cause the test to give
1223 # an incorrect answer.
1224 #--------------------------------------------------------------------
1225
1226 SCM_I_GSC_STACK_GROWS_UP=0
1227 AC_RUN_IFELSE([AC_LANG_SOURCE(
1228 [AC_INCLUDES_DEFAULT
1229 int
1230 find_stack_direction (int *addr, int depth)
1231 {
1232   int dir, dummy = 0;
1233   if (! addr)
1234     addr = &dummy;
1235   *addr = addr < &dummy ? 1 : addr == &dummy ? 0 : -1;
1236   dir = depth ? find_stack_direction (addr, depth - 1) : 0;
1237   return dir + dummy;
1238 }
1239
1240 int
1241 main (int argc, char **argv)
1242 {
1243   return find_stack_direction (0, argc + !argv + 20) < 0;
1244 }])],
1245                [SCM_I_GSC_STACK_GROWS_UP=1],
1246                [],
1247                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1248
1249 #--------------------------------------------------------------------
1250 #
1251 # Boehm's GC library
1252 #
1253 #--------------------------------------------------------------------
1254 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1255
1256 save_LIBS="$LIBS"
1257 LIBS="$BDW_GC_LIBS $LIBS"
1258 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1259
1260 AC_CHECK_FUNCS([GC_do_blocking GC_call_with_gc_active GC_pthread_exit   \
1261   GC_pthread_cancel GC_allow_register_threads GC_pthread_sigmask        \
1262   GC_set_start_callback GC_get_heap_usage_safe                          \
1263   GC_get_free_space_divisor GC_gcollect_and_unmap GC_get_unmapped_bytes \
1264   GC_set_finalizer_notifier GC_set_finalize_on_demand                   \
1265   GC_set_all_interior_pointers GC_get_gc_no GC_set_java_finalization])
1266
1267 # Though the `GC_do_blocking ()' symbol is present in GC 7.1, it is not
1268 # declared, and has a different type (returning void instead of
1269 # void*).
1270 AC_CHECK_DECL([GC_do_blocking],
1271   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1272     [Define this if the `GC_do_blocking ()' function is declared])],
1273   [],
1274   [#include <gc/gc.h>])
1275
1276 # `GC_fn_type' is not available in GC 7.1 and earlier.
1277 AC_CHECK_TYPE([GC_fn_type],
1278   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1279     [Define this if the `GC_fn_type' type is available.])],
1280   [],
1281   [#include <gc/gc.h>])
1282
1283 # `GC_stack_base' is not available in GC 7.1 and earlier.
1284 AC_CHECK_TYPE([struct GC_stack_base],
1285   [AC_DEFINE([HAVE_GC_STACK_BASE], [1],
1286     [Define this if the `GC_stack_base' type is available.])],
1287   [],
1288   [#include <gc/gc.h>])
1289
1290 LIBS="$save_LIBS"
1291
1292
1293 AC_CHECK_SIZEOF(float)
1294 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1295     AC_DEFINE([SCM_SINGLES], 1,
1296               [Define this if floats are the same size as longs.])
1297 fi
1298
1299 AC_MSG_CHECKING(for struct linger)
1300 AC_CACHE_VAL(scm_cv_struct_linger,
1301         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1302 #include <sys/types.h>
1303 #include <sys/socket.h>]],
1304                           [[struct linger lgr;  lgr.l_linger = 100]])],
1305                           [scm_cv_struct_linger="yes"],
1306                           [scm_cv_struct_linger="no"]))
1307 AC_MSG_RESULT($scm_cv_struct_linger)
1308 if test $scm_cv_struct_linger = yes; then
1309         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1310           [Define this if your system defines struct linger, for use with the
1311            getsockopt and setsockopt system calls.])
1312 fi
1313
1314
1315 dnl Check for `struct timespec', for the sake of `gen-scmconfig'.  When
1316 dnl building Guile, we always have it, thanks to Gnulib; but scmconfig.h
1317 dnl must tell whether the system has it.
1318 dnl
1319 dnl On MinGW, struct timespec is in <pthread.h>.
1320 AC_MSG_CHECKING(for struct timespec)
1321 AC_CACHE_VAL(scm_cv_struct_timespec,
1322         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1323 #include <time.h>
1324 #if HAVE_PTHREAD_H
1325 #include <pthread.h>
1326 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1327           [scm_cv_struct_timespec="yes"],
1328           [scm_cv_struct_timespec="no"]))
1329 AC_MSG_RESULT($scm_cv_struct_timespec)
1330 if test $scm_cv_struct_timespec = yes; then
1331   dnl Don't call it `HAVE_STRUCT_TIMESPEC' because pthread-win32's
1332   dnl <pthread.h> checks whether that macro is defined.
1333   AC_DEFINE([HAVE_SYSTEM_STRUCT_TIMESPEC], 1,
1334     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1335 fi
1336
1337 #--------------------------------------------------------------------
1338 #
1339 # Flags for thread support
1340 #
1341 #--------------------------------------------------------------------
1342
1343 SCM_I_GSC_USE_PTHREAD_THREADS=0
1344 SCM_I_GSC_USE_NULL_THREADS=0
1345 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1346 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1347
1348 ### What thread package has the user asked for?
1349 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1350             , with_threads=yes)
1351
1352 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1353 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1354
1355 case "$with_threads" in
1356   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1357
1358     build_pthread_support="yes"
1359
1360     ACX_PTHREAD([CC="$PTHREAD_CC"
1361        LIBS="$PTHREAD_LIBS $LIBS"
1362        SCM_I_GSC_USE_PTHREAD_THREADS=1
1363        with_threads="pthreads"],
1364       [with_threads="null"
1365        build_pthread_support="no"])
1366
1367     old_CFLAGS="$CFLAGS"
1368     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1369
1370     # Reasons for testing:
1371     #     pthread_getattr_np - "np" meaning "non portable" says it
1372     #         all; not present on MacOS X or Solaris 10
1373     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1374     #         all; specific to MacOS X
1375     #     pthread_attr_get_np - "np" meaning "non portable" says it
1376     #         all; specific to FreeBSD
1377     #     pthread_sigmask - not available on mingw
1378     #
1379     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_attr_get_np pthread_sigmask)
1380
1381     # On past versions of Solaris, believe 8 through 10 at least, you
1382     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1383     # This is contrary to POSIX:
1384     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1385     # Check here if this style is required.
1386     #
1387     # glibc (2.3.6 at least) works both with or without braces, so the
1388     # test checks whether it works without.
1389     #
1390
1391     if test "$GCC" = "yes"; then
1392       # Since GCC only issues a warning for missing braces, so we need
1393       # `-Werror' to catch it.
1394       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1395     fi
1396
1397     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1398       guile_cv_need_braces_on_pthread_once_init,
1399       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1400          pthread_once_t foo = PTHREAD_ONCE_INIT;]])],
1401         [guile_cv_need_braces_on_pthread_once_init=no],
1402         [guile_cv_need_braces_on_pthread_once_init=yes])])
1403     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1404       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1405     fi
1406
1407     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1408     # 6.5.30m with GCC 3.3.
1409     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1410       guile_cv_need_braces_on_pthread_mutex_initializer,
1411       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
1412          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;]])],
1413         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1414         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1415     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1416       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1417     fi
1418
1419     CFLAGS="$old_CFLAGS"
1420
1421     # On Solaris, sched_yield lives in -lrt.
1422     AC_SEARCH_LIBS(sched_yield, rt)
1423
1424   ;;
1425 esac
1426
1427 case "$with_threads" in
1428   "pthreads")
1429   ;;
1430   "no" | "null")
1431     SCM_I_GSC_USE_NULL_THREADS=1
1432     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1433     with_threads="null-threads"
1434   ;;
1435   * )
1436     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1437   ;;
1438 esac
1439
1440 AC_MSG_CHECKING(what kind of threads to support)
1441 AC_MSG_RESULT($with_threads)
1442
1443 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1444   [test "x$build_pthread_support" = "xyes"])
1445
1446
1447 if test "$with_threads" = pthreads; then
1448
1449 dnl Normally Gnulib's 'threadlib' module would define this macro, but
1450 dnl since we don't use it, define it by ourselves.
1451 AC_DEFINE([USE_POSIX_THREADS], [1],
1452   [Define to let Gnulib modules know that we use POSIX threads.])
1453
1454 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1455 old_CFLAGS="$CFLAGS"
1456 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1457 if test "$cross_compiling" = "no"; then
1458   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1459   #if HAVE_PTHREAD_ATTR_GETSTACK
1460   #include <pthread.h>
1461
1462   int main ()
1463   {
1464     pthread_attr_t attr;
1465     void *start, *end;
1466     size_t size;
1467
1468     pthread_getattr_np (pthread_self (), &attr);
1469     pthread_attr_getstack (&attr, &start, &size);
1470     end = (char *)start + size;
1471
1472     if ((void *)&attr < start || (void *)&attr >= end)
1473       return 1;
1474     else
1475       return 0;
1476   }
1477   #else
1478   int main ()
1479   {
1480     return 1;
1481   }
1482   #endif
1483   ]])],
1484   [works=yes
1485    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1486   [works=no],
1487   [])
1488 else
1489   works="assuming it doesn't"
1490 fi
1491 CFLAGS="$old_CFLAGS"
1492 AC_MSG_RESULT($works)
1493
1494 GUILE_THREAD_LOCAL_STORAGE
1495
1496 fi # with_threads=pthreads
1497
1498
1499 ## Cross building
1500 if test "$cross_compiling" = "yes"; then
1501   AC_MSG_CHECKING(cc for build)
1502   ## /usr/bin/cc still uses wrong assembler
1503   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1504   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1505 else
1506   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1507 fi
1508
1509 ## AC_MSG_CHECKING("if we are cross compiling")
1510 ## AC_MSG_RESULT($cross_compiling)
1511 if test "$cross_compiling" = "yes"; then
1512    AC_MSG_RESULT($CC_FOR_BUILD)
1513 fi
1514
1515 ## No need as yet to be more elaborate
1516 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1517
1518 AC_SUBST(cross_compiling)
1519 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1520 AC_SUBST(CCLD_FOR_BUILD)
1521
1522 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1523 ## --HOST is the platform that PACKAGE is compiled for.
1524 HOST_CC="$CC_FOR_BUILD"
1525 AC_SUBST(HOST_CC)
1526
1527 GUILE_CHECK_GUILE_FOR_BUILD
1528
1529 ## If we're using GCC, add flags to reduce strictness of undefined
1530 ## behavior, and ask for aggressive warnings.
1531 GCC_CFLAGS=""
1532 case "$GCC" in
1533   yes )
1534     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1535     ## much stuff with generic function pointers for that to really be
1536     ## less than exasperating.
1537     ## -Wundef was removed because Gnulib prevented it (see
1538     ## <http://thread.gmane.org/gmane.lisp.guile.bugs/5329>.)
1539
1540     ## Build with `-fno-strict-aliasing' and `-fwrapv' to prevent
1541     ## miscompilation on some platforms.  See
1542     ## <http://lists.gnu.org/archive/html/guile-devel/2012-01/msg00487.html>.
1543
1544     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1545       -Wdeclaration-after-statement -Wpointer-arith \
1546       -Wswitch-enum -fno-strict-aliasing -fwrapv"
1547     # Do this here so we don't screw up any of the tests above that might
1548     # not be "warning free"
1549     if test "${GUILE_ERROR_ON_WARNING}" = yes
1550     then
1551         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1552         enable_compile_warnings=no
1553     fi
1554
1555     for flag in $POTENTIAL_GCC_CFLAGS
1556     do
1557         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1558     done
1559     ;;
1560 esac
1561
1562 AC_SUBST(GCC_CFLAGS)
1563
1564 # Check for GNU ld's "-z relro".
1565 GUILE_GNU_LD_RELRO
1566
1567
1568 LIBLOBJS=""
1569 for file in $LIBOBJS; do
1570   file=`echo "$file" | sed 's,\.[[^.]]*$,.lo,'`
1571   LIBLOBJS="$LIBLOBJS libguile_${GUILE_EFFECTIVE_VERSION}_la-$file"
1572 done
1573
1574 ## We also need to create corresponding .doc and .x files
1575 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1576 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1577
1578 # GNU Readline bindings.
1579 GUILE_READLINE
1580
1581 AC_SUBST(GUILE_MAJOR_VERSION)
1582 AC_SUBST(GUILE_MINOR_VERSION)
1583 AC_SUBST(GUILE_MICRO_VERSION)
1584 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1585 AC_SUBST(GUILE_VERSION)
1586
1587 #######################################################################
1588 # library versioning
1589
1590 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1591 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1592 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1593 AC_SUBST(LIBGUILE_INTERFACE)
1594
1595 AC_SUBST(LIBGUILE_I18N_MAJOR)
1596 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1597 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1598 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1599 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1600
1601
1602 #######################################################################
1603
1604 dnl Tell guile-config what flags guile users should compile and link
1605 dnl with, keeping only `-I' flags from $CPPFLAGS.
1606 GUILE_CFLAGS=""
1607 next_is_includedir=false
1608 for flag in $CPPFLAGS
1609 do
1610   if $next_is_includedir; then
1611     GUILE_CFLAGS="$GUILE_CFLAGS -I $flag"
1612     next_is_includedir=false
1613   else
1614     case "$flag" in
1615       -I)  next_is_includedir=true;;
1616       -I*) GUILE_CFLAGS="$GUILE_CFLAGS $flag";;
1617       *)   ;;
1618     esac
1619   fi
1620 done
1621
1622 GUILE_CFLAGS="$GUILE_CFLAGS $PTHREAD_CFLAGS"
1623 GUILE_LIBS="$LDFLAGS $LIBS"
1624
1625 AC_SUBST(GUILE_LIBS)
1626 AC_SUBST(GUILE_CFLAGS)
1627
1628 AC_SUBST(AWK)
1629 AC_SUBST(LIBLOBJS)
1630 AC_SUBST(EXTRA_DOT_DOC_FILES)
1631 AC_SUBST(EXTRA_DOT_X_FILES)
1632
1633 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1634 top_builddir_absolute=`pwd`
1635 AC_SUBST(top_builddir_absolute)
1636 top_srcdir_absolute=`(cd $srcdir && pwd)`
1637 AC_SUBST(top_srcdir_absolute)
1638
1639 dnl Add -I flag so that lib/glthread/lock.h finds <libguile/threads.h>.
1640 CPPFLAGS="-I$top_srcdir_absolute $CPPFLAGS"
1641
1642 dnl `sitedir' goes into libpath.h and the pkg-config file.
1643 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1644 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1645 AC_SUBST([sitedir])
1646
1647 # Additional SCM_I_GSC definitions are above.
1648 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1649 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1650 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1651 AC_SUBST([SCM_I_GSC_C_INLINE])
1652 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1653
1654 AC_CONFIG_FILES([
1655   Makefile
1656   am/Makefile
1657   lib/Makefile
1658   benchmark-suite/Makefile
1659   gc-benchmarks/Makefile
1660   doc/Makefile
1661   doc/r5rs/Makefile
1662   doc/ref/Makefile
1663   emacs/Makefile
1664   examples/Makefile
1665   libguile/Makefile
1666   libguile/version.h
1667   guile-readline/Makefile
1668   test-suite/Makefile
1669   test-suite/standalone/Makefile
1670   test-suite/vm/Makefile
1671   meta/Makefile
1672   module/Makefile
1673 ])
1674
1675 AC_CONFIG_FILES([meta/guile-2.0.pc])
1676 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1677
1678 GUILE_CONFIG_SCRIPT([check-guile])
1679 GUILE_CONFIG_SCRIPT([benchmark-guile])
1680 GUILE_CONFIG_SCRIPT([meta/guile])
1681 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1682 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1683 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1684 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1685 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1686 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1687
1688 AC_OUTPUT
1689
1690 dnl Local Variables:
1691 dnl comment-start: "dnl "
1692 dnl comment-end: ""
1693 dnl comment-start-skip: "\\bdnl\\b\\s *"
1694 dnl End: