m4/locale-zh.m4

   1 # locale-zh.m4 serial 4
   2 dnl Copyright (C) 2003, 2005-2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 dnl Determine the name of a chinese locale with GB18030 encoding.
  10 AC_DEFUN([gt_LOCALE_ZH_CN],
  11 [
  12   AC_REQUIRE([AC_CANONICAL_HOST])
  13   AC_REQUIRE([AM_LANGINFO_CODESET])
  14   AC_CACHE_CHECK([for a transitional chinese locale], gt_cv_locale_zh_CN, [
  15     macosx=
  16 changequote(,)dnl
  17     case "$host_os" in
  18       darwin[56]*) ;;
  19       darwin*) macosx=yes;;
  20     esac
  21 changequote([,])dnl
  22     if test -n "$macosx"; then
  23       # On Darwin 7 (MacOS X), the libc supports some locales in non-UTF-8
  24       # encodings, but the kernel does not support them. The documentation
  25       # says:
  26       #   "... all code that calls BSD system routines should ensure
  27       #    that the const *char parameters of these routines are in UTF-8
  28       #    encoding. All BSD system functions expect their string
  29       #    parameters to be in UTF-8 encoding and nothing else."
  30       # See the comments in config.charset. Therefore we bypass the test.
  31       gt_cv_locale_zh_CN=none
  32     else
  33       AC_LANG_CONFTEST([AC_LANG_SOURCE([
  34 changequote(,)dnl
  35 #include <locale.h>
  36 #include <stdlib.h>
  37 #include <time.h>
  38 #if HAVE_LANGINFO_CODESET
  39 # include <langinfo.h>
  40 #endif
  41 #include <stdlib.h>
  42 #include <string.h>
  43 struct tm t;
  44 char buf[16];
  45 int main ()
  46 {
  47   const char *p;
  48   /* Check whether the given locale name is recognized by the system.  */
  49   if (setlocale (LC_ALL, "") == NULL) return 1;
  50   /* Check whether nl_langinfo(CODESET) is nonempty and not "ASCII" or "646".
  51      On MacOS X 10.3.5 (Darwin 7.5) in the fr_FR locale, nl_langinfo(CODESET)
  52      is empty, and the behaviour of Tcl 8.4 in this locale is not useful.
  53      On OpenBSD 4.0, when an unsupported locale is specified, setlocale()
  54      succeeds but then nl_langinfo(CODESET) is "646". In this situation,
  55      some unit tests fail.  */
  56 #if HAVE_LANGINFO_CODESET
  57   {
  58     const char *cs = nl_langinfo (CODESET);
  59     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0)
  60       return 1;
  61   }
  62 #endif
  63 #ifdef __CYGWIN__
  64   /* On Cygwin, avoid locale names without encoding suffix, because the
  65      locale_charset() function relies on the encoding suffix.  Note that
  66      LC_ALL is set on the command line.  */
  67   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  68 #endif
  69   /* Check whether in a month name, no byte in the range 0x80..0x9F occurs.
  70      This excludes the UTF-8 encoding.  */
  71   t.tm_year = 1975 - 1900; t.tm_mon = 2 - 1; t.tm_mday = 4;
  72   if (strftime (buf, sizeof (buf), "%B", &t) < 2) return 1;
  73   for (p = buf; *p != '\0'; p++)
  74     if ((unsigned char) *p >= 0x80 && (unsigned char) *p < 0xa0)
  75       return 1;
  76   /* Check whether a typical GB18030 multibyte sequence is recognized as a
  77      single wide character.  This excludes the GB2312 and GBK encodings.  */
  78   if (mblen ("\203\062\332\066", 5) != 4)
  79     return 1;
  80   return 0;
  81 }
  82 changequote([,])dnl
  83         ])])
  84       if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  85         # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
  86         # otherwise on MacOS X 10.3.5 the LC_TIME=C from the beginning of the
  87         # configure script would override the LC_ALL setting. Likewise for
  88         # LC_CTYPE, which is also set at the beginning of the configure script.
  89         # Test for the locale name without encoding suffix.
  90         if (LC_ALL=zh_CN LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  91           gt_cv_locale_zh_CN=zh_CN
  92         else
  93           # Test for the locale name with explicit encoding suffix.
  94           if (LC_ALL=zh_CN.GB18030 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  95             gt_cv_locale_zh_CN=zh_CN.GB18030
  96           else
  97             # None found.
  98             gt_cv_locale_zh_CN=none
  99           fi
 100         fi
 101       else
 102         # If there was a link error, due to mblen(), the system is so old that
 103         # it certainly doesn't have a chinese locale.
 104         gt_cv_locale_zh_CN=none
 105       fi
 106       rm -fr conftest*
 107     fi
 108   ])
 109   LOCALE_ZH_CN=$gt_cv_locale_zh_CN
 110   AC_SUBST([LOCALE_ZH_CN])
 111 ])