m4/inet_pton.m4

   1 # inet_pton.m4 serial 13
   2 dnl Copyright (C) 2006, 2008-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_INET_PTON],
   8 [
   9   dnl Persuade Solaris <arpa/inet.h> to declare inet_pton.
  10   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  11
  12   dnl Most platforms that provide inet_pton define it in libc.
  13   dnl Solaris 8..10 provide inet_pton in libnsl instead.
  14   HAVE_INET_PTON=1
  15   gl_save_LIBS=$LIBS
  16   AC_SEARCH_LIBS([inet_pton], [nsl], [],
  17     [AC_CHECK_FUNCS([inet_pton])
  18      if test $ac_cv_func_inet_pton = no; then
  19        HAVE_INET_PTON=0
  20      fi
  21     ])
  22   LIBS=$gl_save_LIBS
  23
  24   INET_PTON_LIB=
  25   if test "$ac_cv_search_inet_pton" != "no" &&
  26      test "$ac_cv_search_inet_pton" != "none required"; then
  27     INET_PTON_LIB="$ac_cv_search_inet_pton"
  28   fi
  29   AC_SUBST([INET_PTON_LIB])
  30
  31   AC_CHECK_HEADERS_ONCE([netdb.h])
  32   AC_CHECK_DECLS([inet_pton],,,
  33     [#include <arpa/inet.h>
  34      #if HAVE_NETDB_H
  35      # include <netdb.h>
  36      #endif
  37     ])
  38   if test $ac_cv_have_decl_inet_pton = no; then
  39     HAVE_DECL_INET_PTON=0
  40     AC_REQUIRE([AC_C_RESTRICT])
  41   fi
  42 ])
  43
  44 # Prerequisites of lib/inet_pton.c.
  45 AC_DEFUN([gl_PREREQ_INET_PTON], [
  46   AC_REQUIRE([gl_SOCKET_FAMILIES])
  47 ])