configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_PREREQ(2.50)
  24
  25 AC_INIT
  26 AC_CONFIG_SRCDIR([Makefile.in])
  27 . $srcdir/GUILE-VERSION
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  29 AM_MAINTAINER_MODE
  30 AM_CONFIG_HEADER(libguile/scmconfig.h)
  31
  32 #--------------------------------------------------------------------
  33 #
  34 # Independent Subdirectories
  35 #
  36 #--------------------------------------------------------------------
  37
  38 AC_CONFIG_SUBDIRS(guile-readline)
  39
  40 #--------------------------------------------------------------------
  41 #
  42 # User options
  43 #
  44 #--------------------------------------------------------------------
  45
  46 AC_ARG_ENABLE(debug-freelist,
  47   [  --enable-debug-freelist include garbage collector freelist debugging code],
  48   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  49     AC_DEFINE(GUILE_DEBUG_FREELIST)
  50   fi)
  51
  52 AC_ARG_ENABLE(debug-malloc,
  53   [  --enable-debug-malloc   include malloc debugging code],
  54   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  55     AC_DEFINE(GUILE_DEBUG_MALLOC)
  56   fi)
  57
  58 AC_ARG_ENABLE(guile-debug,
  59   [  --enable-guile-debug    include internal debugging functions],
  60   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  61     AC_DEFINE(GUILE_DEBUG)
  62   fi)
  63
  64 AC_ARG_ENABLE(arrays,
  65   [  --disable-arrays        omit array and uniform array support],,
  66   enable_arrays=yes)
  67
  68 AC_ARG_ENABLE(posix,
  69   [  --disable-posix         omit posix interfaces],,
  70   enable_posix=yes)
  71
  72 AC_ARG_ENABLE(networking,
  73   [  --disable-networking    omit networking interfaces],,
  74   enable_networking=yes)
  75
  76 AC_ARG_ENABLE(regex,
  77   [  --disable-regex         omit regular expression interfaces],,
  78   enable_regex=yes)
  79
  80 AC_ARG_ENABLE(htmldoc,
  81   [  --enable-htmldoc        build HTML documentation as well as Info],
  82   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  83      htmldoc_enabled=yes
  84      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  85      if test "$TEXI2HTML" = "not found"; then
  86        echo
  87        echo Building HTML documentation requires the \`texi2html\' program,
  88        echo which appears not to be present on your machine.
  89        echo
  90        echo \`texi2html\' is available from
  91        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
  92        echo
  93        echo In the meantime, to build the guile-doc distribution
  94        echo without HTML enabled, please rerun \`./configure\' without
  95        echo the \`--enable-htmldoc\' option.
  96        exit -1
  97      fi
  98    fi])
  99
 100 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
 101
 102 AC_ARG_ENABLE(deprecated,
 103   [  --disable-deprecated    omit deprecated features [no]])
 104
 105 if test "$enable_deprecated" = no; then
 106   AC_DEFINE(SCM_DEBUG_DEPRECATED, 1)
 107 else
 108   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 109     warn_default=summary
 110   elif test "$enable_deprecated" = shutup; then
 111     warn_default=no
 112   else
 113     warn_default=$enable_deprecated
 114   fi
 115   AC_DEFINE(SCM_DEBUG_DEPRECATED, 0)
 116   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default")
 117 fi
 118
 119 dnl The --disable-debug used to control these two.  But now they are
 120 dnl a required part of the distribution.
 121 AC_DEFINE(DEBUG_EXTENSIONS)
 122 AC_DEFINE(READER_EXTENSIONS)
 123
 124 dnl files which are destined for separate modules.
 125
 126 if test "$enable_arrays" = yes; then
 127    LIBOBJS="$LIBOBJS ramap.o unif.o"
 128    AC_DEFINE(HAVE_ARRAYS)
 129 fi
 130
 131 if test "$enable_posix" = yes; then
 132    LIBOBJS="$LIBOBJS filesys.o posix.o"
 133    AC_DEFINE(HAVE_POSIX)
 134 fi
 135
 136 if test "$enable_networking" = yes; then
 137    LIBOBJS="$LIBOBJS net_db.o socket.o"
 138    AC_DEFINE(HAVE_NETWORKING)
 139 fi
 140
 141 if test "$enable_debug_malloc" = yes; then
 142    LIBOBJS="$LIBOBJS debug-malloc.o"
 143 fi
 144
 145 #--------------------------------------------------------------------
 146
 147 AC_LIBLTDL_CONVENIENCE
 148 AC_CONFIG_SUBDIRS(libltdl)
 149
 150 AC_PROG_CC
 151 AC_PROG_CPP
 152 AC_LIBTOOL_DLOPEN
 153
 154 AC_AIX
 155 AC_ISC_POSIX
 156 AC_MINIX
 157
 158 AM_PROG_CC_STDC
 159 AM_PROG_LIBTOOL
 160
 161 AC_C_CONST
 162 AC_C_INLINE
 163 AC_C_BIGENDIAN
 164
 165 AC_CHECK_SIZEOF(int)
 166 AC_CHECK_SIZEOF(long)
 167
 168 dnl Check for integral types that can represent the range of pointers.
 169 dnl If these types don't exist on this platform, they are replaced by
 170 dnl "unsigned long" and "long", respectively.
 171
 172 AC_CHECK_HEADERS(stdint.h)
 173 AC_CHECK_TYPES([uintptr_t, ptrdiff_t])
 174
 175 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 176                AC_TRY_COMPILE(,
 177                               [long long a],
 178                               scm_cv_long_longs=yes,
 179                               scm_cv_long_longs=no))
 180 if test "$scm_cv_long_longs" = yes; then
 181   AC_DEFINE(HAVE_LONG_LONGS)
 182   AC_CHECK_SIZEOF(long long)
 183 fi
 184
 185 AC_CHECK_SIZEOF(void *)
 186
 187 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 188   AC_MSG_ERROR(sizes of long and void* are not identical)
 189 fi
 190
 191 AC_HEADER_STDC
 192 AC_HEADER_DIRENT
 193 AC_HEADER_TIME
 194 AC_HEADER_SYS_WAIT
 195 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h sys/utime.h time.h unistd.h utime.h pwd.h winsock2.h grp.h sys/utsname.h)
 196 GUILE_HEADER_LIBC_WITH_UNISTD
 197
 198 AC_TYPE_GETGROUPS
 199 AC_TYPE_SIGNAL
 200 AC_TYPE_MODE_T
 201
 202 AC_CHECK_LIB(m, main)
 203 AC_CHECK_FUNCS(gethostbyname)
 204 if test $ac_cv_func_gethostbyname = no; then
 205     AC_CHECK_LIB(nsl, gethostbyname)
 206 fi
 207 AC_CHECK_FUNCS(connect)
 208 if test $ac_cv_func_connect = no; then
 209     AC_CHECK_LIB(socket, connect)
 210 fi
 211
 212 # Check for dynamic linking
 213
 214 use_modules=yes
 215 AC_ARG_WITH(modules,
 216 [  --with-modules[=FILES]  Add support for dynamic modules],
 217 use_modules="$withval")
 218 test -z "$use_modules" && use_modules=yes
 219 DLPREOPEN=
 220 if test "$use_modules" != no; then
 221   AC_DEFINE(DYNAMIC_LINKING)
 222   if test "$use_modules" = yes; then
 223     DLPREOPEN="-dlpreopen force"
 224   else
 225     DLPREOPEN="-export-dynamic"
 226     for module in $use_modules; do
 227       DLPREOPEN="$DLPREOPEN -dlopen $module"
 228     done
 229   fi
 230 fi
 231 AC_SUBST(INCLTDL)
 232 AC_SUBST(LIBLTDL)
 233 AC_SUBST(DLPREOPEN)
 234
 235 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork)
 236
 237 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 238 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 239 AC_CHECK_LIB(crypt, crypt)
 240
 241 ### Some systems don't declare some functions.  On such systems, we
 242 ### need to at least provide our own K&R-style declarations.
 243
 244 ### GUILE_FUNC_DECLARED(function, headerfile)
 245
 246 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 247 ### not there, #define MISSING_FUNCTION_DECL.
 248 AC_DEFUN(GUILE_FUNC_DECLARED, [
 249   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 250     AC_EGREP_HEADER($1, $2,
 251                     guile_cv_func_$1_declared=yes,
 252                     guile_cv_func_$1_declared=no))
 253   if test [x$guile_cv_func_]$1[_declared] = xno; then
 254     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 255   fi
 256 ])
 257
 258 GUILE_FUNC_DECLARED(strptime, time.h)
 259 GUILE_FUNC_DECLARED(sleep, unistd.h)
 260 GUILE_FUNC_DECLARED(usleep, unistd.h)
 261
 262 ### On some systems usleep has no return value.  If it does have one,
 263 ### we'd like to return it; otherwise, we'll fake it.
 264 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 265   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 266                    /usr/include/unistd.h,
 267                    [guile_cv_func_usleep_return_type=void],
 268                    [guile_cv_func_usleep_return_type=int])])
 269 case "$guile_cv_func_usleep_return_type" in
 270   "void" )
 271     AC_DEFINE(USLEEP_RETURNS_VOID)
 272   ;;
 273 esac
 274
 275 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 276 if test -n "$have_sys_un_h" ; then
 277 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 278 fi
 279
 280 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 281
 282 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 283                setnetent    getnetent    endnetent    dnl
 284                setprotoent  getprotoent  endprotoent  dnl
 285                setservent   getservent   endservent   dnl
 286                getnetbyaddr getnetbyname dnl
 287                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 288                inet_pton inet_ntop)
 289
 290 dnl Some systems do not declare this.  Some systems do declare it, as a
 291 dnl macro.  With cygwin it may be in a DLL.
 292
 293 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 294 AC_CACHE_VAL(guile_cv_have_h_errno,
 295 [AC_TRY_COMPILE([#include <netdb.h>],
 296 [int a = h_errno;],
 297 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 298 AC_MSG_RESULT($guile_cv_have_h_errno)
 299 if test $guile_cv_have_h_errno = yes; then
 300   AC_DEFINE(HAVE_H_ERRNO)
 301 fi
 302
 303 AC_MSG_CHECKING(whether netdb.h defines uint32_t)
 304 AC_CACHE_VAL(guile_cv_have_uint32_t,
 305 [AC_TRY_COMPILE([#include <netdb.h>],
 306 [uint32_t a;],
 307 guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 308 AC_MSG_RESULT($guile_cv_have_uint32_t)
 309 if test $guile_cv_have_uint32_t = yes; then
 310   AC_DEFINE(HAVE_UINT32_T)
 311 fi
 312
 313 AC_MSG_CHECKING(for working IPv6 support)
 314 AC_CACHE_VAL(guile_cv_have_ipv6,
 315 [AC_TRY_COMPILE([#include <netinet/in.h>
 316 #include <sys/socket.h>],
 317 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 318 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 319 AC_MSG_RESULT($guile_cv_have_ipv6)
 320 if test $guile_cv_have_ipv6 = yes; then
 321   AC_DEFINE(HAVE_IPV6)
 322 fi
 323
 324 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 325 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 326 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 327 [AC_TRY_COMPILE([#include <netinet/in.h>],
 328 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 329 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 330 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 331 if test $guile_cv_have_sin6_scope_id = yes; then
 332   AC_DEFINE(HAVE_SIN6_SCOPE_ID)
 333 fi
 334
 335 AC_MSG_CHECKING(whether localtime caches TZ)
 336 AC_CACHE_VAL(guile_cv_localtime_cache,
 337 [if test x$ac_cv_func_tzset = xyes; then
 338 AC_TRY_RUN([#include <time.h>
 339 #if STDC_HEADERS
 340 # include <stdlib.h>
 341 #endif
 342 extern char **environ;
 343 unset_TZ ()
 344 {
 345   char **from, **to;
 346   for (to = from = environ; (*to = *from); from++)
 347     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 348       to++;
 349 }
 350 char TZ_GMT0[] = "TZ=GMT0";
 351 char TZ_PST8[] = "TZ=PST8";
 352 main()
 353 {
 354   time_t now = time ((time_t *) 0);
 355   int hour_GMT0, hour_unset;
 356   if (putenv (TZ_GMT0) != 0)
 357     exit (1);
 358   hour_GMT0 = localtime (&now)->tm_hour;
 359   unset_TZ ();
 360   hour_unset = localtime (&now)->tm_hour;
 361   if (putenv (TZ_PST8) != 0)
 362     exit (1);
 363   if (localtime (&now)->tm_hour == hour_GMT0)
 364     exit (1);
 365   unset_TZ ();
 366   if (localtime (&now)->tm_hour != hour_unset)
 367     exit (1);
 368   exit (0);
 369 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 370 [# If we have tzset, assume the worst when cross-compiling.
 371 guile_cv_localtime_cache=yes])
 372 else
 373         # If we lack tzset, report that localtime does not cache TZ,
 374         # since we can't invalidate the cache if we don't have tzset.
 375         guile_cv_localtime_cache=no
 376 fi])dnl
 377 AC_MSG_RESULT($guile_cv_localtime_cache)
 378 if test $guile_cv_localtime_cache = yes; then
 379   AC_DEFINE(LOCALTIME_CACHE)
 380 fi
 381
 382 dnl Test whether system calls are restartable by default on the
 383 dnl current system.  If they are not, we put a loop around every system
 384 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 385 dnl change from the default behaviour.  On the other hand, if signals
 386 dnl are restartable then the loop is not installed and when libguile
 387 dnl initialises it also resets the behaviour of each signal to cause a
 388 dnl restart (in case a different runtime had a different default
 389 dnl behaviour for some reason: e.g., different versions of linux seem
 390 dnl to behave differently.)
 391
 392 AC_SYS_RESTARTABLE_SYSCALLS
 393
 394 if test "$enable_regex" = yes; then
 395    if test "$ac_cv_header_regex_h" = yes ||
 396       test "$ac_cv_header_rxposix_h" = yes ||
 397       test "$ac_cv_header_rx_rxposix_h" = yes; then
 398      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 399      [AC_CHECK_LIB(rx, main)
 400       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 401      )
 402      dnl The following should not be necessary, but for some reason
 403      dnl autoheader misses it if we don't include it!
 404      if test "$ac_cv_func_regcomp_norx" = yes ||
 405         test "$ac_cv_func_regcomp_rx" = yes; then
 406        AC_DEFINE(HAVE_REGCOMP)
 407      fi
 408    fi
 409 fi
 410
 411 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 412
 413 # When testing for the presence of alloca, we need to add alloca.o
 414 # explicitly to LIBOBJS to make sure that it is translated to
 415 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 416 AC_FUNC_ALLOCA
 417 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 418
 419 AC_CHECK_MEMBERS([struct stat.st_rdev])
 420 AC_CHECK_MEMBERS([struct stat.st_blksize])
 421
 422 AC_STRUCT_ST_BLOCKS
 423
 424 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 425   [AC_TRY_CPP([#include <sys/stat.h>
 426                #ifndef S_ISLNK
 427                #error no S_ISLNK
 428                #endif],
 429                ac_cv_macro_S_ISLNK=yes,
 430                ac_cv_macro_S_ISLNK=no)])
 431 if test $ac_cv_macro_S_ISLNK = yes; then
 432   AC_DEFINE(HAVE_S_ISLNK)
 433 fi
 434
 435 AC_STRUCT_TIMEZONE
 436 GUILE_STRUCT_UTIMBUF
 437
 438 #--------------------------------------------------------------------
 439 #
 440 # Which way does the stack grow?
 441 #
 442 #--------------------------------------------------------------------
 443
 444 AC_TRY_RUN(aux (l) unsigned long l;
 445              { int x; exit (l >= ((unsigned long)&x)); }
 446            main () { int q; aux((unsigned long)&q); },
 447            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 448
 449 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 450     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 451                 [guile_cv_type_float_fits_long=yes],
 452                 [guile_cv_type_float_fits_long=no],
 453                 [guile_cv_type_float_fits_long=guess-yes])])
 454 case $guile_cv_type_float_fits_long in
 455   "yes" )
 456     AC_DEFINE(SCM_SINGLES)
 457   ;;
 458   "guess-yes" )
 459     AC_DEFINE(SCM_SINGLES)
 460     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 461     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 462   ;;
 463 esac
 464
 465
 466 AC_MSG_CHECKING(for struct linger)
 467 AC_CACHE_VAL(scm_cv_struct_linger,
 468         AC_TRY_COMPILE([
 469 #include <sys/types.h>
 470 #include <sys/socket.h>],
 471                         [struct linger lgr;  lgr.l_linger = 100],
 472                         scm_cv_struct_linger="yes",
 473                         scm_cv_struct_linger="no"))
 474 AC_MSG_RESULT($scm_cv_struct_linger)
 475 if test $scm_cv_struct_linger = yes; then
 476         AC_DEFINE(HAVE_STRUCT_LINGER)
 477 fi
 478
 479
 480 AC_MSG_CHECKING(for struct timespec)
 481 AC_CACHE_VAL(scm_cv_struct_timespec,
 482         AC_TRY_COMPILE([
 483 #include <time.h>],
 484                         [struct timespec t;  t.tv_nsec = 100],
 485                         scm_cv_struct_timespec="yes",
 486                         scm_cv_struct_timespec="no"))
 487 AC_MSG_RESULT($scm_cv_struct_timespec)
 488 if test $scm_cv_struct_timespec = yes; then
 489         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 490 fi
 491
 492 #--------------------------------------------------------------------
 493 #
 494 # Flags for thread support
 495 #
 496 #--------------------------------------------------------------------
 497
 498 ### What thread package has the user asked for?
 499 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 500             , with_threads=no)
 501
 502 ### Turn $with_threads into either the name of a threads package, like
 503 ### `qt', or `no', meaning that threads should not be supported.
 504 AC_MSG_CHECKING(whether to support threads)
 505 case "$with_threads" in
 506   "yes" | "qt" | "coop" | "")
 507     with_threads=qt
 508   ;;
 509   "no" )
 510   ;;
 511   * )
 512     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 513   ;;
 514 esac
 515 AC_MSG_RESULT($with_threads)
 516
 517 ## Make sure the threads package we've chosen is actually supported on
 518 ## the present platform.
 519 case "${with_threads}" in
 520   "qt" )
 521     ## This configures the QuickThreads package, and sets or clears
 522     ## the THREAD_PACKAGE variable if qthreads don't configure
 523     ## correctly.
 524     QTHREADS_CONFIGURE
 525    ;;
 526 esac
 527
 528 ## If we're using threads, bring in some other parts of Guile which
 529 ## work with them.
 530 if test "${THREAD_PACKAGE}" != "" ; then
 531   AC_DEFINE(USE_THREADS, 1)
 532
 533   ## Include the Guile thread interface in the library...
 534   LIBOBJS="$LIBOBJS threads.o"
 535
 536   ## ... and tell it which package to talk to.
 537   case "${THREAD_PACKAGE}" in
 538     "QT" )
 539       AC_DEFINE(USE_COOP_THREADS, 1)
 540     ;;
 541     * )
 542       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 543     ;;
 544   esac
 545
 546   ## Bring in scm_internal_select, if appropriate.
 547   if test $ac_cv_func_gettimeofday = yes &&
 548      test $ac_cv_func_select = yes; then
 549     AC_DEFINE(GUILE_ISELECT, 1)
 550   fi
 551
 552   ## Workaround for linuxthreads (currently disabled)
 553   if test $host_os = linux-gnu; then
 554     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 555     AC_CHECK_LIB(pthread, main)
 556   fi
 557 fi
 558 AC_SUBST(LIBGUILEQTHREADS_MAJOR_VERSION)
 559 AC_SUBST(LIBGUILEQTHREADS_MINOR_VERSION)
 560 AC_SUBST(LIBGUILEQTHREADS_REVISION_VERSION)
 561 AC_SUBST(LIBGUILEQTHREADS_VERSION)
 562
 563 ## If we're using GCC, ask for aggressive warnings.
 564 case "$GCC" in
 565   yes )
 566     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 567     ## much stuff with generic function pointers for that to really be
 568     ## less than exasperating.
 569     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 570     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 571     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 572 esac
 573
 574 AC_PROG_AWK
 575
 576 ## If we're creating a shared library (using libtool!), then we'll
 577 ## need to generate a list of .lo files corresponding to the .o files
 578 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 579 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 580
 581 ## We also need to create corresponding .doc and .x files
 582 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 583 EXTRA_DOT_X_FILES="`echo ${LIBOBJS} | sed 's/\.o/.x/g'`"
 584
 585 AC_SUBST(GUILE_MAJOR_VERSION)
 586 AC_SUBST(GUILE_MINOR_VERSION)
 587 AC_SUBST(GUILE_MICRO_VERSION)
 588 AC_SUBST(GUILE_VERSION)
 589 AC_SUBST(LIBGUILE_MAJOR_VERSION)
 590 AC_SUBST(LIBGUILE_MINOR_VERSION)
 591 AC_SUBST(LIBGUILE_REVISION_VERSION)
 592 AC_SUBST(LIBGUILE_VERSION)
 593
 594 dnl Tell guile-config what flags guile users should link against.
 595 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 596 AC_SUBST(GUILE_LIBS)
 597
 598 AC_SUBST(AWK)
 599 AC_SUBST(LIBLOBJS)
 600 AC_SUBST(EXTRA_DOT_DOC_FILES)
 601 AC_SUBST(EXTRA_DOT_X_FILES)
 602
 603 AC_CONFIG_FILES([
 604   Makefile
 605   libguile/Makefile
 606   libguile/guile-snarf
 607   libguile/guile-doc-snarf
 608   libguile/guile-func-name-check
 609   libguile/guile-snarf-docs
 610   libguile/guile-snarf-docs-texi
 611   libguile/versiondat.h
 612   ice-9/Makefile
 613   oop/Makefile
 614   oop/goops/Makefile
 615   scripts/Makefile
 616   srfi/Makefile
 617   qt/Makefile
 618   qt/qt.h
 619   qt/md/Makefile
 620   qt/time/Makefile
 621   guile-config/Makefile
 622   doc/Makefile
 623   examples/Makefile
 624   examples/scripts/Makefile
 625   examples/box/Makefile
 626   examples/box-module/Makefile
 627   examples/box-dynamic/Makefile
 628   examples/box-dynamic-module/Makefile
 629   examples/modules/Makefile
 630   examples/safe/Makefile
 631   check-guile
 632   guile-tools])
 633
 634 AC_CONFIG_COMMANDS(default,
 635   [ chmod +x libguile/guile-snarf \
 636              libguile/guile-doc-snarf \
 637              libguile/guile-func-name-check \
 638              libguile/guile-snarf-docs \
 639              libguile/guile-snarf-docs-texi \
 640              check-guile \
 641              guile-tools])
 642
 643 AC_OUTPUT
 644
 645 dnl Local Variables:
 646 dnl comment-start: "dnl "
 647 dnl comment-end: ""
 648 dnl comment-start-skip: "\\bdnl\\b\\s *"
 649 dnl End: