configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it under
  12 the terms of the GNU Lesser General Public License as published by the
  13 Free Software Foundation; either version 3, or (at your option) any
  14 later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but WITHOUT
  17 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  19 License for more details.
  20
  21 You should have received a copy of the GNU Lesser General Public
  22 License along with GUILE; see the file COPYING.LESSER.  If not, write
  23 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  24 Floor, Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.61)
  29
  30 AC_INIT([GNU Guile],
  31         m4_esyscmd([build-aux/git-version-gen                                   \
  32           .tarball-version                                                      \
  33           's/^release_\([0-9][0-9]*\)-\([0-9][0-9]*\)-\([0-9][0-9]*\)/v\1.\2\.\3/g']),
  34         [bug-guile@gnu.org])
  35 AC_CONFIG_AUX_DIR([build-aux])
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_CONFIG_SRCDIR(GUILE-VERSION)
  38
  39 AM_INIT_AUTOMAKE([gnu no-define -Wall -Wno-override])
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  41
  42 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  43 AC_CONFIG_SRCDIR([GUILE-VERSION])
  44
  45 . $srcdir/GUILE-VERSION
  46 GUILE_VERSION="$PACKAGE_VERSION"
  47
  48 AC_CONFIG_HEADERS([config.h])
  49 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  50
  51 #--------------------------------------------------------------------
  52
  53 AC_LANG([C])
  54
  55 dnl Some more checks for Win32
  56 AC_CANONICAL_HOST
  57
  58 AC_LIBTOOL_WIN32_DLL
  59
  60 AC_PROG_INSTALL
  61 AC_PROG_CC
  62 gl_EARLY
  63 AC_PROG_CPP
  64 AC_PROG_SED
  65 AC_PROG_AWK
  66
  67 dnl Gnulib.
  68 gl_INIT
  69
  70 AC_PROG_CC_C89
  71
  72 # for per-target cflags in the libguile subdir
  73 AM_PROG_CC_C_O
  74
  75 AC_LIBTOOL_DLOPEN
  76 AC_PROG_LIBTOOL
  77 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  78   [AC_MSG_ERROR([libltdl not found.  See README.])])
  79 AC_CHECK_HEADER([ltdl.h], [],
  80   [AC_MSG_ERROR([<ltdl.h> not found.  See README.])])
  81
  82 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  83 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  84
  85 AM_PATH_LISPDIR
  86
  87 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
  88   [Define to the host's GNU triplet.])
  89
  90 #--------------------------------------------------------------------
  91 #
  92 # User options (after above tests that may set default CFLAGS etc.)
  93 #
  94 #--------------------------------------------------------------------
  95
  96 GUILE_ERROR_ON_WARNING="no"
  97
  98 AC_ARG_ENABLE(error-on-warning,
  99   [  --enable-error-on-warning    treat compile warnings as errors],
 100   [case "${enableval}" in
 101      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 102      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 103      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 104    esac])
 105
 106 AC_ARG_ENABLE(debug-malloc,
 107   [  --enable-debug-malloc   include malloc debugging code],
 108   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 109     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 110       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 111   fi)
 112
 113 SCM_I_GSC_GUILE_DEBUG=0
 114 AC_ARG_ENABLE(guile-debug,
 115   [AS_HELP_STRING([--enable-guile-debug],
 116                   [include internal debugging functions])],
 117   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 118     SCM_I_GSC_GUILE_DEBUG=1
 119   fi)
 120
 121 AC_ARG_ENABLE(posix,
 122   [  --disable-posix         omit posix interfaces],,
 123   enable_posix=yes)
 124
 125 AC_ARG_ENABLE(networking,
 126   [  --disable-networking    omit networking interfaces],,
 127   enable_networking=yes)
 128
 129 AC_ARG_ENABLE(regex,
 130   [  --disable-regex         omit regular expression interfaces],,
 131   enable_regex=yes)
 132
 133 AC_ARG_ENABLE([discouraged],
 134   AS_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 135
 136 if test "$enable_discouraged" = no; then
 137   SCM_I_GSC_ENABLE_DISCOURAGED=0
 138 else
 139   SCM_I_GSC_ENABLE_DISCOURAGED=1
 140 fi
 141
 142 AC_ARG_ENABLE([deprecated],
 143   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 144
 145 if test "$enable_deprecated" = no; then
 146   SCM_I_GSC_ENABLE_DEPRECATED=0
 147   warn_default=no
 148 else
 149   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 150     warn_default=summary
 151   elif test "$enable_deprecated" = shutup; then
 152     warn_default=no
 153   else
 154     warn_default=$enable_deprecated
 155   fi
 156   SCM_I_GSC_ENABLE_DEPRECATED=1
 157 fi
 158 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 159 [Define this to control the default warning level for deprecated features.])
 160
 161 dnl  Added the following configure option in January 2008 following
 162 dnl  investigation of problems with "64" system and library calls on
 163 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 164 dnl  system has stat64, it will have all the other 64 APIs too; but on
 165 dnl  Darwin, stat64 is there but other APIs are missing.
 166 dnl
 167 dnl  It also appears, from the Darwin docs, that most system call APIs
 168 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 169 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 170 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 171 dnl
 172 dnl  A similar problem has been reported for HP-UX:
 173 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 174 dnl
 175 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 176 dnl  better than no Guile at all, we provide this option to suppress
 177 dnl  trying to use "64" calls.
 178 dnl
 179 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 180 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 181 dnl  missing out on that.  If so, someone can work on that in the future.
 182 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 183 dnl  wasn't building before.
 184 AC_MSG_CHECKING([whether to use system and library "64" calls])
 185 AC_ARG_WITH([64-calls],
 186   AS_HELP_STRING([--without-64-calls],
 187                  [don't attempt to use system and library calls with "64" in their names]),
 188   [use_64_calls=$withval],
 189   [use_64_calls=yes
 190    case $host in
 191      *-apple-darwin* )
 192        use_64_calls=no
 193        ;;
 194      powerpc-ibm-aix* )
 195        use_64_calls=no
 196        ;;
 197    esac])
 198 AC_MSG_RESULT($use_64_calls)
 199 case "$use_64_calls" in
 200   y* )
 201     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 202       [Define to 1 in order to try to use "64" versions of system and library calls.])
 203     ;;
 204 esac
 205
 206 #--------------------------------------------------------------------
 207
 208 dnl Check for dynamic linking
 209
 210 use_modules=yes
 211 AC_ARG_WITH(modules,
 212 [  --with-modules[=FILES]  Add support for dynamic modules],
 213 use_modules="$withval")
 214 test -z "$use_modules" && use_modules=yes
 215 DLPREOPEN=
 216 if test "$use_modules" != no; then
 217   if test "$use_modules" = yes; then
 218     DLPREOPEN="-dlpreopen force"
 219   else
 220     DLPREOPEN="-export-dynamic"
 221     for module in $use_modules; do
 222       DLPREOPEN="$DLPREOPEN -dlopen $module"
 223     done
 224   fi
 225 fi
 226
 227 dnl files which are destined for separate modules.
 228
 229 if test "$use_modules" != no; then
 230    AC_LIBOBJ([dynl])
 231 fi
 232
 233 if test "$enable_posix" = yes; then
 234    AC_LIBOBJ([filesys])
 235    AC_LIBOBJ([posix])
 236    AC_DEFINE([HAVE_POSIX], 1,
 237      [Define this if you want support for POSIX system calls in Guile.])
 238 fi
 239
 240 if test "$enable_networking" = yes; then
 241    AC_LIBOBJ([net_db])
 242    AC_LIBOBJ([socket])
 243    AC_DEFINE([HAVE_NETWORKING], 1,
 244      [Define this if you want support for networking in Guile.])
 245 fi
 246
 247 if test "$enable_debug_malloc" = yes; then
 248    AC_LIBOBJ([debug-malloc])
 249 fi
 250
 251 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 252
 253 AC_C_CONST
 254
 255 # "volatile" is used in a couple of tests below.
 256 AC_C_VOLATILE
 257
 258 AC_C_INLINE
 259 if test "$ac_cv_c_inline" != no; then
 260   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 261 else
 262   SCM_I_GSC_C_INLINE=NULL
 263 fi
 264 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 265
 266 AC_C_BIGENDIAN
 267
 268 AC_C_LABELS_AS_VALUES
 269
 270 AC_CHECK_SIZEOF(char)
 271 AC_CHECK_SIZEOF(unsigned char)
 272 AC_CHECK_SIZEOF(short)
 273 AC_CHECK_SIZEOF(unsigned short)
 274 AC_CHECK_SIZEOF(int)
 275 AC_CHECK_SIZEOF(unsigned int)
 276 AC_CHECK_SIZEOF(long)
 277 AC_CHECK_SIZEOF(unsigned long)
 278 AC_CHECK_SIZEOF(size_t)
 279 AC_CHECK_SIZEOF(long long)
 280 AC_CHECK_SIZEOF(unsigned long long)
 281 AC_CHECK_SIZEOF(__int64)
 282 AC_CHECK_SIZEOF(unsigned __int64)
 283 AC_CHECK_SIZEOF(void *)
 284 AC_CHECK_SIZEOF(intptr_t)
 285 AC_CHECK_SIZEOF(uintptr_t)
 286 AC_CHECK_SIZEOF(ptrdiff_t)
 287 AC_CHECK_SIZEOF(size_t)
 288 AC_CHECK_SIZEOF(off_t)
 289
 290 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 291   AC_MSG_ERROR(sizes of long and void* are not identical)
 292 fi
 293
 294 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 295   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 296 else
 297   SCM_I_GSC_T_PTRDIFF='"long"'
 298 fi
 299 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 300
 301 AC_CHECK_HEADERS([stdint.h])
 302 AC_CHECK_HEADERS([inttypes.h])
 303
 304 AC_CHECK_SIZEOF(intmax_t)
 305
 306 SCM_I_GSC_NEEDS_STDINT_H=0
 307 SCM_I_GSC_NEEDS_INTTYPES_H=0
 308
 309 ### intptr and uintptr (try not to use inttypes if we don't have to)
 310 if test "$ac_cv_header_inttypes_h" = yes; then
 311   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 312     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 313 #include <stdio.h>])
 314     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 315       SCM_I_GSC_NEEDS_INTTYPES_H=1
 316     fi
 317   fi
 318   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 319     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 320 #include <stdio.h>])
 321     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 322       SCM_I_GSC_NEEDS_INTTYPES_H=1
 323     fi
 324   fi
 325 fi
 326
 327 ### See what's provided by stdint.h
 328 if test "$ac_cv_header_stdint_h" = yes; then
 329    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 330    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 331    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 332    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 333    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 334    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 335    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 336    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 337    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 338    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 339    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 340    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 341 fi
 342
 343 # so we don't get confused by the cache (wish there was a better way
 344 # to check particular headers for the same type...)
 345
 346 unset ac_cv_type_int8_t
 347 unset ac_cv_type_uint8_t
 348 unset ac_cv_type_int16_t
 349 unset ac_cv_type_uint16_t
 350 unset ac_cv_type_int32_t
 351 unset ac_cv_type_uint32_t
 352 unset ac_cv_type_int64_t
 353 unset ac_cv_type_uint64_t
 354 unset ac_cv_type_intmax_t
 355 unset ac_cv_type_uintmax_t
 356
 357 ### See what's provided by inttypes.h
 358 if test "$ac_cv_header_inttypes_h" = yes; then
 359   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 360   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 361   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 362   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 363   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 364   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 365   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 366   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 367   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 368   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 369   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 370   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 371 fi
 372
 373 # Try hard to find definitions for some required scm_t_*int* types.
 374
 375 ### Required type scm_t_int8
 376 if test "$scm_stdint_has_int8"; then
 377   SCM_I_GSC_T_INT8='"int8_t"'
 378   SCM_I_GSC_NEEDS_STDINT_H=1
 379 elif test "$scm_inttypes_has_int8"; then
 380   SCM_I_GSC_T_INT8='"int8_t"'
 381   SCM_I_GSC_NEEDS_INTTYPES_H=1
 382 elif test "$ac_cv_sizeof_char" -eq 1; then
 383   SCM_I_GSC_T_INT8='"signed char"'
 384 else
 385   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 386 fi
 387 AC_SUBST([SCM_I_GSC_T_INT8])
 388
 389 ### Required type scm_t_uint8
 390 if test "$scm_stdint_has_uint8"; then
 391   SCM_I_GSC_T_UINT8='"uint8_t"'
 392   SCM_I_GSC_NEEDS_STDINT_H=1
 393 elif test "$scm_inttypes_has_uint8"; then
 394   SCM_I_GSC_T_UINT8='"uint8_t"'
 395   SCM_I_GSC_NEEDS_INTTYPES_H=1
 396 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 397   SCM_I_GSC_T_UINT8='"unsigned char"'
 398 else
 399   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 400 fi
 401 AC_SUBST([SCM_I_GSC_T_UINT8])
 402
 403 ### Required type scm_t_int16 (ANSI C says int or short might work)
 404 if test "$scm_stdint_has_int16"; then
 405   SCM_I_GSC_T_INT16='"int16_t"'
 406   SCM_I_GSC_NEEDS_STDINT_H=1
 407 elif test "$scm_inttypes_has_int16"; then
 408   SCM_I_GSC_T_INT16='"int16_t"'
 409   SCM_I_GSC_NEEDS_INTTYPES_H=1
 410 elif test "$ac_cv_sizeof_int" -eq 2; then
 411   SCM_I_GSC_T_INT16='"int"'
 412 elif test "$ac_cv_sizeof_short" -eq 2; then
 413   SCM_I_GSC_T_INT16='"short"'
 414 else
 415   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 416 fi
 417 AC_SUBST([SCM_I_GSC_T_INT16])
 418
 419 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 420 if test "$scm_stdint_has_uint16"; then
 421   SCM_I_GSC_T_UINT16='"uint16_t"'
 422   SCM_I_GSC_NEEDS_STDINT_H=1
 423 elif test "$scm_inttypes_has_uint16"; then
 424   SCM_I_GSC_T_UINT16='"uint16_t"'
 425   SCM_I_GSC_NEEDS_INTTYPES_H=1
 426 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 427   SCM_I_GSC_T_UINT16='"unsigned int"'
 428 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 429   SCM_I_GSC_T_UINT16='"unsigned short"'
 430 else
 431   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 432 fi
 433 AC_SUBST([SCM_I_GSC_T_UINT16])
 434
 435
 436 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 437 if test "$scm_stdint_has_int32"; then
 438   SCM_I_GSC_T_INT32='"int32_t"'
 439   SCM_I_GSC_NEEDS_STDINT_H=1
 440 elif test "$scm_inttypes_has_int32"; then
 441   SCM_I_GSC_T_INT32='"int32_t"'
 442   SCM_I_GSC_NEEDS_INTTYPES_H=1
 443 elif test "$ac_cv_sizeof_int" -eq 4; then
 444   SCM_I_GSC_T_INT32='"int"'
 445 elif test "$ac_cv_sizeof_long" -eq 4; then
 446   SCM_I_GSC_T_INT32='"long"'
 447 elif test "$ac_cv_sizeof_short" -eq 4; then
 448   SCM_I_GSC_T_INT32='"short"'
 449 else
 450   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 451 fi
 452 AC_SUBST([SCM_I_GSC_T_INT32])
 453
 454 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 455 if test "$scm_stdint_has_uint32"; then
 456   SCM_I_GSC_T_UINT32='"uint32_t"'
 457   SCM_I_GSC_NEEDS_STDINT_H=1
 458 elif test "$scm_inttypes_has_uint32"; then
 459   SCM_I_GSC_T_UINT32='"uint32_t"'
 460   SCM_I_GSC_NEEDS_INTTYPES_H=1
 461 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 462   SCM_I_GSC_T_UINT32='"unsigned int"'
 463 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 464   SCM_I_GSC_T_UINT32='"unsigned long"'
 465 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 466   SCM_I_GSC_T_UINT32='"unsigned short"'
 467 else
 468   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 469 fi
 470 AC_SUBST([SCM_I_GSC_T_UINT32])
 471
 472 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 473 ### Also try 'long long' and '__int64' if we have it.
 474 SCM_I_GSC_T_INT64=0
 475 if test "$scm_stdint_has_int64"; then
 476   SCM_I_GSC_T_INT64='"int64_t"'
 477   SCM_I_GSC_NEEDS_STDINT_H=1
 478 elif test "$scm_inttypes_has_int64"; then
 479   SCM_I_GSC_T_INT64='"int64_t"'
 480   SCM_I_GSC_NEEDS_INTTYPES_H=1
 481 elif test "$ac_cv_sizeof_int" -eq 8; then
 482   SCM_I_GSC_T_INT64='"int"'
 483 elif test "$ac_cv_sizeof_long" -eq 8; then
 484   SCM_I_GSC_T_INT64='"long"'
 485 elif test "$ac_cv_sizeof_short" -eq 8; then
 486   SCM_I_GSC_T_INT64='"short"'
 487 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 488   SCM_I_GSC_T_INT64='"long long"'
 489 elif test "$ac_cv_sizeof___int64" -eq 8; then
 490   SCM_I_GSC_T_INT64='"__int64"'
 491 else
 492   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 493 fi
 494 AC_SUBST([SCM_I_GSC_T_INT64])
 495
 496
 497 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 498 ### Also try 'long long' and '__int64' if we have it.
 499 SCM_I_GSC_T_UINT64=0
 500 if test "$scm_stdint_has_uint64"; then
 501   SCM_I_GSC_T_UINT64='"uint64_t"'
 502   SCM_I_GSC_NEEDS_STDINT_H=1
 503 elif test "$scm_inttypes_has_uint64"; then
 504   SCM_I_GSC_T_UINT64='"uint64_t"'
 505   SCM_I_GSC_NEEDS_INTTYPES_H=1
 506 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 507   SCM_I_GSC_T_UINT64='"unsigned int"'
 508 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 509   SCM_I_GSC_T_UINT64='"unsigned long"'
 510 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 511   SCM_I_GSC_T_UINT64='"unsigned short"'
 512 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 513   SCM_I_GSC_T_UINT64='"unsigned long long"'
 514 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 515   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 516 else
 517   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 518 fi
 519 AC_SUBST([SCM_I_GSC_T_UINT64])
 520
 521 ### Required type scm_t_intmax
 522 ###
 523 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 524 ### none of them is available, we use 'long'.
 525 ###
 526 SCM_I_GSC_T_INTMAX=0
 527 if test "$scm_stdint_has_intmax"; then
 528   SCM_I_GSC_T_INTMAX='"intmax_t"'
 529   SCM_I_GSC_NEEDS_STDINT_H=1
 530 elif test "$scm_inttypes_has_intmax"; then
 531   SCM_I_GSC_T_INTMAX='"intmax_t"'
 532   SCM_I_GSC_NEEDS_INTTYPES_H=1
 533 elif test "$ac_cv_sizeof___int64" -ne 0; then
 534   SCM_I_GSC_T_INTMAX='"__int64"'
 535 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 536   SCM_I_GSC_T_INTMAX='"long long"'
 537 else
 538   SCM_I_GSC_T_INTMAX='"long"'
 539 fi
 540 AC_SUBST([SCM_I_GSC_T_INTMAX])
 541
 542 ### Required type scm_t_uintmax
 543 ###
 544 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 545 ### this order.  When none of them is available, we use 'unsigned long'.
 546 ###
 547 SCM_I_GSC_T_UINTMAX=0
 548 if test "$scm_stdint_has_uintmax"; then
 549   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 550   SCM_I_GSC_NEEDS_STDINT_H=1
 551 elif test "$scm_inttypes_has_uintmax"; then
 552   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 553   SCM_I_GSC_NEEDS_INTTYPES_H=1
 554 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 555   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 556 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 557   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 558 else
 559   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 560 fi
 561 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 562
 563 ### Required type scm_t_intptr
 564 ###
 565 SCM_I_GSC_T_INTPTR=0
 566 if test "$scm_stdint_has_intptr"; then
 567   SCM_I_GSC_T_INTPTR='"intptr_t"'
 568   SCM_I_GSC_NEEDS_STDINT_H=1
 569 elif test "$scm_inttypes_has_intptr"; then
 570   SCM_I_GSC_T_INTPTR='"intptr_t"'
 571   SCM_I_GSC_NEEDS_INTTYPES_H=1
 572 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 573   SCM_I_GSC_T_INTPTR='"int"'
 574 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 575   SCM_I_GSC_T_INTPTR='"long"'
 576 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 577   SCM_I_GSC_T_INTPTR='"long long"'
 578 else
 579   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 580 fi
 581 AC_SUBST([SCM_I_GSC_T_INTPTR])
 582
 583 ### Required type scm_t_uintptr
 584 ###
 585 SCM_I_GSC_T_UINTPTR=0
 586 if test "$scm_stdint_has_uintptr"; then
 587   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 588   SCM_I_GSC_NEEDS_STDINT_H=1
 589 elif test "$scm_inttypes_has_uintptr"; then
 590   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 591   SCM_I_GSC_NEEDS_INTTYPES_H=1
 592 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 593   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 594 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 595   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 596 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 597   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 598 else
 599   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 600 fi
 601 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 602
 603
 604 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 605 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 606
 607 AC_HEADER_STDC
 608 AC_HEADER_TIME
 609 AC_HEADER_SYS_WAIT
 610 AC_HEADER_DIRENT
 611
 612 # Reason for checking:
 613 #
 614 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 615 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 616 #
 617 AC_CHECK_MEMBER([struct dirent64.d_name],
 618   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 619   [ #ifndef _LARGEFILE64_SOURCE
 620     # define _LARGEFILE64_SOURCE
 621     #endif
 622
 623     /* Per Autoconf manual.  */
 624     #include <sys/types.h>
 625     #ifdef HAVE_DIRENT_H
 626     # include <dirent.h>
 627     #else
 628     # define dirent direct
 629     # ifdef HAVE_SYS_NDIR_H
 630     #  include <sys/ndir.h>
 631     # endif
 632     # ifdef HAVE_SYS_DIR_H
 633     #  include <sys/dir.h>
 634     # endif
 635     # ifdef HAVE_NDIR_H
 636     #  include <ndir.h>
 637     # endif
 638     #endif ])
 639 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 640
 641 # Reasons for testing:
 642 #   complex.h - new in C99
 643 #   fenv.h - available in C99, but not older systems
 644 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 645 #     this file instead of <fenv.h>
 646 #   process.h - mingw specific
 647 #   langinfo.h, nl_types.h - SuS v2
 648 #
 649 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 650 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 651 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 652 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 653 direct.h langinfo.h nl_types.h machine/fpu.h])
 654
 655 # Reasons for testing:
 656 #   nl_item - lacking on Cygwin
 657 AC_CHECK_TYPES([nl_item], [], [],
 658   [[#ifdef HAVE_LANGINFO_H
 659     # include <langinfo.h>
 660     #endif
 661     #ifdef HAVE_NL_TYPES_H
 662     # include <nl_types.h>
 663     #endif]])
 664
 665 # "complex double" is new in C99, and "complex" is only a keyword if
 666 # <complex.h> is included
 667 AC_CHECK_TYPES(complex double,,,
 668 [#if HAVE_COMPLEX_H
 669 #include <complex.h>
 670 #endif])
 671
 672 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 673 # when testing.
 674 AC_CHECK_TYPE(socklen_t, ,
 675   [AC_DEFINE_UNQUOTED([socklen_t], int,
 676                       [Define to `int' if <sys/socket.h> does not define.])],
 677   [#if HAVE_SYS_TYPES_H
 678 #include <sys/types.h>
 679 #endif
 680 #include <sys/socket.h>
 681 ])
 682 AC_CHECK_TYPE(struct ip_mreq)
 683
 684 GUILE_HEADER_LIBC_WITH_UNISTD
 685
 686 AC_TYPE_GETGROUPS
 687 AC_TYPE_SIGNAL
 688 AC_TYPE_MODE_T
 689
 690 # On mingw -lm is empty, so this test is unnecessary, but it's
 691 # harmless so we don't hard-code to suppress it.
 692 #
 693 AC_CHECK_LIB(m, cos)
 694
 695 AC_CHECK_FUNCS(gethostbyname)
 696 if test $ac_cv_func_gethostbyname = no; then
 697     AC_CHECK_LIB(nsl, gethostbyname)
 698 fi
 699
 700 AC_CHECK_FUNCS(connect)
 701 if test $ac_cv_func_connect = no; then
 702     AC_CHECK_LIB(socket, connect)
 703 fi
 704
 705 dnl
 706 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 707 dnl
 708 EXTRA_DEFS=""
 709 case $host in
 710   *-*-mingw*)
 711     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 712       [Define if you have the <winsock2.h> header file.])])
 713     AC_CHECK_LIB(ws2_32, main)
 714     AC_LIBOBJ([win32-uname])
 715     AC_LIBOBJ([win32-dirent])
 716     if test "$enable_networking" = yes ; then
 717       AC_LIBOBJ([win32-socket])
 718     fi
 719     if test "$enable_shared" = yes ; then
 720       EXTRA_DEFS="-DSCM_IMPORT"
 721       AC_DEFINE([USE_DLL_IMPORT], 1,
 722         [Define if you need additional CPP macros on Win32 platforms.])
 723     fi
 724     ;;
 725 esac
 726 AC_SUBST(EXTRA_DEFS)
 727
 728 # Reasons for testing:
 729 #   crt_externs.h - Darwin specific
 730 #
 731 AC_CHECK_HEADERS([assert.h crt_externs.h])
 732
 733 # Reasons for testing:
 734 #   DINFINITY - OSF specific
 735 #   DQNAN - OSF specific
 736 #       (DINFINITY and DQNAN are actually global variables, not functions)
 737 #   chsize - an MS-DOS-ism, found in mingw
 738 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 739 #       for gcc to provide the "complex double" type but the system to not
 740 #       have functions like cexp and clog
 741 #   clog10 - not in mingw (though others like clog and csqrt are)
 742 #   fesetround - available in C99, but not older systems
 743 #   ftruncate - posix, but probably not older systems (current mingw
 744 #               has it as an inline for chsize)
 745 #   ioctl - not in mingw.
 746 #   gmtime_r - recent posix, not on old systems
 747 #   pipe - not in mingw
 748 #   _pipe - specific to mingw, taking 3 args
 749 #   readdir_r - recent posix, not on old systems
 750 #   readdir64_r - not available on HP-UX 11.11
 751 #   stat64 - SuS largefile stuff, not on old systems
 752 #   sysconf - not on old systems
 753 #   truncate - not in mingw
 754 #   isblank - available as a GNU extension or in C99
 755 #   _NSGetEnviron - Darwin specific
 756 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 757 #   nl_langinfo - X/Open, not available on Windows.
 758 #   utimensat: posix.1-2008
 759 #
 760 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat])
 761
 762 # Reasons for testing:
 763 #   netdb.h - not in mingw
 764 #   sys/param.h - not in mingw
 765 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 766 #       check this specifically, we need it for the timespec test below.
 767 #   sethostname - the function itself check because it's not in mingw,
 768 #       the DECL is checked because Solaris 10 doens't have in any header
 769 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 770 #       declaration isn't anywhere.
 771 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 772 #       only with `_XOPEN_SOURCE' or some such.
 773 #
 774 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h])
 775 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 776 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 777
 778 # crypt() may or may not be available, for instance in some countries there
 779 # are restrictions on cryptography.
 780 #
 781 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 782 # -lcrypt library (eg. Debian GNU/Linux).
 783 #
 784 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 785 # be careful to avoid -lcrypt in this case, since libtool will see there's
 786 # only a static libcrypt and decide to build only a static libguile.
 787 #
 788 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 789 # libraries already in that list.
 790 #
 791 AC_SEARCH_LIBS(crypt, crypt,
 792   [AC_DEFINE([HAVE_CRYPT],1,
 793              [Define to 1 if you have the `crypt' function.])])
 794
 795 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 796 # work; in the reported cases so far, 1.0fi works well instead.  According
 797 # to the C99 spec, the complex.h header must provide a working definition
 798 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 799 # is a workaround for the failure of some systems to conform to C99.
 800 if test "$ac_cv_type_complex_double" = yes; then
 801   AC_MSG_CHECKING([for i])
 802   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 803 #if HAVE_COMPLEX_H
 804 #include <complex.h>
 805 #endif
 806 complex double z;
 807 ]], [[
 808 z = _Complex_I;
 809 ]])],
 810     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 811      AC_MSG_RESULT([_Complex_I])],
 812     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 813 #if HAVE_COMPLEX_H
 814 #include <complex.h>
 815 #endif
 816 complex double z;
 817 ]],[[
 818 z = 1.0fi;
 819 ]])],
 820   [AC_DEFINE([GUILE_I],1.0fi)
 821    AC_MSG_RESULT([1.0fi])],
 822   [ac_cv_type_complex_double=no
 823    AC_MSG_RESULT([not available])])])
 824 fi
 825
 826 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 827 # csqrt(-i) returned a negative real part, when it should be positive
 828 # for the principal root.
 829 #
 830 if test "$ac_cv_type_complex_double" = yes; then
 831
 832   AC_CACHE_CHECK([whether csqrt is usable],
 833     guile_cv_use_csqrt,
 834     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 835 #include <complex.h>
 836 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 837    constant, we want to test libc. */
 838 volatile complex double z = - _Complex_I;
 839 int
 840 main (void)
 841 {
 842   z = csqrt (z);
 843   if (creal (z) > 0.0)
 844     return 0;  /* good */
 845   else
 846     return 1;  /* bad */
 847 }]])],
 848     [guile_cv_use_csqrt=yes],
 849     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 850     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 851   case $guile_cv_use_csqrt in
 852     yes*)
 853       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 854       ;;
 855   esac
 856 fi
 857
 858
 859 dnl GMP tests
 860 AC_LIB_HAVE_LINKFLAGS([gmp],
 861   [],
 862   [#include <gmp.h>],
 863   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 864
 865 if test "x$HAVE_LIBGMP" != "xyes"; then
 866   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 867 fi
 868
 869 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 870 if test "x$LTLIBUNISTRING" != "x"; then
 871   LIBS="$LTLIBUNISTRING $LIBS"
 872 else
 873   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 874 fi
 875
 876 dnl Libffi is needed to compile Guile's foreign function interface, but its
 877 dnl interface isn't exposed in Guile's API.
 878 PKG_CHECK_MODULES(LIBFFI, libffi)
 879 AC_SUBST(LIBFFI_CFLAGS)
 880 AC_SUBST(LIBFFI_LIBS)
 881
 882 dnl figure out approriate ffi type for size_t
 883 AC_CHECK_SIZEOF(size_t)
 884 AC_CHECK_SIZEOF(ssize_t)
 885 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 886 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 887 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 888                    [ffi type for size_t])
 889 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 890                    [ffi type for ssize_t])
 891
 892 dnl i18n tests
 893 #AC_CHECK_HEADERS([libintl.h])
 894 #AC_CHECK_FUNCS(gettext)
 895 #if test $ac_cv_func_gettext = no; then
 896 #   AC_CHECK_LIB(intl, gettext)
 897 #fi
 898 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 899 AM_GNU_GETTEXT([external], [need-ngettext])
 900
 901 ### Some systems don't declare some functions.  On such systems, we
 902 ### need to at least provide our own K&R-style declarations.
 903
 904 ### GUILE_FUNC_DECLARED(function, headerfile)
 905
 906 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 907 ### not there, #define MISSING_FUNCTION_DECL.
 908 AC_DEFUN([GUILE_FUNC_DECLARED], [
 909   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 910     AC_EGREP_HEADER($1, $2,
 911                     guile_cv_func_$1_declared=yes,
 912                     guile_cv_func_$1_declared=no))
 913   if test [x$guile_cv_func_]$1[_declared] = xno; then
 914     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 915       [Define if the operating system supplies $1 without declaring it.])
 916   fi
 917 ])
 918
 919 GUILE_FUNC_DECLARED(sleep, unistd.h)
 920 GUILE_FUNC_DECLARED(usleep, unistd.h)
 921
 922 AC_CHECK_DECLS([strptime],,,
 923 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 924 #include <time.h>])
 925
 926 ### On some systems usleep has no return value.  If it does have one,
 927 ### we'd like to return it; otherwise, we'll fake it.
 928 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 929   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 930                    unistd.h,
 931                    [guile_cv_func_usleep_return_type=void],
 932                    [guile_cv_func_usleep_return_type=int])])
 933 case "$guile_cv_func_usleep_return_type" in
 934   "void" )
 935     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 936       [Define if the system headers declare usleep to return void.])
 937   ;;
 938 esac
 939
 940 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 941 if test -n "$have_sys_un_h" ; then
 942   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 943     [Define if the system supports Unix-domain (file-domain) sockets.])
 944 fi
 945
 946 AC_CHECK_FUNCS(getrlimit setrlimit)
 947
 948 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 949
 950 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 951                setnetent    getnetent    endnetent    dnl
 952                setprotoent  getprotoent  endprotoent  dnl
 953                setservent   getservent   endservent   dnl
 954                getnetbyaddr getnetbyname dnl
 955                inet_lnaof inet_makeaddr inet_netof hstrerror)
 956
 957 # struct sockaddr field sin_len is only present on BSD systems.
 958 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 959 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 960 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 961 [#ifdef HAVE_SYS_TYPES_H
 962 #include <sys/types.h>
 963 #endif
 964 #include <netinet/in.h>])
 965
 966 AC_MSG_CHECKING(for __libc_stack_end)
 967 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 968 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 969 extern char *__libc_stack_end;]],
 970    [[printf("%p", (char*) __libc_stack_end);]])],
 971    [guile_cv_have_libc_stack_end=yes],
 972    [guile_cv_have_libc_stack_end=no])])
 973 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 974
 975 if test $guile_cv_have_libc_stack_end = yes; then
 976   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 977            [Define if you have the __libc_stack_end variable.])
 978 fi
 979
 980 dnl Some systems do not declare this.  Some systems do declare it, as a
 981 dnl macro.  With cygwin it may be in a DLL.
 982
 983 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 984 AC_CACHE_VAL(guile_cv_have_h_errno,
 985   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 986                                       [[int a = h_errno;]])],
 987   [guile_cv_have_h_errno=yes],
 988   [guile_cv_have_h_errno=no])])
 989 AC_MSG_RESULT($guile_cv_have_h_errno)
 990 if test $guile_cv_have_h_errno = yes; then
 991   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
 992 fi
 993
 994 AC_MSG_CHECKING(whether uint32_t is defined)
 995 AC_CACHE_VAL(guile_cv_have_uint32_t,
 996   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 997                    #if HAVE_STDINT_H
 998                    #include <stdint.h>
 999                    #endif
1000                    #ifndef HAVE_NETDB_H
1001                    #include <netdb.h>
1002                    #endif]],
1003                    [[uint32_t a;]])],
1004                    [guile_cv_have_uint32_t=yes],
1005                    [guile_cv_have_uint32_t=no])])
1006 AC_MSG_RESULT($guile_cv_have_uint32_t)
1007 if test $guile_cv_have_uint32_t = yes; then
1008   AC_DEFINE([HAVE_UINT32_T], 1,
1009     [Define if uint32_t typedef is defined when netdb.h is include.])
1010 fi
1011
1012 AC_MSG_CHECKING(for working IPv6 support)
1013 AC_CACHE_VAL(guile_cv_have_ipv6,
1014 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1015 #ifdef HAVE_SYS_TYPES_H
1016 #include <sys/types.h>
1017 #endif
1018 #include <netinet/in.h>
1019 #include <sys/socket.h>]],
1020 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1021 [guile_cv_have_ipv6=yes],
1022 [guile_cv_have_ipv6=no])])
1023 AC_MSG_RESULT($guile_cv_have_ipv6)
1024 if test $guile_cv_have_ipv6 = yes; then
1025   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1026 fi
1027
1028 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1029 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1030 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1031 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1032 #ifdef HAVE_SYS_TYPES_H
1033 #include <sys/types.h>
1034 #endif
1035 #include <netinet/in.h>]],
1036 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1037 [guile_cv_have_sin6_scope_id=yes],
1038 [guile_cv_have_sin6_scope_id=no])])
1039 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1040 if test $guile_cv_have_sin6_scope_id = yes; then
1041   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1042     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1043 fi
1044
1045 # struct sockaddr_in6 field sin_len is only present on BSD systems
1046 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1047 [#ifdef HAVE_SYS_TYPES_H
1048 #include <sys/types.h>
1049 #endif
1050 #include <netinet/in.h>])
1051
1052 AC_MSG_CHECKING(whether localtime caches TZ)
1053 AC_CACHE_VAL(guile_cv_localtime_cache,
1054 [if test x$ac_cv_func_tzset = xyes; then
1055 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1056 #if STDC_HEADERS
1057 # include <stdlib.h>
1058 #endif
1059 extern char **environ;
1060 unset_TZ ()
1061 {
1062   char **from, **to;
1063   for (to = from = environ; (*to = *from); from++)
1064     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1065       to++;
1066 }
1067 char TZ_GMT0[] = "TZ=GMT0";
1068 char TZ_PST8[] = "TZ=PST8";
1069 main()
1070 {
1071   time_t now = time ((time_t *) 0);
1072   int hour_GMT0, hour_unset;
1073   if (putenv (TZ_GMT0) != 0)
1074     exit (1);
1075   hour_GMT0 = localtime (&now)->tm_hour;
1076   unset_TZ ();
1077   hour_unset = localtime (&now)->tm_hour;
1078   if (putenv (TZ_PST8) != 0)
1079     exit (1);
1080   if (localtime (&now)->tm_hour == hour_GMT0)
1081     exit (1);
1082   unset_TZ ();
1083   if (localtime (&now)->tm_hour != hour_unset)
1084     exit (1);
1085   exit (0);
1086 }]])],
1087 [guile_cv_localtime_cache=no],
1088 [guile_cv_localtime_cache=yes],
1089 [# If we have tzset, assume the worst when cross-compiling.
1090 guile_cv_localtime_cache=yes])
1091 else
1092         # If we lack tzset, report that localtime does not cache TZ,
1093         # since we can't invalidate the cache if we don't have tzset.
1094         guile_cv_localtime_cache=no
1095 fi])dnl
1096 AC_MSG_RESULT($guile_cv_localtime_cache)
1097 if test $guile_cv_localtime_cache = yes; then
1098   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1099 fi
1100
1101 if test "$enable_regex" = yes; then
1102    if test "$ac_cv_header_regex_h" = yes ||
1103       test "$ac_cv_header_rxposix_h" = yes ||
1104       test "$ac_cv_header_rx_rxposix_h" = yes; then
1105      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1106      [AC_CHECK_LIB(rx, main)
1107       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1108      [AC_CHECK_LIB(regex, main)
1109       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1110      )
1111      dnl The following should not be necessary, but for some reason
1112      dnl autoheader misses it if we don't include it!
1113      if test "$ac_cv_func_regcomp_norx" = yes ||
1114         test "$ac_cv_func_regcomp_regex" = yes ||
1115         test "$ac_cv_func_regcomp_rx" = yes; then
1116        AC_DEFINE([HAVE_REGCOMP], 1,
1117          [This is included as part of a workaround for a autoheader bug.])
1118      fi
1119    fi
1120 fi
1121
1122 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1123
1124 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
1125
1126 # Reasons for testing:
1127 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1128 #                                older systems
1129 #   sincos - GLIBC extension
1130 #
1131 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1132
1133 # C99 specifies isinf and isnan as macros.
1134 # HP-UX provides only macros, no functions.
1135 # glibc 2.3.2 provides both macros and functions.
1136 # IRIX 6.5 and Solaris 8 only provide functions.
1137 #
1138 # The following tests detect isinf and isnan either as functions or as
1139 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1140 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1141 #
1142 AC_MSG_CHECKING([for isinf])
1143 AC_LINK_IFELSE(AC_LANG_SOURCE(
1144 [[#include <math.h>
1145 volatile double x = 0.0;
1146 int main () { return (isinf(x) != 0); }]]),
1147   [AC_MSG_RESULT([yes])
1148    AC_DEFINE([HAVE_ISINF], 1,
1149              [Define to 1 if you have the `isinf' macro or function.])],
1150   [AC_MSG_RESULT([no])])
1151 AC_MSG_CHECKING([for isnan])
1152 AC_LINK_IFELSE(AC_LANG_SOURCE(
1153 [[#include <math.h>
1154 volatile double x = 0.0;
1155 int main () { return (isnan(x) != 0); }]]),
1156   [AC_MSG_RESULT([yes])
1157    AC_DEFINE([HAVE_ISNAN], 1,
1158              [Define to 1 if you have the `isnan' macro or function.])],
1159   [AC_MSG_RESULT([no])])
1160
1161 # Reasons for checking:
1162 #
1163 #     st_rdev
1164 #     st_blksize
1165 #     st_blocks   not in mingw
1166 #     tm_gmtoff   BSD+GNU, not in C99
1167 #
1168 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1169 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1170 #
1171 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1172                  [#define _GNU_SOURCE
1173 AC_INCLUDES_DEFAULT
1174 ])
1175
1176 AC_STRUCT_TIMEZONE
1177 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1178 [#include <time.h>
1179 #ifdef TIME_WITH_SYS_TIME
1180 # include <sys/time.h>
1181 # include <time.h>
1182 #else
1183 # if HAVE_SYS_TIME_H
1184 #  include <sys/time.h>
1185 # else
1186 #  include <time.h>
1187 # endif
1188 #endif
1189 ])
1190 GUILE_STRUCT_UTIMBUF
1191
1192
1193 #--------------------------------------------------------------------
1194 #
1195 # Which way does the stack grow?
1196 #
1197 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1198 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1199 # very similar code, so in future we could look at using that.
1200 #
1201 # An important detail is that the code involves find_stack_direction
1202 # calling _itself_ - which means that find_stack_direction (or at
1203 # least the second find_stack_direction() call) cannot be inlined.
1204 # If the code could be inlined, that might cause the test to give
1205 # an incorrect answer.
1206 #--------------------------------------------------------------------
1207
1208 SCM_I_GSC_STACK_GROWS_UP=0
1209 AC_RUN_IFELSE([AC_LANG_SOURCE(
1210 [AC_INCLUDES_DEFAULT
1211 int
1212 find_stack_direction ()
1213 {
1214   static char *addr = 0;
1215   auto char dummy;
1216   if (addr == 0)
1217     {
1218       addr = &dummy;
1219       return find_stack_direction ();
1220     }
1221   else
1222     return (&dummy > addr) ? 1 : -1;
1223 }
1224
1225 int
1226 main ()
1227 {
1228   return find_stack_direction () < 0;
1229 }])],
1230                [SCM_I_GSC_STACK_GROWS_UP=1],
1231                [],
1232                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1233
1234 #--------------------------------------------------------------------
1235 #
1236 # Boehm's GC library
1237 #
1238 #--------------------------------------------------------------------
1239 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1240
1241 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1242 LIBS="$BDW_GC_LIBS $LIBS"
1243
1244 # `GC_do_blocking ()' is available in GC 7.1 but not declared.
1245 AC_CHECK_FUNCS([GC_do_blocking])
1246 AC_CHECK_DECL([GC_do_blocking],
1247   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1248     [Define this if the `GC_do_blocking ()' function is declared])],
1249   [],
1250   [#include <gc/gc.h>])
1251
1252 # `GC_fn_type' is not available in GC 7.1 and earlier.
1253 AC_CHECK_TYPE([GC_fn_type],
1254   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1255     [Define this if the `GC_fn_type' type is available.])],
1256   [],
1257   [#include <gc/gc.h>])
1258
1259
1260 AC_CHECK_SIZEOF(float)
1261 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1262     AC_DEFINE([SCM_SINGLES], 1,
1263               [Define this if floats are the same size as longs.])
1264 fi
1265
1266 AC_MSG_CHECKING(for struct linger)
1267 AC_CACHE_VAL(scm_cv_struct_linger,
1268         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1269 #include <sys/types.h>
1270 #include <sys/socket.h>]],
1271                           [[struct linger lgr;  lgr.l_linger = 100]])],
1272                           [scm_cv_struct_linger="yes"],
1273                           [scm_cv_struct_linger="no"]))
1274 AC_MSG_RESULT($scm_cv_struct_linger)
1275 if test $scm_cv_struct_linger = yes; then
1276         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1277           [Define this if your system defines struct linger, for use with the
1278            getsockopt and setsockopt system calls.])
1279 fi
1280
1281
1282 # On mingw, struct timespec is in <pthread.h>.
1283 #
1284 AC_MSG_CHECKING(for struct timespec)
1285 AC_CACHE_VAL(scm_cv_struct_timespec,
1286         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1287 #include <time.h>
1288 #if HAVE_PTHREAD_H
1289 #include <pthread.h>
1290 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1291           [scm_cv_struct_timespec="yes"],
1292           [scm_cv_struct_timespec="no"]))
1293 AC_MSG_RESULT($scm_cv_struct_timespec)
1294 if test $scm_cv_struct_timespec = yes; then
1295   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1296     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1297 fi
1298
1299 #--------------------------------------------------------------------
1300 #
1301 # Flags for thread support
1302 #
1303 #--------------------------------------------------------------------
1304
1305 SCM_I_GSC_USE_PTHREAD_THREADS=0
1306 SCM_I_GSC_USE_NULL_THREADS=0
1307 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1308 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1309
1310 ### What thread package has the user asked for?
1311 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1312             , with_threads=yes)
1313
1314 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1315 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1316
1317 case "$with_threads" in
1318   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1319
1320     build_pthread_support="yes"
1321
1322     ACX_PTHREAD([CC="$PTHREAD_CC"
1323        LIBS="$PTHREAD_LIBS $LIBS"
1324        SCM_I_GSC_USE_PTHREAD_THREADS=1
1325        with_threads="pthreads"],
1326       [with_threads="null"
1327        build_pthread_support="no"])
1328
1329     old_CFLAGS="$CFLAGS"
1330     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1331
1332     # Reasons for testing:
1333     #     pthread_getattr_np - "np" meaning "non portable" says it
1334     #         all; not present on MacOS X or Solaris 10
1335     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1336     #         all; specific to MacOS X
1337     #     pthread_sigmask - not available on mingw
1338     #
1339     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1340
1341     # On past versions of Solaris, believe 8 through 10 at least, you
1342     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1343     # This is contrary to POSIX:
1344     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1345     # Check here if this style is required.
1346     #
1347     # glibc (2.3.6 at least) works both with or without braces, so the
1348     # test checks whether it works without.
1349     #
1350
1351     if test "$GCC" = "yes"; then
1352       # Since GCC only issues a warning for missing braces, so we need
1353       # `-Werror' to catch it.
1354       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1355     fi
1356
1357     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1358       guile_cv_need_braces_on_pthread_once_init,
1359       [AC_COMPILE_IFELSE([#include <pthread.h>
1360          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1361         [guile_cv_need_braces_on_pthread_once_init=no],
1362         [guile_cv_need_braces_on_pthread_once_init=yes])])
1363     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1364       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1365     fi
1366
1367     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1368     # 6.5.30m with GCC 3.3.
1369     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1370       guile_cv_need_braces_on_pthread_mutex_initializer,
1371       [AC_COMPILE_IFELSE([#include <pthread.h>
1372          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1373         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1374         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1375     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1376       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1377     fi
1378
1379     CFLAGS="$old_CFLAGS"
1380
1381     # On Solaris, sched_yield lives in -lrt.
1382     AC_SEARCH_LIBS(sched_yield, rt)
1383
1384   ;;
1385 esac
1386
1387 case "$with_threads" in
1388   "pthreads")
1389   ;;
1390   "no" | "null")
1391     SCM_I_GSC_USE_NULL_THREADS=1
1392     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1393     with_threads="null-threads"
1394   ;;
1395   * )
1396     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1397   ;;
1398 esac
1399
1400 AC_MSG_CHECKING(what kind of threads to support)
1401 AC_MSG_RESULT($with_threads)
1402
1403 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1404   [test "x$build_pthread_support" = "xyes"])
1405
1406
1407 ## Check whether pthread_attr_getstack works for the main thread
1408
1409 if test "$with_threads" = pthreads; then
1410
1411 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1412 old_CFLAGS="$CFLAGS"
1413 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1414 if test "$cross_compiling" = "no"; then
1415   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1416   #if HAVE_PTHREAD_ATTR_GETSTACK
1417   #include <pthread.h>
1418
1419   int main ()
1420   {
1421     pthread_attr_t attr;
1422     void *start, *end;
1423     size_t size;
1424
1425     pthread_getattr_np (pthread_self (), &attr);
1426     pthread_attr_getstack (&attr, &start, &size);
1427     end = (char *)start + size;
1428
1429     if ((void *)&attr < start || (void *)&attr >= end)
1430       return 1;
1431     else
1432       return 0;
1433   }
1434   #else
1435   int main ()
1436   {
1437     return 1;
1438   }
1439   #endif
1440   ]])],
1441   [works=yes
1442    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1443   [works=no],
1444   [])
1445 else
1446   works="assuming it doesn't"
1447 fi
1448 CFLAGS="$old_CFLAGS"
1449 AC_MSG_RESULT($works)
1450
1451 GUILE_THREAD_LOCAL_STORAGE
1452
1453 fi # with_threads=pthreads
1454
1455
1456 ## Cross building
1457 if test "$cross_compiling" = "yes"; then
1458   AC_MSG_CHECKING(cc for build)
1459   ## /usr/bin/cc still uses wrong assembler
1460   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1461   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1462 else
1463   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1464 fi
1465
1466 ## AC_MSG_CHECKING("if we are cross compiling")
1467 ## AC_MSG_RESULT($cross_compiling)
1468 if test "$cross_compiling" = "yes"; then
1469    AC_MSG_RESULT($CC_FOR_BUILD)
1470 fi
1471
1472 ## No need as yet to be more elaborate
1473 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1474
1475 AC_SUBST(cross_compiling)
1476 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1477 AC_SUBST(CCLD_FOR_BUILD)
1478
1479 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1480 ## --HOST is the platform that PACKAGE is compiled for.
1481 HOST_CC="$CC_FOR_BUILD"
1482 AC_SUBST(HOST_CC)
1483
1484 if test "$cross_compiling" = "yes"; then
1485   AC_MSG_CHECKING(guile for build)
1486   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1487 else
1488   GUILE_FOR_BUILD='$(preinstguile)'
1489 fi
1490
1491 ## AC_MSG_CHECKING("if we are cross compiling")
1492 ## AC_MSG_RESULT($cross_compiling)
1493 if test "$cross_compiling" = "yes"; then
1494    AC_MSG_RESULT($GUILE_FOR_BUILD)
1495 fi
1496 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1497 AC_SUBST(GUILE_FOR_BUILD)
1498
1499 ## If we're using GCC, ask for aggressive warnings.
1500 GCC_CFLAGS=""
1501 case "$GCC" in
1502   yes )
1503     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1504     ## much stuff with generic function pointers for that to really be
1505     ## less than exasperating.
1506     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1507     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1508     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1509       -Wdeclaration-after-statement -Wundef \
1510       -Wswitch-enum"
1511     # Do this here so we don't screw up any of the tests above that might
1512     # not be "warning free"
1513     if test "${GUILE_ERROR_ON_WARNING}" = yes
1514     then
1515         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1516         enable_compile_warnings=no
1517     fi
1518
1519     for flag in $POTENTIAL_GCC_CFLAGS
1520     do
1521         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1522     done
1523     ;;
1524 esac
1525
1526 AC_SUBST(GCC_CFLAGS)
1527
1528 # Check for GNU ld's "-z relro".
1529 GUILE_GNU_LD_RELRO
1530
1531
1532 ## If we're creating a shared library (using libtool!), then we'll
1533 ## need to generate a list of .lo files corresponding to the .o files
1534 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1535 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1536
1537 ## We also need to create corresponding .doc and .x files
1538 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1539 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1540
1541 # GNU Readline bindings.
1542 GUILE_READLINE
1543
1544 AC_SUBST(GUILE_MAJOR_VERSION)
1545 AC_SUBST(GUILE_MINOR_VERSION)
1546 AC_SUBST(GUILE_MICRO_VERSION)
1547 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1548 AC_SUBST(GUILE_VERSION)
1549
1550 #######################################################################
1551 # library versioning
1552
1553 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1554 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1555 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1556 AC_SUBST(LIBGUILE_INTERFACE)
1557
1558 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1559 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1560 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1561 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1562 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1563
1564 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1565 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1566 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1567 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1568 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1569
1570 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1571 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1572 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1573 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1574 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1575
1576 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1577 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1578 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1579 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1580 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1581
1582 AC_SUBST(LIBGUILE_I18N_MAJOR)
1583 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1584 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1585 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1586 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1587
1588
1589 #######################################################################
1590
1591 dnl Tell guile-config what flags guile users should compile and link with.
1592 GUILE_LIBS="$LDFLAGS $LIBS"
1593 GUILE_CFLAGS="$CPPFLAGS $PTHREAD_CFLAGS"
1594 AC_SUBST(GUILE_LIBS)
1595 AC_SUBST(GUILE_CFLAGS)
1596
1597 AC_SUBST(AWK)
1598 AC_SUBST(LIBLOBJS)
1599 AC_SUBST(EXTRA_DOT_DOC_FILES)
1600 AC_SUBST(EXTRA_DOT_X_FILES)
1601
1602 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1603 top_builddir_absolute=`pwd`
1604 AC_SUBST(top_builddir_absolute)
1605 top_srcdir_absolute=`(cd $srcdir && pwd)`
1606 AC_SUBST(top_srcdir_absolute)
1607
1608 dnl We need `sitedir' in `guile-1.8.pc'.
1609 dnl Note: `sitedir' must be kept in sync with `GUILE_SITE_DIR' in `guile.m4'.
1610 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1611 sitedir="$pkgdatadir/site"
1612 AC_SUBST([sitedir])
1613
1614 # Additional SCM_I_GSC definitions are above.
1615 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1616 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1617 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1618 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1619 AC_SUBST([SCM_I_GSC_C_INLINE])
1620 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1621
1622 AC_CONFIG_FILES([
1623   Makefile
1624   am/Makefile
1625   lib/Makefile
1626   benchmark-suite/Makefile
1627   doc/Makefile
1628   doc/r5rs/Makefile
1629   doc/ref/Makefile
1630   emacs/Makefile
1631   examples/Makefile
1632   libguile/Makefile
1633   srfi/Makefile
1634   guile-readline/Makefile
1635   test-suite/Makefile
1636   test-suite/standalone/Makefile
1637   test-suite/vm/Makefile
1638   meta/Makefile
1639   module/Makefile
1640 ])
1641
1642 AC_CONFIG_FILES([meta/guile-2.0.pc])
1643 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1644 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1645
1646 GUILE_CONFIG_SCRIPT([check-guile])
1647 GUILE_CONFIG_SCRIPT([benchmark-guile])
1648 GUILE_CONFIG_SCRIPT([meta/guile])
1649 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1650 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1651 GUILE_CONFIG_SCRIPT([meta/guile-tools])
1652 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1653 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1654 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1655 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1656
1657 AC_OUTPUT
1658
1659 dnl Local Variables:
1660 dnl comment-start: "dnl "
1661 dnl comment-end: ""
1662 dnl comment-start-skip: "\\bdnl\\b\\s *"
1663 dnl End: