configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_PREREQ(2.50)
  24
  25 AC_INIT
  26 AC_CONFIG_SRCDIR([Makefile.in])
  27 . $srcdir/GUILE-VERSION
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  29 AM_MAINTAINER_MODE
  30 AM_CONFIG_HEADER(libguile/scmconfig.h)
  31
  32 #--------------------------------------------------------------------
  33 #
  34 # Independent Subdirectories
  35 #
  36 #--------------------------------------------------------------------
  37
  38 AC_CONFIG_SUBDIRS(guile-readline)
  39
  40 #--------------------------------------------------------------------
  41 #
  42 # User options
  43 #
  44 #--------------------------------------------------------------------
  45
  46 AC_ARG_ENABLE(debug-freelist,
  47   [  --enable-debug-freelist include garbage collector freelist debugging code],
  48   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  49     AC_DEFINE(GUILE_DEBUG_FREELIST)
  50   fi)
  51
  52 AC_ARG_ENABLE(debug-malloc,
  53   [  --enable-debug-malloc   include malloc debugging code],
  54   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  55     AC_DEFINE(GUILE_DEBUG_MALLOC)
  56   fi)
  57
  58 AC_ARG_ENABLE(guile-debug,
  59   [  --enable-guile-debug    include internal debugging functions],
  60   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  61     AC_DEFINE(GUILE_DEBUG)
  62   fi)
  63
  64 AC_ARG_ENABLE(arrays,
  65   [  --disable-arrays        omit array and uniform array support],,
  66   enable_arrays=yes)
  67
  68 AC_ARG_ENABLE(posix,
  69   [  --disable-posix         omit posix interfaces],,
  70   enable_posix=yes)
  71
  72 AC_ARG_ENABLE(networking,
  73   [  --disable-networking    omit networking interfaces],,
  74   enable_networking=yes)
  75
  76 AC_ARG_ENABLE(regex,
  77   [  --disable-regex         omit regular expression interfaces],,
  78   enable_regex=yes)
  79
  80 AC_ARG_ENABLE(htmldoc,
  81   [  --enable-htmldoc        build HTML documentation as well as Info],
  82   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  83      htmldoc_enabled=yes
  84      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  85      if test "$TEXI2HTML" = "not found"; then
  86        echo
  87        echo Building HTML documentation requires the \`texi2html\' program,
  88        echo which appears not to be present on your machine.
  89        echo
  90        echo \`texi2html\' is available from
  91        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
  92        echo
  93        echo In the meantime, to build the guile-doc distribution
  94        echo without HTML enabled, please rerun \`./configure\' without
  95        echo the \`--enable-htmldoc\' option.
  96        exit -1
  97      fi
  98    fi])
  99
 100 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
 101
 102 AC_ARG_ENABLE(deprecated,
 103   [  --disable-deprecated    omit deprecated features [no]])
 104
 105 if test "$enable_deprecated" = no; then
 106   AC_DEFINE(SCM_DEBUG_DEPRECATED, 1)
 107 else
 108   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 109     warn_default=summary
 110   elif test "$enable_deprecated" = shutup; then
 111     warn_default=no
 112   else
 113     warn_default=$enable_deprecated
 114   fi
 115   AC_DEFINE(SCM_DEBUG_DEPRECATED, 0)
 116   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default")
 117 fi
 118
 119 dnl The --disable-debug used to control these two.  But now they are
 120 dnl a required part of the distribution.
 121 AC_DEFINE(DEBUG_EXTENSIONS)
 122 AC_DEFINE(READER_EXTENSIONS)
 123
 124 dnl files which are destined for separate modules.
 125
 126 if test "$enable_arrays" = yes; then
 127    LIBOBJS="$LIBOBJS ramap.o unif.o"
 128    AC_DEFINE(HAVE_ARRAYS)
 129 fi
 130
 131 if test "$enable_posix" = yes; then
 132    LIBOBJS="$LIBOBJS filesys.o posix.o"
 133    AC_DEFINE(HAVE_POSIX)
 134 fi
 135
 136 if test "$enable_networking" = yes; then
 137    LIBOBJS="$LIBOBJS net_db.o socket.o"
 138    AC_DEFINE(HAVE_NETWORKING)
 139 fi
 140
 141 if test "$enable_debug_malloc" = yes; then
 142    LIBOBJS="$LIBOBJS debug-malloc.o"
 143 fi
 144
 145 #--------------------------------------------------------------------
 146
 147 AC_LIBLTDL_CONVENIENCE
 148 AC_CONFIG_SUBDIRS(libltdl)
 149
 150 AC_PROG_CC
 151 AC_PROG_CPP
 152 AC_LIBTOOL_DLOPEN
 153
 154 AC_AIX
 155 AC_ISC_POSIX
 156 AC_MINIX
 157
 158 AM_PROG_CC_STDC
 159 AM_PROG_LIBTOOL
 160
 161 AC_C_CONST
 162 AC_C_INLINE
 163 AC_C_BIGENDIAN
 164
 165 AC_CHECK_SIZEOF(int)
 166 AC_CHECK_SIZEOF(long)
 167
 168 dnl by the pre C9X ANSI C standards, size_t & ptrdiff_t have to be
 169 dnl representable by a standard integral type.  since the largest
 170 dnl integer type in the pre-C9X ANSI C standards is long...
 171 AC_CHECK_TYPE(ptrdiff_t, long)
 172
 173 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 174                AC_TRY_COMPILE(,
 175                               [long long a],
 176                               scm_cv_long_longs=yes,
 177                               scm_cv_long_longs=no))
 178 if test "$scm_cv_long_longs" = yes; then
 179   AC_DEFINE(HAVE_LONG_LONGS)
 180   AC_CHECK_SIZEOF(long long)
 181 fi
 182
 183 AC_CHECK_SIZEOF(void *)
 184
 185 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 186   AC_MSG_ERROR(sizes of long and void* are not identical)
 187 fi
 188
 189 AC_HEADER_STDC
 190 AC_HEADER_DIRENT
 191 AC_HEADER_TIME
 192 AC_HEADER_SYS_WAIT
 193 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h sys/utime.h time.h unistd.h utime.h)
 194 GUILE_HEADER_LIBC_WITH_UNISTD
 195
 196 AC_TYPE_GETGROUPS
 197 AC_TYPE_SIGNAL
 198 AC_TYPE_MODE_T
 199
 200 AC_CHECK_LIB(m, main)
 201 AC_CHECK_FUNCS(gethostbyname)
 202 if test $ac_cv_func_gethostbyname = no; then
 203     AC_CHECK_LIB(nsl, gethostbyname)
 204 fi
 205 AC_CHECK_FUNCS(connect)
 206 if test $ac_cv_func_connect = no; then
 207     AC_CHECK_LIB(socket, connect)
 208 fi
 209
 210 # Check for dynamic linking
 211
 212 use_modules=yes
 213 AC_ARG_WITH(modules,
 214 [  --with-modules[=FILES]  Add support for dynamic modules],
 215 use_modules="$withval")
 216 test -z "$use_modules" && use_modules=yes
 217 DLPREOPEN=
 218 if test "$use_modules" != no; then
 219   AC_DEFINE(DYNAMIC_LINKING)
 220   if test "$use_modules" = yes; then
 221     DLPREOPEN="-dlpreopen force"
 222   else
 223     DLPREOPEN="-export-dynamic"
 224     for module in $use_modules; do
 225       DLPREOPEN="$DLPREOPEN -dlopen $module"
 226     done
 227   fi
 228 fi
 229 AC_SUBST(INCLTDL)
 230 AC_SUBST(LIBLTDL)
 231 AC_SUBST(DLPREOPEN)
 232
 233 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit)
 234
 235 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 236 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 237 AC_CHECK_LIB(crypt, crypt)
 238
 239 ### Some systems don't declare some functions.  On such systems, we
 240 ### need to at least provide our own K&R-style declarations.
 241
 242 ### GUILE_FUNC_DECLARED(function, headerfile)
 243
 244 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 245 ### not there, #define MISSING_FUNCTION_DECL.
 246 AC_DEFUN(GUILE_FUNC_DECLARED, [
 247   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 248     AC_EGREP_HEADER($1, $2,
 249                     guile_cv_func_$1_declared=yes,
 250                     guile_cv_func_$1_declared=no))
 251   if test [x$guile_cv_func_]$1[_declared] = xno; then
 252     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 253   fi
 254 ])
 255
 256 GUILE_FUNC_DECLARED(strptime, time.h)
 257 GUILE_FUNC_DECLARED(sleep, unistd.h)
 258 GUILE_FUNC_DECLARED(usleep, unistd.h)
 259
 260 ### On some systems usleep has no return value.  If it does have one,
 261 ### we'd like to return it; otherwise, we'll fake it.
 262 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 263   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 264                    /usr/include/unistd.h,
 265                    [guile_cv_func_usleep_return_type=void],
 266                    [guile_cv_func_usleep_return_type=int])])
 267 case "$guile_cv_func_usleep_return_type" in
 268   "void" )
 269     AC_DEFINE(USLEEP_RETURNS_VOID)
 270   ;;
 271 esac
 272
 273 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 274 if test -n "$have_sys_un_h" ; then
 275 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 276 fi
 277
 278 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 279
 280 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 281                setnetent    getnetent    endnetent    dnl
 282                setprotoent  getprotoent  endprotoent  dnl
 283                setservent   getservent   endservent   dnl
 284                getnetbyaddr getnetbyname dnl
 285                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 286                inet_pton inet_ntop)
 287
 288 dnl Some systems do not declare this.  Some systems do declare it, as a
 289 dnl macro.  With cygwin it may be in a DLL.
 290
 291 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 292 AC_CACHE_VAL(guile_cv_have_h_errno,
 293 [AC_TRY_COMPILE([#include <netdb.h>],
 294 [int a = h_errno;],
 295 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 296 AC_MSG_RESULT($guile_cv_have_h_errno)
 297 if test $guile_cv_have_h_errno = yes; then
 298   AC_DEFINE(HAVE_H_ERRNO)
 299 fi
 300
 301 AC_MSG_CHECKING(whether netdb.h defines uint32_t)
 302 AC_CACHE_VAL(guile_cv_have_uint32_t,
 303 [AC_TRY_COMPILE([#include <netdb.h>],
 304 [uint32_t a;],
 305 guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 306 AC_MSG_RESULT($guile_cv_have_uint32_t)
 307 if test $guile_cv_have_uint32_t = yes; then
 308   AC_DEFINE(HAVE_UINT32_T)
 309 fi
 310
 311 AC_MSG_CHECKING(for working IPv6 support)
 312 AC_CACHE_VAL(guile_cv_have_ipv6,
 313 [AC_TRY_COMPILE([#include <netinet/in.h>
 314 #include <sys/socket.h>],
 315 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 316 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 317 AC_MSG_RESULT($guile_cv_have_ipv6)
 318 if test $guile_cv_have_ipv6 = yes; then
 319   AC_DEFINE(HAVE_IPV6)
 320 fi
 321
 322 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 323 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 324 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 325 [AC_TRY_COMPILE([#include <netinet/in.h>],
 326 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 327 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 328 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 329 if test $guile_cv_have_sin6_scope_id = yes; then
 330   AC_DEFINE(HAVE_SIN6_SCOPE_ID)
 331 fi
 332
 333 AC_MSG_CHECKING(whether localtime caches TZ)
 334 AC_CACHE_VAL(guile_cv_localtime_cache,
 335 [if test x$ac_cv_func_tzset = xyes; then
 336 AC_TRY_RUN([#include <time.h>
 337 #if STDC_HEADERS
 338 # include <stdlib.h>
 339 #endif
 340 extern char **environ;
 341 unset_TZ ()
 342 {
 343   char **from, **to;
 344   for (to = from = environ; (*to = *from); from++)
 345     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 346       to++;
 347 }
 348 char TZ_GMT0[] = "TZ=GMT0";
 349 char TZ_PST8[] = "TZ=PST8";
 350 main()
 351 {
 352   time_t now = time ((time_t *) 0);
 353   int hour_GMT0, hour_unset;
 354   if (putenv (TZ_GMT0) != 0)
 355     exit (1);
 356   hour_GMT0 = localtime (&now)->tm_hour;
 357   unset_TZ ();
 358   hour_unset = localtime (&now)->tm_hour;
 359   if (putenv (TZ_PST8) != 0)
 360     exit (1);
 361   if (localtime (&now)->tm_hour == hour_GMT0)
 362     exit (1);
 363   unset_TZ ();
 364   if (localtime (&now)->tm_hour != hour_unset)
 365     exit (1);
 366   exit (0);
 367 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 368 [# If we have tzset, assume the worst when cross-compiling.
 369 guile_cv_localtime_cache=yes])
 370 else
 371         # If we lack tzset, report that localtime does not cache TZ,
 372         # since we can't invalidate the cache if we don't have tzset.
 373         guile_cv_localtime_cache=no
 374 fi])dnl
 375 AC_MSG_RESULT($guile_cv_localtime_cache)
 376 if test $guile_cv_localtime_cache = yes; then
 377   AC_DEFINE(LOCALTIME_CACHE)
 378 fi
 379
 380 dnl Test whether system calls are restartable by default on the
 381 dnl current system.  If they are not, we put a loop around every system
 382 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 383 dnl change from the default behaviour.  On the other hand, if signals
 384 dnl are restartable then the loop is not installed and when libguile
 385 dnl initialises it also resets the behaviour of each signal to cause a
 386 dnl restart (in case a different runtime had a different default
 387 dnl behaviour for some reason: e.g., different versions of linux seem
 388 dnl to behave differently.)
 389
 390 AC_SYS_RESTARTABLE_SYSCALLS
 391
 392 if test "$enable_regex" = yes; then
 393    if test "$ac_cv_header_regex_h" = yes ||
 394       test "$ac_cv_header_rxposix_h" = yes ||
 395       test "$ac_cv_header_rx_rxposix_h" = yes; then
 396      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 397      [AC_CHECK_LIB(rx, main)
 398       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 399      )
 400      dnl The following should not be necessary, but for some reason
 401      dnl autoheader misses it if we don't include it!
 402      if test "$ac_cv_func_regcomp_norx" = yes ||
 403         test "$ac_cv_func_regcomp_rx" = yes; then
 404        AC_DEFINE(HAVE_REGCOMP)
 405      fi
 406    fi
 407 fi
 408
 409 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 410
 411 # When testing for the presence of alloca, we need to add alloca.o
 412 # explicitly to LIBOBJS to make sure that it is translated to
 413 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 414 AC_FUNC_ALLOCA
 415 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 416
 417 AC_CHECK_MEMBERS([struct stat.st_rdev])
 418 AC_CHECK_MEMBERS([struct stat.st_blksize])
 419
 420 AC_STRUCT_ST_BLOCKS
 421
 422 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 423   [AC_TRY_CPP([#include <sys/stat.h>
 424                #ifndef S_ISLNK
 425                #error no S_ISLNK
 426                #endif],
 427                ac_cv_macro_S_ISLNK=yes,
 428                ac_cv_macro_S_ISLNK=no)])
 429 if test $ac_cv_macro_S_ISLNK = yes; then
 430   AC_DEFINE(HAVE_S_ISLNK)
 431 fi
 432
 433 AC_STRUCT_TIMEZONE
 434 GUILE_STRUCT_UTIMBUF
 435
 436 #--------------------------------------------------------------------
 437 #
 438 # Which way does the stack grow?
 439 #
 440 #--------------------------------------------------------------------
 441
 442 AC_TRY_RUN(aux (l) unsigned long l;
 443              { int x; exit (l >= ((unsigned long)&x)); }
 444            main () { int q; aux((unsigned long)&q); },
 445            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 446
 447 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 448     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 449                 [guile_cv_type_float_fits_long=yes],
 450                 [guile_cv_type_float_fits_long=no],
 451                 [guile_cv_type_float_fits_long=guess-yes])])
 452 case $guile_cv_type_float_fits_long in
 453   "yes" )
 454     AC_DEFINE(SCM_SINGLES)
 455   ;;
 456   "guess-yes" )
 457     AC_DEFINE(SCM_SINGLES)
 458     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 459     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 460   ;;
 461 esac
 462
 463
 464 AC_MSG_CHECKING(for struct linger)
 465 AC_CACHE_VAL(scm_cv_struct_linger,
 466         AC_TRY_COMPILE([
 467 #include <sys/types.h>
 468 #include <sys/socket.h>],
 469                         [struct linger lgr;  lgr.l_linger = 100],
 470                         scm_cv_struct_linger="yes",
 471                         scm_cv_struct_linger="no"))
 472 AC_MSG_RESULT($scm_cv_struct_linger)
 473 if test $scm_cv_struct_linger = yes; then
 474         AC_DEFINE(HAVE_STRUCT_LINGER)
 475 fi
 476
 477
 478 AC_MSG_CHECKING(for struct timespec)
 479 AC_CACHE_VAL(scm_cv_struct_timespec,
 480         AC_TRY_COMPILE([
 481 #include <time.h>],
 482                         [struct timespec t;  t.tv_nsec = 100],
 483                         scm_cv_struct_timespec="yes",
 484                         scm_cv_struct_timespec="no"))
 485 AC_MSG_RESULT($scm_cv_struct_timespec)
 486 if test $scm_cv_struct_timespec = yes; then
 487         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 488 fi
 489
 490 #--------------------------------------------------------------------
 491 #
 492 # Flags for thread support
 493 #
 494 #--------------------------------------------------------------------
 495
 496 ### What thread package has the user asked for?
 497 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 498             , with_threads=no)
 499
 500 ### Turn $with_threads into either the name of a threads package, like
 501 ### `qt', or `no', meaning that threads should not be supported.
 502 AC_MSG_CHECKING(whether to support threads)
 503 case "$with_threads" in
 504   "yes" | "qt" | "coop" | "")
 505     with_threads=qt
 506   ;;
 507   "no" )
 508   ;;
 509   * )
 510     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 511   ;;
 512 esac
 513 AC_MSG_RESULT($with_threads)
 514
 515 ## Make sure the threads package we've chosen is actually supported on
 516 ## the present platform.
 517 case "${with_threads}" in
 518   "qt" )
 519     ## This configures the QuickThreads package, and sets or clears
 520     ## the THREAD_PACKAGE variable if qthreads don't configure
 521     ## correctly.
 522     QTHREADS_CONFIGURE
 523    ;;
 524 esac
 525
 526 ## If we're using threads, bring in some other parts of Guile which
 527 ## work with them.
 528 if test "${THREAD_PACKAGE}" != "" ; then
 529   AC_DEFINE(USE_THREADS, 1)
 530
 531   ## Include the Guile thread interface in the library...
 532   LIBOBJS="$LIBOBJS threads.o"
 533
 534   ## ... and tell it which package to talk to.
 535   case "${THREAD_PACKAGE}" in
 536     "QT" )
 537       AC_DEFINE(USE_COOP_THREADS, 1)
 538     ;;
 539     * )
 540       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 541     ;;
 542   esac
 543
 544   ## Bring in scm_internal_select, if appropriate.
 545   if test $ac_cv_func_gettimeofday = yes &&
 546      test $ac_cv_func_select = yes; then
 547     AC_DEFINE(GUILE_ISELECT, 1)
 548   fi
 549
 550   ## Workaround for linuxthreads (currently disabled)
 551   if test $host_os = linux-gnu; then
 552     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 553     AC_CHECK_LIB(pthread, main)
 554   fi
 555 fi
 556 AC_SUBST(LIBGUILEQTHREADS_MAJOR_VERSION)
 557 AC_SUBST(LIBGUILEQTHREADS_MINOR_VERSION)
 558 AC_SUBST(LIBGUILEQTHREADS_REVISION_VERSION)
 559 AC_SUBST(LIBGUILEQTHREADS_VERSION)
 560
 561 ## If we're using GCC, ask for aggressive warnings.
 562 case "$GCC" in
 563   yes )
 564     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 565     ## much stuff with generic function pointers for that to really be
 566     ## less than exasperating.
 567     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 568     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 569     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 570 esac
 571
 572 AC_PROG_AWK
 573
 574 ## If we're creating a shared library (using libtool!), then we'll
 575 ## need to generate a list of .lo files corresponding to the .o files
 576 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 577 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 578
 579 ## We also need to create corresponding .doc and .x files
 580 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 581 EXTRA_DOT_X_FILES="`echo ${LIBOBJS} | sed 's/\.o/.x/g'`"
 582
 583 AC_SUBST(GUILE_MAJOR_VERSION)
 584 AC_SUBST(GUILE_MINOR_VERSION)
 585 AC_SUBST(GUILE_MICRO_VERSION)
 586 AC_SUBST(GUILE_VERSION)
 587 AC_SUBST(LIBGUILE_MAJOR_VERSION)
 588 AC_SUBST(LIBGUILE_MINOR_VERSION)
 589 AC_SUBST(LIBGUILE_REVISION_VERSION)
 590 AC_SUBST(LIBGUILE_VERSION)
 591
 592 dnl Tell guile-config what flags guile users should link against.
 593 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 594 AC_SUBST(GUILE_LIBS)
 595
 596 AC_SUBST(AWK)
 597 AC_SUBST(LIBLOBJS)
 598 AC_SUBST(EXTRA_DOT_DOC_FILES)
 599 AC_SUBST(EXTRA_DOT_X_FILES)
 600
 601 AC_CONFIG_FILES([
 602   Makefile
 603   libguile/Makefile
 604   libguile/guile-doc-snarf
 605   libguile/guile-func-name-check
 606   libguile/guile-snarf-docs
 607   libguile/guile-snarf-docs-texi
 608   libguile/versiondat.h
 609   ice-9/Makefile
 610   oop/Makefile
 611   oop/goops/Makefile
 612   scripts/Makefile
 613   srfi/Makefile
 614   qt/Makefile
 615   qt/qt.h
 616   qt/md/Makefile
 617   qt/time/Makefile
 618   guile-config/Makefile
 619   doc/Makefile
 620   examples/Makefile
 621   examples/scripts/Makefile
 622   examples/box/Makefile
 623   examples/box-module/Makefile
 624   examples/box-dynamic/Makefile
 625   examples/modules/Makefile
 626   examples/safe/Makefile
 627   check-guile
 628   guile-tools])
 629
 630 AC_CONFIG_COMMANDS(default,
 631   [ chmod +x libguile/guile-doc-snarf \
 632              libguile/guile-func-name-check \
 633              libguile/guile-snarf-docs \
 634              libguile/guile-snarf-docs-texi \
 635              check-guile \
 636              guile-tools])
 637
 638 AC_OUTPUT
 639
 640 dnl Local Variables:
 641 dnl comment-start: "dnl "
 642 dnl comment-end: ""
 643 dnl comment-start-skip: "\\bdnl\\b\\s *"
 644 dnl End: