configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it under
  12 the terms of the GNU Lesser General Public License as published by the
  13 Free Software Foundation; either version 3, or (at your option) any
  14 later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but WITHOUT
  17 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  19 License for more details.
  20
  21 You should have received a copy of the GNU Lesser General Public
  22 License along with GUILE; see the file COPYING.LESSER.  If not, write
  23 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  24 Floor, Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.61)
  29
  30 dnl  `patsubst' here deletes the newline which "echo" prints.  We can't use
  31 dnl  "echo -n" since -n is not portable (see autoconf manual "Limitations of
  32 dnl  Builtins"), in particular on solaris it results in a literal "-n" in
  33 dnl  the output.
  34 dnl
  35 AC_INIT([GNU Guile],
  36         patsubst(m4_esyscmd(. ./GUILE-VERSION && echo ${GUILE_VERSION}),[
  37 ]),
  38         [bug-guile@gnu.org])
  39 AC_CONFIG_AUX_DIR([build-aux])
  40 AC_CONFIG_MACRO_DIR([m4])
  41 AC_CONFIG_SRCDIR(GUILE-VERSION)
  42
  43 AM_INIT_AUTOMAKE([gnu no-define check-news -Wall -Wno-override])
  44
  45 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  46 AC_CONFIG_SRCDIR([GUILE-VERSION])
  47
  48 . $srcdir/GUILE-VERSION
  49
  50 AC_CONFIG_HEADERS([config.h])
  51 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  52
  53 #--------------------------------------------------------------------
  54
  55 AC_LANG([C])
  56
  57 dnl Some more checks for Win32
  58 AC_CANONICAL_HOST
  59
  60 AC_LIBTOOL_WIN32_DLL
  61
  62 AC_PROG_INSTALL
  63 AC_PROG_CC
  64 gl_EARLY
  65 AC_PROG_CPP
  66 AC_PROG_SED
  67 AC_PROG_AWK
  68
  69 dnl Gnulib.
  70 gl_INIT
  71
  72 AC_PROG_CC_C89
  73
  74 # for per-target cflags in the libguile subdir
  75 AM_PROG_CC_C_O
  76
  77 AC_LIBTOOL_DLOPEN
  78 AC_PROG_LIBTOOL
  79 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  80   [AC_MSG_ERROR([libltdl not found.  See README.])])
  81 AC_CHECK_HEADER([ltdl.h], [],
  82   [AC_MSG_ERROR([<ltdl.h> not found.  See README.])])
  83
  84 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  85 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  86
  87 AM_PATH_LISPDIR
  88
  89 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
  90   [Define to the host's GNU triplet.])
  91
  92 #--------------------------------------------------------------------
  93 #
  94 # User options (after above tests that may set default CFLAGS etc.)
  95 #
  96 #--------------------------------------------------------------------
  97
  98 GUILE_ERROR_ON_WARNING="no"
  99
 100 AC_ARG_ENABLE(error-on-warning,
 101   [  --enable-error-on-warning    treat compile warnings as errors],
 102   [case "${enableval}" in
 103      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 104      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 105      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 106    esac])
 107
 108 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
 109 AC_ARG_ENABLE(debug-freelist,
 110   [  --enable-debug-freelist include garbage collector freelist debugging code],
 111   if test "$enable_debug_freelist" = y \
 112      || test "$enable_debug_freelist" = yes; then
 113     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 114   fi)
 115
 116 AC_ARG_ENABLE(debug-malloc,
 117   [  --enable-debug-malloc   include malloc debugging code],
 118   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 119     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 120       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 121   fi)
 122
 123 SCM_I_GSC_GUILE_DEBUG=0
 124 AC_ARG_ENABLE(guile-debug,
 125   [AS_HELP_STRING([--enable-guile-debug],
 126                   [include internal debugging functions])],
 127   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 128     SCM_I_GSC_GUILE_DEBUG=1
 129   fi)
 130
 131 AC_ARG_ENABLE(posix,
 132   [  --disable-posix         omit posix interfaces],,
 133   enable_posix=yes)
 134
 135 AC_ARG_ENABLE(networking,
 136   [  --disable-networking    omit networking interfaces],,
 137   enable_networking=yes)
 138
 139 AC_ARG_ENABLE(regex,
 140   [  --disable-regex         omit regular expression interfaces],,
 141   enable_regex=yes)
 142
 143 AC_ARG_ENABLE([discouraged],
 144   AS_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 145
 146 if test "$enable_discouraged" = no; then
 147   SCM_I_GSC_ENABLE_DISCOURAGED=0
 148 else
 149   SCM_I_GSC_ENABLE_DISCOURAGED=1
 150 fi
 151
 152 AC_ARG_ENABLE([deprecated],
 153   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 154
 155 if test "$enable_deprecated" = no; then
 156   SCM_I_GSC_ENABLE_DEPRECATED=0
 157   warn_default=no
 158 else
 159   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 160     warn_default=summary
 161   elif test "$enable_deprecated" = shutup; then
 162     warn_default=no
 163   else
 164     warn_default=$enable_deprecated
 165   fi
 166   SCM_I_GSC_ENABLE_DEPRECATED=1
 167 fi
 168 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 169 [Define this to control the default warning level for deprecated features.])
 170
 171 AC_ARG_ENABLE(elisp,
 172   [  --disable-elisp         omit Emacs Lisp support],,
 173   enable_elisp=yes)
 174
 175 dnl  Added the following configure option in January 2008 following
 176 dnl  investigation of problems with "64" system and library calls on
 177 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 178 dnl  system has stat64, it will have all the other 64 APIs too; but on
 179 dnl  Darwin, stat64 is there but other APIs are missing.
 180 dnl
 181 dnl  It also appears, from the Darwin docs, that most system call APIs
 182 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 183 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 184 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 185 dnl
 186 dnl  A similar problem has been reported for HP-UX:
 187 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 188 dnl
 189 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 190 dnl  better than no Guile at all, we provide this option to suppress
 191 dnl  trying to use "64" calls.
 192 dnl
 193 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 194 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 195 dnl  missing out on that.  If so, someone can work on that in the future.
 196 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 197 dnl  wasn't building before.
 198 AC_MSG_CHECKING([whether to use system and library "64" calls])
 199 AC_ARG_WITH([64-calls],
 200   AS_HELP_STRING([--without-64-calls],
 201                  [don't attempt to use system and library calls with "64" in their names]),
 202   [use_64_calls=$withval],
 203   [use_64_calls=yes
 204    case $host in
 205      *-apple-darwin* )
 206        use_64_calls=no
 207        ;;
 208      powerpc-ibm-aix* )
 209        use_64_calls=no
 210        ;;
 211    esac])
 212 AC_MSG_RESULT($use_64_calls)
 213 case "$use_64_calls" in
 214   y* )
 215     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 216       [Define to 1 in order to try to use "64" versions of system and library calls.])
 217     ;;
 218 esac
 219
 220 #--------------------------------------------------------------------
 221
 222 dnl Check for dynamic linking
 223
 224 use_modules=yes
 225 AC_ARG_WITH(modules,
 226 [  --with-modules[=FILES]  Add support for dynamic modules],
 227 use_modules="$withval")
 228 test -z "$use_modules" && use_modules=yes
 229 DLPREOPEN=
 230 if test "$use_modules" != no; then
 231   if test "$use_modules" = yes; then
 232     DLPREOPEN="-dlpreopen force"
 233   else
 234     DLPREOPEN="-export-dynamic"
 235     for module in $use_modules; do
 236       DLPREOPEN="$DLPREOPEN -dlopen $module"
 237     done
 238   fi
 239 fi
 240
 241 dnl files which are destined for separate modules.
 242
 243 if test "$use_modules" != no; then
 244    AC_LIBOBJ([dynl])
 245 fi
 246
 247 if test "$enable_posix" = yes; then
 248    AC_LIBOBJ([filesys])
 249    AC_LIBOBJ([posix])
 250    AC_DEFINE([HAVE_POSIX], 1,
 251      [Define this if you want support for POSIX system calls in Guile.])
 252 fi
 253
 254 if test "$enable_networking" = yes; then
 255    AC_LIBOBJ([net_db])
 256    AC_LIBOBJ([socket])
 257    AC_DEFINE([HAVE_NETWORKING], 1,
 258      [Define this if you want support for networking in Guile.])
 259 fi
 260
 261 if test "$enable_debug_malloc" = yes; then
 262    AC_LIBOBJ([debug-malloc])
 263 fi
 264
 265 if test "$enable_elisp" = yes; then
 266   SCM_I_GSC_ENABLE_ELISP=1
 267 else
 268   SCM_I_GSC_ENABLE_ELISP=0
 269 fi
 270 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 271
 272 AC_C_CONST
 273
 274 # "volatile" is used in a couple of tests below.
 275 AC_C_VOLATILE
 276
 277 AC_C_INLINE
 278 if test "$ac_cv_c_inline" != no; then
 279   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 280 else
 281   SCM_I_GSC_C_INLINE=NULL
 282 fi
 283 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 284
 285 AC_C_BIGENDIAN
 286
 287 AC_C_LABELS_AS_VALUES
 288
 289 AC_CHECK_SIZEOF(char)
 290 AC_CHECK_SIZEOF(unsigned char)
 291 AC_CHECK_SIZEOF(short)
 292 AC_CHECK_SIZEOF(unsigned short)
 293 AC_CHECK_SIZEOF(int)
 294 AC_CHECK_SIZEOF(unsigned int)
 295 AC_CHECK_SIZEOF(long)
 296 AC_CHECK_SIZEOF(unsigned long)
 297 AC_CHECK_SIZEOF(size_t)
 298 AC_CHECK_SIZEOF(long long)
 299 AC_CHECK_SIZEOF(unsigned long long)
 300 AC_CHECK_SIZEOF(__int64)
 301 AC_CHECK_SIZEOF(unsigned __int64)
 302 AC_CHECK_SIZEOF(void *)
 303 AC_CHECK_SIZEOF(intptr_t)
 304 AC_CHECK_SIZEOF(uintptr_t)
 305 AC_CHECK_SIZEOF(ptrdiff_t)
 306 AC_CHECK_SIZEOF(size_t)
 307 AC_CHECK_SIZEOF(off_t)
 308
 309 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 310   AC_MSG_ERROR(sizes of long and void* are not identical)
 311 fi
 312
 313 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 314   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 315 else
 316   SCM_I_GSC_T_PTRDIFF='"long"'
 317 fi
 318 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 319
 320 AC_CHECK_HEADERS([stdint.h])
 321 AC_CHECK_HEADERS([inttypes.h])
 322
 323 AC_CHECK_SIZEOF(intmax_t)
 324
 325 SCM_I_GSC_NEEDS_STDINT_H=0
 326 SCM_I_GSC_NEEDS_INTTYPES_H=0
 327
 328 ### intptr and uintptr (try not to use inttypes if we don't have to)
 329 if test "$ac_cv_header_inttypes_h" = yes; then
 330   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 331     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 332 #include <stdio.h>])
 333     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 334       SCM_I_GSC_NEEDS_INTTYPES_H=1
 335     fi
 336   fi
 337   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 338     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 339 #include <stdio.h>])
 340     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 341       SCM_I_GSC_NEEDS_INTTYPES_H=1
 342     fi
 343   fi
 344 fi
 345
 346 ### See what's provided by stdint.h
 347 if test "$ac_cv_header_stdint_h" = yes; then
 348    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 349    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 350    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 351    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 352    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 353    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 354    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 355    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 356    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 357    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 358    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 359    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 360 fi
 361
 362 # so we don't get confused by the cache (wish there was a better way
 363 # to check particular headers for the same type...)
 364
 365 unset ac_cv_type_int8_t
 366 unset ac_cv_type_uint8_t
 367 unset ac_cv_type_int16_t
 368 unset ac_cv_type_uint16_t
 369 unset ac_cv_type_int32_t
 370 unset ac_cv_type_uint32_t
 371 unset ac_cv_type_int64_t
 372 unset ac_cv_type_uint64_t
 373 unset ac_cv_type_intmax_t
 374 unset ac_cv_type_uintmax_t
 375
 376 ### See what's provided by inttypes.h
 377 if test "$ac_cv_header_inttypes_h" = yes; then
 378   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 379   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 380   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 381   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 382   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 383   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 384   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 385   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 386   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 387   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 388   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 389   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 390 fi
 391
 392 # Try hard to find definitions for some required scm_t_*int* types.
 393
 394 ### Required type scm_t_int8
 395 if test "$scm_stdint_has_int8"; then
 396   SCM_I_GSC_T_INT8='"int8_t"'
 397   SCM_I_GSC_NEEDS_STDINT_H=1
 398 elif test "$scm_inttypes_has_int8"; then
 399   SCM_I_GSC_T_INT8='"int8_t"'
 400   SCM_I_GSC_NEEDS_INTTYPES_H=1
 401 elif test "$ac_cv_sizeof_char" -eq 1; then
 402   SCM_I_GSC_T_INT8='"signed char"'
 403 else
 404   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 405 fi
 406 AC_SUBST([SCM_I_GSC_T_INT8])
 407
 408 ### Required type scm_t_uint8
 409 if test "$scm_stdint_has_uint8"; then
 410   SCM_I_GSC_T_UINT8='"uint8_t"'
 411   SCM_I_GSC_NEEDS_STDINT_H=1
 412 elif test "$scm_inttypes_has_uint8"; then
 413   SCM_I_GSC_T_UINT8='"uint8_t"'
 414   SCM_I_GSC_NEEDS_INTTYPES_H=1
 415 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 416   SCM_I_GSC_T_UINT8='"unsigned char"'
 417 else
 418   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 419 fi
 420 AC_SUBST([SCM_I_GSC_T_UINT8])
 421
 422 ### Required type scm_t_int16 (ANSI C says int or short might work)
 423 if test "$scm_stdint_has_int16"; then
 424   SCM_I_GSC_T_INT16='"int16_t"'
 425   SCM_I_GSC_NEEDS_STDINT_H=1
 426 elif test "$scm_inttypes_has_int16"; then
 427   SCM_I_GSC_T_INT16='"int16_t"'
 428   SCM_I_GSC_NEEDS_INTTYPES_H=1
 429 elif test "$ac_cv_sizeof_int" -eq 2; then
 430   SCM_I_GSC_T_INT16='"int"'
 431 elif test "$ac_cv_sizeof_short" -eq 2; then
 432   SCM_I_GSC_T_INT16='"short"'
 433 else
 434   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 435 fi
 436 AC_SUBST([SCM_I_GSC_T_INT16])
 437
 438 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 439 if test "$scm_stdint_has_uint16"; then
 440   SCM_I_GSC_T_UINT16='"uint16_t"'
 441   SCM_I_GSC_NEEDS_STDINT_H=1
 442 elif test "$scm_inttypes_has_uint16"; then
 443   SCM_I_GSC_T_UINT16='"uint16_t"'
 444   SCM_I_GSC_NEEDS_INTTYPES_H=1
 445 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 446   SCM_I_GSC_T_UINT16='"unsigned int"'
 447 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 448   SCM_I_GSC_T_UINT16='"unsigned short"'
 449 else
 450   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 451 fi
 452 AC_SUBST([SCM_I_GSC_T_UINT16])
 453
 454
 455 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 456 if test "$scm_stdint_has_int32"; then
 457   SCM_I_GSC_T_INT32='"int32_t"'
 458   SCM_I_GSC_NEEDS_STDINT_H=1
 459 elif test "$scm_inttypes_has_int32"; then
 460   SCM_I_GSC_T_INT32='"int32_t"'
 461   SCM_I_GSC_NEEDS_INTTYPES_H=1
 462 elif test "$ac_cv_sizeof_int" -eq 4; then
 463   SCM_I_GSC_T_INT32='"int"'
 464 elif test "$ac_cv_sizeof_long" -eq 4; then
 465   SCM_I_GSC_T_INT32='"long"'
 466 elif test "$ac_cv_sizeof_short" -eq 4; then
 467   SCM_I_GSC_T_INT32='"short"'
 468 else
 469   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 470 fi
 471 AC_SUBST([SCM_I_GSC_T_INT32])
 472
 473 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 474 if test "$scm_stdint_has_uint32"; then
 475   SCM_I_GSC_T_UINT32='"uint32_t"'
 476   SCM_I_GSC_NEEDS_STDINT_H=1
 477 elif test "$scm_inttypes_has_uint32"; then
 478   SCM_I_GSC_T_UINT32='"uint32_t"'
 479   SCM_I_GSC_NEEDS_INTTYPES_H=1
 480 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 481   SCM_I_GSC_T_UINT32='"unsigned int"'
 482 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 483   SCM_I_GSC_T_UINT32='"unsigned long"'
 484 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 485   SCM_I_GSC_T_UINT32='"unsigned short"'
 486 else
 487   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 488 fi
 489 AC_SUBST([SCM_I_GSC_T_UINT32])
 490
 491 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 492 ### Also try 'long long' and '__int64' if we have it.
 493 SCM_I_GSC_T_INT64=0
 494 if test "$scm_stdint_has_int64"; then
 495   SCM_I_GSC_T_INT64='"int64_t"'
 496   SCM_I_GSC_NEEDS_STDINT_H=1
 497 elif test "$scm_inttypes_has_int64"; then
 498   SCM_I_GSC_T_INT64='"int64_t"'
 499   SCM_I_GSC_NEEDS_INTTYPES_H=1
 500 elif test "$ac_cv_sizeof_int" -eq 8; then
 501   SCM_I_GSC_T_INT64='"int"'
 502 elif test "$ac_cv_sizeof_long" -eq 8; then
 503   SCM_I_GSC_T_INT64='"long"'
 504 elif test "$ac_cv_sizeof_short" -eq 8; then
 505   SCM_I_GSC_T_INT64='"short"'
 506 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 507   SCM_I_GSC_T_INT64='"long long"'
 508 elif test "$ac_cv_sizeof___int64" -eq 8; then
 509   SCM_I_GSC_T_INT64='"__int64"'
 510 else
 511   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 512 fi
 513 AC_SUBST([SCM_I_GSC_T_INT64])
 514
 515
 516 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 517 ### Also try 'long long' and '__int64' if we have it.
 518 SCM_I_GSC_T_UINT64=0
 519 if test "$scm_stdint_has_uint64"; then
 520   SCM_I_GSC_T_UINT64='"uint64_t"'
 521   SCM_I_GSC_NEEDS_STDINT_H=1
 522 elif test "$scm_inttypes_has_uint64"; then
 523   SCM_I_GSC_T_UINT64='"uint64_t"'
 524   SCM_I_GSC_NEEDS_INTTYPES_H=1
 525 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 526   SCM_I_GSC_T_UINT64='"unsigned int"'
 527 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 528   SCM_I_GSC_T_UINT64='"unsigned long"'
 529 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 530   SCM_I_GSC_T_UINT64='"unsigned short"'
 531 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 532   SCM_I_GSC_T_UINT64='"unsigned long long"'
 533 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 534   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 535 else
 536   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 537 fi
 538 AC_SUBST([SCM_I_GSC_T_UINT64])
 539
 540 ### Required type scm_t_intmax
 541 ###
 542 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 543 ### none of them is available, we use 'long'.
 544 ###
 545 SCM_I_GSC_T_INTMAX=0
 546 if test "$scm_stdint_has_intmax"; then
 547   SCM_I_GSC_T_INTMAX='"intmax_t"'
 548   SCM_I_GSC_NEEDS_STDINT_H=1
 549 elif test "$scm_inttypes_has_intmax"; then
 550   SCM_I_GSC_T_INTMAX='"intmax_t"'
 551   SCM_I_GSC_NEEDS_INTTYPES_H=1
 552 elif test "$ac_cv_sizeof___int64" -ne 0; then
 553   SCM_I_GSC_T_INTMAX='"__int64"'
 554 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 555   SCM_I_GSC_T_INTMAX='"long long"'
 556 else
 557   SCM_I_GSC_T_INTMAX='"long"'
 558 fi
 559 AC_SUBST([SCM_I_GSC_T_INTMAX])
 560
 561 ### Required type scm_t_uintmax
 562 ###
 563 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 564 ### this order.  When none of them is available, we use 'unsigned long'.
 565 ###
 566 SCM_I_GSC_T_UINTMAX=0
 567 if test "$scm_stdint_has_uintmax"; then
 568   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 569   SCM_I_GSC_NEEDS_STDINT_H=1
 570 elif test "$scm_inttypes_has_uintmax"; then
 571   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 572   SCM_I_GSC_NEEDS_INTTYPES_H=1
 573 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 574   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 575 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 576   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 577 else
 578   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 579 fi
 580 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 581
 582 ### Required type scm_t_intptr
 583 ###
 584 SCM_I_GSC_T_INTPTR=0
 585 if test "$scm_stdint_has_intptr"; then
 586   SCM_I_GSC_T_INTPTR='"intptr_t"'
 587   SCM_I_GSC_NEEDS_STDINT_H=1
 588 elif test "$scm_inttypes_has_intptr"; then
 589   SCM_I_GSC_T_INTPTR='"intptr_t"'
 590   SCM_I_GSC_NEEDS_INTTYPES_H=1
 591 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 592   SCM_I_GSC_T_INTPTR='"int"'
 593 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 594   SCM_I_GSC_T_INTPTR='"long"'
 595 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 596   SCM_I_GSC_T_INTPTR='"long long"'
 597 else
 598   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 599 fi
 600 AC_SUBST([SCM_I_GSC_T_INTPTR])
 601
 602 ### Required type scm_t_uintptr
 603 ###
 604 SCM_I_GSC_T_UINTPTR=0
 605 if test "$scm_stdint_has_uintptr"; then
 606   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 607   SCM_I_GSC_NEEDS_STDINT_H=1
 608 elif test "$scm_inttypes_has_uintptr"; then
 609   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 610   SCM_I_GSC_NEEDS_INTTYPES_H=1
 611 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 612   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 613 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 614   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 615 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 616   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 617 else
 618   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 619 fi
 620 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 621
 622
 623 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 624 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 625
 626 AC_HEADER_STDC
 627 AC_HEADER_TIME
 628 AC_HEADER_SYS_WAIT
 629 AC_HEADER_DIRENT
 630
 631 # Reason for checking:
 632 #
 633 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 634 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 635 #
 636 AC_CHECK_MEMBER([struct dirent64.d_name],
 637   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 638   [ #ifndef _LARGEFILE64_SOURCE
 639     # define _LARGEFILE64_SOURCE
 640     #endif
 641
 642     /* Per Autoconf manual.  */
 643     #include <sys/types.h>
 644     #ifdef HAVE_DIRENT_H
 645     # include <dirent.h>
 646     #else
 647     # define dirent direct
 648     # ifdef HAVE_SYS_NDIR_H
 649     #  include <sys/ndir.h>
 650     # endif
 651     # ifdef HAVE_SYS_DIR_H
 652     #  include <sys/dir.h>
 653     # endif
 654     # ifdef HAVE_NDIR_H
 655     #  include <ndir.h>
 656     # endif
 657     #endif ])
 658 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 659
 660 # Reasons for testing:
 661 #   complex.h - new in C99
 662 #   fenv.h - available in C99, but not older systems
 663 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 664 #     this file instead of <fenv.h>
 665 #   process.h - mingw specific
 666 #   langinfo.h, nl_types.h - SuS v2
 667 #
 668 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 669 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 670 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 671 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 672 direct.h langinfo.h nl_types.h machine/fpu.h])
 673
 674 # "complex double" is new in C99, and "complex" is only a keyword if
 675 # <complex.h> is included
 676 AC_CHECK_TYPES(complex double,,,
 677 [#if HAVE_COMPLEX_H
 678 #include <complex.h>
 679 #endif])
 680
 681 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 682 # when testing.
 683 AC_CHECK_TYPE(socklen_t, ,
 684   [AC_DEFINE_UNQUOTED([socklen_t], int,
 685                       [Define to `int' if <sys/socket.h> does not define.])],
 686   [#if HAVE_SYS_TYPES_H
 687 #include <sys/types.h>
 688 #endif
 689 #include <sys/socket.h>
 690 ])
 691 AC_CHECK_TYPE(struct ip_mreq)
 692
 693 GUILE_HEADER_LIBC_WITH_UNISTD
 694
 695 AC_TYPE_GETGROUPS
 696 AC_TYPE_SIGNAL
 697 AC_TYPE_MODE_T
 698
 699 # On mingw -lm is empty, so this test is unnecessary, but it's
 700 # harmless so we don't hard-code to suppress it.
 701 #
 702 AC_CHECK_LIB(m, cos)
 703
 704 AC_CHECK_FUNCS(gethostbyname)
 705 if test $ac_cv_func_gethostbyname = no; then
 706     AC_CHECK_LIB(nsl, gethostbyname)
 707 fi
 708
 709 AC_CHECK_FUNCS(connect)
 710 if test $ac_cv_func_connect = no; then
 711     AC_CHECK_LIB(socket, connect)
 712 fi
 713
 714 dnl
 715 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 716 dnl
 717 EXTRA_DEFS=""
 718 case $host in
 719   *-*-mingw*)
 720     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 721       [Define if you have the <winsock2.h> header file.])])
 722     AC_CHECK_LIB(ws2_32, main)
 723     AC_LIBOBJ([win32-uname])
 724     AC_LIBOBJ([win32-dirent])
 725     if test "$enable_networking" = yes ; then
 726       AC_LIBOBJ([win32-socket])
 727     fi
 728     if test "$enable_shared" = yes ; then
 729       EXTRA_DEFS="-DSCM_IMPORT"
 730       AC_DEFINE([USE_DLL_IMPORT], 1,
 731         [Define if you need additional CPP macros on Win32 platforms.])
 732     fi
 733     ;;
 734 esac
 735 AC_SUBST(EXTRA_DEFS)
 736
 737 # Reasons for testing:
 738 #   crt_externs.h - Darwin specific
 739 #
 740 AC_CHECK_HEADERS([assert.h crt_externs.h])
 741
 742 # Reasons for testing:
 743 #   DINFINITY - OSF specific
 744 #   DQNAN - OSF specific
 745 #       (DINFINITY and DQNAN are actually global variables, not functions)
 746 #   chsize - an MS-DOS-ism, found in mingw
 747 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 748 #       for gcc to provide the "complex double" type but the system to not
 749 #       have functions like cexp and clog
 750 #   clog10 - not in mingw (though others like clog and csqrt are)
 751 #   fesetround - available in C99, but not older systems
 752 #   ftruncate - posix, but probably not older systems (current mingw
 753 #               has it as an inline for chsize)
 754 #   ioctl - not in mingw.
 755 #   gmtime_r - recent posix, not on old systems
 756 #   pipe - not in mingw
 757 #   _pipe - specific to mingw, taking 3 args
 758 #   readdir_r - recent posix, not on old systems
 759 #   readdir64_r - not available on HP-UX 11.11
 760 #   stat64 - SuS largefile stuff, not on old systems
 761 #   sysconf - not on old systems
 762 #   truncate - not in mingw
 763 #   isblank - available as a GNU extension or in C99
 764 #   _NSGetEnviron - Darwin specific
 765 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 766 #   nl_langinfo - X/Open, not available on Windows.
 767 #   utimensat: posix.1-2008
 768 #
 769 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat])
 770
 771 # Reasons for testing:
 772 #   netdb.h - not in mingw
 773 #   sys/param.h - not in mingw
 774 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 775 #       check this specifically, we need it for the timespec test below.
 776 #   sethostname - the function itself check because it's not in mingw,
 777 #       the DECL is checked because Solaris 10 doens't have in any header
 778 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 779 #       declaration isn't anywhere.
 780 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 781 #       only with `_XOPEN_SOURCE' or some such.
 782 #
 783 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h])
 784 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 785 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 786
 787 # crypt() may or may not be available, for instance in some countries there
 788 # are restrictions on cryptography.
 789 #
 790 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 791 # -lcrypt library (eg. Debian GNU/Linux).
 792 #
 793 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 794 # be careful to avoid -lcrypt in this case, since libtool will see there's
 795 # only a static libcrypt and decide to build only a static libguile.
 796 #
 797 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 798 # libraries already in that list.
 799 #
 800 AC_SEARCH_LIBS(crypt, crypt,
 801   [AC_DEFINE([HAVE_CRYPT],1,
 802              [Define to 1 if you have the `crypt' function.])])
 803
 804 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 805 # work; in the reported cases so far, 1.0fi works well instead.  According
 806 # to the C99 spec, the complex.h header must provide a working definition
 807 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 808 # is a workaround for the failure of some systems to conform to C99.
 809 if test "$ac_cv_type_complex_double" = yes; then
 810   AC_MSG_CHECKING([for i])
 811   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 812 #if HAVE_COMPLEX_H
 813 #include <complex.h>
 814 #endif
 815 complex double z;
 816 ]], [[
 817 z = _Complex_I;
 818 ]])],
 819     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 820      AC_MSG_RESULT([_Complex_I])],
 821     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 822 #if HAVE_COMPLEX_H
 823 #include <complex.h>
 824 #endif
 825 complex double z;
 826 ]],[[
 827 z = 1.0fi;
 828 ]])],
 829   [AC_DEFINE([GUILE_I],1.0fi)
 830    AC_MSG_RESULT([1.0fi])],
 831   [ac_cv_type_complex_double=no
 832    AC_MSG_RESULT([not available])])])
 833 fi
 834
 835 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 836 # csqrt(-i) returned a negative real part, when it should be positive
 837 # for the principal root.
 838 #
 839 if test "$ac_cv_type_complex_double" = yes; then
 840
 841   AC_CACHE_CHECK([whether csqrt is usable],
 842     guile_cv_use_csqrt,
 843     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 844 #include <complex.h>
 845 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 846    constant, we want to test libc. */
 847 volatile complex double z = - _Complex_I;
 848 int
 849 main (void)
 850 {
 851   z = csqrt (z);
 852   if (creal (z) > 0.0)
 853     return 0;  /* good */
 854   else
 855     return 1;  /* bad */
 856 }]])],
 857     [guile_cv_use_csqrt=yes],
 858     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 859     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 860   case $guile_cv_use_csqrt in
 861     yes*)
 862       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 863       ;;
 864   esac
 865 fi
 866
 867
 868 dnl GMP tests
 869 AC_LIB_HAVE_LINKFLAGS(gmp,
 870   [],
 871   [#include <gmp.h>],
 872   [mpz_import (0, 0, 0, 0, 0, 0, 0);],
 873   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README]))
 874
 875 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 876 if test "x$LTLIBUNISTRING" != "x"; then
 877   LIBS="$LTLIBUNISTRING $LIBS"
 878 else
 879   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 880 fi
 881
 882 dnl Libffi is needed to compile Guile's foreign function interface, but its
 883 dnl interface isn't exposed in Guile's API.
 884 PKG_CHECK_MODULES(LIBFFI, libffi)
 885 AC_SUBST(LIBFFI_CFLAGS)
 886 AC_SUBST(LIBFFI_LIBS)
 887
 888 dnl figure out approriate ffi type for size_t
 889 AC_CHECK_SIZEOF(size_t)
 890 AC_CHECK_SIZEOF(ssize_t)
 891 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 892 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 893 AC_DEFINE_UNQUOTED(ffi_type_size_t, ffi_type_${ffi_size_type},
 894                    [ffi type for size_t])
 895 AC_DEFINE_UNQUOTED(ffi_type_ssize_t, ffi_type_${ffi_ssize_type},
 896                    [ffi type for ssize_t])
 897
 898 dnl i18n tests
 899 #AC_CHECK_HEADERS([libintl.h])
 900 #AC_CHECK_FUNCS(gettext)
 901 #if test $ac_cv_func_gettext = no; then
 902 #   AC_CHECK_LIB(intl, gettext)
 903 #fi
 904 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 905 AM_GNU_GETTEXT([external], [need-ngettext])
 906
 907 ### Some systems don't declare some functions.  On such systems, we
 908 ### need to at least provide our own K&R-style declarations.
 909
 910 ### GUILE_FUNC_DECLARED(function, headerfile)
 911
 912 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 913 ### not there, #define MISSING_FUNCTION_DECL.
 914 AC_DEFUN([GUILE_FUNC_DECLARED], [
 915   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 916     AC_EGREP_HEADER($1, $2,
 917                     guile_cv_func_$1_declared=yes,
 918                     guile_cv_func_$1_declared=no))
 919   if test [x$guile_cv_func_]$1[_declared] = xno; then
 920     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 921       [Define if the operating system supplies $1 without declaring it.])
 922   fi
 923 ])
 924
 925 GUILE_FUNC_DECLARED(sleep, unistd.h)
 926 GUILE_FUNC_DECLARED(usleep, unistd.h)
 927
 928 AC_CHECK_DECLS([strptime],,,
 929 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 930 #include <time.h>])
 931
 932 ### On some systems usleep has no return value.  If it does have one,
 933 ### we'd like to return it; otherwise, we'll fake it.
 934 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 935   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 936                    unistd.h,
 937                    [guile_cv_func_usleep_return_type=void],
 938                    [guile_cv_func_usleep_return_type=int])])
 939 case "$guile_cv_func_usleep_return_type" in
 940   "void" )
 941     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 942       [Define if the system headers declare usleep to return void.])
 943   ;;
 944 esac
 945
 946 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 947 if test -n "$have_sys_un_h" ; then
 948   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 949     [Define if the system supports Unix-domain (file-domain) sockets.])
 950 fi
 951
 952 AC_CHECK_FUNCS(getrlimit setrlimit)
 953
 954 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 955
 956 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 957                setnetent    getnetent    endnetent    dnl
 958                setprotoent  getprotoent  endprotoent  dnl
 959                setservent   getservent   endservent   dnl
 960                getnetbyaddr getnetbyname dnl
 961                inet_lnaof inet_makeaddr inet_netof hstrerror)
 962
 963 # struct sockaddr field sin_len is only present on BSD systems.
 964 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 965 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 966 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 967 [#ifdef HAVE_SYS_TYPES_H
 968 #include <sys/types.h>
 969 #endif
 970 #include <netinet/in.h>])
 971
 972 AC_MSG_CHECKING(for __libc_stack_end)
 973 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 974 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 975 extern char *__libc_stack_end;]],
 976    [[printf("%p", (char*) __libc_stack_end);]])],
 977    [guile_cv_have_libc_stack_end=yes],
 978    [guile_cv_have_libc_stack_end=no])])
 979 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 980
 981 if test $guile_cv_have_libc_stack_end = yes; then
 982   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 983            [Define if you have the __libc_stack_end variable.])
 984 fi
 985
 986 dnl Some systems do not declare this.  Some systems do declare it, as a
 987 dnl macro.  With cygwin it may be in a DLL.
 988
 989 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 990 AC_CACHE_VAL(guile_cv_have_h_errno,
 991   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 992                                       [[int a = h_errno;]])],
 993   [guile_cv_have_h_errno=yes],
 994   [guile_cv_have_h_errno=no])])
 995 AC_MSG_RESULT($guile_cv_have_h_errno)
 996 if test $guile_cv_have_h_errno = yes; then
 997   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
 998 fi
 999
1000 AC_MSG_CHECKING(whether uint32_t is defined)
1001 AC_CACHE_VAL(guile_cv_have_uint32_t,
1002   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1003                    #if HAVE_STDINT_H
1004                    #include <stdint.h>
1005                    #endif
1006                    #ifndef HAVE_NETDB_H
1007                    #include <netdb.h>
1008                    #endif]],
1009                    [[uint32_t a;]])],
1010                    [guile_cv_have_uint32_t=yes],
1011                    [guile_cv_have_uint32_t=no])])
1012 AC_MSG_RESULT($guile_cv_have_uint32_t)
1013 if test $guile_cv_have_uint32_t = yes; then
1014   AC_DEFINE([HAVE_UINT32_T], 1,
1015     [Define if uint32_t typedef is defined when netdb.h is include.])
1016 fi
1017
1018 AC_MSG_CHECKING(for working IPv6 support)
1019 AC_CACHE_VAL(guile_cv_have_ipv6,
1020 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1021 #ifdef HAVE_SYS_TYPES_H
1022 #include <sys/types.h>
1023 #endif
1024 #include <netinet/in.h>
1025 #include <sys/socket.h>]],
1026 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1027 [guile_cv_have_ipv6=yes],
1028 [guile_cv_have_ipv6=no])])
1029 AC_MSG_RESULT($guile_cv_have_ipv6)
1030 if test $guile_cv_have_ipv6 = yes; then
1031   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1032 fi
1033
1034 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1035 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1036 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1037 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1038 #ifdef HAVE_SYS_TYPES_H
1039 #include <sys/types.h>
1040 #endif
1041 #include <netinet/in.h>]],
1042 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1043 [guile_cv_have_sin6_scope_id=yes],
1044 [guile_cv_have_sin6_scope_id=no])])
1045 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1046 if test $guile_cv_have_sin6_scope_id = yes; then
1047   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1048     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1049 fi
1050
1051 # struct sockaddr_in6 field sin_len is only present on BSD systems
1052 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1053 [#ifdef HAVE_SYS_TYPES_H
1054 #include <sys/types.h>
1055 #endif
1056 #include <netinet/in.h>])
1057
1058 AC_MSG_CHECKING(whether localtime caches TZ)
1059 AC_CACHE_VAL(guile_cv_localtime_cache,
1060 [if test x$ac_cv_func_tzset = xyes; then
1061 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1062 #if STDC_HEADERS
1063 # include <stdlib.h>
1064 #endif
1065 extern char **environ;
1066 unset_TZ ()
1067 {
1068   char **from, **to;
1069   for (to = from = environ; (*to = *from); from++)
1070     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1071       to++;
1072 }
1073 char TZ_GMT0[] = "TZ=GMT0";
1074 char TZ_PST8[] = "TZ=PST8";
1075 main()
1076 {
1077   time_t now = time ((time_t *) 0);
1078   int hour_GMT0, hour_unset;
1079   if (putenv (TZ_GMT0) != 0)
1080     exit (1);
1081   hour_GMT0 = localtime (&now)->tm_hour;
1082   unset_TZ ();
1083   hour_unset = localtime (&now)->tm_hour;
1084   if (putenv (TZ_PST8) != 0)
1085     exit (1);
1086   if (localtime (&now)->tm_hour == hour_GMT0)
1087     exit (1);
1088   unset_TZ ();
1089   if (localtime (&now)->tm_hour != hour_unset)
1090     exit (1);
1091   exit (0);
1092 }]])],
1093 [guile_cv_localtime_cache=no],
1094 [guile_cv_localtime_cache=yes],
1095 [# If we have tzset, assume the worst when cross-compiling.
1096 guile_cv_localtime_cache=yes])
1097 else
1098         # If we lack tzset, report that localtime does not cache TZ,
1099         # since we can't invalidate the cache if we don't have tzset.
1100         guile_cv_localtime_cache=no
1101 fi])dnl
1102 AC_MSG_RESULT($guile_cv_localtime_cache)
1103 if test $guile_cv_localtime_cache = yes; then
1104   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1105 fi
1106
1107 if test "$enable_regex" = yes; then
1108    if test "$ac_cv_header_regex_h" = yes ||
1109       test "$ac_cv_header_rxposix_h" = yes ||
1110       test "$ac_cv_header_rx_rxposix_h" = yes; then
1111      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1112      [AC_CHECK_LIB(rx, main)
1113       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1114      [AC_CHECK_LIB(regex, main)
1115       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1116      )
1117      dnl The following should not be necessary, but for some reason
1118      dnl autoheader misses it if we don't include it!
1119      if test "$ac_cv_func_regcomp_norx" = yes ||
1120         test "$ac_cv_func_regcomp_regex" = yes ||
1121         test "$ac_cv_func_regcomp_rx" = yes; then
1122        AC_DEFINE([HAVE_REGCOMP], 1,
1123          [This is included as part of a workaround for a autoheader bug.])
1124      fi
1125    fi
1126 fi
1127
1128 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1129
1130 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
1131
1132 # Reasons for testing:
1133 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1134 #                                older systems
1135 #   sincos - GLIBC extension
1136 #
1137 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1138
1139 # C99 specifies isinf and isnan as macros.
1140 # HP-UX provides only macros, no functions.
1141 # glibc 2.3.2 provides both macros and functions.
1142 # IRIX 6.5 and Solaris 8 only provide functions.
1143 #
1144 # The following tests detect isinf and isnan either as functions or as
1145 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1146 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1147 #
1148 AC_MSG_CHECKING([for isinf])
1149 AC_LINK_IFELSE(AC_LANG_SOURCE(
1150 [[#include <math.h>
1151 volatile double x = 0.0;
1152 int main () { return (isinf(x) != 0); }]]),
1153   [AC_MSG_RESULT([yes])
1154    AC_DEFINE([HAVE_ISINF], 1,
1155              [Define to 1 if you have the `isinf' macro or function.])],
1156   [AC_MSG_RESULT([no])])
1157 AC_MSG_CHECKING([for isnan])
1158 AC_LINK_IFELSE(AC_LANG_SOURCE(
1159 [[#include <math.h>
1160 volatile double x = 0.0;
1161 int main () { return (isnan(x) != 0); }]]),
1162   [AC_MSG_RESULT([yes])
1163    AC_DEFINE([HAVE_ISNAN], 1,
1164              [Define to 1 if you have the `isnan' macro or function.])],
1165   [AC_MSG_RESULT([no])])
1166
1167 # Reasons for checking:
1168 #
1169 #     st_rdev
1170 #     st_blksize
1171 #     st_blocks   not in mingw
1172 #     tm_gmtoff   BSD+GNU, not in C99
1173 #
1174 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1175 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1176 #
1177 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1178                  [#define _GNU_SOURCE
1179 AC_INCLUDES_DEFAULT
1180 ])
1181
1182 AC_STRUCT_TIMEZONE
1183 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1184 [#include <time.h>
1185 #ifdef TIME_WITH_SYS_TIME
1186 # include <sys/time.h>
1187 # include <time.h>
1188 #else
1189 # if HAVE_SYS_TIME_H
1190 #  include <sys/time.h>
1191 # else
1192 #  include <time.h>
1193 # endif
1194 #endif
1195 ])
1196 GUILE_STRUCT_UTIMBUF
1197
1198
1199 #--------------------------------------------------------------------
1200 #
1201 # Which way does the stack grow?
1202 #
1203 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1204 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1205 # very similar code, so in future we could look at using that.
1206 #
1207 # An important detail is that the code involves find_stack_direction
1208 # calling _itself_ - which means that find_stack_direction (or at
1209 # least the second find_stack_direction() call) cannot be inlined.
1210 # If the code could be inlined, that might cause the test to give
1211 # an incorrect answer.
1212 #--------------------------------------------------------------------
1213
1214 SCM_I_GSC_STACK_GROWS_UP=0
1215 AC_RUN_IFELSE([AC_LANG_SOURCE(
1216 [AC_INCLUDES_DEFAULT
1217 int
1218 find_stack_direction ()
1219 {
1220   static char *addr = 0;
1221   auto char dummy;
1222   if (addr == 0)
1223     {
1224       addr = &dummy;
1225       return find_stack_direction ();
1226     }
1227   else
1228     return (&dummy > addr) ? 1 : -1;
1229 }
1230
1231 int
1232 main ()
1233 {
1234   return find_stack_direction () < 0;
1235 }])],
1236                [SCM_I_GSC_STACK_GROWS_UP=1],
1237                [],
1238                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1239
1240 #--------------------------------------------------------------------
1241 #
1242 # Boehm's GC library
1243 #
1244 #--------------------------------------------------------------------
1245 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1246
1247 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1248 LIBS="$BDW_GC_LIBS $LIBS"
1249
1250 # `GC_do_blocking ()' is available in GC 7.1 but not declared.
1251 AC_CHECK_FUNCS([GC_do_blocking])
1252 AC_CHECK_DECL([GC_do_blocking],
1253   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1254     [Define this if the `GC_do_blocking ()' function is declared])],
1255   [],
1256   [#include <gc/gc.h>])
1257
1258 # `GC_fn_type' is not available in GC 7.1 and earlier.
1259 AC_CHECK_TYPE([GC_fn_type],
1260   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1261     [Define this if the `GC_fn_type' type is available.])],
1262   [],
1263   [#include <gc/gc.h>])
1264
1265
1266 AC_CHECK_SIZEOF(float)
1267 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1268     AC_DEFINE([SCM_SINGLES], 1,
1269               [Define this if floats are the same size as longs.])
1270 fi
1271
1272 AC_MSG_CHECKING(for struct linger)
1273 AC_CACHE_VAL(scm_cv_struct_linger,
1274         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1275 #include <sys/types.h>
1276 #include <sys/socket.h>]],
1277                           [[struct linger lgr;  lgr.l_linger = 100]])],
1278                           [scm_cv_struct_linger="yes"],
1279                           [scm_cv_struct_linger="no"]))
1280 AC_MSG_RESULT($scm_cv_struct_linger)
1281 if test $scm_cv_struct_linger = yes; then
1282         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1283           [Define this if your system defines struct linger, for use with the
1284            getsockopt and setsockopt system calls.])
1285 fi
1286
1287
1288 # On mingw, struct timespec is in <pthread.h>.
1289 #
1290 AC_MSG_CHECKING(for struct timespec)
1291 AC_CACHE_VAL(scm_cv_struct_timespec,
1292         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1293 #include <time.h>
1294 #if HAVE_PTHREAD_H
1295 #include <pthread.h>
1296 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1297           [scm_cv_struct_timespec="yes"],
1298           [scm_cv_struct_timespec="no"]))
1299 AC_MSG_RESULT($scm_cv_struct_timespec)
1300 if test $scm_cv_struct_timespec = yes; then
1301   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1302     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1303 fi
1304
1305 #--------------------------------------------------------------------
1306 #
1307 # Flags for thread support
1308 #
1309 #--------------------------------------------------------------------
1310
1311 SCM_I_GSC_USE_PTHREAD_THREADS=0
1312 SCM_I_GSC_USE_NULL_THREADS=0
1313 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1314 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1315
1316 ### What thread package has the user asked for?
1317 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1318             , with_threads=yes)
1319
1320 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1321 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1322
1323 case "$with_threads" in
1324   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1325
1326     build_pthread_support="yes"
1327
1328     ACX_PTHREAD([CC="$PTHREAD_CC"
1329        LIBS="$PTHREAD_LIBS $LIBS"
1330        SCM_I_GSC_USE_PTHREAD_THREADS=1
1331        with_threads="pthreads"],
1332       [with_threads="null"
1333        build_pthread_support="no"])
1334
1335     old_CFLAGS="$CFLAGS"
1336     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1337
1338     # Reasons for testing:
1339     #     pthread_getattr_np - "np" meaning "non portable" says it
1340     #         all; not present on MacOS X or Solaris 10
1341     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1342     #         all; specific to MacOS X
1343     #     pthread_sigmask - not available on mingw
1344     #
1345     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1346
1347     # On past versions of Solaris, believe 8 through 10 at least, you
1348     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1349     # This is contrary to POSIX:
1350     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1351     # Check here if this style is required.
1352     #
1353     # glibc (2.3.6 at least) works both with or without braces, so the
1354     # test checks whether it works without.
1355     #
1356
1357     if test "$GCC" = "yes"; then
1358       # Since GCC only issues a warning for missing braces, so we need
1359       # `-Werror' to catch it.
1360       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1361     fi
1362
1363     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1364       guile_cv_need_braces_on_pthread_once_init,
1365       [AC_COMPILE_IFELSE([#include <pthread.h>
1366          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1367         [guile_cv_need_braces_on_pthread_once_init=no],
1368         [guile_cv_need_braces_on_pthread_once_init=yes])])
1369     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1370       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1371     fi
1372
1373     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1374     # 6.5.30m with GCC 3.3.
1375     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1376       guile_cv_need_braces_on_pthread_mutex_initializer,
1377       [AC_COMPILE_IFELSE([#include <pthread.h>
1378          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1379         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1380         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1381     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1382       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1383     fi
1384
1385     CFLAGS="$old_CFLAGS"
1386
1387     # On Solaris, sched_yield lives in -lrt.
1388     AC_SEARCH_LIBS(sched_yield, rt)
1389
1390   ;;
1391 esac
1392
1393 case "$with_threads" in
1394   "pthreads")
1395   ;;
1396   "no" | "null")
1397     SCM_I_GSC_USE_NULL_THREADS=1
1398     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1399     with_threads="null-threads"
1400   ;;
1401   * )
1402     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1403   ;;
1404 esac
1405
1406 AC_MSG_CHECKING(what kind of threads to support)
1407 AC_MSG_RESULT($with_threads)
1408
1409 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1410   [test "x$build_pthread_support" = "xyes"])
1411
1412
1413 ## Check whether pthread_attr_getstack works for the main thread
1414
1415 if test "$with_threads" = pthreads; then
1416
1417 AC_MSG_CHECKING(whether pthread_attr_getstack works for the main thread)
1418 old_CFLAGS="$CFLAGS"
1419 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1420 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1421 #if HAVE_PTHREAD_ATTR_GETSTACK
1422 #include <pthread.h>
1423
1424 int main ()
1425 {
1426   pthread_attr_t attr;
1427   void *start, *end;
1428   size_t size;
1429
1430   pthread_getattr_np (pthread_self (), &attr);
1431   pthread_attr_getstack (&attr, &start, &size);
1432   end = (char *)start + size;
1433
1434   if ((void *)&attr < start || (void *)&attr >= end)
1435     return 1;
1436   else
1437     return 0;
1438 }
1439 #else
1440 int main ()
1441 {
1442   return 1;
1443 }
1444 #endif
1445 ]])],
1446 [works=yes
1447 AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1448 [works=no],
1449 [])
1450 CFLAGS="$old_CFLAGS"
1451 AC_MSG_RESULT($works)
1452
1453 GUILE_THREAD_LOCAL_STORAGE
1454
1455 fi # with_threads=pthreads
1456
1457
1458 ## Cross building
1459 if test "$cross_compiling" = "yes"; then
1460   AC_MSG_CHECKING(cc for build)
1461   ## /usr/bin/cc still uses wrong assembler
1462   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1463   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1464 else
1465   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1466 fi
1467
1468 ## AC_MSG_CHECKING("if we are cross compiling")
1469 ## AC_MSG_RESULT($cross_compiling)
1470 if test "$cross_compiling" = "yes"; then
1471    AC_MSG_RESULT($CC_FOR_BUILD)
1472 fi
1473
1474 ## No need as yet to be more elaborate
1475 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1476
1477 AC_SUBST(cross_compiling)
1478 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1479 AC_SUBST(CCLD_FOR_BUILD)
1480
1481 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1482 ## --HOST is the platform that PACKAGE is compiled for.
1483 HOST_CC="$CC_FOR_BUILD"
1484 AC_SUBST(HOST_CC)
1485
1486 if test "$cross_compiling" = "yes"; then
1487   AC_MSG_CHECKING(guile for build)
1488   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1489 else
1490   GUILE_FOR_BUILD='$(preinstguile)'
1491 fi
1492
1493 ## AC_MSG_CHECKING("if we are cross compiling")
1494 ## AC_MSG_RESULT($cross_compiling)
1495 if test "$cross_compiling" = "yes"; then
1496    AC_MSG_RESULT($GUILE_FOR_BUILD)
1497 fi
1498 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1499 AC_SUBST(GUILE_FOR_BUILD)
1500
1501 ## If we're using GCC, ask for aggressive warnings.
1502 GCC_CFLAGS=""
1503 case "$GCC" in
1504   yes )
1505     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1506     ## much stuff with generic function pointers for that to really be
1507     ## less than exasperating.
1508     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1509     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1510     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1511       -Wdeclaration-after-statement -Wundef \
1512       -Wswitch-enum"
1513     # Do this here so we don't screw up any of the tests above that might
1514     # not be "warning free"
1515     if test "${GUILE_ERROR_ON_WARNING}" = yes
1516     then
1517         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1518         enable_compile_warnings=no
1519     fi
1520
1521     for flag in $POTENTIAL_GCC_CFLAGS
1522     do
1523         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1524     done
1525     ;;
1526 esac
1527
1528 AC_SUBST(GCC_CFLAGS)
1529
1530 # Check for GNU ld's "-z relro".
1531 GUILE_GNU_LD_RELRO
1532
1533
1534 ## If we're creating a shared library (using libtool!), then we'll
1535 ## need to generate a list of .lo files corresponding to the .o files
1536 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1537 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1538
1539 ## We also need to create corresponding .doc and .x files
1540 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1541 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1542
1543 # GNU Readline bindings.
1544 GUILE_READLINE
1545
1546 AC_SUBST(GUILE_MAJOR_VERSION)
1547 AC_SUBST(GUILE_MINOR_VERSION)
1548 AC_SUBST(GUILE_MICRO_VERSION)
1549 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1550 AC_SUBST(GUILE_VERSION)
1551
1552 #######################################################################
1553 # library versioning
1554
1555 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1556 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1557 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1558 AC_SUBST(LIBGUILE_INTERFACE)
1559
1560 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1561 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1562 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1563 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1564 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1565
1566 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1567 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1568 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1569 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1570 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1571
1572 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1573 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1574 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1575 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1576 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1577
1578 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1579 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1580 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1581 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1582 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1583
1584 AC_SUBST(LIBGUILE_I18N_MAJOR)
1585 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1586 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1587 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1588 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1589
1590
1591 #######################################################################
1592
1593 dnl Tell guile-config what flags guile users should compile and link with.
1594 GUILE_LIBS="$LDFLAGS $LIBS"
1595 GUILE_CFLAGS="$CPPFLAGS $PTHREAD_CFLAGS"
1596 AC_SUBST(GUILE_LIBS)
1597 AC_SUBST(GUILE_CFLAGS)
1598
1599 AC_SUBST(AWK)
1600 AC_SUBST(LIBLOBJS)
1601 AC_SUBST(EXTRA_DOT_DOC_FILES)
1602 AC_SUBST(EXTRA_DOT_X_FILES)
1603
1604 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1605 top_builddir_absolute=`pwd`
1606 AC_SUBST(top_builddir_absolute)
1607 top_srcdir_absolute=`(cd $srcdir && pwd)`
1608 AC_SUBST(top_srcdir_absolute)
1609
1610 dnl We need `sitedir' in `guile-1.8.pc'.
1611 dnl Note: `sitedir' must be kept in sync with `GUILE_SITE_DIR' in `guile.m4'.
1612 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1613 sitedir="$pkgdatadir/site"
1614 AC_SUBST([sitedir])
1615
1616 # Additional SCM_I_GSC definitions are above.
1617 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1618 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1619 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1620 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1621 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1622 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1623 AC_SUBST([SCM_I_GSC_C_INLINE])
1624 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1625
1626 AC_CONFIG_FILES([
1627   Makefile
1628   am/Makefile
1629   lib/Makefile
1630   benchmark-suite/Makefile
1631   doc/Makefile
1632   doc/r5rs/Makefile
1633   doc/ref/Makefile
1634   doc/tutorial/Makefile
1635   emacs/Makefile
1636   examples/Makefile
1637   libguile/Makefile
1638   srfi/Makefile
1639   guile-readline/Makefile
1640   test-suite/Makefile
1641   test-suite/standalone/Makefile
1642   meta/Makefile
1643   module/Makefile
1644   testsuite/Makefile
1645 ])
1646
1647 AC_CONFIG_FILES([meta/guile-2.0.pc])
1648 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1649 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1650 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1651 AC_CONFIG_FILES([meta/guile], [chmod +x meta/guile])
1652 AC_CONFIG_FILES([meta/uninstalled-env], [chmod +x meta/uninstalled-env])
1653 AC_CONFIG_FILES([meta/gdb-uninstalled-guile], [chmod +x meta/gdb-uninstalled-guile])
1654 AC_CONFIG_FILES([meta/guile-tools], [chmod +x meta/guile-tools])
1655 AC_CONFIG_FILES([libguile/guile-snarf],
1656                 [chmod +x libguile/guile-snarf])
1657 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1658                 [chmod +x libguile/guile-doc-snarf])
1659 AC_CONFIG_FILES([libguile/guile-func-name-check],
1660                 [chmod +x libguile/guile-func-name-check])
1661 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1662                 [chmod +x libguile/guile-snarf-docs])
1663 AC_CONFIG_FILES([test-suite/standalone/test-use-srfi],
1664                 [chmod +x test-suite/standalone/test-use-srfi])
1665 AC_CONFIG_FILES([test-suite/standalone/test-fast-slot-ref],
1666                 [chmod +x test-suite/standalone/test-fast-slot-ref])
1667 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1668
1669 AC_OUTPUT
1670
1671 dnl Local Variables:
1672 dnl comment-start: "dnl "
1673 dnl comment-end: ""
1674 dnl comment-start-skip: "\\bdnl\\b\\s *"
1675 dnl End: