| 1 | ;;; hilit-chg.el --- minor mode displaying buffer changes with special face |
| 2 | |
| 3 | ;; Copyright (C) 1998, 2000, 2002, 2003, 2004, |
| 4 | ;; 2005, 2006 Free Software Foundation, Inc. |
| 5 | |
| 6 | ;; Author: Richard Sharman <rsharman@pobox.com> |
| 7 | ;; Keywords: faces |
| 8 | |
| 9 | ;; This file is part of GNU Emacs. |
| 10 | |
| 11 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 12 | ;; it under the terms of the GNU General Public License as published by |
| 13 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 14 | ;; any later version. |
| 15 | |
| 16 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 17 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 18 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 19 | ;; GNU General Public License for more details. |
| 20 | |
| 21 | ;; You should have received a copy of the GNU General Public License |
| 22 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 23 | ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor, |
| 24 | ;; Boston, MA 02110-1301, USA. |
| 25 | |
| 26 | ;;; Commentary: |
| 27 | |
| 28 | ;; A minor mode: "Highlight Changes mode". |
| 29 | ;; |
| 30 | |
| 31 | ;; Highlight Changes mode has 2 submodes: active and passive. |
| 32 | ;; When active, changes to the buffer are displayed in a different face. |
| 33 | ;; When passive, any existing displayed changes are saved and new ones |
| 34 | ;; recorded but are not displayed differently. |
| 35 | ;; Why active and passive? Having the changes visible can be handy when you |
| 36 | ;; want the information but very distracting otherwise. So, you can keep |
| 37 | ;; Highlight Changes mode in passive state while you make your changes, toggle |
| 38 | ;; it on to active mode to see them, then toggle it back off to avoid |
| 39 | ;; distraction. |
| 40 | ;; |
| 41 | ;; When active, changes are displayed in the `highlight-changes' face. |
| 42 | ;; When text is deleted, the following character is displayed in the |
| 43 | ;; `highlight-changes-delete' face. |
| 44 | ;; |
| 45 | ;; |
| 46 | ;; You can "age" different sets of changes by using |
| 47 | ;; `highlight-changes-rotate-faces'. This rotates through a series |
| 48 | ;; of different faces, so you can distinguish "new" changes from "older" |
| 49 | ;; changes. You can customize these "rotated" faces in two ways. You can |
| 50 | ;; either explicitly define each face by customizing |
| 51 | ;; `highlight-changes-face-list'. If, however, the faces differ from |
| 52 | ;; the `highlight-changes' face only in the foreground color, you can simply set |
| 53 | ;; `highlight-changes-colors'. If `highlight-changes-face-list' is nil when |
| 54 | ;; the faces are required they will be constructed from |
| 55 | ;; `highlight-changes-colors'. |
| 56 | ;; |
| 57 | ;; |
| 58 | ;; When a Highlight Changes mode is on (either active or passive) you can go |
| 59 | ;; to the next or previous change with `highlight-changes-next-change' and |
| 60 | ;; `highlight-changes-previous-change'. |
| 61 | ;; |
| 62 | ;; |
| 63 | ;; You can also use the command highlight-compare-with-file to show changes |
| 64 | ;; in this file compared with another file (typically the previous version |
| 65 | ;; of the file). The command highlight-compare-buffers can be used to |
| 66 | ;; compare two buffers. |
| 67 | ;; |
| 68 | ;; |
| 69 | ;; There are currently three hooks run by `highlight-changes-mode': |
| 70 | ;; `highlight-changes-enable-hook' - is run when Highlight Changes mode |
| 71 | ;; is initially enabled for a buffer. |
| 72 | ;; `highlight-changes-disable-hook' - is run when Highlight Changes mode |
| 73 | ;; is turned off. |
| 74 | ;; `highlight-changes-toggle-hook' - is run each time `highlight-changes-mode' |
| 75 | ;; is called. Typically this is when |
| 76 | ;; toggling between active and passive |
| 77 | ;; modes. The variable |
| 78 | ;; `highlight-changes-mode' contains the new |
| 79 | ;; state (`active' or `passive'.) |
| 80 | ;; |
| 81 | ;; |
| 82 | ;; |
| 83 | ;; Example usage: |
| 84 | ;; (defun my-highlight-changes-enable-hook () |
| 85 | ;; (add-hook 'write-file-functions 'highlight-changes-rotate-faces nil t) |
| 86 | ;; ) |
| 87 | ;; |
| 88 | ;; (defun my-highlight-changes-disable-hook () |
| 89 | ;; (remove-hook 'write-file-functions 'highlight-changes-rotate-faces t) |
| 90 | ;; ) |
| 91 | ;; |
| 92 | ;; (add-hook 'highlight-changes-enable-hook 'my-highlight-changes-enable-hook) |
| 93 | ;; (add-hook 'highlight-changes-disable-hook |
| 94 | ;; 'my-highlight-changes-disable-hook) |
| 95 | |
| 96 | |
| 97 | ;; Explicit vs. Implicit |
| 98 | ;; |
| 99 | |
| 100 | ;; Normally, Highlight Changes mode is turned on explicitly in a buffer. |
| 101 | ;; |
| 102 | ;; If you prefer to have it automatically invoked you can do it as |
| 103 | ;; follows. |
| 104 | ;; |
| 105 | ;; 1. Most modes have a major-hook, typically called MODE-hook. You |
| 106 | ;; can use `add-hook' to call `highlight-changes-mode'. |
| 107 | ;; |
| 108 | ;; Example: |
| 109 | ;; (add-hook 'c-mode-hook 'highlight-changes-mode) |
| 110 | ;; |
| 111 | ;; If you want to make it start up in passive mode (regardless of the |
| 112 | ;; setting of highlight-changes-initial-state): |
| 113 | ;; (add-hook 'emacs-lisp-mode-hook |
| 114 | ;; (lambda () |
| 115 | ;; (highlight-changes-mode 'passive))) |
| 116 | ;; |
| 117 | ;; However, this cannot be done for Fundamental mode for there is no |
| 118 | ;; such hook. |
| 119 | ;; |
| 120 | ;; 2. You can use the function `global-highlight-changes' |
| 121 | ;; |
| 122 | ;; This function, which is fashioned after the way `global-font-lock' works, |
| 123 | ;; toggles on or off global Highlight Changes mode. When activated, it turns |
| 124 | ;; on Highlight Changes mode in all "suitable" existing buffers and will turn |
| 125 | ;; it on in new "suitable" buffers to be created. |
| 126 | ;; |
| 127 | ;; A buffer's "suitability" is determined by variable |
| 128 | ;; `highlight-changes-global-modes', as follows. If the variable is |
| 129 | ;; * nil -- then no buffers are suitable; |
| 130 | ;; * a function -- this function is called and the result is used. As |
| 131 | ;; an example, if the value is `buffer-file-name' then all buffers |
| 132 | ;; who are visiting files are suitable, but others (like dired |
| 133 | ;; buffers) are not; |
| 134 | ;; * a list -- then the buffer is suitable iff its mode is in the |
| 135 | ;; list, except if the first element is `not', in which case the test |
| 136 | ;; is reversed (i.e. it is a list of unsuitable modes). |
| 137 | ;; * Otherwise, the buffer is suitable if its name does not begin with |
| 138 | ;; ` ' or `*' and if `buffer-file-name' returns true. |
| 139 | ;; |
| 140 | |
| 141 | |
| 142 | |
| 143 | ;; Possible bindings: |
| 144 | ;; (global-set-key '[C-right] 'highlight-changes-next-change) |
| 145 | ;; (global-set-key '[C-left] 'highlight-changes-previous-change) |
| 146 | ;; |
| 147 | ;; Other interactive functions (which could be bound if desired): |
| 148 | ;; highlight-changes-mode |
| 149 | ;; highlight-changes-remove-highlight |
| 150 | ;; highlight-changes-rotate-faces |
| 151 | ;; highlight-compare-with-file |
| 152 | ;; highlight-compare-buffers |
| 153 | |
| 154 | ;; |
| 155 | ;; You can automatically rotate faces when the buffer is saved; |
| 156 | ;; see function `highlight-changes-rotate-faces' for how to do this. |
| 157 | ;; |
| 158 | |
| 159 | |
| 160 | ;;; Bugs: |
| 161 | |
| 162 | ;; - the next-change and previous-change functions are too literal; |
| 163 | ;; they should find the next "real" change, in other words treat |
| 164 | ;; consecutive changes as one. |
| 165 | |
| 166 | |
| 167 | ;;; To do (maybe), notes, ... |
| 168 | |
| 169 | ;; - having different faces for deletion and non-deletion: is it |
| 170 | ;; really worth the hassle? |
| 171 | ;; - should have better hooks: when should they be run? |
| 172 | ;; - highlight-compare-with-file should allow RCS files - e.g. nice to be |
| 173 | ;; able to say show changes compared with version 2.1. |
| 174 | ;; - Maybe we should have compare-with-buffer as well. (When I tried |
| 175 | ;; a while back I ran into a problem with ediff-buffers-internal.) |
| 176 | |
| 177 | |
| 178 | ;;; History: |
| 179 | |
| 180 | ;; R Sharman (rsharman@pobox.com) Feb 1998: |
| 181 | ;; - initial release as change-mode. |
| 182 | ;; Jari Aalto <jari.aalto@ntc.nokia.com> Mar 1998 |
| 183 | ;; - fixes for byte compile errors |
| 184 | ;; - use eval-and-compile for autoload |
| 185 | ;; Marijn Ros <J.M.Ros@fys.ruu.nl> Mar 98 |
| 186 | ;; - suggested turning it on by default |
| 187 | ;; Eric Ludlam <zappo@gnu.org> Suggested using overlays. |
| 188 | ;; July 98 |
| 189 | ;; - global mode and various stuff added |
| 190 | ;; - Changed to use overlays |
| 191 | ;; August 98 |
| 192 | ;; - renamed to Highlight Changes mode. |
| 193 | ;; Dec 2003 |
| 194 | ;; - Use require for ediff stuff |
| 195 | ;; - Added highlight-compare-buffers |
| 196 | |
| 197 | ;;; Code: |
| 198 | |
| 199 | (require 'wid-edit) |
| 200 | |
| 201 | ;; ====================== Customization ======================= |
| 202 | (defgroup highlight-changes nil |
| 203 | "Highlight Changes mode." |
| 204 | :version "20.4" |
| 205 | :group 'faces) |
| 206 | |
| 207 | |
| 208 | ;; Face information: How the changes appear. |
| 209 | |
| 210 | ;; Defaults for face: red foreground, no change to background, |
| 211 | ;; and underlined if a change is because of a deletion. |
| 212 | ;; Note: underlining is helpful in that it shows up changes in white space. |
| 213 | ;; However, having it set for non-delete changes can be annoying because all |
| 214 | ;; indentation on inserts gets underlined (which can look pretty ugly!). |
| 215 | |
| 216 | (defface highlight-changes |
| 217 | '((((min-colors 88) (class color)) (:foreground "red1")) |
| 218 | (((class color)) (:foreground "red" )) |
| 219 | (t (:inverse-video t))) |
| 220 | "Face used for highlighting changes." |
| 221 | :group 'highlight-changes) |
| 222 | ;; backward-compatibility alias |
| 223 | (put 'highlight-changes-face 'face-alias 'highlight-changes) |
| 224 | |
| 225 | ;; This looks pretty ugly, actually. Maybe the underline should be removed. |
| 226 | (defface highlight-changes-delete |
| 227 | '((((min-colors 88) (class color)) (:foreground "red1" :underline t)) |
| 228 | (((class color)) (:foreground "red" :underline t)) |
| 229 | (t (:inverse-video t))) |
| 230 | "Face used for highlighting deletions." |
| 231 | :group 'highlight-changes) |
| 232 | ;; backward-compatibility alias |
| 233 | (put 'highlight-changes-delete-face 'face-alias 'highlight-changes-delete) |
| 234 | |
| 235 | |
| 236 | |
| 237 | ;; A (not very good) default list of colors to rotate through. |
| 238 | ;; |
| 239 | (defcustom highlight-changes-colors |
| 240 | (if (eq (frame-parameter nil 'background-mode) 'light) |
| 241 | ;; defaults for light background: |
| 242 | '( "magenta" "blue" "darkgreen" "chocolate" "sienna4" "NavyBlue") |
| 243 | ;; defaults for dark background: |
| 244 | '("yellow" "magenta" "blue" "maroon" "firebrick" "green4" "DarkOrchid")) |
| 245 | "*Colors used by `highlight-changes-rotate-faces'. |
| 246 | The newest rotated change will be displayed in the first element of this list, |
| 247 | the next older will be in the second element etc. |
| 248 | |
| 249 | This list is used if `highlight-changes-face-list' is nil, otherwise that |
| 250 | variable overrides this list. If you only care about foreground |
| 251 | colors then use this, if you want fancier faces then set |
| 252 | `highlight-changes-face-list'." |
| 253 | :type '(repeat color) |
| 254 | :group 'highlight-changes) |
| 255 | |
| 256 | (define-obsolete-variable-alias 'highlight-changes-colours |
| 257 | 'highlight-changes-colors "22.1") |
| 258 | |
| 259 | |
| 260 | ;; If you invoke highlight-changes-mode with no argument, should it start in |
| 261 | ;; active or passive mode? |
| 262 | ;; |
| 263 | (defcustom highlight-changes-initial-state 'active |
| 264 | "*What state (active or passive) Highlight Changes mode should start in. |
| 265 | This is used when `highlight-changes-mode' is called with no argument. |
| 266 | This variable must be set to one of the symbols `active' or `passive'." |
| 267 | :type '(choice (const :tag "Active" active) |
| 268 | (const :tag "Passive" passive)) |
| 269 | :group 'highlight-changes) |
| 270 | |
| 271 | (defcustom highlight-changes-global-initial-state 'passive |
| 272 | "*What state global Highlight Changes mode should start in. |
| 273 | This is used if `global-highlight-changes' is called with no argument. |
| 274 | This variable must be set to either `active' or `passive'." |
| 275 | :type '(choice (const :tag "Active" active) |
| 276 | (const :tag "Passive" passive)) |
| 277 | :group 'highlight-changes) |
| 278 | |
| 279 | ;; The strings displayed in the mode-line for the minor mode: |
| 280 | (defcustom highlight-changes-active-string " +Chg" |
| 281 | "*The string used when Highlight Changes mode is in the active state. |
| 282 | This should be set to nil if no indication is desired, or to |
| 283 | a string with a leading space." |
| 284 | :type '(choice string |
| 285 | (const :tag "None" nil)) |
| 286 | :group 'highlight-changes) |
| 287 | |
| 288 | (defcustom highlight-changes-passive-string " -Chg" |
| 289 | "*The string used when Highlight Changes mode is in the passive state. |
| 290 | This should be set to nil if no indication is desired, or to |
| 291 | a string with a leading space." |
| 292 | :type '(choice string |
| 293 | (const :tag "None" nil)) |
| 294 | :group 'highlight-changes) |
| 295 | |
| 296 | (defcustom highlight-changes-global-modes t |
| 297 | "*Determine whether a buffer is suitable for global Highlight Changes mode. |
| 298 | |
| 299 | A function means call that function to decide: if it returns non-nil, |
| 300 | the buffer is suitable. |
| 301 | |
| 302 | A list means the elements are major modes suitable for Highlight |
| 303 | Changes mode, or a list whose first element is `not' followed by major |
| 304 | modes which are not suitable. |
| 305 | |
| 306 | A value of t means the buffer is suitable if it is visiting a file and |
| 307 | its name does not begin with ` ' or `*'. |
| 308 | |
| 309 | A value of nil means no buffers are suitable for `global-highlight-changes' |
| 310 | \(effectively disabling the mode). |
| 311 | |
| 312 | Example: |
| 313 | (c-mode c++-mode) |
| 314 | means that Highlight Changes mode is turned on for buffers in C and C++ |
| 315 | modes only." |
| 316 | :type '(choice |
| 317 | (const :tag "all non-special buffers visiting files" t) |
| 318 | (set :menu-tag "specific modes" :tag "modes" |
| 319 | :value (not) |
| 320 | (const :tag "All except these" not) |
| 321 | (repeat :tag "Modes" :inline t (symbol :tag "mode"))) |
| 322 | (function :menu-tag "determined by function" |
| 323 | :value buffer-file-name) |
| 324 | (const :tag "none" nil) |
| 325 | ) |
| 326 | :group 'highlight-changes) |
| 327 | |
| 328 | (defvar global-highlight-changes nil) |
| 329 | |
| 330 | (defcustom highlight-changes-global-changes-existing-buffers nil |
| 331 | "*If non-nil, toggling global Highlight Changes mode affects existing buffers. |
| 332 | Normally, `global-highlight-changes' affects only new buffers (to be |
| 333 | created). However, if `highlight-changes-global-changes-existing-buffers' |
| 334 | is non-nil, then turning on `global-highlight-changes' will turn on |
| 335 | Highlight Changes mode in suitable buffers, and turning the mode off will |
| 336 | remove it from existing buffers." |
| 337 | :type 'boolean |
| 338 | :group 'highlight-changes) |
| 339 | |
| 340 | (defun hilit-chg-cust-fix-changes-face-list (w wc &optional event) |
| 341 | ;; When customization function `highlight-changes-face-list' inserts a new |
| 342 | ;; face it uses the default face. We don't want the user to modify this |
| 343 | ;; face, so we rename the faces in the list on an insert. The rename is |
| 344 | ;; actually done by copying the faces so user-defined faces still remain |
| 345 | ;; in the same order. |
| 346 | ;; The notifying the parent is needed because without it changes to the |
| 347 | ;; faces are saved but not to the actual list itself. |
| 348 | (let ((old-list (widget-value w))) |
| 349 | (if (member 'default old-list) |
| 350 | (let |
| 351 | ((p (reverse old-list)) |
| 352 | (n (length old-list)) |
| 353 | new-name old-name |
| 354 | (new-list nil) |
| 355 | ) |
| 356 | (while p |
| 357 | (setq old-name (car p)) |
| 358 | (setq new-name (intern (format "highlight-changes-%d" n))) |
| 359 | (if (eq old-name new-name) |
| 360 | nil |
| 361 | ;; A new face has been inserted: we don't want to modify the |
| 362 | ;; default face so copy it. Better, though, (I think) is to |
| 363 | ;; make a new face have the same attributes as |
| 364 | ;; the `highlight-changes' face. |
| 365 | (if (eq old-name 'default) |
| 366 | (copy-face 'highlight-changes new-name) |
| 367 | (copy-face old-name new-name) |
| 368 | )) |
| 369 | (setq new-list (append (list new-name) new-list)) |
| 370 | (setq n (1- n)) |
| 371 | (setq p (cdr p))) |
| 372 | (if (equal new-list (widget-value w)) |
| 373 | nil ;; (message "notify: no change!") |
| 374 | (widget-value-set w new-list) |
| 375 | (widget-setup) |
| 376 | ) |
| 377 | ) |
| 378 | ;; (message "notify: no default here!") |
| 379 | )) |
| 380 | (let ((parent (widget-get w :parent))) |
| 381 | (when parent |
| 382 | (widget-apply parent :notify w event)))) |
| 383 | |
| 384 | |
| 385 | (defcustom highlight-changes-face-list nil |
| 386 | "*A list of faces used when rotating changes. |
| 387 | Normally the variable is initialized to nil and the list is created from |
| 388 | `highlight-changes-colors' when needed. However, you can set this variable |
| 389 | to any list of faces. You will have to do this if you want faces which |
| 390 | don't just differ from the `highlight-changes' face by the foreground color. |
| 391 | Otherwise, this list will be constructed when needed from |
| 392 | `highlight-changes-colors'." |
| 393 | :type '(choice |
| 394 | (repeat |
| 395 | :notify hilit-chg-cust-fix-changes-face-list |
| 396 | face ) |
| 397 | (const :tag "Derive from highlight-changes-colors" nil) |
| 398 | ) |
| 399 | :group 'highlight-changes) |
| 400 | |
| 401 | ;; ======================================================================== |
| 402 | |
| 403 | ;; These shouldn't be changed! |
| 404 | |
| 405 | (defvar highlight-changes-mode nil) |
| 406 | (defvar hilit-chg-list nil) |
| 407 | (defvar hilit-chg-string " ??") |
| 408 | (or (assq 'highlight-changes-mode minor-mode-alist) |
| 409 | (setq minor-mode-alist |
| 410 | (cons '(highlight-changes-mode hilit-chg-string) minor-mode-alist) |
| 411 | )) |
| 412 | (make-variable-buffer-local 'highlight-changes-mode) |
| 413 | (make-variable-buffer-local 'hilit-chg-string) |
| 414 | |
| 415 | |
| 416 | (require 'ediff-init) |
| 417 | (require 'ediff-util) |
| 418 | |
| 419 | |
| 420 | ;;; Functions... |
| 421 | |
| 422 | (defun hilit-chg-map-changes (func &optional start-position end-position) |
| 423 | "Call function FUNC for each region used by Highlight Changes mode." |
| 424 | ;; if start-position is nil, (point-min) is used |
| 425 | ;; if end-position is nil, (point-max) is used |
| 426 | ;; FUNC is called with 3 params: property start stop |
| 427 | (let ((start (or start-position (point-min))) |
| 428 | (limit (or end-position (point-max))) |
| 429 | prop end) |
| 430 | (while (and start (< start limit)) |
| 431 | (setq prop (get-text-property start 'hilit-chg)) |
| 432 | (setq end (text-property-not-all start limit 'hilit-chg prop)) |
| 433 | (if prop |
| 434 | (funcall func prop start (or end limit))) |
| 435 | (setq start end)))) |
| 436 | |
| 437 | |
| 438 | (defun hilit-chg-display-changes (&optional beg end) |
| 439 | "Display face information for Highlight Changes mode. |
| 440 | |
| 441 | An overlay containing a change face is added from the information |
| 442 | in the text property of type `hilit-chg'. |
| 443 | |
| 444 | This is the opposite of `hilit-chg-hide-changes'." |
| 445 | (hilit-chg-map-changes 'hilit-chg-make-ov beg end)) |
| 446 | |
| 447 | |
| 448 | (defun hilit-chg-make-ov (prop start end) |
| 449 | (or prop |
| 450 | (error "hilit-chg-make-ov: prop is nil")) |
| 451 | ;; for the region make change overlays corresponding to |
| 452 | ;; the text property 'hilit-chg |
| 453 | (let ((ov (make-overlay start end)) |
| 454 | face) |
| 455 | (if (eq prop 'hilit-chg-delete) |
| 456 | (setq face 'highlight-changes-delete) |
| 457 | (setq face (nth 1 (member prop hilit-chg-list)))) |
| 458 | (if face |
| 459 | (progn |
| 460 | ;; We must mark the face, that is the purpose of the overlay |
| 461 | (overlay-put ov 'face face) |
| 462 | ;; I don't think we need to set evaporate since we should |
| 463 | ;; be controlling them! |
| 464 | (overlay-put ov 'evaporate t) |
| 465 | ;; We set the change property so we can tell this is one |
| 466 | ;; of our overlays (so we don't delete someone else's). |
| 467 | (overlay-put ov 'hilit-chg t) |
| 468 | ) |
| 469 | (error "hilit-chg-make-ov: no face for prop: %s" prop)))) |
| 470 | |
| 471 | (defun hilit-chg-hide-changes (&optional beg end) |
| 472 | "Remove face information for Highlight Changes mode. |
| 473 | |
| 474 | The overlay containing the face is removed, but the text property |
| 475 | containing the change information is retained. |
| 476 | |
| 477 | This is the opposite of `hilit-chg-display-changes'." |
| 478 | (let ((start (or beg (point-min))) |
| 479 | (limit (or end (point-max))) |
| 480 | p ov) |
| 481 | (setq p (overlays-in start limit)) |
| 482 | (while p |
| 483 | ;; don't delete the overlay if it isn't ours! |
| 484 | (if (overlay-get (car p) 'hilit-chg) |
| 485 | (delete-overlay (car p))) |
| 486 | (setq p (cdr p))))) |
| 487 | |
| 488 | (defun hilit-chg-fixup (beg end) |
| 489 | "Fix change overlays in region between BEG and END. |
| 490 | |
| 491 | Ensure the overlays agree with the changes as determined from |
| 492 | the text properties of type `hilit-chg'." |
| 493 | ;; Remove or alter overlays in region beg..end |
| 494 | (let (ov-start ov-end props q) |
| 495 | ;; temp for debugging: |
| 496 | ;; (or (eq highlight-changes-mode 'active) |
| 497 | ;; (error "hilit-chg-fixup called but Highlight Changes mode not active")) |
| 498 | (dolist (ov (overlays-in beg end)) |
| 499 | ;; Don't alter overlays that are not ours. |
| 500 | (when (overlay-get ov 'hilit-chg) |
| 501 | (let ((ov-start (overlay-start ov)) |
| 502 | (ov-end (overlay-end ov))) |
| 503 | (if (< ov-start beg) |
| 504 | (progn |
| 505 | (move-overlay ov ov-start beg) |
| 506 | (if (> ov-end end) |
| 507 | (progn |
| 508 | (setq props (overlay-properties ov)) |
| 509 | (setq ov (make-overlay end ov-end)) |
| 510 | (while props |
| 511 | (overlay-put ov (car props)(car (cdr props))) |
| 512 | (setq props (cdr (cdr props))))))) |
| 513 | (if (> ov-end end) |
| 514 | (move-overlay ov end ov-end) |
| 515 | (delete-overlay ov)))))) |
| 516 | (hilit-chg-display-changes beg end))) |
| 517 | |
| 518 | ;;;###autoload |
| 519 | (defun highlight-changes-remove-highlight (beg end) |
| 520 | "Remove the change face from the region between BEG and END. |
| 521 | This allows you to manually remove highlighting from uninteresting changes." |
| 522 | (interactive "r") |
| 523 | (let ((after-change-functions nil)) |
| 524 | (remove-text-properties beg end '(hilit-chg nil)) |
| 525 | (hilit-chg-fixup beg end))) |
| 526 | |
| 527 | (defun hilit-chg-set-face-on-change (beg end leng-before |
| 528 | &optional no-property-change) |
| 529 | "Record changes and optionally display them in a distinctive face. |
| 530 | `hilit-chg-set' adds this function to the `after-change-functions' hook." |
| 531 | ;; |
| 532 | ;; This function is called by the `after-change-functions' hook, which |
| 533 | ;; is how we are notified when text is changed. |
| 534 | ;; It is also called from `highlight-compare-with-file'. |
| 535 | ;; |
| 536 | ;; We do NOT want to simply do this if this is an undo command, because |
| 537 | ;; otherwise an undone change shows up as changed. While the properties |
| 538 | ;; are automatically restored by undo, we must fix up the overlay. |
| 539 | (save-match-data |
| 540 | (let ((beg-decr 1) (end-incr 1) |
| 541 | (type 'hilit-chg) |
| 542 | old) |
| 543 | (if undo-in-progress |
| 544 | (if (eq highlight-changes-mode 'active) |
| 545 | (hilit-chg-fixup beg end)) |
| 546 | (if (and (= beg end) (> leng-before 0)) |
| 547 | ;; deletion |
| 548 | (progn |
| 549 | ;; The eolp and bolp tests are a kludge! But they prevent |
| 550 | ;; rather nasty looking displays when deleting text at the end |
| 551 | ;; of line, such as normal corrections as one is typing and |
| 552 | ;; immediately makes a correction, and when deleting first |
| 553 | ;; character of a line. |
| 554 | ;;; (if (= leng-before 1) |
| 555 | ;;; (if (eolp) |
| 556 | ;;; (setq beg-decr 0 end-incr 0) |
| 557 | ;;; (if (bolp) |
| 558 | ;;; (setq beg-decr 0)))) |
| 559 | ;;; (setq beg (max (- beg beg-decr) (point-min))) |
| 560 | (setq end (min (+ end end-incr) (point-max))) |
| 561 | (setq type 'hilit-chg-delete)) |
| 562 | ;; Not a deletion. |
| 563 | ;; Most of the time the following is not necessary, but |
| 564 | ;; if the current text was marked as a deletion then |
| 565 | ;; the old overlay is still in effect, so if we add some |
| 566 | ;; text then remove the deletion marking, but set it to |
| 567 | ;; changed otherwise its highlighting disappears. |
| 568 | (if (eq (get-text-property end 'hilit-chg) 'hilit-chg-delete) |
| 569 | (progn |
| 570 | (remove-text-properties end (+ end 1) '(hilit-chg nil)) |
| 571 | (put-text-property end (+ end 1) 'hilit-chg 'hilit-chg) |
| 572 | (if (eq highlight-changes-mode 'active) |
| 573 | (hilit-chg-fixup beg (+ end 1)))))) |
| 574 | (unless no-property-change |
| 575 | (put-text-property beg end 'hilit-chg type)) |
| 576 | (if (or (eq highlight-changes-mode 'active) no-property-change) |
| 577 | (hilit-chg-make-ov type beg end)))))) |
| 578 | |
| 579 | (defun hilit-chg-set (value) |
| 580 | "Turn on Highlight Changes mode for this buffer." |
| 581 | (setq highlight-changes-mode value) |
| 582 | (remove-hook 'after-change-functions 'hilit-chg-set-face-on-change t) |
| 583 | (hilit-chg-make-list) |
| 584 | (if (eq highlight-changes-mode 'active) |
| 585 | (progn |
| 586 | (setq hilit-chg-string highlight-changes-active-string) |
| 587 | (or buffer-read-only |
| 588 | (hilit-chg-display-changes))) |
| 589 | ;; mode is passive |
| 590 | (setq hilit-chg-string highlight-changes-passive-string) |
| 591 | (or buffer-read-only |
| 592 | (hilit-chg-hide-changes))) |
| 593 | (force-mode-line-update) |
| 594 | (add-hook 'after-change-functions 'hilit-chg-set-face-on-change nil t)) |
| 595 | |
| 596 | (defun hilit-chg-clear () |
| 597 | "Remove Highlight Changes mode for this buffer. |
| 598 | This removes all saved change information." |
| 599 | (if buffer-read-only |
| 600 | ;; We print the buffer name because this function could be called |
| 601 | ;; on many buffers from `global-highlight-changes'. |
| 602 | (message "Cannot remove highlighting from read-only mode buffer %s" |
| 603 | (buffer-name)) |
| 604 | (remove-hook 'after-change-functions 'hilit-chg-set-face-on-change t) |
| 605 | (let ((after-change-functions nil)) |
| 606 | (hilit-chg-hide-changes) |
| 607 | (hilit-chg-map-changes |
| 608 | '(lambda (prop start stop) |
| 609 | (remove-text-properties start stop '(hilit-chg nil)))) |
| 610 | ) |
| 611 | (setq highlight-changes-mode nil) |
| 612 | (force-mode-line-update) |
| 613 | ;; If we type: C-u -1 M-x highlight-changes-mode |
| 614 | ;; we want to turn it off, but hilit-chg-post-command-hook |
| 615 | ;; runs and that turns it back on! |
| 616 | (remove-hook 'post-command-hook 'hilit-chg-post-command-hook))) |
| 617 | |
| 618 | ;;;###autoload |
| 619 | (defun highlight-changes-mode (&optional arg) |
| 620 | "Toggle (or initially set) Highlight Changes mode. |
| 621 | |
| 622 | Without an argument: |
| 623 | If Highlight Changes mode is not enabled, then enable it (in either active |
| 624 | or passive state as determined by the variable |
| 625 | `highlight-changes-initial-state'); otherwise, toggle between active |
| 626 | and passive state. |
| 627 | |
| 628 | With an argument ARG: |
| 629 | If ARG is positive, set state to active; |
| 630 | If ARG is zero, set state to passive; |
| 631 | If ARG is negative, disable Highlight Changes mode completely. |
| 632 | |
| 633 | Active state - means changes are shown in a distinctive face. |
| 634 | Passive state - means changes are kept and new ones recorded but are |
| 635 | not displayed in a different face. |
| 636 | |
| 637 | Functions: |
| 638 | \\[highlight-changes-next-change] - move point to beginning of next change |
| 639 | \\[highlight-changes-previous-change] - move to beginning of previous change |
| 640 | \\[highlight-compare-with-file] - mark text as changed by comparing this |
| 641 | buffer with the contents of a file |
| 642 | \\[highlight-changes-remove-highlight] - remove the change face from the region |
| 643 | \\[highlight-changes-rotate-faces] - rotate different \"ages\" of changes \ |
| 644 | through |
| 645 | various faces |
| 646 | |
| 647 | Hook variables: |
| 648 | `highlight-changes-enable-hook' - when enabling Highlight Changes mode |
| 649 | `highlight-changes-toggle-hook' - when entering active or passive state |
| 650 | `highlight-changes-disable-hook' - when turning off Highlight Changes mode" |
| 651 | (interactive "P") |
| 652 | (if (or (display-color-p) |
| 653 | (and (fboundp 'x-display-grayscale-p) (x-display-grayscale-p))) |
| 654 | (let ((was-on highlight-changes-mode) |
| 655 | (new-highlight-changes-mode |
| 656 | (cond |
| 657 | ((null arg) |
| 658 | ;; no arg => toggle (or set to active initially) |
| 659 | (if highlight-changes-mode |
| 660 | (if (eq highlight-changes-mode 'active) 'passive 'active) |
| 661 | highlight-changes-initial-state)) |
| 662 | ;; an argument is given |
| 663 | ((eq arg 'active) |
| 664 | 'active) |
| 665 | ((eq arg 'passive) |
| 666 | 'passive) |
| 667 | ((> (prefix-numeric-value arg) 0) |
| 668 | 'active) |
| 669 | ((< (prefix-numeric-value arg) 0) |
| 670 | nil) |
| 671 | (t |
| 672 | 'passive)))) |
| 673 | (if new-highlight-changes-mode |
| 674 | ;; mode is turned on -- but may be passive |
| 675 | (progn |
| 676 | (add-to-list 'desktop-locals-to-save 'highlight-changes-mode) |
| 677 | (hilit-chg-set new-highlight-changes-mode) |
| 678 | (or was-on |
| 679 | ;; run highlight-changes-enable-hook once |
| 680 | (run-hooks 'highlight-changes-enable-hook)) |
| 681 | (run-hooks 'highlight-changes-toggle-hook)) |
| 682 | ;; mode is turned off |
| 683 | (run-hooks 'highlight-changes-disable-hook) |
| 684 | (hilit-chg-clear))) |
| 685 | (message "Highlight Changes mode requires color or grayscale display"))) |
| 686 | |
| 687 | ;;;###autoload |
| 688 | (defun highlight-changes-next-change () |
| 689 | "Move to the beginning of the next change, if in Highlight Changes mode." |
| 690 | (interactive) |
| 691 | (if highlight-changes-mode |
| 692 | (let ((start (point)) |
| 693 | prop) |
| 694 | (setq prop (get-text-property (point) 'hilit-chg)) |
| 695 | (if prop |
| 696 | ;; we are in a change |
| 697 | (setq start (next-single-property-change (point) 'hilit-chg))) |
| 698 | (if start |
| 699 | (setq start (next-single-property-change start 'hilit-chg))) |
| 700 | (if start |
| 701 | (goto-char start) |
| 702 | (message "no next change"))) |
| 703 | (message "This buffer is not in Highlight Changes mode."))) |
| 704 | |
| 705 | |
| 706 | ;;;###autoload |
| 707 | (defun highlight-changes-previous-change () |
| 708 | "Move to the beginning of the previous change, if in Highlight Changes mode." |
| 709 | (interactive) |
| 710 | (if highlight-changes-mode |
| 711 | (let ( (start (point)) (prop nil) ) |
| 712 | (or (bobp) |
| 713 | (setq prop (get-text-property (1- (point)) 'hilit-chg))) |
| 714 | (if prop |
| 715 | ;; we are in a change |
| 716 | (setq start (previous-single-property-change (point) 'hilit-chg))) |
| 717 | (if start |
| 718 | (setq start (previous-single-property-change start 'hilit-chg))) |
| 719 | ;; special handling for the case where (point-min) is a change |
| 720 | (if start |
| 721 | (setq start (or (previous-single-property-change start 'hilit-chg) |
| 722 | (if (get-text-property (point-min) 'hilit-chg) |
| 723 | (point-min))))) |
| 724 | (if start |
| 725 | (goto-char start) |
| 726 | (message "no previous change"))) |
| 727 | (message "This buffer is not in Highlight Changes mode."))) |
| 728 | |
| 729 | ;; ======================================================================== |
| 730 | |
| 731 | (defun hilit-chg-make-list (&optional force) |
| 732 | "Construct `hilit-chg-list' and `highlight-changes-face-list'." |
| 733 | ;; Constructs highlight-changes-face-list if necessary, |
| 734 | ;; and hilit-chg-list always: |
| 735 | ;; Maybe this should always be called when rotating a face |
| 736 | ;; so we pick up any changes? |
| 737 | (if (or (null highlight-changes-face-list) ; Don't do it if it |
| 738 | force) ; already exists unless FORCE non-nil. |
| 739 | (let ((p highlight-changes-colors) |
| 740 | (n 1) name) |
| 741 | (setq highlight-changes-face-list nil) |
| 742 | (while p |
| 743 | (setq name (intern (format "highlight-changes-%d" n))) |
| 744 | (copy-face 'highlight-changes name) |
| 745 | (set-face-foreground name (car p)) |
| 746 | (setq highlight-changes-face-list |
| 747 | (append highlight-changes-face-list (list name))) |
| 748 | (setq p (cdr p)) |
| 749 | (setq n (1+ n))))) |
| 750 | (setq hilit-chg-list (list 'hilit-chg 'highlight-changes)) |
| 751 | (let ((p highlight-changes-face-list) |
| 752 | (n 1) |
| 753 | last-category last-face) |
| 754 | (while p |
| 755 | (setq last-category (intern (format "change-%d" n))) |
| 756 | ;; (setq last-face (intern (format "highlight-changes-%d" n))) |
| 757 | (setq last-face (car p)) |
| 758 | (setq hilit-chg-list |
| 759 | (append hilit-chg-list |
| 760 | (list last-category last-face))) |
| 761 | (setq p (cdr p)) |
| 762 | (setq n (1+ n))) |
| 763 | (setq hilit-chg-list |
| 764 | (append hilit-chg-list |
| 765 | (list last-category last-face))))) |
| 766 | |
| 767 | (defun hilit-chg-bump-change (prop start end) |
| 768 | "Increment (age) the Highlight Changes mode text property." |
| 769 | (let ( new-prop ) |
| 770 | (if (eq prop 'hilit-chg-delete) |
| 771 | (setq new-prop (nth 2 hilit-chg-list)) |
| 772 | (setq new-prop (nth 2 (member prop hilit-chg-list)))) |
| 773 | (if prop |
| 774 | (put-text-property start end 'hilit-chg new-prop) |
| 775 | (message "%d-%d unknown property %s not changed" start end prop)))) |
| 776 | |
| 777 | ;;;###autoload |
| 778 | (defun highlight-changes-rotate-faces () |
| 779 | "Rotate the faces used by Highlight Changes mode. |
| 780 | |
| 781 | Current changes are displayed in the face described by the first element |
| 782 | of `highlight-changes-face-list', one level older changes are shown in |
| 783 | face described by the second element, and so on. Very old changes remain |
| 784 | shown in the last face in the list. |
| 785 | |
| 786 | You can automatically rotate colors when the buffer is saved by adding |
| 787 | this function to `write-file-functions' as a buffer-local value. To do |
| 788 | this, eval the following in the buffer to be saved: |
| 789 | |
| 790 | \(add-hook 'write-file-functions 'highlight-changes-rotate-faces nil t)" |
| 791 | (interactive) |
| 792 | ;; If not in active mode do nothing but don't complain because this |
| 793 | ;; may be bound to a hook. |
| 794 | (if (eq highlight-changes-mode 'active) |
| 795 | (let ((after-change-functions nil)) |
| 796 | ;; ensure hilit-chg-list is made and up to date |
| 797 | (hilit-chg-make-list) |
| 798 | ;; remove our existing overlays |
| 799 | (hilit-chg-hide-changes) |
| 800 | ;; for each change text property, increment it |
| 801 | (hilit-chg-map-changes 'hilit-chg-bump-change) |
| 802 | ;; and display them all if active |
| 803 | (if (eq highlight-changes-mode 'active) |
| 804 | (hilit-chg-display-changes)))) |
| 805 | ;; This always returns nil so it is safe to use in write-file-functions |
| 806 | nil) |
| 807 | |
| 808 | ;; ======================================================================== |
| 809 | ;; Comparing buffers/files |
| 810 | ;; These use ediff to find the differences. |
| 811 | |
| 812 | (defun highlight-markup-buffers |
| 813 | (buf-a file-a buf-b file-b &optional markup-a-only) |
| 814 | "Get differences between two buffers and set highlight changes. |
| 815 | Both buffers are done unless optional parameter MARKUP-A-ONLY |
| 816 | is non-nil." |
| 817 | (save-window-excursion |
| 818 | (let* (change-info |
| 819 | change-a change-b |
| 820 | a-start a-end len-a |
| 821 | b-start b-end len-b |
| 822 | (bufa-modified (buffer-modified-p buf-a)) |
| 823 | (bufb-modified (buffer-modified-p buf-b)) |
| 824 | (buf-a-read-only (with-current-buffer buf-a buffer-read-only)) |
| 825 | (buf-b-read-only (with-current-buffer buf-b buffer-read-only)) |
| 826 | temp-a temp-b) |
| 827 | (if (and file-a bufa-modified) |
| 828 | (if (y-or-n-p (format "Save buffer %s? " buf-a)) |
| 829 | (with-current-buffer buf-a |
| 830 | (save-buffer) |
| 831 | (setq bufa-modified (buffer-modified-p buf-a))) |
| 832 | (setq file-a nil))) |
| 833 | (or file-a |
| 834 | (setq temp-a (setq file-a (ediff-make-temp-file buf-a nil)))) |
| 835 | |
| 836 | (if (and file-b bufb-modified) |
| 837 | (if (y-or-n-p (format "Save buffer %s? " buf-b)) |
| 838 | (with-current-buffer buf-b |
| 839 | (save-buffer) |
| 840 | (setq bufb-modified (buffer-modified-p buf-b))) |
| 841 | (setq file-b nil))) |
| 842 | (or file-b |
| 843 | (setq temp-b (setq file-b (ediff-make-temp-file buf-b nil)))) |
| 844 | (set-buffer buf-a) |
| 845 | (highlight-changes-mode 'active) |
| 846 | (or markup-a-only (with-current-buffer buf-b |
| 847 | (highlight-changes-mode 'active))) |
| 848 | (setq change-info (hilit-chg-get-diff-info buf-a file-a buf-b file-b)) |
| 849 | |
| 850 | |
| 851 | (setq change-a (car change-info)) |
| 852 | (setq change-b (car (cdr change-info))) |
| 853 | |
| 854 | (hilit-chg-make-list) |
| 855 | (while change-a |
| 856 | (setq a-start (nth 0 (car change-a))) |
| 857 | (setq a-end (nth 1 (car change-a))) |
| 858 | (setq b-start (nth 0 (car change-b))) |
| 859 | (setq b-end (nth 1 (car change-b))) |
| 860 | (setq len-a (- a-end a-start)) |
| 861 | (setq len-b (- b-end b-start)) |
| 862 | (set-buffer buf-a) |
| 863 | (hilit-chg-set-face-on-change a-start a-end len-b buf-a-read-only) |
| 864 | (or markup-a-only |
| 865 | (with-current-buffer buf-b |
| 866 | (hilit-chg-set-face-on-change b-start b-end len-a |
| 867 | buf-b-read-only) |
| 868 | )) |
| 869 | (setq change-a (cdr change-a)) |
| 870 | (setq change-b (cdr change-b))) |
| 871 | (or bufa-modified |
| 872 | (with-current-buffer buf-a (set-buffer-modified-p nil))) |
| 873 | (or bufb-modified |
| 874 | (with-current-buffer buf-b (set-buffer-modified-p nil))) |
| 875 | (if temp-a |
| 876 | (delete-file temp-a)) |
| 877 | (if temp-b |
| 878 | (delete-file temp-b))) |
| 879 | )) |
| 880 | |
| 881 | ;;;###autoload |
| 882 | (defun highlight-compare-buffers (buf-a buf-b) |
| 883 | "Compare two buffers and highlight the differences. |
| 884 | |
| 885 | The default is the current buffer and the one in the next window. |
| 886 | |
| 887 | If either buffer is modified and is visiting a file, you are prompted |
| 888 | to save the file. |
| 889 | |
| 890 | Unless the buffer is unmodified and visiting a file, the buffer is |
| 891 | written to a temporary file for comparison. |
| 892 | |
| 893 | If a buffer is read-only, differences will be highlighted but no property |
| 894 | changes are made, so \\[highlight-changes-next-change] and |
| 895 | \\[highlight-changes-previous-change] will not work." |
| 896 | (interactive |
| 897 | (list |
| 898 | (get-buffer (read-buffer "buffer-a " (current-buffer) t)) |
| 899 | (get-buffer |
| 900 | (read-buffer "buffer-b " |
| 901 | (window-buffer (next-window (selected-window))) t)))) |
| 902 | (let ((file-a (buffer-file-name buf-a)) |
| 903 | (file-b (buffer-file-name buf-b))) |
| 904 | (highlight-markup-buffers buf-a file-a buf-b file-b) |
| 905 | )) |
| 906 | |
| 907 | ;;;###autoload |
| 908 | (defun highlight-compare-with-file (file-b) |
| 909 | "Compare this buffer with a file, and highlight differences. |
| 910 | |
| 911 | If the buffer has a backup filename, it is used as the default when |
| 912 | this function is called interactively. |
| 913 | |
| 914 | If the current buffer is visiting the file being compared against, it |
| 915 | also will have its differences highlighted. Otherwise, the file is |
| 916 | read in temporarily but the buffer is deleted. |
| 917 | |
| 918 | If the buffer is read-only, differences will be highlighted but no property |
| 919 | changes are made, so \\[highlight-changes-next-change] and |
| 920 | \\[highlight-changes-previous-change] will not work." |
| 921 | (interactive (list |
| 922 | (read-file-name |
| 923 | "File to compare with? " ;; prompt |
| 924 | "" ;; directory |
| 925 | nil ;; default |
| 926 | 'yes ;; must exist |
| 927 | (let ((f (buffer-file-name (current-buffer)))) |
| 928 | (if f |
| 929 | (progn |
| 930 | (setq f (make-backup-file-name f)) |
| 931 | (or (file-exists-p f) |
| 932 | (setq f nil))) |
| 933 | ) |
| 934 | f)))) |
| 935 | (let* ((buf-a (current-buffer)) |
| 936 | (file-a (buffer-file-name)) |
| 937 | (existing-buf (get-file-buffer file-b)) |
| 938 | (buf-b (or existing-buf |
| 939 | (find-file-noselect file-b))) |
| 940 | (buf-b-read-only (with-current-buffer buf-b buffer-read-only))) |
| 941 | (highlight-markup-buffers buf-a file-a buf-b file-b (not existing-buf)) |
| 942 | (unless existing-buf |
| 943 | (kill-buffer buf-b)) |
| 944 | )) |
| 945 | |
| 946 | |
| 947 | (defun hilit-chg-get-diff-info (buf-a file-a buf-b file-b) |
| 948 | (let ((e nil) x y) ;; e is set by function hilit-chg-get-diff-list-hk |
| 949 | (ediff-setup buf-a file-a buf-b file-b |
| 950 | nil nil ; buf-c file-C |
| 951 | 'hilit-chg-get-diff-list-hk |
| 952 | (list (cons 'ediff-job-name 'something)) |
| 953 | ) |
| 954 | (ediff-with-current-buffer e (ediff-really-quit nil)) |
| 955 | (list x y))) |
| 956 | |
| 957 | |
| 958 | (defun hilit-chg-get-diff-list-hk () |
| 959 | ;; x and y are dynamically bound by hilit-chg-get-diff-info |
| 960 | ;; which calls this function as a hook |
| 961 | (defvar x) ;; placate the byte-compiler |
| 962 | (defvar y) |
| 963 | (setq e (current-buffer)) |
| 964 | (let ((n 0) extent p va vb a b) |
| 965 | (setq x nil y nil) ;; x and y are bound by hilit-chg-get-diff-info |
| 966 | (while (< n ediff-number-of-differences) |
| 967 | (ediff-make-fine-diffs n) |
| 968 | (setq va (ediff-get-fine-diff-vector n 'A)) |
| 969 | ;; va is a vector if there are fine differences |
| 970 | (if va |
| 971 | (setq a (append va nil)) |
| 972 | ;; if not, get the unrefined difference |
| 973 | (setq va (ediff-get-difference n 'A)) |
| 974 | (setq a (list (elt va 0)))) |
| 975 | ;; a list a list |
| 976 | (setq p a) |
| 977 | (while p |
| 978 | (setq extent (list (overlay-start (car p)) |
| 979 | (overlay-end (car p)))) |
| 980 | (setq p (cdr p)) |
| 981 | (setq x (append x (list extent) )));; while p |
| 982 | ;; |
| 983 | (setq vb (ediff-get-fine-diff-vector n 'B)) |
| 984 | ;; vb is a vector |
| 985 | (if vb |
| 986 | (setq b (append vb nil)) |
| 987 | ;; if not, get the unrefined difference |
| 988 | (setq vb (ediff-get-difference n 'B)) |
| 989 | (setq b (list (elt vb 0)))) |
| 990 | ;; b list a list |
| 991 | (setq p b) |
| 992 | (while p |
| 993 | (setq extent (list (overlay-start (car p)) |
| 994 | (overlay-end (car p)))) |
| 995 | (setq p (cdr p)) |
| 996 | (setq y (append y (list extent) ))) |
| 997 | (setq n (1+ n)));; while |
| 998 | ;; ediff-quit doesn't work here. |
| 999 | ;; No point in returning a value, since this is a hook function. |
| 1000 | )) |
| 1001 | |
| 1002 | ;; ======================= automatic stuff ============== |
| 1003 | |
| 1004 | ;; Global Highlight Changes mode is modeled after Global Font-lock mode. |
| 1005 | ;; Three hooks are used to gain control. When Global Changes Mode is |
| 1006 | ;; enabled, `find-file-hook' and `change-major-mode-hook' are set. |
| 1007 | ;; `find-file-hook' is called when visiting a file, the new mode is |
| 1008 | ;; known at this time. |
| 1009 | ;; `change-major-mode-hook' is called when a buffer is changing mode. |
| 1010 | ;; This could be because of finding a file in which case |
| 1011 | ;; `find-file-hook' has already been called and has done its work. |
| 1012 | ;; However, it also catches the case where a new mode is being set by |
| 1013 | ;; the user. However, it is called from `kill-all-variables' and at |
| 1014 | ;; this time the mode is the old mode, which is not what we want. |
| 1015 | ;; So, our function temporarily sets `post-command-hook' which will |
| 1016 | ;; be called after the buffer has been completely set up (with the new |
| 1017 | ;; mode). It then removes the `post-command-hook'. |
| 1018 | ;; One other wrinkle - every M-x command runs the `change-major-mode-hook' |
| 1019 | ;; so we ignore this by examining the buffer name. |
| 1020 | |
| 1021 | |
| 1022 | (defun hilit-chg-major-mode-hook () |
| 1023 | (add-hook 'post-command-hook 'hilit-chg-post-command-hook)) |
| 1024 | |
| 1025 | (defun hilit-chg-post-command-hook () |
| 1026 | ;; This is called after changing a major mode, but also after each |
| 1027 | ;; M-x command, in which case the current buffer is a minibuffer. |
| 1028 | ;; In that case, do not act on it here, but don't turn it off |
| 1029 | ;; either, we will get called here again soon-after. |
| 1030 | ;; Also, don't enable it for other special buffers. |
| 1031 | (if (string-match "^[ *]" (buffer-name)) |
| 1032 | nil ;; (message "ignoring this post-command-hook") |
| 1033 | (remove-hook 'post-command-hook 'hilit-chg-post-command-hook) |
| 1034 | ;; The following check isn't necessary, since |
| 1035 | ;; hilit-chg-turn-on-maybe makes this check too. |
| 1036 | (or highlight-changes-mode ;; don't turn it on if it already is |
| 1037 | (hilit-chg-turn-on-maybe highlight-changes-global-initial-state)))) |
| 1038 | |
| 1039 | (defun hilit-chg-check-global () |
| 1040 | ;; This is called from the find file hook. |
| 1041 | (hilit-chg-turn-on-maybe highlight-changes-global-initial-state)) |
| 1042 | |
| 1043 | |
| 1044 | ;;;###autoload |
| 1045 | (defun global-highlight-changes (&optional arg) |
| 1046 | "Turn on or off global Highlight Changes mode. |
| 1047 | |
| 1048 | When called interactively: |
| 1049 | - if no prefix, toggle global Highlight Changes mode on or off |
| 1050 | - if called with a positive prefix (or just C-u) turn it on in active mode |
| 1051 | - if called with a zero prefix turn it on in passive mode |
| 1052 | - if called with a negative prefix turn it off |
| 1053 | |
| 1054 | When called from a program: |
| 1055 | - if ARG is nil or omitted, turn it off |
| 1056 | - if ARG is `active', turn it on in active mode |
| 1057 | - if ARG is `passive', turn it on in passive mode |
| 1058 | - otherwise just turn it on |
| 1059 | |
| 1060 | When global Highlight Changes mode is enabled, Highlight Changes mode is turned |
| 1061 | on for future \"suitable\" buffers (and for \"suitable\" existing buffers if |
| 1062 | variable `highlight-changes-global-changes-existing-buffers' is non-nil). |
| 1063 | \"Suitability\" is determined by variable `highlight-changes-global-modes'." |
| 1064 | |
| 1065 | (interactive |
| 1066 | (list |
| 1067 | (cond |
| 1068 | ((null current-prefix-arg) |
| 1069 | ;; no arg => toggle it on/off |
| 1070 | (setq global-highlight-changes (not global-highlight-changes))) |
| 1071 | ;; positive interactive arg - turn it on as active |
| 1072 | ((> (prefix-numeric-value current-prefix-arg) 0) |
| 1073 | (setq global-highlight-changes t) |
| 1074 | 'active) |
| 1075 | ;; zero interactive arg - turn it on as passive |
| 1076 | ((= (prefix-numeric-value current-prefix-arg) 0) |
| 1077 | (setq global-highlight-changes t) |
| 1078 | 'passive) |
| 1079 | ;; negative interactive arg - turn it off |
| 1080 | (t |
| 1081 | (setq global-highlight-changes nil) |
| 1082 | nil)))) |
| 1083 | |
| 1084 | (if arg |
| 1085 | (progn |
| 1086 | (if (eq arg 'active) |
| 1087 | (setq highlight-changes-global-initial-state 'active) |
| 1088 | (if (eq arg 'passive) |
| 1089 | (setq highlight-changes-global-initial-state 'passive))) |
| 1090 | (setq global-highlight-changes t) |
| 1091 | (message "Turning ON Global Highlight Changes mode in %s state" |
| 1092 | highlight-changes-global-initial-state) |
| 1093 | ;; FIXME: Not sure what this was intended to do. --Stef |
| 1094 | ;; (add-hook 'hilit-chg-major-mode-hook 'hilit-chg-major-mode-hook) |
| 1095 | (add-hook 'find-file-hook 'hilit-chg-check-global) |
| 1096 | (if highlight-changes-global-changes-existing-buffers |
| 1097 | (hilit-chg-update-all-buffers |
| 1098 | highlight-changes-global-initial-state))) |
| 1099 | |
| 1100 | (message "Turning OFF global Highlight Changes mode") |
| 1101 | ;; FIXME: Not sure what this was intended to do. --Stef |
| 1102 | ;; (remove-hook 'hilit-chg-major-mode-hook 'hilit-chg-major-mode-hook) |
| 1103 | (remove-hook 'post-command-hook 'hilit-chg-post-command-hook) |
| 1104 | (remove-hook 'find-file-hook 'hilit-chg-check-global) |
| 1105 | (if highlight-changes-global-changes-existing-buffers |
| 1106 | (hilit-chg-update-all-buffers nil)))) |
| 1107 | |
| 1108 | |
| 1109 | (defun hilit-chg-turn-on-maybe (value) |
| 1110 | "Turn on Highlight Changes mode if it is appropriate for this buffer. |
| 1111 | |
| 1112 | A buffer is appropriate for Highlight Changes mode if all these are true: |
| 1113 | - the buffer is not a special buffer (one whose name begins with |
| 1114 | `*' or ` '), |
| 1115 | - the buffer's mode is suitable as per variable |
| 1116 | `highlight-changes-global-modes', |
| 1117 | - Highlight Changes mode is not already on for this buffer. |
| 1118 | |
| 1119 | This function is called from `hilit-chg-update-all-buffers' or |
| 1120 | from `global-highlight-changes' when turning on global Highlight Changes mode." |
| 1121 | (or highlight-changes-mode ; do nothing if already on |
| 1122 | (if |
| 1123 | (cond |
| 1124 | ((null highlight-changes-global-modes) |
| 1125 | nil) |
| 1126 | ((functionp highlight-changes-global-modes) |
| 1127 | (funcall highlight-changes-global-modes)) |
| 1128 | ((listp highlight-changes-global-modes) |
| 1129 | (if (eq (car-safe highlight-changes-global-modes) 'not) |
| 1130 | (not (memq major-mode (cdr highlight-changes-global-modes))) |
| 1131 | (memq major-mode highlight-changes-global-modes))) |
| 1132 | (t |
| 1133 | (and |
| 1134 | (not (string-match "^[ *]" (buffer-name))) |
| 1135 | (buffer-file-name)))) |
| 1136 | (progn |
| 1137 | (hilit-chg-set value) |
| 1138 | (run-hooks 'highlight-changes-enable-hook))))) |
| 1139 | |
| 1140 | |
| 1141 | (defun hilit-chg-turn-off-maybe () |
| 1142 | (if highlight-changes-mode |
| 1143 | (progn |
| 1144 | (run-hooks 'highlight-changes-disable-hook) |
| 1145 | (hilit-chg-clear)))) |
| 1146 | |
| 1147 | |
| 1148 | (defun hilit-chg-update-all-buffers (value) |
| 1149 | (mapcar |
| 1150 | (function (lambda (buffer) |
| 1151 | (with-current-buffer buffer |
| 1152 | (if value |
| 1153 | (hilit-chg-turn-on-maybe value) |
| 1154 | (hilit-chg-turn-off-maybe)) |
| 1155 | ))) |
| 1156 | (buffer-list))) |
| 1157 | |
| 1158 | ;;;; Desktop support. |
| 1159 | |
| 1160 | ;; Called by `desktop-create-buffer' to restore `highlight-changes-mode'. |
| 1161 | (defun hilit-chg-desktop-restore (desktop-buffer-locals) |
| 1162 | (highlight-changes-mode |
| 1163 | (or (cdr (assq 'highlight-changes-mode desktop-buffer-locals)) 1))) |
| 1164 | |
| 1165 | (add-to-list 'desktop-minor-mode-handlers |
| 1166 | '(highlight-changes-mode . hilit-chg-desktop-restore)) |
| 1167 | |
| 1168 | ;; ===================== debug ================== |
| 1169 | ;; For debug & test use: |
| 1170 | ;; |
| 1171 | ;; (defun hilit-chg-debug-show (&optional beg end) |
| 1172 | ;; (interactive) |
| 1173 | ;; (message "--- hilit-chg-debug-show ---") |
| 1174 | ;; (hilit-chg-map-changes '(lambda (prop start end) |
| 1175 | ;; (message "%d-%d: %s" start end prop) |
| 1176 | ;; ) |
| 1177 | ;; beg end |
| 1178 | ;; )) |
| 1179 | ;; |
| 1180 | ;; ================== end of debug =============== |
| 1181 | |
| 1182 | (provide 'hilit-chg) |
| 1183 | |
| 1184 | ;; arch-tag: de00301d-5bad-44da-aa82-e0e010b0c463 |
| 1185 | ;;; hilit-chg.el ends here |