| 1 | ;;; completion.el --- dynamic word-completion code |
| 2 | |
| 3 | ;; Copyright (C) 1990, 1993, 1995, 1997, 2001-2012 |
| 4 | ;; Free Software Foundation, Inc. |
| 5 | |
| 6 | ;; Maintainer: FSF |
| 7 | ;; Keywords: abbrev convenience |
| 8 | ;; Author: Jim Salem <alem@bbnplanet.com> of Thinking Machines Inc. |
| 9 | ;; (ideas suggested by Brewster Kahle) |
| 10 | |
| 11 | ;; This file is part of GNU Emacs. |
| 12 | |
| 13 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 14 | ;; it under the terms of the GNU General Public License as published by |
| 15 | ;; the Free Software Foundation, either version 3 of the License, or |
| 16 | ;; (at your option) any later version. |
| 17 | |
| 18 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 19 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 20 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 21 | ;; GNU General Public License for more details. |
| 22 | |
| 23 | ;; You should have received a copy of the GNU General Public License |
| 24 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 25 | |
| 26 | ;;; Commentary: |
| 27 | |
| 28 | ;; What to put in .emacs |
| 29 | ;;----------------------- |
| 30 | ;; (dynamic-completion-mode) |
| 31 | \f |
| 32 | ;;--------------------------------------------------------------------------- |
| 33 | ;; Documentation [Slightly out of date] |
| 34 | ;;--------------------------------------------------------------------------- |
| 35 | ;; (also check the documentation string of the functions) |
| 36 | ;; |
| 37 | ;; Introduction |
| 38 | ;;--------------- |
| 39 | ;; |
| 40 | ;; After you type a few characters, pressing the "complete" key inserts |
| 41 | ;; the rest of the word you are likely to type. |
| 42 | ;; |
| 43 | ;; This watches all the words that you type and remembers them. When |
| 44 | ;; typing a new word, pressing "complete" (meta-return) "completes" the |
| 45 | ;; word by inserting the most recently used word that begins with the |
| 46 | ;; same characters. If you press meta-return repeatedly, it cycles |
| 47 | ;; through all the words it knows about. |
| 48 | ;; |
| 49 | ;; If you like the completion then just continue typing, it is as if you |
| 50 | ;; entered the text by hand. If you want the inserted extra characters |
| 51 | ;; to go away, type control-w or delete. More options are described below. |
| 52 | ;; |
| 53 | ;; The guesses are made in the order of the most recently "used". Typing |
| 54 | ;; in a word and then typing a separator character (such as a space) "uses" |
| 55 | ;; the word. So does moving a cursor over the word. If no words are found, |
| 56 | ;; it uses an extended version of the dabbrev style completion. |
| 57 | ;; |
| 58 | ;; You automatically save the completions you use to a file between |
| 59 | ;; sessions. |
| 60 | ;; |
| 61 | ;; Completion enables programmers to enter longer, more descriptive |
| 62 | ;; variable names while typing fewer keystrokes than they normally would. |
| 63 | ;; |
| 64 | ;; |
| 65 | ;; Full documentation |
| 66 | ;;--------------------- |
| 67 | ;; |
| 68 | ;; A "word" is any string containing characters with either word or symbol |
| 69 | ;; syntax. [E.G. Any alphanumeric string with hyphens, underscores, etc.] |
| 70 | ;; Unless you change the constants, you must type at least three characters |
| 71 | ;; for the word to be recognized. Only words longer than 6 characters are |
| 72 | ;; saved. |
| 73 | ;; |
| 74 | ;; When you load this file, completion will be on. I suggest you use the |
| 75 | ;; compiled version (because it is noticeably faster). |
| 76 | ;; |
| 77 | ;; M-x completion-mode toggles whether or not new words are added to the |
| 78 | ;; database by changing the value of enable-completion. |
| 79 | ;; |
| 80 | ;; SAVING/LOADING COMPLETIONS |
| 81 | ;; Completions are automatically saved from one session to another |
| 82 | ;; (unless save-completions-flag or enable-completion is nil). |
| 83 | ;; Activating this minor-mode (calling completion-initialize) loads |
| 84 | ;; a completions database for a saved completions file |
| 85 | ;; (default: ~/.completions). When you exit, Emacs saves a copy of the |
| 86 | ;; completions that you often use. When you next start, Emacs loads in |
| 87 | ;; the saved completion file. |
| 88 | ;; |
| 89 | ;; The number of completions saved depends loosely on |
| 90 | ;; *saved-completions-decay-factor*. Completions that have never been |
| 91 | ;; inserted via "complete" are not saved. You are encouraged to experiment |
| 92 | ;; with different functions (see compute-completion-min-num-uses). |
| 93 | ;; |
| 94 | ;; Some completions are permanent and are always saved out. These |
| 95 | ;; completions have their num-uses slot set to T. Use |
| 96 | ;; add-permanent-completion to do this |
| 97 | ;; |
| 98 | ;; Completions are saved only if enable-completion is T. The number of old |
| 99 | ;; versions kept of the saved completions file is controlled by |
| 100 | ;; completions-file-versions-kept. |
| 101 | ;; |
| 102 | ;; COMPLETE KEY OPTIONS |
| 103 | ;; The complete function takes a numeric arguments. |
| 104 | ;; control-u :: leave the point at the beginning of the completion rather |
| 105 | ;; than the middle. |
| 106 | ;; a number :: rotate through the possible completions by that amount |
| 107 | ;; `-' :: same as -1 (insert previous completion) |
| 108 | ;; |
| 109 | ;; HOW THE DATABASE IS MAINTAINED |
| 110 | ;; <write> |
| 111 | ;; |
| 112 | ;; UPDATING THE DATABASE MANUALLY |
| 113 | ;; m-x kill-completion |
| 114 | ;; kills the completion at point. |
| 115 | ;; m-x add-completion |
| 116 | ;; m-x add-permanent-completion |
| 117 | ;; |
| 118 | ;; UPDATING THE DATABASE FROM A SOURCE CODE FILE |
| 119 | ;; m-x add-completions-from-buffer |
| 120 | ;; Parses all the definition names from a C or LISP mode buffer and |
| 121 | ;; adds them to the completion database. |
| 122 | ;; |
| 123 | ;; m-x add-completions-from-lisp-file |
| 124 | ;; Parses all the definition names from a C or Lisp mode file and |
| 125 | ;; adds them to the completion database. |
| 126 | ;; |
| 127 | ;; UPDATING THE DATABASE FROM A TAGS TABLE |
| 128 | ;; m-x add-completions-from-tags-table |
| 129 | ;; Adds completions from the current tags-table-buffer. |
| 130 | ;; |
| 131 | ;; HOW A COMPLETION IS FOUND |
| 132 | ;; <write> |
| 133 | ;; |
| 134 | ;; STRING CASING |
| 135 | ;; Completion is string case independent if case-fold-search has its |
| 136 | ;; normal default of T. Also when the completion is inserted the case of the |
| 137 | ;; entry is coerced appropriately. |
| 138 | ;; [E.G. APP --> APPROPRIATELY app --> appropriately |
| 139 | ;; App --> Appropriately] |
| 140 | ;; |
| 141 | ;; INITIALIZATION |
| 142 | ;; The form `(completion-initialize)' initializes the completion system by |
| 143 | ;; trying to load in the user's completions. After the first call, further |
| 144 | ;; calls have no effect so one should be careful not to put the form in a |
| 145 | ;; site's standard site-init file. |
| 146 | ;; |
| 147 | ;;--------------------------------------------------------------------------- |
| 148 | ;; |
| 149 | ;; |
| 150 | \f |
| 151 | ;;--------------------------------------------------------------------------- |
| 152 | ;; Functions you might like to call |
| 153 | ;;--------------------------------------------------------------------------- |
| 154 | ;; |
| 155 | ;; add-completion string &optional num-uses |
| 156 | ;; Adds a new string to the database |
| 157 | ;; |
| 158 | ;; add-permanent-completion string |
| 159 | ;; Adds a new string to the database with num-uses = T |
| 160 | ;; |
| 161 | |
| 162 | ;; kill-completion string |
| 163 | ;; Kills the completion from the database. |
| 164 | ;; |
| 165 | ;; clear-all-completions |
| 166 | ;; Clears the database |
| 167 | ;; |
| 168 | ;; list-all-completions |
| 169 | ;; Returns a list of all completions. |
| 170 | ;; |
| 171 | ;; |
| 172 | ;; next-completion string &optional index |
| 173 | ;; Returns a completion entry that starts with string. |
| 174 | ;; |
| 175 | ;; find-exact-completion string |
| 176 | ;; Returns a completion entry that exactly matches string. |
| 177 | ;; |
| 178 | ;; complete |
| 179 | ;; Inserts a completion at point |
| 180 | ;; |
| 181 | ;; completion-initialize |
| 182 | ;; Loads the completions file and sets up so that exiting emacs will |
| 183 | ;; save them. |
| 184 | ;; |
| 185 | ;; save-completions-to-file &optional filename |
| 186 | ;; load-completions-from-file &optional filename |
| 187 | ;; |
| 188 | ;;----------------------------------------------- |
| 189 | ;; Other functions |
| 190 | ;;----------------------------------------------- |
| 191 | ;; |
| 192 | ;; get-completion-list string |
| 193 | ;; |
| 194 | ;; These things are for manipulating the structure |
| 195 | ;; make-completion string num-uses |
| 196 | ;; completion-num-uses completion |
| 197 | ;; completion-string completion |
| 198 | ;; set-completion-num-uses completion num-uses |
| 199 | ;; set-completion-string completion string |
| 200 | ;; |
| 201 | ;; |
| 202 | \f |
| 203 | ;;----------------------------------------------- |
| 204 | ;; To Do :: (anybody ?) |
| 205 | ;;----------------------------------------------- |
| 206 | ;; |
| 207 | ;; Implement Lookup and keyboard interface in C |
| 208 | ;; Add package prefix smarts (for Common Lisp) |
| 209 | ;; Add autoprompting of possible completions after every keystroke (fast |
| 210 | ;; terminals only !) |
| 211 | ;; Add doc. to texinfo |
| 212 | ;; |
| 213 | ;; |
| 214 | ;;----------------------------------------------- |
| 215 | ;;; Change Log: |
| 216 | ;;----------------------------------------------- |
| 217 | ;; Sometime in '84 Brewster implemented a somewhat buggy version for |
| 218 | ;; Symbolics LISPMs. |
| 219 | ;; Jan. '85 Jim became enamored of the idea and implemented a faster, |
| 220 | ;; more robust version. |
| 221 | ;; With input from many users at TMC, (rose, craig, and gls come to mind), |
| 222 | ;; the current style of interface was developed. |
| 223 | ;; 9/87, Jim and Brewster took terminals home. Yuck. After |
| 224 | ;; complaining for a while Brewster implemented a subset of the current |
| 225 | ;; LISPM version for GNU Emacs. |
| 226 | ;; 8/88 After complaining for a while (and with sufficient |
| 227 | ;; promised rewards), Jim reimplemented a version of GNU completion |
| 228 | ;; superior to that of the LISPM version. |
| 229 | ;; |
| 230 | ;;----------------------------------------------- |
| 231 | ;; Acknowledgements |
| 232 | ;;----------------------------------------------- |
| 233 | ;; Cliff Lasser (cal@think.com), Kevin Herbert (kph@cisco.com), |
| 234 | ;; eero@media-lab, kgk@cs.brown.edu, jla@ai.mit.edu, |
| 235 | ;; |
| 236 | ;;----------------------------------------------- |
| 237 | ;; Change Log |
| 238 | ;;----------------------------------------------- |
| 239 | ;; From version 9 to 10 |
| 240 | ;; - Allowance for non-integral *completion-version* nos. |
| 241 | ;; - Fix cmpl-apply-as-top-level for keyboard macros |
| 242 | ;; - Fix broken completion merging (in save-completions-to-file) |
| 243 | ;; - More misc. fixes for version 19.0 of emacs |
| 244 | ;; |
| 245 | ;; From Version 8 to 9 |
| 246 | ;; - Ported to version 19.0 of emacs (backcompatible with version 18) |
| 247 | ;; - Added add-completions-from-tags-table (with thanks to eero@media-lab) |
| 248 | ;; |
| 249 | ;; From Version 7 to 8 |
| 250 | ;; - Misc. changes to comments |
| 251 | ;; - new completion key bindings: c-x o, M->, M-<, c-a, c-e |
| 252 | ;; - cdabbrev now checks all the visible window buffers and the "other buffer" |
| 253 | ;; - `%' is now a symbol character rather than a separator (except in C mode) |
| 254 | ;; |
| 255 | ;; From Version 6 to 7 |
| 256 | ;; - Fixed bug with saving out .completion file the first time |
| 257 | ;; |
| 258 | ;; From Version 5 to 6 |
| 259 | ;; - removed statistics recording |
| 260 | ;; - reworked advise to handle autoloads |
| 261 | ;; - Fixed fortran mode support |
| 262 | ;; - Added new cursor motion triggers |
| 263 | ;; |
| 264 | ;; From Version 4 to 5 |
| 265 | ;; - doesn't bother saving if nothing has changed |
| 266 | ;; - auto-save if haven't used for a 1/2 hour |
| 267 | ;; - save period extended to two weeks |
| 268 | ;; - minor fix to capitalization code |
| 269 | ;; - added *completion-auto-save-period* to variables recorded. |
| 270 | ;; - added reenter protection to cmpl-record-statistics-filter |
| 271 | ;; - added backup protection to save-completions-to-file (prevents |
| 272 | ;; problems with disk full errors) |
| 273 | \f |
| 274 | ;;; Code: |
| 275 | |
| 276 | ;;--------------------------------------------------------------------------- |
| 277 | ;; User changeable parameters |
| 278 | ;;--------------------------------------------------------------------------- |
| 279 | |
| 280 | (defgroup completion nil |
| 281 | "Dynamic word-completion code." |
| 282 | :group 'matching |
| 283 | :group 'convenience) |
| 284 | |
| 285 | |
| 286 | (defcustom enable-completion t |
| 287 | "Non-nil means enable recording and saving of completions. |
| 288 | If nil, no new words are added to the database or saved to the init file." |
| 289 | :type 'boolean |
| 290 | :group 'completion) |
| 291 | |
| 292 | (defcustom save-completions-flag t |
| 293 | "Non-nil means save most-used completions when exiting Emacs. |
| 294 | See also `save-completions-retention-time'." |
| 295 | :type 'boolean |
| 296 | :group 'completion) |
| 297 | |
| 298 | (defcustom save-completions-file-name |
| 299 | (locate-user-emacs-file "completions" ".completions") |
| 300 | "The filename to save completions to." |
| 301 | :type 'file |
| 302 | :group 'completion) |
| 303 | |
| 304 | (defcustom save-completions-retention-time 336 |
| 305 | "Discard a completion if unused for this many hours. |
| 306 | \(1 day = 24, 1 week = 168). If this is 0, non-permanent completions |
| 307 | will not be saved unless these are used. Default is two weeks." |
| 308 | :type 'integer |
| 309 | :group 'completion) |
| 310 | |
| 311 | (defcustom completion-on-separator-character nil |
| 312 | "Non-nil means separator characters mark previous word as used. |
| 313 | This means the word will be saved as a completion." |
| 314 | :type 'boolean |
| 315 | :group 'completion) |
| 316 | |
| 317 | (defcustom completions-file-versions-kept kept-new-versions |
| 318 | "Number of versions to keep for the saved completions file." |
| 319 | :type 'integer |
| 320 | :group 'completion) |
| 321 | |
| 322 | (defcustom completion-prompt-speed-threshold 4800 |
| 323 | "Minimum output speed at which to display next potential completion." |
| 324 | :type 'integer |
| 325 | :group 'completion) |
| 326 | |
| 327 | (defcustom completion-cdabbrev-prompt-flag nil |
| 328 | "If non-nil, the next completion prompt does a cdabbrev search. |
| 329 | This can be time consuming." |
| 330 | :type 'boolean |
| 331 | :group 'completion) |
| 332 | |
| 333 | (defcustom completion-search-distance 15000 |
| 334 | "How far to search in the buffer when looking for completions. |
| 335 | In number of characters. If nil, search the whole buffer." |
| 336 | :type 'integer |
| 337 | :group 'completion) |
| 338 | |
| 339 | (defcustom completions-merging-modes '(lisp c) |
| 340 | "List of modes {`c' or `lisp'} for automatic completions merging. |
| 341 | Definitions from visited files which have these modes |
| 342 | are automatically added to the completion database." |
| 343 | :type '(set (const lisp) (const c)) |
| 344 | :group 'completion) |
| 345 | |
| 346 | ;;(defvar *record-cmpl-statistics-p* nil |
| 347 | ;; "If non-nil, record completion statistics.") |
| 348 | |
| 349 | ;;(defvar *completion-auto-save-period* 1800 |
| 350 | ;; "The period in seconds to wait for emacs to be idle before autosaving |
| 351 | ;;the completions. Default is a 1/2 hour.") |
| 352 | |
| 353 | (defvar completion-min-length 6 |
| 354 | "The minimum length of a stored completion. |
| 355 | DON'T CHANGE WITHOUT RECOMPILING ! This is used by macros.") |
| 356 | |
| 357 | (defvar completion-max-length 200 |
| 358 | "The maximum length of a stored completion. |
| 359 | DON'T CHANGE WITHOUT RECOMPILING ! This is used by macros.") |
| 360 | |
| 361 | (defvar completion-prefix-min-length 3 |
| 362 | "The minimum length of a completion search string. |
| 363 | DON'T CHANGE WITHOUT RECOMPILING ! This is used by macros.") |
| 364 | |
| 365 | ;;--------------------------------------------------------------------------- |
| 366 | ;; Internal Variables |
| 367 | ;;--------------------------------------------------------------------------- |
| 368 | |
| 369 | (defvar cmpl-initialized-p nil |
| 370 | "Set to t when the completion system is initialized. |
| 371 | Indicates that the old completion file has been read in.") |
| 372 | |
| 373 | (defvar cmpl-completions-accepted-p nil |
| 374 | "Set to t as soon as the first completion has been accepted. |
| 375 | Used to decide whether to save completions.") |
| 376 | |
| 377 | (defvar cmpl-preceding-syntax) |
| 378 | |
| 379 | (defvar completion-string) |
| 380 | \f |
| 381 | ;;--------------------------------------------------------------------------- |
| 382 | ;; Low level tools |
| 383 | ;;--------------------------------------------------------------------------- |
| 384 | |
| 385 | ;;----------------------------------------------- |
| 386 | ;; String case coercion |
| 387 | ;;----------------------------------------------- |
| 388 | |
| 389 | (defun cmpl-string-case-type (string) |
| 390 | "Return :capitalized, :up, :down, :mixed, or :neither for case of STRING." |
| 391 | (let ((case-fold-search nil)) |
| 392 | (cond ((string-match "[[:lower:]]" string) |
| 393 | (cond ((string-match "[[:upper:]]" string) |
| 394 | (cond ((and (> (length string) 1) |
| 395 | (null (string-match "[[:upper:]]" string 1))) |
| 396 | :capitalized) |
| 397 | (t |
| 398 | :mixed))) |
| 399 | (t :down))) |
| 400 | (t |
| 401 | (cond ((string-match "[[:upper:]]" string) |
| 402 | :up) |
| 403 | (t :neither)))))) |
| 404 | |
| 405 | ;; Tests - |
| 406 | ;; (cmpl-string-case-type "123ABCDEF456") --> :up |
| 407 | ;; (cmpl-string-case-type "123abcdef456") --> :down |
| 408 | ;; (cmpl-string-case-type "123aBcDeF456") --> :mixed |
| 409 | ;; (cmpl-string-case-type "123456") --> :neither |
| 410 | ;; (cmpl-string-case-type "Abcde123") --> :capitalized |
| 411 | |
| 412 | (defun cmpl-coerce-string-case (string case-type) |
| 413 | (cond ((eq case-type :down) (downcase string)) |
| 414 | ((eq case-type :up) (upcase string)) |
| 415 | ((eq case-type :capitalized) |
| 416 | (setq string (downcase string)) |
| 417 | (aset string 0 (logand ?\337 (aref string 0))) |
| 418 | string) |
| 419 | (t string))) |
| 420 | |
| 421 | (defun cmpl-merge-string-cases (string-to-coerce given-string) |
| 422 | (let ((string-case-type (cmpl-string-case-type string-to-coerce))) |
| 423 | (cond ((memq string-case-type '(:down :up :capitalized)) |
| 424 | ;; Found string is in a standard case. Coerce to a type based on |
| 425 | ;; the given string |
| 426 | (cmpl-coerce-string-case string-to-coerce |
| 427 | (cmpl-string-case-type given-string))) |
| 428 | (t |
| 429 | ;; If the found string is in some unusual case, just insert it |
| 430 | ;; as is |
| 431 | string-to-coerce)))) |
| 432 | |
| 433 | ;; Tests - |
| 434 | ;; (cmpl-merge-string-cases "AbCdEf456" "abc") --> AbCdEf456 |
| 435 | ;; (cmpl-merge-string-cases "abcdef456" "ABC") --> ABCDEF456 |
| 436 | ;; (cmpl-merge-string-cases "ABCDEF456" "Abc") --> Abcdef456 |
| 437 | ;; (cmpl-merge-string-cases "ABCDEF456" "abc") --> abcdef456 |
| 438 | |
| 439 | \f |
| 440 | (defun cmpl-hours-since-origin () |
| 441 | (let ((time (current-time))) |
| 442 | (floor (+ (* 65536.0 (nth 0 time)) (nth 1 time)) 3600))) |
| 443 | \f |
| 444 | ;;--------------------------------------------------------------------------- |
| 445 | ;; "Symbol" parsing functions |
| 446 | ;;--------------------------------------------------------------------------- |
| 447 | ;; The functions symbol-before-point, symbol-under-point, etc. quickly return |
| 448 | ;; an appropriate symbol string. The strategy is to temporarily change |
| 449 | ;; the syntax table to enable fast symbol searching. There are three classes |
| 450 | ;; of syntax in these "symbol" syntax tables :: |
| 451 | ;; |
| 452 | ;; syntax (?_) - "symbol" chars (e.g. alphanumerics) |
| 453 | ;; syntax (?w) - symbol chars to ignore at end of words (e.g. period). |
| 454 | ;; syntax (? ) - everything else |
| 455 | ;; |
| 456 | ;; Thus by judicious use of scan-sexps and forward-word, we can get |
| 457 | ;; the word we want relatively fast and without consing. |
| 458 | ;; |
| 459 | ;; Why do we need a separate category for "symbol chars to ignore at ends" ? |
| 460 | ;; For example, in LISP we want starting :'s trimmed |
| 461 | ;; so keyword argument specifiers also define the keyword completion. And, |
| 462 | ;; for example, in C we want `.' appearing in a structure ref. to |
| 463 | ;; be kept intact in order to store the whole structure ref.; however, if |
| 464 | ;; it appears at the end of a symbol it should be discarded because it is |
| 465 | ;; probably used as a period. |
| 466 | |
| 467 | ;; Here is the default completion syntax :: |
| 468 | ;; Symbol chars :: A-Z a-z 0-9 @ / \ * + ~ $ < > % |
| 469 | ;; Symbol chars to ignore at ends :: _ : . - |
| 470 | ;; Separator chars. :: <tab> <space> ! ^ & ( ) = ` | { } [ ] ; " ' # |
| 471 | ;; , ? <Everything else> |
| 472 | |
| 473 | ;; Mode specific differences and notes :: |
| 474 | ;; LISP diffs -> |
| 475 | ;; Symbol chars :: ! & ? = ^ |
| 476 | ;; |
| 477 | ;; C diffs -> |
| 478 | ;; Separator chars :: + * / : % |
| 479 | ;; A note on the hyphen (`-'). Perhaps the hyphen should also be a separator |
| 480 | ;; char., however, we wanted to have completion symbols include pointer |
| 481 | ;; references. For example, "foo->bar" is a symbol as far as completion is |
| 482 | ;; concerned. |
| 483 | ;; |
| 484 | ;; FORTRAN diffs -> |
| 485 | ;; Separator chars :: + - * / : |
| 486 | ;; |
| 487 | ;; Pathname diffs -> |
| 488 | ;; Symbol chars :: . |
| 489 | ;; Of course there is no pathname "mode" and in fact we have not implemented |
| 490 | ;; this table. However, if there was such a mode, this is what it would look |
| 491 | ;; like. |
| 492 | |
| 493 | ;;----------------------------------------------- |
| 494 | ;; Table definitions |
| 495 | ;;----------------------------------------------- |
| 496 | |
| 497 | (defconst completion-standard-syntax-table |
| 498 | (let ((table (make-syntax-table)) |
| 499 | i) |
| 500 | ;; Default syntax is whitespace. |
| 501 | (setq i 0) |
| 502 | (while (< i 256) |
| 503 | (modify-syntax-entry i " " table) |
| 504 | (setq i (1+ i))) |
| 505 | ;; alpha chars |
| 506 | (setq i 0) |
| 507 | (while (< i 26) |
| 508 | (modify-syntax-entry (+ ?a i) "_" table) |
| 509 | (modify-syntax-entry (+ ?A i) "_" table) |
| 510 | (setq i (1+ i))) |
| 511 | ;; digit chars. |
| 512 | (setq i 0) |
| 513 | (while (< i 10) |
| 514 | (modify-syntax-entry (+ ?0 i) "_" table) |
| 515 | (setq i (1+ i))) |
| 516 | ;; Other ones |
| 517 | (let ((symbol-chars '(?@ ?/ ?\\ ?* ?+ ?~ ?$ ?< ?> ?%)) |
| 518 | (symbol-chars-ignore '(?_ ?- ?: ?.))) |
| 519 | (dolist (char symbol-chars) |
| 520 | (modify-syntax-entry char "_" table)) |
| 521 | (dolist (char symbol-chars-ignore) |
| 522 | (modify-syntax-entry char "w" table))) |
| 523 | table)) |
| 524 | |
| 525 | (defvar completion-syntax-table completion-standard-syntax-table |
| 526 | "This variable holds the current completion syntax table.") |
| 527 | (make-variable-buffer-local 'completion-syntax-table) |
| 528 | |
| 529 | ;;----------------------------------------------- |
| 530 | ;; Symbol functions |
| 531 | ;;----------------------------------------------- |
| 532 | (defvar cmpl-symbol-start nil |
| 533 | "Holds first character of symbol, after any completion symbol function.") |
| 534 | (defvar cmpl-symbol-end nil |
| 535 | "Holds last character of symbol, after any completion symbol function.") |
| 536 | |
| 537 | (defun symbol-under-point () |
| 538 | "Return the symbol that the point is currently on. |
| 539 | But only if it is longer than `completion-min-length'." |
| 540 | (with-syntax-table completion-syntax-table |
| 541 | (when (memq (char-syntax (following-char)) '(?w ?_)) |
| 542 | ;; Cursor is on following-char and after preceding-char |
| 543 | (let ((saved-point (point))) |
| 544 | (setq cmpl-symbol-start (scan-sexps (1+ saved-point) -1) |
| 545 | cmpl-symbol-end (scan-sexps saved-point 1)) |
| 546 | ;; Remove chars to ignore at the start. |
| 547 | (cond ((= (char-syntax (char-after cmpl-symbol-start)) ?w) |
| 548 | (goto-char cmpl-symbol-start) |
| 549 | (forward-word 1) |
| 550 | (setq cmpl-symbol-start (point)) |
| 551 | (goto-char saved-point))) |
| 552 | ;; Remove chars to ignore at the end. |
| 553 | (cond ((= (char-syntax (char-after (1- cmpl-symbol-end))) ?w) |
| 554 | (goto-char cmpl-symbol-end) |
| 555 | (forward-word -1) |
| 556 | (setq cmpl-symbol-end (point)) |
| 557 | (goto-char saved-point))) |
| 558 | ;; Return completion if the length is reasonable. |
| 559 | (if (and (<= completion-min-length |
| 560 | (- cmpl-symbol-end cmpl-symbol-start)) |
| 561 | (<= (- cmpl-symbol-end cmpl-symbol-start) |
| 562 | completion-max-length)) |
| 563 | (buffer-substring-no-properties |
| 564 | cmpl-symbol-start cmpl-symbol-end)))))) |
| 565 | |
| 566 | ;; tests for symbol-under-point |
| 567 | ;; `^' indicates cursor pos. where value is returned |
| 568 | ;; simple-word-test |
| 569 | ;; ^^^^^^^^^^^^^^^^ --> simple-word-test |
| 570 | ;; _harder_word_test_ |
| 571 | ;; ^^^^^^^^^^^^^^^^^^ --> harder_word_test |
| 572 | ;; .___.______. |
| 573 | ;; --> nil |
| 574 | ;; /foo/bar/quux.hello |
| 575 | ;; ^^^^^^^^^^^^^^^^^^^ --> /foo/bar/quux.hello |
| 576 | ;; |
| 577 | |
| 578 | (defun symbol-before-point () |
| 579 | "Return a string of the symbol immediately before point. |
| 580 | Returns nil if there isn't one longer than `completion-min-length'." |
| 581 | ;; This is called when a word separator is typed so it must be FAST ! |
| 582 | (with-syntax-table completion-syntax-table |
| 583 | ;; Cursor is on following-char and after preceding-char |
| 584 | (cond ((= (setq cmpl-preceding-syntax (char-syntax (preceding-char))) ?_) |
| 585 | ;; Number of chars to ignore at end. |
| 586 | (setq cmpl-symbol-end (point) |
| 587 | cmpl-symbol-start (scan-sexps cmpl-symbol-end -1)) |
| 588 | ;; Remove chars to ignore at the start. |
| 589 | (cond ((= (char-syntax (char-after cmpl-symbol-start)) ?w) |
| 590 | (goto-char cmpl-symbol-start) |
| 591 | (forward-word 1) |
| 592 | (setq cmpl-symbol-start (point)) |
| 593 | (goto-char cmpl-symbol-end))) |
| 594 | ;; Return value if long enough. |
| 595 | (if (>= cmpl-symbol-end |
| 596 | (+ cmpl-symbol-start completion-min-length)) |
| 597 | (buffer-substring-no-properties |
| 598 | cmpl-symbol-start cmpl-symbol-end))) |
| 599 | ((= cmpl-preceding-syntax ?w) |
| 600 | ;; chars to ignore at end |
| 601 | (let ((saved-point (point))) |
| 602 | (setq cmpl-symbol-start (scan-sexps saved-point -1)) |
| 603 | ;; take off chars. from end |
| 604 | (forward-word -1) |
| 605 | (setq cmpl-symbol-end (point)) |
| 606 | ;; remove chars to ignore at the start |
| 607 | (cond ((= (char-syntax (char-after cmpl-symbol-start)) ?w) |
| 608 | (goto-char cmpl-symbol-start) |
| 609 | (forward-word 1) |
| 610 | (setq cmpl-symbol-start (point)))) |
| 611 | ;; Restore state. |
| 612 | (goto-char saved-point) |
| 613 | ;; Return completion if the length is reasonable |
| 614 | (if (and (<= completion-min-length |
| 615 | (- cmpl-symbol-end cmpl-symbol-start)) |
| 616 | (<= (- cmpl-symbol-end cmpl-symbol-start) |
| 617 | completion-max-length)) |
| 618 | (buffer-substring-no-properties |
| 619 | cmpl-symbol-start cmpl-symbol-end))))))) |
| 620 | |
| 621 | ;; tests for symbol-before-point |
| 622 | ;; `^' indicates cursor pos. where value is returned |
| 623 | ;; simple-word-test |
| 624 | ;; ^ --> nil |
| 625 | ;; ^ --> nil |
| 626 | ;; ^ --> simple-w |
| 627 | ;; ^ --> simple-word-test |
| 628 | ;; _harder_word_test_ |
| 629 | ;; ^ --> harder_word_test |
| 630 | ;; ^ --> harder_word_test |
| 631 | ;; ^ --> harder |
| 632 | ;; .___.... |
| 633 | ;; --> nil |
| 634 | |
| 635 | (defun symbol-under-or-before-point () |
| 636 | ;; This could be made slightly faster but it is better to avoid |
| 637 | ;; copying all the code. |
| 638 | ;; However, it is only used by the completion string prompter. |
| 639 | ;; If it comes into common use, it could be rewritten. |
| 640 | (if (memq (with-syntax-table completion-syntax-table |
| 641 | (char-syntax (following-char))) |
| 642 | '(?w ?_)) |
| 643 | (symbol-under-point) |
| 644 | (symbol-before-point))) |
| 645 | |
| 646 | |
| 647 | (defun symbol-before-point-for-complete () |
| 648 | ;; "Returns a string of the symbol immediately before point |
| 649 | ;; or nil if there isn't one. Like symbol-before-point but doesn't trim the |
| 650 | ;; end chars." |
| 651 | ;; Cursor is on following-char and after preceding-char |
| 652 | (with-syntax-table completion-syntax-table |
| 653 | (cond ((memq (setq cmpl-preceding-syntax (char-syntax (preceding-char))) |
| 654 | '(?_ ?w)) |
| 655 | (setq cmpl-symbol-end (point) |
| 656 | cmpl-symbol-start (scan-sexps cmpl-symbol-end -1)) |
| 657 | ;; Remove chars to ignore at the start. |
| 658 | (cond ((= (char-syntax (char-after cmpl-symbol-start)) ?w) |
| 659 | (goto-char cmpl-symbol-start) |
| 660 | (forward-word 1) |
| 661 | (setq cmpl-symbol-start (point)) |
| 662 | (goto-char cmpl-symbol-end))) |
| 663 | ;; Return completion if the length is reasonable. |
| 664 | (if (and (<= completion-prefix-min-length |
| 665 | (- cmpl-symbol-end cmpl-symbol-start)) |
| 666 | (<= (- cmpl-symbol-end cmpl-symbol-start) |
| 667 | completion-max-length)) |
| 668 | (buffer-substring-no-properties |
| 669 | cmpl-symbol-start cmpl-symbol-end)))))) |
| 670 | |
| 671 | ;; tests for symbol-before-point-for-complete |
| 672 | ;; `^' indicates cursor pos. where value is returned |
| 673 | ;; simple-word-test |
| 674 | ;; ^ --> nil |
| 675 | ;; ^ --> nil |
| 676 | ;; ^ --> simple-w |
| 677 | ;; ^ --> simple-word-test |
| 678 | ;; _harder_word_test_ |
| 679 | ;; ^ --> harder_word_test |
| 680 | ;; ^ --> harder_word_test_ |
| 681 | ;; ^ --> harder_ |
| 682 | ;; .___.... |
| 683 | ;; --> nil |
| 684 | |
| 685 | |
| 686 | \f |
| 687 | ;;--------------------------------------------------------------------------- |
| 688 | ;; Statistics Recording |
| 689 | ;;--------------------------------------------------------------------------- |
| 690 | |
| 691 | ;; Note that the guts of this has been turned off. The guts |
| 692 | ;; are in completion-stats.el. |
| 693 | |
| 694 | ;;----------------------------------------------- |
| 695 | ;; Conditionalizing code on *record-cmpl-statistics-p* |
| 696 | ;;----------------------------------------------- |
| 697 | ;; All statistics code outside this block should use this |
| 698 | (defmacro cmpl-statistics-block (&rest _body)) |
| 699 | ;; "Only executes body if we are recording statistics." |
| 700 | ;; (list 'cond |
| 701 | ;; (list* '*record-cmpl-statistics-p* body) |
| 702 | ;; )) |
| 703 | |
| 704 | ;;----------------------------------------------- |
| 705 | ;; Completion Sources |
| 706 | ;;----------------------------------------------- |
| 707 | |
| 708 | ;; ID numbers |
| 709 | (defconst cmpl-source-unknown 0) |
| 710 | (defconst cmpl-source-init-file 1) |
| 711 | (defconst cmpl-source-file-parsing 2) |
| 712 | (defconst cmpl-source-separator 3) |
| 713 | (defconst cmpl-source-cursor-moves 4) |
| 714 | (defconst cmpl-source-interactive 5) |
| 715 | (defconst cmpl-source-cdabbrev 6) |
| 716 | (defconst num-cmpl-sources 7) |
| 717 | (defvar current-completion-source cmpl-source-unknown) |
| 718 | |
| 719 | |
| 720 | \f |
| 721 | ;;--------------------------------------------------------------------------- |
| 722 | ;; Completion Method #2: dabbrev-expand style |
| 723 | ;;--------------------------------------------------------------------------- |
| 724 | ;; |
| 725 | ;; This method is used if there are no useful stored completions. It is |
| 726 | ;; based on dabbrev-expand with these differences : |
| 727 | ;; 1) Faster (we don't use regexps) |
| 728 | ;; 2) case coercion handled correctly |
| 729 | ;; This is called cdabbrev to differentiate it. |
| 730 | ;; We simply search backwards through the file looking for words which |
| 731 | ;; start with the same letters we are trying to complete. |
| 732 | ;; |
| 733 | |
| 734 | (defvar cdabbrev-completions-tried nil) |
| 735 | ;; "A list of all the cdabbrev completions since the last reset.") |
| 736 | |
| 737 | (defvar cdabbrev-current-point 0) |
| 738 | ;; "The current point position the cdabbrev search is at.") |
| 739 | |
| 740 | (defvar cdabbrev-current-window nil) |
| 741 | ;; "The current window we are looking for cdabbrevs in. |
| 742 | ;; Return t if looking in (other-buffer), nil if no more cdabbrevs.") |
| 743 | |
| 744 | (defvar cdabbrev-wrapped-p nil) |
| 745 | ;; "Return t if the cdabbrev search has wrapped around the file.") |
| 746 | |
| 747 | (defvar cdabbrev-abbrev-string "") |
| 748 | (defvar cdabbrev-start-point 0) |
| 749 | (defvar cdabbrev-stop-point) |
| 750 | |
| 751 | ;; Test strings for cdabbrev |
| 752 | ;; cdat-upcase ;;same namestring |
| 753 | ;; CDAT-UPCASE ;;ok |
| 754 | ;; cdat2 ;;too short |
| 755 | ;; cdat-1-2-3-4 ;;ok |
| 756 | ;; a-cdat-1 ;;doesn't start correctly |
| 757 | ;; cdat-simple ;;ok |
| 758 | |
| 759 | |
| 760 | (defun reset-cdabbrev (abbrev-string &optional initial-completions-tried) |
| 761 | "Reset the cdabbrev search to search for ABBREV-STRING. |
| 762 | INITIAL-COMPLETIONS-TRIED is a list of downcased strings to ignore |
| 763 | during the search." |
| 764 | (setq cdabbrev-abbrev-string abbrev-string |
| 765 | cdabbrev-completions-tried |
| 766 | (cons (downcase abbrev-string) initial-completions-tried)) |
| 767 | (reset-cdabbrev-window t)) |
| 768 | |
| 769 | (defun set-cdabbrev-buffer () |
| 770 | ;; cdabbrev-current-window must not be nil |
| 771 | (set-buffer (if (eq cdabbrev-current-window t) |
| 772 | (other-buffer) |
| 773 | (window-buffer cdabbrev-current-window)))) |
| 774 | |
| 775 | |
| 776 | (defun reset-cdabbrev-window (&optional initializep) |
| 777 | "Reset the cdabbrev search to search for abbrev-string." |
| 778 | ;; Set the window |
| 779 | (cond (initializep |
| 780 | (setq cdabbrev-current-window (selected-window))) |
| 781 | ((eq cdabbrev-current-window t) |
| 782 | ;; Everything has failed |
| 783 | (setq cdabbrev-current-window nil)) |
| 784 | (cdabbrev-current-window |
| 785 | (setq cdabbrev-current-window (next-window cdabbrev-current-window)) |
| 786 | (if (eq cdabbrev-current-window (selected-window)) |
| 787 | ;; No more windows, try other buffer. |
| 788 | (setq cdabbrev-current-window t)))) |
| 789 | (if cdabbrev-current-window |
| 790 | (save-excursion |
| 791 | (set-cdabbrev-buffer) |
| 792 | (setq cdabbrev-current-point (point) |
| 793 | cdabbrev-start-point cdabbrev-current-point |
| 794 | cdabbrev-stop-point |
| 795 | (if completion-search-distance |
| 796 | (max (point-min) |
| 797 | (- cdabbrev-start-point completion-search-distance)) |
| 798 | (point-min)) |
| 799 | cdabbrev-wrapped-p nil)))) |
| 800 | |
| 801 | (defun next-cdabbrev () |
| 802 | "Return the next possible cdabbrev expansion or nil if there isn't one. |
| 803 | `reset-cdabbrev' must've been called already. |
| 804 | This is sensitive to `case-fold-search'." |
| 805 | ;; note that case-fold-search affects the behavior of this function |
| 806 | ;; Bug: won't pick up an expansion that starts at the top of buffer |
| 807 | (if cdabbrev-current-window |
| 808 | (let (saved-point |
| 809 | saved-syntax |
| 810 | (expansion nil) |
| 811 | downcase-expansion tried-list syntax saved-point-2) |
| 812 | (save-excursion |
| 813 | (unwind-protect |
| 814 | (progn |
| 815 | ;; Switch to current completion buffer |
| 816 | (set-cdabbrev-buffer) |
| 817 | ;; Save current buffer state |
| 818 | (setq saved-point (point) |
| 819 | saved-syntax (syntax-table)) |
| 820 | ;; Restore completion state |
| 821 | (set-syntax-table completion-syntax-table) |
| 822 | (goto-char cdabbrev-current-point) |
| 823 | ;; Loop looking for completions |
| 824 | (while |
| 825 | ;; This code returns t if it should loop again |
| 826 | (cond |
| 827 | (;; search for the string |
| 828 | (search-backward cdabbrev-abbrev-string cdabbrev-stop-point t) |
| 829 | ;; return nil if the completion is valid |
| 830 | (not |
| 831 | (and |
| 832 | ;; does it start with a separator char ? |
| 833 | (or (= (setq syntax (char-syntax (preceding-char))) ? ) |
| 834 | (and (= syntax ?w) |
| 835 | ;; symbol char to ignore at end. Are we at end ? |
| 836 | (progn |
| 837 | (setq saved-point-2 (point)) |
| 838 | (forward-word -1) |
| 839 | (prog1 |
| 840 | (= (char-syntax (preceding-char)) ? ) |
| 841 | (goto-char saved-point-2))))) |
| 842 | ;; is the symbol long enough ? |
| 843 | (setq expansion (symbol-under-point)) |
| 844 | ;; have we not tried this one before |
| 845 | (progn |
| 846 | ;; See if we've already used it |
| 847 | (setq tried-list cdabbrev-completions-tried |
| 848 | downcase-expansion (downcase expansion)) |
| 849 | (while (and tried-list |
| 850 | (not (string-equal downcase-expansion |
| 851 | (car tried-list)))) |
| 852 | ;; Already tried, don't choose this one |
| 853 | (setq tried-list (cdr tried-list))) |
| 854 | ;; at this point tried-list will be nil if this |
| 855 | ;; expansion has not yet been tried |
| 856 | (if tried-list |
| 857 | (setq expansion nil) |
| 858 | t))))) |
| 859 | ;; search failed |
| 860 | (cdabbrev-wrapped-p |
| 861 | ;; If already wrapped, then we've failed completely |
| 862 | nil) |
| 863 | (t |
| 864 | ;; need to wrap |
| 865 | (goto-char (setq cdabbrev-current-point |
| 866 | (if completion-search-distance |
| 867 | (min (point-max) (+ cdabbrev-start-point completion-search-distance)) |
| 868 | (point-max)))) |
| 869 | |
| 870 | (setq cdabbrev-wrapped-p t)))) |
| 871 | ;; end of while loop |
| 872 | (cond (expansion |
| 873 | ;; successful |
| 874 | (setq cdabbrev-completions-tried |
| 875 | (cons downcase-expansion cdabbrev-completions-tried) |
| 876 | cdabbrev-current-point (point))))) |
| 877 | (set-syntax-table saved-syntax) |
| 878 | (goto-char saved-point))) |
| 879 | ;; If no expansion, go to next window |
| 880 | (cond (expansion) |
| 881 | (t (reset-cdabbrev-window) |
| 882 | (next-cdabbrev)))))) |
| 883 | |
| 884 | ;; The following must be eval'd in the minibuffer :: |
| 885 | ;; (reset-cdabbrev "cdat") |
| 886 | ;; (next-cdabbrev) --> "cdat-simple" |
| 887 | ;; (next-cdabbrev) --> "cdat-1-2-3-4" |
| 888 | ;; (next-cdabbrev) --> "CDAT-UPCASE" |
| 889 | ;; (next-cdabbrev) --> "cdat-wrapping" |
| 890 | ;; (next-cdabbrev) --> "cdat_start_sym" |
| 891 | ;; (next-cdabbrev) --> nil |
| 892 | ;; (next-cdabbrev) --> nil |
| 893 | ;; (next-cdabbrev) --> nil |
| 894 | |
| 895 | ;; _cdat_start_sym |
| 896 | ;; cdat-wrapping |
| 897 | |
| 898 | \f |
| 899 | ;;--------------------------------------------------------------------------- |
| 900 | ;; Completion Database |
| 901 | ;;--------------------------------------------------------------------------- |
| 902 | |
| 903 | ;; We use two storage modes for the two search types :: |
| 904 | ;; 1) Prefix {cmpl-prefix-obarray} for looking up possible completions |
| 905 | ;; Used by search-completion-next |
| 906 | ;; the value of the symbol is nil or a cons of head and tail pointers |
| 907 | ;; 2) Interning {cmpl-obarray} to see if it's in the database |
| 908 | ;; Used by find-exact-completion, completion-in-database-p |
| 909 | ;; The value of the symbol is the completion entry |
| 910 | |
| 911 | ;; bad things may happen if this length is changed due to the way |
| 912 | ;; GNU implements obarrays |
| 913 | (defconst cmpl-obarray-length 511) |
| 914 | |
| 915 | (defvar cmpl-prefix-obarray (make-vector cmpl-obarray-length 0) |
| 916 | "An obarray used to store the downcased completion prefixes. |
| 917 | Each symbol is bound to a list of completion entries.") |
| 918 | |
| 919 | (defvar cmpl-obarray (make-vector cmpl-obarray-length 0) |
| 920 | "An obarray used to store the downcased completions. |
| 921 | Each symbol is bound to a single completion entry.") |
| 922 | |
| 923 | ;;----------------------------------------------- |
| 924 | ;; Completion Entry Structure Definition |
| 925 | ;;----------------------------------------------- |
| 926 | |
| 927 | ;; A completion entry is a LIST of string, prefix-symbol num-uses, and |
| 928 | ;; last-use-time (the time the completion was last used) |
| 929 | ;; last-use-time is t if the string should be kept permanently |
| 930 | ;; num-uses is incremented every time the completion is used. |
| 931 | |
| 932 | ;; We chose lists because (car foo) is faster than (aref foo 0) and the |
| 933 | ;; creation time is about the same. |
| 934 | |
| 935 | ;; READER MACROS |
| 936 | |
| 937 | (defmacro completion-string (completion-entry) |
| 938 | (list 'car completion-entry)) |
| 939 | |
| 940 | (defmacro completion-num-uses (completion-entry) |
| 941 | ;; "The number of times it has used. Used to decide whether to save |
| 942 | ;; it." |
| 943 | (list 'car (list 'cdr completion-entry))) |
| 944 | |
| 945 | (defmacro completion-last-use-time (completion-entry) |
| 946 | ;; "The time it was last used. In hours since origin. Used to decide |
| 947 | ;; whether to save it. t if one should always save it." |
| 948 | (list 'nth 2 completion-entry)) |
| 949 | |
| 950 | (defmacro completion-source (completion-entry) |
| 951 | (list 'nth 3 completion-entry)) |
| 952 | |
| 953 | ;; WRITER MACROS |
| 954 | (defmacro set-completion-string (completion-entry string) |
| 955 | (list 'setcar completion-entry string)) |
| 956 | |
| 957 | (defmacro set-completion-num-uses (completion-entry num-uses) |
| 958 | (list 'setcar (list 'cdr completion-entry) num-uses)) |
| 959 | |
| 960 | (defmacro set-completion-last-use-time (completion-entry last-use-time) |
| 961 | (list 'setcar (list 'cdr (list 'cdr completion-entry)) last-use-time)) |
| 962 | |
| 963 | ;; CONSTRUCTOR |
| 964 | (defun make-completion (string) |
| 965 | "Return a completion entry." |
| 966 | (list string 0 nil current-completion-source)) |
| 967 | |
| 968 | ;; Obsolete |
| 969 | ;;(defmacro cmpl-prefix-entry-symbol (completion-entry) |
| 970 | ;; (list 'car (list 'cdr completion-entry))) |
| 971 | |
| 972 | |
| 973 | \f |
| 974 | ;;----------------------------------------------- |
| 975 | ;; Prefix symbol entry definition |
| 976 | ;;----------------------------------------------- |
| 977 | ;; A cons of (head . tail) |
| 978 | |
| 979 | ;; READER Macros |
| 980 | |
| 981 | (defalias 'cmpl-prefix-entry-head 'car) |
| 982 | |
| 983 | (defalias 'cmpl-prefix-entry-tail 'cdr) |
| 984 | |
| 985 | ;; WRITER Macros |
| 986 | |
| 987 | (defmacro set-cmpl-prefix-entry-head (prefix-entry new-head) |
| 988 | (list 'setcar prefix-entry new-head)) |
| 989 | |
| 990 | (defmacro set-cmpl-prefix-entry-tail (prefix-entry new-tail) |
| 991 | (list 'setcdr prefix-entry new-tail)) |
| 992 | |
| 993 | ;; Constructor |
| 994 | |
| 995 | (defun make-cmpl-prefix-entry (completion-entry-list) |
| 996 | "Make a new prefix entry containing only completion-entry." |
| 997 | (cons completion-entry-list completion-entry-list)) |
| 998 | |
| 999 | ;;----------------------------------------------- |
| 1000 | ;; Completion Database - Utilities |
| 1001 | ;;----------------------------------------------- |
| 1002 | |
| 1003 | (defun clear-all-completions () |
| 1004 | "Initialize the completion storage. All existing completions are lost." |
| 1005 | (interactive) |
| 1006 | (setq cmpl-prefix-obarray (make-vector cmpl-obarray-length 0)) |
| 1007 | (setq cmpl-obarray (make-vector cmpl-obarray-length 0)) |
| 1008 | (cmpl-statistics-block |
| 1009 | (record-clear-all-completions))) |
| 1010 | |
| 1011 | (defvar completions-list-return-value) |
| 1012 | |
| 1013 | (defun list-all-completions () |
| 1014 | "Return a list of all the known completion entries." |
| 1015 | (let ((completions-list-return-value nil)) |
| 1016 | (mapatoms 'list-all-completions-1 cmpl-prefix-obarray) |
| 1017 | completions-list-return-value)) |
| 1018 | |
| 1019 | (defun list-all-completions-1 (prefix-symbol) |
| 1020 | (if (boundp prefix-symbol) |
| 1021 | (setq completions-list-return-value |
| 1022 | (append (cmpl-prefix-entry-head (symbol-value prefix-symbol)) |
| 1023 | completions-list-return-value)))) |
| 1024 | |
| 1025 | (defun list-all-completions-by-hash-bucket () |
| 1026 | "Return list of lists of known completion entries, organized by hash bucket." |
| 1027 | (let ((completions-list-return-value nil)) |
| 1028 | (mapatoms 'list-all-completions-by-hash-bucket-1 cmpl-prefix-obarray) |
| 1029 | completions-list-return-value)) |
| 1030 | |
| 1031 | (defun list-all-completions-by-hash-bucket-1 (prefix-symbol) |
| 1032 | (if (boundp prefix-symbol) |
| 1033 | (setq completions-list-return-value |
| 1034 | (cons (cmpl-prefix-entry-head (symbol-value prefix-symbol)) |
| 1035 | completions-list-return-value)))) |
| 1036 | |
| 1037 | \f |
| 1038 | ;;----------------------------------------------- |
| 1039 | ;; Updating the database |
| 1040 | ;;----------------------------------------------- |
| 1041 | ;; |
| 1042 | ;; These are the internal functions used to update the datebase |
| 1043 | ;; |
| 1044 | ;; |
| 1045 | (defvar completion-to-accept nil |
| 1046 | "Set to a string that is pending its acceptance.") |
| 1047 | ;; this checked by the top level reading functions |
| 1048 | |
| 1049 | (defvar cmpl-db-downcase-string nil |
| 1050 | "Setup by `find-exact-completion', etc. The given string, downcased.") |
| 1051 | (defvar cmpl-db-symbol nil |
| 1052 | "The interned symbol corresponding to `cmpl-db-downcase-string'. |
| 1053 | Set up by `cmpl-db-symbol'.") |
| 1054 | (defvar cmpl-db-prefix-symbol nil |
| 1055 | "The interned prefix symbol corresponding to `cmpl-db-downcase-string'.") |
| 1056 | (defvar cmpl-db-entry nil) |
| 1057 | (defvar cmpl-db-debug-p nil |
| 1058 | "Set to t if you want to debug the database.") |
| 1059 | |
| 1060 | ;; READS |
| 1061 | (defun find-exact-completion (string) |
| 1062 | "Return the completion entry for STRING or nil. |
| 1063 | Sets up `cmpl-db-downcase-string' and `cmpl-db-symbol'." |
| 1064 | (and (boundp (setq cmpl-db-symbol |
| 1065 | (intern (setq cmpl-db-downcase-string (downcase string)) |
| 1066 | cmpl-obarray))) |
| 1067 | (symbol-value cmpl-db-symbol))) |
| 1068 | |
| 1069 | (defun find-cmpl-prefix-entry (prefix-string) |
| 1070 | "Return the prefix entry for string. |
| 1071 | Sets `cmpl-db-prefix-symbol'. |
| 1072 | Prefix-string must be exactly `completion-prefix-min-length' long |
| 1073 | and downcased. Sets up `cmpl-db-prefix-symbol'." |
| 1074 | (and (boundp (setq cmpl-db-prefix-symbol |
| 1075 | (intern prefix-string cmpl-prefix-obarray))) |
| 1076 | (symbol-value cmpl-db-prefix-symbol))) |
| 1077 | |
| 1078 | (defvar inside-locate-completion-entry nil) |
| 1079 | ;; used to trap lossage in silent error correction |
| 1080 | |
| 1081 | (defun locate-completion-entry (completion-entry prefix-entry) |
| 1082 | "Locate the completion entry. |
| 1083 | Returns a pointer to the element before the completion entry or nil if |
| 1084 | the completion entry is at the head. |
| 1085 | Must be called after `find-exact-completion'." |
| 1086 | (let ((prefix-list (cmpl-prefix-entry-head prefix-entry)) |
| 1087 | next-prefix-list) |
| 1088 | (cond |
| 1089 | ((not (eq (car prefix-list) completion-entry)) |
| 1090 | ;; not already at head |
| 1091 | (while (and prefix-list |
| 1092 | (not (eq completion-entry |
| 1093 | (car (setq next-prefix-list (cdr prefix-list)))))) |
| 1094 | (setq prefix-list next-prefix-list)) |
| 1095 | (cond (;; found |
| 1096 | prefix-list) |
| 1097 | ;; Didn't find it. Database is messed up. |
| 1098 | (cmpl-db-debug-p |
| 1099 | ;; not found, error if debug mode |
| 1100 | (error "Completion entry exists but not on prefix list - %s" |
| 1101 | completion-string)) |
| 1102 | (inside-locate-completion-entry |
| 1103 | ;; recursive error: really scrod |
| 1104 | (locate-completion-db-error)) |
| 1105 | (t |
| 1106 | ;; Patch out |
| 1107 | (set cmpl-db-symbol nil) |
| 1108 | ;; Retry |
| 1109 | (locate-completion-entry-retry completion-entry))))))) |
| 1110 | |
| 1111 | (defun locate-completion-entry-retry (old-entry) |
| 1112 | (let ((inside-locate-completion-entry t)) |
| 1113 | (add-completion (completion-string old-entry) |
| 1114 | (completion-num-uses old-entry) |
| 1115 | (completion-last-use-time old-entry)) |
| 1116 | (let* ((cmpl-entry (find-exact-completion (completion-string old-entry))) |
| 1117 | (pref-entry |
| 1118 | (if cmpl-entry |
| 1119 | (find-cmpl-prefix-entry |
| 1120 | (substring cmpl-db-downcase-string |
| 1121 | 0 completion-prefix-min-length))))) |
| 1122 | (if (and cmpl-entry pref-entry) |
| 1123 | ;; try again |
| 1124 | (locate-completion-entry cmpl-entry pref-entry) |
| 1125 | ;; still losing |
| 1126 | (locate-completion-db-error))))) |
| 1127 | |
| 1128 | (defun locate-completion-db-error () |
| 1129 | ;; recursive error: really scrod |
| 1130 | (error "Completion database corrupted. Try M-x clear-all-completions. Send bug report")) |
| 1131 | |
| 1132 | ;; WRITES |
| 1133 | (defun add-completion-to-tail-if-new (string) |
| 1134 | "If STRING is not in the database add it to appropriate prefix list. |
| 1135 | STRING is added to the end of the appropriate prefix list with |
| 1136 | num-uses = 0. The database is unchanged if it is there. STRING must be |
| 1137 | longer than `completion-prefix-min-length'. |
| 1138 | This must be very fast. |
| 1139 | Returns the completion entry." |
| 1140 | (or (find-exact-completion string) |
| 1141 | ;; not there |
| 1142 | (let (;; create an entry |
| 1143 | (entry (list (make-completion string))) |
| 1144 | ;; setup the prefix |
| 1145 | (prefix-entry (find-cmpl-prefix-entry |
| 1146 | (substring cmpl-db-downcase-string 0 |
| 1147 | completion-prefix-min-length)))) |
| 1148 | ;; The next two forms should happen as a unit (atomically) but |
| 1149 | ;; no fatal errors should result if that is not the case. |
| 1150 | (cond (prefix-entry |
| 1151 | ;; These two should be atomic, but nothing fatal will happen |
| 1152 | ;; if they're not. |
| 1153 | (setcdr (cmpl-prefix-entry-tail prefix-entry) entry) |
| 1154 | (set-cmpl-prefix-entry-tail prefix-entry entry)) |
| 1155 | (t |
| 1156 | (set cmpl-db-prefix-symbol (make-cmpl-prefix-entry entry)))) |
| 1157 | ;; statistics |
| 1158 | (cmpl-statistics-block |
| 1159 | (note-added-completion)) |
| 1160 | ;; set symbol |
| 1161 | (set cmpl-db-symbol (car entry))))) |
| 1162 | |
| 1163 | (defun add-completion-to-head (completion-string) |
| 1164 | "If COMPLETION-STRING is not in the database, add it to prefix list. |
| 1165 | We add COMPLETION-STRING to the head of the appropriate prefix list, |
| 1166 | or to the head of the list. |
| 1167 | COMPLETION-STRING must be longer than `completion-prefix-min-length'. |
| 1168 | Updates the saved string with the supplied string. |
| 1169 | This must be very fast. |
| 1170 | Returns the completion entry." |
| 1171 | ;; Handle pending acceptance |
| 1172 | (if completion-to-accept (accept-completion)) |
| 1173 | ;; test if already in database |
| 1174 | (if (setq cmpl-db-entry (find-exact-completion completion-string)) |
| 1175 | ;; found |
| 1176 | (let* ((prefix-entry (find-cmpl-prefix-entry |
| 1177 | (substring cmpl-db-downcase-string 0 |
| 1178 | completion-prefix-min-length))) |
| 1179 | (splice-ptr (locate-completion-entry cmpl-db-entry prefix-entry)) |
| 1180 | (cmpl-ptr (cdr splice-ptr))) |
| 1181 | ;; update entry |
| 1182 | (set-completion-string cmpl-db-entry completion-string) |
| 1183 | ;; move to head (if necessary) |
| 1184 | (cond (splice-ptr |
| 1185 | ;; These should all execute atomically but it is not fatal if |
| 1186 | ;; they don't. |
| 1187 | ;; splice it out |
| 1188 | (or (setcdr splice-ptr (cdr cmpl-ptr)) |
| 1189 | ;; fix up tail if necessary |
| 1190 | (set-cmpl-prefix-entry-tail prefix-entry splice-ptr)) |
| 1191 | ;; splice in at head |
| 1192 | (setcdr cmpl-ptr (cmpl-prefix-entry-head prefix-entry)) |
| 1193 | (set-cmpl-prefix-entry-head prefix-entry cmpl-ptr))) |
| 1194 | cmpl-db-entry) |
| 1195 | ;; not there |
| 1196 | (let (;; create an entry |
| 1197 | (entry (list (make-completion completion-string))) |
| 1198 | ;; setup the prefix |
| 1199 | (prefix-entry (find-cmpl-prefix-entry |
| 1200 | (substring cmpl-db-downcase-string 0 |
| 1201 | completion-prefix-min-length)))) |
| 1202 | (cond (prefix-entry |
| 1203 | ;; Splice in at head |
| 1204 | (setcdr entry (cmpl-prefix-entry-head prefix-entry)) |
| 1205 | (set-cmpl-prefix-entry-head prefix-entry entry)) |
| 1206 | (t |
| 1207 | ;; Start new prefix entry |
| 1208 | (set cmpl-db-prefix-symbol (make-cmpl-prefix-entry entry)))) |
| 1209 | ;; statistics |
| 1210 | (cmpl-statistics-block |
| 1211 | (note-added-completion)) |
| 1212 | ;; Add it to the symbol |
| 1213 | (set cmpl-db-symbol (car entry))))) |
| 1214 | |
| 1215 | (defun delete-completion (completion-string) |
| 1216 | "Delete the completion from the database. |
| 1217 | String must be longer than `completion-prefix-min-length'." |
| 1218 | ;; Handle pending acceptance |
| 1219 | (if completion-to-accept (accept-completion)) |
| 1220 | (if (setq cmpl-db-entry (find-exact-completion completion-string)) |
| 1221 | ;; found |
| 1222 | (let* ((prefix-entry (find-cmpl-prefix-entry |
| 1223 | (substring cmpl-db-downcase-string 0 |
| 1224 | completion-prefix-min-length))) |
| 1225 | (splice-ptr (locate-completion-entry cmpl-db-entry prefix-entry))) |
| 1226 | ;; delete symbol reference |
| 1227 | (set cmpl-db-symbol nil) |
| 1228 | ;; remove from prefix list |
| 1229 | (cond (splice-ptr |
| 1230 | ;; not at head |
| 1231 | (or (setcdr splice-ptr (cdr (cdr splice-ptr))) |
| 1232 | ;; fix up tail if necessary |
| 1233 | (set-cmpl-prefix-entry-tail prefix-entry splice-ptr))) |
| 1234 | (t |
| 1235 | ;; at head |
| 1236 | (or (set-cmpl-prefix-entry-head |
| 1237 | prefix-entry (cdr (cmpl-prefix-entry-head prefix-entry))) |
| 1238 | ;; List is now empty |
| 1239 | (set cmpl-db-prefix-symbol nil)))) |
| 1240 | (cmpl-statistics-block |
| 1241 | (note-completion-deleted))) |
| 1242 | (error "Unknown completion `%s'" completion-string))) |
| 1243 | |
| 1244 | ;; Tests -- |
| 1245 | ;; - Add and Find - |
| 1246 | ;; (add-completion-to-head "banana") --> ("banana" 0 nil 0) |
| 1247 | ;; (find-exact-completion "banana") --> ("banana" 0 nil 0) |
| 1248 | ;; (find-exact-completion "bana") --> nil |
| 1249 | ;; (car (find-cmpl-prefix-entry "ban")) --> (("banana" ...)) |
| 1250 | ;; (cdr (find-cmpl-prefix-entry "ban")) --> (("banana" ...)) |
| 1251 | ;; (add-completion-to-head "banish") --> ("banish" 0 nil 0) |
| 1252 | ;; (find-exact-completion "banish") --> ("banish" 0 nil 0) |
| 1253 | ;; (car (find-cmpl-prefix-entry "ban")) --> (("banish" ...) ("banana" ...)) |
| 1254 | ;; (cdr (find-cmpl-prefix-entry "ban")) --> (("banana" ...)) |
| 1255 | ;; (add-completion-to-head "banana") --> ("banana" 0 nil 0) |
| 1256 | ;; (car (find-cmpl-prefix-entry "ban")) --> (("banana" ...) ("banish" ...)) |
| 1257 | ;; (cdr (find-cmpl-prefix-entry "ban")) --> (("banish" ...)) |
| 1258 | ;; |
| 1259 | ;; - Deleting - |
| 1260 | ;; (add-completion-to-head "banner") --> ("banner" 0 nil 0) |
| 1261 | ;; (delete-completion "banner") |
| 1262 | ;; (find-exact-completion "banner") --> nil |
| 1263 | ;; (car (find-cmpl-prefix-entry "ban")) --> (("banana" ...) ("banish" ...)) |
| 1264 | ;; (cdr (find-cmpl-prefix-entry "ban")) --> (("banish" ...)) |
| 1265 | ;; (add-completion-to-head "banner") --> ("banner" 0 nil 0) |
| 1266 | ;; (delete-completion "banana") |
| 1267 | ;; (car (find-cmpl-prefix-entry "ban")) --> (("banner" ...) ("banish" ...)) |
| 1268 | ;; (cdr (find-cmpl-prefix-entry "ban")) --> (("banish" ...)) |
| 1269 | ;; (delete-completion "banner") |
| 1270 | ;; (delete-completion "banish") |
| 1271 | ;; (find-cmpl-prefix-entry "ban") --> nil |
| 1272 | ;; (delete-completion "banner") --> error |
| 1273 | ;; |
| 1274 | ;; - Tail - |
| 1275 | ;; (add-completion-to-tail-if-new "banana") --> ("banana" 0 nil 0) |
| 1276 | ;; (car (find-cmpl-prefix-entry "ban")) --> (("banana" ...)) |
| 1277 | ;; (cdr (find-cmpl-prefix-entry "ban")) --> (("banana" ...)) |
| 1278 | ;; (add-completion-to-tail-if-new "banish") --> ("banish" 0 nil 0) |
| 1279 | ;; (car (find-cmpl-prefix-entry "ban")) -->(("banana" ...) ("banish" ...)) |
| 1280 | ;; (cdr (find-cmpl-prefix-entry "ban")) -->(("banish" ...)) |
| 1281 | ;; |
| 1282 | |
| 1283 | \f |
| 1284 | ;;--------------------------------------------------------------------------- |
| 1285 | ;; Database Update :: Interface level routines |
| 1286 | ;;--------------------------------------------------------------------------- |
| 1287 | ;; |
| 1288 | ;; These lie on top of the database ref. functions but below the standard |
| 1289 | ;; user interface level |
| 1290 | |
| 1291 | |
| 1292 | (defun interactive-completion-string-reader (prompt) |
| 1293 | (let* ((default (symbol-under-or-before-point)) |
| 1294 | (new-prompt |
| 1295 | (if default |
| 1296 | (format "%s (default %s): " prompt default) |
| 1297 | (format "%s: " prompt))) |
| 1298 | (read (completing-read new-prompt cmpl-obarray))) |
| 1299 | (if (zerop (length read)) (setq read (or default ""))) |
| 1300 | (list read))) |
| 1301 | |
| 1302 | (defun check-completion-length (string) |
| 1303 | (if (< (length string) completion-min-length) |
| 1304 | (user-error "The string `%s' is too short to be saved as a completion" |
| 1305 | string) |
| 1306 | (list string))) |
| 1307 | |
| 1308 | (defun add-completion (string &optional num-uses last-use-time) |
| 1309 | "Add STRING to completion list, or move it to head of list. |
| 1310 | The completion is altered appropriately if NUM-USES and/or LAST-USE-TIME |
| 1311 | are specified." |
| 1312 | (interactive (interactive-completion-string-reader "Completion to add")) |
| 1313 | (check-completion-length string) |
| 1314 | (let* ((current-completion-source (if (called-interactively-p 'interactive) |
| 1315 | cmpl-source-interactive |
| 1316 | current-completion-source)) |
| 1317 | (entry (add-completion-to-head string))) |
| 1318 | |
| 1319 | (if num-uses (set-completion-num-uses entry num-uses)) |
| 1320 | (if last-use-time |
| 1321 | (set-completion-last-use-time entry last-use-time)))) |
| 1322 | |
| 1323 | (defun add-permanent-completion (string) |
| 1324 | "Add STRING if it isn't already listed, and mark it permanent." |
| 1325 | (interactive |
| 1326 | (interactive-completion-string-reader "Completion to add permanently")) |
| 1327 | (let ((current-completion-source (if (called-interactively-p 'interactive) |
| 1328 | cmpl-source-interactive |
| 1329 | current-completion-source))) |
| 1330 | (add-completion string nil t))) |
| 1331 | |
| 1332 | (defun kill-completion (string) |
| 1333 | (interactive (interactive-completion-string-reader "Completion to kill")) |
| 1334 | (check-completion-length string) |
| 1335 | (delete-completion string)) |
| 1336 | |
| 1337 | (defun accept-completion () |
| 1338 | "Accepts the pending completion in `completion-to-accept'. |
| 1339 | This bumps num-uses. Called by `add-completion-to-head' and |
| 1340 | `completion-search-reset'." |
| 1341 | (let ((string completion-to-accept) |
| 1342 | ;; if this is added afresh here, then it must be a cdabbrev |
| 1343 | (current-completion-source cmpl-source-cdabbrev) |
| 1344 | entry) |
| 1345 | (setq completion-to-accept nil) |
| 1346 | (setq entry (add-completion-to-head string)) |
| 1347 | (set-completion-num-uses entry (1+ (completion-num-uses entry))) |
| 1348 | (setq cmpl-completions-accepted-p t))) |
| 1349 | |
| 1350 | (defun use-completion-under-point () |
| 1351 | "Add the completion symbol underneath the point into the completion buffer." |
| 1352 | (let ((string (and enable-completion (symbol-under-point))) |
| 1353 | (current-completion-source cmpl-source-cursor-moves)) |
| 1354 | (if string (add-completion-to-head string)))) |
| 1355 | |
| 1356 | (defun use-completion-before-point () |
| 1357 | "Add the completion symbol before point into the completion buffer." |
| 1358 | (let ((string (and enable-completion (symbol-before-point))) |
| 1359 | (current-completion-source cmpl-source-cursor-moves)) |
| 1360 | (if string (add-completion-to-head string)))) |
| 1361 | |
| 1362 | (defun use-completion-under-or-before-point () |
| 1363 | "Add the completion symbol before point into the completion buffer." |
| 1364 | (let ((string (and enable-completion (symbol-under-or-before-point))) |
| 1365 | (current-completion-source cmpl-source-cursor-moves)) |
| 1366 | (if string (add-completion-to-head string)))) |
| 1367 | |
| 1368 | (defun use-completion-before-separator () |
| 1369 | "Add the completion symbol before point into the completion buffer. |
| 1370 | Completions added this way will automatically be saved if |
| 1371 | `completion-on-separator-character' is non-nil." |
| 1372 | (let ((string (and enable-completion (symbol-before-point))) |
| 1373 | (current-completion-source cmpl-source-separator) |
| 1374 | entry) |
| 1375 | (cmpl-statistics-block |
| 1376 | (note-separator-character string)) |
| 1377 | (cond (string |
| 1378 | (setq entry (add-completion-to-head string)) |
| 1379 | (if (and completion-on-separator-character |
| 1380 | (zerop (completion-num-uses entry))) |
| 1381 | (progn |
| 1382 | (set-completion-num-uses entry 1) |
| 1383 | (setq cmpl-completions-accepted-p t))))))) |
| 1384 | |
| 1385 | ;; Tests -- |
| 1386 | ;; - Add and Find - |
| 1387 | ;; (add-completion "banana" 5 10) |
| 1388 | ;; (find-exact-completion "banana") --> ("banana" 5 10 0) |
| 1389 | ;; (add-completion "banana" 6) |
| 1390 | ;; (find-exact-completion "banana") --> ("banana" 6 10 0) |
| 1391 | ;; (add-completion "banish") |
| 1392 | ;; (car (find-cmpl-prefix-entry "ban")) --> (("banish" ...) ("banana" ...)) |
| 1393 | ;; |
| 1394 | ;; - Accepting - |
| 1395 | ;; (setq completion-to-accept "banana") |
| 1396 | ;; (accept-completion) |
| 1397 | ;; (find-exact-completion "banana") --> ("banana" 7 10) |
| 1398 | ;; (car (find-cmpl-prefix-entry "ban")) --> (("banana" ...) ("banish" ...)) |
| 1399 | ;; (setq completion-to-accept "banish") |
| 1400 | ;; (add-completion "banner") |
| 1401 | ;; (car (find-cmpl-prefix-entry "ban")) |
| 1402 | ;; --> (("banner" ...) ("banish" 1 ...) ("banana" 7 ...)) |
| 1403 | ;; |
| 1404 | ;; - Deleting - |
| 1405 | ;; (kill-completion "banish") |
| 1406 | ;; (car (find-cmpl-prefix-entry "ban")) --> (("banner" ...) ("banana" ...)) |
| 1407 | |
| 1408 | \f |
| 1409 | ;;--------------------------------------------------------------------------- |
| 1410 | ;; Searching the database |
| 1411 | ;;--------------------------------------------------------------------------- |
| 1412 | ;; Functions outside this block must call completion-search-reset followed |
| 1413 | ;; by calls to completion-search-next or completion-search-peek |
| 1414 | ;; |
| 1415 | |
| 1416 | ;; Status variables |
| 1417 | ;; Commented out to improve loading speed |
| 1418 | (defvar cmpl-test-string "") |
| 1419 | ;; "The current string used by completion-search-next." |
| 1420 | (defvar cmpl-test-regexp "") |
| 1421 | ;; "The current regexp used by completion-search-next. |
| 1422 | ;; (derived from cmpl-test-string)" |
| 1423 | (defvar cmpl-last-index 0) |
| 1424 | ;; "The last index that completion-search-next was called with." |
| 1425 | (defvar cmpl-cdabbrev-reset-p nil) |
| 1426 | ;; "Set to t when cdabbrevs have been reset." |
| 1427 | (defvar cmpl-next-possibilities nil) |
| 1428 | ;; "A pointer to the element BEFORE the next set of possible completions. |
| 1429 | ;; cadr of this is the cmpl-next-possibility" |
| 1430 | (defvar cmpl-starting-possibilities nil) |
| 1431 | ;; "The initial list of starting possibilities." |
| 1432 | (defvar cmpl-next-possibility nil) |
| 1433 | ;; "The cached next possibility." |
| 1434 | (defvar cmpl-tried-list nil) |
| 1435 | ;; "A downcased list of all the completions we have tried." |
| 1436 | |
| 1437 | |
| 1438 | (defun completion-search-reset (string) |
| 1439 | "Set up the for completion searching for STRING. |
| 1440 | STRING must be longer than `completion-prefix-min-length'." |
| 1441 | (if completion-to-accept (accept-completion)) |
| 1442 | (setq cmpl-starting-possibilities |
| 1443 | (cmpl-prefix-entry-head |
| 1444 | (find-cmpl-prefix-entry |
| 1445 | (downcase (substring string 0 completion-prefix-min-length)))) |
| 1446 | cmpl-test-string string |
| 1447 | cmpl-test-regexp (concat (regexp-quote string) ".")) |
| 1448 | (completion-search-reset-1)) |
| 1449 | |
| 1450 | (defun completion-search-reset-1 () |
| 1451 | (setq cmpl-next-possibilities cmpl-starting-possibilities |
| 1452 | cmpl-next-possibility nil |
| 1453 | cmpl-cdabbrev-reset-p nil |
| 1454 | cmpl-last-index -1 |
| 1455 | cmpl-tried-list nil)) |
| 1456 | |
| 1457 | (defun completion-search-next (index) |
| 1458 | "Return the next completion entry. |
| 1459 | If INDEX is out of sequence, reset and start from the top. |
| 1460 | If there are no more entries, try cdabbrev and return only a string." |
| 1461 | (cond |
| 1462 | ((= index (setq cmpl-last-index (1+ cmpl-last-index))) |
| 1463 | (completion-search-peek t)) |
| 1464 | ((< index 0) |
| 1465 | (completion-search-reset-1) |
| 1466 | (setq cmpl-last-index index) |
| 1467 | ;; reverse the possibilities list |
| 1468 | (setq cmpl-next-possibilities (reverse cmpl-starting-possibilities)) |
| 1469 | ;; do a "normal" search |
| 1470 | (while (and (completion-search-peek nil) |
| 1471 | (< (setq index (1+ index)) 0)) |
| 1472 | (setq cmpl-next-possibility nil)) |
| 1473 | (cond ((not cmpl-next-possibilities)) |
| 1474 | ;; If no more possibilities, leave it that way |
| 1475 | ((= -1 cmpl-last-index) |
| 1476 | ;; next completion is at index 0. reset next-possibility list |
| 1477 | ;; to start at beginning |
| 1478 | (setq cmpl-next-possibilities cmpl-starting-possibilities)) |
| 1479 | (t |
| 1480 | ;; otherwise point to one before current |
| 1481 | (setq cmpl-next-possibilities |
| 1482 | (nthcdr (- (length cmpl-starting-possibilities) |
| 1483 | (length cmpl-next-possibilities)) |
| 1484 | cmpl-starting-possibilities))))) |
| 1485 | (t |
| 1486 | ;; non-negative index, reset and search |
| 1487 | ;;(prin1 'reset) |
| 1488 | (completion-search-reset-1) |
| 1489 | (setq cmpl-last-index index) |
| 1490 | (while (and (completion-search-peek t) |
| 1491 | (not (< (setq index (1- index)) 0))) |
| 1492 | (setq cmpl-next-possibility nil)))) |
| 1493 | (prog1 |
| 1494 | cmpl-next-possibility |
| 1495 | (setq cmpl-next-possibility nil))) |
| 1496 | |
| 1497 | |
| 1498 | (defun completion-search-peek (use-cdabbrev) |
| 1499 | "Return the next completion entry without actually moving the pointers. |
| 1500 | Calling this again or calling `completion-search-next' results in the same |
| 1501 | string being returned. Depends on `case-fold-search'. |
| 1502 | If there are no more entries, try cdabbrev and then return only a string." |
| 1503 | (cond |
| 1504 | ;; return the cached value if we have it |
| 1505 | (cmpl-next-possibility) |
| 1506 | ((and cmpl-next-possibilities |
| 1507 | ;; still a few possibilities left |
| 1508 | (progn |
| 1509 | (while |
| 1510 | (and (not (eq 0 (string-match cmpl-test-regexp |
| 1511 | (completion-string (car cmpl-next-possibilities))))) |
| 1512 | (setq cmpl-next-possibilities (cdr cmpl-next-possibilities)))) |
| 1513 | cmpl-next-possibilities)) |
| 1514 | ;; successful match |
| 1515 | (setq cmpl-next-possibility (car cmpl-next-possibilities) |
| 1516 | cmpl-tried-list (cons (downcase (completion-string cmpl-next-possibility)) |
| 1517 | cmpl-tried-list) |
| 1518 | cmpl-next-possibilities (cdr cmpl-next-possibilities)) |
| 1519 | cmpl-next-possibility) |
| 1520 | (use-cdabbrev |
| 1521 | ;; unsuccessful, use cdabbrev |
| 1522 | (cond ((not cmpl-cdabbrev-reset-p) |
| 1523 | (reset-cdabbrev cmpl-test-string cmpl-tried-list) |
| 1524 | (setq cmpl-cdabbrev-reset-p t))) |
| 1525 | (setq cmpl-next-possibility (next-cdabbrev))) |
| 1526 | ;; Completely unsuccessful, return nil |
| 1527 | )) |
| 1528 | |
| 1529 | ;; Tests -- |
| 1530 | ;; - Add and Find - |
| 1531 | ;; (add-completion "banana") |
| 1532 | ;; (completion-search-reset "ban") |
| 1533 | ;; (completion-search-next 0) --> "banana" |
| 1534 | ;; |
| 1535 | ;; - Discrimination - |
| 1536 | ;; (add-completion "cumberland") |
| 1537 | ;; (add-completion "cumberbund") |
| 1538 | ;; cumbering |
| 1539 | ;; (completion-search-reset "cumb") |
| 1540 | ;; (completion-search-peek t) --> "cumberbund" |
| 1541 | ;; (completion-search-next 0) --> "cumberbund" |
| 1542 | ;; (completion-search-peek t) --> "cumberland" |
| 1543 | ;; (completion-search-next 1) --> "cumberland" |
| 1544 | ;; (completion-search-peek nil) --> nil |
| 1545 | ;; (completion-search-next 2) --> "cumbering" {cdabbrev} |
| 1546 | ;; (completion-search-next 3) --> nil or "cumming"{depends on context} |
| 1547 | ;; (completion-search-next 1) --> "cumberland" |
| 1548 | ;; (completion-search-peek t) --> "cumbering" {cdabbrev} |
| 1549 | ;; |
| 1550 | ;; - Accepting - |
| 1551 | ;; (completion-search-next 1) --> "cumberland" |
| 1552 | ;; (setq completion-to-accept "cumberland") |
| 1553 | ;; (completion-search-reset "foo") |
| 1554 | ;; (completion-search-reset "cum") |
| 1555 | ;; (completion-search-next 0) --> "cumberland" |
| 1556 | ;; |
| 1557 | ;; - Deleting - |
| 1558 | ;; (kill-completion "cumberland") |
| 1559 | ;; cummings |
| 1560 | ;; (completion-search-reset "cum") |
| 1561 | ;; (completion-search-next 0) --> "cumberbund" |
| 1562 | ;; (completion-search-next 1) --> "cummings" |
| 1563 | ;; |
| 1564 | ;; - Ignoring Capitalization - |
| 1565 | ;; (completion-search-reset "CuMb") |
| 1566 | ;; (completion-search-next 0) --> "cumberbund" |
| 1567 | |
| 1568 | |
| 1569 | \f |
| 1570 | ;;----------------------------------------------- |
| 1571 | ;; COMPLETE |
| 1572 | ;;----------------------------------------------- |
| 1573 | |
| 1574 | (defun completion-mode () |
| 1575 | "Toggle whether or not to add new words to the completion database." |
| 1576 | (interactive) |
| 1577 | (setq enable-completion (not enable-completion)) |
| 1578 | (message "Completion mode is now %s." (if enable-completion "ON" "OFF"))) |
| 1579 | |
| 1580 | (defvar cmpl-current-index 0) |
| 1581 | (defvar cmpl-original-string nil) |
| 1582 | (defvar cmpl-last-insert-location -1) |
| 1583 | (defvar cmpl-leave-point-at-start nil) |
| 1584 | |
| 1585 | (defun complete (&optional arg) |
| 1586 | "Fill out a completion of the word before point. |
| 1587 | Point is left at end. Consecutive calls rotate through all possibilities. |
| 1588 | Prefix args :: |
| 1589 | control-u :: leave the point at the beginning of the completion rather |
| 1590 | than at the end. |
| 1591 | a number :: rotate through the possible completions by that amount |
| 1592 | `-' :: same as -1 (insert previous completion) |
| 1593 | {See the comments at the top of `completion.el' for more info.}" |
| 1594 | (interactive "*p") |
| 1595 | ;;; Set up variables |
| 1596 | (cond ((eq last-command this-command) |
| 1597 | ;; Undo last one |
| 1598 | (delete-region cmpl-last-insert-location (point)) |
| 1599 | ;; get next completion |
| 1600 | (setq cmpl-current-index (+ cmpl-current-index (or arg 1)))) |
| 1601 | (t |
| 1602 | (if (not cmpl-initialized-p) |
| 1603 | (completion-initialize)) ;; make sure everything's loaded |
| 1604 | (cond ((consp current-prefix-arg) ;; control-u |
| 1605 | (setq arg 0) |
| 1606 | (setq cmpl-leave-point-at-start t)) |
| 1607 | (t |
| 1608 | (setq cmpl-leave-point-at-start nil))) |
| 1609 | ;; get string |
| 1610 | (setq cmpl-original-string (symbol-before-point-for-complete)) |
| 1611 | (cond ((not cmpl-original-string) |
| 1612 | (setq this-command 'failed-complete) |
| 1613 | (error "To complete, point must be after a symbol at least %d character long" |
| 1614 | completion-prefix-min-length))) |
| 1615 | ;; get index |
| 1616 | (setq cmpl-current-index (if current-prefix-arg arg 0)) |
| 1617 | ;; statistics |
| 1618 | (cmpl-statistics-block |
| 1619 | (note-complete-entered-afresh cmpl-original-string)) |
| 1620 | ;; reset database |
| 1621 | (completion-search-reset cmpl-original-string) |
| 1622 | ;; erase what we've got |
| 1623 | (delete-region cmpl-symbol-start cmpl-symbol-end))) |
| 1624 | |
| 1625 | ;; point is at the point to insert the new symbol |
| 1626 | ;; Get the next completion |
| 1627 | (let* ((print-status-p |
| 1628 | (and (>= baud-rate completion-prompt-speed-threshold) |
| 1629 | (not (window-minibuffer-p (selected-window))))) |
| 1630 | (insert-point (point)) |
| 1631 | (entry (completion-search-next cmpl-current-index)) |
| 1632 | string) |
| 1633 | ;; entry is either a completion entry or a string (if cdabbrev) |
| 1634 | |
| 1635 | ;; If found, insert |
| 1636 | (cond (entry |
| 1637 | ;; Setup for proper case |
| 1638 | (setq string (if (stringp entry) |
| 1639 | entry (completion-string entry))) |
| 1640 | (setq string (cmpl-merge-string-cases |
| 1641 | string cmpl-original-string)) |
| 1642 | ;; insert |
| 1643 | (insert string) |
| 1644 | ;; accept it |
| 1645 | (setq completion-to-accept string) |
| 1646 | ;; fixup and cache point |
| 1647 | (cond (cmpl-leave-point-at-start |
| 1648 | (setq cmpl-last-insert-location (point)) |
| 1649 | (goto-char insert-point)) |
| 1650 | (t;; point at end, |
| 1651 | (setq cmpl-last-insert-location insert-point))) |
| 1652 | ;; statistics |
| 1653 | (cmpl-statistics-block |
| 1654 | (note-complete-inserted entry cmpl-current-index)) |
| 1655 | ;; Done ! cmpl-stat-complete-successful |
| 1656 | ;;display the next completion |
| 1657 | (cond |
| 1658 | ((and print-status-p |
| 1659 | ;; This updates the display and only prints if there |
| 1660 | ;; is no typeahead |
| 1661 | (sit-for 0) |
| 1662 | (setq entry |
| 1663 | (completion-search-peek |
| 1664 | completion-cdabbrev-prompt-flag))) |
| 1665 | (setq string (if (stringp entry) |
| 1666 | entry (completion-string entry))) |
| 1667 | (setq string (cmpl-merge-string-cases |
| 1668 | string cmpl-original-string)) |
| 1669 | (message "Next completion: %s" string)))) |
| 1670 | (t;; none found, insert old |
| 1671 | (insert cmpl-original-string) |
| 1672 | ;; Don't accept completions |
| 1673 | (setq completion-to-accept nil) |
| 1674 | ;; print message |
| 1675 | ;; This used to call cmpl19-sit-for, an undefined function. |
| 1676 | ;; I hope that sit-for does the right thing; I don't know -- rms. |
| 1677 | (if (and print-status-p (sit-for 0)) |
| 1678 | (message "No %scompletions." |
| 1679 | (if (eq this-command last-command) "more " ""))) |
| 1680 | ;; statistics |
| 1681 | (cmpl-statistics-block |
| 1682 | (record-complete-failed cmpl-current-index)) |
| 1683 | ;; Pretend that we were never here |
| 1684 | (setq this-command 'failed-complete))))) |
| 1685 | \f |
| 1686 | ;;--------------------------------------------------------------------------- |
| 1687 | ;; Parsing definitions from files into the database |
| 1688 | ;;--------------------------------------------------------------------------- |
| 1689 | |
| 1690 | ;;----------------------------------------------- |
| 1691 | ;; Top Level functions :: |
| 1692 | ;;----------------------------------------------- |
| 1693 | |
| 1694 | ;; User interface |
| 1695 | (defun add-completions-from-file (file) |
| 1696 | "Parse possible completions from a FILE and add them to database." |
| 1697 | (interactive "fFile: ") |
| 1698 | (setq file (expand-file-name file)) |
| 1699 | (let* ((buffer (get-file-buffer file)) |
| 1700 | (buffer-already-there-p buffer)) |
| 1701 | (if (not buffer-already-there-p) |
| 1702 | (let ((completions-merging-modes nil)) |
| 1703 | (setq buffer (find-file-noselect file)))) |
| 1704 | (unwind-protect |
| 1705 | (with-current-buffer buffer |
| 1706 | (add-completions-from-buffer)) |
| 1707 | (if (not buffer-already-there-p) |
| 1708 | (kill-buffer buffer))))) |
| 1709 | |
| 1710 | (defun add-completions-from-buffer () |
| 1711 | (interactive) |
| 1712 | (let ((current-completion-source cmpl-source-file-parsing) |
| 1713 | (start-num |
| 1714 | (cmpl-statistics-block |
| 1715 | (aref completion-add-count-vector cmpl-source-file-parsing))) |
| 1716 | mode) |
| 1717 | (cond ((memq major-mode '(emacs-lisp-mode lisp-mode)) |
| 1718 | (add-completions-from-lisp-buffer) |
| 1719 | (setq mode 'lisp)) |
| 1720 | ((memq major-mode '(c-mode)) |
| 1721 | (add-completions-from-c-buffer) |
| 1722 | (setq mode 'c)) |
| 1723 | (t |
| 1724 | (error "Cannot parse completions in %s buffers" |
| 1725 | major-mode))) |
| 1726 | (cmpl-statistics-block |
| 1727 | (record-cmpl-parse-file |
| 1728 | mode (point-max) |
| 1729 | (- (aref completion-add-count-vector cmpl-source-file-parsing) |
| 1730 | start-num))))) |
| 1731 | |
| 1732 | ;; Find file hook |
| 1733 | (defun completion-find-file-hook () |
| 1734 | (cond (enable-completion |
| 1735 | (cond ((and (memq major-mode '(emacs-lisp-mode lisp-mode)) |
| 1736 | (memq 'lisp completions-merging-modes)) |
| 1737 | (add-completions-from-buffer)) |
| 1738 | ((and (memq major-mode '(c-mode)) |
| 1739 | (memq 'c completions-merging-modes)) |
| 1740 | (add-completions-from-buffer)))))) |
| 1741 | |
| 1742 | ;;----------------------------------------------- |
| 1743 | ;; Tags Table Completions |
| 1744 | ;;----------------------------------------------- |
| 1745 | |
| 1746 | (defun add-completions-from-tags-table () |
| 1747 | ;; Inspired by eero@media-lab.media.mit.edu |
| 1748 | "Add completions from the current tags table." |
| 1749 | (interactive) |
| 1750 | (visit-tags-table-buffer) ;this will prompt if no tags-table |
| 1751 | (save-excursion |
| 1752 | (goto-char (point-min)) |
| 1753 | (let (string) |
| 1754 | (condition-case nil |
| 1755 | (while t |
| 1756 | (search-forward "\177") |
| 1757 | (backward-char 3) |
| 1758 | (and (setq string (symbol-under-point)) |
| 1759 | (add-completion-to-tail-if-new string)) |
| 1760 | (forward-char 3)) |
| 1761 | (search-failed))))) |
| 1762 | |
| 1763 | \f |
| 1764 | ;;----------------------------------------------- |
| 1765 | ;; Lisp File completion parsing |
| 1766 | ;;----------------------------------------------- |
| 1767 | ;; This merely looks for phrases beginning with (def.... or |
| 1768 | ;; (package:def ... and takes the next word. |
| 1769 | ;; |
| 1770 | ;; We tried using forward-lines and explicit searches but the regexp technique |
| 1771 | ;; was faster. (About 100K characters per second) |
| 1772 | ;; |
| 1773 | (defconst *lisp-def-regexp* |
| 1774 | "\n(\\(\\w*:\\)?def\\(\\w\\|\\s_\\)*\\s +(*" |
| 1775 | "A regexp that searches for Lisp definition form.") |
| 1776 | |
| 1777 | ;; Tests - |
| 1778 | ;; (and (string-match *lisp-def-regexp* "\n(defun foo") (match-end 0)) -> 8 |
| 1779 | ;; (and (string-match *lisp-def-regexp* "\n(si:def foo") (match-end 0)) -> 9 |
| 1780 | ;; (and (string-match *lisp-def-regexp* "\n(def-bar foo")(match-end 0)) -> 10 |
| 1781 | ;; (and (string-match *lisp-def-regexp* "\n(defun (foo") (match-end 0)) -> 9 |
| 1782 | |
| 1783 | ;; Parses all the definition names from a Lisp mode buffer and adds them to |
| 1784 | ;; the completion database. |
| 1785 | (defun add-completions-from-lisp-buffer () |
| 1786 | ;;; Benchmarks |
| 1787 | ;;; Sun-3/280 - 1500 to 3000 lines of lisp code per second |
| 1788 | (let (string) |
| 1789 | (save-excursion |
| 1790 | (goto-char (point-min)) |
| 1791 | (condition-case nil |
| 1792 | (while t |
| 1793 | (re-search-forward *lisp-def-regexp*) |
| 1794 | (and (setq string (symbol-under-point)) |
| 1795 | (add-completion-to-tail-if-new string))) |
| 1796 | (search-failed))))) |
| 1797 | |
| 1798 | \f |
| 1799 | ;;----------------------------------------------- |
| 1800 | ;; C file completion parsing |
| 1801 | ;;----------------------------------------------- |
| 1802 | ;; C : |
| 1803 | ;; Looks for #define or [<storage class>] [<type>] <name>{,<name>} |
| 1804 | ;; or structure, array or pointer defs. |
| 1805 | ;; It gets most of the definition names. |
| 1806 | ;; |
| 1807 | ;; As you might suspect by now, we use some symbol table hackery |
| 1808 | ;; |
| 1809 | ;; Symbol separator chars (have whitespace syntax) --> , ; * = ( |
| 1810 | ;; Opening char --> [ { |
| 1811 | ;; Closing char --> ] } |
| 1812 | ;; opening and closing must be skipped over |
| 1813 | ;; Whitespace chars (have symbol syntax) |
| 1814 | ;; Everything else has word syntax |
| 1815 | |
| 1816 | (defconst completion-c-def-syntax-table |
| 1817 | (let ((table (make-syntax-table)) |
| 1818 | (whitespace-chars '(? ?\n ?\t ?\f ?\v ?\r)) |
| 1819 | ;; unfortunately the ?( causes the parens to appear unbalanced |
| 1820 | (separator-chars '(?, ?* ?= ?\( ?\;)) |
| 1821 | i) |
| 1822 | ;; default syntax is whitespace |
| 1823 | (setq i 0) |
| 1824 | (while (< i 256) |
| 1825 | (modify-syntax-entry i "w" table) |
| 1826 | (setq i (1+ i))) |
| 1827 | (dolist (char whitespace-chars) |
| 1828 | (modify-syntax-entry char "_" table)) |
| 1829 | (dolist (char separator-chars) |
| 1830 | (modify-syntax-entry char " " table)) |
| 1831 | (modify-syntax-entry ?\[ "(]" table) |
| 1832 | (modify-syntax-entry ?\{ "(}" table) |
| 1833 | (modify-syntax-entry ?\] ")[" table) |
| 1834 | (modify-syntax-entry ?\} "){" table) |
| 1835 | table)) |
| 1836 | |
| 1837 | ;; Regexps |
| 1838 | (defconst *c-def-regexp* |
| 1839 | ;; This stops on lines with possible definitions |
| 1840 | "\n[_a-zA-Z#]" |
| 1841 | ;; This stops after the symbol to add. |
| 1842 | ;;"\n\\(#define\\s +.\\|\\(\\(\\w\\|\\s_\\)+\\b\\s *\\)+[(;,[*{=]\\)" |
| 1843 | ;; This stops before the symbol to add. {Test cases in parens. below} |
| 1844 | ;;"\n\\(\\(\\w\\|\\s_\\)+\\s *(\\|\\(\\(#define\\|auto\\|extern\\|register\\|static\\|int\\|long\\|short\\|unsigned\\|char\\|void\\|float\\|double\\|enum\\|struct\\|union\\|typedef\\)\\s +\\)+\\)" |
| 1845 | ;; this simple version picks up too much extraneous stuff |
| 1846 | ;; "\n\\(\\w\\|\\s_\\|#\\)\\B" |
| 1847 | "A regexp that searches for a definition form.") |
| 1848 | ; |
| 1849 | ;(defconst *c-cont-regexp* |
| 1850 | ; "\\(\\w\\|\\s_\\)+\\b\\s *\\({\\|\\(\\[[0-9\t ]*\\]\\s *\\)*,\\(*\\|\\s \\)*\\b\\)" |
| 1851 | ; "This regexp should be used in a looking-at to parse for lists of variables.") |
| 1852 | ; |
| 1853 | ;(defconst *c-struct-regexp* |
| 1854 | ; "\\(*\\|\\s \\)*\\b" |
| 1855 | ; "This regexp should be used to test whether a symbol follows a structure definition.") |
| 1856 | |
| 1857 | ;(defun test-c-def-regexp (regexp string) |
| 1858 | ; (and (eq 0 (string-match regexp string)) (match-end 0)) |
| 1859 | ; ) |
| 1860 | |
| 1861 | ;; Tests - |
| 1862 | ;; (test-c-def-regexp *c-def-regexp* "\n#define foo") -> 10 (9) |
| 1863 | ;; (test-c-def-regexp *c-def-regexp* "\nfoo (x, y) {") -> 6 (6) |
| 1864 | ;; (test-c-def-regexp *c-def-regexp* "\nint foo (x, y)") -> 10 (5) |
| 1865 | ;; (test-c-def-regexp *c-def-regexp* "\n int foo (x, y)") -> nil |
| 1866 | ;; (test-c-def-regexp *c-cont-regexp* "oo, bar") -> 4 |
| 1867 | ;; (test-c-def-regexp *c-cont-regexp* "oo, *bar") -> 5 |
| 1868 | ;; (test-c-def-regexp *c-cont-regexp* "a [5][6], bar") -> 10 |
| 1869 | ;; (test-c-def-regexp *c-cont-regexp* "oo(x,y)") -> nil |
| 1870 | ;; (test-c-def-regexp *c-cont-regexp* "a [6] ,\t bar") -> 9 |
| 1871 | ;; (test-c-def-regexp *c-cont-regexp* "oo {trout =1} my_carp;") -> 14 |
| 1872 | ;; (test-c-def-regexp *c-cont-regexp* "truct_p complex foon") -> nil |
| 1873 | |
| 1874 | ;; Parses all the definition names from a C mode buffer and adds them to the |
| 1875 | ;; completion database. |
| 1876 | (defun add-completions-from-c-buffer () |
| 1877 | ;; Benchmark -- |
| 1878 | ;; Sun 3/280-- 1250 lines/sec. |
| 1879 | |
| 1880 | (let (string next-point char) |
| 1881 | (save-excursion |
| 1882 | (goto-char (point-min)) |
| 1883 | (catch 'finish-add-completions |
| 1884 | (with-syntax-table completion-c-def-syntax-table |
| 1885 | (while t |
| 1886 | ;; we loop here only when scan-sexps fails |
| 1887 | ;; (i.e. unbalance exps.) |
| 1888 | (condition-case e |
| 1889 | (while t |
| 1890 | (re-search-forward *c-def-regexp*) |
| 1891 | (cond |
| 1892 | ((= (preceding-char) ?#) |
| 1893 | ;; preprocessor macro, see if it's one we handle |
| 1894 | (cond ((looking-at "\\(define\\|ifdef\\)\\>") |
| 1895 | ;; skip forward over definition symbol |
| 1896 | ;; and add it to database |
| 1897 | (and (forward-word 2) |
| 1898 | (setq string (symbol-before-point)) |
| 1899 | ;;(push string foo) |
| 1900 | (add-completion-to-tail-if-new string))))) |
| 1901 | (t |
| 1902 | ;; C definition |
| 1903 | (setq next-point (point)) |
| 1904 | (while (and |
| 1905 | next-point |
| 1906 | ;; scan to next separator char. |
| 1907 | (setq next-point (scan-sexps next-point 1))) |
| 1908 | ;; position the point on the word we want to add |
| 1909 | (goto-char next-point) |
| 1910 | (while (= (setq char (following-char)) ?*) |
| 1911 | ;; handle pointer ref |
| 1912 | ;; move to next separator char. |
| 1913 | (goto-char |
| 1914 | (setq next-point (scan-sexps (point) 1)))) |
| 1915 | (forward-word -1) |
| 1916 | ;; add to database |
| 1917 | (if (setq string (symbol-under-point)) |
| 1918 | ;; (push string foo) |
| 1919 | (add-completion-to-tail-if-new string) |
| 1920 | ;; Local TMC hack (useful for parsing paris.h) |
| 1921 | (if (and (looking-at "_AP") ;; "ansi prototype" |
| 1922 | (progn |
| 1923 | (forward-word -1) |
| 1924 | (setq string |
| 1925 | (symbol-under-point)))) |
| 1926 | (add-completion-to-tail-if-new string))) |
| 1927 | ;; go to next |
| 1928 | (goto-char next-point) |
| 1929 | ;; (push (format "%c" (following-char)) foo) |
| 1930 | (if (= (char-syntax char) ?\() |
| 1931 | ;; if on an opening delimiter, go to end |
| 1932 | (while (= (char-syntax char) ?\() |
| 1933 | (setq next-point (scan-sexps next-point 1) |
| 1934 | char (char-after next-point))) |
| 1935 | (or (= char ?,) |
| 1936 | ;; Current char is an end char. |
| 1937 | (setq next-point nil))))))) |
| 1938 | (search-failed ;;done |
| 1939 | (throw 'finish-add-completions t)) |
| 1940 | (error |
| 1941 | ;; Check for failure in scan-sexps |
| 1942 | (if (member (nth 1 e) |
| 1943 | '("Containing expression ends prematurely" |
| 1944 | "Unbalanced parentheses")) |
| 1945 | ;; unbalanced paren., keep going |
| 1946 | ;;(ding) |
| 1947 | (forward-line 1) |
| 1948 | (message "Error parsing C buffer for completions--please send bug report") |
| 1949 | (throw 'finish-add-completions t)))))))))) |
| 1950 | |
| 1951 | \f |
| 1952 | ;;--------------------------------------------------------------------------- |
| 1953 | ;; Init files |
| 1954 | ;;--------------------------------------------------------------------------- |
| 1955 | |
| 1956 | ;; The version of save-completions-to-file called at kill-emacs time. |
| 1957 | (defun kill-emacs-save-completions () |
| 1958 | (if (and save-completions-flag enable-completion cmpl-initialized-p) |
| 1959 | (cond |
| 1960 | ((not cmpl-completions-accepted-p) |
| 1961 | (message "Completions database has not changed - not writing.")) |
| 1962 | (t |
| 1963 | (save-completions-to-file)))) |
| 1964 | (cmpl-statistics-block (record-cmpl-kill-emacs))) |
| 1965 | |
| 1966 | ;; There is no point bothering to change this again |
| 1967 | ;; unless the package changes so much that it matters |
| 1968 | ;; for people that have saved completions. |
| 1969 | (defconst completion-version "11") |
| 1970 | |
| 1971 | (defconst saved-cmpl-file-header |
| 1972 | ";;; Completion Initialization file. |
| 1973 | ;; Version = %s |
| 1974 | ;; Format is (<string> . <last-use-time>) |
| 1975 | ;; <string> is the completion |
| 1976 | ;; <last-use-time> is the time the completion was last used |
| 1977 | ;; If it is t, the completion will never be pruned from the file. |
| 1978 | ;; Otherwise it is in hours since origin. |
| 1979 | \n") |
| 1980 | |
| 1981 | (defun completion-backup-filename (filename) |
| 1982 | (concat filename ".BAK")) |
| 1983 | |
| 1984 | (defun save-completions-to-file (&optional filename) |
| 1985 | "Save completions in init file FILENAME. |
| 1986 | If file name is not specified, use `save-completions-file-name'." |
| 1987 | (interactive) |
| 1988 | (setq filename (expand-file-name (or filename save-completions-file-name))) |
| 1989 | (if (file-writable-p filename) |
| 1990 | (progn |
| 1991 | (if (not cmpl-initialized-p) |
| 1992 | (completion-initialize)) ;; make sure everything's loaded |
| 1993 | (message "Saving completions to file %s" filename) |
| 1994 | |
| 1995 | (let* ((delete-old-versions t) |
| 1996 | (kept-old-versions 0) |
| 1997 | (kept-new-versions completions-file-versions-kept) |
| 1998 | last-use-time |
| 1999 | (current-time (cmpl-hours-since-origin)) |
| 2000 | (total-in-db 0) |
| 2001 | (total-perm 0) |
| 2002 | (total-saved 0) |
| 2003 | (backup-filename (completion-backup-filename filename))) |
| 2004 | |
| 2005 | (with-current-buffer (get-buffer-create " *completion-save-buffer*") |
| 2006 | (setq buffer-file-name filename) |
| 2007 | |
| 2008 | (if (not (verify-visited-file-modtime (current-buffer))) |
| 2009 | (progn |
| 2010 | ;; file has changed on disk. Bring us up-to-date |
| 2011 | (message "Completion file has changed. Merging. . .") |
| 2012 | (load-completions-from-file filename t) |
| 2013 | (message "Merging finished. Saving completions to file %s" filename))) |
| 2014 | |
| 2015 | ;; prepare the buffer to be modified |
| 2016 | (clear-visited-file-modtime) |
| 2017 | (erase-buffer) |
| 2018 | ;; (/ 1 0) |
| 2019 | (insert (format saved-cmpl-file-header completion-version)) |
| 2020 | (dolist (completion (list-all-completions)) |
| 2021 | (setq total-in-db (1+ total-in-db)) |
| 2022 | (setq last-use-time (completion-last-use-time completion)) |
| 2023 | ;; Update num uses and maybe write completion to a file |
| 2024 | (cond ((or;; Write to file if |
| 2025 | ;; permanent |
| 2026 | (and (eq last-use-time t) |
| 2027 | (setq total-perm (1+ total-perm))) |
| 2028 | ;; or if |
| 2029 | (if (> (completion-num-uses completion) 0) |
| 2030 | ;; it's been used |
| 2031 | (setq last-use-time current-time) |
| 2032 | ;; or it was saved before and |
| 2033 | (and last-use-time |
| 2034 | ;; save-completions-retention-time is nil |
| 2035 | (or (not save-completions-retention-time) |
| 2036 | ;; or time since last use is < ...retention-time* |
| 2037 | (< (- current-time last-use-time) |
| 2038 | save-completions-retention-time))))) |
| 2039 | ;; write to file |
| 2040 | (setq total-saved (1+ total-saved)) |
| 2041 | (insert (prin1-to-string (cons (completion-string completion) |
| 2042 | last-use-time)) "\n")))) |
| 2043 | |
| 2044 | ;; write the buffer |
| 2045 | (condition-case nil |
| 2046 | (let ((file-exists-p (file-exists-p filename))) |
| 2047 | (if file-exists-p |
| 2048 | (progn |
| 2049 | ;; If file exists . . . |
| 2050 | ;; Save a backup(so GNU doesn't screw us when we're out of disk) |
| 2051 | ;; (GNU leaves a 0 length file if it gets a disk full error!) |
| 2052 | |
| 2053 | ;; If backup doesn't exit, Rename current to backup |
| 2054 | ;; {If backup exists the primary file is probably messed up} |
| 2055 | (or (file-exists-p backup-filename) |
| 2056 | (rename-file filename backup-filename)) |
| 2057 | ;; Copy the backup back to the current name |
| 2058 | ;; (so versioning works) |
| 2059 | (copy-file backup-filename filename t))) |
| 2060 | ;; Save it |
| 2061 | (save-buffer) |
| 2062 | (if file-exists-p |
| 2063 | ;; If successful, remove backup |
| 2064 | (delete-file backup-filename))) |
| 2065 | (error |
| 2066 | (set-buffer-modified-p nil) |
| 2067 | (message "Couldn't save completion file `%s'" filename))) |
| 2068 | ;; Reset accepted-p flag |
| 2069 | (setq cmpl-completions-accepted-p nil) ) |
| 2070 | (cmpl-statistics-block |
| 2071 | (record-save-completions total-in-db total-perm total-saved)))))) |
| 2072 | |
| 2073 | ;;(defun auto-save-completions () |
| 2074 | ;; (if (and save-completions-flag enable-completion cmpl-initialized-p |
| 2075 | ;; *completion-auto-save-period* |
| 2076 | ;; (> cmpl-emacs-idle-time *completion-auto-save-period*) |
| 2077 | ;; cmpl-completions-accepted-p) |
| 2078 | ;; (save-completions-to-file))) |
| 2079 | |
| 2080 | ;;(add-hook 'cmpl-emacs-idle-time-hooks 'auto-save-completions) |
| 2081 | |
| 2082 | (defun load-completions-from-file (&optional filename no-message-p) |
| 2083 | "Load a completion init file FILENAME. |
| 2084 | If file is not specified, then use `save-completions-file-name'." |
| 2085 | (interactive) |
| 2086 | (setq filename (expand-file-name (or filename save-completions-file-name))) |
| 2087 | (let* ((backup-filename (completion-backup-filename filename)) |
| 2088 | (backup-readable-p (file-readable-p backup-filename))) |
| 2089 | (if backup-readable-p (setq filename backup-filename)) |
| 2090 | (if (file-readable-p filename) |
| 2091 | (progn |
| 2092 | (if (not no-message-p) |
| 2093 | (message "Loading completions from %sfile %s . . ." |
| 2094 | (if backup-readable-p "backup " "") filename)) |
| 2095 | (with-current-buffer (get-buffer-create " *completion-save-buffer*") |
| 2096 | (setq buffer-file-name filename) |
| 2097 | ;; prepare the buffer to be modified |
| 2098 | (clear-visited-file-modtime) |
| 2099 | (erase-buffer) |
| 2100 | |
| 2101 | (let ((insert-okay-p nil) |
| 2102 | (buffer (current-buffer)) |
| 2103 | string entry last-use-time |
| 2104 | cmpl-entry cmpl-last-use-time |
| 2105 | (current-completion-source cmpl-source-init-file) |
| 2106 | (start-num |
| 2107 | (cmpl-statistics-block |
| 2108 | (aref completion-add-count-vector cmpl-source-file-parsing))) |
| 2109 | (total-in-file 0) (total-perm 0)) |
| 2110 | ;; insert the file into a buffer |
| 2111 | (condition-case nil |
| 2112 | (progn (insert-file-contents filename t) |
| 2113 | (setq insert-okay-p t)) |
| 2114 | |
| 2115 | (file-error |
| 2116 | (message "File error trying to load completion file %s." |
| 2117 | filename))) |
| 2118 | ;; parse it |
| 2119 | (if insert-okay-p |
| 2120 | (progn |
| 2121 | (goto-char (point-min)) |
| 2122 | |
| 2123 | (condition-case nil |
| 2124 | (while t |
| 2125 | (setq entry (read buffer)) |
| 2126 | (setq total-in-file (1+ total-in-file)) |
| 2127 | (cond |
| 2128 | ((and (consp entry) |
| 2129 | (stringp (setq string (car entry))) |
| 2130 | (cond |
| 2131 | ((eq (setq last-use-time (cdr entry)) 'T) |
| 2132 | ;; handle case sensitivity |
| 2133 | (setq total-perm (1+ total-perm)) |
| 2134 | (setq last-use-time t)) |
| 2135 | ((eq last-use-time t) |
| 2136 | (setq total-perm (1+ total-perm))) |
| 2137 | ((integerp last-use-time)))) |
| 2138 | ;; Valid entry |
| 2139 | ;; add it in |
| 2140 | (setq cmpl-last-use-time |
| 2141 | (completion-last-use-time |
| 2142 | (setq cmpl-entry |
| 2143 | (add-completion-to-tail-if-new string)))) |
| 2144 | (if (or (eq last-use-time t) |
| 2145 | (and (> last-use-time 1000);;backcompatibility |
| 2146 | (not (eq cmpl-last-use-time t)) |
| 2147 | (or (not cmpl-last-use-time) |
| 2148 | ;; more recent |
| 2149 | (> last-use-time cmpl-last-use-time)))) |
| 2150 | ;; update last-use-time |
| 2151 | (set-completion-last-use-time cmpl-entry last-use-time))) |
| 2152 | (t |
| 2153 | ;; Bad format |
| 2154 | (message "Error: invalid saved completion - %s" |
| 2155 | (prin1-to-string entry)) |
| 2156 | ;; try to get back in sync |
| 2157 | (search-forward "\n(")))) |
| 2158 | (search-failed |
| 2159 | (message "End of file while reading completions.")) |
| 2160 | (end-of-file |
| 2161 | (if (= (point) (point-max)) |
| 2162 | (if (not no-message-p) |
| 2163 | (message "Loading completions from file %s . . . Done." |
| 2164 | filename)) |
| 2165 | (message "End of file while reading completions.")))))) |
| 2166 | |
| 2167 | (cmpl-statistics-block |
| 2168 | (record-load-completions |
| 2169 | total-in-file total-perm |
| 2170 | (- (aref completion-add-count-vector cmpl-source-init-file) |
| 2171 | start-num))) |
| 2172 | )))))) |
| 2173 | |
| 2174 | (defun completion-initialize () |
| 2175 | "Load the default completions file. |
| 2176 | Also sets up so that exiting Emacs will automatically save the file." |
| 2177 | (interactive) |
| 2178 | (unless cmpl-initialized-p |
| 2179 | (load-completions-from-file) |
| 2180 | (setq cmpl-initialized-p t))) |
| 2181 | \f |
| 2182 | ;;----------------------------------------------- |
| 2183 | ;; Kill region patch |
| 2184 | ;;----------------------------------------------- |
| 2185 | |
| 2186 | (defun completion-kill-region (&optional beg end) |
| 2187 | "Kill between point and mark. |
| 2188 | The text is deleted but saved in the kill ring. |
| 2189 | The command \\[yank] can retrieve it from there. |
| 2190 | /(If you want to kill and then yank immediately, use \\[copy-region-as-kill].) |
| 2191 | |
| 2192 | This is the primitive for programs to kill text (as opposed to deleting it). |
| 2193 | Supply two arguments, character positions indicating the stretch of text |
| 2194 | to be killed. |
| 2195 | Any command that calls this function is a \"kill command\". |
| 2196 | If the previous command was also a kill command, |
| 2197 | the text killed this time appends to the text killed last time |
| 2198 | to make one entry in the kill ring. |
| 2199 | Patched to remove the most recent completion." |
| 2200 | (interactive "r") |
| 2201 | (cond ((eq last-command 'complete) |
| 2202 | (delete-region (point) cmpl-last-insert-location) |
| 2203 | (insert cmpl-original-string) |
| 2204 | (setq completion-to-accept nil) |
| 2205 | (cmpl-statistics-block |
| 2206 | (record-complete-failed))) |
| 2207 | (t |
| 2208 | (kill-region beg end)))) |
| 2209 | |
| 2210 | \f |
| 2211 | ;;----------------------------------------------- |
| 2212 | ;; Patches to self-insert-command. |
| 2213 | ;;----------------------------------------------- |
| 2214 | |
| 2215 | ;; Need 2 versions: generic separator chars. and space (to get auto fill |
| 2216 | ;; to work) |
| 2217 | |
| 2218 | ;; All common separators (eg. space "(" ")" """) characters go through a |
| 2219 | ;; function to add new words to the list of words to complete from: |
| 2220 | ;; COMPLETION-SEPARATOR-SELF-INSERT-COMMAND (arg). |
| 2221 | ;; If the character before this was an alpha-numeric then this adds the |
| 2222 | ;; symbol before point to the completion list (using ADD-COMPLETION). |
| 2223 | |
| 2224 | (defun completion-separator-self-insert-command (arg) |
| 2225 | (interactive "p") |
| 2226 | (if (command-remapping 'self-insert-command) |
| 2227 | (funcall (command-remapping 'self-insert-command) arg) |
| 2228 | (use-completion-before-separator) |
| 2229 | (self-insert-command arg))) |
| 2230 | |
| 2231 | (defun completion-separator-self-insert-autofilling (arg) |
| 2232 | (interactive "p") |
| 2233 | (if (command-remapping 'self-insert-command) |
| 2234 | (funcall (command-remapping 'self-insert-command) arg) |
| 2235 | (use-completion-before-separator) |
| 2236 | (self-insert-command arg) |
| 2237 | (and auto-fill-function |
| 2238 | (funcall auto-fill-function)))) |
| 2239 | |
| 2240 | ;;----------------------------------------------- |
| 2241 | ;; Wrapping Macro |
| 2242 | ;;----------------------------------------------- |
| 2243 | |
| 2244 | ;; Note that because of the way byte compiling works, none of |
| 2245 | ;; the functions defined with this macro get byte compiled. |
| 2246 | |
| 2247 | (defun completion-def-wrapper (function-name type) |
| 2248 | "Add a call to update the completion database before function execution. |
| 2249 | TYPE is the type of the wrapper to be added. Can be :before or :under." |
| 2250 | (put function-name 'completion-function |
| 2251 | (cdr (assq type |
| 2252 | '((:separator . use-completion-before-separator) |
| 2253 | (:before . use-completion-before-point) |
| 2254 | (:backward-under . use-completion-backward-under) |
| 2255 | (:backward . use-completion-backward) |
| 2256 | (:under . use-completion-under-point) |
| 2257 | (:under-or-before . use-completion-under-or-before-point) |
| 2258 | (:minibuffer-separator |
| 2259 | . use-completion-minibuffer-separator)))))) |
| 2260 | |
| 2261 | (defun use-completion-minibuffer-separator () |
| 2262 | (let ((completion-syntax-table completion-standard-syntax-table)) |
| 2263 | (use-completion-before-separator))) |
| 2264 | |
| 2265 | (defun use-completion-backward-under () |
| 2266 | (use-completion-under-point) |
| 2267 | (if (eq last-command 'complete) |
| 2268 | ;; probably a failed completion if you have to back up |
| 2269 | (cmpl-statistics-block (record-complete-failed)))) |
| 2270 | |
| 2271 | (defun use-completion-backward () |
| 2272 | (if (eq last-command 'complete) |
| 2273 | ;; probably a failed completion if you have to back up |
| 2274 | (cmpl-statistics-block (record-complete-failed)))) |
| 2275 | |
| 2276 | (defun completion-before-command () |
| 2277 | (funcall (or (and (symbolp this-command) |
| 2278 | (get this-command 'completion-function)) |
| 2279 | 'use-completion-under-or-before-point))) |
| 2280 | \f |
| 2281 | ;; Lisp mode diffs. |
| 2282 | |
| 2283 | (defconst completion-lisp-syntax-table |
| 2284 | (let ((table (copy-syntax-table completion-standard-syntax-table)) |
| 2285 | (symbol-chars '(?! ?& ?? ?= ?^))) |
| 2286 | (dolist (char symbol-chars) |
| 2287 | (modify-syntax-entry char "_" table)) |
| 2288 | table)) |
| 2289 | |
| 2290 | (defun completion-lisp-mode-hook () |
| 2291 | (setq completion-syntax-table completion-lisp-syntax-table) |
| 2292 | ;; Lisp Mode diffs |
| 2293 | (local-set-key "!" 'self-insert-command) |
| 2294 | (local-set-key "&" 'self-insert-command) |
| 2295 | (local-set-key "%" 'self-insert-command) |
| 2296 | (local-set-key "?" 'self-insert-command) |
| 2297 | (local-set-key "=" 'self-insert-command) |
| 2298 | (local-set-key "^" 'self-insert-command)) |
| 2299 | |
| 2300 | ;; C mode diffs. |
| 2301 | |
| 2302 | (defconst completion-c-syntax-table |
| 2303 | (let ((table (copy-syntax-table completion-standard-syntax-table)) |
| 2304 | (separator-chars '(?+ ?* ?/ ?: ?%))) |
| 2305 | (dolist (char separator-chars) |
| 2306 | (modify-syntax-entry char " " table)) |
| 2307 | table)) |
| 2308 | |
| 2309 | (completion-def-wrapper 'electric-c-semi :separator) |
| 2310 | (defun completion-c-mode-hook () |
| 2311 | (setq completion-syntax-table completion-c-syntax-table) |
| 2312 | (local-set-key "+" 'completion-separator-self-insert-command) |
| 2313 | (local-set-key "*" 'completion-separator-self-insert-command) |
| 2314 | (local-set-key "/" 'completion-separator-self-insert-command)) |
| 2315 | |
| 2316 | ;; FORTRAN mode diffs. (these are defined when fortran is called) |
| 2317 | |
| 2318 | (defconst completion-fortran-syntax-table |
| 2319 | (let ((table (copy-syntax-table completion-standard-syntax-table)) |
| 2320 | (separator-chars '(?+ ?- ?* ?/ ?:))) |
| 2321 | (dolist (char separator-chars) |
| 2322 | (modify-syntax-entry char " " table)) |
| 2323 | table)) |
| 2324 | |
| 2325 | (defun completion-setup-fortran-mode () |
| 2326 | (setq completion-syntax-table completion-fortran-syntax-table) |
| 2327 | (local-set-key "+" 'completion-separator-self-insert-command) |
| 2328 | (local-set-key "-" 'completion-separator-self-insert-command) |
| 2329 | (local-set-key "*" 'completion-separator-self-insert-command) |
| 2330 | (local-set-key "/" 'completion-separator-self-insert-command)) |
| 2331 | \f |
| 2332 | ;; Enable completion mode. |
| 2333 | |
| 2334 | (defvar fortran-mode-hook) |
| 2335 | |
| 2336 | (defvar completion-saved-bindings nil) |
| 2337 | |
| 2338 | ;;;###autoload |
| 2339 | (define-minor-mode dynamic-completion-mode |
| 2340 | "Toggle dynamic word-completion on or off. |
| 2341 | With a prefix argument ARG, enable the mode if ARG is positive, |
| 2342 | and disable it otherwise. If called from Lisp, enable the mode |
| 2343 | if ARG is omitted or nil." |
| 2344 | :global t |
| 2345 | ;; This is always good, not specific to dynamic-completion-mode. |
| 2346 | (define-key function-key-map [C-return] [?\C-\r]) |
| 2347 | |
| 2348 | (dolist (x '((find-file-hook . completion-find-file-hook) |
| 2349 | (pre-command-hook . completion-before-command) |
| 2350 | ;; Save completions when killing Emacs. |
| 2351 | (kill-emacs-hook . kill-emacs-save-completions) |
| 2352 | |
| 2353 | ;; Install the appropriate mode tables. |
| 2354 | (lisp-mode-hook . completion-lisp-mode-hook) |
| 2355 | (c-mode-hook . completion-c-mode-hook) |
| 2356 | (fortran-mode-hook . completion-setup-fortran-mode))) |
| 2357 | (if dynamic-completion-mode |
| 2358 | (add-hook (car x) (cdr x)) |
| 2359 | (remove-hook (car x) (cdr x)))) |
| 2360 | |
| 2361 | ;; "Complete" Key Keybindings. We don't want to use a minor-mode |
| 2362 | ;; map because these have too high a priority. We could/should |
| 2363 | ;; probably change the interpretation of minor-mode-map-alist such |
| 2364 | ;; that a map has lower precedence if the symbol is not buffer-local. |
| 2365 | (while completion-saved-bindings |
| 2366 | (let ((binding (pop completion-saved-bindings))) |
| 2367 | (global-set-key (car binding) (cdr binding)))) |
| 2368 | (when dynamic-completion-mode |
| 2369 | (dolist (binding |
| 2370 | '(("\M-\r" . complete) |
| 2371 | ([?\C-\r] . complete) |
| 2372 | |
| 2373 | ;; Tests - |
| 2374 | ;; (add-completion "cumberland") |
| 2375 | ;; (add-completion "cumberbund") |
| 2376 | ;; cum |
| 2377 | ;; Cumber |
| 2378 | ;; cumbering |
| 2379 | ;; cumb |
| 2380 | |
| 2381 | ;; Patches to standard keymaps insert completions |
| 2382 | ([remap kill-region] . completion-kill-region) |
| 2383 | |
| 2384 | ;; Separators |
| 2385 | ;; We've used the completion syntax table given as a guide. |
| 2386 | ;; |
| 2387 | ;; Global separator chars. |
| 2388 | ;; We left out <tab> because there are too many special |
| 2389 | ;; cases for it. Also, in normal coding it's rarely typed |
| 2390 | ;; after a word. |
| 2391 | (" " . completion-separator-self-insert-autofilling) |
| 2392 | ("!" . completion-separator-self-insert-command) |
| 2393 | ("%" . completion-separator-self-insert-command) |
| 2394 | ("^" . completion-separator-self-insert-command) |
| 2395 | ("&" . completion-separator-self-insert-command) |
| 2396 | ("(" . completion-separator-self-insert-command) |
| 2397 | (")" . completion-separator-self-insert-command) |
| 2398 | ("=" . completion-separator-self-insert-command) |
| 2399 | ("`" . completion-separator-self-insert-command) |
| 2400 | ("|" . completion-separator-self-insert-command) |
| 2401 | ("{" . completion-separator-self-insert-command) |
| 2402 | ("}" . completion-separator-self-insert-command) |
| 2403 | ("[" . completion-separator-self-insert-command) |
| 2404 | ("]" . completion-separator-self-insert-command) |
| 2405 | (";" . completion-separator-self-insert-command) |
| 2406 | ("\"". completion-separator-self-insert-command) |
| 2407 | ("'" . completion-separator-self-insert-command) |
| 2408 | ("#" . completion-separator-self-insert-command) |
| 2409 | ("," . completion-separator-self-insert-command) |
| 2410 | ("?" . completion-separator-self-insert-command) |
| 2411 | |
| 2412 | ;; We include period and colon even though they are symbol |
| 2413 | ;; chars because : |
| 2414 | ;; - in text we want to pick up the last word in a sentence. |
| 2415 | ;; - in C pointer refs. we want to pick up the first symbol |
| 2416 | ;; - it won't make a difference for lisp mode (package names |
| 2417 | ;; are short) |
| 2418 | ("." . completion-separator-self-insert-command) |
| 2419 | (":" . completion-separator-self-insert-command))) |
| 2420 | (push (cons (car binding) (lookup-key global-map (car binding))) |
| 2421 | completion-saved-bindings) |
| 2422 | (global-set-key (car binding) (cdr binding))) |
| 2423 | |
| 2424 | ;; Tests -- |
| 2425 | ;; foobarbiz |
| 2426 | ;; foobar |
| 2427 | ;; fooquux |
| 2428 | ;; fooper |
| 2429 | |
| 2430 | (cmpl-statistics-block |
| 2431 | (record-completion-file-loaded)) |
| 2432 | |
| 2433 | (completion-initialize))) |
| 2434 | |
| 2435 | ;;----------------------------------------------- |
| 2436 | ;; End of line chars. |
| 2437 | ;;----------------------------------------------- |
| 2438 | (completion-def-wrapper 'newline :separator) |
| 2439 | (completion-def-wrapper 'newline-and-indent :separator) |
| 2440 | (completion-def-wrapper 'comint-send-input :separator) |
| 2441 | (completion-def-wrapper 'exit-minibuffer :minibuffer-separator) |
| 2442 | (completion-def-wrapper 'eval-print-last-sexp :separator) |
| 2443 | (completion-def-wrapper 'eval-last-sexp :separator) |
| 2444 | ;;(completion-def-wrapper 'minibuffer-complete-and-exit :minibuffer) |
| 2445 | |
| 2446 | ;;----------------------------------------------- |
| 2447 | ;; Cursor movement |
| 2448 | ;;----------------------------------------------- |
| 2449 | |
| 2450 | (completion-def-wrapper 'next-line :under-or-before) |
| 2451 | (completion-def-wrapper 'previous-line :under-or-before) |
| 2452 | (completion-def-wrapper 'beginning-of-buffer :under-or-before) |
| 2453 | (completion-def-wrapper 'end-of-buffer :under-or-before) |
| 2454 | (completion-def-wrapper 'beginning-of-line :under-or-before) |
| 2455 | (completion-def-wrapper 'end-of-line :under-or-before) |
| 2456 | (completion-def-wrapper 'forward-char :under-or-before) |
| 2457 | (completion-def-wrapper 'forward-word :under-or-before) |
| 2458 | (completion-def-wrapper 'forward-sexp :under-or-before) |
| 2459 | (completion-def-wrapper 'backward-char :backward-under) |
| 2460 | (completion-def-wrapper 'backward-word :backward-under) |
| 2461 | (completion-def-wrapper 'backward-sexp :backward-under) |
| 2462 | |
| 2463 | (completion-def-wrapper 'delete-backward-char :backward) |
| 2464 | (completion-def-wrapper 'delete-backward-char-untabify :backward) |
| 2465 | |
| 2466 | ;; Old names, non-namespace-clean. |
| 2467 | (defvaralias 'cmpl-syntax-table 'completion-syntax-table) |
| 2468 | (defalias 'initialize-completions 'completion-initialize) |
| 2469 | |
| 2470 | (provide 'completion) |
| 2471 | |
| 2472 | ;;; completion.el ends here |