configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2014 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.3.90)
  26
  27 dnl We get MINGW64 with MSYS2
  28 if test "x$MSYSTEM" = "xMINGW32" -o "x$MSYSTEM" = "xMINGW64"
  29 then
  30   . $srcdir/nt/mingw-cfg.site
  31
  32   case $srcdir in
  33     /* | ?:*)
  34       # srcdir is an absolute path.  In this case, force the format
  35       # "/c/foo/bar", to simplify later conversions to native Windows
  36       # format ("c:/foo/bar")
  37       srcdir=`cd "${srcdir}" && pwd -W`
  38       srcdir="/${srcdir:0:1}${srcdir:2}"
  39       ;;
  40   esac
  41 fi
  42
  43 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  44 dnl and then quoted again for a C string.  Separate options with spaces.
  45 dnl Add some environment variables, if they were passed via the environment
  46 dnl rather than on the command-line.
  47 emacs_config_options=
  48 optsep=
  49 dnl This is the documented way to record the args passed to configure,
  50 dnl rather than $ac_configure_args.
  51 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  52   case $opt in
  53     -n | --no-create | --no-recursion)
  54       continue ;;
  55     CFLAGS | CPPFLAGS | LDFLAGS)
  56       eval 'test "${'$opt'+set}" = set' || continue
  57       case " $*" in
  58         *" $opt="*) continue ;;
  59       esac
  60       eval opt=$opt=\$$opt ;;
  61   esac
  62
  63   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  64   case $opt in
  65     *[["$emacs_shell_specials"]]*)
  66       case $opt in
  67         *\'*)
  68           emacs_quote_apostrophes="s/'/'\\\\''/g"
  69           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  70       esac
  71       opt="'$opt'"
  72       case $opt in
  73         *[['"\\']]*)
  74           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  75           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  76       esac ;;
  77   esac
  78   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  79   optsep=' '
  80 done
  81
  82 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  83 AC_CONFIG_SRCDIR(src/lisp.h)
  84 AC_CONFIG_AUX_DIR(build-aux)
  85
  86 xcsdkdir=
  87 AC_CHECK_PROGS(XCRUN, [xcrun])
  88 if test -n "$XCRUN"; then
  89   if test -z "$MAKE"; then
  90     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  91     dnl SET_MAKE and with the usual MAKE variable that 'make' itself uses.
  92     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  93     if test -z "$MAKE_PROG"; then
  94       MAKE="$XCRUN MAKE"
  95       export MAKE
  96       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  97     fi
  98   fi
  99 fi
 100
 101 dnl Fairly arbitrary, older versions might work too.
 102 AM_INIT_AUTOMAKE(1.11)
 103
 104 dnl Support for --program-prefix, --program-suffix and
 105 dnl --program-transform-name options
 106 AC_ARG_PROGRAM
 107
 108 dnl It is important that variables on the RHS not be expanded here,
 109 dnl hence the single quotes.  This is per the GNU coding standards, see
 110 dnl (autoconf) Installation Directory Variables
 111 dnl See also epaths.h below.
 112 lispdir='${datadir}/emacs/${version}/lisp'
 113 standardlisppath='${lispdir}'
 114 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 115 '${datadir}/emacs/site-lisp'
 116 lisppath='${locallisppath}:${standardlisppath}'
 117 etcdir='${datadir}/emacs/${version}/etc'
 118 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 119 etcdocdir='${datadir}/emacs/${version}/etc'
 120 gamedir='${localstatedir}/games/emacs'
 121
 122 dnl Special option to disable the most of other options.
 123 AC_ARG_WITH(all,
 124 [AS_HELP_STRING([--without-all],
 125                 [omit almost all features and build
 126                 small executable with minimal dependencies])],
 127   [with_features=$withval],
 128   [with_features=yes])
 129
 130 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 131 dnl Create a new --with option that defaults to being disabled.
 132 dnl NAME is the base name of the option.  The shell variable with_NAME
 133 dnl   will be set to either the user's value (if the option is
 134 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 135 dnl   option is not specified).  Note that the shell variable name is
 136 dnl   constructed as autoconf does, by replacing non-alphanumeric
 137 dnl   characters with "_".
 138 dnl HELP-STRING is the help text for the option.
 139 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 140   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 141     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 142 ])dnl
 143
 144 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 145 dnl Create a new --with option that defaults to $with_features.
 146 dnl NAME is the base name of the option.  The shell variable with_NAME
 147 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 148 dnl   'yes' (if the option is not specified).  Note that the shell
 149 dnl   variable name is constructed as autoconf does, by replacing
 150 dnl   non-alphanumeric characters with "_".
 151 dnl HELP-STRING is the help text for the option.
 152 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 153   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 154    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 155 ])dnl
 156
 157 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 158 if test "$with_pop" = yes; then
 159    AC_DEFINE(MAIL_USE_POP)
 160 fi
 161 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 162
 163 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 164 if test "$with_kerberos" != no; then
 165    AC_DEFINE(KERBEROS)
 166 fi
 167 AH_TEMPLATE(KERBEROS,
 168             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 169
 170 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 171 if test "${with_kerberos5}" != no; then
 172   if test "${with_kerberos}" = no; then
 173     with_kerberos=yes
 174     AC_DEFINE(KERBEROS)
 175   fi
 176   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 177 fi
 178
 179 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 180 dnl FIXME hesiod support may not be present, so it seems like an error
 181 dnl to define, or at least use, this unconditionally.
 182 if test "$with_hesiod" != no; then
 183   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 184 fi
 185
 186 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 187 if test "$with_mmdf" != no; then
 188    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 189 fi
 190
 191 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 192 if test "$with_mail_unlink" != no; then
 193    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 194 fi
 195
 196 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 197     [string giving default POP mail host])],
 198     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 199
 200 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 201   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 202 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW.])],
 203   [ case "${withval}" in
 204       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 205       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 206 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 207       ;;
 208     esac
 209     with_sound=$val
 210   ],
 211   [with_sound=$with_features])
 212
 213 dnl FIXME currently it is not the last.
 214 dnl This should be the last --with option, because --with-x is
 215 dnl added later on when we find the file name of X, and it's best to
 216 dnl keep them together visually.
 217 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 218  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 219 [         case "${withval}" in
 220             y | ye | yes )      val=gtk ;;
 221             n | no )            val=no  ;;
 222             l | lu | luc | luci | lucid )       val=lucid ;;
 223             a | at | ath | athe | athen | athena )      val=athena ;;
 224             m | mo | mot | moti | motif )       val=motif ;;
 225             g | gt | gtk  )     val=gtk ;;
 226             gtk2  )     val=gtk2 ;;
 227             gtk3  )     val=gtk3 ;;
 228             * )
 229 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 230 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 231 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 232 `athena' and `lucid' are synonyms.])
 233             ;;
 234           esac
 235           with_x_toolkit=$val
 236 ])
 237
 238 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 239 if test "$with_wide_int" = yes; then
 240   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 241 fi
 242
 243 dnl _ON results in a '--without' option in the --help output, so
 244 dnl the help text should refer to "don't compile", etc.
 245 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 246 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 247 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 248 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 249 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 250 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 251 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 252 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 253
 254 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 255 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 256 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 257
 258 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 259 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 260 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 261 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 262 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 263
 264 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 265 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 266 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 267 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 268 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 269 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 270 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 271
 272 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 273  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 274  [ case "${withval}" in
 275     y | ye | yes )      val=yes ;;
 276     n | no )            val=no  ;;
 277     g | gf | gfi | gfil | gfile )       val=gfile ;;
 278     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 279     w | w3 | w32 )      val=w32 ;;
 280     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 281 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 282 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 283 otherwise for the first of `gfile' or `inotify' that is usable.])
 284     ;;
 285    esac
 286    with_file_notification=$val
 287  ],
 288  [with_file_notification=$with_features])
 289
 290 ## For the times when you want to build Emacs but don't have
 291 ## a suitable makeinfo, and can live without the manuals.
 292 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 293 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 294
 295 ## Makefile.in needs the cache file name.
 296 AC_SUBST(cache_file)
 297
 298 ## This is an option because I do not know if all info/man support
 299 ## compressed files, nor how to test if they do so.
 300 OPTION_DEFAULT_ON([compress-install],
 301   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 302 make GZIP_PROG= install])
 303
 304 AC_ARG_WITH([pkg-config-prog],dnl
 305 [AS_HELP_STRING([--with-pkg-config-prog=FILENAME],
 306                   [file name of pkg-config for finding GTK and librsvg])])
 307 if test "X${with_pkg_config_prog}" != X; then
 308    if test "${with_pkg_config_prog}" != yes; then
 309       PKG_CONFIG="${with_pkg_config_prog}"
 310    fi
 311 fi
 312
 313 AC_ARG_WITH(gameuser,dnl
 314 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 315 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 316   && gameuser="${with_gameuser}"
 317 test "X$gameuser" = X && gameuser=games
 318
 319 AC_ARG_WITH([gnustep-conf],dnl
 320 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 321    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 322 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 323   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 324 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 325      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 326
 327 AC_ARG_ENABLE(ns-self-contained,
 328 [AS_HELP_STRING([--disable-ns-self-contained],
 329                 [disable self contained build under NeXTstep])],
 330    EN_NS_SELF_CONTAINED=$enableval,
 331    EN_NS_SELF_CONTAINED=yes)
 332
 333 AC_ARG_ENABLE(locallisppath,
 334 [AS_HELP_STRING([--enable-locallisppath=PATH],
 335                 [directories Emacs should search for lisp files specific
 336                  to this site])],
 337 if test "${enableval}" = "no"; then
 338   locallisppath=
 339 elif test "${enableval}" != "yes"; then
 340   locallisppath=${enableval}
 341 fi)
 342
 343 AC_ARG_ENABLE(checking,
 344 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 345                 [enable expensive run-time checks.  With LIST,
 346                  enable only specific categories of checks.
 347                  Categories are: all,yes,no.
 348                  Flags are: stringbytes, stringoverrun, stringfreelist,
 349                  xmallocoverrun, conslist, glyphs])],
 350 [ac_checking_flags="${enableval}"],[])
 351 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 352 for check in $ac_checking_flags
 353 do
 354         case $check in
 355         # these set all the flags to specific states
 356         yes)            ac_enable_checking=1 ;;
 357         no)             ac_enable_checking= ;
 358                         ac_gc_check_stringbytes= ;
 359                         ac_gc_check_string_overrun= ;
 360                         ac_gc_check_string_free_list= ;
 361                         ac_xmalloc_overrun= ;
 362                         ac_gc_check_cons_list= ;
 363                         ac_glyphs_debug= ;;
 364         all)            ac_enable_checking=1 ;
 365                         ac_gc_check_stringbytes=1 ;
 366                         ac_gc_check_string_overrun=1 ;
 367                         ac_gc_check_string_free_list=1 ;
 368                         ac_xmalloc_overrun=1 ;
 369                         ac_gc_check_cons_list=1 ;
 370                         ac_glyphs_debug=1 ;;
 371         # these enable particular checks
 372         stringbytes)    ac_gc_check_stringbytes=1 ;;
 373         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 374         stringfreelist) ac_gc_check_string_free_list=1 ;;
 375         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 376         conslist)       ac_gc_check_cons_list=1 ;;
 377         glyphs)         ac_glyphs_debug=1 ;;
 378         *)      AC_MSG_ERROR(unknown check category $check) ;;
 379         esac
 380 done
 381 IFS="$ac_save_IFS"
 382
 383 if test x$ac_enable_checking != x ; then
 384   AC_DEFINE(ENABLE_CHECKING, 1,
 385 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 386 fi
 387 if test x$ac_gc_check_stringbytes != x ; then
 388   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 389 [Define this temporarily to hunt a bug.  If defined, the size of
 390    strings is redundantly recorded in sdata structures so that it can
 391    be compared to the sizes recorded in Lisp strings.])
 392 fi
 393 if test x$ac_gc_check_string_overrun != x ; then
 394   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 395 [Define this to check for short string overrun.])
 396 fi
 397 if test x$ac_gc_check_string_free_list != x ; then
 398   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 399 [Define this to check the string free list.])
 400 fi
 401 if test x$ac_xmalloc_overrun != x ; then
 402   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 403 [Define this to check for malloc buffer overrun.])
 404 fi
 405 if test x$ac_gc_check_cons_list != x ; then
 406   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 407 [Define this to check for errors in cons list.])
 408 fi
 409 if test x$ac_glyphs_debug != x ; then
 410   AC_DEFINE(GLYPH_DEBUG, 1,
 411 [Define this to enable glyphs debugging code.])
 412 fi
 413
 414 AC_ARG_ENABLE(check-lisp-object-type,
 415 [AS_HELP_STRING([--enable-check-lisp-object-type],
 416                 [enable compile time checks for the Lisp_Object data type.
 417                 This is useful for development for catching certain types of bugs.])],
 418 if test "${enableval}" != "no"; then
 419    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 420    [Define this to enable compile time checks for the Lisp_Object data type.])
 421 fi)
 422
 423
 424 dnl The name of this option is unfortunate.  It predates, and has no
 425 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 426 dnl Actually, it stops it working.
 427 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 428 AC_ARG_ENABLE(profiling,
 429 [AS_HELP_STRING([--enable-profiling],
 430                 [build emacs with low-level, gprof profiling support.
 431                 Mainly useful for debugging Emacs itself.  May not work on
 432                 all platforms.  Stops profiler.el working.])],
 433 [ac_enable_profiling="${enableval}"],[])
 434 if test x$ac_enable_profiling != x ; then
 435    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 436 else
 437    PROFILING_CFLAGS=
 438 fi
 439 AC_SUBST(PROFILING_CFLAGS)
 440
 441 AC_ARG_ENABLE(autodepend,
 442 [AS_HELP_STRING([--enable-autodepend],
 443                 [automatically generate dependencies to .h-files.
 444                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 445                  found])],
 446 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 447
 448 AC_ARG_ENABLE(gtk-deprecation-warnings,
 449 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 450                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 451 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 452
 453 ### Canonicalize the configuration name.
 454
 455 AC_CANONICAL_HOST
 456 canonical=$host
 457 configuration=${host_alias-${build_alias-$host}}
 458
 459 dnl This used to use changequote, but, apart from `changequote is evil'
 460 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 461 dnl the great gob of text.  Thus it's not processed for possible expansion.
 462 dnl Just make sure the brackets remain balanced.
 463 dnl
 464 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 465 dnl indicated by comments.
 466 dnl quotation begins
 467 [
 468
 469 ### If you add support for a new configuration, add code to this
 470 ### switch statement to recognize your configuration name and select
 471 ### the appropriate opsys.
 472
 473 ### As far as handling version numbers on operating systems is
 474 ### concerned, make sure things will fail in a fixable way.  If
 475 ### /etc/MACHINES doesn't say anything about version numbers, be
 476 ### prepared to handle anything reasonably.  If version numbers
 477 ### matter, be sure /etc/MACHINES says something about it.
 478
 479 opsys='' unported=no
 480 case "${canonical}" in
 481
 482   ## GNU/Linux and similar ports
 483   *-*-linux* )
 484     opsys=gnu-linux
 485   ;;
 486
 487   ## FreeBSD ports
 488   *-*-freebsd* )
 489     opsys=freebsd
 490   ;;
 491
 492   ## DragonFly ports
 493   *-*-dragonfly* )
 494     opsys=dragonfly
 495   ;;
 496
 497   ## FreeBSD kernel + glibc based userland
 498   *-*-kfreebsd*gnu* )
 499     opsys=gnu-kfreebsd
 500   ;;
 501
 502   ## NetBSD ports
 503   *-*-netbsd* )
 504     opsys=netbsd
 505   ;;
 506
 507   ## OpenBSD ports
 508   *-*-openbsd* )
 509     opsys=openbsd
 510   ;;
 511
 512   ## Apple Darwin / Mac OS X
 513   *-apple-darwin* )
 514     case "${canonical}" in
 515       i[3456]86-* )  ;;
 516       powerpc-* )    ;;
 517       x86_64-* )     ;;
 518       * )            unported=yes ;;
 519     esac
 520     opsys=darwin
 521     ## Use fink packages if available.
 522     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 523 ##    if test -d /sw/include && test -d /sw/lib; then
 524 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 525 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 526 ##    fi
 527   ;;
 528
 529   ## Cygwin ports
 530   *-*-cygwin )
 531     opsys=cygwin
 532   ;;
 533
 534   ## HP 9000 series 700 and 800, running HP/UX
 535   hppa*-hp-hpux10.2* )
 536     opsys=hpux10-20
 537   ;;
 538   hppa*-hp-hpux1[1-9]* )
 539     opsys=hpux11
 540     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 541   ;;
 542
 543   ## IBM machines
 544   rs6000-ibm-aix4.[23]* )
 545     opsys=aix4-2
 546   ;;
 547   powerpc-ibm-aix4.[23]*  )
 548     opsys=aix4-2
 549   ;;
 550   rs6000-ibm-aix[56]* )
 551     opsys=aix4-2
 552   ;;
 553   powerpc-ibm-aix[56]*  )
 554     opsys=aix4-2
 555   ;;
 556
 557   ## Silicon Graphics machines
 558   ## Iris 4D
 559   mips-sgi-irix6.5 )
 560     opsys=irix6-5
 561     # Without defining _LANGUAGE_C, things get masked out in the headers
 562     # so that, for instance, grepping for `free' in stdlib.h fails and
 563     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 564     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 565   ;;
 566
 567   ## Suns
 568   *-sun-solaris* \
 569     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 570     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 571     case "${canonical}" in
 572       i[3456]86-*-* )   ;;
 573       amd64-*-*|x86_64-*-*) ;;
 574       sparc* )          ;;
 575       * )               unported=yes ;;
 576     esac
 577     case "${canonical}" in
 578       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 579                 opsys=sol2-10
 580                 emacs_check_sunpro_c=yes
 581                 ;;
 582       *-sunos5.6* | *-solaris2.6* )
 583                 opsys=sol2-6
 584                 RANLIB="ar -ts"
 585                 ;;
 586       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 587                 opsys=sol2-6
 588                 emacs_check_sunpro_c=yes
 589                 ;;
 590     esac
 591     ## Watch out for a compiler that we know will not work.
 592     case "${canonical}" in
 593      *-solaris* | *-sunos5* )
 594                 if [ "x$CC" = x/usr/ucb/cc ]; then
 595                   ## /usr/ucb/cc doesn't work;
 596                   ## we should find some other compiler that does work.
 597                   unset CC
 598                 fi
 599                 ;;
 600       *) ;;
 601     esac
 602   ;;
 603
 604   ## Intel 386 machines where we don't care about the manufacturer.
 605   i[3456]86-*-* )
 606     case "${canonical}" in
 607       *-darwin* )               opsys=darwin ;;
 608       *-mingw32 )
 609                 opsys=mingw32
 610                 # MinGW overrides and adds some system headers in nt/inc.
 611                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 612                 ;;
 613       *-sysv4.2uw* )            opsys=unixware ;;
 614       *-sysv5uw* )              opsys=unixware ;;
 615       *-sysv5OpenUNIX* )        opsys=unixware ;;
 616       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 617     esac
 618   ;;
 619
 620   # MinGW64
 621   x86_64-*-* )
 622     case "${canonical}" in
 623       *-mingw32 )
 624                 opsys=mingw32
 625                 # MinGW overrides and adds some system headers in nt/inc.
 626                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 627                 ;;
 628       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 629     esac
 630   ;;
 631
 632   * )
 633     unported=yes
 634   ;;
 635 esac
 636
 637 ### If the code above didn't choose an operating system, just choose
 638 ### an operating system based on the configuration name.  You really
 639 ### only want to use this when you have no idea what the right
 640 ### operating system is; if you know what operating systems a machine
 641 ### runs, it's cleaner to make it explicit in the case statement
 642 ### above.
 643 if test x"${opsys}" = x; then
 644   case "${canonical}" in
 645     *-gnu* )                            opsys=gnu ;;
 646     * )
 647       unported=yes
 648     ;;
 649   esac
 650 fi
 651
 652 ]
 653 dnl quotation ends
 654
 655 if test $unported = yes; then
 656   AC_MSG_ERROR([Emacs does not support `${canonical}' systems.
 657 If you think it should, please send a report to bug-gnu-emacs@gnu.org.
 658 Check `etc/MACHINES' for recognized configuration names.])
 659 fi
 660
 661
 662 #### Choose a compiler.
 663
 664 dnl Sets GCC=yes if using gcc.
 665 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 666 if test -n "$XCRUN"; then
 667   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 668   test -n "$AR" && export AR
 669 fi
 670
 671 AM_PROG_CC_C_O
 672
 673 if test x$GCC = xyes; then
 674   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 675 else
 676   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 677 fi
 678
 679 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 680 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 681 dnl that clash with MinGW.
 682 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 683
 684 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 685 AC_DEFUN([gl_CRYPTO_CHECK])
 686 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 687 # as we don't use them.
 688 AC_DEFUN([gl_FCNTL_O_FLAGS])
 689 # Avoid gnulib's threadlib module, as we do threads our own way.
 690 AC_DEFUN([gl_THREADLIB])
 691
 692 # Initialize gnulib right after choosing the compiler.
 693 dnl Amongst other things, this sets AR and ARFLAGS.
 694 gl_EARLY
 695
 696 if test "$ac_test_CFLAGS" != set; then
 697   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 698   # if -g3 works and the user does not specify CFLAGS.
 699   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 700   case $CFLAGS in
 701     '-g')
 702       emacs_g3_CFLAGS='-g3';;
 703     '-g -O2')
 704       emacs_g3_CFLAGS='-g3 -O2';;
 705     *)
 706       emacs_g3_CFLAGS='';;
 707   esac
 708   if test -n "$emacs_g3_CFLAGS"; then
 709     emacs_save_CFLAGS=$CFLAGS
 710     CFLAGS=$emacs_g3_CFLAGS
 711     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 712       [emacs_cv_prog_cc_g3],
 713       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 714          [emacs_cv_prog_cc_g3=yes],
 715          [emacs_cv_prog_cc_g3=no])])
 716     if test $emacs_cv_prog_cc_g3 != yes; then
 717       CFLAGS=$emacs_save_CFLAGS
 718     fi
 719     if test $opsys = mingw32; then
 720       CFLAGS="$CFLAGS -gdwarf-2"
 721     fi
 722   fi
 723
 724   case $CFLAGS in
 725     *-O*) ;;
 726     *)
 727       # No optimization flag was inferred for this non-GCC compiler.
 728       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 729       emacs_save_CFLAGS=$CFLAGS
 730       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 731       CFLAGS=${CFLAGS}-O
 732       AC_CACHE_CHECK([whether $CC accepts -O],
 733         [emacs_cv_prog_cc_o],
 734         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 735            [emacs_cv_prog_cc_o=yes],
 736            [emacs_cv_prog_cc_o=no])])
 737       if test $emacs_cv_prog_cc_o != yes; then
 738         CFLAGS=$emacs_save_CFLAGS
 739       fi ;;
 740   esac
 741 fi
 742
 743 AC_ARG_ENABLE([gcc-warnings],
 744   [AS_HELP_STRING([--enable-gcc-warnings],
 745                   [turn on lots of GCC warnings/errors. This is intended for
 746                    developers, and may generate false alarms when used
 747                    with older or non-GNU development tools.])],
 748   [case $enableval in
 749      yes|no) ;;
 750      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 751    esac
 752    gl_gcc_warnings=$enableval],
 753   [gl_gcc_warnings=no]
 754 )
 755
 756 AC_ARG_ENABLE(link-time-optimization,
 757 [AS_HELP_STRING([--enable-link-time-optimization],
 758                 [build emacs with link-time optimization.
 759                  This is supported only for GCC since 4.5.0.])],
 760 if test "${enableval}" != "no"; then
 761    AC_MSG_CHECKING([whether link-time optimization is supported])
 762    ac_lto_supported=no
 763    if test x$GCC = xyes; then
 764       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 765       if test x$CPUS != x; then
 766          LTO="-flto=$CPUS"
 767       else
 768          LTO="-flto"
 769       fi
 770       old_CFLAGS=$CFLAGS
 771       CFLAGS="$CFLAGS $LTO"
 772       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 773         [ac_lto_supported=yes], [ac_lto_supported=no])
 774       CFLAGS="$old_CFLAGS"
 775    fi
 776    AC_MSG_RESULT([$ac_lto_supported])
 777    if test "$ac_lto_supported" = "yes"; then
 778       CFLAGS="$CFLAGS $LTO"
 779    fi
 780 fi)
 781
 782 # clang is unduly picky about some things.
 783 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 784   [AC_COMPILE_IFELSE(
 785      [AC_LANG_PROGRAM([[
 786           #ifndef __clang__
 787             error "not clang";
 788           #endif
 789         ]])],
 790      [emacs_cv_clang=yes],
 791      [emacs_cv_clang=no])])
 792
 793 # When compiling with GCC, prefer -isystem to -I when including system
 794 # include files, to avoid generating useless diagnostics for the files.
 795 if test "$gl_gcc_warnings" != yes; then
 796   isystem='-I'
 797   if test "$emacs_cv_clang" = yes
 798   then
 799      # Turn off some warnings if supported.
 800      gl_WARN_ADD([-Wno-switch])
 801      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 802      gl_WARN_ADD([-Wno-pointer-sign])
 803   fi
 804 else
 805   isystem='-isystem '
 806
 807   # This, $nw, is the list of warnings we disable.
 808   nw=
 809
 810   case $with_x_toolkit in
 811     lucid | athena | motif)
 812        # Old toolkits mishandle 'const'.
 813        nw="$nw -Wwrite-strings"
 814        ;;
 815     *)
 816        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 817        ;;
 818   esac
 819   AC_SUBST([WERROR_CFLAGS])
 820
 821   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 822   nw="$nw -Woverlength-strings"     # Not a problem these days
 823   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 824   nw="$nw -Wformat-nonliteral"      # we do this a lot
 825   nw="$nw -Wvla"                    # warnings in gettext.h
 826   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 827   nw="$nw -Wswitch-default"         # Too many warnings for now
 828   nw="$nw -Winline"                 # OK to ignore 'inline'
 829   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 830   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 831                                     # signed overflow has undefined behavior
 832   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 833   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 834   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 835
 836   # Emacs doesn't care about shadowing; see
 837   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 838   nw="$nw -Wshadow"
 839
 840   # Emacs's use of alloca inhibits protecting the stack.
 841   nw="$nw -Wstack-protector"
 842
 843   # The following line should be removable at some point.
 844   nw="$nw -Wsuggest-attribute=pure"
 845
 846   # This part is merely for shortening the command line,
 847   # since -Wno-FOO needs to be added below regardless.
 848   nw="$nw -Wmissing-field-initializers"
 849   nw="$nw -Wswitch"
 850   nw="$nw -Wtype-limits"
 851   nw="$nw -Wunused-parameter"
 852
 853   if test $emacs_cv_clang = yes; then
 854     nw="$nw -Wcast-align"
 855   fi
 856
 857   gl_MANYWARN_ALL_GCC([ws])
 858   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 859   for w in $ws; do
 860     gl_WARN_ADD([$w])
 861   done
 862   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 863   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 864   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 865   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 866   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 867   gl_WARN_ADD([-Wno-format-nonliteral])
 868
 869   # In spite of excluding -Wlogical-op above, it is enabled, as of
 870   # gcc 4.5.0 20090517.
 871   gl_WARN_ADD([-Wno-logical-op])
 872
 873   # More things that clang is unduly picky about.
 874   if test $emacs_cv_clang = yes; then
 875     gl_WARN_ADD([-Wno-format-extra-args])
 876     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 877     gl_WARN_ADD([-Wno-unused-command-line-argument])
 878     gl_WARN_ADD([-Wno-unused-value])
 879   fi
 880
 881   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 882   AH_VERBATIM([FORTIFY_SOURCE],
 883   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 884       without upsetting glibc 2.15+. */
 885    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 886    # define _FORTIFY_SOURCE 2
 887    #endif
 888   ])
 889   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 890
 891   # We use a slightly smaller set of warning options for lib/.
 892   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 893   nw=
 894   nw="$nw -Wunused-macros"
 895
 896   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 897   AC_SUBST([GNULIB_WARN_CFLAGS])
 898 fi
 899
 900
 901
 902 dnl Some other nice autoconf tests.
 903 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 904 dnl AC_PROG_INSTALL
 905 dnl AC_PROG_MKDIR_P
 906 dnl if test "x$RANLIB" = x; then
 907 dnl   AC_PROG_RANLIB
 908 dnl fi
 909
 910
 911 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
 912 dnl can be made to directories.  This is not relevant for our usage, and
 913 dnl excludes some cases that work fine for us.  Eg MS Windows or files
 914 dnl hosted on AFS, both examples where simple links work, but links to
 915 dnl directories fail.  We use a cut-down version instead.
 916 dnl AC_PROG_LN_S
 917
 918 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
 919 rm -f conf$$ conf$$.file
 920
 921 LN_S_FILEONLY='cp -p'
 922
 923 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
 924 dnl random program in the current directory.
 925 if (echo >conf$$.file) 2>/dev/null; then
 926   if ln -s conf$$.file conf$$ 2>/dev/null; then
 927     if test "$opsys" = "mingw32"; then
 928       LN_S_FILEONLY='/bin/ln -s'
 929     else
 930       LN_S_FILEONLY='ln -s'
 931     fi
 932   elif ln conf$$.file conf$$ 2>/dev/null; then
 933     if test "$opsys" = "mingw32"; then
 934       LN_S_FILEONLY=/bin/ln
 935     else
 936       LN_S_FILEONLY=ln
 937     fi
 938   fi
 939 fi
 940
 941 rm -f conf$$ conf$$.file
 942
 943 if test "$LN_S_FILEONLY" = "ln -s"; then
 944    AC_MSG_RESULT([yes])
 945 else
 946    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
 947 fi
 948
 949 AC_SUBST(LN_S_FILEONLY)
 950
 951
 952 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
 953 dnl doesn't support links to directories, as in "ln file dir".  But that
 954 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
 955 dnl executables at "make install" time.
 956 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
 957 dnl for more details.
 958 if test "$opsys" = "mingw32"; then
 959   LN_S="/bin/ln"
 960 fi
 961
 962 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 963   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 964 dnl Don't use GZIP, which is used by gzip for additional parameters.
 965 AC_PATH_PROG(GZIP_PROG, gzip)
 966
 967 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
 968    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
 969
 970 if test $opsys = gnu-linux; then
 971   AC_PATH_PROG(PAXCTL, paxctl,,
 972     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 973   if test "X$PAXCTL" != X; then
 974     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 975     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 976       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 977       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 978   fi
 979
 980   if test "${SETFATTR+set}" != set; then
 981     AC_CACHE_CHECK([for setfattr],
 982       [emacs_cv_prog_setfattr],
 983       [touch conftest.tmp
 984        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
 985          emacs_cv_prog_setfattr=yes
 986        else
 987          emacs_cv_prog_setfattr=no
 988        fi])
 989     if test "$emacs_cv_prog_setfattr" = yes; then
 990       SETFATTR=setfattr
 991     else
 992       SETFATTR=
 993     fi
 994     rm -f conftest.tmp
 995     AC_SUBST([SETFATTR])
 996   fi
 997 fi
 998
 999 ## Need makeinfo >= 4.7 (?) to build the manuals.
1000 AC_PATH_PROG(MAKEINFO, makeinfo, no)
1001 dnl By this stage, configure has already checked for egrep and set EGREP,
1002 dnl or exited with an error if no egrep was found.
1003 if test "$MAKEINFO" != "no"; then
1004   case `
1005     $MAKEINFO --version 2> /dev/null |
1006     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
1007   ` in
1008     '') MAKEINFO=no;;
1009   esac
1010 fi
1011
1012 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1013 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1014 ## therefore in the category of "special tools" not normally required, which
1015 ## configure does not have to check for (eg autoconf itself).
1016 ## In a repository checkout on the other hand, the manuals are not included.
1017 ## So makeinfo is a requirement to build from the repository, and configure
1018 ## should test for it as it does for any other build requirement.
1019 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1020 ## with pre-built manuals, from a repository checkout.
1021 HAVE_MAKEINFO=yes
1022
1023 if test "$MAKEINFO" = "no"; then
1024   MAKEINFO=makeinfo
1025   if test "x${with_makeinfo}" = "xno"; then
1026     HAVE_MAKEINFO=no
1027   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1028     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1029 source tree does not seem to have pre-built manuals in the `info' directory.
1030 Either install a suitable version of makeinfo, or re-run configure
1031 with the `--without-makeinfo' option to build without the manuals.] )
1032   fi
1033 fi
1034 AC_SUBST(HAVE_MAKEINFO)
1035
1036 dnl Just so that there is only a single place we need to edit.
1037 INFO_EXT=.info
1038 INFO_OPTS=--no-split
1039 AC_SUBST(INFO_EXT)
1040 AC_SUBST(INFO_OPTS)
1041
1042 if test $opsys = mingw32; then
1043    DOCMISC_W32=efaq-w32
1044 else
1045    DOCMISC_W32=
1046 fi
1047 AC_SUBST(DOCMISC_W32)
1048
1049 dnl Add our options to ac_link now, after it is set up.
1050
1051 if test x$GCC = xyes; then
1052   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1053     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1054 else
1055   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1056     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1057 fi
1058
1059 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1060 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1061 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1062 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1063 dnl if not built to support GNU ld.
1064
1065 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1066 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1067 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1068 dnl   Eg "make LDFLAGS=... all" could run into problems,
1069 dnl   http://bugs.debian.org/684788
1070 dnl * unnecessary, since temacs is the only thing that actually needs it.
1071 dnl   Indeed this is where it was originally, prior to:
1072 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1073 late_LDFLAGS="$LDFLAGS"
1074 if test x$GCC = xyes; then
1075   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1076 else
1077   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1078 fi
1079
1080 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1081
1082 AC_MSG_CHECKING([for -znocombreloc])
1083 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1084   [AC_MSG_RESULT(yes)],
1085   LDFLAGS_NOCOMBRELOC=
1086   [AC_MSG_RESULT(no)])
1087
1088 LDFLAGS="$late_LDFLAGS"
1089
1090 AC_CACHE_CHECK([whether addresses are sanitized],
1091   [emacs_cv_sanitize_address],
1092   [AC_COMPILE_IFELSE(
1093      [AC_LANG_PROGRAM(
1094         [[#ifndef __has_feature
1095           #define __has_feature(f) 0
1096           #endif
1097           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1098           #else
1099            error "Addresses are not sanitized.";
1100           #endif
1101         ]])],
1102      [emacs_cv_sanitize_address=yes],
1103      [emacs_cv_sanitize_address=no])])
1104
1105 dnl The function dump-emacs will not be defined and temacs will do
1106 dnl (load "loadup") automatically unless told otherwise.
1107 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1108 case "$opsys" in
1109   your-opsys-here) CANNOT_DUMP=yes ;;
1110 esac
1111
1112 if test "$CANNOT_DUMP" = "yes"; then
1113   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1114 elif test "$emacs_cv_sanitize_address" = yes; then
1115   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1116 fi
1117
1118 AC_SUBST(CANNOT_DUMP)
1119
1120
1121 UNEXEC_OBJ=unexelf.o
1122 case "$opsys" in
1123   # MSDOS uses unexcoff.o
1124   aix4-2)
1125    UNEXEC_OBJ=unexaix.o
1126    ;;
1127   cygwin)
1128    UNEXEC_OBJ=unexcw.o
1129    ;;
1130   darwin)
1131    UNEXEC_OBJ=unexmacosx.o
1132    ;;
1133   hpux10-20 | hpux11)
1134    UNEXEC_OBJ=unexhp9k800.o
1135    ;;
1136   mingw32)
1137    UNEXEC_OBJ=unexw32.o
1138    ;;
1139   sol2-10)
1140    # Use the Solaris dldump() function, called from unexsol.c, to dump
1141    # emacs, instead of the generic ELF dump code found in unexelf.c.
1142    # The resulting binary has a complete symbol table, and is better
1143    # for debugging and other observability tools (debuggers, pstack, etc).
1144    #
1145    # If you encounter a problem using dldump(), please consider sending
1146    # a message to the OpenSolaris tools-linking mailing list:
1147    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1148    #
1149    # It is likely that dldump() works with older Solaris too, but this has
1150    # not been tested, so for now this change is for Solaris 10 or newer.
1151    UNEXEC_OBJ=unexsol.o
1152    ;;
1153 esac
1154
1155 LD_SWITCH_SYSTEM=
1156 case "$opsys" in
1157   freebsd|dragonfly)
1158    ## Let `ld' find image libs and similar things in /usr/local/lib.
1159    ## The system compiler, GCC, has apparently been modified to not
1160    ## look there, contrary to what a stock GCC would do.
1161 ### It's not our place to do this.  See bug#10313#17.
1162 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1163       :
1164    ;;
1165
1166   gnu-linux)
1167    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1168    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1169    ;;
1170
1171   netbsd)
1172 ### It's not our place to do this.  See bug#10313#17.
1173 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1174       :
1175    ;;
1176
1177   openbsd)
1178    ## Han Boetes <han@boetes.org> says this is necessary,
1179    ## otherwise Emacs dumps core on elf systems.
1180    LD_SWITCH_SYSTEM="-Z"
1181    ;;
1182 esac
1183 AC_SUBST(LD_SWITCH_SYSTEM)
1184
1185 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1186
1187 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1188 ## which has not been defined yet.  When this was handled with cpp,
1189 ## it was expanded to null when configure sourced the s/*.h file.
1190 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1191 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1192 ## (or somesuch), but because it is supposed to go at the _front_
1193 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1194 ## Compare with the gnu-linux case below, which added to the end
1195 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1196 ## LD_SWITCH_SYSTEM_TEMACS.
1197 case "$opsys" in
1198   netbsd|openbsd)
1199    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1200 esac
1201
1202
1203 C_SWITCH_MACHINE=
1204 case $canonical in
1205  alpha*)
1206   AC_CHECK_DECL([__ELF__])
1207   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1208     ## With ELF, make sure that all common symbols get allocated to in the
1209     ## data section.  Otherwise, the dump of temacs may miss variables in
1210     ## the shared library that have been initialized.  For example, with
1211     ## GNU libc, __malloc_initialized would normally be resolved to the
1212     ## shared library's .bss section, which is fatal.
1213     if test "x$GCC" = "xyes"; then
1214       C_SWITCH_MACHINE="-fno-common"
1215     else
1216       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1217     fi
1218   else
1219       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1220       dnl albeit under the mistaken assumption that said file
1221       dnl was no longer used.
1222       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1223   fi
1224   ;;
1225 esac
1226 AC_SUBST(C_SWITCH_MACHINE)
1227
1228 AC_SUBST(UNEXEC_OBJ)
1229
1230 C_SWITCH_SYSTEM=
1231 ## Some programs in src produce warnings saying certain subprograms
1232 ## are too complex and need a MAXMEM value greater than 2000 for
1233 ## additional optimization.  --nils@exp-math.uni-essen.de
1234 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1235   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1236 if test "$opsys" = "mingw32"; then
1237   case "$canonical" in
1238     x86_64-*-mingw32) C_SWITCH_SYSTEM="-mtune=generic" ;;
1239     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1240   esac
1241 fi
1242 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1243 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1244 AC_SUBST(C_SWITCH_SYSTEM)
1245
1246
1247 LIBS_SYSTEM=
1248 case "$opsys" in
1249   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1250   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1251
1252   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1253
1254   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1255
1256   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1257
1258   ## Motif needs -lgen.
1259   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1260 esac
1261
1262 AC_SUBST(LIBS_SYSTEM)
1263
1264 ### Make sure subsequent tests use flags consistent with the build flags.
1265
1266 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1267   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1268 else
1269   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1270 fi
1271
1272 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1273 AC_DEFUN([AC_TYPE_SIZE_T])
1274 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1275 AC_DEFUN([AC_TYPE_UID_T])
1276
1277
1278 LIB_MATH=-lm
1279 dnl Current possibilities handled by sed (aix4-2 -> aix,
1280 dnl gnu-linux -> gnu/linux, etc.):
1281 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1282 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1283 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1284
1285 case $opsys in
1286   cygwin )
1287     LIB_MATH=
1288     ;;
1289   darwin )
1290     ## Adding -lm confuses the dynamic linker, so omit it.
1291     LIB_MATH=
1292     ;;
1293   freebsd | dragonfly )
1294     SYSTEM_TYPE=berkeley-unix
1295     ;;
1296   gnu-linux | gnu-kfreebsd )
1297     ;;
1298   hpux10-20 | hpux11 )
1299     ;;
1300   mingw32 )
1301     LIB_MATH=
1302     SYSTEM_TYPE=windows-nt
1303     ;;
1304   dnl NB this may be adjusted below.
1305   netbsd | openbsd )
1306     SYSTEM_TYPE=berkeley-unix
1307     ;;
1308
1309   sol2* | unixware )
1310     SYSTEM_TYPE=usg-unix-v
1311     ;;
1312
1313 esac
1314
1315 AC_SUBST(LIB_MATH)
1316 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1317   [The type of system you are compiling for; sets `system-type'.])
1318
1319
1320 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1321 pre_PKG_CONFIG_LIBS=$LIBS
1322
1323 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1324
1325 dnl This function definition taken from Gnome 2.0
1326 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1327 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1328 dnl also defines GSTUFF_PKG_ERRORS on error
1329 AC_DEFUN([PKG_CHECK_MODULES], [
1330   succeeded=no
1331
1332   if test "$PKG_CONFIG" = "no" ; then
1333      ifelse([$4], , [AC_MSG_ERROR([
1334       *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1335   else
1336      PKG_CONFIG_MIN_VERSION=0.9.0
1337      if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1338         AC_MSG_CHECKING(for $2)
1339
1340         if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1341            $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1342            $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1343             edit_cflags="
1344               s,///*,/,g
1345               s/^/ /
1346               s/ -I/ $isystem/g
1347               s/^ //
1348             "
1349             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1350             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1351             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1352             succeeded=yes
1353         else
1354             AC_MSG_RESULT(no)
1355             $1_CFLAGS=""
1356             $1_LIBS=""
1357             ## If we have a custom action on failure, don't print errors, but
1358             ## do set a variable so people can do so.  Do it in a subshell
1359             ## to capture any diagnostics in invoking pkg-config.
1360             $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1`
1361             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1362         fi
1363
1364         AC_SUBST($1_CFLAGS)
1365         AC_SUBST($1_LIBS)
1366      else
1367         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1368         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1369      fi
1370   fi
1371
1372   if test $succeeded = yes; then
1373      ifelse([$3], , :, [$3])
1374   else
1375      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1376   fi
1377 ])
1378
1379 HAVE_SOUND=no
1380 if test "${with_sound}" != "no"; then
1381   # Sound support for GNU/Linux, the free BSDs, and MinGW.
1382   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h],
1383     have_sound_header=yes, [], [
1384     #ifdef __MINGW32__
1385     #define WIN32_LEAN_AND_MEAN
1386     #include <windows.h>
1387     #endif
1388     ])
1389   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1390     AC_MSG_ERROR([OSS sound support requested but not found.])
1391
1392   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1393     # Emulation library used on NetBSD.
1394     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1395     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1396       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1397     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1398     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1399   fi
1400   AC_SUBST(LIBSOUND)
1401
1402   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1403     ALSA_REQUIRED=1.0.0
1404     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1405     PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1406     if test $HAVE_ALSA = yes; then
1407       SAVE_CFLAGS="$CFLAGS"
1408       SAVE_LIBS="$LIBS"
1409       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1410       LIBS="$ALSA_LIBS $LIBS"
1411       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1412                       emacs_alsa_normal=yes,
1413                     emacs_alsa_normal=no)
1414       if test "$emacs_alsa_normal" != yes; then
1415         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1416                        [[snd_lib_error_set_handler (0);]])],
1417                        emacs_alsa_subdir=yes,
1418                      emacs_alsa_subdir=no)
1419         if test "$emacs_alsa_subdir" != yes; then
1420           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1421         fi
1422         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1423       fi
1424
1425       CFLAGS="$SAVE_CFLAGS"
1426       LIBS="$SAVE_LIBS"
1427       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1428       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1429       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1430     elif test "${with_sound}" = "alsa"; then
1431       AC_MSG_ERROR([ALSA sound support requested but not found.])
1432     fi
1433   fi                            dnl with_sound = alsa|yes
1434
1435   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1436   dnl compiles only on the specified platforms.  For others, it
1437   dnl probably doesn't make sense to try.
1438   dnl FIXME So surely we should bypass this whole section if not using
1439   dnl one of these platforms?
1440   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1441      case "$opsys" in
1442        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1443        dnl Adjust the --with-sound help text if you change this.
1444        gnu-linux|freebsd|netbsd|mingw32)
1445          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1446          HAVE_SOUND=yes
1447          ;;
1448      esac
1449   fi
1450
1451   AC_SUBST(CFLAGS_SOUND)
1452 fi
1453
1454 dnl checks for header files
1455 AC_CHECK_HEADERS_ONCE(
1456   sys/systeminfo.h
1457   coff.h pty.h
1458   sys/resource.h
1459   sys/utsname.h pwd.h utmp.h util.h)
1460
1461 AC_MSG_CHECKING(if personality LINUX32 can be set)
1462 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1463                emacs_cv_personality_linux32=yes,
1464                emacs_cv_personality_linux32=no)
1465 AC_MSG_RESULT($emacs_cv_personality_linux32)
1466
1467 if test $emacs_cv_personality_linux32 = yes; then
1468   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1469             [Define to 1 if personality LINUX32 can be set.])
1470 fi
1471
1472 dnl On Solaris 8 there's a compilation warning for term.h because
1473 dnl it doesn't define `bool'.
1474 AC_CHECK_HEADERS(term.h, , , -)
1475 AC_HEADER_TIME
1476 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1477                                       ]])
1478 if test $ac_cv_have_decl_sys_siglist != yes; then
1479   # For Tru64, at least:
1480   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1481                                           ]])
1482 fi
1483 AC_HEADER_SYS_WAIT
1484
1485 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1486 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1487 #if HAVE_SYS_SOCKET_H
1488 #include <sys/socket.h>
1489 #endif])
1490 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1491 #if HAVE_SYS_SOCKET_H
1492 #include <sys/socket.h>
1493 #endif])
1494 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1495 #if HAVE_SYS_SOCKET_H
1496 #include <sys/socket.h>
1497 #endif])
1498
1499 dnl checks for structure members
1500 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1501                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1502                   struct ifreq.ifr_addr,
1503                   struct ifreq.ifr_addr.sa_len], , ,
1504                  [AC_INCLUDES_DEFAULT
1505 #if HAVE_SYS_SOCKET_H
1506 #include <sys/socket.h>
1507 #endif
1508 #if HAVE_NET_IF_H
1509 #include <net/if.h>
1510 #endif])
1511
1512 dnl Check for endianness.
1513 dnl AC_C_BIGENDIAN is done by gnulib.
1514
1515 dnl check for Make feature
1516 dnl AC_PROG_MAKE_SET is done by Automake.
1517
1518 DEPFLAGS=
1519 MKDEPDIR=":"
1520 deps_frag=deps.mk
1521 dnl check for GNU Make if we have GCC and autodepend is on.
1522 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1523    AC_MSG_CHECKING([whether we are using GNU Make])
1524    HAVE_GNU_MAKE=no
1525    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1526    if test "x$testval" != x; then
1527       HAVE_GNU_MAKE=yes
1528    else
1529       ac_enable_autodepend=no
1530    fi
1531    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1532    if test $HAVE_GNU_MAKE = yes; then
1533       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1534       SAVE_CFLAGS="$CFLAGS"
1535       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1536       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1537       CFLAGS="$SAVE_CFLAGS"
1538       test -f deps.d || ac_enable_autodepend=no
1539       rm -rf deps.d
1540       AC_MSG_RESULT([$ac_enable_autodepend])
1541    fi
1542    if test $ac_enable_autodepend = yes; then
1543       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1544       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1545       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1546       deps_frag=autodeps.mk
1547    fi
1548 fi
1549 deps_frag=$srcdir/src/$deps_frag
1550 AC_SUBST(MKDEPDIR)
1551 AC_SUBST(DEPFLAGS)
1552 AC_SUBST_FILE(deps_frag)
1553
1554
1555 lisp_frag=$srcdir/src/lisp.mk
1556 AC_SUBST_FILE(lisp_frag)
1557
1558
1559 dnl checks for operating system services
1560 AC_SYS_LONG_FILE_NAMES
1561
1562 #### Choose a window system.
1563
1564 ## We leave window_system equal to none if
1565 ## we end up building without one.  Any new window system should
1566 ## set window_system to an appropriate value and add objects to
1567 ## window-system-specific substs.
1568
1569 window_system=none
1570 AC_PATH_X
1571 if test "$no_x" != yes; then
1572   window_system=x11
1573 fi
1574
1575 LD_SWITCH_X_SITE_RPATH=
1576 if test "${x_libraries}" != NONE; then
1577   if test -n "${x_libraries}"; then
1578     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1579     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1580   fi
1581   x_default_search_path=""
1582   x_search_path=${x_libraries}
1583   if test -z "${x_search_path}"; then
1584     x_search_path=/usr/lib
1585   fi
1586   for x_library in `echo ${x_search_path}: | \
1587                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1588     x_search_path="\
1589 ${x_library}/X11/%L/%T/%N%C%S:\
1590 ${x_library}/X11/%l/%T/%N%C%S:\
1591 ${x_library}/X11/%T/%N%C%S:\
1592 ${x_library}/X11/%L/%T/%N%S:\
1593 ${x_library}/X11/%l/%T/%N%S:\
1594 ${x_library}/X11/%T/%N%S"
1595     if test x"${x_default_search_path}" = x; then
1596       x_default_search_path=${x_search_path}
1597     else
1598       x_default_search_path="${x_search_path}:${x_default_search_path}"
1599     fi
1600   done
1601 fi
1602 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1603
1604 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1605   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1606 fi
1607
1608 if test x"${x_includes}" = x; then
1609   bitmapdir=/usr/include/X11/bitmaps
1610 else
1611   # accumulate include directories that have X11 bitmap subdirectories
1612   bmd_acc="dummyval"
1613   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1614     if test -d "${bmd}/X11/bitmaps"; then
1615       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1616     fi
1617     if test -d "${bmd}/bitmaps"; then
1618       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1619     fi
1620   done
1621   if test ${bmd_acc} != "dummyval"; then
1622     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1623   fi
1624 fi
1625
1626 HAVE_NS=no
1627 NS_IMPL_COCOA=no
1628 NS_IMPL_GNUSTEP=no
1629 tmp_CPPFLAGS="$CPPFLAGS"
1630 tmp_CFLAGS="$CFLAGS"
1631 CPPFLAGS="$CPPFLAGS -x objective-c"
1632 CFLAGS="$CFLAGS -x objective-c"
1633 GNU_OBJC_CFLAGS=
1634 LIBS_GNUSTEP=
1635 if test "${with_ns}" != no; then
1636   if test "${opsys}" = darwin; then
1637      NS_IMPL_COCOA=yes
1638      ns_appdir=`pwd`/nextstep/Emacs.app
1639      ns_appbindir=${ns_appdir}/Contents/MacOS
1640      ns_appresdir=${ns_appdir}/Contents/Resources
1641      ns_appsrc=Cocoa/Emacs.base
1642   elif test -f $GNUSTEP_CONFIG_FILE; then
1643      NS_IMPL_GNUSTEP=yes
1644      ns_appdir=`pwd`/nextstep/Emacs.app
1645      ns_appbindir=${ns_appdir}
1646      ns_appresdir=${ns_appdir}/Resources
1647      ns_appsrc=GNUstep/Emacs.base
1648      dnl FIXME sourcing this several times in subshells seems inefficient.
1649      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1650      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1651      dnl I seemed to need these as well with GNUstep-startup 0.25.
1652      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1653      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1654      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1655        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1656      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1657        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1658      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1659      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1660      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1661      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1662      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1663      dnl If they had chosen to either define it or not, we could have
1664      dnl just used AC_CHECK_DECL here.
1665      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1666        emacs_cv_objc_exceptions,
1667 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1668 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1669 1;
1670 #else
1671 fail;
1672 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1673      if test $emacs_cv_objc_exceptions = yes; then
1674        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1675        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1676          [Define if GNUstep uses ObjC exceptions.])
1677        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1678      fi
1679   fi
1680
1681   dnl This is only used while we test the NS headers, it gets reset below.
1682   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1683
1684   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1685                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1686   files are missing or cannot be compiled.])])
1687
1688   macfont_file=""
1689   if test "${NS_IMPL_COCOA}" = "yes"; then
1690     AC_MSG_CHECKING([for OSX 10.4 or newer])
1691     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1692                                      [
1693 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1694 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1695  ; /* OK */
1696 #else
1697  error "OSX 10.4 or newer required";
1698 #endif
1699 #endif
1700                     ])],
1701                     ns_osx_have_104=yes,
1702                     ns_osx_have_104=no)
1703     AC_MSG_RESULT([$ns_osx_have_104])
1704
1705     if test $ns_osx_have_104 = no; then
1706        AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1707     fi
1708     AC_MSG_CHECKING([for OSX 10.5 or newer])
1709     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1710                                      [
1711 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1712 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1050
1713  ; /* OK */
1714 #else
1715  error "OSX 10.5 not found";
1716 #endif
1717 #endif
1718                     ])],
1719                     ns_osx_have_105=yes,
1720                     ns_osx_have_105=no)
1721     AC_MSG_RESULT([$ns_osx_have_105])
1722     if test $ns_osx_have_105 = yes; then
1723       macfont_file="macfont.o"
1724     fi
1725   fi
1726   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1727                                      [NSInteger i;])],
1728                     ns_have_nsinteger=yes,
1729                     ns_have_nsinteger=no)
1730   if test $ns_have_nsinteger = yes; then
1731     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1732   fi
1733 fi
1734
1735 AC_SUBST(LIBS_GNUSTEP)
1736
1737 INSTALL_ARCH_INDEP_EXTRA=install-etc
1738 ns_self_contained=no
1739 NS_OBJ=
1740 NS_OBJC_OBJ=
1741 if test "${HAVE_NS}" = yes; then
1742   if test "$with_toolkit_scroll_bars" = "no"; then
1743     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1744   fi
1745
1746   window_system=nextstep
1747   # set up packaging dirs
1748   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1749      ns_self_contained=yes
1750      prefix=${ns_appresdir}
1751      exec_prefix=${ns_appbindir}
1752      dnl This one isn't really used, only archlibdir is.
1753      libexecdir="\${ns_appbindir}/libexec"
1754      archlibdir="\${ns_appbindir}/libexec"
1755      etcdocdir="\${ns_appresdir}/etc"
1756      etcdir="\${ns_appresdir}/etc"
1757      dnl FIXME maybe set datarootdir instead.
1758      dnl That would also get applications, icons, man.
1759      infodir="\${ns_appresdir}/info"
1760      mandir="\${ns_appresdir}/man"
1761      lispdir="\${ns_appresdir}/lisp"
1762      INSTALL_ARCH_INDEP_EXTRA=
1763   fi
1764
1765   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o $macfont_file"
1766 fi
1767 CFLAGS="$tmp_CFLAGS"
1768 CPPFLAGS="$tmp_CPPFLAGS"
1769 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1770 AC_SUBST(ns_self_contained)
1771 AC_SUBST(NS_OBJ)
1772 AC_SUBST(NS_OBJC_OBJ)
1773
1774 HAVE_W32=no
1775 W32_OBJ=
1776 W32_LIBS=
1777 EMACSRES=
1778 CLIENTRES=
1779 CLIENTW=
1780 W32_RES_LINK=
1781 EMACS_MANIFEST=
1782 UPDATE_MANIFEST=
1783 if test "${with_w32}" != no; then
1784   case "${opsys}" in
1785     cygwin)
1786       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1787              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1788                    cannot be found.])])
1789     ;;
1790     mingw32)
1791     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1792     ;;
1793     *)
1794       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1795     ;;
1796   esac
1797 fi
1798
1799 if test "${opsys}" = "mingw32"; then
1800   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1801   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1802      #include <windows.h>
1803      #include <usp10.h>]],
1804    [[PIMAGE_NT_HEADERS pHeader;
1805      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1806    [emacs_cv_w32api=yes
1807     HAVE_W32=yes],
1808    emacs_cv_w32api=no)
1809   AC_MSG_RESULT($emacs_cv_w32api)
1810   if test "${emacs_cv_w32api}" = "no"; then
1811     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1812   fi
1813 fi
1814
1815 FIRSTFILE_OBJ=
1816 NTDIR=
1817 LIBS_ECLIENT=
1818 LIB_WSOCK32=
1819 NTLIB=
1820 CM_OBJ="cm.o"
1821 XARGS_LIMIT=
1822 if test "${HAVE_W32}" = "yes"; then
1823   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1824   AC_CHECK_TOOL(WINDRES, [windres],
1825                 [AC_MSG_ERROR([No resource compiler found.])])
1826   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1827   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1828   EMACSRES="emacs.res"
1829   case "$canonical" in
1830     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1831     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1832   esac
1833   if test "${opsys}" = "cygwin"; then
1834     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1835     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1836     # Tell the linker that emacs.res is an object (which we compile from
1837     # the rc file), not a linker script.
1838     W32_RES_LINK="-Wl,emacs.res"
1839   else
1840     UPDATE_MANIFEST=update-game-score.exe.manifest
1841     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1842     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1843     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1844     W32_RES_LINK="\$(EMACSRES)"
1845     CLIENTRES="emacsclient.res"
1846     CLIENTW="emacsclientw\$(EXEEXT)"
1847     FIRSTFILE_OBJ=firstfile.o
1848     NTDIR=nt
1849     CM_OBJ=
1850     LIBS_ECLIENT="-lcomctl32"
1851     LIB_WSOCK32="-lwsock32"
1852     NTLIB="ntlib.$ac_objext"
1853     XARGS_LIMIT="-s 10000"
1854   fi
1855 fi
1856 AC_SUBST(W32_OBJ)
1857 AC_SUBST(W32_LIBS)
1858 AC_SUBST(EMACSRES)
1859 AC_SUBST(EMACS_MANIFEST)
1860 AC_SUBST(UPDATE_MANIFEST)
1861 AC_SUBST(CLIENTRES)
1862 AC_SUBST(CLIENTW)
1863 AC_SUBST(W32_RES_LINK)
1864 AC_SUBST(FIRSTFILE_OBJ)
1865 AC_SUBST(NTDIR)
1866 AC_SUBST(CM_OBJ)
1867 AC_SUBST(LIBS_ECLIENT)
1868 AC_SUBST(LIB_WSOCK32)
1869 AC_SUBST(NTLIB)
1870 AC_SUBST(XARGS_LIMIT)
1871
1872 if test "${HAVE_W32}" = "yes"; then
1873   window_system=w32
1874   with_xft=no
1875 fi
1876
1877 ## $window_system is now set to the window system we will
1878 ## ultimately use.
1879
1880 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
1881    # Too many warnings for now.
1882    nw=
1883    nw="$nw -Wsuggest-attribute=const"
1884    nw="$nw -Wsuggest-attribute=noreturn"
1885    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1886
1887    gl_WARN_ADD([-Wno-unused-variable])
1888    gl_WARN_ADD([-Wno-unused-but-set-variable])
1889    gl_WARN_ADD([-Wno-unused-but-set-parameter])
1890 fi
1891
1892 term_header=
1893 HAVE_X_WINDOWS=no
1894 HAVE_X11=no
1895 USE_X_TOOLKIT=none
1896
1897 case "${window_system}" in
1898   x11 )
1899     HAVE_X_WINDOWS=yes
1900     HAVE_X11=yes
1901     term_header=xterm.h
1902     case "${with_x_toolkit}" in
1903       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1904       motif ) USE_X_TOOLKIT=MOTIF ;;
1905       gtk ) with_gtk=yes
1906             term_header=gtkutil.h
1907 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1908 dnl USE_X_TOOLKIT is set.
1909             USE_X_TOOLKIT=none ;;
1910       gtk2 ) with_gtk2=yes
1911              term_header=gtkutil.h
1912              USE_X_TOOLKIT=none ;;
1913       gtk3 ) with_gtk3=yes
1914              term_header=gtkutil.h
1915              USE_X_TOOLKIT=none ;;
1916       no ) USE_X_TOOLKIT=none ;;
1917 dnl If user did not say whether to use a toolkit, make this decision later:
1918 dnl use the toolkit if we have gtk, or X11R5 or newer.
1919       * ) USE_X_TOOLKIT=maybe ;;
1920     esac
1921   ;;
1922   nextstep )
1923     term_header=nsterm.h
1924   ;;
1925   w32 )
1926     term_header=w32term.h
1927   ;;
1928 esac
1929
1930 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1931    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1932    if test "$HAVE_XSERVER" = true ||
1933       test -n "$DISPLAY" ||
1934       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1935         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1936 were found.  You should install the relevant development files for X
1937 and for the toolkit you want, such as Gtk+ or Motif.  Also make
1938 sure you have development files for image handling, i.e.
1939 tiff, gif, jpeg, png and xpm.
1940 If you are sure you want Emacs compiled without X window support, pass
1941   --without-x
1942 to configure.])
1943    fi
1944 fi
1945
1946 # Does the opsystem file prohibit the use of the GNU malloc?
1947 # Assume not, until told otherwise.
1948 GNU_MALLOC=yes
1949
1950 AC_CACHE_CHECK(
1951   [whether malloc is Doug Lea style],
1952   [emacs_cv_var_doug_lea_malloc],
1953   [emacs_cv_var_doug_lea_malloc=no
1954    dnl Hooks do not work with address sanitization.
1955    if test "$emacs_cv_sanitize_address" != yes; then
1956      AC_LINK_IFELSE(
1957        [AC_LANG_PROGRAM(
1958           [[#include <malloc.h>
1959             static void hook (void) {}]],
1960           [[malloc_set_state (malloc_get_state ());
1961             __after_morecore_hook = hook;
1962             __malloc_initialize_hook = hook;]])],
1963        [emacs_cv_var_doug_lea_malloc=yes])])
1964    fi
1965 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1966
1967 system_malloc=$emacs_cv_sanitize_address
1968 case "$opsys" in
1969   ## darwin ld insists on the use of malloc routines in the System framework.
1970   darwin|sol2-10) system_malloc=yes ;;
1971 esac
1972
1973 GMALLOC_OBJ=
1974 if test "${system_malloc}" = "yes"; then
1975   AC_DEFINE([SYSTEM_MALLOC], 1,
1976     [Define to 1 to use the system memory allocator, even if it is not
1977      Doug Lea style.])
1978   GNU_MALLOC=no
1979   GNU_MALLOC_reason="
1980     (The GNU allocators don't work with this system configuration.)"
1981   VMLIMIT_OBJ=
1982 else
1983   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1984   VMLIMIT_OBJ=vm-limit.o
1985
1986   AC_CHECK_HEADERS([sys/vlimit.h])
1987   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
1988     [AC_LINK_IFELSE(
1989        [AC_LANG_PROGRAM(
1990          [[extern char data_start[]; char ch;]],
1991          [[return data_start < &ch;]])],
1992        [emacs_cv_data_start=yes],
1993        [emacs_cv_data_start=no])])
1994   if test $emacs_cv_data_start = yes; then
1995     AC_DEFINE([HAVE_DATA_START], 1,
1996       [Define to 1 if data_start is the address of the start
1997        of the main data segment.])
1998   fi
1999 fi
2000 AC_SUBST(GMALLOC_OBJ)
2001 AC_SUBST(VMLIMIT_OBJ)
2002
2003 if test "$doug_lea_malloc" = "yes" ; then
2004   if test "$GNU_MALLOC" = yes ; then
2005     GNU_MALLOC_reason="
2006       (Using Doug Lea's new malloc from the GNU C Library.)"
2007   fi
2008   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2009     [Define to 1 if the system memory allocator is Doug Lea style,
2010      with malloc hooks and malloc_set_state.])
2011
2012   ## Use mmap directly for allocating larger buffers.
2013   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2014   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2015   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2016   case "$opsys" in
2017     gnu*) REL_ALLOC=no ;;
2018   esac
2019 fi
2020
2021 if test x"${REL_ALLOC}" = x; then
2022   REL_ALLOC=${GNU_MALLOC}
2023 fi
2024
2025 use_mmap_for_buffers=no
2026 case "$opsys" in
2027   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2028 esac
2029
2030 AC_FUNC_MMAP
2031 if test $use_mmap_for_buffers = yes; then
2032   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2033   REL_ALLOC=no
2034 fi
2035
2036 LIBS="$LIBS_SYSTEM $LIBS"
2037
2038 dnl If found, this adds -ldnet to LIBS, which Autoconf uses for checks.
2039 AC_CHECK_LIB(dnet, dnet_ntoa)
2040 dnl This causes -lresolv to get used in subsequent tests,
2041 dnl which causes failures on some systems such as HPUX 9.
2042 dnl AC_CHECK_LIB(resolv, gethostbyname)
2043
2044 dnl FIXME replace main with a function we actually want from this library.
2045 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2046
2047 dnl Check if pthreads is available.
2048 LIB_PTHREAD=
2049 AC_CHECK_HEADERS_ONCE(pthread.h)
2050 if test "$ac_cv_header_pthread_h"; then
2051   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
2052   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
2053   dnl testing for pthread_self if Emacs uses gmalloc.c.
2054   if test "$GMALLOC_OBJ" = gmalloc.o; then
2055     emacs_pthread_function=pthread_atfork
2056   else
2057     emacs_pthread_function=pthread_self
2058   fi
2059   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
2060 fi
2061 if test "$HAVE_PTHREAD" = yes; then
2062   case "${canonical}" in
2063     *-hpux*) ;;
2064     *) LIB_PTHREAD="-lpthread"
2065        LIBS="$LIB_PTHREAD $LIBS" ;;
2066   esac
2067   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
2068 fi
2069 AC_SUBST([LIB_PTHREAD])
2070
2071 AC_CHECK_LIB(pthreads, cma_open)
2072
2073 ## Note: when using cpp in s/aix4.2.h, this definition depended on
2074 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
2075 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
2076 ## added to LIBS in configure would never contain the pthreads part,
2077 ## but the value used in Makefiles might.  FIXME?
2078 ##
2079 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
2080 ## be harmless on older versions of X where it happens to exist.
2081 test "$opsys" = "aix4-2" && \
2082   test $ac_cv_lib_pthreads_cma_open = yes && \
2083   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
2084
2085 dnl Check for need for bigtoc support on IBM AIX
2086
2087 case ${host_os} in
2088 aix*)
2089   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2090     case $GCC in
2091     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2092     *) gdb_cv_bigtoc=-bbigtoc ;;
2093     esac
2094
2095     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2096     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2097   ])
2098   ;;
2099 esac
2100
2101 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
2102 # used for the tests that follow.  We set them back to REAL_CFLAGS and
2103 # REAL_CPPFLAGS later on.
2104
2105 REAL_CFLAGS="$CFLAGS"
2106 REAL_CPPFLAGS="$CPPFLAGS"
2107
2108 if test "${HAVE_X11}" = "yes"; then
2109   DEFS="$C_SWITCH_X_SITE $DEFS"
2110   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2111   LIBS="-lX11 $LIBS"
2112   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2113   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2114
2115   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2116   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2117   # but it's more convenient here to set LD_RUN_PATH since this
2118   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2119   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2120     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2121     export LD_RUN_PATH
2122   fi
2123
2124   if test "${opsys}" = "gnu-linux"; then
2125     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2126     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2127      [[XOpenDisplay ("foo");]])],
2128      [xgnu_linux_first_failure=no],
2129      [xgnu_linux_first_failure=yes])
2130     if test "${xgnu_linux_first_failure}" = "yes"; then
2131       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
2132       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
2133       OLD_CPPFLAGS="$CPPFLAGS"
2134       OLD_LIBS="$LIBS"
2135       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2136       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2137       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2138       LIBS="$LIBS -b i486-linuxaout"
2139       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2140        [[XOpenDisplay ("foo");]])],
2141        [xgnu_linux_second_failure=no],
2142        [xgnu_linux_second_failure=yes])
2143       if test "${xgnu_linux_second_failure}" = "yes"; then
2144         # If we get the same failure with -b, there is no use adding -b.
2145         # So take it out.  This plays safe.
2146         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
2147         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
2148         CPPFLAGS="$OLD_CPPFLAGS"
2149         LIBS="$OLD_LIBS"
2150         AC_MSG_RESULT(no)
2151       else
2152         AC_MSG_RESULT(yes)
2153       fi
2154     else
2155       AC_MSG_RESULT(no)
2156     fi
2157   fi
2158
2159   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2160   # header files included from there.
2161   AC_MSG_CHECKING(for Xkb)
2162   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2163 #include <X11/XKBlib.h>]],
2164         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2165         emacs_xkb=yes, emacs_xkb=no)
2166   AC_MSG_RESULT($emacs_xkb)
2167   if test $emacs_xkb = yes; then
2168     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2169   fi
2170
2171   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2172 XScreenNumberOfScreen)
2173 fi
2174
2175 if test "${window_system}" = "x11"; then
2176   AC_MSG_CHECKING(X11 version 6)
2177   AC_CACHE_VAL(emacs_cv_x11_version_6,
2178   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2179 [[#if XlibSpecificationRelease < 6
2180 fail;
2181 #endif
2182 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2183   if test $emacs_cv_x11_version_6 = yes; then
2184     AC_MSG_RESULT(6 or newer)
2185     AC_DEFINE(HAVE_X11R6, 1,
2186               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2187     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2188     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2189     ## XIM support.
2190     case "$opsys" in
2191       sol2-*) : ;;
2192       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2193            [Define if you have usable X11R6-style XIM support.])
2194          ;;
2195     esac
2196   else
2197     AC_MSG_RESULT(before 6)
2198   fi
2199 fi
2200
2201
2202 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2203 HAVE_RSVG=no
2204 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2205   if test "${with_rsvg}" != "no"; then
2206     RSVG_REQUIRED=2.11.0
2207     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2208
2209     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
2210     AC_SUBST(RSVG_CFLAGS)
2211     AC_SUBST(RSVG_LIBS)
2212
2213     if test $HAVE_RSVG = yes; then
2214       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2215       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2216       # Windows loads librsvg dynamically
2217       if test "${opsys}" = "mingw32"; then
2218         RSVG_LIBS=
2219       fi
2220       LIBS="$RSVG_LIBS $LIBS"
2221     fi
2222   fi
2223 fi
2224
2225 HAVE_IMAGEMAGICK=no
2226 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2227   if test "${with_imagemagick}" != "no"; then
2228     ## 6.2.8 is the earliest version known to work, but earlier versions
2229     ## might work - let us know if you find one.
2230     ## 6.0.7 does not work.  See bug#7955.
2231     ## 6.8.2 makes Emacs crash; see Bug#13867.
2232     IMAGEMAGICK_MODULE="Wand >= 6.2.8 Wand != 6.8.2"
2233     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
2234     AC_SUBST(IMAGEMAGICK_CFLAGS)
2235     AC_SUBST(IMAGEMAGICK_LIBS)
2236
2237     if test $HAVE_IMAGEMAGICK = yes; then
2238       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2239       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2240       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2241       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2242     fi
2243   fi
2244 fi
2245
2246
2247 HAVE_GTK=no
2248 GTK_OBJ=
2249 gtk_term_header=$term_header
2250 check_gtk2=no
2251 gtk3_pkg_errors=
2252 if test "${opsys}" != "mingw32"; then
2253   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2254     GLIB_REQUIRED=2.28
2255     GTK_REQUIRED=3.0
2256     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2257
2258     dnl Checks for libraries.
2259     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2260     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2261        AC_MSG_ERROR($GTK_PKG_ERRORS)
2262     fi
2263     if test "$pkg_check_gtk" = "yes"; then
2264        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2265        GTK_OBJ=emacsgtkfixed.o
2266        gtk_term_header=gtkutil.h
2267        USE_GTK_TOOLKIT="GTK3"
2268        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2269          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2270            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2271          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2272            [Define to 1 to disable Glib deprecation warnings.])
2273        fi
2274     else
2275        check_gtk2=yes
2276        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2277     fi
2278   fi
2279
2280   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2281     GLIB_REQUIRED=2.10
2282     GTK_REQUIRED=2.10
2283     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2284
2285     dnl Checks for libraries.
2286     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2287     if test "$pkg_check_gtk" = "no" &&
2288        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2289     then
2290       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2291     fi
2292     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2293   fi
2294 fi
2295
2296 if test x"$pkg_check_gtk" = xyes; then
2297
2298   AC_SUBST(GTK_LIBS)
2299   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2300   CFLAGS="$CFLAGS $GTK_CFLAGS"
2301   LIBS="$GTK_LIBS $LIBS"
2302   dnl Try to compile a simple GTK program.
2303   AC_MSG_CHECKING([whether GTK compiles])
2304   GTK_COMPILES=no
2305   AC_LINK_IFELSE(
2306     [AC_LANG_PROGRAM(
2307        [[/* Check the Gtk and Glib APIs.  */
2308          #include <gtk/gtk.h>
2309          #include <glib-object.h>
2310          static void
2311          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2312          {}
2313        ]],
2314        [[
2315          GtkSettings *gs = 0;
2316          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2317             strict C prohibits this.  Use gtk_main_iteration to test that the
2318             libraries are there.  */
2319          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2320                                     0, 0, 0, G_CALLBACK (callback), 0))
2321            gtk_main_iteration ();
2322        ]])],
2323     [GTK_COMPILES=yes])
2324   AC_MSG_RESULT([$GTK_COMPILES])
2325   if test "${GTK_COMPILES}" != "yes"; then
2326     GTK_OBJ=
2327     if test "$USE_X_TOOLKIT" != "maybe"; then
2328       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2329     fi
2330   else
2331     HAVE_GTK=yes
2332     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2333     GTK_OBJ="gtkutil.o $GTK_OBJ"
2334     term_header=$gtk_term_header
2335     USE_X_TOOLKIT=none
2336     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2337       :
2338     else
2339       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2340        closing open displays.  This is no problem if you just use
2341        one display, but if you use more than one and close one of them
2342        Emacs may crash.]])
2343       sleep 3
2344     fi
2345   fi
2346
2347 fi
2348 AC_SUBST(GTK_OBJ)
2349
2350
2351 if test "${HAVE_GTK}" = "yes"; then
2352
2353   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2354   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2355   if test "$with_toolkit_scroll_bars" != no; then
2356     with_toolkit_scroll_bars=yes
2357   fi
2358
2359   dnl  Check if we have the old file selection dialog declared and
2360   dnl  in the link library.  In 2.x it may be in the library,
2361   dnl  but not declared if deprecated featured has been selected out.
2362   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2363   HAVE_GTK_FILE_SELECTION=no
2364   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2365                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2366 #include <gtk/gtk.h>])
2367   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2368     AC_CHECK_FUNCS(gtk_file_selection_new)
2369   fi
2370
2371   dnl Same as above for gtk_handle_box.
2372   HAVE_GTK_HANDLE_BOX=no
2373   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2374                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2375 #include <gtk/gtk.h>])
2376   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2377     AC_CHECK_FUNCS(gtk_handle_box_new)
2378   fi
2379
2380   dnl Same as above for gtk_tearoff_menu_item.
2381   HAVE_GTK_TEAROFF_MENU_ITEM=no
2382   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2383                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2384 #include <gtk/gtk.h>])
2385   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2386     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2387   fi
2388
2389   dnl Check for functions introduced in 2.14 and later.
2390   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2391                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2392                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2393                  gtk_orientable_set_orientation \
2394                  gtk_window_set_has_resize_grip)
2395
2396  term_header=gtkutil.h
2397 fi
2398
2399 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2400 dnl other platforms.
2401 HAVE_DBUS=no
2402 DBUS_OBJ=
2403 if test "${with_dbus}" = "yes"; then
2404    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2405    if test "$HAVE_DBUS" = yes; then
2406      LIBS="$LIBS $DBUS_LIBS"
2407      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2408      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2409      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2410      dnl D-Bus 1.5.12.
2411      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2412                     dbus_type_is_valid \
2413                     dbus_validate_bus_name \
2414                     dbus_validate_path \
2415                     dbus_validate_interface \
2416                     dbus_validate_member)
2417      DBUS_OBJ=dbusbind.o
2418    fi
2419 fi
2420 AC_SUBST(DBUS_OBJ)
2421
2422 dnl GSettings has been tested under GNU/Linux only.
2423 HAVE_GSETTINGS=no
2424 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2425    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2426    if test "$HAVE_GSETTINGS" = "yes"; then
2427       old_CFLAGS=$CFLAGS
2428       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2429       old_LIBS=$LIBS
2430       LIBS="$LIBS $GSETTINGS_LIBS"
2431       AC_MSG_CHECKING([whether GSettings is in gio])
2432       AC_LINK_IFELSE(
2433          [AC_LANG_PROGRAM(
2434              [[/* Check that gsettings really is present.  */
2435              #include <glib-object.h>
2436              #include <gio/gio.h>
2437              ]],
2438              [[
2439                GSettings *settings;
2440                GVariant *val = g_settings_get_value (settings, "");
2441              ]])],
2442          [], HAVE_GSETTINGS=no)
2443       AC_MSG_RESULT([$HAVE_GSETTINGS])
2444
2445       if test "$HAVE_GSETTINGS" = "yes"; then
2446         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2447         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2448         SETTINGS_LIBS="$GSETTINGS_LIBS"
2449       fi
2450       CFLAGS=$old_CFLAGS
2451       LIBS=$old_LIBS
2452    fi
2453 fi
2454
2455 dnl GConf has been tested under GNU/Linux only.
2456 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2457 HAVE_GCONF=no
2458 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2459    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2460    if test "$HAVE_GCONF" = yes; then
2461       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2462       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2463       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2464       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2465    fi
2466 fi
2467
2468 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2469     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2470     if test "$HAVE_GOBJECT" = "yes"; then
2471        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2472        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2473     fi
2474     SAVE_CFLAGS="$CFLAGS"
2475     SAVE_LIBS="$LIBS"
2476     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2477     LIBS="$SETTINGS_LIBS $LIBS"
2478     CFLAGS="$SAVE_CFLAGS"
2479     LIBS="$SAVE_LIBS"
2480 fi
2481 AC_SUBST(SETTINGS_CFLAGS)
2482 AC_SUBST(SETTINGS_LIBS)
2483
2484
2485 dnl SELinux is available for GNU/Linux only.
2486 HAVE_LIBSELINUX=no
2487 LIBSELINUX_LIBS=
2488 if test "${with_selinux}" = "yes"; then
2489    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2490    if test "$HAVE_LIBSELINUX" = yes; then
2491       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2492       LIBSELINUX_LIBS=-lselinux
2493    fi
2494 fi
2495 AC_SUBST(LIBSELINUX_LIBS)
2496
2497 HAVE_GNUTLS=no
2498 HAVE_GNUTLS3=no
2499 if test "${with_gnutls}" = "yes" ; then
2500   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.0.0], HAVE_GNUTLS3=yes, HAVE_GNUTLS3=no)
2501   if test "${HAVE_GNUTLS3}" = "yes"; then
2502     AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])
2503     HAVE_GNUTLS="yes"
2504   else
2505     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2506   fi
2507   if test "${HAVE_GNUTLS}" = "yes"; then
2508     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2509   fi
2510
2511   # Windows loads GnuTLS dynamically
2512   if test "${opsys}" = "mingw32"; then
2513     LIBGNUTLS_LIBS=
2514   fi
2515 fi
2516
2517 AC_SUBST(LIBGNUTLS_LIBS)
2518 AC_SUBST(LIBGNUTLS_CFLAGS)
2519
2520 NOTIFY_OBJ=
2521 NOTIFY_SUMMARY=no
2522
2523 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2524 dnl a particular library.  This doesn't make much sense?
2525 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2526   with_file_notification=no
2527 fi
2528
2529 dnl MS Windows native file monitor is available for mingw32 only.
2530 case $with_file_notification,$opsys in
2531   w32,* | yes,mingw32)
2532     AC_CHECK_HEADER(windows.h)
2533     if test "$ac_cv_header_windows_h" = yes ; then
2534        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2535        NOTIFY_OBJ=w32notify.o
2536        NOTIFY_SUMMARY="yes (w32)"
2537     fi ;;
2538 esac
2539
2540 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2541 dnl has been added in glib 2.24.  It has been tested under
2542 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2543 dnl only sense when glib has been compiled with inotify support.  How
2544 dnl to check?
2545 case $with_file_notification,$NOTIFY_OBJ in
2546   gfile, | yes,)
2547     PKG_CHECK_MODULES(GFILENOTIFY, gio-2.0 >= 2.24, HAVE_GFILENOTIFY=yes, HAVE_GFILENOTIFY=no)
2548     if test "$HAVE_GFILENOTIFY" = "yes"; then
2549        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2550        NOTIFY_OBJ=gfilenotify.o
2551        NOTIFY_SUMMARY="yes -lgio (gfile)"
2552     fi ;;
2553 esac
2554
2555 dnl inotify is only available on GNU/Linux.
2556 case $with_file_notification,$NOTIFY_OBJ in
2557   inotify, | yes,)
2558     AC_CHECK_HEADER(sys/inotify.h)
2559     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2560         AC_CHECK_FUNC(inotify_init1)
2561         if test "$ac_cv_func_inotify_init1" = yes; then
2562           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2563           NOTIFY_OBJ=inotify.o
2564           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2565        fi
2566     fi ;;
2567 esac
2568
2569 case $with_file_notification,$NOTIFY_OBJ in
2570   yes,* | no,* | *,?*) ;;
2571   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2572 esac
2573
2574 if test -n "$NOTIFY_OBJ"; then
2575    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2576 fi
2577 AC_SUBST(NOTIFY_OBJ)
2578 AC_SUBST(GFILENOTIFY_CFLAGS)
2579 AC_SUBST(GFILENOTIFY_LIBS)
2580
2581 dnl Do not put whitespace before the #include statements below.
2582 dnl Older compilers (eg sunos4 cc) choke on it.
2583 HAVE_XAW3D=no
2584 LUCID_LIBW=
2585 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2586   if test "$with_xaw3d" != no; then
2587     AC_CACHE_VAL(emacs_cv_xaw3d,
2588     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2589 #include <X11/Intrinsic.h>
2590 #include <X11/Xaw3d/Simple.h>]],
2591       [[]])],
2592       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2593                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2594       emacs_cv_xaw3d=no)])
2595   else
2596     emacs_cv_xaw3d=no
2597   fi
2598   if test $emacs_cv_xaw3d = yes; then
2599     AC_MSG_CHECKING(for xaw3d)
2600     AC_MSG_RESULT([yes; using Lucid toolkit])
2601     USE_X_TOOLKIT=LUCID
2602     HAVE_XAW3D=yes
2603     LUCID_LIBW=-lXaw3d
2604     AC_DEFINE(HAVE_XAW3D, 1,
2605               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2606   else
2607     AC_MSG_CHECKING(for xaw3d)
2608     AC_MSG_RESULT(no)
2609     AC_MSG_CHECKING(for libXaw)
2610     AC_CACHE_VAL(emacs_cv_xaw,
2611     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2612 #include <X11/Intrinsic.h>
2613 #include <X11/Xaw/Simple.h>]],
2614       [[]])],
2615       emacs_cv_xaw=yes,
2616       emacs_cv_xaw=no)])
2617     if test $emacs_cv_xaw = yes; then
2618       AC_MSG_RESULT([yes; using Lucid toolkit])
2619       USE_X_TOOLKIT=LUCID
2620       LUCID_LIBW=-lXaw
2621     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2622       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2623     else
2624       AC_MSG_ERROR([No X toolkit could be found.
2625 If you are sure you want Emacs compiled without an X toolkit, pass
2626   --with-x-toolkit=no
2627 to configure.  Otherwise, install the development libraries for the toolkit
2628 that you want to use (e.g. Gtk+) and re-run configure.])
2629     fi
2630   fi
2631 fi
2632
2633 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2634
2635 LIBXTR6=
2636 if test "${USE_X_TOOLKIT}" != "none"; then
2637   AC_MSG_CHECKING(X11 toolkit version)
2638   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2639   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2640 [[#if XtSpecificationRelease < 6
2641 fail;
2642 #endif
2643 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2644   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2645   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2646     AC_MSG_RESULT(6 or newer)
2647     AC_DEFINE(HAVE_X11XTR6, 1,
2648               [Define to 1 if you have the X11R6 or newer version of Xt.])
2649     LIBXTR6="-lSM -lICE"
2650     case "$opsys" in
2651       ## Use libw.a along with X11R6 Xt.
2652       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2653     esac
2654   else
2655     AC_MSG_RESULT(before 6)
2656   fi
2657
2658 dnl If using toolkit, check whether libXmu.a exists.
2659 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2660   OLDLIBS="$LIBS"
2661   if test x$HAVE_X11XTR6 = xyes; then
2662     LIBS="-lXt -lSM -lICE $LIBS"
2663   else
2664     LIBS="-lXt $LIBS"
2665   fi
2666   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2667   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2668   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2669 fi
2670 AC_SUBST(LIBXTR6)
2671
2672 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2673 dnl Why not just test for libxmu in the normal way?
2674 LIBXMU=-lXmu
2675 case $opsys in
2676   ## These systems don't supply Xmu.
2677   hpux* | aix4-2 )
2678     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2679     ;;
2680   mingw32 )
2681     LIBXMU=
2682     ;;
2683 esac
2684 AC_SUBST(LIBXMU)
2685
2686 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2687 if test "${HAVE_X11}" = "yes"; then
2688   if test "${USE_X_TOOLKIT}" != "none"; then
2689     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2690   fi
2691 fi
2692
2693 LIBXP=
2694 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2695   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2696   if test -d /usr/include/openmotif; then
2697     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2698     emacs_cv_openmotif=yes
2699     case "$canonical" in
2700       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2701       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2702       ;;
2703       *)
2704       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2705     esac
2706   else
2707     emacs_cv_openmotif=no
2708   fi
2709   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2710   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2711     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2712 int x = 5;
2713 #else
2714 Motif version prior to 2.1.
2715 #endif]])],
2716     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2717   if test $emacs_cv_motif_version_2_1 = yes; then
2718     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2719     if test x$emacs_cv_openmotif = xyes; then
2720       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2721     fi
2722   else
2723     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2724     # We put this in CFLAGS temporarily to precede other -I options
2725     # that might be in CFLAGS temporarily.
2726     # We put this in CPPFLAGS where it precedes the other -I options.
2727     OLD_CPPFLAGS=$CPPFLAGS
2728     OLD_CFLAGS=$CFLAGS
2729     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2730     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2731     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2732       [[int x = 5;]])],
2733       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2734     if test $emacs_cv_lesstif = yes; then
2735       # Make sure this -I option remains in CPPFLAGS after it is set
2736       # back to REAL_CPPFLAGS.
2737       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2738       # have those other -I options anyway.  Ultimately, having this
2739       # directory ultimately in CPPFLAGS will be enough.
2740       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2741       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2742     else
2743       CFLAGS=$OLD_CFLAGS
2744       CPPFLAGS=$OLD_CPPFLAGS
2745     fi
2746   fi
2747   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2748     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2749 fi
2750
2751 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2752 dnl using Motif or Xaw3d is available, and unless
2753 dnl --with-toolkit-scroll-bars=no was specified.
2754
2755 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2756             [Define to 1 if we should use toolkit scroll bars.])dnl
2757 USE_TOOLKIT_SCROLL_BARS=no
2758 if test "${with_toolkit_scroll_bars}" != "no"; then
2759   if test "${USE_X_TOOLKIT}" != "none"; then
2760     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2761       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2762       HAVE_XAW3D=no
2763       USE_TOOLKIT_SCROLL_BARS=yes
2764     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2765       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2766       USE_TOOLKIT_SCROLL_BARS=yes
2767     fi
2768   elif test "${HAVE_GTK}" = "yes"; then
2769     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2770     USE_TOOLKIT_SCROLL_BARS=yes
2771   elif test "${HAVE_NS}" = "yes"; then
2772     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2773     USE_TOOLKIT_SCROLL_BARS=yes
2774   elif test "${HAVE_W32}" = "yes"; then
2775     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2776     USE_TOOLKIT_SCROLL_BARS=yes
2777   fi
2778 fi
2779
2780 dnl See if XIM is available.
2781 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2782           #include <X11/Xlib.h>
2783           #include <X11/Xresource.h>]],
2784          [[XIMProc  callback;]])],
2785          [HAVE_XIM=yes
2786          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2787          HAVE_XIM=no)
2788
2789 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2790
2791 if test "${with_xim}" != "no"; then
2792   AC_DEFINE(USE_XIM, 1,
2793             [Define to 1 if we should use XIM, if it is available.])
2794 fi
2795
2796
2797 if test "${HAVE_XIM}" != "no"; then
2798   late_CFLAGS=$CFLAGS
2799   if test "$GCC" = yes; then
2800     CFLAGS="$CFLAGS --pedantic-errors"
2801   fi
2802   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2803 #include <X11/Xlib.h>
2804 #include <X11/Xresource.h>]],
2805 [[Display *display;
2806 XrmDatabase db;
2807 char *res_name;
2808 char *res_class;
2809 XIMProc  callback;
2810 XPointer *client_data;
2811 #ifndef __GNUC__
2812 /* If we're not using GCC, it's probably not XFree86, and this is
2813    probably right, but we can't use something like --pedantic-errors.  */
2814 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2815                                            char*, XIMProc, XPointer*);
2816 #endif
2817 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2818    client_data);]])],
2819     [emacs_cv_arg6_star=yes])
2820   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2821          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2822 either XPointer or XPointer*.])dnl
2823   if test "$emacs_cv_arg6_star" = yes; then
2824     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2825   else
2826     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2827   fi
2828   CFLAGS=$late_CFLAGS
2829 fi
2830
2831 ### Start of font-backend (under any platform) section.
2832 # (nothing here yet -- this is a placeholder)
2833 ### End of font-backend (under any platform) section.
2834
2835 ### Start of font-backend (under X11) section.
2836 if test "${HAVE_X11}" = "yes"; then
2837    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2838
2839    ## Use -lXft if available, unless `--with-xft=no'.
2840    HAVE_XFT=maybe
2841     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2842       with_xft="no";
2843     fi
2844     if test "x${with_xft}" != "xno"; then
2845
2846       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2847       ## Because xftfont.c uses XRenderQueryExtension, we also
2848       ## need to link to -lXrender.
2849       HAVE_XRENDER=no
2850       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2851       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2852         OLD_CPPFLAGS="$CPPFLAGS"
2853         OLD_CFLAGS="$CFLAGS"
2854         OLD_LIBS="$LIBS"
2855         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2856         CFLAGS="$CFLAGS $XFT_CFLAGS"
2857         XFT_LIBS="-lXrender $XFT_LIBS"
2858         LIBS="$XFT_LIBS $LIBS"
2859         AC_CHECK_HEADER(X11/Xft/Xft.h,
2860           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2861           [[#include <X11/X.h>]])
2862
2863         if test "${HAVE_XFT}" = "yes"; then
2864           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2865             AC_SUBST(XFT_LIBS)
2866           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2867         else
2868           CPPFLAGS="$OLD_CPPFLAGS"
2869           CFLAGS="$OLD_CFLAGS"
2870           LIBS="$OLD_LIBS"
2871         fi                        # "${HAVE_XFT}" = "yes"
2872       fi                          # "$HAVE_XFT" != no
2873     fi                            # "x${with_xft}" != "xno"
2874
2875     ## We used to allow building with FreeType and without Xft.
2876     ## However, the ftx font backend driver is not in good shape.
2877     if test "$HAVE_XFT" != "yes"; then
2878        dnl For the "Does Emacs use" message at the end.
2879        HAVE_XFT=no
2880        HAVE_FREETYPE=no
2881     else
2882        dnl Strict linkers fail with
2883        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2884        dnl if -lfreetype is not specified.
2885        dnl The following is needed to set FREETYPE_LIBS.
2886        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2887                          HAVE_FREETYPE=no)
2888
2889        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2890     fi
2891
2892     HAVE_LIBOTF=no
2893     if test "${HAVE_FREETYPE}" = "yes"; then
2894       AC_DEFINE(HAVE_FREETYPE, 1,
2895                 [Define to 1 if using the freetype and fontconfig libraries.])
2896       if test "${with_libotf}" != "no"; then
2897         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2898                           HAVE_LIBOTF=no)
2899         if test "$HAVE_LIBOTF" = "yes"; then
2900           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2901           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2902                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2903                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2904           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2905             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2906                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2907           fi
2908         fi
2909       fi
2910     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2911     dnl Does the new font backend require it, or can it work without it?
2912     fi
2913
2914     HAVE_M17N_FLT=no
2915     if test "${HAVE_LIBOTF}" = yes; then
2916       if test "${with_m17n_flt}" != "no"; then
2917         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2918         if test "$HAVE_M17N_FLT" = "yes"; then
2919           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2920         fi
2921       fi
2922     fi
2923 else
2924     HAVE_XFT=no
2925     HAVE_FREETYPE=no
2926     HAVE_LIBOTF=no
2927     HAVE_M17N_FLT=no
2928 fi
2929
2930 ### End of font-backend (under X11) section.
2931
2932 AC_SUBST(FREETYPE_CFLAGS)
2933 AC_SUBST(FREETYPE_LIBS)
2934 AC_SUBST(FONTCONFIG_CFLAGS)
2935 AC_SUBST(FONTCONFIG_LIBS)
2936 AC_SUBST(LIBOTF_CFLAGS)
2937 AC_SUBST(LIBOTF_LIBS)
2938 AC_SUBST(M17N_FLT_CFLAGS)
2939 AC_SUBST(M17N_FLT_LIBS)
2940
2941 ### Use -lXpm if available, unless `--with-xpm=no'.
2942 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2943 HAVE_XPM=no
2944 LIBXPM=
2945 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
2946   if test "${with_xpm}" != "no"; then
2947     SAVE_CPPFLAGS="$CPPFLAGS"
2948     SAVE_LDFLAGS="$LDFLAGS"
2949     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2950     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2951     AC_CHECK_HEADER(X11/xpm.h,
2952       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2953     if test "${HAVE_XPM}" = "yes"; then
2954       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2955       AC_EGREP_CPP(no_return_alloc_pixels,
2956       [#include "X11/xpm.h"
2957 #ifndef XpmReturnAllocPixels
2958 no_return_alloc_pixels
2959 #endif
2960       ], HAVE_XPM=no, HAVE_XPM=yes)
2961
2962       if test "${HAVE_XPM}" = "yes"; then
2963         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2964         AC_MSG_RESULT(yes)
2965       else
2966         AC_MSG_RESULT(no)
2967         CPPFLAGS="$SAVE_CPPFLAGS"
2968         LDFLAGS="$SAVE_LDFLAGS"
2969       fi
2970     fi
2971   fi
2972
2973   if test "${HAVE_XPM}" = "yes"; then
2974     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2975     LIBXPM=-lXpm
2976   fi
2977 fi
2978
2979 if test "${HAVE_X11}" = "yes"; then
2980   if test "${with_xpm}" != "no"; then
2981     AC_CHECK_HEADER(X11/xpm.h,
2982       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2983     if test "${HAVE_XPM}" = "yes"; then
2984       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2985       AC_EGREP_CPP(no_return_alloc_pixels,
2986       [#include "X11/xpm.h"
2987 #ifndef XpmReturnAllocPixels
2988 no_return_alloc_pixels
2989 #endif
2990       ], HAVE_XPM=no, HAVE_XPM=yes)
2991
2992       if test "${HAVE_XPM}" = "yes"; then
2993         AC_MSG_RESULT(yes)
2994       else
2995         AC_MSG_RESULT(no)
2996       fi
2997     fi
2998   fi
2999
3000   if test "${HAVE_XPM}" = "yes"; then
3001     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3002     LIBXPM=-lXpm
3003   fi
3004 fi
3005
3006 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3007 ### slightly different requirements wrt image libraries (it doesn't
3008 ### use -lXpm because it loads the xpm shared library dynamically at
3009 ### run time).
3010 if test "${opsys}" = "mingw32"; then
3011   if test "${with_xpm}" != "no"; then
3012     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3013 #define FOR_MSW 1])
3014   fi
3015
3016   if test "${HAVE_XPM}" = "yes"; then
3017     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3018   fi
3019 fi
3020
3021 AC_SUBST(LIBXPM)
3022
3023 ### Use -ljpeg if available, unless `--with-jpeg=no'.
3024 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
3025 HAVE_JPEG=no
3026 LIBJPEG=
3027 if test "${opsys}" = "mingw32"; then
3028   if test "${with_jpeg}" != "no"; then
3029     dnl Checking for jpeglib.h can lose because of a redefinition of
3030     dnl HAVE_STDLIB_H.
3031     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
3032   fi
3033   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3034   if test "${HAVE_JPEG}" = "yes"; then
3035     AC_DEFINE(HAVE_JPEG)
3036     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3037         [#include <jpeglib.h>
3038          version=JPEG_LIB_VERSION
3039 ],
3040         [AC_DEFINE(HAVE_JPEG)],
3041         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3042         HAVE_JPEG=no])
3043   fi
3044 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3045   if test "${with_jpeg}" != "no"; then
3046     dnl Checking for jpeglib.h can lose because of a redefinition of
3047     dnl  HAVE_STDLIB_H.
3048     AC_CHECK_HEADER(jerror.h,
3049       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
3050   fi
3051
3052   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3053   if test "${HAVE_JPEG}" = "yes"; then
3054     AC_DEFINE(HAVE_JPEG)
3055     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3056         [#include <jpeglib.h>
3057          version=JPEG_LIB_VERSION
3058 ],
3059         [AC_DEFINE(HAVE_JPEG)],
3060         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3061         HAVE_JPEG=no])
3062   fi
3063   if test "${HAVE_JPEG}" = "yes"; then
3064     LIBJPEG=-ljpeg
3065   fi
3066 fi
3067 AC_SUBST(LIBJPEG)
3068
3069 ### Use -lpng if available, unless `--with-png=no'.
3070 ### mingw32 doesn't use -lpng, since it loads the library dynamically.
3071 HAVE_PNG=no
3072 LIBPNG=
3073 if test "${opsys}" = "mingw32"; then
3074   if test "${with_png}" != "no"; then
3075     AC_CHECK_HEADER(png.h, HAVE_PNG=yes, HAVE_PNG=no)
3076   fi
3077   if test "${HAVE_PNG}" = "yes"; then
3078     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
3079
3080     AC_CHECK_DECL(png_longjmp,
3081       [],
3082       [AC_DEFINE(PNG_DEPSTRUCT, [],
3083          [Define to empty to suppress deprecation warnings when building
3084           with --enable-gcc-warnings and with libpng versions before 1.5,
3085           which lack png_longjmp.])],
3086       [[#ifdef HAVE_LIBPNG_PNG_H
3087         # include <libpng/png.h>
3088         #else
3089         # include <png.h>
3090         #endif
3091       ]])
3092   fi
3093 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3094   if test "${with_png}" != "no"; then
3095     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3096     # in /usr/include/libpng.
3097     AC_CHECK_HEADERS(png.h libpng/png.h, break)
3098     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
3099       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
3100     fi
3101   fi
3102
3103   if test "${HAVE_PNG}" = "yes"; then
3104     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
3105     LIBPNG="-lpng -lz -lm"
3106
3107     AC_CHECK_DECL(png_longjmp,
3108       [],
3109       [AC_DEFINE(PNG_DEPSTRUCT, [],
3110          [Define to empty to suppress deprecation warnings when building
3111           with --enable-gcc-warnings and with libpng versions before 1.5,
3112           which lack png_longjmp.])],
3113       [[#ifdef HAVE_LIBPNG_PNG_H
3114         # include <libpng/png.h>
3115         #else
3116         # include <png.h>
3117         #endif
3118       ]])
3119   fi
3120 fi
3121 AC_SUBST(LIBPNG)
3122
3123 HAVE_ZLIB=no
3124 LIBZ=
3125 if test "${with_zlib}" != "no"; then
3126   OLIBS=$LIBS
3127   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3128   LIBS=$OLIBS
3129   case $ac_cv_search_inflateEnd in
3130     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3131   esac
3132 fi
3133 if test "${HAVE_ZLIB}" = "yes"; then
3134   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3135   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3136   if test "${opsys}" = "mingw32"; then
3137      LIBZ=
3138   fi
3139 fi
3140 AC_SUBST(LIBZ)
3141
3142
3143 ### Use -ltiff if available, unless `--with-tiff=no'.
3144 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3145 HAVE_TIFF=no
3146 LIBTIFF=
3147 if test "${opsys}" = "mingw32"; then
3148   if test "${with_tiff}" != "no"; then
3149     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3150   fi
3151   if test "${HAVE_TIFF}" = "yes"; then
3152     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3153   fi
3154 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3155   if test "${with_tiff}" != "no"; then
3156     AC_CHECK_HEADER(tiffio.h,
3157       [tifflibs="-lz -lm"
3158       # At least one tiff package requires the jpeg library.
3159       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3160       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3161   fi
3162
3163   if test "${HAVE_TIFF}" = "yes"; then
3164     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3165     dnl FIXME -lz -lm, as per libpng?
3166     LIBTIFF=-ltiff
3167   fi
3168 fi
3169 AC_SUBST(LIBTIFF)
3170
3171 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3172 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3173 HAVE_GIF=no
3174 LIBGIF=
3175 if test "${opsys}" = "mingw32"; then
3176   if test "${with_gif}" != "no"; then
3177     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3178   fi
3179   if test "${HAVE_GIF}" = "yes"; then
3180     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3181   fi
3182 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3183         || test "${HAVE_W32}" = "yes"; then
3184   AC_CHECK_HEADER(gif_lib.h,
3185 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3186 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3187     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3188         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3189
3190   if test "$HAVE_GIF" = yes; then
3191     LIBGIF=-lgif
3192   elif test "$HAVE_GIF" = maybe; then
3193 # If gif_lib.h but no libgif, try libungif.
3194     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3195     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3196   fi
3197
3198   if test "${HAVE_GIF}" = "yes"; then
3199     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3200   fi
3201 fi
3202 AC_SUBST(LIBGIF)
3203
3204 dnl Check for required libraries.
3205 if test "${HAVE_X11}" = "yes"; then
3206   MISSING=""
3207   WITH_NO=""
3208   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3209     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3210   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3211     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3212   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3213     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3214   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3215     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3216   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3217     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3218
3219   if test "X${MISSING}" != X; then
3220     AC_MSG_ERROR([The following required libraries were not found:
3221     $MISSING
3222 Maybe some development libraries/packages are missing?
3223 If you don't want to link with them give
3224     $WITH_NO
3225 as options to configure])
3226   fi
3227 fi
3228
3229 ### Use -lgpm if available, unless `--with-gpm=no'.
3230 HAVE_GPM=no
3231 LIBGPM=
3232 if test "${with_gpm}" != "no"; then
3233   AC_CHECK_HEADER(gpm.h,
3234     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3235
3236   if test "${HAVE_GPM}" = "yes"; then
3237     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3238     LIBGPM=-lgpm
3239   fi
3240 fi
3241 AC_SUBST(LIBGPM)
3242
3243 dnl Check for malloc/malloc.h on darwin
3244 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3245
3246 GNUSTEP_CFLAGS=
3247 ### Use NeXTstep API to implement GUI.
3248 if test "${HAVE_NS}" = "yes"; then
3249   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3250   if test "${NS_IMPL_COCOA}" = "yes"; then
3251     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3252   fi
3253   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3254     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3255     # See also .m.o rule in Makefile.in */
3256     # FIXME: are all these flags really needed?  Document here why.  */
3257     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3258     ## Extra CFLAGS applied to src/*.m files.
3259     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3260   fi
3261   OTHER_FILES=ns-app
3262 fi
3263
3264 ### Use session management (-lSM -lICE) if available
3265 HAVE_X_SM=no
3266 LIBXSM=
3267 if test "${HAVE_X11}" = "yes"; then
3268   AC_CHECK_HEADER(X11/SM/SMlib.h,
3269     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3270
3271   if test "${HAVE_X_SM}" = "yes"; then
3272     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3273     LIBXSM="-lSM -lICE"
3274     case "$LIBS" in
3275       *-lSM*) ;;
3276       *)      LIBS="$LIBXSM $LIBS" ;;
3277     esac
3278   fi
3279 fi
3280 AC_SUBST(LIBXSM)
3281
3282 ### Use XRandr (-lXrandr) if available
3283 HAVE_XRANDR=no
3284 if test "${HAVE_X11}" = "yes"; then
3285   XRANDR_REQUIRED=1.2.2
3286   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3287   PKG_CHECK_MODULES(XRANDR, $XRANDR_MODULES, HAVE_XRANDR=yes, HAVE_XRANDR=no)
3288   if test $HAVE_XRANDR = no; then
3289     # Test old way in case pkg-config doesn't have it (older machines).
3290     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3291       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3292     if test $HAVE_XRANDR = yes; then
3293       XRANDR_LIBS=-lXrandr
3294       AC_SUBST(XRANDR_LIBS)
3295     fi
3296   fi
3297   if test $HAVE_XRANDR = yes; then
3298     SAVE_CFLAGS="$CFLAGS"
3299     SAVE_LIBS="$LIBS"
3300     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3301     LIBS="$XRANDR_LIBS $LIBS"
3302     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3303     CFLAGS="$SAVE_CFLAGS"
3304     LIBS="$SAVE_LIBS"
3305
3306     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3307   fi
3308 fi
3309
3310 ### Use Xinerama (-lXinerama) if available
3311 HAVE_XINERAMA=no
3312 if test "${HAVE_X11}" = "yes"; then
3313   XINERAMA_REQUIRED=1.0.2
3314   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3315   PKG_CHECK_MODULES(XINERAMA, $XINERAMA_MODULES, HAVE_XINERAMA=yes,
3316                     HAVE_XINERAMA=no)
3317   if test $HAVE_XINERAMA = no; then
3318     # Test old way in case pkg-config doesn't have it (older machines).
3319     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3320       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3321     if test $HAVE_XINERAMA = yes; then
3322       XINERAMA_LIBS=-lXinerama
3323       AC_SUBST(XINERAMA_LIBS)
3324     fi
3325   fi
3326   if test $HAVE_XINERAMA = yes; then
3327     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3328   fi
3329 fi
3330
3331
3332 ### Use libxml (-lxml2) if available
3333 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3334 HAVE_LIBXML2=no
3335 if test "${with_xml2}" != "no"; then
3336   ### I'm not sure what the version number should be, so I just guessed.
3337   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3338   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3339   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3340     SAVE_CPPFLAGS="$CPPFLAGS"
3341     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3342     AC_CHECK_HEADER(libxml/HTMLparser.h,
3343       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3344                      [#include <libxml/HTMLparser.h>])])
3345     CPPFLAGS="$SAVE_CPPFLAGS"
3346     if test "${HAVE_LIBXML2}" = "yes"; then
3347       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3348       LIBXML2_LIBS="-lxml2"
3349     fi
3350   fi
3351   if test "${HAVE_LIBXML2}" = "yes"; then
3352     if test "${opsys}" != "mingw32"; then
3353       LIBS="$LIBXML2_LIBS $LIBS"
3354       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3355     else
3356       LIBXML2_LIBS=""
3357     fi
3358     if test "${HAVE_LIBXML2}" = "yes"; then
3359       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3360     else
3361       LIBXML2_LIBS=""
3362       LIBXML2_CFLAGS=""
3363     fi
3364   fi
3365 fi
3366 AC_SUBST(LIBXML2_LIBS)
3367 AC_SUBST(LIBXML2_CFLAGS)
3368
3369 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3370 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3371 if test "${opsys}" = "mingw32"; then
3372   emacs_cv_netdb_declares_h_errno=yes
3373 fi
3374 AC_CACHE_CHECK(whether netdb declares h_errno,
3375                emacs_cv_netdb_declares_h_errno,
3376 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3377   [[return h_errno;]])],
3378   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3379 if test $emacs_cv_netdb_declares_h_errno = yes; then
3380   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3381 fi
3382
3383 # sqrt and other floating-point functions such as fmod and frexp
3384 # are found in -lm on most systems, but mingw32 doesn't use -lm.
3385 if test "${opsys}" != "mingw32"; then
3386   AC_CHECK_LIB(m, sqrt)
3387 fi
3388
3389 # Check for mail-locking functions in a "mail" library.  Probably this should
3390 # have the same check as for liblockfile below.
3391 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3392 if test $have_mail = yes; then
3393   LIBS_MAIL=-lmail
3394   LIBS="$LIBS_MAIL $LIBS"
3395   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3396 else
3397   LIBS_MAIL=
3398 fi
3399 dnl Debian, at least:
3400 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3401 if test $have_lockfile = yes; then
3402    LIBS_MAIL=-llockfile
3403    LIBS="$LIBS_MAIL $LIBS"
3404    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3405 else
3406 # If we have the shared liblockfile, assume we must use it for mail
3407 # locking (e.g. Debian).  If we couldn't link against liblockfile
3408 # (no liblockfile.a installed), ensure that we don't need to.
3409   dnl This works for files generally, not just executables.
3410   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3411   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3412                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3413   if test $ac_cv_prog_liblockfile = yes; then
3414     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3415 This probably means that movemail could lose mail.
3416 There may be a `development' package to install containing liblockfile.])
3417   fi
3418 fi
3419 AC_CHECK_HEADERS_ONCE(maillock.h)
3420 AC_SUBST(LIBS_MAIL)
3421
3422 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3423 ## interlock access to the mail spool.  The alternative is a lock file named
3424 ## /usr/spool/mail/$USER.lock.
3425 mail_lock=no
3426 case "$opsys" in
3427   aix4-2) mail_lock="lockf" ;;
3428
3429   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3430
3431   ## On GNU/Linux systems, both methods are used by various mail programs.
3432   ## I assume most people are using newer mailers that have heard of flock.
3433   ## Change this if you need to.
3434   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3435   ## configure gets the right answers, and that means *NOT* using flock.
3436   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3437   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3438   ## Debian maintainer hasn't provided a clean fix for Emacs.
3439   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3440   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3441   ## correct logic.  -- fx
3442   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3443   ## liblockfile is a Free Software replacement for libmail, used on
3444   ## Debian systems and elsewhere. -rfr.
3445   gnu-*)
3446     mail_lock="flock"
3447     if test $have_mail = yes || test $have_lockfile = yes; then
3448       test $ac_cv_header_maillock_h = yes && mail_lock=no
3449     fi
3450     ;;
3451
3452   mingw32)
3453     mail_lock="none-needed" ;;
3454 esac
3455
3456 BLESSMAIL_TARGET=
3457 case "$mail_lock" in
3458   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3459
3460   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3461
3462   none-needed) ;;
3463
3464   *) BLESSMAIL_TARGET="need-blessmail" ;;
3465 esac
3466 AC_SUBST(BLESSMAIL_TARGET)
3467
3468
3469 AC_CHECK_FUNCS(accept4 gethostname \
3470 getrusage get_current_dir_name \
3471 lrand48 \
3472 select getpagesize setlocale \
3473 getrlimit setrlimit shutdown getaddrinfo \
3474 strsignal setitimer \
3475 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3476 gai_strerror getline getdelim sync \
3477 getpwent endpwent getgrent endgrent \
3478 touchlock \
3479 cfmakeraw cfsetspeed copysign __executable_start log2)
3480
3481 dnl No need to check for aligned_alloc and posix_memalign if using
3482 dnl gmalloc.o, as it supplies them.  Don't use these functions on
3483 dnl Darwin as they are incompatible with unexmacosx.c.
3484 if test -z "$GMALLOC_OBJ" && test "$opsys" != darwin; then
3485   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3486 fi
3487
3488 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
3489 ## has a broken `rint' in some library versions including math library
3490 ## version number A.09.05.
3491 ## You can fix the math library by installing patch number PHSS_4630.
3492 ## But we can fix it more reliably for Emacs by just not using rint.
3493 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
3494 case $opsys in
3495    hpux*) : ;;
3496    *) AC_CHECK_FUNCS(random rint) ;;
3497 esac
3498
3499 dnl Cannot use AC_CHECK_FUNCS
3500 AC_CACHE_CHECK([for __builtin_unwind_init],
3501                emacs_cv_func___builtin_unwind_init,
3502 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3503                 emacs_cv_func___builtin_unwind_init=yes,
3504                 emacs_cv_func___builtin_unwind_init=no)])
3505 if test $emacs_cv_func___builtin_unwind_init = yes; then
3506   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3507             [Define to 1 if you have the `__builtin_unwind_init' function.])
3508 fi
3509
3510 AC_CHECK_HEADERS_ONCE(sys/un.h)
3511
3512 AC_FUNC_FSEEKO
3513
3514 # UNIX98 PTYs.
3515 AC_CHECK_FUNCS(grantpt)
3516
3517 # PTY-related GNU extensions.
3518 AC_CHECK_FUNCS(getpt posix_openpt)
3519
3520 # Check this now, so that we will NOT find the above functions in ncurses.
3521 # That is because we have not set up to link ncurses in lib-src.
3522 # It's better to believe a function is not available
3523 # than to expect to find it in ncurses.
3524 # Also we need tputs and friends to be able to build at all.
3525 AC_MSG_CHECKING([for library containing tputs])
3526 # Run a test program that contains a call to tputs, a call that is
3527 # never executed.  This tests whether a pre-'main' dynamic linker
3528 # works with the library.  It's too much trouble to actually call
3529 # tputs in the test program, due to portability hassles.  When
3530 # cross-compiling, assume the test program will run if it links.
3531 AC_DEFUN([tputs_link_source], [
3532   AC_LANG_SOURCE(
3533      [[extern void tputs (const char *, int, int (*)(int));
3534        int main (int argc, char **argv)
3535        {
3536           if (argc == 10000)
3537             tputs (argv[0], 0, 0);
3538           return 0;
3539        }]])
3540 ])
3541 if test "${opsys}" = "mingw32"; then
3542   msg='none required'
3543 else
3544   # Maybe curses should be tried earlier?
3545   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3546   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3547     OLIBS=$LIBS
3548     if test -z "$tputs_library"; then
3549       LIBS_TERMCAP=
3550       msg='none required'
3551     else
3552       LIBS_TERMCAP=-l$tputs_library
3553       msg=$LIBS_TERMCAP
3554       LIBS="$LIBS_TERMCAP $LIBS"
3555     fi
3556     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3557       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3558     LIBS=$OLIBS
3559     if test "X$msg" != Xno; then
3560       break
3561     fi
3562   done
3563 fi
3564 AC_MSG_RESULT([$msg])
3565 if test "X$msg" = Xno; then
3566   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3567 The following libraries were tried (in order):
3568   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3569 Please try installing whichever of these libraries is most appropriate
3570 for your system, together with its header files.
3571 For example, a libncurses-dev(el) or similar package.])
3572 fi
3573
3574 ## Use termcap instead of terminfo?
3575 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3576 TERMINFO=yes
3577 ## FIXME?  In the cases below where we unconditionally set
3578 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3579 ## if that was found above to have tputs.
3580 ## Should we use the gnu* logic everywhere?
3581 case "$opsys" in
3582   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3583   ##  The ncurses library has been moved out of the System framework in
3584   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3585   ##  option to use it.
3586   darwin) LIBS_TERMCAP="-lncurses" ;;
3587
3588   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3589
3590   freebsd)
3591     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3592     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3593     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3594 [[#if __FreeBSD_version < 400000
3595 fail;
3596 #endif
3597 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3598
3599     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3600
3601     if test $emacs_cv_freebsd_terminfo = yes; then
3602       LIBS_TERMCAP="-lncurses"
3603     else
3604       TERMINFO=no
3605       LIBS_TERMCAP="-ltermcap"
3606     fi
3607     ;;
3608
3609   mingw32)
3610     TERMINFO=no
3611     LIBS_TERMCAP=
3612     ;;
3613
3614   netbsd)
3615     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3616       TERMINFO=no
3617       LIBS_TERMCAP="-ltermcap"
3618     fi
3619     ;;
3620
3621   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3622
3623   ## hpux: Make sure we get select from libc rather than from libcurses
3624   ##  because libcurses on HPUX 10.10 has a broken version of select.
3625   ##  We used to use -lc -lcurses, but this may be cleaner.
3626   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3627   # set that way, now it uses the default).  Isn't this a contradiction?
3628   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3629
3630 esac
3631
3632 TERMCAP_OBJ=tparam.o
3633 if test $TERMINFO = yes; then
3634   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3635   TERMCAP_OBJ=terminfo.o
3636 fi
3637 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3638   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3639 fi
3640 AC_SUBST(LIBS_TERMCAP)
3641 AC_SUBST(TERMCAP_OBJ)
3642
3643
3644 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3645 # On Darwin, res_init appears not to be useful: see bug#562 and
3646 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3647 resolv=no
3648
3649 if test $opsys != darwin; then
3650
3651   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3652 #include <arpa/nameser.h>
3653 #include <resolv.h>]],
3654     [[return res_init();]])],
3655     have_res_init=yes, have_res_init=no)
3656   if test "$have_res_init" = no; then
3657     OLIBS="$LIBS"
3658     LIBS="$LIBS -lresolv"
3659     AC_MSG_CHECKING(for res_init with -lresolv)
3660     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3661 #include <arpa/nameser.h>
3662 #include <resolv.h>]],
3663       [[return res_init();]])],
3664       have_res_init=yes, have_res_init=no)
3665     AC_MSG_RESULT($have_res_init)
3666     if test "$have_res_init" = yes ; then
3667       resolv=yes
3668     fi
3669     LIBS="$OLIBS"
3670   fi
3671
3672   if test "$have_res_init" = yes; then
3673     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3674   fi
3675 fi                              dnl !darwin
3676
3677 # Do we need the Hesiod library to provide the support routines?
3678 dnl FIXME?  Should we be skipping this on Darwin too?
3679 LIBHESIOD=
3680 if test "$with_hesiod" != no ; then
3681   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3682   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3683      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3684                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3685   if test "$resolv" = yes ; then
3686     RESOLVLIB=-lresolv
3687   else
3688     RESOLVLIB=
3689   fi
3690   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3691         hesiod=yes, :, $RESOLVLIB)])
3692
3693   if test x"$hesiod" = xyes; then
3694     LIBHESIOD=-lhesiod
3695   fi
3696 fi
3697 AC_SUBST(LIBHESIOD)
3698
3699 # Do we need libresolv (due to res_init or Hesiod)?
3700 if test "$resolv" = yes && test $opsys != darwin; then
3701   LIBRESOLV=-lresolv
3702 else
3703   LIBRESOLV=
3704 fi
3705 AC_SUBST(LIBRESOLV)
3706
3707 # These tell us which Kerberos-related libraries to use.
3708 COM_ERRLIB=
3709 CRYPTOLIB=
3710 KRB5LIB=
3711 DESLIB=
3712 KRB4LIB=
3713
3714 if test "${with_kerberos}" != no; then
3715   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3716   if test $have_com_err = yes; then
3717     COM_ERRLIB=-lcom_err
3718     LIBS="$COM_ERRLIB $LIBS"
3719   fi
3720   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3721   if test $have_crypto = yes; then
3722     CRYPTOLIB=-lcrypto
3723     LIBS="$CRYPTOLIB $LIBS"
3724   fi
3725   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3726   if test $have_k5crypto = yes; then
3727     CRYPTOLIB=-lk5crypto
3728     LIBS="$CRYPTOLIB $LIBS"
3729   fi
3730   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3731   if test $have_krb5=yes; then
3732     KRB5LIB=-lkrb5
3733     LIBS="$KRB5LIB $LIBS"
3734   fi
3735   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3736   if test "${with_kerberos5}" = no; then
3737     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3738     if test $have_des425 = yes; then
3739       DESLIB=-ldes425
3740       LIBS="$DESLIB $LIBS"
3741     else
3742       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3743       if test $have_des = yes; then
3744         DESLIB=-ldes
3745         LIBS="$DESLIB $LIBS"
3746       fi
3747     fi
3748     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3749     if test $have_krb4 = yes; then
3750       KRB4LIB=-lkrb4
3751       LIBS="$KRB4LIB $LIBS"
3752     else
3753       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3754       if test $have_krb = yes; then
3755         KRB4LIB=-lkrb
3756         LIBS="$KRB4LIB $LIBS"
3757       fi
3758     fi
3759   fi
3760
3761   if test "${with_kerberos5}" != no; then
3762     AC_CHECK_HEADERS(krb5.h,
3763       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3764                         [#include <krb5.h>])])
3765   else
3766     AC_CHECK_HEADERS(krb.h,,
3767                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3768                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3769   fi
3770   AC_CHECK_HEADERS(com_err.h)
3771 fi
3772
3773 AC_SUBST(COM_ERRLIB)
3774 AC_SUBST(CRYPTOLIB)
3775 AC_SUBST(KRB5LIB)
3776 AC_SUBST(DESLIB)
3777 AC_SUBST(KRB4LIB)
3778
3779 AC_CHECK_HEADERS(valgrind/valgrind.h)
3780
3781 AC_CHECK_FUNCS_ONCE(tzset)
3782 AC_MSG_CHECKING(whether localtime caches TZ)
3783 AC_CACHE_VAL(emacs_cv_localtime_cache,
3784 [if test x$ac_cv_func_tzset = xyes; then
3785 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3786 char TZ_GMT0[] = "TZ=GMT0";
3787 char TZ_PST8[] = "TZ=PST8";
3788 main()
3789 {
3790   time_t now = time ((time_t *) 0);
3791   int hour_GMT0, hour_unset;
3792   if (putenv (TZ_GMT0) != 0)
3793     exit (1);
3794   hour_GMT0 = localtime (&now)->tm_hour;
3795   unsetenv("TZ");
3796   hour_unset = localtime (&now)->tm_hour;
3797   if (putenv (TZ_PST8) != 0)
3798     exit (1);
3799   if (localtime (&now)->tm_hour == hour_GMT0)
3800     exit (1);
3801   unsetenv("TZ");
3802   if (localtime (&now)->tm_hour != hour_unset)
3803     exit (1);
3804   exit (0);
3805 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3806 [# If we have tzset, assume the worst when cross-compiling.
3807 emacs_cv_localtime_cache=yes])
3808 else
3809         # If we lack tzset, report that localtime does not cache TZ,
3810         # since we can't invalidate the cache if we don't have tzset.
3811         emacs_cv_localtime_cache=no
3812 fi])dnl
3813 AC_MSG_RESULT($emacs_cv_localtime_cache)
3814 if test $emacs_cv_localtime_cache = yes; then
3815   AC_DEFINE(LOCALTIME_CACHE, 1,
3816             [Define to 1 if localtime caches TZ.])
3817 fi
3818
3819 ok_so_far=yes
3820 AC_CHECK_FUNC(socket, , ok_so_far=no)
3821 if test $ok_so_far = yes; then
3822   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3823 fi
3824 if test $ok_so_far = yes; then
3825   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3826 fi
3827 if test $ok_so_far = yes; then
3828 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3829   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3830             [Define to 1 if you have inet sockets.])
3831 fi
3832
3833 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3834 dnl This can be removed once we assume Autoconf 2.70.
3835 case $canonical in
3836   *-solaris2.4 | *-solaris2.4.*)
3837     dnl Disable the Autoconf-generated vfork test.
3838     : ${ac_cv_func_vfork_works=no};;
3839 esac
3840
3841 AC_FUNC_FORK
3842
3843 AC_CHECK_FUNCS(snprintf)
3844
3845 dnl Check this late.  It depends on what other libraries (lrsvg, Gtk+ etc)
3846 dnl Emacs uses.
3847 XGSELOBJ=
3848 OLDCFLAGS="$CFLAGS"
3849 OLDLIBS="$LIBS"
3850 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS"
3851 LIBS="$LIBS $GFILENOTIFY_LIBS"
3852 AC_MSG_CHECKING([whether GLib is linked in])
3853 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3854         [[#include <glib.h>
3855         ]],
3856         [[g_print ("Hello world");]])],
3857      [links_glib=yes],
3858      [links_glib=no])
3859 AC_MSG_RESULT([$links_glib])
3860 if test "${links_glib}" = "yes"; then
3861   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3862   if test "$HAVE_NS" = no;then
3863     XGSELOBJ=xgselect.o
3864   fi
3865 fi
3866 CFLAGS="$OLDCFLAGS"
3867 LIBS="$OLDLIBS"
3868 AC_SUBST(XGSELOBJ)
3869
3870 dnl Adapted from Haible's version.
3871 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3872   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3873     [[char* cs = nl_langinfo(CODESET);]])],
3874     emacs_cv_langinfo_codeset=yes,
3875     emacs_cv_langinfo_codeset=no)
3876   ])
3877 if test $emacs_cv_langinfo_codeset = yes; then
3878   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3879     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3880 fi
3881
3882 AC_TYPE_MBSTATE_T
3883
3884 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3885   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3886                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3887 if test "$emacs_cv_c_restrict_arr" = yes; then
3888   AC_DEFINE(__restrict_arr, __restrict,
3889     [Define to compiler's equivalent of C99 restrict keyword in array
3890      declarations.  Define as empty for no equivalent.])
3891 fi
3892
3893 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3894 dnl how the tty code is related to POSIX and/or other versions of termios.
3895 dnl The following looks like a useful start.
3896 dnl
3897 dnl AC_SYS_POSIX_TERMIOS
3898 dnl if test $ac_cv_sys_posix_termios = yes; then
3899 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3900 dnl                                and macros for terminal control.])
3901 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3902 dnl fi
3903
3904 dnl Turned on June 1996 supposing nobody will mind it.
3905 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3906 if test "${opsys}" != "mingw32"; then
3907    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3908      in the full name stands for the login id.])
3909 fi
3910
3911 dnl Every platform that uses configure supports this.
3912 dnl There is a create-lockfiles option you can
3913 dnl customize if you do not want the lock files to be written.
3914 dnl So it is not clear that this #define still needs to exist.
3915 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3916   so that Emacs can tell instantly when you try to modify a file that
3917   someone else has modified in his/her Emacs.])
3918
3919 dnl Everybody supports this, except MS.
3920 dnl Seems like the kind of thing we should be testing for, though.
3921 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3922 if test "${opsys}" != "mingw32"; then
3923   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3924 fi
3925
3926 dnl Everybody supports this, except MS-DOS.
3927 dnl Seems like the kind of thing we should be testing for, though.
3928 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3929 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3930   4.2-compatible sockets.])
3931
3932 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3933
3934 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
3935   a null file, or a data sink.])
3936 if test "${opsys}" = "mingw32"; then
3937   AC_DEFINE(NULL_DEVICE, ["NUL:"])
3938 else
3939   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
3940 fi
3941
3942 if test "${opsys}" = "mingw32"; then
3943   SEPCHAR=';'
3944 else
3945   SEPCHAR=':'
3946 fi
3947 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
3948 dnl This is for MinGW, and is used in test/automated/Makefile.in.
3949 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
3950 dnl decides that a command-line argument to be passed to a MinGW program
3951 dnl is a PATH-style list of directories.  But that heuristics plays it
3952 dnl safe, and only does the replacement when it is _absolutely_ sure it
3953 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
3954 dnl which breaks in-tree builds.  So we do this manually instead.
3955 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
3956 dnl be computed as ':' in MSYS Bash.
3957 AC_SUBST(SEPCHAR)
3958
3959 dnl Everybody supports this, except MS-DOS.
3960 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3961
3962 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3963
3964
3965 AC_DEFINE(DIRECTORY_SEP, ['/'],
3966   [Character that separates directories in a file name.])
3967
3968 if test "${opsys}" = "mingw32"; then
3969   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
3970     [Returns true if character is a device separator.])
3971
3972   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
3973     [Returns true if character is a directory separator.])
3974
3975   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
3976     [Returns true if character is any form of separator.])
3977 else
3978   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3979     [Returns true if character is a device separator.])
3980
3981   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3982     [Returns true if character is a directory separator.])
3983
3984   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3985     [Returns true if character is any form of separator.])
3986 fi
3987
3988 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3989
3990 case $opsys in
3991   aix4-2)
3992     dnl Unfortunately without libXmu we cannot support EditRes.
3993     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3994       AC_DEFINE(NO_EDITRES, 1)
3995     fi
3996     ;;
3997
3998   hpux*)
3999     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4000     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4001     AC_DEFINE(NO_EDITRES, 1)
4002     ;;
4003 esac
4004
4005
4006 case $opsys in
4007   irix6-5 | sol2* | unixware )
4008     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4009     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4010     dnl need the constant to dimension an array.  So wire in the appropriate
4011     dnl value here.
4012     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4013     ;;
4014 esac
4015
4016 emacs_broken_SIGIO=no
4017
4018 case $opsys in
4019   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4020   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4021   hpux* | irix6-5 | openbsd | sol2* | unixware )
4022     emacs_broken_SIGIO=yes
4023     ;;
4024
4025   aix4-2)
4026     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4027     dnl the way this system works, libc functions that return malloced
4028     dnl memory use the libc malloc implementation. Calling xfree or
4029     dnl xrealloc on the results of such functions results in a crash.
4030     dnl
4031     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4032     dnl but that does not currently work on this system.
4033     dnl
4034     dnl It is possible to completely override the malloc implementation on
4035     dnl AIX, but that involves putting the malloc functions in a shared
4036     dnl library and setting the MALLOCTYPE environment variable to point to
4037     dnl that shared library.
4038     dnl
4039     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4040     dnl to avoid a crash just use the Emacs implementation for that function.
4041     dnl
4042     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4043     dnl of this file, so that we do not check for get_current_dir_name
4044     dnl on AIX.  But that might be fragile if something else ends
4045     dnl up testing for get_current_dir_name as a dependency.
4046     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4047       get_current_dir_name should not be used.])
4048     ;;
4049
4050   freebsd)
4051     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4052     dnl writes/reads on a PTY, read(2) returns bogus data:
4053     dnl
4054     dnl write(2)  1022 bytes
4055     dnl write(2)   954 bytes, get EAGAIN
4056     dnl read(2)   1024 bytes in process_read_output
4057     dnl read(2)     11 bytes in process_read_output
4058     dnl
4059     dnl That is, read(2) returns more bytes than have ever been written
4060     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4061     dnl successfully after processing (for example with CRs added if the
4062     dnl terminal is set up that way which it is here).  The same bytes will
4063     dnl be seen again in a later read(2), without the CRs.
4064     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4065       work around an issue when reading from a PTY.])
4066     ;;
4067 esac
4068
4069 case $opsys in
4070   gnu-* | sol2-10 )
4071     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4072     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4073   ;;
4074 esac
4075
4076 case $opsys in
4077   darwin | dragonfly | freebsd | netbsd | openbsd )
4078     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4079       close a pty to make it a controlling terminal (it is already a
4080       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4081   ;;
4082 esac
4083
4084 dnl FIXME Surely we can test for this rather than hard-code it.
4085 case $opsys in
4086   netbsd | openbsd) sound_device="/dev/audio" ;;
4087   *) sound_device="/dev/dsp" ;;
4088 esac
4089
4090 dnl Used in sound.c
4091 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4092   [Name of the default sound device.])
4093
4094
4095 dnl Emacs can read input using SIGIO and buffering characters itself,
4096 dnl or using CBREAK mode and making C-g cause SIGINT.
4097 dnl The choice is controlled by the variable interrupt_input.
4098 dnl
4099 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4100 dnl
4101 dnl Emacs uses the presence of the USABLE_SIGIO macro
4102 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4103 dnl INTERRUPT_INPUT to decide whether to use it by default.
4104 dnl
4105 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4106 dnl CBREAK mode has two disadvantages
4107 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4108 dnl I hear that in system V this problem does not exist.
4109 dnl 2) Control-G causes output to be discarded.
4110 dnl I do not know whether this can be fixed in system V.
4111 dnl
4112 dnl Another method of doing input is planned but not implemented.
4113 dnl It would have Emacs fork off a separate process
4114 dnl to read the input and send it to the true Emacs process
4115 dnl through a pipe.
4116 case $opsys in
4117   darwin | gnu-linux | gnu-kfreebsd )
4118     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4119   ;;
4120 esac
4121
4122
4123 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4124 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4125 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4126 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4127 dnl taking float or double parameters.
4128 case $opsys in
4129   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4130     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4131       file defines `NeedWidePrototypes' as `NO'.])
4132   ;;
4133 esac
4134
4135
4136 dnl Used in process.c, this must be a loop, even if it only runs once.
4137 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4138 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4139 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4140 dnl trying suffixes 0-16.
4141 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4142   first PTY, if PTYs are supported.])
4143 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4144 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4145   end of a PTY, if non-standard.])
4146 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4147   end of a PTY, if non-standard.])
4148
4149 case $opsys in
4150   aix4-2 )
4151     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4152     dnl You allocate a pty by opening /dev/ptc to get the master side.
4153     dnl To get the name of the slave side, you just ttyname() the master side.
4154     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4155     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4156     ;;
4157
4158   cygwin )
4159     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4160     dnl multi-line AC_DEFINEs are hard. :(
4161     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4162     AC_DEFINE(PTY_NAME_SPRINTF, [])
4163     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4164     ;;
4165
4166   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4167   darwin )
4168     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4169     dnl Not used, because PTY_ITERATION is defined.
4170     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4171     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4172     dnl But we don't have to block SIGCHLD because it is blocked in the
4173     dnl implementation of grantpt.
4174     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4175     AC_DEFINE(PTY_NAME_SPRINTF, [])
4176     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4177     ;;
4178
4179   gnu | openbsd )
4180     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4181     ;;
4182
4183   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4184     dnl if HAVE_GRANTPT
4185     if test "x$ac_cv_func_grantpt" = xyes; then
4186       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4187       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4188       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4189       dnl to prevent sigchld_handler from intercepting the child's death.
4190       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4191       dnl if HAVE_POSIX_OPENPT
4192       if test "x$ac_cv_func_posix_openpt" = xyes; then
4193         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4194         AC_DEFINE(PTY_NAME_SPRINTF, [])
4195       dnl if HAVE_GETPT
4196       elif test "x$ac_cv_func_getpt" = xyes; then
4197         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4198         AC_DEFINE(PTY_NAME_SPRINTF, [])
4199       else
4200         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4201       fi
4202     else
4203       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4204     fi
4205     ;;
4206
4207   hpux*)
4208     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4209     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4210     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4211     ;;
4212
4213   irix6-5 )
4214     dnl It looks like this cannot be right, because it is not a loop.
4215     dnl However, process.c actually does this:
4216     dnl # ifndef __sgi
4217     dnl   continue;
4218     dnl # else
4219     dnl   return -1;
4220     dnl # endif
4221     dnl which presumably makes it OK, since irix == sgi (?).
4222     dnl FIXME it seems like this special treatment is unnecessary?
4223     dnl Why can't irix use a single-trip loop like eg cygwin?
4224     AC_DEFINE(PTY_ITERATION, [])
4225     dnl Not used, because PTY_ITERATION is defined.
4226     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4227     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4228     dnl No need to get the pty name at all.
4229     AC_DEFINE(PTY_NAME_SPRINTF, [])
4230     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4231     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4232     ;;
4233
4234   sol2* )
4235     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4236     dnl from intercepting that death.  If any child but grantpt's should die
4237     dnl within, it should be caught after sigrelse(2).
4238     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4239     ;;
4240
4241   unixware )
4242     dnl Comments are as per sol2*.
4243     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4244     ;;
4245 esac
4246
4247
4248 case $opsys in
4249   sol2* | unixware )
4250     dnl This change means that we don't loop through allocate_pty too
4251     dnl many times in the (rare) event of a failure.
4252     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4253     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4254     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4255     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4256     ;;
4257 esac
4258
4259
4260 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4261 "typing" a signal character on the pty.])
4262
4263 case $opsys in
4264   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4265   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4266   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4267     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4268     ;;
4269
4270   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4271   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4272   gnu-linux | gnu-kfreebsd )
4273
4274     AC_MSG_CHECKING([for signals via characters])
4275     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4276 #include <linux/version.h>
4277 #if LINUX_VERSION_CODE < 0x20400
4278 # error "Linux version too old"
4279 #endif
4280       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4281
4282     AC_MSG_RESULT([$emacs_signals_via_chars])
4283     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4284     ;;
4285 esac
4286
4287
4288 dnl Used in lisp.h, emacs.c, vm-limit.c
4289 dnl NEWS.18 describes this as "a number which contains
4290 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
4291 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
4292 stored in a Lisp_Object.])
4293 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
4294
4295 case $opsys in
4296   aix*)
4297     dnl This works with 32-bit executables; Emacs doesn't support 64-bit.
4298     AC_DEFINE(DATA_SEG_BITS, [0x20000000])
4299     ;;
4300   hpux*)
4301     dnl The data segment on this machine always starts at address 0x40000000.
4302     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
4303     ;;
4304   irix6-5)
4305     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
4306     ;;
4307 esac
4308
4309
4310 AH_TEMPLATE(TAB3, [Undocumented.])
4311
4312 case $opsys in
4313   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4314
4315   gnu | dragonfly | freebsd | netbsd | openbsd )
4316     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4317     AC_DEFINE(TAB3, OXTABS)
4318     ;;
4319
4320   gnu-linux | gnu-kfreebsd )
4321     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4322 #ifndef __ia64__
4323 # error "not ia64"
4324 #endif
4325       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4326         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4327         [Mark a secondary stack, like the register stack on the ia64.]), [])
4328     ;;
4329
4330   hpux*)
4331     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4332       run_time_remap; for HPUX.])
4333     ;;
4334 esac
4335
4336
4337 dnl This won't be used automatically yet.  We also need to know, at least,
4338 dnl that the stack is continuous.
4339 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4340   registers relevant for conservative garbage collection in the jmp_buf.])
4341
4342
4343 case $opsys in
4344   dnl Not all the architectures are tested, but there are Debian packages
4345   dnl for SCM and/or Guile on them, so the technique must work.  See also
4346   dnl comments in alloc.c concerning setjmp and gcc.
4347   dnl Fixme: it's probably safe to just use the GCC conditional below.
4348   gnu-linux | gnu-kfreebsd )
4349     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4350 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4351   || defined __alpha__ || defined __mips__ || defined __s390__ \
4352   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4353   || defined __ia64__ || defined __sh__
4354 /* ok */
4355 #else
4356 # error "setjmp not known to work on this arch"
4357 #endif
4358     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4359     ;;
4360 esac
4361
4362
4363 if test x$GCC = xyes; then
4364    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4365    AC_DEFINE(GC_SETJMP_WORKS, 1)
4366 else
4367   case $opsys in
4368     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4369     dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4370       AC_DEFINE(GC_SETJMP_WORKS, 1)
4371       ;;
4372   esac
4373 fi                              dnl GCC?
4374
4375 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4376 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4377   [AC_LINK_IFELSE(
4378      [AC_LANG_PROGRAM(
4379        [[#include <setjmp.h>
4380          #ifdef __MINGW32__
4381          # define _longjmp longjmp
4382          #endif
4383        ]],
4384        [[jmp_buf j;
4385          if (! _setjmp (j))
4386            _longjmp (j, 1);]])],
4387      [emacs_cv_func__setjmp=yes],
4388      [emacs_cv_func__setjmp=no])])
4389 if test $emacs_cv_func__setjmp = yes; then
4390   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4391 else
4392   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4393     [AC_LINK_IFELSE(
4394        [AC_LANG_PROGRAM(
4395          [[#include <setjmp.h>
4396          ]],
4397          [[sigjmp_buf j;
4398            if (! sigsetjmp (j, 1))
4399              siglongjmp (j, 1);]])],
4400        [emacs_cv_func_sigsetjmp=yes],
4401        [emacs_cv_func_sigsetjmp=no])])
4402   if test $emacs_cv_func_sigsetjmp = yes; then
4403     AC_DEFINE([HAVE_SIGSETJMP], 1,
4404       [Define to 1 if sigsetjmp and siglongjmp work.
4405        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
4406   fi
4407 fi
4408
4409 case $opsys in
4410   sol2* | unixware )
4411     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4412     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4413     dnl and this is all we need.
4414     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4415     ;;
4416 esac
4417
4418
4419 case $opsys in
4420   hpux* | sol2* )
4421     dnl Used in xfaces.c.
4422     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4423       some systems, where it requires time.h.])
4424     ;;
4425 esac
4426
4427
4428 dnl Define symbols to identify the version of Unix this is.
4429 dnl Define all the symbols that apply correctly.
4430 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4431 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4432 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4433 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4434
4435 case $opsys in
4436   aix4-2)
4437     AC_DEFINE(USG, [])
4438     dnl This symbol should be defined on AIX Version 3  ???????
4439     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4440 #ifndef _AIX
4441 # error "_AIX not defined"
4442 #endif
4443     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4444     ;;
4445
4446   cygwin)
4447     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4448     ;;
4449
4450   darwin)
4451     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4452     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4453     dnl distinguish OS X from pure Darwin.
4454     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4455     ;;
4456
4457   gnu-linux | gnu-kfreebsd )
4458     AC_DEFINE(USG, [])
4459     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4460     ;;
4461
4462   hpux*)
4463     AC_DEFINE(USG, [])
4464     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4465     ;;
4466
4467   irix6-5)
4468     AC_DEFINE(USG, [])
4469     AC_DEFINE(USG5_4, [])
4470     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4471     ;;
4472
4473   mingw32)
4474     AC_DEFINE(DOS_NT, [])
4475     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4476     if test "x$ac_enable_checking" != "x" ; then
4477       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4478     fi
4479     ;;
4480
4481   sol2*)
4482     AC_DEFINE(USG, [])
4483     AC_DEFINE(USG5_4, [])
4484     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4485     ;;
4486
4487   unixware)
4488     AC_DEFINE(USG, [])
4489     AC_DEFINE(USG5_4, [])
4490     ;;
4491 esac
4492
4493 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4494   [case $opsys in
4495      aix4-2)
4496        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4497        emacs_cv_usable_FIONREAD=no
4498        ;;
4499
4500      mingw32)
4501        emacs_cv_usable_FIONREAD=yes
4502        ;;
4503
4504      *)
4505        AC_COMPILE_IFELSE(
4506          [AC_LANG_PROGRAM([[#include <sys/types.h>
4507                             #include <sys/ioctl.h>
4508                             #ifdef USG5_4
4509                             # include <sys/filio.h>
4510                             #endif
4511                           ]],
4512                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4513          [emacs_cv_usable_FIONREAD=yes],
4514          [emacs_cv_usable_FIONREAD=no])
4515        ;;
4516    esac])
4517 if test $emacs_cv_usable_FIONREAD = yes; then
4518   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4519
4520   if test $emacs_broken_SIGIO = no; then
4521     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4522       [AC_COMPILE_IFELSE(
4523          [AC_LANG_PROGRAM([[#include <fcntl.h>
4524                             #include <signal.h>
4525                           ]],
4526                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4527          [emacs_cv_usable_SIGIO=yes],
4528          [emacs_cv_usable_SIGIO=no])],
4529       [emacs_cv_usable_SIGIO=yes],
4530       [emacs_cv_usable_SIGIO=no])
4531     if test $emacs_cv_usable_SIGIO = yes; then
4532       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4533     fi
4534   fi
4535 fi
4536
4537
4538 case $opsys in
4539   dnl Emacs supplies its own malloc, but glib calls posix_memalign,
4540   dnl and on Cygwin prior to version 1.7.24 that becomes the
4541   dnl Cygwin-supplied posix_memalign.  As malloc is not the Cygwin
4542   dnl malloc, the Cygwin posix_memalign always returns ENOSYS.  A
4543   dnl workaround is to set G_SLICE=always-malloc.  This is no longer
4544   dnl needed starting with cygwin-1.7.24, and it is no longer
4545   dnl effective starting with glib-2.36. */
4546   cygwin)
4547     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4548       G_SLICE environment variable to "always-malloc" at startup.])
4549     ;;
4550
4551   hpux11)
4552     dnl It works to open the pty's tty in the parent (Emacs), then
4553     dnl close and reopen it in the child.
4554     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4555       works to open a pty's tty in the parent process, then close and
4556       reopen it in the child.])
4557     ;;
4558
4559   irix6-5)
4560     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4561       use VSUSP instead of VSWTCH.])
4562     ;;
4563
4564   sol2-10)
4565     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4566       on Solaris.])
4567     ;;
4568 esac
4569
4570 # Set up the CFLAGS for real compilation, so we can substitute it.
4571 CFLAGS="$REAL_CFLAGS"
4572 CPPFLAGS="$REAL_CPPFLAGS"
4573
4574 ## Hack to detect a buggy GCC version.
4575 if test "x$GCC" = xyes \
4576    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4577    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4578    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4579    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4580 fi
4581
4582 version=$PACKAGE_VERSION
4583
4584 copyright="Copyright (C) 2014 Free Software Foundation, Inc."
4585 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4586   [Short copyright string for this version of Emacs.])
4587 AC_SUBST(copyright)
4588
4589 ### Specify what sort of things we'll be editing into Makefile and config.h.
4590 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4591 AC_SUBST(version)
4592 AC_SUBST(configuration)
4593 ## Unused?
4594 AC_SUBST(canonical)
4595 AC_SUBST(srcdir)
4596 AC_SUBST(prefix)
4597 AC_SUBST(exec_prefix)
4598 AC_SUBST(bindir)
4599 AC_SUBST(datadir)
4600 AC_SUBST(sharedstatedir)
4601 AC_SUBST(libexecdir)
4602 AC_SUBST(mandir)
4603 AC_SUBST(infodir)
4604 AC_SUBST(lispdir)
4605 AC_SUBST(standardlisppath)
4606 AC_SUBST(locallisppath)
4607 AC_SUBST(lisppath)
4608 AC_SUBST(x_default_search_path)
4609 AC_SUBST(etcdir)
4610 AC_SUBST(archlibdir)
4611 AC_SUBST(etcdocdir)
4612 AC_SUBST(bitmapdir)
4613 AC_SUBST(gamedir)
4614 AC_SUBST(gameuser)
4615 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4616 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4617 ## end of LIBX_BASE, but nothing ever set it.
4618 AC_SUBST(LD_SWITCH_X_SITE)
4619 AC_SUBST(C_SWITCH_X_SITE)
4620 AC_SUBST(GNUSTEP_CFLAGS)
4621 AC_SUBST(CFLAGS)
4622 ## Used in lwlib/Makefile.in.
4623 AC_SUBST(X_TOOLKIT_TYPE)
4624 AC_SUBST(ns_appdir)
4625 AC_SUBST(ns_appbindir)
4626 AC_SUBST(ns_appresdir)
4627 AC_SUBST(ns_appsrc)
4628 AC_SUBST(GNU_OBJC_CFLAGS)
4629 AC_SUBST(OTHER_FILES)
4630
4631 if test -n "${term_header}"; then
4632     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4633         [Define to the header for the built-in window system.])
4634 fi
4635
4636 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4637                    [Define to the canonical Emacs configuration name.])
4638 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4639                    [Define to the options passed to configure.])
4640 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4641   define this to include extra configuration information.])
4642
4643 case $opsys in
4644   mingw32)
4645     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4646     ;;
4647 esac
4648
4649 XMENU_OBJ=
4650 XOBJ=
4651 FONT_OBJ=
4652 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4653   AC_DEFINE(HAVE_X_WINDOWS, 1,
4654             [Define to 1 if you want to use the X window system.])
4655   XMENU_OBJ=xmenu.o
4656   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4657   FONT_OBJ=xfont.o
4658   if test "$HAVE_XFT" = "yes"; then
4659     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4660   elif test "$HAVE_FREETYPE" = "yes"; then
4661     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4662   fi
4663   AC_SUBST(FONT_OBJ)
4664 fi
4665 AC_SUBST(XMENU_OBJ)
4666 AC_SUBST(XOBJ)
4667 AC_SUBST(FONT_OBJ)
4668
4669 WIDGET_OBJ=
4670 MOTIF_LIBW=
4671 if test "${USE_X_TOOLKIT}" != "none" ; then
4672   WIDGET_OBJ=widget.o
4673   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4674   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4675     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4676   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4677     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4678     MOTIF_LIBW=-lXm
4679     case "$opsys" in
4680       gnu-linux)
4681         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4682         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4683         ;;
4684
4685       unixware)
4686         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4687         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4688         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4689         ;;
4690
4691       aix4-2)
4692         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4693         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4694         ;;
4695     esac
4696     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4697   fi
4698 fi
4699 AC_SUBST(WIDGET_OBJ)
4700
4701 TOOLKIT_LIBW=
4702 case "$USE_X_TOOLKIT" in
4703   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4704   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4705   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4706 esac
4707 AC_SUBST(TOOLKIT_LIBW)
4708
4709 if test "${opsys}" != "mingw32"; then
4710   if test "$USE_X_TOOLKIT" = "none"; then
4711     LIBXT_OTHER="\$(LIBXSM)"
4712   else
4713     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4714   fi
4715 fi
4716 AC_SUBST(LIBXT_OTHER)
4717
4718 if test "${HAVE_X11}" = "yes" ; then
4719   AC_DEFINE(HAVE_X11, 1,
4720             [Define to 1 if you want to use version 11 of X windows.])
4721   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4722 else
4723   LIBX_OTHER=
4724 fi
4725 AC_SUBST(LIBX_OTHER)
4726
4727 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4728   LIBXMENU=
4729 elif test "$USE_X_TOOLKIT" = none; then
4730   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4731 else
4732   LIBXMENU='$(lwlibdir)/liblw.a'
4733 fi
4734 AC_SUBST(LIBXMENU)
4735
4736 if test "${GNU_MALLOC}" = "yes" ; then
4737   AC_DEFINE(GNU_MALLOC, 1,
4738             [Define to 1 if you want to use the GNU memory allocator.])
4739 fi
4740
4741 RALLOC_OBJ=
4742 if test "${REL_ALLOC}" = "yes" ; then
4743   AC_DEFINE(REL_ALLOC, 1,
4744             [Define REL_ALLOC if you want to use the relocating allocator for
4745              buffer space.])
4746
4747   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4748 fi
4749 AC_SUBST(RALLOC_OBJ)
4750
4751 if test "$opsys" = "cygwin"; then
4752   CYGWIN_OBJ="sheap.o cygw32.o"
4753   ## Cygwin differs because of its unexec().
4754   PRE_ALLOC_OBJ=
4755   POST_ALLOC_OBJ=lastfile.o
4756 elif test "$opsys" = "mingw32"; then
4757   CYGWIN_OBJ=
4758   PRE_ALLOC_OBJ=
4759   POST_ALLOC_OBJ=lastfile.o
4760 else
4761   CYGWIN_OBJ=
4762   PRE_ALLOC_OBJ=lastfile.o
4763   POST_ALLOC_OBJ=
4764 fi
4765 AC_SUBST(CYGWIN_OBJ)
4766 AC_SUBST(PRE_ALLOC_OBJ)
4767 AC_SUBST(POST_ALLOC_OBJ)
4768
4769 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4770 dnl verbatim defined above.  The tricky name is apropos, as this hack
4771 dnl makes Fortify go sour!
4772 AH_VERBATIM([FORTIFY_SOUR],
4773 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4774    The workaround disables some useful run-time checking, so it
4775    should be conditional to the platforms with the performance bug.
4776    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4777 #if defined __APPLE__ && defined __GNUC__
4778 # ifndef _DONT_USE_CTYPE_INLINE_
4779 #  define _DONT_USE_CTYPE_INLINE_
4780 # endif
4781 # ifndef _FORTIFY_SOURCE
4782 #  define _FORTIFY_SOURCE 0
4783 # endif
4784 #endif
4785 ])
4786
4787 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4788 # it temporarily reverts them to their pre-pkg-config values,
4789 # because gnulib needs to work with both src (which uses the
4790 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4791 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4792 # and it therefore needs to run in an environment where LIBS does not
4793 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4794 # for some package unrelated to lib-src.
4795 SAVE_CFLAGS=$CFLAGS
4796 SAVE_LIBS=$LIBS
4797 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4798 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4799 gl_ASSERT_NO_GNULIB_POSIXCHECK
4800 gl_ASSERT_NO_GNULIB_TESTS
4801 gl_INIT
4802 CFLAGS=$SAVE_CFLAGS
4803 LIBS=$SAVE_LIBS
4804
4805 if test "${opsys}" = "mingw32"; then
4806   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4807   # Remove unneeded switches from the value of CC that goes to Makefiles
4808   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4809 fi
4810
4811 case "$opsys" in
4812   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4813
4814   darwin)
4815    ## The -headerpad option tells ld (see man page) to leave room at the
4816    ## end of the header for adding load commands.  Needed for dumping.
4817    ## 0x690 is the total size of 30 segment load commands (at 56
4818    ## each); under Cocoa 31 commands are required.
4819    if test "$HAVE_NS" = "yes"; then
4820      libs_nsgui="-framework AppKit"
4821      if test "$NS_IMPL_COCOA" = "yes"; then
4822         libs_nsgui="$libs_nsgui -framework IOKit"
4823      fi
4824      headerpad_extra=6C8
4825    else
4826      libs_nsgui=
4827      headerpad_extra=690
4828    fi
4829    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4830
4831    ## This is here because src/Makefile.in did some extra fiddling around
4832    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4833    ## LD_SWITCH_SYSTEM_TEMACS instead,
4834    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4835      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4836    ;;
4837
4838   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4839   ## find X at run-time.
4840   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4841   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4842   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4843   ## had different values in configure (in ac_link) and src/Makefile.in.
4844   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4845   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4846
4847   mingw32)
4848    ## MinGW64 does not prepend an underscore to symbols, so we must
4849    ## pass a different -entry switch to linker.  FIXME: It is better
4850    ## to make the entry points the same by changing unexw32.c.
4851    case "$canonical" in
4852      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4853      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4854    esac
4855    ;;
4856
4857   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4858
4859   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4860 esac
4861
4862 if test x$ac_enable_profiling != x ; then
4863   case $opsys in
4864     *freebsd | gnu-linux) ;;
4865     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4866   esac
4867 fi
4868
4869 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
4870
4871 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4872
4873 ## MinGW-specific post-link processing of temacs.
4874 TEMACS_POST_LINK=":"
4875 ADDSECTION=
4876 EMACS_HEAPSIZE=
4877 if test "${opsys}" = "mingw32"; then
4878   TEMACS_POST_LINK="\$(MINGW_TEMACS_POST_LINK)"
4879   ADDSECTION="../nt/addsection\$(EXEEXT)"
4880   ## Preload heap size of temacs.exe in MB.
4881   case "$canonical" in
4882     x86_64-*-*) EMACS_HEAPSIZE=42 ;;
4883     *) EMACS_HEAPSIZE=27 ;;
4884   esac
4885 fi
4886
4887 AC_SUBST(ADDSECTION)
4888 AC_SUBST(TEMACS_POST_LINK)
4889 AC_SUBST(EMACS_HEAPSIZE)
4890
4891 ## Common for all window systems
4892 if test "$window_system" != "none"; then
4893   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4894   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4895 fi
4896
4897 AC_SUBST(WINDOW_SYSTEM_OBJ)
4898
4899 AH_TOP([/* GNU Emacs site configuration template file.
4900
4901 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2014
4902   Free Software Foundation, Inc.
4903
4904 This file is part of GNU Emacs.
4905
4906 GNU Emacs is free software: you can redistribute it and/or modify
4907 it under the terms of the GNU General Public License as published by
4908 the Free Software Foundation, either version 3 of the License, or
4909 (at your option) any later version.
4910
4911 GNU Emacs is distributed in the hope that it will be useful,
4912 but WITHOUT ANY WARRANTY; without even the implied warranty of
4913 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4914 GNU General Public License for more details.
4915
4916 You should have received a copy of the GNU General Public License
4917 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4918
4919
4920 /* No code in Emacs #includes config.h twice, but some bits of code
4921    intended to work with other packages as well (like gmalloc.c)
4922    think they can include it as many times as they like.  */
4923 #ifndef EMACS_CONFIG_H
4924 #define EMACS_CONFIG_H
4925 ])dnl
4926
4927 AH_BOTTOM([#include <conf_post.h>
4928
4929 #endif /* EMACS_CONFIG_H */
4930
4931 /*
4932 Local Variables:
4933 mode: c
4934 End:
4935 */
4936 ])dnl
4937
4938 #### Report on what we decided to do.
4939 #### Report GTK as a toolkit, even if it doesn't use Xt.
4940 #### It makes printing result more understandable as using GTK sets
4941 #### toolkit_scroll_bars to yes by default.
4942 if test "${HAVE_GTK}" = "yes"; then
4943   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4944 fi
4945
4946 if test $USE_ACL -ne 0; then
4947   acl_summary="yes $LIB_ACL"
4948 else
4949   acl_summary=no
4950 fi
4951
4952 echo "
4953 Configured for \`${canonical}'.
4954
4955   Where should the build process find the source code?    ${srcdir}
4956   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4957   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4958   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4959   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4960   What window system should Emacs use?                    ${window_system}
4961   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4962
4963 if test -n "${x_includes}"; then
4964 echo "  Where do we find X Windows header files?                ${x_includes}"
4965 else
4966 echo "  Where do we find X Windows header files?                Standard dirs"
4967 fi
4968 if test -n "${x_libraries}"; then
4969 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4970 else
4971 echo "  Where do we find X Windows libraries?                   Standard dirs"
4972 fi
4973
4974 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4975 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4976 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4977 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4978 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4979 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4980 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4981 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4982
4983 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
4984
4985 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4986 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4987 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4988 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4989 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
4990 echo "  Does Emacs use access control lists?                    ${acl_summary}"
4991 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4992 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4993 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4994
4995 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4996 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4997 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4998 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4999 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
5000
5001 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
5002 echo
5003
5004 if test -n "${EMACSDATA}"; then
5005    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
5006 fi
5007 if test -n "${EMACSDOC}"; then
5008    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
5009 fi
5010
5011 echo
5012
5013 if test "$HAVE_NS" = "yes"; then
5014    echo
5015    echo "You must run \"${MAKE-make} install\" in order to test the built application.
5016 The installed application will go to nextstep/Emacs.app and can be
5017 run or moved from there."
5018    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5019       echo "The application will be fully self-contained."
5020     else
5021       echo "The lisp resources for the application will be installed under ${prefix}.
5022 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5023 to run if these resources are not installed."
5024    fi
5025    echo
5026 fi
5027
5028 if test "${opsys}" = "cygwin"; then
5029   case `uname -r` in
5030     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5031            echo
5032            ;;
5033   esac
5034 fi
5035
5036 # Remove any trailing slashes in these variables.
5037 [test "${prefix}" != NONE &&
5038   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5039 test "${exec_prefix}" != NONE &&
5040   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5041
5042 if test "$HAVE_NS" = "yes"; then
5043   if test "$NS_IMPL_GNUSTEP" = yes; then
5044     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5045       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5046     ns_check_file=Resources/Info-gnustep.plist
5047   else
5048     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5049       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5050     ns_check_file=Contents/Info.plist
5051   fi
5052   AC_SUBST(ns_check_file)
5053 fi
5054
5055 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5056 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5057 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5058 dnl (else you get "no `Makefile.am' found for any configure output").
5059 dnl This will work, but you get a config.status that is not quite right
5060 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5061 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5062 dnl it seems better to just live with the duplication.
5063 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5064
5065 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5066        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5067        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5068        leim/Makefile nextstep/Makefile nt/Makefile])
5069
5070 dnl test/ is not present in release tarfiles.
5071 opt_makefile=test/automated/Makefile
5072
5073 if test -f "$srcdir/$opt_makefile.in"; then
5074   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5075   dnl Again, it's best not to use a variable.  Though you can add
5076   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5077   AC_CONFIG_FILES([test/automated/Makefile])
5078 fi
5079
5080
5081 dnl The admin/ directory used to be excluded from tarfiles.
5082 if test -d $srcdir/admin; then
5083   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5084   AC_CONFIG_FILES([admin/unidata/Makefile])
5085   AC_CONFIG_FILES([admin/grammars/Makefile])
5086 fi                              dnl -d admin
5087
5088
5089 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5090
5091 AC_SUBST(SUBDIR_MAKEFILES_IN)
5092
5093 dnl You might wonder (I did) why epaths.h is generated by running make,
5094 dnl rather than just letting configure generate it from epaths.in.
5095 dnl One reason is that the various paths are not fully expanded (see above);
5096 dnl eg gamedir=${prefix}/var/games/emacs.
5097 dnl Secondly, the GNU Coding standards require that one should be able
5098 dnl to run `make prefix=/some/where/else' and override the values set
5099 dnl by configure.  This also explains the `move-if-change' test and
5100 dnl the use of force in the `epaths-force' rule in Makefile.in.
5101 AC_CONFIG_COMMANDS([src/epaths.h], [
5102 if test "${opsys}" = "mingw32"; then
5103   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5104 else
5105   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5106 fi
5107 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5108
5109 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5110 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5111 dnl or a symlink?
5112 AC_CONFIG_COMMANDS([src/.gdbinit], [
5113 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5114   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5115 fi
5116 ])
5117
5118 AC_OUTPUT