configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT(m4_esyscmd(. ./GUILE-VERSION && echo -n ${PACKAGE}),
  31         m4_esyscmd(. ./GUILE-VERSION && echo -n ${GUILE_VERSION}),
  32         [bug-guile@gnu.org])
  33 AC_CONFIG_AUX_DIR([.])
  34 AC_CONFIG_SRCDIR(GUILE-VERSION)
  35 AM_INIT_AUTOMAKE([no-define])
  36
  37 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  38 AC_CONFIG_SRCDIR([GUILE-VERSION])
  39
  40 . $srcdir/GUILE-VERSION
  41
  42 AM_MAINTAINER_MODE
  43 AM_CONFIG_HEADER([config.h])
  44 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  45
  46 #--------------------------------------------------------------------
  47 #
  48 # Independent Subdirectories
  49 #
  50 #--------------------------------------------------------------------
  51
  52 AC_CONFIG_SUBDIRS(guile-readline)
  53
  54 #--------------------------------------------------------------------
  55
  56 dnl Some more checks for Win32
  57 AC_CYGWIN
  58 AC_LIBTOOL_WIN32_DLL
  59
  60 AC_PROG_INSTALL
  61 AC_PROG_CC
  62 AC_PROG_CPP
  63 AC_PROG_AWK
  64
  65 AC_AIX
  66 AC_ISC_POSIX
  67 AC_MINIX
  68
  69 AM_PROG_CC_STDC
  70 # for per-target cflags in the libguile subdir
  71 AM_PROG_CC_C_O
  72
  73 AC_LIBTOOL_DLOPEN
  74 AC_PROG_LIBTOOL
  75 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  76   [AC_MSG_ERROR([libltdl not found.  See README.])])
  77
  78 AC_SUBST(DLPREOPEN)
  79
  80 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  81 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  82
  83 AM_PATH_LISPDIR
  84
  85 #--------------------------------------------------------------------
  86 #
  87 # User options (after above tests that may set default CFLAGS etc.)
  88 #
  89 #--------------------------------------------------------------------
  90
  91 GUILE_ERROR_ON_WARNING="yes"
  92
  93 AC_ARG_ENABLE(error-on-warning,
  94   [  --enable-error-on-warning    treat compile warnings as errors],
  95   [case "${enableval}" in
  96      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  97      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  98      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  99    esac])
 100
 101 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
 102 AC_ARG_ENABLE(debug-freelist,
 103   [  --enable-debug-freelist include garbage collector freelist debugging code],
 104   if test "$enable_debug_freelist" = y \
 105      || test "$enable_debug_freelist" = yes; then
 106     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 107   fi)
 108
 109 AC_ARG_ENABLE(debug-malloc,
 110   [  --enable-debug-malloc   include malloc debugging code],
 111   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 112     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 113       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 114   fi)
 115
 116 SCM_I_GSC_GUILE_DEBUG=0
 117 AC_ARG_ENABLE(guile-debug,
 118   [AC_HELP_STRING([--enable-guile-debug],
 119                   [include internal debugging functions])],
 120   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 121     SCM_I_GSC_GUILE_DEBUG=1
 122   fi)
 123
 124 AC_ARG_ENABLE(posix,
 125   [  --disable-posix         omit posix interfaces],,
 126   enable_posix=yes)
 127
 128 AC_ARG_ENABLE(networking,
 129   [  --disable-networking    omit networking interfaces],,
 130   enable_networking=yes)
 131
 132 AC_ARG_ENABLE(regex,
 133   [  --disable-regex         omit regular expression interfaces],,
 134   enable_regex=yes)
 135
 136 AC_ARG_ENABLE([discouraged],
 137   AC_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 138
 139 if test "$enable_discouraged" = no; then
 140   SCM_I_GSC_ENABLE_DISCOURAGED=0
 141 else
 142   SCM_I_GSC_ENABLE_DISCOURAGED=1
 143 fi
 144
 145 AC_ARG_ENABLE([deprecated],
 146   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 147
 148 if test "$enable_deprecated" = no; then
 149   SCM_I_GSC_ENABLE_DEPRECATED=0
 150 else
 151   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 152     warn_default=summary
 153   elif test "$enable_deprecated" = shutup; then
 154     warn_default=no
 155   else
 156     warn_default=$enable_deprecated
 157   fi
 158   SCM_I_GSC_ENABLE_DEPRECATED=1
 159   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 160   [Define this to control the default warning level for deprecated features.])
 161 fi
 162
 163 AC_ARG_ENABLE(elisp,
 164   [  --disable-elisp         omit Emacs Lisp support],,
 165   enable_elisp=yes)
 166
 167 #--------------------------------------------------------------------
 168
 169 dnl Check for dynamic linking
 170
 171 use_modules=yes
 172 AC_ARG_WITH(modules,
 173 [  --with-modules[=FILES]  Add support for dynamic modules],
 174 use_modules="$withval")
 175 test -z "$use_modules" && use_modules=yes
 176 DLPREOPEN=
 177 if test "$use_modules" != no; then
 178   if test "$use_modules" = yes; then
 179     DLPREOPEN="-dlpreopen force"
 180   else
 181     DLPREOPEN="-export-dynamic"
 182     for module in $use_modules; do
 183       DLPREOPEN="$DLPREOPEN -dlopen $module"
 184     done
 185   fi
 186 fi
 187
 188 dnl files which are destined for separate modules.
 189
 190 if test "$use_modules" != no; then
 191    AC_LIBOBJ([dynl])
 192 fi
 193
 194 if test "$enable_posix" = yes; then
 195    AC_LIBOBJ([filesys])
 196    AC_LIBOBJ([posix])
 197    AC_DEFINE(HAVE_POSIX, 1,
 198      [Define this if you want support for POSIX system calls in Guile.])
 199 fi
 200
 201 if test "$enable_networking" = yes; then
 202    AC_LIBOBJ([net_db])
 203    AC_LIBOBJ([socket])
 204    AC_DEFINE(HAVE_NETWORKING, 1,
 205      [Define this if you want support for networking in Guile.])
 206 fi
 207
 208 if test "$enable_debug_malloc" = yes; then
 209    AC_LIBOBJ([debug-malloc])
 210 fi
 211
 212 if test "$enable_elisp" = yes; then
 213   SCM_I_GSC_ENABLE_ELISP=1
 214 else
 215   SCM_I_GSC_ENABLE_ELISP=0
 216 fi
 217 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 218
 219 AC_C_CONST
 220
 221 AC_C_INLINE
 222 if test "$ac_cv_c_inline" != no; then
 223   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 224 else
 225   SCM_I_GSC_C_INLINE=NULL
 226 fi
 227 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 228
 229 AC_C_BIGENDIAN
 230
 231 AC_CHECK_SIZEOF(char)
 232 AC_CHECK_SIZEOF(unsigned char)
 233 AC_CHECK_SIZEOF(short)
 234 AC_CHECK_SIZEOF(unsigned short)
 235 AC_CHECK_SIZEOF(int)
 236 AC_CHECK_SIZEOF(unsigned int)
 237 AC_CHECK_SIZEOF(long)
 238 AC_CHECK_SIZEOF(unsigned long)
 239 AC_CHECK_SIZEOF(size_t)
 240 AC_CHECK_SIZEOF(long long)
 241 AC_CHECK_SIZEOF(unsigned long long)
 242 AC_CHECK_SIZEOF(__int64)
 243 AC_CHECK_SIZEOF(unsigned __int64)
 244 AC_CHECK_SIZEOF(void *)
 245 AC_CHECK_SIZEOF(intptr_t)
 246 AC_CHECK_SIZEOF(uintptr_t)
 247 AC_CHECK_SIZEOF(ptrdiff_t)
 248 AC_CHECK_SIZEOF(size_t)
 249 AC_CHECK_SIZEOF(off_t)
 250
 251 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 252   AC_MSG_ERROR(sizes of long and void* are not identical)
 253 fi
 254
 255 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 256   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 257 else
 258   SCM_I_GSC_T_PTRDIFF='"long"'
 259 fi
 260 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 261
 262 AC_CHECK_HEADERS([stdint.h])
 263 AC_CHECK_HEADERS([inttypes.h])
 264
 265 AC_CHECK_SIZEOF(intmax_t)
 266
 267 SCM_I_GSC_NEEDS_STDINT_H=0
 268 SCM_I_GSC_NEEDS_INTTYPES_H=0
 269
 270 ### intptr and uintptr (try not to use inttypes if we don't have to)
 271 if test "$ac_cv_header_inttypes_h" = yes; then
 272   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 273     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 274 #include <stdio.h>])
 275     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 276       SCM_I_GSC_NEEDS_INTTYPES_H=1
 277     fi
 278   fi
 279   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 280     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 281 #include <stdio.h>])
 282     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 283       SCM_I_GSC_NEEDS_INTTYPES_H=1
 284     fi
 285   fi
 286 fi
 287
 288 ### See what's provided by stdint.h
 289 if test "$ac_cv_header_stdint_h" = yes; then
 290    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 291    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 292    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 293    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 294    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 295    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 296    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 297    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 298    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 299    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 300 fi
 301
 302 # so we don't get confused by the cache (wish there was a better way
 303 # to check particular headers for the same type...)
 304
 305 unset ac_cv_type_int8_t
 306 unset ac_cv_type_uint8_t
 307 unset ac_cv_type_int16_t
 308 unset ac_cv_type_uint16_t
 309 unset ac_cv_type_int32_t
 310 unset ac_cv_type_uint32_t
 311 unset ac_cv_type_int64_t
 312 unset ac_cv_type_uint64_t
 313 unset ac_cv_type_intmax_t
 314 unset ac_cv_type_uintmax_t
 315
 316 ### See what's provided by inttypes.h
 317 if test "$ac_cv_header_inttypes_h" = yes; then
 318   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 319   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 320   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 321   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 322   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 323   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 324   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 325   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 326   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 327   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 328 fi
 329
 330 # Try hard to find definitions for some required scm_t_*int* types.
 331
 332 ### Required type scm_t_int8
 333 if test "$scm_stdint_has_int8"; then
 334   SCM_I_GSC_T_INT8='"int8_t"'
 335   SCM_I_GSC_NEEDS_STDINT_H=1
 336 elif test "$scm_inttypes_has_int8"; then
 337   SCM_I_GSC_T_INT8='"int8_t"'
 338   SCM_I_GSC_NEEDS_INTTYPES_H=1
 339 elif test "$ac_cv_sizeof_char" -eq 1; then
 340   SCM_I_GSC_T_INT8='"signed char"'
 341 else
 342   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 343 fi
 344 AC_SUBST([SCM_I_GSC_T_INT8])
 345
 346 ### Required type scm_t_uint8
 347 if test "$scm_stdint_has_uint8"; then
 348   SCM_I_GSC_T_UINT8='"uint8_t"'
 349   SCM_I_GSC_NEEDS_STDINT_H=1
 350 elif test "$scm_inttypes_has_uint8"; then
 351   SCM_I_GSC_T_UINT8='"uint8_t"'
 352   SCM_I_GSC_NEEDS_INTTYPES_H=1
 353 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 354   SCM_I_GSC_T_UINT8='"unsigned char"'
 355 else
 356   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 357 fi
 358 AC_SUBST([SCM_I_GSC_T_UINT8])
 359
 360 ### Required type scm_t_int16 (ANSI C says int or short might work)
 361 if test "$scm_stdint_has_int16"; then
 362   SCM_I_GSC_T_INT16='"int16_t"'
 363   SCM_I_GSC_NEEDS_STDINT_H=1
 364 elif test "$scm_inttypes_has_int16"; then
 365   SCM_I_GSC_T_INT16='"int16_t"'
 366   SCM_I_GSC_NEEDS_INTTYPES_H=1
 367 elif test "$ac_cv_sizeof_int" -eq 2; then
 368   SCM_I_GSC_T_INT16='"int"'
 369 elif test "$ac_cv_sizeof_short" -eq 2; then
 370   SCM_I_GSC_T_INT16='"short"'
 371 else
 372   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 373 fi
 374 AC_SUBST([SCM_I_GSC_T_INT16])
 375
 376 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 377 if test "$scm_stdint_has_uint16"; then
 378   SCM_I_GSC_T_UINT16='"uint16_t"'
 379   SCM_I_GSC_NEEDS_STDINT_H=1
 380 elif test "$scm_inttypes_has_uint16"; then
 381   SCM_I_GSC_T_UINT16='"uint16_t"'
 382   SCM_I_GSC_NEEDS_INTTYPES_H=1
 383 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 384   SCM_I_GSC_T_UINT16='"unsigned int"'
 385 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 386   SCM_I_GSC_T_UINT16='"unsigned short"'
 387 else
 388   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 389 fi
 390 AC_SUBST([SCM_I_GSC_T_UINT16])
 391
 392
 393 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 394 if test "$scm_stdint_has_int32"; then
 395   SCM_I_GSC_T_INT32='"int32_t"'
 396   SCM_I_GSC_NEEDS_STDINT_H=1
 397 elif test "$scm_inttypes_has_int32"; then
 398   SCM_I_GSC_T_INT32='"int32_t"'
 399   SCM_I_GSC_NEEDS_INTTYPES_H=1
 400 elif test "$ac_cv_sizeof_int" -eq 4; then
 401   SCM_I_GSC_T_INT32='"int"'
 402 elif test "$ac_cv_sizeof_long" -eq 4; then
 403   SCM_I_GSC_T_INT32='"long"'
 404 elif test "$ac_cv_sizeof_short" -eq 4; then
 405   SCM_I_GSC_T_INT32='"short"'
 406 else
 407   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 408 fi
 409 AC_SUBST([SCM_I_GSC_T_INT32])
 410
 411 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 412 if test "$scm_stdint_has_uint32"; then
 413   SCM_I_GSC_T_UINT32='"uint32_t"'
 414   SCM_I_GSC_NEEDS_STDINT_H=1
 415 elif test "$scm_inttypes_has_uint32"; then
 416   SCM_I_GSC_T_UINT32='"uint32_t"'
 417   SCM_I_GSC_NEEDS_INTTYPES_H=1
 418 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 419   SCM_I_GSC_T_UINT32='"unsigned int"'
 420 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 421   SCM_I_GSC_T_UINT32='"unsigned long"'
 422 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 423   SCM_I_GSC_T_UINT32='"unsigned short"'
 424 else
 425   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 426 fi
 427 AC_SUBST([SCM_I_GSC_T_UINT32])
 428
 429 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 430 ### Also try 'long long' and '__int64' if we have it.
 431 SCM_I_GSC_T_INT64=0
 432 if test "$scm_stdint_has_int64"; then
 433   SCM_I_GSC_T_INT64='"int64_t"'
 434   SCM_I_GSC_NEEDS_STDINT_H=1
 435 elif test "$scm_inttypes_has_int64"; then
 436   SCM_I_GSC_T_INT64='"int64_t"'
 437   SCM_I_GSC_NEEDS_INTTYPES_H=1
 438 elif test "$ac_cv_sizeof_int" -eq 8; then
 439   SCM_I_GSC_T_INT64='"int"'
 440 elif test "$ac_cv_sizeof_long" -eq 8; then
 441   SCM_I_GSC_T_INT64='"long"'
 442 elif test "$ac_cv_sizeof_short" -eq 8; then
 443   SCM_I_GSC_T_INT64='"short"'
 444 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 445   SCM_I_GSC_T_INT64='"long long"'
 446 elif test "$ac_cv_sizeof___int64" -eq 8; then
 447   SCM_I_GSC_T_INT64='"__int64"'
 448 else
 449   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 450 fi
 451 AC_SUBST([SCM_I_GSC_T_INT64])
 452
 453
 454 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 455 ### Also try 'long long' and '__int64' if we have it.
 456 SCM_I_GSC_T_UINT64=0
 457 if test "$scm_stdint_has_uint64"; then
 458   SCM_I_GSC_T_UINT64='"uint64_t"'
 459   SCM_I_GSC_NEEDS_STDINT_H=1
 460 elif test "$scm_inttypes_has_uint64"; then
 461   SCM_I_GSC_T_UINT64='"uint64_t"'
 462   SCM_I_GSC_NEEDS_INTTYPES_H=1
 463 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 464   SCM_I_GSC_T_UINT64='"unsigned int"'
 465 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 466   SCM_I_GSC_T_UINT64='"unsigned long"'
 467 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 468   SCM_I_GSC_T_UINT64='"unsigned short"'
 469 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 470   SCM_I_GSC_T_UINT64='"unsigned long long"'
 471 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 472   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 473 else
 474   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 475 fi
 476 AC_SUBST([SCM_I_GSC_T_UINT64])
 477
 478 ### Required type scm_t_intmax
 479 ###
 480 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 481 ### none of them is available, we use 'long'.
 482 ###
 483 SCM_I_GSC_T_INTMAX=0
 484 if test "$scm_stdint_has_intmax"; then
 485   SCM_I_GSC_T_INTMAX='"intmax_t"'
 486   SCM_I_GSC_NEEDS_STDINT_H=1
 487 elif test "$scm_inttypes_has_intmax"; then
 488   SCM_I_GSC_T_INTMAX='"intmax_t"'
 489   SCM_I_GSC_NEEDS_INTTYPES_H=1
 490 elif test "$ac_cv_sizeof___int64" -ne 0; then
 491   SCM_I_GSC_T_INTMAX='"__int64"'
 492 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 493   SCM_I_GSC_T_INTMAX='"long long"'
 494 else
 495   SCM_I_GSC_T_INTMAX='"long"'
 496 fi
 497 AC_SUBST([SCM_I_GSC_T_INTMAX])
 498
 499 ### Required type scm_t_uintmax
 500 ###
 501 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 502 ### this order.  When none of them is available, we use 'unsigned long'.
 503 ###
 504 SCM_I_GSC_T_UINTMAX=0
 505 if test "$scm_stdint_has_uintmax"; then
 506   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 507   SCM_I_GSC_NEEDS_STDINT_H=1
 508 elif test "$scm_inttypes_has_uintmax"; then
 509   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 510   SCM_I_GSC_NEEDS_INTTYPES_H=1
 511 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 512   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 513 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 514   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 515 else
 516   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 517 fi
 518 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 519
 520
 521 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 522 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 523
 524 AC_HEADER_STDC
 525 AC_HEADER_DIRENT
 526 AC_HEADER_TIME
 527 AC_HEADER_SYS_WAIT
 528
 529 # Reasons for testing:
 530 #   complex.h - new in C99
 531 #   fenv.h - available in C99, but not older systems
 532 #   process.h - mingw specific
 533 #
 534 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 535 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 536 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 537 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 538 direct.h])
 539
 540 # "complex double" is new in C99, and "complex" is only a keyword if
 541 # <complex.h> is included
 542 AC_CHECK_TYPES(complex double,,,
 543 [#if HAVE_COMPLEX_H
 544 #include <complex.h>
 545 #endif])
 546
 547 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 548 # when testing.
 549 AC_CHECK_TYPE(socklen_t, ,
 550   [AC_DEFINE_UNQUOTED(socklen_t, int,
 551                       [Define to `int' if <sys/socket.h> does not define.])],
 552   [#if HAVE_SYS_TYPES_H
 553 #include <sys/types.h>
 554 #endif
 555 #include <sys/socket.h>
 556 ])
 557 AC_CHECK_TYPE(struct ip_mreq)
 558
 559 GUILE_HEADER_LIBC_WITH_UNISTD
 560
 561 AC_TYPE_GETGROUPS
 562 AC_TYPE_SIGNAL
 563 AC_TYPE_MODE_T
 564
 565 # On mingw -lm is empty, so this test is unnecessary, but it's
 566 # harmless so we don't hard-code to suppress it.
 567 #
 568 AC_CHECK_LIB(m, cos)
 569
 570 AC_CHECK_FUNCS(gethostbyname)
 571 if test $ac_cv_func_gethostbyname = no; then
 572     AC_CHECK_LIB(nsl, gethostbyname)
 573 fi
 574
 575 AC_CHECK_FUNCS(connect)
 576 if test $ac_cv_func_connect = no; then
 577     AC_CHECK_LIB(socket, connect)
 578 fi
 579
 580 dnl
 581 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 582 dnl
 583 EXTRA_DEFS=""
 584 case $host in
 585   *-*-mingw*)
 586     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 587       [Define if you have the <winsock2.h> header file.])])
 588     AC_CHECK_LIB(ws2_32, main)
 589     AC_LIBOBJ([win32-uname])
 590     AC_LIBOBJ([win32-dirent])
 591     if test "$enable_networking" = yes ; then
 592       AC_LIBOBJ([win32-socket])
 593     fi
 594     if test "$enable_shared" = yes ; then
 595       EXTRA_DEFS="-DSCM_IMPORT"
 596       AC_DEFINE(USE_DLL_IMPORT, 1,
 597         [Define if you need additional CPP macros on Win32 platforms.])
 598     fi
 599     ;;
 600 esac
 601 AC_SUBST(EXTRA_DEFS)
 602
 603 # Reasons for testing:
 604 #   crt_externs.h - Darwin specific
 605 #
 606 AC_CHECK_HEADERS([assert.h crt_externs.h])
 607
 608 # Reasons for testing:
 609 #   DINFINITY - OSF specific
 610 #   DQNAN - OSF specific
 611 #       (DINFINITY and DQNAN are actually global variables, not functions)
 612 #   chsize - an MS-DOS-ism, found in mingw
 613 #   clog10 - not in mingw (though others like clog and csqrt are)
 614 #   fesetround - available in C99, but not older systems
 615 #   ftruncate - posix, but probably not older systems (current mingw
 616 #               has it as an inline for chsize)
 617 #   ioctl - not in mingw.
 618 #   gmtime_r - recent posix, not on old systems
 619 #   pipe - not in mingw
 620 #   _pipe - specific to mingw, taking 3 args
 621 #   readdir_r - recent posix, not on old systems
 622 #   stat64 - SuS largefile stuff, not on old systems
 623 #   sysconf - not on old systems
 624 #   truncate - not in mingw
 625 #   isblank - available as a GNU extension or in C99
 626 #   _NSGetEnviron - Darwin specific
 627 #   strcoll_l, newlocale - GNU extensions (glibc)
 628 #
 629 AC_CHECK_FUNCS([DINFINITY DQNAN chsize clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale])
 630
 631 # Reasons for testing:
 632 #   netdb.h - not in mingw
 633 #   sys/param.h - not in mingw
 634 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 635 #       check this specifically, we need it for the timespec test below.
 636 #   sethostname - the function itself check because it's not in mingw,
 637 #       the DECL is checked because Solaris 10 doens't have in any header
 638 #
 639 AC_CHECK_HEADERS(crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h)
 640 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 641 AC_CHECK_DECLS([sethostname])
 642
 643 # crypt() may or may not be available, for instance in some countries there
 644 # are restrictions on cryptography.
 645 #
 646 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 647 # -lcrypt library (eg. Debian GNU/Linux).
 648 #
 649 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 650 # be careful to avoid -lcrypt in this case, since libtool will see there's
 651 # only a static libcrypt and decide to build only a static libguile.
 652 #
 653 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 654 # libraries already in that list.
 655 #
 656 AC_SEARCH_LIBS(crypt, crypt,
 657   [AC_DEFINE(HAVE_CRYPT,1,
 658              [Define to 1 if you have the `crypt' function.])])
 659
 660 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 661 # csqrt(-i) returned a negative real part, when it should be positive
 662 # for the principal root.
 663 #
 664 if test "$ac_cv_type_complex_double" = yes; then
 665   AC_CACHE_CHECK([whether csqrt is usable],
 666     guile_cv_use_csqrt,
 667     [AC_TRY_RUN([
 668 #include <complex.h>
 669 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 670    constant, we want to test libc. */
 671 volatile complex double z = - _Complex_I;
 672 int
 673 main (void)
 674 {
 675   z = csqrt (z);
 676   if (creal (z) > 0.0)
 677     return 0;  /* good */
 678   else
 679     return 1;  /* bad */
 680 }],
 681     [guile_cv_use_csqrt=yes],
 682     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 683     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 684   case $guile_cv_use_csqrt in
 685     yes*)
 686       AC_DEFINE(HAVE_USABLE_CSQRT, 1, [Define to 1 if csqrt is bug-free])
 687       ;;
 688   esac
 689 fi
 690
 691
 692 dnl GMP tests
 693 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 694   [AC_MSG_ERROR([GNU MP not found, see README])])
 695
 696 # mpz_import is a macro so we need to include <gmp.h>
 697 AC_TRY_LINK([#include <gmp.h>],
 698             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 699   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see README])])
 700
 701 dnl i18n tests
 702 #AC_CHECK_HEADERS([libintl.h])
 703 #AC_CHECK_FUNCS(gettext)
 704 #if test $ac_cv_func_gettext = no; then
 705 #   AC_CHECK_LIB(intl, gettext)
 706 #fi
 707 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 708 AM_GNU_GETTEXT([external], [need-ngettext])
 709 AM_GNU_GETTEXT_VERSION([0.16])
 710
 711 ### Some systems don't declare some functions.  On such systems, we
 712 ### need to at least provide our own K&R-style declarations.
 713
 714 ### GUILE_FUNC_DECLARED(function, headerfile)
 715
 716 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 717 ### not there, #define MISSING_FUNCTION_DECL.
 718 AC_DEFUN([GUILE_FUNC_DECLARED], [
 719   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 720     AC_EGREP_HEADER($1, $2,
 721                     guile_cv_func_$1_declared=yes,
 722                     guile_cv_func_$1_declared=no))
 723   if test [x$guile_cv_func_]$1[_declared] = xno; then
 724     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 725       [Define if the operating system supplies $1 without declaring it.])
 726   fi
 727 ])
 728
 729 GUILE_FUNC_DECLARED(sleep, unistd.h)
 730 GUILE_FUNC_DECLARED(usleep, unistd.h)
 731
 732 AC_CHECK_DECLS([strptime],,,
 733 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 734 #include <time.h>])
 735
 736 ### On some systems usleep has no return value.  If it does have one,
 737 ### we'd like to return it; otherwise, we'll fake it.
 738 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 739   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 740                    unistd.h,
 741                    [guile_cv_func_usleep_return_type=void],
 742                    [guile_cv_func_usleep_return_type=int])])
 743 case "$guile_cv_func_usleep_return_type" in
 744   "void" )
 745     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 746       [Define if the system headers declare usleep to return void.])
 747   ;;
 748 esac
 749
 750 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 751 if test -n "$have_sys_un_h" ; then
 752   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 753     [Define if the system supports Unix-domain (file-domain) sockets.])
 754 fi
 755
 756 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 757
 758 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 759                setnetent    getnetent    endnetent    dnl
 760                setprotoent  getprotoent  endprotoent  dnl
 761                setservent   getservent   endservent   dnl
 762                getnetbyaddr getnetbyname dnl
 763                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 764                inet_pton inet_ntop)
 765
 766 # struct sockaddr field sin_len is only present on BSD systems.
 767 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 768 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 769 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 770 [#ifdef HAVE_SYS_TYPES_H
 771 #include <sys/types.h>
 772 #endif
 773 #include <netinet/in.h>])
 774
 775 AC_MSG_CHECKING(for __libc_stack_end)
 776 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 777 [AC_TRY_LINK([#include <stdio.h>
 778 extern char *__libc_stack_end;],
 779              [printf("%p", (char*) __libc_stack_end);],
 780              guile_cv_have_libc_stack_end=yes,
 781              guile_cv_have_libc_stack_end=no)])
 782 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 783
 784 if test $guile_cv_have_libc_stack_end = yes; then
 785   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 786            [Define if you have the __libc_stack_end variable.])
 787 fi
 788
 789 dnl Some systems do not declare this.  Some systems do declare it, as a
 790 dnl macro.  With cygwin it may be in a DLL.
 791
 792 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 793 AC_CACHE_VAL(guile_cv_have_h_errno,
 794 [AC_TRY_COMPILE([#include <netdb.h>],
 795 [int a = h_errno;],
 796 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 797 AC_MSG_RESULT($guile_cv_have_h_errno)
 798 if test $guile_cv_have_h_errno = yes; then
 799   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 800 fi
 801
 802 AC_MSG_CHECKING(whether uint32_t is defined)
 803 AC_CACHE_VAL(guile_cv_have_uint32_t,
 804   [AC_TRY_COMPILE([#include <sys/types.h>
 805                    #if HAVE_STDINT_H
 806                    #include <stdint.h>
 807                    #endif
 808                    #ifndef HAVE_NETDB_H
 809                    #include <netdb.h>
 810                    #endif],
 811                   [uint32_t a;],
 812                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 813 AC_MSG_RESULT($guile_cv_have_uint32_t)
 814 if test $guile_cv_have_uint32_t = yes; then
 815   AC_DEFINE(HAVE_UINT32_T, 1,
 816     [Define if uint32_t typedef is defined when netdb.h is include.])
 817 fi
 818
 819 AC_MSG_CHECKING(for working IPv6 support)
 820 AC_CACHE_VAL(guile_cv_have_ipv6,
 821 [AC_TRY_COMPILE([
 822 #ifdef HAVE_SYS_TYPES_H
 823 #include <sys/types.h>
 824 #endif
 825 #include <netinet/in.h>
 826 #include <sys/socket.h>],
 827 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 828 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 829 AC_MSG_RESULT($guile_cv_have_ipv6)
 830 if test $guile_cv_have_ipv6 = yes; then
 831   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 832 fi
 833
 834 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 835 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 836 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 837 [AC_TRY_COMPILE([
 838 #ifdef HAVE_SYS_TYPES_H
 839 #include <sys/types.h>
 840 #endif
 841 #include <netinet/in.h>],
 842 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 843 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 844 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 845 if test $guile_cv_have_sin6_scope_id = yes; then
 846   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 847     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 848 fi
 849
 850 # struct sockaddr_in6 field sin_len is only present on BSD systems
 851 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 852 [#ifdef HAVE_SYS_TYPES_H
 853 #include <sys/types.h>
 854 #endif
 855 #include <netinet/in.h>])
 856
 857 AC_MSG_CHECKING(whether localtime caches TZ)
 858 AC_CACHE_VAL(guile_cv_localtime_cache,
 859 [if test x$ac_cv_func_tzset = xyes; then
 860 AC_TRY_RUN([#include <time.h>
 861 #if STDC_HEADERS
 862 # include <stdlib.h>
 863 #endif
 864 extern char **environ;
 865 unset_TZ ()
 866 {
 867   char **from, **to;
 868   for (to = from = environ; (*to = *from); from++)
 869     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 870       to++;
 871 }
 872 char TZ_GMT0[] = "TZ=GMT0";
 873 char TZ_PST8[] = "TZ=PST8";
 874 main()
 875 {
 876   time_t now = time ((time_t *) 0);
 877   int hour_GMT0, hour_unset;
 878   if (putenv (TZ_GMT0) != 0)
 879     exit (1);
 880   hour_GMT0 = localtime (&now)->tm_hour;
 881   unset_TZ ();
 882   hour_unset = localtime (&now)->tm_hour;
 883   if (putenv (TZ_PST8) != 0)
 884     exit (1);
 885   if (localtime (&now)->tm_hour == hour_GMT0)
 886     exit (1);
 887   unset_TZ ();
 888   if (localtime (&now)->tm_hour != hour_unset)
 889     exit (1);
 890   exit (0);
 891 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 892 [# If we have tzset, assume the worst when cross-compiling.
 893 guile_cv_localtime_cache=yes])
 894 else
 895         # If we lack tzset, report that localtime does not cache TZ,
 896         # since we can't invalidate the cache if we don't have tzset.
 897         guile_cv_localtime_cache=no
 898 fi])dnl
 899 AC_MSG_RESULT($guile_cv_localtime_cache)
 900 if test $guile_cv_localtime_cache = yes; then
 901   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 902 fi
 903
 904 dnl Test whether system calls are restartable by default on the
 905 dnl current system.  If they are not, we put a loop around every system
 906 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 907 dnl change from the default behaviour.  On the other hand, if signals
 908 dnl are restartable then the loop is not installed and when libguile
 909 dnl initialises it also resets the behaviour of each signal to cause a
 910 dnl restart (in case a different runtime had a different default
 911 dnl behaviour for some reason: e.g., different versions of linux seem
 912 dnl to behave differently.)
 913
 914 AC_SYS_RESTARTABLE_SYSCALLS
 915
 916 if test "$enable_regex" = yes; then
 917    if test "$ac_cv_header_regex_h" = yes ||
 918       test "$ac_cv_header_rxposix_h" = yes ||
 919       test "$ac_cv_header_rx_rxposix_h" = yes; then
 920      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 921      [AC_CHECK_LIB(rx, main)
 922       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 923      [AC_CHECK_LIB(regex, main)
 924       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 925      )
 926      dnl The following should not be necessary, but for some reason
 927      dnl autoheader misses it if we don't include it!
 928      if test "$ac_cv_func_regcomp_norx" = yes ||
 929         test "$ac_cv_func_regcomp_regex" = yes ||
 930         test "$ac_cv_func_regcomp_rx" = yes; then
 931        AC_DEFINE(HAVE_REGCOMP, 1,
 932          [This is included as part of a workaround for a autoheader bug.])
 933      fi
 934    fi
 935 fi
 936
 937 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 938
 939 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 940
 941 # Reasons for testing:
 942 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 943 #                                older systems
 944 #   sincos - GLIBC extension
 945 #
 946 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
 947
 948 # C99 specifies isinf and isnan as macros.
 949 # HP-UX provides only macros, no functions.
 950 # glibc 2.3.2 provides both macros and functions.
 951 # IRIX 6.5 and Solaris 8 only provide functions.
 952 #
 953 # The following tests detect isinf and isnan either as functions or as
 954 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
 955 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
 956 #
 957 AC_MSG_CHECKING([for isinf])
 958 AC_LINK_IFELSE(
 959 [#include <math.h>
 960 int main () { return (isinf(0.0) != 0); }],
 961   [AC_MSG_RESULT([yes])
 962    AC_DEFINE(HAVE_ISINF, 1,
 963              [Define to 1 if you have the `isinf' macro or function.])],
 964   [AC_MSG_RESULT([no])])
 965 AC_MSG_CHECKING([for isnan])
 966 AC_LINK_IFELSE(
 967 [#include <math.h>
 968 int main () { return (isnan(0.0) != 0); }],
 969   [AC_MSG_RESULT([yes])
 970    AC_DEFINE(HAVE_ISNAN, 1,
 971              [Define to 1 if you have the `isnan' macro or function.])],
 972   [AC_MSG_RESULT([no])])
 973
 974 # We must have a proper stack-using alloca in order for stack-copying
 975 # continuations to work properly.  If we don't find a native one,
 976 # abort.
 977
 978 AC_FUNC_ALLOCA
 979 if test "$ALLOCA" = "alloca.o"
 980 then
 981   AC_ERROR([No native alloca found.])
 982 fi
 983
 984 # Reasons for checking:
 985 #
 986 #     st_rdev
 987 #     st_blksize
 988 #     st_blocks   not in mingw
 989 #     tm_gmtoff   BSD+GNU, not in C99
 990 #
 991 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
 992 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
 993 #
 994 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks])
 995
 996 AC_STRUCT_TIMEZONE
 997 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
 998 [#include <time.h>
 999 #ifdef TIME_WITH_SYS_TIME
1000 # include <sys/time.h>
1001 # include <time.h>
1002 #else
1003 # if HAVE_SYS_TIME_H
1004 #  include <sys/time.h>
1005 # else
1006 #  include <time.h>
1007 # endif
1008 #endif
1009 ])
1010 GUILE_STRUCT_UTIMBUF
1011
1012
1013 #--------------------------------------------------------------------
1014 #
1015 # Which way does the stack grow?
1016 #
1017 #--------------------------------------------------------------------
1018
1019 SCM_I_GSC_STACK_GROWS_UP=0
1020 AC_TRY_RUN(aux (l) unsigned long l;
1021              { int x; exit (l >= ((unsigned long)&x)); }
1022            main () { int q; aux((unsigned long)&q); },
1023            [SCM_I_GSC_STACK_GROWS_UP=1],
1024            [],
1025            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1026
1027 AC_CHECK_SIZEOF(float)
1028 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1029     AC_DEFINE(SCM_SINGLES, 1,
1030               [Define this if floats are the same size as longs.])
1031 fi
1032
1033 AC_MSG_CHECKING(for struct linger)
1034 AC_CACHE_VAL(scm_cv_struct_linger,
1035         AC_TRY_COMPILE([
1036 #include <sys/types.h>
1037 #include <sys/socket.h>],
1038                         [struct linger lgr;  lgr.l_linger = 100],
1039                         scm_cv_struct_linger="yes",
1040                         scm_cv_struct_linger="no"))
1041 AC_MSG_RESULT($scm_cv_struct_linger)
1042 if test $scm_cv_struct_linger = yes; then
1043         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
1044           [Define this if your system defines struct linger, for use with the
1045            getsockopt and setsockopt system calls.])
1046 fi
1047
1048
1049 # On mingw, struct timespec is in <pthread.h>.
1050 #
1051 AC_MSG_CHECKING(for struct timespec)
1052 AC_CACHE_VAL(scm_cv_struct_timespec,
1053         AC_TRY_COMPILE([
1054 #include <time.h>
1055 #if HAVE_PTHREAD_H
1056 #include <pthread.h>
1057 #endif],
1058                         [struct timespec t;  t.tv_nsec = 100],
1059                         scm_cv_struct_timespec="yes",
1060                         scm_cv_struct_timespec="no"))
1061 AC_MSG_RESULT($scm_cv_struct_timespec)
1062 if test $scm_cv_struct_timespec = yes; then
1063   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
1064     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1065 fi
1066
1067 #--------------------------------------------------------------------
1068 #
1069 # Flags for thread support
1070 #
1071 #--------------------------------------------------------------------
1072
1073 SCM_I_GSC_USE_PTHREAD_THREADS=0
1074 SCM_I_GSC_USE_NULL_THREADS=0
1075 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1076 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1077
1078 ### What thread package has the user asked for?
1079 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1080             , with_threads=yes)
1081
1082 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1083
1084 case "$with_threads" in
1085   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1086     ACX_PTHREAD(CC="$PTHREAD_CC"
1087       LIBS="$PTHREAD_LIBS $LIBS"
1088       SCM_I_GSC_USE_PTHREAD_THREADS=1
1089       with_threads="pthreads",
1090       with_threads="null")
1091
1092     old_CFLAGS="$CFLAGS"
1093     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1094
1095     # Reasons for testing:
1096     #     pthread_getattr_np - "np" meaning "non portable" says it
1097     #         all; not present on MacOS X or Solaris 10
1098     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1099     #         all; specific to MacOS X
1100     #     pthread_sigmask - not available on mingw
1101     #
1102     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1103
1104     # On past versions of Solaris, believe 8 through 10 at least, you
1105     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1106     # This is contrary to posix:
1107     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1108     # Check here if this style is required.
1109     #
1110     # glibc (2.3.6 at least) works both with or without braces, so the
1111     # test checks whether it works without.
1112     #
1113     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1114       guile_cv_need_braces_on_pthread_once_init,
1115       [AC_TRY_COMPILE([#include <pthread.h>],
1116         [pthread_once_t foo = PTHREAD_ONCE_INIT;],
1117         [guile_cv_need_braces_on_pthread_once_init=no],
1118         [guile_cv_need_braces_on_pthread_once_init=yes])])
1119     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1120       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1121     fi
1122
1123     CFLAGS="$old_CFLAGS"
1124
1125     # On Solaris, sched_yield lives in -lrt.
1126     AC_SEARCH_LIBS(sched_yield, rt)
1127
1128   ;;
1129 esac
1130
1131 case "$with_threads" in
1132   "pthreads")
1133   ;;
1134   "no" | "null")
1135     SCM_I_GSC_USE_NULL_THREADS=1
1136     with_threads="null-threads"
1137   ;;
1138   * )
1139     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1140   ;;
1141 esac
1142
1143 AC_MSG_CHECKING(what kind of threads to support)
1144 AC_MSG_RESULT($with_threads)
1145
1146 ## Check whether pthread_attr_getstack works for the main thread
1147
1148 if test "$with_threads" = pthreads; then
1149
1150 AC_MSG_CHECKING(whether pthread_attr_getstack works for the main thread)
1151 old_CFLAGS="$CFLAGS"
1152 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1153 AC_TRY_RUN(
1154 [
1155 #if HAVE_PTHREAD_ATTR_GETSTACK
1156 #include <pthread.h>
1157
1158 int main ()
1159 {
1160   pthread_attr_t attr;
1161   void *start, *end;
1162   size_t size;
1163
1164   pthread_getattr_np (pthread_self (), &attr);
1165   pthread_attr_getstack (&attr, &start, &size);
1166   end = (char *)start + size;
1167
1168   if ((void *)&attr < start || (void *)&attr >= end)
1169     return 1;
1170   else
1171     return 0;
1172 }
1173 #else
1174 int main ()
1175 {
1176   return 1;
1177 }
1178 #endif
1179 ],
1180 [works=yes
1181 AC_DEFINE(PTHREAD_ATTR_GETSTACK_WORKS, [1], [Define when pthread_att_get_stack works for the main thread])],
1182 [works=no])
1183 CFLAGS="$old_CFLAGS"
1184 AC_MSG_RESULT($works)
1185
1186 fi # with_threads=pthreads
1187
1188
1189 ## Cross building
1190 if test "$cross_compiling" = "yes"; then
1191   AC_MSG_CHECKING(cc for build)
1192   ## /usr/bin/cc still uses wrong assembler
1193   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1194   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1195 else
1196   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1197 fi
1198
1199 ## AC_MSG_CHECKING("if we are cross compiling")
1200 ## AC_MSG_RESULT($cross_compiling)
1201 if test "$cross_compiling" = "yes"; then
1202    AC_MSG_RESULT($CC_FOR_BUILD)
1203 fi
1204
1205 ## No need as yet to be more elaborate
1206 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1207
1208 AC_SUBST(cross_compiling)
1209 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1210 AC_SUBST(CCLD_FOR_BUILD)
1211
1212 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1213 ## --HOST is the platform that PACKAGE is compiled for.
1214 HOST_CC="$CC_FOR_BUILD"
1215 AC_SUBST(HOST_CC)
1216
1217 if test "$cross_compiling" = "yes"; then
1218   AC_MSG_CHECKING(guile for build)
1219   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1220 else
1221   GUILE_FOR_BUILD='$(preinstguile)'
1222 fi
1223
1224 ## AC_MSG_CHECKING("if we are cross compiling")
1225 ## AC_MSG_RESULT($cross_compiling)
1226 if test "$cross_compiling" = "yes"; then
1227    AC_MSG_RESULT($GUILE_FOR_BUILD)
1228 fi
1229 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1230 AC_SUBST(GUILE_FOR_BUILD)
1231
1232 ## If we're using GCC, ask for aggressive warnings.
1233 case "$GCC" in
1234   yes )
1235     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1236     ## much stuff with generic function pointers for that to really be
1237     ## less than exasperating.
1238     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1239     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1240     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1241     # Do this here so we don't screw up any of the tests above that might
1242     # not be "warning free"
1243     if test "${GUILE_ERROR_ON_WARNING}" = yes
1244     then
1245         CFLAGS="${CFLAGS} -Werror"
1246         enable_compile_warnings=no
1247     fi
1248     ;;
1249 esac
1250
1251 ## If we're creating a shared library (using libtool!), then we'll
1252 ## need to generate a list of .lo files corresponding to the .o files
1253 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1254 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1255
1256 ## We also need to create corresponding .doc and .x files
1257 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1258 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1259
1260 AC_SUBST(GUILE_MAJOR_VERSION)
1261 AC_SUBST(GUILE_MINOR_VERSION)
1262 AC_SUBST(GUILE_MICRO_VERSION)
1263 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1264 AC_SUBST(GUILE_VERSION)
1265
1266 #######################################################################
1267 # library versioning
1268
1269 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1270 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1271 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1272 AC_SUBST(LIBGUILE_INTERFACE)
1273
1274 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1275 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1276 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1277 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1278 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1279
1280 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1281 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1282 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1283 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1284 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1285
1286 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1287 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1288 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1289 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1290 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1291
1292 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1293 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1294 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1295 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1296 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1297
1298 AC_SUBST(LIBGUILE_I18N_MAJOR)
1299 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1300 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1301 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1302 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1303
1304
1305 #######################################################################
1306
1307 dnl Tell guile-config what flags guile users should compile and link with.
1308 GUILE_LIBS="$LDFLAGS $LIBS"
1309 GUILE_CFLAGS="$PTHREAD_CFLAGS"
1310 AC_SUBST(GUILE_LIBS)
1311 AC_SUBST(GUILE_CFLAGS)
1312
1313 AC_SUBST(AWK)
1314 AC_SUBST(LIBLOBJS)
1315 AC_SUBST(EXTRA_DOT_DOC_FILES)
1316 AC_SUBST(EXTRA_DOT_X_FILES)
1317
1318 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1319 top_builddir_absolute=`pwd`
1320 AC_SUBST(top_builddir_absolute)
1321 top_srcdir_absolute=`(cd $srcdir && pwd)`
1322 AC_SUBST(top_srcdir_absolute)
1323
1324 # Additional SCM_I_GSC definitions are above.
1325 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1326 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1327 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1328 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1329 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1330 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1331 AC_SUBST([SCM_I_GSC_C_INLINE])
1332 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1333
1334 AC_CONFIG_FILES([
1335   Makefile
1336   am/Makefile
1337   benchmark-suite/Makefile
1338   doc/Makefile
1339   doc/goops/Makefile
1340   doc/r5rs/Makefile
1341   doc/ref/Makefile
1342   doc/tutorial/Makefile
1343   emacs/Makefile
1344   examples/Makefile
1345   examples/box-dynamic-module/Makefile
1346   examples/box-dynamic/Makefile
1347   examples/box-module/Makefile
1348   examples/box/Makefile
1349   examples/modules/Makefile
1350   examples/safe/Makefile
1351   examples/scripts/Makefile
1352   guile-config/Makefile
1353   ice-9/Makefile
1354   ice-9/debugger/Makefile
1355   ice-9/debugging/Makefile
1356   lang/Makefile
1357   lang/elisp/Makefile
1358   lang/elisp/internals/Makefile
1359   lang/elisp/primitives/Makefile
1360   libguile/Makefile
1361   oop/Makefile
1362   oop/goops/Makefile
1363   scripts/Makefile
1364   srfi/Makefile
1365   test-suite/Makefile
1366   test-suite/standalone/Makefile
1367 ])
1368
1369 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1370 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1371 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1372 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1373 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1374 AC_CONFIG_FILES([libguile/guile-snarf],
1375                 [chmod +x libguile/guile-snarf])
1376 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1377                 [chmod +x libguile/guile-doc-snarf])
1378 AC_CONFIG_FILES([libguile/guile-func-name-check],
1379                 [chmod +x libguile/guile-func-name-check])
1380 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1381                 [chmod +x libguile/guile-snarf-docs])
1382
1383 AC_OUTPUT
1384
1385 dnl Local Variables:
1386 dnl comment-start: "dnl "
1387 dnl comment-end: ""
1388 dnl comment-start-skip: "\\bdnl\\b\\s *"
1389 dnl End: