lisp/progmodes/scheme.el

   1 ;;; scheme.el --- Scheme (and DSSSL) editing mode    -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 1986-1988, 1997-1998, 2001-2014 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Author: Bill Rozas <jinx@martigny.ai.mit.edu>
   7 ;; Adapted-by: Dave Love <d.love@dl.ac.uk>
   8 ;; Keywords: languages, lisp
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; The major mode for editing Scheme-type Lisp code, very similar to
  28 ;; the Lisp mode documented in the Emacs manual.  `dsssl-mode' is a
  29 ;; variant of scheme-mode for editing DSSSL specifications for SGML
  30 ;; documents.  [As of Apr 1997, some pointers for DSSSL may be found,
  31 ;; for instance, at <URL:http://www.sil.org/sgml/related.html#dsssl>.]
  32 ;; All these Lisp-ish modes vary basically in details of the language
  33 ;; syntax they highlight/indent/index, but dsssl-mode uses "^;;;" as
  34 ;; the page-delimiter since ^L isn't normally a valid SGML character.
  35 ;;
  36 ;; For interacting with a Scheme interpreter See also `run-scheme' in
  37 ;; the `cmuscheme' package and also the implementation-specific
  38 ;; `xscheme' package.
  39
  40 ;; Here's a recipe to generate a TAGS file for DSSSL, by the way:
  41 ;; etags --lang=scheme --regex='/[ \t]*(\(mode\|element\)[ \t
  42 ;; ]+\([^ \t(
  43 ;; ]+\)/\2/' --regex='/[ \t]*(element[ \t
  44 ;; ]*([^)]+[ \t
  45 ;; ]+\([^)]+\)[ \t
  46 ;; ]*)/\1/' --regex='/(declare[^ \t
  47 ;; ]*[ \t
  48 ;; ]+\([^ \t
  49 ;; ]+\)/\1/' "$@"
  50
  51 ;;; Code:
  52 \f
  53 (require 'lisp-mode)
  54
  55 (defvar scheme-mode-syntax-table
  56   (let ((st (make-syntax-table))
  57         (i 0))
  58     ;; Symbol constituents
  59     ;; We used to treat chars 128-256 as symbol-constituent, but they
  60     ;; should be valid word constituents (Bug#8843).  Note that valid
  61     ;; identifier characters are Scheme-implementation dependent.
  62     (while (< i ?0)
  63       (modify-syntax-entry i "_   " st)
  64       (setq i (1+ i)))
  65     (setq i (1+ ?9))
  66     (while (< i ?A)
  67       (modify-syntax-entry i "_   " st)
  68       (setq i (1+ i)))
  69     (setq i (1+ ?Z))
  70     (while (< i ?a)
  71       (modify-syntax-entry i "_   " st)
  72       (setq i (1+ i)))
  73     (setq i (1+ ?z))
  74     (while (< i 128)
  75       (modify-syntax-entry i "_   " st)
  76       (setq i (1+ i)))
  77
  78     ;; Whitespace
  79     (modify-syntax-entry ?\t "    " st)
  80     (modify-syntax-entry ?\n ">   " st)
  81     (modify-syntax-entry ?\f "    " st)
  82     (modify-syntax-entry ?\r "    " st)
  83     (modify-syntax-entry ?\s "    " st)
  84
  85     ;; These characters are delimiters but otherwise undefined.
  86     ;; Brackets and braces balance for editing convenience.
  87     (modify-syntax-entry ?\[ "(]  " st)
  88     (modify-syntax-entry ?\] ")[  " st)
  89     (modify-syntax-entry ?{ "(}  " st)
  90     (modify-syntax-entry ?} "){  " st)
  91     (modify-syntax-entry ?\| "\" 23bn" st)
  92     ;; Guile allows #! ... !# comments.
  93     ;; But SRFI-22 defines the comment as #!...\n instead.
  94     ;; Also Guile says that the !# should be on a line of its own.
  95     ;; It's too difficult to get it right, for too little benefit.
  96     ;; (modify-syntax-entry ?! "_ 2" st)
  97
  98     ;; Other atom delimiters
  99     (modify-syntax-entry ?\( "()  " st)
 100     (modify-syntax-entry ?\) ")(  " st)
 101     ;; It's used for single-line comments as well as for #;(...) sexp-comments.
 102     (modify-syntax-entry ?\; "<"    st)
 103     (modify-syntax-entry ?\" "\"   " st)
 104     (modify-syntax-entry ?' "'   " st)
 105     (modify-syntax-entry ?` "'   " st)
 106
 107     ;; Special characters
 108     (modify-syntax-entry ?, "'   " st)
 109     (modify-syntax-entry ?@ "'   " st)
 110     (modify-syntax-entry ?# "' 14" st)
 111     (modify-syntax-entry ?\\ "\\   " st)
 112     st))
 113 \f
 114 (defvar scheme-mode-abbrev-table nil)
 115 (define-abbrev-table 'scheme-mode-abbrev-table ())
 116
 117 (defvar scheme-imenu-generic-expression
 118       '((nil
 119          "^(define\\(\\|-\\(generic\\(\\|-procedure\\)\\|method\\)\\)*\\s-+(?\\(\\sw+\\)" 4)
 120         ("Types"
 121          "^(define-class\\s-+(?\\(\\sw+\\)" 1)
 122         ("Macros"
 123          "^(\\(defmacro\\|define-macro\\|define-syntax\\)\\s-+(?\\(\\sw+\\)" 2))
 124   "Imenu generic expression for Scheme mode.  See `imenu-generic-expression'.")
 125
 126 (defun scheme-mode-variables ()
 127   (set-syntax-table scheme-mode-syntax-table)
 128   (setq local-abbrev-table scheme-mode-abbrev-table)
 129   (setq-local paragraph-start (concat "$\\|" page-delimiter))
 130   (setq-local paragraph-separate paragraph-start)
 131   (setq-local paragraph-ignore-fill-prefix t)
 132   (setq-local fill-paragraph-function 'lisp-fill-paragraph)
 133   ;; Adaptive fill mode gets in the way of auto-fill,
 134   ;; and should make no difference for explicit fill
 135   ;; because lisp-fill-paragraph should do the job.
 136   (setq-local adaptive-fill-mode nil)
 137   (setq-local indent-line-function 'lisp-indent-line)
 138   (setq-local parse-sexp-ignore-comments t)
 139   (setq-local outline-regexp ";;; \\|(....")
 140   (setq-local add-log-current-defun-function #'lisp-current-defun-name)
 141   (setq-local comment-start ";")
 142   (setq-local comment-add 1)
 143   (setq-local comment-start-skip ";+[ \t]*")
 144   (setq-local comment-use-syntax t)
 145   (setq-local comment-column 40)
 146   (setq-local parse-sexp-ignore-comments t)
 147   (setq-local lisp-indent-function 'scheme-indent-function)
 148   (setq mode-line-process '("" scheme-mode-line-process))
 149   (setq-local imenu-case-fold-search t)
 150   (setq-local imenu-generic-expression scheme-imenu-generic-expression)
 151   (setq-local imenu-syntax-alist '(("+-*/.<>=?!$%_&~^:" . "w")))
 152   (setq-local syntax-propertize-function #'scheme-syntax-propertize)
 153   (setq font-lock-defaults
 154         '((scheme-font-lock-keywords
 155            scheme-font-lock-keywords-1 scheme-font-lock-keywords-2)
 156           nil t (("+-*/.<>=!?$%_&~^:" . "w") (?#. "w 14"))
 157           beginning-of-defun
 158           (font-lock-mark-block-function . mark-defun)))
 159   (setq-local lisp-doc-string-elt-property 'scheme-doc-string-elt))
 160
 161 (defvar scheme-mode-line-process "")
 162
 163 (defvar scheme-mode-map
 164   (let ((smap (make-sparse-keymap))
 165         (map (make-sparse-keymap "Scheme")))
 166     (set-keymap-parent smap lisp-mode-shared-map)
 167     (define-key smap [menu-bar scheme] (cons "Scheme" map))
 168     (define-key map [run-scheme] '("Run Inferior Scheme" . run-scheme))
 169     (define-key map [uncomment-region]
 170       '("Uncomment Out Region" . (lambda (beg end)
 171                                    (interactive "r")
 172                                    (comment-region beg end '(4)))))
 173     (define-key map [comment-region] '("Comment Out Region" . comment-region))
 174     (define-key map [indent-region] '("Indent Region" . indent-region))
 175     (define-key map [indent-line] '("Indent Line" . lisp-indent-line))
 176     (put 'comment-region 'menu-enable 'mark-active)
 177     (put 'uncomment-region 'menu-enable 'mark-active)
 178     (put 'indent-region 'menu-enable 'mark-active)
 179     smap)
 180   "Keymap for Scheme mode.
 181 All commands in `lisp-mode-shared-map' are inherited by this map.")
 182
 183 ;; Used by cmuscheme
 184 (defun scheme-mode-commands (map)
 185   ;;(define-key map "\t" 'indent-for-tab-command) ; default
 186   (define-key map "\177" 'backward-delete-char-untabify)
 187   (define-key map "\e\C-q" 'indent-sexp))
 188 \f
 189 ;;;###autoload
 190 (define-derived-mode scheme-mode prog-mode "Scheme"
 191   "Major mode for editing Scheme code.
 192 Editing commands are similar to those of `lisp-mode'.
 193
 194 In addition, if an inferior Scheme process is running, some additional
 195 commands will be defined, for evaluating expressions and controlling
 196 the interpreter, and the state of the process will be displayed in the
 197 mode line of all Scheme buffers.  The names of commands that interact
 198 with the Scheme process start with \"xscheme-\" if you use the MIT
 199 Scheme-specific `xscheme' package; for more information see the
 200 documentation for `xscheme-interaction-mode'.  Use \\[run-scheme] to
 201 start an inferior Scheme using the more general `cmuscheme' package.
 202
 203 Commands:
 204 Delete converts tabs to spaces as it moves back.
 205 Blank lines separate paragraphs.  Semicolons start comments.
 206 \\{scheme-mode-map}"
 207   (scheme-mode-variables))
 208
 209 (defgroup scheme nil
 210   "Editing Scheme code."
 211   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
 212   :group 'lisp)
 213
 214 (defcustom scheme-mit-dialect t
 215   "If non-nil, scheme mode is specialized for MIT Scheme.
 216 Set this to nil if you normally use another dialect."
 217   :type 'boolean
 218   :group 'scheme)
 219
 220 (defcustom dsssl-sgml-declaration
 221   "<!DOCTYPE style-sheet PUBLIC \"-//James Clark//DTD DSSSL Style Sheet//EN\">
 222 "
 223   "An SGML declaration for the DSSSL file.
 224 If it is defined as a string this will be inserted into an empty buffer
 225 which is in `dsssl-mode'.  It is typically James Clark's style-sheet
 226 doctype, as required for Jade."
 227   :type '(choice (string :tag "Specified string")
 228                  (const :tag "None" :value nil))
 229   :group 'scheme)
 230
 231 (defcustom scheme-mode-hook nil
 232   "Normal hook run when entering `scheme-mode'.
 233 See `run-hooks'."
 234   :type 'hook
 235   :group 'scheme)
 236
 237 (defcustom dsssl-mode-hook nil
 238   "Normal hook run when entering `dsssl-mode'.
 239 See `run-hooks'."
 240   :type 'hook
 241   :group 'scheme)
 242
 243 ;; This is shared by cmuscheme and xscheme.
 244 (defcustom scheme-program-name "scheme"
 245   "Program invoked by the `run-scheme' command."
 246   :type 'string
 247   :group 'scheme)
 248
 249 (defvar dsssl-imenu-generic-expression
 250   ;; Perhaps this should also look for the style-sheet DTD tags.  I'm
 251   ;; not sure it's the best way to organize it; perhaps one type
 252   ;; should be at the first level, though you don't see this anyhow if
 253   ;; it gets split up.
 254   '(("Defines"
 255      "^(define\\s-+(?\\(\\sw+\\)" 1)
 256     ("Modes"
 257      "^\\s-*(mode\\s-+\\(\\(\\sw\\|\\s-\\)+\\)" 1)
 258     ("Elements"
 259      ;; (element foo ...) or (element (foo bar ...) ...)
 260      ;; Fixme: Perhaps it should do `root'.
 261      "^\\s-*(element\\s-+(?\\(\\(\\sw\\|\\s-\\)+\\))?" 1)
 262     ("Declarations"
 263      "^(declare\\(-\\sw+\\)+\\>\\s-+\\(\\sw+\\)" 2))
 264   "Imenu generic expression for DSSSL mode.  See `imenu-generic-expression'.")
 265
 266 (defconst scheme-font-lock-keywords-1
 267   (eval-when-compile
 268     (list
 269      ;;
 270      ;; Declarations.  Hannes Haug <hannes.haug@student.uni-tuebingen.de> says
 271      ;; this works for SOS, STklos, SCOOPS, Meroon and Tiny CLOS.
 272      (list (concat "(\\(define\\*?\\("
 273                    ;; Function names.
 274                    "\\(\\|-public\\|-method\\|-generic\\(-procedure\\)?\\)\\|"
 275                    ;; Macro names, as variable names.  A bit dubious, this.
 276                    "\\(-syntax\\|-macro\\)\\|"
 277                    ;; Class names.
 278                    "-class"
 279                    ;; Guile modules.
 280                    "\\|-module"
 281                    "\\)\\)\\>"
 282                    ;; Any whitespace and declared object.
 283                    ;; The "(*" is for curried definitions, e.g.,
 284                    ;;  (define ((sum a) b) (+ a b))
 285                    "[ \t]*(*"
 286                    "\\(\\sw+\\)?")
 287            '(1 font-lock-keyword-face)
 288            '(6 (cond ((match-beginning 3) font-lock-function-name-face)
 289                      ((match-beginning 5) font-lock-variable-name-face)
 290                      (t font-lock-type-face))
 291                nil t))
 292      ))
 293   "Subdued expressions to highlight in Scheme modes.")
 294
 295 (defconst scheme-font-lock-keywords-2
 296   (append scheme-font-lock-keywords-1
 297    (eval-when-compile
 298      (list
 299       ;;
 300       ;; Control structures.
 301       (cons
 302        (concat
 303         "(" (regexp-opt
 304              '("begin" "call-with-current-continuation" "call/cc"
 305                "call-with-input-file" "call-with-output-file" "case" "cond"
 306                "do" "else" "for-each" "if" "lambda" "λ"
 307                "let" "let*" "let-syntax" "letrec" "letrec-syntax"
 308                ;; R6RS library subforms.
 309                "export" "import"
 310                ;; SRFI 11 usage comes up often enough.
 311                "let-values" "let*-values"
 312                ;; Hannes Haug <hannes.haug@student.uni-tuebingen.de> wants:
 313                "and" "or" "delay" "force"
 314                ;; Stefan Monnier <stefan.monnier@epfl.ch> says don't bother:
 315                ;;"quasiquote" "quote" "unquote" "unquote-splicing"
 316                "map" "syntax" "syntax-rules") t)
 317         "\\>") 1)
 318       ;;
 319       ;; It wouldn't be Scheme w/o named-let.
 320       '("(let\\s-+\\(\\sw+\\)"
 321         (1 font-lock-function-name-face))
 322       ;;
 323       ;; David Fox <fox@graphics.cs.nyu.edu> for SOS/STklos class specifiers.
 324       '("\\<<\\sw+>\\>" . font-lock-type-face)
 325       ;;
 326       ;; Scheme `:' and `#:' keywords as builtins.
 327       '("\\<#?:\\sw+\\>" . font-lock-builtin-face)
 328       ;; R6RS library declarations.
 329       '("(\\(\\<library\\>\\)\\s-*(?\\(\\sw+\\)?"
 330         (1 font-lock-keyword-face)
 331         (2 font-lock-type-face))
 332       )))
 333   "Gaudy expressions to highlight in Scheme modes.")
 334
 335 (defvar scheme-font-lock-keywords scheme-font-lock-keywords-1
 336   "Default expressions to highlight in Scheme modes.")
 337
 338 (defconst scheme-sexp-comment-syntax-table
 339   (let ((st (make-syntax-table scheme-mode-syntax-table)))
 340     (modify-syntax-entry ?\; "." st)
 341     (modify-syntax-entry ?\n " " st)
 342     (modify-syntax-entry ?#  "'" st)
 343     st))
 344
 345 (put 'lambda 'scheme-doc-string-elt 2)
 346 ;; Docstring's pos in a `define' depends on whether it's a var or fun def.
 347 (put 'define 'scheme-doc-string-elt
 348      (lambda ()
 349        ;; The function is called with point right after "define".
 350        (forward-comment (point-max))
 351        (if (eq (char-after) ?\() 2 0)))
 352
 353 (defun scheme-syntax-propertize (beg end)
 354   (goto-char beg)
 355   (scheme-syntax-propertize-sexp-comment (point) end)
 356   (funcall
 357    (syntax-propertize-rules
 358     ("\\(#\\);" (1 (prog1 "< cn"
 359                      (scheme-syntax-propertize-sexp-comment (point) end)))))
 360    (point) end))
 361
 362 (defun scheme-syntax-propertize-sexp-comment (_ end)
 363   (let ((state (syntax-ppss)))
 364     (when (eq 2 (nth 7 state))
 365       ;; It's a sexp-comment.  Tell parse-partial-sexp where it ends.
 366       (condition-case nil
 367           (progn
 368             (goto-char (+ 2 (nth 8 state)))
 369             ;; FIXME: this doesn't handle the case where the sexp
 370             ;; itself contains a #; comment.
 371             (forward-sexp 1)
 372             (put-text-property (1- (point)) (point)
 373                                'syntax-table (string-to-syntax "> cn")))
 374         (scan-error (goto-char end))))))
 375
 376 ;;;###autoload
 377 (define-derived-mode dsssl-mode scheme-mode "DSSSL"
 378   "Major mode for editing DSSSL code.
 379 Editing commands are similar to those of `lisp-mode'.
 380
 381 Commands:
 382 Delete converts tabs to spaces as it moves back.
 383 Blank lines separate paragraphs.  Semicolons start comments.
 384 \\{scheme-mode-map}
 385 Entering this mode runs the hooks `scheme-mode-hook' and then
 386 `dsssl-mode-hook' and inserts the value of `dsssl-sgml-declaration' if
 387 that variable's value is a string."
 388   (setq-local page-delimiter "^;;;") ; ^L not valid SGML char
 389   ;; Insert a suitable SGML declaration into an empty buffer.
 390   ;; FIXME: This should use `auto-insert-alist' instead.
 391   (and (zerop (buffer-size))
 392        (stringp dsssl-sgml-declaration)
 393        (not buffer-read-only)
 394        (insert dsssl-sgml-declaration))
 395   (setq font-lock-defaults '(dsssl-font-lock-keywords
 396                              nil t (("+-*/.<>=?$%_&~^:" . "w"))
 397                              beginning-of-defun
 398                              (font-lock-mark-block-function . mark-defun)))
 399   (setq-local add-log-current-defun-function #'lisp-current-defun-name)
 400   (setq-local imenu-case-fold-search nil)
 401   (setq imenu-generic-expression dsssl-imenu-generic-expression)
 402   (setq-local imenu-syntax-alist '(("+-*/.<>=?$%_&~^:" . "w"))))
 403
 404 ;; Extra syntax for DSSSL.  This isn't separated from Scheme, but
 405 ;; shouldn't cause much trouble in scheme-mode.
 406 (put 'element 'scheme-indent-function 1)
 407 (put 'mode 'scheme-indent-function 1)
 408 (put 'with-mode 'scheme-indent-function 1)
 409 (put 'make 'scheme-indent-function 1)
 410 (put 'style 'scheme-indent-function 1)
 411 (put 'root 'scheme-indent-function 1)
 412 (put 'λ 'scheme-indent-function 1)
 413
 414 (defvar dsssl-font-lock-keywords
 415   (eval-when-compile
 416     (list
 417      ;; Similar to Scheme
 418      (list "(\\(define\\(-\\w+\\)?\\)\\>[       ]*\\\((?\\)\\(\\sw+\\)\\>"
 419            '(1 font-lock-keyword-face)
 420            '(4 font-lock-function-name-face))
 421      (cons
 422       (concat "(\\("
 423               ;; (make-regexp '("case" "cond" "else" "if" "lambda"
 424               ;; "let" "let*" "letrec" "and" "or" "map" "with-mode"))
 425               "and\\|c\\(ase\\|ond\\)\\|else\\|if\\|"
 426               "l\\(ambda\\|et\\(\\|*\\|rec\\)\\)\\|map\\|or\\|with-mode"
 427               "\\)\\>")
 428       1)
 429      ;; DSSSL syntax
 430      '("(\\(element\\|mode\\|declare-\\w+\\)\\>[        ]*\\(\\sw+\\)"
 431        (1 font-lock-keyword-face)
 432        (2 font-lock-type-face))
 433      '("(\\(element\\)\\>[      ]*(\\(\\S)+\\))"
 434        (1 font-lock-keyword-face)
 435        (2 font-lock-type-face))
 436      '("\\<\\sw+:\\>" . font-lock-constant-face) ; trailing `:' c.f. scheme
 437      ;; SGML markup (from sgml-mode) :
 438      '("<\\([!?][-a-z0-9]+\\)" 1 font-lock-keyword-face)
 439      '("<\\(/?[-a-z0-9]+\\)" 1 font-lock-function-name-face)))
 440   "Default expressions to highlight in DSSSL mode.")
 441
 442 \f
 443 (defvar calculate-lisp-indent-last-sexp)
 444
 445
 446 ;; FIXME this duplicates almost all of lisp-indent-function.
 447 ;; Extract common code to a subroutine.
 448 (defun scheme-indent-function (indent-point state)
 449   "Scheme mode function for the value of the variable `lisp-indent-function'.
 450 This behaves like the function `lisp-indent-function', except that:
 451
 452 i) it checks for a non-nil value of the property `scheme-indent-function'
 453 \(or the deprecated `scheme-indent-hook'), rather than `lisp-indent-function'.
 454
 455 ii) if that property specifies a function, it is called with three
 456 arguments (not two), the third argument being the default (i.e., current)
 457 indentation."
 458   (let ((normal-indent (current-column)))
 459     (goto-char (1+ (elt state 1)))
 460     (parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
 461     (if (and (elt state 2)
 462              (not (looking-at "\\sw\\|\\s_")))
 463         ;; car of form doesn't seem to be a symbol
 464         (progn
 465           (if (not (> (save-excursion (forward-line 1) (point))
 466                       calculate-lisp-indent-last-sexp))
 467               (progn (goto-char calculate-lisp-indent-last-sexp)
 468                      (beginning-of-line)
 469                      (parse-partial-sexp (point)
 470                                          calculate-lisp-indent-last-sexp 0 t)))
 471           ;; Indent under the list or under the first sexp on the same
 472           ;; line as calculate-lisp-indent-last-sexp.  Note that first
 473           ;; thing on that line has to be complete sexp since we are
 474           ;; inside the innermost containing sexp.
 475           (backward-prefix-chars)
 476           (current-column))
 477       (let ((function (buffer-substring (point)
 478                                         (progn (forward-sexp 1) (point))))
 479             method)
 480         (setq method (or (get (intern-soft function) 'scheme-indent-function)
 481                          (get (intern-soft function) 'scheme-indent-hook)))
 482         (cond ((or (eq method 'defun)
 483                    (and (null method)
 484                         (> (length function) 3)
 485                         (string-match "\\`def" function)))
 486                (lisp-indent-defform state indent-point))
 487               ((integerp method)
 488                (lisp-indent-specform method state
 489                                      indent-point normal-indent))
 490               (method
 491                 (funcall method state indent-point normal-indent)))))))
 492
 493 \f
 494 ;;; Let is different in Scheme
 495
 496 ;; (defun scheme-would-be-symbol (string)
 497 ;;   (not (string-equal (substring string 0 1) "(")))
 498
 499 ;; (defun scheme-next-sexp-as-string ()
 500 ;;   ;; Assumes that it is protected by a save-excursion
 501 ;;   (forward-sexp 1)
 502 ;;   (let ((the-end (point)))
 503 ;;     (backward-sexp 1)
 504 ;;     (buffer-substring (point) the-end)))
 505
 506 ;; This is correct but too slow.
 507 ;; The one below works almost always.
 508 ;;(defun scheme-let-indent (state indent-point)
 509 ;;  (if (scheme-would-be-symbol (scheme-next-sexp-as-string))
 510 ;;      (scheme-indent-specform 2 state indent-point)
 511 ;;      (scheme-indent-specform 1 state indent-point)))
 512
 513 (defun scheme-let-indent (state indent-point normal-indent)
 514   (skip-chars-forward " \t")
 515   (if (looking-at "[-a-zA-Z0-9+*/?!@$%^&_:~]")
 516       (lisp-indent-specform 2 state indent-point normal-indent)
 517     (lisp-indent-specform 1 state indent-point normal-indent)))
 518
 519 ;; (put 'begin 'scheme-indent-function 0), say, causes begin to be indented
 520 ;; like defun if the first form is placed on the next line, otherwise
 521 ;; it is indented like any other form (i.e. forms line up under first).
 522
 523 (put 'begin 'scheme-indent-function 0)
 524 (put 'case 'scheme-indent-function 1)
 525 (put 'delay 'scheme-indent-function 0)
 526 (put 'do 'scheme-indent-function 2)
 527 (put 'lambda 'scheme-indent-function 1)
 528 (put 'let 'scheme-indent-function 'scheme-let-indent)
 529 (put 'let* 'scheme-indent-function 1)
 530 (put 'letrec 'scheme-indent-function 1)
 531 (put 'let-values 'scheme-indent-function 1) ; SRFI 11
 532 (put 'let*-values 'scheme-indent-function 1) ; SRFI 11
 533 (put 'sequence 'scheme-indent-function 0) ; SICP, not r4rs
 534 (put 'let-syntax 'scheme-indent-function 1)
 535 (put 'letrec-syntax 'scheme-indent-function 1)
 536 (put 'syntax-rules 'scheme-indent-function 1)
 537 (put 'syntax-case 'scheme-indent-function 2) ; not r5rs
 538 (put 'library 'scheme-indent-function 1) ; R6RS
 539
 540 (put 'call-with-input-file 'scheme-indent-function 1)
 541 (put 'with-input-from-file 'scheme-indent-function 1)
 542 (put 'with-input-from-port 'scheme-indent-function 1)
 543 (put 'call-with-output-file 'scheme-indent-function 1)
 544 (put 'with-output-to-file 'scheme-indent-function 1)
 545 (put 'with-output-to-port 'scheme-indent-function 1)
 546 (put 'call-with-values 'scheme-indent-function 1) ; r5rs?
 547 (put 'dynamic-wind 'scheme-indent-function 3) ; r5rs?
 548 \f
 549 ;;;; MIT Scheme specific indentation.
 550
 551 (if scheme-mit-dialect
 552     (progn
 553       (put 'fluid-let 'scheme-indent-function 1)
 554       (put 'in-package 'scheme-indent-function 1)
 555       (put 'local-declare 'scheme-indent-function 1)
 556       (put 'macro 'scheme-indent-function 1)
 557       (put 'make-environment 'scheme-indent-function 0)
 558       (put 'named-lambda 'scheme-indent-function 1)
 559       (put 'using-syntax 'scheme-indent-function 1)
 560
 561       (put 'with-input-from-string 'scheme-indent-function 1)
 562       (put 'with-output-to-string 'scheme-indent-function 0)
 563       (put 'with-values 'scheme-indent-function 1)
 564
 565       (put 'syntax-table-define 'scheme-indent-function 2)
 566       (put 'list-transform-positive 'scheme-indent-function 1)
 567       (put 'list-transform-negative 'scheme-indent-function 1)
 568       (put 'list-search-positive 'scheme-indent-function 1)
 569       (put 'list-search-negative 'scheme-indent-function 1)
 570
 571       (put 'access-components 'scheme-indent-function 1)
 572       (put 'assignment-components 'scheme-indent-function 1)
 573       (put 'combination-components 'scheme-indent-function 1)
 574       (put 'comment-components 'scheme-indent-function 1)
 575       (put 'conditional-components 'scheme-indent-function 1)
 576       (put 'disjunction-components 'scheme-indent-function 1)
 577       (put 'declaration-components 'scheme-indent-function 1)
 578       (put 'definition-components 'scheme-indent-function 1)
 579       (put 'delay-components 'scheme-indent-function 1)
 580       (put 'in-package-components 'scheme-indent-function 1)
 581       (put 'lambda-components 'scheme-indent-function 1)
 582       (put 'lambda-components* 'scheme-indent-function 1)
 583       (put 'lambda-components** 'scheme-indent-function 1)
 584       (put 'open-block-components 'scheme-indent-function 1)
 585       (put 'pathname-components 'scheme-indent-function 1)
 586       (put 'procedure-components 'scheme-indent-function 1)
 587       (put 'sequence-components 'scheme-indent-function 1)
 588       (put 'unassigned\?-components 'scheme-indent-function 1)
 589       (put 'unbound\?-components 'scheme-indent-function 1)
 590       (put 'variable-components 'scheme-indent-function 1)))
 591
 592 (provide 'scheme)
 593
 594 ;;; scheme.el ends here