| 1 | ;;; icomplete.el --- minibuffer completion incremental feedback |
| 2 | |
| 3 | ;; Copyright (C) 1992, 1993, 1994, 1997, 1999, 2001, 2002, 2003, |
| 4 | ;; 2004, 2005, 2006 Free Software Foundation, Inc. |
| 5 | |
| 6 | ;; Author: Ken Manheimer <klm@i.am> |
| 7 | ;; Maintainer: Ken Manheimer <klm@i.am> |
| 8 | ;; Created: Mar 1993 Ken Manheimer, klm@nist.gov - first release to usenet |
| 9 | ;; Last update: Ken Manheimer <klm@i.am>, 11/18/1999. |
| 10 | ;; Keywords: help, abbrev |
| 11 | |
| 12 | ;; This file is part of GNU Emacs. |
| 13 | |
| 14 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 15 | ;; it under the terms of the GNU General Public License as published by |
| 16 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 17 | ;; any later version. |
| 18 | |
| 19 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 20 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 21 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 22 | ;; GNU General Public License for more details. |
| 23 | |
| 24 | ;; You should have received a copy of the GNU General Public License |
| 25 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 26 | ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor, |
| 27 | ;; Boston, MA 02110-1301, USA. |
| 28 | |
| 29 | ;;; Commentary: |
| 30 | |
| 31 | ;; Loading this package implements a more fine-grained minibuffer |
| 32 | ;; completion feedback scheme. Prospective completions are concisely |
| 33 | ;; indicated within the minibuffer itself, with each successive |
| 34 | ;; keystroke. |
| 35 | |
| 36 | ;; See `icomplete-completions' docstring for a description of the |
| 37 | ;; icomplete display format. |
| 38 | |
| 39 | ;; See the `icomplete-minibuffer-setup-hook' docstring for a means to |
| 40 | ;; customize icomplete setup for interoperation with other |
| 41 | ;; minibuffer-oriented packages. |
| 42 | |
| 43 | ;; To activate icomplete mode, load the package and use the |
| 44 | ;; `icomplete-mode' function. You can subsequently deactivate it by |
| 45 | ;; invoking the function icomplete-mode with a negative prefix-arg |
| 46 | ;; (C-U -1 ESC-x icomplete-mode). Also, you can prevent activation of |
| 47 | ;; the mode during package load by first setting the variable |
| 48 | ;; `icomplete-mode' to nil. Icompletion can be enabled any time after |
| 49 | ;; the package is loaded by invoking icomplete-mode without a prefix |
| 50 | ;; arg. |
| 51 | |
| 52 | ;; Thanks to everyone for their suggestions for refinements of this |
| 53 | ;; package. I particularly have to credit Michael Cook, who |
| 54 | ;; implemented an incremental completion style in his 'iswitch' |
| 55 | ;; functions that served as a model for icomplete. Some other |
| 56 | ;; contributors: Noah Friedman (restructuring as minor mode), Colin |
| 57 | ;; Rafferty (lemacs reconciliation), Lars Lindberg, RMS, and others. |
| 58 | |
| 59 | ;; klm. |
| 60 | |
| 61 | ;;; Code: |
| 62 | |
| 63 | ;;;_* Provide |
| 64 | (provide 'icomplete) |
| 65 | |
| 66 | |
| 67 | (defgroup icomplete nil |
| 68 | "Show completions dynamically in minibuffer." |
| 69 | :prefix "icomplete-" |
| 70 | :group 'minibuffer) |
| 71 | |
| 72 | ;;;_* User Customization variables |
| 73 | (defcustom icomplete-prospects-length 80 |
| 74 | "*Length of string displaying the prospects." |
| 75 | :type 'integer |
| 76 | :group 'icomplete) |
| 77 | |
| 78 | (defcustom icomplete-compute-delay .3 |
| 79 | "*Completions-computation stall, used only with large-number |
| 80 | completions - see `icomplete-delay-completions-threshold'." |
| 81 | :type 'number |
| 82 | :group 'icomplete) |
| 83 | |
| 84 | (defcustom icomplete-delay-completions-threshold 400 |
| 85 | "*Pending-completions number over which to apply icomplete-compute-delay." |
| 86 | :type 'integer |
| 87 | :group 'icomplete) |
| 88 | |
| 89 | (defcustom icomplete-max-delay-chars 3 |
| 90 | "*Maximum number of initial chars to apply icomplete compute delay." |
| 91 | :type 'integer |
| 92 | :group 'icomplete) |
| 93 | |
| 94 | (defcustom icomplete-show-key-bindings t |
| 95 | "*If non-nil, show key bindings as well as completion for sole matches." |
| 96 | :type 'boolean |
| 97 | :group 'icomplete) |
| 98 | |
| 99 | (defcustom icomplete-minibuffer-setup-hook nil |
| 100 | "*Icomplete-specific customization of minibuffer setup. |
| 101 | |
| 102 | This hook is run during minibuffer setup iff icomplete will be active. |
| 103 | It is intended for use in customizing icomplete for interoperation |
| 104 | with other features and packages. For instance: |
| 105 | |
| 106 | \(add-hook 'icomplete-minibuffer-setup-hook |
| 107 | \(function |
| 108 | \(lambda () |
| 109 | \(make-local-variable 'max-mini-window-height) |
| 110 | \(setq max-mini-window-height 3)))) |
| 111 | |
| 112 | will constrain Emacs to a maximum minibuffer height of 3 lines when |
| 113 | icompletion is occurring." |
| 114 | :type 'hook |
| 115 | :group 'icomplete) |
| 116 | |
| 117 | |
| 118 | ;;;_* Initialization |
| 119 | |
| 120 | ;;;_ + Internal Variables |
| 121 | ;;;_ = icomplete-eoinput nil |
| 122 | (defvar icomplete-eoinput nil |
| 123 | "Point where minibuffer input ends and completion info begins.") |
| 124 | (make-variable-buffer-local 'icomplete-eoinput) |
| 125 | ;;;_ = icomplete-pre-command-hook |
| 126 | (defvar icomplete-pre-command-hook nil |
| 127 | "Incremental-minibuffer-completion pre-command-hook. |
| 128 | |
| 129 | Is run in minibuffer before user input when `icomplete-mode' is non-nil. |
| 130 | Use `icomplete-mode' function to set it up properly for incremental |
| 131 | minibuffer completion.") |
| 132 | (add-hook 'icomplete-pre-command-hook 'icomplete-tidy) |
| 133 | ;;;_ = icomplete-post-command-hook |
| 134 | (defvar icomplete-post-command-hook nil |
| 135 | "Incremental-minibuffer-completion post-command-hook. |
| 136 | |
| 137 | Is run in minibuffer after user input when `icomplete-mode' is non-nil. |
| 138 | Use `icomplete-mode' function to set it up properly for incremental |
| 139 | minibuffer completion.") |
| 140 | (add-hook 'icomplete-post-command-hook 'icomplete-exhibit) |
| 141 | |
| 142 | (defun icomplete-get-keys (func-name) |
| 143 | "Return strings naming keys bound to `func-name', or nil if none. |
| 144 | Examines the prior, not current, buffer, presuming that current buffer |
| 145 | is minibuffer." |
| 146 | (if (commandp func-name) |
| 147 | (save-excursion |
| 148 | (let* ((sym (intern func-name)) |
| 149 | (buf (other-buffer)) |
| 150 | (map (save-excursion (set-buffer buf) (current-local-map))) |
| 151 | (keys (where-is-internal sym map))) |
| 152 | (if keys |
| 153 | (concat "<" |
| 154 | (mapconcat 'key-description |
| 155 | (sort keys |
| 156 | #'(lambda (x y) |
| 157 | (< (length x) (length y)))) |
| 158 | ", ") |
| 159 | ">")))))) |
| 160 | |
| 161 | ;;;_ > icomplete-mode (&optional prefix) |
| 162 | ;;;###autoload |
| 163 | (define-minor-mode icomplete-mode |
| 164 | "Toggle incremental minibuffer completion for this Emacs session. |
| 165 | With a numeric argument, turn Icomplete mode on iff ARG is positive." |
| 166 | :global t :group 'icomplete |
| 167 | (if icomplete-mode |
| 168 | ;; The following is not really necessary after first time - |
| 169 | ;; no great loss. |
| 170 | (add-hook 'minibuffer-setup-hook 'icomplete-minibuffer-setup) |
| 171 | (remove-hook 'minibuffer-setup-hook 'icomplete-minibuffer-setup))) |
| 172 | |
| 173 | ;;;_ > icomplete-simple-completing-p () |
| 174 | (defun icomplete-simple-completing-p () |
| 175 | "Non-nil if current window is minibuffer that's doing simple completion. |
| 176 | |
| 177 | Conditions are: |
| 178 | the selected window is a minibuffer, |
| 179 | and not in the middle of macro execution, |
| 180 | and `minibuffer-completion-table' is not a symbol (which would |
| 181 | indicate some non-standard, non-simple completion mechanism, |
| 182 | like file-name and other custom-func completions)." |
| 183 | |
| 184 | (and (window-minibuffer-p (selected-window)) |
| 185 | (not executing-kbd-macro) |
| 186 | minibuffer-completion-table |
| 187 | ;; (or minibuffer-completing-file-name |
| 188 | (not (functionp minibuffer-completion-table)))) ;; ) |
| 189 | |
| 190 | ;;;_ > icomplete-minibuffer-setup () |
| 191 | (defun icomplete-minibuffer-setup () |
| 192 | "Run in minibuffer on activation to establish incremental completion. |
| 193 | Usually run by inclusion in `minibuffer-setup-hook'." |
| 194 | (when (and icomplete-mode (icomplete-simple-completing-p)) |
| 195 | (add-hook 'pre-command-hook |
| 196 | (lambda () (run-hooks 'icomplete-pre-command-hook)) |
| 197 | nil t) |
| 198 | (add-hook 'post-command-hook |
| 199 | (lambda () (run-hooks 'icomplete-post-command-hook)) |
| 200 | nil t) |
| 201 | (run-hooks 'icomplete-minibuffer-setup-hook))) |
| 202 | ;\f |
| 203 | |
| 204 | |
| 205 | ;;;_* Completion |
| 206 | |
| 207 | ;;;_ > icomplete-tidy () |
| 208 | (defun icomplete-tidy () |
| 209 | "Remove completions display \(if any) prior to new user input. |
| 210 | Should be run in on the minibuffer `pre-command-hook'. See `icomplete-mode' |
| 211 | and `minibuffer-setup-hook'." |
| 212 | (when icomplete-eoinput |
| 213 | |
| 214 | (unless (>= icomplete-eoinput (point-max)) |
| 215 | (let ((buffer-undo-list t)) ; prevent entry |
| 216 | (delete-region icomplete-eoinput (point-max)))) |
| 217 | |
| 218 | ;; Reestablish the safe value. |
| 219 | (setq icomplete-eoinput nil))) |
| 220 | |
| 221 | ;;;_ > icomplete-exhibit () |
| 222 | (defun icomplete-exhibit () |
| 223 | "Insert icomplete completions display. |
| 224 | Should be run via minibuffer `post-command-hook'. See `icomplete-mode' |
| 225 | and `minibuffer-setup-hook'." |
| 226 | (when (icomplete-simple-completing-p) |
| 227 | (save-excursion |
| 228 | (goto-char (point-max)) |
| 229 | ;; Register the end of input, so we know where the extra stuff |
| 230 | ;; (match-status info) begins: |
| 231 | (setq icomplete-eoinput (point)) |
| 232 | ; Insert the match-status information: |
| 233 | (if (and (> (point-max) (minibuffer-prompt-end)) |
| 234 | buffer-undo-list ; Wait for some user input. |
| 235 | (or |
| 236 | ;; Don't bother with delay after certain number of chars: |
| 237 | (> (- (point) (field-beginning)) icomplete-max-delay-chars) |
| 238 | ;; Don't delay if alternatives number is small enough: |
| 239 | (and (sequencep minibuffer-completion-table) |
| 240 | (< (length minibuffer-completion-table) |
| 241 | icomplete-delay-completions-threshold)) |
| 242 | ;; Delay - give some grace time for next keystroke, before |
| 243 | ;; embarking on computing completions: |
| 244 | (sit-for icomplete-compute-delay))) |
| 245 | (let ((text (while-no-input |
| 246 | (list |
| 247 | (icomplete-completions |
| 248 | (field-string) |
| 249 | minibuffer-completion-table |
| 250 | minibuffer-completion-predicate |
| 251 | (not minibuffer-completion-confirm))))) |
| 252 | (buffer-undo-list t)) |
| 253 | ;; Do nothing if while-no-input was aborted. |
| 254 | (if (consp text) (insert (car text)))))))) |
| 255 | |
| 256 | ;;;_ > icomplete-completions (name candidates predicate require-match) |
| 257 | (defun icomplete-completions (name candidates predicate require-match) |
| 258 | "Identify prospective candidates for minibuffer completion. |
| 259 | |
| 260 | The display is updated with each minibuffer keystroke during |
| 261 | minibuffer completion. |
| 262 | |
| 263 | Prospective completion suffixes (if any) are displayed, bracketed by |
| 264 | one of \(), \[], or \{} pairs. The choice of brackets is as follows: |
| 265 | |
| 266 | \(...) - a single prospect is identified and matching is enforced, |
| 267 | \[...] - a single prospect is identified but matching is optional, or |
| 268 | \{...} - multiple prospects, separated by commas, are indicated, and |
| 269 | further input is required to distinguish a single one. |
| 270 | |
| 271 | The displays for unambiguous matches have ` [Matched]' appended |
| 272 | \(whether complete or not), or ` \[No matches]', if no eligible |
| 273 | matches exist. \(Keybindings for uniquely matched commands |
| 274 | are exhibited within the square braces.)" |
| 275 | |
| 276 | ;; 'all-completions' doesn't like empty |
| 277 | ;; minibuffer-completion-table's (ie: (nil)) |
| 278 | (if (and (listp candidates) (null (car candidates))) |
| 279 | (setq candidates nil)) |
| 280 | |
| 281 | (let ((comps (all-completions name candidates predicate)) |
| 282 | ; "-determined" - only one candidate |
| 283 | (open-bracket-determined (if require-match "(" "[")) |
| 284 | (close-bracket-determined (if require-match ")" "]"))) |
| 285 | ;; `concat'/`mapconcat' is the slow part. With the introduction of |
| 286 | ;; `icomplete-prospects-length', there is no need for `catch'/`throw'. |
| 287 | (if (null comps) (format " %sNo matches%s" |
| 288 | open-bracket-determined |
| 289 | close-bracket-determined) |
| 290 | (let* ((most-try (try-completion name (mapcar (function list) comps))) |
| 291 | (most (if (stringp most-try) most-try (car comps))) |
| 292 | (most-len (length most)) |
| 293 | (determ (and (> most-len (length name)) |
| 294 | (concat open-bracket-determined |
| 295 | (substring most (length name)) |
| 296 | close-bracket-determined))) |
| 297 | ;;"-prospects" - more than one candidate |
| 298 | (prospects-len 0) |
| 299 | prospects most-is-exact comp) |
| 300 | (if (eq most-try t) |
| 301 | (setq prospects nil) |
| 302 | (while (and comps (< prospects-len icomplete-prospects-length)) |
| 303 | (setq comp (substring (car comps) most-len) |
| 304 | comps (cdr comps)) |
| 305 | (cond ((string-equal comp "") (setq most-is-exact t)) |
| 306 | ((member comp prospects)) |
| 307 | (t (setq prospects (cons comp prospects) |
| 308 | prospects-len (+ (length comp) 1 prospects-len)))))) |
| 309 | (if prospects |
| 310 | (concat determ |
| 311 | "{" |
| 312 | (and most-is-exact ",") |
| 313 | (mapconcat 'identity |
| 314 | (sort prospects (function string-lessp)) |
| 315 | ",") |
| 316 | (and comps ",...") |
| 317 | "}") |
| 318 | (concat determ |
| 319 | " [Matched" |
| 320 | (let ((keys (and icomplete-show-key-bindings |
| 321 | (commandp (intern-soft most)) |
| 322 | (icomplete-get-keys most)))) |
| 323 | (if keys (concat "; " keys) "")) |
| 324 | "]")))))) |
| 325 | |
| 326 | ;;;_* Local emacs vars. |
| 327 | ;;;Local variables: |
| 328 | ;;;allout-layout: (-2 :) |
| 329 | ;;;End: |
| 330 | |
| 331 | ;; arch-tag: 339ec25a-0741-4eb6-be63-997532e89b0f |
| 332 | ;;; icomplete.el ends here |