| 1 | ;;; simple.el --- basic editing commands for Emacs |
| 2 | |
| 3 | ;; Copyright (C) 1985, 1986, 1987, 1992 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; This file is part of GNU Emacs. |
| 6 | |
| 7 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 8 | ;; it under the terms of the GNU General Public License as published by |
| 9 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 10 | ;; any later version. |
| 11 | |
| 12 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 13 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 14 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 15 | ;; GNU General Public License for more details. |
| 16 | |
| 17 | ;; You should have received a copy of the GNU General Public License |
| 18 | ;; along with GNU Emacs; see the file COPYING. If not, write to |
| 19 | ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA. |
| 20 | |
| 21 | ;;; Code: |
| 22 | |
| 23 | (defun open-line (arg) |
| 24 | "Insert a newline and leave point before it. |
| 25 | If there is a fill prefix, insert the fill prefix on the new line |
| 26 | if the line would have been empty. |
| 27 | With arg N, insert N newlines." |
| 28 | (interactive "*p") |
| 29 | (let* ((do-fill-prefix (and fill-prefix (bolp))) |
| 30 | (flag (and (null do-fill-prefix) (bolp) (not (bobp))))) |
| 31 | ;; If this is a simple case, and we are at the beginning of a line, |
| 32 | ;; actually insert the newline *before* the preceding newline |
| 33 | ;; instead of after. That makes better display behavior. |
| 34 | (if flag |
| 35 | (progn |
| 36 | ;; If undo is enabled, don't let this hack be visible: |
| 37 | ;; record the real value of point as the place to move back to |
| 38 | ;; if we undo this insert. |
| 39 | (if (and buffer-undo-list (not (eq buffer-undo-list t))) |
| 40 | (setq buffer-undo-list (cons (point) buffer-undo-list))) |
| 41 | (forward-char -1))) |
| 42 | (while (> arg 0) |
| 43 | (save-excursion |
| 44 | (insert ?\n)) |
| 45 | (if do-fill-prefix (insert fill-prefix)) |
| 46 | (setq arg (1- arg))) |
| 47 | (if flag (forward-char 1)))) |
| 48 | |
| 49 | (defun split-line () |
| 50 | "Split current line, moving portion beyond point vertically down." |
| 51 | (interactive "*") |
| 52 | (skip-chars-forward " \t") |
| 53 | (let ((col (current-column)) |
| 54 | (pos (point))) |
| 55 | (insert ?\n) |
| 56 | (indent-to col 0) |
| 57 | (goto-char pos))) |
| 58 | |
| 59 | (defun quoted-insert (arg) |
| 60 | "Read next input character and insert it. |
| 61 | This is useful for inserting control characters. |
| 62 | You may also type up to 3 octal digits, to insert a character with that code" |
| 63 | (interactive "*p") |
| 64 | (let ((char (read-quoted-char))) |
| 65 | (while (> arg 0) |
| 66 | (insert char) |
| 67 | (setq arg (1- arg))))) |
| 68 | |
| 69 | (defun delete-indentation (&optional arg) |
| 70 | "Join this line to previous and fix up whitespace at join. |
| 71 | If there is a fill prefix, delete it from the beginning of this line. |
| 72 | With argument, join this line to following line." |
| 73 | (interactive "*P") |
| 74 | (beginning-of-line) |
| 75 | (if arg (forward-line 1)) |
| 76 | (if (eq (preceding-char) ?\n) |
| 77 | (progn |
| 78 | (delete-region (point) (1- (point))) |
| 79 | ;; If the second line started with the fill prefix, |
| 80 | ;; delete the prefix. |
| 81 | (if (and fill-prefix |
| 82 | (<= (+ (point) (length fill-prefix)) (point-max)) |
| 83 | (string= fill-prefix |
| 84 | (buffer-substring (point) |
| 85 | (+ (point) (length fill-prefix))))) |
| 86 | (delete-region (point) (+ (point) (length fill-prefix)))) |
| 87 | (fixup-whitespace)))) |
| 88 | |
| 89 | (defun fixup-whitespace () |
| 90 | "Fixup white space between objects around point. |
| 91 | Leave one space or none, according to the context." |
| 92 | (interactive "*") |
| 93 | (save-excursion |
| 94 | (delete-horizontal-space) |
| 95 | (if (or (looking-at "^\\|\\s)") |
| 96 | (save-excursion (forward-char -1) |
| 97 | (looking-at "$\\|\\s(\\|\\s'"))) |
| 98 | nil |
| 99 | (insert ?\ )))) |
| 100 | |
| 101 | (defun delete-horizontal-space () |
| 102 | "Delete all spaces and tabs around point." |
| 103 | (interactive "*") |
| 104 | (skip-chars-backward " \t") |
| 105 | (delete-region (point) (progn (skip-chars-forward " \t") (point)))) |
| 106 | |
| 107 | (defun just-one-space () |
| 108 | "Delete all spaces and tabs around point, leaving one space." |
| 109 | (interactive "*") |
| 110 | (skip-chars-backward " \t") |
| 111 | (if (= (following-char) ? ) |
| 112 | (forward-char 1) |
| 113 | (insert ? )) |
| 114 | (delete-region (point) (progn (skip-chars-forward " \t") (point)))) |
| 115 | |
| 116 | (defun delete-blank-lines () |
| 117 | "On blank line, delete all surrounding blank lines, leaving just one. |
| 118 | On isolated blank line, delete that one. |
| 119 | On nonblank line, delete all blank lines that follow it." |
| 120 | (interactive "*") |
| 121 | (let (thisblank singleblank) |
| 122 | (save-excursion |
| 123 | (beginning-of-line) |
| 124 | (setq thisblank (looking-at "[ \t]*$")) |
| 125 | ;; Set singleblank if there is just one blank line here. |
| 126 | (setq singleblank |
| 127 | (and thisblank |
| 128 | (not (looking-at "[ \t]*\n[ \t]*$")) |
| 129 | (or (bobp) |
| 130 | (progn (forward-line -1) |
| 131 | (not (looking-at "[ \t]*$"))))))) |
| 132 | ;; Delete preceding blank lines, and this one too if it's the only one. |
| 133 | (if thisblank |
| 134 | (progn |
| 135 | (beginning-of-line) |
| 136 | (if singleblank (forward-line 1)) |
| 137 | (delete-region (point) |
| 138 | (if (re-search-backward "[^ \t\n]" nil t) |
| 139 | (progn (forward-line 1) (point)) |
| 140 | (point-min))))) |
| 141 | ;; Delete following blank lines, unless the current line is blank |
| 142 | ;; and there are no following blank lines. |
| 143 | (if (not (and thisblank singleblank)) |
| 144 | (save-excursion |
| 145 | (end-of-line) |
| 146 | (forward-line 1) |
| 147 | (delete-region (point) |
| 148 | (if (re-search-forward "[^ \t\n]" nil t) |
| 149 | (progn (beginning-of-line) (point)) |
| 150 | (point-max))))) |
| 151 | ;; Handle the special case where point is followed by newline and eob. |
| 152 | ;; Delete the line, leaving point at eob. |
| 153 | (if (looking-at "^[ \t]*\n\\'") |
| 154 | (delete-region (point) (point-max))))) |
| 155 | |
| 156 | (defun back-to-indentation () |
| 157 | "Move point to the first non-whitespace character on this line." |
| 158 | (interactive) |
| 159 | (beginning-of-line 1) |
| 160 | (skip-chars-forward " \t")) |
| 161 | |
| 162 | (defun newline-and-indent () |
| 163 | "Insert a newline, then indent according to major mode. |
| 164 | Indentation is done using the value of `indent-line-function'. |
| 165 | In programming language modes, this is the same as TAB. |
| 166 | In some text modes, where TAB inserts a tab, this command indents to the |
| 167 | column specified by the variable `left-margin'." |
| 168 | (interactive "*") |
| 169 | (delete-region (point) (progn (skip-chars-backward " \t") (point))) |
| 170 | (newline) |
| 171 | (indent-according-to-mode)) |
| 172 | |
| 173 | (defun reindent-then-newline-and-indent () |
| 174 | "Reindent current line, insert newline, then indent the new line. |
| 175 | Indentation of both lines is done according to the current major mode, |
| 176 | which means calling the current value of `indent-line-function'. |
| 177 | In programming language modes, this is the same as TAB. |
| 178 | In some text modes, where TAB inserts a tab, this indents to the |
| 179 | column specified by the variable `left-margin'." |
| 180 | (interactive "*") |
| 181 | (save-excursion |
| 182 | (delete-region (point) (progn (skip-chars-backward " \t") (point))) |
| 183 | (indent-according-to-mode)) |
| 184 | (newline) |
| 185 | (indent-according-to-mode)) |
| 186 | |
| 187 | ;; Internal subroutine of delete-char |
| 188 | (defun kill-forward-chars (arg) |
| 189 | (if (listp arg) (setq arg (car arg))) |
| 190 | (if (eq arg '-) (setq arg -1)) |
| 191 | (kill-region (point) (+ (point) arg))) |
| 192 | |
| 193 | ;; Internal subroutine of backward-delete-char |
| 194 | (defun kill-backward-chars (arg) |
| 195 | (if (listp arg) (setq arg (car arg))) |
| 196 | (if (eq arg '-) (setq arg -1)) |
| 197 | (kill-region (point) (- (point) arg))) |
| 198 | |
| 199 | (defun backward-delete-char-untabify (arg &optional killp) |
| 200 | "Delete characters backward, changing tabs into spaces. |
| 201 | Delete ARG chars, and kill (save in kill ring) if KILLP is non-nil. |
| 202 | Interactively, ARG is the prefix arg (default 1) |
| 203 | and KILLP is t if prefix arg is was specified." |
| 204 | (interactive "*p\nP") |
| 205 | (let ((count arg)) |
| 206 | (save-excursion |
| 207 | (while (and (> count 0) (not (bobp))) |
| 208 | (if (= (preceding-char) ?\t) |
| 209 | (let ((col (current-column))) |
| 210 | (forward-char -1) |
| 211 | (setq col (- col (current-column))) |
| 212 | (insert-char ?\ col) |
| 213 | (delete-char 1))) |
| 214 | (forward-char -1) |
| 215 | (setq count (1- count))))) |
| 216 | (delete-backward-char arg killp) |
| 217 | ;; In overwrite mode, back over columns while clearing them out, |
| 218 | ;; unless at end of line. |
| 219 | (and overwrite-mode (not (eolp)) |
| 220 | (save-excursion (insert-char ?\ arg)))) |
| 221 | |
| 222 | (defun zap-to-char (arg char) |
| 223 | "Kill up to and including ARG'th occurrence of CHAR. |
| 224 | Goes backward if ARG is negative; error if CHAR not found." |
| 225 | (interactive "p\ncZap to char: ") |
| 226 | (kill-region (point) (progn |
| 227 | (search-forward (char-to-string char) nil nil arg) |
| 228 | ; (goto-char (if (> arg 0) (1- (point)) (1+ (point)))) |
| 229 | (point)))) |
| 230 | |
| 231 | (defun beginning-of-buffer (&optional arg) |
| 232 | "Move point to the beginning of the buffer; leave mark at previous position. |
| 233 | With arg N, put point N/10 of the way from the true beginning. |
| 234 | |
| 235 | Don't use this command in Lisp programs! |
| 236 | \(goto-char (point-min)) is faster and avoids clobbering the mark." |
| 237 | (interactive "P") |
| 238 | (push-mark) |
| 239 | (goto-char (if arg |
| 240 | (if (> (buffer-size) 10000) |
| 241 | ;; Avoid overflow for large buffer sizes! |
| 242 | (* (prefix-numeric-value arg) |
| 243 | (/ (buffer-size) 10)) |
| 244 | (/ (+ 10 (* (buffer-size) (prefix-numeric-value arg))) 10)) |
| 245 | (point-min))) |
| 246 | (if arg (forward-line 1))) |
| 247 | |
| 248 | (defun end-of-buffer (&optional arg) |
| 249 | "Move point to the end of the buffer; leave mark at previous position. |
| 250 | With arg N, put point N/10 of the way from the true end. |
| 251 | |
| 252 | Don't use this command in Lisp programs! |
| 253 | \(goto-char (point-max)) is faster and avoids clobbering the mark." |
| 254 | (interactive "P") |
| 255 | (push-mark) |
| 256 | (goto-char (if arg |
| 257 | (- (1+ (buffer-size)) |
| 258 | (if (> (buffer-size) 10000) |
| 259 | ;; Avoid overflow for large buffer sizes! |
| 260 | (* (prefix-numeric-value arg) |
| 261 | (/ (buffer-size) 10)) |
| 262 | (/ (* (buffer-size) (prefix-numeric-value arg)) 10))) |
| 263 | (point-max))) |
| 264 | ;; If we went to a place in the middle of the buffer, |
| 265 | ;; adjust it to the beginning of a line. |
| 266 | (if arg (forward-line 1) |
| 267 | ;; If the end of the buffer is not already on the screen, |
| 268 | ;; then scroll specially to put it near, but not at, the bottom. |
| 269 | (if (let ((old-point (point))) |
| 270 | (save-excursion |
| 271 | (goto-char (window-start)) |
| 272 | (vertical-motion (window-height)) |
| 273 | (< (point) old-point))) |
| 274 | (recenter -3)))) |
| 275 | |
| 276 | (defun mark-whole-buffer () |
| 277 | "Put point at beginning and mark at end of buffer. |
| 278 | You probably should not use this function in Lisp programs; |
| 279 | it is usually a mistake for a Lisp function to use any subroutine |
| 280 | that uses or sets the mark." |
| 281 | (interactive) |
| 282 | (push-mark (point)) |
| 283 | (push-mark (point-max)) |
| 284 | (goto-char (point-min))) |
| 285 | |
| 286 | (defun count-lines-region (start end) |
| 287 | "Print number of lines and charcters in the region." |
| 288 | (interactive "r") |
| 289 | (message "Region has %d lines, %d characters" |
| 290 | (count-lines start end) (- end start))) |
| 291 | |
| 292 | (defun what-line () |
| 293 | "Print the current line number (in the buffer) of point." |
| 294 | (interactive) |
| 295 | (save-restriction |
| 296 | (widen) |
| 297 | (save-excursion |
| 298 | (beginning-of-line) |
| 299 | (message "Line %d" |
| 300 | (1+ (count-lines 1 (point))))))) |
| 301 | |
| 302 | (defun count-lines (start end) |
| 303 | "Return number of lines between START and END. |
| 304 | This is usually the number of newlines between them, |
| 305 | but can be one more if START is not equal to END |
| 306 | and the greater of them is not at the start of a line." |
| 307 | (save-excursion |
| 308 | (save-restriction |
| 309 | (narrow-to-region start end) |
| 310 | (goto-char (point-min)) |
| 311 | (if (eq selective-display t) |
| 312 | (let ((done 0)) |
| 313 | (while (re-search-forward "[\n\C-m]" nil t 40) |
| 314 | (setq done (+ 40 done))) |
| 315 | (while (re-search-forward "[\n\C-m]" nil t 1) |
| 316 | (setq done (+ 1 done))) |
| 317 | done) |
| 318 | (- (buffer-size) (forward-line (buffer-size))))))) |
| 319 | |
| 320 | (defun what-cursor-position () |
| 321 | "Print info on cursor position (on screen and within buffer)." |
| 322 | (interactive) |
| 323 | (let* ((char (following-char)) |
| 324 | (beg (point-min)) |
| 325 | (end (point-max)) |
| 326 | (pos (point)) |
| 327 | (total (buffer-size)) |
| 328 | (percent (if (> total 50000) |
| 329 | ;; Avoid overflow from multiplying by 100! |
| 330 | (/ (+ (/ total 200) (1- pos)) (max (/ total 100) 1)) |
| 331 | (/ (+ (/ total 2) (* 100 (1- pos))) (max total 1)))) |
| 332 | (hscroll (if (= (window-hscroll) 0) |
| 333 | "" |
| 334 | (format " Hscroll=%d" (window-hscroll)))) |
| 335 | (col (current-column))) |
| 336 | (if (= pos end) |
| 337 | (if (or (/= beg 1) (/= end (1+ total))) |
| 338 | (message "point=%d of %d(%d%%) <%d - %d> column %d %s" |
| 339 | pos total percent beg end col hscroll) |
| 340 | (message "point=%d of %d(%d%%) column %d %s" |
| 341 | pos total percent col hscroll)) |
| 342 | (if (or (/= beg 1) (/= end (1+ total))) |
| 343 | (message "Char: %s (0%o) point=%d of %d(%d%%) <%d - %d> column %d %s" |
| 344 | (single-key-description char) char pos total percent beg end col hscroll) |
| 345 | (message "Char: %s (0%o) point=%d of %d(%d%%) column %d %s" |
| 346 | (single-key-description char) char pos total percent col hscroll))))) |
| 347 | |
| 348 | (defun fundamental-mode () |
| 349 | "Major mode not specialized for anything in particular. |
| 350 | Other major modes are defined by comparison with this one." |
| 351 | (interactive) |
| 352 | (kill-all-local-variables)) |
| 353 | |
| 354 | (defvar read-expression-map (copy-keymap minibuffer-local-map) |
| 355 | "Minibuffer keymap used for reading Lisp expressions.") |
| 356 | (define-key read-expression-map "\M-\t" 'lisp-complete-symbol) |
| 357 | |
| 358 | (put 'eval-expression 'disabled t) |
| 359 | |
| 360 | ;; We define this, rather than making eval interactive, |
| 361 | ;; for the sake of completion of names like eval-region, eval-current-buffer. |
| 362 | (defun eval-expression (expression) |
| 363 | "Evaluate EXPRESSION and print value in minibuffer. |
| 364 | Value is also consed on to front of the variable `values'." |
| 365 | (interactive (list (read-from-minibuffer "Eval: " |
| 366 | nil read-expression-map t))) |
| 367 | (setq values (cons (eval expression) values)) |
| 368 | (prin1 (car values) t)) |
| 369 | |
| 370 | (defun edit-and-eval-command (prompt command) |
| 371 | "Prompting with PROMPT, let user edit COMMAND and eval result. |
| 372 | COMMAND is a Lisp expression. Let user edit that expression in |
| 373 | the minibuffer, then read and evaluate the result." |
| 374 | (let ((command (read-from-minibuffer prompt |
| 375 | (prin1-to-string command) |
| 376 | read-expression-map t))) |
| 377 | ;; Add edited command to command history, unless redundant. |
| 378 | (or (equal command (car command-history)) |
| 379 | (setq command-history (cons command command-history))) |
| 380 | (eval command))) |
| 381 | |
| 382 | (defun repeat-complex-command (arg) |
| 383 | "Edit and re-evaluate last complex command, or ARGth from last. |
| 384 | A complex command is one which used the minibuffer. |
| 385 | The command is placed in the minibuffer as a Lisp form for editing. |
| 386 | The result is executed, repeating the command as changed. |
| 387 | If the command has been changed or is not the most recent previous command |
| 388 | it is added to the front of the command history. |
| 389 | You can use the minibuffer history commands \\<minibuffer-local-map>\\[next-history-element] and \\[previous-history-element] |
| 390 | to get different commands to edit and resubmit." |
| 391 | (interactive "p") |
| 392 | (let ((elt (nth (1- arg) command-history)) |
| 393 | (minibuffer-history-position arg) |
| 394 | (minibuffer-history-sexp-flag t) |
| 395 | newcmd) |
| 396 | (if elt |
| 397 | (progn |
| 398 | (setq newcmd (read-from-minibuffer "Redo: " |
| 399 | (prin1-to-string elt) |
| 400 | read-expression-map |
| 401 | t |
| 402 | (cons 'command-history |
| 403 | arg))) |
| 404 | ;; If command was added to command-history as a string, |
| 405 | ;; get rid of that. We want only evallable expressions there. |
| 406 | (if (stringp (car command-history)) |
| 407 | (setq command-history (cdr command-history))) |
| 408 | ;; If command to be redone does not match front of history, |
| 409 | ;; add it to the history. |
| 410 | (or (equal newcmd (car command-history)) |
| 411 | (setq command-history (cons newcmd command-history))) |
| 412 | (eval newcmd)) |
| 413 | (ding)))) |
| 414 | \f |
| 415 | (defvar minibuffer-history nil |
| 416 | "Default minibuffer history list. |
| 417 | This is used for all minibuffer input |
| 418 | except when an alternate history list is specified.") |
| 419 | (defvar minibuffer-history-sexp-flag nil |
| 420 | "Nonzero when doing history operations on `command-history'. |
| 421 | More generally, indicates that the history list being acted on |
| 422 | contains expressions rather than strings.") |
| 423 | (setq minibuffer-history-variable 'minibuffer-history) |
| 424 | (setq minibuffer-history-position nil) |
| 425 | (defvar minibuffer-history-search-history nil) |
| 426 | |
| 427 | (mapcar |
| 428 | (function (lambda (key-and-command) |
| 429 | (mapcar |
| 430 | (function (lambda (keymap) |
| 431 | (define-key (symbol-value keymap) |
| 432 | (car key-and-command) |
| 433 | (cdr key-and-command)))) |
| 434 | '(minibuffer-local-map |
| 435 | minibuffer-local-ns-map |
| 436 | minibuffer-local-completion-map |
| 437 | minibuffer-local-must-match-map |
| 438 | read-expression-map)))) |
| 439 | '(("\en" . next-history-element) ([next] . next-history-element) |
| 440 | ("\ep" . previous-history-element) ([prior] . previous-history-element) |
| 441 | ("\er" . previous-matching-history-element) |
| 442 | ("\es" . next-matching-history-element))) |
| 443 | |
| 444 | (defun previous-matching-history-element (regexp n) |
| 445 | "Find the previous history element that matches REGEXP. |
| 446 | \(Previous history elements refer to earlier actions.) |
| 447 | With prefix argument N, search for Nth previous match. |
| 448 | If N is negative, find the next or Nth next match." |
| 449 | (interactive |
| 450 | (let ((enable-recursive-minibuffers t) |
| 451 | (minibuffer-history-sexp-flag nil)) |
| 452 | (list (read-from-minibuffer "Previous element matching (regexp): " |
| 453 | nil |
| 454 | minibuffer-local-map |
| 455 | nil |
| 456 | 'minibuffer-history-search-history) |
| 457 | (prefix-numeric-value current-prefix-arg)))) |
| 458 | (let ((history (symbol-value minibuffer-history-variable)) |
| 459 | prevpos |
| 460 | (pos minibuffer-history-position)) |
| 461 | (while (/= n 0) |
| 462 | (setq prevpos pos) |
| 463 | (setq pos (min (max 1 (+ pos (if (< n 0) -1 1))) (length history))) |
| 464 | (if (= pos prevpos) |
| 465 | (error (if (= pos 1) |
| 466 | "No later matching history item" |
| 467 | "No earlier matching history item"))) |
| 468 | (if (string-match regexp |
| 469 | (if minibuffer-history-sexp-flag |
| 470 | (prin1-to-string (nth (1- pos) history)) |
| 471 | (nth (1- pos) history))) |
| 472 | (setq n (+ n (if (< n 0) 1 -1))))) |
| 473 | (setq minibuffer-history-position pos) |
| 474 | (erase-buffer) |
| 475 | (let ((elt (nth (1- pos) history))) |
| 476 | (insert (if minibuffer-history-sexp-flag |
| 477 | (prin1-to-string elt) |
| 478 | elt))) |
| 479 | (goto-char (point-min))) |
| 480 | (if (or (eq (car (car command-history)) 'previous-matching-history-element) |
| 481 | (eq (car (car command-history)) 'next-matching-history-element)) |
| 482 | (setq command-history (cdr command-history)))) |
| 483 | |
| 484 | (defun next-matching-history-element (regexp n) |
| 485 | "Find the next history element that matches REGEXP. |
| 486 | \(The next history element refers to a more recent action.) |
| 487 | With prefix argument N, search for Nth next match. |
| 488 | If N is negative, find the previous or Nth previous match." |
| 489 | (interactive |
| 490 | (let ((enable-recursive-minibuffers t) |
| 491 | (minibuffer-history-sexp-flag nil)) |
| 492 | (list (read-from-minibuffer "Next element matching (regexp): " |
| 493 | nil |
| 494 | minibuffer-local-map |
| 495 | nil |
| 496 | 'minibuffer-history-search-history) |
| 497 | (prefix-numeric-value current-prefix-arg)))) |
| 498 | (previous-matching-history-element regexp (- n))) |
| 499 | |
| 500 | (defun next-history-element (n) |
| 501 | "Insert the next element of the minibuffer history into the minibuffer." |
| 502 | (interactive "p") |
| 503 | (let ((narg (min (max 1 (- minibuffer-history-position n)) |
| 504 | (length (symbol-value minibuffer-history-variable))))) |
| 505 | (if (= minibuffer-history-position narg) |
| 506 | (error (if (= minibuffer-history-position 1) |
| 507 | "End of history; no next item" |
| 508 | "Beginning of history; no preceding item")) |
| 509 | (erase-buffer) |
| 510 | (setq minibuffer-history-position narg) |
| 511 | (let ((elt (nth (1- minibuffer-history-position) |
| 512 | (symbol-value minibuffer-history-variable)))) |
| 513 | (insert |
| 514 | (if minibuffer-history-sexp-flag |
| 515 | (prin1-to-string elt) |
| 516 | elt))) |
| 517 | (goto-char (point-min))))) |
| 518 | |
| 519 | (defun previous-history-element (n) |
| 520 | "Inserts the previous element of the minibuffer history into the minibuffer." |
| 521 | (interactive "p") |
| 522 | (next-history-element (- n))) |
| 523 | \f |
| 524 | (defun goto-line (arg) |
| 525 | "Goto line ARG, counting from line 1 at beginning of buffer." |
| 526 | (interactive "NGoto line: ") |
| 527 | (save-restriction |
| 528 | (widen) |
| 529 | (goto-char 1) |
| 530 | (if (eq selective-display t) |
| 531 | (re-search-forward "[\n\C-m]" nil 'end (1- arg)) |
| 532 | (forward-line (1- arg))))) |
| 533 | |
| 534 | ;Put this on C-x u, so we can force that rather than C-_ into startup msg |
| 535 | (fset 'advertised-undo 'undo) |
| 536 | |
| 537 | (defun undo (&optional arg) |
| 538 | "Undo some previous changes. |
| 539 | Repeat this command to undo more changes. |
| 540 | A numeric argument serves as a repeat count." |
| 541 | (interactive "*p") |
| 542 | (let ((modified (buffer-modified-p))) |
| 543 | (or (eq (selected-window) (minibuffer-window)) |
| 544 | (message "Undo!")) |
| 545 | (or (eq last-command 'undo) |
| 546 | (progn (undo-start) |
| 547 | (undo-more 1))) |
| 548 | (setq this-command 'undo) |
| 549 | (undo-more (or arg 1)) |
| 550 | (and modified (not (buffer-modified-p)) |
| 551 | (delete-auto-save-file-if-necessary)))) |
| 552 | |
| 553 | (defun undo-start () |
| 554 | "Set `pending-undo-list' to the front of the undo list. |
| 555 | The next call to `undo-more' will undo the most recently made change." |
| 556 | (if (eq buffer-undo-list t) |
| 557 | (error "No undo information in this buffer")) |
| 558 | (setq pending-undo-list buffer-undo-list)) |
| 559 | |
| 560 | (defun undo-more (count) |
| 561 | "Undo back N undo-boundaries beyond what was already undone recently. |
| 562 | Call `undo-start' to get ready to undo recent changes, |
| 563 | then call `undo-more' one or more times to undo them." |
| 564 | (or pending-undo-list |
| 565 | (error "No further undo information")) |
| 566 | (setq pending-undo-list (primitive-undo count pending-undo-list))) |
| 567 | |
| 568 | (defvar last-shell-command "") |
| 569 | (defvar last-shell-command-on-region "") |
| 570 | |
| 571 | (defun shell-command (command &optional flag) |
| 572 | "Execute string COMMAND in inferior shell; display output, if any. |
| 573 | If COMMAND ends in ampersand, execute it asynchronously. |
| 574 | |
| 575 | Optional second arg non-nil (prefix arg, if interactive) |
| 576 | means insert output in current buffer after point (leave mark after it). |
| 577 | This cannot be done asynchronously." |
| 578 | (interactive (list (read-string "Shell command: " last-shell-command) |
| 579 | current-prefix-arg)) |
| 580 | (if flag |
| 581 | (progn (barf-if-buffer-read-only) |
| 582 | (push-mark) |
| 583 | ;; We do not use -f for csh; we will not support broken use of |
| 584 | ;; .cshrcs. Even the BSD csh manual says to use |
| 585 | ;; "if ($?prompt) exit" before things which are not useful |
| 586 | ;; non-interactively. Besides, if someone wants their other |
| 587 | ;; aliases for shell commands then they can still have them. |
| 588 | (call-process shell-file-name nil t nil |
| 589 | "-c" command) |
| 590 | (exchange-point-and-mark)) |
| 591 | ;; Preserve the match data in case called from a program. |
| 592 | (let ((data (match-data))) |
| 593 | (unwind-protect |
| 594 | (if (string-match "[ \t]*&[ \t]*$" command) |
| 595 | ;; Command ending with ampersand means asynchronous. |
| 596 | (let ((buffer (get-buffer-create "*shell-command*")) |
| 597 | (directory default-directory) |
| 598 | proc) |
| 599 | ;; Remove the ampersand. |
| 600 | (setq command (substring command 0 (match-beginning 0))) |
| 601 | ;; If will kill a process, query first. |
| 602 | (setq proc (get-buffer-process buffer)) |
| 603 | (if proc |
| 604 | (if (yes-or-no-p "A command is running. Kill it? ") |
| 605 | (kill-process proc) |
| 606 | (error "Shell command in progress"))) |
| 607 | (save-excursion |
| 608 | (set-buffer buffer) |
| 609 | (erase-buffer) |
| 610 | (display-buffer buffer) |
| 611 | (setq default-directory directory) |
| 612 | (setq proc (start-process "Shell" buffer |
| 613 | shell-file-name "-c" command)) |
| 614 | (setq mode-line-process '(": %s")) |
| 615 | (set-process-sentinel proc 'shell-command-sentinel) |
| 616 | (set-process-filter proc 'shell-command-filter) |
| 617 | )) |
| 618 | (shell-command-on-region (point) (point) command nil)) |
| 619 | (store-match-data data))))) |
| 620 | |
| 621 | ;; We have a sentinel to prevent insertion of a termination message |
| 622 | ;; in the buffer itself. |
| 623 | (defun shell-command-sentinel (process signal) |
| 624 | (if (memq (process-status process) '(exit signal)) |
| 625 | (progn |
| 626 | (message "%s: %s." |
| 627 | (car (cdr (cdr (process-command process)))) |
| 628 | (substring signal 0 -1)) |
| 629 | (save-excursion |
| 630 | (set-buffer (process-buffer process)) |
| 631 | (setq mode-line-process nil)) |
| 632 | (delete-process process)))) |
| 633 | |
| 634 | (defun shell-command-filter (proc string) |
| 635 | ;; Do save-excursion by hand so that we can leave point numerically unchanged |
| 636 | ;; despite an insertion immediately after it. |
| 637 | (let* ((obuf (current-buffer)) |
| 638 | (buffer (process-buffer proc)) |
| 639 | opoint |
| 640 | (window (get-buffer-window buffer)) |
| 641 | (pos (window-start window))) |
| 642 | (unwind-protect |
| 643 | (progn |
| 644 | (set-buffer buffer) |
| 645 | (setq opoint (point)) |
| 646 | (goto-char (point-max)) |
| 647 | (insert-before-markers string)) |
| 648 | ;; insert-before-markers moved this marker: set it back. |
| 649 | (set-window-start window pos) |
| 650 | ;; Finish our save-excursion. |
| 651 | (goto-char opoint) |
| 652 | (set-buffer obuf)))) |
| 653 | |
| 654 | (defun shell-command-on-region (start end command &optional flag interactive) |
| 655 | "Execute string COMMAND in inferior shell with region as input. |
| 656 | Normally display output (if any) in temp buffer `*Shell Command Output*'; |
| 657 | Prefix arg means replace the region with it. |
| 658 | Noninteractive args are START, END, COMMAND, FLAG. |
| 659 | Noninteractively FLAG means insert output in place of text from START to END, |
| 660 | and put point at the end, but don't alter the mark. |
| 661 | |
| 662 | If the output is one line, it is displayed in the echo area, |
| 663 | but it is nonetheless available in buffer `*Shell Command Output*' |
| 664 | even though that buffer is not automatically displayed. If there is no output |
| 665 | or output is inserted in the current buffer then `*Shell Command Output*' is |
| 666 | deleted." |
| 667 | (interactive (list (region-beginning) (region-end) |
| 668 | (read-string "Shell command on region: " |
| 669 | last-shell-command-on-region) |
| 670 | current-prefix-arg |
| 671 | (prefix-numeric-value current-prefix-arg))) |
| 672 | (if flag |
| 673 | ;; Replace specified region with output from command. |
| 674 | (let ((swap (and interactive (< (point) (mark))))) |
| 675 | ;; Don't muck with mark |
| 676 | ;; unless called interactively. |
| 677 | (and interactive (push-mark)) |
| 678 | (call-process-region start end shell-file-name t t nil |
| 679 | "-c" command) |
| 680 | (if (get-buffer "*Shell Command Output*") |
| 681 | (kill-buffer "*Shell Command Output*")) |
| 682 | (and interactive swap (exchange-point-and-mark))) |
| 683 | ;; No prefix argument: put the output in a temp buffer, |
| 684 | ;; replacing its entire contents. |
| 685 | (let ((buffer (get-buffer-create "*Shell Command Output*"))) |
| 686 | (if (eq buffer (current-buffer)) |
| 687 | ;; If the input is the same buffer as the output, |
| 688 | ;; delete everything but the specified region, |
| 689 | ;; then replace that region with the output. |
| 690 | (progn (delete-region end (point-max)) |
| 691 | (delete-region (point-min) start) |
| 692 | (call-process-region (point-min) (point-max) |
| 693 | shell-file-name t t nil |
| 694 | "-c" command)) |
| 695 | ;; Clear the output buffer, then run the command with output there. |
| 696 | (save-excursion |
| 697 | (set-buffer buffer) |
| 698 | (erase-buffer)) |
| 699 | (call-process-region start end shell-file-name |
| 700 | nil buffer nil |
| 701 | "-c" command)) |
| 702 | ;; Report the amount of output. |
| 703 | (let ((lines (save-excursion |
| 704 | (set-buffer buffer) |
| 705 | (if (= (buffer-size) 0) |
| 706 | 0 |
| 707 | (count-lines (point-min) (point-max)))))) |
| 708 | (cond ((= lines 0) |
| 709 | (message "(Shell command completed with no output)") |
| 710 | (kill-buffer "*Shell Command Output*")) |
| 711 | ((= lines 1) |
| 712 | (message "%s" |
| 713 | (save-excursion |
| 714 | (set-buffer buffer) |
| 715 | (goto-char (point-min)) |
| 716 | (buffer-substring (point) |
| 717 | (progn (end-of-line) (point)))))) |
| 718 | (t |
| 719 | (set-window-start (display-buffer buffer) 1))))))) |
| 720 | \f |
| 721 | (defun universal-argument () |
| 722 | "Begin a numeric argument for the following command. |
| 723 | Digits or minus sign following \\[universal-argument] make up the numeric argument. |
| 724 | \\[universal-argument] following the digits or minus sign ends the argument. |
| 725 | \\[universal-argument] without digits or minus sign provides 4 as argument. |
| 726 | Repeating \\[universal-argument] without digits or minus sign |
| 727 | multiplies the argument by 4 each time." |
| 728 | (interactive nil) |
| 729 | (let ((factor 4) |
| 730 | key) |
| 731 | ;; (describe-arg (list factor) 1) |
| 732 | (setq key (read-key-sequence nil t)) |
| 733 | (while (equal (key-binding key) 'universal-argument) |
| 734 | (setq factor (* 4 factor)) |
| 735 | ;; (describe-arg (list factor) 1) |
| 736 | (setq key (read-key-sequence nil t))) |
| 737 | (prefix-arg-internal key factor nil))) |
| 738 | |
| 739 | (defun prefix-arg-internal (key factor value) |
| 740 | (let ((sign 1)) |
| 741 | (if (and (numberp value) (< value 0)) |
| 742 | (setq sign -1 value (- value))) |
| 743 | (if (eq value '-) |
| 744 | (setq sign -1 value nil)) |
| 745 | ;; (describe-arg value sign) |
| 746 | (while (equal key "-") |
| 747 | (setq sign (- sign) factor nil) |
| 748 | ;; (describe-arg value sign) |
| 749 | (setq key (read-key-sequence nil t))) |
| 750 | (while (and (stringp key) |
| 751 | (= (length key) 1) |
| 752 | (not (string< key "0")) |
| 753 | (not (string< "9" key))) |
| 754 | (setq value (+ (* (if (numberp value) value 0) 10) |
| 755 | (- (aref key 0) ?0)) |
| 756 | factor nil) |
| 757 | ;; (describe-arg value sign) |
| 758 | (setq key (read-key-sequence nil t))) |
| 759 | (setq prefix-arg |
| 760 | (cond (factor (list factor)) |
| 761 | ((numberp value) (* value sign)) |
| 762 | ((= sign -1) '-))) |
| 763 | ;; Calling universal-argument after digits |
| 764 | ;; terminates the argument but is ignored. |
| 765 | (if (eq (key-binding key) 'universal-argument) |
| 766 | (progn |
| 767 | (describe-arg value sign) |
| 768 | (setq key (read-key-sequence nil t)))) |
| 769 | (if (= (length key) 1) |
| 770 | ;; Make sure self-insert-command finds the proper character; |
| 771 | ;; unread the character and let the command loop process it. |
| 772 | (setq unread-command-char (string-to-char key)) |
| 773 | ;; We can't push back a longer string, so we'll emulate the |
| 774 | ;; command loop ourselves. |
| 775 | (command-execute (key-binding key))))) |
| 776 | |
| 777 | (defun describe-arg (value sign) |
| 778 | (cond ((numberp value) |
| 779 | (message "Arg: %d" (* value sign))) |
| 780 | ((consp value) |
| 781 | (message "Arg: [%d]" (car value))) |
| 782 | ((< sign 0) |
| 783 | (message "Arg: -")))) |
| 784 | |
| 785 | (defun digit-argument (arg) |
| 786 | "Part of the numeric argument for the next command. |
| 787 | \\[universal-argument] following digits or minus sign ends the argument." |
| 788 | (interactive "P") |
| 789 | (prefix-arg-internal (char-to-string (logand last-command-char ?\177)) |
| 790 | nil arg)) |
| 791 | |
| 792 | (defun negative-argument (arg) |
| 793 | "Begin a negative numeric argument for the next command. |
| 794 | \\[universal-argument] following digits or minus sign ends the argument." |
| 795 | (interactive "P") |
| 796 | (prefix-arg-internal "-" nil arg)) |
| 797 | \f |
| 798 | (defun forward-to-indentation (arg) |
| 799 | "Move forward ARG lines and position at first nonblank character." |
| 800 | (interactive "p") |
| 801 | (forward-line arg) |
| 802 | (skip-chars-forward " \t")) |
| 803 | |
| 804 | (defun backward-to-indentation (arg) |
| 805 | "Move backward ARG lines and position at first nonblank character." |
| 806 | (interactive "p") |
| 807 | (forward-line (- arg)) |
| 808 | (skip-chars-forward " \t")) |
| 809 | |
| 810 | (defun kill-line (&optional arg) |
| 811 | "Kill the rest of the current line; if no nonblanks there, kill thru newline. |
| 812 | With prefix argument, kill that many lines from point. |
| 813 | Negative arguments kill lines backward. |
| 814 | |
| 815 | When calling from a program, nil means \"no arg\", |
| 816 | a number counts as a prefix arg." |
| 817 | (interactive "P") |
| 818 | (kill-region (point) |
| 819 | (progn |
| 820 | (if arg |
| 821 | (forward-line (prefix-numeric-value arg)) |
| 822 | (if (eobp) |
| 823 | (signal 'end-of-buffer nil)) |
| 824 | (if (looking-at "[ \t]*$") |
| 825 | (forward-line 1) |
| 826 | (end-of-line))) |
| 827 | (point)))) |
| 828 | \f |
| 829 | ;;;; Window system cut and paste hooks. |
| 830 | |
| 831 | (defvar interprogram-cut-function nil |
| 832 | "Function to call to make a killed region available to other programs. |
| 833 | |
| 834 | Most window systems provide some sort of facility for cutting and |
| 835 | pasting text between the windows of different programs. On startup, |
| 836 | this variable is set to a function which emacs will call whenever text |
| 837 | is put in the kill ring to make the new kill available to other |
| 838 | programs. |
| 839 | |
| 840 | The function takes one argument, TEXT, which is a string containing |
| 841 | the text which should be made available.") |
| 842 | |
| 843 | (defvar interprogram-paste-function nil |
| 844 | "Function to call to get text cut from other programs. |
| 845 | |
| 846 | Most window systems provide some sort of facility for cutting and |
| 847 | pasting text between the windows of different programs. On startup, |
| 848 | this variable is set to a function which emacs will call to obtain |
| 849 | text that other programs have provided for pasting. |
| 850 | |
| 851 | The function should be called with no arguments. If the function |
| 852 | returns nil, then no other program has provided such text, and the top |
| 853 | of the Emacs kill ring should be used. If the function returns a |
| 854 | string, that string should be put in the kill ring as the latest kill. |
| 855 | |
| 856 | Note that the function should return a string only if a program other |
| 857 | than Emacs has provided a string for pasting; if Emacs provided the |
| 858 | most recent string, the function should return nil. If it is |
| 859 | difficult to tell whether Emacs or some other program provided the |
| 860 | current string, it is probably good enough to return nil if the string |
| 861 | is equal (according to `string=') to the last text Emacs provided.") |
| 862 | |
| 863 | |
| 864 | \f |
| 865 | ;;;; The kill ring data structure. |
| 866 | |
| 867 | (defvar kill-ring nil |
| 868 | "List of killed text sequences. |
| 869 | Since the kill ring is supposed to interact nicely with cut-and-paste |
| 870 | facilities offered by window systems, use of this variable should |
| 871 | interact nicely with `interprogram-cut-function' and |
| 872 | `interprogram-paste-function'. The functions `kill-new', |
| 873 | `kill-append', and `current-kill' are supposed to implement this |
| 874 | interaction; you may want to use them instead of manipulating the kill |
| 875 | ring directly.") |
| 876 | |
| 877 | (defconst kill-ring-max 30 |
| 878 | "*Maximum length of kill ring before oldest elements are thrown away.") |
| 879 | |
| 880 | (defvar kill-ring-yank-pointer nil |
| 881 | "The tail of the kill ring whose car is the last thing yanked.") |
| 882 | |
| 883 | (defun kill-new (string) |
| 884 | "Make STRING the latest kill in the kill ring. |
| 885 | Set the kill-ring-yank pointer to point to it. |
| 886 | If `interprogram-cut-function' is non-nil, apply it to STRING." |
| 887 | (setq kill-ring (cons string kill-ring)) |
| 888 | (if (> (length kill-ring) kill-ring-max) |
| 889 | (setcdr (nthcdr (1- kill-ring-max) kill-ring) nil)) |
| 890 | (setq kill-ring-yank-pointer kill-ring) |
| 891 | (if interprogram-cut-function |
| 892 | (funcall interprogram-cut-function string))) |
| 893 | |
| 894 | (defun kill-append (string before-p) |
| 895 | "Append STRING to the end of the latest kill in the kill ring. |
| 896 | If BEFORE-P is non-nil, prepend STRING to the kill. |
| 897 | If 'interprogram-cut-function' is set, pass the resulting kill to |
| 898 | it." |
| 899 | (setcar kill-ring |
| 900 | (if before-p |
| 901 | (concat string (car kill-ring)) |
| 902 | (concat (car kill-ring) string))) |
| 903 | (if interprogram-cut-function |
| 904 | (funcall interprogram-cut-function (car kill-ring)))) |
| 905 | |
| 906 | (defun current-kill (n &optional do-not-move) |
| 907 | "Rotate the yanking point by N places, and then return that kill. |
| 908 | If N is zero, `interprogram-paste-function' is set, and calling it |
| 909 | returns a string, then that string is added to the front of the |
| 910 | kill ring and returned as the latest kill. |
| 911 | If optional arg DO-NOT-MOVE is non-nil, then don't actually move the |
| 912 | yanking point; just return the Nth kill forward." |
| 913 | (let ((interprogram-paste (and (= n 0) |
| 914 | interprogram-paste-function |
| 915 | (funcall interprogram-paste-function)))) |
| 916 | (if interprogram-paste |
| 917 | (progn |
| 918 | ;; Disable the interprogram cut function when we add the new |
| 919 | ;; text to the kill ring, so Emacs doesn't try to own the |
| 920 | ;; selection, with identical text. |
| 921 | (let ((interprogram-cut-function nil)) |
| 922 | (kill-new interprogram-paste)) |
| 923 | interprogram-paste) |
| 924 | (or kill-ring (error "Kill ring is empty")) |
| 925 | (let* ((length (length kill-ring)) |
| 926 | (ARGth-kill-element |
| 927 | (nthcdr (% (+ n (- length (length kill-ring-yank-pointer))) |
| 928 | length) |
| 929 | kill-ring))) |
| 930 | (or do-not-move |
| 931 | (setq kill-ring-yank-pointer ARGth-kill-element)) |
| 932 | (car ARGth-kill-element))))) |
| 933 | |
| 934 | |
| 935 | \f |
| 936 | ;;;; Commands for manipulating the kill ring. |
| 937 | |
| 938 | (defun kill-region (beg end) |
| 939 | "Kill between point and mark. |
| 940 | The text is deleted but saved in the kill ring. |
| 941 | The command \\[yank] can retrieve it from there. |
| 942 | \(If you want to kill and then yank immediately, use \\[copy-region-as-kill].) |
| 943 | |
| 944 | This is the primitive for programs to kill text (as opposed to deleting it). |
| 945 | Supply two arguments, character numbers indicating the stretch of text |
| 946 | to be killed. |
| 947 | Any command that calls this function is a \"kill command\". |
| 948 | If the previous command was also a kill command, |
| 949 | the text killed this time appends to the text killed last time |
| 950 | to make one entry in the kill ring." |
| 951 | (interactive "r") |
| 952 | (cond |
| 953 | (buffer-read-only |
| 954 | (copy-region-as-kill beg end)) |
| 955 | ((not (or (eq buffer-undo-list t) |
| 956 | (eq last-command 'kill-region) |
| 957 | (eq beg end))) |
| 958 | ;; Don't let the undo list be truncated before we can even access it. |
| 959 | (let ((undo-strong-limit (+ (- (max beg end) (min beg end)) 100))) |
| 960 | (delete-region beg end) |
| 961 | ;; Take the same string recorded for undo |
| 962 | ;; and put it in the kill-ring. |
| 963 | (kill-new (car (car buffer-undo-list))) |
| 964 | (setq this-command 'kill-region))) |
| 965 | (t |
| 966 | (copy-region-as-kill beg end) |
| 967 | (delete-region beg end)))) |
| 968 | |
| 969 | (defun copy-region-as-kill (beg end) |
| 970 | "Save the region as if killed, but don't kill it. |
| 971 | If `interprogram-cut-function' is non-nil, also save the text for a window |
| 972 | system cut and paste." |
| 973 | (interactive "r") |
| 974 | (if (eq last-command 'kill-region) |
| 975 | (kill-append (buffer-substring beg end) (< end beg)) |
| 976 | (kill-new (buffer-substring beg end))) |
| 977 | (setq this-command 'kill-region) |
| 978 | nil) |
| 979 | |
| 980 | (defun kill-ring-save (beg end) |
| 981 | "Save the region as if killed, but don't kill it." |
| 982 | (interactive "r") |
| 983 | (copy-region-as-kill beg end) |
| 984 | (if (interactive-p) |
| 985 | (save-excursion |
| 986 | (let ((other-end (if (= (point) beg) end beg))) |
| 987 | (if (pos-visible-in-window-p other-end (selected-window)) |
| 988 | (progn |
| 989 | (goto-char other-end) |
| 990 | (sit-for 1)) |
| 991 | (let* ((killed-text (current-kill 0)) |
| 992 | (message-len (min (length killed-text) 40))) |
| 993 | (if (= (point) beg) |
| 994 | ;; Don't say "killed"; that is misleading. |
| 995 | (message "Saved text until \"%s\"" |
| 996 | (substring killed-text (- message-len))) |
| 997 | (message "Saved text from \"%s\"" |
| 998 | (substring killed-text 0 message-len))))))))) |
| 999 | |
| 1000 | (defun append-next-kill () |
| 1001 | "Cause following command, if it kills, to append to previous kill." |
| 1002 | (interactive) |
| 1003 | (if (interactive-p) |
| 1004 | (progn |
| 1005 | (setq this-command 'kill-region) |
| 1006 | (message "If the next command is a kill, it will append")) |
| 1007 | (setq last-command 'kill-region))) |
| 1008 | |
| 1009 | (defun yank-pop (arg) |
| 1010 | "Replace just-yanked stretch of killed text with a different stretch. |
| 1011 | This command is allowed only immediately after a `yank' or a `yank-pop'. |
| 1012 | At such a time, the region contains a stretch of reinserted |
| 1013 | previously-killed text. `yank-pop' deletes that text and inserts in its |
| 1014 | place a different stretch of killed text. |
| 1015 | |
| 1016 | With no argument, the previous kill is inserted. |
| 1017 | With argument N, insert the Nth previous kill. |
| 1018 | If N is negative, this is a more recent kill. |
| 1019 | |
| 1020 | The sequence of kills wraps around, so that after the oldest one |
| 1021 | comes the newest one." |
| 1022 | (interactive "*p") |
| 1023 | (if (not (eq last-command 'yank)) |
| 1024 | (error "Previous command was not a yank")) |
| 1025 | (setq this-command 'yank) |
| 1026 | (let ((before (< (point) (mark)))) |
| 1027 | (delete-region (point) (mark)) |
| 1028 | (set-mark (point)) |
| 1029 | (insert (current-kill arg)) |
| 1030 | (if before (exchange-point-and-mark)))) |
| 1031 | |
| 1032 | (defun yank (&optional arg) |
| 1033 | "Reinsert the last stretch of killed text. |
| 1034 | More precisely, reinsert the stretch of killed text most recently |
| 1035 | killed OR yanked. Put point at end, and set mark at beginning. |
| 1036 | With just C-u as argument, same but put point at beginning (and mark at end). |
| 1037 | With argument N, reinsert the Nth most recently killed stretch of killed |
| 1038 | text. |
| 1039 | See also the command \\[yank-pop]." |
| 1040 | (interactive "*P") |
| 1041 | (push-mark (point)) |
| 1042 | (insert (current-kill (cond |
| 1043 | ((listp arg) 0) |
| 1044 | ((eq arg '-) -1) |
| 1045 | (t (1- arg))))) |
| 1046 | (if (consp arg) |
| 1047 | (exchange-point-and-mark))) |
| 1048 | |
| 1049 | (defun rotate-yank-pointer (arg) |
| 1050 | "Rotate the yanking point in the kill ring. |
| 1051 | With argument, rotate that many kills forward (or backward, if negative)." |
| 1052 | (interactive "p") |
| 1053 | (current-kill arg)) |
| 1054 | |
| 1055 | \f |
| 1056 | (defun insert-buffer (buffer) |
| 1057 | "Insert after point the contents of BUFFER. |
| 1058 | Puts mark after the inserted text. |
| 1059 | BUFFER may be a buffer or a buffer name." |
| 1060 | (interactive (list (progn (barf-if-buffer-read-only) |
| 1061 | (read-buffer "Insert buffer: " (other-buffer) t)))) |
| 1062 | (or (bufferp buffer) |
| 1063 | (setq buffer (get-buffer buffer))) |
| 1064 | (let (start end newmark) |
| 1065 | (save-excursion |
| 1066 | (save-excursion |
| 1067 | (set-buffer buffer) |
| 1068 | (setq start (point-min) end (point-max))) |
| 1069 | (insert-buffer-substring buffer start end) |
| 1070 | (setq newmark (point))) |
| 1071 | (push-mark newmark))) |
| 1072 | |
| 1073 | (defun append-to-buffer (buffer start end) |
| 1074 | "Append to specified buffer the text of the region. |
| 1075 | It is inserted into that buffer before its point. |
| 1076 | |
| 1077 | When calling from a program, give three arguments: |
| 1078 | BUFFER (or buffer name), START and END. |
| 1079 | START and END specify the portion of the current buffer to be copied." |
| 1080 | (interactive |
| 1081 | (list (read-buffer "Append to buffer: " (other-buffer nil t) t))) |
| 1082 | (let ((oldbuf (current-buffer))) |
| 1083 | (save-excursion |
| 1084 | (set-buffer (get-buffer-create buffer)) |
| 1085 | (insert-buffer-substring oldbuf start end)))) |
| 1086 | |
| 1087 | (defun prepend-to-buffer (buffer start end) |
| 1088 | "Prepend to specified buffer the text of the region. |
| 1089 | It is inserted into that buffer after its point. |
| 1090 | |
| 1091 | When calling from a program, give three arguments: |
| 1092 | BUFFER (or buffer name), START and END. |
| 1093 | START and END specify the portion of the current buffer to be copied." |
| 1094 | (interactive "BPrepend to buffer: \nr") |
| 1095 | (let ((oldbuf (current-buffer))) |
| 1096 | (save-excursion |
| 1097 | (set-buffer (get-buffer-create buffer)) |
| 1098 | (save-excursion |
| 1099 | (insert-buffer-substring oldbuf start end))))) |
| 1100 | |
| 1101 | (defun copy-to-buffer (buffer start end) |
| 1102 | "Copy to specified buffer the text of the region. |
| 1103 | It is inserted into that buffer, replacing existing text there. |
| 1104 | |
| 1105 | When calling from a program, give three arguments: |
| 1106 | BUFFER (or buffer name), START and END. |
| 1107 | START and END specify the portion of the current buffer to be copied." |
| 1108 | (interactive "BCopy to buffer: \nr") |
| 1109 | (let ((oldbuf (current-buffer))) |
| 1110 | (save-excursion |
| 1111 | (set-buffer (get-buffer-create buffer)) |
| 1112 | (erase-buffer) |
| 1113 | (save-excursion |
| 1114 | (insert-buffer-substring oldbuf start end))))) |
| 1115 | \f |
| 1116 | (defun mark () |
| 1117 | "Return this buffer's mark value as integer, or nil if no mark. |
| 1118 | If you are using this in an editing command, you are most likely making |
| 1119 | a mistake; see the documentation of `set-mark'." |
| 1120 | (marker-position (mark-marker))) |
| 1121 | |
| 1122 | (defun set-mark (pos) |
| 1123 | "Set this buffer's mark to POS. Don't use this function! |
| 1124 | That is to say, don't use this function unless you want |
| 1125 | the user to see that the mark has moved, and you want the previous |
| 1126 | mark position to be lost. |
| 1127 | |
| 1128 | Normally, when a new mark is set, the old one should go on the stack. |
| 1129 | This is why most applications should use push-mark, not set-mark. |
| 1130 | |
| 1131 | Novice Emacs Lisp programmers often try to use the mark for the wrong |
| 1132 | purposes. The mark saves a location for the user's convenience. |
| 1133 | Most editing commands should not alter the mark. |
| 1134 | To remember a location for internal use in the Lisp program, |
| 1135 | store it in a Lisp variable. Example: |
| 1136 | |
| 1137 | (let ((beg (point))) (forward-line 1) (delete-region beg (point)))." |
| 1138 | |
| 1139 | (set-marker (mark-marker) pos (current-buffer))) |
| 1140 | |
| 1141 | (defvar mark-ring nil |
| 1142 | "The list of saved former marks of the current buffer, |
| 1143 | most recent first.") |
| 1144 | (make-variable-buffer-local 'mark-ring) |
| 1145 | |
| 1146 | (defconst mark-ring-max 16 |
| 1147 | "*Maximum size of mark ring. Start discarding off end if gets this big.") |
| 1148 | |
| 1149 | (defun set-mark-command (arg) |
| 1150 | "Set mark at where point is, or jump to mark. |
| 1151 | With no prefix argument, set mark, and push previous mark on mark ring. |
| 1152 | With argument, jump to mark, and pop into mark off the mark ring. |
| 1153 | |
| 1154 | Novice Emacs Lisp programmers often try to use the mark for the wrong |
| 1155 | purposes. See the documentation of `set-mark' for more information." |
| 1156 | (interactive "P") |
| 1157 | (if (null arg) |
| 1158 | (push-mark) |
| 1159 | (if (null (mark)) |
| 1160 | (error "No mark set in this buffer") |
| 1161 | (goto-char (mark)) |
| 1162 | (pop-mark)))) |
| 1163 | |
| 1164 | (defun push-mark (&optional location nomsg) |
| 1165 | "Set mark at LOCATION (point, by default) and push old mark on mark ring. |
| 1166 | Displays \"Mark set\" unless the optional second arg NOMSG is non-nil. |
| 1167 | |
| 1168 | Novice Emacs Lisp programmers often try to use the mark for the wrong |
| 1169 | purposes. See the documentation of `set-mark' for more information." |
| 1170 | (if (null (mark)) |
| 1171 | nil |
| 1172 | (setq mark-ring (cons (copy-marker (mark-marker)) mark-ring)) |
| 1173 | (if (> (length mark-ring) mark-ring-max) |
| 1174 | (progn |
| 1175 | (move-marker (car (nthcdr mark-ring-max mark-ring)) nil) |
| 1176 | (setcdr (nthcdr (1- mark-ring-max) mark-ring) nil)))) |
| 1177 | (set-mark (or location (point))) |
| 1178 | (or nomsg executing-macro (> (minibuffer-depth) 0) |
| 1179 | (message "Mark set")) |
| 1180 | nil) |
| 1181 | |
| 1182 | (defun pop-mark () |
| 1183 | "Pop off mark ring into the buffer's actual mark. |
| 1184 | Does not set point. Does nothing if mark ring is empty." |
| 1185 | (if mark-ring |
| 1186 | (progn |
| 1187 | (setq mark-ring (nconc mark-ring (list (copy-marker (mark-marker))))) |
| 1188 | (set-mark (+ 0 (car mark-ring))) |
| 1189 | (move-marker (car mark-ring) nil) |
| 1190 | (if (null (mark)) (ding)) |
| 1191 | (setq mark-ring (cdr mark-ring))))) |
| 1192 | |
| 1193 | (fset 'exchange-dot-and-mark 'exchange-point-and-mark) |
| 1194 | (defun exchange-point-and-mark () |
| 1195 | "Put the mark where point is now, and point where the mark is now." |
| 1196 | (interactive nil) |
| 1197 | (let ((omark (mark))) |
| 1198 | (if (null omark) |
| 1199 | (error "No mark set in this buffer")) |
| 1200 | (set-mark (point)) |
| 1201 | (goto-char omark) |
| 1202 | nil)) |
| 1203 | \f |
| 1204 | (defun next-line (arg) |
| 1205 | "Move cursor vertically down ARG lines. |
| 1206 | If there is no character in the target line exactly under the current column, |
| 1207 | the cursor is positioned after the character in that line which spans this |
| 1208 | column, or at the end of the line if it is not long enough. |
| 1209 | If there is no line in the buffer after this one, |
| 1210 | a newline character is inserted to create a line |
| 1211 | and the cursor moves to that line. |
| 1212 | |
| 1213 | The command \\[set-goal-column] can be used to create |
| 1214 | a semipermanent goal column to which this command always moves. |
| 1215 | Then it does not try to move vertically. This goal column is stored |
| 1216 | in `goal-column', which is nil when there is none. |
| 1217 | |
| 1218 | If you are thinking of using this in a Lisp program, consider |
| 1219 | using `forward-line' instead. It is usually easier to use |
| 1220 | and more reliable (no dependence on goal column, etc.)." |
| 1221 | (interactive "p") |
| 1222 | (if (= arg 1) |
| 1223 | (let ((opoint (point))) |
| 1224 | (forward-line 1) |
| 1225 | (if (or (= opoint (point)) |
| 1226 | (not (eq (preceding-char) ?\n))) |
| 1227 | (insert ?\n) |
| 1228 | (goto-char opoint) |
| 1229 | (line-move arg))) |
| 1230 | (line-move arg)) |
| 1231 | nil) |
| 1232 | |
| 1233 | (defun previous-line (arg) |
| 1234 | "Move cursor vertically up ARG lines. |
| 1235 | If there is no character in the target line exactly over the current column, |
| 1236 | the cursor is positioned after the character in that line which spans this |
| 1237 | column, or at the end of the line if it is not long enough. |
| 1238 | |
| 1239 | The command \\[set-goal-column] can be used to create |
| 1240 | a semipermanent goal column to which this command always moves. |
| 1241 | Then it does not try to move vertically. |
| 1242 | |
| 1243 | If you are thinking of using this in a Lisp program, consider using |
| 1244 | `forward-line' with negative argument instead.. It is usually easier |
| 1245 | to use and more reliable (no dependence on goal column, etc.)." |
| 1246 | (interactive "p") |
| 1247 | (line-move (- arg)) |
| 1248 | nil) |
| 1249 | |
| 1250 | (defconst track-eol nil |
| 1251 | "*Non-nil means vertical motion starting at end of line keeps to ends of lines. |
| 1252 | This means moving to the end of each line moved onto. |
| 1253 | The beginning of a blank line does not count as the end of a line.") |
| 1254 | |
| 1255 | (defvar goal-column nil |
| 1256 | "*Semipermanent goal column for vertical motion, as set by \\[set-goal-column], or nil.") |
| 1257 | (make-variable-buffer-local 'goal-column) |
| 1258 | |
| 1259 | (defvar temporary-goal-column 0 |
| 1260 | "Current goal column for vertical motion. |
| 1261 | It is the column where point was |
| 1262 | at the start of current run of vertical motion commands. |
| 1263 | When the `track-eol' feature is doing its job, the value is 9999.") |
| 1264 | |
| 1265 | (defun line-move (arg) |
| 1266 | (if (not (or (eq last-command 'next-line) |
| 1267 | (eq last-command 'previous-line))) |
| 1268 | (setq temporary-goal-column |
| 1269 | (if (and track-eol (eolp) |
| 1270 | ;; Don't count beg of empty line as end of line |
| 1271 | ;; unless we just did explicit end-of-line. |
| 1272 | (or (not (bolp)) (eq last-command 'end-of-line))) |
| 1273 | 9999 |
| 1274 | (current-column)))) |
| 1275 | (if (not (integerp selective-display)) |
| 1276 | (forward-line arg) |
| 1277 | ;; Move by arg lines, but ignore invisible ones. |
| 1278 | (while (> arg 0) |
| 1279 | (vertical-motion 1) |
| 1280 | (forward-char -1) |
| 1281 | (forward-line 1) |
| 1282 | (setq arg (1- arg))) |
| 1283 | (while (< arg 0) |
| 1284 | (vertical-motion -1) |
| 1285 | (beginning-of-line) |
| 1286 | (setq arg (1+ arg)))) |
| 1287 | (move-to-column (or goal-column temporary-goal-column)) |
| 1288 | nil) |
| 1289 | |
| 1290 | |
| 1291 | (defun set-goal-column (arg) |
| 1292 | "Set the current horizontal position as a goal for \\[next-line] and \\[previous-line]. |
| 1293 | Those commands will move to this position in the line moved to |
| 1294 | rather than trying to keep the same horizontal position. |
| 1295 | With a non-nil argument, clears out the goal column |
| 1296 | so that \\[next-line] and \\[previous-line] resume vertical motion. |
| 1297 | The goal column is stored in the variable `goal-column'." |
| 1298 | (interactive "P") |
| 1299 | (if arg |
| 1300 | (progn |
| 1301 | (setq goal-column nil) |
| 1302 | (message "No goal column")) |
| 1303 | (setq goal-column (current-column)) |
| 1304 | (message (substitute-command-keys |
| 1305 | "Goal column %d (use \\[set-goal-column] with an arg to unset it)") |
| 1306 | goal-column)) |
| 1307 | nil) |
| 1308 | \f |
| 1309 | (defun transpose-chars (arg) |
| 1310 | "Interchange characters around point, moving forward one character. |
| 1311 | With prefix arg ARG, effect is to take character before point |
| 1312 | and drag it forward past ARG other characters (backward if ARG negative). |
| 1313 | If no argument and at end of line, the previous two chars are exchanged." |
| 1314 | (interactive "*P") |
| 1315 | (and (null arg) (eolp) (forward-char -1)) |
| 1316 | (transpose-subr 'forward-char (prefix-numeric-value arg))) |
| 1317 | |
| 1318 | (defun transpose-words (arg) |
| 1319 | "Interchange words around point, leaving point at end of them. |
| 1320 | With prefix arg ARG, effect is to take word before or around point |
| 1321 | and drag it forward past ARG other words (backward if ARG negative). |
| 1322 | If ARG is zero, the words around or after point and around or after mark |
| 1323 | are interchanged." |
| 1324 | (interactive "*p") |
| 1325 | (transpose-subr 'forward-word arg)) |
| 1326 | |
| 1327 | (defun transpose-sexps (arg) |
| 1328 | "Like \\[transpose-words] but applies to sexps. |
| 1329 | Does not work on a sexp that point is in the middle of |
| 1330 | if it is a list or string." |
| 1331 | (interactive "*p") |
| 1332 | (transpose-subr 'forward-sexp arg)) |
| 1333 | |
| 1334 | (defun transpose-lines (arg) |
| 1335 | "Exchange current line and previous line, leaving point after both. |
| 1336 | With argument ARG, takes previous line and moves it past ARG lines. |
| 1337 | With argument 0, interchanges line point is in with line mark is in." |
| 1338 | (interactive "*p") |
| 1339 | (transpose-subr (function |
| 1340 | (lambda (arg) |
| 1341 | (if (= arg 1) |
| 1342 | (progn |
| 1343 | ;; Move forward over a line, |
| 1344 | ;; but create a newline if none exists yet. |
| 1345 | (end-of-line) |
| 1346 | (if (eobp) |
| 1347 | (newline) |
| 1348 | (forward-char 1))) |
| 1349 | (forward-line arg)))) |
| 1350 | arg)) |
| 1351 | |
| 1352 | (defun transpose-subr (mover arg) |
| 1353 | (let (start1 end1 start2 end2) |
| 1354 | (if (= arg 0) |
| 1355 | (progn |
| 1356 | (save-excursion |
| 1357 | (funcall mover 1) |
| 1358 | (setq end2 (point)) |
| 1359 | (funcall mover -1) |
| 1360 | (setq start2 (point)) |
| 1361 | (goto-char (mark)) |
| 1362 | (funcall mover 1) |
| 1363 | (setq end1 (point)) |
| 1364 | (funcall mover -1) |
| 1365 | (setq start1 (point)) |
| 1366 | (transpose-subr-1)) |
| 1367 | (exchange-point-and-mark))) |
| 1368 | (while (> arg 0) |
| 1369 | (funcall mover -1) |
| 1370 | (setq start1 (point)) |
| 1371 | (funcall mover 1) |
| 1372 | (setq end1 (point)) |
| 1373 | (funcall mover 1) |
| 1374 | (setq end2 (point)) |
| 1375 | (funcall mover -1) |
| 1376 | (setq start2 (point)) |
| 1377 | (transpose-subr-1) |
| 1378 | (goto-char end2) |
| 1379 | (setq arg (1- arg))) |
| 1380 | (while (< arg 0) |
| 1381 | (funcall mover -1) |
| 1382 | (setq start2 (point)) |
| 1383 | (funcall mover -1) |
| 1384 | (setq start1 (point)) |
| 1385 | (funcall mover 1) |
| 1386 | (setq end1 (point)) |
| 1387 | (funcall mover 1) |
| 1388 | (setq end2 (point)) |
| 1389 | (transpose-subr-1) |
| 1390 | (setq arg (1+ arg))))) |
| 1391 | |
| 1392 | (defun transpose-subr-1 () |
| 1393 | (if (> (min end1 end2) (max start1 start2)) |
| 1394 | (error "Don't have two things to transpose")) |
| 1395 | (let ((word1 (buffer-substring start1 end1)) |
| 1396 | (word2 (buffer-substring start2 end2))) |
| 1397 | (delete-region start2 end2) |
| 1398 | (goto-char start2) |
| 1399 | (insert word1) |
| 1400 | (goto-char (if (< start1 start2) start1 |
| 1401 | (+ start1 (- (length word1) (length word2))))) |
| 1402 | (delete-char (length word1)) |
| 1403 | (insert word2))) |
| 1404 | \f |
| 1405 | (defconst comment-column 32 |
| 1406 | "*Column to indent right-margin comments to. |
| 1407 | Setting this variable automatically makes it local to the current buffer.") |
| 1408 | (make-variable-buffer-local 'comment-column) |
| 1409 | |
| 1410 | (defconst comment-start nil |
| 1411 | "*String to insert to start a new comment, or nil if no comment syntax defined.") |
| 1412 | |
| 1413 | (defconst comment-start-skip nil |
| 1414 | "*Regexp to match the start of a comment plus everything up to its body. |
| 1415 | If there are any \\(...\\) pairs, the comment delimiter text is held to begin |
| 1416 | at the place matched by the close of the first pair.") |
| 1417 | |
| 1418 | (defconst comment-end "" |
| 1419 | "*String to insert to end a new comment. |
| 1420 | Should be an empty string if comments are terminated by end-of-line.") |
| 1421 | |
| 1422 | (defconst comment-indent-hook |
| 1423 | '(lambda () comment-column) |
| 1424 | "Function to compute desired indentation for a comment. |
| 1425 | This function is called with no args with point at the beginning of |
| 1426 | the comment's starting delimiter.") |
| 1427 | |
| 1428 | (defun indent-for-comment () |
| 1429 | "Indent this line's comment to comment column, or insert an empty comment." |
| 1430 | (interactive "*") |
| 1431 | (beginning-of-line 1) |
| 1432 | (if (null comment-start) |
| 1433 | (error "No comment syntax defined") |
| 1434 | (let* ((eolpos (save-excursion (end-of-line) (point))) |
| 1435 | cpos indent begpos) |
| 1436 | (if (re-search-forward comment-start-skip eolpos 'move) |
| 1437 | (progn (setq cpos (point-marker)) |
| 1438 | ;; Find the start of the comment delimiter. |
| 1439 | ;; If there were paren-pairs in comment-start-skip, |
| 1440 | ;; position at the end of the first pair. |
| 1441 | (if (match-end 1) |
| 1442 | (goto-char (match-end 1)) |
| 1443 | ;; If comment-start-skip matched a string with internal |
| 1444 | ;; whitespace (not final whitespace) then the delimiter |
| 1445 | ;; start at the end of that whitespace. |
| 1446 | ;; Otherwise, it starts at the beginning of what was matched. |
| 1447 | (skip-chars-backward " \t" (match-beginning 0)) |
| 1448 | (skip-chars-backward "^ \t" (match-beginning 0))))) |
| 1449 | (setq begpos (point)) |
| 1450 | ;; Compute desired indent. |
| 1451 | (if (= (current-column) |
| 1452 | (setq indent (funcall comment-indent-hook))) |
| 1453 | (goto-char begpos) |
| 1454 | ;; If that's different from current, change it. |
| 1455 | (skip-chars-backward " \t") |
| 1456 | (delete-region (point) begpos) |
| 1457 | (indent-to indent)) |
| 1458 | ;; An existing comment? |
| 1459 | (if cpos |
| 1460 | (progn (goto-char cpos) |
| 1461 | (set-marker cpos nil)) |
| 1462 | ;; No, insert one. |
| 1463 | (insert comment-start) |
| 1464 | (save-excursion |
| 1465 | (insert comment-end)))))) |
| 1466 | |
| 1467 | (defun set-comment-column (arg) |
| 1468 | "Set the comment column based on point. |
| 1469 | With no arg, set the comment column to the current column. |
| 1470 | With just minus as arg, kill any comment on this line. |
| 1471 | With any other arg, set comment column to indentation of the previous comment |
| 1472 | and then align or create a comment on this line at that column." |
| 1473 | (interactive "P") |
| 1474 | (if (eq arg '-) |
| 1475 | (kill-comment nil) |
| 1476 | (if arg |
| 1477 | (progn |
| 1478 | (save-excursion |
| 1479 | (beginning-of-line) |
| 1480 | (re-search-backward comment-start-skip) |
| 1481 | (beginning-of-line) |
| 1482 | (re-search-forward comment-start-skip) |
| 1483 | (goto-char (match-beginning 0)) |
| 1484 | (setq comment-column (current-column)) |
| 1485 | (message "Comment column set to %d" comment-column)) |
| 1486 | (indent-for-comment)) |
| 1487 | (setq comment-column (current-column)) |
| 1488 | (message "Comment column set to %d" comment-column)))) |
| 1489 | |
| 1490 | (defun kill-comment (arg) |
| 1491 | "Kill the comment on this line, if any. |
| 1492 | With argument, kill comments on that many lines starting with this one." |
| 1493 | ;; this function loses in a lot of situations. it incorrectly recognises |
| 1494 | ;; comment delimiters sometimes (ergo, inside a string), doesn't work |
| 1495 | ;; with multi-line comments, can kill extra whitespace if comment wasn't |
| 1496 | ;; through end-of-line, et cetera. |
| 1497 | (interactive "P") |
| 1498 | (or comment-start-skip (error "No comment syntax defined")) |
| 1499 | (let ((count (prefix-numeric-value arg)) endc) |
| 1500 | (while (> count 0) |
| 1501 | (save-excursion |
| 1502 | (end-of-line) |
| 1503 | (setq endc (point)) |
| 1504 | (beginning-of-line) |
| 1505 | (and (string< "" comment-end) |
| 1506 | (setq endc |
| 1507 | (progn |
| 1508 | (re-search-forward (regexp-quote comment-end) endc 'move) |
| 1509 | (skip-chars-forward " \t") |
| 1510 | (point)))) |
| 1511 | (beginning-of-line) |
| 1512 | (if (re-search-forward comment-start-skip endc t) |
| 1513 | (progn |
| 1514 | (goto-char (match-beginning 0)) |
| 1515 | (skip-chars-backward " \t") |
| 1516 | (kill-region (point) endc) |
| 1517 | ;; to catch comments a line beginnings |
| 1518 | (indent-according-to-mode)))) |
| 1519 | (if arg (forward-line 1)) |
| 1520 | (setq count (1- count))))) |
| 1521 | |
| 1522 | (defun comment-region (beg end &optional arg) |
| 1523 | "Comment the region; third arg numeric means use ARG comment characters. |
| 1524 | If ARG is negative, delete that many comment characters instead. |
| 1525 | Comments are terminated on each line, even for syntax in which newline does |
| 1526 | not end the comment. Blank lines do not get comments." |
| 1527 | ;; if someone wants it to only put a comment-start at the beginning and |
| 1528 | ;; comment-end at the end then typing it, C-x C-x, closing it, C-x C-x |
| 1529 | ;; is easy enough. No option is made here for other than commenting |
| 1530 | ;; every line. |
| 1531 | (interactive "r\np") |
| 1532 | (or comment-start (error "No comment syntax is defined")) |
| 1533 | (if (> beg end) (let (mid) (setq mid beg beg end end mid))) |
| 1534 | (save-excursion |
| 1535 | (save-restriction |
| 1536 | (let ((cs comment-start) (ce comment-end)) |
| 1537 | (cond ((not arg) (setq arg 1)) |
| 1538 | ((> arg 1) |
| 1539 | (while (> (setq arg (1- arg)) 0) |
| 1540 | (setq cs (concat cs comment-start) |
| 1541 | ce (concat ce comment-end))))) |
| 1542 | (narrow-to-region beg end) |
| 1543 | (goto-char beg) |
| 1544 | (while (not (eobp)) |
| 1545 | (if (< arg 0) |
| 1546 | (let ((count arg)) |
| 1547 | (while (and (> 1 (setq count (1+ count))) |
| 1548 | (looking-at (regexp-quote cs))) |
| 1549 | (delete-char (length cs))) |
| 1550 | (if (string= "" ce) () |
| 1551 | (setq count arg) |
| 1552 | (while (> 1 (setq count (1+ count))) |
| 1553 | (end-of-line) |
| 1554 | ;; this is questionable if comment-end ends in whitespace |
| 1555 | ;; that is pretty brain-damaged though |
| 1556 | (skip-chars-backward " \t") |
| 1557 | (backward-char (length ce)) |
| 1558 | (if (looking-at (regexp-quote ce)) |
| 1559 | (delete-char (length ce))))) |
| 1560 | (forward-line 1)) |
| 1561 | (if (looking-at "[ \t]*$") () |
| 1562 | (insert cs) |
| 1563 | (if (string= "" ce) () |
| 1564 | (end-of-line) |
| 1565 | (insert ce))) |
| 1566 | (search-forward "\n" nil 'move))))))) |
| 1567 | \f |
| 1568 | (defun backward-word (arg) |
| 1569 | "Move backward until encountering the end of a word. |
| 1570 | With argument, do this that many times. |
| 1571 | In programs, it is faster to call `forward-word' with negative arg." |
| 1572 | (interactive "p") |
| 1573 | (forward-word (- arg))) |
| 1574 | |
| 1575 | (defun mark-word (arg) |
| 1576 | "Set mark arg words away from point." |
| 1577 | (interactive "p") |
| 1578 | (push-mark |
| 1579 | (save-excursion |
| 1580 | (forward-word arg) |
| 1581 | (point)))) |
| 1582 | |
| 1583 | (defun kill-word (arg) |
| 1584 | "Kill characters forward until encountering the end of a word. |
| 1585 | With argument, do this that many times." |
| 1586 | (interactive "p") |
| 1587 | (kill-region (point) (save-excursion (forward-word arg) (point)))) |
| 1588 | |
| 1589 | (defun backward-kill-word (arg) |
| 1590 | "Kill characters backward until encountering the end of a word. |
| 1591 | With argument, do this that many times." |
| 1592 | (interactive "p") |
| 1593 | (kill-word (- arg))) |
| 1594 | \f |
| 1595 | (defconst fill-prefix nil |
| 1596 | "*String for filling to insert at front of new line, or nil for none. |
| 1597 | Setting this variable automatically makes it local to the current buffer.") |
| 1598 | (make-variable-buffer-local 'fill-prefix) |
| 1599 | |
| 1600 | (defconst auto-fill-inhibit-regexp nil |
| 1601 | "*Regexp to match lines which should not be auto-filled.") |
| 1602 | |
| 1603 | (defun do-auto-fill () |
| 1604 | (let (give-up) |
| 1605 | (or (and auto-fill-inhibit-regexp |
| 1606 | (save-excursion (beginning-of-line) |
| 1607 | (looking-at auto-fill-inhibit-regexp))) |
| 1608 | (while (and (not give-up) (> (current-column) fill-column)) |
| 1609 | (let ((fill-point |
| 1610 | (let ((opoint (point))) |
| 1611 | (save-excursion |
| 1612 | (move-to-column (1+ fill-column)) |
| 1613 | (skip-chars-backward "^ \t\n") |
| 1614 | (if (bolp) |
| 1615 | (re-search-forward "[ \t]" opoint t)) |
| 1616 | (skip-chars-backward " \t") |
| 1617 | (point))))) |
| 1618 | ;; If there is a space on the line before fill-point, |
| 1619 | ;; and nonspaces precede it, break the line there. |
| 1620 | (if (save-excursion |
| 1621 | (goto-char fill-point) |
| 1622 | (not (bolp))) |
| 1623 | ;; If point is at the fill-point, do not `save-excursion'. |
| 1624 | ;; Otherwise, if a comment prefix or fill-prefix is inserted, |
| 1625 | ;; point will end up before it rather than after it. |
| 1626 | (if (save-excursion |
| 1627 | (skip-chars-backward " \t") |
| 1628 | (= (point) fill-point)) |
| 1629 | (indent-new-comment-line) |
| 1630 | (save-excursion |
| 1631 | (goto-char fill-point) |
| 1632 | (indent-new-comment-line))) |
| 1633 | ;; No place to break => stop trying. |
| 1634 | (setq give-up t))))))) |
| 1635 | |
| 1636 | (defconst comment-multi-line nil |
| 1637 | "*Non-nil means \\[indent-new-comment-line] should continue same comment |
| 1638 | on new line, with no new terminator or starter. |
| 1639 | This is obsolete because you might as well use \\[newline-and-indent].") |
| 1640 | |
| 1641 | (defun indent-new-comment-line () |
| 1642 | "Break line at point and indent, continuing comment if presently within one. |
| 1643 | The body of the continued comment is indented under the previous comment line. |
| 1644 | |
| 1645 | This command is intended for styles where you write a comment per line, |
| 1646 | starting a new comment (and terminating it if necessary) on each line. |
| 1647 | If you want to continue one comment across several lines, use \\[newline-and-indent]." |
| 1648 | (interactive "*") |
| 1649 | (let (comcol comstart) |
| 1650 | (skip-chars-backward " \t") |
| 1651 | (delete-region (point) |
| 1652 | (progn (skip-chars-forward " \t") |
| 1653 | (point))) |
| 1654 | (insert ?\n) |
| 1655 | (if (not comment-multi-line) |
| 1656 | (save-excursion |
| 1657 | (if (and comment-start-skip |
| 1658 | (let ((opoint (point))) |
| 1659 | (forward-line -1) |
| 1660 | (re-search-forward comment-start-skip opoint t))) |
| 1661 | ;; The old line is a comment. |
| 1662 | ;; Set WIN to the pos of the comment-start. |
| 1663 | ;; But if the comment is empty, look at preceding lines |
| 1664 | ;; to find one that has a nonempty comment. |
| 1665 | (let ((win (match-beginning 0))) |
| 1666 | (while (and (eolp) (not (bobp)) |
| 1667 | (let (opoint) |
| 1668 | (beginning-of-line) |
| 1669 | (setq opoint (point)) |
| 1670 | (forward-line -1) |
| 1671 | (re-search-forward comment-start-skip opoint t))) |
| 1672 | (setq win (match-beginning 0))) |
| 1673 | ;; Indent this line like what we found. |
| 1674 | (goto-char win) |
| 1675 | (setq comcol (current-column)) |
| 1676 | (setq comstart (buffer-substring (point) (match-end 0))))))) |
| 1677 | (if comcol |
| 1678 | (let ((comment-column comcol) |
| 1679 | (comment-start comstart) |
| 1680 | (comment-end comment-end)) |
| 1681 | (and comment-end (not (equal comment-end "")) |
| 1682 | ; (if (not comment-multi-line) |
| 1683 | (progn |
| 1684 | (forward-char -1) |
| 1685 | (insert comment-end) |
| 1686 | (forward-char 1)) |
| 1687 | ; (setq comment-column (+ comment-column (length comment-start)) |
| 1688 | ; comment-start "") |
| 1689 | ; ) |
| 1690 | ) |
| 1691 | (if (not (eolp)) |
| 1692 | (setq comment-end "")) |
| 1693 | (insert ?\n) |
| 1694 | (forward-char -1) |
| 1695 | (indent-for-comment) |
| 1696 | (save-excursion |
| 1697 | ;; Make sure we delete the newline inserted above. |
| 1698 | (end-of-line) |
| 1699 | (delete-char 1))) |
| 1700 | (if fill-prefix |
| 1701 | (insert fill-prefix) |
| 1702 | (indent-according-to-mode))))) |
| 1703 | |
| 1704 | (defun auto-fill-mode (&optional arg) |
| 1705 | "Toggle auto-fill mode. |
| 1706 | With arg, turn auto-fill mode on if and only if arg is positive. |
| 1707 | In auto-fill mode, inserting a space at a column beyond fill-column |
| 1708 | automatically breaks the line at a previous space." |
| 1709 | (interactive "P") |
| 1710 | (prog1 (setq auto-fill-function |
| 1711 | (if (if (null arg) |
| 1712 | (not auto-fill-function) |
| 1713 | (> (prefix-numeric-value arg) 0)) |
| 1714 | 'do-auto-fill |
| 1715 | nil)) |
| 1716 | ;; update mode-line |
| 1717 | (set-buffer-modified-p (buffer-modified-p)))) |
| 1718 | |
| 1719 | (defun turn-on-auto-fill () |
| 1720 | "Unconditionally turn on Auto Fill mode." |
| 1721 | (auto-fill-mode 1)) |
| 1722 | |
| 1723 | (defun set-fill-column (arg) |
| 1724 | "Set `fill-column' to current column, or to argument if given. |
| 1725 | The variable `fill-column' has a separate value for each buffer." |
| 1726 | (interactive "P") |
| 1727 | (setq fill-column (if (integerp arg) arg (current-column))) |
| 1728 | (message "fill-column set to %d" fill-column)) |
| 1729 | \f |
| 1730 | (defun set-selective-display (arg) |
| 1731 | "Set `selective-display' to ARG; clear it if no arg. |
| 1732 | When the value of `selective-display' is a number > 0, |
| 1733 | lines whose indentation is >= that value are not displayed. |
| 1734 | The variable `selective-display' has a separate value for each buffer." |
| 1735 | (interactive "P") |
| 1736 | (if (eq selective-display t) |
| 1737 | (error "selective-display already in use for marked lines")) |
| 1738 | (let ((current-vpos |
| 1739 | (save-restriction |
| 1740 | (narrow-to-region (point-min) (point)) |
| 1741 | (goto-char (window-start)) |
| 1742 | (vertical-motion (window-height))))) |
| 1743 | (setq selective-display |
| 1744 | (and arg (prefix-numeric-value arg))) |
| 1745 | (recenter current-vpos)) |
| 1746 | (set-window-start (selected-window) (window-start (selected-window))) |
| 1747 | (princ "selective-display set to " t) |
| 1748 | (prin1 selective-display t) |
| 1749 | (princ "." t)) |
| 1750 | |
| 1751 | (defun overwrite-mode (arg) |
| 1752 | "Toggle overwrite mode. |
| 1753 | With arg, turn overwrite mode on iff arg is positive. |
| 1754 | In overwrite mode, printing characters typed in replace existing text |
| 1755 | on a one-for-one basis, rather than pushing it to the right." |
| 1756 | (interactive "P") |
| 1757 | (setq overwrite-mode |
| 1758 | (if (null arg) (not overwrite-mode) |
| 1759 | (> (prefix-numeric-value arg) 0))) |
| 1760 | (set-buffer-modified-p (buffer-modified-p))) ;No-op, but updates mode line. |
| 1761 | \f |
| 1762 | (defvar blink-matching-paren t |
| 1763 | "*Non-nil means show matching open-paren when close-paren is inserted.") |
| 1764 | |
| 1765 | (defconst blink-matching-paren-distance 4000 |
| 1766 | "*If non-nil, is maximum distance to search for matching open-paren |
| 1767 | when close-paren is inserted.") |
| 1768 | |
| 1769 | (defun blink-matching-open () |
| 1770 | "Move cursor momentarily to the beginning of the sexp before point." |
| 1771 | (interactive) |
| 1772 | (and (> (point) (1+ (point-min))) |
| 1773 | (/= (char-syntax (char-after (- (point) 2))) ?\\ ) |
| 1774 | blink-matching-paren |
| 1775 | (let* ((oldpos (point)) |
| 1776 | (blinkpos) |
| 1777 | (mismatch)) |
| 1778 | (save-excursion |
| 1779 | (save-restriction |
| 1780 | (if blink-matching-paren-distance |
| 1781 | (narrow-to-region (max (point-min) |
| 1782 | (- (point) blink-matching-paren-distance)) |
| 1783 | oldpos)) |
| 1784 | (condition-case () |
| 1785 | (setq blinkpos (scan-sexps oldpos -1)) |
| 1786 | (error nil))) |
| 1787 | (and blinkpos (/= (char-syntax (char-after blinkpos)) |
| 1788 | ?\$) |
| 1789 | (setq mismatch |
| 1790 | (/= (char-after (1- oldpos)) |
| 1791 | (logand (lsh (aref (syntax-table) |
| 1792 | (char-after blinkpos)) |
| 1793 | -8) |
| 1794 | 255)))) |
| 1795 | (if mismatch (setq blinkpos nil)) |
| 1796 | (if blinkpos |
| 1797 | (progn |
| 1798 | (goto-char blinkpos) |
| 1799 | (if (pos-visible-in-window-p) |
| 1800 | (sit-for 1) |
| 1801 | (goto-char blinkpos) |
| 1802 | (message |
| 1803 | "Matches %s" |
| 1804 | (if (save-excursion |
| 1805 | (skip-chars-backward " \t") |
| 1806 | (not (bolp))) |
| 1807 | (buffer-substring (progn (beginning-of-line) (point)) |
| 1808 | (1+ blinkpos)) |
| 1809 | (buffer-substring blinkpos |
| 1810 | (progn |
| 1811 | (forward-char 1) |
| 1812 | (skip-chars-forward "\n \t") |
| 1813 | (end-of-line) |
| 1814 | (point))))))) |
| 1815 | (cond (mismatch |
| 1816 | (message "Mismatched parentheses")) |
| 1817 | ((not blink-matching-paren-distance) |
| 1818 | (message "Unmatched parenthesis")))))))) |
| 1819 | |
| 1820 | ;Turned off because it makes dbx bomb out. |
| 1821 | (setq blink-paren-function 'blink-matching-open) |
| 1822 | |
| 1823 | ; this is just something for the luser to see in a keymap -- this is not |
| 1824 | ; how quitting works normally! |
| 1825 | (defun keyboard-quit () |
| 1826 | "Signal a quit condition." |
| 1827 | (interactive) |
| 1828 | (signal 'quit nil)) |
| 1829 | |
| 1830 | (define-key global-map "\C-g" 'keyboard-quit) |
| 1831 | \f |
| 1832 | (defun set-variable (var val) |
| 1833 | "Set VARIABLE to VALUE. VALUE is a Lisp object. |
| 1834 | When using this interactively, supply a Lisp expression for VALUE. |
| 1835 | If you want VALUE to be a string, you must surround it with doublequotes. |
| 1836 | |
| 1837 | If VARIABLE has a `variable-interactive' property, that is used as if |
| 1838 | it were the arg to `interactive' (which see) to interactively read the value." |
| 1839 | (interactive |
| 1840 | (let* ((var (read-variable "Set variable: ")) |
| 1841 | (minibuffer-help-form |
| 1842 | '(funcall myhelp)) |
| 1843 | (myhelp |
| 1844 | (function |
| 1845 | (lambda () |
| 1846 | (with-output-to-temp-buffer "*Help*" |
| 1847 | (prin1 var) |
| 1848 | (princ "\nDocumentation:\n") |
| 1849 | (princ (substring (documentation-property var 'variable-documentation) |
| 1850 | 1)) |
| 1851 | (if (boundp var) |
| 1852 | (let ((print-length 20)) |
| 1853 | (princ "\n\nCurrent value: ") |
| 1854 | (prin1 (symbol-value var)))) |
| 1855 | nil))))) |
| 1856 | (list var |
| 1857 | (let ((prop (get var 'variable-interactive))) |
| 1858 | (if prop |
| 1859 | ;; Use VAR's `variable-interactive' property |
| 1860 | ;; as an interactive spec for prompting. |
| 1861 | (call-interactively (list 'lambda '(arg) |
| 1862 | (list 'interactive prop) |
| 1863 | 'arg)) |
| 1864 | (eval-minibuffer (format "Set %s to value: " var))))))) |
| 1865 | (set var val)) |
| 1866 | |
| 1867 | ;;; simple.el ends here |