configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2014 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.3.50)
  26
  27 dnl We get MINGW64 with MSYS2
  28 if test "x$MSYSTEM" = "xMINGW32" -o "x$MSYSTEM" = "xMINGW64"
  29 then
  30   . $srcdir/nt/mingw-cfg.site
  31
  32   case $srcdir in
  33     /* | ?:*)
  34       # srcdir is an absolute path.  In this case, force the format
  35       # "/c/foo/bar", to simplify later conversions to native Windows
  36       # format ("c:/foo/bar")
  37       srcdir=`cd "${srcdir}" && pwd -W`
  38       srcdir="/${srcdir:0:1}${srcdir:2}"
  39       ;;
  40   esac
  41 fi
  42
  43 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  44 dnl and then quoted again for a C string.  Separate options with spaces.
  45 dnl Add some environment variables, if they were passed via the environment
  46 dnl rather than on the command-line.
  47 emacs_config_options=
  48 optsep=
  49 dnl This is the documented way to record the args passed to configure,
  50 dnl rather than $ac_configure_args.
  51 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  52   case $opt in
  53     -n | --no-create | --no-recursion)
  54       continue ;;
  55     CFLAGS | CPPFLAGS | LDFLAGS)
  56       eval 'test "${'$opt'+set}" = set' || continue
  57       case " $*" in
  58         *" $opt="*) continue ;;
  59       esac
  60       eval opt=$opt=\$$opt ;;
  61   esac
  62
  63   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  64   case $opt in
  65     *[["$emacs_shell_specials"]]*)
  66       case $opt in
  67         *\'*)
  68           emacs_quote_apostrophes="s/'/'\\\\''/g"
  69           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  70       esac
  71       opt="'$opt'"
  72       case $opt in
  73         *[['"\\']]*)
  74           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  75           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  76       esac ;;
  77   esac
  78   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  79   optsep=' '
  80 done
  81
  82 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  83 AC_CONFIG_SRCDIR(src/lisp.h)
  84 AC_CONFIG_AUX_DIR(build-aux)
  85
  86 xcsdkdir=
  87 AC_CHECK_PROGS(XCRUN, [xcrun])
  88 if test -n "$XCRUN"; then
  89   if test -z "$MAKE"; then
  90     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  91     dnl SET_MAKE and with the usual MAKE variable that 'make' itself uses.
  92     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  93     if test -z "$MAKE_PROG"; then
  94       MAKE="$XCRUN MAKE"
  95       export MAKE
  96       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  97     fi
  98   fi
  99 fi
 100
 101 dnl Fairly arbitrary, older versions might work too.
 102 AM_INIT_AUTOMAKE(1.11)
 103
 104 dnl Support for --program-prefix, --program-suffix and
 105 dnl --program-transform-name options
 106 AC_ARG_PROGRAM
 107
 108 dnl It is important that variables on the RHS not be expanded here,
 109 dnl hence the single quotes.  This is per the GNU coding standards, see
 110 dnl (autoconf) Installation Directory Variables
 111 dnl See also epaths.h below.
 112 lispdir='${datadir}/emacs/${version}/lisp'
 113 standardlisppath='${lispdir}'
 114 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 115 '${datadir}/emacs/site-lisp'
 116 lisppath='${locallisppath}:${standardlisppath}'
 117 etcdir='${datadir}/emacs/${version}/etc'
 118 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 119 etcdocdir='${datadir}/emacs/${version}/etc'
 120 gamedir='${localstatedir}/games/emacs'
 121
 122 dnl Special option to disable the most of other options.
 123 AC_ARG_WITH(all,
 124 [AS_HELP_STRING([--without-all],
 125                 [omit almost all features and build
 126                 small executable with minimal dependencies])],
 127   [with_features=$withval],
 128   [with_features=yes])
 129
 130 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 131 dnl Create a new --with option that defaults to being disabled.
 132 dnl NAME is the base name of the option.  The shell variable with_NAME
 133 dnl   will be set to either the user's value (if the option is
 134 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 135 dnl   option is not specified).  Note that the shell variable name is
 136 dnl   constructed as autoconf does, by replacing non-alphanumeric
 137 dnl   characters with "_".
 138 dnl HELP-STRING is the help text for the option.
 139 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 140   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 141     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 142 ])dnl
 143
 144 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 145 dnl Create a new --with option that defaults to $with_features.
 146 dnl NAME is the base name of the option.  The shell variable with_NAME
 147 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 148 dnl   'yes' (if the option is not specified).  Note that the shell
 149 dnl   variable name is constructed as autoconf does, by replacing
 150 dnl   non-alphanumeric characters with "_".
 151 dnl HELP-STRING is the help text for the option.
 152 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 153   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 154    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 155 ])dnl
 156
 157 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 158 if test "$with_pop" = yes; then
 159    AC_DEFINE(MAIL_USE_POP)
 160 fi
 161 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 162
 163 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 164 if test "$with_kerberos" != no; then
 165    AC_DEFINE(KERBEROS)
 166 fi
 167 AH_TEMPLATE(KERBEROS,
 168             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 169
 170 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 171 if test "${with_kerberos5}" != no; then
 172   if test "${with_kerberos}" = no; then
 173     with_kerberos=yes
 174     AC_DEFINE(KERBEROS)
 175   fi
 176   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 177 fi
 178
 179 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 180 dnl FIXME hesiod support may not be present, so it seems like an error
 181 dnl to define, or at least use, this unconditionally.
 182 if test "$with_hesiod" != no; then
 183   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 184 fi
 185
 186 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 187 if test "$with_mmdf" != no; then
 188    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 189 fi
 190
 191 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 192 if test "$with_mail_unlink" != no; then
 193    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 194 fi
 195
 196 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 197     [string giving default POP mail host])],
 198     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 199
 200 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 201   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 202 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW.])],
 203   [ case "${withval}" in
 204       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 205       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 206 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 207       ;;
 208     esac
 209     with_sound=$val
 210   ],
 211   [with_sound=$with_features])
 212
 213 dnl FIXME currently it is not the last.
 214 dnl This should be the last --with option, because --with-x is
 215 dnl added later on when we find the file name of X, and it's best to
 216 dnl keep them together visually.
 217 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 218  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 219 [         case "${withval}" in
 220             y | ye | yes )      val=gtk ;;
 221             n | no )            val=no  ;;
 222             l | lu | luc | luci | lucid )       val=lucid ;;
 223             a | at | ath | athe | athen | athena )      val=athena ;;
 224             m | mo | mot | moti | motif )       val=motif ;;
 225             g | gt | gtk  )     val=gtk ;;
 226             gtk2  )     val=gtk2 ;;
 227             gtk3  )     val=gtk3 ;;
 228             * )
 229 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 230 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 231 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 232 `athena' and `lucid' are synonyms.])
 233             ;;
 234           esac
 235           with_x_toolkit=$val
 236 ])
 237
 238 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 239 if test "$with_wide_int" = yes; then
 240   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 241 fi
 242
 243 dnl _ON results in a '--without' option in the --help output, so
 244 dnl the help text should refer to "don't compile", etc.
 245 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 246 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 247 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 248 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 249 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 250 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 251 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 252 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 253
 254 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 255 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 256 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 257
 258 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 259 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 260 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 261 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 262 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 263
 264 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 265 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 266 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 267 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 268 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 269 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 270 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 271
 272 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 273  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 274  [ case "${withval}" in
 275     y | ye | yes )      val=yes ;;
 276     n | no )            val=no  ;;
 277     g | gf | gfi | gfil | gfile )       val=gfile ;;
 278     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 279     w | w3 | w32 )      val=w32 ;;
 280     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 281 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 282 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 283 otherwise for the first of `gfile' or `inotify' that is usable.])
 284     ;;
 285    esac
 286    with_file_notification=$val
 287  ],
 288  [with_file_notification=$with_features])
 289
 290 ## For the times when you want to build Emacs but don't have
 291 ## a suitable makeinfo, and can live without the manuals.
 292 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 293 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 294
 295 ## Makefile.in needs the cache file name.
 296 AC_SUBST(cache_file)
 297
 298 ## This is an option because I do not know if all info/man support
 299 ## compressed files, nor how to test if they do so.
 300 OPTION_DEFAULT_ON([compress-install],
 301   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 302 make GZIP_PROG= install])
 303
 304 AC_ARG_WITH([pkg-config-prog],dnl
 305 [AS_HELP_STRING([--with-pkg-config-prog=FILENAME],
 306                   [file name of pkg-config for finding GTK and librsvg])])
 307 if test "X${with_pkg_config_prog}" != X; then
 308    if test "${with_pkg_config_prog}" != yes; then
 309       PKG_CONFIG="${with_pkg_config_prog}"
 310    fi
 311 fi
 312
 313 AC_ARG_WITH(gameuser,dnl
 314 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 315 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 316   && gameuser="${with_gameuser}"
 317 test "X$gameuser" = X && gameuser=games
 318
 319 AC_ARG_WITH([gnustep-conf],dnl
 320 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 321    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 322 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 323   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 324 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 325      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 326
 327 AC_ARG_ENABLE(ns-self-contained,
 328 [AS_HELP_STRING([--disable-ns-self-contained],
 329                 [disable self contained build under NeXTstep])],
 330    EN_NS_SELF_CONTAINED=$enableval,
 331    EN_NS_SELF_CONTAINED=yes)
 332
 333 AC_ARG_ENABLE(locallisppath,
 334 [AS_HELP_STRING([--enable-locallisppath=PATH],
 335                 [directories Emacs should search for lisp files specific
 336                  to this site])],
 337 if test "${enableval}" = "no"; then
 338   locallisppath=
 339 elif test "${enableval}" != "yes"; then
 340   locallisppath=${enableval}
 341 fi)
 342
 343 AC_ARG_ENABLE(checking,
 344 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 345                 [enable expensive run-time checks.  With LIST,
 346                  enable only specific categories of checks.
 347                  Categories are: all,yes,no.
 348                  Flags are: stringbytes, stringoverrun, stringfreelist,
 349                  xmallocoverrun, conslist, glyphs])],
 350 [ac_checking_flags="${enableval}"],[])
 351 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 352 for check in $ac_checking_flags
 353 do
 354         case $check in
 355         # these set all the flags to specific states
 356         yes)            ac_enable_checking=1 ;;
 357         no)             ac_enable_checking= ;
 358                         ac_gc_check_stringbytes= ;
 359                         ac_gc_check_string_overrun= ;
 360                         ac_gc_check_string_free_list= ;
 361                         ac_xmalloc_overrun= ;
 362                         ac_gc_check_cons_list= ;
 363                         ac_glyphs_debug= ;;
 364         all)            ac_enable_checking=1 ;
 365                         ac_gc_check_stringbytes=1 ;
 366                         ac_gc_check_string_overrun=1 ;
 367                         ac_gc_check_string_free_list=1 ;
 368                         ac_xmalloc_overrun=1 ;
 369                         ac_gc_check_cons_list=1 ;
 370                         ac_glyphs_debug=1 ;;
 371         # these enable particular checks
 372         stringbytes)    ac_gc_check_stringbytes=1 ;;
 373         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 374         stringfreelist) ac_gc_check_string_free_list=1 ;;
 375         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 376         conslist)       ac_gc_check_cons_list=1 ;;
 377         glyphs)         ac_glyphs_debug=1 ;;
 378         *)      AC_MSG_ERROR(unknown check category $check) ;;
 379         esac
 380 done
 381 IFS="$ac_save_IFS"
 382
 383 if test x$ac_enable_checking != x ; then
 384   AC_DEFINE(ENABLE_CHECKING, 1,
 385 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 386 fi
 387 if test x$ac_gc_check_stringbytes != x ; then
 388   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 389 [Define this temporarily to hunt a bug.  If defined, the size of
 390    strings is redundantly recorded in sdata structures so that it can
 391    be compared to the sizes recorded in Lisp strings.])
 392 fi
 393 if test x$ac_gc_check_string_overrun != x ; then
 394   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 395 [Define this to check for short string overrun.])
 396 fi
 397 if test x$ac_gc_check_string_free_list != x ; then
 398   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 399 [Define this to check the string free list.])
 400 fi
 401 if test x$ac_xmalloc_overrun != x ; then
 402   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 403 [Define this to check for malloc buffer overrun.])
 404 fi
 405 if test x$ac_gc_check_cons_list != x ; then
 406   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 407 [Define this to check for errors in cons list.])
 408 fi
 409 if test x$ac_glyphs_debug != x ; then
 410   AC_DEFINE(GLYPH_DEBUG, 1,
 411 [Define this to enable glyphs debugging code.])
 412 fi
 413
 414 AC_ARG_ENABLE(check-lisp-object-type,
 415 [AS_HELP_STRING([--enable-check-lisp-object-type],
 416                 [enable compile time checks for the Lisp_Object data type.
 417                 This is useful for development for catching certain types of bugs.])],
 418 if test "${enableval}" != "no"; then
 419    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 420    [Define this to enable compile time checks for the Lisp_Object data type.])
 421 fi)
 422
 423
 424 dnl The name of this option is unfortunate.  It predates, and has no
 425 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 426 dnl Actually, it stops it working.
 427 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 428 AC_ARG_ENABLE(profiling,
 429 [AS_HELP_STRING([--enable-profiling],
 430                 [build emacs with low-level, gprof profiling support.
 431                 Mainly useful for debugging Emacs itself.  May not work on
 432                 all platforms.  Stops profiler.el working.])],
 433 [ac_enable_profiling="${enableval}"],[])
 434 if test x$ac_enable_profiling != x ; then
 435    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 436 else
 437    PROFILING_CFLAGS=
 438 fi
 439 AC_SUBST(PROFILING_CFLAGS)
 440
 441 AC_ARG_ENABLE(autodepend,
 442 [AS_HELP_STRING([--enable-autodepend],
 443                 [automatically generate dependencies to .h-files.
 444                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 445                  found])],
 446 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 447
 448 AC_ARG_ENABLE(gtk-deprecation-warnings,
 449 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 450                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 451 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 452
 453 ### Canonicalize the configuration name.
 454
 455 AC_CANONICAL_HOST
 456 canonical=$host
 457 configuration=${host_alias-${build_alias-$host}}
 458
 459 dnl This used to use changequote, but, apart from `changequote is evil'
 460 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 461 dnl the great gob of text.  Thus it's not processed for possible expansion.
 462 dnl Just make sure the brackets remain balanced.
 463 dnl
 464 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 465 dnl indicated by comments.
 466 dnl quotation begins
 467 [
 468
 469 ### If you add support for a new configuration, add code to this
 470 ### switch statement to recognize your configuration name and select
 471 ### the appropriate opsys.
 472
 473 ### As far as handling version numbers on operating systems is
 474 ### concerned, make sure things will fail in a fixable way.  If
 475 ### /etc/MACHINES doesn't say anything about version numbers, be
 476 ### prepared to handle anything reasonably.  If version numbers
 477 ### matter, be sure /etc/MACHINES says something about it.
 478
 479 opsys='' unported=no
 480 case "${canonical}" in
 481
 482   ## GNU/Linux and similar ports
 483   *-*-linux* )
 484     opsys=gnu-linux
 485   ;;
 486
 487   ## FreeBSD ports
 488   *-*-freebsd* )
 489     opsys=freebsd
 490   ;;
 491
 492   ## DragonFly ports
 493   *-*-dragonfly* )
 494     opsys=dragonfly
 495   ;;
 496
 497   ## FreeBSD kernel + glibc based userland
 498   *-*-kfreebsd*gnu* )
 499     opsys=gnu-kfreebsd
 500   ;;
 501
 502   ## NetBSD ports
 503   *-*-netbsd* )
 504     opsys=netbsd
 505   ;;
 506
 507   ## OpenBSD ports
 508   *-*-openbsd* )
 509     opsys=openbsd
 510   ;;
 511
 512   ## Apple Darwin / Mac OS X
 513   *-apple-darwin* )
 514     case "${canonical}" in
 515       i[3456]86-* )  ;;
 516       powerpc-* )    ;;
 517       x86_64-* )     ;;
 518       * )            unported=yes ;;
 519     esac
 520     opsys=darwin
 521     ## Use fink packages if available.
 522     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 523 ##    if test -d /sw/include && test -d /sw/lib; then
 524 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 525 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 526 ##    fi
 527   ;;
 528
 529   ## Cygwin ports
 530   *-*-cygwin )
 531     opsys=cygwin
 532   ;;
 533
 534   ## HP 9000 series 700 and 800, running HP/UX
 535   hppa*-hp-hpux10.2* )
 536     opsys=hpux10-20
 537   ;;
 538   hppa*-hp-hpux1[1-9]* )
 539     opsys=hpux11
 540     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 541   ;;
 542
 543   ## IBM machines
 544   rs6000-ibm-aix4.[23]* )
 545     opsys=aix4-2
 546   ;;
 547   powerpc-ibm-aix4.[23]*  )
 548     opsys=aix4-2
 549   ;;
 550   rs6000-ibm-aix[56]* )
 551     opsys=aix4-2
 552   ;;
 553   powerpc-ibm-aix[56]*  )
 554     opsys=aix4-2
 555   ;;
 556
 557   ## Silicon Graphics machines
 558   ## Iris 4D
 559   mips-sgi-irix6.5 )
 560     opsys=irix6-5
 561     # Without defining _LANGUAGE_C, things get masked out in the headers
 562     # so that, for instance, grepping for `free' in stdlib.h fails and
 563     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 564     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 565   ;;
 566
 567   ## Suns
 568   *-sun-solaris* \
 569     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 570     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 571     case "${canonical}" in
 572       i[3456]86-*-* )   ;;
 573       amd64-*-*|x86_64-*-*) ;;
 574       sparc* )          ;;
 575       * )               unported=yes ;;
 576     esac
 577     case "${canonical}" in
 578       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 579                 opsys=sol2-10
 580                 emacs_check_sunpro_c=yes
 581                 ;;
 582       *-sunos5.6* | *-solaris2.6* )
 583                 opsys=sol2-6
 584                 RANLIB="ar -ts"
 585                 ;;
 586       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 587                 opsys=sol2-6
 588                 emacs_check_sunpro_c=yes
 589                 ;;
 590     esac
 591     ## Watch out for a compiler that we know will not work.
 592     case "${canonical}" in
 593      *-solaris* | *-sunos5* )
 594                 if [ "x$CC" = x/usr/ucb/cc ]; then
 595                   ## /usr/ucb/cc doesn't work;
 596                   ## we should find some other compiler that does work.
 597                   unset CC
 598                 fi
 599                 ;;
 600       *) ;;
 601     esac
 602   ;;
 603
 604   ## Intel 386 machines where we don't care about the manufacturer.
 605   i[3456]86-*-* )
 606     case "${canonical}" in
 607       *-darwin* )               opsys=darwin ;;
 608       *-mingw32 )
 609                 opsys=mingw32
 610                 # MinGW overrides and adds some system headers in nt/inc.
 611                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 612                 ;;
 613       *-sysv4.2uw* )            opsys=unixware ;;
 614       *-sysv5uw* )              opsys=unixware ;;
 615       *-sysv5OpenUNIX* )        opsys=unixware ;;
 616       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 617     esac
 618   ;;
 619
 620   # MinGW64
 621   x86_64-*-* )
 622     case "${canonical}" in
 623       *-mingw32 )
 624                 opsys=mingw32
 625                 # MinGW overrides and adds some system headers in nt/inc.
 626                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 627                 ;;
 628       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 629     esac
 630   ;;
 631
 632   * )
 633     unported=yes
 634   ;;
 635 esac
 636
 637 ### If the code above didn't choose an operating system, just choose
 638 ### an operating system based on the configuration name.  You really
 639 ### only want to use this when you have no idea what the right
 640 ### operating system is; if you know what operating systems a machine
 641 ### runs, it's cleaner to make it explicit in the case statement
 642 ### above.
 643 if test x"${opsys}" = x; then
 644   case "${canonical}" in
 645     *-gnu* )                            opsys=gnu ;;
 646     * )
 647       unported=yes
 648     ;;
 649   esac
 650 fi
 651
 652 ]
 653 dnl quotation ends
 654
 655 if test $unported = yes; then
 656   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 657 Check `etc/MACHINES' for recognized configuration names.])
 658 fi
 659
 660
 661 #### Choose a compiler.
 662
 663 dnl Sets GCC=yes if using gcc.
 664 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 665 if test -n "$XCRUN"; then
 666   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 667   test -n "$AR" && export AR
 668 fi
 669
 670 AM_PROG_CC_C_O
 671
 672 if test x$GCC = xyes; then
 673   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 674 else
 675   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 676 fi
 677
 678 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 679 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 680 dnl that clash with MinGW.
 681 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 682
 683 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 684 AC_DEFUN([gl_CRYPTO_CHECK])
 685 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 686 # as we don't use them.
 687 AC_DEFUN([gl_FCNTL_O_FLAGS])
 688 # Avoid gnulib's threadlib module, as we do threads our own way.
 689 AC_DEFUN([gl_THREADLIB])
 690
 691 # Initialize gnulib right after choosing the compiler.
 692 dnl Amongst other things, this sets AR and ARFLAGS.
 693 gl_EARLY
 694
 695 if test "$ac_test_CFLAGS" != set; then
 696   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 697   # if -g3 works and the user does not specify CFLAGS.
 698   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 699   case $CFLAGS in
 700     '-g')
 701       emacs_g3_CFLAGS='-g3';;
 702     '-g -O2')
 703       emacs_g3_CFLAGS='-g3 -O2';;
 704     *)
 705       emacs_g3_CFLAGS='';;
 706   esac
 707   if test -n "$emacs_g3_CFLAGS"; then
 708     emacs_save_CFLAGS=$CFLAGS
 709     CFLAGS=$emacs_g3_CFLAGS
 710     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 711       [emacs_cv_prog_cc_g3],
 712       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 713          [emacs_cv_prog_cc_g3=yes],
 714          [emacs_cv_prog_cc_g3=no])])
 715     if test $emacs_cv_prog_cc_g3 != yes; then
 716       CFLAGS=$emacs_save_CFLAGS
 717     fi
 718     if test $opsys = mingw32; then
 719       CFLAGS="$CFLAGS -gdwarf-2"
 720     fi
 721   fi
 722
 723   case $CFLAGS in
 724     *-O*) ;;
 725     *)
 726       # No optimization flag was inferred for this non-GCC compiler.
 727       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 728       emacs_save_CFLAGS=$CFLAGS
 729       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 730       CFLAGS=${CFLAGS}-O
 731       AC_CACHE_CHECK([whether $CC accepts -O],
 732         [emacs_cv_prog_cc_o],
 733         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 734            [emacs_cv_prog_cc_o=yes],
 735            [emacs_cv_prog_cc_o=no])])
 736       if test $emacs_cv_prog_cc_o != yes; then
 737         CFLAGS=$emacs_save_CFLAGS
 738       fi ;;
 739   esac
 740 fi
 741
 742 AC_ARG_ENABLE([gcc-warnings],
 743   [AS_HELP_STRING([--enable-gcc-warnings],
 744                   [turn on lots of GCC warnings/errors. This is intended for
 745                    developers, and may generate false alarms when used
 746                    with older or non-GNU development tools.])],
 747   [case $enableval in
 748      yes|no) ;;
 749      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 750    esac
 751    gl_gcc_warnings=$enableval],
 752   [gl_gcc_warnings=no]
 753 )
 754
 755 AC_ARG_ENABLE(link-time-optimization,
 756 [AS_HELP_STRING([--enable-link-time-optimization],
 757                 [build emacs with link-time optimization.
 758                  This is supported only for GCC since 4.5.0.])],
 759 if test "${enableval}" != "no"; then
 760    AC_MSG_CHECKING([whether link-time optimization is supported])
 761    ac_lto_supported=no
 762    if test x$GCC = xyes; then
 763       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 764       if test x$CPUS != x; then
 765          LTO="-flto=$CPUS"
 766       else
 767          LTO="-flto"
 768       fi
 769       old_CFLAGS=$CFLAGS
 770       CFLAGS="$CFLAGS $LTO"
 771       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 772         [ac_lto_supported=yes], [ac_lto_supported=no])
 773       CFLAGS="$old_CFLAGS"
 774    fi
 775    AC_MSG_RESULT([$ac_lto_supported])
 776    if test "$ac_lto_supported" = "yes"; then
 777       CFLAGS="$CFLAGS $LTO"
 778    fi
 779 fi)
 780
 781 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 782 # ------------------------------------------------
 783 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 784 # Otherwise, run RUN-IF-NOT-FOUND.
 785 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 786   [AC_PREPROC_IFELSE(
 787     [AC_LANG_PROGRAM(
 788       [[
 789 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 790 /* ok */
 791 #else
 792 # error "your version of gcc is older than $1.$2"
 793 #endif
 794       ]]),
 795     ], [$3], [$4])
 796   ]
 797 )
 798
 799 # clang is unduly picky about some things.
 800 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 801   [AC_COMPILE_IFELSE(
 802      [AC_LANG_PROGRAM([[
 803           #ifndef __clang__
 804             #error "not clang"
 805           #endif
 806         ]])],
 807      [emacs_cv_clang=yes],
 808      [emacs_cv_clang=no])])
 809
 810 # When compiling with GCC, prefer -isystem to -I when including system
 811 # include files, to avoid generating useless diagnostics for the files.
 812 if test "$gl_gcc_warnings" != yes; then
 813   isystem='-I'
 814   if test "$emacs_cv_clang" = yes
 815   then
 816      # Turn off some warnings if supported.
 817      gl_WARN_ADD([-Wno-switch])
 818      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 819      gl_WARN_ADD([-Wno-pointer-sign])
 820   fi
 821 else
 822   isystem='-isystem '
 823
 824   # This, $nw, is the list of warnings we disable.
 825   nw=
 826
 827   case $with_x_toolkit in
 828     lucid | athena | motif)
 829        # Old toolkits mishandle 'const'.
 830        nw="$nw -Wwrite-strings"
 831        ;;
 832     *)
 833        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 834        ;;
 835   esac
 836   AC_SUBST([WERROR_CFLAGS])
 837
 838   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 839   nw="$nw -Woverlength-strings"     # Not a problem these days
 840   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 841   nw="$nw -Wformat-nonliteral"      # we do this a lot
 842   nw="$nw -Wvla"                    # warnings in gettext.h
 843   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 844   nw="$nw -Wswitch-default"         # Too many warnings for now
 845   nw="$nw -Winline"                 # OK to ignore 'inline'
 846   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 847   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 848                                     # signed overflow has undefined behavior
 849   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 850   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 851   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 852
 853   # Emacs doesn't care about shadowing; see
 854   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 855   nw="$nw -Wshadow"
 856
 857   # Emacs's use of alloca inhibits protecting the stack.
 858   nw="$nw -Wstack-protector"
 859
 860   # The following line should be removable at some point.
 861   nw="$nw -Wsuggest-attribute=pure"
 862
 863   # This part is merely for shortening the command line,
 864   # since -Wno-FOO needs to be added below regardless.
 865   nw="$nw -Wmissing-field-initializers"
 866   nw="$nw -Wswitch"
 867   nw="$nw -Wtype-limits"
 868   nw="$nw -Wunused-parameter"
 869
 870   if test $emacs_cv_clang = yes; then
 871     nw="$nw -Wcast-align"
 872   fi
 873
 874   gl_MANYWARN_ALL_GCC([ws])
 875   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 876   for w in $ws; do
 877     gl_WARN_ADD([$w])
 878   done
 879   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 880   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 881   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 882   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 883   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 884   gl_WARN_ADD([-Wno-format-nonliteral])
 885
 886   # In spite of excluding -Wlogical-op above, it is enabled, as of
 887   # gcc 4.5.0 20090517.
 888   gl_WARN_ADD([-Wno-logical-op])
 889
 890   # More things that clang is unduly picky about.
 891   if test $emacs_cv_clang = yes; then
 892     gl_WARN_ADD([-Wno-format-extra-args])
 893     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 894     gl_WARN_ADD([-Wno-unused-command-line-argument])
 895     gl_WARN_ADD([-Wno-unused-value])
 896   fi
 897
 898   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 899   AH_VERBATIM([FORTIFY_SOURCE],
 900   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 901       without upsetting glibc 2.15+. */
 902    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 903    # define _FORTIFY_SOURCE 2
 904    #endif
 905   ])
 906   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 907
 908   # We use a slightly smaller set of warning options for lib/.
 909   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 910   nw=
 911   nw="$nw -Wunused-macros"
 912
 913   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 914   AC_SUBST([GNULIB_WARN_CFLAGS])
 915 fi
 916
 917
 918
 919 dnl Some other nice autoconf tests.
 920 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 921 dnl AC_PROG_INSTALL
 922 dnl AC_PROG_MKDIR_P
 923 dnl if test "x$RANLIB" = x; then
 924 dnl   AC_PROG_RANLIB
 925 dnl fi
 926
 927
 928 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
 929 dnl can be made to directories.  This is not relevant for our usage, and
 930 dnl excludes some cases that work fine for us.  Eg MS Windows or files
 931 dnl hosted on AFS, both examples where simple links work, but links to
 932 dnl directories fail.  We use a cut-down version instead.
 933 dnl AC_PROG_LN_S
 934
 935 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
 936 rm -f conf$$ conf$$.file
 937
 938 LN_S_FILEONLY='cp -p'
 939
 940 if (echo >conf$$.file) 2>/dev/null; then
 941   if ln -s conf$$.file conf$$ 2>/dev/null; then
 942     LN_S_FILEONLY='ln -s'
 943   elif ln conf$$.file conf$$ 2>/dev/null; then
 944     LN_S_FILEONLY=ln
 945   fi
 946 fi
 947
 948 rm -f conf$$ conf$$.file
 949
 950 if test "$LN_S_FILEONLY" = "ln -s"; then
 951    AC_MSG_RESULT([yes])
 952 else
 953    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
 954 fi
 955
 956 AC_SUBST(LN_S_FILEONLY)
 957
 958
 959 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
 960 dnl doesn't support links to directories, as in "ln file dir".  But that
 961 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
 962 dnl executables at "make install" time.
 963 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
 964 dnl for more details.
 965 if test "$opsys" = "mingw32"; then
 966   LN_S="ln"
 967 fi
 968
 969 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 970   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 971 dnl Don't use GZIP, which is used by gzip for additional parameters.
 972 AC_PATH_PROG(GZIP_PROG, gzip)
 973
 974 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
 975    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
 976
 977 if test $opsys = gnu-linux; then
 978   AC_PATH_PROG(PAXCTL, paxctl,,
 979     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 980   if test "X$PAXCTL" != X; then
 981     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 982     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 983       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 984       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 985   fi
 986
 987   if test "${SETFATTR+set}" != set; then
 988     AC_CACHE_CHECK([for setfattr],
 989       [emacs_cv_prog_setfattr],
 990       [touch conftest.tmp
 991        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
 992          emacs_cv_prog_setfattr=yes
 993        else
 994          emacs_cv_prog_setfattr=no
 995        fi])
 996     if test "$emacs_cv_prog_setfattr" = yes; then
 997       SETFATTR=setfattr
 998     else
 999       SETFATTR=
1000     fi
1001     rm -f conftest.tmp
1002     AC_SUBST([SETFATTR])
1003   fi
1004 fi
1005
1006 ## Need makeinfo >= 4.7 (?) to build the manuals.
1007 AC_PATH_PROG(MAKEINFO, makeinfo, no)
1008 dnl By this stage, configure has already checked for egrep and set EGREP,
1009 dnl or exited with an error if no egrep was found.
1010 if test "$MAKEINFO" != "no"; then
1011   case `
1012     $MAKEINFO --version 2> /dev/null |
1013     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
1014   ` in
1015     '') MAKEINFO=no;;
1016   esac
1017 fi
1018
1019 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1020 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1021 ## therefore in the category of "special tools" not normally required, which
1022 ## configure does not have to check for (eg autoconf itself).
1023 ## In a repository checkout on the other hand, the manuals are not included.
1024 ## So makeinfo is a requirement to build from the repository, and configure
1025 ## should test for it as it does for any other build requirement.
1026 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1027 ## with pre-built manuals, from a repository checkout.
1028 HAVE_MAKEINFO=yes
1029
1030 if test "$MAKEINFO" = "no"; then
1031   MAKEINFO=makeinfo
1032   if test "x${with_makeinfo}" = "xno"; then
1033     HAVE_MAKEINFO=no
1034   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1035     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1036 source tree does not seem to have pre-built manuals in the `info' directory.
1037 Either install a suitable version of makeinfo, or re-run configure
1038 with the `--without-makeinfo' option to build without the manuals.] )
1039   fi
1040 fi
1041 AC_SUBST(HAVE_MAKEINFO)
1042
1043 dnl Just so that there is only a single place we need to edit.
1044 INFO_EXT=.info
1045 INFO_OPTS=--no-split
1046 AC_SUBST(INFO_EXT)
1047 AC_SUBST(INFO_OPTS)
1048
1049 if test $opsys = mingw32; then
1050    DOCMISC_W32=efaq-w32
1051 else
1052    DOCMISC_W32=
1053 fi
1054 AC_SUBST(DOCMISC_W32)
1055
1056 dnl Add our options to ac_link now, after it is set up.
1057
1058 if test x$GCC = xyes; then
1059   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1060     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1061 else
1062   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1063     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1064 fi
1065
1066 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1067 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1068 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1069 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1070 dnl if not built to support GNU ld.
1071
1072 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1073 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1074 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1075 dnl   Eg "make LDFLAGS=... all" could run into problems,
1076 dnl   http://bugs.debian.org/684788
1077 dnl * unnecessary, since temacs is the only thing that actually needs it.
1078 dnl   Indeed this is where it was originally, prior to:
1079 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1080 late_LDFLAGS="$LDFLAGS"
1081 if test x$GCC = xyes; then
1082   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1083 else
1084   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1085 fi
1086
1087 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1088
1089 AC_MSG_CHECKING([for -znocombreloc])
1090 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1091   [AC_MSG_RESULT(yes)],
1092   LDFLAGS_NOCOMBRELOC=
1093   [AC_MSG_RESULT(no)])
1094
1095 LDFLAGS="$late_LDFLAGS"
1096
1097 AC_CACHE_CHECK([whether addresses are sanitized],
1098   [emacs_cv_sanitize_address],
1099   [AC_COMPILE_IFELSE(
1100      [AC_LANG_PROGRAM(
1101         [[#ifndef __has_feature
1102           #define __has_feature(f) 0
1103           #endif
1104           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1105           #else
1106            #error "Addresses are not sanitized."
1107           #endif
1108         ]])],
1109      [emacs_cv_sanitize_address=yes],
1110      [emacs_cv_sanitize_address=no])])
1111
1112 dnl The function dump-emacs will not be defined and temacs will do
1113 dnl (load "loadup") automatically unless told otherwise.
1114 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1115 case "$opsys" in
1116   your-opsys-here) CANNOT_DUMP=yes ;;
1117 esac
1118
1119 if test "$CANNOT_DUMP" = "yes"; then
1120   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1121 elif test "$emacs_cv_sanitize_address" = yes; then
1122   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1123 fi
1124
1125 AC_SUBST(CANNOT_DUMP)
1126
1127
1128 UNEXEC_OBJ=unexelf.o
1129 case "$opsys" in
1130   # MSDOS uses unexcoff.o
1131   aix4-2)
1132    UNEXEC_OBJ=unexaix.o
1133    ;;
1134   cygwin)
1135    UNEXEC_OBJ=unexcw.o
1136    ;;
1137   darwin)
1138    UNEXEC_OBJ=unexmacosx.o
1139    ;;
1140   hpux10-20 | hpux11)
1141    UNEXEC_OBJ=unexhp9k800.o
1142    ;;
1143   mingw32)
1144    UNEXEC_OBJ=unexw32.o
1145    ;;
1146   sol2-10)
1147    # Use the Solaris dldump() function, called from unexsol.c, to dump
1148    # emacs, instead of the generic ELF dump code found in unexelf.c.
1149    # The resulting binary has a complete symbol table, and is better
1150    # for debugging and other observability tools (debuggers, pstack, etc).
1151    #
1152    # If you encounter a problem using dldump(), please consider sending
1153    # a message to the OpenSolaris tools-linking mailing list:
1154    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1155    #
1156    # It is likely that dldump() works with older Solaris too, but this has
1157    # not been tested, so for now this change is for Solaris 10 or newer.
1158    UNEXEC_OBJ=unexsol.o
1159    ;;
1160 esac
1161
1162 LD_SWITCH_SYSTEM=
1163 case "$opsys" in
1164   freebsd|dragonfly)
1165    ## Let `ld' find image libs and similar things in /usr/local/lib.
1166    ## The system compiler, GCC, has apparently been modified to not
1167    ## look there, contrary to what a stock GCC would do.
1168 ### It's not our place to do this.  See bug#10313#17.
1169 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1170       :
1171    ;;
1172
1173   gnu-linux)
1174    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1175    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1176    ;;
1177
1178   netbsd)
1179 ### It's not our place to do this.  See bug#10313#17.
1180 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1181       :
1182    ;;
1183
1184   openbsd)
1185    ## Han Boetes <han@boetes.org> says this is necessary,
1186    ## otherwise Emacs dumps core on elf systems.
1187    LD_SWITCH_SYSTEM="-Z"
1188    ;;
1189 esac
1190 AC_SUBST(LD_SWITCH_SYSTEM)
1191
1192 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1193
1194 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1195 ## which has not been defined yet.  When this was handled with cpp,
1196 ## it was expanded to null when configure sourced the s/*.h file.
1197 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1198 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1199 ## (or somesuch), but because it is supposed to go at the _front_
1200 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1201 ## Compare with the gnu-linux case below, which added to the end
1202 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1203 ## LD_SWITCH_SYSTEM_TEMACS.
1204 case "$opsys" in
1205   netbsd|openbsd)
1206    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1207 esac
1208
1209
1210 C_SWITCH_MACHINE=
1211 case $canonical in
1212  alpha*)
1213   AC_CHECK_DECL([__ELF__])
1214   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1215     ## With ELF, make sure that all common symbols get allocated to in the
1216     ## data section.  Otherwise, the dump of temacs may miss variables in
1217     ## the shared library that have been initialized.  For example, with
1218     ## GNU libc, __malloc_initialized would normally be resolved to the
1219     ## shared library's .bss section, which is fatal.
1220     if test "x$GCC" = "xyes"; then
1221       C_SWITCH_MACHINE="-fno-common"
1222     else
1223       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1224     fi
1225   else
1226       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1227       dnl albeit under the mistaken assumption that said file
1228       dnl was no longer used.
1229       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1230   fi
1231   ;;
1232 esac
1233 AC_SUBST(C_SWITCH_MACHINE)
1234
1235 AC_SUBST(UNEXEC_OBJ)
1236
1237 C_SWITCH_SYSTEM=
1238 ## Some programs in src produce warnings saying certain subprograms
1239 ## are too complex and need a MAXMEM value greater than 2000 for
1240 ## additional optimization.  --nils@exp-math.uni-essen.de
1241 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1242   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1243 if test "$opsys" = "mingw32"; then
1244   case "$canonical" in
1245     x86_64-*-mingw32) C_SWITCH_SYSTEM="-mtune=generic" ;;
1246     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1247   esac
1248 fi
1249 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1250 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1251 AC_SUBST(C_SWITCH_SYSTEM)
1252
1253
1254 LIBS_SYSTEM=
1255 case "$opsys" in
1256   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1257   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1258
1259   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1260
1261   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1262
1263   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1264
1265   ## Motif needs -lgen.
1266   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1267 esac
1268
1269 AC_SUBST(LIBS_SYSTEM)
1270
1271 ### Make sure subsequent tests use flags consistent with the build flags.
1272
1273 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1274   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1275 else
1276   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1277 fi
1278
1279 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1280 AC_DEFUN([AC_TYPE_SIZE_T])
1281 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1282 AC_DEFUN([AC_TYPE_UID_T])
1283
1284
1285 LIB_MATH=-lm
1286 dnl Current possibilities handled by sed (aix4-2 -> aix,
1287 dnl gnu-linux -> gnu/linux, etc.):
1288 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1289 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1290 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1291
1292 case $opsys in
1293   cygwin )
1294     LIB_MATH=
1295     ;;
1296   darwin )
1297     ## Adding -lm confuses the dynamic linker, so omit it.
1298     LIB_MATH=
1299     ;;
1300   freebsd | dragonfly )
1301     SYSTEM_TYPE=berkeley-unix
1302     ;;
1303   gnu-linux | gnu-kfreebsd )
1304     ;;
1305   hpux10-20 | hpux11 )
1306     ;;
1307   mingw32 )
1308     LIB_MATH=
1309     SYSTEM_TYPE=windows-nt
1310     ;;
1311   dnl NB this may be adjusted below.
1312   netbsd | openbsd )
1313     SYSTEM_TYPE=berkeley-unix
1314     ;;
1315
1316   sol2* | unixware )
1317     SYSTEM_TYPE=usg-unix-v
1318     ;;
1319
1320 esac
1321
1322 AC_SUBST(LIB_MATH)
1323 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1324   [The type of system you are compiling for; sets `system-type'.])
1325
1326
1327 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1328 pre_PKG_CONFIG_LIBS=$LIBS
1329
1330 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1331
1332 dnl This function definition taken from Gnome 2.0
1333 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1334 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1335 dnl also defines GSTUFF_PKG_ERRORS on error
1336 AC_DEFUN([PKG_CHECK_MODULES], [
1337   succeeded=no
1338
1339   if test "$PKG_CONFIG" = "no" ; then
1340      ifelse([$4], , [AC_MSG_ERROR([
1341       *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1342   else
1343      PKG_CONFIG_MIN_VERSION=0.9.0
1344      if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1345         AC_MSG_CHECKING(for $2)
1346
1347         if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1348            $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1349            $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1350             edit_cflags="
1351               s,///*,/,g
1352               s/^/ /
1353               s/ -I/ $isystem/g
1354               s/^ //
1355             "
1356             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1357             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1358             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1359             succeeded=yes
1360         else
1361             AC_MSG_RESULT(no)
1362             $1_CFLAGS=""
1363             $1_LIBS=""
1364             ## If we have a custom action on failure, don't print errors, but
1365             ## do set a variable so people can do so.  Do it in a subshell
1366             ## to capture any diagnostics in invoking pkg-config.
1367             $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1`
1368             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1369         fi
1370
1371         AC_SUBST($1_CFLAGS)
1372         AC_SUBST($1_LIBS)
1373      else
1374         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1375         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1376      fi
1377   fi
1378
1379   if test $succeeded = yes; then
1380      ifelse([$3], , :, [$3])
1381   else
1382      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1383   fi
1384 ])
1385
1386 HAVE_SOUND=no
1387 if test "${with_sound}" != "no"; then
1388   # Sound support for GNU/Linux, the free BSDs, and MinGW.
1389   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h],
1390     have_sound_header=yes, [], [
1391     #ifdef __MINGW32__
1392     #define WIN32_LEAN_AND_MEAN
1393     #include <windows.h>
1394     #endif
1395     ])
1396   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1397     AC_MSG_ERROR([OSS sound support requested but not found.])
1398
1399   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1400     # Emulation library used on NetBSD.
1401     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1402     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1403       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1404     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1405     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1406   fi
1407   AC_SUBST(LIBSOUND)
1408
1409   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1410     ALSA_REQUIRED=1.0.0
1411     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1412     PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1413     if test $HAVE_ALSA = yes; then
1414       SAVE_CFLAGS="$CFLAGS"
1415       SAVE_LIBS="$LIBS"
1416       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1417       LIBS="$ALSA_LIBS $LIBS"
1418       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1419                       emacs_alsa_normal=yes,
1420                     emacs_alsa_normal=no)
1421       if test "$emacs_alsa_normal" != yes; then
1422         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1423                        [[snd_lib_error_set_handler (0);]])],
1424                        emacs_alsa_subdir=yes,
1425                      emacs_alsa_subdir=no)
1426         if test "$emacs_alsa_subdir" != yes; then
1427           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1428         fi
1429         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1430       fi
1431
1432       CFLAGS="$SAVE_CFLAGS"
1433       LIBS="$SAVE_LIBS"
1434       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1435       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1436       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1437     elif test "${with_sound}" = "alsa"; then
1438       AC_MSG_ERROR([ALSA sound support requested but not found.])
1439     fi
1440   fi                            dnl with_sound = alsa|yes
1441
1442   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1443   dnl compiles only on the specified platforms.  For others, it
1444   dnl probably doesn't make sense to try.
1445   dnl FIXME So surely we should bypass this whole section if not using
1446   dnl one of these platforms?
1447   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1448      case "$opsys" in
1449        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1450        dnl Adjust the --with-sound help text if you change this.
1451        gnu-linux|freebsd|netbsd|mingw32)
1452          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1453          HAVE_SOUND=yes
1454          ;;
1455      esac
1456   fi
1457
1458   AC_SUBST(CFLAGS_SOUND)
1459 fi
1460
1461 dnl checks for header files
1462 AC_CHECK_HEADERS_ONCE(
1463   sys/systeminfo.h
1464   coff.h pty.h
1465   sys/resource.h
1466   sys/utsname.h pwd.h utmp.h util.h)
1467
1468 AC_MSG_CHECKING(if personality LINUX32 can be set)
1469 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1470                emacs_cv_personality_linux32=yes,
1471                emacs_cv_personality_linux32=no)
1472 AC_MSG_RESULT($emacs_cv_personality_linux32)
1473
1474 if test $emacs_cv_personality_linux32 = yes; then
1475   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1476             [Define to 1 if personality LINUX32 can be set.])
1477 fi
1478
1479 dnl On Solaris 8 there's a compilation warning for term.h because
1480 dnl it doesn't define `bool'.
1481 AC_CHECK_HEADERS(term.h, , , -)
1482 AC_HEADER_TIME
1483 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1484                                       ]])
1485 if test $ac_cv_have_decl_sys_siglist != yes; then
1486   # For Tru64, at least:
1487   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1488                                           ]])
1489 fi
1490 AC_HEADER_SYS_WAIT
1491
1492 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1493 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1494 #if HAVE_SYS_SOCKET_H
1495 #include <sys/socket.h>
1496 #endif])
1497 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1498 #if HAVE_SYS_SOCKET_H
1499 #include <sys/socket.h>
1500 #endif])
1501 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1502 #if HAVE_SYS_SOCKET_H
1503 #include <sys/socket.h>
1504 #endif])
1505
1506 dnl checks for structure members
1507 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1508                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1509                   struct ifreq.ifr_addr,
1510                   struct ifreq.ifr_addr.sa_len], , ,
1511                  [AC_INCLUDES_DEFAULT
1512 #if HAVE_SYS_SOCKET_H
1513 #include <sys/socket.h>
1514 #endif
1515 #if HAVE_NET_IF_H
1516 #include <net/if.h>
1517 #endif])
1518
1519 dnl Check for endianness.
1520 dnl AC_C_BIGENDIAN is done by gnulib.
1521
1522 dnl check for Make feature
1523 dnl AC_PROG_MAKE_SET is done by Automake.
1524
1525 DEPFLAGS=
1526 MKDEPDIR=":"
1527 deps_frag=deps.mk
1528 dnl check for GNU Make if we have GCC and autodepend is on.
1529 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1530    AC_MSG_CHECKING([whether we are using GNU Make])
1531    HAVE_GNU_MAKE=no
1532    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1533    if test "x$testval" != x; then
1534       HAVE_GNU_MAKE=yes
1535    else
1536       ac_enable_autodepend=no
1537    fi
1538    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1539    if test $HAVE_GNU_MAKE = yes; then
1540       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1541       SAVE_CFLAGS="$CFLAGS"
1542       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1543       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1544       CFLAGS="$SAVE_CFLAGS"
1545       test -f deps.d || ac_enable_autodepend=no
1546       rm -rf deps.d
1547       AC_MSG_RESULT([$ac_enable_autodepend])
1548    fi
1549    if test $ac_enable_autodepend = yes; then
1550       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1551       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1552       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1553       deps_frag=autodeps.mk
1554    fi
1555 fi
1556 deps_frag=$srcdir/src/$deps_frag
1557 AC_SUBST(MKDEPDIR)
1558 AC_SUBST(DEPFLAGS)
1559 AC_SUBST_FILE(deps_frag)
1560
1561
1562 lisp_frag=$srcdir/src/lisp.mk
1563 AC_SUBST_FILE(lisp_frag)
1564
1565
1566 dnl checks for operating system services
1567 AC_SYS_LONG_FILE_NAMES
1568
1569 #### Choose a window system.
1570
1571 ## We leave window_system equal to none if
1572 ## we end up building without one.  Any new window system should
1573 ## set window_system to an appropriate value and add objects to
1574 ## window-system-specific substs.
1575
1576 window_system=none
1577 AC_PATH_X
1578 if test "$no_x" != yes; then
1579   window_system=x11
1580 fi
1581
1582 LD_SWITCH_X_SITE_RPATH=
1583 if test "${x_libraries}" != NONE; then
1584   if test -n "${x_libraries}"; then
1585     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1586     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1587   fi
1588   x_default_search_path=""
1589   x_search_path=${x_libraries}
1590   if test -z "${x_search_path}"; then
1591     x_search_path=/usr/lib
1592   fi
1593   for x_library in `echo ${x_search_path}: | \
1594                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1595     x_search_path="\
1596 ${x_library}/X11/%L/%T/%N%C%S:\
1597 ${x_library}/X11/%l/%T/%N%C%S:\
1598 ${x_library}/X11/%T/%N%C%S:\
1599 ${x_library}/X11/%L/%T/%N%S:\
1600 ${x_library}/X11/%l/%T/%N%S:\
1601 ${x_library}/X11/%T/%N%S"
1602     if test x"${x_default_search_path}" = x; then
1603       x_default_search_path=${x_search_path}
1604     else
1605       x_default_search_path="${x_search_path}:${x_default_search_path}"
1606     fi
1607   done
1608 fi
1609 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1610
1611 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1612   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1613 fi
1614
1615 if test x"${x_includes}" = x; then
1616   bitmapdir=/usr/include/X11/bitmaps
1617 else
1618   # accumulate include directories that have X11 bitmap subdirectories
1619   bmd_acc="dummyval"
1620   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1621     if test -d "${bmd}/X11/bitmaps"; then
1622       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1623     fi
1624     if test -d "${bmd}/bitmaps"; then
1625       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1626     fi
1627   done
1628   if test ${bmd_acc} != "dummyval"; then
1629     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1630   fi
1631 fi
1632
1633 HAVE_NS=no
1634 NS_IMPL_COCOA=no
1635 NS_IMPL_GNUSTEP=no
1636 tmp_CPPFLAGS="$CPPFLAGS"
1637 tmp_CFLAGS="$CFLAGS"
1638 CPPFLAGS="$CPPFLAGS -x objective-c"
1639 CFLAGS="$CFLAGS -x objective-c"
1640 GNU_OBJC_CFLAGS=
1641 LIBS_GNUSTEP=
1642 if test "${with_ns}" != no; then
1643   if test "${opsys}" = darwin; then
1644      NS_IMPL_COCOA=yes
1645      ns_appdir=`pwd`/nextstep/Emacs.app
1646      ns_appbindir=${ns_appdir}/Contents/MacOS
1647      ns_appresdir=${ns_appdir}/Contents/Resources
1648      ns_appsrc=Cocoa/Emacs.base
1649   elif test -f $GNUSTEP_CONFIG_FILE; then
1650      NS_IMPL_GNUSTEP=yes
1651      ns_appdir=`pwd`/nextstep/Emacs.app
1652      ns_appbindir=${ns_appdir}
1653      ns_appresdir=${ns_appdir}/Resources
1654      ns_appsrc=GNUstep/Emacs.base
1655      dnl FIXME sourcing this several times in subshells seems inefficient.
1656      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1657      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1658      dnl I seemed to need these as well with GNUstep-startup 0.25.
1659      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1660      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1661      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1662        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1663      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1664        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1665      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1666      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1667      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1668      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1669      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1670      dnl If they had chosen to either define it or not, we could have
1671      dnl just used AC_CHECK_DECL here.
1672      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1673        emacs_cv_objc_exceptions,
1674 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1675 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1676 1;
1677 #else
1678 fail;
1679 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1680      if test $emacs_cv_objc_exceptions = yes; then
1681        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1682        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1683          [Define if GNUstep uses ObjC exceptions.])
1684        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1685      fi
1686   fi
1687
1688   dnl This is only used while we test the NS headers, it gets reset below.
1689   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1690
1691   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1692                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1693   files are missing or cannot be compiled.])])
1694
1695   macfont_file=""
1696   if test "${NS_IMPL_COCOA}" = "yes"; then
1697     AC_MSG_CHECKING([for OSX 10.4 or newer])
1698     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1699                                      [
1700 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1701 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1702  ; /* OK */
1703 #else
1704 #error "OSX 10.4 or newer required"
1705 #endif
1706 #endif
1707                     ])],
1708                     ns_osx_have_104=yes,
1709                     ns_osx_have_104=no)
1710     AC_MSG_RESULT([$ns_osx_have_104])
1711
1712     if test $ns_osx_have_104 = no; then
1713        AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1714     fi
1715     AC_MSG_CHECKING([for OSX 10.5 or newer])
1716     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1717                                      [
1718 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1719 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1050
1720  ; /* OK */
1721 #else
1722 #error "OSX 10.5 not found"
1723 #endif
1724 #endif
1725                     ])],
1726                     ns_osx_have_105=yes,
1727                     ns_osx_have_105=no)
1728     AC_MSG_RESULT([$ns_osx_have_105])
1729     if test $ns_osx_have_105 = yes; then
1730       macfont_file="macfont.o"
1731     fi
1732   fi
1733   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1734                                      [NSInteger i;])],
1735                     ns_have_nsinteger=yes,
1736                     ns_have_nsinteger=no)
1737   if test $ns_have_nsinteger = yes; then
1738     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1739   fi
1740 fi
1741
1742 AC_SUBST(LIBS_GNUSTEP)
1743
1744 INSTALL_ARCH_INDEP_EXTRA=install-etc
1745 ns_self_contained=no
1746 NS_OBJ=
1747 NS_OBJC_OBJ=
1748 if test "${HAVE_NS}" = yes; then
1749   if test "$with_toolkit_scroll_bars" = "no"; then
1750     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1751   fi
1752
1753   window_system=nextstep
1754   # set up packaging dirs
1755   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1756      ns_self_contained=yes
1757      prefix=${ns_appresdir}
1758      exec_prefix=${ns_appbindir}
1759      dnl This one isn't really used, only archlibdir is.
1760      libexecdir="\${ns_appbindir}/libexec"
1761      archlibdir="\${ns_appbindir}/libexec"
1762      etcdocdir="\${ns_appresdir}/etc"
1763      etcdir="\${ns_appresdir}/etc"
1764      dnl FIXME maybe set datarootdir instead.
1765      dnl That would also get applications, icons, man.
1766      infodir="\${ns_appresdir}/info"
1767      mandir="\${ns_appresdir}/man"
1768      lispdir="\${ns_appresdir}/lisp"
1769      INSTALL_ARCH_INDEP_EXTRA=
1770   fi
1771
1772   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o $macfont_file"
1773 fi
1774 CFLAGS="$tmp_CFLAGS"
1775 CPPFLAGS="$tmp_CPPFLAGS"
1776 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1777 AC_SUBST(ns_self_contained)
1778 AC_SUBST(NS_OBJ)
1779 AC_SUBST(NS_OBJC_OBJ)
1780
1781 HAVE_W32=no
1782 W32_OBJ=
1783 W32_LIBS=
1784 EMACSRES=
1785 CLIENTRES=
1786 CLIENTW=
1787 W32_RES_LINK=
1788 EMACS_MANIFEST=
1789 UPDATE_MANIFEST=
1790 if test "${with_w32}" != no; then
1791   case "${opsys}" in
1792     cygwin)
1793       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1794              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1795                    cannot be found.])])
1796     ;;
1797     mingw32)
1798     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1799     ;;
1800     *)
1801       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1802     ;;
1803   esac
1804 fi
1805
1806 if test "${opsys}" = "mingw32"; then
1807   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1808   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1809      #include <windows.h>
1810      #include <usp10.h>]],
1811    [[PIMAGE_NT_HEADERS pHeader;
1812      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1813    [emacs_cv_w32api=yes
1814     HAVE_W32=yes],
1815    emacs_cv_w32api=no)
1816   AC_MSG_RESULT($emacs_cv_w32api)
1817   if test "${emacs_cv_w32api}" = "no"; then
1818     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1819   fi
1820 fi
1821
1822 FIRSTFILE_OBJ=
1823 NTDIR=
1824 LIBS_ECLIENT=
1825 LIB_WSOCK32=
1826 NTLIB=
1827 CM_OBJ="cm.o"
1828 XARGS_LIMIT=
1829 if test "${HAVE_W32}" = "yes"; then
1830   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1831   AC_CHECK_TOOL(WINDRES, [windres],
1832                 [AC_MSG_ERROR([No resource compiler found.])])
1833   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1834   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1835   EMACSRES="emacs.res"
1836   case "$canonical" in
1837     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1838     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1839   esac
1840   UPDATE_MANIFEST=update-game-score.exe.manifest
1841   if test "${opsys}" = "cygwin"; then
1842     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1843     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1844     # Tell the linker that emacs.res is an object (which we compile from
1845     # the rc file), not a linker script.
1846     W32_RES_LINK="-Wl,emacs.res"
1847   else
1848     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1849     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1850     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1851     W32_RES_LINK="\$(EMACSRES)"
1852     CLIENTRES="emacsclient.res"
1853     CLIENTW="emacsclientw\$(EXEEXT)"
1854     FIRSTFILE_OBJ=firstfile.o
1855     NTDIR=nt
1856     CM_OBJ=
1857     LIBS_ECLIENT="-lcomctl32"
1858     LIB_WSOCK32="-lwsock32"
1859     NTLIB="ntlib.$ac_objext"
1860     XARGS_LIMIT="-s 10000"
1861   fi
1862 fi
1863 AC_SUBST(W32_OBJ)
1864 AC_SUBST(W32_LIBS)
1865 AC_SUBST(EMACSRES)
1866 AC_SUBST(EMACS_MANIFEST)
1867 AC_SUBST(UPDATE_MANIFEST)
1868 AC_SUBST(CLIENTRES)
1869 AC_SUBST(CLIENTW)
1870 AC_SUBST(W32_RES_LINK)
1871 AC_SUBST(FIRSTFILE_OBJ)
1872 AC_SUBST(NTDIR)
1873 AC_SUBST(CM_OBJ)
1874 AC_SUBST(LIBS_ECLIENT)
1875 AC_SUBST(LIB_WSOCK32)
1876 AC_SUBST(NTLIB)
1877 AC_SUBST(XARGS_LIMIT)
1878
1879 if test "${HAVE_W32}" = "yes"; then
1880   window_system=w32
1881   with_xft=no
1882 fi
1883
1884 ## $window_system is now set to the window system we will
1885 ## ultimately use.
1886
1887 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
1888    # Too many warnings for now.
1889    nw=
1890    nw="$nw -Wsuggest-attribute=const"
1891    nw="$nw -Wsuggest-attribute=noreturn"
1892    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1893
1894    gl_WARN_ADD([-Wno-unused-variable])
1895    gl_WARN_ADD([-Wno-unused-but-set-variable])
1896    gl_WARN_ADD([-Wno-unused-but-set-parameter])
1897 fi
1898
1899 term_header=
1900 HAVE_X_WINDOWS=no
1901 HAVE_X11=no
1902 USE_X_TOOLKIT=none
1903
1904 case "${window_system}" in
1905   x11 )
1906     HAVE_X_WINDOWS=yes
1907     HAVE_X11=yes
1908     term_header=xterm.h
1909     case "${with_x_toolkit}" in
1910       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1911       motif ) USE_X_TOOLKIT=MOTIF ;;
1912       gtk ) with_gtk=yes
1913             term_header=gtkutil.h
1914 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1915 dnl USE_X_TOOLKIT is set.
1916             USE_X_TOOLKIT=none ;;
1917       gtk2 ) with_gtk2=yes
1918              term_header=gtkutil.h
1919              USE_X_TOOLKIT=none ;;
1920       gtk3 ) with_gtk3=yes
1921              term_header=gtkutil.h
1922              USE_X_TOOLKIT=none ;;
1923       no ) USE_X_TOOLKIT=none ;;
1924 dnl If user did not say whether to use a toolkit, make this decision later:
1925 dnl use the toolkit if we have gtk, or X11R5 or newer.
1926       * ) USE_X_TOOLKIT=maybe ;;
1927     esac
1928   ;;
1929   nextstep )
1930     term_header=nsterm.h
1931   ;;
1932   w32 )
1933     term_header=w32term.h
1934   ;;
1935 esac
1936
1937 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1938    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1939    if test "$HAVE_XSERVER" = true ||
1940       test -n "$DISPLAY" ||
1941       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1942         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1943 were found.  You should install the relevant development files for X
1944 and for the toolkit you want, such as Gtk+ or Motif.  Also make
1945 sure you have development files for image handling, i.e.
1946 tiff, gif, jpeg, png and xpm.
1947 If you are sure you want Emacs compiled without X window support, pass
1948   --without-x
1949 to configure.])
1950    fi
1951 fi
1952
1953 # Does the opsystem file prohibit the use of the GNU malloc?
1954 # Assume not, until told otherwise.
1955 GNU_MALLOC=yes
1956
1957 AC_CACHE_CHECK(
1958   [whether malloc is Doug Lea style],
1959   [emacs_cv_var_doug_lea_malloc],
1960   [emacs_cv_var_doug_lea_malloc=no
1961    dnl Hooks do not work with address sanitization.
1962    if test "$emacs_cv_sanitize_address" != yes; then
1963      AC_LINK_IFELSE(
1964        [AC_LANG_PROGRAM(
1965           [[#include <malloc.h>
1966             static void hook (void) {}]],
1967           [[malloc_set_state (malloc_get_state ());
1968             __after_morecore_hook = hook;
1969             __malloc_initialize_hook = hook;]])],
1970        [emacs_cv_var_doug_lea_malloc=yes])])
1971    fi
1972 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1973
1974 system_malloc=$emacs_cv_sanitize_address
1975 case "$opsys" in
1976   ## darwin ld insists on the use of malloc routines in the System framework.
1977   darwin|sol2-10) system_malloc=yes ;;
1978 esac
1979
1980 GMALLOC_OBJ=
1981 if test "${system_malloc}" = "yes"; then
1982   AC_DEFINE([SYSTEM_MALLOC], 1,
1983     [Define to 1 to use the system memory allocator, even if it is not
1984      Doug Lea style.])
1985   GNU_MALLOC=no
1986   GNU_MALLOC_reason="
1987     (The GNU allocators don't work with this system configuration.)"
1988   VMLIMIT_OBJ=
1989 else
1990   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1991   VMLIMIT_OBJ=vm-limit.o
1992
1993   AC_CHECK_HEADERS([sys/vlimit.h])
1994   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
1995     [AC_LINK_IFELSE(
1996        [AC_LANG_PROGRAM(
1997          [[extern char data_start[]; char ch;]],
1998          [[return data_start < &ch;]])],
1999        [emacs_cv_data_start=yes],
2000        [emacs_cv_data_start=no])])
2001   if test $emacs_cv_data_start = yes; then
2002     AC_DEFINE([HAVE_DATA_START], 1,
2003       [Define to 1 if data_start is the address of the start
2004        of the main data segment.])
2005   fi
2006 fi
2007 AC_SUBST(GMALLOC_OBJ)
2008 AC_SUBST(VMLIMIT_OBJ)
2009
2010 if test "$doug_lea_malloc" = "yes" ; then
2011   if test "$GNU_MALLOC" = yes ; then
2012     GNU_MALLOC_reason="
2013       (Using Doug Lea's new malloc from the GNU C Library.)"
2014   fi
2015   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2016     [Define to 1 if the system memory allocator is Doug Lea style,
2017      with malloc hooks and malloc_set_state.])
2018
2019   ## Use mmap directly for allocating larger buffers.
2020   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2021   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2022   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2023   case "$opsys" in
2024     gnu*) REL_ALLOC=no ;;
2025   esac
2026 fi
2027
2028 if test x"${REL_ALLOC}" = x; then
2029   REL_ALLOC=${GNU_MALLOC}
2030 fi
2031
2032 use_mmap_for_buffers=no
2033 case "$opsys" in
2034   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2035 esac
2036
2037 AC_FUNC_MMAP
2038 if test $use_mmap_for_buffers = yes; then
2039   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2040   REL_ALLOC=no
2041 fi
2042
2043 LIBS="$LIBS_SYSTEM $LIBS"
2044
2045 dnl If found, this adds -ldnet to LIBS, which Autoconf uses for checks.
2046 AC_CHECK_LIB(dnet, dnet_ntoa)
2047 dnl This causes -lresolv to get used in subsequent tests,
2048 dnl which causes failures on some systems such as HPUX 9.
2049 dnl AC_CHECK_LIB(resolv, gethostbyname)
2050
2051 dnl FIXME replace main with a function we actually want from this library.
2052 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2053
2054 dnl Check if pthreads is available.
2055 LIB_PTHREAD=
2056 AC_CHECK_HEADERS_ONCE(pthread.h)
2057 if test "$ac_cv_header_pthread_h"; then
2058   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
2059   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
2060   dnl testing for pthread_self if Emacs uses gmalloc.c.
2061   if test "$GMALLOC_OBJ" = gmalloc.o; then
2062     emacs_pthread_function=pthread_atfork
2063   else
2064     emacs_pthread_function=pthread_self
2065   fi
2066   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
2067 fi
2068 if test "$HAVE_PTHREAD" = yes; then
2069   case "${canonical}" in
2070     *-hpux*) ;;
2071     *) LIB_PTHREAD="-lpthread"
2072        LIBS="$LIB_PTHREAD $LIBS" ;;
2073   esac
2074   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
2075 fi
2076 AC_SUBST([LIB_PTHREAD])
2077
2078 AC_CHECK_LIB(pthreads, cma_open)
2079
2080 ## Note: when using cpp in s/aix4.2.h, this definition depended on
2081 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
2082 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
2083 ## added to LIBS in configure would never contain the pthreads part,
2084 ## but the value used in Makefiles might.  FIXME?
2085 ##
2086 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
2087 ## be harmless on older versions of X where it happens to exist.
2088 test "$opsys" = "aix4-2" && \
2089   test $ac_cv_lib_pthreads_cma_open = yes && \
2090   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
2091
2092 dnl Check for need for bigtoc support on IBM AIX
2093
2094 case ${host_os} in
2095 aix*)
2096   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2097     case $GCC in
2098     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2099     *) gdb_cv_bigtoc=-bbigtoc ;;
2100     esac
2101
2102     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2103     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2104   ])
2105   ;;
2106 esac
2107
2108 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
2109 # used for the tests that follow.  We set them back to REAL_CFLAGS and
2110 # REAL_CPPFLAGS later on.
2111
2112 REAL_CFLAGS="$CFLAGS"
2113 REAL_CPPFLAGS="$CPPFLAGS"
2114
2115 if test "${HAVE_X11}" = "yes"; then
2116   DEFS="$C_SWITCH_X_SITE $DEFS"
2117   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2118   LIBS="-lX11 $LIBS"
2119   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2120   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2121
2122   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2123   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2124   # but it's more convenient here to set LD_RUN_PATH since this
2125   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2126   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2127     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2128     export LD_RUN_PATH
2129   fi
2130
2131   if test "${opsys}" = "gnu-linux"; then
2132     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2133     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2134      [[XOpenDisplay ("foo");]])],
2135      [xgnu_linux_first_failure=no],
2136      [xgnu_linux_first_failure=yes])
2137     if test "${xgnu_linux_first_failure}" = "yes"; then
2138       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
2139       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
2140       OLD_CPPFLAGS="$CPPFLAGS"
2141       OLD_LIBS="$LIBS"
2142       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2143       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2144       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2145       LIBS="$LIBS -b i486-linuxaout"
2146       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2147        [[XOpenDisplay ("foo");]])],
2148        [xgnu_linux_second_failure=no],
2149        [xgnu_linux_second_failure=yes])
2150       if test "${xgnu_linux_second_failure}" = "yes"; then
2151         # If we get the same failure with -b, there is no use adding -b.
2152         # So take it out.  This plays safe.
2153         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
2154         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
2155         CPPFLAGS="$OLD_CPPFLAGS"
2156         LIBS="$OLD_LIBS"
2157         AC_MSG_RESULT(no)
2158       else
2159         AC_MSG_RESULT(yes)
2160       fi
2161     else
2162       AC_MSG_RESULT(no)
2163     fi
2164   fi
2165
2166   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2167   # header files included from there.
2168   AC_MSG_CHECKING(for Xkb)
2169   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2170 #include <X11/XKBlib.h>]],
2171         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2172         emacs_xkb=yes, emacs_xkb=no)
2173   AC_MSG_RESULT($emacs_xkb)
2174   if test $emacs_xkb = yes; then
2175     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2176   fi
2177
2178   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2179 XScreenNumberOfScreen)
2180 fi
2181
2182 if test "${window_system}" = "x11"; then
2183   AC_MSG_CHECKING(X11 version 6)
2184   AC_CACHE_VAL(emacs_cv_x11_version_6,
2185   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2186 [[#if XlibSpecificationRelease < 6
2187 fail;
2188 #endif
2189 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2190   if test $emacs_cv_x11_version_6 = yes; then
2191     AC_MSG_RESULT(6 or newer)
2192     AC_DEFINE(HAVE_X11R6, 1,
2193               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2194     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2195     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2196     ## XIM support.
2197     case "$opsys" in
2198       sol2-*) : ;;
2199       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2200            [Define if you have usable X11R6-style XIM support.])
2201          ;;
2202     esac
2203   else
2204     AC_MSG_RESULT(before 6)
2205   fi
2206 fi
2207
2208
2209 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2210 HAVE_RSVG=no
2211 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2212   if test "${with_rsvg}" != "no"; then
2213     RSVG_REQUIRED=2.11.0
2214     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2215
2216     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
2217     AC_SUBST(RSVG_CFLAGS)
2218     AC_SUBST(RSVG_LIBS)
2219
2220     if test $HAVE_RSVG = yes; then
2221       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2222       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2223       # Windows loads librsvg dynamically
2224       if test "${opsys}" = "mingw32"; then
2225         RSVG_LIBS=
2226       fi
2227       LIBS="$RSVG_LIBS $LIBS"
2228     fi
2229   fi
2230 fi
2231
2232 HAVE_IMAGEMAGICK=no
2233 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2234   if test "${with_imagemagick}" != "no"; then
2235     ## 6.2.8 is the earliest version known to work, but earlier versions
2236     ## might work - let us know if you find one.
2237     ## 6.0.7 does not work.  See bug#7955.
2238     ## 6.8.2 makes Emacs crash; see Bug#13867.
2239     IMAGEMAGICK_MODULE="Wand >= 6.2.8 Wand != 6.8.2"
2240     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
2241     AC_SUBST(IMAGEMAGICK_CFLAGS)
2242     AC_SUBST(IMAGEMAGICK_LIBS)
2243
2244     if test $HAVE_IMAGEMAGICK = yes; then
2245       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2246       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2247       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2248       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2249     fi
2250   fi
2251 fi
2252
2253
2254 HAVE_GTK=no
2255 GTK_OBJ=
2256 gtk_term_header=$term_header
2257 check_gtk2=no
2258 gtk3_pkg_errors=
2259 if test "${opsys}" != "mingw32"; then
2260   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2261     GLIB_REQUIRED=2.28
2262     GTK_REQUIRED=3.0
2263     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2264
2265     dnl Checks for libraries.
2266     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2267     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2268        AC_MSG_ERROR($GTK_PKG_ERRORS)
2269     fi
2270     if test "$pkg_check_gtk" = "yes"; then
2271        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2272        GTK_OBJ=emacsgtkfixed.o
2273        gtk_term_header=gtkutil.h
2274        USE_GTK_TOOLKIT="GTK3"
2275        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2276          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2277            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2278          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2279            [Define to 1 to disable Glib deprecation warnings.])
2280        fi
2281     else
2282        check_gtk2=yes
2283        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2284     fi
2285   fi
2286
2287   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2288     GLIB_REQUIRED=2.10
2289     GTK_REQUIRED=2.10
2290     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2291
2292     dnl Checks for libraries.
2293     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2294     if test "$pkg_check_gtk" = "no" &&
2295        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2296     then
2297       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2298     fi
2299     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2300   fi
2301 fi
2302
2303 if test x"$pkg_check_gtk" = xyes; then
2304
2305   AC_SUBST(GTK_LIBS)
2306   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2307   CFLAGS="$CFLAGS $GTK_CFLAGS"
2308   LIBS="$GTK_LIBS $LIBS"
2309   dnl Try to compile a simple GTK program.
2310   AC_MSG_CHECKING([whether GTK compiles])
2311   GTK_COMPILES=no
2312   AC_LINK_IFELSE(
2313     [AC_LANG_PROGRAM(
2314        [[/* Check the Gtk and Glib APIs.  */
2315          #include <gtk/gtk.h>
2316          #include <glib-object.h>
2317          static void
2318          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2319          {}
2320        ]],
2321        [[
2322          GtkSettings *gs = 0;
2323          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2324             strict C prohibits this.  Use gtk_main_iteration to test that the
2325             libraries are there.  */
2326          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2327                                     0, 0, 0, G_CALLBACK (callback), 0))
2328            gtk_main_iteration ();
2329        ]])],
2330     [GTK_COMPILES=yes])
2331   AC_MSG_RESULT([$GTK_COMPILES])
2332   if test "${GTK_COMPILES}" != "yes"; then
2333     GTK_OBJ=
2334     if test "$USE_X_TOOLKIT" != "maybe"; then
2335       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2336     fi
2337   else
2338     HAVE_GTK=yes
2339     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2340     GTK_OBJ="gtkutil.o $GTK_OBJ"
2341     term_header=$gtk_term_header
2342     USE_X_TOOLKIT=none
2343     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2344       :
2345     else
2346       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2347        closing open displays.  This is no problem if you just use
2348        one display, but if you use more than one and close one of them
2349        Emacs may crash.]])
2350       sleep 3
2351     fi
2352   fi
2353
2354 fi
2355 AC_SUBST(GTK_OBJ)
2356
2357
2358 if test "${HAVE_GTK}" = "yes"; then
2359
2360   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2361   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2362   if test "$with_toolkit_scroll_bars" != no; then
2363     with_toolkit_scroll_bars=yes
2364   fi
2365
2366   dnl  Check if we have the old file selection dialog declared and
2367   dnl  in the link library.  In 2.x it may be in the library,
2368   dnl  but not declared if deprecated featured has been selected out.
2369   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2370   HAVE_GTK_FILE_SELECTION=no
2371   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2372                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2373 #include <gtk/gtk.h>])
2374   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2375     AC_CHECK_FUNCS(gtk_file_selection_new)
2376   fi
2377
2378   dnl Same as above for gtk_handle_box.
2379   HAVE_GTK_HANDLE_BOX=no
2380   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2381                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2382 #include <gtk/gtk.h>])
2383   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2384     AC_CHECK_FUNCS(gtk_handle_box_new)
2385   fi
2386
2387   dnl Same as above for gtk_tearoff_menu_item.
2388   HAVE_GTK_TEAROFF_MENU_ITEM=no
2389   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2390                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2391 #include <gtk/gtk.h>])
2392   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2393     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2394   fi
2395
2396   dnl Check for functions introduced in 2.14 and later.
2397   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2398                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2399                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2400                  gtk_orientable_set_orientation \
2401                  gtk_window_set_has_resize_grip)
2402
2403  term_header=gtkutil.h
2404 fi
2405
2406 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2407 dnl other platforms.
2408 HAVE_DBUS=no
2409 DBUS_OBJ=
2410 if test "${with_dbus}" = "yes"; then
2411    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2412    if test "$HAVE_DBUS" = yes; then
2413      LIBS="$LIBS $DBUS_LIBS"
2414      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2415      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2416      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2417      dnl D-Bus 1.5.12.
2418      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2419                     dbus_type_is_valid \
2420                     dbus_validate_bus_name \
2421                     dbus_validate_path \
2422                     dbus_validate_interface \
2423                     dbus_validate_member)
2424      DBUS_OBJ=dbusbind.o
2425    fi
2426 fi
2427 AC_SUBST(DBUS_OBJ)
2428
2429 dnl GSettings has been tested under GNU/Linux only.
2430 HAVE_GSETTINGS=no
2431 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2432    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2433    if test "$HAVE_GSETTINGS" = "yes"; then
2434       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2435       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2436       SETTINGS_LIBS="$GSETTINGS_LIBS"
2437    fi
2438 fi
2439
2440 dnl GConf has been tested under GNU/Linux only.
2441 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2442 HAVE_GCONF=no
2443 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2444    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2445    if test "$HAVE_GCONF" = yes; then
2446       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2447       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2448       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2449       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2450    fi
2451 fi
2452
2453 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2454     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2455     if test "$HAVE_GOBJECT" = "yes"; then
2456        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2457        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2458     fi
2459     SAVE_CFLAGS="$CFLAGS"
2460     SAVE_LIBS="$LIBS"
2461     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2462     LIBS="$SETTINGS_LIBS $LIBS"
2463     CFLAGS="$SAVE_CFLAGS"
2464     LIBS="$SAVE_LIBS"
2465 fi
2466 AC_SUBST(SETTINGS_CFLAGS)
2467 AC_SUBST(SETTINGS_LIBS)
2468
2469
2470 dnl SELinux is available for GNU/Linux only.
2471 HAVE_LIBSELINUX=no
2472 LIBSELINUX_LIBS=
2473 if test "${with_selinux}" = "yes"; then
2474    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2475    if test "$HAVE_LIBSELINUX" = yes; then
2476       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2477       LIBSELINUX_LIBS=-lselinux
2478    fi
2479 fi
2480 AC_SUBST(LIBSELINUX_LIBS)
2481
2482 HAVE_GNUTLS=no
2483 HAVE_GNUTLS3=no
2484 if test "${with_gnutls}" = "yes" ; then
2485   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.0.0], HAVE_GNUTLS3=yes, HAVE_GNUTLS3=no)
2486   if test "${HAVE_GNUTLS3}" = "yes"; then
2487     AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])
2488     HAVE_GNUTLS="yes"
2489   else
2490     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2491   fi
2492   if test "${HAVE_GNUTLS}" = "yes"; then
2493     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2494   fi
2495
2496   # Windows loads GnuTLS dynamically
2497   if test "${opsys}" = "mingw32"; then
2498     LIBGNUTLS_LIBS=
2499   else
2500     CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2501     LIBS="$LIBGNUTLS_LIBS $LIBS"
2502   fi
2503 fi
2504
2505 AC_SUBST(LIBGNUTLS_LIBS)
2506 AC_SUBST(LIBGNUTLS_CFLAGS)
2507
2508 NOTIFY_OBJ=
2509 NOTIFY_SUMMARY=no
2510
2511 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2512 dnl a particular library.  This doesn't make much sense?
2513 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2514   with_file_notification=no
2515 fi
2516
2517 dnl MS Windows native file monitor is available for mingw32 only.
2518 case $with_file_notification,$opsys in
2519   w32,* | yes,mingw32)
2520     AC_CHECK_HEADER(windows.h)
2521     if test "$ac_cv_header_windows_h" = yes ; then
2522        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2523        NOTIFY_OBJ=w32notify.o
2524        NOTIFY_SUMMARY="yes (w32)"
2525     fi ;;
2526 esac
2527
2528 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2529 dnl has been added in glib 2.24.  It has been tested under
2530 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2531 dnl only sense when glib has been compiled with inotify support.  How
2532 dnl to check?
2533 case $with_file_notification,$NOTIFY_OBJ in
2534   gfile, | yes,)
2535     PKG_CHECK_MODULES(GFILENOTIFY, gio-2.0 >= 2.24, HAVE_GFILENOTIFY=yes, HAVE_GFILENOTIFY=no)
2536     if test "$HAVE_GFILENOTIFY" = "yes"; then
2537        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2538        NOTIFY_OBJ=gfilenotify.o
2539        NOTIFY_SUMMARY="yes -lgio (gfile)"
2540     fi ;;
2541 esac
2542
2543 dnl inotify is only available on GNU/Linux.
2544 case $with_file_notification,$NOTIFY_OBJ in
2545   inotify, | yes,)
2546     AC_CHECK_HEADER(sys/inotify.h)
2547     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2548         AC_CHECK_FUNC(inotify_init1)
2549         if test "$ac_cv_func_inotify_init1" = yes; then
2550           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2551           NOTIFY_OBJ=inotify.o
2552           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2553        fi
2554     fi ;;
2555 esac
2556
2557 case $with_file_notification,$NOTIFY_OBJ in
2558   yes,* | no,* | *,?*) ;;
2559   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2560 esac
2561
2562 if test -n "$NOTIFY_OBJ"; then
2563    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2564 fi
2565 AC_SUBST(NOTIFY_OBJ)
2566 AC_SUBST(GFILENOTIFY_CFLAGS)
2567 AC_SUBST(GFILENOTIFY_LIBS)
2568
2569 dnl Do not put whitespace before the #include statements below.
2570 dnl Older compilers (eg sunos4 cc) choke on it.
2571 HAVE_XAW3D=no
2572 LUCID_LIBW=
2573 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2574   if test "$with_xaw3d" != no; then
2575     AC_CACHE_VAL(emacs_cv_xaw3d,
2576     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2577 #include <X11/Intrinsic.h>
2578 #include <X11/Xaw3d/Simple.h>]],
2579       [[]])],
2580       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2581                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2582       emacs_cv_xaw3d=no)])
2583   else
2584     emacs_cv_xaw3d=no
2585   fi
2586   if test $emacs_cv_xaw3d = yes; then
2587     AC_MSG_CHECKING(for xaw3d)
2588     AC_MSG_RESULT([yes; using Lucid toolkit])
2589     USE_X_TOOLKIT=LUCID
2590     HAVE_XAW3D=yes
2591     LUCID_LIBW=-lXaw3d
2592     AC_DEFINE(HAVE_XAW3D, 1,
2593               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2594   else
2595     AC_MSG_CHECKING(for xaw3d)
2596     AC_MSG_RESULT(no)
2597     AC_MSG_CHECKING(for libXaw)
2598     AC_CACHE_VAL(emacs_cv_xaw,
2599     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2600 #include <X11/Intrinsic.h>
2601 #include <X11/Xaw/Simple.h>]],
2602       [[]])],
2603       emacs_cv_xaw=yes,
2604       emacs_cv_xaw=no)])
2605     if test $emacs_cv_xaw = yes; then
2606       AC_MSG_RESULT([yes; using Lucid toolkit])
2607       USE_X_TOOLKIT=LUCID
2608       LUCID_LIBW=-lXaw
2609     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2610       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2611     else
2612       AC_MSG_ERROR([No X toolkit could be found.
2613 If you are sure you want Emacs compiled without an X toolkit, pass
2614   --with-x-toolkit=no
2615 to configure.  Otherwise, install the development libraries for the toolkit
2616 that you want to use (e.g. Gtk+) and re-run configure.])
2617     fi
2618   fi
2619 fi
2620
2621 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2622
2623 LIBXTR6=
2624 if test "${USE_X_TOOLKIT}" != "none"; then
2625   AC_MSG_CHECKING(X11 toolkit version)
2626   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2627   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2628 [[#if XtSpecificationRelease < 6
2629 fail;
2630 #endif
2631 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2632   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2633   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2634     AC_MSG_RESULT(6 or newer)
2635     AC_DEFINE(HAVE_X11XTR6, 1,
2636               [Define to 1 if you have the X11R6 or newer version of Xt.])
2637     LIBXTR6="-lSM -lICE"
2638     case "$opsys" in
2639       ## Use libw.a along with X11R6 Xt.
2640       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2641     esac
2642   else
2643     AC_MSG_RESULT(before 6)
2644   fi
2645
2646 dnl If using toolkit, check whether libXmu.a exists.
2647 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2648   OLDLIBS="$LIBS"
2649   if test x$HAVE_X11XTR6 = xyes; then
2650     LIBS="-lXt -lSM -lICE $LIBS"
2651   else
2652     LIBS="-lXt $LIBS"
2653   fi
2654   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2655   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2656   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2657 fi
2658 AC_SUBST(LIBXTR6)
2659
2660 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2661 dnl Why not just test for libxmu in the normal way?
2662 LIBXMU=-lXmu
2663 case $opsys in
2664   ## These systems don't supply Xmu.
2665   hpux* | aix4-2 )
2666     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2667     ;;
2668   mingw32 )
2669     LIBXMU=
2670     ;;
2671 esac
2672 AC_SUBST(LIBXMU)
2673
2674 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2675 if test "${HAVE_X11}" = "yes"; then
2676   if test "${USE_X_TOOLKIT}" != "none"; then
2677     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2678   fi
2679 fi
2680
2681 LIBXP=
2682 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2683   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2684   if test -d /usr/include/openmotif; then
2685     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2686     emacs_cv_openmotif=yes
2687     case "$canonical" in
2688       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2689       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2690       ;;
2691       *)
2692       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2693     esac
2694   else
2695     emacs_cv_openmotif=no
2696   fi
2697   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2698   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2699     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2700 int x = 5;
2701 #else
2702 Motif version prior to 2.1.
2703 #endif]])],
2704     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2705   if test $emacs_cv_motif_version_2_1 = yes; then
2706     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2707     if test x$emacs_cv_openmotif = xyes; then
2708       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2709     fi
2710   else
2711     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2712     # We put this in CFLAGS temporarily to precede other -I options
2713     # that might be in CFLAGS temporarily.
2714     # We put this in CPPFLAGS where it precedes the other -I options.
2715     OLD_CPPFLAGS=$CPPFLAGS
2716     OLD_CFLAGS=$CFLAGS
2717     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2718     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2719     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2720       [[int x = 5;]])],
2721       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2722     if test $emacs_cv_lesstif = yes; then
2723       # Make sure this -I option remains in CPPFLAGS after it is set
2724       # back to REAL_CPPFLAGS.
2725       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2726       # have those other -I options anyway.  Ultimately, having this
2727       # directory ultimately in CPPFLAGS will be enough.
2728       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2729       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2730     else
2731       CFLAGS=$OLD_CFLAGS
2732       CPPFLAGS=$OLD_CPPFLAGS
2733     fi
2734   fi
2735   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2736     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2737 fi
2738
2739 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2740 dnl using Motif or Xaw3d is available, and unless
2741 dnl --with-toolkit-scroll-bars=no was specified.
2742
2743 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2744             [Define to 1 if we should use toolkit scroll bars.])dnl
2745 USE_TOOLKIT_SCROLL_BARS=no
2746 if test "${with_toolkit_scroll_bars}" != "no"; then
2747   if test "${USE_X_TOOLKIT}" != "none"; then
2748     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2749       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2750       HAVE_XAW3D=no
2751       USE_TOOLKIT_SCROLL_BARS=yes
2752     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2753       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2754       USE_TOOLKIT_SCROLL_BARS=yes
2755     fi
2756   elif test "${HAVE_GTK}" = "yes"; then
2757     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2758     USE_TOOLKIT_SCROLL_BARS=yes
2759   elif test "${HAVE_NS}" = "yes"; then
2760     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2761     USE_TOOLKIT_SCROLL_BARS=yes
2762   elif test "${HAVE_W32}" = "yes"; then
2763     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2764     USE_TOOLKIT_SCROLL_BARS=yes
2765   fi
2766 fi
2767
2768 dnl See if XIM is available.
2769 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2770           #include <X11/Xlib.h>
2771           #include <X11/Xresource.h>]],
2772          [[XIMProc  callback;]])],
2773          [HAVE_XIM=yes
2774          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2775          HAVE_XIM=no)
2776
2777 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2778
2779 if test "${with_xim}" != "no"; then
2780   AC_DEFINE(USE_XIM, 1,
2781             [Define to 1 if we should use XIM, if it is available.])
2782 fi
2783
2784
2785 if test "${HAVE_XIM}" != "no"; then
2786   late_CFLAGS=$CFLAGS
2787   if test "$GCC" = yes; then
2788     CFLAGS="$CFLAGS --pedantic-errors"
2789   fi
2790   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2791 #include <X11/Xlib.h>
2792 #include <X11/Xresource.h>]],
2793 [[Display *display;
2794 XrmDatabase db;
2795 char *res_name;
2796 char *res_class;
2797 XIMProc  callback;
2798 XPointer *client_data;
2799 #ifndef __GNUC__
2800 /* If we're not using GCC, it's probably not XFree86, and this is
2801    probably right, but we can't use something like --pedantic-errors.  */
2802 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2803                                            char*, XIMProc, XPointer*);
2804 #endif
2805 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2806    client_data);]])],
2807     [emacs_cv_arg6_star=yes])
2808   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2809          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2810 either XPointer or XPointer*.])dnl
2811   if test "$emacs_cv_arg6_star" = yes; then
2812     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2813   else
2814     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2815   fi
2816   CFLAGS=$late_CFLAGS
2817 fi
2818
2819 ### Start of font-backend (under any platform) section.
2820 # (nothing here yet -- this is a placeholder)
2821 ### End of font-backend (under any platform) section.
2822
2823 ### Start of font-backend (under X11) section.
2824 if test "${HAVE_X11}" = "yes"; then
2825    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2826
2827    ## Use -lXft if available, unless `--with-xft=no'.
2828    HAVE_XFT=maybe
2829     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2830       with_xft="no";
2831     fi
2832     if test "x${with_xft}" != "xno"; then
2833
2834       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2835       ## Because xftfont.c uses XRenderQueryExtension, we also
2836       ## need to link to -lXrender.
2837       HAVE_XRENDER=no
2838       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2839       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2840         OLD_CPPFLAGS="$CPPFLAGS"
2841         OLD_CFLAGS="$CFLAGS"
2842         OLD_LIBS="$LIBS"
2843         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2844         CFLAGS="$CFLAGS $XFT_CFLAGS"
2845         XFT_LIBS="-lXrender $XFT_LIBS"
2846         LIBS="$XFT_LIBS $LIBS"
2847         AC_CHECK_HEADER(X11/Xft/Xft.h,
2848           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2849           [[#include <X11/X.h>]])
2850
2851         if test "${HAVE_XFT}" = "yes"; then
2852           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2853             AC_SUBST(XFT_LIBS)
2854           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2855         else
2856           CPPFLAGS="$OLD_CPPFLAGS"
2857           CFLAGS="$OLD_CFLAGS"
2858           LIBS="$OLD_LIBS"
2859         fi                        # "${HAVE_XFT}" = "yes"
2860       fi                          # "$HAVE_XFT" != no
2861     fi                            # "x${with_xft}" != "xno"
2862
2863     ## We used to allow building with FreeType and without Xft.
2864     ## However, the ftx font backend driver is not in good shape.
2865     if test "$HAVE_XFT" != "yes"; then
2866        dnl For the "Does Emacs use" message at the end.
2867        HAVE_XFT=no
2868        HAVE_FREETYPE=no
2869     else
2870        dnl Strict linkers fail with
2871        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2872        dnl if -lfreetype is not specified.
2873        dnl The following is needed to set FREETYPE_LIBS.
2874        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2875                          HAVE_FREETYPE=no)
2876
2877        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2878     fi
2879
2880     HAVE_LIBOTF=no
2881     if test "${HAVE_FREETYPE}" = "yes"; then
2882       AC_DEFINE(HAVE_FREETYPE, 1,
2883                 [Define to 1 if using the freetype and fontconfig libraries.])
2884       if test "${with_libotf}" != "no"; then
2885         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2886                           HAVE_LIBOTF=no)
2887         if test "$HAVE_LIBOTF" = "yes"; then
2888           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2889           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2890                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2891                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2892           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2893             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2894                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2895           fi
2896         fi
2897       fi
2898     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2899     dnl Does the new font backend require it, or can it work without it?
2900     fi
2901
2902     HAVE_M17N_FLT=no
2903     if test "${HAVE_LIBOTF}" = yes; then
2904       if test "${with_m17n_flt}" != "no"; then
2905         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2906         if test "$HAVE_M17N_FLT" = "yes"; then
2907           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2908         fi
2909       fi
2910     fi
2911 else
2912     HAVE_XFT=no
2913     HAVE_FREETYPE=no
2914     HAVE_LIBOTF=no
2915     HAVE_M17N_FLT=no
2916 fi
2917
2918 ### End of font-backend (under X11) section.
2919
2920 AC_SUBST(FREETYPE_CFLAGS)
2921 AC_SUBST(FREETYPE_LIBS)
2922 AC_SUBST(FONTCONFIG_CFLAGS)
2923 AC_SUBST(FONTCONFIG_LIBS)
2924 AC_SUBST(LIBOTF_CFLAGS)
2925 AC_SUBST(LIBOTF_LIBS)
2926 AC_SUBST(M17N_FLT_CFLAGS)
2927 AC_SUBST(M17N_FLT_LIBS)
2928
2929 ### Use -lXpm if available, unless `--with-xpm=no'.
2930 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2931 HAVE_XPM=no
2932 LIBXPM=
2933 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
2934   if test "${with_xpm}" != "no"; then
2935     SAVE_CPPFLAGS="$CPPFLAGS"
2936     SAVE_LDFLAGS="$LDFLAGS"
2937     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2938     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2939     AC_CHECK_HEADER(X11/xpm.h,
2940       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2941     if test "${HAVE_XPM}" = "yes"; then
2942       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2943       AC_EGREP_CPP(no_return_alloc_pixels,
2944       [#include "X11/xpm.h"
2945 #ifndef XpmReturnAllocPixels
2946 no_return_alloc_pixels
2947 #endif
2948       ], HAVE_XPM=no, HAVE_XPM=yes)
2949
2950       if test "${HAVE_XPM}" = "yes"; then
2951         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2952         AC_MSG_RESULT(yes)
2953       else
2954         AC_MSG_RESULT(no)
2955         CPPFLAGS="$SAVE_CPPFLAGS"
2956         LDFLAGS="$SAVE_LDFLAGS"
2957       fi
2958     fi
2959   fi
2960
2961   if test "${HAVE_XPM}" = "yes"; then
2962     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2963     LIBXPM=-lXpm
2964   fi
2965 fi
2966
2967 if test "${HAVE_X11}" = "yes"; then
2968   if test "${with_xpm}" != "no"; then
2969     AC_CHECK_HEADER(X11/xpm.h,
2970       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2971     if test "${HAVE_XPM}" = "yes"; then
2972       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2973       AC_EGREP_CPP(no_return_alloc_pixels,
2974       [#include "X11/xpm.h"
2975 #ifndef XpmReturnAllocPixels
2976 no_return_alloc_pixels
2977 #endif
2978       ], HAVE_XPM=no, HAVE_XPM=yes)
2979
2980       if test "${HAVE_XPM}" = "yes"; then
2981         AC_MSG_RESULT(yes)
2982       else
2983         AC_MSG_RESULT(no)
2984       fi
2985     fi
2986   fi
2987
2988   if test "${HAVE_XPM}" = "yes"; then
2989     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2990     LIBXPM=-lXpm
2991   fi
2992 fi
2993
2994 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
2995 ### slightly different requirements wrt image libraries (it doesn't
2996 ### use -lXpm because it loads the xpm shared library dynamically at
2997 ### run time).
2998 if test "${opsys}" = "mingw32"; then
2999   if test "${with_xpm}" != "no"; then
3000     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3001 #define FOR_MSW 1])
3002   fi
3003
3004   if test "${HAVE_XPM}" = "yes"; then
3005     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3006   fi
3007 fi
3008
3009 AC_SUBST(LIBXPM)
3010
3011 ### Use -ljpeg if available, unless `--with-jpeg=no'.
3012 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
3013 HAVE_JPEG=no
3014 LIBJPEG=
3015 if test "${opsys}" = "mingw32"; then
3016   if test "${with_jpeg}" != "no"; then
3017     dnl Checking for jpeglib.h can lose because of a redefinition of
3018     dnl HAVE_STDLIB_H.
3019     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
3020   fi
3021   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3022   if test "${HAVE_JPEG}" = "yes"; then
3023     AC_DEFINE(HAVE_JPEG)
3024     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3025         [#include <jpeglib.h>
3026          version=JPEG_LIB_VERSION
3027 ],
3028         [AC_DEFINE(HAVE_JPEG)],
3029         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3030         HAVE_JPEG=no])
3031   fi
3032 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3033   if test "${with_jpeg}" != "no"; then
3034     dnl Checking for jpeglib.h can lose because of a redefinition of
3035     dnl  HAVE_STDLIB_H.
3036     AC_CHECK_HEADER(jerror.h,
3037       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
3038   fi
3039
3040   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3041   if test "${HAVE_JPEG}" = "yes"; then
3042     AC_DEFINE(HAVE_JPEG)
3043     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3044         [#include <jpeglib.h>
3045          version=JPEG_LIB_VERSION
3046 ],
3047         [AC_DEFINE(HAVE_JPEG)],
3048         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3049         HAVE_JPEG=no])
3050   fi
3051   if test "${HAVE_JPEG}" = "yes"; then
3052     LIBJPEG=-ljpeg
3053   fi
3054 fi
3055 AC_SUBST(LIBJPEG)
3056
3057 ### Use -lpng if available, unless `--with-png=no'.
3058 ### mingw32 doesn't use -lpng, since it loads the library dynamically.
3059 HAVE_PNG=no
3060 LIBPNG=
3061 if test "${opsys}" = "mingw32"; then
3062   if test "${with_png}" != "no"; then
3063     AC_CHECK_HEADER(png.h, HAVE_PNG=yes, HAVE_PNG=no)
3064   fi
3065   if test "${HAVE_PNG}" = "yes"; then
3066     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
3067
3068     AC_CHECK_DECL(png_longjmp,
3069       [],
3070       [AC_DEFINE(PNG_DEPSTRUCT, [],
3071          [Define to empty to suppress deprecation warnings when building
3072           with --enable-gcc-warnings and with libpng versions before 1.5,
3073           which lack png_longjmp.])],
3074       [[#ifdef HAVE_LIBPNG_PNG_H
3075         # include <libpng/png.h>
3076         #else
3077         # include <png.h>
3078         #endif
3079       ]])
3080   fi
3081 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3082   if test "${with_png}" != "no"; then
3083     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3084     # in /usr/include/libpng.
3085     AC_CHECK_HEADERS(png.h libpng/png.h, break)
3086     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
3087       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
3088     fi
3089   fi
3090
3091   if test "${HAVE_PNG}" = "yes"; then
3092     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
3093     LIBPNG="-lpng -lz -lm"
3094
3095     AC_CHECK_DECL(png_longjmp,
3096       [],
3097       [AC_DEFINE(PNG_DEPSTRUCT, [],
3098          [Define to empty to suppress deprecation warnings when building
3099           with --enable-gcc-warnings and with libpng versions before 1.5,
3100           which lack png_longjmp.])],
3101       [[#ifdef HAVE_LIBPNG_PNG_H
3102         # include <libpng/png.h>
3103         #else
3104         # include <png.h>
3105         #endif
3106       ]])
3107   fi
3108 fi
3109 AC_SUBST(LIBPNG)
3110
3111 HAVE_ZLIB=no
3112 LIBZ=
3113 if test "${with_zlib}" != "no"; then
3114   OLIBS=$LIBS
3115   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3116   LIBS=$OLIBS
3117   case $ac_cv_search_inflateEnd in
3118     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3119   esac
3120 fi
3121 if test "${HAVE_ZLIB}" = "yes"; then
3122   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3123   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3124   if test "${opsys}" = "mingw32"; then
3125      LIBZ=
3126   fi
3127 fi
3128 AC_SUBST(LIBZ)
3129
3130
3131 ### Use -ltiff if available, unless `--with-tiff=no'.
3132 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3133 HAVE_TIFF=no
3134 LIBTIFF=
3135 if test "${opsys}" = "mingw32"; then
3136   if test "${with_tiff}" != "no"; then
3137     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3138   fi
3139   if test "${HAVE_TIFF}" = "yes"; then
3140     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3141   fi
3142 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3143   if test "${with_tiff}" != "no"; then
3144     AC_CHECK_HEADER(tiffio.h,
3145       [tifflibs="-lz -lm"
3146       # At least one tiff package requires the jpeg library.
3147       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3148       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3149   fi
3150
3151   if test "${HAVE_TIFF}" = "yes"; then
3152     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3153     dnl FIXME -lz -lm, as per libpng?
3154     LIBTIFF=-ltiff
3155   fi
3156 fi
3157 AC_SUBST(LIBTIFF)
3158
3159 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3160 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3161 HAVE_GIF=no
3162 LIBGIF=
3163 if test "${opsys}" = "mingw32"; then
3164   if test "${with_gif}" != "no"; then
3165     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3166   fi
3167   if test "${HAVE_GIF}" = "yes"; then
3168     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3169   fi
3170 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3171         || test "${HAVE_W32}" = "yes"; then
3172   AC_CHECK_HEADER(gif_lib.h,
3173 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3174 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3175     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3176         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3177
3178   if test "$HAVE_GIF" = yes; then
3179     LIBGIF=-lgif
3180   elif test "$HAVE_GIF" = maybe; then
3181 # If gif_lib.h but no libgif, try libungif.
3182     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3183     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3184   fi
3185
3186   if test "${HAVE_GIF}" = "yes"; then
3187     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3188   fi
3189 fi
3190 AC_SUBST(LIBGIF)
3191
3192 dnl Check for required libraries.
3193 if test "${HAVE_X11}" = "yes"; then
3194   MISSING=""
3195   WITH_NO=""
3196   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3197     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3198   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3199     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3200   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3201     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3202   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3203     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3204   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3205     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3206
3207   if test "X${MISSING}" != X; then
3208     AC_MSG_ERROR([The following required libraries were not found:
3209     $MISSING
3210 Maybe some development libraries/packages are missing?
3211 If you don't want to link with them give
3212     $WITH_NO
3213 as options to configure])
3214   fi
3215 fi
3216
3217 ### Use -lgpm if available, unless `--with-gpm=no'.
3218 HAVE_GPM=no
3219 LIBGPM=
3220 if test "${with_gpm}" != "no"; then
3221   AC_CHECK_HEADER(gpm.h,
3222     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3223
3224   if test "${HAVE_GPM}" = "yes"; then
3225     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3226     LIBGPM=-lgpm
3227   fi
3228 fi
3229 AC_SUBST(LIBGPM)
3230
3231 dnl Check for malloc/malloc.h on darwin
3232 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3233
3234 GNUSTEP_CFLAGS=
3235 ### Use NeXTstep API to implement GUI.
3236 if test "${HAVE_NS}" = "yes"; then
3237   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3238   if test "${NS_IMPL_COCOA}" = "yes"; then
3239     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3240   fi
3241   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3242     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3243     # See also .m.o rule in Makefile.in */
3244     # FIXME: are all these flags really needed?  Document here why.  */
3245     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3246     ## Extra CFLAGS applied to src/*.m files.
3247     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3248   fi
3249   OTHER_FILES=ns-app
3250 fi
3251
3252 ### Use session management (-lSM -lICE) if available
3253 HAVE_X_SM=no
3254 LIBXSM=
3255 if test "${HAVE_X11}" = "yes"; then
3256   AC_CHECK_HEADER(X11/SM/SMlib.h,
3257     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3258
3259   if test "${HAVE_X_SM}" = "yes"; then
3260     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3261     LIBXSM="-lSM -lICE"
3262     case "$LIBS" in
3263       *-lSM*) ;;
3264       *)      LIBS="$LIBXSM $LIBS" ;;
3265     esac
3266   fi
3267 fi
3268 AC_SUBST(LIBXSM)
3269
3270 ### Use XRandr (-lXrandr) if available
3271 HAVE_XRANDR=no
3272 if test "${HAVE_X11}" = "yes"; then
3273   XRANDR_REQUIRED=1.2.2
3274   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3275   PKG_CHECK_MODULES(XRANDR, $XRANDR_MODULES, HAVE_XRANDR=yes, HAVE_XRANDR=no)
3276   if test $HAVE_XRANDR = no; then
3277     # Test old way in case pkg-config doesn't have it (older machines).
3278     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3279       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3280     if test $HAVE_XRANDR = yes; then
3281       XRANDR_LIBS=-lXrandr
3282       AC_SUBST(XRANDR_LIBS)
3283     fi
3284   fi
3285   if test $HAVE_XRANDR = yes; then
3286     SAVE_CFLAGS="$CFLAGS"
3287     SAVE_LIBS="$LIBS"
3288     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3289     LIBS="$XRANDR_LIBS $LIBS"
3290     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3291     CFLAGS="$SAVE_CFLAGS"
3292     LIBS="$SAVE_LIBS"
3293
3294     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3295   fi
3296 fi
3297
3298 ### Use Xinerama (-lXinerama) if available
3299 HAVE_XINERAMA=no
3300 if test "${HAVE_X11}" = "yes"; then
3301   XINERAMA_REQUIRED=1.0.2
3302   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3303   PKG_CHECK_MODULES(XINERAMA, $XINERAMA_MODULES, HAVE_XINERAMA=yes,
3304                     HAVE_XINERAMA=no)
3305   if test $HAVE_XINERAMA = no; then
3306     # Test old way in case pkg-config doesn't have it (older machines).
3307     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3308       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3309     if test $HAVE_XINERAMA = yes; then
3310       XINERAMA_LIBS=-lXinerama
3311       AC_SUBST(XINERAMA_LIBS)
3312     fi
3313   fi
3314   if test $HAVE_XINERAMA = yes; then
3315     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3316   fi
3317 fi
3318
3319
3320 ### Use libxml (-lxml2) if available
3321 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3322 HAVE_LIBXML2=no
3323 if test "${with_xml2}" != "no"; then
3324   ### I'm not sure what the version number should be, so I just guessed.
3325   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3326   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3327   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3328     SAVE_CPPFLAGS="$CPPFLAGS"
3329     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3330     AC_CHECK_HEADER(libxml/HTMLparser.h,
3331       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3332                      [#include <libxml/HTMLparser.h>])])
3333     CPPFLAGS="$SAVE_CPPFLAGS"
3334     if test "${HAVE_LIBXML2}" = "yes"; then
3335       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3336       LIBXML2_LIBS="-lxml2"
3337     fi
3338   fi
3339   if test "${HAVE_LIBXML2}" = "yes"; then
3340     if test "${opsys}" != "mingw32"; then
3341       LIBS="$LIBXML2_LIBS $LIBS"
3342       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3343     else
3344       LIBXML2_LIBS=""
3345     fi
3346     if test "${HAVE_LIBXML2}" = "yes"; then
3347       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3348     else
3349       LIBXML2_LIBS=""
3350       LIBXML2_CFLAGS=""
3351     fi
3352   fi
3353 fi
3354 AC_SUBST(LIBXML2_LIBS)
3355 AC_SUBST(LIBXML2_CFLAGS)
3356
3357 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3358 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3359 if test "${opsys}" = "mingw32"; then
3360   emacs_cv_netdb_declares_h_errno=yes
3361 fi
3362 AC_CACHE_CHECK(whether netdb declares h_errno,
3363                emacs_cv_netdb_declares_h_errno,
3364 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3365   [[return h_errno;]])],
3366   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3367 if test $emacs_cv_netdb_declares_h_errno = yes; then
3368   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3369 fi
3370
3371 # sqrt and other floating-point functions such as fmod and frexp
3372 # are found in -lm on most systems, but mingw32 doesn't use -lm.
3373 if test "${opsys}" != "mingw32"; then
3374   AC_CHECK_LIB(m, sqrt)
3375 fi
3376
3377 # Check for mail-locking functions in a "mail" library.  Probably this should
3378 # have the same check as for liblockfile below.
3379 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3380 if test $have_mail = yes; then
3381   LIBS_MAIL=-lmail
3382   LIBS="$LIBS_MAIL $LIBS"
3383   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3384 else
3385   LIBS_MAIL=
3386 fi
3387 dnl Debian, at least:
3388 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3389 if test $have_lockfile = yes; then
3390    LIBS_MAIL=-llockfile
3391    LIBS="$LIBS_MAIL $LIBS"
3392    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3393 else
3394 # If we have the shared liblockfile, assume we must use it for mail
3395 # locking (e.g. Debian).  If we couldn't link against liblockfile
3396 # (no liblockfile.a installed), ensure that we don't need to.
3397   dnl This works for files generally, not just executables.
3398   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3399   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3400                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3401   if test $ac_cv_prog_liblockfile = yes; then
3402     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3403 This probably means that movemail could lose mail.
3404 There may be a `development' package to install containing liblockfile.])
3405   fi
3406 fi
3407 AC_CHECK_HEADERS_ONCE(maillock.h)
3408 AC_SUBST(LIBS_MAIL)
3409
3410 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3411 ## interlock access to the mail spool.  The alternative is a lock file named
3412 ## /usr/spool/mail/$USER.lock.
3413 mail_lock=no
3414 case "$opsys" in
3415   aix4-2) mail_lock="lockf" ;;
3416
3417   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3418
3419   ## On GNU/Linux systems, both methods are used by various mail programs.
3420   ## I assume most people are using newer mailers that have heard of flock.
3421   ## Change this if you need to.
3422   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3423   ## configure gets the right answers, and that means *NOT* using flock.
3424   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3425   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3426   ## Debian maintainer hasn't provided a clean fix for Emacs.
3427   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3428   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3429   ## correct logic.  -- fx
3430   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3431   ## liblockfile is a Free Software replacement for libmail, used on
3432   ## Debian systems and elsewhere. -rfr.
3433   gnu-*)
3434     mail_lock="flock"
3435     if test $have_mail = yes || test $have_lockfile = yes; then
3436       test $ac_cv_header_maillock_h = yes && mail_lock=no
3437     fi
3438     ;;
3439
3440   mingw32)
3441     mail_lock="none-needed" ;;
3442 esac
3443
3444 BLESSMAIL_TARGET=
3445 case "$mail_lock" in
3446   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3447
3448   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3449
3450   none-needed) ;;
3451
3452   *) BLESSMAIL_TARGET="need-blessmail" ;;
3453 esac
3454 AC_SUBST(BLESSMAIL_TARGET)
3455
3456
3457 AC_CHECK_FUNCS(accept4 gethostname \
3458 getrusage get_current_dir_name \
3459 lrand48 \
3460 select getpagesize setlocale \
3461 getrlimit setrlimit shutdown getaddrinfo \
3462 strsignal setitimer \
3463 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3464 gai_strerror getline getdelim sync \
3465 getpwent endpwent getgrent endgrent \
3466 touchlock \
3467 cfmakeraw cfsetspeed copysign __executable_start log2)
3468
3469 dnl No need to check for aligned_alloc and posix_memalign if using
3470 dnl gmalloc.o, as it supplies them.  Don't use these functions on
3471 dnl Darwin as they are incompatible with unexmacosx.c.
3472 if test -z "$GMALLOC_OBJ" && test "$opsys" != darwin; then
3473   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3474 fi
3475
3476 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
3477 ## has a broken `rint' in some library versions including math library
3478 ## version number A.09.05.
3479 ## You can fix the math library by installing patch number PHSS_4630.
3480 ## But we can fix it more reliably for Emacs by just not using rint.
3481 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
3482 case $opsys in
3483    hpux*) : ;;
3484    *) AC_CHECK_FUNCS(random rint) ;;
3485 esac
3486
3487 dnl Cannot use AC_CHECK_FUNCS
3488 AC_CACHE_CHECK([for __builtin_unwind_init],
3489                emacs_cv_func___builtin_unwind_init,
3490 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3491                 emacs_cv_func___builtin_unwind_init=yes,
3492                 emacs_cv_func___builtin_unwind_init=no)])
3493 if test $emacs_cv_func___builtin_unwind_init = yes; then
3494   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3495             [Define to 1 if you have the `__builtin_unwind_init' function.])
3496 fi
3497
3498 AC_CHECK_HEADERS_ONCE(sys/un.h)
3499
3500 AC_FUNC_FSEEKO
3501
3502 # UNIX98 PTYs.
3503 AC_CHECK_FUNCS(grantpt)
3504
3505 # PTY-related GNU extensions.
3506 AC_CHECK_FUNCS(getpt posix_openpt)
3507
3508 # Check this now, so that we will NOT find the above functions in ncurses.
3509 # That is because we have not set up to link ncurses in lib-src.
3510 # It's better to believe a function is not available
3511 # than to expect to find it in ncurses.
3512 # Also we need tputs and friends to be able to build at all.
3513 AC_MSG_CHECKING([for library containing tputs])
3514 # Run a test program that contains a call to tputs, a call that is
3515 # never executed.  This tests whether a pre-'main' dynamic linker
3516 # works with the library.  It's too much trouble to actually call
3517 # tputs in the test program, due to portability hassles.  When
3518 # cross-compiling, assume the test program will run if it links.
3519 AC_DEFUN([tputs_link_source], [
3520   AC_LANG_SOURCE(
3521      [[extern void tputs (const char *, int, int (*)(int));
3522        int main (int argc, char **argv)
3523        {
3524           if (argc == 10000)
3525             tputs (argv[0], 0, 0);
3526           return 0;
3527        }]])
3528 ])
3529 if test "${opsys}" = "mingw32"; then
3530   msg='none required'
3531 else
3532   # Maybe curses should be tried earlier?
3533   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3534   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3535     OLIBS=$LIBS
3536     if test -z "$tputs_library"; then
3537       LIBS_TERMCAP=
3538       msg='none required'
3539     else
3540       LIBS_TERMCAP=-l$tputs_library
3541       msg=$LIBS_TERMCAP
3542       LIBS="$LIBS_TERMCAP $LIBS"
3543     fi
3544     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3545       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3546     LIBS=$OLIBS
3547     if test "X$msg" != Xno; then
3548       break
3549     fi
3550   done
3551 fi
3552 AC_MSG_RESULT([$msg])
3553 if test "X$msg" = Xno; then
3554   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3555 The following libraries were tried (in order):
3556   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3557 Please try installing whichever of these libraries is most appropriate
3558 for your system, together with its header files.
3559 For example, a libncurses-dev(el) or similar package.])
3560 fi
3561
3562 ## Use termcap instead of terminfo?
3563 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3564 TERMINFO=yes
3565 ## FIXME?  In the cases below where we unconditionally set
3566 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3567 ## if that was found above to have tputs.
3568 ## Should we use the gnu* logic everywhere?
3569 case "$opsys" in
3570   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3571   ##  The ncurses library has been moved out of the System framework in
3572   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3573   ##  option to use it.
3574   darwin) LIBS_TERMCAP="-lncurses" ;;
3575
3576   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3577
3578   freebsd)
3579     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3580     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3581     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3582 [[#if __FreeBSD_version < 400000
3583 fail;
3584 #endif
3585 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3586
3587     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3588
3589     if test $emacs_cv_freebsd_terminfo = yes; then
3590       LIBS_TERMCAP="-lncurses"
3591     else
3592       TERMINFO=no
3593       LIBS_TERMCAP="-ltermcap"
3594     fi
3595     ;;
3596
3597   mingw32)
3598     TERMINFO=no
3599     LIBS_TERMCAP=
3600     ;;
3601
3602   netbsd)
3603     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3604       TERMINFO=no
3605       LIBS_TERMCAP="-ltermcap"
3606     fi
3607     ;;
3608
3609   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3610
3611   ## hpux: Make sure we get select from libc rather than from libcurses
3612   ##  because libcurses on HPUX 10.10 has a broken version of select.
3613   ##  We used to use -lc -lcurses, but this may be cleaner.
3614   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3615   # set that way, now it uses the default).  Isn't this a contradiction?
3616   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3617
3618 esac
3619
3620 TERMCAP_OBJ=tparam.o
3621 if test $TERMINFO = yes; then
3622   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3623   TERMCAP_OBJ=terminfo.o
3624 fi
3625 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3626   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3627 fi
3628 AC_SUBST(LIBS_TERMCAP)
3629 AC_SUBST(TERMCAP_OBJ)
3630
3631
3632 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3633 # On Darwin, res_init appears not to be useful: see bug#562 and
3634 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3635 resolv=no
3636
3637 if test $opsys != darwin; then
3638
3639   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3640 #include <arpa/nameser.h>
3641 #include <resolv.h>]],
3642     [[return res_init();]])],
3643     have_res_init=yes, have_res_init=no)
3644   if test "$have_res_init" = no; then
3645     OLIBS="$LIBS"
3646     LIBS="$LIBS -lresolv"
3647     AC_MSG_CHECKING(for res_init with -lresolv)
3648     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3649 #include <arpa/nameser.h>
3650 #include <resolv.h>]],
3651       [[return res_init();]])],
3652       have_res_init=yes, have_res_init=no)
3653     AC_MSG_RESULT($have_res_init)
3654     if test "$have_res_init" = yes ; then
3655       resolv=yes
3656     fi
3657     LIBS="$OLIBS"
3658   fi
3659
3660   if test "$have_res_init" = yes; then
3661     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3662   fi
3663 fi                              dnl !darwin
3664
3665 # Do we need the Hesiod library to provide the support routines?
3666 dnl FIXME?  Should we be skipping this on Darwin too?
3667 LIBHESIOD=
3668 if test "$with_hesiod" != no ; then
3669   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3670   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3671      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3672                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3673   if test "$resolv" = yes ; then
3674     RESOLVLIB=-lresolv
3675   else
3676     RESOLVLIB=
3677   fi
3678   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3679         hesiod=yes, :, $RESOLVLIB)])
3680
3681   if test x"$hesiod" = xyes; then
3682     LIBHESIOD=-lhesiod
3683   fi
3684 fi
3685 AC_SUBST(LIBHESIOD)
3686
3687 # Do we need libresolv (due to res_init or Hesiod)?
3688 if test "$resolv" = yes && test $opsys != darwin; then
3689   LIBRESOLV=-lresolv
3690 else
3691   LIBRESOLV=
3692 fi
3693 AC_SUBST(LIBRESOLV)
3694
3695 # These tell us which Kerberos-related libraries to use.
3696 COM_ERRLIB=
3697 CRYPTOLIB=
3698 KRB5LIB=
3699 DESLIB=
3700 KRB4LIB=
3701
3702 if test "${with_kerberos}" != no; then
3703   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3704   if test $have_com_err = yes; then
3705     COM_ERRLIB=-lcom_err
3706     LIBS="$COM_ERRLIB $LIBS"
3707   fi
3708   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3709   if test $have_crypto = yes; then
3710     CRYPTOLIB=-lcrypto
3711     LIBS="$CRYPTOLIB $LIBS"
3712   fi
3713   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3714   if test $have_k5crypto = yes; then
3715     CRYPTOLIB=-lk5crypto
3716     LIBS="$CRYPTOLIB $LIBS"
3717   fi
3718   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3719   if test $have_krb5=yes; then
3720     KRB5LIB=-lkrb5
3721     LIBS="$KRB5LIB $LIBS"
3722   fi
3723   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3724   if test "${with_kerberos5}" = no; then
3725     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3726     if test $have_des425 = yes; then
3727       DESLIB=-ldes425
3728       LIBS="$DESLIB $LIBS"
3729     else
3730       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3731       if test $have_des = yes; then
3732         DESLIB=-ldes
3733         LIBS="$DESLIB $LIBS"
3734       fi
3735     fi
3736     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3737     if test $have_krb4 = yes; then
3738       KRB4LIB=-lkrb4
3739       LIBS="$KRB4LIB $LIBS"
3740     else
3741       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3742       if test $have_krb = yes; then
3743         KRB4LIB=-lkrb
3744         LIBS="$KRB4LIB $LIBS"
3745       fi
3746     fi
3747   fi
3748
3749   if test "${with_kerberos5}" != no; then
3750     AC_CHECK_HEADERS(krb5.h,
3751       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3752                         [#include <krb5.h>])])
3753   else
3754     AC_CHECK_HEADERS(krb.h,,
3755                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3756                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3757   fi
3758   AC_CHECK_HEADERS(com_err.h)
3759 fi
3760
3761 AC_SUBST(COM_ERRLIB)
3762 AC_SUBST(CRYPTOLIB)
3763 AC_SUBST(KRB5LIB)
3764 AC_SUBST(DESLIB)
3765 AC_SUBST(KRB4LIB)
3766
3767 AC_CHECK_HEADERS(valgrind/valgrind.h)
3768
3769 AC_CHECK_FUNCS_ONCE(tzset)
3770 AC_MSG_CHECKING(whether localtime caches TZ)
3771 AC_CACHE_VAL(emacs_cv_localtime_cache,
3772 [if test x$ac_cv_func_tzset = xyes; then
3773 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3774 char TZ_GMT0[] = "TZ=GMT0";
3775 char TZ_PST8[] = "TZ=PST8";
3776 main()
3777 {
3778   time_t now = time ((time_t *) 0);
3779   int hour_GMT0, hour_unset;
3780   if (putenv (TZ_GMT0) != 0)
3781     exit (1);
3782   hour_GMT0 = localtime (&now)->tm_hour;
3783   unsetenv("TZ");
3784   hour_unset = localtime (&now)->tm_hour;
3785   if (putenv (TZ_PST8) != 0)
3786     exit (1);
3787   if (localtime (&now)->tm_hour == hour_GMT0)
3788     exit (1);
3789   unsetenv("TZ");
3790   if (localtime (&now)->tm_hour != hour_unset)
3791     exit (1);
3792   exit (0);
3793 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3794 [# If we have tzset, assume the worst when cross-compiling.
3795 emacs_cv_localtime_cache=yes])
3796 else
3797         # If we lack tzset, report that localtime does not cache TZ,
3798         # since we can't invalidate the cache if we don't have tzset.
3799         emacs_cv_localtime_cache=no
3800 fi])dnl
3801 AC_MSG_RESULT($emacs_cv_localtime_cache)
3802 if test $emacs_cv_localtime_cache = yes; then
3803   AC_DEFINE(LOCALTIME_CACHE, 1,
3804             [Define to 1 if localtime caches TZ.])
3805 fi
3806
3807 ok_so_far=yes
3808 AC_CHECK_FUNC(socket, , ok_so_far=no)
3809 if test $ok_so_far = yes; then
3810   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3811 fi
3812 if test $ok_so_far = yes; then
3813   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3814 fi
3815 if test $ok_so_far = yes; then
3816 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3817   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3818             [Define to 1 if you have inet sockets.])
3819 fi
3820
3821 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3822 dnl This can be removed once we assume Autoconf 2.70.
3823 case $canonical in
3824   *-solaris2.4 | *-solaris2.4.*)
3825     dnl Disable the Autoconf-generated vfork test.
3826     : ${ac_cv_func_vfork_works=no};;
3827 esac
3828
3829 AC_FUNC_FORK
3830
3831 AC_CHECK_FUNCS(snprintf)
3832
3833 dnl Check this late.  It depends on what other libraries (lrsvg, Gtk+ etc)
3834 dnl Emacs uses.
3835 XGSELOBJ=
3836 AC_MSG_CHECKING([whether GLib is linked in])
3837 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3838         [[#include <glib.h>
3839         ]],
3840         [[g_print ("Hello world");]])],
3841      [links_glib=yes],
3842      [links_glib=no])
3843 AC_MSG_RESULT([$links_glib])
3844 if test "${links_glib}" = "yes"; then
3845   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3846   if test "$HAVE_NS" = no;then
3847     XGSELOBJ=xgselect.o
3848   fi
3849 fi
3850 AC_SUBST(XGSELOBJ)
3851
3852 dnl Adapted from Haible's version.
3853 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3854   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3855     [[char* cs = nl_langinfo(CODESET);]])],
3856     emacs_cv_langinfo_codeset=yes,
3857     emacs_cv_langinfo_codeset=no)
3858   ])
3859 if test $emacs_cv_langinfo_codeset = yes; then
3860   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3861     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3862 fi
3863
3864 AC_TYPE_MBSTATE_T
3865
3866 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3867   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3868                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3869 if test "$emacs_cv_c_restrict_arr" = yes; then
3870   AC_DEFINE(__restrict_arr, __restrict,
3871     [Define to compiler's equivalent of C99 restrict keyword in array
3872      declarations.  Define as empty for no equivalent.])
3873 fi
3874
3875 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3876 dnl how the tty code is related to POSIX and/or other versions of termios.
3877 dnl The following looks like a useful start.
3878 dnl
3879 dnl AC_SYS_POSIX_TERMIOS
3880 dnl if test $ac_cv_sys_posix_termios = yes; then
3881 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3882 dnl                                and macros for terminal control.])
3883 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3884 dnl fi
3885
3886 dnl Turned on June 1996 supposing nobody will mind it.
3887 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3888 if test "${opsys}" != "mingw32"; then
3889    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3890      in the full name stands for the login id.])
3891 fi
3892
3893 dnl Every platform that uses configure supports this.
3894 dnl There is a create-lockfiles option you can
3895 dnl customize if you do not want the lock files to be written.
3896 dnl So it is not clear that this #define still needs to exist.
3897 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3898   so that Emacs can tell instantly when you try to modify a file that
3899   someone else has modified in his/her Emacs.])
3900
3901 dnl Everybody supports this, except MS.
3902 dnl Seems like the kind of thing we should be testing for, though.
3903 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3904 if test "${opsys}" != "mingw32"; then
3905   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3906 fi
3907
3908 dnl Everybody supports this, except MS-DOS.
3909 dnl Seems like the kind of thing we should be testing for, though.
3910 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3911 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3912   4.2-compatible sockets.])
3913
3914 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3915
3916 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
3917   a null file, or a data sink.])
3918 if test "${opsys}" = "mingw32"; then
3919   AC_DEFINE(NULL_DEVICE, ["NUL:"])
3920 else
3921   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
3922 fi
3923
3924 if test "${opsys}" = "mingw32"; then
3925   SEPCHAR=';'
3926 else
3927   SEPCHAR=':'
3928 fi
3929 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
3930 dnl This is for MinGW, and is used in test/automated/Makefile.in.
3931 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
3932 dnl decides that a command-line argument to be passed to a MinGW program
3933 dnl is a PATH-style list of directories.  But that heuristics plays it
3934 dnl safe, and only does the replacement when it is _absolutely_ sure it
3935 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
3936 dnl which breaks in-tree builds.  So we do this manually instead.
3937 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
3938 dnl be computed as ':' in MSYS Bash.
3939 AC_SUBST(SEPCHAR)
3940
3941 dnl Everybody supports this, except MS-DOS.
3942 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3943
3944 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3945
3946
3947 AC_DEFINE(DIRECTORY_SEP, ['/'],
3948   [Character that separates directories in a file name.])
3949
3950 if test "${opsys}" = "mingw32"; then
3951   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
3952     [Returns true if character is a device separator.])
3953
3954   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
3955     [Returns true if character is a directory separator.])
3956
3957   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
3958     [Returns true if character is any form of separator.])
3959 else
3960   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3961     [Returns true if character is a device separator.])
3962
3963   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3964     [Returns true if character is a directory separator.])
3965
3966   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3967     [Returns true if character is any form of separator.])
3968 fi
3969
3970 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3971
3972 case $opsys in
3973   aix4-2)
3974     dnl Unfortunately without libXmu we cannot support EditRes.
3975     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3976       AC_DEFINE(NO_EDITRES, 1)
3977     fi
3978     ;;
3979
3980   hpux*)
3981     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3982     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3983     AC_DEFINE(NO_EDITRES, 1)
3984     ;;
3985 esac
3986
3987
3988 case $opsys in
3989   irix6-5 | sol2* | unixware )
3990     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3991     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3992     dnl need the constant to dimension an array.  So wire in the appropriate
3993     dnl value here.
3994     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3995     ;;
3996 esac
3997
3998 emacs_broken_SIGIO=no
3999
4000 case $opsys in
4001   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4002   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4003   hpux* | irix6-5 | openbsd | sol2* | unixware )
4004     emacs_broken_SIGIO=yes
4005     ;;
4006
4007   aix4-2)
4008     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4009     dnl the way this system works, libc functions that return malloced
4010     dnl memory use the libc malloc implementation. Calling xfree or
4011     dnl xrealloc on the results of such functions results in a crash.
4012     dnl
4013     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4014     dnl but that does not currently work on this system.
4015     dnl
4016     dnl It is possible to completely override the malloc implementation on
4017     dnl AIX, but that involves putting the malloc functions in a shared
4018     dnl library and setting the MALLOCTYPE environment variable to point to
4019     dnl that shared library.
4020     dnl
4021     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4022     dnl to avoid a crash just use the Emacs implementation for that function.
4023     dnl
4024     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4025     dnl of this file, so that we do not check for get_current_dir_name
4026     dnl on AIX.  But that might be fragile if something else ends
4027     dnl up testing for get_current_dir_name as a dependency.
4028     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4029       get_current_dir_name should not be used.])
4030     ;;
4031
4032   freebsd)
4033     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4034     dnl writes/reads on a PTY, read(2) returns bogus data:
4035     dnl
4036     dnl write(2)  1022 bytes
4037     dnl write(2)   954 bytes, get EAGAIN
4038     dnl read(2)   1024 bytes in process_read_output
4039     dnl read(2)     11 bytes in process_read_output
4040     dnl
4041     dnl That is, read(2) returns more bytes than have ever been written
4042     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4043     dnl successfully after processing (for example with CRs added if the
4044     dnl terminal is set up that way which it is here).  The same bytes will
4045     dnl be seen again in a later read(2), without the CRs.
4046     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4047       work around an issue when reading from a PTY.])
4048     ;;
4049 esac
4050
4051 case $opsys in
4052   gnu-* | sol2-10 )
4053     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4054     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4055   ;;
4056 esac
4057
4058 case $opsys in
4059   darwin | dragonfly | freebsd | netbsd | openbsd )
4060     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4061       close a pty to make it a controlling terminal (it is already a
4062       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4063   ;;
4064 esac
4065
4066 dnl FIXME Surely we can test for this rather than hard-code it.
4067 case $opsys in
4068   netbsd | openbsd) sound_device="/dev/audio" ;;
4069   *) sound_device="/dev/dsp" ;;
4070 esac
4071
4072 dnl Used in sound.c
4073 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4074   [Name of the default sound device.])
4075
4076
4077 dnl Emacs can read input using SIGIO and buffering characters itself,
4078 dnl or using CBREAK mode and making C-g cause SIGINT.
4079 dnl The choice is controlled by the variable interrupt_input.
4080 dnl
4081 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4082 dnl
4083 dnl Emacs uses the presence of the USABLE_SIGIO macro
4084 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4085 dnl INTERRUPT_INPUT to decide whether to use it by default.
4086 dnl
4087 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4088 dnl CBREAK mode has two disadvantages
4089 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4090 dnl I hear that in system V this problem does not exist.
4091 dnl 2) Control-G causes output to be discarded.
4092 dnl I do not know whether this can be fixed in system V.
4093 dnl
4094 dnl Another method of doing input is planned but not implemented.
4095 dnl It would have Emacs fork off a separate process
4096 dnl to read the input and send it to the true Emacs process
4097 dnl through a pipe.
4098 case $opsys in
4099   darwin | gnu-linux | gnu-kfreebsd )
4100     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4101   ;;
4102 esac
4103
4104
4105 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4106 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4107 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4108 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4109 dnl taking float or double parameters.
4110 case $opsys in
4111   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4112     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4113       file defines `NeedWidePrototypes' as `NO'.])
4114   ;;
4115 esac
4116
4117
4118 dnl Used in process.c, this must be a loop, even if it only runs once.
4119 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4120 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4121 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4122 dnl trying suffixes 0-16.
4123 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4124   first PTY, if PTYs are supported.])
4125 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4126 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4127   end of a PTY, if non-standard.])
4128 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4129   end of a PTY, if non-standard.])
4130
4131 case $opsys in
4132   aix4-2 )
4133     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4134     dnl You allocate a pty by opening /dev/ptc to get the master side.
4135     dnl To get the name of the slave side, you just ttyname() the master side.
4136     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4137     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4138     ;;
4139
4140   cygwin )
4141     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4142     dnl multi-line AC_DEFINEs are hard. :(
4143     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4144     AC_DEFINE(PTY_NAME_SPRINTF, [])
4145     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4146     ;;
4147
4148   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4149   darwin )
4150     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4151     dnl Not used, because PTY_ITERATION is defined.
4152     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4153     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4154     dnl But we don't have to block SIGCHLD because it is blocked in the
4155     dnl implementation of grantpt.
4156     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4157     AC_DEFINE(PTY_NAME_SPRINTF, [])
4158     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4159     ;;
4160
4161   gnu | openbsd )
4162     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4163     ;;
4164
4165   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4166     dnl if HAVE_GRANTPT
4167     if test "x$ac_cv_func_grantpt" = xyes; then
4168       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4169       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4170       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4171       dnl to prevent sigchld_handler from intercepting the child's death.
4172       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4173       dnl if HAVE_POSIX_OPENPT
4174       if test "x$ac_cv_func_posix_openpt" = xyes; then
4175         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4176         AC_DEFINE(PTY_NAME_SPRINTF, [])
4177       dnl if HAVE_GETPT
4178       elif test "x$ac_cv_func_getpt" = xyes; then
4179         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4180         AC_DEFINE(PTY_NAME_SPRINTF, [])
4181       else
4182         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4183       fi
4184     else
4185       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4186     fi
4187     ;;
4188
4189   hpux*)
4190     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4191     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4192     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4193     ;;
4194
4195   irix6-5 )
4196     dnl It looks like this cannot be right, because it is not a loop.
4197     dnl However, process.c actually does this:
4198     dnl # ifndef __sgi
4199     dnl   continue;
4200     dnl # else
4201     dnl   return -1;
4202     dnl # endif
4203     dnl which presumably makes it OK, since irix == sgi (?).
4204     dnl FIXME it seems like this special treatment is unnecessary?
4205     dnl Why can't irix use a single-trip loop like eg cygwin?
4206     AC_DEFINE(PTY_ITERATION, [])
4207     dnl Not used, because PTY_ITERATION is defined.
4208     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4209     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4210     dnl No need to get the pty name at all.
4211     AC_DEFINE(PTY_NAME_SPRINTF, [])
4212     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4213     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4214     ;;
4215
4216   sol2* )
4217     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4218     dnl from intercepting that death.  If any child but grantpt's should die
4219     dnl within, it should be caught after sigrelse(2).
4220     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4221     ;;
4222
4223   unixware )
4224     dnl Comments are as per sol2*.
4225     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4226     ;;
4227 esac
4228
4229
4230 case $opsys in
4231   sol2* | unixware )
4232     dnl This change means that we don't loop through allocate_pty too
4233     dnl many times in the (rare) event of a failure.
4234     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4235     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4236     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4237     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4238     ;;
4239 esac
4240
4241
4242 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4243 "typing" a signal character on the pty.])
4244
4245 case $opsys in
4246   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4247   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4248   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4249     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4250     ;;
4251
4252   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4253   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4254   gnu-linux | gnu-kfreebsd )
4255
4256     AC_MSG_CHECKING([for signals via characters])
4257     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4258 #include <linux/version.h>
4259 #if LINUX_VERSION_CODE < 0x20400
4260 # error "Linux version too old"
4261 #endif
4262       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4263
4264     AC_MSG_RESULT([$emacs_signals_via_chars])
4265     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4266     ;;
4267 esac
4268
4269
4270 dnl Used in lisp.h, emacs.c, vm-limit.c
4271 dnl NEWS.18 describes this as "a number which contains
4272 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
4273 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
4274 stored in a Lisp_Object.])
4275 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
4276
4277 case $opsys in
4278   aix*)
4279     dnl This works with 32-bit executables; Emacs doesn't support 64-bit.
4280     AC_DEFINE(DATA_SEG_BITS, [0x20000000])
4281     ;;
4282   hpux*)
4283     dnl The data segment on this machine always starts at address 0x40000000.
4284     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
4285     ;;
4286   irix6-5)
4287     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
4288     ;;
4289 esac
4290
4291
4292 AH_TEMPLATE(TAB3, [Undocumented.])
4293
4294 case $opsys in
4295   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4296
4297   gnu | dragonfly | freebsd | netbsd | openbsd )
4298     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4299     AC_DEFINE(TAB3, OXTABS)
4300     ;;
4301
4302   gnu-linux | gnu-kfreebsd )
4303     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4304 #ifndef __ia64__
4305 # error "not ia64"
4306 #endif
4307       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4308         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4309         [Mark a secondary stack, like the register stack on the ia64.]), [])
4310     ;;
4311
4312   hpux*)
4313     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4314       run_time_remap; for HPUX.])
4315     ;;
4316 esac
4317
4318
4319 dnl This won't be used automatically yet.  We also need to know, at least,
4320 dnl that the stack is continuous.
4321 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4322   registers relevant for conservative garbage collection in the jmp_buf.])
4323
4324
4325 case $opsys in
4326   dnl Not all the architectures are tested, but there are Debian packages
4327   dnl for SCM and/or Guile on them, so the technique must work.  See also
4328   dnl comments in alloc.c concerning setjmp and gcc.
4329   dnl Fixme: it's probably safe to just use the GCC conditional below.
4330   gnu-linux | gnu-kfreebsd )
4331     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4332 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4333   || defined __alpha__ || defined __mips__ || defined __s390__ \
4334   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4335   || defined __ia64__ || defined __sh__
4336 /* ok */
4337 #else
4338 # error "setjmp not known to work on this arch"
4339 #endif
4340     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4341     ;;
4342 esac
4343
4344
4345 if test x$GCC = xyes; then
4346    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4347    AC_DEFINE(GC_SETJMP_WORKS, 1)
4348 else
4349   case $opsys in
4350     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4351     dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4352       AC_DEFINE(GC_SETJMP_WORKS, 1)
4353       ;;
4354   esac
4355 fi                              dnl GCC?
4356
4357 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4358 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4359   [AC_LINK_IFELSE(
4360      [AC_LANG_PROGRAM(
4361        [[#include <setjmp.h>
4362          #ifdef __MINGW32__
4363          # define _longjmp longjmp
4364          #endif
4365        ]],
4366        [[jmp_buf j;
4367          if (! _setjmp (j))
4368            _longjmp (j, 1);]])],
4369      [emacs_cv_func__setjmp=yes],
4370      [emacs_cv_func__setjmp=no])])
4371 if test $emacs_cv_func__setjmp = yes; then
4372   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4373 else
4374   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4375     [AC_LINK_IFELSE(
4376        [AC_LANG_PROGRAM(
4377          [[#include <setjmp.h>
4378          ]],
4379          [[sigjmp_buf j;
4380            if (! sigsetjmp (j, 1))
4381              siglongjmp (j, 1);]])],
4382        [emacs_cv_func_sigsetjmp=yes],
4383        [emacs_cv_func_sigsetjmp=no])])
4384   if test $emacs_cv_func_sigsetjmp = yes; then
4385     AC_DEFINE([HAVE_SIGSETJMP], 1,
4386       [Define to 1 if sigsetjmp and siglongjmp work.
4387        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
4388   fi
4389 fi
4390
4391 case $opsys in
4392   sol2* | unixware )
4393     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4394     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4395     dnl and this is all we need.
4396     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4397     ;;
4398 esac
4399
4400
4401 case $opsys in
4402   hpux* | sol2* )
4403     dnl Used in xfaces.c.
4404     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4405       some systems, where it requires time.h.])
4406     ;;
4407 esac
4408
4409
4410 dnl Define symbols to identify the version of Unix this is.
4411 dnl Define all the symbols that apply correctly.
4412 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4413 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4414 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4415 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4416
4417 case $opsys in
4418   aix4-2)
4419     AC_DEFINE(USG, [])
4420     dnl This symbol should be defined on AIX Version 3  ???????
4421     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4422 #ifndef _AIX
4423 # error "_AIX not defined"
4424 #endif
4425     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4426     ;;
4427
4428   cygwin)
4429     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4430     ;;
4431
4432   darwin)
4433     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4434     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4435     dnl distinguish OS X from pure Darwin.
4436     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4437     ;;
4438
4439   gnu-linux | gnu-kfreebsd )
4440     AC_DEFINE(USG, [])
4441     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4442     ;;
4443
4444   hpux*)
4445     AC_DEFINE(USG, [])
4446     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4447     ;;
4448
4449   irix6-5)
4450     AC_DEFINE(USG, [])
4451     AC_DEFINE(USG5_4, [])
4452     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4453     ;;
4454
4455   mingw32)
4456     AC_DEFINE(DOS_NT, [])
4457     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4458     if test "x$ac_enable_checking" != "x" ; then
4459       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4460     fi
4461     ;;
4462
4463   sol2*)
4464     AC_DEFINE(USG, [])
4465     AC_DEFINE(USG5_4, [])
4466     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4467     ;;
4468
4469   unixware)
4470     AC_DEFINE(USG, [])
4471     AC_DEFINE(USG5_4, [])
4472     ;;
4473 esac
4474
4475 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4476   [case $opsys in
4477      aix4-2)
4478        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4479        emacs_cv_usable_FIONREAD=no
4480        ;;
4481
4482      mingw32)
4483        emacs_cv_usable_FIONREAD=yes
4484        ;;
4485
4486      *)
4487        AC_COMPILE_IFELSE(
4488          [AC_LANG_PROGRAM([[#include <sys/types.h>
4489                             #include <sys/ioctl.h>
4490                             #ifdef USG5_4
4491                             # include <sys/filio.h>
4492                             #endif
4493                           ]],
4494                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4495          [emacs_cv_usable_FIONREAD=yes],
4496          [emacs_cv_usable_FIONREAD=no])
4497        ;;
4498    esac])
4499 if test $emacs_cv_usable_FIONREAD = yes; then
4500   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4501
4502   if test $emacs_broken_SIGIO = no; then
4503     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4504       [AC_COMPILE_IFELSE(
4505          [AC_LANG_PROGRAM([[#include <fcntl.h>
4506                             #include <signal.h>
4507                           ]],
4508                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4509          [emacs_cv_usable_SIGIO=yes],
4510          [emacs_cv_usable_SIGIO=no])],
4511       [emacs_cv_usable_SIGIO=yes],
4512       [emacs_cv_usable_SIGIO=no])
4513     if test $emacs_cv_usable_SIGIO = yes; then
4514       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4515     fi
4516   fi
4517 fi
4518
4519
4520 case $opsys in
4521   dnl Emacs supplies its own malloc, but glib calls posix_memalign,
4522   dnl and on Cygwin prior to version 1.7.24 that becomes the
4523   dnl Cygwin-supplied posix_memalign.  As malloc is not the Cygwin
4524   dnl malloc, the Cygwin posix_memalign always returns ENOSYS.  A
4525   dnl workaround is to set G_SLICE=always-malloc.  This is no longer
4526   dnl needed starting with cygwin-1.7.24, and it is no longer
4527   dnl effective starting with glib-2.36. */
4528   cygwin)
4529     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4530       G_SLICE environment variable to "always-malloc" at startup.])
4531     ;;
4532
4533   hpux11)
4534     dnl It works to open the pty's tty in the parent (Emacs), then
4535     dnl close and reopen it in the child.
4536     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4537       works to open a pty's tty in the parent process, then close and
4538       reopen it in the child.])
4539     ;;
4540
4541   irix6-5)
4542     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4543       use VSUSP instead of VSWTCH.])
4544     ;;
4545
4546   sol2-10)
4547     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4548       on Solaris.])
4549     ;;
4550 esac
4551
4552 # Set up the CFLAGS for real compilation, so we can substitute it.
4553 CFLAGS="$REAL_CFLAGS"
4554 CPPFLAGS="$REAL_CPPFLAGS"
4555
4556 ## Hack to detect a buggy GCC version.
4557 if test "x$GCC" = xyes \
4558    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4559    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4560    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4561    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4562 fi
4563
4564 version=$PACKAGE_VERSION
4565
4566 copyright="Copyright (C) 2014 Free Software Foundation, Inc."
4567 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4568   [Short copyright string for this version of Emacs.])
4569 AC_SUBST(copyright)
4570
4571 ### Specify what sort of things we'll be editing into Makefile and config.h.
4572 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4573 AC_SUBST(version)
4574 AC_SUBST(configuration)
4575 ## Unused?
4576 AC_SUBST(canonical)
4577 AC_SUBST(srcdir)
4578 AC_SUBST(prefix)
4579 AC_SUBST(exec_prefix)
4580 AC_SUBST(bindir)
4581 AC_SUBST(datadir)
4582 AC_SUBST(sharedstatedir)
4583 AC_SUBST(libexecdir)
4584 AC_SUBST(mandir)
4585 AC_SUBST(infodir)
4586 AC_SUBST(lispdir)
4587 AC_SUBST(standardlisppath)
4588 AC_SUBST(locallisppath)
4589 AC_SUBST(lisppath)
4590 AC_SUBST(x_default_search_path)
4591 AC_SUBST(etcdir)
4592 AC_SUBST(archlibdir)
4593 AC_SUBST(etcdocdir)
4594 AC_SUBST(bitmapdir)
4595 AC_SUBST(gamedir)
4596 AC_SUBST(gameuser)
4597 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4598 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4599 ## end of LIBX_BASE, but nothing ever set it.
4600 AC_SUBST(LD_SWITCH_X_SITE)
4601 AC_SUBST(C_SWITCH_X_SITE)
4602 AC_SUBST(GNUSTEP_CFLAGS)
4603 AC_SUBST(CFLAGS)
4604 ## Used in lwlib/Makefile.in.
4605 AC_SUBST(X_TOOLKIT_TYPE)
4606 AC_SUBST(ns_appdir)
4607 AC_SUBST(ns_appbindir)
4608 AC_SUBST(ns_appresdir)
4609 AC_SUBST(ns_appsrc)
4610 AC_SUBST(GNU_OBJC_CFLAGS)
4611 AC_SUBST(OTHER_FILES)
4612
4613 if test -n "${term_header}"; then
4614     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4615         [Define to the header for the built-in window system.])
4616 fi
4617
4618 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4619                    [Define to the canonical Emacs configuration name.])
4620 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4621                    [Define to the options passed to configure.])
4622 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4623   define this to include extra configuration information.])
4624
4625 case $opsys in
4626   mingw32)
4627     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4628     ;;
4629 esac
4630
4631 XMENU_OBJ=
4632 XOBJ=
4633 FONT_OBJ=
4634 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4635   AC_DEFINE(HAVE_X_WINDOWS, 1,
4636             [Define to 1 if you want to use the X window system.])
4637   XMENU_OBJ=xmenu.o
4638   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4639   FONT_OBJ=xfont.o
4640   if test "$HAVE_XFT" = "yes"; then
4641     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4642   elif test "$HAVE_FREETYPE" = "yes"; then
4643     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4644   fi
4645   AC_SUBST(FONT_OBJ)
4646 fi
4647 AC_SUBST(XMENU_OBJ)
4648 AC_SUBST(XOBJ)
4649 AC_SUBST(FONT_OBJ)
4650
4651 WIDGET_OBJ=
4652 MOTIF_LIBW=
4653 if test "${USE_X_TOOLKIT}" != "none" ; then
4654   WIDGET_OBJ=widget.o
4655   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4656   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4657     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4658   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4659     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4660     MOTIF_LIBW=-lXm
4661     case "$opsys" in
4662       gnu-linux)
4663         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4664         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4665         ;;
4666
4667       unixware)
4668         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4669         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4670         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4671         ;;
4672
4673       aix4-2)
4674         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4675         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4676         ;;
4677     esac
4678     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4679   fi
4680 fi
4681 AC_SUBST(WIDGET_OBJ)
4682
4683 TOOLKIT_LIBW=
4684 case "$USE_X_TOOLKIT" in
4685   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4686   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4687   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4688 esac
4689 AC_SUBST(TOOLKIT_LIBW)
4690
4691 if test "${opsys}" != "mingw32"; then
4692   if test "$USE_X_TOOLKIT" = "none"; then
4693     LIBXT_OTHER="\$(LIBXSM)"
4694   else
4695     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4696   fi
4697 fi
4698 AC_SUBST(LIBXT_OTHER)
4699
4700 if test "${HAVE_X11}" = "yes" ; then
4701   AC_DEFINE(HAVE_X11, 1,
4702             [Define to 1 if you want to use version 11 of X windows.])
4703   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4704 else
4705   LIBX_OTHER=
4706 fi
4707 AC_SUBST(LIBX_OTHER)
4708
4709 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4710   LIBXMENU=
4711 elif test "$USE_X_TOOLKIT" = none; then
4712   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4713 else
4714   LIBXMENU='$(lwlibdir)/liblw.a'
4715 fi
4716 AC_SUBST(LIBXMENU)
4717
4718 if test "${GNU_MALLOC}" = "yes" ; then
4719   AC_DEFINE(GNU_MALLOC, 1,
4720             [Define to 1 if you want to use the GNU memory allocator.])
4721 fi
4722
4723 RALLOC_OBJ=
4724 if test "${REL_ALLOC}" = "yes" ; then
4725   AC_DEFINE(REL_ALLOC, 1,
4726             [Define REL_ALLOC if you want to use the relocating allocator for
4727              buffer space.])
4728
4729   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4730 fi
4731 AC_SUBST(RALLOC_OBJ)
4732
4733 if test "$opsys" = "cygwin"; then
4734   CYGWIN_OBJ="sheap.o cygw32.o"
4735   ## Cygwin differs because of its unexec().
4736   PRE_ALLOC_OBJ=
4737   POST_ALLOC_OBJ=lastfile.o
4738 elif test "$opsys" = "mingw32"; then
4739   CYGWIN_OBJ=
4740   PRE_ALLOC_OBJ=
4741   POST_ALLOC_OBJ=lastfile.o
4742 else
4743   CYGWIN_OBJ=
4744   PRE_ALLOC_OBJ=lastfile.o
4745   POST_ALLOC_OBJ=
4746 fi
4747 AC_SUBST(CYGWIN_OBJ)
4748 AC_SUBST(PRE_ALLOC_OBJ)
4749 AC_SUBST(POST_ALLOC_OBJ)
4750
4751 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4752 dnl verbatim defined above.  The tricky name is apropos, as this hack
4753 dnl makes Fortify go sour!
4754 AH_VERBATIM([FORTIFY_SOUR],
4755 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4756    The workaround disables some useful run-time checking, so it
4757    should be conditional to the platforms with the performance bug.
4758    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4759 #if defined __APPLE__ && defined __GNUC__
4760 # ifndef _DONT_USE_CTYPE_INLINE_
4761 #  define _DONT_USE_CTYPE_INLINE_
4762 # endif
4763 # ifndef _FORTIFY_SOURCE
4764 #  define _FORTIFY_SOURCE 0
4765 # endif
4766 #endif
4767 ])
4768
4769 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4770 # it temporarily reverts them to their pre-pkg-config values,
4771 # because gnulib needs to work with both src (which uses the
4772 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4773 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4774 # and it therefore needs to run in an environment where LIBS does not
4775 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4776 # for some package unrelated to lib-src.
4777 SAVE_CFLAGS=$CFLAGS
4778 SAVE_LIBS=$LIBS
4779 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4780 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4781 gl_ASSERT_NO_GNULIB_POSIXCHECK
4782 gl_ASSERT_NO_GNULIB_TESTS
4783 gl_INIT
4784 CFLAGS=$SAVE_CFLAGS
4785 LIBS=$SAVE_LIBS
4786
4787 if test "${opsys}" = "mingw32"; then
4788   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4789   # Remove unneeded switches from the value of CC that goes to Makefiles
4790   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4791 fi
4792
4793 case "$opsys" in
4794   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4795
4796   darwin)
4797    ## The -headerpad option tells ld (see man page) to leave room at the
4798    ## end of the header for adding load commands.  Needed for dumping.
4799    ## 0x690 is the total size of 30 segment load commands (at 56
4800    ## each); under Cocoa 31 commands are required.
4801    if test "$HAVE_NS" = "yes"; then
4802      libs_nsgui="-framework AppKit"
4803      if test "$NS_IMPL_COCOA" = "yes"; then
4804         libs_nsgui="$libs_nsgui -framework IOKit"
4805      fi
4806      headerpad_extra=6C8
4807    else
4808      libs_nsgui=
4809      headerpad_extra=690
4810    fi
4811    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4812
4813    ## This is here because src/Makefile.in did some extra fiddling around
4814    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4815    ## LD_SWITCH_SYSTEM_TEMACS instead,
4816    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4817      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4818    ;;
4819
4820   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4821   ## find X at run-time.
4822   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4823   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4824   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4825   ## had different values in configure (in ac_link) and src/Makefile.in.
4826   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4827   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4828
4829   mingw32)
4830    ## MinGW64 does not prepend an underscore to symbols, so we must
4831    ## pass a different -entry switch to linker.  FIXME: It is better
4832    ## to make the entry points the same by changing unexw32.c.
4833    case "$canonical" in
4834      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4835      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4836    esac
4837    ;;
4838
4839   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4840
4841   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4842 esac
4843
4844 if test x$ac_enable_profiling != x ; then
4845   case $opsys in
4846     *freebsd | gnu-linux) ;;
4847     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4848   esac
4849 fi
4850
4851 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
4852
4853 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4854
4855 ## MinGW-specific post-link processing of temacs.
4856 TEMACS_POST_LINK=":"
4857 ADDSECTION=
4858 EMACS_HEAPSIZE=
4859 if test "${opsys}" = "mingw32"; then
4860   TEMACS_POST_LINK="\$(MINGW_TEMACS_POST_LINK)"
4861   ADDSECTION="../nt/addsection\$(EXEEXT)"
4862   ## Preload heap size of temacs.exe in MB.
4863   case "$canonical" in
4864     x86_64-*-*) EMACS_HEAPSIZE=42 ;;
4865     *) EMACS_HEAPSIZE=27 ;;
4866   esac
4867 fi
4868
4869 AC_SUBST(ADDSECTION)
4870 AC_SUBST(TEMACS_POST_LINK)
4871 AC_SUBST(EMACS_HEAPSIZE)
4872
4873 ## Common for all window systems
4874 if test "$window_system" != "none"; then
4875   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4876   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4877 fi
4878
4879 AC_SUBST(WINDOW_SYSTEM_OBJ)
4880
4881 AH_TOP([/* GNU Emacs site configuration template file.
4882
4883 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2014
4884   Free Software Foundation, Inc.
4885
4886 This file is part of GNU Emacs.
4887
4888 GNU Emacs is free software: you can redistribute it and/or modify
4889 it under the terms of the GNU General Public License as published by
4890 the Free Software Foundation, either version 3 of the License, or
4891 (at your option) any later version.
4892
4893 GNU Emacs is distributed in the hope that it will be useful,
4894 but WITHOUT ANY WARRANTY; without even the implied warranty of
4895 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4896 GNU General Public License for more details.
4897
4898 You should have received a copy of the GNU General Public License
4899 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4900
4901
4902 /* No code in Emacs #includes config.h twice, but some bits of code
4903    intended to work with other packages as well (like gmalloc.c)
4904    think they can include it as many times as they like.  */
4905 #ifndef EMACS_CONFIG_H
4906 #define EMACS_CONFIG_H
4907 ])dnl
4908
4909 AH_BOTTOM([#include <conf_post.h>
4910
4911 #endif /* EMACS_CONFIG_H */
4912
4913 /*
4914 Local Variables:
4915 mode: c
4916 End:
4917 */
4918 ])dnl
4919
4920 #### Report on what we decided to do.
4921 #### Report GTK as a toolkit, even if it doesn't use Xt.
4922 #### It makes printing result more understandable as using GTK sets
4923 #### toolkit_scroll_bars to yes by default.
4924 if test "${HAVE_GTK}" = "yes"; then
4925   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4926 fi
4927
4928 if test $USE_ACL -ne 0; then
4929   acl_summary="yes $LIB_ACL"
4930 else
4931   acl_summary=no
4932 fi
4933
4934 echo "
4935 Configured for \`${canonical}'.
4936
4937   Where should the build process find the source code?    ${srcdir}
4938   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4939   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4940   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4941   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4942   What window system should Emacs use?                    ${window_system}
4943   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4944
4945 if test -n "${x_includes}"; then
4946 echo "  Where do we find X Windows header files?                ${x_includes}"
4947 else
4948 echo "  Where do we find X Windows header files?                Standard dirs"
4949 fi
4950 if test -n "${x_libraries}"; then
4951 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4952 else
4953 echo "  Where do we find X Windows libraries?                   Standard dirs"
4954 fi
4955
4956 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4957 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4958 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4959 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4960 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4961 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4962 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4963 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4964
4965 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
4966
4967 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4968 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4969 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4970 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4971 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
4972 echo "  Does Emacs use access control lists?                    ${acl_summary}"
4973 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4974 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4975 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4976
4977 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4978 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4979 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4980 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4981 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
4982
4983 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4984 echo
4985
4986 if test -n "${EMACSDATA}"; then
4987    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4988 fi
4989 if test -n "${EMACSDOC}"; then
4990    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4991 fi
4992
4993 echo
4994
4995 if test "$HAVE_NS" = "yes"; then
4996    echo
4997    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4998 The installed application will go to nextstep/Emacs.app and can be
4999 run or moved from there."
5000    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5001       echo "The application will be fully self-contained."
5002     else
5003       echo "The lisp resources for the application will be installed under ${prefix}.
5004 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5005 to run if these resources are not installed."
5006    fi
5007    echo
5008 fi
5009
5010 if test "${opsys}" = "cygwin"; then
5011   case `uname -r` in
5012     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5013            echo
5014            ;;
5015   esac
5016 fi
5017
5018 # Remove any trailing slashes in these variables.
5019 [test "${prefix}" != NONE &&
5020   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5021 test "${exec_prefix}" != NONE &&
5022   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5023
5024 if test "$HAVE_NS" = "yes"; then
5025   if test "$NS_IMPL_GNUSTEP" = yes; then
5026     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5027       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5028     ns_check_file=Resources/Info-gnustep.plist
5029   else
5030     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5031       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5032     ns_check_file=Contents/Info.plist
5033   fi
5034   AC_SUBST(ns_check_file)
5035 fi
5036
5037 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5038 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5039 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5040 dnl (else you get "no `Makefile.am' found for any configure output").
5041 dnl This will work, but you get a config.status that is not quite right
5042 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5043 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5044 dnl it seems better to just live with the duplication.
5045 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5046
5047 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5048        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5049        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5050        leim/Makefile nextstep/Makefile nt/Makefile])
5051
5052 dnl test/ is not present in release tarfiles.
5053 opt_makefile=test/automated/Makefile
5054
5055 if test -f "$srcdir/$opt_makefile.in"; then
5056   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5057   dnl Again, it's best not to use a variable.  Though you can add
5058   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5059   AC_CONFIG_FILES([test/automated/Makefile])
5060 fi
5061
5062
5063 dnl The admin/ directory used to be excluded from tarfiles.
5064 if test -d $srcdir/admin; then
5065   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5066   AC_CONFIG_FILES([admin/unidata/Makefile])
5067   AC_CONFIG_FILES([admin/grammars/Makefile])
5068 fi                              dnl -d admin
5069
5070
5071 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5072
5073 AC_SUBST(SUBDIR_MAKEFILES_IN)
5074
5075 dnl You might wonder (I did) why epaths.h is generated by running make,
5076 dnl rather than just letting configure generate it from epaths.in.
5077 dnl One reason is that the various paths are not fully expanded (see above);
5078 dnl eg gamedir=${prefix}/var/games/emacs.
5079 dnl Secondly, the GNU Coding standards require that one should be able
5080 dnl to run `make prefix=/some/where/else' and override the values set
5081 dnl by configure.  This also explains the `move-if-change' test and
5082 dnl the use of force in the `epaths-force' rule in Makefile.in.
5083 AC_CONFIG_COMMANDS([src/epaths.h], [
5084 if test "${opsys}" = "mingw32"; then
5085   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5086 else
5087   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5088 fi
5089 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5090
5091 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5092 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5093 dnl or a symlink?
5094 AC_CONFIG_COMMANDS([src/.gdbinit], [
5095 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5096   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5097 fi
5098 ])
5099
5100 AC_OUTPUT