configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it under
  12 the terms of the GNU Lesser General Public License as published by the
  13 Free Software Foundation; either version 3, or (at your option) any
  14 later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but WITHOUT
  17 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  19 License for more details.
  20
  21 You should have received a copy of the GNU Lesser General Public
  22 License along with GUILE; see the file COPYING.LESSER.  If not, write
  23 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  24 Floor, Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.61)
  29
  30 dnl  `patsubst' here deletes the newline which "echo" prints.  We can't use
  31 dnl  "echo -n" since -n is not portable (see autoconf manual "Limitations of
  32 dnl  Builtins"), in particular on solaris it results in a literal "-n" in
  33 dnl  the output.
  34 dnl
  35 AC_INIT(patsubst(m4_esyscmd(. ./GUILE-VERSION && echo ${PACKAGE}),[
  36 ]),
  37         patsubst(m4_esyscmd(. ./GUILE-VERSION && echo ${GUILE_VERSION}),[
  38 ]),
  39         [bug-guile@gnu.org])
  40 AC_CONFIG_AUX_DIR([build-aux])
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR(GUILE-VERSION)
  43
  44 AM_INIT_AUTOMAKE([gnu no-define check-news -Wall -Wno-override])
  45
  46 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  47 AC_CONFIG_SRCDIR([GUILE-VERSION])
  48
  49 . $srcdir/GUILE-VERSION
  50
  51 AC_CONFIG_HEADERS([config.h])
  52 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  53
  54 #--------------------------------------------------------------------
  55
  56 AC_LANG([C])
  57
  58 dnl Some more checks for Win32
  59 AC_CANONICAL_HOST
  60
  61 AC_LIBTOOL_WIN32_DLL
  62
  63 AC_PROG_INSTALL
  64 AC_PROG_CC
  65 gl_EARLY
  66 AC_PROG_CPP
  67 AC_PROG_SED
  68 AC_PROG_AWK
  69
  70 dnl Gnulib.
  71 gl_INIT
  72
  73 AC_PROG_CC_C89
  74
  75 # for per-target cflags in the libguile subdir
  76 AM_PROG_CC_C_O
  77
  78 AC_LIBTOOL_DLOPEN
  79 AC_PROG_LIBTOOL
  80 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  81   [AC_MSG_ERROR([libltdl not found.  See README.])])
  82 AC_CHECK_HEADER([ltdl.h], [],
  83   [AC_MSG_ERROR([<ltdl.h> not found.  See README.])])
  84
  85 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  86 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  87
  88 AM_PATH_LISPDIR
  89
  90 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
  91   [Define to the host's GNU triplet.])
  92
  93 #--------------------------------------------------------------------
  94 #
  95 # User options (after above tests that may set default CFLAGS etc.)
  96 #
  97 #--------------------------------------------------------------------
  98
  99 GUILE_ERROR_ON_WARNING="yes"
 100
 101 AC_ARG_ENABLE(error-on-warning,
 102   [  --enable-error-on-warning    treat compile warnings as errors],
 103   [case "${enableval}" in
 104      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 105      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 106      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 107    esac])
 108
 109 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
 110 AC_ARG_ENABLE(debug-freelist,
 111   [  --enable-debug-freelist include garbage collector freelist debugging code],
 112   if test "$enable_debug_freelist" = y \
 113      || test "$enable_debug_freelist" = yes; then
 114     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 115   fi)
 116
 117 AC_ARG_ENABLE(debug-malloc,
 118   [  --enable-debug-malloc   include malloc debugging code],
 119   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 120     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 121       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 122   fi)
 123
 124 SCM_I_GSC_GUILE_DEBUG=0
 125 AC_ARG_ENABLE(guile-debug,
 126   [AS_HELP_STRING([--enable-guile-debug],
 127                   [include internal debugging functions])],
 128   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 129     SCM_I_GSC_GUILE_DEBUG=1
 130   fi)
 131
 132 AC_ARG_ENABLE(posix,
 133   [  --disable-posix         omit posix interfaces],,
 134   enable_posix=yes)
 135
 136 AC_ARG_ENABLE(networking,
 137   [  --disable-networking    omit networking interfaces],,
 138   enable_networking=yes)
 139
 140 AC_ARG_ENABLE(regex,
 141   [  --disable-regex         omit regular expression interfaces],,
 142   enable_regex=yes)
 143
 144 AC_ARG_ENABLE([discouraged],
 145   AS_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 146
 147 if test "$enable_discouraged" = no; then
 148   SCM_I_GSC_ENABLE_DISCOURAGED=0
 149 else
 150   SCM_I_GSC_ENABLE_DISCOURAGED=1
 151 fi
 152
 153 AC_ARG_ENABLE([deprecated],
 154   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 155
 156 if test "$enable_deprecated" = no; then
 157   SCM_I_GSC_ENABLE_DEPRECATED=0
 158   warn_default=no
 159 else
 160   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 161     warn_default=summary
 162   elif test "$enable_deprecated" = shutup; then
 163     warn_default=no
 164   else
 165     warn_default=$enable_deprecated
 166   fi
 167   SCM_I_GSC_ENABLE_DEPRECATED=1
 168 fi
 169 AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 170 [Define this to control the default warning level for deprecated features.])
 171
 172 AC_ARG_ENABLE(elisp,
 173   [  --disable-elisp         omit Emacs Lisp support],,
 174   enable_elisp=yes)
 175
 176 dnl  Added the following configure option in January 2008 following
 177 dnl  investigation of problems with "64" system and library calls on
 178 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 179 dnl  system has stat64, it will have all the other 64 APIs too; but on
 180 dnl  Darwin, stat64 is there but other APIs are missing.
 181 dnl
 182 dnl  It also appears, from the Darwin docs, that most system call APIs
 183 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 184 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 185 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 186 dnl
 187 dnl  A similar problem has been reported for HP-UX:
 188 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 189 dnl
 190 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 191 dnl  better than no Guile at all, we provide this option to suppress
 192 dnl  trying to use "64" calls.
 193 dnl
 194 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 195 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 196 dnl  missing out on that.  If so, someone can work on that in the future.
 197 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 198 dnl  wasn't building before.
 199 AC_MSG_CHECKING([whether to use system and library "64" calls])
 200 AC_ARG_WITH([64-calls],
 201   AS_HELP_STRING([--without-64-calls],
 202                  [don't attempt to use system and library calls with "64" in their names]),
 203   [use_64_calls=$withval],
 204   [use_64_calls=yes
 205    case $host in
 206      *-apple-darwin* )
 207        use_64_calls=no
 208        ;;
 209      powerpc-ibm-aix* )
 210        use_64_calls=no
 211        ;;
 212    esac])
 213 AC_MSG_RESULT($use_64_calls)
 214 case "$use_64_calls" in
 215   y* )
 216     AC_DEFINE(GUILE_USE_64_CALLS, 1,
 217       [Define to 1 in order to try to use "64" versions of system and library calls.])
 218     ;;
 219 esac
 220
 221 #--------------------------------------------------------------------
 222
 223 dnl Check for dynamic linking
 224
 225 use_modules=yes
 226 AC_ARG_WITH(modules,
 227 [  --with-modules[=FILES]  Add support for dynamic modules],
 228 use_modules="$withval")
 229 test -z "$use_modules" && use_modules=yes
 230 DLPREOPEN=
 231 if test "$use_modules" != no; then
 232   if test "$use_modules" = yes; then
 233     DLPREOPEN="-dlpreopen force"
 234   else
 235     DLPREOPEN="-export-dynamic"
 236     for module in $use_modules; do
 237       DLPREOPEN="$DLPREOPEN -dlopen $module"
 238     done
 239   fi
 240 fi
 241
 242 dnl files which are destined for separate modules.
 243
 244 if test "$use_modules" != no; then
 245    AC_LIBOBJ([dynl])
 246 fi
 247
 248 if test "$enable_posix" = yes; then
 249    AC_LIBOBJ([filesys])
 250    AC_LIBOBJ([posix])
 251    AC_DEFINE(HAVE_POSIX, 1,
 252      [Define this if you want support for POSIX system calls in Guile.])
 253 fi
 254
 255 if test "$enable_networking" = yes; then
 256    AC_LIBOBJ([net_db])
 257    AC_LIBOBJ([socket])
 258    AC_DEFINE(HAVE_NETWORKING, 1,
 259      [Define this if you want support for networking in Guile.])
 260 fi
 261
 262 if test "$enable_debug_malloc" = yes; then
 263    AC_LIBOBJ([debug-malloc])
 264 fi
 265
 266 if test "$enable_elisp" = yes; then
 267   SCM_I_GSC_ENABLE_ELISP=1
 268 else
 269   SCM_I_GSC_ENABLE_ELISP=0
 270 fi
 271 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 272
 273 AC_C_CONST
 274
 275 # "volatile" is used in a couple of tests below.
 276 AC_C_VOLATILE
 277
 278 AC_C_INLINE
 279 if test "$ac_cv_c_inline" != no; then
 280   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 281 else
 282   SCM_I_GSC_C_INLINE=NULL
 283 fi
 284 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 285
 286 AC_C_BIGENDIAN
 287
 288 AC_C_LABELS_AS_VALUES
 289
 290 AC_CHECK_SIZEOF(char)
 291 AC_CHECK_SIZEOF(unsigned char)
 292 AC_CHECK_SIZEOF(short)
 293 AC_CHECK_SIZEOF(unsigned short)
 294 AC_CHECK_SIZEOF(int)
 295 AC_CHECK_SIZEOF(unsigned int)
 296 AC_CHECK_SIZEOF(long)
 297 AC_CHECK_SIZEOF(unsigned long)
 298 AC_CHECK_SIZEOF(size_t)
 299 AC_CHECK_SIZEOF(long long)
 300 AC_CHECK_SIZEOF(unsigned long long)
 301 AC_CHECK_SIZEOF(__int64)
 302 AC_CHECK_SIZEOF(unsigned __int64)
 303 AC_CHECK_SIZEOF(void *)
 304 AC_CHECK_SIZEOF(intptr_t)
 305 AC_CHECK_SIZEOF(uintptr_t)
 306 AC_CHECK_SIZEOF(ptrdiff_t)
 307 AC_CHECK_SIZEOF(size_t)
 308 AC_CHECK_SIZEOF(off_t)
 309
 310 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 311   AC_MSG_ERROR(sizes of long and void* are not identical)
 312 fi
 313
 314 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 315   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 316 else
 317   SCM_I_GSC_T_PTRDIFF='"long"'
 318 fi
 319 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 320
 321 AC_CHECK_HEADERS([stdint.h])
 322 AC_CHECK_HEADERS([inttypes.h])
 323
 324 AC_CHECK_SIZEOF(intmax_t)
 325
 326 SCM_I_GSC_NEEDS_STDINT_H=0
 327 SCM_I_GSC_NEEDS_INTTYPES_H=0
 328
 329 ### intptr and uintptr (try not to use inttypes if we don't have to)
 330 if test "$ac_cv_header_inttypes_h" = yes; then
 331   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 332     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 333 #include <stdio.h>])
 334     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 335       SCM_I_GSC_NEEDS_INTTYPES_H=1
 336     fi
 337   fi
 338   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 339     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 340 #include <stdio.h>])
 341     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 342       SCM_I_GSC_NEEDS_INTTYPES_H=1
 343     fi
 344   fi
 345 fi
 346
 347 ### See what's provided by stdint.h
 348 if test "$ac_cv_header_stdint_h" = yes; then
 349    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 350    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 351    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 352    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 353    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 354    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 355    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 356    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 357    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 358    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 359 fi
 360
 361 # so we don't get confused by the cache (wish there was a better way
 362 # to check particular headers for the same type...)
 363
 364 unset ac_cv_type_int8_t
 365 unset ac_cv_type_uint8_t
 366 unset ac_cv_type_int16_t
 367 unset ac_cv_type_uint16_t
 368 unset ac_cv_type_int32_t
 369 unset ac_cv_type_uint32_t
 370 unset ac_cv_type_int64_t
 371 unset ac_cv_type_uint64_t
 372 unset ac_cv_type_intmax_t
 373 unset ac_cv_type_uintmax_t
 374
 375 ### See what's provided by inttypes.h
 376 if test "$ac_cv_header_inttypes_h" = yes; then
 377   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 378   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 379   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 380   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 381   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 382   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 383   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 384   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 385   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 386   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 387 fi
 388
 389 # Try hard to find definitions for some required scm_t_*int* types.
 390
 391 ### Required type scm_t_int8
 392 if test "$scm_stdint_has_int8"; then
 393   SCM_I_GSC_T_INT8='"int8_t"'
 394   SCM_I_GSC_NEEDS_STDINT_H=1
 395 elif test "$scm_inttypes_has_int8"; then
 396   SCM_I_GSC_T_INT8='"int8_t"'
 397   SCM_I_GSC_NEEDS_INTTYPES_H=1
 398 elif test "$ac_cv_sizeof_char" -eq 1; then
 399   SCM_I_GSC_T_INT8='"signed char"'
 400 else
 401   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 402 fi
 403 AC_SUBST([SCM_I_GSC_T_INT8])
 404
 405 ### Required type scm_t_uint8
 406 if test "$scm_stdint_has_uint8"; then
 407   SCM_I_GSC_T_UINT8='"uint8_t"'
 408   SCM_I_GSC_NEEDS_STDINT_H=1
 409 elif test "$scm_inttypes_has_uint8"; then
 410   SCM_I_GSC_T_UINT8='"uint8_t"'
 411   SCM_I_GSC_NEEDS_INTTYPES_H=1
 412 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 413   SCM_I_GSC_T_UINT8='"unsigned char"'
 414 else
 415   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 416 fi
 417 AC_SUBST([SCM_I_GSC_T_UINT8])
 418
 419 ### Required type scm_t_int16 (ANSI C says int or short might work)
 420 if test "$scm_stdint_has_int16"; then
 421   SCM_I_GSC_T_INT16='"int16_t"'
 422   SCM_I_GSC_NEEDS_STDINT_H=1
 423 elif test "$scm_inttypes_has_int16"; then
 424   SCM_I_GSC_T_INT16='"int16_t"'
 425   SCM_I_GSC_NEEDS_INTTYPES_H=1
 426 elif test "$ac_cv_sizeof_int" -eq 2; then
 427   SCM_I_GSC_T_INT16='"int"'
 428 elif test "$ac_cv_sizeof_short" -eq 2; then
 429   SCM_I_GSC_T_INT16='"short"'
 430 else
 431   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 432 fi
 433 AC_SUBST([SCM_I_GSC_T_INT16])
 434
 435 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 436 if test "$scm_stdint_has_uint16"; then
 437   SCM_I_GSC_T_UINT16='"uint16_t"'
 438   SCM_I_GSC_NEEDS_STDINT_H=1
 439 elif test "$scm_inttypes_has_uint16"; then
 440   SCM_I_GSC_T_UINT16='"uint16_t"'
 441   SCM_I_GSC_NEEDS_INTTYPES_H=1
 442 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 443   SCM_I_GSC_T_UINT16='"unsigned int"'
 444 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 445   SCM_I_GSC_T_UINT16='"unsigned short"'
 446 else
 447   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 448 fi
 449 AC_SUBST([SCM_I_GSC_T_UINT16])
 450
 451
 452 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 453 if test "$scm_stdint_has_int32"; then
 454   SCM_I_GSC_T_INT32='"int32_t"'
 455   SCM_I_GSC_NEEDS_STDINT_H=1
 456 elif test "$scm_inttypes_has_int32"; then
 457   SCM_I_GSC_T_INT32='"int32_t"'
 458   SCM_I_GSC_NEEDS_INTTYPES_H=1
 459 elif test "$ac_cv_sizeof_int" -eq 4; then
 460   SCM_I_GSC_T_INT32='"int"'
 461 elif test "$ac_cv_sizeof_long" -eq 4; then
 462   SCM_I_GSC_T_INT32='"long"'
 463 elif test "$ac_cv_sizeof_short" -eq 4; then
 464   SCM_I_GSC_T_INT32='"short"'
 465 else
 466   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 467 fi
 468 AC_SUBST([SCM_I_GSC_T_INT32])
 469
 470 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 471 if test "$scm_stdint_has_uint32"; then
 472   SCM_I_GSC_T_UINT32='"uint32_t"'
 473   SCM_I_GSC_NEEDS_STDINT_H=1
 474 elif test "$scm_inttypes_has_uint32"; then
 475   SCM_I_GSC_T_UINT32='"uint32_t"'
 476   SCM_I_GSC_NEEDS_INTTYPES_H=1
 477 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 478   SCM_I_GSC_T_UINT32='"unsigned int"'
 479 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 480   SCM_I_GSC_T_UINT32='"unsigned long"'
 481 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 482   SCM_I_GSC_T_UINT32='"unsigned short"'
 483 else
 484   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 485 fi
 486 AC_SUBST([SCM_I_GSC_T_UINT32])
 487
 488 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 489 ### Also try 'long long' and '__int64' if we have it.
 490 SCM_I_GSC_T_INT64=0
 491 if test "$scm_stdint_has_int64"; then
 492   SCM_I_GSC_T_INT64='"int64_t"'
 493   SCM_I_GSC_NEEDS_STDINT_H=1
 494 elif test "$scm_inttypes_has_int64"; then
 495   SCM_I_GSC_T_INT64='"int64_t"'
 496   SCM_I_GSC_NEEDS_INTTYPES_H=1
 497 elif test "$ac_cv_sizeof_int" -eq 8; then
 498   SCM_I_GSC_T_INT64='"int"'
 499 elif test "$ac_cv_sizeof_long" -eq 8; then
 500   SCM_I_GSC_T_INT64='"long"'
 501 elif test "$ac_cv_sizeof_short" -eq 8; then
 502   SCM_I_GSC_T_INT64='"short"'
 503 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 504   SCM_I_GSC_T_INT64='"long long"'
 505 elif test "$ac_cv_sizeof___int64" -eq 8; then
 506   SCM_I_GSC_T_INT64='"__int64"'
 507 else
 508   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 509 fi
 510 AC_SUBST([SCM_I_GSC_T_INT64])
 511
 512
 513 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 514 ### Also try 'long long' and '__int64' if we have it.
 515 SCM_I_GSC_T_UINT64=0
 516 if test "$scm_stdint_has_uint64"; then
 517   SCM_I_GSC_T_UINT64='"uint64_t"'
 518   SCM_I_GSC_NEEDS_STDINT_H=1
 519 elif test "$scm_inttypes_has_uint64"; then
 520   SCM_I_GSC_T_UINT64='"uint64_t"'
 521   SCM_I_GSC_NEEDS_INTTYPES_H=1
 522 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 523   SCM_I_GSC_T_UINT64='"unsigned int"'
 524 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 525   SCM_I_GSC_T_UINT64='"unsigned long"'
 526 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 527   SCM_I_GSC_T_UINT64='"unsigned short"'
 528 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 529   SCM_I_GSC_T_UINT64='"unsigned long long"'
 530 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 531   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 532 else
 533   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 534 fi
 535 AC_SUBST([SCM_I_GSC_T_UINT64])
 536
 537 ### Required type scm_t_intmax
 538 ###
 539 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 540 ### none of them is available, we use 'long'.
 541 ###
 542 SCM_I_GSC_T_INTMAX=0
 543 if test "$scm_stdint_has_intmax"; then
 544   SCM_I_GSC_T_INTMAX='"intmax_t"'
 545   SCM_I_GSC_NEEDS_STDINT_H=1
 546 elif test "$scm_inttypes_has_intmax"; then
 547   SCM_I_GSC_T_INTMAX='"intmax_t"'
 548   SCM_I_GSC_NEEDS_INTTYPES_H=1
 549 elif test "$ac_cv_sizeof___int64" -ne 0; then
 550   SCM_I_GSC_T_INTMAX='"__int64"'
 551 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 552   SCM_I_GSC_T_INTMAX='"long long"'
 553 else
 554   SCM_I_GSC_T_INTMAX='"long"'
 555 fi
 556 AC_SUBST([SCM_I_GSC_T_INTMAX])
 557
 558 ### Required type scm_t_uintmax
 559 ###
 560 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 561 ### this order.  When none of them is available, we use 'unsigned long'.
 562 ###
 563 SCM_I_GSC_T_UINTMAX=0
 564 if test "$scm_stdint_has_uintmax"; then
 565   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 566   SCM_I_GSC_NEEDS_STDINT_H=1
 567 elif test "$scm_inttypes_has_uintmax"; then
 568   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 569   SCM_I_GSC_NEEDS_INTTYPES_H=1
 570 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 571   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 572 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 573   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 574 else
 575   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 576 fi
 577 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 578
 579
 580 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 581 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 582
 583 AC_HEADER_STDC
 584 AC_HEADER_TIME
 585 AC_HEADER_SYS_WAIT
 586 AC_HEADER_DIRENT
 587
 588 # Reason for checking:
 589 #
 590 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 591 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 592 #
 593 AC_CHECK_MEMBER([struct dirent64.d_name],
 594   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 595   [ #ifndef _LARGEFILE64_SOURCE
 596     # define _LARGEFILE64_SOURCE
 597     #endif
 598
 599     /* Per Autoconf manual.  */
 600     #include <sys/types.h>
 601     #ifdef HAVE_DIRENT_H
 602     # include <dirent.h>
 603     #else
 604     # define dirent direct
 605     # ifdef HAVE_SYS_NDIR_H
 606     #  include <sys/ndir.h>
 607     # endif
 608     # ifdef HAVE_SYS_DIR_H
 609     #  include <sys/dir.h>
 610     # endif
 611     # ifdef HAVE_NDIR_H
 612     #  include <ndir.h>
 613     # endif
 614     #endif ])
 615 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 616
 617 # Reasons for testing:
 618 #   complex.h - new in C99
 619 #   fenv.h - available in C99, but not older systems
 620 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 621 #     this file instead of <fenv.h>
 622 #   process.h - mingw specific
 623 #   langinfo.h, nl_types.h - SuS v2
 624 #
 625 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 626 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 627 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 628 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 629 direct.h langinfo.h nl_types.h machine/fpu.h])
 630
 631 # "complex double" is new in C99, and "complex" is only a keyword if
 632 # <complex.h> is included
 633 AC_CHECK_TYPES(complex double,,,
 634 [#if HAVE_COMPLEX_H
 635 #include <complex.h>
 636 #endif])
 637
 638 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 639 # when testing.
 640 AC_CHECK_TYPE(socklen_t, ,
 641   [AC_DEFINE_UNQUOTED(socklen_t, int,
 642                       [Define to `int' if <sys/socket.h> does not define.])],
 643   [#if HAVE_SYS_TYPES_H
 644 #include <sys/types.h>
 645 #endif
 646 #include <sys/socket.h>
 647 ])
 648 AC_CHECK_TYPE(struct ip_mreq)
 649
 650 GUILE_HEADER_LIBC_WITH_UNISTD
 651
 652 AC_TYPE_GETGROUPS
 653 AC_TYPE_SIGNAL
 654 AC_TYPE_MODE_T
 655
 656 # On mingw -lm is empty, so this test is unnecessary, but it's
 657 # harmless so we don't hard-code to suppress it.
 658 #
 659 AC_CHECK_LIB(m, cos)
 660
 661 AC_CHECK_FUNCS(gethostbyname)
 662 if test $ac_cv_func_gethostbyname = no; then
 663     AC_CHECK_LIB(nsl, gethostbyname)
 664 fi
 665
 666 AC_CHECK_FUNCS(connect)
 667 if test $ac_cv_func_connect = no; then
 668     AC_CHECK_LIB(socket, connect)
 669 fi
 670
 671 dnl
 672 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 673 dnl
 674 EXTRA_DEFS=""
 675 case $host in
 676   *-*-mingw*)
 677     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 678       [Define if you have the <winsock2.h> header file.])])
 679     AC_CHECK_LIB(ws2_32, main)
 680     AC_LIBOBJ([win32-uname])
 681     AC_LIBOBJ([win32-dirent])
 682     if test "$enable_networking" = yes ; then
 683       AC_LIBOBJ([win32-socket])
 684     fi
 685     if test "$enable_shared" = yes ; then
 686       EXTRA_DEFS="-DSCM_IMPORT"
 687       AC_DEFINE(USE_DLL_IMPORT, 1,
 688         [Define if you need additional CPP macros on Win32 platforms.])
 689     fi
 690     ;;
 691 esac
 692 AC_SUBST(EXTRA_DEFS)
 693
 694 # Reasons for testing:
 695 #   crt_externs.h - Darwin specific
 696 #
 697 AC_CHECK_HEADERS([assert.h crt_externs.h])
 698
 699 # Reasons for testing:
 700 #   DINFINITY - OSF specific
 701 #   DQNAN - OSF specific
 702 #       (DINFINITY and DQNAN are actually global variables, not functions)
 703 #   chsize - an MS-DOS-ism, found in mingw
 704 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 705 #       for gcc to provide the "complex double" type but the system to not
 706 #       have functions like cexp and clog
 707 #   clog10 - not in mingw (though others like clog and csqrt are)
 708 #   fesetround - available in C99, but not older systems
 709 #   ftruncate - posix, but probably not older systems (current mingw
 710 #               has it as an inline for chsize)
 711 #   ioctl - not in mingw.
 712 #   gmtime_r - recent posix, not on old systems
 713 #   pipe - not in mingw
 714 #   _pipe - specific to mingw, taking 3 args
 715 #   readdir_r - recent posix, not on old systems
 716 #   readdir64_r - not available on HP-UX 11.11
 717 #   stat64 - SuS largefile stuff, not on old systems
 718 #   sysconf - not on old systems
 719 #   truncate - not in mingw
 720 #   isblank - available as a GNU extension or in C99
 721 #   _NSGetEnviron - Darwin specific
 722 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 723 #   nl_langinfo - X/Open, not available on Windows.
 724 #
 725 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo])
 726
 727 # Reasons for testing:
 728 #   netdb.h - not in mingw
 729 #   sys/param.h - not in mingw
 730 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 731 #       check this specifically, we need it for the timespec test below.
 732 #   sethostname - the function itself check because it's not in mingw,
 733 #       the DECL is checked because Solaris 10 doens't have in any header
 734 #   xlocale.h - needed on Darwin for the `locale_t' API
 735 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 736 #       declaration isn't anywhere.
 737 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 738 #       only with `_XOPEN_SOURCE' or some such.
 739 #
 740 AC_CHECK_HEADERS(crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h xlocale.h)
 741 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 742 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 743
 744 # crypt() may or may not be available, for instance in some countries there
 745 # are restrictions on cryptography.
 746 #
 747 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 748 # -lcrypt library (eg. Debian GNU/Linux).
 749 #
 750 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 751 # be careful to avoid -lcrypt in this case, since libtool will see there's
 752 # only a static libcrypt and decide to build only a static libguile.
 753 #
 754 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 755 # libraries already in that list.
 756 #
 757 AC_SEARCH_LIBS(crypt, crypt,
 758   [AC_DEFINE(HAVE_CRYPT,1,
 759              [Define to 1 if you have the `crypt' function.])])
 760
 761 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 762 # work; in the reported cases so far, 1.0fi works well instead.  According
 763 # to the C99 spec, the complex.h header must provide a working definition
 764 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 765 # is a workaround for the failure of some systems to conform to C99.
 766 if test "$ac_cv_type_complex_double" = yes; then
 767   AC_MSG_CHECKING([for i])
 768   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 769 #if HAVE_COMPLEX_H
 770 #include <complex.h>
 771 #endif
 772 complex double z;
 773 ]], [[
 774 z = _Complex_I;
 775 ]])],
 776     [AC_DEFINE(GUILE_I,_Complex_I,[The imaginary unit (positive square root of -1).])
 777      AC_MSG_RESULT([_Complex_I])],
 778     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 779 #if HAVE_COMPLEX_H
 780 #include <complex.h>
 781 #endif
 782 complex double z;
 783 ]],[[
 784 z = 1.0fi;
 785 ]])],
 786   [AC_DEFINE(GUILE_I,1.0fi)
 787    AC_MSG_RESULT([1.0fi])],
 788   [ac_cv_type_complex_double=no
 789    AC_MSG_RESULT([not available])])])
 790 fi
 791
 792 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 793 # csqrt(-i) returned a negative real part, when it should be positive
 794 # for the principal root.
 795 #
 796 if test "$ac_cv_type_complex_double" = yes; then
 797
 798   AC_CACHE_CHECK([whether csqrt is usable],
 799     guile_cv_use_csqrt,
 800     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 801 #include <complex.h>
 802 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 803    constant, we want to test libc. */
 804 volatile complex double z = - _Complex_I;
 805 int
 806 main (void)
 807 {
 808   z = csqrt (z);
 809   if (creal (z) > 0.0)
 810     return 0;  /* good */
 811   else
 812     return 1;  /* bad */
 813 }]])],
 814     [guile_cv_use_csqrt=yes],
 815     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 816     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 817   case $guile_cv_use_csqrt in
 818     yes*)
 819       AC_DEFINE(HAVE_USABLE_CSQRT, 1, [Define to 1 if csqrt is bug-free])
 820       ;;
 821   esac
 822 fi
 823
 824
 825 dnl GMP tests
 826 AC_LIB_HAVE_LINKFLAGS(gmp,
 827   [],
 828   [#include <gmp.h>],
 829   [mpz_import (0, 0, 0, 0, 0, 0, 0);],
 830   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README]))
 831
 832 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 833 if test "x$LTLIBUNISTRING" != "x"; then
 834   LIBS="$LTLIBUNISTRING $LIBS"
 835 else
 836   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 837 fi
 838
 839 dnl i18n tests
 840 #AC_CHECK_HEADERS([libintl.h])
 841 #AC_CHECK_FUNCS(gettext)
 842 #if test $ac_cv_func_gettext = no; then
 843 #   AC_CHECK_LIB(intl, gettext)
 844 #fi
 845 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 846 AM_GNU_GETTEXT([external], [need-ngettext])
 847
 848 ### Some systems don't declare some functions.  On such systems, we
 849 ### need to at least provide our own K&R-style declarations.
 850
 851 ### GUILE_FUNC_DECLARED(function, headerfile)
 852
 853 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 854 ### not there, #define MISSING_FUNCTION_DECL.
 855 AC_DEFUN([GUILE_FUNC_DECLARED], [
 856   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 857     AC_EGREP_HEADER($1, $2,
 858                     guile_cv_func_$1_declared=yes,
 859                     guile_cv_func_$1_declared=no))
 860   if test [x$guile_cv_func_]$1[_declared] = xno; then
 861     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 862       [Define if the operating system supplies $1 without declaring it.])
 863   fi
 864 ])
 865
 866 GUILE_FUNC_DECLARED(sleep, unistd.h)
 867 GUILE_FUNC_DECLARED(usleep, unistd.h)
 868
 869 AC_CHECK_DECLS([strptime],,,
 870 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 871 #include <time.h>])
 872
 873 ### On some systems usleep has no return value.  If it does have one,
 874 ### we'd like to return it; otherwise, we'll fake it.
 875 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 876   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 877                    unistd.h,
 878                    [guile_cv_func_usleep_return_type=void],
 879                    [guile_cv_func_usleep_return_type=int])])
 880 case "$guile_cv_func_usleep_return_type" in
 881   "void" )
 882     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 883       [Define if the system headers declare usleep to return void.])
 884   ;;
 885 esac
 886
 887 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 888 if test -n "$have_sys_un_h" ; then
 889   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 890     [Define if the system supports Unix-domain (file-domain) sockets.])
 891 fi
 892
 893 AC_CHECK_FUNCS(getrlimit setrlimit)
 894
 895 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 896
 897 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 898                setnetent    getnetent    endnetent    dnl
 899                setprotoent  getprotoent  endprotoent  dnl
 900                setservent   getservent   endservent   dnl
 901                getnetbyaddr getnetbyname dnl
 902                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 903                inet_pton inet_ntop)
 904
 905 # struct sockaddr field sin_len is only present on BSD systems.
 906 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 907 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 908 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 909 [#ifdef HAVE_SYS_TYPES_H
 910 #include <sys/types.h>
 911 #endif
 912 #include <netinet/in.h>])
 913
 914 AC_MSG_CHECKING(for __libc_stack_end)
 915 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 916 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 917 extern char *__libc_stack_end;]],
 918    [[printf("%p", (char*) __libc_stack_end);]])],
 919    [guile_cv_have_libc_stack_end=yes],
 920    [guile_cv_have_libc_stack_end=no])])
 921 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 922
 923 if test $guile_cv_have_libc_stack_end = yes; then
 924   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 925            [Define if you have the __libc_stack_end variable.])
 926 fi
 927
 928 dnl Some systems do not declare this.  Some systems do declare it, as a
 929 dnl macro.  With cygwin it may be in a DLL.
 930
 931 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 932 AC_CACHE_VAL(guile_cv_have_h_errno,
 933   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 934                                       [[int a = h_errno;]])],
 935   [guile_cv_have_h_errno=yes],
 936   [guile_cv_have_h_errno=no])])
 937 AC_MSG_RESULT($guile_cv_have_h_errno)
 938 if test $guile_cv_have_h_errno = yes; then
 939   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 940 fi
 941
 942 AC_MSG_CHECKING(whether uint32_t is defined)
 943 AC_CACHE_VAL(guile_cv_have_uint32_t,
 944   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 945                    #if HAVE_STDINT_H
 946                    #include <stdint.h>
 947                    #endif
 948                    #ifndef HAVE_NETDB_H
 949                    #include <netdb.h>
 950                    #endif]],
 951                    [[uint32_t a;]])],
 952                    [guile_cv_have_uint32_t=yes],
 953                    [guile_cv_have_uint32_t=no])])
 954 AC_MSG_RESULT($guile_cv_have_uint32_t)
 955 if test $guile_cv_have_uint32_t = yes; then
 956   AC_DEFINE(HAVE_UINT32_T, 1,
 957     [Define if uint32_t typedef is defined when netdb.h is include.])
 958 fi
 959
 960 AC_MSG_CHECKING(for working IPv6 support)
 961 AC_CACHE_VAL(guile_cv_have_ipv6,
 962 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 963 #ifdef HAVE_SYS_TYPES_H
 964 #include <sys/types.h>
 965 #endif
 966 #include <netinet/in.h>
 967 #include <sys/socket.h>]],
 968 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
 969 [guile_cv_have_ipv6=yes],
 970 [guile_cv_have_ipv6=no])])
 971 AC_MSG_RESULT($guile_cv_have_ipv6)
 972 if test $guile_cv_have_ipv6 = yes; then
 973   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 974 fi
 975
 976 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 977 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 978 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 979 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 980 #ifdef HAVE_SYS_TYPES_H
 981 #include <sys/types.h>
 982 #endif
 983 #include <netinet/in.h>]],
 984 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
 985 [guile_cv_have_sin6_scope_id=yes],
 986 [guile_cv_have_sin6_scope_id=no])])
 987 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 988 if test $guile_cv_have_sin6_scope_id = yes; then
 989   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 990     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 991 fi
 992
 993 # struct sockaddr_in6 field sin_len is only present on BSD systems
 994 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 995 [#ifdef HAVE_SYS_TYPES_H
 996 #include <sys/types.h>
 997 #endif
 998 #include <netinet/in.h>])
 999
1000 AC_MSG_CHECKING(whether localtime caches TZ)
1001 AC_CACHE_VAL(guile_cv_localtime_cache,
1002 [if test x$ac_cv_func_tzset = xyes; then
1003 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1004 #if STDC_HEADERS
1005 # include <stdlib.h>
1006 #endif
1007 extern char **environ;
1008 unset_TZ ()
1009 {
1010   char **from, **to;
1011   for (to = from = environ; (*to = *from); from++)
1012     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1013       to++;
1014 }
1015 char TZ_GMT0[] = "TZ=GMT0";
1016 char TZ_PST8[] = "TZ=PST8";
1017 main()
1018 {
1019   time_t now = time ((time_t *) 0);
1020   int hour_GMT0, hour_unset;
1021   if (putenv (TZ_GMT0) != 0)
1022     exit (1);
1023   hour_GMT0 = localtime (&now)->tm_hour;
1024   unset_TZ ();
1025   hour_unset = localtime (&now)->tm_hour;
1026   if (putenv (TZ_PST8) != 0)
1027     exit (1);
1028   if (localtime (&now)->tm_hour == hour_GMT0)
1029     exit (1);
1030   unset_TZ ();
1031   if (localtime (&now)->tm_hour != hour_unset)
1032     exit (1);
1033   exit (0);
1034 }]])],
1035 [guile_cv_localtime_cache=no],
1036 [guile_cv_localtime_cache=yes],
1037 [# If we have tzset, assume the worst when cross-compiling.
1038 guile_cv_localtime_cache=yes])
1039 else
1040         # If we lack tzset, report that localtime does not cache TZ,
1041         # since we can't invalidate the cache if we don't have tzset.
1042         guile_cv_localtime_cache=no
1043 fi])dnl
1044 AC_MSG_RESULT($guile_cv_localtime_cache)
1045 if test $guile_cv_localtime_cache = yes; then
1046   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
1047 fi
1048
1049 if test "$enable_regex" = yes; then
1050    if test "$ac_cv_header_regex_h" = yes ||
1051       test "$ac_cv_header_rxposix_h" = yes ||
1052       test "$ac_cv_header_rx_rxposix_h" = yes; then
1053      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1054      [AC_CHECK_LIB(rx, main)
1055       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1056      [AC_CHECK_LIB(regex, main)
1057       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1058      )
1059      dnl The following should not be necessary, but for some reason
1060      dnl autoheader misses it if we don't include it!
1061      if test "$ac_cv_func_regcomp_norx" = yes ||
1062         test "$ac_cv_func_regcomp_regex" = yes ||
1063         test "$ac_cv_func_regcomp_rx" = yes; then
1064        AC_DEFINE(HAVE_REGCOMP, 1,
1065          [This is included as part of a workaround for a autoheader bug.])
1066      fi
1067    fi
1068 fi
1069
1070 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
1071
1072 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
1073
1074 # Reasons for testing:
1075 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1076 #                                older systems
1077 #   sincos - GLIBC extension
1078 #
1079 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1080
1081 # C99 specifies isinf and isnan as macros.
1082 # HP-UX provides only macros, no functions.
1083 # glibc 2.3.2 provides both macros and functions.
1084 # IRIX 6.5 and Solaris 8 only provide functions.
1085 #
1086 # The following tests detect isinf and isnan either as functions or as
1087 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1088 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1089 #
1090 AC_MSG_CHECKING([for isinf])
1091 AC_LINK_IFELSE(AC_LANG_SOURCE(
1092 [[#include <math.h>
1093 volatile double x = 0.0;
1094 int main () { return (isinf(x) != 0); }]]),
1095   [AC_MSG_RESULT([yes])
1096    AC_DEFINE(HAVE_ISINF, 1,
1097              [Define to 1 if you have the `isinf' macro or function.])],
1098   [AC_MSG_RESULT([no])])
1099 AC_MSG_CHECKING([for isnan])
1100 AC_LINK_IFELSE(AC_LANG_SOURCE(
1101 [[#include <math.h>
1102 volatile double x = 0.0;
1103 int main () { return (isnan(x) != 0); }]]),
1104   [AC_MSG_RESULT([yes])
1105    AC_DEFINE(HAVE_ISNAN, 1,
1106              [Define to 1 if you have the `isnan' macro or function.])],
1107   [AC_MSG_RESULT([no])])
1108
1109 # Reasons for checking:
1110 #
1111 #     st_rdev
1112 #     st_blksize
1113 #     st_blocks   not in mingw
1114 #     tm_gmtoff   BSD+GNU, not in C99
1115 #
1116 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1117 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1118 #
1119 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks])
1120
1121 AC_STRUCT_TIMEZONE
1122 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1123 [#include <time.h>
1124 #ifdef TIME_WITH_SYS_TIME
1125 # include <sys/time.h>
1126 # include <time.h>
1127 #else
1128 # if HAVE_SYS_TIME_H
1129 #  include <sys/time.h>
1130 # else
1131 #  include <time.h>
1132 # endif
1133 #endif
1134 ])
1135 GUILE_STRUCT_UTIMBUF
1136
1137
1138 #--------------------------------------------------------------------
1139 #
1140 # Which way does the stack grow?
1141 #
1142 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1143 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1144 # very similar code, so in future we could look at using that.
1145 #
1146 # An important detail is that the code involves find_stack_direction
1147 # calling _itself_ - which means that find_stack_direction (or at
1148 # least the second find_stack_direction() call) cannot be inlined.
1149 # If the code could be inlined, that might cause the test to give
1150 # an incorrect answer.
1151 #--------------------------------------------------------------------
1152
1153 SCM_I_GSC_STACK_GROWS_UP=0
1154 AC_RUN_IFELSE([AC_LANG_SOURCE(
1155 [AC_INCLUDES_DEFAULT
1156 int
1157 find_stack_direction ()
1158 {
1159   static char *addr = 0;
1160   auto char dummy;
1161   if (addr == 0)
1162     {
1163       addr = &dummy;
1164       return find_stack_direction ();
1165     }
1166   else
1167     return (&dummy > addr) ? 1 : -1;
1168 }
1169
1170 int
1171 main ()
1172 {
1173   return find_stack_direction () < 0;
1174 }])],
1175                [SCM_I_GSC_STACK_GROWS_UP=1],
1176                [],
1177                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1178
1179 #--------------------------------------------------------------------
1180 #
1181 # Boehm's GC library
1182 #
1183 #--------------------------------------------------------------------
1184 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1185
1186 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1187 LIBS="$BDW_GC_LIBS $LIBS"
1188
1189 # `GC_do_blocking ()' is available in GC 7.1 but not declared.
1190 AC_CHECK_FUNCS([GC_do_blocking])
1191 AC_CHECK_DECL([GC_do_blocking],
1192   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1193     [Define this if the `GC_do_blocking ()' function is declared])],
1194   [],
1195   [#include <gc/gc.h>])
1196
1197 # `GC_fn_type' is not available in GC 7.1 and earlier.
1198 AC_CHECK_TYPE([GC_fn_type],
1199   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1200     [Define this if the `GC_fn_type' type is available.])],
1201   [],
1202   [#include <gc/gc.h>])
1203
1204
1205 AC_CHECK_SIZEOF(float)
1206 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1207     AC_DEFINE(SCM_SINGLES, 1,
1208               [Define this if floats are the same size as longs.])
1209 fi
1210
1211 AC_MSG_CHECKING(for struct linger)
1212 AC_CACHE_VAL(scm_cv_struct_linger,
1213         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1214 #include <sys/types.h>
1215 #include <sys/socket.h>]],
1216                           [[struct linger lgr;  lgr.l_linger = 100]])],
1217                           [scm_cv_struct_linger="yes"],
1218                           [scm_cv_struct_linger="no"]))
1219 AC_MSG_RESULT($scm_cv_struct_linger)
1220 if test $scm_cv_struct_linger = yes; then
1221         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
1222           [Define this if your system defines struct linger, for use with the
1223            getsockopt and setsockopt system calls.])
1224 fi
1225
1226
1227 # On mingw, struct timespec is in <pthread.h>.
1228 #
1229 AC_MSG_CHECKING(for struct timespec)
1230 AC_CACHE_VAL(scm_cv_struct_timespec,
1231         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1232 #include <time.h>
1233 #if HAVE_PTHREAD_H
1234 #include <pthread.h>
1235 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1236           [scm_cv_struct_timespec="yes"],
1237           [scm_cv_struct_timespec="no"]))
1238 AC_MSG_RESULT($scm_cv_struct_timespec)
1239 if test $scm_cv_struct_timespec = yes; then
1240   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
1241     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1242 fi
1243
1244 #--------------------------------------------------------------------
1245 #
1246 # Flags for thread support
1247 #
1248 #--------------------------------------------------------------------
1249
1250 SCM_I_GSC_USE_PTHREAD_THREADS=0
1251 SCM_I_GSC_USE_NULL_THREADS=0
1252 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1253 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1254
1255 ### What thread package has the user asked for?
1256 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1257             , with_threads=yes)
1258
1259 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1260 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1261
1262 case "$with_threads" in
1263   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1264
1265     build_pthread_support="yes"
1266
1267     ACX_PTHREAD([CC="$PTHREAD_CC"
1268        LIBS="$PTHREAD_LIBS $LIBS"
1269        SCM_I_GSC_USE_PTHREAD_THREADS=1
1270        with_threads="pthreads"],
1271       [with_threads="null"
1272        build_pthread_support="no"])
1273
1274     old_CFLAGS="$CFLAGS"
1275     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1276
1277     # Reasons for testing:
1278     #     pthread_getattr_np - "np" meaning "non portable" says it
1279     #         all; not present on MacOS X or Solaris 10
1280     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1281     #         all; specific to MacOS X
1282     #     pthread_sigmask - not available on mingw
1283     #
1284     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1285
1286     # On past versions of Solaris, believe 8 through 10 at least, you
1287     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1288     # This is contrary to POSIX:
1289     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1290     # Check here if this style is required.
1291     #
1292     # glibc (2.3.6 at least) works both with or without braces, so the
1293     # test checks whether it works without.
1294     #
1295
1296     if test "$GCC" = "yes"; then
1297       # Since GCC only issues a warning for missing braces, so we need
1298       # `-Werror' to catch it.
1299       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1300     fi
1301
1302     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1303       guile_cv_need_braces_on_pthread_once_init,
1304       [AC_COMPILE_IFELSE([#include <pthread.h>
1305          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1306         [guile_cv_need_braces_on_pthread_once_init=no],
1307         [guile_cv_need_braces_on_pthread_once_init=yes])])
1308     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1309       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1310     fi
1311
1312     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1313     # 6.5.30m with GCC 3.3.
1314     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1315       guile_cv_need_braces_on_pthread_mutex_initializer,
1316       [AC_COMPILE_IFELSE([#include <pthread.h>
1317          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1318         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1319         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1320     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1321       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1322     fi
1323
1324     CFLAGS="$old_CFLAGS"
1325
1326     # On Solaris, sched_yield lives in -lrt.
1327     AC_SEARCH_LIBS(sched_yield, rt)
1328
1329   ;;
1330 esac
1331
1332 case "$with_threads" in
1333   "pthreads")
1334   ;;
1335   "no" | "null")
1336     SCM_I_GSC_USE_NULL_THREADS=1
1337     with_threads="null-threads"
1338   ;;
1339   * )
1340     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1341   ;;
1342 esac
1343
1344 AC_MSG_CHECKING(what kind of threads to support)
1345 AC_MSG_RESULT($with_threads)
1346
1347 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1348   [test "x$build_pthread_support" = "xyes"])
1349
1350
1351 ## Check whether pthread_attr_getstack works for the main thread
1352
1353 if test "$with_threads" = pthreads; then
1354
1355 AC_MSG_CHECKING(whether pthread_attr_getstack works for the main thread)
1356 old_CFLAGS="$CFLAGS"
1357 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1358 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1359 #if HAVE_PTHREAD_ATTR_GETSTACK
1360 #include <pthread.h>
1361
1362 int main ()
1363 {
1364   pthread_attr_t attr;
1365   void *start, *end;
1366   size_t size;
1367
1368   pthread_getattr_np (pthread_self (), &attr);
1369   pthread_attr_getstack (&attr, &start, &size);
1370   end = (char *)start + size;
1371
1372   if ((void *)&attr < start || (void *)&attr >= end)
1373     return 1;
1374   else
1375     return 0;
1376 }
1377 #else
1378 int main ()
1379 {
1380   return 1;
1381 }
1382 #endif
1383 ]])],
1384 [works=yes
1385 AC_DEFINE(PTHREAD_ATTR_GETSTACK_WORKS, [1], [Define when pthread_att_get_stack works for the main thread])],
1386 [works=no],
1387 [])
1388 CFLAGS="$old_CFLAGS"
1389 AC_MSG_RESULT($works)
1390
1391 GUILE_THREAD_LOCAL_STORAGE
1392
1393 fi # with_threads=pthreads
1394
1395
1396 ## Cross building
1397 if test "$cross_compiling" = "yes"; then
1398   AC_MSG_CHECKING(cc for build)
1399   ## /usr/bin/cc still uses wrong assembler
1400   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1401   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1402 else
1403   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1404 fi
1405
1406 ## AC_MSG_CHECKING("if we are cross compiling")
1407 ## AC_MSG_RESULT($cross_compiling)
1408 if test "$cross_compiling" = "yes"; then
1409    AC_MSG_RESULT($CC_FOR_BUILD)
1410 fi
1411
1412 ## No need as yet to be more elaborate
1413 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1414
1415 AC_SUBST(cross_compiling)
1416 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1417 AC_SUBST(CCLD_FOR_BUILD)
1418
1419 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1420 ## --HOST is the platform that PACKAGE is compiled for.
1421 HOST_CC="$CC_FOR_BUILD"
1422 AC_SUBST(HOST_CC)
1423
1424 if test "$cross_compiling" = "yes"; then
1425   AC_MSG_CHECKING(guile for build)
1426   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1427 else
1428   GUILE_FOR_BUILD='$(preinstguile)'
1429 fi
1430
1431 ## AC_MSG_CHECKING("if we are cross compiling")
1432 ## AC_MSG_RESULT($cross_compiling)
1433 if test "$cross_compiling" = "yes"; then
1434    AC_MSG_RESULT($GUILE_FOR_BUILD)
1435 fi
1436 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1437 AC_SUBST(GUILE_FOR_BUILD)
1438
1439 ## If we're using GCC, ask for aggressive warnings.
1440 case "$GCC" in
1441   yes )
1442     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1443     ## much stuff with generic function pointers for that to really be
1444     ## less than exasperating.
1445     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1446     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1447     GCC_CFLAGS="-Wall -Wmissing-prototypes"
1448     # Do this here so we don't screw up any of the tests above that might
1449     # not be "warning free"
1450     if test "${GUILE_ERROR_ON_WARNING}" = yes
1451     then
1452         GCC_CFLAGS="${GCC_CFLAGS} -Werror"
1453         enable_compile_warnings=no
1454     fi
1455     ;;
1456 esac
1457
1458 AC_SUBST(GCC_CFLAGS)
1459
1460 # Check for GNU ld's "-z relro".
1461 GUILE_GNU_LD_RELRO
1462
1463
1464 ## If we're creating a shared library (using libtool!), then we'll
1465 ## need to generate a list of .lo files corresponding to the .o files
1466 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1467 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1468
1469 ## We also need to create corresponding .doc and .x files
1470 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1471 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1472
1473 # GNU Readline bindings.
1474 GUILE_READLINE
1475
1476 AC_SUBST(GUILE_MAJOR_VERSION)
1477 AC_SUBST(GUILE_MINOR_VERSION)
1478 AC_SUBST(GUILE_MICRO_VERSION)
1479 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1480 AC_SUBST(GUILE_VERSION)
1481
1482 #######################################################################
1483 # library versioning
1484
1485 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1486 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1487 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1488 AC_SUBST(LIBGUILE_INTERFACE)
1489
1490 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1491 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1492 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1493 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1494 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1495
1496 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1497 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1498 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1499 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1500 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1501
1502 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1503 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1504 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1505 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1506 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1507
1508 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1509 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1510 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1511 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1512 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1513
1514 AC_SUBST(LIBGUILE_I18N_MAJOR)
1515 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1516 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1517 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1518 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1519
1520
1521 #######################################################################
1522
1523 dnl Tell guile-config what flags guile users should compile and link with.
1524 GUILE_LIBS="$LDFLAGS $LIBS"
1525 GUILE_CFLAGS="$CPPFLAGS $PTHREAD_CFLAGS"
1526 AC_SUBST(GUILE_LIBS)
1527 AC_SUBST(GUILE_CFLAGS)
1528
1529 AC_SUBST(AWK)
1530 AC_SUBST(LIBLOBJS)
1531 AC_SUBST(EXTRA_DOT_DOC_FILES)
1532 AC_SUBST(EXTRA_DOT_X_FILES)
1533
1534 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1535 top_builddir_absolute=`pwd`
1536 AC_SUBST(top_builddir_absolute)
1537 top_srcdir_absolute=`(cd $srcdir && pwd)`
1538 AC_SUBST(top_srcdir_absolute)
1539
1540 dnl We need `sitedir' in `guile-1.8.pc'.
1541 dnl Note: `sitedir' must be kept in sync with `GUILE_SITE_DIR' in `guile.m4'.
1542 pkgdatadir="$datadir/guile"
1543 sitedir="$pkgdatadir/site"
1544 AC_SUBST([sitedir])
1545
1546 # Additional SCM_I_GSC definitions are above.
1547 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1548 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1549 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1550 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1551 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1552 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1553 AC_SUBST([SCM_I_GSC_C_INLINE])
1554 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1555
1556 AC_CONFIG_FILES([
1557   Makefile
1558   am/Makefile
1559   lib/Makefile
1560   benchmark-suite/Makefile
1561   doc/Makefile
1562   doc/r5rs/Makefile
1563   doc/ref/Makefile
1564   doc/tutorial/Makefile
1565   emacs/Makefile
1566   examples/Makefile
1567   lang/Makefile
1568   libguile/Makefile
1569   srfi/Makefile
1570   guile-readline/Makefile
1571   test-suite/Makefile
1572   test-suite/standalone/Makefile
1573   meta/Makefile
1574   module/Makefile
1575   testsuite/Makefile
1576 ])
1577
1578 AC_CONFIG_FILES([meta/guile-2.0.pc])
1579 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1580 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1581 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1582 AC_CONFIG_FILES([meta/guile], [chmod +x meta/guile])
1583 AC_CONFIG_FILES([meta/uninstalled-env], [chmod +x meta/uninstalled-env])
1584 AC_CONFIG_FILES([meta/gdb-uninstalled-guile], [chmod +x meta/gdb-uninstalled-guile])
1585 AC_CONFIG_FILES([meta/guile-tools], [chmod +x meta/guile-tools])
1586 AC_CONFIG_FILES([libguile/guile-snarf],
1587                 [chmod +x libguile/guile-snarf])
1588 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1589                 [chmod +x libguile/guile-doc-snarf])
1590 AC_CONFIG_FILES([libguile/guile-func-name-check],
1591                 [chmod +x libguile/guile-func-name-check])
1592 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1593                 [chmod +x libguile/guile-snarf-docs])
1594 AC_CONFIG_FILES([test-suite/standalone/test-use-srfi],
1595                 [chmod +x test-suite/standalone/test-use-srfi])
1596 AC_CONFIG_FILES([test-suite/standalone/test-fast-slot-ref],
1597                 [chmod +x test-suite/standalone/test-fast-slot-ref])
1598 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1599
1600 AC_OUTPUT
1601
1602 dnl Local Variables:
1603 dnl comment-start: "dnl "
1604 dnl comment-end: ""
1605 dnl comment-start-skip: "\\bdnl\\b\\s *"
1606 dnl End: