test-suite/tests/ports.test

   1 ;;;; ports.test --- Guile I/O ports.    -*- coding: utf-8; mode: scheme; -*-
   2 ;;;; Jim Blandy <jimb@red-bean.com> --- May 1999
   3 ;;;;
   4 ;;;;    Copyright (C) 1999, 2001, 2004, 2006, 2007, 2009, 2010,
   5 ;;;;      2011 Free Software Foundation, Inc.
   6 ;;;;
   7 ;;;; This library is free software; you can redistribute it and/or
   8 ;;;; modify it under the terms of the GNU Lesser General Public
   9 ;;;; License as published by the Free Software Foundation; either
  10 ;;;; version 3 of the License, or (at your option) any later version.
  11 ;;;;
  12 ;;;; This library is distributed in the hope that it will be useful,
  13 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;;;; Lesser General Public License for more details.
  16 ;;;;
  17 ;;;; You should have received a copy of the GNU Lesser General Public
  18 ;;;; License along with this library; if not, write to the Free Software
  19 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  20
  21 (define-module (test-suite test-ports)
  22   #:use-module (test-suite lib)
  23   #:use-module (test-suite guile-test)
  24   #:use-module (ice-9 popen)
  25   #:use-module (ice-9 rdelim)
  26   #:use-module (rnrs bytevectors)
  27   #:use-module ((rnrs io ports) #:select (open-bytevector-input-port)))
  28
  29 (define (display-line . args)
  30   (for-each display args)
  31   (newline))
  32
  33 (define (test-file)
  34   (data-file-name "ports-test.tmp"))
  35
  36 \f
  37 ;;;; Some general utilities for testing ports.
  38
  39 ;; Make sure we are set up for 8-bit Latin-1 data.
  40 (fluid-set! %default-port-encoding "ISO-8859-1")
  41 (for-each (lambda (p)
  42             (set-port-encoding! p (fluid-ref %default-port-encoding)))
  43           (list (current-input-port) (current-output-port)
  44                 (current-error-port)))
  45
  46 ;;; Read from PORT until EOF, and return the result as a string.
  47 (define (read-all port)
  48   (let loop ((chars '()))
  49     (let ((char (read-char port)))
  50       (if (eof-object? char)
  51           (list->string (reverse! chars))
  52           (loop (cons char chars))))))
  53
  54 (define (read-file filename)
  55   (let* ((port (open-input-file filename))
  56          (string (read-all port)))
  57     (close-port port)
  58     string))
  59
  60 \f
  61 ;;;; Normal file ports.
  62
  63 ;;; Write out an s-expression, and read it back.
  64 (let ((string '("From fairest creatures we desire increase,"
  65                 "That thereby beauty's rose might never die,"))
  66       (filename (test-file)))
  67   (let ((port (open-output-file filename)))
  68     (write string port)
  69     (close-port port))
  70   (let ((port (open-input-file filename)))
  71     (let ((in-string (read port)))
  72       (pass-if "file: write and read back list of strings"
  73                (equal? string in-string)))
  74     (close-port port))
  75   (delete-file filename))
  76
  77 ;;; Write out a string, and read it back a character at a time.
  78 (let ((string "This is a test string\nwith no newline at the end")
  79       (filename (test-file)))
  80   (let ((port (open-output-file filename)))
  81     (display string port)
  82     (close-port port))
  83   (let ((in-string (read-file filename)))
  84     (pass-if "file: write and read back characters"
  85              (equal? string in-string)))
  86   (delete-file filename))
  87
  88 ;;; Buffered input/output port with seeking.
  89 (let* ((filename (test-file))
  90        (port (open-file filename "w+")))
  91   (display "J'Accuse" port)
  92   (seek port -1 SEEK_CUR)
  93   (pass-if "file: r/w 1"
  94            (char=? (read-char port) #\e))
  95   (pass-if "file: r/w 2"
  96            (eof-object? (read-char port)))
  97   (seek port -1 SEEK_CUR)
  98   (write-char #\x port)
  99   (seek port 7 SEEK_SET)
 100   (pass-if "file: r/w 3"
 101            (char=? (read-char port) #\x))
 102   (seek port -2 SEEK_END)
 103   (pass-if "file: r/w 4"
 104            (char=? (read-char port) #\s))
 105   (close-port port)
 106   (delete-file filename))
 107
 108 ;;; Unbuffered input/output port with seeking.
 109 (let* ((filename (test-file))
 110        (port (open-file filename "w+0")))
 111   (display "J'Accuse" port)
 112   (seek port -1 SEEK_CUR)
 113   (pass-if "file: ub r/w 1"
 114            (char=? (read-char port) #\e))
 115   (pass-if "file: ub r/w 2"
 116            (eof-object? (read-char port)))
 117   (seek port -1 SEEK_CUR)
 118   (write-char #\x port)
 119   (seek port 7 SEEK_SET)
 120   (pass-if "file: ub r/w 3"
 121            (char=? (read-char port) #\x))
 122   (seek port -2 SEEK_END)
 123   (pass-if "file: ub r/w 4"
 124            (char=? (read-char port) #\s))
 125   (close-port port)
 126   (delete-file filename))
 127
 128 ;;; Buffered output-only and input-only ports with seeking.
 129 (let* ((filename (test-file))
 130        (port (open-output-file filename)))
 131   (display "J'Accuse" port)
 132   (pass-if "file: out tell"
 133            (= (seek port 0 SEEK_CUR) 8))
 134   (seek port -1 SEEK_CUR)
 135   (write-char #\x port)
 136   (close-port port)
 137   (let ((iport (open-input-file filename)))
 138     (pass-if "file: in tell 0"
 139              (= (seek iport 0 SEEK_CUR) 0))
 140     (read-char iport)
 141     (pass-if "file: in tell 1"
 142              (= (seek iport 0 SEEK_CUR) 1))
 143     (unread-char #\z iport)
 144     (pass-if "file: in tell 0 after unread"
 145              (= (seek iport 0 SEEK_CUR) 0))
 146     (pass-if "file: unread char still there"
 147              (char=? (read-char iport) #\z))
 148     (seek iport 7 SEEK_SET)
 149     (pass-if "file: in last char"
 150              (char=? (read-char iport) #\x))
 151     (close-port iport))
 152   (delete-file filename))
 153
 154 ;;; unusual characters.
 155 (let* ((filename (test-file))
 156        (port (open-output-file filename)))
 157   (display (string #\nul (integer->char 255) (integer->char 128)
 158                    #\nul) port)
 159   (close-port port)
 160   (let* ((port (open-input-file filename))
 161          (line (read-line port)))
 162     (pass-if "file: read back NUL 1"
 163              (char=? (string-ref line 0) #\nul))
 164     (pass-if "file: read back 255"
 165              (char=? (string-ref line 1) (integer->char 255)))
 166     (pass-if "file: read back 128"
 167              (char=? (string-ref line 2) (integer->char 128)))
 168     (pass-if "file: read back NUL 2"
 169              (char=? (string-ref line 3) #\nul))
 170     (pass-if "file: EOF"
 171              (eof-object? (read-char port)))
 172     (close-port port))
 173   (delete-file filename))
 174
 175 ;;; line buffering mode.
 176 (let* ((filename (test-file))
 177        (port (open-file filename "wl"))
 178        (test-string "one line more or less"))
 179   (write-line test-string port)
 180   (let* ((in-port (open-input-file filename))
 181          (line (read-line in-port)))
 182     (close-port in-port)
 183     (close-port port)
 184     (pass-if "file: line buffering"
 185              (string=? line test-string)))
 186   (delete-file filename))
 187
 188 ;;; read-line should use the port encoding (not the locale encoding).
 189 (let ((str "ĉu bone?"))
 190   (with-locale "C"
 191                (let* ((filename (test-file))
 192                       (port (open-file filename "wl")))
 193                  (set-port-encoding! port "UTF-8")
 194                  (write-line str port)
 195                  (let ((in-port (open-input-file filename)))
 196                    (set-port-encoding! in-port "UTF-8")
 197                    (let ((line (read-line in-port)))
 198                      (close-port in-port)
 199                      (close-port port)
 200                      (pass-if "file: read-line honors port encoding"
 201                               (string=? line str))))
 202                  (delete-file filename))))
 203
 204 ;;; binary mode ignores port encoding
 205 (pass-if "file: binary mode ignores port encoding"
 206   (with-fluids ((%default-port-encoding "UTF-8"))
 207                (let* ((filename (test-file))
 208                       (port (open-file filename "w"))
 209                       (test-string "一二三")
 210                       (binary-test-string
 211                        (apply string
 212                               (map integer->char
 213                                    (uniform-vector->list
 214                                     (string->utf8 test-string))))))
 215                  (write-line test-string port)
 216                  (close-port port)
 217                  (let* ((in-port (open-file filename "rb"))
 218                         (line (read-line in-port)))
 219                    (close-port in-port)
 220                    (delete-file filename)
 221                    (string=? line binary-test-string)))))
 222
 223 ;;; binary mode ignores file coding declaration
 224 (pass-if "file: binary mode ignores file coding declaration"
 225   (with-fluids ((%default-port-encoding "UTF-8"))
 226                (let* ((filename (test-file))
 227                       (port (open-file filename "w"))
 228                       (test-string "一二三")
 229                       (binary-test-string
 230                        (apply string
 231                               (map integer->char
 232                                    (uniform-vector->list
 233                                     (string->utf8 test-string))))))
 234                  (write-line ";; coding: utf-8" port)
 235                  (write-line test-string port)
 236                  (close-port port)
 237                  (let* ((in-port (open-file filename "rb"))
 238                         (line1 (read-line in-port))
 239                         (line2 (read-line in-port)))
 240                    (close-port in-port)
 241                    (delete-file filename)
 242                    (string=? line2 binary-test-string)))))
 243
 244 ;; open-file honors file coding declarations
 245 (pass-if "file: open-file honors coding declarations"
 246   (with-fluids ((%default-port-encoding "UTF-8"))
 247                (let* ((filename (test-file))
 248                       (port (open-output-file filename))
 249                       (test-string "€100"))
 250                  (set-port-encoding! port "ISO-8859-15")
 251                  (write-line ";; coding: iso-8859-15" port)
 252                  (write-line test-string port)
 253                  (close-port port)
 254                  (let* ((in-port (open-input-file filename))
 255                         (line1 (read-line in-port))
 256                         (line2 (read-line in-port)))
 257                    (close-port in-port)
 258                    (delete-file filename)
 259                    (string=? line2 test-string)))))
 260
 261 ;;; ungetting characters and strings.
 262 (with-input-from-string "walk on the moon\nmoon"
 263                         (lambda ()
 264                           (read-char)
 265                           (unread-char #\a (current-input-port))
 266                           (pass-if "unread-char"
 267                                    (char=? (read-char) #\a))
 268                           (read-line)
 269                           (let ((replacenoid "chicken enchilada"))
 270                             (unread-char #\newline (current-input-port))
 271                             (unread-string replacenoid (current-input-port))
 272                             (pass-if "unread-string"
 273                                      (string=? (read-line) replacenoid)))
 274                           (pass-if "unread residue"
 275                                    (string=? (read-line) "moon"))))
 276
 277 ;;; non-blocking mode on a port.  create a pipe and set O_NONBLOCK on
 278 ;;; the reading end.  try to read a byte: should get EAGAIN or
 279 ;;; EWOULDBLOCK error.
 280 (let* ((p (pipe))
 281        (r (car p)))
 282   (fcntl r F_SETFL (logior (fcntl r F_GETFL) O_NONBLOCK))
 283   (pass-if "non-blocking-I/O"
 284            (catch 'system-error
 285                   (lambda () (read-char r) #f)
 286                   (lambda (key . args)
 287                     (and (eq? key 'system-error)
 288                          (let ((errno (car (list-ref args 3))))
 289                            (or (= errno EAGAIN)
 290                                (= errno EWOULDBLOCK))))))))
 291
 292 \f
 293 ;;;; Pipe (popen) ports.
 294
 295 ;;; Run a command, and read its output.
 296 (let* ((pipe (open-pipe "echo 'Howdy there, partner!'" "r"))
 297        (in-string (read-all pipe)))
 298   (close-pipe pipe)
 299   (pass-if "pipe: read"
 300            (equal? in-string "Howdy there, partner!\n")))
 301
 302 ;;; Run a command, send some output to it, and see if it worked.
 303 (let* ((filename (test-file))
 304        (pipe (open-pipe (string-append "grep Mommy > " filename) "w")))
 305   (display "Now Jimmy lives on a mushroom cloud\n" pipe)
 306   (display "Mommy, why does everybody have a bomb?\n" pipe)
 307   (close-pipe pipe)
 308   (let ((in-string (read-file filename)))
 309     (pass-if "pipe: write"
 310              (equal? in-string "Mommy, why does everybody have a bomb?\n")))
 311   (delete-file filename))
 312
 313 \f
 314 ;;;; Void ports.  These are so trivial we don't test them.
 315
 316 \f
 317 ;;;; String ports.
 318
 319 (with-test-prefix "string ports"
 320
 321   ;; Write text to a string port.
 322   (let* ((string "Howdy there, partner!")
 323          (in-string (call-with-output-string
 324                      (lambda (port)
 325                        (display string port)
 326                        (newline port)))))
 327     (pass-if "display text"
 328              (equal? in-string (string-append string "\n"))))
 329
 330   ;; Write an s-expression to a string port.
 331   (let* ((sexpr '("more utterly random text" 1729 #(a vector) 3.1415926))
 332          (in-sexpr
 333           (call-with-input-string (call-with-output-string
 334                                    (lambda (port)
 335                                      (write sexpr port)))
 336                                   read)))
 337     (pass-if "write/read sexpr"
 338              (equal? in-sexpr sexpr)))
 339
 340   ;; seeking and unreading from an input string.
 341   (let ((text "that text didn't look random to me"))
 342     (call-with-input-string text
 343                             (lambda (p)
 344                               (pass-if "input tell 0"
 345                                        (= (seek p 0 SEEK_CUR) 0))
 346                               (read-char p)
 347                               (pass-if "input tell 1"
 348                                        (= (seek p 0 SEEK_CUR) 1))
 349                               (unread-char #\x p)
 350                               (pass-if "input tell back to 0"
 351                                        (= (seek p 0 SEEK_CUR) 0))
 352                               (pass-if "input ungetted char"
 353                                        (char=? (read-char p) #\x))
 354                               (seek p 0 SEEK_END)
 355                               (pass-if "input seek to end"
 356                                        (= (seek p 0 SEEK_CUR)
 357                                           (string-length text)))
 358                               (unread-char #\x p)
 359                               (pass-if "input seek to beginning"
 360                                        (= (seek p 0 SEEK_SET) 0))
 361                               (pass-if "input reread first char"
 362                                        (char=? (read-char p)
 363                                                (string-ref text 0))))))
 364
 365   ;; seeking an output string.
 366   (let* ((text (string-copy "123456789"))
 367          (len (string-length text))
 368          (result (call-with-output-string
 369                   (lambda (p)
 370                     (pass-if "output tell 0"
 371                              (= (seek p 0 SEEK_CUR) 0))
 372                     (display text p)
 373                     (pass-if "output tell end"
 374                              (= (seek p 0 SEEK_CUR) len))
 375                     (pass-if "output seek to beginning"
 376                              (= (seek p 0 SEEK_SET) 0))
 377                     (write-char #\a p)
 378                     (seek p -1 SEEK_END)
 379                     (pass-if "output seek to last char"
 380                              (= (seek p 0 SEEK_CUR)
 381                                 (- len 1)))
 382                     (write-char #\b p)))))
 383     (string-set! text 0 #\a)
 384     (string-set! text (- len 1) #\b)
 385     (pass-if "output check"
 386              (string=? text result)))
 387
 388   (pass-if "%default-port-encoding is honored"
 389     (let ((encodings '("UTF-8" "UTF-16" "ISO-8859-1" "ISO-8859-3")))
 390       (equal? (map (lambda (e)
 391                      (with-fluids ((%default-port-encoding e))
 392                        (call-with-output-string
 393                          (lambda (p)
 394                            (and (string=? e (port-encoding p))
 395                                 (display (port-encoding p) p))))))
 396                    encodings)
 397               encodings)))
 398
 399   (pass-if "suitable encoding [latin-1]"
 400     (let ((str "hello, world"))
 401       (with-fluids ((%default-port-encoding "ISO-8859-1"))
 402         (equal? str
 403                 (with-output-to-string
 404                   (lambda ()
 405                     (display str)))))))
 406
 407   (pass-if "suitable encoding [latin-3]"
 408     (let ((str "ĉu bone?"))
 409       (with-fluids ((%default-port-encoding "ISO-8859-3"))
 410         (equal? str
 411                 (with-output-to-string
 412                   (lambda ()
 413                     (display str)))))))
 414
 415   (pass-if "wrong encoding"
 416     (let ((str "ĉu bone?"))
 417       (catch 'encoding-error
 418         (lambda ()
 419           ;; Latin-1 cannot represent ‘ĉ’.
 420           (with-fluids ((%default-port-encoding "ISO-8859-1"))
 421             (with-output-to-string
 422               (lambda ()
 423                 (display str)))))
 424         (lambda (key subr message errno port chr)
 425           (and (eq? chr #\ĉ)
 426                (string? (strerror errno)))))))
 427
 428   (pass-if "wrong encoding, substitute"
 429     (let ((str "ĉu bone?"))
 430       (with-fluids ((%default-port-encoding "ISO-8859-1"))
 431         (string=? (with-output-to-string
 432                     (lambda ()
 433                       (set-port-conversion-strategy! (current-output-port)
 434                                                      'substitute)
 435                       (display str)))
 436                   "?u bone?"))))
 437
 438   (pass-if "wrong encoding, escape"
 439     (let ((str "ĉu bone?"))
 440       (with-fluids ((%default-port-encoding "ISO-8859-1"))
 441         (string=? (with-output-to-string
 442                     (lambda ()
 443                       (set-port-conversion-strategy! (current-output-port)
 444                                                      'escape)
 445                       (display str)))
 446                   "\\u0109u bone?"))))
 447
 448   (pass-if "peek-char [latin-1]"
 449     (let ((p (with-fluids ((%default-port-encoding #f))
 450                (open-input-string "hello, world"))))
 451       (and (char=? (peek-char p) #\h)
 452            (char=? (peek-char p) #\h)
 453            (char=? (peek-char p) #\h)
 454            (= (port-line p) 0)
 455            (= (port-column p) 0))))
 456
 457   (pass-if "peek-char [utf-8]"
 458     (let ((p (with-fluids ((%default-port-encoding "UTF-8"))
 459                (open-input-string "안녕하세요"))))
 460       (and (char=? (peek-char p) #\안)
 461            (char=? (peek-char p) #\안)
 462            (char=? (peek-char p) #\안)
 463            (= (port-line p) 0)
 464            (= (port-column p) 0))))
 465
 466   (pass-if "peek-char [utf-16]"
 467     (let ((p (with-fluids ((%default-port-encoding "UTF-16BE"))
 468                (open-input-string "안녕하세요"))))
 469       (and (char=? (peek-char p) #\안)
 470            (char=? (peek-char p) #\안)
 471            (char=? (peek-char p) #\안)
 472            (= (port-line p) 0)
 473            (= (port-column p) 0))))
 474
 475   ;; Mini DSL to test decoding error handling.
 476   (letrec-syntax ((decoding-error?
 477                    (syntax-rules ()
 478                      ((_ port exp)
 479                       (catch 'decoding-error
 480                         (lambda ()
 481                           (pk 'exp exp)
 482                           #f)
 483                         (lambda (key subr message errno p)
 484                           (and (eq? p port)
 485                                (not (= 0 errno))))))))
 486                   (make-check
 487                    (syntax-rules (-> error eof)
 488                      ((_ port (proc -> error))
 489                       (decoding-error? port (proc port)))
 490                      ((_ port (proc -> eof))
 491                       (eof-object? (proc port)))
 492                      ((_ port (proc -> char))
 493                       (eq? (proc port) char))))
 494                   (make-checks
 495                    (syntax-rules ()
 496                      ((_ port check ...)
 497                       (and (make-check port check) ...))))
 498                   (test-decoding-error
 499                       (syntax-rules (tests)
 500                         ((_ sequence encoding strategy (tests checks ...))
 501                          (pass-if (format #f "test-decoding-error: ~s ~s ~s ~s"
 502                                           (caar '(checks ...))
 503                                           'sequence encoding strategy)
 504                            (let ((p (open-bytevector-input-port
 505                                      (u8-list->bytevector 'sequence))))
 506                              (set-port-encoding! p encoding)
 507                              (set-port-conversion-strategy! p strategy)
 508                              (make-checks p checks ...)))))))
 509
 510     (test-decoding-error (255 65 66 67) "UTF-8" 'error
 511       (tests
 512        (read-char -> error)
 513        (read-char -> #\A)
 514        (read-char -> #\B)
 515        (read-char -> #\C)
 516        (read-char -> eof)))
 517
 518     (test-decoding-error (255 65 66 67) "UTF-8" 'escape
 519       ;; `escape' should behave exactly like `error'.
 520       (tests
 521        (read-char -> error)
 522        (read-char -> #\A)
 523        (read-char -> #\B)
 524        (read-char -> #\C)
 525        (read-char -> eof)))
 526
 527     (test-decoding-error (255 206 187 206 188) "UTF-8" 'substitute
 528       (tests
 529        (read-char -> #\?)
 530        (read-char -> #\λ)
 531        (read-char -> #\μ)
 532        (read-char -> eof)))
 533
 534     (test-decoding-error (206 187 206) "UTF-8" 'error
 535       ;; Unterminated sequence.
 536       (tests
 537        (read-char -> #\λ)
 538        (read-char -> error)
 539        (read-char -> eof)))
 540
 541     (test-decoding-error (206 187 206) "UTF-8" 'substitute
 542       ;; Unterminated sequence.
 543       (tests
 544        (read-char -> #\λ)
 545        (read-char -> #\?)
 546        (read-char -> eof)))
 547
 548     (test-decoding-error (255 65 66 67) "UTF-8" 'error
 549       (tests
 550        ;; `peek-char' should repeatedly raise an error.
 551        (peek-char -> error)
 552        (peek-char -> error)
 553        (peek-char -> error)
 554
 555        ;; Move past the error.
 556        (read-char -> error)
 557
 558        (read-char -> #\A)
 559        (read-char -> #\B)
 560        (read-char -> #\C)
 561        (read-char -> eof)))
 562
 563     ;; Check how ill-formed UTF-8 sequences are handled (see Table 3-7
 564     ;; of the "Conformance" chapter of Unicode 6.0.0.)
 565
 566     (test-decoding-error (#xc0 #x80 #x41) "UTF-8" 'error
 567       (tests
 568        (read-char -> error) ;; C0: should be in the C2..DF range
 569        (read-char -> error) ;; 80: invalid
 570        (read-char -> #\A)
 571        (read-char -> eof)))
 572
 573     (test-decoding-error (#xc0 #x80 #x41) "UTF-8" 'error
 574       (tests
 575        (read-char -> error) ;; C0: should be in the C2..DF range
 576        (read-char -> error) ;; 80: invalid
 577        (read-char -> #\A)
 578        (read-char -> eof)))
 579
 580     (test-decoding-error (#xe0 #x88 #x88) "UTF-8" 'error
 581       (tests
 582        (read-char -> error) ;; 2nd byte should be in the A0..BF range
 583        (read-char -> eof)))
 584
 585     (test-decoding-error (#xf0 #x88 #x88 #x88) "UTF-8" 'error
 586       (tests
 587        (read-char -> error) ;; 2nd byte should be in the 90..BF range
 588        (read-char -> eof)))))
 589
 590 (with-test-prefix "call-with-output-string"
 591
 592   ;; In Guile 1.6.4, closing the port resulted in a segv, check that doesn't
 593   ;; occur.
 594   (pass-if-exception "proc closes port" exception:wrong-type-arg
 595     (call-with-output-string close-port)))
 596
 597
 598 \f
 599 ;;;; Soft ports.  No tests implemented yet.
 600
 601 \f
 602 ;;;; Generic operations across all port types.
 603
 604 (let ((port-loop-temp (test-file)))
 605
 606   ;; Return a list of input ports that all return the same text.
 607   ;; We map tests over this list.
 608   (define (input-port-list text)
 609
 610     ;; Create a text file some of the ports will use.
 611     (let ((out-port (open-output-file port-loop-temp)))
 612       (display text out-port)
 613       (close-port out-port))
 614
 615     (list (open-input-file port-loop-temp)
 616           (open-input-pipe (string-append "cat " port-loop-temp))
 617           (call-with-input-string text (lambda (x) x))
 618           ;; We don't test soft ports at the moment.
 619           ))
 620
 621   (define port-list-names '("file" "pipe" "string"))
 622
 623   ;; Test the line counter.
 624   (define (test-line-counter text second-line final-column)
 625     (with-test-prefix "line counter"
 626       (let ((ports (input-port-list text)))
 627         (for-each
 628          (lambda (port port-name)
 629            (with-test-prefix port-name
 630              (pass-if "at beginning of input"
 631                       (= (port-line port) 0))
 632              (pass-if "read first character"
 633                       (eqv? (read-char port) #\x))
 634              (pass-if "after reading one character"
 635                       (= (port-line port) 0))
 636              (pass-if "read first newline"
 637                       (eqv? (read-char port) #\newline))
 638              (pass-if "after reading first newline char"
 639                       (= (port-line port) 1))
 640              (pass-if "second line read correctly"
 641                       (equal? (read-line port) second-line))
 642              (pass-if "read-line increments line number"
 643                       (= (port-line port) 2))
 644              (pass-if "read-line returns EOF"
 645                       (let loop ((i 0))
 646                         (cond
 647                          ((eof-object? (read-line port)) #t)
 648                          ((> i 20) #f)
 649                          (else (loop (+ i 1))))))
 650              (pass-if "line count is 5 at EOF"
 651                       (= (port-line port) 5))
 652              (pass-if "column is correct at EOF"
 653                       (= (port-column port) final-column))))
 654          ports port-list-names)
 655         (for-each close-port ports)
 656         (delete-file port-loop-temp))))
 657
 658   (with-test-prefix "newline"
 659     (test-line-counter
 660      (string-append "x\n"
 661                     "He who receives an idea from me, receives instruction\n"
 662                     "himself without lessening mine; as he who lights his\n"
 663                     "taper at mine, receives light without darkening me.\n"
 664                     "  --- Thomas Jefferson\n")
 665      "He who receives an idea from me, receives instruction"
 666      0))
 667
 668   (with-test-prefix "no newline"
 669     (test-line-counter
 670      (string-append "x\n"
 671                     "He who receives an idea from me, receives instruction\n"
 672                     "himself without lessening mine; as he who lights his\n"
 673                     "taper at mine, receives light without darkening me.\n"
 674                     "  --- Thomas Jefferson\n"
 675                     "no newline here")
 676      "He who receives an idea from me, receives instruction"
 677      15)))
 678
 679 ;; Test port-line and port-column for output ports
 680
 681 (define (test-output-line-counter text final-column)
 682   (with-test-prefix "port-line and port-column for output ports"
 683     (let ((port (open-output-string)))
 684       (pass-if "at beginning of input"
 685                (and (= (port-line port) 0)
 686                     (= (port-column port) 0)))
 687       (write-char #\x port)
 688       (pass-if "after writing one character"
 689                (and (= (port-line port) 0)
 690                     (= (port-column port) 1)))
 691       (write-char #\newline port)
 692       (pass-if "after writing first newline char"
 693                (and (= (port-line port) 1)
 694                     (= (port-column port) 0)))
 695       (display text port)
 696       (pass-if "line count is 5 at end"
 697                (= (port-line port) 5))
 698       (pass-if "column is correct at end"
 699                (= (port-column port) final-column)))))
 700
 701 (test-output-line-counter
 702  (string-append "He who receives an idea from me, receives instruction\n"
 703                 "himself without lessening mine; as he who lights his\n"
 704                 "taper at mine, receives light without darkening me.\n"
 705                 "  --- Thomas Jefferson\n"
 706                 "no newline here")
 707  15)
 708
 709 (with-test-prefix "port-column"
 710
 711   (with-test-prefix "output"
 712
 713     (pass-if "x"
 714       (let ((port (open-output-string)))
 715         (display "x" port)
 716         (= 1 (port-column port))))
 717
 718     (pass-if "\\a"
 719       (let ((port (open-output-string)))
 720         (display "\a" port)
 721         (= 0 (port-column port))))
 722
 723     (pass-if "x\\a"
 724       (let ((port (open-output-string)))
 725         (display "x\a" port)
 726         (= 1 (port-column port))))
 727
 728     (pass-if "\\x08 backspace"
 729       (let ((port (open-output-string)))
 730         (display "\x08" port)
 731         (= 0 (port-column port))))
 732
 733     (pass-if "x\\x08 backspace"
 734       (let ((port (open-output-string)))
 735         (display "x\x08" port)
 736         (= 0 (port-column port))))
 737
 738     (pass-if "\\n"
 739       (let ((port (open-output-string)))
 740         (display "\n" port)
 741         (= 0 (port-column port))))
 742
 743     (pass-if "x\\n"
 744       (let ((port (open-output-string)))
 745         (display "x\n" port)
 746         (= 0 (port-column port))))
 747
 748     (pass-if "\\r"
 749       (let ((port (open-output-string)))
 750         (display "\r" port)
 751         (= 0 (port-column port))))
 752
 753     (pass-if "x\\r"
 754       (let ((port (open-output-string)))
 755         (display "x\r" port)
 756         (= 0 (port-column port))))
 757
 758     (pass-if "\\t"
 759       (let ((port (open-output-string)))
 760         (display "\t" port)
 761         (= 8 (port-column port))))
 762
 763     (pass-if "x\\t"
 764       (let ((port (open-output-string)))
 765         (display "x\t" port)
 766         (= 8 (port-column port)))))
 767
 768   (with-test-prefix "input"
 769
 770     (pass-if "x"
 771       (let ((port (open-input-string "x")))
 772         (while (not (eof-object? (read-char port))))
 773         (= 1 (port-column port))))
 774
 775     (pass-if "\\a"
 776       (let ((port (open-input-string "\a")))
 777         (while (not (eof-object? (read-char port))))
 778         (= 0 (port-column port))))
 779
 780     (pass-if "x\\a"
 781       (let ((port (open-input-string "x\a")))
 782         (while (not (eof-object? (read-char port))))
 783         (= 1 (port-column port))))
 784
 785     (pass-if "\\x08 backspace"
 786       (let ((port (open-input-string "\x08")))
 787         (while (not (eof-object? (read-char port))))
 788         (= 0 (port-column port))))
 789
 790     (pass-if "x\\x08 backspace"
 791       (let ((port (open-input-string "x\x08")))
 792         (while (not (eof-object? (read-char port))))
 793         (= 0 (port-column port))))
 794
 795     (pass-if "\\n"
 796       (let ((port (open-input-string "\n")))
 797         (while (not (eof-object? (read-char port))))
 798         (= 0 (port-column port))))
 799
 800     (pass-if "x\\n"
 801       (let ((port (open-input-string "x\n")))
 802         (while (not (eof-object? (read-char port))))
 803         (= 0 (port-column port))))
 804
 805     (pass-if "\\r"
 806       (let ((port (open-input-string "\r")))
 807         (while (not (eof-object? (read-char port))))
 808         (= 0 (port-column port))))
 809
 810     (pass-if "x\\r"
 811       (let ((port (open-input-string "x\r")))
 812         (while (not (eof-object? (read-char port))))
 813         (= 0 (port-column port))))
 814
 815     (pass-if "\\t"
 816       (let ((port (open-input-string "\t")))
 817         (while (not (eof-object? (read-char port))))
 818         (= 8 (port-column port))))
 819
 820     (pass-if "x\\t"
 821       (let ((port (open-input-string "x\t")))
 822         (while (not (eof-object? (read-char port))))
 823         (= 8 (port-column port))))))
 824
 825 (with-test-prefix "port-line"
 826
 827   ;; in guile 1.8.1 and earlier port-line was truncated to an int, whereas
 828   ;; scm_t_port actually holds a long; this restricted the range on 64-bit
 829   ;; systems
 830   (pass-if "set most-positive-fixnum/2"
 831     (let ((n    (quotient most-positive-fixnum 2))
 832           (port (open-output-string)))
 833       (set-port-line! port n)
 834       (eqv? n (port-line port)))))
 835
 836 (with-test-prefix "port-encoding"
 837
 838   (pass-if-exception "set-port-encoding!, wrong encoding"
 839     exception:miscellaneous-error
 840     (set-port-encoding! (open-input-string "") "does-not-exist"))
 841
 842   (pass-if-exception "%default-port-encoding, wrong encoding"
 843     exception:miscellaneous-error
 844     (read (with-fluids ((%default-port-encoding "does-not-exist"))
 845             (open-input-string "")))))
 846
 847 ;;;
 848 ;;; port-for-each
 849 ;;;
 850
 851 (with-test-prefix "port-for-each"
 852
 853   ;; In guile 1.8.0 through 1.8.2, port-for-each could pass a freed cell to
 854   ;; its iterator func if a port was inaccessible in the last gc mark but
 855   ;; the lazy sweeping has not yet reached it to remove it from the port
 856   ;; table (scm_i_port_table).  Provoking those gc conditions is a little
 857   ;; tricky, but the following code made it happen in 1.8.2.
 858   (pass-if "passing freed cell"
 859     (let ((lst '()))
 860       ;; clear out the heap
 861       (gc) (gc) (gc)
 862       ;; allocate cells so the opened ports aren't at the start of the heap
 863       (make-list 1000)
 864       (open-input-file "/dev/null")
 865       (make-list 1000)
 866       (open-input-file "/dev/null")
 867       ;; this gc leaves the above ports unmarked, ie. inaccessible
 868       (gc)
 869       ;; but they're still in the port table, so this sees them
 870       (port-for-each (lambda (port)
 871                        (set! lst (cons port lst))))
 872       ;; this forces completion of the sweeping
 873       (gc) (gc) (gc)
 874       ;; and (if the bug is present) the cells accumulated in LST are now
 875       ;; freed cells, which give #f from `port?'
 876       (not (memq #f (map port? lst))))))
 877
 878 (with-test-prefix
 879  "fdes->port"
 880  (pass-if "fdes->ports finds port"
 881           (let ((port (open-file (test-file) "w")))
 882
 883             (not (not (memq port (fdes->ports (port->fdes port))))))))
 884
 885 ;;;
 886 ;;; seek
 887 ;;;
 888
 889 (with-test-prefix "seek"
 890
 891   (with-test-prefix "file port"
 892
 893     (pass-if "SEEK_CUR"
 894       (call-with-output-file (test-file)
 895         (lambda (port)
 896           (display "abcde" port)))
 897       (let ((port (open-file (test-file) "r")))
 898         (read-char port)
 899         (seek port 2 SEEK_CUR)
 900         (eqv? #\d (read-char port))))
 901
 902     (pass-if "SEEK_SET"
 903       (call-with-output-file (test-file)
 904         (lambda (port)
 905           (display "abcde" port)))
 906       (let ((port (open-file (test-file) "r")))
 907         (read-char port)
 908         (seek port 3 SEEK_SET)
 909         (eqv? #\d (read-char port))))
 910
 911     (pass-if "SEEK_END"
 912       (call-with-output-file (test-file)
 913         (lambda (port)
 914           (display "abcde" port)))
 915       (let ((port (open-file (test-file) "r")))
 916         (read-char port)
 917         (seek port -2 SEEK_END)
 918         (eqv? #\d (read-char port))))))
 919
 920 ;;;
 921 ;;; truncate-file
 922 ;;;
 923
 924 (with-test-prefix "truncate-file"
 925
 926   (pass-if-exception "flonum file" exception:wrong-type-arg
 927     (truncate-file 1.0 123))
 928
 929   (pass-if-exception "frac file" exception:wrong-type-arg
 930     (truncate-file 7/3 123))
 931
 932   (with-test-prefix "filename"
 933
 934     (pass-if-exception "flonum length" exception:wrong-type-arg
 935       (call-with-output-file (test-file)
 936         (lambda (port)
 937           (display "hello" port)))
 938       (truncate-file (test-file) 1.0))
 939
 940     (pass-if "shorten"
 941       (call-with-output-file (test-file)
 942         (lambda (port)
 943           (display "hello" port)))
 944       (truncate-file (test-file) 1)
 945       (eqv? 1 (stat:size (stat (test-file)))))
 946
 947     (pass-if-exception "shorten to current pos" exception:miscellaneous-error
 948       (call-with-output-file (test-file)
 949         (lambda (port)
 950           (display "hello" port)))
 951       (truncate-file (test-file))))
 952
 953   (with-test-prefix "file descriptor"
 954
 955     (pass-if "shorten"
 956       (call-with-output-file (test-file)
 957         (lambda (port)
 958           (display "hello" port)))
 959       (let ((fd (open-fdes (test-file) O_RDWR)))
 960         (truncate-file fd 1)
 961         (close-fdes fd))
 962       (eqv? 1 (stat:size (stat (test-file)))))
 963
 964     (pass-if "shorten to current pos"
 965       (call-with-output-file (test-file)
 966         (lambda (port)
 967           (display "hello" port)))
 968       (let ((fd (open-fdes (test-file) O_RDWR)))
 969         (seek fd 1 SEEK_SET)
 970         (truncate-file fd)
 971         (close-fdes fd))
 972       (eqv? 1 (stat:size (stat (test-file))))))
 973
 974   (with-test-prefix "file port"
 975
 976     (pass-if "shorten"
 977       (call-with-output-file (test-file)
 978         (lambda (port)
 979           (display "hello" port)))
 980       (let ((port (open-file (test-file) "r+")))
 981         (truncate-file port 1))
 982       (eqv? 1 (stat:size (stat (test-file)))))
 983
 984     (pass-if "shorten to current pos"
 985       (call-with-output-file (test-file)
 986         (lambda (port)
 987           (display "hello" port)))
 988       (let ((port (open-file (test-file) "r+")))
 989         (read-char port)
 990         (truncate-file port))
 991       (eqv? 1 (stat:size (stat (test-file)))))))
 992
 993
 994 ;;;; testing read-delimited and friends
 995
 996 (with-test-prefix "read-delimited!"
 997   (let ((c (make-string 20 #\!)))
 998     (call-with-input-string
 999      "defdef\nghighi\n"
1000      (lambda (port)
1001
1002        (read-delimited! "\n" c port 'concat)
1003        (pass-if "read-delimited! reads a first line"
1004                 (string=? c "defdef\n!!!!!!!!!!!!!"))
1005
1006        (read-delimited! "\n" c port 'concat 3)
1007        (pass-if "read-delimited! reads a first line"
1008                 (string=? c "defghighi\n!!!!!!!!!!"))))))
1009
1010 \f
1011 ;;;; char-ready?
1012
1013 (call-with-input-string
1014  "howdy"
1015  (lambda (port)
1016    (pass-if "char-ready? returns true on string port"
1017             (char-ready? port))))
1018
1019 ;;; This segfaults on some versions of Guile.  We really should run
1020 ;;; the tests in a subprocess...
1021
1022 (call-with-input-string
1023  "howdy"
1024  (lambda (port)
1025    (with-input-from-port
1026        port
1027      (lambda ()
1028        (pass-if "char-ready? returns true on string port as default port"
1029                 (char-ready?))))))
1030
1031 \f
1032 ;;;; Close current-input-port, and make sure everyone can handle it.
1033
1034 (with-test-prefix "closing current-input-port"
1035   (for-each (lambda (procedure name)
1036               (with-input-from-port
1037                   (call-with-input-string "foo" (lambda (p) p))
1038                 (lambda ()
1039                   (close-port (current-input-port))
1040                   (pass-if-exception name
1041                     exception:wrong-type-arg
1042                     (procedure)))))
1043             (list read read-char read-line)
1044             '("read" "read-char" "read-line")))
1045
1046 (delete-file (test-file))
1047
1048 ;;; Local Variables:
1049 ;;; eval: (put 'test-decoding-error 'scheme-indent-function 3)
1050 ;;; End: