| 1 | ;;; lisp.el --- Lisp editing commands for Emacs |
| 2 | |
| 3 | ;; Copyright (C) 1985, 1986, 1994 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Maintainer: FSF |
| 6 | ;; Keywords: lisp, languages |
| 7 | |
| 8 | ;; This file is part of GNU Emacs. |
| 9 | |
| 10 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 11 | ;; it under the terms of the GNU General Public License as published by |
| 12 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 13 | ;; any later version. |
| 14 | |
| 15 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 16 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 17 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 18 | ;; GNU General Public License for more details. |
| 19 | |
| 20 | ;; You should have received a copy of the GNU General Public License |
| 21 | ;; along with GNU Emacs; see the file COPYING. If not, write to |
| 22 | ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA. |
| 23 | |
| 24 | ;;; Commentary: |
| 25 | |
| 26 | ;; Lisp editing commands to go with Lisp major mode. |
| 27 | |
| 28 | ;;; Code: |
| 29 | |
| 30 | ;; Note that this variable is used by non-lisp modes too. |
| 31 | (defvar defun-prompt-regexp nil |
| 32 | "*Non-nil => regexp to ignore, before the character that starts a defun. |
| 33 | This is only necessary if the opening paren or brace is not in column 0. |
| 34 | See `beginning-of-defun'.") |
| 35 | (make-variable-buffer-local 'defun-prompt-regexp) |
| 36 | |
| 37 | (defvar parens-require-spaces t |
| 38 | "Non-nil => `insert-parentheses' should insert whitespace as needed.") |
| 39 | |
| 40 | (defun forward-sexp (&optional arg) |
| 41 | "Move forward across one balanced expression (sexp). |
| 42 | With argument, do it that many times. Negative arg -N means |
| 43 | move backward across N balanced expressions." |
| 44 | (interactive "p") |
| 45 | (or arg (setq arg 1)) |
| 46 | (goto-char (or (scan-sexps (point) arg) (buffer-end arg))) |
| 47 | (if (< arg 0) (backward-prefix-chars))) |
| 48 | |
| 49 | (defun backward-sexp (&optional arg) |
| 50 | "Move backward across one balanced expression (sexp). |
| 51 | With argument, do it that many times. Negative arg -N means |
| 52 | move forward across N balanced expressions." |
| 53 | (interactive "p") |
| 54 | (or arg (setq arg 1)) |
| 55 | (forward-sexp (- arg))) |
| 56 | |
| 57 | (defun mark-sexp (arg) |
| 58 | "Set mark ARG sexps from point. |
| 59 | The place mark goes is the same place \\[forward-sexp] would |
| 60 | move to with the same argument." |
| 61 | (interactive "p") |
| 62 | (push-mark |
| 63 | (save-excursion |
| 64 | (forward-sexp arg) |
| 65 | (point)) |
| 66 | nil t)) |
| 67 | |
| 68 | (defun forward-list (&optional arg) |
| 69 | "Move forward across one balanced group of parentheses. |
| 70 | With argument, do it that many times. |
| 71 | Negative arg -N means move backward across N groups of parentheses." |
| 72 | (interactive "p") |
| 73 | (or arg (setq arg 1)) |
| 74 | (goto-char (or (scan-lists (point) arg 0) (buffer-end arg)))) |
| 75 | |
| 76 | (defun backward-list (&optional arg) |
| 77 | "Move backward across one balanced group of parentheses. |
| 78 | With argument, do it that many times. |
| 79 | Negative arg -N means move forward across N groups of parentheses." |
| 80 | (interactive "p") |
| 81 | (or arg (setq arg 1)) |
| 82 | (forward-list (- arg))) |
| 83 | |
| 84 | (defun down-list (arg) |
| 85 | "Move forward down one level of parentheses. |
| 86 | With argument, do this that many times. |
| 87 | A negative argument means move backward but still go down a level. |
| 88 | In Lisp programs, an argument is required." |
| 89 | (interactive "p") |
| 90 | (let ((inc (if (> arg 0) 1 -1))) |
| 91 | (while (/= arg 0) |
| 92 | (goto-char (or (scan-lists (point) inc -1) (buffer-end arg))) |
| 93 | (setq arg (- arg inc))))) |
| 94 | |
| 95 | (defun backward-up-list (arg) |
| 96 | "Move backward out of one level of parentheses. |
| 97 | With argument, do this that many times. |
| 98 | A negative argument means move forward but still to a less deep spot. |
| 99 | In Lisp programs, an argument is required." |
| 100 | (interactive "p") |
| 101 | (up-list (- arg))) |
| 102 | |
| 103 | (defun up-list (arg) |
| 104 | "Move forward out of one level of parentheses. |
| 105 | With argument, do this that many times. |
| 106 | A negative argument means move backward but still to a less deep spot. |
| 107 | In Lisp programs, an argument is required." |
| 108 | (interactive "p") |
| 109 | (let ((inc (if (> arg 0) 1 -1))) |
| 110 | (while (/= arg 0) |
| 111 | (goto-char (or (scan-lists (point) inc 1) (buffer-end arg))) |
| 112 | (setq arg (- arg inc))))) |
| 113 | |
| 114 | (defun kill-sexp (arg) |
| 115 | "Kill the sexp (balanced expression) following the cursor. |
| 116 | With argument, kill that many sexps after the cursor. |
| 117 | Negative arg -N means kill N sexps before the cursor." |
| 118 | (interactive "p") |
| 119 | (let ((opoint (point))) |
| 120 | (forward-sexp arg) |
| 121 | (kill-region opoint (point)))) |
| 122 | |
| 123 | (defun backward-kill-sexp (arg) |
| 124 | "Kill the sexp (balanced expression) preceding the cursor. |
| 125 | With argument, kill that many sexps before the cursor. |
| 126 | Negative arg -N means kill N sexps after the cursor." |
| 127 | (interactive "p") |
| 128 | (kill-sexp (- arg))) |
| 129 | \f |
| 130 | (defun beginning-of-defun (&optional arg) |
| 131 | "Move backward to the beginning of a defun. |
| 132 | With argument, do it that many times. Negative arg -N |
| 133 | means move forward to Nth following beginning of defun. |
| 134 | Returns t unless search stops due to beginning or end of buffer. |
| 135 | |
| 136 | Normally a defun starts when there is an char with open-parenthesis |
| 137 | syntax at the beginning of a line. If `defun-prompt-regexp' is |
| 138 | non-nil, then a string which matches that regexp may precede the |
| 139 | open-parenthesis, and point ends up at the beginning of the line." |
| 140 | (interactive "p") |
| 141 | (and (beginning-of-defun-raw arg) |
| 142 | (progn (beginning-of-line) t))) |
| 143 | |
| 144 | (defun beginning-of-defun-raw (&optional arg) |
| 145 | "Move point to the character that starts a defun. |
| 146 | This is identical to beginning-of-defun, except that point does not move |
| 147 | to the beginning of the line when `defun-prompt-regexp' is non-nil." |
| 148 | (interactive "p") |
| 149 | (and arg (< arg 0) (not (eobp)) (forward-char 1)) |
| 150 | (and (re-search-backward (if defun-prompt-regexp |
| 151 | (concat "^\\s(\\|" |
| 152 | "\\(" defun-prompt-regexp "\\)\\s(") |
| 153 | "^\\s(") |
| 154 | nil 'move (or arg 1)) |
| 155 | (progn (goto-char (1- (match-end 0)))) t)) |
| 156 | |
| 157 | (defun buffer-end (arg) |
| 158 | (if (> arg 0) (point-max) (point-min))) |
| 159 | |
| 160 | (defun end-of-defun (&optional arg) |
| 161 | "Move forward to next end of defun. With argument, do it that many times. |
| 162 | Negative argument -N means move back to Nth preceding end of defun. |
| 163 | |
| 164 | An end of a defun occurs right after the close-parenthesis that matches |
| 165 | the open-parenthesis that starts a defun; see `beginning-of-defun'." |
| 166 | (interactive "p") |
| 167 | (if (or (null arg) (= arg 0)) (setq arg 1)) |
| 168 | (let ((first t)) |
| 169 | (while (and (> arg 0) (< (point) (point-max))) |
| 170 | (let ((pos (point)) npos) |
| 171 | (while (progn |
| 172 | (if (and first |
| 173 | (progn |
| 174 | (end-of-line 1) |
| 175 | (beginning-of-defun-raw 1))) |
| 176 | nil |
| 177 | (or (bobp) (forward-char -1)) |
| 178 | (beginning-of-defun-raw -1)) |
| 179 | (setq first nil) |
| 180 | (forward-list 1) |
| 181 | (skip-chars-forward " \t") |
| 182 | (if (looking-at "\\s<\\|\n") |
| 183 | (forward-line 1)) |
| 184 | (<= (point) pos)))) |
| 185 | (setq arg (1- arg))) |
| 186 | (while (< arg 0) |
| 187 | (let ((pos (point))) |
| 188 | (beginning-of-defun-raw 1) |
| 189 | (forward-sexp 1) |
| 190 | (forward-line 1) |
| 191 | (if (>= (point) pos) |
| 192 | (if (beginning-of-defun-raw 2) |
| 193 | (progn |
| 194 | (forward-list 1) |
| 195 | (skip-chars-forward " \t") |
| 196 | (if (looking-at "\\s<\\|\n") |
| 197 | (forward-line 1))) |
| 198 | (goto-char (point-min))))) |
| 199 | (setq arg (1+ arg))))) |
| 200 | |
| 201 | (defun mark-defun () |
| 202 | "Put mark at end of this defun, point at beginning. |
| 203 | The defun marked is the one that contains point or follows point." |
| 204 | (interactive) |
| 205 | (push-mark (point)) |
| 206 | (end-of-defun) |
| 207 | (push-mark (point) nil t) |
| 208 | (beginning-of-defun) |
| 209 | (re-search-backward "^\n" (- (point) 1) t)) |
| 210 | |
| 211 | (defun insert-parentheses (arg) |
| 212 | "Put parentheses around next ARG sexps. Leave point after open-paren. |
| 213 | No argument is equivalent to zero: just insert `()' and leave point between. |
| 214 | If `parens-require-spaces' is non-nil, this command also inserts a space |
| 215 | before and after, depending on the surrounding characters." |
| 216 | (interactive "P") |
| 217 | (if arg (setq arg (prefix-numeric-value arg)) |
| 218 | (setq arg 0)) |
| 219 | (or (eq arg 0) (skip-chars-forward " \t")) |
| 220 | (and parens-require-spaces |
| 221 | (not (bobp)) |
| 222 | (memq (char-syntax (preceding-char)) '(?w ?_ ?\) )) |
| 223 | (insert " ")) |
| 224 | (insert ?\() |
| 225 | (save-excursion |
| 226 | (or (eq arg 0) (forward-sexp arg)) |
| 227 | (insert ?\)) |
| 228 | (and parens-require-spaces |
| 229 | (not (eobp)) |
| 230 | (memq (char-syntax (following-char)) '(?w ?_ ?\( )) |
| 231 | (insert " ")))) |
| 232 | |
| 233 | (defun move-past-close-and-reindent () |
| 234 | "Move past next `)', delete indentation before it, then indent after it." |
| 235 | (interactive) |
| 236 | (up-list 1) |
| 237 | (forward-char -1) |
| 238 | (while (save-excursion ; this is my contribution |
| 239 | (let ((before-paren (point))) |
| 240 | (back-to-indentation) |
| 241 | (= (point) before-paren))) |
| 242 | (delete-indentation)) |
| 243 | (forward-char 1) |
| 244 | (newline-and-indent)) |
| 245 | \f |
| 246 | (defun lisp-complete-symbol () |
| 247 | "Perform completion on Lisp symbol preceding point. |
| 248 | Compare that symbol against the known Lisp symbols. |
| 249 | |
| 250 | The context determines which symbols are considered. |
| 251 | If the symbol starts just after an open-parenthesis, only symbols |
| 252 | with function definitions are considered. Otherwise, all symbols with |
| 253 | function definitions, values or properties are considered." |
| 254 | (interactive) |
| 255 | (let* ((end (point)) |
| 256 | (buffer-syntax (syntax-table)) |
| 257 | (beg (unwind-protect |
| 258 | (save-excursion |
| 259 | (set-syntax-table emacs-lisp-mode-syntax-table) |
| 260 | (backward-sexp 1) |
| 261 | (while (= (char-syntax (following-char)) ?\') |
| 262 | (forward-char 1)) |
| 263 | (point)) |
| 264 | (set-syntax-table buffer-syntax))) |
| 265 | (pattern (buffer-substring beg end)) |
| 266 | (predicate |
| 267 | (if (eq (char-after (1- beg)) ?\() |
| 268 | 'fboundp |
| 269 | (function (lambda (sym) |
| 270 | (or (boundp sym) (fboundp sym) |
| 271 | (symbol-plist sym)))))) |
| 272 | (completion (try-completion pattern obarray predicate))) |
| 273 | (cond ((eq completion t)) |
| 274 | ((null completion) |
| 275 | (message "Can't find completion for \"%s\"" pattern) |
| 276 | (ding)) |
| 277 | ((not (string= pattern completion)) |
| 278 | (delete-region beg end) |
| 279 | (insert completion)) |
| 280 | (t |
| 281 | (message "Making completion list...") |
| 282 | (let ((list (all-completions pattern obarray predicate)) |
| 283 | (completion-fixup-function |
| 284 | (function (lambda () (if (save-excursion |
| 285 | (goto-char (max (point-min) (- (point) 4))) |
| 286 | (looking-at " <f>")) |
| 287 | (forward-char -4)))))) |
| 288 | (or (eq predicate 'fboundp) |
| 289 | (let (new) |
| 290 | (while list |
| 291 | (setq new (cons (if (fboundp (intern (car list))) |
| 292 | (list (car list) " <f>") |
| 293 | (car list)) |
| 294 | new)) |
| 295 | (setq list (cdr list))) |
| 296 | (setq list (nreverse new)))) |
| 297 | (with-output-to-temp-buffer "*Completions*" |
| 298 | (display-completion-list list))) |
| 299 | (message "Making completion list...%s" "done"))))) |
| 300 | |
| 301 | ;;; lisp.el ends here |