lisp/net/eudcb-bbdb.el

   1 ;;; eudcb-bbdb.el --- Emacs Unified Directory Client - BBDB Backend
   2
   3 ;; Copyright (C) 1998-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Oscar Figueiredo <oscar@cpe.fr>
   6 ;; Maintainer: Pavel Janík <Pavel@Janik.cz>
   7 ;; Keywords: comm
   8 ;; Package: eudc
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26 ;;    This library provides an interface to use BBDB as a backend of
  27 ;;    the Emacs Unified Directory Client.
  28
  29 ;;; Code:
  30
  31 (require 'eudc)
  32 (if (not (featurep 'bbdb))
  33     (load-library "bbdb"))
  34 (if (not (featurep 'bbdb-com))
  35     (load-library "bbdb-com"))
  36
  37 ;;{{{      Internal cooking
  38
  39 ;; I don't like this but mapcar does not accept a parameter to the function and
  40 ;; I don't want to use mapcar*
  41 (defvar eudc-bbdb-current-query nil)
  42 (defvar eudc-bbdb-current-return-attributes nil)
  43
  44 (defvar eudc-bbdb-attributes-translation-alist
  45   '((name . lastname)
  46     (email . net)
  47     (phone . phones))
  48   "Alist mapping EUDC attribute names to BBDB names.")
  49
  50 (eudc-protocol-set 'eudc-query-function 'eudc-bbdb-query-internal 'bbdb)
  51 (eudc-protocol-set 'eudc-list-attributes-function nil 'bbdb)
  52 (eudc-protocol-set 'eudc-protocol-attributes-translation-alist
  53                    'eudc-bbdb-attributes-translation-alist 'bbdb)
  54 (eudc-protocol-set 'eudc-bbdb-conversion-alist nil 'bbdb)
  55 (eudc-protocol-set 'eudc-protocol-has-default-query-attributes nil 'bbdb)
  56
  57 (defun eudc-bbdb-format-query (query)
  58   "Format a EUDC query alist into a list suitable to `bbdb-search'."
  59   (let* ((firstname (cdr (assq 'firstname query)))
  60          (lastname (cdr (assq 'lastname query)))
  61          (name (or (and firstname lastname
  62                         (concat firstname " " lastname))
  63                    firstname
  64                    lastname))
  65         (company (cdr (assq 'company query)))
  66         (net (cdr (assq 'net query)))
  67         (notes (cdr (assq 'notes query)))
  68         (phone (cdr (assq 'phone query))))
  69     (list name company net notes phone)))
  70
  71
  72 (defun eudc-bbdb-filter-non-matching-record (record)
  73   "Return RECORD if it matches `eudc-bbdb-current-query', nil otherwise."
  74   (catch 'unmatch
  75     (progn
  76       (dolist (condition eudc-bbdb-current-query)
  77         (let ((attr (car condition))
  78               (val (cdr condition))
  79               (case-fold-search t)
  80               bbdb-val)
  81           (or (and (memq attr '(firstname lastname aka company phones
  82                                 addresses net))
  83                    (progn
  84                      (setq bbdb-val
  85                            (eval (list (intern (concat "bbdb-record-"
  86                                                        (symbol-name attr)))
  87                                        'record)))
  88                      (if (listp bbdb-val)
  89                          (if eudc-bbdb-enable-substring-matches
  90                              (eval `(or ,@(mapcar (lambda (subval)
  91                                                     (string-match val subval))
  92                                                   bbdb-val)))
  93                            (member (downcase val)
  94                                    (mapcar 'downcase bbdb-val)))
  95                        (if eudc-bbdb-enable-substring-matches
  96                            (string-match val bbdb-val)
  97                          (string-equal (downcase val) (downcase bbdb-val))))))
  98               (throw 'unmatch nil))))
  99       record)))
 100
 101 ;; External.
 102 (declare-function bbdb-phone-location   "ext:bbdb" t) ; via bbdb-defstruct
 103 (declare-function bbdb-phone-string     "ext:bbdb" (phone))
 104 (declare-function bbdb-record-phones    "ext:bbdb" t) ; via bbdb-defstruct
 105 (declare-function bbdb-address-streets  "ext:bbdb" t) ; via bbdb-defstruct
 106 (declare-function bbdb-address-city     "ext:bbdb" t) ; via bbdb-defstruct
 107 (declare-function bbdb-address-state    "ext:bbdb" t) ; via bbdb-defstruct
 108 (declare-function bbdb-address-zip      "ext:bbdb" t) ; via bbdb-defstruct
 109 (declare-function bbdb-address-location "ext:bbdb" t) ; via bbdb-defstruct
 110 (declare-function bbdb-record-addresses "ext:bbdb" t) ; via bbdb-defstruct
 111 (declare-function bbdb-records          "ext:bbdb"
 112                   (&optional dont-check-disk already-in-db-buffer))
 113
 114 (defun eudc-bbdb-extract-phones (record)
 115   (mapcar (function
 116            (lambda (phone)
 117              (if eudc-bbdb-use-locations-as-attribute-names
 118                  (cons (intern (bbdb-phone-location phone))
 119                        (bbdb-phone-string phone))
 120                (cons 'phones (format "%s: %s"
 121                                      (bbdb-phone-location phone)
 122                                      (bbdb-phone-string phone))))))
 123           (bbdb-record-phones record)))
 124
 125 (defun eudc-bbdb-extract-addresses (record)
 126   (let (s c val)
 127     (mapcar (lambda (address)
 128               (setq c (bbdb-address-streets address))
 129               (dotimes (n 3)
 130                 (unless (zerop (length (setq s (nth n c))))
 131                   (setq val (concat val s "\n"))))
 132               (setq c (bbdb-address-city address)
 133                     s (bbdb-address-state address))
 134               (setq val (concat val
 135                                 (if (and (> (length c) 0) (> (length s) 0))
 136                                     (concat c ", " s)
 137                                   c)
 138                                 " "
 139                                 (bbdb-address-zip address)))
 140               (if eudc-bbdb-use-locations-as-attribute-names
 141                   (cons (intern (bbdb-address-location address)) val)
 142                 (cons 'addresses (concat (bbdb-address-location address)
 143                                          "\n" val))))
 144             (bbdb-record-addresses record))))
 145
 146 (defun eudc-bbdb-format-record-as-result (record)
 147   "Format the BBDB RECORD as a EUDC query result record.
 148 The record is filtered according to `eudc-bbdb-current-return-attributes'"
 149   (let ((attrs (or eudc-bbdb-current-return-attributes
 150                    '(firstname lastname aka company phones addresses net notes)))
 151         attr
 152         eudc-rec
 153         val)
 154     (while (prog1
 155                (setq attr (car attrs))
 156              (setq attrs (cdr attrs)))
 157       (cond
 158        ((eq attr 'phones)
 159         (setq val (eudc-bbdb-extract-phones record)))
 160        ((eq attr 'addresses)
 161         (setq val (eudc-bbdb-extract-addresses record)))
 162        ((memq attr '(firstname lastname aka company net notes))
 163         (setq val (eval
 164                    (list (intern
 165                           (concat "bbdb-record-"
 166                                   (symbol-name attr)))
 167                          'record))))
 168        (t
 169         (setq val "Unknown BBDB attribute")))
 170       (if val
 171         (cond
 172          ((memq attr '(phones addresses))
 173           (setq eudc-rec (append val eudc-rec)))
 174          ((and (listp val)
 175           (= 1 (length val)))
 176           (setq eudc-rec (cons (cons attr (car val)) eudc-rec)))
 177          ((> (length val) 0)
 178           (setq eudc-rec (cons (cons attr val) eudc-rec)))
 179          (t
 180           (error "Unexpected attribute value")))))
 181     (nreverse eudc-rec)))
 182
 183
 184
 185 (defun eudc-bbdb-query-internal (query &optional return-attrs)
 186   "Query BBDB  with QUERY.
 187 QUERY is a list of cons cells (ATTR . VALUE) where ATTRs should be valid
 188 BBDB attribute names.
 189 RETURN-ATTRS is a list of attributes to return, defaulting to
 190 `eudc-default-return-attributes'."
 191
 192   (let ((eudc-bbdb-current-query query)
 193         (eudc-bbdb-current-return-attributes return-attrs)
 194         (query-attrs (eudc-bbdb-format-query query))
 195         bbdb-attrs
 196         (records (bbdb-records))
 197         result
 198         filtered)
 199     ;; BBDB ORs its query attributes while EUDC ANDs them, hence we need to
 200     ;; call bbdb-search iteratively on the returned records for each of the
 201     ;; requested attributes
 202     (while (and records (> (length query-attrs) 0))
 203       (setq bbdb-attrs (append bbdb-attrs (list (car query-attrs))))
 204       (if (car query-attrs)
 205           (setq records (eval `(bbdb-search ,(quote records) ,@bbdb-attrs))))
 206       (setq query-attrs (cdr query-attrs)))
 207     (mapc (function
 208            (lambda (record)
 209              (setq filtered (eudc-filter-duplicate-attributes record))
 210              ;; If there were duplicate attributes reverse the order of the
 211              ;; record so the unique attributes appear first
 212              (if (> (length filtered) 1)
 213                  (setq filtered (mapcar (function
 214                                          (lambda (rec)
 215                                            (reverse rec)))
 216                                         filtered)))
 217              (setq result (append result filtered))))
 218           (delq nil
 219                 (mapcar 'eudc-bbdb-format-record-as-result
 220                         (delq nil
 221                               (mapcar 'eudc-bbdb-filter-non-matching-record
 222                                       records)))))
 223     result))
 224
 225 ;;}}}
 226
 227 ;;{{{      High-level interfaces (interactive functions)
 228
 229 (defun eudc-bbdb-set-server (dummy)
 230   "Set the EUDC server to BBDB."
 231   (interactive)
 232   (eudc-set-server dummy 'bbdb)
 233   (message "BBDB server selected"))
 234
 235 ;;}}}
 236
 237
 238 (eudc-register-protocol 'bbdb)
 239
 240 (provide 'eudcb-bbdb)
 241
 242 ;;; eudcb-bbdb.el ends here