configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2014 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.3.91)
  26
  27 dnl We get MINGW64 with MSYS2
  28 if test "x$MSYSTEM" = "xMINGW32" -o "x$MSYSTEM" = "xMINGW64"
  29 then
  30   . $srcdir/nt/mingw-cfg.site
  31
  32   case $srcdir in
  33     /* | ?:*)
  34       # srcdir is an absolute path.  In this case, force the format
  35       # "/c/foo/bar", to simplify later conversions to native Windows
  36       # format ("c:/foo/bar")
  37       srcdir=`cd "${srcdir}" && pwd -W`
  38       srcdir="/${srcdir:0:1}${srcdir:2}"
  39       ;;
  40   esac
  41 fi
  42
  43 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  44 dnl and then quoted again for a C string.  Separate options with spaces.
  45 dnl Add some environment variables, if they were passed via the environment
  46 dnl rather than on the command-line.
  47 emacs_config_options=
  48 optsep=
  49 dnl This is the documented way to record the args passed to configure,
  50 dnl rather than $ac_configure_args.
  51 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  52   case $opt in
  53     -n | --no-create | --no-recursion)
  54       continue ;;
  55     CFLAGS | CPPFLAGS | LDFLAGS)
  56       eval 'test "${'$opt'+set}" = set' || continue
  57       case " $*" in
  58         *" $opt="*) continue ;;
  59       esac
  60       eval opt=$opt=\$$opt ;;
  61   esac
  62
  63   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  64   case $opt in
  65     *[["$emacs_shell_specials"]]*)
  66       case $opt in
  67         *\'*)
  68           emacs_quote_apostrophes="s/'/'\\\\''/g"
  69           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  70       esac
  71       opt="'$opt'"
  72       case $opt in
  73         *[['"\\']]*)
  74           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  75           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  76       esac ;;
  77   esac
  78   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  79   optsep=' '
  80 done
  81
  82 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  83 AC_CONFIG_SRCDIR(src/lisp.h)
  84 AC_CONFIG_AUX_DIR(build-aux)
  85
  86 xcsdkdir=
  87 AC_CHECK_PROGS(XCRUN, [xcrun])
  88 if test -n "$XCRUN"; then
  89   if test -z "$MAKE"; then
  90     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  91     dnl SET_MAKE and with the usual MAKE variable that 'make' itself uses.
  92     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  93     if test -z "$MAKE_PROG"; then
  94       MAKE="$XCRUN MAKE"
  95       export MAKE
  96       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  97     fi
  98   fi
  99 fi
 100
 101 dnl Fairly arbitrary, older versions might work too.
 102 AM_INIT_AUTOMAKE(1.11)
 103
 104 dnl Support for --program-prefix, --program-suffix and
 105 dnl --program-transform-name options
 106 AC_ARG_PROGRAM
 107
 108 dnl It is important that variables on the RHS not be expanded here,
 109 dnl hence the single quotes.  This is per the GNU coding standards, see
 110 dnl (autoconf) Installation Directory Variables
 111 dnl See also epaths.h below.
 112 lispdir='${datadir}/emacs/${version}/lisp'
 113 standardlisppath='${lispdir}'
 114 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 115 '${datadir}/emacs/site-lisp'
 116 lisppath='${locallisppath}:${standardlisppath}'
 117 etcdir='${datadir}/emacs/${version}/etc'
 118 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 119 etcdocdir='${datadir}/emacs/${version}/etc'
 120 gamedir='${localstatedir}/games/emacs'
 121
 122 dnl Special option to disable the most of other options.
 123 AC_ARG_WITH(all,
 124 [AS_HELP_STRING([--without-all],
 125                 [omit almost all features and build
 126                 small executable with minimal dependencies])],
 127   [with_features=$withval],
 128   [with_features=yes])
 129
 130 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 131 dnl Create a new --with option that defaults to being disabled.
 132 dnl NAME is the base name of the option.  The shell variable with_NAME
 133 dnl   will be set to either the user's value (if the option is
 134 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 135 dnl   option is not specified).  Note that the shell variable name is
 136 dnl   constructed as autoconf does, by replacing non-alphanumeric
 137 dnl   characters with "_".
 138 dnl HELP-STRING is the help text for the option.
 139 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 140   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 141     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 142 ])dnl
 143
 144 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 145 dnl Create a new --with option that defaults to $with_features.
 146 dnl NAME is the base name of the option.  The shell variable with_NAME
 147 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 148 dnl   'yes' (if the option is not specified).  Note that the shell
 149 dnl   variable name is constructed as autoconf does, by replacing
 150 dnl   non-alphanumeric characters with "_".
 151 dnl HELP-STRING is the help text for the option.
 152 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 153   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 154    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 155 ])dnl
 156
 157 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 158 if test "$with_pop" = yes; then
 159    AC_DEFINE(MAIL_USE_POP)
 160 fi
 161 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 162
 163 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 164 if test "$with_kerberos" != no; then
 165    AC_DEFINE(KERBEROS)
 166 fi
 167 AH_TEMPLATE(KERBEROS,
 168             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 169
 170 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 171 if test "${with_kerberos5}" != no; then
 172   if test "${with_kerberos}" = no; then
 173     with_kerberos=yes
 174     AC_DEFINE(KERBEROS)
 175   fi
 176   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 177 fi
 178
 179 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 180 dnl FIXME hesiod support may not be present, so it seems like an error
 181 dnl to define, or at least use, this unconditionally.
 182 if test "$with_hesiod" != no; then
 183   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 184 fi
 185
 186 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 187 if test "$with_mmdf" != no; then
 188    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 189 fi
 190
 191 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 192 if test "$with_mail_unlink" != no; then
 193    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 194 fi
 195
 196 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 197     [string giving default POP mail host])],
 198     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 199
 200 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 201   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 202 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW.])],
 203   [ case "${withval}" in
 204       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 205       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 206 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 207       ;;
 208     esac
 209     with_sound=$val
 210   ],
 211   [with_sound=$with_features])
 212
 213 dnl FIXME currently it is not the last.
 214 dnl This should be the last --with option, because --with-x is
 215 dnl added later on when we find the file name of X, and it's best to
 216 dnl keep them together visually.
 217 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 218  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 219 [         case "${withval}" in
 220             y | ye | yes )      val=gtk ;;
 221             n | no )            val=no  ;;
 222             l | lu | luc | luci | lucid )       val=lucid ;;
 223             a | at | ath | athe | athen | athena )      val=athena ;;
 224             m | mo | mot | moti | motif )       val=motif ;;
 225             g | gt | gtk  )     val=gtk ;;
 226             gtk2  )     val=gtk2 ;;
 227             gtk3  )     val=gtk3 ;;
 228             * )
 229 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 230 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 231 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 232 `athena' and `lucid' are synonyms.])
 233             ;;
 234           esac
 235           with_x_toolkit=$val
 236 ])
 237
 238 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 239 if test "$with_wide_int" = yes; then
 240   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 241 fi
 242
 243 dnl _ON results in a '--without' option in the --help output, so
 244 dnl the help text should refer to "don't compile", etc.
 245 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 246 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 247 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 248 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 249 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 250 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 251 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 252 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 253
 254 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 255 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 256 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 257
 258 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 259 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 260 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 261 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 262 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 263
 264 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 265 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 266 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 267 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 268 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 269 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 270 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 271
 272 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 273  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 274  [ case "${withval}" in
 275     y | ye | yes )      val=yes ;;
 276     n | no )            val=no  ;;
 277     g | gf | gfi | gfil | gfile )       val=gfile ;;
 278     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 279     w | w3 | w32 )      val=w32 ;;
 280     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 281 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 282 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 283 otherwise for the first of `gfile' or `inotify' that is usable.])
 284     ;;
 285    esac
 286    with_file_notification=$val
 287  ],
 288  [with_file_notification=$with_features])
 289
 290 ## For the times when you want to build Emacs but don't have
 291 ## a suitable makeinfo, and can live without the manuals.
 292 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 293 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 294
 295 ## Makefile.in needs the cache file name.
 296 AC_SUBST(cache_file)
 297
 298 ## This is an option because I do not know if all info/man support
 299 ## compressed files, nor how to test if they do so.
 300 OPTION_DEFAULT_ON([compress-install],
 301   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 302 make GZIP_PROG= install])
 303
 304 AC_ARG_WITH([pkg-config-prog],dnl
 305 [AS_HELP_STRING([--with-pkg-config-prog=FILENAME],
 306                   [file name of pkg-config for finding GTK and librsvg])])
 307 if test "X${with_pkg_config_prog}" != X; then
 308    if test "${with_pkg_config_prog}" != yes; then
 309       PKG_CONFIG="${with_pkg_config_prog}"
 310    fi
 311 fi
 312
 313 AC_ARG_WITH(gameuser,dnl
 314 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 315 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 316   && gameuser="${with_gameuser}"
 317 test "X$gameuser" = X && gameuser=games
 318
 319 AC_ARG_WITH([gnustep-conf],dnl
 320 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 321    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 322 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 323   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 324 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 325      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 326
 327 AC_ARG_ENABLE(ns-self-contained,
 328 [AS_HELP_STRING([--disable-ns-self-contained],
 329                 [disable self contained build under NeXTstep])],
 330    EN_NS_SELF_CONTAINED=$enableval,
 331    EN_NS_SELF_CONTAINED=yes)
 332
 333 AC_ARG_ENABLE(locallisppath,
 334 [AS_HELP_STRING([--enable-locallisppath=PATH],
 335                 [directories Emacs should search for lisp files specific
 336                  to this site])],
 337 if test "${enableval}" = "no"; then
 338   locallisppath=
 339 elif test "${enableval}" != "yes"; then
 340   locallisppath=${enableval}
 341 fi)
 342
 343 AC_ARG_ENABLE(checking,
 344 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 345                 [enable expensive run-time checks.  With LIST,
 346                  enable only specific categories of checks.
 347                  Categories are: all,yes,no.
 348                  Flags are: stringbytes, stringoverrun, stringfreelist,
 349                  xmallocoverrun, conslist, glyphs])],
 350 [ac_checking_flags="${enableval}"],[])
 351 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 352 for check in $ac_checking_flags
 353 do
 354         case $check in
 355         # these set all the flags to specific states
 356         yes)            ac_enable_checking=1 ;;
 357         no)             ac_enable_checking= ;
 358                         ac_gc_check_stringbytes= ;
 359                         ac_gc_check_string_overrun= ;
 360                         ac_gc_check_string_free_list= ;
 361                         ac_xmalloc_overrun= ;
 362                         ac_gc_check_cons_list= ;
 363                         ac_glyphs_debug= ;;
 364         all)            ac_enable_checking=1 ;
 365                         ac_gc_check_stringbytes=1 ;
 366                         ac_gc_check_string_overrun=1 ;
 367                         ac_gc_check_string_free_list=1 ;
 368                         ac_xmalloc_overrun=1 ;
 369                         ac_gc_check_cons_list=1 ;
 370                         ac_glyphs_debug=1 ;;
 371         # these enable particular checks
 372         stringbytes)    ac_gc_check_stringbytes=1 ;;
 373         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 374         stringfreelist) ac_gc_check_string_free_list=1 ;;
 375         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 376         conslist)       ac_gc_check_cons_list=1 ;;
 377         glyphs)         ac_glyphs_debug=1 ;;
 378         *)      AC_MSG_ERROR(unknown check category $check) ;;
 379         esac
 380 done
 381 IFS="$ac_save_IFS"
 382
 383 if test x$ac_enable_checking != x ; then
 384   AC_DEFINE(ENABLE_CHECKING, 1,
 385 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 386 fi
 387 if test x$ac_gc_check_stringbytes != x ; then
 388   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 389 [Define this temporarily to hunt a bug.  If defined, the size of
 390    strings is redundantly recorded in sdata structures so that it can
 391    be compared to the sizes recorded in Lisp strings.])
 392 fi
 393 if test x$ac_gc_check_string_overrun != x ; then
 394   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 395 [Define this to check for short string overrun.])
 396 fi
 397 if test x$ac_gc_check_string_free_list != x ; then
 398   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 399 [Define this to check the string free list.])
 400 fi
 401 if test x$ac_xmalloc_overrun != x ; then
 402   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 403 [Define this to check for malloc buffer overrun.])
 404 fi
 405 if test x$ac_gc_check_cons_list != x ; then
 406   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 407 [Define this to check for errors in cons list.])
 408 fi
 409 if test x$ac_glyphs_debug != x ; then
 410   AC_DEFINE(GLYPH_DEBUG, 1,
 411 [Define this to enable glyphs debugging code.])
 412 fi
 413
 414 AC_ARG_ENABLE(check-lisp-object-type,
 415 [AS_HELP_STRING([--enable-check-lisp-object-type],
 416                 [enable compile time checks for the Lisp_Object data type.
 417                 This is useful for development for catching certain types of bugs.])],
 418 if test "${enableval}" != "no"; then
 419    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 420    [Define this to enable compile time checks for the Lisp_Object data type.])
 421 fi)
 422
 423
 424 dnl The name of this option is unfortunate.  It predates, and has no
 425 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 426 dnl Actually, it stops it working.
 427 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 428 AC_ARG_ENABLE(profiling,
 429 [AS_HELP_STRING([--enable-profiling],
 430                 [build emacs with low-level, gprof profiling support.
 431                 Mainly useful for debugging Emacs itself.  May not work on
 432                 all platforms.  Stops profiler.el working.])],
 433 [ac_enable_profiling="${enableval}"],[])
 434 if test x$ac_enable_profiling != x ; then
 435    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 436 else
 437    PROFILING_CFLAGS=
 438 fi
 439 AC_SUBST(PROFILING_CFLAGS)
 440
 441 AC_ARG_ENABLE(autodepend,
 442 [AS_HELP_STRING([--enable-autodepend],
 443                 [automatically generate dependencies to .h-files.
 444                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 445                  found])],
 446 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 447
 448 AC_ARG_ENABLE(gtk-deprecation-warnings,
 449 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 450                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 451 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 452
 453 ### Canonicalize the configuration name.
 454
 455 AC_CANONICAL_HOST
 456 canonical=$host
 457 configuration=${host_alias-${build_alias-$host}}
 458
 459 dnl This used to use changequote, but, apart from `changequote is evil'
 460 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 461 dnl the great gob of text.  Thus it's not processed for possible expansion.
 462 dnl Just make sure the brackets remain balanced.
 463 dnl
 464 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 465 dnl indicated by comments.
 466 dnl quotation begins
 467 [
 468
 469 ### If you add support for a new configuration, add code to this
 470 ### switch statement to recognize your configuration name and select
 471 ### the appropriate opsys.
 472
 473 ### As far as handling version numbers on operating systems is
 474 ### concerned, make sure things will fail in a fixable way.  If
 475 ### /etc/MACHINES doesn't say anything about version numbers, be
 476 ### prepared to handle anything reasonably.  If version numbers
 477 ### matter, be sure /etc/MACHINES says something about it.
 478
 479 opsys='' unported=no
 480 case "${canonical}" in
 481
 482   ## GNU/Linux and similar ports
 483   *-*-linux* )
 484     opsys=gnu-linux
 485   ;;
 486
 487   ## FreeBSD ports
 488   *-*-freebsd* )
 489     opsys=freebsd
 490   ;;
 491
 492   ## DragonFly ports
 493   *-*-dragonfly* )
 494     opsys=dragonfly
 495   ;;
 496
 497   ## FreeBSD kernel + glibc based userland
 498   *-*-kfreebsd*gnu* )
 499     opsys=gnu-kfreebsd
 500   ;;
 501
 502   ## NetBSD ports
 503   *-*-netbsd* )
 504     opsys=netbsd
 505   ;;
 506
 507   ## OpenBSD ports
 508   *-*-openbsd* | *-*-mirbsd* )
 509     opsys=openbsd
 510   ;;
 511
 512   ## Apple Darwin / Mac OS X
 513   *-apple-darwin* )
 514     case "${canonical}" in
 515       i[3456]86-* )  ;;
 516       powerpc-* )    ;;
 517       x86_64-* )     ;;
 518       * )            unported=yes ;;
 519     esac
 520     opsys=darwin
 521     ## Use fink packages if available.
 522     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 523 ##    if test -d /sw/include && test -d /sw/lib; then
 524 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 525 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 526 ##    fi
 527   ;;
 528
 529   ## Cygwin ports
 530   *-*-cygwin )
 531     opsys=cygwin
 532   ;;
 533
 534   ## HP 9000 series 700 and 800, running HP/UX
 535   hppa*-hp-hpux10.2* )
 536     opsys=hpux10-20
 537   ;;
 538   hppa*-hp-hpux1[1-9]* )
 539     opsys=hpux11
 540     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 541   ;;
 542
 543   ## IBM machines
 544   rs6000-ibm-aix4.[23]* )
 545     opsys=aix4-2
 546   ;;
 547   powerpc-ibm-aix4.[23]*  )
 548     opsys=aix4-2
 549   ;;
 550   rs6000-ibm-aix[56]* )
 551     opsys=aix4-2
 552   ;;
 553   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 554     opsys=aix4-2
 555   ;;
 556
 557   ## Silicon Graphics machines
 558   ## Iris 4D
 559   mips-sgi-irix6.5 )
 560     opsys=irix6-5
 561     # Without defining _LANGUAGE_C, things get masked out in the headers
 562     # so that, for instance, grepping for `free' in stdlib.h fails and
 563     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 564     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 565   ;;
 566
 567   ## Suns
 568   *-sun-solaris* \
 569     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 570     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 571     case "${canonical}" in
 572       i[3456]86-*-* )   ;;
 573       amd64-*-*|x86_64-*-*) ;;
 574       sparc* )          ;;
 575       * )               unported=yes ;;
 576     esac
 577     case "${canonical}" in
 578       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 579                 opsys=sol2-10
 580                 emacs_check_sunpro_c=yes
 581                 ;;
 582       *-sunos5.6* | *-solaris2.6* )
 583                 opsys=sol2-6
 584                 RANLIB="ar -ts"
 585                 ;;
 586       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 587                 opsys=sol2-6
 588                 emacs_check_sunpro_c=yes
 589                 ;;
 590     esac
 591     ## Watch out for a compiler that we know will not work.
 592     case "${canonical}" in
 593      *-solaris* | *-sunos5* )
 594                 if [ "x$CC" = x/usr/ucb/cc ]; then
 595                   ## /usr/ucb/cc doesn't work;
 596                   ## we should find some other compiler that does work.
 597                   unset CC
 598                 fi
 599                 ;;
 600       *) ;;
 601     esac
 602   ;;
 603
 604   ## Intel 386 machines where we don't care about the manufacturer.
 605   i[3456]86-*-* )
 606     case "${canonical}" in
 607       *-darwin* )               opsys=darwin ;;
 608       *-mingw32 )
 609                 opsys=mingw32
 610                 # MinGW overrides and adds some system headers in nt/inc.
 611                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 612                 ;;
 613       *-sysv4.2uw* )            opsys=unixware ;;
 614       *-sysv5uw* )              opsys=unixware ;;
 615       *-sysv5OpenUNIX* )        opsys=unixware ;;
 616       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 617     esac
 618   ;;
 619
 620   # MinGW64
 621   x86_64-*-* )
 622     case "${canonical}" in
 623       *-mingw32 )
 624                 opsys=mingw32
 625                 # MinGW overrides and adds some system headers in nt/inc.
 626                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 627                 ;;
 628       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 629     esac
 630   ;;
 631
 632   * )
 633     unported=yes
 634   ;;
 635 esac
 636
 637 ### If the code above didn't choose an operating system, just choose
 638 ### an operating system based on the configuration name.  You really
 639 ### only want to use this when you have no idea what the right
 640 ### operating system is; if you know what operating systems a machine
 641 ### runs, it's cleaner to make it explicit in the case statement
 642 ### above.
 643 if test x"${opsys}" = x; then
 644   case "${canonical}" in
 645     *-gnu* )                            opsys=gnu ;;
 646     * )
 647       unported=yes
 648     ;;
 649   esac
 650 fi
 651
 652 ]
 653 dnl quotation ends
 654
 655 if test $unported = yes; then
 656   AC_MSG_ERROR([Emacs does not support `${canonical}' systems.
 657 If you think it should, please send a report to bug-gnu-emacs@gnu.org.
 658 Check `etc/MACHINES' for recognized configuration names.])
 659 fi
 660
 661
 662 #### Choose a compiler.
 663
 664 dnl Sets GCC=yes if using gcc.
 665 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 666 if test -n "$XCRUN"; then
 667   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 668   test -n "$AR" && export AR
 669 fi
 670
 671 AM_PROG_CC_C_O
 672
 673 if test x$GCC = xyes; then
 674   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 675 else
 676   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 677 fi
 678
 679 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 680 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 681 dnl that clash with MinGW.
 682 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 683
 684 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 685 AC_DEFUN([gl_CRYPTO_CHECK])
 686 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 687 # as we don't use them.
 688 AC_DEFUN([gl_FCNTL_O_FLAGS])
 689 # Avoid gnulib's threadlib module, as we do threads our own way.
 690 AC_DEFUN([gl_THREADLIB])
 691
 692 # Initialize gnulib right after choosing the compiler.
 693 dnl Amongst other things, this sets AR and ARFLAGS.
 694 gl_EARLY
 695
 696 if test "$ac_test_CFLAGS" != set; then
 697   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 698   # if -g3 works and the user does not specify CFLAGS.
 699   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 700   case $CFLAGS in
 701     '-g')
 702       emacs_g3_CFLAGS='-g3';;
 703     '-g -O2')
 704       emacs_g3_CFLAGS='-g3 -O2';;
 705     *)
 706       emacs_g3_CFLAGS='';;
 707   esac
 708   if test -n "$emacs_g3_CFLAGS"; then
 709     emacs_save_CFLAGS=$CFLAGS
 710     CFLAGS=$emacs_g3_CFLAGS
 711     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 712       [emacs_cv_prog_cc_g3],
 713       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 714          [emacs_cv_prog_cc_g3=yes],
 715          [emacs_cv_prog_cc_g3=no])])
 716     if test $emacs_cv_prog_cc_g3 != yes; then
 717       CFLAGS=$emacs_save_CFLAGS
 718     fi
 719     if test $opsys = mingw32; then
 720       CFLAGS="$CFLAGS -gdwarf-2"
 721     fi
 722   fi
 723
 724   case $CFLAGS in
 725     *-O*) ;;
 726     *)
 727       # No optimization flag was inferred for this non-GCC compiler.
 728       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 729       emacs_save_CFLAGS=$CFLAGS
 730       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 731       CFLAGS=${CFLAGS}-O
 732       AC_CACHE_CHECK([whether $CC accepts -O],
 733         [emacs_cv_prog_cc_o],
 734         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 735            [emacs_cv_prog_cc_o=yes],
 736            [emacs_cv_prog_cc_o=no])])
 737       if test $emacs_cv_prog_cc_o != yes; then
 738         CFLAGS=$emacs_save_CFLAGS
 739       fi ;;
 740   esac
 741 fi
 742
 743 AC_ARG_ENABLE([gcc-warnings],
 744   [AS_HELP_STRING([--enable-gcc-warnings],
 745                   [turn on lots of GCC warnings/errors. This is intended for
 746                    developers, and may generate false alarms when used
 747                    with older or non-GNU development tools.])],
 748   [case $enableval in
 749      yes|no) ;;
 750      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 751    esac
 752    gl_gcc_warnings=$enableval],
 753   [gl_gcc_warnings=no]
 754 )
 755
 756 AC_ARG_ENABLE(link-time-optimization,
 757 [AS_HELP_STRING([--enable-link-time-optimization],
 758                 [build emacs with link-time optimization.
 759                  This is supported only for GCC since 4.5.0.])],
 760 if test "${enableval}" != "no"; then
 761    AC_MSG_CHECKING([whether link-time optimization is supported])
 762    ac_lto_supported=no
 763    if test x$GCC = xyes; then
 764       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 765       if test x$CPUS != x; then
 766          LTO="-flto=$CPUS"
 767       else
 768          LTO="-flto"
 769       fi
 770       old_CFLAGS=$CFLAGS
 771       CFLAGS="$CFLAGS $LTO"
 772       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 773         [ac_lto_supported=yes], [ac_lto_supported=no])
 774       CFLAGS="$old_CFLAGS"
 775    fi
 776    AC_MSG_RESULT([$ac_lto_supported])
 777    if test "$ac_lto_supported" = "yes"; then
 778       CFLAGS="$CFLAGS $LTO"
 779    fi
 780 fi)
 781
 782 # clang is unduly picky about some things.
 783 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 784   [AC_COMPILE_IFELSE(
 785      [AC_LANG_PROGRAM([[
 786           #ifndef __clang__
 787             error "not clang";
 788           #endif
 789         ]])],
 790      [emacs_cv_clang=yes],
 791      [emacs_cv_clang=no])])
 792
 793 # When compiling with GCC, prefer -isystem to -I when including system
 794 # include files, to avoid generating useless diagnostics for the files.
 795 if test "$gl_gcc_warnings" != yes; then
 796   isystem='-I'
 797   if test "$emacs_cv_clang" = yes
 798   then
 799      # Turn off some warnings if supported.
 800      gl_WARN_ADD([-Wno-switch])
 801      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 802      gl_WARN_ADD([-Wno-pointer-sign])
 803   fi
 804 else
 805   isystem='-isystem '
 806
 807   # This, $nw, is the list of warnings we disable.
 808   nw=
 809
 810   case $with_x_toolkit in
 811     lucid | athena | motif)
 812        # Old toolkits mishandle 'const'.
 813        nw="$nw -Wwrite-strings"
 814        ;;
 815     *)
 816        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 817        ;;
 818   esac
 819   AC_SUBST([WERROR_CFLAGS])
 820
 821   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 822   nw="$nw -Woverlength-strings"     # Not a problem these days
 823   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 824   nw="$nw -Wformat-nonliteral"      # we do this a lot
 825   nw="$nw -Wvla"                    # warnings in gettext.h
 826   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 827   nw="$nw -Wswitch-default"         # Too many warnings for now
 828   nw="$nw -Winline"                 # OK to ignore 'inline'
 829   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 830   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 831                                     # signed overflow has undefined behavior
 832   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 833   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 834   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 835
 836   # Emacs doesn't care about shadowing; see
 837   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 838   nw="$nw -Wshadow"
 839
 840   # Emacs's use of alloca inhibits protecting the stack.
 841   nw="$nw -Wstack-protector"
 842
 843   # The following line should be removable at some point.
 844   nw="$nw -Wsuggest-attribute=pure"
 845
 846   # This part is merely for shortening the command line,
 847   # since -Wno-FOO needs to be added below regardless.
 848   nw="$nw -Wmissing-field-initializers"
 849   nw="$nw -Wswitch"
 850   nw="$nw -Wtype-limits"
 851   nw="$nw -Wunused-parameter"
 852
 853   if test $emacs_cv_clang = yes; then
 854     nw="$nw -Wcast-align"
 855   fi
 856
 857   gl_MANYWARN_ALL_GCC([ws])
 858   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 859   for w in $ws; do
 860     gl_WARN_ADD([$w])
 861   done
 862   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 863   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 864   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 865   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 866   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 867   gl_WARN_ADD([-Wno-format-nonliteral])
 868
 869   # In spite of excluding -Wlogical-op above, it is enabled, as of
 870   # gcc 4.5.0 20090517.
 871   gl_WARN_ADD([-Wno-logical-op])
 872
 873   # More things that clang is unduly picky about.
 874   if test $emacs_cv_clang = yes; then
 875     gl_WARN_ADD([-Wno-format-extra-args])
 876     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 877     gl_WARN_ADD([-Wno-unused-command-line-argument])
 878     gl_WARN_ADD([-Wno-unused-value])
 879   fi
 880
 881   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 882   AH_VERBATIM([FORTIFY_SOURCE],
 883   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 884       without upsetting glibc 2.15+. */
 885    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 886    # define _FORTIFY_SOURCE 2
 887    #endif
 888   ])
 889   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 890
 891   # We use a slightly smaller set of warning options for lib/.
 892   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 893   nw=
 894   nw="$nw -Wunused-macros"
 895
 896   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 897   AC_SUBST([GNULIB_WARN_CFLAGS])
 898 fi
 899
 900 edit_cflags="
 901   s,///*,/,g
 902   s/^/ /
 903   s/ -I/ $isystem/g
 904   s/^ //
 905 "
 906
 907
 908 dnl Some other nice autoconf tests.
 909 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 910 dnl AC_PROG_INSTALL
 911 dnl AC_PROG_MKDIR_P
 912 dnl if test "x$RANLIB" = x; then
 913 dnl   AC_PROG_RANLIB
 914 dnl fi
 915
 916
 917 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
 918 dnl can be made to directories.  This is not relevant for our usage, and
 919 dnl excludes some cases that work fine for us.  Eg MS Windows or files
 920 dnl hosted on AFS, both examples where simple links work, but links to
 921 dnl directories fail.  We use a cut-down version instead.
 922 dnl AC_PROG_LN_S
 923
 924 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
 925 rm -f conf$$ conf$$.file
 926
 927 LN_S_FILEONLY='cp -p'
 928
 929 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
 930 dnl random program in the current directory.
 931 if (echo >conf$$.file) 2>/dev/null; then
 932   if ln -s conf$$.file conf$$ 2>/dev/null; then
 933     if test "$opsys" = "mingw32"; then
 934       LN_S_FILEONLY='/bin/ln -s'
 935     else
 936       LN_S_FILEONLY='ln -s'
 937     fi
 938   elif ln conf$$.file conf$$ 2>/dev/null; then
 939     if test "$opsys" = "mingw32"; then
 940       LN_S_FILEONLY=/bin/ln
 941     else
 942       LN_S_FILEONLY=ln
 943     fi
 944   fi
 945 fi
 946
 947 rm -f conf$$ conf$$.file
 948
 949 if test "$LN_S_FILEONLY" = "ln -s"; then
 950    AC_MSG_RESULT([yes])
 951 else
 952    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
 953 fi
 954
 955 AC_SUBST(LN_S_FILEONLY)
 956
 957
 958 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
 959 dnl doesn't support links to directories, as in "ln file dir".  But that
 960 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
 961 dnl executables at "make install" time.
 962 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
 963 dnl for more details.
 964 if test "$opsys" = "mingw32"; then
 965   LN_S="/bin/ln"
 966 fi
 967
 968 dnl On some Debian versions, "install-info" prints irritating messages
 969 dnl "This is not dpkg install-info anymore, but GNU install-info"
 970 dnl if called via an absolute file name.
 971 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
 972 dnl Sadly some people may have an old ginstall-info installed on
 973 dnl non-Debian systems, so we can't use this.
 974 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
 975 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 976
 977 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 978   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 979 dnl Don't use GZIP, which is used by gzip for additional parameters.
 980 AC_PATH_PROG(GZIP_PROG, gzip)
 981
 982 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
 983    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
 984
 985 if test $opsys = gnu-linux; then
 986   AC_PATH_PROG(PAXCTL, paxctl,,
 987     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 988   if test "X$PAXCTL" != X; then
 989     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 990     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 991       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 992       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 993   fi
 994
 995   if test "${SETFATTR+set}" != set; then
 996     AC_CACHE_CHECK([for setfattr],
 997       [emacs_cv_prog_setfattr],
 998       [touch conftest.tmp
 999        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1000          emacs_cv_prog_setfattr=yes
1001        else
1002          emacs_cv_prog_setfattr=no
1003        fi])
1004     if test "$emacs_cv_prog_setfattr" = yes; then
1005       SETFATTR=setfattr
1006     else
1007       SETFATTR=
1008     fi
1009     rm -f conftest.tmp
1010     AC_SUBST([SETFATTR])
1011   fi
1012 fi
1013
1014 ## Need makeinfo >= 4.7 (?) to build the manuals.
1015 AC_PATH_PROG(MAKEINFO, makeinfo, no)
1016 dnl By this stage, configure has already checked for egrep and set EGREP,
1017 dnl or exited with an error if no egrep was found.
1018 if test "$MAKEINFO" != "no"; then
1019   case `
1020     $MAKEINFO --version 2> /dev/null |
1021     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
1022   ` in
1023     '') MAKEINFO=no;;
1024   esac
1025 fi
1026
1027 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1028 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1029 ## therefore in the category of "special tools" not normally required, which
1030 ## configure does not have to check for (eg autoconf itself).
1031 ## In a repository checkout on the other hand, the manuals are not included.
1032 ## So makeinfo is a requirement to build from the repository, and configure
1033 ## should test for it as it does for any other build requirement.
1034 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1035 ## with pre-built manuals, from a repository checkout.
1036 HAVE_MAKEINFO=yes
1037
1038 if test "$MAKEINFO" = "no"; then
1039   MAKEINFO=makeinfo
1040   if test "x${with_makeinfo}" = "xno"; then
1041     HAVE_MAKEINFO=no
1042   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1043     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1044 source tree does not seem to have pre-built manuals in the `info' directory.
1045 Either install a suitable version of makeinfo, or re-run configure
1046 with the `--without-makeinfo' option to build without the manuals.] )
1047   fi
1048 fi
1049 AC_SUBST(HAVE_MAKEINFO)
1050
1051 dnl Just so that there is only a single place we need to edit.
1052 INFO_EXT=.info
1053 INFO_OPTS=--no-split
1054 AC_SUBST(INFO_EXT)
1055 AC_SUBST(INFO_OPTS)
1056
1057 if test $opsys = mingw32; then
1058    DOCMISC_W32=efaq-w32
1059 else
1060    DOCMISC_W32=
1061 fi
1062 AC_SUBST(DOCMISC_W32)
1063
1064 dnl Add our options to ac_link now, after it is set up.
1065
1066 if test x$GCC = xyes; then
1067   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1068     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1069 else
1070   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1071     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1072 fi
1073
1074 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1075 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1076 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1077 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1078 dnl if not built to support GNU ld.
1079
1080 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1081 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1082 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1083 dnl   Eg "make LDFLAGS=... all" could run into problems,
1084 dnl   http://bugs.debian.org/684788
1085 dnl * unnecessary, since temacs is the only thing that actually needs it.
1086 dnl   Indeed this is where it was originally, prior to:
1087 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1088 late_LDFLAGS="$LDFLAGS"
1089 if test x$GCC = xyes; then
1090   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1091 else
1092   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1093 fi
1094
1095 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1096
1097 AC_MSG_CHECKING([for -znocombreloc])
1098 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1099   [AC_MSG_RESULT(yes)],
1100   LDFLAGS_NOCOMBRELOC=
1101   [AC_MSG_RESULT(no)])
1102
1103 LDFLAGS="$late_LDFLAGS"
1104
1105 AC_CACHE_CHECK([whether addresses are sanitized],
1106   [emacs_cv_sanitize_address],
1107   [AC_COMPILE_IFELSE(
1108      [AC_LANG_PROGRAM(
1109         [[#ifndef __has_feature
1110           #define __has_feature(f) 0
1111           #endif
1112           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1113           #else
1114            error "Addresses are not sanitized.";
1115           #endif
1116         ]])],
1117      [emacs_cv_sanitize_address=yes],
1118      [emacs_cv_sanitize_address=no])])
1119
1120 dnl The function dump-emacs will not be defined and temacs will do
1121 dnl (load "loadup") automatically unless told otherwise.
1122 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1123 case "$opsys" in
1124   your-opsys-here) CANNOT_DUMP=yes ;;
1125 esac
1126
1127 if test "$CANNOT_DUMP" = "yes"; then
1128   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1129 elif test "$emacs_cv_sanitize_address" = yes; then
1130   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1131 fi
1132
1133 AC_SUBST(CANNOT_DUMP)
1134
1135
1136 UNEXEC_OBJ=unexelf.o
1137 case "$opsys" in
1138   # MSDOS uses unexcoff.o
1139   aix4-2)
1140    UNEXEC_OBJ=unexaix.o
1141    ;;
1142   cygwin)
1143    UNEXEC_OBJ=unexcw.o
1144    ;;
1145   darwin)
1146    UNEXEC_OBJ=unexmacosx.o
1147    ;;
1148   hpux10-20 | hpux11)
1149    UNEXEC_OBJ=unexhp9k800.o
1150    ;;
1151   mingw32)
1152    UNEXEC_OBJ=unexw32.o
1153    ;;
1154   sol2-10)
1155    # Use the Solaris dldump() function, called from unexsol.c, to dump
1156    # emacs, instead of the generic ELF dump code found in unexelf.c.
1157    # The resulting binary has a complete symbol table, and is better
1158    # for debugging and other observability tools (debuggers, pstack, etc).
1159    #
1160    # If you encounter a problem using dldump(), please consider sending
1161    # a message to the OpenSolaris tools-linking mailing list:
1162    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1163    #
1164    # It is likely that dldump() works with older Solaris too, but this has
1165    # not been tested, so for now this change is for Solaris 10 or newer.
1166    UNEXEC_OBJ=unexsol.o
1167    ;;
1168 esac
1169
1170 LD_SWITCH_SYSTEM=
1171 case "$opsys" in
1172   freebsd|dragonfly)
1173    ## Let `ld' find image libs and similar things in /usr/local/lib.
1174    ## The system compiler, GCC, has apparently been modified to not
1175    ## look there, contrary to what a stock GCC would do.
1176 ### It's not our place to do this.  See bug#10313#17.
1177 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1178       :
1179    ;;
1180
1181   gnu-linux)
1182    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1183    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1184    ;;
1185
1186   netbsd)
1187 ### It's not our place to do this.  See bug#10313#17.
1188 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1189       :
1190    ;;
1191
1192   openbsd)
1193    ## Han Boetes <han@boetes.org> says this is necessary,
1194    ## otherwise Emacs dumps core on elf systems.
1195    LD_SWITCH_SYSTEM="-Z"
1196    ;;
1197 esac
1198 AC_SUBST(LD_SWITCH_SYSTEM)
1199
1200 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1201
1202 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1203 ## which has not been defined yet.  When this was handled with cpp,
1204 ## it was expanded to null when configure sourced the s/*.h file.
1205 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1206 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1207 ## (or somesuch), but because it is supposed to go at the _front_
1208 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1209 ## Compare with the gnu-linux case below, which added to the end
1210 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1211 ## LD_SWITCH_SYSTEM_TEMACS.
1212 case "$opsys" in
1213   netbsd|openbsd)
1214    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1215 esac
1216
1217
1218 C_SWITCH_MACHINE=
1219 case $canonical in
1220  alpha*)
1221   AC_CHECK_DECL([__ELF__])
1222   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1223     ## With ELF, make sure that all common symbols get allocated to in the
1224     ## data section.  Otherwise, the dump of temacs may miss variables in
1225     ## the shared library that have been initialized.  For example, with
1226     ## GNU libc, __malloc_initialized would normally be resolved to the
1227     ## shared library's .bss section, which is fatal.
1228     if test "x$GCC" = "xyes"; then
1229       C_SWITCH_MACHINE="-fno-common"
1230     else
1231       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1232     fi
1233   else
1234       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1235       dnl albeit under the mistaken assumption that said file
1236       dnl was no longer used.
1237       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1238   fi
1239   ;;
1240 esac
1241 AC_SUBST(C_SWITCH_MACHINE)
1242
1243 AC_SUBST(UNEXEC_OBJ)
1244
1245 C_SWITCH_SYSTEM=
1246 ## Some programs in src produce warnings saying certain subprograms
1247 ## are too complex and need a MAXMEM value greater than 2000 for
1248 ## additional optimization.  --nils@exp-math.uni-essen.de
1249 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1250   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1251 if test "$opsys" = "mingw32"; then
1252   case "$canonical" in
1253     x86_64-*-mingw32) C_SWITCH_SYSTEM="-mtune=generic" ;;
1254     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1255   esac
1256 fi
1257 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1258 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1259 AC_SUBST(C_SWITCH_SYSTEM)
1260
1261
1262 LIBS_SYSTEM=
1263 case "$opsys" in
1264   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1265   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1266
1267   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1268
1269   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1270
1271   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1272
1273   ## Motif needs -lgen.
1274   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1275 esac
1276
1277 AC_SUBST(LIBS_SYSTEM)
1278
1279 ### Make sure subsequent tests use flags consistent with the build flags.
1280
1281 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1282   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1283 else
1284   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1285 fi
1286
1287 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1288 AC_DEFUN([AC_TYPE_SIZE_T])
1289 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1290 AC_DEFUN([AC_TYPE_UID_T])
1291
1292
1293 LIB_MATH=-lm
1294 dnl Current possibilities handled by sed (aix4-2 -> aix,
1295 dnl gnu-linux -> gnu/linux, etc.):
1296 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1297 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1298 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1299
1300 case $opsys in
1301   cygwin )
1302     LIB_MATH=
1303     ;;
1304   darwin )
1305     ## Adding -lm confuses the dynamic linker, so omit it.
1306     LIB_MATH=
1307     ;;
1308   freebsd | dragonfly )
1309     SYSTEM_TYPE=berkeley-unix
1310     ;;
1311   gnu-linux | gnu-kfreebsd )
1312     ;;
1313   hpux10-20 | hpux11 )
1314     ;;
1315   mingw32 )
1316     LIB_MATH=
1317     SYSTEM_TYPE=windows-nt
1318     ;;
1319   dnl NB this may be adjusted below.
1320   netbsd | openbsd )
1321     SYSTEM_TYPE=berkeley-unix
1322     ;;
1323
1324   sol2* | unixware )
1325     SYSTEM_TYPE=usg-unix-v
1326     ;;
1327
1328 esac
1329
1330 AC_SUBST(LIB_MATH)
1331 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1332   [The type of system you are compiling for; sets `system-type'.])
1333
1334
1335 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1336 pre_PKG_CONFIG_LIBS=$LIBS
1337
1338 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1339
1340 dnl This function definition taken from Gnome 2.0
1341 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1342 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1343 dnl also defines GSTUFF_PKG_ERRORS on error
1344 AC_DEFUN([PKG_CHECK_MODULES], [
1345   succeeded=no
1346
1347   if test "$PKG_CONFIG" = "no" ; then
1348      ifelse([$4], , [AC_MSG_ERROR([
1349       *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1350   else
1351      PKG_CONFIG_MIN_VERSION=0.9.0
1352      if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1353         AC_MSG_CHECKING(for $2)
1354
1355         if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1356            $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1357            $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1358             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1359             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1360             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1361             succeeded=yes
1362         else
1363             AC_MSG_RESULT(no)
1364             $1_CFLAGS=""
1365             $1_LIBS=""
1366             ## If we have a custom action on failure, don't print errors, but
1367             ## do set a variable so people can do so.  Do it in a subshell
1368             ## to capture any diagnostics in invoking pkg-config.
1369             $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1`
1370             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1371         fi
1372
1373         AC_SUBST($1_CFLAGS)
1374         AC_SUBST($1_LIBS)
1375      else
1376         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1377         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1378      fi
1379   fi
1380
1381   if test $succeeded = yes; then
1382      ifelse([$3], , :, [$3])
1383   else
1384      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1385   fi
1386 ])
1387
1388 HAVE_SOUND=no
1389 if test "${with_sound}" != "no"; then
1390   # Sound support for GNU/Linux, the free BSDs, and MinGW.
1391   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h],
1392     have_sound_header=yes, [], [
1393     #ifdef __MINGW32__
1394     #define WIN32_LEAN_AND_MEAN
1395     #include <windows.h>
1396     #endif
1397     ])
1398   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1399     AC_MSG_ERROR([OSS sound support requested but not found.])
1400
1401   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1402     # Emulation library used on NetBSD.
1403     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1404     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1405       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1406     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1407     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1408   fi
1409   AC_SUBST(LIBSOUND)
1410
1411   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1412     ALSA_REQUIRED=1.0.0
1413     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1414     PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1415     if test $HAVE_ALSA = yes; then
1416       SAVE_CFLAGS="$CFLAGS"
1417       SAVE_LIBS="$LIBS"
1418       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1419       LIBS="$ALSA_LIBS $LIBS"
1420       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1421                       emacs_alsa_normal=yes,
1422                     emacs_alsa_normal=no)
1423       if test "$emacs_alsa_normal" != yes; then
1424         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1425                        [[snd_lib_error_set_handler (0);]])],
1426                        emacs_alsa_subdir=yes,
1427                      emacs_alsa_subdir=no)
1428         if test "$emacs_alsa_subdir" != yes; then
1429           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1430         fi
1431         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1432       fi
1433
1434       CFLAGS="$SAVE_CFLAGS"
1435       LIBS="$SAVE_LIBS"
1436       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1437       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1438       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1439     elif test "${with_sound}" = "alsa"; then
1440       AC_MSG_ERROR([ALSA sound support requested but not found.])
1441     fi
1442   fi                            dnl with_sound = alsa|yes
1443
1444   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1445   dnl compiles only on the specified platforms.  For others, it
1446   dnl probably doesn't make sense to try.
1447   dnl FIXME So surely we should bypass this whole section if not using
1448   dnl one of these platforms?
1449   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1450      case "$opsys" in
1451        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1452        dnl Adjust the --with-sound help text if you change this.
1453        gnu-linux|freebsd|netbsd|mingw32)
1454          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1455          HAVE_SOUND=yes
1456          ;;
1457      esac
1458   fi
1459
1460   AC_SUBST(CFLAGS_SOUND)
1461 fi
1462
1463 dnl checks for header files
1464 AC_CHECK_HEADERS_ONCE(
1465   sys/systeminfo.h
1466   coff.h pty.h
1467   sys/resource.h
1468   sys/utsname.h pwd.h utmp.h util.h)
1469
1470 AC_MSG_CHECKING(if personality LINUX32 can be set)
1471 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1472                emacs_cv_personality_linux32=yes,
1473                emacs_cv_personality_linux32=no)
1474 AC_MSG_RESULT($emacs_cv_personality_linux32)
1475
1476 if test $emacs_cv_personality_linux32 = yes; then
1477   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1478             [Define to 1 if personality LINUX32 can be set.])
1479 fi
1480
1481 dnl On Solaris 8 there's a compilation warning for term.h because
1482 dnl it doesn't define `bool'.
1483 AC_CHECK_HEADERS(term.h, , , -)
1484 AC_HEADER_TIME
1485 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1486                                       ]])
1487 if test $ac_cv_have_decl_sys_siglist != yes; then
1488   # For Tru64, at least:
1489   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1490                                           ]])
1491 fi
1492 AC_HEADER_SYS_WAIT
1493
1494 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1495 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1496 #if HAVE_SYS_SOCKET_H
1497 #include <sys/socket.h>
1498 #endif])
1499 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1500 #if HAVE_SYS_SOCKET_H
1501 #include <sys/socket.h>
1502 #endif])
1503 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1504 #if HAVE_SYS_SOCKET_H
1505 #include <sys/socket.h>
1506 #endif])
1507
1508 dnl checks for structure members
1509 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1510                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1511                   struct ifreq.ifr_addr,
1512                   struct ifreq.ifr_addr.sa_len], , ,
1513                  [AC_INCLUDES_DEFAULT
1514 #if HAVE_SYS_SOCKET_H
1515 #include <sys/socket.h>
1516 #endif
1517 #if HAVE_NET_IF_H
1518 #include <net/if.h>
1519 #endif])
1520
1521 dnl Check for endianness.
1522 dnl AC_C_BIGENDIAN is done by gnulib.
1523
1524 dnl check for Make feature
1525 dnl AC_PROG_MAKE_SET is done by Automake.
1526
1527 DEPFLAGS=
1528 MKDEPDIR=":"
1529 deps_frag=deps.mk
1530 dnl check for GNU Make if we have GCC and autodepend is on.
1531 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1532    AC_MSG_CHECKING([whether we are using GNU Make])
1533    HAVE_GNU_MAKE=no
1534    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1535    if test "x$testval" != x; then
1536       HAVE_GNU_MAKE=yes
1537    else
1538       ac_enable_autodepend=no
1539    fi
1540    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1541    if test $HAVE_GNU_MAKE = yes; then
1542       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1543       SAVE_CFLAGS="$CFLAGS"
1544       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1545       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1546       CFLAGS="$SAVE_CFLAGS"
1547       test -f deps.d || ac_enable_autodepend=no
1548       rm -rf deps.d
1549       AC_MSG_RESULT([$ac_enable_autodepend])
1550    fi
1551    if test $ac_enable_autodepend = yes; then
1552       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1553       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1554       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1555       deps_frag=autodeps.mk
1556    fi
1557 fi
1558 deps_frag=$srcdir/src/$deps_frag
1559 AC_SUBST(MKDEPDIR)
1560 AC_SUBST(DEPFLAGS)
1561 AC_SUBST_FILE(deps_frag)
1562
1563
1564 lisp_frag=$srcdir/src/lisp.mk
1565 AC_SUBST_FILE(lisp_frag)
1566
1567
1568 dnl checks for operating system services
1569 AC_SYS_LONG_FILE_NAMES
1570
1571 #### Choose a window system.
1572
1573 ## We leave window_system equal to none if
1574 ## we end up building without one.  Any new window system should
1575 ## set window_system to an appropriate value and add objects to
1576 ## window-system-specific substs.
1577
1578 window_system=none
1579 AC_PATH_X
1580 if test "$no_x" != yes; then
1581   window_system=x11
1582 fi
1583
1584 LD_SWITCH_X_SITE_RPATH=
1585 if test "${x_libraries}" != NONE; then
1586   if test -n "${x_libraries}"; then
1587     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1588     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1589   fi
1590   x_default_search_path=""
1591   x_search_path=${x_libraries}
1592   if test -z "${x_search_path}"; then
1593     x_search_path=/usr/lib
1594   fi
1595   for x_library in `echo ${x_search_path}: | \
1596                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1597     x_search_path="\
1598 ${x_library}/X11/%L/%T/%N%C%S:\
1599 ${x_library}/X11/%l/%T/%N%C%S:\
1600 ${x_library}/X11/%T/%N%C%S:\
1601 ${x_library}/X11/%L/%T/%N%S:\
1602 ${x_library}/X11/%l/%T/%N%S:\
1603 ${x_library}/X11/%T/%N%S"
1604     if test x"${x_default_search_path}" = x; then
1605       x_default_search_path=${x_search_path}
1606     else
1607       x_default_search_path="${x_search_path}:${x_default_search_path}"
1608     fi
1609   done
1610 fi
1611 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1612
1613 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1614   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1615 fi
1616
1617 if test x"${x_includes}" = x; then
1618   bitmapdir=/usr/include/X11/bitmaps
1619 else
1620   # accumulate include directories that have X11 bitmap subdirectories
1621   bmd_acc="dummyval"
1622   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1623     if test -d "${bmd}/X11/bitmaps"; then
1624       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1625     fi
1626     if test -d "${bmd}/bitmaps"; then
1627       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1628     fi
1629   done
1630   if test ${bmd_acc} != "dummyval"; then
1631     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1632   fi
1633 fi
1634
1635 HAVE_NS=no
1636 NS_IMPL_COCOA=no
1637 NS_IMPL_GNUSTEP=no
1638 tmp_CPPFLAGS="$CPPFLAGS"
1639 tmp_CFLAGS="$CFLAGS"
1640 CPPFLAGS="$CPPFLAGS -x objective-c"
1641 CFLAGS="$CFLAGS -x objective-c"
1642 GNU_OBJC_CFLAGS=
1643 LIBS_GNUSTEP=
1644 if test "${with_ns}" != no; then
1645   if test "${opsys}" = darwin; then
1646      NS_IMPL_COCOA=yes
1647      ns_appdir=`pwd`/nextstep/Emacs.app
1648      ns_appbindir=${ns_appdir}/Contents/MacOS
1649      ns_appresdir=${ns_appdir}/Contents/Resources
1650      ns_appsrc=Cocoa/Emacs.base
1651   elif test -f $GNUSTEP_CONFIG_FILE; then
1652      NS_IMPL_GNUSTEP=yes
1653      ns_appdir=`pwd`/nextstep/Emacs.app
1654      ns_appbindir=${ns_appdir}
1655      ns_appresdir=${ns_appdir}/Resources
1656      ns_appsrc=GNUstep/Emacs.base
1657      dnl FIXME sourcing this several times in subshells seems inefficient.
1658      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1659      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1660      dnl I seemed to need these as well with GNUstep-startup 0.25.
1661      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1662      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1663      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1664        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1665      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1666        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1667      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1668      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1669      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1670      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1671      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1672      dnl If they had chosen to either define it or not, we could have
1673      dnl just used AC_CHECK_DECL here.
1674      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1675        emacs_cv_objc_exceptions,
1676 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1677 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1678 1;
1679 #else
1680 fail;
1681 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1682      if test $emacs_cv_objc_exceptions = yes; then
1683        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1684        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1685          [Define if GNUstep uses ObjC exceptions.])
1686        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1687      fi
1688   fi
1689
1690   dnl This is only used while we test the NS headers, it gets reset below.
1691   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1692
1693   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1694                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1695   files are missing or cannot be compiled.])])
1696
1697   macfont_file=""
1698   if test "${NS_IMPL_COCOA}" = "yes"; then
1699     AC_MSG_CHECKING([for OSX 10.4 or newer])
1700     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1701                                      [
1702 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1703 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1704  ; /* OK */
1705 #else
1706  error "OSX 10.4 or newer required";
1707 #endif
1708 #endif
1709                     ])],
1710                     ns_osx_have_104=yes,
1711                     ns_osx_have_104=no)
1712     AC_MSG_RESULT([$ns_osx_have_104])
1713
1714     if test $ns_osx_have_104 = no; then
1715        AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1716     fi
1717     AC_MSG_CHECKING([for OSX 10.5 or newer])
1718     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1719                                      [
1720 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1721 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1050
1722  ; /* OK */
1723 #else
1724  error "OSX 10.5 not found";
1725 #endif
1726 #endif
1727                     ])],
1728                     ns_osx_have_105=yes,
1729                     ns_osx_have_105=no)
1730     AC_MSG_RESULT([$ns_osx_have_105])
1731     if test $ns_osx_have_105 = yes; then
1732       macfont_file="macfont.o"
1733     fi
1734   fi
1735   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1736                                      [NSInteger i;])],
1737                     ns_have_nsinteger=yes,
1738                     ns_have_nsinteger=no)
1739   if test $ns_have_nsinteger = yes; then
1740     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1741   fi
1742 fi
1743
1744 AC_SUBST(LIBS_GNUSTEP)
1745
1746 INSTALL_ARCH_INDEP_EXTRA=install-etc
1747 ns_self_contained=no
1748 NS_OBJ=
1749 NS_OBJC_OBJ=
1750 if test "${HAVE_NS}" = yes; then
1751   if test "$with_toolkit_scroll_bars" = "no"; then
1752     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1753   fi
1754
1755   window_system=nextstep
1756   # set up packaging dirs
1757   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1758      ns_self_contained=yes
1759      prefix=${ns_appresdir}
1760      exec_prefix=${ns_appbindir}
1761      dnl This one isn't really used, only archlibdir is.
1762      libexecdir="\${ns_appbindir}/libexec"
1763      archlibdir="\${ns_appbindir}/libexec"
1764      etcdocdir="\${ns_appresdir}/etc"
1765      etcdir="\${ns_appresdir}/etc"
1766      dnl FIXME maybe set datarootdir instead.
1767      dnl That would also get applications, icons, man.
1768      infodir="\${ns_appresdir}/info"
1769      mandir="\${ns_appresdir}/man"
1770      lispdir="\${ns_appresdir}/lisp"
1771      INSTALL_ARCH_INDEP_EXTRA=
1772   fi
1773
1774   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o $macfont_file"
1775 fi
1776 CFLAGS="$tmp_CFLAGS"
1777 CPPFLAGS="$tmp_CPPFLAGS"
1778 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1779 AC_SUBST(ns_self_contained)
1780 AC_SUBST(NS_OBJ)
1781 AC_SUBST(NS_OBJC_OBJ)
1782
1783 HAVE_W32=no
1784 W32_OBJ=
1785 W32_LIBS=
1786 EMACSRES=
1787 CLIENTRES=
1788 CLIENTW=
1789 W32_RES_LINK=
1790 EMACS_MANIFEST=
1791 UPDATE_MANIFEST=
1792 if test "${with_w32}" != no; then
1793   case "${opsys}" in
1794     cygwin)
1795       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1796              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1797                    cannot be found.])])
1798     ;;
1799     mingw32)
1800     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1801     ;;
1802     *)
1803       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1804     ;;
1805   esac
1806 fi
1807
1808 if test "${opsys}" = "mingw32"; then
1809   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1810   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1811      #include <windows.h>
1812      #include <usp10.h>]],
1813    [[PIMAGE_NT_HEADERS pHeader;
1814      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1815    [emacs_cv_w32api=yes
1816     HAVE_W32=yes],
1817    emacs_cv_w32api=no)
1818   AC_MSG_RESULT($emacs_cv_w32api)
1819   if test "${emacs_cv_w32api}" = "no"; then
1820     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1821   fi
1822 fi
1823
1824 FIRSTFILE_OBJ=
1825 NTDIR=
1826 LIBS_ECLIENT=
1827 LIB_WSOCK32=
1828 NTLIB=
1829 CM_OBJ="cm.o"
1830 XARGS_LIMIT=
1831 if test "${HAVE_W32}" = "yes"; then
1832   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1833   AC_CHECK_TOOL(WINDRES, [windres],
1834                 [AC_MSG_ERROR([No resource compiler found.])])
1835   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1836   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1837   EMACSRES="emacs.res"
1838   case "$canonical" in
1839     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1840     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1841   esac
1842   if test "${opsys}" = "cygwin"; then
1843     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1844     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1845     # Tell the linker that emacs.res is an object (which we compile from
1846     # the rc file), not a linker script.
1847     W32_RES_LINK="-Wl,emacs.res"
1848   else
1849     UPDATE_MANIFEST=update-game-score.exe.manifest
1850     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1851     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1852     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1853     W32_RES_LINK="\$(EMACSRES)"
1854     CLIENTRES="emacsclient.res"
1855     CLIENTW="emacsclientw\$(EXEEXT)"
1856     FIRSTFILE_OBJ=firstfile.o
1857     NTDIR=nt
1858     CM_OBJ=
1859     LIBS_ECLIENT="-lcomctl32"
1860     LIB_WSOCK32="-lwsock32"
1861     NTLIB="ntlib.$ac_objext"
1862     XARGS_LIMIT="-s 10000"
1863   fi
1864 fi
1865 AC_SUBST(W32_OBJ)
1866 AC_SUBST(W32_LIBS)
1867 AC_SUBST(EMACSRES)
1868 AC_SUBST(EMACS_MANIFEST)
1869 AC_SUBST(UPDATE_MANIFEST)
1870 AC_SUBST(CLIENTRES)
1871 AC_SUBST(CLIENTW)
1872 AC_SUBST(W32_RES_LINK)
1873 AC_SUBST(FIRSTFILE_OBJ)
1874 AC_SUBST(NTDIR)
1875 AC_SUBST(CM_OBJ)
1876 AC_SUBST(LIBS_ECLIENT)
1877 AC_SUBST(LIB_WSOCK32)
1878 AC_SUBST(NTLIB)
1879 AC_SUBST(XARGS_LIMIT)
1880
1881 if test "${HAVE_W32}" = "yes"; then
1882   window_system=w32
1883   with_xft=no
1884 fi
1885
1886 ## $window_system is now set to the window system we will
1887 ## ultimately use.
1888
1889 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
1890    # Too many warnings for now.
1891    nw=
1892    nw="$nw -Wsuggest-attribute=const"
1893    nw="$nw -Wsuggest-attribute=noreturn"
1894    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1895
1896    gl_WARN_ADD([-Wno-unused-variable])
1897    gl_WARN_ADD([-Wno-unused-but-set-variable])
1898    gl_WARN_ADD([-Wno-unused-but-set-parameter])
1899 fi
1900
1901 term_header=
1902 HAVE_X_WINDOWS=no
1903 HAVE_X11=no
1904 USE_X_TOOLKIT=none
1905
1906 case "${window_system}" in
1907   x11 )
1908     HAVE_X_WINDOWS=yes
1909     HAVE_X11=yes
1910     term_header=xterm.h
1911     case "${with_x_toolkit}" in
1912       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1913       motif ) USE_X_TOOLKIT=MOTIF ;;
1914       gtk ) with_gtk=yes
1915             term_header=gtkutil.h
1916 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1917 dnl USE_X_TOOLKIT is set.
1918             USE_X_TOOLKIT=none ;;
1919       gtk2 ) with_gtk2=yes
1920              term_header=gtkutil.h
1921              USE_X_TOOLKIT=none ;;
1922       gtk3 ) with_gtk3=yes
1923              term_header=gtkutil.h
1924              USE_X_TOOLKIT=none ;;
1925       no ) USE_X_TOOLKIT=none ;;
1926 dnl If user did not say whether to use a toolkit, make this decision later:
1927 dnl use the toolkit if we have gtk, or X11R5 or newer.
1928       * ) USE_X_TOOLKIT=maybe ;;
1929     esac
1930   ;;
1931   nextstep )
1932     term_header=nsterm.h
1933   ;;
1934   w32 )
1935     term_header=w32term.h
1936   ;;
1937 esac
1938
1939 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1940    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1941    if test "$HAVE_XSERVER" = true ||
1942       test -n "$DISPLAY" ||
1943       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1944         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1945 were found.  You should install the relevant development files for X
1946 and for the toolkit you want, such as Gtk+ or Motif.  Also make
1947 sure you have development files for image handling, i.e.
1948 tiff, gif, jpeg, png and xpm.
1949 If you are sure you want Emacs compiled without X window support, pass
1950   --without-x
1951 to configure.])
1952    fi
1953 fi
1954
1955 # Does the opsystem file prohibit the use of the GNU malloc?
1956 # Assume not, until told otherwise.
1957 GNU_MALLOC=yes
1958
1959 AC_CACHE_CHECK(
1960   [whether malloc is Doug Lea style],
1961   [emacs_cv_var_doug_lea_malloc],
1962   [emacs_cv_var_doug_lea_malloc=no
1963    dnl Hooks do not work with address sanitization.
1964    if test "$emacs_cv_sanitize_address" != yes; then
1965      AC_LINK_IFELSE(
1966        [AC_LANG_PROGRAM(
1967           [[#include <malloc.h>
1968             static void hook (void) {}]],
1969           [[malloc_set_state (malloc_get_state ());
1970             __after_morecore_hook = hook;
1971             __malloc_initialize_hook = hook;]])],
1972        [emacs_cv_var_doug_lea_malloc=yes])])
1973    fi
1974 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1975
1976 system_malloc=$emacs_cv_sanitize_address
1977 case "$opsys" in
1978   ## darwin ld insists on the use of malloc routines in the System framework.
1979   darwin|sol2-10) system_malloc=yes ;;
1980 esac
1981
1982 GMALLOC_OBJ=
1983 if test "${system_malloc}" = "yes"; then
1984   AC_DEFINE([SYSTEM_MALLOC], 1,
1985     [Define to 1 to use the system memory allocator, even if it is not
1986      Doug Lea style.])
1987   GNU_MALLOC=no
1988   GNU_MALLOC_reason="
1989     (The GNU allocators don't work with this system configuration.)"
1990   VMLIMIT_OBJ=
1991 else
1992   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1993   VMLIMIT_OBJ=vm-limit.o
1994
1995   AC_CHECK_HEADERS([sys/vlimit.h])
1996   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
1997     [AC_LINK_IFELSE(
1998        [AC_LANG_PROGRAM(
1999          [[extern char data_start[]; char ch;]],
2000          [[return data_start < &ch;]])],
2001        [emacs_cv_data_start=yes],
2002        [emacs_cv_data_start=no])])
2003   if test $emacs_cv_data_start = yes; then
2004     AC_DEFINE([HAVE_DATA_START], 1,
2005       [Define to 1 if data_start is the address of the start
2006        of the main data segment.])
2007   fi
2008 fi
2009 AC_SUBST(GMALLOC_OBJ)
2010 AC_SUBST(VMLIMIT_OBJ)
2011
2012 if test "$doug_lea_malloc" = "yes" ; then
2013   if test "$GNU_MALLOC" = yes ; then
2014     GNU_MALLOC_reason="
2015       (Using Doug Lea's new malloc from the GNU C Library.)"
2016   fi
2017   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2018     [Define to 1 if the system memory allocator is Doug Lea style,
2019      with malloc hooks and malloc_set_state.])
2020
2021   ## Use mmap directly for allocating larger buffers.
2022   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2023   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2024   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2025   case "$opsys" in
2026     gnu*) REL_ALLOC=no ;;
2027   esac
2028 fi
2029
2030 if test x"${REL_ALLOC}" = x; then
2031   REL_ALLOC=${GNU_MALLOC}
2032 fi
2033
2034 use_mmap_for_buffers=no
2035 case "$opsys" in
2036   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2037 esac
2038
2039 AC_FUNC_MMAP
2040 if test $use_mmap_for_buffers = yes; then
2041   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2042   REL_ALLOC=no
2043 fi
2044
2045 LIBS="$LIBS_SYSTEM $LIBS"
2046
2047 dnl If found, this adds -ldnet to LIBS, which Autoconf uses for checks.
2048 AC_CHECK_LIB(dnet, dnet_ntoa)
2049 dnl This causes -lresolv to get used in subsequent tests,
2050 dnl which causes failures on some systems such as HPUX 9.
2051 dnl AC_CHECK_LIB(resolv, gethostbyname)
2052
2053 dnl FIXME replace main with a function we actually want from this library.
2054 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2055
2056 dnl Check if pthreads is available.
2057 LIB_PTHREAD=
2058 AC_CHECK_HEADERS_ONCE(pthread.h)
2059 if test "$ac_cv_header_pthread_h"; then
2060   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
2061   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
2062   dnl testing for pthread_self if Emacs uses gmalloc.c.
2063   if test "$GMALLOC_OBJ" = gmalloc.o; then
2064     emacs_pthread_function=pthread_atfork
2065   else
2066     emacs_pthread_function=pthread_self
2067   fi
2068   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
2069 fi
2070 if test "$HAVE_PTHREAD" = yes; then
2071   case "${canonical}" in
2072     *-hpux*) ;;
2073     *) LIB_PTHREAD="-lpthread"
2074        LIBS="$LIB_PTHREAD $LIBS" ;;
2075   esac
2076   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
2077 fi
2078 AC_SUBST([LIB_PTHREAD])
2079
2080 AC_CHECK_LIB(pthreads, cma_open)
2081
2082 ## Note: when using cpp in s/aix4.2.h, this definition depended on
2083 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
2084 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
2085 ## added to LIBS in configure would never contain the pthreads part,
2086 ## but the value used in Makefiles might.  FIXME?
2087 ##
2088 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
2089 ## be harmless on older versions of X where it happens to exist.
2090 test "$opsys" = "aix4-2" && \
2091   test $ac_cv_lib_pthreads_cma_open = yes && \
2092   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
2093
2094 dnl Check for need for bigtoc support on IBM AIX
2095
2096 case ${host_os} in
2097 aix*)
2098   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2099     case $GCC in
2100     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2101     *) gdb_cv_bigtoc=-bbigtoc ;;
2102     esac
2103
2104     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2105     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2106   ])
2107   ;;
2108 esac
2109
2110 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
2111 # used for the tests that follow.  We set them back to REAL_CFLAGS and
2112 # REAL_CPPFLAGS later on.
2113
2114 REAL_CFLAGS="$CFLAGS"
2115 REAL_CPPFLAGS="$CPPFLAGS"
2116
2117 if test "${HAVE_X11}" = "yes"; then
2118   DEFS="$C_SWITCH_X_SITE $DEFS"
2119   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2120   LIBS="-lX11 $LIBS"
2121   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2122   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2123
2124   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2125   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2126   # but it's more convenient here to set LD_RUN_PATH since this
2127   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2128   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2129     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2130     export LD_RUN_PATH
2131   fi
2132
2133   if test "${opsys}" = "gnu-linux"; then
2134     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2135     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2136      [[XOpenDisplay ("foo");]])],
2137      [xgnu_linux_first_failure=no],
2138      [xgnu_linux_first_failure=yes])
2139     if test "${xgnu_linux_first_failure}" = "yes"; then
2140       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
2141       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
2142       OLD_CPPFLAGS="$CPPFLAGS"
2143       OLD_LIBS="$LIBS"
2144       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2145       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2146       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2147       LIBS="$LIBS -b i486-linuxaout"
2148       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2149        [[XOpenDisplay ("foo");]])],
2150        [xgnu_linux_second_failure=no],
2151        [xgnu_linux_second_failure=yes])
2152       if test "${xgnu_linux_second_failure}" = "yes"; then
2153         # If we get the same failure with -b, there is no use adding -b.
2154         # So take it out.  This plays safe.
2155         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
2156         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
2157         CPPFLAGS="$OLD_CPPFLAGS"
2158         LIBS="$OLD_LIBS"
2159         AC_MSG_RESULT(no)
2160       else
2161         AC_MSG_RESULT(yes)
2162       fi
2163     else
2164       AC_MSG_RESULT(no)
2165     fi
2166   fi
2167
2168   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2169   # header files included from there.
2170   AC_MSG_CHECKING(for Xkb)
2171   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2172 #include <X11/XKBlib.h>]],
2173         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2174         emacs_xkb=yes, emacs_xkb=no)
2175   AC_MSG_RESULT($emacs_xkb)
2176   if test $emacs_xkb = yes; then
2177     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2178   fi
2179
2180   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2181 XScreenNumberOfScreen)
2182 fi
2183
2184 if test "${window_system}" = "x11"; then
2185   AC_MSG_CHECKING(X11 version 6)
2186   AC_CACHE_VAL(emacs_cv_x11_version_6,
2187   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2188 [[#if XlibSpecificationRelease < 6
2189 fail;
2190 #endif
2191 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2192   if test $emacs_cv_x11_version_6 = yes; then
2193     AC_MSG_RESULT(6 or newer)
2194     AC_DEFINE(HAVE_X11R6, 1,
2195               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2196     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2197     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2198     ## XIM support.
2199     case "$opsys" in
2200       sol2-*) : ;;
2201       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2202            [Define if you have usable X11R6-style XIM support.])
2203          ;;
2204     esac
2205   else
2206     AC_MSG_RESULT(before 6)
2207   fi
2208 fi
2209
2210
2211 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2212 HAVE_RSVG=no
2213 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2214   if test "${with_rsvg}" != "no"; then
2215     RSVG_REQUIRED=2.11.0
2216     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2217
2218     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
2219     AC_SUBST(RSVG_CFLAGS)
2220     AC_SUBST(RSVG_LIBS)
2221
2222     if test $HAVE_RSVG = yes; then
2223       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2224       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2225       # Windows loads librsvg dynamically
2226       if test "${opsys}" = "mingw32"; then
2227         RSVG_LIBS=
2228       fi
2229       LIBS="$RSVG_LIBS $LIBS"
2230     fi
2231   fi
2232 fi
2233
2234 HAVE_IMAGEMAGICK=no
2235 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2236   if test "${with_imagemagick}" != "no"; then
2237     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2238     ## 6.8.2 makes Emacs crash; see Bug#13867.
2239     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2240     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
2241     AC_SUBST(IMAGEMAGICK_CFLAGS)
2242     AC_SUBST(IMAGEMAGICK_LIBS)
2243
2244     if test $HAVE_IMAGEMAGICK = yes; then
2245       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2246       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2247       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2248       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2249     fi
2250   fi
2251 fi
2252
2253
2254 HAVE_GTK=no
2255 GTK_OBJ=
2256 gtk_term_header=$term_header
2257 check_gtk2=no
2258 gtk3_pkg_errors=
2259 if test "${opsys}" != "mingw32"; then
2260   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2261     GLIB_REQUIRED=2.28
2262     GTK_REQUIRED=3.0
2263     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2264
2265     dnl Checks for libraries.
2266     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2267     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2268        AC_MSG_ERROR($GTK_PKG_ERRORS)
2269     fi
2270     if test "$pkg_check_gtk" = "yes"; then
2271        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2272        GTK_OBJ=emacsgtkfixed.o
2273        gtk_term_header=gtkutil.h
2274        USE_GTK_TOOLKIT="GTK3"
2275        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2276          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2277            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2278          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2279            [Define to 1 to disable Glib deprecation warnings.])
2280        fi
2281     else
2282        check_gtk2=yes
2283        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2284     fi
2285   fi
2286
2287   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2288     GLIB_REQUIRED=2.10
2289     GTK_REQUIRED=2.10
2290     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2291
2292     dnl Checks for libraries.
2293     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2294     if test "$pkg_check_gtk" = "no" &&
2295        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2296     then
2297       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2298     fi
2299     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2300   fi
2301 fi
2302
2303 if test x"$pkg_check_gtk" = xyes; then
2304
2305   AC_SUBST(GTK_LIBS)
2306   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2307   CFLAGS="$CFLAGS $GTK_CFLAGS"
2308   LIBS="$GTK_LIBS $LIBS"
2309   dnl Try to compile a simple GTK program.
2310   AC_MSG_CHECKING([whether GTK compiles])
2311   GTK_COMPILES=no
2312   AC_LINK_IFELSE(
2313     [AC_LANG_PROGRAM(
2314        [[/* Check the Gtk and Glib APIs.  */
2315          #include <gtk/gtk.h>
2316          #include <glib-object.h>
2317          static void
2318          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2319          {}
2320        ]],
2321        [[
2322          GtkSettings *gs = 0;
2323          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2324             strict C prohibits this.  Use gtk_main_iteration to test that the
2325             libraries are there.  */
2326          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2327                                     0, 0, 0, G_CALLBACK (callback), 0))
2328            gtk_main_iteration ();
2329        ]])],
2330     [GTK_COMPILES=yes])
2331   AC_MSG_RESULT([$GTK_COMPILES])
2332   if test "${GTK_COMPILES}" != "yes"; then
2333     GTK_OBJ=
2334     if test "$USE_X_TOOLKIT" != "maybe"; then
2335       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2336     fi
2337   else
2338     HAVE_GTK=yes
2339     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2340     GTK_OBJ="gtkutil.o $GTK_OBJ"
2341     term_header=$gtk_term_header
2342     USE_X_TOOLKIT=none
2343     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2344       :
2345     else
2346       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2347        closing open displays.  This is no problem if you just use
2348        one display, but if you use more than one and close one of them
2349        Emacs may crash.]])
2350       sleep 3
2351     fi
2352   fi
2353
2354 fi
2355 AC_SUBST(GTK_OBJ)
2356
2357
2358 if test "${HAVE_GTK}" = "yes"; then
2359
2360   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2361   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2362   if test "$with_toolkit_scroll_bars" != no; then
2363     with_toolkit_scroll_bars=yes
2364   fi
2365
2366   dnl  Check if we have the old file selection dialog declared and
2367   dnl  in the link library.  In 2.x it may be in the library,
2368   dnl  but not declared if deprecated featured has been selected out.
2369   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2370   HAVE_GTK_FILE_SELECTION=no
2371   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2372                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2373 #include <gtk/gtk.h>])
2374   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2375     AC_CHECK_FUNCS(gtk_file_selection_new)
2376   fi
2377
2378   dnl Same as above for gtk_handle_box.
2379   HAVE_GTK_HANDLE_BOX=no
2380   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2381                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2382 #include <gtk/gtk.h>])
2383   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2384     AC_CHECK_FUNCS(gtk_handle_box_new)
2385   fi
2386
2387   dnl Same as above for gtk_tearoff_menu_item.
2388   HAVE_GTK_TEAROFF_MENU_ITEM=no
2389   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2390                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2391 #include <gtk/gtk.h>])
2392   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2393     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2394   fi
2395
2396   dnl Check for functions introduced in 2.14 and later.
2397   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2398                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2399                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2400                  gtk_orientable_set_orientation \
2401                  gtk_window_set_has_resize_grip)
2402
2403  term_header=gtkutil.h
2404 fi
2405
2406 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2407 dnl other platforms.
2408 HAVE_DBUS=no
2409 DBUS_OBJ=
2410 if test "${with_dbus}" = "yes"; then
2411    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2412    if test "$HAVE_DBUS" = yes; then
2413      LIBS="$LIBS $DBUS_LIBS"
2414      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2415      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2416      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2417      dnl D-Bus 1.5.12.
2418      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2419                     dbus_type_is_valid \
2420                     dbus_validate_bus_name \
2421                     dbus_validate_path \
2422                     dbus_validate_interface \
2423                     dbus_validate_member)
2424      DBUS_OBJ=dbusbind.o
2425    fi
2426 fi
2427 AC_SUBST(DBUS_OBJ)
2428
2429 dnl GSettings has been tested under GNU/Linux only.
2430 HAVE_GSETTINGS=no
2431 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2432    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2433    if test "$HAVE_GSETTINGS" = "yes"; then
2434       old_CFLAGS=$CFLAGS
2435       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2436       old_LIBS=$LIBS
2437       LIBS="$LIBS $GSETTINGS_LIBS"
2438       AC_MSG_CHECKING([whether GSettings is in gio])
2439       AC_LINK_IFELSE(
2440          [AC_LANG_PROGRAM(
2441              [[/* Check that gsettings really is present.  */
2442              #include <glib-object.h>
2443              #include <gio/gio.h>
2444              ]],
2445              [[
2446                GSettings *settings;
2447                GVariant *val = g_settings_get_value (settings, "");
2448              ]])],
2449          [], HAVE_GSETTINGS=no)
2450       AC_MSG_RESULT([$HAVE_GSETTINGS])
2451
2452       if test "$HAVE_GSETTINGS" = "yes"; then
2453         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2454         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2455         SETTINGS_LIBS="$GSETTINGS_LIBS"
2456       fi
2457       CFLAGS=$old_CFLAGS
2458       LIBS=$old_LIBS
2459    fi
2460 fi
2461
2462 dnl GConf has been tested under GNU/Linux only.
2463 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2464 HAVE_GCONF=no
2465 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2466    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2467    if test "$HAVE_GCONF" = yes; then
2468       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2469       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2470       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2471       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2472    fi
2473 fi
2474
2475 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2476     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2477     if test "$HAVE_GOBJECT" = "yes"; then
2478        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2479        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2480     fi
2481     SAVE_CFLAGS="$CFLAGS"
2482     SAVE_LIBS="$LIBS"
2483     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2484     LIBS="$SETTINGS_LIBS $LIBS"
2485     CFLAGS="$SAVE_CFLAGS"
2486     LIBS="$SAVE_LIBS"
2487 fi
2488 AC_SUBST(SETTINGS_CFLAGS)
2489 AC_SUBST(SETTINGS_LIBS)
2490
2491
2492 dnl SELinux is available for GNU/Linux only.
2493 HAVE_LIBSELINUX=no
2494 LIBSELINUX_LIBS=
2495 if test "${with_selinux}" = "yes"; then
2496    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2497    if test "$HAVE_LIBSELINUX" = yes; then
2498       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2499       LIBSELINUX_LIBS=-lselinux
2500    fi
2501 fi
2502 AC_SUBST(LIBSELINUX_LIBS)
2503
2504 HAVE_GNUTLS=no
2505 HAVE_GNUTLS3=no
2506 if test "${with_gnutls}" = "yes" ; then
2507   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.0.0], HAVE_GNUTLS3=yes, HAVE_GNUTLS3=no)
2508   if test "${HAVE_GNUTLS3}" = "yes"; then
2509     AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])
2510     HAVE_GNUTLS="yes"
2511   else
2512     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2513   fi
2514   if test "${HAVE_GNUTLS}" = "yes"; then
2515     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2516   fi
2517
2518   # Windows loads GnuTLS dynamically
2519   if test "${opsys}" = "mingw32"; then
2520     LIBGNUTLS_LIBS=
2521   fi
2522 fi
2523
2524 AC_SUBST(LIBGNUTLS_LIBS)
2525 AC_SUBST(LIBGNUTLS_CFLAGS)
2526
2527 NOTIFY_OBJ=
2528 NOTIFY_SUMMARY=no
2529
2530 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2531 dnl a particular library.  This doesn't make much sense?
2532 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2533   with_file_notification=no
2534 fi
2535
2536 dnl MS Windows native file monitor is available for mingw32 only.
2537 case $with_file_notification,$opsys in
2538   w32,* | yes,mingw32)
2539     AC_CHECK_HEADER(windows.h)
2540     if test "$ac_cv_header_windows_h" = yes ; then
2541        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2542        NOTIFY_OBJ=w32notify.o
2543        NOTIFY_SUMMARY="yes (w32)"
2544     fi ;;
2545 esac
2546
2547 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2548 dnl has been added in glib 2.24.  It has been tested under
2549 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2550 dnl only sense when glib has been compiled with inotify support.  How
2551 dnl to check?
2552 case $with_file_notification,$NOTIFY_OBJ in
2553   gfile, | yes,)
2554     PKG_CHECK_MODULES(GFILENOTIFY, gio-2.0 >= 2.24, HAVE_GFILENOTIFY=yes, HAVE_GFILENOTIFY=no)
2555     if test "$HAVE_GFILENOTIFY" = "yes"; then
2556        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2557        NOTIFY_OBJ=gfilenotify.o
2558        NOTIFY_SUMMARY="yes -lgio (gfile)"
2559     fi ;;
2560 esac
2561
2562 dnl inotify is only available on GNU/Linux.
2563 case $with_file_notification,$NOTIFY_OBJ in
2564   inotify, | yes,)
2565     AC_CHECK_HEADER(sys/inotify.h)
2566     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2567         AC_CHECK_FUNC(inotify_init1)
2568         if test "$ac_cv_func_inotify_init1" = yes; then
2569           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2570           NOTIFY_OBJ=inotify.o
2571           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2572        fi
2573     fi ;;
2574 esac
2575
2576 case $with_file_notification,$NOTIFY_OBJ in
2577   yes,* | no,* | *,?*) ;;
2578   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2579 esac
2580
2581 if test -n "$NOTIFY_OBJ"; then
2582    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2583 fi
2584 AC_SUBST(NOTIFY_OBJ)
2585 AC_SUBST(GFILENOTIFY_CFLAGS)
2586 AC_SUBST(GFILENOTIFY_LIBS)
2587
2588 dnl Do not put whitespace before the #include statements below.
2589 dnl Older compilers (eg sunos4 cc) choke on it.
2590 HAVE_XAW3D=no
2591 LUCID_LIBW=
2592 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2593   if test "$with_xaw3d" != no; then
2594     AC_CACHE_VAL(emacs_cv_xaw3d,
2595     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2596 #include <X11/Intrinsic.h>
2597 #include <X11/Xaw3d/Simple.h>]],
2598       [[]])],
2599       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2600                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2601       emacs_cv_xaw3d=no)])
2602   else
2603     emacs_cv_xaw3d=no
2604   fi
2605   if test $emacs_cv_xaw3d = yes; then
2606     AC_MSG_CHECKING(for xaw3d)
2607     AC_MSG_RESULT([yes; using Lucid toolkit])
2608     USE_X_TOOLKIT=LUCID
2609     HAVE_XAW3D=yes
2610     LUCID_LIBW=-lXaw3d
2611     AC_DEFINE(HAVE_XAW3D, 1,
2612               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2613   else
2614     AC_MSG_CHECKING(for xaw3d)
2615     AC_MSG_RESULT(no)
2616     AC_MSG_CHECKING(for libXaw)
2617     AC_CACHE_VAL(emacs_cv_xaw,
2618     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2619 #include <X11/Intrinsic.h>
2620 #include <X11/Xaw/Simple.h>]],
2621       [[]])],
2622       emacs_cv_xaw=yes,
2623       emacs_cv_xaw=no)])
2624     if test $emacs_cv_xaw = yes; then
2625       AC_MSG_RESULT([yes; using Lucid toolkit])
2626       USE_X_TOOLKIT=LUCID
2627       LUCID_LIBW=-lXaw
2628     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2629       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2630     else
2631       AC_MSG_ERROR([No X toolkit could be found.
2632 If you are sure you want Emacs compiled without an X toolkit, pass
2633   --with-x-toolkit=no
2634 to configure.  Otherwise, install the development libraries for the toolkit
2635 that you want to use (e.g. Gtk+) and re-run configure.])
2636     fi
2637   fi
2638 fi
2639
2640 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2641
2642 LIBXTR6=
2643 if test "${USE_X_TOOLKIT}" != "none"; then
2644   AC_MSG_CHECKING(X11 toolkit version)
2645   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2646   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2647 [[#if XtSpecificationRelease < 6
2648 fail;
2649 #endif
2650 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2651   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2652   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2653     AC_MSG_RESULT(6 or newer)
2654     AC_DEFINE(HAVE_X11XTR6, 1,
2655               [Define to 1 if you have the X11R6 or newer version of Xt.])
2656     LIBXTR6="-lSM -lICE"
2657     case "$opsys" in
2658       ## Use libw.a along with X11R6 Xt.
2659       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2660     esac
2661   else
2662     AC_MSG_RESULT(before 6)
2663   fi
2664
2665 dnl If using toolkit, check whether libXmu.a exists.
2666 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2667   OLDLIBS="$LIBS"
2668   if test x$HAVE_X11XTR6 = xyes; then
2669     LIBS="-lXt -lSM -lICE $LIBS"
2670   else
2671     LIBS="-lXt $LIBS"
2672   fi
2673   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2674   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2675   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2676 fi
2677 AC_SUBST(LIBXTR6)
2678
2679 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2680 dnl Why not just test for libxmu in the normal way?
2681 LIBXMU=-lXmu
2682 case $opsys in
2683   ## These systems don't supply Xmu.
2684   hpux* | aix4-2 )
2685     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2686     ;;
2687   mingw32 )
2688     LIBXMU=
2689     ;;
2690 esac
2691 AC_SUBST(LIBXMU)
2692
2693 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2694 if test "${HAVE_X11}" = "yes"; then
2695   if test "${USE_X_TOOLKIT}" != "none"; then
2696     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2697   fi
2698 fi
2699
2700 LIBXP=
2701 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2702   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2703   if test -d /usr/include/openmotif; then
2704     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2705     emacs_cv_openmotif=yes
2706     case "$canonical" in
2707       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2708       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2709       ;;
2710       *)
2711       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2712     esac
2713   else
2714     emacs_cv_openmotif=no
2715   fi
2716   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2717   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2718     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2719 int x = 5;
2720 #else
2721 Motif version prior to 2.1.
2722 #endif]])],
2723     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2724   if test $emacs_cv_motif_version_2_1 = yes; then
2725     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2726     if test x$emacs_cv_openmotif = xyes; then
2727       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2728     fi
2729   else
2730     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2731     # We put this in CFLAGS temporarily to precede other -I options
2732     # that might be in CFLAGS temporarily.
2733     # We put this in CPPFLAGS where it precedes the other -I options.
2734     OLD_CPPFLAGS=$CPPFLAGS
2735     OLD_CFLAGS=$CFLAGS
2736     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2737     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2738     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2739       [[int x = 5;]])],
2740       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2741     if test $emacs_cv_lesstif = yes; then
2742       # Make sure this -I option remains in CPPFLAGS after it is set
2743       # back to REAL_CPPFLAGS.
2744       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2745       # have those other -I options anyway.  Ultimately, having this
2746       # directory ultimately in CPPFLAGS will be enough.
2747       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2748       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2749     else
2750       CFLAGS=$OLD_CFLAGS
2751       CPPFLAGS=$OLD_CPPFLAGS
2752     fi
2753   fi
2754   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2755     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2756 fi
2757
2758 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2759 dnl using Motif or Xaw3d is available, and unless
2760 dnl --with-toolkit-scroll-bars=no was specified.
2761
2762 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2763             [Define to 1 if we should use toolkit scroll bars.])dnl
2764 USE_TOOLKIT_SCROLL_BARS=no
2765 if test "${with_toolkit_scroll_bars}" != "no"; then
2766   if test "${USE_X_TOOLKIT}" != "none"; then
2767     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2768       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2769       HAVE_XAW3D=no
2770       USE_TOOLKIT_SCROLL_BARS=yes
2771     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2772       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2773       USE_TOOLKIT_SCROLL_BARS=yes
2774     fi
2775   elif test "${HAVE_GTK}" = "yes"; then
2776     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2777     USE_TOOLKIT_SCROLL_BARS=yes
2778   elif test "${HAVE_NS}" = "yes"; then
2779     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2780     USE_TOOLKIT_SCROLL_BARS=yes
2781   elif test "${HAVE_W32}" = "yes"; then
2782     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2783     USE_TOOLKIT_SCROLL_BARS=yes
2784   fi
2785 fi
2786
2787 dnl See if XIM is available.
2788 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2789           #include <X11/Xlib.h>
2790           #include <X11/Xresource.h>]],
2791          [[XIMProc  callback;]])],
2792          [HAVE_XIM=yes
2793          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2794          HAVE_XIM=no)
2795
2796 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2797
2798 if test "${with_xim}" != "no"; then
2799   AC_DEFINE(USE_XIM, 1,
2800             [Define to 1 if we should use XIM, if it is available.])
2801 fi
2802
2803
2804 if test "${HAVE_XIM}" != "no"; then
2805   late_CFLAGS=$CFLAGS
2806   if test "$GCC" = yes; then
2807     CFLAGS="$CFLAGS --pedantic-errors"
2808   fi
2809   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2810 #include <X11/Xlib.h>
2811 #include <X11/Xresource.h>]],
2812 [[Display *display;
2813 XrmDatabase db;
2814 char *res_name;
2815 char *res_class;
2816 XIMProc  callback;
2817 XPointer *client_data;
2818 #ifndef __GNUC__
2819 /* If we're not using GCC, it's probably not XFree86, and this is
2820    probably right, but we can't use something like --pedantic-errors.  */
2821 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2822                                            char*, XIMProc, XPointer*);
2823 #endif
2824 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2825    client_data);]])],
2826     [emacs_cv_arg6_star=yes])
2827   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2828          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2829 either XPointer or XPointer*.])dnl
2830   if test "$emacs_cv_arg6_star" = yes; then
2831     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2832   else
2833     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2834   fi
2835   CFLAGS=$late_CFLAGS
2836 fi
2837
2838 ### Start of font-backend (under any platform) section.
2839 # (nothing here yet -- this is a placeholder)
2840 ### End of font-backend (under any platform) section.
2841
2842 ### Start of font-backend (under X11) section.
2843 if test "${HAVE_X11}" = "yes"; then
2844    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2845
2846    ## Use -lXft if available, unless `--with-xft=no'.
2847    HAVE_XFT=maybe
2848     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2849       with_xft="no";
2850     fi
2851     if test "x${with_xft}" != "xno"; then
2852
2853       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2854       ## Because xftfont.c uses XRenderQueryExtension, we also
2855       ## need to link to -lXrender.
2856       HAVE_XRENDER=no
2857       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2858       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2859         OLD_CPPFLAGS="$CPPFLAGS"
2860         OLD_CFLAGS="$CFLAGS"
2861         OLD_LIBS="$LIBS"
2862         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2863         CFLAGS="$CFLAGS $XFT_CFLAGS"
2864         XFT_LIBS="-lXrender $XFT_LIBS"
2865         LIBS="$XFT_LIBS $LIBS"
2866         AC_CHECK_HEADER(X11/Xft/Xft.h,
2867           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2868           [[#include <X11/X.h>]])
2869
2870         if test "${HAVE_XFT}" = "yes"; then
2871           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2872             AC_SUBST(XFT_LIBS)
2873           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2874         else
2875           CPPFLAGS="$OLD_CPPFLAGS"
2876           CFLAGS="$OLD_CFLAGS"
2877           LIBS="$OLD_LIBS"
2878         fi                        # "${HAVE_XFT}" = "yes"
2879       fi                          # "$HAVE_XFT" != no
2880     fi                            # "x${with_xft}" != "xno"
2881
2882     ## We used to allow building with FreeType and without Xft.
2883     ## However, the ftx font backend driver is not in good shape.
2884     if test "$HAVE_XFT" != "yes"; then
2885        dnl For the "Does Emacs use" message at the end.
2886        HAVE_XFT=no
2887        HAVE_FREETYPE=no
2888     else
2889        dnl Strict linkers fail with
2890        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2891        dnl if -lfreetype is not specified.
2892        dnl The following is needed to set FREETYPE_LIBS.
2893        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2894                          HAVE_FREETYPE=no)
2895
2896        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2897     fi
2898
2899     HAVE_LIBOTF=no
2900     if test "${HAVE_FREETYPE}" = "yes"; then
2901       AC_DEFINE(HAVE_FREETYPE, 1,
2902                 [Define to 1 if using the freetype and fontconfig libraries.])
2903       if test "${with_libotf}" != "no"; then
2904         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2905                           HAVE_LIBOTF=no)
2906         if test "$HAVE_LIBOTF" = "yes"; then
2907           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2908           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2909                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2910                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2911           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2912             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2913                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2914           fi
2915         fi
2916       fi
2917     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2918     dnl Does the new font backend require it, or can it work without it?
2919     fi
2920
2921     HAVE_M17N_FLT=no
2922     if test "${HAVE_LIBOTF}" = yes; then
2923       if test "${with_m17n_flt}" != "no"; then
2924         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2925         if test "$HAVE_M17N_FLT" = "yes"; then
2926           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2927         fi
2928       fi
2929     fi
2930 else
2931     HAVE_XFT=no
2932     HAVE_FREETYPE=no
2933     HAVE_LIBOTF=no
2934     HAVE_M17N_FLT=no
2935 fi
2936
2937 ### End of font-backend (under X11) section.
2938
2939 AC_SUBST(FREETYPE_CFLAGS)
2940 AC_SUBST(FREETYPE_LIBS)
2941 AC_SUBST(FONTCONFIG_CFLAGS)
2942 AC_SUBST(FONTCONFIG_LIBS)
2943 AC_SUBST(LIBOTF_CFLAGS)
2944 AC_SUBST(LIBOTF_LIBS)
2945 AC_SUBST(M17N_FLT_CFLAGS)
2946 AC_SUBST(M17N_FLT_LIBS)
2947
2948 ### Use -lXpm if available, unless `--with-xpm=no'.
2949 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2950 HAVE_XPM=no
2951 LIBXPM=
2952 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
2953   if test "${with_xpm}" != "no"; then
2954     SAVE_CPPFLAGS="$CPPFLAGS"
2955     SAVE_LDFLAGS="$LDFLAGS"
2956     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2957     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2958     AC_CHECK_HEADER(X11/xpm.h,
2959       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2960     if test "${HAVE_XPM}" = "yes"; then
2961       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2962       AC_EGREP_CPP(no_return_alloc_pixels,
2963       [#include "X11/xpm.h"
2964 #ifndef XpmReturnAllocPixels
2965 no_return_alloc_pixels
2966 #endif
2967       ], HAVE_XPM=no, HAVE_XPM=yes)
2968
2969       if test "${HAVE_XPM}" = "yes"; then
2970         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2971         AC_MSG_RESULT(yes)
2972       else
2973         AC_MSG_RESULT(no)
2974         CPPFLAGS="$SAVE_CPPFLAGS"
2975         LDFLAGS="$SAVE_LDFLAGS"
2976       fi
2977     fi
2978   fi
2979
2980   if test "${HAVE_XPM}" = "yes"; then
2981     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2982     LIBXPM=-lXpm
2983   fi
2984 fi
2985
2986 if test "${HAVE_X11}" = "yes"; then
2987   if test "${with_xpm}" != "no"; then
2988     AC_CHECK_HEADER(X11/xpm.h,
2989       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2990     if test "${HAVE_XPM}" = "yes"; then
2991       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2992       AC_EGREP_CPP(no_return_alloc_pixels,
2993       [#include "X11/xpm.h"
2994 #ifndef XpmReturnAllocPixels
2995 no_return_alloc_pixels
2996 #endif
2997       ], HAVE_XPM=no, HAVE_XPM=yes)
2998
2999       if test "${HAVE_XPM}" = "yes"; then
3000         AC_MSG_RESULT(yes)
3001       else
3002         AC_MSG_RESULT(no)
3003       fi
3004     fi
3005   fi
3006
3007   if test "${HAVE_XPM}" = "yes"; then
3008     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3009     LIBXPM=-lXpm
3010   fi
3011 fi
3012
3013 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3014 ### slightly different requirements wrt image libraries (it doesn't
3015 ### use -lXpm because it loads the xpm shared library dynamically at
3016 ### run time).
3017 if test "${opsys}" = "mingw32"; then
3018   if test "${with_xpm}" != "no"; then
3019     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3020 #define FOR_MSW 1])
3021   fi
3022
3023   if test "${HAVE_XPM}" = "yes"; then
3024     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3025   fi
3026 fi
3027
3028 AC_SUBST(LIBXPM)
3029
3030 ### Use -ljpeg if available, unless `--with-jpeg=no'.
3031 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
3032 HAVE_JPEG=no
3033 LIBJPEG=
3034 if test "${opsys}" = "mingw32"; then
3035   if test "${with_jpeg}" != "no"; then
3036     dnl Checking for jpeglib.h can lose because of a redefinition of
3037     dnl HAVE_STDLIB_H.
3038     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
3039   fi
3040   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3041   if test "${HAVE_JPEG}" = "yes"; then
3042     AC_DEFINE(HAVE_JPEG)
3043     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3044         [#include <jpeglib.h>
3045          version=JPEG_LIB_VERSION
3046 ],
3047         [AC_DEFINE(HAVE_JPEG)],
3048         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3049         HAVE_JPEG=no])
3050   fi
3051 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3052   if test "${with_jpeg}" != "no"; then
3053     dnl Checking for jpeglib.h can lose because of a redefinition of
3054     dnl  HAVE_STDLIB_H.
3055     AC_CHECK_HEADER(jerror.h,
3056       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
3057   fi
3058
3059   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3060   if test "${HAVE_JPEG}" = "yes"; then
3061     AC_DEFINE(HAVE_JPEG)
3062     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3063         [#include <jpeglib.h>
3064          version=JPEG_LIB_VERSION
3065 ],
3066         [AC_DEFINE(HAVE_JPEG)],
3067         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3068         HAVE_JPEG=no])
3069   fi
3070   if test "${HAVE_JPEG}" = "yes"; then
3071     LIBJPEG=-ljpeg
3072   fi
3073 fi
3074 AC_SUBST(LIBJPEG)
3075
3076 ### Use -lpng if available, unless `--with-png=no'.
3077 ### mingw32 doesn't use -lpng, since it loads the library dynamically.
3078 HAVE_PNG=no
3079 LIBPNG=
3080 if test "${opsys}" = "mingw32"; then
3081   if test "${with_png}" != "no"; then
3082     AC_CHECK_HEADER(png.h, HAVE_PNG=yes, HAVE_PNG=no)
3083   fi
3084   if test "${HAVE_PNG}" = "yes"; then
3085     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
3086
3087     AC_CHECK_DECL(png_longjmp,
3088       [],
3089       [AC_DEFINE(PNG_DEPSTRUCT, [],
3090          [Define to empty to suppress deprecation warnings when building
3091           with --enable-gcc-warnings and with libpng versions before 1.5,
3092           which lack png_longjmp.])],
3093       [[#ifdef HAVE_LIBPNG_PNG_H
3094         # include <libpng/png.h>
3095         #else
3096         # include <png.h>
3097         #endif
3098       ]])
3099   fi
3100 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3101   if test "${with_png}" != "no"; then
3102     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3103     # in /usr/include/libpng.
3104     AC_CHECK_HEADERS(png.h libpng/png.h, break)
3105     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
3106       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
3107     fi
3108   fi
3109
3110   if test "${HAVE_PNG}" = "yes"; then
3111     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library.])
3112
3113     dnl Some systems, eg NetBSD 6, only provide eg "libpng16", not "libpng".
3114     lpng=`libpng-config --libs 2> /dev/null`
3115     case $lpng in
3116       -l*) : ;;
3117       *) lpng="-lpng" ;;
3118     esac
3119     LIBPNG="$lpng -lz -lm"
3120
3121     AC_CHECK_DECL(png_longjmp,
3122       [],
3123       [AC_DEFINE(PNG_DEPSTRUCT, [],
3124          [Define to empty to suppress deprecation warnings when building
3125           with --enable-gcc-warnings and with libpng versions before 1.5,
3126           which lack png_longjmp.])],
3127       [[#ifdef HAVE_LIBPNG_PNG_H
3128         # include <libpng/png.h>
3129         #else
3130         # include <png.h>
3131         #endif
3132       ]])
3133   fi
3134 fi
3135 AC_SUBST(LIBPNG)
3136
3137 HAVE_ZLIB=no
3138 LIBZ=
3139 if test "${with_zlib}" != "no"; then
3140   OLIBS=$LIBS
3141   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3142   LIBS=$OLIBS
3143   case $ac_cv_search_inflateEnd in
3144     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3145   esac
3146 fi
3147 if test "${HAVE_ZLIB}" = "yes"; then
3148   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3149   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3150   if test "${opsys}" = "mingw32"; then
3151      LIBZ=
3152   fi
3153 fi
3154 AC_SUBST(LIBZ)
3155
3156
3157 ### Use -ltiff if available, unless `--with-tiff=no'.
3158 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3159 HAVE_TIFF=no
3160 LIBTIFF=
3161 if test "${opsys}" = "mingw32"; then
3162   if test "${with_tiff}" != "no"; then
3163     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3164   fi
3165   if test "${HAVE_TIFF}" = "yes"; then
3166     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3167   fi
3168 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3169   if test "${with_tiff}" != "no"; then
3170     AC_CHECK_HEADER(tiffio.h,
3171       [tifflibs="-lz -lm"
3172       # At least one tiff package requires the jpeg library.
3173       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3174       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3175   fi
3176
3177   if test "${HAVE_TIFF}" = "yes"; then
3178     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3179     dnl FIXME -lz -lm, as per libpng?
3180     LIBTIFF=-ltiff
3181   fi
3182 fi
3183 AC_SUBST(LIBTIFF)
3184
3185 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3186 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3187 HAVE_GIF=no
3188 LIBGIF=
3189 if test "${opsys}" = "mingw32"; then
3190   if test "${with_gif}" != "no"; then
3191     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3192   fi
3193   if test "${HAVE_GIF}" = "yes"; then
3194     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3195   fi
3196 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3197         || test "${HAVE_W32}" = "yes"; then
3198   AC_CHECK_HEADER(gif_lib.h,
3199 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3200 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3201     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3202         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3203
3204   if test "$HAVE_GIF" = yes; then
3205     LIBGIF=-lgif
3206   elif test "$HAVE_GIF" = maybe; then
3207 # If gif_lib.h but no libgif, try libungif.
3208     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3209     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3210   fi
3211
3212   if test "${HAVE_GIF}" = "yes"; then
3213     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3214   fi
3215 fi
3216 AC_SUBST(LIBGIF)
3217
3218 dnl Check for required libraries.
3219 if test "${HAVE_X11}" = "yes"; then
3220   MISSING=""
3221   WITH_NO=""
3222   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3223     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3224   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3225     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3226   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3227     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3228   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3229     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3230   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3231     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3232
3233   if test "X${MISSING}" != X; then
3234     AC_MSG_ERROR([The following required libraries were not found:
3235     $MISSING
3236 Maybe some development libraries/packages are missing?
3237 If you don't want to link with them give
3238     $WITH_NO
3239 as options to configure])
3240   fi
3241 fi
3242
3243 ### Use -lgpm if available, unless `--with-gpm=no'.
3244 HAVE_GPM=no
3245 LIBGPM=
3246 if test "${with_gpm}" != "no"; then
3247   AC_CHECK_HEADER(gpm.h,
3248     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3249
3250   if test "${HAVE_GPM}" = "yes"; then
3251     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3252     LIBGPM=-lgpm
3253   fi
3254 fi
3255 AC_SUBST(LIBGPM)
3256
3257 dnl Check for malloc/malloc.h on darwin
3258 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3259
3260 GNUSTEP_CFLAGS=
3261 ### Use NeXTstep API to implement GUI.
3262 if test "${HAVE_NS}" = "yes"; then
3263   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3264   if test "${NS_IMPL_COCOA}" = "yes"; then
3265     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3266   fi
3267   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3268     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3269     # See also .m.o rule in Makefile.in */
3270     # FIXME: are all these flags really needed?  Document here why.  */
3271     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3272     ## Extra CFLAGS applied to src/*.m files.
3273     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3274   fi
3275   OTHER_FILES=ns-app
3276 fi
3277
3278 ### Use session management (-lSM -lICE) if available
3279 HAVE_X_SM=no
3280 LIBXSM=
3281 if test "${HAVE_X11}" = "yes"; then
3282   AC_CHECK_HEADER(X11/SM/SMlib.h,
3283     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3284
3285   if test "${HAVE_X_SM}" = "yes"; then
3286     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3287     LIBXSM="-lSM -lICE"
3288     case "$LIBS" in
3289       *-lSM*) ;;
3290       *)      LIBS="$LIBXSM $LIBS" ;;
3291     esac
3292   fi
3293 fi
3294 AC_SUBST(LIBXSM)
3295
3296 ### Use XRandr (-lXrandr) if available
3297 HAVE_XRANDR=no
3298 if test "${HAVE_X11}" = "yes"; then
3299   XRANDR_REQUIRED=1.2.2
3300   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3301   PKG_CHECK_MODULES(XRANDR, $XRANDR_MODULES, HAVE_XRANDR=yes, HAVE_XRANDR=no)
3302   if test $HAVE_XRANDR = no; then
3303     # Test old way in case pkg-config doesn't have it (older machines).
3304     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3305       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3306     if test $HAVE_XRANDR = yes; then
3307       XRANDR_LIBS=-lXrandr
3308       AC_SUBST(XRANDR_LIBS)
3309     fi
3310   fi
3311   if test $HAVE_XRANDR = yes; then
3312     SAVE_CFLAGS="$CFLAGS"
3313     SAVE_LIBS="$LIBS"
3314     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3315     LIBS="$XRANDR_LIBS $LIBS"
3316     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3317     CFLAGS="$SAVE_CFLAGS"
3318     LIBS="$SAVE_LIBS"
3319
3320     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3321   fi
3322 fi
3323
3324 ### Use Xinerama (-lXinerama) if available
3325 HAVE_XINERAMA=no
3326 if test "${HAVE_X11}" = "yes"; then
3327   XINERAMA_REQUIRED=1.0.2
3328   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3329   PKG_CHECK_MODULES(XINERAMA, $XINERAMA_MODULES, HAVE_XINERAMA=yes,
3330                     HAVE_XINERAMA=no)
3331   if test $HAVE_XINERAMA = no; then
3332     # Test old way in case pkg-config doesn't have it (older machines).
3333     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3334       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3335     if test $HAVE_XINERAMA = yes; then
3336       XINERAMA_LIBS=-lXinerama
3337       AC_SUBST(XINERAMA_LIBS)
3338     fi
3339   fi
3340   if test $HAVE_XINERAMA = yes; then
3341     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3342   fi
3343 fi
3344
3345
3346 ### Use libxml (-lxml2) if available
3347 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3348 HAVE_LIBXML2=no
3349 if test "${with_xml2}" != "no"; then
3350   ### I'm not sure what the version number should be, so I just guessed.
3351   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3352   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3353   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3354     SAVE_CPPFLAGS="$CPPFLAGS"
3355     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3356     AC_CHECK_HEADER(libxml/HTMLparser.h,
3357       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3358                      [#include <libxml/HTMLparser.h>])])
3359     CPPFLAGS="$SAVE_CPPFLAGS"
3360     if test "${HAVE_LIBXML2}" = "yes"; then
3361       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3362       LIBXML2_LIBS="-lxml2"
3363     fi
3364   fi
3365   if test "${HAVE_LIBXML2}" = "yes"; then
3366     if test "${opsys}" != "mingw32"; then
3367       LIBS="$LIBXML2_LIBS $LIBS"
3368       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3369     else
3370       LIBXML2_LIBS=""
3371     fi
3372     if test "${HAVE_LIBXML2}" = "yes"; then
3373       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3374     else
3375       LIBXML2_LIBS=""
3376       LIBXML2_CFLAGS=""
3377     fi
3378   fi
3379 fi
3380 AC_SUBST(LIBXML2_LIBS)
3381 AC_SUBST(LIBXML2_CFLAGS)
3382
3383 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3384 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3385 if test "${opsys}" = "mingw32"; then
3386   emacs_cv_netdb_declares_h_errno=yes
3387 fi
3388 AC_CACHE_CHECK(whether netdb declares h_errno,
3389                emacs_cv_netdb_declares_h_errno,
3390 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3391   [[return h_errno;]])],
3392   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3393 if test $emacs_cv_netdb_declares_h_errno = yes; then
3394   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3395 fi
3396
3397 # sqrt and other floating-point functions such as fmod and frexp
3398 # are found in -lm on most systems, but mingw32 doesn't use -lm.
3399 if test "${opsys}" != "mingw32"; then
3400   AC_CHECK_LIB(m, sqrt)
3401 fi
3402
3403 # Check for mail-locking functions in a "mail" library.  Probably this should
3404 # have the same check as for liblockfile below.
3405 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3406 if test $have_mail = yes; then
3407   LIBS_MAIL=-lmail
3408   LIBS="$LIBS_MAIL $LIBS"
3409   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3410 else
3411   LIBS_MAIL=
3412 fi
3413 dnl Debian, at least:
3414 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3415 if test $have_lockfile = yes; then
3416    LIBS_MAIL=-llockfile
3417    LIBS="$LIBS_MAIL $LIBS"
3418    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3419 else
3420 # If we have the shared liblockfile, assume we must use it for mail
3421 # locking (e.g. Debian).  If we couldn't link against liblockfile
3422 # (no liblockfile.a installed), ensure that we don't need to.
3423   dnl This works for files generally, not just executables.
3424   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3425   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3426                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3427   if test $ac_cv_prog_liblockfile = yes; then
3428     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3429 This probably means that movemail could lose mail.
3430 There may be a `development' package to install containing liblockfile.])
3431   fi
3432 fi
3433 AC_CHECK_HEADERS_ONCE(maillock.h)
3434 AC_SUBST(LIBS_MAIL)
3435
3436 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3437 ## interlock access to the mail spool.  The alternative is a lock file named
3438 ## /usr/spool/mail/$USER.lock.
3439 mail_lock=no
3440 case "$opsys" in
3441   aix4-2) mail_lock="lockf" ;;
3442
3443   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3444
3445   ## On GNU/Linux systems, both methods are used by various mail programs.
3446   ## I assume most people are using newer mailers that have heard of flock.
3447   ## Change this if you need to.
3448   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3449   ## configure gets the right answers, and that means *NOT* using flock.
3450   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3451   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3452   ## Debian maintainer hasn't provided a clean fix for Emacs.
3453   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3454   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3455   ## correct logic.  -- fx
3456   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3457   ## liblockfile is a Free Software replacement for libmail, used on
3458   ## Debian systems and elsewhere. -rfr.
3459   gnu-*)
3460     mail_lock="flock"
3461     if test $have_mail = yes || test $have_lockfile = yes; then
3462       test $ac_cv_header_maillock_h = yes && mail_lock=no
3463     fi
3464     ;;
3465
3466   mingw32)
3467     mail_lock="none-needed" ;;
3468 esac
3469
3470 BLESSMAIL_TARGET=
3471 case "$mail_lock" in
3472   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3473
3474   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3475
3476   none-needed) ;;
3477
3478   *) BLESSMAIL_TARGET="need-blessmail" ;;
3479 esac
3480 AC_SUBST(BLESSMAIL_TARGET)
3481
3482
3483 AC_CHECK_FUNCS(accept4 gethostname \
3484 getrusage get_current_dir_name \
3485 lrand48 \
3486 select getpagesize setlocale \
3487 getrlimit setrlimit shutdown getaddrinfo \
3488 strsignal setitimer \
3489 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3490 gai_strerror getline getdelim sync \
3491 getpwent endpwent getgrent endgrent \
3492 touchlock \
3493 cfmakeraw cfsetspeed copysign __executable_start log2)
3494
3495 dnl No need to check for aligned_alloc and posix_memalign if using
3496 dnl gmalloc.o, as it supplies them.  Don't use these functions on
3497 dnl Darwin as they are incompatible with unexmacosx.c.
3498 if test -z "$GMALLOC_OBJ" && test "$opsys" != darwin; then
3499   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3500 fi
3501
3502 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
3503 ## has a broken `rint' in some library versions including math library
3504 ## version number A.09.05.
3505 ## You can fix the math library by installing patch number PHSS_4630.
3506 ## But we can fix it more reliably for Emacs by just not using rint.
3507 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
3508 case $opsys in
3509    hpux*) : ;;
3510    *) AC_CHECK_FUNCS(random rint) ;;
3511 esac
3512
3513 dnl Cannot use AC_CHECK_FUNCS
3514 AC_CACHE_CHECK([for __builtin_unwind_init],
3515                emacs_cv_func___builtin_unwind_init,
3516 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3517                 emacs_cv_func___builtin_unwind_init=yes,
3518                 emacs_cv_func___builtin_unwind_init=no)])
3519 if test $emacs_cv_func___builtin_unwind_init = yes; then
3520   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3521             [Define to 1 if you have the `__builtin_unwind_init' function.])
3522 fi
3523
3524 AC_CHECK_HEADERS_ONCE(sys/un.h)
3525
3526 AC_FUNC_FSEEKO
3527
3528 # UNIX98 PTYs.
3529 AC_CHECK_FUNCS(grantpt)
3530
3531 # PTY-related GNU extensions.
3532 AC_CHECK_FUNCS(getpt posix_openpt)
3533
3534 # Check this now, so that we will NOT find the above functions in ncurses.
3535 # That is because we have not set up to link ncurses in lib-src.
3536 # It's better to believe a function is not available
3537 # than to expect to find it in ncurses.
3538 # Also we need tputs and friends to be able to build at all.
3539 AC_MSG_CHECKING([for library containing tputs])
3540 # Run a test program that contains a call to tputs, a call that is
3541 # never executed.  This tests whether a pre-'main' dynamic linker
3542 # works with the library.  It's too much trouble to actually call
3543 # tputs in the test program, due to portability hassles.  When
3544 # cross-compiling, assume the test program will run if it links.
3545 AC_DEFUN([tputs_link_source], [
3546   AC_LANG_SOURCE(
3547      [[extern void tputs (const char *, int, int (*)(int));
3548        int main (int argc, char **argv)
3549        {
3550           if (argc == 10000)
3551             tputs (argv[0], 0, 0);
3552           return 0;
3553        }]])
3554 ])
3555 if test "${opsys}" = "mingw32"; then
3556   msg='none required'
3557 else
3558   # Maybe curses should be tried earlier?
3559   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3560   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3561     OLIBS=$LIBS
3562     if test -z "$tputs_library"; then
3563       LIBS_TERMCAP=
3564       msg='none required'
3565     else
3566       LIBS_TERMCAP=-l$tputs_library
3567       msg=$LIBS_TERMCAP
3568       LIBS="$LIBS_TERMCAP $LIBS"
3569     fi
3570     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3571       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3572     LIBS=$OLIBS
3573     if test "X$msg" != Xno; then
3574       break
3575     fi
3576   done
3577 fi
3578 AC_MSG_RESULT([$msg])
3579 if test "X$msg" = Xno; then
3580   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3581 The following libraries were tried (in order):
3582   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3583 Please try installing whichever of these libraries is most appropriate
3584 for your system, together with its header files.
3585 For example, a libncurses-dev(el) or similar package.])
3586 fi
3587
3588 ## Use termcap instead of terminfo?
3589 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3590 TERMINFO=yes
3591 ## FIXME?  In the cases below where we unconditionally set
3592 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3593 ## if that was found above to have tputs.
3594 ## Should we use the gnu* logic everywhere?
3595 case "$opsys" in
3596   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3597   ##  The ncurses library has been moved out of the System framework in
3598   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3599   ##  option to use it.
3600   darwin) LIBS_TERMCAP="-lncurses" ;;
3601
3602   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3603
3604   freebsd)
3605     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3606     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3607     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3608 [[#if __FreeBSD_version < 400000
3609 fail;
3610 #endif
3611 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3612
3613     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3614
3615     if test $emacs_cv_freebsd_terminfo = yes; then
3616       LIBS_TERMCAP="-lncurses"
3617     else
3618       TERMINFO=no
3619       LIBS_TERMCAP="-ltermcap"
3620     fi
3621     ;;
3622
3623   mingw32)
3624     TERMINFO=no
3625     LIBS_TERMCAP=
3626     ;;
3627
3628   netbsd)
3629     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3630       TERMINFO=no
3631       LIBS_TERMCAP="-ltermcap"
3632     fi
3633     ;;
3634
3635   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3636
3637   ## hpux: Make sure we get select from libc rather than from libcurses
3638   ##  because libcurses on HPUX 10.10 has a broken version of select.
3639   ##  We used to use -lc -lcurses, but this may be cleaner.
3640   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3641   # set that way, now it uses the default).  Isn't this a contradiction?
3642   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3643
3644 esac
3645
3646 TERMCAP_OBJ=tparam.o
3647 if test $TERMINFO = yes; then
3648   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3649   TERMCAP_OBJ=terminfo.o
3650 fi
3651 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3652   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3653 fi
3654 AC_SUBST(LIBS_TERMCAP)
3655 AC_SUBST(TERMCAP_OBJ)
3656
3657
3658 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3659 # On Darwin, res_init appears not to be useful: see bug#562 and
3660 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3661 resolv=no
3662
3663 if test $opsys != darwin; then
3664
3665   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3666 #include <arpa/nameser.h>
3667 #include <resolv.h>]],
3668     [[return res_init();]])],
3669     have_res_init=yes, have_res_init=no)
3670   if test "$have_res_init" = no; then
3671     OLIBS="$LIBS"
3672     LIBS="$LIBS -lresolv"
3673     AC_MSG_CHECKING(for res_init with -lresolv)
3674     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3675 #include <arpa/nameser.h>
3676 #include <resolv.h>]],
3677       [[return res_init();]])],
3678       have_res_init=yes, have_res_init=no)
3679     AC_MSG_RESULT($have_res_init)
3680     if test "$have_res_init" = yes ; then
3681       resolv=yes
3682     fi
3683     LIBS="$OLIBS"
3684   fi
3685
3686   if test "$have_res_init" = yes; then
3687     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3688   fi
3689 fi                              dnl !darwin
3690
3691 # Do we need the Hesiod library to provide the support routines?
3692 dnl FIXME?  Should we be skipping this on Darwin too?
3693 LIBHESIOD=
3694 if test "$with_hesiod" != no ; then
3695   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3696   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3697      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3698                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3699   if test "$resolv" = yes ; then
3700     RESOLVLIB=-lresolv
3701   else
3702     RESOLVLIB=
3703   fi
3704   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3705         hesiod=yes, :, $RESOLVLIB)])
3706
3707   if test x"$hesiod" = xyes; then
3708     LIBHESIOD=-lhesiod
3709   fi
3710 fi
3711 AC_SUBST(LIBHESIOD)
3712
3713 # Do we need libresolv (due to res_init or Hesiod)?
3714 if test "$resolv" = yes && test $opsys != darwin; then
3715   LIBRESOLV=-lresolv
3716 else
3717   LIBRESOLV=
3718 fi
3719 AC_SUBST(LIBRESOLV)
3720
3721 # These tell us which Kerberos-related libraries to use.
3722 COM_ERRLIB=
3723 CRYPTOLIB=
3724 KRB5LIB=
3725 DESLIB=
3726 KRB4LIB=
3727
3728 if test "${with_kerberos}" != no; then
3729   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3730   if test $have_com_err = yes; then
3731     COM_ERRLIB=-lcom_err
3732     LIBS="$COM_ERRLIB $LIBS"
3733   fi
3734   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3735   if test $have_crypto = yes; then
3736     CRYPTOLIB=-lcrypto
3737     LIBS="$CRYPTOLIB $LIBS"
3738   fi
3739   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3740   if test $have_k5crypto = yes; then
3741     CRYPTOLIB=-lk5crypto
3742     LIBS="$CRYPTOLIB $LIBS"
3743   fi
3744   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3745   if test $have_krb5=yes; then
3746     KRB5LIB=-lkrb5
3747     LIBS="$KRB5LIB $LIBS"
3748   fi
3749   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3750   if test "${with_kerberos5}" = no; then
3751     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3752     if test $have_des425 = yes; then
3753       DESLIB=-ldes425
3754       LIBS="$DESLIB $LIBS"
3755     else
3756       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3757       if test $have_des = yes; then
3758         DESLIB=-ldes
3759         LIBS="$DESLIB $LIBS"
3760       fi
3761     fi
3762     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3763     if test $have_krb4 = yes; then
3764       KRB4LIB=-lkrb4
3765       LIBS="$KRB4LIB $LIBS"
3766     else
3767       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3768       if test $have_krb = yes; then
3769         KRB4LIB=-lkrb
3770         LIBS="$KRB4LIB $LIBS"
3771       fi
3772     fi
3773   fi
3774
3775   if test "${with_kerberos5}" != no; then
3776     AC_CHECK_HEADERS(krb5.h,
3777       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3778                         [#include <krb5.h>])])
3779   else
3780     AC_CHECK_HEADERS(krb.h,,
3781                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3782                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3783   fi
3784   AC_CHECK_HEADERS(com_err.h)
3785 fi
3786
3787 AC_SUBST(COM_ERRLIB)
3788 AC_SUBST(CRYPTOLIB)
3789 AC_SUBST(KRB5LIB)
3790 AC_SUBST(DESLIB)
3791 AC_SUBST(KRB4LIB)
3792
3793 AC_CHECK_HEADERS(valgrind/valgrind.h)
3794
3795 AC_CHECK_FUNCS_ONCE(tzset)
3796 AC_MSG_CHECKING(whether localtime caches TZ)
3797 AC_CACHE_VAL(emacs_cv_localtime_cache,
3798 [if test x$ac_cv_func_tzset = xyes; then
3799 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3800 char TZ_GMT0[] = "TZ=GMT0";
3801 char TZ_PST8[] = "TZ=PST8";
3802 main()
3803 {
3804   time_t now = time ((time_t *) 0);
3805   int hour_GMT0, hour_unset;
3806   if (putenv (TZ_GMT0) != 0)
3807     exit (1);
3808   hour_GMT0 = localtime (&now)->tm_hour;
3809   unsetenv("TZ");
3810   hour_unset = localtime (&now)->tm_hour;
3811   if (putenv (TZ_PST8) != 0)
3812     exit (1);
3813   if (localtime (&now)->tm_hour == hour_GMT0)
3814     exit (1);
3815   unsetenv("TZ");
3816   if (localtime (&now)->tm_hour != hour_unset)
3817     exit (1);
3818   exit (0);
3819 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3820 [# If we have tzset, assume the worst when cross-compiling.
3821 emacs_cv_localtime_cache=yes])
3822 else
3823         # If we lack tzset, report that localtime does not cache TZ,
3824         # since we can't invalidate the cache if we don't have tzset.
3825         emacs_cv_localtime_cache=no
3826 fi])dnl
3827 AC_MSG_RESULT($emacs_cv_localtime_cache)
3828 if test $emacs_cv_localtime_cache = yes; then
3829   AC_DEFINE(LOCALTIME_CACHE, 1,
3830             [Define to 1 if localtime caches TZ.])
3831 fi
3832
3833 ok_so_far=yes
3834 AC_CHECK_FUNC(socket, , ok_so_far=no)
3835 if test $ok_so_far = yes; then
3836   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3837 fi
3838 if test $ok_so_far = yes; then
3839   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3840 fi
3841 if test $ok_so_far = yes; then
3842 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3843   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3844             [Define to 1 if you have inet sockets.])
3845 fi
3846
3847 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3848 dnl This can be removed once we assume Autoconf 2.70.
3849 case $canonical in
3850   *-solaris2.4 | *-solaris2.4.*)
3851     dnl Disable the Autoconf-generated vfork test.
3852     : ${ac_cv_func_vfork_works=no};;
3853 esac
3854
3855 AC_FUNC_FORK
3856
3857 AC_CHECK_FUNCS(snprintf)
3858
3859 dnl Check this late.  It depends on what other libraries (lrsvg, Gtk+ etc)
3860 dnl Emacs uses.
3861 XGSELOBJ=
3862 OLDCFLAGS="$CFLAGS"
3863 OLDLIBS="$LIBS"
3864 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS"
3865 LIBS="$LIBS $GFILENOTIFY_LIBS"
3866 AC_MSG_CHECKING([whether GLib is linked in])
3867 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3868         [[#include <glib.h>
3869         ]],
3870         [[g_print ("Hello world");]])],
3871      [links_glib=yes],
3872      [links_glib=no])
3873 AC_MSG_RESULT([$links_glib])
3874 if test "${links_glib}" = "yes"; then
3875   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3876   if test "$HAVE_NS" = no;then
3877     XGSELOBJ=xgselect.o
3878   fi
3879 fi
3880 CFLAGS="$OLDCFLAGS"
3881 LIBS="$OLDLIBS"
3882 AC_SUBST(XGSELOBJ)
3883
3884 dnl Adapted from Haible's version.
3885 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3886   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3887     [[char* cs = nl_langinfo(CODESET);]])],
3888     emacs_cv_langinfo_codeset=yes,
3889     emacs_cv_langinfo_codeset=no)
3890   ])
3891 if test $emacs_cv_langinfo_codeset = yes; then
3892   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3893     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3894 fi
3895
3896 AC_TYPE_MBSTATE_T
3897
3898 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3899   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3900                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3901 if test "$emacs_cv_c_restrict_arr" = yes; then
3902   AC_DEFINE(__restrict_arr, __restrict,
3903     [Define to compiler's equivalent of C99 restrict keyword in array
3904      declarations.  Define as empty for no equivalent.])
3905 fi
3906
3907 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3908 dnl how the tty code is related to POSIX and/or other versions of termios.
3909 dnl The following looks like a useful start.
3910 dnl
3911 dnl AC_SYS_POSIX_TERMIOS
3912 dnl if test $ac_cv_sys_posix_termios = yes; then
3913 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3914 dnl                                and macros for terminal control.])
3915 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3916 dnl fi
3917
3918 dnl Turned on June 1996 supposing nobody will mind it.
3919 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3920 if test "${opsys}" != "mingw32"; then
3921    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3922      in the full name stands for the login id.])
3923 fi
3924
3925 dnl Every platform that uses configure supports this.
3926 dnl There is a create-lockfiles option you can
3927 dnl customize if you do not want the lock files to be written.
3928 dnl So it is not clear that this #define still needs to exist.
3929 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3930   so that Emacs can tell instantly when you try to modify a file that
3931   someone else has modified in his/her Emacs.])
3932
3933 dnl Everybody supports this, except MS.
3934 dnl Seems like the kind of thing we should be testing for, though.
3935 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3936 if test "${opsys}" != "mingw32"; then
3937   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3938 fi
3939
3940 dnl Everybody supports this, except MS-DOS.
3941 dnl Seems like the kind of thing we should be testing for, though.
3942 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3943 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3944   4.2-compatible sockets.])
3945
3946 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3947
3948 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
3949   a null file, or a data sink.])
3950 if test "${opsys}" = "mingw32"; then
3951   AC_DEFINE(NULL_DEVICE, ["NUL:"])
3952 else
3953   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
3954 fi
3955
3956 if test "${opsys}" = "mingw32"; then
3957   SEPCHAR=';'
3958 else
3959   SEPCHAR=':'
3960 fi
3961 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
3962 dnl This is for MinGW, and is used in test/automated/Makefile.in.
3963 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
3964 dnl decides that a command-line argument to be passed to a MinGW program
3965 dnl is a PATH-style list of directories.  But that heuristics plays it
3966 dnl safe, and only does the replacement when it is _absolutely_ sure it
3967 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
3968 dnl which breaks in-tree builds.  So we do this manually instead.
3969 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
3970 dnl be computed as ':' in MSYS Bash.
3971 AC_SUBST(SEPCHAR)
3972
3973 dnl Everybody supports this, except MS-DOS.
3974 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3975
3976 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3977
3978
3979 AC_DEFINE(DIRECTORY_SEP, ['/'],
3980   [Character that separates directories in a file name.])
3981
3982 if test "${opsys}" = "mingw32"; then
3983   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
3984     [Returns true if character is a device separator.])
3985
3986   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
3987     [Returns true if character is a directory separator.])
3988
3989   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
3990     [Returns true if character is any form of separator.])
3991 else
3992   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3993     [Returns true if character is a device separator.])
3994
3995   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3996     [Returns true if character is a directory separator.])
3997
3998   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3999     [Returns true if character is any form of separator.])
4000 fi
4001
4002 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4003
4004 case $opsys in
4005   aix4-2)
4006     dnl Unfortunately without libXmu we cannot support EditRes.
4007     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
4008       AC_DEFINE(NO_EDITRES, 1)
4009     fi
4010     ;;
4011
4012   hpux*)
4013     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4014     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4015     AC_DEFINE(NO_EDITRES, 1)
4016     ;;
4017 esac
4018
4019
4020 case $opsys in
4021   irix6-5 | sol2* | unixware )
4022     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4023     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4024     dnl need the constant to dimension an array.  So wire in the appropriate
4025     dnl value here.
4026     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4027     ;;
4028 esac
4029
4030 emacs_broken_SIGIO=no
4031
4032 case $opsys in
4033   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4034   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4035   hpux* | irix6-5 | openbsd | sol2* | unixware )
4036     emacs_broken_SIGIO=yes
4037     ;;
4038
4039   aix4-2)
4040     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4041     dnl the way this system works, libc functions that return malloced
4042     dnl memory use the libc malloc implementation. Calling xfree or
4043     dnl xrealloc on the results of such functions results in a crash.
4044     dnl
4045     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4046     dnl but that does not currently work on this system.
4047     dnl
4048     dnl It is possible to completely override the malloc implementation on
4049     dnl AIX, but that involves putting the malloc functions in a shared
4050     dnl library and setting the MALLOCTYPE environment variable to point to
4051     dnl that shared library.
4052     dnl
4053     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4054     dnl to avoid a crash just use the Emacs implementation for that function.
4055     dnl
4056     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4057     dnl of this file, so that we do not check for get_current_dir_name
4058     dnl on AIX.  But that might be fragile if something else ends
4059     dnl up testing for get_current_dir_name as a dependency.
4060     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4061       get_current_dir_name should not be used.])
4062     ;;
4063
4064   freebsd)
4065     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4066     dnl writes/reads on a PTY, read(2) returns bogus data:
4067     dnl
4068     dnl write(2)  1022 bytes
4069     dnl write(2)   954 bytes, get EAGAIN
4070     dnl read(2)   1024 bytes in process_read_output
4071     dnl read(2)     11 bytes in process_read_output
4072     dnl
4073     dnl That is, read(2) returns more bytes than have ever been written
4074     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4075     dnl successfully after processing (for example with CRs added if the
4076     dnl terminal is set up that way which it is here).  The same bytes will
4077     dnl be seen again in a later read(2), without the CRs.
4078     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4079       work around an issue when reading from a PTY.])
4080     ;;
4081 esac
4082
4083 case $opsys in
4084   gnu-* | sol2-10 )
4085     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4086     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4087   ;;
4088 esac
4089
4090 case $opsys in
4091   darwin | dragonfly | freebsd | netbsd | openbsd )
4092     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4093       close a pty to make it a controlling terminal (it is already a
4094       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4095   ;;
4096 esac
4097
4098 dnl FIXME Surely we can test for this rather than hard-code it.
4099 case $opsys in
4100   netbsd | openbsd) sound_device="/dev/audio" ;;
4101   *) sound_device="/dev/dsp" ;;
4102 esac
4103
4104 dnl Used in sound.c
4105 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4106   [Name of the default sound device.])
4107
4108
4109 dnl Emacs can read input using SIGIO and buffering characters itself,
4110 dnl or using CBREAK mode and making C-g cause SIGINT.
4111 dnl The choice is controlled by the variable interrupt_input.
4112 dnl
4113 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4114 dnl
4115 dnl Emacs uses the presence of the USABLE_SIGIO macro
4116 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4117 dnl INTERRUPT_INPUT to decide whether to use it by default.
4118 dnl
4119 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4120 dnl CBREAK mode has two disadvantages
4121 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4122 dnl I hear that in system V this problem does not exist.
4123 dnl 2) Control-G causes output to be discarded.
4124 dnl I do not know whether this can be fixed in system V.
4125 dnl
4126 dnl Another method of doing input is planned but not implemented.
4127 dnl It would have Emacs fork off a separate process
4128 dnl to read the input and send it to the true Emacs process
4129 dnl through a pipe.
4130 case $opsys in
4131   darwin | gnu-linux | gnu-kfreebsd )
4132     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4133   ;;
4134 esac
4135
4136
4137 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4138 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4139 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4140 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4141 dnl taking float or double parameters.
4142 case $opsys in
4143   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4144     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4145       file defines `NeedWidePrototypes' as `NO'.])
4146   ;;
4147 esac
4148
4149
4150 dnl Used in process.c, this must be a loop, even if it only runs once.
4151 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4152 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4153 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4154 dnl trying suffixes 0-16.
4155 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4156   first PTY, if PTYs are supported.])
4157 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4158 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4159   end of a PTY, if non-standard.])
4160 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4161   end of a PTY, if non-standard.])
4162
4163 case $opsys in
4164   aix4-2 )
4165     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4166     dnl You allocate a pty by opening /dev/ptc to get the master side.
4167     dnl To get the name of the slave side, you just ttyname() the master side.
4168     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4169     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4170     ;;
4171
4172   cygwin )
4173     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4174     dnl multi-line AC_DEFINEs are hard. :(
4175     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4176     AC_DEFINE(PTY_NAME_SPRINTF, [])
4177     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4178     ;;
4179
4180   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4181   darwin )
4182     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4183     dnl Not used, because PTY_ITERATION is defined.
4184     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4185     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4186     dnl But we don't have to block SIGCHLD because it is blocked in the
4187     dnl implementation of grantpt.
4188     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4189     AC_DEFINE(PTY_NAME_SPRINTF, [])
4190     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4191     ;;
4192
4193   gnu | openbsd )
4194     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4195     ;;
4196
4197   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4198     dnl if HAVE_GRANTPT
4199     if test "x$ac_cv_func_grantpt" = xyes; then
4200       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4201       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4202       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4203       dnl to prevent sigchld_handler from intercepting the child's death.
4204       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4205       dnl if HAVE_POSIX_OPENPT
4206       if test "x$ac_cv_func_posix_openpt" = xyes; then
4207         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4208         AC_DEFINE(PTY_NAME_SPRINTF, [])
4209       dnl if HAVE_GETPT
4210       elif test "x$ac_cv_func_getpt" = xyes; then
4211         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4212         AC_DEFINE(PTY_NAME_SPRINTF, [])
4213       else
4214         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4215       fi
4216     else
4217       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4218     fi
4219     ;;
4220
4221   hpux*)
4222     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4223     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4224     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4225     ;;
4226
4227   irix6-5 )
4228     dnl It looks like this cannot be right, because it is not a loop.
4229     dnl However, process.c actually does this:
4230     dnl # ifndef __sgi
4231     dnl   continue;
4232     dnl # else
4233     dnl   return -1;
4234     dnl # endif
4235     dnl which presumably makes it OK, since irix == sgi (?).
4236     dnl FIXME it seems like this special treatment is unnecessary?
4237     dnl Why can't irix use a single-trip loop like eg cygwin?
4238     AC_DEFINE(PTY_ITERATION, [])
4239     dnl Not used, because PTY_ITERATION is defined.
4240     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4241     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4242     dnl No need to get the pty name at all.
4243     AC_DEFINE(PTY_NAME_SPRINTF, [])
4244     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4245     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4246     ;;
4247
4248   sol2* )
4249     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4250     dnl from intercepting that death.  If any child but grantpt's should die
4251     dnl within, it should be caught after sigrelse(2).
4252     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4253     ;;
4254
4255   unixware )
4256     dnl Comments are as per sol2*.
4257     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4258     ;;
4259 esac
4260
4261
4262 case $opsys in
4263   sol2* | unixware )
4264     dnl This change means that we don't loop through allocate_pty too
4265     dnl many times in the (rare) event of a failure.
4266     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4267     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4268     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4269     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4270     ;;
4271 esac
4272
4273
4274 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4275 "typing" a signal character on the pty.])
4276
4277 case $opsys in
4278   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4279   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4280   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4281     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4282     ;;
4283
4284   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4285   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4286   gnu-linux | gnu-kfreebsd )
4287
4288     AC_MSG_CHECKING([for signals via characters])
4289     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4290 #include <linux/version.h>
4291 #if LINUX_VERSION_CODE < 0x20400
4292 # error "Linux version too old"
4293 #endif
4294       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4295
4296     AC_MSG_RESULT([$emacs_signals_via_chars])
4297     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4298     ;;
4299 esac
4300
4301
4302 dnl Used in lisp.h, emacs.c, vm-limit.c
4303 dnl NEWS.18 describes this as "a number which contains
4304 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
4305 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
4306 stored in a Lisp_Object.])
4307 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
4308
4309 case $opsys in
4310   aix*)
4311     dnl This works with 32-bit executables; Emacs doesn't support 64-bit.
4312     AC_DEFINE(DATA_SEG_BITS, [0x20000000])
4313     ;;
4314   hpux*)
4315     dnl The data segment on this machine always starts at address 0x40000000.
4316     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
4317     ;;
4318   irix6-5)
4319     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
4320     ;;
4321 esac
4322
4323
4324 AH_TEMPLATE(TAB3, [Undocumented.])
4325
4326 case $opsys in
4327   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4328
4329   gnu | dragonfly | freebsd | netbsd | openbsd )
4330     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4331     AC_DEFINE(TAB3, OXTABS)
4332     ;;
4333
4334   gnu-linux | gnu-kfreebsd )
4335     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4336 #ifndef __ia64__
4337 # error "not ia64"
4338 #endif
4339       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4340         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4341         [Mark a secondary stack, like the register stack on the ia64.]), [])
4342     ;;
4343
4344   hpux*)
4345     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4346       run_time_remap; for HPUX.])
4347     ;;
4348 esac
4349
4350
4351 dnl This won't be used automatically yet.  We also need to know, at least,
4352 dnl that the stack is continuous.
4353 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4354   registers relevant for conservative garbage collection in the jmp_buf.])
4355
4356
4357 case $opsys in
4358   dnl Not all the architectures are tested, but there are Debian packages
4359   dnl for SCM and/or Guile on them, so the technique must work.  See also
4360   dnl comments in alloc.c concerning setjmp and gcc.
4361   dnl Fixme: it's probably safe to just use the GCC conditional below.
4362   gnu-linux | gnu-kfreebsd )
4363     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4364 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4365   || defined __alpha__ || defined __mips__ || defined __s390__ \
4366   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4367   || defined __ia64__ || defined __sh__
4368 /* ok */
4369 #else
4370 # error "setjmp not known to work on this arch"
4371 #endif
4372     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4373     ;;
4374 esac
4375
4376
4377 if test x$GCC = xyes; then
4378    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4379    AC_DEFINE(GC_SETJMP_WORKS, 1)
4380 else
4381   case $opsys in
4382     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4383     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4384       AC_DEFINE(GC_SETJMP_WORKS, 1)
4385       ;;
4386   esac
4387 fi                              dnl GCC?
4388
4389 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4390 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4391   [AC_LINK_IFELSE(
4392      [AC_LANG_PROGRAM(
4393        [[#include <setjmp.h>
4394          #ifdef __MINGW32__
4395          # define _longjmp longjmp
4396          #endif
4397        ]],
4398        [[jmp_buf j;
4399          if (! _setjmp (j))
4400            _longjmp (j, 1);]])],
4401      [emacs_cv_func__setjmp=yes],
4402      [emacs_cv_func__setjmp=no])])
4403 if test $emacs_cv_func__setjmp = yes; then
4404   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4405 else
4406   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4407     [AC_LINK_IFELSE(
4408        [AC_LANG_PROGRAM(
4409          [[#include <setjmp.h>
4410          ]],
4411          [[sigjmp_buf j;
4412            if (! sigsetjmp (j, 1))
4413              siglongjmp (j, 1);]])],
4414        [emacs_cv_func_sigsetjmp=yes],
4415        [emacs_cv_func_sigsetjmp=no])])
4416   if test $emacs_cv_func_sigsetjmp = yes; then
4417     AC_DEFINE([HAVE_SIGSETJMP], 1,
4418       [Define to 1 if sigsetjmp and siglongjmp work.
4419        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
4420   fi
4421 fi
4422
4423 case $opsys in
4424   sol2* | unixware )
4425     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4426     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4427     dnl and this is all we need.
4428     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4429     ;;
4430 esac
4431
4432
4433 case $opsys in
4434   hpux* | sol2* )
4435     dnl Used in xfaces.c.
4436     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4437       some systems, where it requires time.h.])
4438     ;;
4439 esac
4440
4441
4442 dnl Define symbols to identify the version of Unix this is.
4443 dnl Define all the symbols that apply correctly.
4444 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4445 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4446 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4447 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4448
4449 case $opsys in
4450   aix4-2)
4451     AC_DEFINE(USG, [])
4452     dnl This symbol should be defined on AIX Version 3  ???????
4453     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4454 #ifndef _AIX
4455 # error "_AIX not defined"
4456 #endif
4457     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4458     ;;
4459
4460   cygwin)
4461     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4462     ;;
4463
4464   darwin)
4465     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4466     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4467     dnl distinguish OS X from pure Darwin.
4468     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4469     ;;
4470
4471   gnu-linux | gnu-kfreebsd )
4472     AC_DEFINE(USG, [])
4473     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4474     ;;
4475
4476   hpux*)
4477     AC_DEFINE(USG, [])
4478     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4479     ;;
4480
4481   irix6-5)
4482     AC_DEFINE(USG, [])
4483     AC_DEFINE(USG5_4, [])
4484     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4485     ;;
4486
4487   mingw32)
4488     AC_DEFINE(DOS_NT, [])
4489     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4490     if test "x$ac_enable_checking" != "x" ; then
4491       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4492     fi
4493     ;;
4494
4495   sol2*)
4496     AC_DEFINE(USG, [])
4497     AC_DEFINE(USG5_4, [])
4498     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4499     ;;
4500
4501   unixware)
4502     AC_DEFINE(USG, [])
4503     AC_DEFINE(USG5_4, [])
4504     ;;
4505 esac
4506
4507 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4508   [case $opsys in
4509      aix4-2)
4510        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4511        emacs_cv_usable_FIONREAD=no
4512        ;;
4513
4514      mingw32)
4515        emacs_cv_usable_FIONREAD=yes
4516        ;;
4517
4518      *)
4519        AC_COMPILE_IFELSE(
4520          [AC_LANG_PROGRAM([[#include <sys/types.h>
4521                             #include <sys/ioctl.h>
4522                             #ifdef USG5_4
4523                             # include <sys/filio.h>
4524                             #endif
4525                           ]],
4526                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4527          [emacs_cv_usable_FIONREAD=yes],
4528          [emacs_cv_usable_FIONREAD=no])
4529        ;;
4530    esac])
4531 if test $emacs_cv_usable_FIONREAD = yes; then
4532   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4533
4534   if test $emacs_broken_SIGIO = no; then
4535     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4536       [AC_COMPILE_IFELSE(
4537          [AC_LANG_PROGRAM([[#include <fcntl.h>
4538                             #include <signal.h>
4539                           ]],
4540                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4541          [emacs_cv_usable_SIGIO=yes],
4542          [emacs_cv_usable_SIGIO=no])],
4543       [emacs_cv_usable_SIGIO=yes],
4544       [emacs_cv_usable_SIGIO=no])
4545     if test $emacs_cv_usable_SIGIO = yes; then
4546       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4547     fi
4548   fi
4549 fi
4550
4551
4552 case $opsys in
4553   dnl Emacs supplies its own malloc, but glib calls posix_memalign,
4554   dnl and on Cygwin prior to version 1.7.24 that becomes the
4555   dnl Cygwin-supplied posix_memalign.  As malloc is not the Cygwin
4556   dnl malloc, the Cygwin posix_memalign always returns ENOSYS.  A
4557   dnl workaround is to set G_SLICE=always-malloc.  This is no longer
4558   dnl needed starting with cygwin-1.7.24, and it is no longer
4559   dnl effective starting with glib-2.36. */
4560   cygwin)
4561     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4562       G_SLICE environment variable to "always-malloc" at startup.])
4563     ;;
4564
4565   hpux11)
4566     dnl It works to open the pty's tty in the parent (Emacs), then
4567     dnl close and reopen it in the child.
4568     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4569       works to open a pty's tty in the parent process, then close and
4570       reopen it in the child.])
4571     ;;
4572
4573   irix6-5)
4574     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4575       use VSUSP instead of VSWTCH.])
4576     ;;
4577
4578   sol2-10)
4579     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4580       on Solaris.])
4581     ;;
4582 esac
4583
4584 # Set up the CFLAGS for real compilation, so we can substitute it.
4585 CFLAGS="$REAL_CFLAGS"
4586 CPPFLAGS="$REAL_CPPFLAGS"
4587
4588 ## Hack to detect a buggy GCC version.
4589 if test "x$GCC" = xyes \
4590    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4591    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4592    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4593    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4594 fi
4595
4596 version=$PACKAGE_VERSION
4597
4598 copyright="Copyright (C) 2014 Free Software Foundation, Inc."
4599 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4600   [Short copyright string for this version of Emacs.])
4601 AC_SUBST(copyright)
4602
4603 ### Specify what sort of things we'll be editing into Makefile and config.h.
4604 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4605 AC_SUBST(version)
4606 AC_SUBST(configuration)
4607 ## Unused?
4608 AC_SUBST(canonical)
4609 AC_SUBST(srcdir)
4610 AC_SUBST(prefix)
4611 AC_SUBST(exec_prefix)
4612 AC_SUBST(bindir)
4613 AC_SUBST(datadir)
4614 AC_SUBST(sharedstatedir)
4615 AC_SUBST(libexecdir)
4616 AC_SUBST(mandir)
4617 AC_SUBST(infodir)
4618 AC_SUBST(lispdir)
4619 AC_SUBST(standardlisppath)
4620 AC_SUBST(locallisppath)
4621 AC_SUBST(lisppath)
4622 AC_SUBST(x_default_search_path)
4623 AC_SUBST(etcdir)
4624 AC_SUBST(archlibdir)
4625 AC_SUBST(etcdocdir)
4626 AC_SUBST(bitmapdir)
4627 AC_SUBST(gamedir)
4628 AC_SUBST(gameuser)
4629 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4630 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4631 ## end of LIBX_BASE, but nothing ever set it.
4632 AC_SUBST(LD_SWITCH_X_SITE)
4633 AC_SUBST(C_SWITCH_X_SITE)
4634 AC_SUBST(GNUSTEP_CFLAGS)
4635 AC_SUBST(CFLAGS)
4636 ## Used in lwlib/Makefile.in.
4637 AC_SUBST(X_TOOLKIT_TYPE)
4638 AC_SUBST(ns_appdir)
4639 AC_SUBST(ns_appbindir)
4640 AC_SUBST(ns_appresdir)
4641 AC_SUBST(ns_appsrc)
4642 AC_SUBST(GNU_OBJC_CFLAGS)
4643 AC_SUBST(OTHER_FILES)
4644
4645 if test -n "${term_header}"; then
4646     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4647         [Define to the header for the built-in window system.])
4648 fi
4649
4650 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4651                    [Define to the canonical Emacs configuration name.])
4652 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4653                    [Define to the options passed to configure.])
4654 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4655   define this to include extra configuration information.])
4656
4657 case $opsys in
4658   mingw32)
4659     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4660     ;;
4661 esac
4662
4663 XMENU_OBJ=
4664 XOBJ=
4665 FONT_OBJ=
4666 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4667   AC_DEFINE(HAVE_X_WINDOWS, 1,
4668             [Define to 1 if you want to use the X window system.])
4669   XMENU_OBJ=xmenu.o
4670   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4671   FONT_OBJ=xfont.o
4672   if test "$HAVE_XFT" = "yes"; then
4673     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4674   elif test "$HAVE_FREETYPE" = "yes"; then
4675     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4676   fi
4677   AC_SUBST(FONT_OBJ)
4678 fi
4679 AC_SUBST(XMENU_OBJ)
4680 AC_SUBST(XOBJ)
4681 AC_SUBST(FONT_OBJ)
4682
4683 WIDGET_OBJ=
4684 MOTIF_LIBW=
4685 if test "${USE_X_TOOLKIT}" != "none" ; then
4686   WIDGET_OBJ=widget.o
4687   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4688   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4689     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4690   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4691     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4692     MOTIF_LIBW=-lXm
4693     case "$opsys" in
4694       gnu-linux)
4695         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4696         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4697         ;;
4698
4699       unixware)
4700         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4701         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4702         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4703         ;;
4704
4705       aix4-2)
4706         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4707         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4708         ;;
4709     esac
4710     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4711   fi
4712 fi
4713 AC_SUBST(WIDGET_OBJ)
4714
4715 TOOLKIT_LIBW=
4716 case "$USE_X_TOOLKIT" in
4717   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4718   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4719   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4720 esac
4721 AC_SUBST(TOOLKIT_LIBW)
4722
4723 if test "${opsys}" != "mingw32"; then
4724   if test "$USE_X_TOOLKIT" = "none"; then
4725     LIBXT_OTHER="\$(LIBXSM)"
4726   else
4727     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4728   fi
4729 fi
4730 AC_SUBST(LIBXT_OTHER)
4731
4732 if test "${HAVE_X11}" = "yes" ; then
4733   AC_DEFINE(HAVE_X11, 1,
4734             [Define to 1 if you want to use version 11 of X windows.])
4735   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4736 else
4737   LIBX_OTHER=
4738 fi
4739 AC_SUBST(LIBX_OTHER)
4740
4741 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4742   LIBXMENU=
4743 elif test "$USE_X_TOOLKIT" = none; then
4744   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4745 else
4746   LIBXMENU='$(lwlibdir)/liblw.a'
4747 fi
4748 AC_SUBST(LIBXMENU)
4749
4750 if test "${GNU_MALLOC}" = "yes" ; then
4751   AC_DEFINE(GNU_MALLOC, 1,
4752             [Define to 1 if you want to use the GNU memory allocator.])
4753 fi
4754
4755 RALLOC_OBJ=
4756 if test "${REL_ALLOC}" = "yes" ; then
4757   AC_DEFINE(REL_ALLOC, 1,
4758             [Define REL_ALLOC if you want to use the relocating allocator for
4759              buffer space.])
4760
4761   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4762 fi
4763 AC_SUBST(RALLOC_OBJ)
4764
4765 if test "$opsys" = "cygwin"; then
4766   CYGWIN_OBJ="sheap.o cygw32.o"
4767   ## Cygwin differs because of its unexec().
4768   PRE_ALLOC_OBJ=
4769   POST_ALLOC_OBJ=lastfile.o
4770 elif test "$opsys" = "mingw32"; then
4771   CYGWIN_OBJ=
4772   PRE_ALLOC_OBJ=
4773   POST_ALLOC_OBJ=lastfile.o
4774 else
4775   CYGWIN_OBJ=
4776   PRE_ALLOC_OBJ=lastfile.o
4777   POST_ALLOC_OBJ=
4778 fi
4779 AC_SUBST(CYGWIN_OBJ)
4780 AC_SUBST(PRE_ALLOC_OBJ)
4781 AC_SUBST(POST_ALLOC_OBJ)
4782
4783 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4784 dnl verbatim defined above.  The tricky name is apropos, as this hack
4785 dnl makes Fortify go sour!
4786 AH_VERBATIM([FORTIFY_SOUR],
4787 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4788    The workaround disables some useful run-time checking, so it
4789    should be conditional to the platforms with the performance bug.
4790    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4791 #if defined __APPLE__ && defined __GNUC__
4792 # ifndef _DONT_USE_CTYPE_INLINE_
4793 #  define _DONT_USE_CTYPE_INLINE_
4794 # endif
4795 # ifndef _FORTIFY_SOURCE
4796 #  define _FORTIFY_SOURCE 0
4797 # endif
4798 #endif
4799 ])
4800
4801 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4802 # it temporarily reverts them to their pre-pkg-config values,
4803 # because gnulib needs to work with both src (which uses the
4804 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4805 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4806 # and it therefore needs to run in an environment where LIBS does not
4807 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4808 # for some package unrelated to lib-src.
4809 SAVE_CFLAGS=$CFLAGS
4810 SAVE_LIBS=$LIBS
4811 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4812 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4813 gl_ASSERT_NO_GNULIB_POSIXCHECK
4814 gl_ASSERT_NO_GNULIB_TESTS
4815 gl_INIT
4816 CFLAGS=$SAVE_CFLAGS
4817 LIBS=$SAVE_LIBS
4818
4819 if test "${opsys}" = "mingw32"; then
4820   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4821   # Remove unneeded switches from the value of CC that goes to Makefiles
4822   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4823 fi
4824
4825 case "$opsys" in
4826   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4827
4828   darwin)
4829    ## The -headerpad option tells ld (see man page) to leave room at the
4830    ## end of the header for adding load commands.  Needed for dumping.
4831    ## 0x690 is the total size of 30 segment load commands (at 56
4832    ## each); under Cocoa 31 commands are required.
4833    if test "$HAVE_NS" = "yes"; then
4834      libs_nsgui="-framework AppKit"
4835      if test "$NS_IMPL_COCOA" = "yes"; then
4836         libs_nsgui="$libs_nsgui -framework IOKit"
4837      fi
4838      headerpad_extra=6C8
4839    else
4840      libs_nsgui=
4841      headerpad_extra=690
4842    fi
4843    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4844
4845    ## This is here because src/Makefile.in did some extra fiddling around
4846    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4847    ## LD_SWITCH_SYSTEM_TEMACS instead,
4848    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4849      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4850    ;;
4851
4852   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4853   ## find X at run-time.
4854   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4855   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4856   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4857   ## had different values in configure (in ac_link) and src/Makefile.in.
4858   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4859   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4860
4861   mingw32)
4862    ## MinGW64 does not prepend an underscore to symbols, so we must
4863    ## pass a different -entry switch to linker.  FIXME: It is better
4864    ## to make the entry points the same by changing unexw32.c.
4865    case "$canonical" in
4866      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4867      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4868    esac
4869    ;;
4870
4871   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4872
4873   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4874 esac
4875
4876 if test x$ac_enable_profiling != x ; then
4877   case $opsys in
4878     *freebsd | gnu-linux) ;;
4879     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4880   esac
4881 fi
4882
4883 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
4884
4885 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4886
4887 ## MinGW-specific post-link processing of temacs.
4888 TEMACS_POST_LINK=":"
4889 ADDSECTION=
4890 EMACS_HEAPSIZE=
4891 if test "${opsys}" = "mingw32"; then
4892   TEMACS_POST_LINK="\$(MINGW_TEMACS_POST_LINK)"
4893   ADDSECTION="../nt/addsection\$(EXEEXT)"
4894   ## Preload heap size of temacs.exe in MB.
4895   case "$canonical" in
4896     x86_64-*-*) EMACS_HEAPSIZE=42 ;;
4897     *) EMACS_HEAPSIZE=27 ;;
4898   esac
4899 fi
4900
4901 AC_SUBST(ADDSECTION)
4902 AC_SUBST(TEMACS_POST_LINK)
4903 AC_SUBST(EMACS_HEAPSIZE)
4904
4905 ## Common for all window systems
4906 if test "$window_system" != "none"; then
4907   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4908   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4909 fi
4910
4911 AC_SUBST(WINDOW_SYSTEM_OBJ)
4912
4913 AH_TOP([/* GNU Emacs site configuration template file.
4914
4915 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2014
4916   Free Software Foundation, Inc.
4917
4918 This file is part of GNU Emacs.
4919
4920 GNU Emacs is free software: you can redistribute it and/or modify
4921 it under the terms of the GNU General Public License as published by
4922 the Free Software Foundation, either version 3 of the License, or
4923 (at your option) any later version.
4924
4925 GNU Emacs is distributed in the hope that it will be useful,
4926 but WITHOUT ANY WARRANTY; without even the implied warranty of
4927 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4928 GNU General Public License for more details.
4929
4930 You should have received a copy of the GNU General Public License
4931 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4932
4933
4934 /* No code in Emacs #includes config.h twice, but some bits of code
4935    intended to work with other packages as well (like gmalloc.c)
4936    think they can include it as many times as they like.  */
4937 #ifndef EMACS_CONFIG_H
4938 #define EMACS_CONFIG_H
4939 ])dnl
4940
4941 AH_BOTTOM([#include <conf_post.h>
4942
4943 #endif /* EMACS_CONFIG_H */
4944
4945 /*
4946 Local Variables:
4947 mode: c
4948 End:
4949 */
4950 ])dnl
4951
4952 #### Report on what we decided to do.
4953 #### Report GTK as a toolkit, even if it doesn't use Xt.
4954 #### It makes printing result more understandable as using GTK sets
4955 #### toolkit_scroll_bars to yes by default.
4956 if test "${HAVE_GTK}" = "yes"; then
4957   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4958 fi
4959
4960 if test $USE_ACL -ne 0; then
4961   acl_summary="yes $LIB_ACL"
4962 else
4963   acl_summary=no
4964 fi
4965
4966 echo "
4967 Configured for \`${canonical}'.
4968
4969   Where should the build process find the source code?    ${srcdir}
4970   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4971   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4972   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4973   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4974   What window system should Emacs use?                    ${window_system}
4975   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4976
4977 if test -n "${x_includes}"; then
4978 echo "  Where do we find X Windows header files?                ${x_includes}"
4979 else
4980 echo "  Where do we find X Windows header files?                Standard dirs"
4981 fi
4982 if test -n "${x_libraries}"; then
4983 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4984 else
4985 echo "  Where do we find X Windows libraries?                   Standard dirs"
4986 fi
4987
4988 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4989 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4990 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4991 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4992 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4993 echo "  Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG"
4994 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4995 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4996
4997 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
4998
4999 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
5000 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
5001 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
5002 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
5003 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
5004 echo "  Does Emacs use access control lists?                    ${acl_summary}"
5005 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
5006 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
5007 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
5008
5009 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
5010 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
5011 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
5012 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
5013 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
5014
5015 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
5016 echo
5017
5018 if test -n "${EMACSDATA}"; then
5019    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
5020 fi
5021 if test -n "${EMACSDOC}"; then
5022    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
5023 fi
5024
5025 echo
5026
5027 if test "$HAVE_NS" = "yes"; then
5028    echo
5029    echo "You must run \"${MAKE-make} install\" in order to test the built application.
5030 The installed application will go to nextstep/Emacs.app and can be
5031 run or moved from there."
5032    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5033       echo "The application will be fully self-contained."
5034     else
5035       echo "The lisp resources for the application will be installed under ${prefix}.
5036 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5037 to run if these resources are not installed."
5038    fi
5039    echo
5040 fi
5041
5042 if test "${opsys}" = "cygwin"; then
5043   case `uname -r` in
5044     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5045            echo
5046            ;;
5047   esac
5048 fi
5049
5050 # Remove any trailing slashes in these variables.
5051 [test "${prefix}" != NONE &&
5052   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5053 test "${exec_prefix}" != NONE &&
5054   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5055
5056 if test "$HAVE_NS" = "yes"; then
5057   if test "$NS_IMPL_GNUSTEP" = yes; then
5058     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5059       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5060     ns_check_file=Resources/Info-gnustep.plist
5061   else
5062     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5063       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5064     ns_check_file=Contents/Info.plist
5065   fi
5066   AC_SUBST(ns_check_file)
5067 fi
5068
5069 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5070 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5071 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5072 dnl (else you get "no `Makefile.am' found for any configure output").
5073 dnl This will work, but you get a config.status that is not quite right
5074 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5075 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5076 dnl it seems better to just live with the duplication.
5077 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5078
5079 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5080        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5081        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5082        leim/Makefile nextstep/Makefile nt/Makefile])
5083
5084 dnl test/ is not present in release tarfiles.
5085 opt_makefile=test/automated/Makefile
5086
5087 if test -f "$srcdir/$opt_makefile.in"; then
5088   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5089   dnl Again, it's best not to use a variable.  Though you can add
5090   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5091   AC_CONFIG_FILES([test/automated/Makefile])
5092 fi
5093
5094
5095 dnl The admin/ directory used to be excluded from tarfiles.
5096 if test -d $srcdir/admin; then
5097   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5098   AC_CONFIG_FILES([admin/unidata/Makefile])
5099   AC_CONFIG_FILES([admin/grammars/Makefile])
5100 fi                              dnl -d admin
5101
5102
5103 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5104
5105 AC_SUBST(SUBDIR_MAKEFILES_IN)
5106
5107 dnl You might wonder (I did) why epaths.h is generated by running make,
5108 dnl rather than just letting configure generate it from epaths.in.
5109 dnl One reason is that the various paths are not fully expanded (see above);
5110 dnl eg gamedir=${prefix}/var/games/emacs.
5111 dnl Secondly, the GNU Coding standards require that one should be able
5112 dnl to run `make prefix=/some/where/else' and override the values set
5113 dnl by configure.  This also explains the `move-if-change' test and
5114 dnl the use of force in the `epaths-force' rule in Makefile.in.
5115 AC_CONFIG_COMMANDS([src/epaths.h], [
5116 if test "${opsys}" = "mingw32"; then
5117   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5118 else
5119   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5120 fi
5121 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5122
5123 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5124 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5125 dnl or a symlink?
5126 AC_CONFIG_COMMANDS([src/.gdbinit], [
5127 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5128   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5129 fi
5130 ])
5131
5132 AC_OUTPUT