configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it under
  12 the terms of the GNU Lesser General Public License as published by the
  13 Free Software Foundation; either version 3, or (at your option) any
  14 later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but WITHOUT
  17 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  19 License for more details.
  20
  21 You should have received a copy of the GNU Lesser General Public
  22 License along with GUILE; see the file COPYING.LESSER.  If not, write
  23 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  24 Floor, Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.61)
  29
  30 AC_INIT([GNU Guile],
  31         m4_esyscmd([build-aux/git-version-gen                                   \
  32           .tarball-version                                                      \
  33           's/^release_\([0-9]\+\)-\([0-9]\+\)-\([0-9]\+\)/v\1.\2\.\3/g']),
  34         [bug-guile@gnu.org])
  35 AC_CONFIG_AUX_DIR([build-aux])
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_CONFIG_SRCDIR(GUILE-VERSION)
  38
  39 AM_INIT_AUTOMAKE([gnu no-define -Wall -Wno-override])
  40
  41 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  42 AC_CONFIG_SRCDIR([GUILE-VERSION])
  43
  44 . $srcdir/GUILE-VERSION
  45 GUILE_VERSION="$PACKAGE_VERSION"
  46
  47 AC_CONFIG_HEADERS([config.h])
  48 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  49
  50 #--------------------------------------------------------------------
  51
  52 AC_LANG([C])
  53
  54 dnl Some more checks for Win32
  55 AC_CANONICAL_HOST
  56
  57 AC_LIBTOOL_WIN32_DLL
  58
  59 AC_PROG_INSTALL
  60 AC_PROG_CC
  61 gl_EARLY
  62 AC_PROG_CPP
  63 AC_PROG_SED
  64 AC_PROG_AWK
  65
  66 dnl Gnulib.
  67 gl_INIT
  68
  69 AC_PROG_CC_C89
  70
  71 # for per-target cflags in the libguile subdir
  72 AM_PROG_CC_C_O
  73
  74 AC_LIBTOOL_DLOPEN
  75 AC_PROG_LIBTOOL
  76 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  77   [AC_MSG_ERROR([libltdl not found.  See README.])])
  78 AC_CHECK_HEADER([ltdl.h], [],
  79   [AC_MSG_ERROR([<ltdl.h> not found.  See README.])])
  80
  81 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  82 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  83
  84 AM_PATH_LISPDIR
  85
  86 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
  87   [Define to the host's GNU triplet.])
  88
  89 #--------------------------------------------------------------------
  90 #
  91 # User options (after above tests that may set default CFLAGS etc.)
  92 #
  93 #--------------------------------------------------------------------
  94
  95 GUILE_ERROR_ON_WARNING="no"
  96
  97 AC_ARG_ENABLE(error-on-warning,
  98   [  --enable-error-on-warning    treat compile warnings as errors],
  99   [case "${enableval}" in
 100      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 101      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 102      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 103    esac])
 104
 105 AC_ARG_ENABLE(debug-malloc,
 106   [  --enable-debug-malloc   include malloc debugging code],
 107   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 108     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 109       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 110   fi)
 111
 112 SCM_I_GSC_GUILE_DEBUG=0
 113 AC_ARG_ENABLE(guile-debug,
 114   [AS_HELP_STRING([--enable-guile-debug],
 115                   [include internal debugging functions])],
 116   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 117     SCM_I_GSC_GUILE_DEBUG=1
 118   fi)
 119
 120 AC_ARG_ENABLE(posix,
 121   [  --disable-posix         omit posix interfaces],,
 122   enable_posix=yes)
 123
 124 AC_ARG_ENABLE(networking,
 125   [  --disable-networking    omit networking interfaces],,
 126   enable_networking=yes)
 127
 128 AC_ARG_ENABLE(regex,
 129   [  --disable-regex         omit regular expression interfaces],,
 130   enable_regex=yes)
 131
 132 AC_ARG_ENABLE([discouraged],
 133   AS_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 134
 135 if test "$enable_discouraged" = no; then
 136   SCM_I_GSC_ENABLE_DISCOURAGED=0
 137 else
 138   SCM_I_GSC_ENABLE_DISCOURAGED=1
 139 fi
 140
 141 AC_ARG_ENABLE([deprecated],
 142   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 143
 144 if test "$enable_deprecated" = no; then
 145   SCM_I_GSC_ENABLE_DEPRECATED=0
 146   warn_default=no
 147 else
 148   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 149     warn_default=summary
 150   elif test "$enable_deprecated" = shutup; then
 151     warn_default=no
 152   else
 153     warn_default=$enable_deprecated
 154   fi
 155   SCM_I_GSC_ENABLE_DEPRECATED=1
 156 fi
 157 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 158 [Define this to control the default warning level for deprecated features.])
 159
 160 dnl  Added the following configure option in January 2008 following
 161 dnl  investigation of problems with "64" system and library calls on
 162 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 163 dnl  system has stat64, it will have all the other 64 APIs too; but on
 164 dnl  Darwin, stat64 is there but other APIs are missing.
 165 dnl
 166 dnl  It also appears, from the Darwin docs, that most system call APIs
 167 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 168 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 169 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 170 dnl
 171 dnl  A similar problem has been reported for HP-UX:
 172 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 173 dnl
 174 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 175 dnl  better than no Guile at all, we provide this option to suppress
 176 dnl  trying to use "64" calls.
 177 dnl
 178 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 179 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 180 dnl  missing out on that.  If so, someone can work on that in the future.
 181 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 182 dnl  wasn't building before.
 183 AC_MSG_CHECKING([whether to use system and library "64" calls])
 184 AC_ARG_WITH([64-calls],
 185   AS_HELP_STRING([--without-64-calls],
 186                  [don't attempt to use system and library calls with "64" in their names]),
 187   [use_64_calls=$withval],
 188   [use_64_calls=yes
 189    case $host in
 190      *-apple-darwin* )
 191        use_64_calls=no
 192        ;;
 193      powerpc-ibm-aix* )
 194        use_64_calls=no
 195        ;;
 196    esac])
 197 AC_MSG_RESULT($use_64_calls)
 198 case "$use_64_calls" in
 199   y* )
 200     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 201       [Define to 1 in order to try to use "64" versions of system and library calls.])
 202     ;;
 203 esac
 204
 205 #--------------------------------------------------------------------
 206
 207 dnl Check for dynamic linking
 208
 209 use_modules=yes
 210 AC_ARG_WITH(modules,
 211 [  --with-modules[=FILES]  Add support for dynamic modules],
 212 use_modules="$withval")
 213 test -z "$use_modules" && use_modules=yes
 214 DLPREOPEN=
 215 if test "$use_modules" != no; then
 216   if test "$use_modules" = yes; then
 217     DLPREOPEN="-dlpreopen force"
 218   else
 219     DLPREOPEN="-export-dynamic"
 220     for module in $use_modules; do
 221       DLPREOPEN="$DLPREOPEN -dlopen $module"
 222     done
 223   fi
 224 fi
 225
 226 dnl files which are destined for separate modules.
 227
 228 if test "$use_modules" != no; then
 229    AC_LIBOBJ([dynl])
 230 fi
 231
 232 if test "$enable_posix" = yes; then
 233    AC_LIBOBJ([filesys])
 234    AC_LIBOBJ([posix])
 235    AC_DEFINE([HAVE_POSIX], 1,
 236      [Define this if you want support for POSIX system calls in Guile.])
 237 fi
 238
 239 if test "$enable_networking" = yes; then
 240    AC_LIBOBJ([net_db])
 241    AC_LIBOBJ([socket])
 242    AC_DEFINE([HAVE_NETWORKING], 1,
 243      [Define this if you want support for networking in Guile.])
 244 fi
 245
 246 if test "$enable_debug_malloc" = yes; then
 247    AC_LIBOBJ([debug-malloc])
 248 fi
 249
 250 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 251
 252 AC_C_CONST
 253
 254 # "volatile" is used in a couple of tests below.
 255 AC_C_VOLATILE
 256
 257 AC_C_INLINE
 258 if test "$ac_cv_c_inline" != no; then
 259   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 260 else
 261   SCM_I_GSC_C_INLINE=NULL
 262 fi
 263 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 264
 265 AC_C_BIGENDIAN
 266
 267 AC_C_LABELS_AS_VALUES
 268
 269 AC_CHECK_SIZEOF(char)
 270 AC_CHECK_SIZEOF(unsigned char)
 271 AC_CHECK_SIZEOF(short)
 272 AC_CHECK_SIZEOF(unsigned short)
 273 AC_CHECK_SIZEOF(int)
 274 AC_CHECK_SIZEOF(unsigned int)
 275 AC_CHECK_SIZEOF(long)
 276 AC_CHECK_SIZEOF(unsigned long)
 277 AC_CHECK_SIZEOF(size_t)
 278 AC_CHECK_SIZEOF(long long)
 279 AC_CHECK_SIZEOF(unsigned long long)
 280 AC_CHECK_SIZEOF(__int64)
 281 AC_CHECK_SIZEOF(unsigned __int64)
 282 AC_CHECK_SIZEOF(void *)
 283 AC_CHECK_SIZEOF(intptr_t)
 284 AC_CHECK_SIZEOF(uintptr_t)
 285 AC_CHECK_SIZEOF(ptrdiff_t)
 286 AC_CHECK_SIZEOF(size_t)
 287 AC_CHECK_SIZEOF(off_t)
 288
 289 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 290   AC_MSG_ERROR(sizes of long and void* are not identical)
 291 fi
 292
 293 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 294   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 295 else
 296   SCM_I_GSC_T_PTRDIFF='"long"'
 297 fi
 298 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 299
 300 AC_CHECK_HEADERS([stdint.h])
 301 AC_CHECK_HEADERS([inttypes.h])
 302
 303 AC_CHECK_SIZEOF(intmax_t)
 304
 305 SCM_I_GSC_NEEDS_STDINT_H=0
 306 SCM_I_GSC_NEEDS_INTTYPES_H=0
 307
 308 ### intptr and uintptr (try not to use inttypes if we don't have to)
 309 if test "$ac_cv_header_inttypes_h" = yes; then
 310   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 311     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 312 #include <stdio.h>])
 313     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 314       SCM_I_GSC_NEEDS_INTTYPES_H=1
 315     fi
 316   fi
 317   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 318     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 319 #include <stdio.h>])
 320     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 321       SCM_I_GSC_NEEDS_INTTYPES_H=1
 322     fi
 323   fi
 324 fi
 325
 326 ### See what's provided by stdint.h
 327 if test "$ac_cv_header_stdint_h" = yes; then
 328    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 329    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 330    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 331    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 332    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 333    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 334    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 335    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 336    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 337    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 338    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 339    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 340 fi
 341
 342 # so we don't get confused by the cache (wish there was a better way
 343 # to check particular headers for the same type...)
 344
 345 unset ac_cv_type_int8_t
 346 unset ac_cv_type_uint8_t
 347 unset ac_cv_type_int16_t
 348 unset ac_cv_type_uint16_t
 349 unset ac_cv_type_int32_t
 350 unset ac_cv_type_uint32_t
 351 unset ac_cv_type_int64_t
 352 unset ac_cv_type_uint64_t
 353 unset ac_cv_type_intmax_t
 354 unset ac_cv_type_uintmax_t
 355
 356 ### See what's provided by inttypes.h
 357 if test "$ac_cv_header_inttypes_h" = yes; then
 358   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 359   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 360   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 361   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 362   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 363   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 364   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 365   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 366   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 367   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 368   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 369   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 370 fi
 371
 372 # Try hard to find definitions for some required scm_t_*int* types.
 373
 374 ### Required type scm_t_int8
 375 if test "$scm_stdint_has_int8"; then
 376   SCM_I_GSC_T_INT8='"int8_t"'
 377   SCM_I_GSC_NEEDS_STDINT_H=1
 378 elif test "$scm_inttypes_has_int8"; then
 379   SCM_I_GSC_T_INT8='"int8_t"'
 380   SCM_I_GSC_NEEDS_INTTYPES_H=1
 381 elif test "$ac_cv_sizeof_char" -eq 1; then
 382   SCM_I_GSC_T_INT8='"signed char"'
 383 else
 384   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 385 fi
 386 AC_SUBST([SCM_I_GSC_T_INT8])
 387
 388 ### Required type scm_t_uint8
 389 if test "$scm_stdint_has_uint8"; then
 390   SCM_I_GSC_T_UINT8='"uint8_t"'
 391   SCM_I_GSC_NEEDS_STDINT_H=1
 392 elif test "$scm_inttypes_has_uint8"; then
 393   SCM_I_GSC_T_UINT8='"uint8_t"'
 394   SCM_I_GSC_NEEDS_INTTYPES_H=1
 395 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 396   SCM_I_GSC_T_UINT8='"unsigned char"'
 397 else
 398   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 399 fi
 400 AC_SUBST([SCM_I_GSC_T_UINT8])
 401
 402 ### Required type scm_t_int16 (ANSI C says int or short might work)
 403 if test "$scm_stdint_has_int16"; then
 404   SCM_I_GSC_T_INT16='"int16_t"'
 405   SCM_I_GSC_NEEDS_STDINT_H=1
 406 elif test "$scm_inttypes_has_int16"; then
 407   SCM_I_GSC_T_INT16='"int16_t"'
 408   SCM_I_GSC_NEEDS_INTTYPES_H=1
 409 elif test "$ac_cv_sizeof_int" -eq 2; then
 410   SCM_I_GSC_T_INT16='"int"'
 411 elif test "$ac_cv_sizeof_short" -eq 2; then
 412   SCM_I_GSC_T_INT16='"short"'
 413 else
 414   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 415 fi
 416 AC_SUBST([SCM_I_GSC_T_INT16])
 417
 418 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 419 if test "$scm_stdint_has_uint16"; then
 420   SCM_I_GSC_T_UINT16='"uint16_t"'
 421   SCM_I_GSC_NEEDS_STDINT_H=1
 422 elif test "$scm_inttypes_has_uint16"; then
 423   SCM_I_GSC_T_UINT16='"uint16_t"'
 424   SCM_I_GSC_NEEDS_INTTYPES_H=1
 425 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 426   SCM_I_GSC_T_UINT16='"unsigned int"'
 427 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 428   SCM_I_GSC_T_UINT16='"unsigned short"'
 429 else
 430   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 431 fi
 432 AC_SUBST([SCM_I_GSC_T_UINT16])
 433
 434
 435 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 436 if test "$scm_stdint_has_int32"; then
 437   SCM_I_GSC_T_INT32='"int32_t"'
 438   SCM_I_GSC_NEEDS_STDINT_H=1
 439 elif test "$scm_inttypes_has_int32"; then
 440   SCM_I_GSC_T_INT32='"int32_t"'
 441   SCM_I_GSC_NEEDS_INTTYPES_H=1
 442 elif test "$ac_cv_sizeof_int" -eq 4; then
 443   SCM_I_GSC_T_INT32='"int"'
 444 elif test "$ac_cv_sizeof_long" -eq 4; then
 445   SCM_I_GSC_T_INT32='"long"'
 446 elif test "$ac_cv_sizeof_short" -eq 4; then
 447   SCM_I_GSC_T_INT32='"short"'
 448 else
 449   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 450 fi
 451 AC_SUBST([SCM_I_GSC_T_INT32])
 452
 453 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 454 if test "$scm_stdint_has_uint32"; then
 455   SCM_I_GSC_T_UINT32='"uint32_t"'
 456   SCM_I_GSC_NEEDS_STDINT_H=1
 457 elif test "$scm_inttypes_has_uint32"; then
 458   SCM_I_GSC_T_UINT32='"uint32_t"'
 459   SCM_I_GSC_NEEDS_INTTYPES_H=1
 460 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 461   SCM_I_GSC_T_UINT32='"unsigned int"'
 462 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 463   SCM_I_GSC_T_UINT32='"unsigned long"'
 464 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 465   SCM_I_GSC_T_UINT32='"unsigned short"'
 466 else
 467   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 468 fi
 469 AC_SUBST([SCM_I_GSC_T_UINT32])
 470
 471 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 472 ### Also try 'long long' and '__int64' if we have it.
 473 SCM_I_GSC_T_INT64=0
 474 if test "$scm_stdint_has_int64"; then
 475   SCM_I_GSC_T_INT64='"int64_t"'
 476   SCM_I_GSC_NEEDS_STDINT_H=1
 477 elif test "$scm_inttypes_has_int64"; then
 478   SCM_I_GSC_T_INT64='"int64_t"'
 479   SCM_I_GSC_NEEDS_INTTYPES_H=1
 480 elif test "$ac_cv_sizeof_int" -eq 8; then
 481   SCM_I_GSC_T_INT64='"int"'
 482 elif test "$ac_cv_sizeof_long" -eq 8; then
 483   SCM_I_GSC_T_INT64='"long"'
 484 elif test "$ac_cv_sizeof_short" -eq 8; then
 485   SCM_I_GSC_T_INT64='"short"'
 486 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 487   SCM_I_GSC_T_INT64='"long long"'
 488 elif test "$ac_cv_sizeof___int64" -eq 8; then
 489   SCM_I_GSC_T_INT64='"__int64"'
 490 else
 491   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 492 fi
 493 AC_SUBST([SCM_I_GSC_T_INT64])
 494
 495
 496 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 497 ### Also try 'long long' and '__int64' if we have it.
 498 SCM_I_GSC_T_UINT64=0
 499 if test "$scm_stdint_has_uint64"; then
 500   SCM_I_GSC_T_UINT64='"uint64_t"'
 501   SCM_I_GSC_NEEDS_STDINT_H=1
 502 elif test "$scm_inttypes_has_uint64"; then
 503   SCM_I_GSC_T_UINT64='"uint64_t"'
 504   SCM_I_GSC_NEEDS_INTTYPES_H=1
 505 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 506   SCM_I_GSC_T_UINT64='"unsigned int"'
 507 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 508   SCM_I_GSC_T_UINT64='"unsigned long"'
 509 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 510   SCM_I_GSC_T_UINT64='"unsigned short"'
 511 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 512   SCM_I_GSC_T_UINT64='"unsigned long long"'
 513 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 514   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 515 else
 516   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 517 fi
 518 AC_SUBST([SCM_I_GSC_T_UINT64])
 519
 520 ### Required type scm_t_intmax
 521 ###
 522 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 523 ### none of them is available, we use 'long'.
 524 ###
 525 SCM_I_GSC_T_INTMAX=0
 526 if test "$scm_stdint_has_intmax"; then
 527   SCM_I_GSC_T_INTMAX='"intmax_t"'
 528   SCM_I_GSC_NEEDS_STDINT_H=1
 529 elif test "$scm_inttypes_has_intmax"; then
 530   SCM_I_GSC_T_INTMAX='"intmax_t"'
 531   SCM_I_GSC_NEEDS_INTTYPES_H=1
 532 elif test "$ac_cv_sizeof___int64" -ne 0; then
 533   SCM_I_GSC_T_INTMAX='"__int64"'
 534 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 535   SCM_I_GSC_T_INTMAX='"long long"'
 536 else
 537   SCM_I_GSC_T_INTMAX='"long"'
 538 fi
 539 AC_SUBST([SCM_I_GSC_T_INTMAX])
 540
 541 ### Required type scm_t_uintmax
 542 ###
 543 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 544 ### this order.  When none of them is available, we use 'unsigned long'.
 545 ###
 546 SCM_I_GSC_T_UINTMAX=0
 547 if test "$scm_stdint_has_uintmax"; then
 548   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 549   SCM_I_GSC_NEEDS_STDINT_H=1
 550 elif test "$scm_inttypes_has_uintmax"; then
 551   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 552   SCM_I_GSC_NEEDS_INTTYPES_H=1
 553 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 554   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 555 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 556   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 557 else
 558   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 559 fi
 560 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 561
 562 ### Required type scm_t_intptr
 563 ###
 564 SCM_I_GSC_T_INTPTR=0
 565 if test "$scm_stdint_has_intptr"; then
 566   SCM_I_GSC_T_INTPTR='"intptr_t"'
 567   SCM_I_GSC_NEEDS_STDINT_H=1
 568 elif test "$scm_inttypes_has_intptr"; then
 569   SCM_I_GSC_T_INTPTR='"intptr_t"'
 570   SCM_I_GSC_NEEDS_INTTYPES_H=1
 571 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 572   SCM_I_GSC_T_INTPTR='"int"'
 573 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 574   SCM_I_GSC_T_INTPTR='"long"'
 575 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 576   SCM_I_GSC_T_INTPTR='"long long"'
 577 else
 578   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 579 fi
 580 AC_SUBST([SCM_I_GSC_T_INTPTR])
 581
 582 ### Required type scm_t_uintptr
 583 ###
 584 SCM_I_GSC_T_UINTPTR=0
 585 if test "$scm_stdint_has_uintptr"; then
 586   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 587   SCM_I_GSC_NEEDS_STDINT_H=1
 588 elif test "$scm_inttypes_has_uintptr"; then
 589   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 590   SCM_I_GSC_NEEDS_INTTYPES_H=1
 591 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 592   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 593 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 594   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 595 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 596   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 597 else
 598   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 599 fi
 600 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 601
 602
 603 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 604 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 605
 606 AC_HEADER_STDC
 607 AC_HEADER_TIME
 608 AC_HEADER_SYS_WAIT
 609 AC_HEADER_DIRENT
 610
 611 # Reason for checking:
 612 #
 613 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 614 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 615 #
 616 AC_CHECK_MEMBER([struct dirent64.d_name],
 617   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 618   [ #ifndef _LARGEFILE64_SOURCE
 619     # define _LARGEFILE64_SOURCE
 620     #endif
 621
 622     /* Per Autoconf manual.  */
 623     #include <sys/types.h>
 624     #ifdef HAVE_DIRENT_H
 625     # include <dirent.h>
 626     #else
 627     # define dirent direct
 628     # ifdef HAVE_SYS_NDIR_H
 629     #  include <sys/ndir.h>
 630     # endif
 631     # ifdef HAVE_SYS_DIR_H
 632     #  include <sys/dir.h>
 633     # endif
 634     # ifdef HAVE_NDIR_H
 635     #  include <ndir.h>
 636     # endif
 637     #endif ])
 638 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 639
 640 # Reasons for testing:
 641 #   complex.h - new in C99
 642 #   fenv.h - available in C99, but not older systems
 643 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 644 #     this file instead of <fenv.h>
 645 #   process.h - mingw specific
 646 #   langinfo.h, nl_types.h - SuS v2
 647 #
 648 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 649 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 650 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 651 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 652 direct.h langinfo.h nl_types.h machine/fpu.h])
 653
 654 # Reasons for testing:
 655 #   nl_item - lacking on Cygwin
 656 AC_CHECK_TYPES([nl_item], [], [],
 657   [[#ifdef HAVE_LANGINFO_H
 658     # include <langinfo.h>
 659     #endif
 660     #ifdef HAVE_NL_TYPES_H
 661     # include <nl_types.h>
 662     #endif]])
 663
 664 # "complex double" is new in C99, and "complex" is only a keyword if
 665 # <complex.h> is included
 666 AC_CHECK_TYPES(complex double,,,
 667 [#if HAVE_COMPLEX_H
 668 #include <complex.h>
 669 #endif])
 670
 671 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 672 # when testing.
 673 AC_CHECK_TYPE(socklen_t, ,
 674   [AC_DEFINE_UNQUOTED([socklen_t], int,
 675                       [Define to `int' if <sys/socket.h> does not define.])],
 676   [#if HAVE_SYS_TYPES_H
 677 #include <sys/types.h>
 678 #endif
 679 #include <sys/socket.h>
 680 ])
 681 AC_CHECK_TYPE(struct ip_mreq)
 682
 683 GUILE_HEADER_LIBC_WITH_UNISTD
 684
 685 AC_TYPE_GETGROUPS
 686 AC_TYPE_SIGNAL
 687 AC_TYPE_MODE_T
 688
 689 # On mingw -lm is empty, so this test is unnecessary, but it's
 690 # harmless so we don't hard-code to suppress it.
 691 #
 692 AC_CHECK_LIB(m, cos)
 693
 694 AC_CHECK_FUNCS(gethostbyname)
 695 if test $ac_cv_func_gethostbyname = no; then
 696     AC_CHECK_LIB(nsl, gethostbyname)
 697 fi
 698
 699 AC_CHECK_FUNCS(connect)
 700 if test $ac_cv_func_connect = no; then
 701     AC_CHECK_LIB(socket, connect)
 702 fi
 703
 704 dnl
 705 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 706 dnl
 707 EXTRA_DEFS=""
 708 case $host in
 709   *-*-mingw*)
 710     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 711       [Define if you have the <winsock2.h> header file.])])
 712     AC_CHECK_LIB(ws2_32, main)
 713     AC_LIBOBJ([win32-uname])
 714     AC_LIBOBJ([win32-dirent])
 715     if test "$enable_networking" = yes ; then
 716       AC_LIBOBJ([win32-socket])
 717     fi
 718     if test "$enable_shared" = yes ; then
 719       EXTRA_DEFS="-DSCM_IMPORT"
 720       AC_DEFINE([USE_DLL_IMPORT], 1,
 721         [Define if you need additional CPP macros on Win32 platforms.])
 722     fi
 723     ;;
 724 esac
 725 AC_SUBST(EXTRA_DEFS)
 726
 727 # Reasons for testing:
 728 #   crt_externs.h - Darwin specific
 729 #
 730 AC_CHECK_HEADERS([assert.h crt_externs.h])
 731
 732 # Reasons for testing:
 733 #   DINFINITY - OSF specific
 734 #   DQNAN - OSF specific
 735 #       (DINFINITY and DQNAN are actually global variables, not functions)
 736 #   chsize - an MS-DOS-ism, found in mingw
 737 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 738 #       for gcc to provide the "complex double" type but the system to not
 739 #       have functions like cexp and clog
 740 #   clog10 - not in mingw (though others like clog and csqrt are)
 741 #   fesetround - available in C99, but not older systems
 742 #   ftruncate - posix, but probably not older systems (current mingw
 743 #               has it as an inline for chsize)
 744 #   ioctl - not in mingw.
 745 #   gmtime_r - recent posix, not on old systems
 746 #   pipe - not in mingw
 747 #   _pipe - specific to mingw, taking 3 args
 748 #   readdir_r - recent posix, not on old systems
 749 #   readdir64_r - not available on HP-UX 11.11
 750 #   stat64 - SuS largefile stuff, not on old systems
 751 #   sysconf - not on old systems
 752 #   truncate - not in mingw
 753 #   isblank - available as a GNU extension or in C99
 754 #   _NSGetEnviron - Darwin specific
 755 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 756 #   nl_langinfo - X/Open, not available on Windows.
 757 #   utimensat: posix.1-2008
 758 #
 759 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat])
 760
 761 # Reasons for testing:
 762 #   netdb.h - not in mingw
 763 #   sys/param.h - not in mingw
 764 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 765 #       check this specifically, we need it for the timespec test below.
 766 #   sethostname - the function itself check because it's not in mingw,
 767 #       the DECL is checked because Solaris 10 doens't have in any header
 768 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 769 #       declaration isn't anywhere.
 770 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 771 #       only with `_XOPEN_SOURCE' or some such.
 772 #
 773 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h])
 774 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 775 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 776
 777 # crypt() may or may not be available, for instance in some countries there
 778 # are restrictions on cryptography.
 779 #
 780 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 781 # -lcrypt library (eg. Debian GNU/Linux).
 782 #
 783 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 784 # be careful to avoid -lcrypt in this case, since libtool will see there's
 785 # only a static libcrypt and decide to build only a static libguile.
 786 #
 787 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 788 # libraries already in that list.
 789 #
 790 AC_SEARCH_LIBS(crypt, crypt,
 791   [AC_DEFINE([HAVE_CRYPT],1,
 792              [Define to 1 if you have the `crypt' function.])])
 793
 794 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 795 # work; in the reported cases so far, 1.0fi works well instead.  According
 796 # to the C99 spec, the complex.h header must provide a working definition
 797 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 798 # is a workaround for the failure of some systems to conform to C99.
 799 if test "$ac_cv_type_complex_double" = yes; then
 800   AC_MSG_CHECKING([for i])
 801   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 802 #if HAVE_COMPLEX_H
 803 #include <complex.h>
 804 #endif
 805 complex double z;
 806 ]], [[
 807 z = _Complex_I;
 808 ]])],
 809     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 810      AC_MSG_RESULT([_Complex_I])],
 811     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 812 #if HAVE_COMPLEX_H
 813 #include <complex.h>
 814 #endif
 815 complex double z;
 816 ]],[[
 817 z = 1.0fi;
 818 ]])],
 819   [AC_DEFINE([GUILE_I],1.0fi)
 820    AC_MSG_RESULT([1.0fi])],
 821   [ac_cv_type_complex_double=no
 822    AC_MSG_RESULT([not available])])])
 823 fi
 824
 825 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 826 # csqrt(-i) returned a negative real part, when it should be positive
 827 # for the principal root.
 828 #
 829 if test "$ac_cv_type_complex_double" = yes; then
 830
 831   AC_CACHE_CHECK([whether csqrt is usable],
 832     guile_cv_use_csqrt,
 833     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 834 #include <complex.h>
 835 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 836    constant, we want to test libc. */
 837 volatile complex double z = - _Complex_I;
 838 int
 839 main (void)
 840 {
 841   z = csqrt (z);
 842   if (creal (z) > 0.0)
 843     return 0;  /* good */
 844   else
 845     return 1;  /* bad */
 846 }]])],
 847     [guile_cv_use_csqrt=yes],
 848     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 849     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 850   case $guile_cv_use_csqrt in
 851     yes*)
 852       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 853       ;;
 854   esac
 855 fi
 856
 857
 858 dnl GMP tests
 859 AC_LIB_HAVE_LINKFLAGS([gmp],
 860   [],
 861   [#include <gmp.h>],
 862   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 863
 864 if test "x$HAVE_LIBGMP" != "xyes"; then
 865   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 866 fi
 867
 868 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 869 if test "x$LTLIBUNISTRING" != "x"; then
 870   LIBS="$LTLIBUNISTRING $LIBS"
 871 else
 872   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 873 fi
 874
 875 dnl Libffi is needed to compile Guile's foreign function interface, but its
 876 dnl interface isn't exposed in Guile's API.
 877 PKG_CHECK_MODULES(LIBFFI, libffi)
 878 AC_SUBST(LIBFFI_CFLAGS)
 879 AC_SUBST(LIBFFI_LIBS)
 880
 881 dnl figure out approriate ffi type for size_t
 882 AC_CHECK_SIZEOF(size_t)
 883 AC_CHECK_SIZEOF(ssize_t)
 884 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 885 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 886 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 887                    [ffi type for size_t])
 888 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 889                    [ffi type for ssize_t])
 890
 891 dnl i18n tests
 892 #AC_CHECK_HEADERS([libintl.h])
 893 #AC_CHECK_FUNCS(gettext)
 894 #if test $ac_cv_func_gettext = no; then
 895 #   AC_CHECK_LIB(intl, gettext)
 896 #fi
 897 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 898 AM_GNU_GETTEXT([external], [need-ngettext])
 899
 900 ### Some systems don't declare some functions.  On such systems, we
 901 ### need to at least provide our own K&R-style declarations.
 902
 903 ### GUILE_FUNC_DECLARED(function, headerfile)
 904
 905 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 906 ### not there, #define MISSING_FUNCTION_DECL.
 907 AC_DEFUN([GUILE_FUNC_DECLARED], [
 908   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 909     AC_EGREP_HEADER($1, $2,
 910                     guile_cv_func_$1_declared=yes,
 911                     guile_cv_func_$1_declared=no))
 912   if test [x$guile_cv_func_]$1[_declared] = xno; then
 913     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 914       [Define if the operating system supplies $1 without declaring it.])
 915   fi
 916 ])
 917
 918 GUILE_FUNC_DECLARED(sleep, unistd.h)
 919 GUILE_FUNC_DECLARED(usleep, unistd.h)
 920
 921 AC_CHECK_DECLS([strptime],,,
 922 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 923 #include <time.h>])
 924
 925 ### On some systems usleep has no return value.  If it does have one,
 926 ### we'd like to return it; otherwise, we'll fake it.
 927 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 928   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 929                    unistd.h,
 930                    [guile_cv_func_usleep_return_type=void],
 931                    [guile_cv_func_usleep_return_type=int])])
 932 case "$guile_cv_func_usleep_return_type" in
 933   "void" )
 934     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 935       [Define if the system headers declare usleep to return void.])
 936   ;;
 937 esac
 938
 939 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 940 if test -n "$have_sys_un_h" ; then
 941   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 942     [Define if the system supports Unix-domain (file-domain) sockets.])
 943 fi
 944
 945 AC_CHECK_FUNCS(getrlimit setrlimit)
 946
 947 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 948
 949 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 950                setnetent    getnetent    endnetent    dnl
 951                setprotoent  getprotoent  endprotoent  dnl
 952                setservent   getservent   endservent   dnl
 953                getnetbyaddr getnetbyname dnl
 954                inet_lnaof inet_makeaddr inet_netof hstrerror)
 955
 956 # struct sockaddr field sin_len is only present on BSD systems.
 957 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 958 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 959 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 960 [#ifdef HAVE_SYS_TYPES_H
 961 #include <sys/types.h>
 962 #endif
 963 #include <netinet/in.h>])
 964
 965 AC_MSG_CHECKING(for __libc_stack_end)
 966 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 967 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 968 extern char *__libc_stack_end;]],
 969    [[printf("%p", (char*) __libc_stack_end);]])],
 970    [guile_cv_have_libc_stack_end=yes],
 971    [guile_cv_have_libc_stack_end=no])])
 972 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 973
 974 if test $guile_cv_have_libc_stack_end = yes; then
 975   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 976            [Define if you have the __libc_stack_end variable.])
 977 fi
 978
 979 dnl Some systems do not declare this.  Some systems do declare it, as a
 980 dnl macro.  With cygwin it may be in a DLL.
 981
 982 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 983 AC_CACHE_VAL(guile_cv_have_h_errno,
 984   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 985                                       [[int a = h_errno;]])],
 986   [guile_cv_have_h_errno=yes],
 987   [guile_cv_have_h_errno=no])])
 988 AC_MSG_RESULT($guile_cv_have_h_errno)
 989 if test $guile_cv_have_h_errno = yes; then
 990   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
 991 fi
 992
 993 AC_MSG_CHECKING(whether uint32_t is defined)
 994 AC_CACHE_VAL(guile_cv_have_uint32_t,
 995   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 996                    #if HAVE_STDINT_H
 997                    #include <stdint.h>
 998                    #endif
 999                    #ifndef HAVE_NETDB_H
1000                    #include <netdb.h>
1001                    #endif]],
1002                    [[uint32_t a;]])],
1003                    [guile_cv_have_uint32_t=yes],
1004                    [guile_cv_have_uint32_t=no])])
1005 AC_MSG_RESULT($guile_cv_have_uint32_t)
1006 if test $guile_cv_have_uint32_t = yes; then
1007   AC_DEFINE([HAVE_UINT32_T], 1,
1008     [Define if uint32_t typedef is defined when netdb.h is include.])
1009 fi
1010
1011 AC_MSG_CHECKING(for working IPv6 support)
1012 AC_CACHE_VAL(guile_cv_have_ipv6,
1013 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1014 #ifdef HAVE_SYS_TYPES_H
1015 #include <sys/types.h>
1016 #endif
1017 #include <netinet/in.h>
1018 #include <sys/socket.h>]],
1019 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1020 [guile_cv_have_ipv6=yes],
1021 [guile_cv_have_ipv6=no])])
1022 AC_MSG_RESULT($guile_cv_have_ipv6)
1023 if test $guile_cv_have_ipv6 = yes; then
1024   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1025 fi
1026
1027 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1028 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1029 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1030 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1031 #ifdef HAVE_SYS_TYPES_H
1032 #include <sys/types.h>
1033 #endif
1034 #include <netinet/in.h>]],
1035 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1036 [guile_cv_have_sin6_scope_id=yes],
1037 [guile_cv_have_sin6_scope_id=no])])
1038 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1039 if test $guile_cv_have_sin6_scope_id = yes; then
1040   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1041     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1042 fi
1043
1044 # struct sockaddr_in6 field sin_len is only present on BSD systems
1045 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1046 [#ifdef HAVE_SYS_TYPES_H
1047 #include <sys/types.h>
1048 #endif
1049 #include <netinet/in.h>])
1050
1051 AC_MSG_CHECKING(whether localtime caches TZ)
1052 AC_CACHE_VAL(guile_cv_localtime_cache,
1053 [if test x$ac_cv_func_tzset = xyes; then
1054 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1055 #if STDC_HEADERS
1056 # include <stdlib.h>
1057 #endif
1058 extern char **environ;
1059 unset_TZ ()
1060 {
1061   char **from, **to;
1062   for (to = from = environ; (*to = *from); from++)
1063     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1064       to++;
1065 }
1066 char TZ_GMT0[] = "TZ=GMT0";
1067 char TZ_PST8[] = "TZ=PST8";
1068 main()
1069 {
1070   time_t now = time ((time_t *) 0);
1071   int hour_GMT0, hour_unset;
1072   if (putenv (TZ_GMT0) != 0)
1073     exit (1);
1074   hour_GMT0 = localtime (&now)->tm_hour;
1075   unset_TZ ();
1076   hour_unset = localtime (&now)->tm_hour;
1077   if (putenv (TZ_PST8) != 0)
1078     exit (1);
1079   if (localtime (&now)->tm_hour == hour_GMT0)
1080     exit (1);
1081   unset_TZ ();
1082   if (localtime (&now)->tm_hour != hour_unset)
1083     exit (1);
1084   exit (0);
1085 }]])],
1086 [guile_cv_localtime_cache=no],
1087 [guile_cv_localtime_cache=yes],
1088 [# If we have tzset, assume the worst when cross-compiling.
1089 guile_cv_localtime_cache=yes])
1090 else
1091         # If we lack tzset, report that localtime does not cache TZ,
1092         # since we can't invalidate the cache if we don't have tzset.
1093         guile_cv_localtime_cache=no
1094 fi])dnl
1095 AC_MSG_RESULT($guile_cv_localtime_cache)
1096 if test $guile_cv_localtime_cache = yes; then
1097   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1098 fi
1099
1100 if test "$enable_regex" = yes; then
1101    if test "$ac_cv_header_regex_h" = yes ||
1102       test "$ac_cv_header_rxposix_h" = yes ||
1103       test "$ac_cv_header_rx_rxposix_h" = yes; then
1104      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1105      [AC_CHECK_LIB(rx, main)
1106       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1107      [AC_CHECK_LIB(regex, main)
1108       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1109      )
1110      dnl The following should not be necessary, but for some reason
1111      dnl autoheader misses it if we don't include it!
1112      if test "$ac_cv_func_regcomp_norx" = yes ||
1113         test "$ac_cv_func_regcomp_regex" = yes ||
1114         test "$ac_cv_func_regcomp_rx" = yes; then
1115        AC_DEFINE([HAVE_REGCOMP], 1,
1116          [This is included as part of a workaround for a autoheader bug.])
1117      fi
1118    fi
1119 fi
1120
1121 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1122
1123 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
1124
1125 # Reasons for testing:
1126 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1127 #                                older systems
1128 #   sincos - GLIBC extension
1129 #
1130 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1131
1132 # C99 specifies isinf and isnan as macros.
1133 # HP-UX provides only macros, no functions.
1134 # glibc 2.3.2 provides both macros and functions.
1135 # IRIX 6.5 and Solaris 8 only provide functions.
1136 #
1137 # The following tests detect isinf and isnan either as functions or as
1138 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1139 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1140 #
1141 AC_MSG_CHECKING([for isinf])
1142 AC_LINK_IFELSE(AC_LANG_SOURCE(
1143 [[#include <math.h>
1144 volatile double x = 0.0;
1145 int main () { return (isinf(x) != 0); }]]),
1146   [AC_MSG_RESULT([yes])
1147    AC_DEFINE([HAVE_ISINF], 1,
1148              [Define to 1 if you have the `isinf' macro or function.])],
1149   [AC_MSG_RESULT([no])])
1150 AC_MSG_CHECKING([for isnan])
1151 AC_LINK_IFELSE(AC_LANG_SOURCE(
1152 [[#include <math.h>
1153 volatile double x = 0.0;
1154 int main () { return (isnan(x) != 0); }]]),
1155   [AC_MSG_RESULT([yes])
1156    AC_DEFINE([HAVE_ISNAN], 1,
1157              [Define to 1 if you have the `isnan' macro or function.])],
1158   [AC_MSG_RESULT([no])])
1159
1160 # Reasons for checking:
1161 #
1162 #     st_rdev
1163 #     st_blksize
1164 #     st_blocks   not in mingw
1165 #     tm_gmtoff   BSD+GNU, not in C99
1166 #
1167 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1168 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1169 #
1170 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1171                  [#define _GNU_SOURCE
1172 AC_INCLUDES_DEFAULT
1173 ])
1174
1175 AC_STRUCT_TIMEZONE
1176 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1177 [#include <time.h>
1178 #ifdef TIME_WITH_SYS_TIME
1179 # include <sys/time.h>
1180 # include <time.h>
1181 #else
1182 # if HAVE_SYS_TIME_H
1183 #  include <sys/time.h>
1184 # else
1185 #  include <time.h>
1186 # endif
1187 #endif
1188 ])
1189 GUILE_STRUCT_UTIMBUF
1190
1191
1192 #--------------------------------------------------------------------
1193 #
1194 # Which way does the stack grow?
1195 #
1196 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1197 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1198 # very similar code, so in future we could look at using that.
1199 #
1200 # An important detail is that the code involves find_stack_direction
1201 # calling _itself_ - which means that find_stack_direction (or at
1202 # least the second find_stack_direction() call) cannot be inlined.
1203 # If the code could be inlined, that might cause the test to give
1204 # an incorrect answer.
1205 #--------------------------------------------------------------------
1206
1207 SCM_I_GSC_STACK_GROWS_UP=0
1208 AC_RUN_IFELSE([AC_LANG_SOURCE(
1209 [AC_INCLUDES_DEFAULT
1210 int
1211 find_stack_direction ()
1212 {
1213   static char *addr = 0;
1214   auto char dummy;
1215   if (addr == 0)
1216     {
1217       addr = &dummy;
1218       return find_stack_direction ();
1219     }
1220   else
1221     return (&dummy > addr) ? 1 : -1;
1222 }
1223
1224 int
1225 main ()
1226 {
1227   return find_stack_direction () < 0;
1228 }])],
1229                [SCM_I_GSC_STACK_GROWS_UP=1],
1230                [],
1231                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1232
1233 #--------------------------------------------------------------------
1234 #
1235 # Boehm's GC library
1236 #
1237 #--------------------------------------------------------------------
1238 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1239
1240 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1241 LIBS="$BDW_GC_LIBS $LIBS"
1242
1243 # `GC_do_blocking ()' is available in GC 7.1 but not declared.
1244 AC_CHECK_FUNCS([GC_do_blocking])
1245 AC_CHECK_DECL([GC_do_blocking],
1246   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1247     [Define this if the `GC_do_blocking ()' function is declared])],
1248   [],
1249   [#include <gc/gc.h>])
1250
1251 # `GC_fn_type' is not available in GC 7.1 and earlier.
1252 AC_CHECK_TYPE([GC_fn_type],
1253   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1254     [Define this if the `GC_fn_type' type is available.])],
1255   [],
1256   [#include <gc/gc.h>])
1257
1258
1259 AC_CHECK_SIZEOF(float)
1260 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1261     AC_DEFINE([SCM_SINGLES], 1,
1262               [Define this if floats are the same size as longs.])
1263 fi
1264
1265 AC_MSG_CHECKING(for struct linger)
1266 AC_CACHE_VAL(scm_cv_struct_linger,
1267         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1268 #include <sys/types.h>
1269 #include <sys/socket.h>]],
1270                           [[struct linger lgr;  lgr.l_linger = 100]])],
1271                           [scm_cv_struct_linger="yes"],
1272                           [scm_cv_struct_linger="no"]))
1273 AC_MSG_RESULT($scm_cv_struct_linger)
1274 if test $scm_cv_struct_linger = yes; then
1275         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1276           [Define this if your system defines struct linger, for use with the
1277            getsockopt and setsockopt system calls.])
1278 fi
1279
1280
1281 # On mingw, struct timespec is in <pthread.h>.
1282 #
1283 AC_MSG_CHECKING(for struct timespec)
1284 AC_CACHE_VAL(scm_cv_struct_timespec,
1285         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1286 #include <time.h>
1287 #if HAVE_PTHREAD_H
1288 #include <pthread.h>
1289 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1290           [scm_cv_struct_timespec="yes"],
1291           [scm_cv_struct_timespec="no"]))
1292 AC_MSG_RESULT($scm_cv_struct_timespec)
1293 if test $scm_cv_struct_timespec = yes; then
1294   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1295     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1296 fi
1297
1298 #--------------------------------------------------------------------
1299 #
1300 # Flags for thread support
1301 #
1302 #--------------------------------------------------------------------
1303
1304 SCM_I_GSC_USE_PTHREAD_THREADS=0
1305 SCM_I_GSC_USE_NULL_THREADS=0
1306 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1307 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1308
1309 ### What thread package has the user asked for?
1310 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1311             , with_threads=yes)
1312
1313 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1314 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1315
1316 case "$with_threads" in
1317   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1318
1319     build_pthread_support="yes"
1320
1321     ACX_PTHREAD([CC="$PTHREAD_CC"
1322        LIBS="$PTHREAD_LIBS $LIBS"
1323        SCM_I_GSC_USE_PTHREAD_THREADS=1
1324        with_threads="pthreads"],
1325       [with_threads="null"
1326        build_pthread_support="no"])
1327
1328     old_CFLAGS="$CFLAGS"
1329     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1330
1331     # Reasons for testing:
1332     #     pthread_getattr_np - "np" meaning "non portable" says it
1333     #         all; not present on MacOS X or Solaris 10
1334     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1335     #         all; specific to MacOS X
1336     #     pthread_sigmask - not available on mingw
1337     #
1338     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1339
1340     # On past versions of Solaris, believe 8 through 10 at least, you
1341     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1342     # This is contrary to POSIX:
1343     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1344     # Check here if this style is required.
1345     #
1346     # glibc (2.3.6 at least) works both with or without braces, so the
1347     # test checks whether it works without.
1348     #
1349
1350     if test "$GCC" = "yes"; then
1351       # Since GCC only issues a warning for missing braces, so we need
1352       # `-Werror' to catch it.
1353       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1354     fi
1355
1356     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1357       guile_cv_need_braces_on_pthread_once_init,
1358       [AC_COMPILE_IFELSE([#include <pthread.h>
1359          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1360         [guile_cv_need_braces_on_pthread_once_init=no],
1361         [guile_cv_need_braces_on_pthread_once_init=yes])])
1362     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1363       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1364     fi
1365
1366     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1367     # 6.5.30m with GCC 3.3.
1368     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1369       guile_cv_need_braces_on_pthread_mutex_initializer,
1370       [AC_COMPILE_IFELSE([#include <pthread.h>
1371          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1372         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1373         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1374     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1375       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1376     fi
1377
1378     CFLAGS="$old_CFLAGS"
1379
1380     # On Solaris, sched_yield lives in -lrt.
1381     AC_SEARCH_LIBS(sched_yield, rt)
1382
1383   ;;
1384 esac
1385
1386 case "$with_threads" in
1387   "pthreads")
1388   ;;
1389   "no" | "null")
1390     SCM_I_GSC_USE_NULL_THREADS=1
1391     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1392     with_threads="null-threads"
1393   ;;
1394   * )
1395     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1396   ;;
1397 esac
1398
1399 AC_MSG_CHECKING(what kind of threads to support)
1400 AC_MSG_RESULT($with_threads)
1401
1402 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1403   [test "x$build_pthread_support" = "xyes"])
1404
1405
1406 ## Check whether pthread_attr_getstack works for the main thread
1407
1408 if test "$with_threads" = pthreads; then
1409
1410 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1411 old_CFLAGS="$CFLAGS"
1412 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1413 if test "$cross_compiling" = "no"; then
1414   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1415   #if HAVE_PTHREAD_ATTR_GETSTACK
1416   #include <pthread.h>
1417
1418   int main ()
1419   {
1420     pthread_attr_t attr;
1421     void *start, *end;
1422     size_t size;
1423
1424     pthread_getattr_np (pthread_self (), &attr);
1425     pthread_attr_getstack (&attr, &start, &size);
1426     end = (char *)start + size;
1427
1428     if ((void *)&attr < start || (void *)&attr >= end)
1429       return 1;
1430     else
1431       return 0;
1432   }
1433   #else
1434   int main ()
1435   {
1436     return 1;
1437   }
1438   #endif
1439   ]])],
1440   [works=yes
1441    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1442   [works=no],
1443   [])
1444 else
1445   works="assuming it doesn't"
1446 fi
1447 CFLAGS="$old_CFLAGS"
1448 AC_MSG_RESULT($works)
1449
1450 GUILE_THREAD_LOCAL_STORAGE
1451
1452 fi # with_threads=pthreads
1453
1454
1455 ## Cross building
1456 if test "$cross_compiling" = "yes"; then
1457   AC_MSG_CHECKING(cc for build)
1458   ## /usr/bin/cc still uses wrong assembler
1459   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1460   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1461 else
1462   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1463 fi
1464
1465 ## AC_MSG_CHECKING("if we are cross compiling")
1466 ## AC_MSG_RESULT($cross_compiling)
1467 if test "$cross_compiling" = "yes"; then
1468    AC_MSG_RESULT($CC_FOR_BUILD)
1469 fi
1470
1471 ## No need as yet to be more elaborate
1472 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1473
1474 AC_SUBST(cross_compiling)
1475 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1476 AC_SUBST(CCLD_FOR_BUILD)
1477
1478 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1479 ## --HOST is the platform that PACKAGE is compiled for.
1480 HOST_CC="$CC_FOR_BUILD"
1481 AC_SUBST(HOST_CC)
1482
1483 if test "$cross_compiling" = "yes"; then
1484   AC_MSG_CHECKING(guile for build)
1485   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1486 else
1487   GUILE_FOR_BUILD='$(preinstguile)'
1488 fi
1489
1490 ## AC_MSG_CHECKING("if we are cross compiling")
1491 ## AC_MSG_RESULT($cross_compiling)
1492 if test "$cross_compiling" = "yes"; then
1493    AC_MSG_RESULT($GUILE_FOR_BUILD)
1494 fi
1495 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1496 AC_SUBST(GUILE_FOR_BUILD)
1497
1498 ## If we're using GCC, ask for aggressive warnings.
1499 GCC_CFLAGS=""
1500 case "$GCC" in
1501   yes )
1502     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1503     ## much stuff with generic function pointers for that to really be
1504     ## less than exasperating.
1505     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1506     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1507     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1508       -Wdeclaration-after-statement -Wundef \
1509       -Wswitch-enum"
1510     # Do this here so we don't screw up any of the tests above that might
1511     # not be "warning free"
1512     if test "${GUILE_ERROR_ON_WARNING}" = yes
1513     then
1514         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1515         enable_compile_warnings=no
1516     fi
1517
1518     for flag in $POTENTIAL_GCC_CFLAGS
1519     do
1520         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1521     done
1522     ;;
1523 esac
1524
1525 AC_SUBST(GCC_CFLAGS)
1526
1527 # Check for GNU ld's "-z relro".
1528 GUILE_GNU_LD_RELRO
1529
1530
1531 ## If we're creating a shared library (using libtool!), then we'll
1532 ## need to generate a list of .lo files corresponding to the .o files
1533 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1534 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1535
1536 ## We also need to create corresponding .doc and .x files
1537 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1538 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1539
1540 # GNU Readline bindings.
1541 GUILE_READLINE
1542
1543 AC_SUBST(GUILE_MAJOR_VERSION)
1544 AC_SUBST(GUILE_MINOR_VERSION)
1545 AC_SUBST(GUILE_MICRO_VERSION)
1546 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1547 AC_SUBST(GUILE_VERSION)
1548
1549 #######################################################################
1550 # library versioning
1551
1552 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1553 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1554 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1555 AC_SUBST(LIBGUILE_INTERFACE)
1556
1557 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1558 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1559 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1560 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1561 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1562
1563 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1564 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1565 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1566 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1567 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1568
1569 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1570 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1571 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1572 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1573 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1574
1575 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1576 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1577 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1578 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1579 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1580
1581 AC_SUBST(LIBGUILE_I18N_MAJOR)
1582 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1583 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1584 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1585 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1586
1587
1588 #######################################################################
1589
1590 dnl Tell guile-config what flags guile users should compile and link with.
1591 GUILE_LIBS="$LDFLAGS $LIBS"
1592 GUILE_CFLAGS="$CPPFLAGS $PTHREAD_CFLAGS"
1593 AC_SUBST(GUILE_LIBS)
1594 AC_SUBST(GUILE_CFLAGS)
1595
1596 AC_SUBST(AWK)
1597 AC_SUBST(LIBLOBJS)
1598 AC_SUBST(EXTRA_DOT_DOC_FILES)
1599 AC_SUBST(EXTRA_DOT_X_FILES)
1600
1601 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1602 top_builddir_absolute=`pwd`
1603 AC_SUBST(top_builddir_absolute)
1604 top_srcdir_absolute=`(cd $srcdir && pwd)`
1605 AC_SUBST(top_srcdir_absolute)
1606
1607 dnl We need `sitedir' in `guile-1.8.pc'.
1608 dnl Note: `sitedir' must be kept in sync with `GUILE_SITE_DIR' in `guile.m4'.
1609 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1610 sitedir="$pkgdatadir/site"
1611 AC_SUBST([sitedir])
1612
1613 # Additional SCM_I_GSC definitions are above.
1614 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1615 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1616 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1617 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1618 AC_SUBST([SCM_I_GSC_C_INLINE])
1619 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1620
1621 AC_CONFIG_FILES([
1622   Makefile
1623   am/Makefile
1624   lib/Makefile
1625   benchmark-suite/Makefile
1626   doc/Makefile
1627   doc/r5rs/Makefile
1628   doc/ref/Makefile
1629   emacs/Makefile
1630   examples/Makefile
1631   libguile/Makefile
1632   srfi/Makefile
1633   guile-readline/Makefile
1634   test-suite/Makefile
1635   test-suite/standalone/Makefile
1636   test-suite/vm/Makefile
1637   meta/Makefile
1638   module/Makefile
1639 ])
1640
1641 AC_CONFIG_FILES([meta/guile-2.0.pc])
1642 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1643 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1644
1645 dnl We can get fancy with m4sugar (m4_foreach et al) later.
1646 dnl NB: We don't jam everything into one GUILE_CONFIG_SCRIPT call
1647 dnl since that expands "chmod +x LONG-LIST-OF-FILES" multiply.  --ttn
1648 AC_DEFUN([GUILE_CONFIG_SCRIPT],[AC_CONFIG_FILES([$1],[chmod +x $1])])
1649
1650 GUILE_CONFIG_SCRIPT([check-guile])
1651 GUILE_CONFIG_SCRIPT([benchmark-guile])
1652 GUILE_CONFIG_SCRIPT([meta/guile])
1653 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1654 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1655 GUILE_CONFIG_SCRIPT([meta/guile-tools])
1656 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1657 GUILE_CONFIG_SCRIPT([libguile/guile-doc-snarf])
1658 GUILE_CONFIG_SCRIPT([libguile/guile-func-name-check])
1659 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1660 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1661 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1662
1663 AC_OUTPUT
1664
1665 dnl Local Variables:
1666 dnl comment-start: "dnl "
1667 dnl comment-end: ""
1668 dnl comment-start-skip: "\\bdnl\\b\\s *"
1669 dnl End: