| 1 | ;;; dired-x.el --- extra Dired functionality -*- lexical-binding:t -*- |
| 2 | |
| 3 | ;; Copyright (C) 1993-1994, 1997, 2001-2014 Free Software Foundation, |
| 4 | ;; Inc. |
| 5 | |
| 6 | ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de> |
| 7 | ;; Lawrence R. Dodd <dodd@roebling.poly.edu> |
| 8 | ;; Maintainer: Romain Francoise <rfrancoise@gnu.org> |
| 9 | ;; Keywords: dired extensions files |
| 10 | ;; Package: emacs |
| 11 | |
| 12 | ;; This file is part of GNU Emacs. |
| 13 | |
| 14 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 15 | ;; it under the terms of the GNU General Public License as published by |
| 16 | ;; the Free Software Foundation, either version 3 of the License, or |
| 17 | ;; (at your option) any later version. |
| 18 | |
| 19 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 20 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 21 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 22 | ;; GNU General Public License for more details. |
| 23 | |
| 24 | ;; You should have received a copy of the GNU General Public License |
| 25 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 26 | |
| 27 | ;;; Commentary: |
| 28 | |
| 29 | ;; This is based on Sebastian Kremer's excellent dired-x.el (Dired Extra), |
| 30 | ;; version 1.191, adapted for GNU Emacs. See the `dired-x' info pages. |
| 31 | |
| 32 | ;; USAGE: In your ~/.emacs, |
| 33 | ;; |
| 34 | ;; (add-hook 'dired-load-hook |
| 35 | ;; (lambda () |
| 36 | ;; (load "dired-x") |
| 37 | ;; ;; Set global variables here. For example: |
| 38 | ;; ;; (setq dired-guess-shell-gnutar "gtar") |
| 39 | ;; )) |
| 40 | ;; (add-hook 'dired-mode-hook |
| 41 | ;; (lambda () |
| 42 | ;; ;; Set buffer-local variables here. For example: |
| 43 | ;; ;; (dired-omit-mode 1) |
| 44 | ;; )) |
| 45 | ;; |
| 46 | ;; At load time dired-x.el will install itself and bind some dired keys. |
| 47 | ;; Some dired.el and dired-aux.el functions have extra features if |
| 48 | ;; dired-x is loaded. |
| 49 | |
| 50 | ;; User customization: M-x customize-group RET dired-x RET. |
| 51 | |
| 52 | ;; *Please* see the `dired-x' info pages for more details. |
| 53 | |
| 54 | \f |
| 55 | ;;; Code: |
| 56 | |
| 57 | ;; This is a no-op if dired-x is being loaded via `dired-load-hook', |
| 58 | ;; but maybe not if a dired-x function is being autoloaded. |
| 59 | (require 'dired) |
| 60 | |
| 61 | ;;; User-defined variables. |
| 62 | |
| 63 | (defgroup dired-x nil |
| 64 | "Extended directory editing (dired-x)." |
| 65 | :group 'dired) |
| 66 | |
| 67 | (defgroup dired-keys nil |
| 68 | "Dired keys customizations." |
| 69 | :prefix "dired-" |
| 70 | :group 'dired-x) |
| 71 | |
| 72 | (defcustom dired-bind-vm nil |
| 73 | "Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'. |
| 74 | RMAIL files in the old Babyl format (used before before Emacs 23.1) |
| 75 | contain \"-*- rmail -*-\" at the top, so `dired-find-file' |
| 76 | will run `rmail' on these files. New RMAIL files use the standard |
| 77 | mbox format, and so cannot be distinguished in this way." |
| 78 | :type 'boolean |
| 79 | :group 'dired-keys) |
| 80 | |
| 81 | (defcustom dired-bind-jump t |
| 82 | "Non-nil means bind `dired-jump' to C-x C-j, otherwise do not. |
| 83 | Setting this variable directly after dired-x is loaded has no effect - |
| 84 | use \\[customize]." |
| 85 | :type 'boolean |
| 86 | :set (lambda (sym val) |
| 87 | (if (set sym val) |
| 88 | (progn |
| 89 | (define-key ctl-x-map "\C-j" 'dired-jump) |
| 90 | (define-key ctl-x-4-map "\C-j" 'dired-jump-other-window)) |
| 91 | (if (eq 'dired-jump (lookup-key ctl-x-map "\C-j")) |
| 92 | (define-key ctl-x-map "\C-j" nil)) |
| 93 | (if (eq 'dired-jump-other-window (lookup-key ctl-x-4-map "\C-j")) |
| 94 | (define-key ctl-x-4-map "\C-j" nil)))) |
| 95 | :group 'dired-keys) |
| 96 | |
| 97 | (defcustom dired-bind-man t |
| 98 | "Non-nil means bind `dired-man' to \"N\" in Dired, otherwise do not. |
| 99 | Setting this variable directly after dired-x is loaded has no effect - |
| 100 | use \\[customize]." |
| 101 | :type 'boolean |
| 102 | :set (lambda (sym val) |
| 103 | (if (set sym val) |
| 104 | (define-key dired-mode-map "N" 'dired-man) |
| 105 | (if (eq 'dired-man (lookup-key dired-mode-map "N")) |
| 106 | (define-key dired-mode-map "N" nil)))) |
| 107 | :group 'dired-keys) |
| 108 | |
| 109 | (defcustom dired-bind-info t |
| 110 | "Non-nil means bind `dired-info' to \"I\" in Dired, otherwise do not. |
| 111 | Setting this variable directly after dired-x is loaded has no effect - |
| 112 | use \\[customize]." |
| 113 | :type 'boolean |
| 114 | :set (lambda (sym val) |
| 115 | (if (set sym val) |
| 116 | (define-key dired-mode-map "I" 'dired-info) |
| 117 | (if (eq 'dired-info (lookup-key dired-mode-map "I")) |
| 118 | (define-key dired-mode-map "I" nil)))) |
| 119 | :group 'dired-keys) |
| 120 | |
| 121 | (defcustom dired-vm-read-only-folders nil |
| 122 | "If non-nil, \\[dired-vm] will visit all folders read-only. |
| 123 | If neither nil nor t, e.g. the symbol `if-file-read-only', only |
| 124 | files not writable by you are visited read-only." |
| 125 | :type '(choice (const :tag "off" nil) |
| 126 | (const :tag "on" t) |
| 127 | (other :tag "non-writable only" if-file-read-only)) |
| 128 | :group 'dired-x) |
| 129 | |
| 130 | (defcustom dired-omit-size-limit 30000 |
| 131 | "Maximum size for the \"omitting\" feature. |
| 132 | If nil, there is no maximum size." |
| 133 | :type '(choice (const :tag "no maximum" nil) integer) |
| 134 | :group 'dired-x) |
| 135 | |
| 136 | ;; For backward compatibility |
| 137 | (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1") |
| 138 | (define-minor-mode dired-omit-mode |
| 139 | "Toggle omission of uninteresting files in Dired (Dired-Omit mode). |
| 140 | With a prefix argument ARG, enable Dired-Omit mode if ARG is |
| 141 | positive, and disable it otherwise. If called from Lisp, enable |
| 142 | the mode if ARG is omitted or nil. |
| 143 | |
| 144 | Dired-Omit mode is a buffer-local minor mode. When enabled in a |
| 145 | Dired buffer, Dired does not list files whose filenames match |
| 146 | regexp `dired-omit-files', nor files ending with extensions in |
| 147 | `dired-omit-extensions'. |
| 148 | |
| 149 | To enable omitting in every Dired buffer, you can put this in |
| 150 | your init file: |
| 151 | |
| 152 | (add-hook 'dired-mode-hook (lambda () (dired-omit-mode))) |
| 153 | |
| 154 | See Info node `(dired-x) Omitting Variables' for more information." |
| 155 | :group 'dired-x |
| 156 | (if dired-omit-mode |
| 157 | ;; This will mention how many lines were omitted: |
| 158 | (let ((dired-omit-size-limit nil)) (dired-omit-expunge)) |
| 159 | (revert-buffer))) |
| 160 | |
| 161 | (put 'dired-omit-mode 'safe-local-variable 'booleanp) |
| 162 | |
| 163 | (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$" |
| 164 | "Filenames matching this regexp will not be displayed. |
| 165 | This only has effect when `dired-omit-mode' is t. See interactive function |
| 166 | `dired-omit-mode' (\\[dired-omit-mode]) and variable |
| 167 | `dired-omit-extensions'. The default is to omit `.', `..', auto-save |
| 168 | files and lock files." |
| 169 | :type 'regexp |
| 170 | :group 'dired-x) |
| 171 | |
| 172 | (defcustom dired-omit-verbose t |
| 173 | "When non-nil, show messages when omitting files. |
| 174 | When nil, don't show messages." |
| 175 | :version "24.1" |
| 176 | :type 'boolean |
| 177 | :group 'dired-x) |
| 178 | |
| 179 | (defcustom dired-find-subdir nil ; t is pretty near to DWIM... |
| 180 | "If non-nil, Dired always finds a directory in a buffer of its own. |
| 181 | If nil, Dired finds the directory as a subdirectory in some other buffer |
| 182 | if it is present as one. |
| 183 | |
| 184 | If there are several Dired buffers for a directory, the most recently |
| 185 | used is chosen. |
| 186 | |
| 187 | Dired avoids switching to the current buffer, so that if you have |
| 188 | a normal and a wildcard buffer for the same directory, \\[dired] will |
| 189 | toggle between those two." |
| 190 | :type 'boolean |
| 191 | :group 'dired-x) |
| 192 | |
| 193 | (defcustom dired-enable-local-variables t |
| 194 | "Control use of local-variables lists in Dired. |
| 195 | This temporarily overrides the value of `enable-local-variables' when |
| 196 | listing a directory. See also `dired-local-variables-file'." |
| 197 | :risky t |
| 198 | :type '(choice (const :tag "Query Unsafe" t) |
| 199 | (const :tag "Safe Only" :safe) |
| 200 | (const :tag "Do all" :all) |
| 201 | (const :tag "Ignore" nil) |
| 202 | (other :tag "Query" other)) |
| 203 | :group 'dired-x) |
| 204 | |
| 205 | (make-obsolete-variable 'dired-enable-local-variables |
| 206 | "use a standard `dir-locals-file' instead." "24.1") |
| 207 | |
| 208 | (defcustom dired-guess-shell-gnutar |
| 209 | (catch 'found |
| 210 | (dolist (exe '("tar" "gtar")) |
| 211 | (if (with-temp-buffer |
| 212 | (ignore-errors (call-process exe nil t nil "--version")) |
| 213 | (and (re-search-backward "GNU tar" nil t) t)) |
| 214 | (throw 'found exe)))) |
| 215 | "If non-nil, name of GNU tar executable. |
| 216 | \(E.g., \"tar\" or \"gtar\"). The `z' switch will be used with it for |
| 217 | compressed or gzip'ed tar files. If you don't have GNU tar, set this |
| 218 | to nil: a pipe using `zcat' or `gunzip -c' will be used." |
| 219 | ;; Changed from system-type test to testing --version output. |
| 220 | ;; Maybe test --help for -z instead? |
| 221 | :version "24.1" |
| 222 | :type '(choice (const :tag "Not GNU tar" nil) |
| 223 | (string :tag "Command name")) |
| 224 | :group 'dired-x) |
| 225 | |
| 226 | (defcustom dired-guess-shell-gzip-quiet t |
| 227 | "Non-nil says pass -q to gzip overriding verbose GZIP environment." |
| 228 | :type 'boolean |
| 229 | :group 'dired-x) |
| 230 | |
| 231 | (defcustom dired-guess-shell-znew-switches nil |
| 232 | "If non-nil, then string of switches passed to `znew', example: \"-K\"." |
| 233 | :type '(choice (const :tag "None" nil) |
| 234 | (string :tag "Switches")) |
| 235 | :group 'dired-x) |
| 236 | |
| 237 | (defcustom dired-clean-up-buffers-too t |
| 238 | "Non-nil means offer to kill buffers visiting files and dirs deleted in Dired." |
| 239 | :type 'boolean |
| 240 | :group 'dired-x) |
| 241 | |
| 242 | ;;; KEY BINDINGS. |
| 243 | |
| 244 | (define-key dired-mode-map "\C-x\M-o" 'dired-omit-mode) |
| 245 | (define-key dired-mode-map "*O" 'dired-mark-omitted) |
| 246 | (define-key dired-mode-map "\M-(" 'dired-mark-sexp) |
| 247 | (define-key dired-mode-map "*(" 'dired-mark-sexp) |
| 248 | (define-key dired-mode-map "*." 'dired-mark-extension) |
| 249 | (define-key dired-mode-map "\M-!" 'dired-smart-shell-command) |
| 250 | (define-key dired-mode-map "\M-G" 'dired-goto-subdir) |
| 251 | (define-key dired-mode-map "F" 'dired-do-find-marked-files) |
| 252 | (define-key dired-mode-map "Y" 'dired-do-relsymlink) |
| 253 | (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp) |
| 254 | (define-key dired-mode-map "V" 'dired-do-run-mail) |
| 255 | |
| 256 | ;;; MENU BINDINGS |
| 257 | |
| 258 | (require 'easymenu) |
| 259 | |
| 260 | (let ((menu (lookup-key dired-mode-map [menu-bar]))) |
| 261 | (easy-menu-add-item menu '("Operate") |
| 262 | ["Find Files" dired-do-find-marked-files |
| 263 | :help "Find current or marked files"] |
| 264 | "Shell Command...") |
| 265 | (easy-menu-add-item menu '("Operate") |
| 266 | ["Relative Symlink to..." dired-do-relsymlink |
| 267 | :visible (fboundp 'make-symbolic-link) |
| 268 | :help "Make relative symbolic links for current or \ |
| 269 | marked files"] |
| 270 | "Hardlink to...") |
| 271 | (easy-menu-add-item menu '("Mark") |
| 272 | ["Flag Extension..." dired-flag-extension |
| 273 | :help "Flag files with a certain extension for deletion"] |
| 274 | "Mark Executables") |
| 275 | (easy-menu-add-item menu '("Mark") |
| 276 | ["Mark Extension..." dired-mark-extension |
| 277 | :help "Mark files with a certain extension"] |
| 278 | "Unmark All") |
| 279 | (easy-menu-add-item menu '("Mark") |
| 280 | ["Mark Omitted" dired-mark-omitted |
| 281 | :help "Mark files matching `dired-omit-files' \ |
| 282 | and `dired-omit-extensions'"] |
| 283 | "Unmark All") |
| 284 | (easy-menu-add-item menu '("Regexp") |
| 285 | ["Relative Symlink..." dired-do-relsymlink-regexp |
| 286 | :visible (fboundp 'make-symbolic-link) |
| 287 | :help "Make relative symbolic links for files \ |
| 288 | matching regexp"] |
| 289 | "Hardlink...") |
| 290 | (easy-menu-add-item menu '("Immediate") |
| 291 | ["Omit Mode" dired-omit-mode |
| 292 | :style toggle :selected dired-omit-mode |
| 293 | :help "Enable or disable omitting \"uninteresting\" \ |
| 294 | files"] |
| 295 | "Refresh")) |
| 296 | |
| 297 | \f |
| 298 | ;; Install into appropriate hooks. |
| 299 | |
| 300 | (add-hook 'dired-mode-hook 'dired-extra-startup) |
| 301 | (add-hook 'dired-after-readin-hook 'dired-omit-expunge) |
| 302 | |
| 303 | (defun dired-extra-startup () |
| 304 | "Automatically put on `dired-mode-hook' to get extra Dired features: |
| 305 | \\<dired-mode-map> |
| 306 | \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm') |
| 307 | \\[dired-info]\t-- run info on file |
| 308 | \\[dired-man]\t-- run man on file |
| 309 | \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously |
| 310 | \\[dired-omit-mode]\t-- toggle omitting of files |
| 311 | \\[dired-mark-sexp]\t-- mark by Lisp expression |
| 312 | |
| 313 | To see the options you can set, use M-x customize-group RET dired-x RET. |
| 314 | See also the functions: |
| 315 | `dired-flag-extension' |
| 316 | `dired-virtual' |
| 317 | `dired-jump' |
| 318 | `dired-man' |
| 319 | `dired-vm' |
| 320 | `dired-rmail' |
| 321 | `dired-info' |
| 322 | `dired-do-find-marked-files'" |
| 323 | (interactive) |
| 324 | ;; These must be done in each new dired buffer. |
| 325 | (dired-hack-local-variables) |
| 326 | (dired-omit-startup)) |
| 327 | |
| 328 | \f |
| 329 | ;;; EXTENSION MARKING FUNCTIONS. |
| 330 | |
| 331 | ;; Mark files with some extension. |
| 332 | (defun dired-mark-extension (extension &optional marker-char) |
| 333 | "Mark all files with a certain EXTENSION for use in later commands. |
| 334 | A `.' is *not* automatically prepended to the string entered. |
| 335 | EXTENSION may also be a list of extensions instead of a single one. |
| 336 | Optional MARKER-CHAR is marker to use." |
| 337 | (interactive "sMarking extension: \nP") |
| 338 | (or (listp extension) |
| 339 | (setq extension (list extension))) |
| 340 | (dired-mark-files-regexp |
| 341 | (concat ".";; don't match names with nothing but an extension |
| 342 | "\\(" |
| 343 | (mapconcat 'regexp-quote extension "\\|") |
| 344 | "\\)$") |
| 345 | marker-char)) |
| 346 | |
| 347 | (defun dired-flag-extension (extension) |
| 348 | "In Dired, flag all files with a certain EXTENSION for deletion. |
| 349 | A `.' is *not* automatically prepended to the string entered." |
| 350 | (interactive "sFlagging extension: ") |
| 351 | (dired-mark-extension extension dired-del-marker)) |
| 352 | |
| 353 | ;; Define some unpopular file extensions. Used for cleaning and omitting. |
| 354 | |
| 355 | (defvar dired-patch-unclean-extensions |
| 356 | '(".rej" ".orig") |
| 357 | "List of extensions of dispensable files created by the `patch' program.") |
| 358 | |
| 359 | (defvar dired-tex-unclean-extensions |
| 360 | '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions |
| 361 | "List of extensions of dispensable files created by TeX.") |
| 362 | |
| 363 | (defvar dired-latex-unclean-extensions |
| 364 | '(".idx" ".lof" ".lot" ".glo") |
| 365 | "List of extensions of dispensable files created by LaTeX.") |
| 366 | |
| 367 | (defvar dired-bibtex-unclean-extensions |
| 368 | '(".blg" ".bbl") |
| 369 | "List of extensions of dispensable files created by BibTeX.") |
| 370 | |
| 371 | (defvar dired-texinfo-unclean-extensions |
| 372 | '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs" |
| 373 | ".tp" ".tps" ".vr" ".vrs") |
| 374 | "List of extensions of dispensable files created by texinfo.") |
| 375 | |
| 376 | (defun dired-clean-patch () |
| 377 | "Flag dispensable files created by patch for deletion. |
| 378 | See variable `dired-patch-unclean-extensions'." |
| 379 | (interactive) |
| 380 | (dired-flag-extension dired-patch-unclean-extensions)) |
| 381 | |
| 382 | (defun dired-clean-tex () |
| 383 | "Flag dispensable files created by [La]TeX etc. for deletion. |
| 384 | See variables `dired-tex-unclean-extensions', |
| 385 | `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and |
| 386 | `dired-texinfo-unclean-extensions'." |
| 387 | (interactive) |
| 388 | (dired-flag-extension (append dired-texinfo-unclean-extensions |
| 389 | dired-latex-unclean-extensions |
| 390 | dired-bibtex-unclean-extensions |
| 391 | dired-tex-unclean-extensions))) |
| 392 | |
| 393 | (defun dired-very-clean-tex () |
| 394 | "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion. |
| 395 | See variables `dired-texinfo-unclean-extensions', |
| 396 | `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and |
| 397 | `dired-texinfo-unclean-extensions'." |
| 398 | (interactive) |
| 399 | (dired-flag-extension (append dired-texinfo-unclean-extensions |
| 400 | dired-latex-unclean-extensions |
| 401 | dired-bibtex-unclean-extensions |
| 402 | dired-tex-unclean-extensions |
| 403 | (list ".dvi")))) |
| 404 | \f |
| 405 | ;;; JUMP. |
| 406 | |
| 407 | ;;;###autoload |
| 408 | (defun dired-jump (&optional other-window file-name) |
| 409 | "Jump to Dired buffer corresponding to current buffer. |
| 410 | If in a file, Dired the current directory and move to file's line. |
| 411 | If in Dired already, pop up a level and goto old directory's line. |
| 412 | In case the proper Dired file line cannot be found, refresh the dired |
| 413 | buffer and try again. |
| 414 | When OTHER-WINDOW is non-nil, jump to Dired buffer in other window. |
| 415 | Interactively with prefix argument, read FILE-NAME and |
| 416 | move to its line in dired." |
| 417 | (interactive |
| 418 | (list nil (and current-prefix-arg |
| 419 | (read-file-name "Jump to Dired file: ")))) |
| 420 | (let* ((file (or file-name buffer-file-name)) |
| 421 | (dir (if file (file-name-directory file) default-directory))) |
| 422 | (if (and (eq major-mode 'dired-mode) (null file-name)) |
| 423 | (progn |
| 424 | (setq dir (dired-current-directory)) |
| 425 | (dired-up-directory other-window) |
| 426 | (unless (dired-goto-file dir) |
| 427 | ;; refresh and try again |
| 428 | (dired-insert-subdir (file-name-directory dir)) |
| 429 | (dired-goto-file dir))) |
| 430 | (if other-window |
| 431 | (dired-other-window dir) |
| 432 | (dired dir)) |
| 433 | (if file |
| 434 | (or (dired-goto-file file) |
| 435 | ;; refresh and try again |
| 436 | (progn |
| 437 | (dired-insert-subdir (file-name-directory file)) |
| 438 | (dired-goto-file file)) |
| 439 | ;; Toggle omitting, if it is on, and try again. |
| 440 | (when dired-omit-mode |
| 441 | (dired-omit-mode) |
| 442 | (dired-goto-file file))))))) |
| 443 | |
| 444 | ;;;###autoload |
| 445 | (defun dired-jump-other-window (&optional file-name) |
| 446 | "Like \\[dired-jump] (`dired-jump') but in other window." |
| 447 | (interactive |
| 448 | (list (and current-prefix-arg |
| 449 | (read-file-name "Jump to Dired file: ")))) |
| 450 | (dired-jump t file-name)) |
| 451 | \f |
| 452 | ;;; OMITTING. |
| 453 | |
| 454 | ;; Enhanced omitting of lines from directory listings. |
| 455 | ;; Marked files are never omitted. |
| 456 | |
| 457 | ;; should probably get rid of this and always use 'no-dir. |
| 458 | ;; sk 28-Aug-1991 09:37 |
| 459 | (defvar dired-omit-localp 'no-dir |
| 460 | "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'. |
| 461 | If it is `no-dir', omitting is much faster, but you can only match |
| 462 | against the non-directory part of the file name. Set it to nil if you |
| 463 | need to match the entire file name.") |
| 464 | |
| 465 | ;; \017=^O for Omit - other packages can chose other control characters. |
| 466 | (defvar dired-omit-marker-char ?\017 |
| 467 | "Temporary marker used by Dired-Omit. |
| 468 | Should never be used as marker by the user or other packages.") |
| 469 | |
| 470 | (defun dired-omit-startup () |
| 471 | (or (assq 'dired-omit-mode minor-mode-alist) |
| 472 | (setq minor-mode-alist |
| 473 | (append '((dired-omit-mode |
| 474 | (:eval (if (eq major-mode 'dired-mode) |
| 475 | " Omit" "")))) |
| 476 | minor-mode-alist)))) |
| 477 | |
| 478 | (defun dired-mark-omitted () |
| 479 | "Mark files matching `dired-omit-files' and `dired-omit-extensions'." |
| 480 | (interactive) |
| 481 | (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files |
| 482 | (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp)) |
| 483 | |
| 484 | (defcustom dired-omit-extensions |
| 485 | (append completion-ignored-extensions |
| 486 | dired-latex-unclean-extensions |
| 487 | dired-bibtex-unclean-extensions |
| 488 | dired-texinfo-unclean-extensions) |
| 489 | "If non-nil, a list of extensions (strings) to omit from Dired listings. |
| 490 | Defaults to elements of `completion-ignored-extensions', |
| 491 | `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and |
| 492 | `dired-texinfo-unclean-extensions'. |
| 493 | |
| 494 | See interactive function `dired-omit-mode' (\\[dired-omit-mode]) and |
| 495 | variables `dired-omit-mode' and `dired-omit-files'." |
| 496 | :type '(repeat string) |
| 497 | :group 'dired-x) |
| 498 | |
| 499 | (defun dired-omit-expunge (&optional regexp) |
| 500 | "Erases all unmarked files matching REGEXP. |
| 501 | Does nothing if global variable `dired-omit-mode' is nil, or if called |
| 502 | non-interactively and buffer is bigger than `dired-omit-size-limit'. |
| 503 | If REGEXP is nil or not specified, uses `dired-omit-files', and also omits |
| 504 | filenames ending in `dired-omit-extensions'. |
| 505 | If REGEXP is the empty string, this function is a no-op. |
| 506 | |
| 507 | This functions works by temporarily binding `dired-marker-char' to |
| 508 | `dired-omit-marker-char' and calling `dired-do-kill-lines'." |
| 509 | (interactive "sOmit files (regexp): ") |
| 510 | (if (and dired-omit-mode |
| 511 | (or (called-interactively-p 'interactive) |
| 512 | (not dired-omit-size-limit) |
| 513 | (< (buffer-size) dired-omit-size-limit) |
| 514 | (progn |
| 515 | (when dired-omit-verbose |
| 516 | (message "Not omitting: directory larger than %d characters." |
| 517 | dired-omit-size-limit)) |
| 518 | (setq dired-omit-mode nil) |
| 519 | nil))) |
| 520 | (let ((omit-re (or regexp (dired-omit-regexp))) |
| 521 | (old-modified-p (buffer-modified-p)) |
| 522 | count) |
| 523 | (or (string= omit-re "") |
| 524 | (let ((dired-marker-char dired-omit-marker-char)) |
| 525 | (when dired-omit-verbose (message "Omitting...")) |
| 526 | (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp) |
| 527 | (progn |
| 528 | (setq count (dired-do-kill-lines |
| 529 | nil |
| 530 | (if dired-omit-verbose "Omitted %d line%s." ""))) |
| 531 | (force-mode-line-update)) |
| 532 | (when dired-omit-verbose (message "(Nothing to omit)"))))) |
| 533 | ;; Try to preserve modified state of buffer. So `%*' doesn't appear |
| 534 | ;; in mode-line of omitted buffers. |
| 535 | (set-buffer-modified-p (and old-modified-p |
| 536 | (save-excursion |
| 537 | (goto-char (point-min)) |
| 538 | (re-search-forward dired-re-mark nil t)))) |
| 539 | count))) |
| 540 | |
| 541 | (defun dired-omit-regexp () |
| 542 | (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "") |
| 543 | (if (and dired-omit-files dired-omit-extensions) "\\|" "") |
| 544 | (if dired-omit-extensions |
| 545 | (concat ".";; a non-extension part should exist |
| 546 | "\\(" |
| 547 | (mapconcat 'regexp-quote dired-omit-extensions "\\|") |
| 548 | "\\)$") |
| 549 | ""))) |
| 550 | |
| 551 | ;; Returns t if any work was done, nil otherwise. |
| 552 | (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp) |
| 553 | "Mark unmarked files matching REGEXP, displaying MSG. |
| 554 | REGEXP is matched against the entire file name. When called |
| 555 | interactively, prompt for REGEXP. |
| 556 | With prefix argument, unflag all those files. |
| 557 | Optional fourth argument LOCALP is as in `dired-get-filename'." |
| 558 | (interactive |
| 559 | (list (dired-read-regexp |
| 560 | "Mark unmarked files matching regexp (default all): ") |
| 561 | nil current-prefix-arg nil)) |
| 562 | (let ((dired-marker-char (if unflag-p ?\s dired-marker-char))) |
| 563 | (dired-mark-if |
| 564 | (and |
| 565 | ;; not already marked |
| 566 | (looking-at-p " ") |
| 567 | ;; uninteresting |
| 568 | (let ((fn (dired-get-filename localp t))) |
| 569 | (and fn (string-match-p regexp fn)))) |
| 570 | msg))) |
| 571 | |
| 572 | \f |
| 573 | ;;; VIRTUAL DIRED MODE. |
| 574 | |
| 575 | ;; For browsing `ls -lR' listings in a dired-like fashion. |
| 576 | |
| 577 | (defalias 'virtual-dired 'dired-virtual) |
| 578 | (defun dired-virtual (dirname &optional switches) |
| 579 | "Put this buffer into Virtual Dired mode. |
| 580 | |
| 581 | In Virtual Dired mode, all commands that do not actually consult the |
| 582 | filesystem will work. |
| 583 | |
| 584 | This is useful if you want to peruse and move around in an ls -lR |
| 585 | output file, for example one you got from an ftp server. With |
| 586 | ange-ftp, you can even Dired a directory containing an ls-lR file, |
| 587 | visit that file and turn on Virtual Dired mode. But don't try to save |
| 588 | this file, as dired-virtual indents the listing and thus changes the |
| 589 | buffer. |
| 590 | |
| 591 | If you have save a Dired buffer in a file you can use \\[dired-virtual] to |
| 592 | resume it in a later session. |
| 593 | |
| 594 | Type \\<dired-mode-map>\\[revert-buffer] \ |
| 595 | in the Virtual Dired buffer and answer `y' to convert |
| 596 | the virtual to a real Dired buffer again. You don't have to do this, though: |
| 597 | you can relist single subdirs using \\[dired-do-redisplay]." |
| 598 | |
| 599 | ;; DIRNAME is the top level directory of the buffer. It will become |
| 600 | ;; its `default-directory'. If nil, the old value of |
| 601 | ;; default-directory is used. |
| 602 | |
| 603 | ;; Optional SWITCHES are the ls switches to use. |
| 604 | |
| 605 | ;; Shell wildcards will be used if there already is a `wildcard' |
| 606 | ;; line in the buffer (thus it is a saved Dired buffer), but there |
| 607 | ;; is no other way to get wildcards. Insert a `wildcard' line by |
| 608 | ;; hand if you want them. |
| 609 | |
| 610 | (interactive |
| 611 | (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir)))) |
| 612 | (goto-char (point-min)) |
| 613 | (or (looking-at-p " ") |
| 614 | ;; if not already indented, do it now: |
| 615 | (indent-region (point-min) (point-max) 2)) |
| 616 | (or dirname (setq dirname default-directory)) |
| 617 | (setq dirname (expand-file-name (file-name-as-directory dirname))) |
| 618 | (setq default-directory dirname) ; contains no wildcards |
| 619 | (let ((wildcard (save-excursion |
| 620 | (goto-char (point-min)) |
| 621 | (forward-line 1) |
| 622 | (and (looking-at "^ wildcard ") |
| 623 | (buffer-substring (match-end 0) |
| 624 | (line-end-position)))))) |
| 625 | (if wildcard |
| 626 | (setq dirname (expand-file-name wildcard default-directory)))) |
| 627 | ;; If raw ls listing (not a saved old dired buffer), give it a |
| 628 | ;; decent subdir headerline: |
| 629 | (goto-char (point-min)) |
| 630 | (or (looking-at-p dired-subdir-regexp) |
| 631 | (insert " " |
| 632 | (directory-file-name (file-name-directory default-directory)) |
| 633 | ":\n")) |
| 634 | (dired-mode dirname (or switches dired-listing-switches)) |
| 635 | (setq mode-name "Virtual Dired" |
| 636 | revert-buffer-function 'dired-virtual-revert) |
| 637 | (set (make-local-variable 'dired-subdir-alist) nil) |
| 638 | (dired-build-subdir-alist) |
| 639 | (goto-char (point-min)) |
| 640 | (dired-initial-position dirname)) |
| 641 | |
| 642 | (defun dired-virtual-guess-dir () |
| 643 | "Guess and return appropriate working directory of this buffer. |
| 644 | The buffer is assumed to be in Dired or ls -lR format. The guess is |
| 645 | based upon buffer contents. If nothing could be guessed, returns |
| 646 | nil." |
| 647 | |
| 648 | (let ((regexp "^\\( \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]") |
| 649 | (subexpr 2)) |
| 650 | (goto-char (point-min)) |
| 651 | (cond ((looking-at regexp) |
| 652 | ;; If a saved dired buffer, look to which dir and |
| 653 | ;; perhaps wildcard it belongs: |
| 654 | (let ((dir (buffer-substring (match-beginning subexpr) |
| 655 | (match-end subexpr)))) |
| 656 | (file-name-as-directory dir))) |
| 657 | ;; Else no match for headerline found. It's a raw ls listing. |
| 658 | ;; In raw ls listings the directory does not have a headerline |
| 659 | ;; try parent of first subdir, if any |
| 660 | ((re-search-forward regexp nil t) |
| 661 | (file-name-directory |
| 662 | (directory-file-name |
| 663 | (file-name-as-directory |
| 664 | (buffer-substring (match-beginning subexpr) |
| 665 | (match-end subexpr)))))) |
| 666 | (t ; if all else fails |
| 667 | nil)))) |
| 668 | |
| 669 | |
| 670 | (defun dired-virtual-revert (&optional _arg _noconfirm) |
| 671 | (if (not |
| 672 | (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? ")) |
| 673 | (error "Cannot revert a Virtual Dired buffer") |
| 674 | (setq mode-name "Dired" |
| 675 | revert-buffer-function 'dired-revert) |
| 676 | (revert-buffer))) |
| 677 | |
| 678 | ;; A zero-arg version of dired-virtual. |
| 679 | (defun dired-virtual-mode () |
| 680 | "Put current buffer into Virtual Dired mode (see `dired-virtual'). |
| 681 | Useful on `magic-mode-alist' with the regexp |
| 682 | |
| 683 | \"^ \\\\(/[^ /]+\\\\)+/?:$\" |
| 684 | |
| 685 | to put saved Dired buffers automatically into Virtual Dired mode. |
| 686 | |
| 687 | Also useful for `auto-mode-alist' like this: |
| 688 | |
| 689 | (add-to-list 'auto-mode-alist |
| 690 | '(\"[^/]\\\\.dired\\\\'\" . dired-virtual-mode))" |
| 691 | (interactive) |
| 692 | (dired-virtual (dired-virtual-guess-dir))) |
| 693 | |
| 694 | \f |
| 695 | ;;; SMART SHELL. |
| 696 | |
| 697 | ;; An Emacs buffer can have but one working directory, stored in the |
| 698 | ;; buffer-local variable `default-directory'. A Dired buffer may have |
| 699 | ;; several subdirectories inserted, but still has but one working directory: |
| 700 | ;; that of the top level Dired directory in that buffer. For some commands |
| 701 | ;; it is appropriate that they use the current Dired directory instead of |
| 702 | ;; `default-directory', e.g., `find-file' and `compile'. This is a general |
| 703 | ;; mechanism is provided for special handling of the working directory in |
| 704 | ;; special major modes. |
| 705 | |
| 706 | (define-obsolete-variable-alias 'default-directory-alist |
| 707 | 'dired-default-directory-alist "24.1") |
| 708 | |
| 709 | ;; It's easier to add to this alist than redefine function |
| 710 | ;; default-directory while keeping the old information. |
| 711 | (defconst dired-default-directory-alist |
| 712 | '((dired-mode . (if (fboundp 'dired-current-directory) |
| 713 | (dired-current-directory) |
| 714 | default-directory))) |
| 715 | "Alist of major modes and their opinion on `default-directory'. |
| 716 | Each element has the form (MAJOR . EXPRESSION). |
| 717 | The function `dired-default-directory' evaluates EXPRESSION to |
| 718 | determine a default directory.") |
| 719 | |
| 720 | (put 'dired-default-directory-alist 'risky-local-variable t) ; gets eval'd |
| 721 | (make-obsolete-variable 'dired-default-directory-alist |
| 722 | "this feature is due to be removed." "24.1") |
| 723 | |
| 724 | (defun dired-default-directory () |
| 725 | "Return the `dired-default-directory-alist' entry for the current major-mode. |
| 726 | If none, return `default-directory'." |
| 727 | ;; It looks like this was intended to be something of a "general" |
| 728 | ;; feature, but it only ever seems to have been used in |
| 729 | ;; dired-smart-shell-command, and doesn't seem worth keeping around. |
| 730 | (declare (obsolete nil "24.1")) |
| 731 | (or (eval (cdr (assq major-mode dired-default-directory-alist))) |
| 732 | default-directory)) |
| 733 | |
| 734 | (defun dired-smart-shell-command (command &optional output-buffer error-buffer) |
| 735 | "Like function `shell-command', but in the current Virtual Dired directory." |
| 736 | (interactive |
| 737 | (list |
| 738 | (read-shell-command "Shell command: " nil nil |
| 739 | (cond |
| 740 | (buffer-file-name (file-relative-name buffer-file-name)) |
| 741 | ((eq major-mode 'dired-mode) (dired-get-filename t t)))) |
| 742 | current-prefix-arg |
| 743 | shell-command-default-error-buffer)) |
| 744 | (let ((default-directory (or (and (eq major-mode 'dired-mode) |
| 745 | (dired-current-directory)) |
| 746 | default-directory))) |
| 747 | (shell-command command output-buffer error-buffer))) |
| 748 | |
| 749 | \f |
| 750 | ;;; LOCAL VARIABLES FOR DIRED BUFFERS. |
| 751 | |
| 752 | ;; Brief Description (This feature is obsolete as of Emacs 24.1) |
| 753 | ;; |
| 754 | ;; * `dired-extra-startup' is part of the `dired-mode-hook'. |
| 755 | ;; |
| 756 | ;; * `dired-extra-startup' calls `dired-hack-local-variables' |
| 757 | ;; |
| 758 | ;; * `dired-hack-local-variables' checks the value of |
| 759 | ;; `dired-local-variables-file' |
| 760 | ;; |
| 761 | ;; * Check if `dired-local-variables-file' is a non-nil string and is a |
| 762 | ;; filename found in the directory of the Dired Buffer being created. |
| 763 | ;; |
| 764 | ;; * If `dired-local-variables-file' satisfies the above, then temporarily |
| 765 | ;; include it in the Dired Buffer at the bottom. |
| 766 | ;; |
| 767 | ;; * Set `enable-local-variables' temporarily to the user variable |
| 768 | ;; `dired-enable-local-variables' and run `hack-local-variables' on the |
| 769 | ;; Dired Buffer. |
| 770 | |
| 771 | (defcustom dired-local-variables-file (convert-standard-filename ".dired") |
| 772 | "Filename, as string, containing local Dired buffer variables to be hacked. |
| 773 | If this file found in current directory, then it will be inserted into dired |
| 774 | buffer and `hack-local-variables' will be run. See Info node |
| 775 | `(emacs)File Variables' for more information on local variables. |
| 776 | See also `dired-enable-local-variables'." |
| 777 | :type 'file |
| 778 | :group 'dired) |
| 779 | |
| 780 | (make-obsolete-variable 'dired-local-variables-file 'dir-locals-file "24.1") |
| 781 | |
| 782 | (defun dired-hack-local-variables () |
| 783 | "Evaluate local variables in `dired-local-variables-file' for Dired buffer." |
| 784 | (declare (obsolete hack-dir-local-variables-non-file-buffer "24.1")) |
| 785 | (and (stringp dired-local-variables-file) |
| 786 | (file-exists-p dired-local-variables-file) |
| 787 | (let ((opoint (point-max)) |
| 788 | (inhibit-read-only t) |
| 789 | ;; In case user has `enable-local-variables' set to nil we |
| 790 | ;; override it locally with dired's variable. |
| 791 | (enable-local-variables dired-enable-local-variables)) |
| 792 | ;; Insert 'em. |
| 793 | (save-excursion |
| 794 | (goto-char opoint) |
| 795 | (insert "\^L\n") |
| 796 | (insert-file-contents dired-local-variables-file)) |
| 797 | ;; Hack 'em. |
| 798 | (unwind-protect |
| 799 | (let ((buffer-file-name dired-local-variables-file)) |
| 800 | (hack-local-variables)) |
| 801 | ;; Delete this stuff: `eobp' is used to find last subdir by dired.el. |
| 802 | (delete-region opoint (point-max))) |
| 803 | ;; Make sure that the mode line shows the proper information. |
| 804 | (dired-sort-set-mode-line)))) |
| 805 | |
| 806 | ;; Does not seem worth a dedicated command. |
| 807 | ;; See the more general features in files-x.el. |
| 808 | (defun dired-omit-here-always () |
| 809 | "Create `dir-locals-file' setting `dired-omit-mode' to t in `dired-mode'. |
| 810 | If in a Dired buffer, reverts it." |
| 811 | (declare (obsolete add-dir-local-variable "24.1")) |
| 812 | (interactive) |
| 813 | (if (file-exists-p dired-local-variables-file) |
| 814 | (error "Old-style dired-local-variables-file `./%s' found; |
| 815 | replace it with a dir-locals-file `./%s'" |
| 816 | dired-local-variables-file |
| 817 | dir-locals-file)) |
| 818 | (if (file-exists-p dir-locals-file) |
| 819 | (message "File `./%s' already exists." dir-locals-file) |
| 820 | (with-temp-buffer |
| 821 | (insert "\ |
| 822 | \((dired-mode . ((subdirs . nil) |
| 823 | (dired-omit-mode . t))))\n") |
| 824 | (write-file dir-locals-file)) |
| 825 | ;; Run extra-hooks and revert directory. |
| 826 | (when (derived-mode-p 'dired-mode) |
| 827 | (hack-dir-local-variables-non-file-buffer) |
| 828 | (dired-extra-startup) |
| 829 | (dired-revert)))) |
| 830 | |
| 831 | \f |
| 832 | ;;; GUESS SHELL COMMAND. |
| 833 | |
| 834 | ;; Brief Description: |
| 835 | ;;; |
| 836 | ;; * `dired-do-shell-command' is bound to `!' by dired.el. |
| 837 | ;;; |
| 838 | ;; * `dired-guess-shell-command' provides smarter defaults for |
| 839 | ;;; dired-aux.el's `dired-read-shell-command'. |
| 840 | ;;; |
| 841 | ;; * `dired-guess-shell-command' calls `dired-guess-default' with list of |
| 842 | ;;; marked files. |
| 843 | ;;; |
| 844 | ;; * Parse `dired-guess-shell-alist-user' and |
| 845 | ;;; `dired-guess-shell-alist-default' (in that order) for the first REGEXP |
| 846 | ;;; that matches the first file in the file list. |
| 847 | ;;; |
| 848 | ;; * If the REGEXP matches all the entries of the file list then evaluate |
| 849 | ;;; COMMAND, which is either a string or a Lisp expression returning a |
| 850 | ;;; string. COMMAND may be a list of commands. |
| 851 | ;;; |
| 852 | ;; * Return this command to `dired-guess-shell-command' which prompts user |
| 853 | ;;; with it. The list of commands is put into the list of default values. |
| 854 | ;;; If a command is used successfully then it is stored permanently in |
| 855 | ;;; `dired-shell-command-history'. |
| 856 | |
| 857 | ;; Guess what shell command to apply to a file. |
| 858 | (defvar dired-shell-command-history nil |
| 859 | "History list for commands that read dired-shell commands.") |
| 860 | |
| 861 | ;; Default list of shell commands. |
| 862 | |
| 863 | ;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files. Some do not |
| 864 | ;; install GNU zip's version of zcat. |
| 865 | |
| 866 | (autoload 'Man-support-local-filenames "man") |
| 867 | |
| 868 | (defvar dired-guess-shell-alist-default |
| 869 | (list |
| 870 | (list "\\.tar\\'" |
| 871 | '(if dired-guess-shell-gnutar |
| 872 | (concat dired-guess-shell-gnutar " xvf") |
| 873 | "tar xvf") |
| 874 | ;; Extract files into a separate subdirectory |
| 875 | '(if dired-guess-shell-gnutar |
| 876 | (concat "mkdir " (file-name-sans-extension file) |
| 877 | "; " dired-guess-shell-gnutar " -C " |
| 878 | (file-name-sans-extension file) " -xvf") |
| 879 | (concat "mkdir " (file-name-sans-extension file) |
| 880 | "; tar -C " (file-name-sans-extension file) " -xvf")) |
| 881 | ;; List archive contents. |
| 882 | '(if dired-guess-shell-gnutar |
| 883 | (concat dired-guess-shell-gnutar " tvf") |
| 884 | "tar tvf")) |
| 885 | |
| 886 | ;; REGEXPS for compressed archives must come before the .Z rule to |
| 887 | ;; be recognized: |
| 888 | (list "\\.tar\\.Z\\'" |
| 889 | ;; Untar it. |
| 890 | '(if dired-guess-shell-gnutar |
| 891 | (concat dired-guess-shell-gnutar " zxvf") |
| 892 | (concat "zcat * | tar xvf -")) |
| 893 | ;; Optional conversion to gzip format. |
| 894 | '(concat "znew" (if dired-guess-shell-gzip-quiet " -q") |
| 895 | " " dired-guess-shell-znew-switches)) |
| 896 | |
| 897 | ;; gzip'ed archives |
| 898 | (list "\\.t\\(ar\\.\\)?gz\\'" |
| 899 | '(if dired-guess-shell-gnutar |
| 900 | (concat dired-guess-shell-gnutar " zxvf") |
| 901 | (concat "gunzip -qc * | tar xvf -")) |
| 902 | ;; Extract files into a separate subdirectory |
| 903 | '(if dired-guess-shell-gnutar |
| 904 | (concat "mkdir " (file-name-sans-extension file) |
| 905 | "; " dired-guess-shell-gnutar " -C " |
| 906 | (file-name-sans-extension file) " -zxvf") |
| 907 | (concat "mkdir " (file-name-sans-extension file) |
| 908 | "; gunzip -qc * | tar -C " |
| 909 | (file-name-sans-extension file) " -xvf -")) |
| 910 | ;; Optional decompression. |
| 911 | '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" "")) |
| 912 | ;; List archive contents. |
| 913 | '(if dired-guess-shell-gnutar |
| 914 | (concat dired-guess-shell-gnutar " ztvf") |
| 915 | (concat "gunzip -qc * | tar tvf -"))) |
| 916 | |
| 917 | ;; bzip2'ed archives |
| 918 | (list "\\.t\\(ar\\.bz2\\|bz\\)\\'" |
| 919 | "bunzip2 -c * | tar xvf -" |
| 920 | ;; Extract files into a separate subdirectory |
| 921 | '(concat "mkdir " (file-name-sans-extension file) |
| 922 | "; bunzip2 -c * | tar -C " |
| 923 | (file-name-sans-extension file) " -xvf -") |
| 924 | ;; Optional decompression. |
| 925 | "bunzip2") |
| 926 | |
| 927 | ;; xz'ed archives |
| 928 | (list "\\.t\\(ar\\.\\)?xz\\'" |
| 929 | "unxz -c * | tar xvf -" |
| 930 | ;; Extract files into a separate subdirectory |
| 931 | '(concat "mkdir " (file-name-sans-extension file) |
| 932 | "; unxz -c * | tar -C " |
| 933 | (file-name-sans-extension file) " -xvf -") |
| 934 | ;; Optional decompression. |
| 935 | "unxz") |
| 936 | |
| 937 | '("\\.shar\\.Z\\'" "zcat * | unshar") |
| 938 | '("\\.shar\\.g?z\\'" "gunzip -qc * | unshar") |
| 939 | |
| 940 | '("\\.e?ps\\'" "ghostview" "xloadimage" "lpr") |
| 941 | (list "\\.e?ps\\.g?z\\'" "gunzip -qc * | ghostview -" |
| 942 | ;; Optional decompression. |
| 943 | '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q"))) |
| 944 | (list "\\.e?ps\\.Z\\'" "zcat * | ghostview -" |
| 945 | ;; Optional conversion to gzip format. |
| 946 | '(concat "znew" (if dired-guess-shell-gzip-quiet " -q") |
| 947 | " " dired-guess-shell-znew-switches)) |
| 948 | |
| 949 | '("\\.patch\\'" "cat * | patch") |
| 950 | (list "\\.patch\\.g?z\\'" "gunzip -qc * | patch" |
| 951 | ;; Optional decompression. |
| 952 | '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q"))) |
| 953 | (list "\\.patch\\.Z\\'" "zcat * | patch" |
| 954 | ;; Optional conversion to gzip format. |
| 955 | '(concat "znew" (if dired-guess-shell-gzip-quiet " -q") |
| 956 | " " dired-guess-shell-znew-switches)) |
| 957 | |
| 958 | ;; The following four extensions are useful with dired-man ("N" key) |
| 959 | ;; FIXME "man ./" does not work with dired-do-shell-command, |
| 960 | ;; because there seems to be no way for us to modify the filename, |
| 961 | ;; only the command. Hmph. `dired-man' works though. |
| 962 | (list "\\.\\(?:[0-9]\\|man\\)\\'" |
| 963 | '(let ((loc (Man-support-local-filenames))) |
| 964 | (cond ((eq loc 'man-db) "man -l") |
| 965 | ((eq loc 'man) "man ./") |
| 966 | (t |
| 967 | "cat * | tbl | nroff -man -h | col -b")))) |
| 968 | (list "\\.\\(?:[0-9]\\|man\\)\\.g?z\\'" |
| 969 | '(let ((loc (Man-support-local-filenames))) |
| 970 | (cond ((eq loc 'man-db) |
| 971 | "man -l") |
| 972 | ((eq loc 'man) |
| 973 | "man ./") |
| 974 | (t "gunzip -qc * | tbl | nroff -man -h | col -b"))) |
| 975 | ;; Optional decompression. |
| 976 | '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q"))) |
| 977 | (list "\\.[0-9]\\.Z\\'" |
| 978 | '(let ((loc (Man-support-local-filenames))) |
| 979 | (cond ((eq loc 'man-db) "man -l") |
| 980 | ((eq loc 'man) "man ./") |
| 981 | (t "zcat * | tbl | nroff -man -h | col -b"))) |
| 982 | ;; Optional conversion to gzip format. |
| 983 | '(concat "znew" (if dired-guess-shell-gzip-quiet " -q") |
| 984 | " " dired-guess-shell-znew-switches)) |
| 985 | '("\\.pod\\'" "perldoc" "pod2man * | nroff -man") |
| 986 | |
| 987 | '("\\.dvi\\'" "xdvi" "dvips") ; preview and printing |
| 988 | '("\\.au\\'" "play") ; play Sun audiofiles |
| 989 | '("\\.mpe?g\\'\\|\\.avi\\'" "xine -p") |
| 990 | '("\\.ogg\\'" "ogg123") |
| 991 | '("\\.mp3\\'" "mpg123") |
| 992 | '("\\.wav\\'" "play") |
| 993 | '("\\.uu\\'" "uudecode") ; for uudecoded files |
| 994 | '("\\.hqx\\'" "mcvert") |
| 995 | '("\\.sh\\'" "sh") ; execute shell scripts |
| 996 | '("\\.xbm\\'" "bitmap") ; view X11 bitmaps |
| 997 | '("\\.gp\\'" "gnuplot") |
| 998 | '("\\.p[bgpn]m\\'" "xloadimage") |
| 999 | '("\\.gif\\'" "xloadimage") ; view gif pictures |
| 1000 | '("\\.tif\\'" "xloadimage") |
| 1001 | '("\\.png\\'" "display") ; xloadimage 4.1 doesn't grok PNG |
| 1002 | '("\\.jpe?g\\'" "xloadimage") |
| 1003 | '("\\.fig\\'" "xfig") ; edit fig pictures |
| 1004 | '("\\.out\\'" "xgraph") ; for plotting purposes. |
| 1005 | '("\\.tex\\'" "latex" "tex") |
| 1006 | '("\\.texi\\(nfo\\)?\\'" "makeinfo" "texi2dvi") |
| 1007 | '("\\.pdf\\'" "xpdf") |
| 1008 | '("\\.doc\\'" "antiword" "strings") |
| 1009 | '("\\.rpm\\'" "rpm -qilp" "rpm -ivh") |
| 1010 | '("\\.dia\\'" "dia") |
| 1011 | '("\\.mgp\\'" "mgp") |
| 1012 | |
| 1013 | ;; Some other popular archivers. |
| 1014 | (list "\\.zip\\'" "unzip" "unzip -l" |
| 1015 | ;; Extract files into a separate subdirectory |
| 1016 | '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q") |
| 1017 | " -d " (file-name-sans-extension file))) |
| 1018 | '("\\.zoo\\'" "zoo x//") |
| 1019 | '("\\.lzh\\'" "lharc x") |
| 1020 | '("\\.arc\\'" "arc x") |
| 1021 | '("\\.shar\\'" "unshar") |
| 1022 | '("\\.rar\\'" "unrar x") |
| 1023 | '("\\.7z\\'" "7z x") |
| 1024 | |
| 1025 | ;; Compression. |
| 1026 | (list "\\.g?z\\'" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q"))) |
| 1027 | (list "\\.dz\\'" "dictunzip") |
| 1028 | (list "\\.bz2\\'" "bunzip2") |
| 1029 | (list "\\.xz\\'" "unxz") |
| 1030 | (list "\\.Z\\'" "uncompress" |
| 1031 | ;; Optional conversion to gzip format. |
| 1032 | '(concat "znew" (if dired-guess-shell-gzip-quiet " -q") |
| 1033 | " " dired-guess-shell-znew-switches)) |
| 1034 | |
| 1035 | '("\\.sign?\\'" "gpg --verify")) |
| 1036 | |
| 1037 | "Default alist used for shell command guessing. |
| 1038 | See `dired-guess-shell-alist-user'.") |
| 1039 | |
| 1040 | (defcustom dired-guess-shell-alist-user nil |
| 1041 | "User-defined alist of rules for suggested commands. |
| 1042 | These rules take precedence over the predefined rules in the variable |
| 1043 | `dired-guess-shell-alist-default' (to which they are prepended). |
| 1044 | |
| 1045 | Each element of this list looks like |
| 1046 | |
| 1047 | (REGEXP COMMAND...) |
| 1048 | |
| 1049 | where each COMMAND can either be a string or a Lisp expression that evaluates |
| 1050 | to a string. This expression can access the file name as the variable `file'. |
| 1051 | If several COMMANDs are given, the first one will be the default |
| 1052 | and the rest will be added temporarily to the history and can be retrieved |
| 1053 | with \\[previous-history-element] (M-p) . |
| 1054 | |
| 1055 | The variable `dired-guess-shell-case-fold-search' controls whether |
| 1056 | REGEXP is matched case-sensitively. |
| 1057 | |
| 1058 | You can set this variable in your ~/.emacs. For example, to add rules for |
| 1059 | `.foo' and `.bar' files, write |
| 1060 | |
| 1061 | (setq dired-guess-shell-alist-user |
| 1062 | '((\"\\\\.foo\\\\'\" \"FOO-COMMAND\") |
| 1063 | (\"\\\\.bar\\\\'\" |
| 1064 | (if condition |
| 1065 | \"BAR-COMMAND-1\" |
| 1066 | \"BAR-COMMAND-2\"))))" |
| 1067 | :group 'dired-x |
| 1068 | :type '(alist :key-type regexp :value-type (repeat sexp))) |
| 1069 | |
| 1070 | (defcustom dired-guess-shell-case-fold-search t |
| 1071 | "If non-nil, `dired-guess-shell-alist-default' and |
| 1072 | `dired-guess-shell-alist-user' are matched case-insensitively." |
| 1073 | :group 'dired-x |
| 1074 | :type 'boolean) |
| 1075 | |
| 1076 | (defun dired-guess-default (files) |
| 1077 | "Return a shell command, or a list of commands, appropriate for FILES. |
| 1078 | See `dired-guess-shell-alist-user'." |
| 1079 | |
| 1080 | (let* ((case-fold-search dired-guess-shell-case-fold-search) |
| 1081 | ;; Prepend the user's alist to the default alist. |
| 1082 | (alist (append dired-guess-shell-alist-user |
| 1083 | dired-guess-shell-alist-default)) |
| 1084 | (file (car files)) |
| 1085 | (flist (cdr files)) |
| 1086 | elt regexp cmds) |
| 1087 | |
| 1088 | ;; Find the first match in the alist for first file in FILES. |
| 1089 | (while alist |
| 1090 | (setq elt (car alist) |
| 1091 | regexp (car elt) |
| 1092 | alist (cdr alist)) |
| 1093 | (if (string-match-p regexp file) |
| 1094 | (setq cmds (cdr elt) |
| 1095 | alist nil))) |
| 1096 | |
| 1097 | ;; If more than one file, see if all of FILES match regular expression. |
| 1098 | (while (and flist |
| 1099 | (string-match-p regexp (car flist))) |
| 1100 | (setq flist (cdr flist))) |
| 1101 | |
| 1102 | ;; If flist is still non-nil, then do not guess since this means that not |
| 1103 | ;; all the files in FILES were matched by the regexp. |
| 1104 | (setq cmds (and (not flist) cmds)) |
| 1105 | |
| 1106 | ;; Return commands or nil if flist is still non-nil. |
| 1107 | ;; Evaluate the commands in order that any logical testing will be done. |
| 1108 | (if (cdr cmds) |
| 1109 | (delete-dups (mapcar (lambda (cmd) (eval cmd `((file . ,file)))) cmds)) |
| 1110 | (eval (car cmds) `((file . ,file)))))) ; single command |
| 1111 | |
| 1112 | (defun dired-guess-shell-command (prompt files) |
| 1113 | "Ask user with PROMPT for a shell command, guessing a default from FILES." |
| 1114 | (let ((default (dired-guess-default files)) |
| 1115 | default-list val) |
| 1116 | (if (null default) |
| 1117 | ;; Nothing to guess |
| 1118 | (read-shell-command prompt nil 'dired-shell-command-history) |
| 1119 | (setq prompt (replace-regexp-in-string ": $" " " prompt)) |
| 1120 | (if (listp default) |
| 1121 | ;; More than one guess |
| 1122 | (setq default-list default |
| 1123 | default (car default) |
| 1124 | prompt (concat |
| 1125 | prompt |
| 1126 | (format "{%d guesses} " (length default-list)))) |
| 1127 | ;; Just one guess |
| 1128 | (setq default-list (list default))) |
| 1129 | ;; Put the first guess in the prompt but not in the initial value. |
| 1130 | (setq prompt (concat prompt (format "[%s]: " default))) |
| 1131 | ;; All guesses can be retrieved with M-n |
| 1132 | (setq val (read-shell-command prompt nil |
| 1133 | 'dired-shell-command-history |
| 1134 | default-list)) |
| 1135 | ;; If we got a return, then return default. |
| 1136 | (if (equal val "") default val)))) |
| 1137 | |
| 1138 | \f |
| 1139 | ;;; RELATIVE SYMBOLIC LINKS. |
| 1140 | |
| 1141 | (declare-function make-symbolic-link "fileio.c") |
| 1142 | |
| 1143 | (defvar dired-keep-marker-relsymlink ?S |
| 1144 | "See variable `dired-keep-marker-move'.") |
| 1145 | |
| 1146 | (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists) |
| 1147 | "Make a symbolic link (pointing to FILE1) in FILE2. |
| 1148 | The link is relative (if possible), for example |
| 1149 | |
| 1150 | \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\" |
| 1151 | |
| 1152 | results in |
| 1153 | |
| 1154 | \"../../tex/bin/foo\" \"/vol/local/bin/foo\"" |
| 1155 | (interactive "FRelSymLink: \nFRelSymLink %s: \np") |
| 1156 | (let (name1 name2 len1 len2 (index 0) sub) |
| 1157 | (setq file1 (expand-file-name file1) |
| 1158 | file2 (expand-file-name file2) |
| 1159 | len1 (length file1) |
| 1160 | len2 (length file2)) |
| 1161 | ;; Find common initial file name components: |
| 1162 | (let (next) |
| 1163 | (while (and (setq next (string-match "/" file1 index)) |
| 1164 | (< (setq next (1+ next)) (min len1 len2)) |
| 1165 | ;; For the comparison, both substrings must end in |
| 1166 | ;; `/', so NEXT is *one plus* the result of the |
| 1167 | ;; string-match. |
| 1168 | ;; E.g., consider the case of linking "/tmp/a/abc" |
| 1169 | ;; to "/tmp/abc" erroneously giving "/tmp/a" instead |
| 1170 | ;; of "/tmp/" as common initial component |
| 1171 | (string-equal (substring file1 0 next) |
| 1172 | (substring file2 0 next))) |
| 1173 | (setq index next)) |
| 1174 | (setq name2 file2 |
| 1175 | sub (substring file1 0 index) |
| 1176 | name1 (substring file1 index))) |
| 1177 | (if (string-equal sub "/") |
| 1178 | ;; No common initial file name found |
| 1179 | (setq name1 file1) |
| 1180 | ;; Else they have a common parent directory |
| 1181 | (let ((tem (substring file2 index)) |
| 1182 | (start 0) |
| 1183 | (count 0)) |
| 1184 | ;; Count number of slashes we must compensate for ... |
| 1185 | (while (setq start (string-match "/" tem start)) |
| 1186 | (setq count (1+ count) |
| 1187 | start (1+ start))) |
| 1188 | ;; ... and prepend a "../" for each slash found: |
| 1189 | (dotimes (_ count) |
| 1190 | (setq name1 (concat "../" name1))))) |
| 1191 | (make-symbolic-link |
| 1192 | (directory-file-name name1) ; must not link to foo/ |
| 1193 | ; (trailing slash!) |
| 1194 | name2 ok-if-already-exists))) |
| 1195 | |
| 1196 | (autoload 'dired-do-create-files "dired-aux") |
| 1197 | |
| 1198 | ;;;###autoload |
| 1199 | (defun dired-do-relsymlink (&optional arg) |
| 1200 | "Relative symlink all marked (or next ARG) files into a directory. |
| 1201 | Otherwise make a relative symbolic link to the current file. |
| 1202 | This creates relative symbolic links like |
| 1203 | |
| 1204 | foo -> ../bar/foo |
| 1205 | |
| 1206 | not absolute ones like |
| 1207 | |
| 1208 | foo -> /ugly/file/name/that/may/change/any/day/bar/foo |
| 1209 | |
| 1210 | For absolute symlinks, use \\[dired-do-symlink]." |
| 1211 | (interactive "P") |
| 1212 | (dired-do-create-files 'relsymlink #'dired-make-relative-symlink |
| 1213 | "RelSymLink" arg dired-keep-marker-relsymlink)) |
| 1214 | |
| 1215 | (autoload 'dired-mark-read-regexp "dired-aux") |
| 1216 | (autoload 'dired-do-create-files-regexp "dired-aux") |
| 1217 | |
| 1218 | (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name) |
| 1219 | "RelSymlink all marked files containing REGEXP to NEWNAME. |
| 1220 | See functions `dired-do-rename-regexp' and `dired-do-relsymlink' |
| 1221 | for more info." |
| 1222 | (interactive (dired-mark-read-regexp "RelSymLink")) |
| 1223 | (dired-do-create-files-regexp |
| 1224 | #'dired-make-relative-symlink |
| 1225 | "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink)) |
| 1226 | |
| 1227 | \f |
| 1228 | ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY. |
| 1229 | |
| 1230 | ;; Brief Description: |
| 1231 | ;;; |
| 1232 | ;; `dired-do-find-marked-files' is bound to `F' by dired-x.el. |
| 1233 | ;;; |
| 1234 | ;; * Use `dired-get-marked-files' to collect the marked files in the current |
| 1235 | ;;; Dired Buffer into a list of filenames `FILE-LIST'. |
| 1236 | ;;; |
| 1237 | ;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with |
| 1238 | ;;; `dired-do-find-marked-files''s prefix argument NOSELECT. |
| 1239 | ;;; |
| 1240 | ;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the |
| 1241 | ;;; list each time. |
| 1242 | ;;; |
| 1243 | ;; * If NOSELECT is non-nil then just run `find-file-noselect' on each |
| 1244 | ;;; element of FILE-LIST. |
| 1245 | ;;; |
| 1246 | ;; * If NOSELECT is nil then calculate the `size' of the window for each file |
| 1247 | ;;; by dividing the `window-height' by length of FILE-LIST. Thus, `size' is |
| 1248 | ;;; cognizant of the window-configuration. |
| 1249 | ;;; |
| 1250 | ;; * If `size' is too small abort, otherwise run `find-file' on each element |
| 1251 | ;;; of FILE-LIST giving each a window of height `size'. |
| 1252 | |
| 1253 | (defun dired-do-find-marked-files (&optional noselect) |
| 1254 | "Find all marked files displaying all of them simultaneously. |
| 1255 | With optional NOSELECT just find files but do not select them. |
| 1256 | |
| 1257 | The current window is split across all files marked, as evenly as possible. |
| 1258 | Remaining lines go to bottom-most window. The number of files that can be |
| 1259 | displayed this way is restricted by the height of the current window and |
| 1260 | `window-min-height'. |
| 1261 | |
| 1262 | To keep Dired buffer displayed, type \\[split-window-below] first. |
| 1263 | To display just marked files, type \\[delete-other-windows] first." |
| 1264 | (interactive "P") |
| 1265 | (dired-simultaneous-find-file (dired-get-marked-files) noselect)) |
| 1266 | |
| 1267 | (defun dired-simultaneous-find-file (file-list noselect) |
| 1268 | "Visit all files in FILE-LIST and display them simultaneously. |
| 1269 | The current window is split across all files in FILE-LIST, as evenly as |
| 1270 | possible. Remaining lines go to the bottom-most window. The number of |
| 1271 | files that can be displayed this way is restricted by the height of the |
| 1272 | current window and the variable `window-min-height'. With non-nil |
| 1273 | NOSELECT the files are merely found but not selected." |
| 1274 | ;; We don't make this function interactive because it is usually too clumsy |
| 1275 | ;; to specify FILE-LIST interactively unless via dired. |
| 1276 | (let (size) |
| 1277 | (if noselect |
| 1278 | ;; Do not select the buffer. |
| 1279 | (find-file-noselect (car file-list)) |
| 1280 | ;; We will have to select the buffer. Calculate and check window size. |
| 1281 | (setq size (/ (window-height) (length file-list))) |
| 1282 | (or (<= window-min-height size) |
| 1283 | (error "Too many files to visit simultaneously. Try C-u prefix")) |
| 1284 | (find-file (car file-list))) |
| 1285 | ;; Decrement. |
| 1286 | (dolist (file (cdr file-list)) |
| 1287 | (if noselect |
| 1288 | ;; Do not select the buffer. |
| 1289 | (find-file-noselect file) |
| 1290 | ;; Vertically split off a window of desired size. Upper window will |
| 1291 | ;; have SIZE lines. Select lower (larger) window. We split it again. |
| 1292 | (select-window (split-window nil size)) |
| 1293 | (find-file file))))) |
| 1294 | |
| 1295 | \f |
| 1296 | ;;; MISCELLANEOUS COMMANDS. |
| 1297 | |
| 1298 | ;; Run man on files. |
| 1299 | |
| 1300 | (declare-function Man-getpage-in-background "man" (topic)) |
| 1301 | |
| 1302 | (defvar manual-program) ; from man.el |
| 1303 | |
| 1304 | (defun dired-man () |
| 1305 | "Run `man' on this file." |
| 1306 | ;; Used also to say: "Display old buffer if buffer name matches filename." |
| 1307 | ;; but I have no idea what that means. |
| 1308 | (interactive) |
| 1309 | (require 'man) |
| 1310 | (let* ((file (dired-get-filename)) |
| 1311 | (manual-program (replace-regexp-in-string "\\*" "%s" |
| 1312 | (dired-guess-shell-command |
| 1313 | "Man command: " (list file))))) |
| 1314 | (Man-getpage-in-background file))) |
| 1315 | |
| 1316 | ;; Run Info on files. |
| 1317 | |
| 1318 | (defun dired-info () |
| 1319 | "Run `info' on this file." |
| 1320 | (interactive) |
| 1321 | (info (dired-get-filename))) |
| 1322 | |
| 1323 | ;; Run mail on mail folders. |
| 1324 | |
| 1325 | (declare-function vm-visit-folder "ext:vm" (folder &optional read-only)) |
| 1326 | (defvar vm-folder-directory) |
| 1327 | |
| 1328 | (defun dired-vm (&optional read-only) |
| 1329 | "Run VM on this file. |
| 1330 | With optional prefix argument, visits the folder read-only. |
| 1331 | Otherwise obeys the value of `dired-vm-read-only-folders'." |
| 1332 | (interactive "P") |
| 1333 | (let ((dir (dired-current-directory)) |
| 1334 | (fil (dired-get-filename))) |
| 1335 | (vm-visit-folder fil (or read-only |
| 1336 | (eq t dired-vm-read-only-folders) |
| 1337 | (and dired-vm-read-only-folders |
| 1338 | (not (file-writable-p fil))))) |
| 1339 | ;; So that pressing `v' inside VM does prompt within current directory: |
| 1340 | (set (make-local-variable 'vm-folder-directory) dir))) |
| 1341 | |
| 1342 | (defun dired-rmail () |
| 1343 | "Run RMAIL on this file." |
| 1344 | (interactive) |
| 1345 | (rmail (dired-get-filename))) |
| 1346 | |
| 1347 | (defun dired-do-run-mail () |
| 1348 | "Visit the current file as a mailbox, using VM or RMAIL. |
| 1349 | Prompt for confirmation first; if the user says yes, call |
| 1350 | `dired-vm' if `dired-bind-vm' is non-nil, `dired-rmail' |
| 1351 | otherwise." |
| 1352 | (interactive) |
| 1353 | (let ((file (dired-get-filename t))) |
| 1354 | (if dired-bind-vm |
| 1355 | (if (y-or-n-p (concat "Visit `" file |
| 1356 | "' as a mail folder with VM?")) |
| 1357 | (dired-vm)) |
| 1358 | ;; Read mail folder using rmail. |
| 1359 | (if (y-or-n-p (concat "Visit `" file |
| 1360 | "' as a mailbox with RMAIL?")) |
| 1361 | (dired-rmail))))) |
| 1362 | |
| 1363 | \f |
| 1364 | ;;; MISCELLANEOUS INTERNAL FUNCTIONS. |
| 1365 | |
| 1366 | ;; This should be a builtin |
| 1367 | (defun dired-buffer-more-recently-used-p (buffer1 buffer2) |
| 1368 | "Return t if BUFFER1 is more recently used than BUFFER2. |
| 1369 | Considers buffers closer to the car of `buffer-list' to be more recent." |
| 1370 | (and (not (equal buffer1 buffer2)) |
| 1371 | (memq buffer1 (buffer-list)) |
| 1372 | (not (memq buffer1 (memq buffer2 (buffer-list)))))) |
| 1373 | |
| 1374 | ;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93 |
| 1375 | ;; (defun dired-buffers-for-dir-exact (dir) |
| 1376 | ;; ;; Return a list of buffers that dired DIR (a directory or wildcard) |
| 1377 | ;; ;; at top level, or as subdirectory. |
| 1378 | ;; ;; Top level matches must match the wildcard part too, if any. |
| 1379 | ;; ;; The list is in reverse order of buffer creation, most recent last. |
| 1380 | ;; ;; As a side effect, killed dired buffers for DIR are removed from |
| 1381 | ;; ;; dired-buffers. |
| 1382 | ;; (let ((alist dired-buffers) result elt) |
| 1383 | ;; (while alist |
| 1384 | ;; (setq elt (car alist) |
| 1385 | ;; alist (cdr alist)) |
| 1386 | ;; (let ((buf (cdr elt))) |
| 1387 | ;; (if (buffer-name buf) |
| 1388 | ;; ;; Top level must match exactly against dired-directory in |
| 1389 | ;; ;; case one of them is a wildcard. |
| 1390 | ;; (if (or (equal dir (with-current-buffer buf dired-directory)) |
| 1391 | ;; (assoc dir (with-current-buffer buf dired-subdir-alist))) |
| 1392 | ;; (setq result (cons buf result))) |
| 1393 | ;; ;; else buffer is killed - clean up: |
| 1394 | ;; (setq dired-buffers (delq elt dired-buffers))))) |
| 1395 | ;; result)) |
| 1396 | |
| 1397 | \f |
| 1398 | ;; Does anyone use this? - lrd 6/29/93. |
| 1399 | ;; Apparently people do use it. - lrd 12/22/97. |
| 1400 | |
| 1401 | (defun dired-mark-sexp (predicate &optional unflag-p) |
| 1402 | "Mark files for which PREDICATE returns non-nil. |
| 1403 | With a prefix arg, unmark or unflag those files instead. |
| 1404 | |
| 1405 | PREDICATE is a lisp expression that can refer to the following symbols: |
| 1406 | |
| 1407 | inode [integer] the inode of the file (only for ls -i output) |
| 1408 | s [integer] the size of the file for ls -s output |
| 1409 | (usually in blocks or, with -k, in KByte) |
| 1410 | mode [string] file permission bits, e.g. \"-rw-r--r--\" |
| 1411 | nlink [integer] number of links to file |
| 1412 | uid [string] owner |
| 1413 | gid [string] group (If the gid is not displayed by ls, |
| 1414 | this will still be set (to the same as uid)) |
| 1415 | size [integer] file size in bytes |
| 1416 | time [string] the time that ls displays, e.g. \"Feb 12 14:17\" |
| 1417 | name [string] the name of the file |
| 1418 | sym [string] if file is a symbolic link, the linked-to name, else \"\" |
| 1419 | |
| 1420 | For example, use |
| 1421 | |
| 1422 | (equal 0 size) |
| 1423 | |
| 1424 | to mark all zero length files." |
| 1425 | ;; Using sym="" instead of nil avoids the trap of |
| 1426 | ;; (string-match "foo" sym) into which a user would soon fall. |
| 1427 | ;; Give `equal' instead of `=' in the example, as this works on |
| 1428 | ;; integers and strings. |
| 1429 | (interactive "xMark if (lisp expr): \nP") |
| 1430 | (message "%s" predicate) |
| 1431 | (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char)) |
| 1432 | inode s mode nlink uid gid size time name sym) |
| 1433 | (dired-mark-if |
| 1434 | (save-excursion |
| 1435 | (and |
| 1436 | ;; Sets vars |
| 1437 | ;; inode s mode nlink uid gid size time name sym |
| 1438 | |
| 1439 | ;; according to current file line. Returns t for success, nil if |
| 1440 | ;; there is no file line. Upon success, all variables are set, either |
| 1441 | ;; to nil or the appropriate value, so they need not be initialized. |
| 1442 | ;; Moves point within the current line. |
| 1443 | (dired-move-to-filename) |
| 1444 | (let (pos |
| 1445 | (mode-len 10) ; length of mode string |
| 1446 | ;; like in dired.el, but with subexpressions \1=inode, \2=s: |
| 1447 | (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?")) |
| 1448 | (beginning-of-line) |
| 1449 | (forward-char 2) |
| 1450 | (if (looking-at dired-re-inode-size) |
| 1451 | (progn |
| 1452 | (goto-char (match-end 0)) |
| 1453 | (setq inode (string-to-number |
| 1454 | (buffer-substring (match-beginning 1) |
| 1455 | (match-end 1))) |
| 1456 | s (string-to-number |
| 1457 | (buffer-substring (match-beginning 2) |
| 1458 | (match-end 2))))) |
| 1459 | (setq inode nil |
| 1460 | s nil)) |
| 1461 | (setq mode (buffer-substring (point) (+ mode-len (point)))) |
| 1462 | (forward-char mode-len) |
| 1463 | ;; Skip any extended attributes marker ("." or "+"). |
| 1464 | (or (looking-at " ") |
| 1465 | (forward-char 1)) |
| 1466 | (setq nlink (read (current-buffer))) |
| 1467 | ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid. |
| 1468 | (setq uid (buffer-substring (1+ (point)) |
| 1469 | (progn (forward-word 1) (point)))) |
| 1470 | (re-search-forward directory-listing-before-filename-regexp) |
| 1471 | (goto-char (match-beginning 1)) |
| 1472 | (forward-char -1) |
| 1473 | (setq size (string-to-number |
| 1474 | (buffer-substring (save-excursion |
| 1475 | (backward-word 1) |
| 1476 | (setq pos (point))) |
| 1477 | (point)))) |
| 1478 | (goto-char pos) |
| 1479 | (backward-word 1) |
| 1480 | ;; if no gid is displayed, gid will be set to uid |
| 1481 | ;; but user will then not reference it anyway in PREDICATE. |
| 1482 | (setq gid (buffer-substring (save-excursion |
| 1483 | (forward-word 1) (point)) |
| 1484 | (point)) |
| 1485 | time (buffer-substring (match-beginning 1) |
| 1486 | (1- (dired-move-to-filename))) |
| 1487 | name (buffer-substring (point) |
| 1488 | (or |
| 1489 | (dired-move-to-end-of-filename t) |
| 1490 | (point))) |
| 1491 | sym (if (looking-at-p " -> ") |
| 1492 | (buffer-substring (progn (forward-char 4) (point)) |
| 1493 | (line-end-position)) |
| 1494 | "")) |
| 1495 | t) |
| 1496 | (eval predicate |
| 1497 | `((inode . ,inode) |
| 1498 | (s . ,s) |
| 1499 | (mode . ,mode) |
| 1500 | (nlink . ,nlink) |
| 1501 | (uid . ,uid) |
| 1502 | (gid . ,gid) |
| 1503 | (size . ,size) |
| 1504 | (time . ,time) |
| 1505 | (name . ,name) |
| 1506 | (sym . ,sym))))) |
| 1507 | (format "'%s file" predicate)))) |
| 1508 | |
| 1509 | \f |
| 1510 | ;;; FIND FILE AT POINT. |
| 1511 | |
| 1512 | (defcustom dired-x-hands-off-my-keys t |
| 1513 | "Non-nil means don't remap `find-file' to `dired-x-find-file'. |
| 1514 | Similarly for `find-file-other-window' and `dired-x-find-file-other-window'. |
| 1515 | If you change this variable without using \\[customize] after `dired-x.el' |
| 1516 | is loaded then call \\[dired-x-bind-find-file]." |
| 1517 | :type 'boolean |
| 1518 | :initialize 'custom-initialize-default |
| 1519 | :set (lambda (symbol value) |
| 1520 | (set symbol value) |
| 1521 | (dired-x-bind-find-file)) |
| 1522 | :group 'dired-x) |
| 1523 | |
| 1524 | (defun dired-x-bind-find-file () |
| 1525 | "Bind `dired-x-find-file' in place of `find-file' (or vice-versa). |
| 1526 | Similarly for `dired-x-find-file-other-window' and `find-file-other-window'. |
| 1527 | Binding direction based on `dired-x-hands-off-my-keys'." |
| 1528 | (interactive) |
| 1529 | (if (called-interactively-p 'interactive) |
| 1530 | (setq dired-x-hands-off-my-keys |
| 1531 | (not (y-or-n-p "Bind dired-x-find-file over find-file? ")))) |
| 1532 | (define-key (current-global-map) [remap find-file] |
| 1533 | (if (not dired-x-hands-off-my-keys) 'dired-x-find-file)) |
| 1534 | (define-key (current-global-map) [remap find-file-other-window] |
| 1535 | (if (not dired-x-hands-off-my-keys) 'dired-x-find-file-other-window))) |
| 1536 | |
| 1537 | ;; Now call it so binding is correct. This could go in the :initialize |
| 1538 | ;; slot, but then dired-x-bind-find-file has to be defined before the |
| 1539 | ;; defcustom, and we get free variable warnings. |
| 1540 | (dired-x-bind-find-file) |
| 1541 | |
| 1542 | (defun dired-x-find-file (filename) |
| 1543 | "Edit file FILENAME. |
| 1544 | Like `find-file', except that when called interactively with a |
| 1545 | prefix argument, it offers the filename near point as a default." |
| 1546 | (interactive (list (dired-x-read-filename-at-point "Find file: "))) |
| 1547 | (find-file filename)) |
| 1548 | |
| 1549 | (defun dired-x-find-file-other-window (filename) |
| 1550 | "Edit file FILENAME, in another window. |
| 1551 | Like `find-file-other-window', except that when called interactively with |
| 1552 | a prefix argument, when it offers the filename near point as a default." |
| 1553 | (interactive (list (dired-x-read-filename-at-point "Find file: "))) |
| 1554 | (find-file-other-window filename)) |
| 1555 | |
| 1556 | ;;; Internal functions. |
| 1557 | |
| 1558 | ;; Fixme: This should probably use `thing-at-point'. -- fx |
| 1559 | (defun dired-filename-at-point () |
| 1560 | "Return the filename closest to point, expanded. |
| 1561 | Point should be in or after a filename." |
| 1562 | (save-excursion |
| 1563 | ;; First see if just past a filename. |
| 1564 | (or (eobp) ; why? |
| 1565 | (when (looking-at-p "[] \t\n[{}()]") ; whitespace or some parens |
| 1566 | (skip-chars-backward " \n\t\r({[]})") |
| 1567 | (or (bobp) (backward-char 1)))) |
| 1568 | (let ((filename-chars "-.[:alnum:]_/:$+@") |
| 1569 | start prefix) |
| 1570 | (if (looking-at-p (format "[%s]" filename-chars)) |
| 1571 | (progn |
| 1572 | (skip-chars-backward filename-chars) |
| 1573 | (setq start (point) |
| 1574 | prefix |
| 1575 | ;; This is something to do with ange-ftp filenames. |
| 1576 | ;; It convert foo@bar to /foo@bar. |
| 1577 | ;; But when does the former occur in dired buffers? |
| 1578 | (and (string-match-p |
| 1579 | "^\\w+@" |
| 1580 | (buffer-substring start (line-end-position))) |
| 1581 | "/")) |
| 1582 | (if (string-match-p "[/~]" (char-to-string (preceding-char))) |
| 1583 | (setq start (1- start))) |
| 1584 | (skip-chars-forward filename-chars)) |
| 1585 | (error "No file found around point!")) |
| 1586 | ;; Return string. |
| 1587 | (expand-file-name (concat prefix (buffer-substring start (point))))))) |
| 1588 | |
| 1589 | (defun dired-x-read-filename-at-point (prompt) |
| 1590 | "Return filename prompting with PROMPT with completion. |
| 1591 | If `current-prefix-arg' is non-nil, uses name at point as guess." |
| 1592 | (if current-prefix-arg |
| 1593 | (let ((guess (dired-filename-at-point))) |
| 1594 | (read-file-name prompt |
| 1595 | (file-name-directory guess) |
| 1596 | guess |
| 1597 | nil (file-name-nondirectory guess))) |
| 1598 | (read-file-name prompt default-directory))) |
| 1599 | |
| 1600 | (define-obsolete-function-alias 'read-filename-at-point |
| 1601 | 'dired-x-read-filename-at-point "24.1") ; is this even needed? |
| 1602 | \f |
| 1603 | ;;; BUG REPORTS |
| 1604 | |
| 1605 | (define-obsolete-function-alias 'dired-x-submit-report 'report-emacs-bug "24.1") |
| 1606 | |
| 1607 | \f |
| 1608 | ;; As Barry Warsaw would say: "This might be useful..." |
| 1609 | (provide 'dired-x) |
| 1610 | |
| 1611 | ;; Local Variables: |
| 1612 | ;; byte-compile-dynamic: t |
| 1613 | ;; generated-autoload-file: "dired.el" |
| 1614 | ;; End: |
| 1615 | |
| 1616 | ;;; dired-x.el ends here |