test-suite/tests/ports.test

   1 ;;;; ports.test --- Guile I/O ports.    -*- coding: utf-8; mode: scheme; -*-
   2 ;;;; Jim Blandy <jimb@red-bean.com> --- May 1999
   3 ;;;;
   4 ;;;;    Copyright (C) 1999, 2001, 2004, 2006, 2007, 2009, 2010,
   5 ;;;;      2011 Free Software Foundation, Inc.
   6 ;;;;
   7 ;;;; This library is free software; you can redistribute it and/or
   8 ;;;; modify it under the terms of the GNU Lesser General Public
   9 ;;;; License as published by the Free Software Foundation; either
  10 ;;;; version 3 of the License, or (at your option) any later version.
  11 ;;;;
  12 ;;;; This library is distributed in the hope that it will be useful,
  13 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;;;; Lesser General Public License for more details.
  16 ;;;;
  17 ;;;; You should have received a copy of the GNU Lesser General Public
  18 ;;;; License along with this library; if not, write to the Free Software
  19 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  20
  21 (define-module (test-suite test-ports)
  22   #:use-module (test-suite lib)
  23   #:use-module (test-suite guile-test)
  24   #:use-module (ice-9 popen)
  25   #:use-module (ice-9 rdelim)
  26   #:use-module (rnrs bytevectors)
  27   #:use-module ((rnrs io ports) #:select (open-bytevector-input-port)))
  28
  29 (define (display-line . args)
  30   (for-each display args)
  31   (newline))
  32
  33 (define (test-file)
  34   (data-file-name "ports-test.tmp"))
  35
  36 \f
  37 ;;;; Some general utilities for testing ports.
  38
  39 ;; Make sure we are set up for 8-bit Latin-1 data.
  40 (fluid-set! %default-port-encoding "ISO-8859-1")
  41 (for-each (lambda (p)
  42             (set-port-encoding! p (fluid-ref %default-port-encoding)))
  43           (list (current-input-port) (current-output-port)
  44                 (current-error-port)))
  45
  46 ;;; Read from PORT until EOF, and return the result as a string.
  47 (define (read-all port)
  48   (let loop ((chars '()))
  49     (let ((char (read-char port)))
  50       (if (eof-object? char)
  51           (list->string (reverse! chars))
  52           (loop (cons char chars))))))
  53
  54 (define (read-file filename)
  55   (let* ((port (open-input-file filename))
  56          (string (read-all port)))
  57     (close-port port)
  58     string))
  59
  60 \f
  61 ;;;; Normal file ports.
  62
  63 ;;; Write out an s-expression, and read it back.
  64 (let ((string '("From fairest creatures we desire increase,"
  65                 "That thereby beauty's rose might never die,"))
  66       (filename (test-file)))
  67   (let ((port (open-output-file filename)))
  68     (write string port)
  69     (close-port port))
  70   (let ((port (open-input-file filename)))
  71     (let ((in-string (read port)))
  72       (pass-if "file: write and read back list of strings"
  73                (equal? string in-string)))
  74     (close-port port))
  75   (delete-file filename))
  76
  77 ;;; Write out a string, and read it back a character at a time.
  78 (let ((string "This is a test string\nwith no newline at the end")
  79       (filename (test-file)))
  80   (let ((port (open-output-file filename)))
  81     (display string port)
  82     (close-port port))
  83   (let ((in-string (read-file filename)))
  84     (pass-if "file: write and read back characters"
  85              (equal? string in-string)))
  86   (delete-file filename))
  87
  88 ;;; Buffered input/output port with seeking.
  89 (let* ((filename (test-file))
  90        (port (open-file filename "w+")))
  91   (display "J'Accuse" port)
  92   (seek port -1 SEEK_CUR)
  93   (pass-if "file: r/w 1"
  94            (char=? (read-char port) #\e))
  95   (pass-if "file: r/w 2"
  96            (eof-object? (read-char port)))
  97   (seek port -1 SEEK_CUR)
  98   (write-char #\x port)
  99   (seek port 7 SEEK_SET)
 100   (pass-if "file: r/w 3"
 101            (char=? (read-char port) #\x))
 102   (seek port -2 SEEK_END)
 103   (pass-if "file: r/w 4"
 104            (char=? (read-char port) #\s))
 105   (close-port port)
 106   (delete-file filename))
 107
 108 ;;; Unbuffered input/output port with seeking.
 109 (let* ((filename (test-file))
 110        (port (open-file filename "w+0")))
 111   (display "J'Accuse" port)
 112   (seek port -1 SEEK_CUR)
 113   (pass-if "file: ub r/w 1"
 114            (char=? (read-char port) #\e))
 115   (pass-if "file: ub r/w 2"
 116            (eof-object? (read-char port)))
 117   (seek port -1 SEEK_CUR)
 118   (write-char #\x port)
 119   (seek port 7 SEEK_SET)
 120   (pass-if "file: ub r/w 3"
 121            (char=? (read-char port) #\x))
 122   (seek port -2 SEEK_END)
 123   (pass-if "file: ub r/w 4"
 124            (char=? (read-char port) #\s))
 125   (close-port port)
 126   (delete-file filename))
 127
 128 ;;; Buffered output-only and input-only ports with seeking.
 129 (let* ((filename (test-file))
 130        (port (open-output-file filename)))
 131   (display "J'Accuse" port)
 132   (pass-if "file: out tell"
 133            (= (seek port 0 SEEK_CUR) 8))
 134   (seek port -1 SEEK_CUR)
 135   (write-char #\x port)
 136   (close-port port)
 137   (let ((iport (open-input-file filename)))
 138     (pass-if "file: in tell 0"
 139              (= (seek iport 0 SEEK_CUR) 0))
 140     (read-char iport)
 141     (pass-if "file: in tell 1"
 142              (= (seek iport 0 SEEK_CUR) 1))
 143     (unread-char #\z iport)
 144     (pass-if "file: in tell 0 after unread"
 145              (= (seek iport 0 SEEK_CUR) 0))
 146     (pass-if "file: unread char still there"
 147              (char=? (read-char iport) #\z))
 148     (seek iport 7 SEEK_SET)
 149     (pass-if "file: in last char"
 150              (char=? (read-char iport) #\x))
 151     (close-port iport))
 152   (delete-file filename))
 153
 154 ;;; unusual characters.
 155 (let* ((filename (test-file))
 156        (port (open-output-file filename)))
 157   (display (string #\nul (integer->char 255) (integer->char 128)
 158                    #\nul) port)
 159   (close-port port)
 160   (let* ((port (open-input-file filename))
 161          (line (read-line port)))
 162     (pass-if "file: read back NUL 1"
 163              (char=? (string-ref line 0) #\nul))
 164     (pass-if "file: read back 255"
 165              (char=? (string-ref line 1) (integer->char 255)))
 166     (pass-if "file: read back 128"
 167              (char=? (string-ref line 2) (integer->char 128)))
 168     (pass-if "file: read back NUL 2"
 169              (char=? (string-ref line 3) #\nul))
 170     (pass-if "file: EOF"
 171              (eof-object? (read-char port)))
 172     (close-port port))
 173   (delete-file filename))
 174
 175 ;;; line buffering mode.
 176 (let* ((filename (test-file))
 177        (port (open-file filename "wl"))
 178        (test-string "one line more or less"))
 179   (write-line test-string port)
 180   (let* ((in-port (open-input-file filename))
 181          (line (read-line in-port)))
 182     (close-port in-port)
 183     (close-port port)
 184     (pass-if "file: line buffering"
 185              (string=? line test-string)))
 186   (delete-file filename))
 187
 188 ;;; read-line should use the port encoding (not the locale encoding).
 189 (let ((str "ĉu bone?"))
 190   (with-locale "C"
 191                (let* ((filename (test-file))
 192                       (port (open-file filename "wl")))
 193                  (set-port-encoding! port "UTF-8")
 194                  (write-line str port)
 195                  (let ((in-port (open-input-file filename)))
 196                    (set-port-encoding! in-port "UTF-8")
 197                    (let ((line (read-line in-port)))
 198                      (close-port in-port)
 199                      (close-port port)
 200                      (pass-if "file: read-line honors port encoding"
 201                               (string=? line str))))
 202                  (delete-file filename))))
 203
 204 ;;; binary mode ignores port encoding
 205 (pass-if "file: binary mode ignores port encoding"
 206   (with-fluids ((%default-port-encoding "UTF-8"))
 207                (let* ((filename (test-file))
 208                       (port (open-file filename "w"))
 209                       (test-string "一二三")
 210                       (binary-test-string
 211                        (apply string
 212                               (map integer->char
 213                                    (uniform-vector->list
 214                                     (string->utf8 test-string))))))
 215                  (write-line test-string port)
 216                  (close-port port)
 217                  (let* ((in-port (open-file filename "rb"))
 218                         (line (read-line in-port)))
 219                    (close-port in-port)
 220                    (delete-file filename)
 221                    (string=? line binary-test-string)))))
 222
 223 ;;; binary mode ignores file coding declaration
 224 (pass-if "file: binary mode ignores file coding declaration"
 225   (with-fluids ((%default-port-encoding "UTF-8"))
 226                (let* ((filename (test-file))
 227                       (port (open-file filename "w"))
 228                       (test-string "一二三")
 229                       (binary-test-string
 230                        (apply string
 231                               (map integer->char
 232                                    (uniform-vector->list
 233                                     (string->utf8 test-string))))))
 234                  (write-line ";; coding: utf-8" port)
 235                  (write-line test-string port)
 236                  (close-port port)
 237                  (let* ((in-port (open-file filename "rb"))
 238                         (line1 (read-line in-port))
 239                         (line2 (read-line in-port)))
 240                    (close-port in-port)
 241                    (delete-file filename)
 242                    (string=? line2 binary-test-string)))))
 243
 244 ;; open-file honors file coding declarations
 245 (pass-if "file: open-file honors coding declarations"
 246   (with-fluids ((%default-port-encoding "UTF-8"))
 247                (let* ((filename (test-file))
 248                       (port (open-output-file filename))
 249                       (test-string "€100"))
 250                  (set-port-encoding! port "ISO-8859-15")
 251                  (write-line ";; coding: iso-8859-15" port)
 252                  (write-line test-string port)
 253                  (close-port port)
 254                  (let* ((in-port (open-input-file filename))
 255                         (line1 (read-line in-port))
 256                         (line2 (read-line in-port)))
 257                    (close-port in-port)
 258                    (delete-file filename)
 259                    (string=? line2 test-string)))))
 260
 261 ;;; ungetting characters and strings.
 262 (with-input-from-string "walk on the moon\nmoon"
 263                         (lambda ()
 264                           (read-char)
 265                           (unread-char #\a (current-input-port))
 266                           (pass-if "unread-char"
 267                                    (char=? (read-char) #\a))
 268                           (read-line)
 269                           (let ((replacenoid "chicken enchilada"))
 270                             (unread-char #\newline (current-input-port))
 271                             (unread-string replacenoid (current-input-port))
 272                             (pass-if "unread-string"
 273                                      (string=? (read-line) replacenoid)))
 274                           (pass-if "unread residue"
 275                                    (string=? (read-line) "moon"))))
 276
 277 ;;; non-blocking mode on a port.  create a pipe and set O_NONBLOCK on
 278 ;;; the reading end.  try to read a byte: should get EAGAIN or
 279 ;;; EWOULDBLOCK error.
 280 (let* ((p (pipe))
 281        (r (car p)))
 282   (fcntl r F_SETFL (logior (fcntl r F_GETFL) O_NONBLOCK))
 283   (pass-if "non-blocking-I/O"
 284            (catch 'system-error
 285                   (lambda () (read-char r) #f)
 286                   (lambda (key . args)
 287                     (and (eq? key 'system-error)
 288                          (let ((errno (car (list-ref args 3))))
 289                            (or (= errno EAGAIN)
 290                                (= errno EWOULDBLOCK))))))))
 291
 292 \f
 293 ;;;; Pipe (popen) ports.
 294
 295 ;;; Run a command, and read its output.
 296 (let* ((pipe (open-pipe "echo 'Howdy there, partner!'" "r"))
 297        (in-string (read-all pipe)))
 298   (close-pipe pipe)
 299   (pass-if "pipe: read"
 300            (equal? in-string "Howdy there, partner!\n")))
 301
 302 ;;; Run a command, send some output to it, and see if it worked.
 303 (let* ((filename (test-file))
 304        (pipe (open-pipe (string-append "grep Mommy > " filename) "w")))
 305   (display "Now Jimmy lives on a mushroom cloud\n" pipe)
 306   (display "Mommy, why does everybody have a bomb?\n" pipe)
 307   (close-pipe pipe)
 308   (let ((in-string (read-file filename)))
 309     (pass-if "pipe: write"
 310              (equal? in-string "Mommy, why does everybody have a bomb?\n")))
 311   (delete-file filename))
 312
 313 \f
 314 ;;;; Void ports.  These are so trivial we don't test them.
 315
 316 \f
 317 ;;;; String ports.
 318
 319 (with-test-prefix "string ports"
 320
 321   ;; Write text to a string port.
 322   (let* ((string "Howdy there, partner!")
 323          (in-string (call-with-output-string
 324                      (lambda (port)
 325                        (display string port)
 326                        (newline port)))))
 327     (pass-if "display text"
 328              (equal? in-string (string-append string "\n"))))
 329
 330   ;; Write an s-expression to a string port.
 331   (let* ((sexpr '("more utterly random text" 1729 #(a vector) 3.1415926))
 332          (in-sexpr
 333           (call-with-input-string (call-with-output-string
 334                                    (lambda (port)
 335                                      (write sexpr port)))
 336                                   read)))
 337     (pass-if "write/read sexpr"
 338              (equal? in-sexpr sexpr)))
 339
 340   ;; seeking and unreading from an input string.
 341   (let ((text "that text didn't look random to me"))
 342     (call-with-input-string text
 343                             (lambda (p)
 344                               (pass-if "input tell 0"
 345                                        (= (seek p 0 SEEK_CUR) 0))
 346                               (read-char p)
 347                               (pass-if "input tell 1"
 348                                        (= (seek p 0 SEEK_CUR) 1))
 349                               (unread-char #\x p)
 350                               (pass-if "input tell back to 0"
 351                                        (= (seek p 0 SEEK_CUR) 0))
 352                               (pass-if "input ungetted char"
 353                                        (char=? (read-char p) #\x))
 354                               (seek p 0 SEEK_END)
 355                               (pass-if "input seek to end"
 356                                        (= (seek p 0 SEEK_CUR)
 357                                           (string-length text)))
 358                               (unread-char #\x p)
 359                               (pass-if "input seek to beginning"
 360                                        (= (seek p 0 SEEK_SET) 0))
 361                               (pass-if "input reread first char"
 362                                        (char=? (read-char p)
 363                                                (string-ref text 0))))))
 364
 365   ;; seeking an output string.
 366   (let* ((text (string-copy "123456789"))
 367          (len (string-length text))
 368          (result (call-with-output-string
 369                   (lambda (p)
 370                     (pass-if "output tell 0"
 371                              (= (seek p 0 SEEK_CUR) 0))
 372                     (display text p)
 373                     (pass-if "output tell end"
 374                              (= (seek p 0 SEEK_CUR) len))
 375                     (pass-if "output seek to beginning"
 376                              (= (seek p 0 SEEK_SET) 0))
 377                     (write-char #\a p)
 378                     (seek p -1 SEEK_END)
 379                     (pass-if "output seek to last char"
 380                              (= (seek p 0 SEEK_CUR)
 381                                 (- len 1)))
 382                     (write-char #\b p)))))
 383     (string-set! text 0 #\a)
 384     (string-set! text (- len 1) #\b)
 385     (pass-if "output check"
 386              (string=? text result)))
 387
 388   (pass-if "%default-port-encoding is honored"
 389     (let ((encodings '("UTF-8" "UTF-16" "ISO-8859-1" "ISO-8859-3")))
 390       (equal? (map (lambda (e)
 391                      (with-fluids ((%default-port-encoding e))
 392                        (call-with-output-string
 393                          (lambda (p)
 394                            (and (string=? e (port-encoding p))
 395                                 (display (port-encoding p) p))))))
 396                    encodings)
 397               encodings)))
 398
 399   (pass-if "suitable encoding [latin-1]"
 400     (let ((str "hello, world"))
 401       (with-fluids ((%default-port-encoding "ISO-8859-1"))
 402         (equal? str
 403                 (with-output-to-string
 404                   (lambda ()
 405                     (display str)))))))
 406
 407   (pass-if "suitable encoding [latin-3]"
 408     (let ((str "ĉu bone?"))
 409       (with-fluids ((%default-port-encoding "ISO-8859-3"))
 410         (equal? str
 411                 (with-output-to-string
 412                   (lambda ()
 413                     (display str)))))))
 414
 415   (pass-if "wrong encoding"
 416     (let ((str "ĉu bone?"))
 417       (catch 'encoding-error
 418         (lambda ()
 419           ;; Latin-1 cannot represent ‘ĉ’.
 420           (with-fluids ((%default-port-encoding "ISO-8859-1"))
 421             (with-output-to-string
 422               (lambda ()
 423                 (display str)))))
 424         (lambda (key subr message errno port chr)
 425           (and (eq? chr #\ĉ)
 426                (string? (strerror errno)))))))
 427
 428   (pass-if "wrong encoding, substitute"
 429     (let ((str "ĉu bone?"))
 430       (with-fluids ((%default-port-encoding "ISO-8859-1"))
 431         (string=? (with-output-to-string
 432                     (lambda ()
 433                       (set-port-conversion-strategy! (current-output-port)
 434                                                      'substitute)
 435                       (display str)))
 436                   "?u bone?"))))
 437
 438   (pass-if "wrong encoding, escape"
 439     (let ((str "ĉu bone?"))
 440       (with-fluids ((%default-port-encoding "ISO-8859-1"))
 441         (string=? (with-output-to-string
 442                     (lambda ()
 443                       (set-port-conversion-strategy! (current-output-port)
 444                                                      'escape)
 445                       (display str)))
 446                   "\\u0109u bone?"))))
 447
 448   (pass-if "peek-char [latin-1]"
 449     (let ((p (with-fluids ((%default-port-encoding #f))
 450                (open-input-string "hello, world"))))
 451       (and (char=? (peek-char p) #\h)
 452            (char=? (peek-char p) #\h)
 453            (char=? (peek-char p) #\h)
 454            (= (port-line p) 0)
 455            (= (port-column p) 0))))
 456
 457   (pass-if "peek-char [utf-8]"
 458     (let ((p (with-fluids ((%default-port-encoding "UTF-8"))
 459                (open-input-string "안녕하세요"))))
 460       (and (char=? (peek-char p) #\안)
 461            (char=? (peek-char p) #\안)
 462            (char=? (peek-char p) #\안)
 463            (= (port-line p) 0)
 464            (= (port-column p) 0))))
 465
 466   (pass-if "peek-char [utf-16]"
 467     (let ((p (with-fluids ((%default-port-encoding "UTF-16BE"))
 468                (open-input-string "안녕하세요"))))
 469       (and (char=? (peek-char p) #\안)
 470            (char=? (peek-char p) #\안)
 471            (char=? (peek-char p) #\안)
 472            (= (port-line p) 0)
 473            (= (port-column p) 0))))
 474
 475   ;; Mini DSL to test decoding error handling.
 476   (letrec-syntax ((decoding-error?
 477                    (syntax-rules ()
 478                      ((_ port exp)
 479                       (catch 'decoding-error
 480                         (lambda ()
 481                           (pk 'exp exp)
 482                           #f)
 483                         (lambda (key subr message errno p)
 484                           (and (eq? p port)
 485                                (not (= 0 errno))))))))
 486                   (make-check
 487                    (syntax-rules (-> error eof)
 488                      ((_ port (proc -> error))
 489                       (if (eq? 'substitute
 490                                (port-conversion-strategy port))
 491                           (eq? (proc port) #\?)
 492                           (decoding-error? port (proc port))))
 493                      ((_ port (proc -> eof))
 494                       (eof-object? (proc port)))
 495                      ((_ port (proc -> char))
 496                       (eq? (proc port) char))))
 497                   (make-checks
 498                    (syntax-rules ()
 499                      ((_ port check ...)
 500                       (and (make-check port check) ...))))
 501                   (make-peek+read-checks
 502                    (syntax-rules ()
 503                      ((_ port (result ...) e1 expected ...)
 504                       (make-peek+read-checks port
 505                                              (result ...
 506                                                      (peek-char -> e1)
 507                                                      (read-char -> e1))
 508                                              expected ...))
 509                      ((_ port (result ...))
 510                       (make-checks port result ...))
 511                      ((_ port #f e1 expected ...)
 512                       (make-peek+read-checks port
 513                                              ((peek-char -> e1)
 514                                               (read-char -> e1))
 515                                              expected ...))))
 516
 517                   (test-decoding-error*
 518                       (syntax-rules ()
 519                         ((_ sequence encoding strategy (expected ...))
 520                          (begin
 521                           (pass-if (format #f "test-decoding-error: ~s ~s ~s"
 522                                            'sequence encoding strategy)
 523                             (let ((p (open-bytevector-input-port
 524                                       (u8-list->bytevector 'sequence))))
 525                               (set-port-encoding! p encoding)
 526                               (set-port-conversion-strategy! p strategy)
 527                               (make-checks p
 528                                            (read-char -> expected) ...)))
 529
 530                           ;; Generate the same test, but with one
 531                           ;; `peek-char' call before each `read-char'.
 532                           ;; Both should yield the same result.
 533                           (pass-if (format #f "test-decoding-error: ~s ~s ~s + peek-char"
 534                                            'sequence encoding strategy)
 535                             (let ((p (open-bytevector-input-port
 536                                       (u8-list->bytevector 'sequence))))
 537                               (set-port-encoding! p encoding)
 538                               (set-port-conversion-strategy! p strategy)
 539                               (make-peek+read-checks p #f expected
 540                                                      ...)))))))
 541                   (test-decoding-error
 542                       (syntax-rules ()
 543                         ((_ sequence encoding (expected ...))
 544                          (begin
 545                            (test-decoding-error* sequence encoding 'error
 546                              (expected ...))
 547
 548                            ;; `escape' should behave exactly like `error'.
 549                            (test-decoding-error* sequence encoding 'escape
 550                              (expected ...))
 551
 552                            (test-decoding-error* sequence encoding 'substitute
 553                              (expected ...)))))))
 554
 555     (test-decoding-error (255 65 66 67) "UTF-8"
 556       (error #\A #\B #\C eof))
 557
 558     (test-decoding-error (255 206 187 206 188) "UTF-8"
 559       (error #\λ #\μ eof))
 560
 561     (test-decoding-error (206 187 206) "UTF-8"
 562       ;; Unterminated sequence.
 563       (#\λ error eof))
 564
 565     ;; Check how ill-formed UTF-8 sequences are handled (see Table 3-7
 566     ;; of the "Conformance" chapter of Unicode 6.0.0.)
 567
 568     (test-decoding-error (#xc0 #x80 #x41) "UTF-8"
 569       (error                ;; C0: should be in the C2..DF range
 570        error                ;; 80: invalid
 571        #\A
 572        eof))
 573
 574     (test-decoding-error (#xc2 #x41 #x42) "UTF-8"
 575       (error                ;; 41: should be in the 80..BF range
 576        #\B
 577        eof))
 578
 579     (test-decoding-error (#xe0 #x88 #x88) "UTF-8"
 580       (error                ;; 2nd byte should be in the A0..BF range
 581        eof))
 582
 583     (test-decoding-error (#xe0 #xa0 #x41 #x42) "UTF-8"
 584       (error                ;; 3rd byte should be in the 80..BF range
 585        #\B
 586        eof))
 587
 588     (test-decoding-error (#xf0 #x88 #x88 #x88) "UTF-8"
 589       (error                ;; 2nd byte should be in the 90..BF range
 590        eof))))
 591
 592 (with-test-prefix "call-with-output-string"
 593
 594   ;; In Guile 1.6.4, closing the port resulted in a segv, check that doesn't
 595   ;; occur.
 596   (pass-if-exception "proc closes port" exception:wrong-type-arg
 597     (call-with-output-string close-port)))
 598
 599
 600 \f
 601 ;;;; Soft ports.  No tests implemented yet.
 602
 603 \f
 604 ;;;; Generic operations across all port types.
 605
 606 (let ((port-loop-temp (test-file)))
 607
 608   ;; Return a list of input ports that all return the same text.
 609   ;; We map tests over this list.
 610   (define (input-port-list text)
 611
 612     ;; Create a text file some of the ports will use.
 613     (let ((out-port (open-output-file port-loop-temp)))
 614       (display text out-port)
 615       (close-port out-port))
 616
 617     (list (open-input-file port-loop-temp)
 618           (open-input-pipe (string-append "cat " port-loop-temp))
 619           (call-with-input-string text (lambda (x) x))
 620           ;; We don't test soft ports at the moment.
 621           ))
 622
 623   (define port-list-names '("file" "pipe" "string"))
 624
 625   ;; Test the line counter.
 626   (define (test-line-counter text second-line final-column)
 627     (with-test-prefix "line counter"
 628       (let ((ports (input-port-list text)))
 629         (for-each
 630          (lambda (port port-name)
 631            (with-test-prefix port-name
 632              (pass-if "at beginning of input"
 633                       (= (port-line port) 0))
 634              (pass-if "read first character"
 635                       (eqv? (read-char port) #\x))
 636              (pass-if "after reading one character"
 637                       (= (port-line port) 0))
 638              (pass-if "read first newline"
 639                       (eqv? (read-char port) #\newline))
 640              (pass-if "after reading first newline char"
 641                       (= (port-line port) 1))
 642              (pass-if "second line read correctly"
 643                       (equal? (read-line port) second-line))
 644              (pass-if "read-line increments line number"
 645                       (= (port-line port) 2))
 646              (pass-if "read-line returns EOF"
 647                       (let loop ((i 0))
 648                         (cond
 649                          ((eof-object? (read-line port)) #t)
 650                          ((> i 20) #f)
 651                          (else (loop (+ i 1))))))
 652              (pass-if "line count is 5 at EOF"
 653                       (= (port-line port) 5))
 654              (pass-if "column is correct at EOF"
 655                       (= (port-column port) final-column))))
 656          ports port-list-names)
 657         (for-each close-port ports)
 658         (delete-file port-loop-temp))))
 659
 660   (with-test-prefix "newline"
 661     (test-line-counter
 662      (string-append "x\n"
 663                     "He who receives an idea from me, receives instruction\n"
 664                     "himself without lessening mine; as he who lights his\n"
 665                     "taper at mine, receives light without darkening me.\n"
 666                     "  --- Thomas Jefferson\n")
 667      "He who receives an idea from me, receives instruction"
 668      0))
 669
 670   (with-test-prefix "no newline"
 671     (test-line-counter
 672      (string-append "x\n"
 673                     "He who receives an idea from me, receives instruction\n"
 674                     "himself without lessening mine; as he who lights his\n"
 675                     "taper at mine, receives light without darkening me.\n"
 676                     "  --- Thomas Jefferson\n"
 677                     "no newline here")
 678      "He who receives an idea from me, receives instruction"
 679      15)))
 680
 681 ;; Test port-line and port-column for output ports
 682
 683 (define (test-output-line-counter text final-column)
 684   (with-test-prefix "port-line and port-column for output ports"
 685     (let ((port (open-output-string)))
 686       (pass-if "at beginning of input"
 687                (and (= (port-line port) 0)
 688                     (= (port-column port) 0)))
 689       (write-char #\x port)
 690       (pass-if "after writing one character"
 691                (and (= (port-line port) 0)
 692                     (= (port-column port) 1)))
 693       (write-char #\newline port)
 694       (pass-if "after writing first newline char"
 695                (and (= (port-line port) 1)
 696                     (= (port-column port) 0)))
 697       (display text port)
 698       (pass-if "line count is 5 at end"
 699                (= (port-line port) 5))
 700       (pass-if "column is correct at end"
 701                (= (port-column port) final-column)))))
 702
 703 (test-output-line-counter
 704  (string-append "He who receives an idea from me, receives instruction\n"
 705                 "himself without lessening mine; as he who lights his\n"
 706                 "taper at mine, receives light without darkening me.\n"
 707                 "  --- Thomas Jefferson\n"
 708                 "no newline here")
 709  15)
 710
 711 (with-test-prefix "port-column"
 712
 713   (with-test-prefix "output"
 714
 715     (pass-if "x"
 716       (let ((port (open-output-string)))
 717         (display "x" port)
 718         (= 1 (port-column port))))
 719
 720     (pass-if "\\a"
 721       (let ((port (open-output-string)))
 722         (display "\a" port)
 723         (= 0 (port-column port))))
 724
 725     (pass-if "x\\a"
 726       (let ((port (open-output-string)))
 727         (display "x\a" port)
 728         (= 1 (port-column port))))
 729
 730     (pass-if "\\x08 backspace"
 731       (let ((port (open-output-string)))
 732         (display "\x08" port)
 733         (= 0 (port-column port))))
 734
 735     (pass-if "x\\x08 backspace"
 736       (let ((port (open-output-string)))
 737         (display "x\x08" port)
 738         (= 0 (port-column port))))
 739
 740     (pass-if "\\n"
 741       (let ((port (open-output-string)))
 742         (display "\n" port)
 743         (= 0 (port-column port))))
 744
 745     (pass-if "x\\n"
 746       (let ((port (open-output-string)))
 747         (display "x\n" port)
 748         (= 0 (port-column port))))
 749
 750     (pass-if "\\r"
 751       (let ((port (open-output-string)))
 752         (display "\r" port)
 753         (= 0 (port-column port))))
 754
 755     (pass-if "x\\r"
 756       (let ((port (open-output-string)))
 757         (display "x\r" port)
 758         (= 0 (port-column port))))
 759
 760     (pass-if "\\t"
 761       (let ((port (open-output-string)))
 762         (display "\t" port)
 763         (= 8 (port-column port))))
 764
 765     (pass-if "x\\t"
 766       (let ((port (open-output-string)))
 767         (display "x\t" port)
 768         (= 8 (port-column port)))))
 769
 770   (with-test-prefix "input"
 771
 772     (pass-if "x"
 773       (let ((port (open-input-string "x")))
 774         (while (not (eof-object? (read-char port))))
 775         (= 1 (port-column port))))
 776
 777     (pass-if "\\a"
 778       (let ((port (open-input-string "\a")))
 779         (while (not (eof-object? (read-char port))))
 780         (= 0 (port-column port))))
 781
 782     (pass-if "x\\a"
 783       (let ((port (open-input-string "x\a")))
 784         (while (not (eof-object? (read-char port))))
 785         (= 1 (port-column port))))
 786
 787     (pass-if "\\x08 backspace"
 788       (let ((port (open-input-string "\x08")))
 789         (while (not (eof-object? (read-char port))))
 790         (= 0 (port-column port))))
 791
 792     (pass-if "x\\x08 backspace"
 793       (let ((port (open-input-string "x\x08")))
 794         (while (not (eof-object? (read-char port))))
 795         (= 0 (port-column port))))
 796
 797     (pass-if "\\n"
 798       (let ((port (open-input-string "\n")))
 799         (while (not (eof-object? (read-char port))))
 800         (= 0 (port-column port))))
 801
 802     (pass-if "x\\n"
 803       (let ((port (open-input-string "x\n")))
 804         (while (not (eof-object? (read-char port))))
 805         (= 0 (port-column port))))
 806
 807     (pass-if "\\r"
 808       (let ((port (open-input-string "\r")))
 809         (while (not (eof-object? (read-char port))))
 810         (= 0 (port-column port))))
 811
 812     (pass-if "x\\r"
 813       (let ((port (open-input-string "x\r")))
 814         (while (not (eof-object? (read-char port))))
 815         (= 0 (port-column port))))
 816
 817     (pass-if "\\t"
 818       (let ((port (open-input-string "\t")))
 819         (while (not (eof-object? (read-char port))))
 820         (= 8 (port-column port))))
 821
 822     (pass-if "x\\t"
 823       (let ((port (open-input-string "x\t")))
 824         (while (not (eof-object? (read-char port))))
 825         (= 8 (port-column port))))))
 826
 827 (with-test-prefix "port-line"
 828
 829   ;; in guile 1.8.1 and earlier port-line was truncated to an int, whereas
 830   ;; scm_t_port actually holds a long; this restricted the range on 64-bit
 831   ;; systems
 832   (pass-if "set most-positive-fixnum/2"
 833     (let ((n    (quotient most-positive-fixnum 2))
 834           (port (open-output-string)))
 835       (set-port-line! port n)
 836       (eqv? n (port-line port)))))
 837
 838 (with-test-prefix "port-encoding"
 839
 840   (pass-if-exception "set-port-encoding!, wrong encoding"
 841     exception:miscellaneous-error
 842     (set-port-encoding! (open-input-string "") "does-not-exist"))
 843
 844   (pass-if-exception "%default-port-encoding, wrong encoding"
 845     exception:miscellaneous-error
 846     (read (with-fluids ((%default-port-encoding "does-not-exist"))
 847             (open-input-string "")))))
 848
 849 ;;;
 850 ;;; port-for-each
 851 ;;;
 852
 853 (with-test-prefix "port-for-each"
 854
 855   ;; In guile 1.8.0 through 1.8.2, port-for-each could pass a freed cell to
 856   ;; its iterator func if a port was inaccessible in the last gc mark but
 857   ;; the lazy sweeping has not yet reached it to remove it from the port
 858   ;; table (scm_i_port_table).  Provoking those gc conditions is a little
 859   ;; tricky, but the following code made it happen in 1.8.2.
 860   (pass-if "passing freed cell"
 861     (let ((lst '()))
 862       ;; clear out the heap
 863       (gc) (gc) (gc)
 864       ;; allocate cells so the opened ports aren't at the start of the heap
 865       (make-list 1000)
 866       (open-input-file "/dev/null")
 867       (make-list 1000)
 868       (open-input-file "/dev/null")
 869       ;; this gc leaves the above ports unmarked, ie. inaccessible
 870       (gc)
 871       ;; but they're still in the port table, so this sees them
 872       (port-for-each (lambda (port)
 873                        (set! lst (cons port lst))))
 874       ;; this forces completion of the sweeping
 875       (gc) (gc) (gc)
 876       ;; and (if the bug is present) the cells accumulated in LST are now
 877       ;; freed cells, which give #f from `port?'
 878       (not (memq #f (map port? lst))))))
 879
 880 (with-test-prefix
 881  "fdes->port"
 882  (pass-if "fdes->ports finds port"
 883           (let ((port (open-file (test-file) "w")))
 884
 885             (not (not (memq port (fdes->ports (port->fdes port))))))))
 886
 887 ;;;
 888 ;;; seek
 889 ;;;
 890
 891 (with-test-prefix "seek"
 892
 893   (with-test-prefix "file port"
 894
 895     (pass-if "SEEK_CUR"
 896       (call-with-output-file (test-file)
 897         (lambda (port)
 898           (display "abcde" port)))
 899       (let ((port (open-file (test-file) "r")))
 900         (read-char port)
 901         (seek port 2 SEEK_CUR)
 902         (eqv? #\d (read-char port))))
 903
 904     (pass-if "SEEK_SET"
 905       (call-with-output-file (test-file)
 906         (lambda (port)
 907           (display "abcde" port)))
 908       (let ((port (open-file (test-file) "r")))
 909         (read-char port)
 910         (seek port 3 SEEK_SET)
 911         (eqv? #\d (read-char port))))
 912
 913     (pass-if "SEEK_END"
 914       (call-with-output-file (test-file)
 915         (lambda (port)
 916           (display "abcde" port)))
 917       (let ((port (open-file (test-file) "r")))
 918         (read-char port)
 919         (seek port -2 SEEK_END)
 920         (eqv? #\d (read-char port))))))
 921
 922 ;;;
 923 ;;; truncate-file
 924 ;;;
 925
 926 (with-test-prefix "truncate-file"
 927
 928   (pass-if-exception "flonum file" exception:wrong-type-arg
 929     (truncate-file 1.0 123))
 930
 931   (pass-if-exception "frac file" exception:wrong-type-arg
 932     (truncate-file 7/3 123))
 933
 934   (with-test-prefix "filename"
 935
 936     (pass-if-exception "flonum length" exception:wrong-type-arg
 937       (call-with-output-file (test-file)
 938         (lambda (port)
 939           (display "hello" port)))
 940       (truncate-file (test-file) 1.0))
 941
 942     (pass-if "shorten"
 943       (call-with-output-file (test-file)
 944         (lambda (port)
 945           (display "hello" port)))
 946       (truncate-file (test-file) 1)
 947       (eqv? 1 (stat:size (stat (test-file)))))
 948
 949     (pass-if-exception "shorten to current pos" exception:miscellaneous-error
 950       (call-with-output-file (test-file)
 951         (lambda (port)
 952           (display "hello" port)))
 953       (truncate-file (test-file))))
 954
 955   (with-test-prefix "file descriptor"
 956
 957     (pass-if "shorten"
 958       (call-with-output-file (test-file)
 959         (lambda (port)
 960           (display "hello" port)))
 961       (let ((fd (open-fdes (test-file) O_RDWR)))
 962         (truncate-file fd 1)
 963         (close-fdes fd))
 964       (eqv? 1 (stat:size (stat (test-file)))))
 965
 966     (pass-if "shorten to current pos"
 967       (call-with-output-file (test-file)
 968         (lambda (port)
 969           (display "hello" port)))
 970       (let ((fd (open-fdes (test-file) O_RDWR)))
 971         (seek fd 1 SEEK_SET)
 972         (truncate-file fd)
 973         (close-fdes fd))
 974       (eqv? 1 (stat:size (stat (test-file))))))
 975
 976   (with-test-prefix "file port"
 977
 978     (pass-if "shorten"
 979       (call-with-output-file (test-file)
 980         (lambda (port)
 981           (display "hello" port)))
 982       (let ((port (open-file (test-file) "r+")))
 983         (truncate-file port 1))
 984       (eqv? 1 (stat:size (stat (test-file)))))
 985
 986     (pass-if "shorten to current pos"
 987       (call-with-output-file (test-file)
 988         (lambda (port)
 989           (display "hello" port)))
 990       (let ((port (open-file (test-file) "r+")))
 991         (read-char port)
 992         (truncate-file port))
 993       (eqv? 1 (stat:size (stat (test-file)))))))
 994
 995
 996 ;;;; testing read-delimited and friends
 997
 998 (with-test-prefix "read-delimited!"
 999   (let ((c (make-string 20 #\!)))
1000     (call-with-input-string
1001      "defdef\nghighi\n"
1002      (lambda (port)
1003
1004        (read-delimited! "\n" c port 'concat)
1005        (pass-if "read-delimited! reads a first line"
1006                 (string=? c "defdef\n!!!!!!!!!!!!!"))
1007
1008        (read-delimited! "\n" c port 'concat 3)
1009        (pass-if "read-delimited! reads a first line"
1010                 (string=? c "defghighi\n!!!!!!!!!!"))))))
1011
1012 \f
1013 ;;;; char-ready?
1014
1015 (call-with-input-string
1016  "howdy"
1017  (lambda (port)
1018    (pass-if "char-ready? returns true on string port"
1019             (char-ready? port))))
1020
1021 ;;; This segfaults on some versions of Guile.  We really should run
1022 ;;; the tests in a subprocess...
1023
1024 (call-with-input-string
1025  "howdy"
1026  (lambda (port)
1027    (with-input-from-port
1028        port
1029      (lambda ()
1030        (pass-if "char-ready? returns true on string port as default port"
1031                 (char-ready?))))))
1032
1033 \f
1034 ;;;; Close current-input-port, and make sure everyone can handle it.
1035
1036 (with-test-prefix "closing current-input-port"
1037   (for-each (lambda (procedure name)
1038               (with-input-from-port
1039                   (call-with-input-string "foo" (lambda (p) p))
1040                 (lambda ()
1041                   (close-port (current-input-port))
1042                   (pass-if-exception name
1043                     exception:wrong-type-arg
1044                     (procedure)))))
1045             (list read read-char read-line)
1046             '("read" "read-char" "read-line")))
1047
1048 (delete-file (test-file))
1049
1050 ;;; Local Variables:
1051 ;;; eval: (put 'test-decoding-error 'scheme-indent-function 3)
1052 ;;; End: