configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 dnl _ON results in a '--without' option in the --help output, so
 151 dnl the help text should refer to "don't compile", etc.
 152 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 153 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 154 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 155 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 156 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 157 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 158
 159 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 160 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 161 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 162
 163 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 164 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 165 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 166 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 167
 168 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 169 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 170 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 171 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH([gnustep-conf],dnl
 204 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 205 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 206   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 207 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 208      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 209
 210 AC_ARG_ENABLE(ns-self-contained,
 211 [AS_HELP_STRING([--disable-ns-self-contained],
 212                 [disable self contained build under NeXTstep])],
 213    EN_NS_SELF_CONTAINED=$enableval,
 214    EN_NS_SELF_CONTAINED=yes)
 215
 216 AC_ARG_ENABLE(asserts,
 217 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 218       USE_XASSERTS=$enableval,
 219       USE_XASSERTS=no)
 220
 221 AC_ARG_ENABLE(maintainer-mode,
 222 [AS_HELP_STRING([--enable-maintainer-mode],
 223                 [enable make rules and dependencies not useful (and sometimes
 224                  confusing) to the casual installer])],
 225       USE_MAINTAINER_MODE=$enableval,
 226       USE_MAINTAINER_MODE=no)
 227 if test $USE_MAINTAINER_MODE = yes; then
 228   MAINT=
 229 else
 230   MAINT=#
 231 fi
 232 AC_SUBST(MAINT)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;;
 264         all)            ac_enable_checking=1 ;
 265                         ac_gc_check_stringbytes=1 ;
 266                         ac_gc_check_string_overrun=1 ;
 267                         ac_gc_check_string_free_list=1 ;
 268                         ac_xmalloc_overrun=1 ;
 269                         ac_gc_check_cons_list=1 ;;
 270         # these enable particular checks
 271         stringbytes)    ac_gc_check_stringbytes=1 ;;
 272         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 273         stringfreelist) ac_gc_check_string_free_list=1 ;;
 274         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 275         conslist)       ac_gc_check_cons_list=1 ;;
 276         *)      AC_MSG_ERROR(unknown check category $check) ;;
 277         esac
 278 done
 279 IFS="$ac_save_IFS"
 280
 281 if test x$ac_enable_checking != x ; then
 282   AC_DEFINE(ENABLE_CHECKING, 1,
 283 [Enable expensive run-time checking of data types?])
 284 fi
 285 if test x$ac_gc_check_stringbytes != x ; then
 286   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 287 [Define this temporarily to hunt a bug.  If defined, the size of
 288    strings is redundantly recorded in sdata structures so that it can
 289    be compared to the sizes recorded in Lisp strings.])
 290 fi
 291 if test x$ac_gc_check_stringoverrun != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 293 [Define this to check for short string overrun.])
 294 fi
 295 if test x$ac_gc_check_string_free_list != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 297 [Define this to check the string free list.])
 298 fi
 299 if test x$ac_xmalloc_overrun != x ; then
 300   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 301 [Define this to check for malloc buffer overrun.])
 302 fi
 303 if test x$ac_gc_check_cons_list != x ; then
 304   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 305 [Define this to check for errors in cons list.])
 306 fi
 307
 308 AC_ARG_ENABLE(use-lisp-union-type,
 309 [AS_HELP_STRING([--enable-use-lisp-union-type],
 310                 [use a union for the Lisp_Object data type.
 311                 This is only useful for development for catching certain types of bugs.])],
 312 if test "${enableval}" != "no"; then
 313    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 314    [Define this to use a lisp union for the Lisp_Object data type.])
 315 fi)
 316
 317
 318 AC_ARG_ENABLE(profiling,
 319 [AS_HELP_STRING([--enable-profiling],
 320                 [build emacs with profiling support.
 321                  This might not work on all platforms])],
 322 [ac_enable_profiling="${enableval}"],[])
 323 if test x$ac_enable_profiling != x ; then
 324    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 325    PROFILING_LDFLAGS="-pg"
 326 else
 327    PROFILING_CFLAGS=
 328    PROFILING_LDFLAGS=
 329 fi
 330 AC_SUBST(PROFILING_CFLAGS)
 331 AC_SUBST(PROFILING_LDFLAGS)
 332
 333 AC_ARG_ENABLE(autodepend,
 334 [AS_HELP_STRING([--enable-autodepend],
 335                 [automatically generate dependencies to .h-files.
 336                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 337                  found])],
 338 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 339
 340 #### Make srcdir absolute, if it isn't already.  It's important to
 341 #### avoid running the path through pwd unnecessarily, since pwd can
 342 #### give you automounter prefixes, which can go away.  We do all this
 343 #### so Emacs can find its files when run uninstalled.
 344 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 345 unset CDPATH
 346 case "${srcdir}" in
 347   /* ) ;;
 348   . )
 349     ## We may be able to use the $PWD environment variable to make this
 350     ## absolute.  But sometimes PWD is inaccurate.
 351     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 352     ## but that tested only for a well-formed and valid PWD,
 353     ## it did not object when PWD was well-formed and valid but just wrong.
 354     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 355     then
 356       srcdir="$PWD"
 357     else
 358       srcdir="`(cd ${srcdir}; pwd)`"
 359     fi
 360   ;;
 361   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 362 esac
 363
 364 #### Check if the source directory already has a configured system in it.
 365 if test `pwd` != `(cd ${srcdir} && pwd)` \
 366    && test -f "${srcdir}/src/config.h" ; then
 367   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 368    as a build directory right now; it has been configured in its own
 369    right.  To configure in another directory as well, you MUST
 370    use GNU make.  If you do not have GNU make, then you must
 371    now do `make distclean' in ${srcdir},
 372    and then run $0 again.]])
 373 fi
 374
 375 #### Given the configuration name, set machfile and opsysfile to the
 376 #### names of the m/*.h and s/*.h files we should use.
 377
 378 ### Canonicalize the configuration name.
 379
 380 AC_CANONICAL_HOST
 381 canonical=$host
 382 configuration=${host_alias-${build_alias-$host}}
 383
 384 dnl This used to use changequote, but, apart from `changequote is evil'
 385 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 386 dnl the great gob of text.  Thus it's not processed for possible expansion.
 387 dnl Just make sure the brackets remain balanced.
 388 dnl
 389 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 390 dnl indicated by comments.
 391 dnl quotation begins
 392 [
 393
 394 ### If you add support for a new configuration, add code to this
 395 ### switch statement to recognize your configuration name and select
 396 ### the appropriate operating system and machine description files.
 397
 398 ### You would hope that you could choose an m/*.h file pretty much
 399 ### based on the machine portion of the configuration name, and an s/*.h
 400 ### file based on the operating system portion.  However, it turns out
 401 ### that each m/*.h file is pretty manufacturer-specific - for
 402 ### example mips.h is MIPS
 403 ### So we basically have to have a special case for each
 404 ### configuration name.
 405 ###
 406 ### As far as handling version numbers on operating systems is
 407 ### concerned, make sure things will fail in a fixable way.  If
 408 ### /etc/MACHINES doesn't say anything about version numbers, be
 409 ### prepared to handle anything reasonably.  If version numbers
 410 ### matter, be sure /etc/MACHINES says something about it.
 411
 412 machine='' opsys='' unported=no
 413 case "${canonical}" in
 414
 415   ## FreeBSD ports
 416   *-*-freebsd* )
 417     opsys=freebsd
 418     case "${canonical}" in
 419       alpha*)           machine=alpha ;;
 420       amd64-*|x86_64-*) machine=amdx86-64 ;;
 421       arm*)             machine=arm ;;
 422       ia64-*)           machine=ia64 ;;
 423       i[3456]86-*)      machine=intel386 ;;
 424       powerpc-*)        machine=macppc ;;
 425       sparc-*)          machine=sparc ;;
 426       sparc64-*)        machine=sparc ;;
 427     esac
 428   ;;
 429
 430   ## FreeBSD kernel + glibc based userland
 431   *-*-kfreebsd*gnu* )
 432     opsys=gnu-kfreebsd
 433     case "${canonical}" in
 434       alpha*)           machine=alpha ;;
 435       amd64-*|x86_64-*) machine=amdx86-64 ;;
 436       ia64-*)           machine=ia64 ;;
 437       i[3456]86-*)      machine=intel386 ;;
 438       powerpc-*)        machine=macppc ;;
 439       sparc-*)          machine=sparc ;;
 440       sparc64-*)        machine=sparc ;;
 441     esac
 442   ;;
 443
 444   ## NetBSD ports
 445   *-*-netbsd* )
 446     opsys=netbsd
 447     case "${canonical}" in
 448       alpha*)      machine=alpha ;;
 449       x86_64-*)    machine=amdx86-64 ;;
 450       arm-*)       machine=arm ;;
 451       hppa-*)      machine=hp800 ;;
 452       i[3456]86-*) machine=intel386 ;;
 453       m68k-*)      machine=m68k ;;
 454       powerpc-*)   machine=macppc ;;
 455       mips-*)      machine=mips ;;
 456       mipse[bl]-*) machine=mips ;;
 457       sparc*-)     machine=sparc ;;
 458       vax-*)       machine=vax ;;
 459     esac
 460   ;;
 461
 462   ## OpenBSD ports
 463   *-*-openbsd* )
 464     opsys=openbsd
 465     case "${canonical}" in
 466       alpha*)    machine=alpha ;;
 467       x86_64-*)  machine=amdx86-64 ;;
 468       arm-*)     machine=arm ;;
 469       hppa-*)    machine=hp800 ;;
 470       i386-*)    machine=intel386 ;;
 471       powerpc-*) machine=macppc ;;
 472       sparc*)    machine=sparc ;;
 473       vax-*)     machine=vax ;;
 474     esac
 475   ;;
 476
 477   alpha*-*-linux-gnu* )
 478     machine=alpha opsys=gnu-linux
 479   ;;
 480
 481   arm*-*-linux-gnu* )
 482     machine=arm opsys=gnu-linux
 483   ;;
 484
 485   ## Apple Darwin / Mac OS X
 486   *-apple-darwin* )
 487     case "${canonical}" in
 488       i[3456]86-* )  machine=intel386 ;;
 489       powerpc-* )    machine=macppc ;;
 490       x86_64-* )     machine=amdx86-64 ;;
 491       * )            unported=yes ;;
 492     esac
 493     opsys=darwin
 494     # Define CPP as follows to make autoconf work correctly.
 495     CPP="${CC-cc} -E -no-cpp-precomp"
 496     # Use fink packages if available.
 497     if test -d /sw/include && test -d /sw/lib; then
 498       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 499       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 500       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 501     fi
 502   ;;
 503
 504   ## HP 9000 series 700 and 800, running HP/UX
 505   hppa*-hp-hpux10.2* )
 506     machine=hp800 opsys=hpux10-20
 507   ;;
 508   hppa*-hp-hpux1[1-9]* )
 509     machine=hp800 opsys=hpux11
 510     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 511   ;;
 512
 513   hppa*-*-linux-gnu* )
 514     machine=hp800 opsys=gnu-linux
 515   ;;
 516
 517   ## IBM machines
 518   s390-*-linux-gnu* )
 519     machine=ibms390 opsys=gnu-linux
 520   ;;
 521   s390x-*-linux-gnu* )
 522     machine=ibms390x opsys=gnu-linux
 523   ;;
 524   rs6000-ibm-aix4.[23]* )
 525     machine=ibmrs6000 opsys=aix4-2
 526   ;;
 527   powerpc-ibm-aix4.[23]*  )
 528     machine=ibmrs6000 opsys=aix4-2
 529   ;;
 530   rs6000-ibm-aix[56]* )
 531     machine=ibmrs6000 opsys=aix4-2
 532   ;;
 533   powerpc-ibm-aix[56]*  )
 534     machine=ibmrs6000 opsys=aix4-2
 535   ;;
 536
 537   ## Macintosh PowerPC
 538   powerpc*-*-linux-gnu* )
 539     machine=macppc opsys=gnu-linux
 540   ;;
 541
 542   ## Silicon Graphics machines
 543   ## Iris 4D
 544   mips-sgi-irix6.5 )
 545     machine=iris4d opsys=irix6-5
 546     # Without defining _LANGUAGE_C, things get masked out in the headers
 547     # so that, for instance, grepping for `free' in stdlib.h fails and
 548     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 549     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 550     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 551   ;;
 552
 553   ## Suns
 554   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 555     machine=sparc opsys=gnu-linux
 556   ;;
 557
 558   *-sun-solaris* \
 559     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 560     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 561     case "${canonical}" in
 562       i[3456]86-*-* )     machine=intel386 ;;
 563       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 564       sparc* )          machine=sparc ;;
 565       * )               unported=yes ;;
 566     esac
 567     case "${canonical}" in
 568       *-sunos5.6* | *-solaris2.6* )
 569                 opsys=sol2-6
 570                 NON_GNU_CPP=/usr/ccs/lib/cpp
 571                 RANLIB="ar -ts"
 572                 ;;
 573       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 574                 opsys=sol2-6
 575                 emacs_check_sunpro_c=yes
 576                 NON_GNU_CPP=/usr/ccs/lib/cpp
 577                 ;;
 578       *-sunos5* | *-solaris* )
 579                 opsys=sol2-10
 580                 emacs_check_sunpro_c=yes
 581                 NON_GNU_CPP=/usr/ccs/lib/cpp
 582                 ;;
 583     esac
 584     ## Watch out for a compiler that we know will not work.
 585     case "${canonical}" in
 586      *-solaris* | *-sunos5* )
 587                 if [ "x$CC" = x/usr/ucb/cc ]; then
 588                   ## /usr/ucb/cc doesn't work;
 589                   ## we should find some other compiler that does work.
 590                   unset CC
 591                 fi
 592                 ;;
 593       *) ;;
 594     esac
 595   ;;
 596
 597   ## IA-64
 598   ia64*-*-linux* )
 599     machine=ia64 opsys=gnu-linux
 600   ;;
 601
 602   ## Intel 386 machines where we don't care about the manufacturer.
 603   i[3456]86-*-* )
 604     machine=intel386
 605     case "${canonical}" in
 606       *-cygwin )                opsys=cygwin ;;
 607       *-darwin* )               opsys=darwin
 608                                 CPP="${CC-cc} -E -no-cpp-precomp"
 609                                 ;;
 610       *-linux-gnu* )            opsys=gnu-linux ;;
 611       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 612       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 613       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 614       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 615     esac
 616   ;;
 617
 618   ## m68k Linux-based GNU system
 619   m68k-*-linux-gnu* )
 620     machine=m68k opsys=gnu-linux
 621   ;;
 622
 623   ## Mips Linux-based GNU system
 624   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 625     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 626     machine=mips opsys=gnu-linux
 627   ;;
 628
 629   ## AMD x86-64 Linux-based GNU system
 630   x86_64-*-linux-gnu* )
 631     machine=amdx86-64 opsys=gnu-linux
 632   ;;
 633
 634   ## Tensilica Xtensa Linux-based GNU system
 635   xtensa*-*-linux-gnu* )
 636     machine=xtensa opsys=gnu-linux
 637     ;;
 638
 639   ## SuperH Linux-based GNU system
 640   sh[34]*-*-linux-gnu* )
 641     machine=sh3 opsys=gnu-linux
 642   ;;
 643
 644   * )
 645     unported=yes
 646   ;;
 647 esac
 648
 649 ### If the code above didn't choose an operating system, just choose
 650 ### an operating system based on the configuration name.  You really
 651 ### only want to use this when you have no idea what the right
 652 ### operating system is; if you know what operating systems a machine
 653 ### runs, it's cleaner to make it explicit in the case statement
 654 ### above.
 655 if test x"${opsys}" = x; then
 656   case "${canonical}" in
 657     *-gnu* )                            opsys=gnu ;;
 658     * )
 659       unported=yes
 660     ;;
 661   esac
 662 fi
 663
 664 ]
 665 dnl quotation ends
 666
 667 if test $unported = yes; then
 668   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 669 Check `etc/MACHINES' for recognized configuration names.])
 670 fi
 671
 672 machfile="m/${machine}.h"
 673 opsysfile="s/${opsys}.h"
 674
 675
 676 #### Choose a compiler.
 677 test -n "$CC" && cc_specified=yes
 678
 679 # Save the value of CFLAGS that the user specified.
 680 SPECIFIED_CFLAGS="$CFLAGS"
 681
 682 dnl Sets GCC=yes if using gcc.
 683 AC_PROG_CC
 684
 685 # On Suns, sometimes $CPP names a directory.
 686 if test -n "$CPP" && test -d "$CPP"; then
 687   CPP=
 688 fi
 689
 690 ## If not using gcc, and on Solaris, and no CPP specified, see if
 691 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 692 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 693  test x"$CPP" = x; then
 694   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 695   AC_CACHE_VAL(emacs_cv_sunpro_c,
 696   [AC_TRY_LINK([],
 697 [#ifndef __SUNPRO_C
 698 fail;
 699 #endif
 700 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 701   AC_MSG_RESULT($emacs_cv_sunpro_c)
 702
 703   if test x"$emacs_cv_sunpro_c" = xyes; then
 704     NON_GNU_CPP="$CC -E -Xs"
 705   fi
 706 fi
 707
 708 #### Some systems specify a CPP to use unless we are using GCC.
 709 #### Now that we know whether we are using GCC, we can decide whether
 710 #### to use that one.
 711 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 712 then
 713   CPP="$NON_GNU_CPP"
 714 fi
 715
 716 #### Some systems specify a CC to use unless we are using GCC.
 717 #### Now that we know whether we are using GCC, we can decide whether
 718 #### to use that one.
 719 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 720   test x$cc_specified != xyes
 721 then
 722   CC="$NON_GNU_CC"
 723 fi
 724
 725 dnl checks for Unix variants
 726 AC_USE_SYSTEM_EXTENSIONS
 727
 728 ### Use -Wno-pointer-sign if the compiler supports it
 729 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 730 SAVE_CFLAGS="$CFLAGS"
 731 CFLAGS="$CFLAGS -Wno-pointer-sign"
 732 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 733 if test $has_option = yes; then
 734    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 735 fi
 736 AC_MSG_RESULT($has_option)
 737 CFLAGS="$SAVE_CFLAGS"
 738 unset has_option
 739 unset SAVE_CFLAGS
 740
 741 ### Use -Wdeclaration-after-statement if the compiler supports it
 742 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 743 SAVE_CFLAGS="$CFLAGS"
 744 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 745 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 746 if test $has_option = yes; then
 747    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 748 fi
 749 AC_MSG_RESULT($has_option)
 750 CFLAGS="$SAVE_CFLAGS"
 751 unset has_option
 752 unset SAVE_CFLAGS
 753
 754 ### Use -Wold-style-definition if the compiler supports it
 755 # This can be removed when conversion to standard C is finished.
 756 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 757 SAVE_CFLAGS="$CFLAGS"
 758 CFLAGS="$CFLAGS -Wold-style-definition"
 759 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 760 if test $has_option = yes; then
 761    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 762 fi
 763 AC_MSG_RESULT($has_option)
 764 CFLAGS="$SAVE_CFLAGS"
 765 unset has_option
 766 unset SAVE_CFLAGS
 767 AC_SUBST(C_WARNINGS_SWITCH)
 768
 769
 770 #### Some other nice autoconf tests.
 771
 772 dnl checks for programs
 773 AC_PROG_CPP
 774 AC_PROG_INSTALL
 775 if test "x$RANLIB" = x; then
 776   AC_PROG_RANLIB
 777 fi
 778
 779 ## Although we're running on an amd64 kernel, we're actually compiling for
 780 ## the x86 architecture.  The user should probably have provided an
 781 ## explicit --build to `configure', but if everything else than the kernel
 782 ## is running in i386 mode, we can help them out.
 783 if test "$machine" = "amdx86-64"; then
 784   AC_CHECK_DECL([i386])
 785   if test "$ac_cv_have_decl_i386" = "yes"; then
 786     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 787     machine=intel386
 788     machfile="m/${machine}.h"
 789   fi
 790 fi
 791
 792 AC_PATH_PROG(INSTALL_INFO, install-info)
 793 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 794 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 795 dnl Don't use GZIP, which is used by gzip for additional parameters.
 796 AC_PATH_PROG(GZIP_PROG, gzip)
 797
 798
 799 ## Need makeinfo >= 4.6 (?) to build the manuals.
 800 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 801 dnl By this stage, configure has already checked for egrep and set EGREP,
 802 dnl or exited with an error if no egrep was found.
 803 if test "$MAKEINFO" != "no" && \
 804   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 805    MAKEINFO=no
 806 fi
 807
 808 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 809 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 810 ## therefore in the category of "special tools" not normally required, which
 811 ## configure does not have to check for (eg autoconf itself).
 812 ## In a Bazaar checkout on the other hand, the manuals are not included.
 813 ## So makeinfo is a requirement to build from Bazaar, and configure
 814 ## should test for it as it does for any other build requirement.
 815 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 816 ## with pre-built manuals, from a Bazaar checkout.
 817 if test "$MAKEINFO" = "no"; then
 818   if test "x${with_makeinfo}" = "xno"; then
 819     MAKEINFO=off
 820   elif test ! -e $srcdir/info/emacs; then
 821     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 822 source tree does not seem to have pre-built manuals in the `info' directory.
 823 Either install a suitable version of makeinfo, or re-run configure
 824 with the `--without-makeinfo' option to build without the manuals.] )
 825   fi
 826 fi
 827
 828 dnl Add our options to ac_link now, after it is set up.
 829
 830 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 831 then
 832   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 833 fi
 834
 835 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 836 then
 837   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 838 fi
 839
 840 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 841 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 842 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 843 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 844 dnl if not built to support GNU ld.
 845
 846 late_LDFLAGS=$LDFLAGS
 847 if test "$GCC" = yes; then
 848   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 849 else
 850   LDFLAGS="$LDFLAGS -znocombreloc"
 851 fi
 852
 853 AC_MSG_CHECKING([for -znocombreloc])
 854 AC_LINK_IFELSE([main(){return 0;}],
 855   [AC_MSG_RESULT(yes)],
 856   LDFLAGS=$late_LDFLAGS
 857   [AC_MSG_RESULT(no)])
 858
 859
 860 # The value of CPP is a quoted variable reference, so we need to do this
 861 # to get its actual value...
 862 CPP=`eval "echo $CPP"`
 863
 864
 865 dnl Not used by any currently supported platform.
 866 dnl The function dump-emacs will not be defined and temacs will do
 867 dnl (load "loadup") automatically unless told otherwise.
 868 CANNOT_DUMP=no
 869 case "$opsys" in
 870   your-opsys-here)
 871    CANNOT_DUMP=yes
 872    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 873   ;;
 874 esac
 875 AC_SUBST(CANNOT_DUMP)
 876
 877
 878 UNEXEC_OBJ=unexelf.o
 879 case "$opsys" in
 880   # MSDOS uses unexec.o
 881   # MSWindows uses unexw32.o
 882   aix4-2)
 883    UNEXEC_OBJ=unexaix.o
 884    ;;
 885   cygwin)
 886    UNEXEC_OBJ=unexcw.o
 887    ;;
 888   darwin)
 889    UNEXEC_OBJ=unexmacosx.o
 890    ;;
 891   hpux10-20 | hpux11)
 892    UNEXEC_OBJ=unexhp9k800.o
 893    ;;
 894   sol2-10)
 895    # Use the Solaris dldump() function, called from unexsol.c, to dump
 896    # emacs, instead of the generic ELF dump code found in unexelf.c.
 897    # The resulting binary has a complete symbol table, and is better
 898    # for debugging and other observability tools (debuggers, pstack, etc).
 899    #
 900    # If you encounter a problem using dldump(), please consider sending
 901    # a message to the OpenSolaris tools-linking mailing list:
 902    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 903    #
 904    # It is likely that dldump() works with older Solaris too, but this has
 905    # not been tested, so for now this change is for Solaris 10 or newer.
 906    UNEXEC_OBJ=unexsol.o
 907    ;;
 908 esac
 909
 910 LD_SWITCH_SYSTEM=
 911 case "$opsys" in
 912   freebsd)
 913    ## Let `ld' find image libs and similar things in /usr/local/lib.
 914    ## The system compiler, GCC, has apparently been modified to not
 915    ## look there, contrary to what a stock GCC would do.
 916    LD_SWITCH_SYSTEM=-L/usr/local/lib
 917    ;;
 918
 919   gnu-linux)
 920    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 921    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 922    ;;
 923
 924   netbsd)
 925    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 926    ;;
 927
 928   openbsd)
 929    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 930    ## otherwise Emacs dumps core on elf systems.
 931    LD_SWITCH_SYSTEM="-Z"
 932    ;;
 933 esac
 934 AC_SUBST(LD_SWITCH_SYSTEM)
 935
 936 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 937
 938 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 939 ## which has not been defined yet.  When this was handled with cpp,
 940 ## it was expanded to null when configure sourced the s/*.h file.
 941 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 942 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 943 ## (or somesuch), but because it is supposed to go at the _front_
 944 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 945 ## Compare with the gnu-linux case below, which added to the end
 946 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 947 ## LD_SWITCH_SYSTEM_TEMACS.
 948 case "$opsys" in
 949   netbsd|openbsd)
 950    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 951    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 952 esac
 953
 954
 955 C_SWITCH_MACHINE=
 956 if test "$machine" = "alpha"; then
 957   AC_CHECK_DECL([__ELF__])
 958   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 959     ## With ELF, make sure that all common symbols get allocated to in the
 960     ## data section.  Otherwise, the dump of temacs may miss variables in
 961     ## the shared library that have been initialized.  For example, with
 962     ## GNU libc, __malloc_initialized would normally be resolved to the
 963     ## shared library's .bss section, which is fatal.
 964     if test "x$GCC" = "xyes"; then
 965       C_SWITCH_MACHINE="-fno-common"
 966     else
 967       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 968     fi
 969   else
 970     UNEXEC_OBJ=unexalpha.o
 971   fi
 972 fi
 973 AC_SUBST(C_SWITCH_MACHINE)
 974
 975 AC_SUBST(UNEXEC_OBJ)
 976
 977 C_SWITCH_SYSTEM=
 978 ## Some programs in src produce warnings saying certain subprograms
 979 ## are too complex and need a MAXMEM value greater than 2000 for
 980 ## additional optimization.  --nils@exp-math.uni-essen.de
 981 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 982   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 983 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 984 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 985 AC_SUBST(C_SWITCH_SYSTEM)
 986
 987
 988 LIBS_SYSTEM=
 989 case "$opsys" in
 990   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 991   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 992
 993   freebsd) LIBS_SYSTEM="-lutil" ;;
 994
 995   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 996
 997   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
 998
 999   ## Motif needs -lgen.
1000   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1001 esac
1002 AC_SUBST(LIBS_SYSTEM)
1003
1004
1005 ### Make sure subsequent tests use flags consistent with the build flags.
1006
1007 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1008   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1009 else
1010   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1011 fi
1012
1013 dnl For AC_FUNC_GETLOADAVG, at least:
1014 AC_CONFIG_LIBOBJ_DIR(src)
1015
1016 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1017 AC_SYS_LARGEFILE
1018
1019
1020 ## If user specified a crt-dir, use that unconditionally.
1021 if test "X$CRT_DIR" = "X"; then
1022
1023   case "$canonical" in
1024     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1025     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1026     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1027     ## For anything else (eg /usr/lib32), it is up the user to specify
1028     ## the location (bug#5655).
1029     ## Test for crtn.o, not just the directory, because sometimes the
1030     ## directory exists but does not have the relevant files (bug#1287).
1031     ## FIXME better to test for binary compatibility somehow.
1032     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1033     ;;
1034
1035     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1036   esac
1037
1038   case "$opsys" in
1039     hpux10-20) CRT_DIR=/lib ;;
1040   esac
1041
1042   ## Default is /usr/lib.
1043   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1044
1045 else
1046
1047   ## Some platforms don't use any of these files, so it is not
1048   ## appropriate to put this test outside the if block.
1049   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1050     AC_MSG_ERROR([crt*.o not found in specified location.])
1051
1052 fi
1053
1054 AC_SUBST(CRT_DIR)
1055
1056 LIB_MATH=-lm
1057 LIB_STANDARD=
1058 START_FILES=
1059
1060 case $opsys in
1061   cygwin )
1062     LIB_MATH=
1063     START_FILES='pre-crt0.o'
1064     ;;
1065   darwin )
1066     ## Adding -lm confuses the dynamic linker, so omit it.
1067     LIB_MATH=
1068     START_FILES='pre-crt0.o'
1069     ;;
1070   freebsd )
1071     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1072     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1073     ;;
1074   gnu-linux | gnu-kfreebsd )
1075     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1076     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1077     ;;
1078   hpux10-20 | hpux11 )
1079     LIB_STANDARD=-lc
1080     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1081     ;;
1082   netbsd | openbsd )
1083     if test -f $CRT_DIR/crti.o; then
1084         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1085         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1086     else
1087         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1088         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1089     fi
1090     ;;
1091 esac
1092
1093 AC_SUBST(LIB_MATH)
1094 AC_SUBST(START_FILES)
1095
1096 dnl This function definition taken from Gnome 2.0
1097 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1098 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1099 dnl also defines GSTUFF_PKG_ERRORS on error
1100 AC_DEFUN([PKG_CHECK_MODULES], [
1101   succeeded=no
1102
1103   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1104
1105   if test "$PKG_CONFIG" = "no" ; then
1106      ifelse([$4], , [AC_MSG_ERROR([
1107       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1108   else
1109      PKG_CONFIG_MIN_VERSION=0.9.0
1110      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1111         AC_MSG_CHECKING(for $2)
1112
1113         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1114             AC_MSG_RESULT(yes)
1115             succeeded=yes
1116
1117             AC_MSG_CHECKING($1_CFLAGS)
1118             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1119             AC_MSG_RESULT($$1_CFLAGS)
1120
1121             AC_MSG_CHECKING($1_LIBS)
1122             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1123             AC_MSG_RESULT($$1_LIBS)
1124         else
1125             AC_MSG_RESULT(no)
1126             $1_CFLAGS=""
1127             $1_LIBS=""
1128             ## If we have a custom action on failure, don't print errors, but
1129             ## do set a variable so people can do so.
1130             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1131             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1132         fi
1133
1134         AC_SUBST($1_CFLAGS)
1135         AC_SUBST($1_LIBS)
1136      else
1137         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1138         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1139      fi
1140   fi
1141
1142   if test $succeeded = yes; then
1143      ifelse([$3], , :, [$3])
1144   else
1145      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1146   fi
1147 ])
1148
1149
1150 if test "${with_sound}" != "no"; then
1151   # Sound support for GNU/Linux and the free BSDs.
1152   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1153     have_sound_header=yes)
1154   # Emulation library used on NetBSD.
1155   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1156   AC_SUBST(LIBSOUND)
1157
1158   ALSA_REQUIRED=1.0.0
1159   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1160   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1161   if test $HAVE_ALSA = yes; then
1162     SAVE_CFLAGS="$CFLAGS"
1163     SAVE_LDFLAGS="$LDFLAGS"
1164     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1165     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1166     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1167                     emacs_alsa_normal=yes,
1168                     emacs_alsa_normal=no)
1169     if test "$emacs_alsa_normal" != yes; then
1170       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1171                      [snd_lib_error_set_handler (0);],
1172                      emacs_alsa_subdir=yes,
1173                      emacs_alsa_subdir=no)
1174       if test "$emacs_alsa_subdir" != yes; then
1175         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1176       fi
1177       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1178     fi
1179
1180     CFLAGS="$SAVE_CFLAGS"
1181     LDFLAGS="$SAVE_LDFLAGS"
1182     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1183     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1184     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1185   fi
1186
1187   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1188   dnl compiles only on the specified platforms.  For others, it
1189   dnl probably doesn't make sense to try.
1190   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1191      case "$opsys" in
1192        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1193        gnu-linux|freebsd|netbsd)
1194          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1195          ;;
1196      esac
1197   fi
1198
1199   AC_SUBST(CFLAGS_SOUND)
1200 fi
1201
1202 dnl checks for header files
1203 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1204   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1205   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1206   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1207   sys/utsname.h pwd.h utmp.h dirent.h)
1208
1209 AC_MSG_CHECKING(if personality LINUX32 can be set)
1210 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1211                emacs_cv_personality_linux32=yes,
1212                emacs_cv_personality_linux32=no)
1213 AC_MSG_RESULT($emacs_cv_personality_linux32)
1214
1215 if test $emacs_cv_personality_linux32 = yes; then
1216   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1217             [Define to 1 if personality LINUX32 can be set.])
1218 fi
1219
1220 dnl On Solaris 8 there's a compilation warning for term.h because
1221 dnl it doesn't define `bool'.
1222 AC_CHECK_HEADERS(term.h, , , -)
1223 AC_HEADER_STDC
1224 AC_HEADER_TIME
1225 AC_CHECK_DECLS([sys_siglist])
1226 if test $ac_cv_have_decl_sys_siglist != yes; then
1227   # For Tru64, at least:
1228   AC_CHECK_DECLS([__sys_siglist])
1229   if test $ac_cv_have_decl___sys_siglist = yes; then
1230     AC_DEFINE(sys_siglist, __sys_siglist,
1231               [Define to any substitute for sys_siglist.])
1232   fi
1233 fi
1234 AC_HEADER_SYS_WAIT
1235
1236 dnl Some systems have utime.h but don't declare the struct anyplace.
1237 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1238 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1239 #include <sys/time.h>
1240 #include <time.h>
1241 #else
1242 #ifdef HAVE_SYS_TIME_H
1243 #include <sys/time.h>
1244 #else
1245 #include <time.h>
1246 #endif
1247 #endif
1248 #ifdef HAVE_UTIME_H
1249 #include <utime.h>
1250 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1251   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1252 if test $emacs_cv_struct_utimbuf = yes; then
1253   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1254 fi
1255
1256 dnl checks for typedefs
1257 AC_TYPE_SIGNAL
1258
1259 dnl Check for speed_t typedef.
1260 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1261   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1262     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1263 if test $emacs_cv_speed_t = yes; then
1264   AC_DEFINE(HAVE_SPEED_T, 1,
1265            [Define to 1 if `speed_t' is declared by <termios.h>.])
1266 fi
1267
1268 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1269 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1270 #include <sys/time.h>
1271 #include <time.h>
1272 #else
1273 #ifdef HAVE_SYS_TIME_H
1274 #include <sys/time.h>
1275 #else
1276 #include <time.h>
1277 #endif
1278 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1279   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1280 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1281 if test $emacs_cv_struct_timeval = yes; then
1282   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1283 fi
1284
1285 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1286 AC_TRY_COMPILE([#include <math.h>],
1287 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1288   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1289 HAVE_EXCEPTION=$emacs_cv_struct_exception
1290 if test $emacs_cv_struct_exception != yes; then
1291   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1292 fi
1293
1294 AC_CHECK_HEADERS(sys/socket.h)
1295 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1296 #if HAVE_SYS_SOCKET_H
1297 #include <sys/socket.h>
1298 #endif])
1299
1300 dnl checks for structure members
1301 AC_STRUCT_TM
1302 AC_STRUCT_TIMEZONE
1303 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1304                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1305                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1306                 [#include <time.h>])
1307 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1308                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1309                   struct ifreq.ifr_addr], , ,
1310                  [AC_INCLUDES_DEFAULT
1311 #if HAVE_SYS_SOCKET_H
1312 #include <sys/socket.h>
1313 #endif
1314 #if HAVE_NET_IF_H
1315 #include <net/if.h>
1316 #endif])
1317
1318 dnl checks for compiler characteristics
1319
1320 dnl Testing __STDC__ to determine prototype support isn't good enough.
1321 dnl DEC C, for instance, doesn't define it with default options, and
1322 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1323 dnl and void *.
1324 AC_C_PROTOTYPES
1325 AC_C_VOLATILE
1326 AC_C_CONST
1327 dnl This isn't useful because we can't turn on use of `inline' unless
1328 dnl the compiler groks `extern inline'.
1329 dnl AC_C_INLINE
1330 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1331   [AC_TRY_COMPILE(, [void * foo;],
1332                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1333 if test $emacs_cv_void_star = yes; then
1334   AC_DEFINE(POINTER_TYPE, void)
1335 else
1336   AC_DEFINE(POINTER_TYPE, char)
1337 fi
1338 AH_TEMPLATE(POINTER_TYPE,
1339             [Define as `void' if your compiler accepts `void *'; otherwise
1340              define as `char'.])dnl
1341
1342
1343
1344 dnl This could be used for targets which can have both byte sexes.
1345 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1346 dnl AC_C_BIGENDIAN
1347
1348 dnl check for Make feature
1349 AC_PROG_MAKE_SET
1350
1351 DEPFLAGS=
1352 MKDEPDIR=":"
1353 deps_frag=deps.mk
1354 dnl check for GNU Make if we have GCC and autodepend is on.
1355 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1356    AC_MSG_CHECKING([whether we are using GNU Make])
1357    HAVE_GNU_MAKE=no
1358    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1359    if test "x$testval" != x; then
1360       HAVE_GNU_MAKE=yes
1361    else
1362       ac_enable_autodepend=no
1363    fi
1364    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1365    if test $HAVE_GNU_MAKE = yes; then
1366       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1367       SAVE_CFLAGS="$CFLAGS"
1368       CFLAGS="$CFLAGS -MMD -MF deps.d"
1369       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1370       CFLAGS="$SAVE_CFLAGS"
1371       test -f deps.d || ac_enable_autodepend=no
1372       rm -rf deps.d
1373       AC_MSG_RESULT([$ac_enable_autodepend])
1374    fi
1375    if test $ac_enable_autodepend = yes; then
1376       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1377       ## In parallel builds, another make might create depdir between
1378       ## the first test and mkdir, so stick another test on the end.
1379       ## Or use mkinstalldirs?  mkdir -p is not portable.
1380       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1381       deps_frag=autodeps.mk
1382    fi
1383 fi
1384 deps_frag=$srcdir/src/$deps_frag
1385 AC_SUBST(MKDEPDIR)
1386 AC_SUBST(DEPFLAGS)
1387 AC_SUBST_FILE(deps_frag)
1388
1389
1390 dnl checks for operating system services
1391 AC_SYS_LONG_FILE_NAMES
1392
1393 #### Choose a window system.
1394
1395 AC_PATH_X
1396 if test "$no_x" = yes; then
1397   window_system=none
1398 else
1399   window_system=x11
1400 fi
1401
1402 ## Workaround for bug in autoconf <= 2.62.
1403 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1404 ## No need to do anything special for these standard directories.
1405 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1406
1407    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1408
1409 fi
1410
1411 LD_SWITCH_X_SITE_AUX=
1412 LD_SWITCH_X_SITE_AUX_RPATH=
1413 if test "${x_libraries}" != NONE; then
1414   if test -n "${x_libraries}"; then
1415     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1416     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1417     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1418   fi
1419   x_default_search_path=""
1420   x_search_path=${x_libraries}
1421   if test -z "${x_search_path}"; then
1422     x_search_path=/usr/lib
1423   fi
1424   for x_library in `echo ${x_search_path}: | \
1425                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1426     x_search_path="\
1427 ${x_library}/X11/%L/%T/%N%C%S:\
1428 ${x_library}/X11/%l/%T/%N%C%S:\
1429 ${x_library}/X11/%T/%N%C%S:\
1430 ${x_library}/X11/%L/%T/%N%S:\
1431 ${x_library}/X11/%l/%T/%N%S:\
1432 ${x_library}/X11/%T/%N%S"
1433     if test x"${x_default_search_path}" = x; then
1434       x_default_search_path=${x_search_path}
1435     else
1436       x_default_search_path="${x_search_path}:${x_default_search_path}"
1437     fi
1438   done
1439 fi
1440 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1441 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1442
1443 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1444   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1445 fi
1446
1447 if test x"${x_includes}" = x; then
1448   bitmapdir=/usr/include/X11/bitmaps
1449 else
1450   # accumulate include directories that have X11 bitmap subdirectories
1451   bmd_acc="dummyval"
1452   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1453     if test -d "${bmd}/X11/bitmaps"; then
1454       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1455     fi
1456     if test -d "${bmd}/bitmaps"; then
1457       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1458     fi
1459   done
1460   if test ${bmd_acc} != "dummyval"; then
1461     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1462   fi
1463 fi
1464
1465 HAVE_NS=no
1466 NS_IMPL_COCOA=no
1467 NS_IMPL_GNUSTEP=no
1468 tmp_CPPFLAGS="$CPPFLAGS"
1469 tmp_CFLAGS="$CFLAGS"
1470 CPPFLAGS="$CPPFLAGS -x objective-c"
1471 CFLAGS="$CFLAGS -x objective-c"
1472 TEMACS_LDFLAGS2="\${LDFLAGS} \${PROFILING_LDFLAGS}"
1473 dnl I don't think it's especially important, but src/Makefile.in
1474 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1475 dnl trailing "/" to it, so now we do it here.
1476 if test "${with_ns}" != no; then
1477   if test "${opsys}" = darwin; then
1478      NS_IMPL_COCOA=yes
1479      ns_appdir=`pwd`/nextstep/Emacs.app/
1480      ns_appbindir=${ns_appdir}Contents/MacOS/
1481      ns_appresdir=${ns_appdir}Contents/Resources
1482      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1483   elif test -f $GNUSTEP_CONFIG_FILE; then
1484      NS_IMPL_GNUSTEP=yes
1485      ns_appdir=`pwd`/nextstep/Emacs.app/
1486      ns_appbindir=${ns_appdir}
1487      ns_appresdir=${ns_appdir}Resources
1488      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1489      dnl FIXME sourcing this several times in subshells seems inefficient.
1490      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1491      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1492      dnl I seemed to need these as well with GNUstep-startup 0.25.
1493      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1494      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1495      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1496        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1497      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1498        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1499      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1500      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1501      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1502      LIB_STANDARD=
1503      START_FILES=
1504      TEMACS_LDFLAGS2=
1505   fi
1506   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1507                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1508   files are missing or cannot be compiled.])])
1509   NS_HAVE_NSINTEGER=yes
1510   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1511                                      [NSInteger i;])],
1512                     ns_have_nsinteger=yes,
1513                     ns_have_nsinteger=no)
1514   if test $ns_have_nsinteger = no; then
1515     NS_HAVE_NSINTEGER=no
1516   fi
1517 fi
1518 AC_SUBST(TEMACS_LDFLAGS2)
1519
1520 ns_frag=/dev/null
1521 NS_OBJ=
1522 NS_SUPPORT=
1523 if test "${HAVE_NS}" = yes; then
1524   window_system=nextstep
1525   with_xft=no
1526   # set up packaging dirs
1527   exec_prefix=${ns_appbindir}
1528   libexecdir=${ns_appbindir}/libexec
1529   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1530      prefix=${ns_appresdir}
1531   fi
1532   ns_frag=$srcdir/src/ns.mk
1533   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1534   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1535 fi
1536 CFLAGS="$tmp_CFLAGS"
1537 CPPFLAGS="$tmp_CPPFLAGS"
1538 AC_SUBST(NS_OBJ)
1539 AC_SUBST(NS_SUPPORT)
1540 AC_SUBST(LIB_STANDARD)
1541 AC_SUBST_FILE(ns_frag)
1542
1543 case "${window_system}" in
1544   x11 )
1545     HAVE_X_WINDOWS=yes
1546     HAVE_X11=yes
1547     case "${with_x_toolkit}" in
1548       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1549       motif ) USE_X_TOOLKIT=MOTIF ;;
1550       gtk ) with_gtk=yes
1551 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1552 dnl USE_X_TOOLKIT is set.
1553             USE_X_TOOLKIT=none ;;
1554       gtk3 ) with_gtk3=yes
1555              USE_X_TOOLKIT=none ;;
1556       no ) USE_X_TOOLKIT=none ;;
1557 dnl If user did not say whether to use a toolkit, make this decision later:
1558 dnl use the toolkit if we have gtk, or X11R5 or newer.
1559       * ) USE_X_TOOLKIT=maybe ;;
1560     esac
1561   ;;
1562   nextstep | none )
1563     HAVE_X_WINDOWS=no
1564     HAVE_X11=no
1565     USE_X_TOOLKIT=none
1566   ;;
1567 esac
1568
1569 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1570    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1571    if test "$HAVE_XSERVER" = true ||
1572       test -n "$DISPLAY" ||
1573       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1574         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1575 were found.  You should install the relevant development files for X
1576 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1577 sure you have development files for image handling, i.e.
1578 tiff, gif, jpeg, png and xpm.
1579 If you are sure you want Emacs compiled without X window support, pass
1580   --without-x
1581 to configure.])
1582    fi
1583 fi
1584
1585 ### If we're using X11, we should use the X menu package.
1586 HAVE_MENUS=no
1587 case ${HAVE_X11} in
1588   yes ) HAVE_MENUS=yes ;;
1589 esac
1590
1591 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1592 # Assume not, until told otherwise.
1593 GNU_MALLOC=yes
1594 doug_lea_malloc=yes
1595 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1596 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1597 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1598                emacs_cv_var___after_morecore_hook,
1599 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1600   emacs_cv_var___after_morecore_hook=yes,
1601   emacs_cv_var___after_morecore_hook=no)])
1602 if test $emacs_cv_var___after_morecore_hook = no; then
1603   doug_lea_malloc=no
1604 fi
1605
1606
1607 dnl See comments in aix4-2.h about maybe using system malloc there.
1608 system_malloc=no
1609 case "$opsys" in
1610   ## darwin ld insists on the use of malloc routines in the System framework.
1611   darwin|sol2-10) system_malloc=yes ;;
1612 esac
1613
1614 if test "${system_malloc}" = "yes"; then
1615   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1616   GNU_MALLOC=no
1617   GNU_MALLOC_reason="
1618     (The GNU allocators don't work with this system configuration.)"
1619   GMALLOC_OBJ=
1620   VMLIMIT_OBJ=
1621 else
1622   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1623   VMLIMIT_OBJ=vm-limit.o
1624 fi
1625 AC_SUBST(GMALLOC_OBJ)
1626 AC_SUBST(VMLIMIT_OBJ)
1627
1628 if test "$doug_lea_malloc" = "yes" ; then
1629   if test "$GNU_MALLOC" = yes ; then
1630     GNU_MALLOC_reason="
1631       (Using Doug Lea's new malloc from the GNU C Library.)"
1632   fi
1633   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1634             [Define to 1 if you are using the GNU C Library.])
1635
1636   ## Use mmap directly for allocating larger buffers.
1637   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1638   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1639   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1640   case "$opsys" in
1641     gnu*) REL_ALLOC=no ;;
1642   esac
1643 fi
1644
1645 if test x"${REL_ALLOC}" = x; then
1646   REL_ALLOC=${GNU_MALLOC}
1647 fi
1648
1649 use_mmap_for_buffers=no
1650 case "$opsys" in
1651   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1652 esac
1653
1654 AC_FUNC_MMAP
1655 if test $use_mmap_for_buffers = yes; then
1656   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1657   REL_ALLOC=no
1658 fi
1659
1660 LIBS="$LIBS_SYSTEM $LIBS"
1661
1662 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1663 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1664 AC_CHECK_LIB(dnet, dnet_ntoa)
1665 dnl This causes -lresolv to get used in subsequent tests,
1666 dnl which causes failures on some systems such as HPUX 9.
1667 dnl AC_CHECK_LIB(resolv, gethostbyname)
1668
1669 dnl FIXME replace main with a function we actually want from this library.
1670 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1671
1672 AC_CHECK_LIB(pthreads, cma_open)
1673
1674 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1675 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1676 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1677 ## added to LIBS in configure would never contain the pthreads part,
1678 ## but the value used in Makefiles might.  FIXME?
1679 ##
1680 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1681 ## be harmless on older versions of X where it happens to exist.
1682 test "$opsys" = "aix4-2" && \
1683   test $ac_cv_lib_pthreads_cma_open = yes && \
1684   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1685
1686 dnl Check for need for bigtoc support on IBM AIX
1687
1688 case ${host_os} in
1689 aix*)
1690   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1691     case $GCC in
1692     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1693     *) gdb_cv_bigtoc=-bbigtoc ;;
1694     esac
1695
1696     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1697     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1698   ])
1699   ;;
1700 esac
1701
1702 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1703 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1704 # REAL_CPPFLAGS later on.
1705
1706 REAL_CFLAGS="$CFLAGS"
1707 REAL_CPPFLAGS="$CPPFLAGS"
1708
1709 if test "${HAVE_X11}" = "yes"; then
1710   DEFS="$C_SWITCH_X_SITE $DEFS"
1711   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1712   LIBS="-lX11 $LIBS"
1713   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1714   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1715
1716   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1717   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1718   # but it's more convenient here to set LD_RUN_PATH
1719   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1720   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1721     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1722     export LD_RUN_PATH
1723   fi
1724
1725   if test "${opsys}" = "gnu-linux"; then
1726     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1727     AC_TRY_LINK([],
1728      [XOpenDisplay ("foo");],
1729      [xlinux_first_failure=no],
1730      [xlinux_first_failure=yes])
1731     if test "${xlinux_first_failure}" = "yes"; then
1732       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1733       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1734       OLD_CPPFLAGS="$CPPFLAGS"
1735       OLD_LIBS="$LIBS"
1736       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1737       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1738       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1739       LIBS="$LIBS -b i486-linuxaout"
1740       AC_TRY_LINK([],
1741        [XOpenDisplay ("foo");],
1742        [xlinux_second_failure=no],
1743        [xlinux_second_failure=yes])
1744       if test "${xlinux_second_failure}" = "yes"; then
1745         # If we get the same failure with -b, there is no use adding -b.
1746         # So take it out.  This plays safe.
1747         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1748         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1749         CPPFLAGS="$OLD_CPPFLAGS"
1750         LIBS="$OLD_LIBS"
1751         AC_MSG_RESULT(no)
1752       else
1753         AC_MSG_RESULT(yes)
1754       fi
1755     else
1756       AC_MSG_RESULT(no)
1757     fi
1758   fi
1759
1760   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1761   # header files included from there.
1762   AC_MSG_CHECKING(for Xkb)
1763   AC_TRY_LINK([#include <X11/Xlib.h>
1764 #include <X11/XKBlib.h>],
1765         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1766         emacs_xkb=yes, emacs_xkb=no)
1767   AC_MSG_RESULT($emacs_xkb)
1768   if test $emacs_xkb = yes; then
1769     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1770   fi
1771
1772   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1773 XScreenNumberOfScreen XSetWMProtocols)
1774 fi
1775
1776 if test "${window_system}" = "x11"; then
1777   AC_MSG_CHECKING(X11 version 6)
1778   AC_CACHE_VAL(emacs_cv_x11_version_6,
1779   [AC_TRY_LINK([#include <X11/Xlib.h>],
1780 [#if XlibSpecificationRelease < 6
1781 fail;
1782 #endif
1783 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1784   if test $emacs_cv_x11_version_6 = yes; then
1785     AC_MSG_RESULT(6 or newer)
1786     AC_DEFINE(HAVE_X11R6, 1,
1787               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1788     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1789     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1790     ## XIM support.
1791     case "$opsys" in
1792       sol2-*) : ;;
1793       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1794            [Define if you have usable X11R6-style XIM support.])
1795          ;;
1796     esac
1797   else
1798     AC_MSG_RESULT(before 6)
1799   fi
1800 fi
1801
1802
1803 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1804 HAVE_RSVG=no
1805 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1806   if test "${with_rsvg}" != "no"; then
1807     RSVG_REQUIRED=2.11.0
1808     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1809
1810     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1811     AC_SUBST(RSVG_CFLAGS)
1812     AC_SUBST(RSVG_LIBS)
1813
1814     if test ".${RSVG_CFLAGS}" != "."; then
1815       HAVE_RSVG=yes
1816       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1817       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1818       LIBS="$RSVG_LIBS $LIBS"
1819     fi
1820   fi
1821 fi
1822
1823
1824 HAVE_GTK=no
1825 if test "${with_gtk3}" = "yes"; then
1826   GLIB_REQUIRED=2.6
1827   GTK_REQUIRED=2.90
1828   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1829
1830   dnl Checks for libraries.
1831   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1832   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1833      AC_MSG_ERROR($GTK_PKG_ERRORS)
1834   fi
1835 fi
1836
1837 if test "$pkg_check_gtk" != "yes"; then
1838   HAVE_GTK=no
1839 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1840   GLIB_REQUIRED=2.6
1841   GTK_REQUIRED=2.6
1842   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1843
1844   dnl Checks for libraries.
1845   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1846   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1847      AC_MSG_ERROR($GTK_PKG_ERRORS)
1848   fi
1849 fi
1850 fi
1851
1852 GTK_OBJ=
1853 if test x"$pkg_check_gtk" = xyes; then
1854
1855   AC_SUBST(GTK_CFLAGS)
1856   AC_SUBST(GTK_LIBS)
1857   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1858   CFLAGS="$CFLAGS $GTK_CFLAGS"
1859   LIBS="$GTK_LIBS $LIBS"
1860   dnl Try to compile a simple GTK program.
1861   GTK_COMPILES=no
1862   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1863   if test "${GTK_COMPILES}" != "yes"; then
1864     if test "$USE_X_TOOLKIT" != "maybe"; then
1865       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1866     fi
1867   else
1868     HAVE_GTK=yes
1869     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1870     GTK_OBJ=gtkutil.o
1871     USE_X_TOOLKIT=none
1872     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1873       :
1874     else
1875       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1876        closing open displays.  This is no problem if you just use
1877        one display, but if you use more than one and close one of them
1878        Emacs may crash.]])
1879       sleep 3
1880     fi
1881   fi
1882
1883 fi
1884 AC_SUBST(GTK_OBJ)
1885
1886
1887 if test "${HAVE_GTK}" = "yes"; then
1888
1889   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1890   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1891   if test "$with_toolkit_scroll_bars" != no; then
1892     with_toolkit_scroll_bars=yes
1893   fi
1894
1895   dnl  Check if we have the old file selection dialog declared and
1896   dnl  in the link library.  In 2.x it may be in the library,
1897   dnl  but not declared if deprecated featured has been selected out.
1898   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1899   HAVE_GTK_FILE_SELECTION=no
1900   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1901                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1902 #include <gtk/gtk.h>])
1903   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1904     AC_CHECK_FUNCS(gtk_file_selection_new)
1905   fi
1906
1907   dnl Check if pthreads are available.  Emacs only needs this when using
1908   dnl gtk_file_chooser under Gnome.
1909     HAVE_GTK_AND_PTHREAD=no
1910     AC_CHECK_HEADERS(pthread.h)
1911     if test "$ac_cv_header_pthread_h"; then
1912       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1913     fi
1914     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1915       case "${canonical}" in
1916         *-hpux*) ;;
1917         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1918       esac
1919       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1920                [Define to 1 if you have GTK and pthread (-lpthread).])
1921     fi
1922
1923   dnl Check for functions introduced in 2.14 and later.
1924   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1925                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1926                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1927                  gtk_orientable_set_orientation)
1928
1929 fi
1930
1931 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1932 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1933 dnl also not configured.
1934 HAVE_DBUS=no
1935 DBUS_OBJ=
1936 if test "${with_dbus}" = "yes"; then
1937    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1938    if test "$HAVE_DBUS" = yes; then
1939      LIBS="$LIBS $DBUS_LIBS"
1940      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1941      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1942      DBUS_OBJ=dbusbind.o
1943    fi
1944 fi
1945 AC_SUBST(DBUS_OBJ)
1946
1947 dnl GConf has been tested under GNU/Linux only.
1948 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1949 HAVE_GCONF=no
1950 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1951    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1952    if test "$HAVE_GCONF" = yes; then
1953       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1954    fi
1955 fi
1956
1957 dnl SELinux is available for GNU/Linux only.
1958 HAVE_LIBSELINUX=no
1959 LIBSELINUX_LIBS=
1960 if test "${with_selinux}" = "yes"; then
1961    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1962    if test "$HAVE_LIBSELINUX" = yes; then
1963       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1964       LIBSELINUX_LIBS=-lselinux
1965    fi
1966 fi
1967 AC_SUBST(LIBSELINUX_LIBS)
1968
1969 dnl Do not put whitespace before the #include statements below.
1970 dnl Older compilers (eg sunos4 cc) choke on it.
1971 HAVE_XAW3D=no
1972 LUCID_LIBW=
1973 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1974   if test "$with_xaw3d" != no; then
1975     AC_MSG_CHECKING(for xaw3d)
1976     AC_CACHE_VAL(emacs_cv_xaw3d,
1977     [AC_TRY_LINK([
1978 #include <X11/Intrinsic.h>
1979 #include <X11/Xaw3d/Simple.h>],
1980       [],
1981       emacs_cv_xaw3d=yes,
1982       emacs_cv_xaw3d=no)])
1983   else
1984     emacs_cv_xaw3d=no
1985   fi
1986   if test $emacs_cv_xaw3d = yes; then
1987     AC_MSG_RESULT([yes; using Lucid toolkit])
1988     USE_X_TOOLKIT=LUCID
1989     HAVE_XAW3D=yes
1990     LUCID_LIBW=-lXaw3d
1991     AC_DEFINE(HAVE_XAW3D, 1,
1992               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1993   else
1994     AC_MSG_RESULT(no)
1995     AC_MSG_CHECKING(for libXaw)
1996     AC_CACHE_VAL(emacs_cv_xaw,
1997     [AC_TRY_LINK([
1998 #include <X11/Intrinsic.h>
1999 #include <X11/Xaw/Simple.h>],
2000       [],
2001       emacs_cv_xaw=yes,
2002       emacs_cv_xaw=no)])
2003     if test $emacs_cv_xaw = yes; then
2004       AC_MSG_RESULT([yes; using Lucid toolkit])
2005       USE_X_TOOLKIT=LUCID
2006       LUCID_LIBW=-lXaw
2007     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2008       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2009     else
2010       AC_MSG_RESULT([no; do not use toolkit by default])
2011       USE_X_TOOLKIT=none
2012     fi
2013   fi
2014 fi
2015
2016 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2017
2018 LIBXTR6=
2019 if test "${USE_X_TOOLKIT}" != "none"; then
2020   AC_MSG_CHECKING(X11 toolkit version)
2021   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2022   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2023 [#if XtSpecificationRelease < 6
2024 fail;
2025 #endif
2026 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2027   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2028   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2029     AC_MSG_RESULT(6 or newer)
2030     AC_DEFINE(HAVE_X11XTR6, 1,
2031               [Define to 1 if you have the X11R6 or newer version of Xt.])
2032     LIBXTR6="-lSM -lICE"
2033     case "$opsys" in
2034       ## Use libw.a along with X11R6 Xt.
2035       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2036     esac
2037   else
2038     AC_MSG_RESULT(before 6)
2039   fi
2040
2041 dnl If using toolkit, check whether libXmu.a exists.
2042 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2043   OLDLIBS="$LIBS"
2044   if test x$HAVE_X11XTR6 = xyes; then
2045     LIBS="-lXt -lSM -lICE $LIBS"
2046   else
2047     LIBS="-lXt $LIBS"
2048   fi
2049   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2050   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2051 fi
2052 AC_SUBST(LIBXTR6)
2053
2054 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2055 dnl Why not just test for libxmu in the normal way?
2056 LIBXMU=-lXmu
2057 case "$machine" in
2058   ## These machines don't supply Xmu.
2059   hpux* | aix4-2 )
2060     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2061     ;;
2062 esac
2063 AC_SUBST(LIBXMU)
2064
2065 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2066 if test "${HAVE_X11}" = "yes"; then
2067   if test "${USE_X_TOOLKIT}" != "none"; then
2068     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2069   fi
2070 fi
2071
2072 LIBXP=
2073 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2074   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2075   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2076     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2077 int x = 5;
2078 #else
2079 Motif version prior to 2.1.
2080 #endif],
2081     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2082   if test $emacs_cv_motif_version_2_1 = yes; then
2083     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2084   else
2085     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2086     # We put this in CFLAGS temporarily to precede other -I options
2087     # that might be in CFLAGS temporarily.
2088     # We put this in CPPFLAGS where it precedes the other -I options.
2089     OLD_CPPFLAGS=$CPPFLAGS
2090     OLD_CFLAGS=$CFLAGS
2091     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2092     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2093     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2094       [int x = 5;],
2095       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2096     if test $emacs_cv_lesstif = yes; then
2097       # Make sure this -I option remains in CPPFLAGS after it is set
2098       # back to REAL_CPPFLAGS.
2099       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2100       # have those other -I options anyway.  Ultimately, having this
2101       # directory ultimately in CPPFLAGS will be enough.
2102       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2103       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2104     else
2105       CFLAGS=$OLD_CFLAGS
2106       CPPFLAGS=$OLD_CPPFLAGS
2107     fi
2108   fi
2109 fi
2110
2111 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2112 dnl using Motif or Xaw3d is available, and unless
2113 dnl --with-toolkit-scroll-bars=no was specified.
2114
2115 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2116             [Define to 1 if we should use toolkit scroll bars.])dnl
2117 USE_TOOLKIT_SCROLL_BARS=no
2118 if test "${with_toolkit_scroll_bars}" != "no"; then
2119   if test "${USE_X_TOOLKIT}" != "none"; then
2120     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2121       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2122       HAVE_XAW3D=no
2123       USE_TOOLKIT_SCROLL_BARS=yes
2124     elif test "${HAVE_XAW3D}" = "yes"; then
2125       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2126       USE_TOOLKIT_SCROLL_BARS=yes
2127     fi
2128   elif test "${HAVE_GTK}" = "yes"; then
2129     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2130     USE_TOOLKIT_SCROLL_BARS=yes
2131   elif test "${HAVE_NS}" = "yes"; then
2132     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2133     USE_TOOLKIT_SCROLL_BARS=yes
2134   fi
2135 fi
2136
2137 dnl See if XIM is available.
2138 AC_TRY_COMPILE([
2139           #include <X11/Xlib.h>
2140           #include <X11/Xresource.h>],
2141          [XIMProc  callback;],
2142          [HAVE_XIM=yes
2143          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2144          HAVE_XIM=no)
2145
2146 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2147
2148 if test "${with_xim}" != "no"; then
2149   AC_DEFINE(USE_XIM, 1,
2150             [Define to 1 if we should use XIM, if it is available.])
2151 fi
2152
2153
2154 if test "${HAVE_XIM}" != "no"; then
2155   late_CFLAGS=$CFLAGS
2156   if test "$GCC" = yes; then
2157     CFLAGS="$CFLAGS --pedantic-errors"
2158   fi
2159   AC_TRY_COMPILE([
2160 #include <X11/Xlib.h>
2161 #include <X11/Xresource.h>],
2162 [Display *display;
2163 XrmDatabase db;
2164 char *res_name;
2165 char *res_class;
2166 XIMProc  callback;
2167 XPointer *client_data;
2168 #ifndef __GNUC__
2169 /* If we're not using GCC, it's probably not XFree86, and this is
2170    probably right, but we can't use something like --pedantic-errors.  */
2171 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2172                                            char*, XIMProc, XPointer*);
2173 #endif
2174 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2175    client_data);],
2176     [emacs_cv_arg6_star=yes])
2177   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2178          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2179 either XPointer or XPointer*.])dnl
2180   if test "$emacs_cv_arg6_star" = yes; then
2181     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2182   else
2183     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2184   fi
2185   CFLAGS=$late_CFLAGS
2186 fi
2187
2188 ### Start of font-backend (under any platform) section.
2189 # (nothing here yet -- this is a placeholder)
2190 ### End of font-backend (under any platform) section.
2191
2192 ### Start of font-backend (under X11) section.
2193 if test "${HAVE_X11}" = "yes"; then
2194    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2195
2196    ## Use -lXft if available, unless `--with-xft=no'.
2197    HAVE_XFT=maybe
2198     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2199       with_xft="no";
2200     fi
2201     if test "x${with_xft}" != "xno"; then
2202
2203       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2204       ## Because xftfont.c uses XRenderQueryExtension, we also
2205       ## need to link to -lXrender.
2206       HAVE_XRENDER=no
2207       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2208       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2209         OLD_CPPFLAGS="$CPPFLAGS"
2210         OLD_CFLAGS="$CFLAGS"
2211         OLD_LIBS="$LIBS"
2212         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2213         CFLAGS="$CFLAGS $XFT_CFLAGS"
2214         XFT_LIBS="-lXrender $XFT_LIBS"
2215         LIBS="$XFT_LIBS $LIBS"
2216         AC_CHECK_HEADER(X11/Xft/Xft.h,
2217           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2218
2219         if test "${HAVE_XFT}" = "yes"; then
2220           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2221             AC_SUBST(XFT_LIBS)
2222           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2223         else
2224           CPPFLAGS="$OLD_CPPFLAGS"
2225           CFLAGS="$OLD_CFLAGS"
2226           LIBS="$OLD_LIBS"
2227         fi                        # "${HAVE_XFT}" = "yes"
2228       fi                          # "$HAVE_XFT" != no
2229     fi                            # "x${with_xft}" != "xno"
2230
2231     dnl For the "Does Emacs use" message at the end.
2232     if test "$HAVE_XFT" != "yes"; then
2233        HAVE_XFT=no
2234     fi
2235
2236
2237     HAVE_FREETYPE=no
2238     ## We used to allow building with FreeType and without Xft.
2239     ## However, the ftx font backend driver is not in good shape.
2240     if test "${HAVE_XFT}" = "yes"; then
2241       dnl As we use Xft, we anyway use freetype.
2242       dnl There's no need for additional CFLAGS and LIBS.
2243       HAVE_FREETYPE=yes
2244       FONTCONFIG_CFLAGS=
2245       FONTCONFIG_LIBS=
2246     fi
2247
2248     HAVE_LIBOTF=no
2249     if test "${HAVE_FREETYPE}" = "yes"; then
2250       AC_DEFINE(HAVE_FREETYPE, 1,
2251                 [Define to 1 if using the freetype and fontconfig libraries.])
2252       if test "${with_libotf}" != "no"; then
2253         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2254                           HAVE_LIBOTF=no)
2255         if test "$HAVE_LIBOTF" = "yes"; then
2256           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2257           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2258                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2259                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2260           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2261             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2262                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2263           fi
2264         fi
2265       fi
2266     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2267     dnl Does the new font backend require it, or can it work without it?
2268     fi
2269
2270     HAVE_M17N_FLT=no
2271     if test "${HAVE_LIBOTF}" = yes; then
2272       if test "${with_m17n_flt}" != "no"; then
2273         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2274         if test "$HAVE_M17N_FLT" = "yes"; then
2275           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2276         fi
2277       fi
2278     fi
2279 else
2280     HAVE_XFT=no
2281     HAVE_FREETYPE=no
2282     HAVE_LIBOTF=no
2283     HAVE_M17N_FLT=no
2284 fi
2285
2286 ### End of font-backend (under X11) section.
2287
2288 AC_SUBST(FREETYPE_CFLAGS)
2289 AC_SUBST(FREETYPE_LIBS)
2290 AC_SUBST(FONTCONFIG_CFLAGS)
2291 AC_SUBST(FONTCONFIG_LIBS)
2292 AC_SUBST(LIBOTF_CFLAGS)
2293 AC_SUBST(LIBOTF_LIBS)
2294 AC_SUBST(M17N_FLT_CFLAGS)
2295 AC_SUBST(M17N_FLT_LIBS)
2296
2297 ### Use -lXpm if available, unless `--with-xpm=no'.
2298 HAVE_XPM=no
2299 LIBXPM=
2300 if test "${HAVE_X11}" = "yes"; then
2301   if test "${with_xpm}" != "no"; then
2302     AC_CHECK_HEADER(X11/xpm.h,
2303       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2304     if test "${HAVE_XPM}" = "yes"; then
2305       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2306       AC_EGREP_CPP(no_return_alloc_pixels,
2307       [#include "X11/xpm.h"
2308 #ifndef XpmReturnAllocPixels
2309 no_return_alloc_pixels
2310 #endif
2311       ], HAVE_XPM=no, HAVE_XPM=yes)
2312
2313       if test "${HAVE_XPM}" = "yes"; then
2314         AC_MSG_RESULT(yes)
2315       else
2316         AC_MSG_RESULT(no)
2317       fi
2318     fi
2319   fi
2320
2321   if test "${HAVE_XPM}" = "yes"; then
2322     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2323     LIBXPM=-lXpm
2324   fi
2325 fi
2326 AC_SUBST(LIBXPM)
2327
2328 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2329 HAVE_JPEG=no
2330 LIBJPEG=
2331 if test "${HAVE_X11}" = "yes"; then
2332   if test "${with_jpeg}" != "no"; then
2333     dnl Checking for jpeglib.h can lose because of a redefinition of
2334     dnl  HAVE_STDLIB_H.
2335     AC_CHECK_HEADER(jerror.h,
2336       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2337   fi
2338
2339   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2340   if test "${HAVE_JPEG}" = "yes"; then
2341     AC_DEFINE(HAVE_JPEG)
2342     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2343         [#include <jpeglib.h>
2344          version=JPEG_LIB_VERSION
2345 ],
2346         [AC_DEFINE(HAVE_JPEG)],
2347         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2348         HAVE_JPEG=no])
2349   fi
2350   if test "${HAVE_JPEG}" = "yes"; then
2351     LIBJPEG=-ljpeg
2352   fi
2353 fi
2354 AC_SUBST(LIBJPEG)
2355
2356 ### Use -lpng if available, unless `--with-png=no'.
2357 HAVE_PNG=no
2358 LIBPNG=
2359 if test "${HAVE_X11}" = "yes"; then
2360   if test "${with_png}" != "no"; then
2361     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2362     # in /usr/include/libpng.
2363     AC_CHECK_HEADERS(png.h libpng/png.h)
2364     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2365       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2366     fi
2367   fi
2368
2369   if test "${HAVE_PNG}" = "yes"; then
2370     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2371     LIBPNG="-lpng -lz -lm"
2372   fi
2373 fi
2374 AC_SUBST(LIBPNG)
2375
2376 ### Use -ltiff if available, unless `--with-tiff=no'.
2377 HAVE_TIFF=no
2378 LIBTIFF=
2379 if test "${HAVE_X11}" = "yes"; then
2380   if test "${with_tiff}" != "no"; then
2381     AC_CHECK_HEADER(tiffio.h,
2382       [tifflibs="-lz -lm"
2383       # At least one tiff package requires the jpeg library.
2384       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2385       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2386   fi
2387
2388   if test "${HAVE_TIFF}" = "yes"; then
2389     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2390     dnl FIXME -lz -lm, as per libpng?
2391     LIBTIFF=-ltiff
2392   fi
2393 fi
2394 AC_SUBST(LIBTIFF)
2395
2396 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2397 HAVE_GIF=no
2398 LIBGIF=
2399 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2400   AC_CHECK_HEADER(gif_lib.h,
2401 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2402 # Earlier versions can crash Emacs.
2403     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2404
2405   if test "$HAVE_GIF" = yes; then
2406     LIBGIF=-lgif
2407   elif test "$HAVE_GIF" = maybe; then
2408 # If gif_lib.h but no libgif, try libungif.
2409     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2410     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2411   fi
2412
2413   if test "${HAVE_GIF}" = "yes"; then
2414     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2415   fi
2416 fi
2417 AC_SUBST(LIBGIF)
2418
2419 dnl Check for required libraries.
2420 if test "${HAVE_X11}" = "yes"; then
2421   MISSING=""
2422   WITH_NO=""
2423   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2424     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2425   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2426     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2427   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2428     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2429   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2430     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2431   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2432     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2433
2434   if test "X${MISSING}" != X; then
2435     AC_MSG_ERROR([The following required libraries were not found:
2436     $MISSING
2437 Maybe some development libraries/packages are missing?
2438 If you don't want to link with them give
2439     $WITH_NO
2440 as options to configure])
2441   fi
2442 fi
2443
2444 ### Use -lgpm if available, unless `--with-gpm=no'.
2445 HAVE_GPM=no
2446 LIBGPM=
2447 MOUSE_SUPPORT=
2448 if test "${with_gpm}" != "no"; then
2449   AC_CHECK_HEADER(gpm.h,
2450     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2451
2452   if test "${HAVE_GPM}" = "yes"; then
2453     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2454     LIBGPM=-lgpm
2455     ## May be reset below.
2456     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2457   fi
2458 fi
2459 AC_SUBST(LIBGPM)
2460
2461 dnl Check for malloc/malloc.h on darwin
2462 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2463
2464 C_SWITCH_X_SYSTEM=
2465 ### Use NeXTstep API to implement GUI.
2466 if test "${HAVE_NS}" = "yes"; then
2467   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2468   if test "${NS_IMPL_COCOA}" = "yes"; then
2469     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2470     GNU_OBJC_CFLAGS=
2471   fi
2472   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2473     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2474     # See also .m.o rule in Makefile.in */
2475     # FIXME: are all these flags really needed?  Document here why.  */
2476     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2477     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2478   fi
2479   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2480     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2481   fi
2482   # We also have mouse menus.
2483   HAVE_MENUS=yes
2484   OTHER_FILES=ns-app
2485 fi
2486
2487
2488 ### Use session management (-lSM -lICE) if available
2489 HAVE_X_SM=no
2490 LIBXSM=
2491 if test "${HAVE_X11}" = "yes"; then
2492   AC_CHECK_HEADER(X11/SM/SMlib.h,
2493     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2494
2495   if test "${HAVE_X_SM}" = "yes"; then
2496     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2497     LIBXSM="-lSM -lICE"
2498     case "$LIBS" in
2499       *-lSM*) ;;
2500       *)      LIBS="$LIBXSM $LIBS" ;;
2501     esac
2502   fi
2503 fi
2504 AC_SUBST(LIBXSM)
2505
2506 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2507 AC_CACHE_CHECK(whether netdb declares h_errno,
2508                emacs_cv_netdb_declares_h_errno,
2509 [AC_TRY_LINK([#include <netdb.h>],
2510   [return h_errno;],
2511   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2512 if test $emacs_cv_netdb_declares_h_errno = yes; then
2513   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2514 fi
2515
2516 AC_FUNC_ALLOCA
2517
2518 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2519 dnl FIXME is there an autoconf test that does the right thing, without
2520 dnl needing to call A_M_E afterwards?
2521 if test x"$ac_cv_func_alloca_works" != xyes; then
2522    AC_MSG_ERROR( [a system implementation of alloca is required] )
2523 fi
2524
2525 # fmod, logb, and frexp are found in -lm on most systems.
2526 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2527 AC_CHECK_LIB(m, sqrt)
2528
2529 # Check for mail-locking functions in a "mail" library.  Probably this should
2530 # have the same check as for liblockfile below.
2531 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2532 if test $have_mail = yes; then
2533   LIBS_MAIL=-lmail
2534   LIBS="$LIBS_MAIL $LIBS"
2535   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2536 else
2537   LIBS_MAIL=
2538 fi
2539 dnl Debian, at least:
2540 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2541 if test $have_lockfile = yes; then
2542    LIBS_MAIL=-llockfile
2543    LIBS="$LIBS_MAIL $LIBS"
2544    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2545 else
2546 # If we have the shared liblockfile, assume we must use it for mail
2547 # locking (e.g. Debian).  If we couldn't link against liblockfile
2548 # (no liblockfile.a installed), ensure that we don't need to.
2549   dnl This works for files generally, not just executables.
2550   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2551   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2552                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2553   if test $ac_cv_prog_liblockfile = yes; then
2554     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2555 This probably means that movemail could lose mail.
2556 There may be a `development' package to install containing liblockfile.])
2557   fi
2558 fi
2559 AC_CHECK_FUNCS(touchlock)
2560 AC_CHECK_HEADERS(maillock.h)
2561 AC_SUBST(LIBS_MAIL)
2562
2563 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2564 ## interlock access to the mail spool.  The alternative is a lock file named
2565 ## /usr/spool/mail/$USER.lock.
2566 mail_lock=no
2567 case "$opsys" in
2568   aix4-2) mail_lock="lockf" ;;
2569
2570   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2571
2572   ## On GNU/Linux systems, both methods are used by various mail programs.
2573   ## I assume most people are using newer mailers that have heard of flock.
2574   ## Change this if you need to.
2575   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2576   ## configure gets the right answers, and that means *NOT* using flock.
2577   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2578   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2579   ## Debian maintainer hasn't provided a clean fix for Emacs.
2580   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2581   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2582   ## correct logic.  -- fx
2583   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2584   ## liblockfile is a Free Software replacement for libmail, used on
2585   ## Debian systems and elsewhere. -rfr.
2586   gnu-*)
2587     mail_lock="flock"
2588     if test $have_mail = yes || test $have_lockfile = yes; then
2589       test $ac_cv_header_maillock_h = yes && mail_lock=no
2590     fi
2591     ;;
2592 esac
2593
2594 BLESSMAIL_TARGET=
2595 case "$mail_lock" in
2596   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2597
2598   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2599
2600   *) BLESSMAIL_TARGET="need-blessmail" ;;
2601 esac
2602 AC_SUBST(BLESSMAIL_TARGET)
2603
2604
2605 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2606 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2607 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2608 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2609 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2610 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2611 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2612 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2613 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2614 cfmakeraw cfsetspeed isnan copysign __executable_start)
2615
2616 AC_CHECK_HEADERS(sys/un.h)
2617
2618 AC_FUNC_MKTIME
2619 if test "$ac_cv_func_working_mktime" = no; then
2620   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2621 fi
2622
2623 AC_FUNC_GETLOADAVG
2624
2625 AC_FUNC_FSEEKO
2626
2627 # Configure getopt.
2628 m4_include([m4/getopt.m4])
2629 gl_GETOPT_IFELSE([
2630   gl_GETOPT_SUBSTITUTE_HEADER
2631   gl_PREREQ_GETOPT
2632   GETOPTOBJS='getopt.o getopt1.o'
2633 ])
2634 AC_SUBST(GETOPTOBJS)
2635
2636 AC_FUNC_GETPGRP
2637
2638 AC_FUNC_STRFTIME
2639
2640 # UNIX98 PTYs.
2641 AC_CHECK_FUNCS(grantpt)
2642
2643 # PTY-related GNU extensions.
2644 AC_CHECK_FUNCS(getpt)
2645
2646 # Check this now, so that we will NOT find the above functions in ncurses.
2647 # That is because we have not set up to link ncurses in lib-src.
2648 # It's better to believe a function is not available
2649 # than to expect to find it in ncurses.
2650 # Also we need tputs and friends to be able to build at all.
2651 have_tputs_et_al=true
2652 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2653 if test "$have_tputs_et_al" != true; then
2654   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2655 Maybe some development libraries/packages are missing?  Try installing
2656 libncurses-dev(el), libterminfo-dev(el) or similar.])
2657 fi
2658 # Must define this when any termcap library is found.
2659 AC_DEFINE(HAVE_LIBNCURSES, 1,
2660           [Define to 1 if you have the `ncurses' library (-lncurses).])
2661 ## FIXME This was the cpp logic, but I am not sure it is right.
2662 ## The above test has not necessarily found libncurses.
2663 HAVE_LIBNCURSES=yes
2664
2665 ## Use terminfo instead of termcap?
2666 ## Note only system files NOT using terminfo are:
2667 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2668 ## darwin|gnu without ncurses.
2669 TERMINFO=no
2670 LIBS_TERMCAP=
2671 case "$opsys" in
2672   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2673   ## hpux10-20: Use the system provided termcap(3) library.
2674   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2675   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2676   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2677
2678   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2679   ##  The ncurses library has been moved out of the System framework in
2680   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2681   ##  option to use it.
2682   darwin|gnu*)
2683     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2684     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2685       TERMINFO=yes
2686       LIBS_TERMCAP="-lncurses"
2687     fi
2688     ;;
2689
2690   freebsd)
2691     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2692     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2693     [AC_TRY_LINK([#include <osreldate.h>],
2694 [#if __FreeBSD_version < 400000
2695 fail;
2696 #endif
2697 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2698
2699     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2700
2701     if test $emacs_cv_freebsd_terminfo = yes; then
2702       TERMINFO=yes
2703       LIBS_TERMCAP="-lncurses"
2704     else
2705       LIBS_TERMCAP="-ltermcap"
2706     fi
2707     ;;
2708
2709   netbsd)
2710     if test $ac_cv_search_tputs = -lterminfo; then
2711       TERMINFO=yes
2712       LIBS_TERMCAP="-lterminfo"
2713     else
2714       LIBS_TERMCAP="-ltermcap"
2715     fi
2716     ;;
2717
2718 esac
2719
2720 case "$opsys" in
2721   ## hpux: Make sure we get select from libc rather than from libcurses
2722   ##  because libcurses on HPUX 10.10 has a broken version of select.
2723   ##  We used to use -lc -lcurses, but this may be cleaner.
2724   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2725
2726   openbsd) LIBS_TERMCAP="-lncurses" ;;
2727
2728   ## Must use system termcap, if we use any termcap.  It does special things.
2729   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2730 esac
2731
2732 TERMCAP_OBJ=tparam.o
2733 if test $TERMINFO = yes; then
2734   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2735
2736   ## Default used to be -ltermcap.  Add a case above if need something else.
2737   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2738
2739   TERMCAP_OBJ=terminfo.o
2740 fi
2741 AC_SUBST(LIBS_TERMCAP)
2742 AC_SUBST(TERMCAP_OBJ)
2743
2744
2745 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2746 resolv=no
2747 AC_TRY_LINK([#include <netinet/in.h>
2748 #include <arpa/nameser.h>
2749 #include <resolv.h>],
2750     [return res_init();],
2751     have_res_init=yes, have_res_init=no)
2752 if test "$have_res_init" = no; then
2753   OLIBS="$LIBS"
2754   LIBS="$LIBS -lresolv"
2755   AC_MSG_CHECKING(for res_init with -lresolv)
2756   AC_TRY_LINK([#include <netinet/in.h>
2757 #include <arpa/nameser.h>
2758 #include <resolv.h>],
2759     [return res_init();],
2760     have_res_init=yes, have_res_init=no)
2761   AC_MSG_RESULT($have_res_init)
2762   if test "$have_res_init" = yes ; then
2763     resolv=yes
2764   fi
2765   LIBS="$OLIBS"
2766 fi
2767
2768 if test "$have_res_init" = yes; then
2769   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2770 fi
2771
2772 # Do we need the Hesiod library to provide the support routines?
2773 LIBHESIOD=
2774 if test "$with_hesiod" != no ; then
2775   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2776   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2777      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2778                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2779   if test "$resolv" = yes ; then
2780     RESOLVLIB=-lresolv
2781   else
2782     RESOLVLIB=
2783   fi
2784   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2785         hesiod=yes, :, $RESOLVLIB)])
2786
2787   if test x"$hesiod" = xyes; then
2788     AC_DEFINE(HAVE_LIBHESIOD, 1,
2789               [Define to 1 if you have the hesiod library (-lhesiod).])
2790     LIBHESIOD=-lhesiod
2791   fi
2792 fi
2793 AC_SUBST(LIBHESIOD)
2794
2795 # Do we need libresolv (due to res_init or Hesiod)?
2796 if test "$resolv" = yes ; then
2797   AC_DEFINE(HAVE_LIBRESOLV, 1,
2798             [Define to 1 if you have the resolv library (-lresolv).])
2799   LIBRESOLV=-lresolv
2800 else
2801   LIBRESOLV=
2802 fi
2803 AC_SUBST(LIBRESOLV)
2804
2805 # These tell us which Kerberos-related libraries to use.
2806 COM_ERRLIB=
2807 CRYPTOLIB=
2808 KRB5LIB=
2809 DESLIB=
2810 KRB4LIB=
2811
2812 if test "${with_kerberos}" != no; then
2813   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2814   if test $have_com_err = yes; then
2815     COM_ERRLIB=-lcom_err
2816     LIBS="$COM_ERRLIB $LIBS"
2817     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2818   fi
2819   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2820   if test $have_crypto = yes; then
2821     CRYPTOLIB=-lcrypto
2822     LIBS="$CRYPTOLIB $LIBS"
2823     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2824   fi
2825   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2826   if test $have_k5crypto = yes; then
2827     CRYPTOLIB=-lk5crypto
2828     LIBS="$CRYPTOLIB $LIBS"
2829     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2830   fi
2831   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2832   if test $have_krb5=yes; then
2833     KRB5LIB=-lkrb5
2834     LIBS="$KRB5LIB $LIBS"
2835     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2836   fi
2837   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2838   if test "${with_kerberos5}" = no; then
2839     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2840     if test $have_des425 = yes; then
2841       DESLIB=-ldes425
2842       LIBS="$DESLIB $LIBS"
2843       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2844     else
2845       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2846       if test $have_des = yes; then
2847         DESLIB=-ldes
2848         LIBS="$DESLIB $LIBS"
2849         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2850       fi
2851     fi
2852     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2853     if test $have_krb4 = yes; then
2854       KRB4LIB=-lkrb4
2855       LIBS="$KRB4LIB $LIBS"
2856       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2857     else
2858       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2859       if test $have_krb = yes; then
2860         KRB4LIB=-lkrb
2861         LIBS="$KRB4LIB $LIBS"
2862         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2863       fi
2864     fi
2865   fi
2866
2867   if test "${with_kerberos5}" != no; then
2868     AC_CHECK_HEADERS(krb5.h,
2869       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2870                         [#include <krb5.h>])])
2871   else
2872     AC_CHECK_HEADERS(des.h,,
2873                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2874                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2875     AC_CHECK_HEADERS(krb.h,,
2876                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2877                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2878   fi
2879   AC_CHECK_HEADERS(com_err.h)
2880 fi
2881
2882 AC_SUBST(COM_ERRLIB)
2883 AC_SUBST(CRYPTOLIB)
2884 AC_SUBST(KRB5LIB)
2885 AC_SUBST(DESLIB)
2886 AC_SUBST(KRB4LIB)
2887
2888 # Solaris requires -lintl if you want strerror (which calls dgettext)
2889 # to return localized messages.
2890 AC_CHECK_LIB(intl, dgettext)
2891
2892 AC_MSG_CHECKING(whether localtime caches TZ)
2893 AC_CACHE_VAL(emacs_cv_localtime_cache,
2894 [if test x$ac_cv_func_tzset = xyes; then
2895 AC_TRY_RUN([#include <time.h>
2896 extern char **environ;
2897 unset_TZ ()
2898 {
2899   char **from, **to;
2900   for (to = from = environ; (*to = *from); from++)
2901     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2902       to++;
2903 }
2904 char TZ_GMT0[] = "TZ=GMT0";
2905 char TZ_PST8[] = "TZ=PST8";
2906 main()
2907 {
2908   time_t now = time ((time_t *) 0);
2909   int hour_GMT0, hour_unset;
2910   if (putenv (TZ_GMT0) != 0)
2911     exit (1);
2912   hour_GMT0 = localtime (&now)->tm_hour;
2913   unset_TZ ();
2914   hour_unset = localtime (&now)->tm_hour;
2915   if (putenv (TZ_PST8) != 0)
2916     exit (1);
2917   if (localtime (&now)->tm_hour == hour_GMT0)
2918     exit (1);
2919   unset_TZ ();
2920   if (localtime (&now)->tm_hour != hour_unset)
2921     exit (1);
2922   exit (0);
2923 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2924 [# If we have tzset, assume the worst when cross-compiling.
2925 emacs_cv_localtime_cache=yes])
2926 else
2927         # If we lack tzset, report that localtime does not cache TZ,
2928         # since we can't invalidate the cache if we don't have tzset.
2929         emacs_cv_localtime_cache=no
2930 fi])dnl
2931 AC_MSG_RESULT($emacs_cv_localtime_cache)
2932 if test $emacs_cv_localtime_cache = yes; then
2933   AC_DEFINE(LOCALTIME_CACHE, 1,
2934             [Define to 1 if localtime caches TZ.])
2935 fi
2936
2937 if test "x$HAVE_TIMEVAL" = xyes; then
2938   AC_CHECK_FUNCS(gettimeofday)
2939   if test $ac_cv_func_gettimeofday = yes; then
2940     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2941                    emacs_cv_gettimeofday_two_arguments,
2942     [AC_TRY_COMPILE([
2943 #ifdef TIME_WITH_SYS_TIME
2944 #include <sys/time.h>
2945 #include <time.h>
2946 #else
2947 #ifdef HAVE_SYS_TIME_H
2948 #include <sys/time.h>
2949 #else
2950 #include <time.h>
2951 #endif
2952 #endif],
2953       [struct timeval time;
2954        gettimeofday (&time, 0);],
2955       emacs_cv_gettimeofday_two_arguments=yes,
2956       emacs_cv_gettimeofday_two_arguments=no)])
2957     if test $emacs_cv_gettimeofday_two_arguments = no; then
2958       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2959                 [Define to 1 if gettimeofday accepts only one argument.])
2960     fi
2961   fi
2962 fi
2963
2964 ok_so_far=yes
2965 AC_CHECK_FUNC(socket, , ok_so_far=no)
2966 if test $ok_so_far = yes; then
2967   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2968 fi
2969 if test $ok_so_far = yes; then
2970   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2971 fi
2972 if test $ok_so_far = yes; then
2973 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2974   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2975             [Define to 1 if you have inet sockets.])
2976 fi
2977
2978 AC_CHECK_HEADERS(sys/ioctl.h)
2979
2980 if test -f /usr/lpp/X11/bin/smt.exp; then
2981   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2982             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2983 fi
2984
2985 AC_MSG_CHECKING(whether system supports dynamic ptys)
2986 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2987   AC_MSG_RESULT(yes)
2988   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2989 else
2990   AC_MSG_RESULT(no)
2991 fi
2992
2993 AC_FUNC_FORK
2994
2995 dnl Adapted from Haible's version.
2996 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2997   [AC_TRY_LINK([#include <langinfo.h>],
2998     [char* cs = nl_langinfo(CODESET);],
2999     emacs_cv_langinfo_codeset=yes,
3000     emacs_cv_langinfo_codeset=no)
3001   ])
3002 if test $emacs_cv_langinfo_codeset = yes; then
3003   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3004     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3005 fi
3006
3007 AC_CHECK_TYPES(size_t)
3008
3009 AC_TYPE_MBSTATE_T
3010
3011 dnl Restrict could probably be used effectively other than in regex.c.
3012 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3013   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3014                   emacs_cv_c_restrict=yes,
3015                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3016                                   emacs_cv_c_restrict=__restrict,
3017                                   emacs_cv_c_restrict=no)])])
3018 case "$emacs_cv_c_restrict" in
3019   yes) emacs_restrict=restrict;;
3020   no) emacs_restrict="";;
3021   *) emacs_restrict="$emacs_cv_c_restrict";;
3022 esac
3023 if test "$emacs_restrict" != __restrict; then
3024   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3025     [Define to compiler's equivalent of C99 restrict keyword.
3026      Don't define if equivalent is `__restrict'.])
3027 fi
3028
3029 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3030   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3031                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3032 if test "$emacs_cv_c_restrict_arr" = yes; then
3033   AC_DEFINE(__restrict_arr, __restrict,
3034     [Define to compiler's equivalent of C99 restrict keyword in array
3035      declarations.  Define as empty for no equivalent.])
3036 fi
3037
3038 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3039 dnl how the tty code is related to POSIX and/or other versions of termios.
3040 dnl The following looks like a useful start.
3041 dnl
3042 dnl AC_SYS_POSIX_TERMIOS
3043 dnl if test $ac_cv_sys_posix_termios = yes; then
3044 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3045 dnl                                and macros for terminal control.])
3046 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3047 dnl fi
3048
3049 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3050
3051 # Set up the CFLAGS for real compilation, so we can substitute it.
3052 CFLAGS="$REAL_CFLAGS"
3053 CPPFLAGS="$REAL_CPPFLAGS"
3054
3055 ## Hack to detect a buggy GCC version.
3056 if test "x$GCC" = xyes \
3057    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3058    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3059    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3060    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3061 fi
3062
3063 #### Find out which version of Emacs this is.
3064 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3065          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3066 if test x"${version}" = x; then
3067   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3068 fi
3069 if test x"${version}" != x"$PACKAGE_VERSION"; then
3070   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3071 fi
3072
3073 ### Specify what sort of things we'll be editing into Makefile and config.h.
3074 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3075 AC_SUBST(version)
3076 AC_SUBST(configuration)
3077 ## Unused?
3078 AC_SUBST(canonical)
3079 AC_SUBST(srcdir)
3080 AC_SUBST(prefix)
3081 AC_SUBST(exec_prefix)
3082 AC_SUBST(bindir)
3083 AC_SUBST(datadir)
3084 AC_SUBST(sharedstatedir)
3085 AC_SUBST(libexecdir)
3086 AC_SUBST(mandir)
3087 AC_SUBST(infodir)
3088 AC_SUBST(lispdir)
3089 AC_SUBST(locallisppath)
3090 AC_SUBST(lisppath)
3091 AC_SUBST(x_default_search_path)
3092 AC_SUBST(etcdir)
3093 AC_SUBST(archlibdir)
3094 AC_SUBST(docdir)
3095 AC_SUBST(bitmapdir)
3096 AC_SUBST(gamedir)
3097 AC_SUBST(gameuser)
3098 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3099 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3100 ## end of LIBX_BASE, but nothing ever set it.
3101 AC_SUBST(LD_SWITCH_X_SITE)
3102 AC_SUBST(C_SWITCH_X_SITE)
3103 AC_SUBST(C_SWITCH_X_SYSTEM)
3104 AC_SUBST(CFLAGS)
3105 ## Used in lwlib/Makefile.in.
3106 AC_SUBST(X_TOOLKIT_TYPE)
3107 AC_SUBST(machfile)
3108 AC_SUBST(opsysfile)
3109 AC_SUBST(GETLOADAVG_LIBS)
3110 AC_SUBST(ns_appdir)
3111 AC_SUBST(ns_appbindir)
3112 AC_SUBST(ns_appresdir)
3113 AC_SUBST(ns_appsrc)
3114 AC_SUBST(GNU_OBJC_CFLAGS)
3115 AC_SUBST(OTHER_FILES)
3116
3117 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3118                    [Define to the canonical Emacs configuration name.])
3119 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3120                    [Define to the options passed to configure.])
3121 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3122                    [Define to the used machine dependent file.])
3123 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3124                    [Define to the used os dependent file.])
3125
3126 XMENU_OBJ=
3127 XOBJ=
3128 FONT_OBJ=
3129 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3130   AC_DEFINE(HAVE_X_WINDOWS, 1,
3131             [Define to 1 if you want to use the X window system.])
3132   XMENU_OBJ=xmenu.o
3133   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3134   FONT_OBJ=xfont.o
3135   if test "$HAVE_XFT" = "yes"; then
3136     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3137   elif test "$HAVE_FREETYPE" = "yes"; then
3138     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3139   fi
3140   AC_SUBST(FONT_OBJ)
3141 fi
3142 AC_SUBST(XMENU_OBJ)
3143 AC_SUBST(XOBJ)
3144 AC_SUBST(FONT_OBJ)
3145
3146 WIDGET_OBJ=
3147 MOTIF_LIBW=
3148 if test "${USE_X_TOOLKIT}" != "none" ; then
3149   WIDGET_OBJ=widget.o
3150   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3151   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3152     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3153   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3154     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3155     MOTIF_LIBW=-lXm
3156     case "$opsys" in
3157       gnu-linux)
3158         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3159         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3160         ;;
3161
3162       unixware)
3163         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3164         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3165         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3166         ;;
3167
3168       aix4-2)
3169         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3170         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3171         ;;
3172     esac
3173     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3174   fi
3175 fi
3176 AC_SUBST(WIDGET_OBJ)
3177
3178 TOOLKIT_LIBW=
3179 case "$USE_X_TOOLKIT" in
3180   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3181   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3182   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3183 esac
3184 AC_SUBST(TOOLKIT_LIBW)
3185
3186 if test "$USE_X_TOOLKIT" = "none"; then
3187   LIBXT_OTHER="\$(LIBXSM)"
3188   OLDXMENU_TARGET="really-oldXMenu"
3189 else
3190   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3191   OLDXMENU_TARGET="really-lwlib"
3192 fi
3193 AC_SUBST(LIBXT_OTHER)
3194
3195 ## The X Menu stuff is present in the X10 distribution, but missing
3196 ## from X11.  If we have X10, just use the installed library;
3197 ## otherwise, use our own copy.
3198 if test "${HAVE_X11}" = "yes" ; then
3199   AC_DEFINE(HAVE_X11, 1,
3200             [Define to 1 if you want to use version 11 of X windows.
3201              Otherwise, Emacs expects to use version 10.])
3202
3203   if test "$USE_X_TOOLKIT" = "none"; then
3204     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3205   else
3206     OLDXMENU="\${lwlibdir}liblw.a"
3207   fi
3208   LIBXMENU="\$(OLDXMENU)"
3209   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3210   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3211 else
3212   ## For a syntactically valid Makefile; not actually used for anything.
3213   ## See comments in src/Makefile.in.
3214   OLDXMENU=nothing
3215   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3216   if test "${HAVE_X_WINDOWS}" = "yes"; then
3217     LIBXMENU="-lXMenu"
3218   else
3219     LIBXMENU=
3220   fi
3221   LIBX_OTHER=
3222   OLDXMENU_DEPS=
3223 fi
3224
3225 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3226   OLDXMENU_TARGET=
3227   OLDXMENU=nothing
3228   LIBXMENU=
3229   OLDXMENU_DEPS=
3230 fi
3231
3232 AC_SUBST(OLDXMENU_TARGET)
3233 AC_SUBST(OLDXMENU)
3234 AC_SUBST(LIBXMENU)
3235 AC_SUBST(LIBX_OTHER)
3236 AC_SUBST(OLDXMENU_DEPS)
3237
3238 if test "${HAVE_MENUS}" = "yes" ; then
3239   AC_DEFINE(HAVE_MENUS, 1,
3240             [Define to 1 if you have mouse menus.
3241              (This is automatic if you use X, but the option to specify it remains.)
3242              It is also defined with other window systems that support xmenu.c.])
3243 fi
3244
3245 if test "${GNU_MALLOC}" = "yes" ; then
3246   AC_DEFINE(GNU_MALLOC, 1,
3247             [Define to 1 if you want to use the GNU memory allocator.])
3248 fi
3249
3250 RALLOC_OBJ=
3251 if test "${REL_ALLOC}" = "yes" ; then
3252   AC_DEFINE(REL_ALLOC, 1,
3253             [Define REL_ALLOC if you want to use the relocating allocator for
3254              buffer space.])
3255
3256   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3257 fi
3258 AC_SUBST(RALLOC_OBJ)
3259
3260 if test "$opsys" = "cygwin"; then
3261   CYGWIN_OBJ="sheap.o"
3262   ## Cygwin differs because of its unexec().
3263   PRE_ALLOC_OBJ=
3264   POST_ALLOC_OBJ=lastfile.o
3265 else
3266   CYGWIN_OBJ=
3267   PRE_ALLOC_OBJ=lastfile.o
3268   POST_ALLOC_OBJ=
3269 fi
3270 AC_SUBST(CYGWIN_OBJ)
3271 AC_SUBST(PRE_ALLOC_OBJ)
3272 AC_SUBST(POST_ALLOC_OBJ)
3273
3274
3275 case "$opsys" in
3276   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3277
3278   darwin)
3279    ## The -headerpad option tells ld (see man page) to leave room at the
3280    ## end of the header for adding load commands.  Needed for dumping.
3281    ## 0x690 is the total size of 30 segment load commands (at 56
3282    ## each); under Cocoa 31 commands are required.
3283    if test "$HAVE_NS" = "yes"; then
3284      libs_nsgui="-framework AppKit"
3285      headerpad_extra=6C8
3286    else
3287      libs_nsgui=
3288      headerpad_extra=690
3289    fi
3290    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3291
3292    ## This is here because src/Makefile.in did some extra fiddling around
3293    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3294    ##   #ifndef LD_SWITCH_SYSTEM
3295    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3296    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3297    ## not using gcc, darwin system not on an alpha (ie darwin, since
3298    ## darwin + alpha does not occur).
3299    ## Because this was done in src/Makefile.in, the resulting part of
3300    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3301    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3302    ## rather than LD_SWITCH_SYSTEM.
3303    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3304      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3305    ;;
3306
3307   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3308   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3309   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3310   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3311   ## had different values in configure (in ac_link) and src/Makefile.in.
3312   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3313   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3314
3315   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3316 esac
3317
3318 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3319   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3320 fi
3321
3322 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3323
3324
3325 LINKER=
3326 ORDINARY_LINK=
3327 case "$opsys" in
3328   ## gnu: GNU needs its own crt0.
3329   aix4-2|cygwin|darwin|gnu|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3330
3331   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3332   ## library search parth, i.e. it won't search /usr/lib for libc and
3333   ## friends.  Using -nostartfiles instead avoids this problem, and
3334   ## will also work on earlier NetBSD releases.
3335   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3336
3337   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3338   ##   MkLinux/LinuxPPC needs this.
3339   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3340   gnu-*)
3341     case "$machine" in
3342       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3343     esac
3344     ;;
3345 esac
3346
3347
3348 if test "x$ORDINARY_LINK" = "xyes"; then
3349
3350   LINKER="\$(CC)"
3351   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3352
3353 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3354 ## (bsd-common), freebsd, gnu-* not on macppc|ibms390x, hpux*.
3355 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3356
3357   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3358   ## places that are difficult to figure out at make time.  Fortunately,
3359   ## these same versions allow you to pass arbitrary flags on to the
3360   ## linker, so there is no reason not to use it as a linker.
3361   ##
3362   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3363   ## searching for libraries in its internal directories, so we have to
3364   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3365   LINKER="\$(CC) -nostdlib"
3366 fi
3367
3368 test "x$LINKER" = "x" && LINKER=ld
3369 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3370 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3371
3372 AC_SUBST(LINKER)
3373
3374
3375 ## FIXME? The logic here is not precisely the same as that above.
3376 ## There is no check here for a pre-defined LINKER.
3377 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3378 LIB_GCC=
3379 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3380
3381   case "$opsys" in
3382     freebsd|netbsd|openbsd) LIB_GCC= ;;
3383
3384     gnu-*)
3385       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3386       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3387       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3388       if test "$machine" = "arm"; then
3389         LIB_GCC="-lgcc_s"
3390       else
3391         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3392         ## immediately undefine it again and redefine it to empty.
3393         ## Was the C_SWITCH_X_SITE part really necessary?
3394 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3395         LIB_GCC=
3396       fi
3397       ;;
3398
3399     ## Ask GCC where to find libgcc.a.
3400     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3401   esac
3402 fi                              dnl if $GCC
3403 AC_SUBST(LIB_GCC)
3404
3405
3406 TOOLTIP_SUPPORT=
3407 WINDOW_SUPPORT=
3408 ## If we're using X11/GNUstep, define some consequences.
3409 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3410   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3411   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3412   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3413   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3414
3415   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3416   test "$HAVE_X_WINDOWS" = "yes" && \
3417     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3418
3419 fi
3420 AC_SUBST(MOUSE_SUPPORT)
3421 AC_SUBST(TOOLTIP_SUPPORT)
3422 AC_SUBST(WINDOW_SUPPORT)
3423
3424
3425 AH_TOP([/* GNU Emacs site configuration template file.
3426    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3427      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3428
3429 This file is part of GNU Emacs.
3430
3431 GNU Emacs is free software: you can redistribute it and/or modify
3432 it under the terms of the GNU General Public License as published by
3433 the Free Software Foundation, either version 3 of the License, or
3434 (at your option) any later version.
3435
3436 GNU Emacs is distributed in the hope that it will be useful,
3437 but WITHOUT ANY WARRANTY; without even the implied warranty of
3438 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3439 GNU General Public License for more details.
3440
3441 You should have received a copy of the GNU General Public License
3442 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3443
3444
3445 /* No code in Emacs #includes config.h twice, but some bits of code
3446    intended to work with other packages as well (like gmalloc.c)
3447    think they can include it as many times as they like.  */
3448 #ifndef EMACS_CONFIG_H
3449 #define EMACS_CONFIG_H
3450 ])dnl
3451
3452 AH_BOTTOM([
3453 /* Define AMPERSAND_FULL_NAME if you use the convention
3454    that & in the full name stands for the login id.  */
3455 /* Turned on June 1996 supposing nobody will mind it.  */
3456 #define AMPERSAND_FULL_NAME
3457
3458 /* If using GNU, then support inline function declarations.  */
3459 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3460    generally, because even if non-gcc compilers accept `inline', they
3461    may reject `extern inline'.  */
3462 #if defined (__GNUC__) && defined (OPTIMIZE)
3463 #define INLINE __inline__
3464 #else
3465 #define INLINE
3466 #endif
3467
3468 /* `subprocesses' should be defined if you want to
3469    have code for asynchronous subprocesses
3470    (as used in M-x compile and M-x shell).
3471    Only MSDOS does not support this (it overrides
3472    this in its config_opsysfile below).  */
3473
3474 #define subprocesses
3475
3476 /* Include the os and machine dependent files.  */
3477 #include config_opsysfile
3478 #include config_machfile
3479
3480 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3481   (There is probably a better place to do this, but right now the Cocoa
3482    side does this in s/darwin.h and we cannot
3483    parallel this exactly since GNUstep is multi-OS.  */
3484 #ifdef HAVE_NS
3485 # ifdef NS_IMPL_GNUSTEP
3486 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3487 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3488 #  define SYSTEM_PURESIZE_EXTRA 30000
3489 # endif /* NS_IMPL_GNUSTEP */
3490 #endif /* HAVE_NS */
3491
3492 /* SIGTYPE is the macro we actually use.  */
3493 #ifndef SIGTYPE
3494 #define SIGTYPE RETSIGTYPE
3495 #endif
3496
3497 #ifdef emacs /* Don't do this for lib-src.  */
3498 /* Tell regex.c to use a type compatible with Emacs.  */
3499 #define RE_TRANSLATE_TYPE Lisp_Object
3500 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3501 #ifdef make_number
3502 /* If make_number is a macro, use it.  */
3503 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3504 #else
3505 /* If make_number is a function, avoid it.  */
3506 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3507 #endif
3508 #endif
3509
3510 /* Avoid link-time collision with system mktime if we will use our own.  */
3511 #if ! HAVE_MKTIME || BROKEN_MKTIME
3512 #define mktime emacs_mktime
3513 #endif
3514
3515 #define my_strftime nstrftime   /* for strftime.c */
3516
3517 /* These default definitions are good for almost all machines.
3518    The exceptions override them in m/MACHINE.h.  */
3519
3520 #ifndef BITS_PER_CHAR
3521 #define BITS_PER_CHAR 8
3522 #endif
3523
3524 #ifndef BITS_PER_SHORT
3525 #define BITS_PER_SHORT 16
3526 #endif
3527
3528 /* Note that lisp.h uses this in a preprocessor conditional, so it
3529    would not work to use sizeof.  That being so, we do all of them
3530    without sizeof, for uniformity's sake.  */
3531 #ifndef BITS_PER_INT
3532 #define BITS_PER_INT 32
3533 #endif
3534
3535 #ifndef BITS_PER_LONG
3536 #ifdef _LP64
3537 #define BITS_PER_LONG 64
3538 #else
3539 #define BITS_PER_LONG 32
3540 #endif
3541 #endif
3542
3543 /* Define if the compiler supports function prototypes.  It may do so but
3544    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3545 #undef PROTOTYPES
3546
3547 #ifdef HAVE_STRING_H
3548 #include <string.h>
3549 #endif
3550
3551 #ifdef HAVE_STDLIB_H
3552 #include <stdlib.h>
3553 #endif
3554
3555 #ifdef HAVE_ALLOCA_H
3556 # include <alloca.h>
3557 #elif defined __GNUC__
3558 # define alloca __builtin_alloca
3559 #elif defined _AIX
3560 # define alloca __alloca
3561 #else
3562 # include <stddef.h>
3563 # ifdef  __cplusplus
3564 extern "C"
3565 # endif
3566 void *alloca (size_t);
3567 #endif
3568
3569 #ifndef HAVE_SIZE_T
3570 typedef unsigned size_t;
3571 #endif
3572
3573 #ifndef HAVE_STRCHR
3574 #define strchr(a, b) index (a, b)
3575 #endif
3576
3577 #ifndef HAVE_STRRCHR
3578 #define strrchr(a, b) rindex (a, b)
3579 #endif
3580
3581 #if defined __GNUC__ && (__GNUC__ > 2 \
3582                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3583 #define NO_RETURN       __attribute__ ((__noreturn__))
3584 #else
3585 #define NO_RETURN       /* nothing */
3586 #endif
3587
3588 /* These won't be used automatically yet.  We also need to know, at least,
3589    that the stack is continuous.  */
3590 #ifdef __GNUC__
3591 #  ifndef GC_SETJMP_WORKS
3592   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3593 #    define GC_SETJMP_WORKS 1
3594 #  endif
3595 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3596 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3597 #  endif
3598 #endif
3599
3600 #endif /* EMACS_CONFIG_H */
3601
3602 /*
3603 Local Variables:
3604 mode: c
3605 End:
3606 */
3607 ])dnl
3608
3609 #### Report on what we decided to do.
3610 #### Report GTK as a toolkit, even if it doesn't use Xt.
3611 #### It makes printing result more understandable as using GTK sets
3612 #### toolkit_scroll_bars to yes by default.
3613 if test "${HAVE_GTK}" = "yes"; then
3614   USE_X_TOOLKIT=GTK
3615 fi
3616
3617 echo "
3618 Configured for \`${canonical}'.
3619
3620   Where should the build process find the source code?    ${srcdir}
3621   What operating system and machine description files should Emacs use?
3622         \`${opsysfile}' and \`${machfile}'
3623   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3624   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3625   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3626   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3627   What window system should Emacs use?                    ${window_system}
3628   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3629
3630 if test -n "${x_includes}"; then
3631 echo "  Where do we find X Windows header files?                ${x_includes}"
3632 else
3633 echo "  Where do we find X Windows header files?                Standard dirs"
3634 fi
3635 if test -n "${x_libraries}"; then
3636 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3637 else
3638 echo "  Where do we find X Windows libraries?                   Standard dirs"
3639 fi
3640
3641 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3642 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3643 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3644 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3645 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3646 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3647 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3648 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3649 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3650 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3651 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3652
3653 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3654 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3655 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3656 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3657
3658 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3659 echo
3660
3661 if test $USE_XASSERTS = yes; then
3662    echo "  Compiling with asserts turned on."
3663    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3664 fi
3665
3666 echo
3667
3668 if test "$HAVE_NS" = "yes"; then
3669    echo
3670    echo "You must run \"make install\" in order to test the built application.
3671 The installed application will go to nextstep/Emacs.app and can be
3672 run or moved from there."
3673    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3674       echo "The application will be fully self-contained."
3675     else
3676       echo "The lisp resources for the application will be installed under ${prefix}.
3677 You may need to run \"make install\" with sudo.  The application will fail
3678 to run if these resources are not installed."
3679    fi
3680    echo
3681 fi
3682
3683 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3684   echo "D-Bus integration has been tested for GNU/Linux only."
3685   echo
3686 fi
3687
3688
3689 # Remove any trailing slashes in these variables.
3690 [test "${prefix}" != NONE &&
3691   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3692 test "${exec_prefix}" != NONE &&
3693   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3694
3695 dnl You might wonder (I did) why epaths.h is generated by running make,
3696 dnl rather than just letting configure generate it from epaths.in.
3697 dnl One reason is that the various paths are not fully expanded (see above);
3698 dnl eg gamedir=${prefix}/var/games/emacs.
3699 dnl Secondly, the GNU Coding standards require that one should be able
3700 dnl to run `make prefix=/some/where/else' and override the values set
3701 dnl by configure.  This also explains the `move-if-change' test and
3702 dnl the use of force in the `epaths-force' rule in Makefile.in.
3703 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3704         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3705         doc/lispref/Makefile src/Makefile \
3706         lwlib/Makefile lisp/Makefile leim/Makefile, [
3707
3708 ### Make the necessary directories, if they don't exist.
3709 for dir in etc lisp ; do
3710   test -d ${dir} || mkdir ${dir}
3711 done
3712
3713 echo creating src/epaths.h
3714 ${MAKE-make} epaths-force
3715
3716 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3717   echo creating src/.gdbinit
3718   echo source $srcdir/src/.gdbinit > src/.gdbinit
3719 fi
3720
3721 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3722
3723 m4_if(dnl       Do not change this comment
3724    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3725 )dnl