configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # Independent Subdirectories
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_CONFIG_SUBDIRS(guile-readline)
  36
  37 #--------------------------------------------------------------------
  38 #
  39 # User options
  40 #
  41 #--------------------------------------------------------------------
  42
  43 AC_ARG_ENABLE(debug-freelist,
  44   [  --enable-debug-freelist include garbage collector freelist debugging code],
  45   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  46     AC_DEFINE(GUILE_DEBUG_FREELIST)
  47   fi)
  48
  49 AC_ARG_ENABLE(debug-malloc,
  50   [  --enable-debug-malloc   include malloc debugging code],
  51   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  52     AC_DEFINE(GUILE_DEBUG_MALLOC)
  53   fi)
  54
  55 AC_ARG_ENABLE(guile-debug,
  56   [  --enable-guile-debug    include internal debugging functions],
  57   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  58     AC_DEFINE(GUILE_DEBUG)
  59   fi)
  60
  61 AC_ARG_ENABLE(arrays,
  62   [  --disable-arrays        omit array and uniform array support],,
  63   enable_arrays=yes)
  64
  65 AC_ARG_ENABLE(posix,
  66   [  --disable-posix         omit posix interfaces],,
  67   enable_posix=yes)
  68
  69 AC_ARG_ENABLE(networking,
  70   [  --disable-networking    omit networking interfaces],,
  71   enable_networking=yes)
  72
  73 AC_ARG_ENABLE(regex,
  74   [  --disable-regex         omit regular expression interfaces],,
  75   enable_regex=yes)
  76
  77 AC_ARG_ENABLE(htmldoc,
  78   [  --enable-htmldoc        build HTML documentation as well as Info],
  79   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  80      htmldoc_enabled=yes
  81      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  82      if test "$TEXI2HTML" = "not found"; then
  83        echo
  84        echo Building HTML documentation requires the \`texi2html\' program,
  85        echo which appears not to be present on your machine.
  86        echo
  87        echo \`texi2html\' is available from
  88        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
  89        echo
  90        echo In the meantime, to build the guile-doc distribution
  91        echo without HTML enabled, please rerun \`./configure\' without
  92        echo the \`--enable-htmldoc\' option.
  93        exit -1
  94      fi
  95    fi])
  96
  97 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
  98
  99 AC_ARG_ENABLE(deprecated,
 100   [  --disable-deprecated    omit deprecated features [no]])
 101
 102 if test "$enable_deprecated" = no; then
 103   AC_DEFINE(SCM_DEBUG_DEPRECATED)
 104 else
 105   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 106     enable_deprecated=summary
 107   fi
 108   AC_DEFINE_UNQUOTED(GUILE_WARN_DEPRECATED_DEFAULT, "$enable_deprecated")
 109 fi
 110
 111 dnl The --disable-debug used to control these two.  But now they are
 112 dnl a required part of the distribution.
 113 AC_DEFINE(DEBUG_EXTENSIONS)
 114 AC_DEFINE(READER_EXTENSIONS)
 115
 116 dnl files which are destined for separate modules.
 117
 118 if test "$enable_arrays" = yes; then
 119    LIBOBJS="$LIBOBJS ramap.o unif.o"
 120    AC_DEFINE(HAVE_ARRAYS)
 121 fi
 122
 123 if test "$enable_posix" = yes; then
 124    LIBOBJS="$LIBOBJS filesys.o posix.o"
 125    AC_DEFINE(HAVE_POSIX)
 126 fi
 127
 128 if test "$enable_networking" = yes; then
 129    LIBOBJS="$LIBOBJS net_db.o socket.o"
 130    AC_DEFINE(HAVE_NETWORKING)
 131 fi
 132
 133 if test "$enable_debug_malloc" = yes; then
 134    LIBOBJS="$LIBOBJS debug-malloc.o"
 135 fi
 136
 137 #--------------------------------------------------------------------
 138
 139 AC_LIBLTDL_CONVENIENCE
 140 AC_CONFIG_SUBDIRS(libltdl)
 141
 142 AC_PROG_CC
 143 AC_PROG_CPP
 144 AC_LIBTOOL_DLOPEN
 145
 146 AC_AIX
 147 AC_ISC_POSIX
 148 AC_MINIX
 149
 150 AM_PROG_CC_STDC
 151 AM_PROG_LIBTOOL
 152
 153 AC_C_CONST
 154 AC_C_INLINE
 155 AC_C_BIGENDIAN
 156
 157 AC_CHECK_SIZEOF(int)
 158 AC_CHECK_SIZEOF(long)
 159 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 160                AC_TRY_COMPILE(,
 161                               [long long a],
 162                               scm_cv_long_longs=yes,
 163                               scm_cv_long_longs=no))
 164 if test "$scm_cv_long_longs" = yes; then
 165   AC_DEFINE(HAVE_LONG_LONGS)
 166 fi
 167
 168 AC_HEADER_STDC
 169 AC_HEADER_DIRENT
 170 AC_HEADER_TIME
 171 AC_HEADER_SYS_WAIT
 172 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
 173 GUILE_HEADER_LIBC_WITH_UNISTD
 174
 175 AC_TYPE_GETGROUPS
 176 AC_TYPE_SIGNAL
 177 AC_TYPE_MODE_T
 178
 179 AC_CHECK_LIB(m, main)
 180 AC_CHECK_FUNCS(gethostbyname)
 181 if test $ac_cv_func_gethostbyname = no; then
 182     AC_CHECK_LIB(nsl, gethostbyname)
 183 fi
 184 AC_CHECK_FUNCS(connect)
 185 if test $ac_cv_func_connect = no; then
 186     AC_CHECK_LIB(socket, connect)
 187 fi
 188
 189 # Check for dynamic linking
 190
 191 use_modules=yes
 192 AC_ARG_WITH(modules,
 193 [  --with-modules[=FILES]  Add support for dynamic modules],
 194 use_modules="$withval")
 195 test -z "$use_modules" && use_modules=yes
 196 DLPREOPEN=
 197 if test "$use_modules" != no; then
 198   AC_DEFINE(DYNAMIC_LINKING)
 199   if test "$use_modules" = yes; then
 200     DLPREOPEN="-dlpreopen force"
 201   else
 202     DLPREOPEN="-export-dynamic"
 203     for module in $use_modules; do
 204       DLPREOPEN="$DLPREOPEN -dlopen $module"
 205     done
 206   fi
 207 fi
 208 AC_SUBST(INCLTDL)
 209 AC_SUBST(LIBLTDL)
 210 AC_SUBST(DLPREOPEN)
 211
 212 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit)
 213
 214 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 215 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 216 AC_CHECK_LIB(crypt, crypt)
 217
 218 ### Some systems don't declare some functions.  On such systems, we
 219 ### need to at least provide our own K&R-style declarations.
 220
 221 ### GUILE_FUNC_DECLARED(function, headerfile)
 222
 223 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 224 ### not there, #define MISSING_FUNCTION_DECL.
 225 AC_DEFUN(GUILE_FUNC_DECLARED, [
 226   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 227     AC_EGREP_HEADER($1, $2,
 228                     guile_cv_func_$1_declared=yes,
 229                     guile_cv_func_$1_declared=no))
 230   if test [x$guile_cv_func_]$1[_declared] = xno; then
 231     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 232   fi
 233 ])
 234
 235 GUILE_FUNC_DECLARED(strptime, time.h)
 236 GUILE_FUNC_DECLARED(sleep, unistd.h)
 237 GUILE_FUNC_DECLARED(usleep, unistd.h)
 238
 239 ### On some systems usleep has no return value.  If it does have one,
 240 ### we'd like to return it; otherwise, we'll fake it.
 241 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 242   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 243                    /usr/include/unistd.h,
 244                    [guile_cv_func_usleep_return_type=void],
 245                    [guile_cv_func_usleep_return_type=int])])
 246 case "$guile_cv_func_usleep_return_type" in
 247   "void" )
 248     AC_DEFINE(USLEEP_RETURNS_VOID)
 249   ;;
 250 esac
 251
 252 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 253 if test -n "$have_sys_un_h" ; then
 254 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 255 fi
 256
 257 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 258
 259 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 260                setnetent    getnetent    endnetent    dnl
 261                setprotoent  getprotoent  endprotoent  dnl
 262                setservent   getservent   endservent   dnl
 263                getnetbyaddr getnetbyname dnl
 264                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 265                inet_pton inet_ntop)
 266
 267 dnl Some systems do not declare this.  Some systems do declare it, as a
 268 dnl macro.  With cygwin it may be in a DLL.
 269
 270 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 271 AC_CACHE_VAL(guile_cv_have_h_errno,
 272 [AC_TRY_COMPILE([#include <netdb.h>],
 273 [int a = h_errno;],
 274 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 275 AC_MSG_RESULT($guile_cv_have_h_errno)
 276 if test $guile_cv_have_h_errno = yes; then
 277   AC_DEFINE(HAVE_H_ERRNO)
 278 fi
 279
 280 AC_MSG_CHECKING(whether netdb.h defines uint32_t)
 281 AC_CACHE_VAL(guile_cv_have_uint32_t,
 282 [AC_TRY_COMPILE([#include <netdb.h>],
 283 [uint32_t a;],
 284 guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 285 AC_MSG_RESULT($guile_cv_have_uint32_t)
 286 if test $guile_cv_have_uint32_t = yes; then
 287   AC_DEFINE(HAVE_UINT32_T)
 288 fi
 289
 290 AC_MSG_CHECKING(for working IPv6 support)
 291 AC_CACHE_VAL(guile_cv_have_ipv6,
 292 [AC_TRY_COMPILE([#include <netinet/in.h>],
 293 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 294 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 295 AC_MSG_RESULT($guile_cv_have_ipv6)
 296 if test $guile_cv_have_ipv6 = yes; then
 297   AC_DEFINE(HAVE_IPV6)
 298 fi
 299
 300 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 301 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 302 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 303 [AC_TRY_COMPILE([#include <netinet/in.h>],
 304 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 305 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 306 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 307 if test $guile_cv_have_sin6_scope_id = yes; then
 308   AC_DEFINE(HAVE_SIN6_SCOPE_ID)
 309 fi
 310
 311 AC_MSG_CHECKING(whether localtime caches TZ)
 312 AC_CACHE_VAL(guile_cv_localtime_cache,
 313 [if test x$ac_cv_func_tzset = xyes; then
 314 AC_TRY_RUN([#include <time.h>
 315 #if STDC_HEADERS
 316 # include <stdlib.h>
 317 #endif
 318 extern char **environ;
 319 unset_TZ ()
 320 {
 321   char **from, **to;
 322   for (to = from = environ; (*to = *from); from++)
 323     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 324       to++;
 325 }
 326 char TZ_GMT0[] = "TZ=GMT0";
 327 char TZ_PST8[] = "TZ=PST8";
 328 main()
 329 {
 330   time_t now = time ((time_t *) 0);
 331   int hour_GMT0, hour_unset;
 332   if (putenv (TZ_GMT0) != 0)
 333     exit (1);
 334   hour_GMT0 = localtime (&now)->tm_hour;
 335   unset_TZ ();
 336   hour_unset = localtime (&now)->tm_hour;
 337   if (putenv (TZ_PST8) != 0)
 338     exit (1);
 339   if (localtime (&now)->tm_hour == hour_GMT0)
 340     exit (1);
 341   unset_TZ ();
 342   if (localtime (&now)->tm_hour != hour_unset)
 343     exit (1);
 344   exit (0);
 345 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 346 [# If we have tzset, assume the worst when cross-compiling.
 347 guile_cv_localtime_cache=yes])
 348 else
 349         # If we lack tzset, report that localtime does not cache TZ,
 350         # since we can't invalidate the cache if we don't have tzset.
 351         guile_cv_localtime_cache=no
 352 fi])dnl
 353 AC_MSG_RESULT($guile_cv_localtime_cache)
 354 if test $guile_cv_localtime_cache = yes; then
 355   AC_DEFINE(LOCALTIME_CACHE)
 356 fi
 357
 358 dnl Test whether system calls are restartable by default on the
 359 dnl current system.  If they are not, we put a loop around every system
 360 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 361 dnl change from the default behaviour.  On the other hand, if signals
 362 dnl are restartable then the loop is not installed and when libguile
 363 dnl initialises it also resets the behaviour of each signal to cause a
 364 dnl restart (in case a different runtime had a different default
 365 dnl behaviour for some reason: e.g., different versions of linux seem
 366 dnl to behave differently.)
 367
 368 AC_SYS_RESTARTABLE_SYSCALLS
 369
 370 if test "$enable_regex" = yes; then
 371    if test "$ac_cv_header_regex_h" = yes ||
 372       test "$ac_cv_header_rxposix_h" = yes ||
 373       test "$ac_cv_header_rx_rxposix_h" = yes; then
 374      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 375      [AC_CHECK_LIB(rx, main)
 376       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 377      )
 378      dnl The following should not be necessary, but for some reason
 379      dnl autoheader misses it if we don't include it!
 380      if test "$ac_cv_func_regcomp_norx" = yes ||
 381         test "$ac_cv_func_regcomp_rx" = yes; then
 382        AC_DEFINE(HAVE_REGCOMP)
 383      fi
 384    fi
 385 fi
 386
 387 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
 388
 389 # When testing for the presence of alloca, we need to add alloca.o
 390 # explicitly to LIBOBJS to make sure that it is translated to
 391 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 392 AC_FUNC_ALLOCA
 393 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 394
 395 AC_STRUCT_ST_RDEV
 396 AC_STRUCT_ST_BLKSIZE
 397
 398 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 399 # LIBOBJS, which we don't need.  This seems more direct.
 400 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 401 [AC_TRY_COMPILE([#include <sys/types.h>
 402 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 403 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 404 if test $ac_cv_struct_st_blocks = yes; then
 405   AC_DEFINE(HAVE_ST_BLOCKS)
 406 fi
 407
 408 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 409   [AC_TRY_CPP([#include <sys/stat.h>
 410                #ifndef S_ISLNK
 411                #error no S_ISLNK
 412                #endif],
 413                ac_cv_macro_S_ISLNK=yes,
 414                ac_cv_macro_S_ISLNK=no)])
 415 if test $ac_cv_macro_S_ISLNK = yes; then
 416   AC_DEFINE(HAVE_S_ISLNK)
 417 fi
 418
 419 AC_STRUCT_TIMEZONE
 420 GUILE_STRUCT_UTIMBUF
 421
 422 #--------------------------------------------------------------------
 423 #
 424 # Which way does the stack grow?
 425 #
 426 #--------------------------------------------------------------------
 427
 428 AC_TRY_RUN(aux (l) unsigned long l;
 429              { int x; exit (l >= ((unsigned long)&x)); }
 430            main () { int q; aux((unsigned long)&q); },
 431            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 432
 433 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 434     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 435                 [guile_cv_type_float_fits_long=yes],
 436                 [guile_cv_type_float_fits_long=no],
 437                 [guile_cv_type_float_fits_long=guess-yes])])
 438 case $guile_cv_type_float_fits_long in
 439   "yes" )
 440     AC_DEFINE(SCM_SINGLES)
 441   ;;
 442   "guess-yes" )
 443     AC_DEFINE(SCM_SINGLES)
 444     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 445     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 446   ;;
 447 esac
 448
 449
 450 AC_MSG_CHECKING(for struct linger)
 451 AC_CACHE_VAL(scm_cv_struct_linger,
 452         AC_TRY_COMPILE([
 453 #include <sys/types.h>
 454 #include <sys/socket.h>],
 455                         [struct linger lgr;  lgr.l_linger = 100],
 456                         scm_cv_struct_linger="yes",
 457                         scm_cv_struct_linger="no"))
 458 AC_MSG_RESULT($scm_cv_struct_linger)
 459 if test $scm_cv_struct_linger = yes; then
 460         AC_DEFINE(HAVE_STRUCT_LINGER)
 461 fi
 462
 463
 464 AC_MSG_CHECKING(for struct timespec)
 465 AC_CACHE_VAL(scm_cv_struct_timespec,
 466         AC_TRY_COMPILE([
 467 #include <time.h>],
 468                         [struct timespec t;  t.tv_nsec = 100],
 469                         scm_cv_struct_timespec="yes",
 470                         scm_cv_struct_timespec="no"))
 471 AC_MSG_RESULT($scm_cv_struct_timespec)
 472 if test $scm_cv_struct_timespec = yes; then
 473         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 474 fi
 475
 476 #--------------------------------------------------------------------
 477 #
 478 # Flags for thread support
 479 #
 480 #--------------------------------------------------------------------
 481
 482 ### What thread package has the user asked for?
 483 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 484             , with_threads=no)
 485
 486 ### Turn $with_threads into either the name of a threads package, like
 487 ### `qt', or `no', meaning that threads should not be supported.
 488 AC_MSG_CHECKING(whether to support threads)
 489 case "$with_threads" in
 490   "yes" | "qt" | "coop" | "")
 491     with_threads=qt
 492   ;;
 493   "no" )
 494   ;;
 495   * )
 496     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 497   ;;
 498 esac
 499 AC_MSG_RESULT($with_threads)
 500
 501 ## Make sure the threads package we've chosen is actually supported on
 502 ## the present platform.
 503 case "${with_threads}" in
 504   "qt" )
 505     ## This configures the QuickThreads package, and sets or clears
 506     ## the THREAD_PACKAGE variable if qthreads don't configure
 507     ## correctly.
 508     QTHREADS_CONFIGURE
 509    ;;
 510 esac
 511
 512 ## If we're using threads, bring in some other parts of Guile which
 513 ## work with them.
 514 if test "${THREAD_PACKAGE}" != "" ; then
 515   AC_DEFINE(USE_THREADS, 1)
 516
 517   ## Include the Guile thread interface in the library...
 518   LIBOBJS="$LIBOBJS threads.o"
 519
 520   ## ... and tell it which package to talk to.
 521   case "${THREAD_PACKAGE}" in
 522     "QT" )
 523       AC_DEFINE(USE_COOP_THREADS, 1)
 524     ;;
 525     * )
 526       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 527     ;;
 528   esac
 529
 530   ## Bring in scm_internal_select, if appropriate.
 531   if test $ac_cv_func_gettimeofday = yes &&
 532      test $ac_cv_func_select = yes; then
 533     AC_DEFINE(GUILE_ISELECT, 1)
 534   fi
 535
 536   ## Workaround for linuxthreads (currently disabled)
 537   if test $host_os = linux-gnu; then
 538     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 539     AC_CHECK_LIB(pthread, main)
 540   fi
 541 fi
 542 AC_SUBST(LIBGUILEQTHREADS_MAJOR_VERSION)
 543 AC_SUBST(LIBGUILEQTHREADS_MINOR_VERSION)
 544 AC_SUBST(LIBGUILEQTHREADS_REVISION_VERSION)
 545 AC_SUBST(LIBGUILEQTHREADS_VERSION)
 546
 547 ## If we're using GCC, ask for aggressive warnings.
 548 case "$GCC" in
 549   yes )
 550     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 551     ## much stuff with generic function pointers for that to really be
 552     ## less than exasperating.
 553     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 554     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 555     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 556 esac
 557
 558 AC_PROG_AWK
 559
 560 ## If we're creating a shared library (using libtool!), then we'll
 561 ## need to generate a list of .lo files corresponding to the .o files
 562 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 563 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 564
 565 ## We also need to create corresponding .doc and .x files
 566 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 567 EXTRA_DOT_X_FILES="`echo ${LIBOBJS} | sed 's/\.o/.x/g'`"
 568
 569 AC_SUBST(GUILE_MAJOR_VERSION)
 570 AC_SUBST(GUILE_MINOR_VERSION)
 571 AC_SUBST(GUILE_VERSION)
 572 AC_SUBST(LIBGUILE_MAJOR_VERSION)
 573 AC_SUBST(LIBGUILE_MINOR_VERSION)
 574 AC_SUBST(LIBGUILE_REVISION_VERSION)
 575 AC_SUBST(LIBGUILE_VERSION)
 576
 577 dnl Tell guile-config what flags guile users should link against.
 578 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 579 AC_SUBST(GUILE_LIBS)
 580
 581 AC_SUBST(AWK)
 582 AC_SUBST(LIBLOBJS)
 583 AC_SUBST(EXTRA_DOT_DOC_FILES)
 584 AC_SUBST(EXTRA_DOT_X_FILES)
 585
 586 AC_OUTPUT([Makefile
 587            libguile/Makefile
 588            libguile/guile-snarf
 589            libguile/guile-doc-snarf
 590            libguile/guile-func-name-check
 591            libguile/guile-snarf.awk
 592            libguile/versiondat.h
 593            ice-9/Makefile
 594            oop/Makefile
 595            oop/goops/Makefile
 596            scripts/Makefile
 597            srfi/Makefile
 598            qt/Makefile
 599            qt/qt.h
 600            qt/md/Makefile
 601            qt/time/Makefile
 602            guile-config/Makefile
 603            doc/Makefile
 604            check-guile
 605            guile-tools],
 606           [chmod +x libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check check-guile guile-tools])
 607
 608 dnl Local Variables:
 609 dnl comment-start: "dnl "
 610 dnl comment-end: ""
 611 dnl comment-start-skip: "\\bdnl\\b\\s *"
 612 dnl End: