| 1 | ;;; dired-aux.el --- less commonly used parts of dired -*-byte-compile-dynamic: t;-*- |
| 2 | |
| 3 | ;; Copyright (C) 1985, 1986, 1992, 1994, 1998, 2000, 2001 |
| 4 | ;; Free Software Foundation, Inc. |
| 5 | |
| 6 | ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>. |
| 7 | ;; Maintainer: FSF |
| 8 | ;; Keywords: files |
| 9 | |
| 10 | ;; This file is part of GNU Emacs. |
| 11 | |
| 12 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 13 | ;; it under the terms of the GNU General Public License as published by |
| 14 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 15 | ;; any later version. |
| 16 | |
| 17 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 18 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 19 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 20 | ;; GNU General Public License for more details. |
| 21 | |
| 22 | ;; You should have received a copy of the GNU General Public License |
| 23 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 24 | ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, |
| 25 | ;; Boston, MA 02111-1307, USA. |
| 26 | |
| 27 | ;;; Commentary: |
| 28 | |
| 29 | ;; The parts of dired mode not normally used. This is a space-saving hack |
| 30 | ;; to avoid having to load a large mode when all that's wanted are a few |
| 31 | ;; functions. |
| 32 | |
| 33 | ;; Rewritten in 1990/1991 to add tree features, file marking and |
| 34 | ;; sorting by Sebastian Kremer <sk@thp.uni-koeln.de>. |
| 35 | ;; Finished up by rms in 1992. |
| 36 | |
| 37 | ;;; Code: |
| 38 | |
| 39 | ;; We need macros in dired.el to compile properly. |
| 40 | (eval-when-compile (require 'dired)) |
| 41 | |
| 42 | ;;; 15K |
| 43 | ;;;###begin dired-cmd.el |
| 44 | ;; Diffing and compressing |
| 45 | |
| 46 | ;;;###autoload |
| 47 | (defun dired-diff (file &optional switches) |
| 48 | "Compare file at point with file FILE using `diff'. |
| 49 | FILE defaults to the file at the mark. (That's the mark set by |
| 50 | \\[set-mark-command], not by Dired's \\[dired-mark] command.) |
| 51 | The prompted-for file is the first file given to `diff'. |
| 52 | With prefix arg, prompt for second argument SWITCHES, |
| 53 | which is options for `diff'." |
| 54 | (interactive |
| 55 | (let ((default (if (mark t) |
| 56 | (save-excursion (goto-char (mark t)) |
| 57 | (dired-get-filename t t))))) |
| 58 | (require 'diff) |
| 59 | (list (read-file-name (format "Diff %s with: %s" |
| 60 | (dired-get-filename t) |
| 61 | (if default |
| 62 | (concat "(default " default ") ") |
| 63 | "")) |
| 64 | (dired-current-directory) default t) |
| 65 | (if current-prefix-arg |
| 66 | (read-string "Options for diff: " |
| 67 | (if (stringp diff-switches) |
| 68 | diff-switches |
| 69 | (mapconcat 'identity diff-switches " "))))))) |
| 70 | (diff file (dired-get-filename t) switches)) |
| 71 | |
| 72 | ;;;###autoload |
| 73 | (defun dired-backup-diff (&optional switches) |
| 74 | "Diff this file with its backup file or vice versa. |
| 75 | Uses the latest backup, if there are several numerical backups. |
| 76 | If this file is a backup, diff it with its original. |
| 77 | The backup file is the first file given to `diff'. |
| 78 | With prefix arg, prompt for argument SWITCHES which is options for `diff'." |
| 79 | (interactive |
| 80 | (if current-prefix-arg |
| 81 | (list (read-string "Options for diff: " |
| 82 | (if (stringp diff-switches) |
| 83 | diff-switches |
| 84 | (mapconcat 'identity diff-switches " ")))) |
| 85 | nil)) |
| 86 | (diff-backup (dired-get-filename) switches)) |
| 87 | |
| 88 | (defun dired-do-chxxx (attribute-name program op-symbol arg) |
| 89 | ;; Change file attributes (mode, group, owner) of marked files and |
| 90 | ;; refresh their file lines. |
| 91 | ;; ATTRIBUTE-NAME is a string describing the attribute to the user. |
| 92 | ;; PROGRAM is the program used to change the attribute. |
| 93 | ;; OP-SYMBOL is the type of operation (for use in dired-mark-pop-up). |
| 94 | ;; ARG describes which files to use, as in dired-get-marked-files. |
| 95 | (let* ((files (dired-get-marked-files t arg)) |
| 96 | (new-attribute |
| 97 | (dired-mark-read-string |
| 98 | (concat "Change " attribute-name " of %s to: ") |
| 99 | nil op-symbol arg files)) |
| 100 | (operation (concat program " " new-attribute)) |
| 101 | failures) |
| 102 | (setq failures |
| 103 | (dired-bunch-files 10000 |
| 104 | (function dired-check-process) |
| 105 | (append |
| 106 | (list operation program new-attribute) |
| 107 | (if (string-match "gnu" system-configuration) |
| 108 | '("--") nil)) |
| 109 | files)) |
| 110 | (dired-do-redisplay arg);; moves point if ARG is an integer |
| 111 | (if failures |
| 112 | (dired-log-summary |
| 113 | (format "%s: error" operation) |
| 114 | nil)))) |
| 115 | |
| 116 | ;;;###autoload |
| 117 | (defun dired-do-chmod (&optional arg) |
| 118 | "Change the mode of the marked (or next ARG) files. |
| 119 | This calls chmod, thus symbolic modes like `g+w' are allowed." |
| 120 | (interactive "P") |
| 121 | (dired-do-chxxx "Mode" dired-chmod-program 'chmod arg)) |
| 122 | |
| 123 | ;;;###autoload |
| 124 | (defun dired-do-chgrp (&optional arg) |
| 125 | "Change the group of the marked (or next ARG) files." |
| 126 | (interactive "P") |
| 127 | (if (memq system-type '(ms-dos windows-nt)) |
| 128 | (error "chgrp not supported on this system")) |
| 129 | (dired-do-chxxx "Group" "chgrp" 'chgrp arg)) |
| 130 | |
| 131 | ;;;###autoload |
| 132 | (defun dired-do-chown (&optional arg) |
| 133 | "Change the owner of the marked (or next ARG) files." |
| 134 | (interactive "P") |
| 135 | (if (memq system-type '(ms-dos windows-nt)) |
| 136 | (error "chown not supported on this system")) |
| 137 | (dired-do-chxxx "Owner" dired-chown-program 'chown arg)) |
| 138 | |
| 139 | ;; Process all the files in FILES in batches of a convenient size, |
| 140 | ;; by means of (FUNCALL FUNCTION ARGS... SOME-FILES...). |
| 141 | ;; Batches are chosen to need less than MAX chars for the file names, |
| 142 | ;; allowing 3 extra characters of separator per file name. |
| 143 | (defun dired-bunch-files (max function args files) |
| 144 | (let (pending |
| 145 | (pending-length 0) |
| 146 | failures) |
| 147 | ;; Accumulate files as long as they fit in MAX chars, |
| 148 | ;; then process the ones accumulated so far. |
| 149 | (while files |
| 150 | (let* ((thisfile (car files)) |
| 151 | (thislength (+ (length thisfile) 3)) |
| 152 | (rest (cdr files))) |
| 153 | ;; If we have at least 1 pending file |
| 154 | ;; and this file won't fit in the length limit, process now. |
| 155 | (if (and pending (> (+ thislength pending-length) max)) |
| 156 | (setq failures |
| 157 | (nconc (apply function (append args (nreverse pending))) |
| 158 | failures) |
| 159 | pending nil |
| 160 | pending-length 0)) |
| 161 | ;; Do (setq pending (cons thisfile pending)) |
| 162 | ;; but reuse the cons that was in `files'. |
| 163 | (setcdr files pending) |
| 164 | (setq pending files) |
| 165 | (setq pending-length (+ thislength pending-length)) |
| 166 | (setq files rest))) |
| 167 | (nconc (apply function (append args (nreverse pending))) |
| 168 | failures))) |
| 169 | |
| 170 | ;;;###autoload |
| 171 | (defun dired-do-print (&optional arg) |
| 172 | "Print the marked (or next ARG) files. |
| 173 | Uses the shell command coming from variables `lpr-command' and |
| 174 | `lpr-switches' as default." |
| 175 | (interactive "P") |
| 176 | (let* ((file-list (dired-get-marked-files t arg)) |
| 177 | (command (dired-mark-read-string |
| 178 | "Print %s with: " |
| 179 | (mapconcat 'identity |
| 180 | (cons lpr-command |
| 181 | (if (stringp lpr-switches) |
| 182 | (list lpr-switches) |
| 183 | lpr-switches)) |
| 184 | " ") |
| 185 | 'print arg file-list))) |
| 186 | (dired-run-shell-command (dired-shell-stuff-it command file-list nil)))) |
| 187 | |
| 188 | ;; Read arguments for a marked-files command that wants a string |
| 189 | ;; that is not a file name, |
| 190 | ;; perhaps popping up the list of marked files. |
| 191 | ;; ARG is the prefix arg and indicates whether the files came from |
| 192 | ;; marks (ARG=nil) or a repeat factor (integerp ARG). |
| 193 | ;; If the current file was used, the list has but one element and ARG |
| 194 | ;; does not matter. (It is non-nil, non-integer in that case, namely '(4)). |
| 195 | |
| 196 | (defun dired-mark-read-string (prompt initial op-symbol arg files) |
| 197 | ;; PROMPT for a string, with INITIAL input. |
| 198 | ;; Other args are used to give user feedback and pop-up: |
| 199 | ;; OP-SYMBOL of command, prefix ARG, marked FILES. |
| 200 | (dired-mark-pop-up |
| 201 | nil op-symbol files |
| 202 | (function read-string) |
| 203 | (format prompt (dired-mark-prompt arg files)) initial)) |
| 204 | \f |
| 205 | ;;; Cleaning a directory: flagging some backups for deletion. |
| 206 | |
| 207 | (defvar dired-file-version-alist) |
| 208 | |
| 209 | (defun dired-clean-directory (keep) |
| 210 | "Flag numerical backups for deletion. |
| 211 | Spares `dired-kept-versions' latest versions, and `kept-old-versions' oldest. |
| 212 | Positive prefix arg KEEP overrides `dired-kept-versions'; |
| 213 | Negative prefix arg KEEP overrides `kept-old-versions' with KEEP made positive. |
| 214 | |
| 215 | To clear the flags on these files, you can use \\[dired-flag-backup-files] |
| 216 | with a prefix argument." |
| 217 | (interactive "P") |
| 218 | (setq keep (if keep (prefix-numeric-value keep) dired-kept-versions)) |
| 219 | (let ((early-retention (if (< keep 0) (- keep) kept-old-versions)) |
| 220 | (late-retention (if (<= keep 0) dired-kept-versions keep)) |
| 221 | (dired-file-version-alist ())) |
| 222 | (message "Cleaning numerical backups (keeping %d late, %d old)..." |
| 223 | late-retention early-retention) |
| 224 | ;; Look at each file. |
| 225 | ;; If the file has numeric backup versions, |
| 226 | ;; put on dired-file-version-alist an element of the form |
| 227 | ;; (FILENAME . VERSION-NUMBER-LIST) |
| 228 | (dired-map-dired-file-lines (function dired-collect-file-versions)) |
| 229 | ;; Sort each VERSION-NUMBER-LIST, |
| 230 | ;; and remove the versions not to be deleted. |
| 231 | (let ((fval dired-file-version-alist)) |
| 232 | (while fval |
| 233 | (let* ((sorted-v-list (cons 'q (sort (cdr (car fval)) '<))) |
| 234 | (v-count (length sorted-v-list))) |
| 235 | (if (> v-count (+ early-retention late-retention)) |
| 236 | (rplacd (nthcdr early-retention sorted-v-list) |
| 237 | (nthcdr (- v-count late-retention) |
| 238 | sorted-v-list))) |
| 239 | (rplacd (car fval) |
| 240 | (cdr sorted-v-list))) |
| 241 | (setq fval (cdr fval)))) |
| 242 | ;; Look at each file. If it is a numeric backup file, |
| 243 | ;; find it in a VERSION-NUMBER-LIST and maybe flag it for deletion. |
| 244 | (dired-map-dired-file-lines (function dired-trample-file-versions)) |
| 245 | (message "Cleaning numerical backups...done"))) |
| 246 | |
| 247 | ;;; Subroutines of dired-clean-directory. |
| 248 | |
| 249 | (defun dired-map-dired-file-lines (fun) |
| 250 | ;; Perform FUN with point at the end of each non-directory line. |
| 251 | ;; FUN takes one argument, the absolute filename. |
| 252 | (save-excursion |
| 253 | (let (file buffer-read-only) |
| 254 | (goto-char (point-min)) |
| 255 | (while (not (eobp)) |
| 256 | (save-excursion |
| 257 | (and (not (looking-at dired-re-dir)) |
| 258 | (not (eolp)) |
| 259 | (setq file (dired-get-filename nil t)) ; nil on non-file |
| 260 | (progn (end-of-line) |
| 261 | (funcall fun file)))) |
| 262 | (forward-line 1))))) |
| 263 | |
| 264 | (defun dired-collect-file-versions (fn) |
| 265 | (let ((fn (file-name-sans-versions fn))) |
| 266 | ;; Only do work if this file is not already in the alist. |
| 267 | (if (assoc fn dired-file-version-alist) |
| 268 | nil |
| 269 | ;; If it looks like file FN has versions, return a list of the versions. |
| 270 | ;;That is a list of strings which are file names. |
| 271 | ;;The caller may want to flag some of these files for deletion. |
| 272 | (let* ((base-versions |
| 273 | (concat (file-name-nondirectory fn) ".~")) |
| 274 | (backup-extract-version-start (length base-versions)) |
| 275 | (possibilities (file-name-all-completions |
| 276 | base-versions |
| 277 | (file-name-directory fn))) |
| 278 | (versions (mapcar 'backup-extract-version possibilities))) |
| 279 | (if versions |
| 280 | (setq dired-file-version-alist |
| 281 | (cons (cons fn versions) |
| 282 | dired-file-version-alist))))))) |
| 283 | |
| 284 | (defun dired-trample-file-versions (fn) |
| 285 | (let* ((start-vn (string-match "\\.~[0-9]+~$" fn)) |
| 286 | base-version-list) |
| 287 | (and start-vn |
| 288 | (setq base-version-list ; there was a base version to which |
| 289 | (assoc (substring fn 0 start-vn) ; this looks like a |
| 290 | dired-file-version-alist)) ; subversion |
| 291 | (not (memq (string-to-int (substring fn (+ 2 start-vn))) |
| 292 | base-version-list)) ; this one doesn't make the cut |
| 293 | (progn (beginning-of-line) |
| 294 | (delete-char 1) |
| 295 | (insert dired-del-marker))))) |
| 296 | \f |
| 297 | ;;; Shell commands |
| 298 | |
| 299 | (defun dired-read-shell-command (prompt arg files) |
| 300 | ;; "Read a dired shell command prompting with PROMPT (using read-string). |
| 301 | ;;ARG is the prefix arg and may be used to indicate in the prompt which |
| 302 | ;; files are affected. |
| 303 | ;;This is an extra function so that you can redefine it, e.g., to use gmhist." |
| 304 | (dired-mark-pop-up |
| 305 | nil 'shell files |
| 306 | (function read-string) |
| 307 | (format prompt (dired-mark-prompt arg files)) |
| 308 | nil 'shell-command-history)) |
| 309 | |
| 310 | ;; The in-background argument is only needed in Emacs 18 where |
| 311 | ;; shell-command doesn't understand an appended ampersand `&'. |
| 312 | ;;;###autoload |
| 313 | (defun dired-do-shell-command (command &optional arg file-list) |
| 314 | "Run a shell command COMMAND on the marked files. |
| 315 | If no files are marked or a specific numeric prefix arg is given, |
| 316 | the next ARG files are used. Just \\[universal-argument] means the current file. |
| 317 | The prompt mentions the file(s) or the marker, as appropriate. |
| 318 | |
| 319 | If there is a `*' in COMMAND, surrounded by whitespace, this runs |
| 320 | COMMAND just once with the entire file list substituted there. |
| 321 | |
| 322 | If there is no `*', but there is a `?' in COMMAND, surrounded by |
| 323 | whitespace, this runs COMMAND on each file individually with the |
| 324 | file name substituted for `?'. |
| 325 | |
| 326 | Otherwise, this runs COMMAND on each file individually with the |
| 327 | file name added at the end of COMMAND (separated by a space). |
| 328 | |
| 329 | `*' and `?' when not surrounded by whitespace have no special |
| 330 | significance for `dired-do-shell-command', and are passed through |
| 331 | normally to the shell, but you must confirm first. To pass `*' by |
| 332 | itself to the shell as a wildcard, type `*\"\"'. |
| 333 | |
| 334 | If COMMAND produces output, it goes to a separate buffer. |
| 335 | |
| 336 | This feature does not try to redisplay Dired buffers afterward, as |
| 337 | there's no telling what files COMMAND may have changed. |
| 338 | Type \\[dired-do-redisplay] to redisplay the marked files. |
| 339 | |
| 340 | When COMMAND runs, its working directory is the top-level directory of |
| 341 | the Dired buffer, so output files usually are created there instead of |
| 342 | in a subdir. |
| 343 | |
| 344 | In a noninteractive call (from Lisp code), you must specify |
| 345 | the list of file names explicitly with the FILE-LIST argument." |
| 346 | ;;Functions dired-run-shell-command and dired-shell-stuff-it do the |
| 347 | ;;actual work and can be redefined for customization. |
| 348 | (interactive |
| 349 | (let ((files (dired-get-marked-files t current-prefix-arg))) |
| 350 | (list |
| 351 | ;; Want to give feedback whether this file or marked files are used: |
| 352 | (dired-read-shell-command (concat "! on " |
| 353 | "%s: ") |
| 354 | current-prefix-arg |
| 355 | files) |
| 356 | current-prefix-arg |
| 357 | files))) |
| 358 | (let* ((on-each (not (string-match "\\(^\\|[ \t]\\)\\*\\([ \t]\\|$\\)" command))) |
| 359 | (subst (not (string-match "\\(^\\|[ \t]\\)\\?\\([ \t]\\|$\\)" command))) |
| 360 | (star (not (string-match "\\*" command))) |
| 361 | (qmark (not (string-match "\\?" command)))) |
| 362 | ;; Get confirmation for wildcards that may have been meant |
| 363 | ;; to control substitution of a file name or the file name list. |
| 364 | (if (cond ((and star (not on-each)) |
| 365 | (y-or-n-p "Confirm--do you mean to use `*' as a wildcard? ")) |
| 366 | ((and qmark (not subst)) |
| 367 | (y-or-n-p "Confirm--do you mean to use `?' as a wildcard? ")) |
| 368 | (t)) |
| 369 | (if on-each |
| 370 | (dired-bunch-files |
| 371 | (- 10000 (length command)) |
| 372 | (function (lambda (&rest files) |
| 373 | (dired-run-shell-command |
| 374 | (dired-shell-stuff-it command files t arg)))) |
| 375 | nil |
| 376 | file-list) |
| 377 | ;; execute the shell command |
| 378 | (dired-run-shell-command |
| 379 | (dired-shell-stuff-it command file-list nil arg)))))) |
| 380 | |
| 381 | ;; Might use {,} for bash or csh: |
| 382 | (defvar dired-mark-prefix "" |
| 383 | "Prepended to marked files in dired shell commands.") |
| 384 | (defvar dired-mark-postfix "" |
| 385 | "Appended to marked files in dired shell commands.") |
| 386 | (defvar dired-mark-separator " " |
| 387 | "Separates marked files in dired shell commands.") |
| 388 | |
| 389 | (defun dired-shell-stuff-it (command file-list on-each &optional raw-arg) |
| 390 | ;; "Make up a shell command line from COMMAND and FILE-LIST. |
| 391 | ;; If ON-EACH is t, COMMAND should be applied to each file, else |
| 392 | ;; simply concat all files and apply COMMAND to this. |
| 393 | ;; FILE-LIST's elements will be quoted for the shell." |
| 394 | ;; Might be redefined for smarter things and could then use RAW-ARG |
| 395 | ;; (coming from interactive P and currently ignored) to decide what to do. |
| 396 | ;; Smart would be a way to access basename or extension of file names. |
| 397 | (let ((stuff-it |
| 398 | (cond ((string-match "\\(^\\|[ \t]\\)\\*\\([ \t]\\|$\\)" command) |
| 399 | (lambda (x) |
| 400 | (string-match "\\(^\\|[ \t]\\)\\(\\*\\)\\([ \t]\\|$\\)" command) |
| 401 | (replace-match x t t command 2))) |
| 402 | ((string-match "\\(^\\|[ \t]\\)\\?\\([ \t]\\|$\\)" command) |
| 403 | (lambda (x) |
| 404 | (string-match "\\(^\\|[ \t]\\)\\(\\?\\)\\([ \t]\\|$\\)" command) |
| 405 | (replace-match x t t command 2))) |
| 406 | (t (lambda (x) (concat command dired-mark-separator x)))))) |
| 407 | (if on-each |
| 408 | (mapconcat stuff-it (mapcar 'shell-quote-argument file-list) ";") |
| 409 | (let ((files (mapconcat 'shell-quote-argument |
| 410 | file-list dired-mark-separator))) |
| 411 | (if (> (length file-list) 1) |
| 412 | (setq files (concat dired-mark-prefix files dired-mark-postfix))) |
| 413 | (funcall stuff-it files))))) |
| 414 | |
| 415 | ;; This is an extra function so that it can be redefined by ange-ftp. |
| 416 | (defun dired-run-shell-command (command) |
| 417 | (let ((handler |
| 418 | (find-file-name-handler (directory-file-name default-directory) |
| 419 | 'shell-command))) |
| 420 | (if handler (apply handler 'shell-command (list command)) |
| 421 | (shell-command command))) |
| 422 | ;; Return nil for sake of nconc in dired-bunch-files. |
| 423 | nil) |
| 424 | \f |
| 425 | ;; In Emacs 19 this will return program's exit status. |
| 426 | ;; This is a separate function so that ange-ftp can redefine it. |
| 427 | (defun dired-call-process (program discard &rest arguments) |
| 428 | ; "Run PROGRAM with output to current buffer unless DISCARD is t. |
| 429 | ;Remaining arguments are strings passed as command arguments to PROGRAM." |
| 430 | ;; Look for a handler for default-directory in case it is a remote file name. |
| 431 | (let ((handler |
| 432 | (find-file-name-handler (directory-file-name default-directory) |
| 433 | 'dired-call-process))) |
| 434 | (if handler (apply handler 'dired-call-process |
| 435 | program discard arguments) |
| 436 | (apply 'call-process program nil (not discard) nil arguments)))) |
| 437 | |
| 438 | (defun dired-check-process (msg program &rest arguments) |
| 439 | ; "Display MSG while running PROGRAM, and check for output. |
| 440 | ;Remaining arguments are strings passed as command arguments to PROGRAM. |
| 441 | ; On error, insert output |
| 442 | ; in a log buffer and return the offending ARGUMENTS or PROGRAM. |
| 443 | ; Caller can cons up a list of failed args. |
| 444 | ;Else returns nil for success." |
| 445 | (let (err-buffer err (dir default-directory)) |
| 446 | (message "%s..." msg) |
| 447 | (save-excursion |
| 448 | ;; Get a clean buffer for error output: |
| 449 | (setq err-buffer (get-buffer-create " *dired-check-process output*")) |
| 450 | (set-buffer err-buffer) |
| 451 | (erase-buffer) |
| 452 | (setq default-directory dir ; caller's default-directory |
| 453 | err (/= 0 |
| 454 | (apply (function dired-call-process) program nil arguments))) |
| 455 | (if err |
| 456 | (progn |
| 457 | (dired-log (concat program " " (prin1-to-string arguments) "\n")) |
| 458 | (dired-log err-buffer) |
| 459 | (or arguments program t)) |
| 460 | (kill-buffer err-buffer) |
| 461 | (message "%s...done" msg) |
| 462 | nil)))) |
| 463 | \f |
| 464 | ;; Commands that delete or redisplay part of the dired buffer. |
| 465 | |
| 466 | (defun dired-kill-line (&optional arg) |
| 467 | (interactive "P") |
| 468 | (setq arg (prefix-numeric-value arg)) |
| 469 | (let (buffer-read-only file) |
| 470 | (while (/= 0 arg) |
| 471 | (setq file (dired-get-filename nil t)) |
| 472 | (if (not file) |
| 473 | (error "Can only kill file lines") |
| 474 | (save-excursion (and file |
| 475 | (dired-goto-subdir file) |
| 476 | (dired-kill-subdir))) |
| 477 | (delete-region (progn (beginning-of-line) (point)) |
| 478 | (progn (forward-line 1) (point))) |
| 479 | (if (> arg 0) |
| 480 | (setq arg (1- arg)) |
| 481 | (setq arg (1+ arg)) |
| 482 | (forward-line -1)))) |
| 483 | (dired-move-to-filename))) |
| 484 | |
| 485 | ;;;###autoload |
| 486 | (defun dired-do-kill-lines (&optional arg fmt) |
| 487 | "Kill all marked lines (not the files). |
| 488 | With a prefix argument, kill that many lines starting with the current line. |
| 489 | \(A negative argument kills lines before the current line.) |
| 490 | To kill an entire subdirectory, go to its directory header line |
| 491 | and use this command with a prefix argument (the value does not matter)." |
| 492 | ;; Returns count of killed lines. FMT="" suppresses message. |
| 493 | (interactive "P") |
| 494 | (if arg |
| 495 | (if (dired-get-subdir) |
| 496 | (dired-kill-subdir) |
| 497 | (dired-kill-line arg)) |
| 498 | (save-excursion |
| 499 | (goto-char (point-min)) |
| 500 | (let (buffer-read-only (count 0)) |
| 501 | (if (not arg) ; kill marked lines |
| 502 | (let ((regexp (dired-marker-regexp))) |
| 503 | (while (and (not (eobp)) |
| 504 | (re-search-forward regexp nil t)) |
| 505 | (setq count (1+ count)) |
| 506 | (delete-region (progn (beginning-of-line) (point)) |
| 507 | (progn (forward-line 1) (point))))) |
| 508 | ;; else kill unmarked lines |
| 509 | (while (not (eobp)) |
| 510 | (if (or (dired-between-files) |
| 511 | (not (looking-at "^ "))) |
| 512 | (forward-line 1) |
| 513 | (setq count (1+ count)) |
| 514 | (delete-region (point) (save-excursion |
| 515 | (forward-line 1) |
| 516 | (point)))))) |
| 517 | (or (equal "" fmt) |
| 518 | (message (or fmt "Killed %d line%s.") count (dired-plural-s count))) |
| 519 | count)))) |
| 520 | |
| 521 | ;;;###end dired-cmd.el |
| 522 | \f |
| 523 | ;;; 30K |
| 524 | ;;;###begin dired-cp.el |
| 525 | |
| 526 | (defun dired-compress () |
| 527 | ;; Compress or uncompress the current file. |
| 528 | ;; Return nil for success, offending filename else. |
| 529 | (let* (buffer-read-only |
| 530 | (from-file (dired-get-filename)) |
| 531 | (new-file (dired-compress-file from-file))) |
| 532 | (if new-file |
| 533 | (let ((start (point))) |
| 534 | ;; Remove any preexisting entry for the name NEW-FILE. |
| 535 | (condition-case nil |
| 536 | (dired-remove-entry new-file) |
| 537 | (error nil)) |
| 538 | (goto-char start) |
| 539 | ;; Now replace the current line with an entry for NEW-FILE. |
| 540 | (dired-update-file-line new-file) nil) |
| 541 | (dired-log (concat "Failed to compress" from-file)) |
| 542 | from-file))) |
| 543 | |
| 544 | (defvar dired-compress-file-suffixes |
| 545 | '(("\\.gz\\'" "" "gunzip") |
| 546 | ("\\.tgz\\'" ".tar" "gunzip") |
| 547 | ("\\.Z\\'" "" "uncompress") |
| 548 | ;; For .z, try gunzip. It might be an old gzip file, |
| 549 | ;; or it might be from compact? pack? (which?) but gunzip handles both. |
| 550 | ("\\.z\\'" "" "gunzip") |
| 551 | ("\\.bz2\\'" "" "bunzip2") |
| 552 | ;; This item controls naming for compression. |
| 553 | ("\\.tar\\'" ".tgz" nil)) |
| 554 | "Control changes in file name suffixes for compression and uncompression. |
| 555 | Each element specifies one transformation rule, and has the form: |
| 556 | (REGEXP NEW-SUFFIX PROGRAM) |
| 557 | The rule applies when the old file name matches REGEXP. |
| 558 | The new file name is computed by deleting the part that matches REGEXP |
| 559 | (as well as anything after that), then adding NEW-SUFFIX in its place. |
| 560 | If PROGRAM is non-nil, the rule is an uncompression rule, |
| 561 | and uncompression is done by running PROGRAM. |
| 562 | Otherwise, the rule is a compression rule, and compression is done with gzip.") |
| 563 | |
| 564 | ;;;###autoload |
| 565 | (defun dired-compress-file (file) |
| 566 | ;; Compress or uncompress FILE. |
| 567 | ;; Return the name of the compressed or uncompressed file. |
| 568 | ;; Return nil if no change in files. |
| 569 | (let ((handler (find-file-name-handler file 'dired-compress-file)) |
| 570 | suffix newname |
| 571 | (suffixes dired-compress-file-suffixes)) |
| 572 | ;; See if any suffix rule matches this file name. |
| 573 | (while suffixes |
| 574 | (let (case-fold-search) |
| 575 | (if (string-match (car (car suffixes)) file) |
| 576 | (setq suffix (car suffixes) suffixes nil)) |
| 577 | (setq suffixes (cdr suffixes)))) |
| 578 | ;; If so, compute desired new name. |
| 579 | (if suffix |
| 580 | (setq newname (concat (substring file 0 (match-beginning 0)) |
| 581 | (nth 1 suffix)))) |
| 582 | (cond (handler |
| 583 | (funcall handler 'dired-compress-file file)) |
| 584 | ((file-symlink-p file) |
| 585 | nil) |
| 586 | ((and suffix (nth 2 suffix)) |
| 587 | ;; We found an uncompression rule. |
| 588 | (if (not (dired-check-process (concat "Uncompressing " file) |
| 589 | (nth 2 suffix) file)) |
| 590 | newname)) |
| 591 | (t |
| 592 | ;;; We don't recognize the file as compressed, so compress it. |
| 593 | ;;; Try gzip; if we don't have that, use compress. |
| 594 | (condition-case nil |
| 595 | (if (not (dired-check-process (concat "Compressing " file) |
| 596 | "gzip" "-f" file)) |
| 597 | (let ((out-name |
| 598 | (if (file-exists-p (concat file ".gz")) |
| 599 | (concat file ".gz") |
| 600 | (concat file ".z")))) |
| 601 | ;; Rename the compressed file to NEWNAME |
| 602 | ;; if it hasn't got that name already. |
| 603 | (if (and newname (not (equal newname out-name))) |
| 604 | (progn |
| 605 | (rename-file out-name newname t) |
| 606 | newname) |
| 607 | out-name))) |
| 608 | (file-error |
| 609 | (if (not (dired-check-process (concat "Compressing " file) |
| 610 | "compress" "-f" file)) |
| 611 | ;; Don't use NEWNAME with `compress'. |
| 612 | (concat file ".Z")))))))) |
| 613 | \f |
| 614 | (defun dired-mark-confirm (op-symbol arg) |
| 615 | ;; Request confirmation from the user that the operation described |
| 616 | ;; by OP-SYMBOL is to be performed on the marked files. |
| 617 | ;; Confirmation consists in a y-or-n question with a file list |
| 618 | ;; pop-up unless OP-SYMBOL is a member of `dired-no-confirm'. |
| 619 | ;; The files used are determined by ARG (as in dired-get-marked-files). |
| 620 | (or (eq dired-no-confirm t) |
| 621 | (memq op-symbol dired-no-confirm) |
| 622 | (let ((files (dired-get-marked-files t arg)) |
| 623 | (string (if (eq op-symbol 'compress) "Compress or uncompress" |
| 624 | (capitalize (symbol-name op-symbol))))) |
| 625 | (dired-mark-pop-up nil op-symbol files (function y-or-n-p) |
| 626 | (concat string " " |
| 627 | (dired-mark-prompt arg files) "? "))))) |
| 628 | |
| 629 | (defun dired-map-over-marks-check (fun arg op-symbol &optional show-progress) |
| 630 | ; "Map FUN over marked files (with second ARG like in dired-map-over-marks) |
| 631 | ; and display failures. |
| 632 | |
| 633 | ; FUN takes zero args. It returns non-nil (the offending object, e.g. |
| 634 | ; the short form of the filename) for a failure and probably logs a |
| 635 | ; detailed error explanation using function `dired-log'. |
| 636 | |
| 637 | ; OP-SYMBOL is a symbol describing the operation performed (e.g. |
| 638 | ; `compress'). It is used with `dired-mark-pop-up' to prompt the user |
| 639 | ; (e.g. with `Compress * [2 files]? ') and to display errors (e.g. |
| 640 | ; `Failed to compress 1 of 2 files - type W to see why ("foo")') |
| 641 | |
| 642 | ; SHOW-PROGRESS if non-nil means redisplay dired after each file." |
| 643 | (if (dired-mark-confirm op-symbol arg) |
| 644 | (let* ((total-list;; all of FUN's return values |
| 645 | (dired-map-over-marks (funcall fun) arg show-progress)) |
| 646 | (total (length total-list)) |
| 647 | (failures (delq nil total-list)) |
| 648 | (count (length failures)) |
| 649 | (string (if (eq op-symbol 'compress) "Compress or uncompress" |
| 650 | (capitalize (symbol-name op-symbol))))) |
| 651 | (if (not failures) |
| 652 | (message "%s: %d file%s." |
| 653 | string total (dired-plural-s total)) |
| 654 | ;; end this bunch of errors: |
| 655 | (dired-log-summary |
| 656 | (format "Failed to %s %d of %d file%s" |
| 657 | (downcase string) count total (dired-plural-s total)) |
| 658 | failures))))) |
| 659 | |
| 660 | (defvar dired-query-alist |
| 661 | '((?\y . y) (?\040 . y) ; `y' or SPC means accept once |
| 662 | (?n . n) (?\177 . n) ; `n' or DEL skips once |
| 663 | (?! . yes) ; `!' accepts rest |
| 664 | (?q. no) (?\e . no) ; `q' or ESC skips rest |
| 665 | ;; None of these keys quit - use C-g for that. |
| 666 | )) |
| 667 | |
| 668 | (defun dired-query (qs-var qs-prompt &rest qs-args) |
| 669 | ;; Query user and return nil or t. |
| 670 | ;; Store answer in symbol VAR (which must initially be bound to nil). |
| 671 | ;; Format PROMPT with ARGS. |
| 672 | ;; Binding variable help-form will help the user who types the help key. |
| 673 | (let* ((char (symbol-value qs-var)) |
| 674 | (action (cdr (assoc char dired-query-alist)))) |
| 675 | (cond ((eq 'yes action) |
| 676 | t) ; accept, and don't ask again |
| 677 | ((eq 'no action) |
| 678 | nil) ; skip, and don't ask again |
| 679 | (t;; no lasting effects from last time we asked - ask now |
| 680 | (let ((qprompt (concat qs-prompt |
| 681 | (if help-form |
| 682 | (format " [Type yn!q or %s] " |
| 683 | (key-description |
| 684 | (char-to-string help-char))) |
| 685 | " [Type y, n, q or !] "))) |
| 686 | result elt) |
| 687 | ;; Actually it looks nicer without cursor-in-echo-area - you can |
| 688 | ;; look at the dired buffer instead of at the prompt to decide. |
| 689 | (apply 'message qprompt qs-args) |
| 690 | (setq char (set qs-var (read-char))) |
| 691 | (while (not (setq elt (assoc char dired-query-alist))) |
| 692 | (message "Invalid char - type %c for help." help-char) |
| 693 | (ding) |
| 694 | (sit-for 1) |
| 695 | (apply 'message qprompt qs-args) |
| 696 | (setq char (set qs-var (read-char)))) |
| 697 | (memq (cdr elt) '(t y yes))))))) |
| 698 | \f |
| 699 | ;;;###autoload |
| 700 | (defun dired-do-compress (&optional arg) |
| 701 | "Compress or uncompress marked (or next ARG) files." |
| 702 | (interactive "P") |
| 703 | (dired-map-over-marks-check (function dired-compress) arg 'compress t)) |
| 704 | |
| 705 | ;; Commands for Emacs Lisp files - load and byte compile |
| 706 | |
| 707 | (defun dired-byte-compile () |
| 708 | ;; Return nil for success, offending file name else. |
| 709 | (let* ((filename (dired-get-filename)) |
| 710 | elc-file buffer-read-only failure) |
| 711 | (condition-case err |
| 712 | (save-excursion (byte-compile-file filename)) |
| 713 | (error |
| 714 | (setq failure err))) |
| 715 | (setq elc-file (byte-compile-dest-file filename)) |
| 716 | (or (file-exists-p elc-file) |
| 717 | (setq failure t)) |
| 718 | (if failure |
| 719 | (progn |
| 720 | (dired-log "Byte compile error for %s:\n%s\n" filename failure) |
| 721 | (dired-make-relative filename)) |
| 722 | (dired-remove-file elc-file) |
| 723 | (forward-line) ; insert .elc after its .el file |
| 724 | (dired-add-file elc-file) |
| 725 | nil))) |
| 726 | |
| 727 | ;;;###autoload |
| 728 | (defun dired-do-byte-compile (&optional arg) |
| 729 | "Byte compile marked (or next ARG) Emacs Lisp files." |
| 730 | (interactive "P") |
| 731 | (dired-map-over-marks-check (function dired-byte-compile) arg 'byte-compile t)) |
| 732 | |
| 733 | (defun dired-load () |
| 734 | ;; Return nil for success, offending file name else. |
| 735 | (let ((file (dired-get-filename)) failure) |
| 736 | (condition-case err |
| 737 | (load file nil nil t) |
| 738 | (error (setq failure err))) |
| 739 | (if (not failure) |
| 740 | nil |
| 741 | (dired-log "Load error for %s:\n%s\n" file failure) |
| 742 | (dired-make-relative file)))) |
| 743 | |
| 744 | ;;;###autoload |
| 745 | (defun dired-do-load (&optional arg) |
| 746 | "Load the marked (or next ARG) Emacs Lisp files." |
| 747 | (interactive "P") |
| 748 | (dired-map-over-marks-check (function dired-load) arg 'load t)) |
| 749 | |
| 750 | ;;;###autoload |
| 751 | (defun dired-do-redisplay (&optional arg test-for-subdir) |
| 752 | "Redisplay all marked (or next ARG) files. |
| 753 | If on a subdir line, redisplay that subdirectory. In that case, |
| 754 | a prefix arg lets you edit the `ls' switches used for the new listing." |
| 755 | ;; Moves point if the next ARG files are redisplayed. |
| 756 | (interactive "P\np") |
| 757 | (if (and test-for-subdir (dired-get-subdir)) |
| 758 | (dired-insert-subdir |
| 759 | (dired-get-subdir) |
| 760 | (if arg (read-string "Switches for listing: " dired-actual-switches))) |
| 761 | (message "Redisplaying...") |
| 762 | ;; message much faster than making dired-map-over-marks show progress |
| 763 | (dired-uncache |
| 764 | (if (consp dired-directory) (car dired-directory) dired-directory)) |
| 765 | (dired-map-over-marks (let ((fname (dired-get-filename))) |
| 766 | (message "Redisplaying... %s" fname) |
| 767 | (dired-update-file-line fname)) |
| 768 | arg) |
| 769 | (dired-move-to-filename) |
| 770 | (message "Redisplaying...done"))) |
| 771 | \f |
| 772 | (defun dired-update-file-line (file) |
| 773 | ;; Delete the current line, and insert an entry for FILE. |
| 774 | ;; If FILE is nil, then just delete the current line. |
| 775 | ;; Keeps any marks that may be present in column one (doing this |
| 776 | ;; here is faster than with dired-add-entry's optional arg). |
| 777 | ;; Does not update other dired buffers. Use dired-relist-entry for that. |
| 778 | (beginning-of-line) |
| 779 | (let ((char (following-char)) (opoint (point)) |
| 780 | (buffer-read-only)) |
| 781 | (delete-region (point) (progn (forward-line 1) (point))) |
| 782 | (if file |
| 783 | (progn |
| 784 | (dired-add-entry file nil t) |
| 785 | ;; Replace space by old marker without moving point. |
| 786 | ;; Faster than goto+insdel inside a save-excursion? |
| 787 | (subst-char-in-region opoint (1+ opoint) ?\040 char)))) |
| 788 | (dired-move-to-filename)) |
| 789 | |
| 790 | (defun dired-fun-in-all-buffers (directory file fun &rest args) |
| 791 | ;; In all buffers dired'ing DIRECTORY, run FUN with ARGS. |
| 792 | ;; If the buffer has a wildcard pattern, check that it matches FILE. |
| 793 | ;; (FILE does not include a directory component.) |
| 794 | ;; FILE may be nil, in which case ignore it. |
| 795 | ;; Return list of buffers where FUN succeeded (i.e., returned non-nil). |
| 796 | (let ((buf-list (dired-buffers-for-dir (expand-file-name directory) |
| 797 | file)) |
| 798 | (obuf (current-buffer)) |
| 799 | buf success-list) |
| 800 | (while buf-list |
| 801 | (setq buf (car buf-list) |
| 802 | buf-list (cdr buf-list)) |
| 803 | (unwind-protect |
| 804 | (progn |
| 805 | (set-buffer buf) |
| 806 | (if (apply fun args) |
| 807 | (setq success-list (cons (buffer-name buf) success-list)))) |
| 808 | (set-buffer obuf))) |
| 809 | success-list)) |
| 810 | |
| 811 | ;;;###autoload |
| 812 | (defun dired-add-file (filename &optional marker-char) |
| 813 | (dired-fun-in-all-buffers |
| 814 | (file-name-directory filename) (file-name-nondirectory filename) |
| 815 | (function dired-add-entry) filename marker-char)) |
| 816 | |
| 817 | (defun dired-add-entry (filename &optional marker-char relative) |
| 818 | ;; Add a new entry for FILENAME, optionally marking it |
| 819 | ;; with MARKER-CHAR (a character, else dired-marker-char is used). |
| 820 | ;; Note that this adds the entry `out of order' if files sorted by |
| 821 | ;; time, etc. |
| 822 | ;; At least this version inserts in the right subdirectory (if present). |
| 823 | ;; And it skips "." or ".." (see `dired-trivial-filenames'). |
| 824 | ;; Hidden subdirs are exposed if a file is added there. |
| 825 | (setq filename (directory-file-name filename)) |
| 826 | ;; Entry is always for files, even if they happen to also be directories |
| 827 | (let* ((opoint (point)) |
| 828 | (cur-dir (dired-current-directory)) |
| 829 | (orig-file-name filename) |
| 830 | (directory (if relative cur-dir (file-name-directory filename))) |
| 831 | reason) |
| 832 | (setq filename |
| 833 | (if relative |
| 834 | (file-relative-name filename directory) |
| 835 | (file-name-nondirectory filename)) |
| 836 | reason |
| 837 | (catch 'not-found |
| 838 | (if (string= directory cur-dir) |
| 839 | (progn |
| 840 | (skip-chars-forward "^\r\n") |
| 841 | (if (eq (following-char) ?\r) |
| 842 | (dired-unhide-subdir)) |
| 843 | ;; We are already where we should be, except when |
| 844 | ;; point is before the subdir line or its total line. |
| 845 | (let ((p (dired-after-subdir-garbage cur-dir))) |
| 846 | (if (< (point) p) |
| 847 | (goto-char p)))) |
| 848 | ;; else try to find correct place to insert |
| 849 | (if (dired-goto-subdir directory) |
| 850 | (progn ;; unhide if necessary |
| 851 | (if (looking-at "\r") ;; point is at end of subdir line |
| 852 | (dired-unhide-subdir)) |
| 853 | ;; found - skip subdir and `total' line |
| 854 | ;; and uninteresting files like . and .. |
| 855 | ;; This better not moves into the next subdir! |
| 856 | (dired-goto-next-nontrivial-file)) |
| 857 | ;; not found |
| 858 | (throw 'not-found "Subdir not found"))) |
| 859 | (let (buffer-read-only opoint) |
| 860 | (beginning-of-line) |
| 861 | (setq opoint (point)) |
| 862 | (dired-add-entry-do-indentation marker-char) |
| 863 | ;; don't expand `.'. Show just the file name within directory. |
| 864 | (let ((default-directory directory)) |
| 865 | (insert-directory filename |
| 866 | (concat dired-actual-switches "d"))) |
| 867 | ;; Compensate for a bug in ange-ftp. |
| 868 | ;; It inserts the file's absolute name, rather than |
| 869 | ;; the relative one. That may be hard to fix since it |
| 870 | ;; is probably controlled by something in ftp. |
| 871 | (goto-char opoint) |
| 872 | (let ((inserted-name (dired-get-filename 'verbatim))) |
| 873 | (if (file-name-directory inserted-name) |
| 874 | (progn |
| 875 | (end-of-line) |
| 876 | (delete-char (- (length inserted-name))) |
| 877 | (insert filename) |
| 878 | (forward-char 1)) |
| 879 | (forward-line 1))) |
| 880 | ;; Give each line a text property recording info about it. |
| 881 | (dired-insert-set-properties opoint (point)) |
| 882 | (forward-line -1) |
| 883 | (if dired-after-readin-hook ;; the subdir-alist is not affected... |
| 884 | (save-excursion ;; ...so we can run it right now: |
| 885 | (save-restriction |
| 886 | (beginning-of-line) |
| 887 | (narrow-to-region (point) (save-excursion |
| 888 | (forward-line 1) (point))) |
| 889 | (run-hooks 'dired-after-readin-hook)))) |
| 890 | (dired-move-to-filename)) |
| 891 | ;; return nil if all went well |
| 892 | nil)) |
| 893 | (if reason ; don't move away on failure |
| 894 | (goto-char opoint)) |
| 895 | (not reason))) ; return t on success, nil else |
| 896 | |
| 897 | ;; This is a separate function for the sake of nested dired format. |
| 898 | (defun dired-add-entry-do-indentation (marker-char) |
| 899 | ;; two spaces or a marker plus a space: |
| 900 | (insert (if marker-char |
| 901 | (if (integerp marker-char) marker-char dired-marker-char) |
| 902 | ?\040) |
| 903 | ?\040)) |
| 904 | |
| 905 | (defun dired-after-subdir-garbage (dir) |
| 906 | ;; Return pos of first file line of DIR, skipping header and total |
| 907 | ;; or wildcard lines. |
| 908 | ;; Important: never moves into the next subdir. |
| 909 | ;; DIR is assumed to be unhidden. |
| 910 | ;; Will probably be redefined for VMS etc. |
| 911 | (save-excursion |
| 912 | (or (dired-goto-subdir dir) (error "This cannot happen")) |
| 913 | (forward-line 1) |
| 914 | (while (and (not (eolp)) ; don't cross subdir boundary |
| 915 | (not (dired-move-to-filename))) |
| 916 | (forward-line 1)) |
| 917 | (point))) |
| 918 | |
| 919 | ;;;###autoload |
| 920 | (defun dired-remove-file (file) |
| 921 | (dired-fun-in-all-buffers |
| 922 | (file-name-directory file) (file-name-nondirectory file) |
| 923 | (function dired-remove-entry) file)) |
| 924 | |
| 925 | (defun dired-remove-entry (file) |
| 926 | (save-excursion |
| 927 | (and (dired-goto-file file) |
| 928 | (let (buffer-read-only) |
| 929 | (delete-region (progn (beginning-of-line) (point)) |
| 930 | (save-excursion (forward-line 1) (point))))))) |
| 931 | |
| 932 | ;;;###autoload |
| 933 | (defun dired-relist-file (file) |
| 934 | (dired-fun-in-all-buffers (file-name-directory file) |
| 935 | (file-name-nondirectory file) |
| 936 | (function dired-relist-entry) file)) |
| 937 | |
| 938 | (defun dired-relist-entry (file) |
| 939 | ;; Relist the line for FILE, or just add it if it did not exist. |
| 940 | ;; FILE must be an absolute file name. |
| 941 | (let (buffer-read-only marker) |
| 942 | ;; If cursor is already on FILE's line delete-region will cause |
| 943 | ;; save-excursion to fail because of floating makers, |
| 944 | ;; moving point to beginning of line. Sigh. |
| 945 | (save-excursion |
| 946 | (and (dired-goto-file file) |
| 947 | (delete-region (progn (beginning-of-line) |
| 948 | (setq marker (following-char)) |
| 949 | (point)) |
| 950 | (save-excursion (forward-line 1) (point)))) |
| 951 | (setq file (directory-file-name file)) |
| 952 | (dired-add-entry file (if (eq ?\040 marker) nil marker))))) |
| 953 | \f |
| 954 | ;;; Copy, move/rename, making hard and symbolic links |
| 955 | |
| 956 | (defcustom dired-recursive-copies nil |
| 957 | "*Decide whether recursive copies are allowed. |
| 958 | nil means no recursive copies. |
| 959 | `always' means copy recursively without asking. |
| 960 | `top' means ask for each directory at top level. |
| 961 | Anything else means ask for each directory." |
| 962 | :type '(choice :tag "Copy directories" |
| 963 | (const :tag "No recursive copies" nil) |
| 964 | (const :tag "Ask for each directory" t) |
| 965 | (const :tag "Ask for each top directory only" top) |
| 966 | (const :tag "Copy directories without asking" always)) |
| 967 | :group 'dired) |
| 968 | |
| 969 | (defcustom dired-backup-overwrite nil |
| 970 | "*Non-nil if Dired should ask about making backups before overwriting files. |
| 971 | Special value `always' suppresses confirmation." |
| 972 | :type '(choice (const :tag "off" nil) |
| 973 | (const :tag "suppress" always) |
| 974 | (other :tag "ask" t)) |
| 975 | :group 'dired) |
| 976 | |
| 977 | (defvar dired-overwrite-confirmed) |
| 978 | |
| 979 | (defun dired-handle-overwrite (to) |
| 980 | ;; Save old version of a to be overwritten file TO. |
| 981 | ;; `dired-overwrite-confirmed' and `overwrite-backup-query' are fluid vars |
| 982 | ;; from dired-create-files. |
| 983 | (let (backup) |
| 984 | (if (and dired-backup-overwrite |
| 985 | dired-overwrite-confirmed |
| 986 | (setq backup (car (find-backup-file-name to))) |
| 987 | (or (eq 'always dired-backup-overwrite) |
| 988 | (dired-query 'overwrite-backup-query |
| 989 | (format "Make backup for existing file `%s'? " |
| 990 | to)))) |
| 991 | (progn |
| 992 | (rename-file to backup 0) ; confirm overwrite of old backup |
| 993 | (dired-relist-entry backup))))) |
| 994 | |
| 995 | ;;;###autoload |
| 996 | (defun dired-copy-file (from to ok-flag) |
| 997 | (dired-handle-overwrite to) |
| 998 | (condition-case () |
| 999 | (dired-copy-file-recursive from to ok-flag dired-copy-preserve-time t |
| 1000 | dired-recursive-copies) |
| 1001 | (file-date-error (message "Can't set date") |
| 1002 | (sit-for 1)))) |
| 1003 | |
| 1004 | (defun dired-copy-file-recursive (from to ok-flag &optional |
| 1005 | preserve-time top recursive) |
| 1006 | (if (and recursive |
| 1007 | (eq t (car (file-attributes from))) ; A directory, no symbolic link. |
| 1008 | (or (eq recursive 'always) |
| 1009 | (yes-or-no-p (format "Recursive copies of %s " from)))) |
| 1010 | (let ((files (directory-files from nil dired-re-no-dot))) |
| 1011 | (if (eq recursive 'top) (setq recursive 'always)) ; Don't ask any more. |
| 1012 | (if (file-exists-p to) |
| 1013 | (or top (dired-handle-overwrite to)) |
| 1014 | (make-directory to)) |
| 1015 | (while files |
| 1016 | (dired-copy-file-recursive |
| 1017 | (expand-file-name (car files) from) |
| 1018 | (expand-file-name (car files) to) |
| 1019 | ok-flag preserve-time nil recursive) |
| 1020 | (setq files (cdr files)))) |
| 1021 | (or top (dired-handle-overwrite to)) ; Just a file. |
| 1022 | (copy-file from to ok-flag dired-copy-preserve-time))) |
| 1023 | |
| 1024 | ;;;###autoload |
| 1025 | (defun dired-rename-file (from to ok-flag) |
| 1026 | (dired-handle-overwrite to) |
| 1027 | (rename-file from to ok-flag) ; error is caught in -create-files |
| 1028 | ;; Silently rename the visited file of any buffer visiting this file. |
| 1029 | (and (get-file-buffer from) |
| 1030 | (with-current-buffer (get-file-buffer from) |
| 1031 | (set-visited-file-name to nil t))) |
| 1032 | (dired-remove-file from) |
| 1033 | ;; See if it's an inserted subdir, and rename that, too. |
| 1034 | (dired-rename-subdir from to)) |
| 1035 | |
| 1036 | (defun dired-rename-subdir (from-dir to-dir) |
| 1037 | (setq from-dir (file-name-as-directory from-dir) |
| 1038 | to-dir (file-name-as-directory to-dir)) |
| 1039 | (dired-fun-in-all-buffers from-dir nil |
| 1040 | (function dired-rename-subdir-1) from-dir to-dir) |
| 1041 | ;; Update visited file name of all affected buffers |
| 1042 | (let ((expanded-from-dir (expand-file-name from-dir)) |
| 1043 | (blist (buffer-list))) |
| 1044 | (while blist |
| 1045 | (save-excursion |
| 1046 | (set-buffer (car blist)) |
| 1047 | (if (and buffer-file-name |
| 1048 | (dired-in-this-tree buffer-file-name expanded-from-dir)) |
| 1049 | (let ((modflag (buffer-modified-p)) |
| 1050 | (to-file (dired-replace-in-string |
| 1051 | (concat "^" (regexp-quote from-dir)) |
| 1052 | to-dir |
| 1053 | buffer-file-name))) |
| 1054 | (set-visited-file-name to-file) |
| 1055 | (set-buffer-modified-p modflag)))) |
| 1056 | (setq blist (cdr blist))))) |
| 1057 | |
| 1058 | (defun dired-rename-subdir-1 (dir to) |
| 1059 | ;; Rename DIR to TO in headerlines and dired-subdir-alist, if DIR or |
| 1060 | ;; one of its subdirectories is expanded in this buffer. |
| 1061 | (let ((expanded-dir (expand-file-name dir)) |
| 1062 | (alist dired-subdir-alist) |
| 1063 | (elt nil)) |
| 1064 | (while alist |
| 1065 | (setq elt (car alist) |
| 1066 | alist (cdr alist)) |
| 1067 | (if (dired-in-this-tree (car elt) expanded-dir) |
| 1068 | ;; ELT's subdir is affected by the rename |
| 1069 | (dired-rename-subdir-2 elt dir to))) |
| 1070 | (if (equal dir default-directory) |
| 1071 | ;; if top level directory was renamed, lots of things have to be |
| 1072 | ;; updated: |
| 1073 | (progn |
| 1074 | (dired-unadvertise dir) ; we no longer dired DIR... |
| 1075 | (setq default-directory to |
| 1076 | dired-directory (expand-file-name;; this is correct |
| 1077 | ;; with and without wildcards |
| 1078 | (file-name-nondirectory dired-directory) |
| 1079 | to)) |
| 1080 | (let ((new-name (file-name-nondirectory |
| 1081 | (directory-file-name dired-directory)))) |
| 1082 | ;; try to rename buffer, but just leave old name if new |
| 1083 | ;; name would already exist (don't try appending "<%d>") |
| 1084 | (or (get-buffer new-name) |
| 1085 | (rename-buffer new-name))) |
| 1086 | ;; ... we dired TO now: |
| 1087 | (dired-advertise))))) |
| 1088 | |
| 1089 | (defun dired-rename-subdir-2 (elt dir to) |
| 1090 | ;; Update the headerline and dired-subdir-alist element of directory |
| 1091 | ;; described by alist-element ELT to reflect the moving of DIR to TO. |
| 1092 | ;; Thus, ELT describes either DIR itself or a subdir of DIR. |
| 1093 | (save-excursion |
| 1094 | (let ((regexp (regexp-quote (directory-file-name dir))) |
| 1095 | (newtext (directory-file-name to)) |
| 1096 | buffer-read-only) |
| 1097 | (goto-char (dired-get-subdir-min elt)) |
| 1098 | ;; Update subdir headerline in buffer |
| 1099 | (if (not (looking-at dired-subdir-regexp)) |
| 1100 | (error "%s not found where expected - dired-subdir-alist broken?" |
| 1101 | dir) |
| 1102 | (goto-char (match-beginning 1)) |
| 1103 | (if (re-search-forward regexp (match-end 1) t) |
| 1104 | (replace-match newtext t t) |
| 1105 | (error "Expected to find `%s' in headerline of %s" dir (car elt)))) |
| 1106 | ;; Update buffer-local dired-subdir-alist |
| 1107 | (setcar elt |
| 1108 | (dired-normalize-subdir |
| 1109 | (dired-replace-in-string regexp newtext (car elt))))))) |
| 1110 | \f |
| 1111 | ;; The basic function for half a dozen variations on cp/mv/ln/ln -s. |
| 1112 | (defun dired-create-files (file-creator operation fn-list name-constructor |
| 1113 | &optional marker-char) |
| 1114 | |
| 1115 | ;; Create a new file for each from a list of existing files. The user |
| 1116 | ;; is queried, dired buffers are updated, and at the end a success or |
| 1117 | ;; failure message is displayed |
| 1118 | |
| 1119 | ;; FILE-CREATOR must accept three args: oldfile newfile ok-if-already-exists |
| 1120 | |
| 1121 | ;; It is called for each file and must create newfile, the entry of |
| 1122 | ;; which will be added. The user will be queried if the file already |
| 1123 | ;; exists. If oldfile is removed by FILE-CREATOR (i.e, it is a |
| 1124 | ;; rename), it is FILE-CREATOR's responsibility to update dired |
| 1125 | ;; buffers. FILE-CREATOR must abort by signaling a file-error if it |
| 1126 | ;; could not create newfile. The error is caught and logged. |
| 1127 | |
| 1128 | ;; OPERATION (a capitalized string, e.g. `Copy') describes the |
| 1129 | ;; operation performed. It is used for error logging. |
| 1130 | |
| 1131 | ;; FN-LIST is the list of files to copy (full absolute file names). |
| 1132 | |
| 1133 | ;; NAME-CONSTRUCTOR returns a newfile for every oldfile, or nil to |
| 1134 | ;; skip. If it skips files for other reasons than a direct user |
| 1135 | ;; query, it is supposed to tell why (using dired-log). |
| 1136 | |
| 1137 | ;; Optional MARKER-CHAR is a character with which to mark every |
| 1138 | ;; newfile's entry, or t to use the current marker character if the |
| 1139 | ;; oldfile was marked. |
| 1140 | |
| 1141 | (let (failures skipped (success-count 0) (total (length fn-list))) |
| 1142 | (let (to overwrite-query |
| 1143 | overwrite-backup-query) ; for dired-handle-overwrite |
| 1144 | (mapcar |
| 1145 | (function |
| 1146 | (lambda (from) |
| 1147 | (setq to (funcall name-constructor from)) |
| 1148 | (if (equal to from) |
| 1149 | (progn |
| 1150 | (setq to nil) |
| 1151 | (dired-log "Cannot %s to same file: %s\n" |
| 1152 | (downcase operation) from))) |
| 1153 | (if (not to) |
| 1154 | (setq skipped (cons (dired-make-relative from) skipped)) |
| 1155 | (let* ((overwrite (file-exists-p to)) |
| 1156 | (dired-overwrite-confirmed ; for dired-handle-overwrite |
| 1157 | (and overwrite |
| 1158 | (let ((help-form '(format "\ |
| 1159 | Type SPC or `y' to overwrite file `%s', |
| 1160 | DEL or `n' to skip to next, |
| 1161 | ESC or `q' to not overwrite any of the remaining files, |
| 1162 | `!' to overwrite all remaining files with no more questions." to))) |
| 1163 | (dired-query 'overwrite-query |
| 1164 | "Overwrite `%s'?" to)))) |
| 1165 | ;; must determine if FROM is marked before file-creator |
| 1166 | ;; gets a chance to delete it (in case of a move). |
| 1167 | (actual-marker-char |
| 1168 | (cond ((integerp marker-char) marker-char) |
| 1169 | (marker-char (dired-file-marker from)) ; slow |
| 1170 | (t nil)))) |
| 1171 | (condition-case err |
| 1172 | (progn |
| 1173 | (funcall file-creator from to dired-overwrite-confirmed) |
| 1174 | (if overwrite |
| 1175 | ;; If we get here, file-creator hasn't been aborted |
| 1176 | ;; and the old entry (if any) has to be deleted |
| 1177 | ;; before adding the new entry. |
| 1178 | (dired-remove-file to)) |
| 1179 | (setq success-count (1+ success-count)) |
| 1180 | (message "%s: %d of %d" operation success-count total) |
| 1181 | (dired-add-file to actual-marker-char)) |
| 1182 | (file-error ; FILE-CREATOR aborted |
| 1183 | (progn |
| 1184 | (setq failures (cons (dired-make-relative from) failures)) |
| 1185 | (dired-log "%s `%s' to `%s' failed:\n%s\n" |
| 1186 | operation from to err)))))))) |
| 1187 | fn-list)) |
| 1188 | (cond |
| 1189 | (failures |
| 1190 | (dired-log-summary |
| 1191 | (format "%s failed for %d of %d file%s" |
| 1192 | operation (length failures) total |
| 1193 | (dired-plural-s total)) |
| 1194 | failures)) |
| 1195 | (skipped |
| 1196 | (dired-log-summary |
| 1197 | (format "%s: %d of %d file%s skipped" |
| 1198 | operation (length skipped) total |
| 1199 | (dired-plural-s total)) |
| 1200 | skipped)) |
| 1201 | (t |
| 1202 | (message "%s: %s file%s" |
| 1203 | operation success-count (dired-plural-s success-count))))) |
| 1204 | (dired-move-to-filename)) |
| 1205 | \f |
| 1206 | (defun dired-do-create-files (op-symbol file-creator operation arg |
| 1207 | &optional marker-char op1 |
| 1208 | how-to) |
| 1209 | "Create a new file for each marked file. |
| 1210 | Prompts user for target, which is a directory in which to create |
| 1211 | the new files. Target may be a plain file if only one marked |
| 1212 | file exists. The way the default for the target directory is |
| 1213 | computed depends on the value of `dired-dwim-target-directory'. |
| 1214 | OP-SYMBOL is the symbol for the operation. Function `dired-mark-pop-up' |
| 1215 | will determine whether pop-ups are appropriate for this OP-SYMBOL. |
| 1216 | FILE-CREATOR and OPERATION as in `dired-create-files'. |
| 1217 | ARG as in `dired-get-marked-files'. |
| 1218 | Optional arg MARKER-CHAR as in `dired-create-files'. |
| 1219 | Optional arg OP1 is an alternate form for OPERATION if there is |
| 1220 | only one file. |
| 1221 | Optional arg HOW-TO is used to set the value of the into-dir variable |
| 1222 | which determines how to treat target. |
| 1223 | If into-dir is set to nil then target is not regarded as a directory, |
| 1224 | there must be exactly one marked file, else error. |
| 1225 | Else if into-dir is set to a list, then target is a generalized |
| 1226 | directory (e.g. some sort of archive). The first element of into-dir |
| 1227 | must be a function with at least four arguments: |
| 1228 | operation as OPERATION above. |
| 1229 | rfn-list a list of the relative names for the marked files. |
| 1230 | fn-list a list of the absolute names for the marked files. |
| 1231 | target. |
| 1232 | The rest of into-dir are optional arguments. |
| 1233 | Else into-dir is not a list. Target is a directory. |
| 1234 | The marked file(s) are created inside the target directory. |
| 1235 | |
| 1236 | If HOW-TO is not given (or nil), then into-dir is set to true if |
| 1237 | target is a directory and otherwise to nil. |
| 1238 | Else if HOW-TO is t, then into-dir is set to nil. |
| 1239 | Else HOW-TO is assumed to be a function of one argument, target, |
| 1240 | that looks at target and returns a value for the into-dir |
| 1241 | variable. The function `dired-into-dir-with-symlinks' is provided |
| 1242 | for the case (common when creating symlinks) that symbolic |
| 1243 | links to directories are not to be considered as directories |
| 1244 | (as `file-directory-p' would if HOW-TO had been nil)." |
| 1245 | (or op1 (setq op1 operation)) |
| 1246 | (let* ((fn-list (dired-get-marked-files nil arg)) |
| 1247 | (rfn-list (mapcar (function dired-make-relative) fn-list)) |
| 1248 | (dired-one-file ; fluid variable inside dired-create-files |
| 1249 | (and (consp fn-list) (null (cdr fn-list)) (car fn-list))) |
| 1250 | (target-dir (dired-dwim-target-directory)) |
| 1251 | (default (and dired-one-file |
| 1252 | (expand-file-name (file-name-nondirectory (car fn-list)) |
| 1253 | target-dir))) |
| 1254 | (target (expand-file-name ; fluid variable inside dired-create-files |
| 1255 | (dired-mark-read-file-name |
| 1256 | (concat (if dired-one-file op1 operation) " %s to: ") |
| 1257 | target-dir op-symbol arg rfn-list default))) |
| 1258 | (into-dir (cond ((null how-to) |
| 1259 | ;; Allow DOS/Windows users to change the letter |
| 1260 | ;; case of a directory. If we don't test these |
| 1261 | ;; conditions up front, file-directory-p below |
| 1262 | ;; will return t because the filesystem is |
| 1263 | ;; case-insensitive, and Emacs will try to move |
| 1264 | ;; foo -> foo/foo, which fails. |
| 1265 | (if (and (memq system-type '(ms-dos windows-nt)) |
| 1266 | (eq op-symbol 'move) |
| 1267 | dired-one-file |
| 1268 | (string= (downcase |
| 1269 | (expand-file-name (car fn-list))) |
| 1270 | (downcase |
| 1271 | (expand-file-name target))) |
| 1272 | (not (string= |
| 1273 | (file-name-nondirectory (car fn-list)) |
| 1274 | (file-name-nondirectory target)))) |
| 1275 | nil |
| 1276 | (file-directory-p target))) |
| 1277 | ((eq how-to t) nil) |
| 1278 | (t (funcall how-to target))))) |
| 1279 | (if (and (consp into-dir) (functionp (car into-dir))) |
| 1280 | (apply (car into-dir) operation rfn-list fn-list target (cdr into-dir)) |
| 1281 | (if (not (or dired-one-file into-dir)) |
| 1282 | (error "Marked %s: target must be a directory: %s" operation target)) |
| 1283 | ;; rename-file bombs when moving directories unless we do this: |
| 1284 | (or into-dir (setq target (directory-file-name target))) |
| 1285 | (dired-create-files |
| 1286 | file-creator operation fn-list |
| 1287 | (if into-dir ; target is a directory |
| 1288 | ;; This function uses fluid variable target when called |
| 1289 | ;; inside dired-create-files: |
| 1290 | (function |
| 1291 | (lambda (from) |
| 1292 | (expand-file-name (file-name-nondirectory from) target))) |
| 1293 | (function (lambda (from) target))) |
| 1294 | marker-char)))) |
| 1295 | |
| 1296 | ;; Read arguments for a marked-files command that wants a file name, |
| 1297 | ;; perhaps popping up the list of marked files. |
| 1298 | ;; ARG is the prefix arg and indicates whether the files came from |
| 1299 | ;; marks (ARG=nil) or a repeat factor (integerp ARG). |
| 1300 | ;; If the current file was used, the list has but one element and ARG |
| 1301 | ;; does not matter. (It is non-nil, non-integer in that case, namely '(4)). |
| 1302 | ;; DEFAULT is the default value to return if the user just hits RET; |
| 1303 | ;; if it is omitted or nil, then the name of the directory is used. |
| 1304 | |
| 1305 | (defun dired-mark-read-file-name (prompt dir op-symbol arg files |
| 1306 | &optional default) |
| 1307 | (dired-mark-pop-up |
| 1308 | nil op-symbol files |
| 1309 | (function read-file-name) |
| 1310 | (format prompt (dired-mark-prompt arg files)) dir default)) |
| 1311 | |
| 1312 | (defun dired-dwim-target-directory () |
| 1313 | ;; Try to guess which target directory the user may want. |
| 1314 | ;; If there is a dired buffer displayed in the next window, use |
| 1315 | ;; its current subdir, else use current subdir of this dired buffer. |
| 1316 | (let ((this-dir (and (eq major-mode 'dired-mode) |
| 1317 | (dired-current-directory)))) |
| 1318 | ;; non-dired buffer may want to profit from this function, e.g. vm-uudecode |
| 1319 | (if dired-dwim-target |
| 1320 | (let* ((other-buf (window-buffer (next-window))) |
| 1321 | (other-dir (save-excursion |
| 1322 | (set-buffer other-buf) |
| 1323 | (and (eq major-mode 'dired-mode) |
| 1324 | (dired-current-directory))))) |
| 1325 | (or other-dir this-dir)) |
| 1326 | this-dir))) |
| 1327 | \f |
| 1328 | ;;;###autoload |
| 1329 | (defun dired-create-directory (directory) |
| 1330 | "Create a directory called DIRECTORY." |
| 1331 | (interactive |
| 1332 | (list (read-file-name "Create directory: " (dired-current-directory)))) |
| 1333 | (let ((expanded (directory-file-name (expand-file-name directory)))) |
| 1334 | (make-directory expanded) |
| 1335 | (dired-add-file expanded) |
| 1336 | (dired-move-to-filename))) |
| 1337 | |
| 1338 | (defun dired-into-dir-with-symlinks (target) |
| 1339 | (and (file-directory-p target) |
| 1340 | (not (file-symlink-p target)))) |
| 1341 | ;; This may not always be what you want, especially if target is your |
| 1342 | ;; home directory and it happens to be a symbolic link, as is often the |
| 1343 | ;; case with NFS and automounters. Or if you want to make symlinks |
| 1344 | ;; into directories that themselves are only symlinks, also quite |
| 1345 | ;; common. |
| 1346 | |
| 1347 | ;; So we don't use this function as value for HOW-TO in |
| 1348 | ;; dired-do-symlink, which has the minor disadvantage of |
| 1349 | ;; making links *into* a symlinked-dir, when you really wanted to |
| 1350 | ;; *overwrite* that symlink. In that (rare, I guess) case, you'll |
| 1351 | ;; just have to remove that symlink by hand before making your marked |
| 1352 | ;; symlinks. |
| 1353 | |
| 1354 | (defvar dired-copy-how-to-fn nil |
| 1355 | "nil or a function used by `dired-do-copy' to determine target. |
| 1356 | See HOW-TO argument for `dired-do-create-files'.") |
| 1357 | |
| 1358 | ;;;###autoload |
| 1359 | (defun dired-do-copy (&optional arg) |
| 1360 | "Copy all marked (or next ARG) files, or copy the current file. |
| 1361 | This normally preserves the last-modified date when copying. |
| 1362 | When operating on just the current file, you specify the new name. |
| 1363 | When operating on multiple or marked files, you specify a directory, |
| 1364 | and new copies of these files are made in that directory |
| 1365 | with the same names that the files currently have. The default |
| 1366 | suggested for the target directory depends on the value of |
| 1367 | `dired-dwim-target', which see." |
| 1368 | (interactive "P") |
| 1369 | (let ((dired-recursive-copies dired-recursive-copies)) |
| 1370 | (dired-do-create-files 'copy (function dired-copy-file) |
| 1371 | (if dired-copy-preserve-time "Copy [-p]" "Copy") |
| 1372 | arg dired-keep-marker-copy |
| 1373 | nil dired-copy-how-to-fn))) |
| 1374 | |
| 1375 | ;;;###autoload |
| 1376 | (defun dired-do-symlink (&optional arg) |
| 1377 | "Make symbolic links to current file or all marked (or next ARG) files. |
| 1378 | When operating on just the current file, you specify the new name. |
| 1379 | When operating on multiple or marked files, you specify a directory |
| 1380 | and new symbolic links are made in that directory |
| 1381 | with the same names that the files currently have. The default |
| 1382 | suggested for the target directory depends on the value of |
| 1383 | `dired-dwim-target', which see." |
| 1384 | (interactive "P") |
| 1385 | (dired-do-create-files 'symlink (function make-symbolic-link) |
| 1386 | "Symlink" arg dired-keep-marker-symlink)) |
| 1387 | |
| 1388 | ;;;###autoload |
| 1389 | (defun dired-do-hardlink (&optional arg) |
| 1390 | "Add names (hard links) current file or all marked (or next ARG) files. |
| 1391 | When operating on just the current file, you specify the new name. |
| 1392 | When operating on multiple or marked files, you specify a directory |
| 1393 | and new hard links are made in that directory |
| 1394 | with the same names that the files currently have. The default |
| 1395 | suggested for the target directory depends on the value of |
| 1396 | `dired-dwim-target', which see." |
| 1397 | (interactive "P") |
| 1398 | (dired-do-create-files 'hardlink (function add-name-to-file) |
| 1399 | "Hardlink" arg dired-keep-marker-hardlink)) |
| 1400 | |
| 1401 | ;;;###autoload |
| 1402 | (defun dired-do-rename (&optional arg) |
| 1403 | "Rename current file or all marked (or next ARG) files. |
| 1404 | When renaming just the current file, you specify the new name. |
| 1405 | When renaming multiple or marked files, you specify a directory. |
| 1406 | The default suggested for the target directory depends on the value |
| 1407 | of `dired-dwim-target', which see." |
| 1408 | (interactive "P") |
| 1409 | (dired-do-create-files 'move (function dired-rename-file) |
| 1410 | "Move" arg dired-keep-marker-rename "Rename")) |
| 1411 | ;;;###end dired-cp.el |
| 1412 | \f |
| 1413 | ;;; 5K |
| 1414 | ;;;###begin dired-re.el |
| 1415 | (defun dired-do-create-files-regexp |
| 1416 | (file-creator operation arg regexp newname &optional whole-path marker-char) |
| 1417 | ;; Create a new file for each marked file using regexps. |
| 1418 | ;; FILE-CREATOR and OPERATION as in dired-create-files. |
| 1419 | ;; ARG as in dired-get-marked-files. |
| 1420 | ;; Matches each marked file against REGEXP and constructs the new |
| 1421 | ;; filename from NEWNAME (like in function replace-match). |
| 1422 | ;; Optional arg WHOLE-PATH means match/replace the whole file name |
| 1423 | ;; instead of only the non-directory part of the file. |
| 1424 | ;; Optional arg MARKER-CHAR as in dired-create-files. |
| 1425 | (let* ((fn-list (dired-get-marked-files nil arg)) |
| 1426 | (fn-count (length fn-list)) |
| 1427 | (operation-prompt (concat operation " `%s' to `%s'?")) |
| 1428 | (rename-regexp-help-form (format "\ |
| 1429 | Type SPC or `y' to %s one match, DEL or `n' to skip to next, |
| 1430 | `!' to %s all remaining matches with no more questions." |
| 1431 | (downcase operation) |
| 1432 | (downcase operation))) |
| 1433 | (regexp-name-constructor |
| 1434 | ;; Function to construct new filename using REGEXP and NEWNAME: |
| 1435 | (if whole-path ; easy (but rare) case |
| 1436 | (function |
| 1437 | (lambda (from) |
| 1438 | (let ((to (dired-string-replace-match regexp from newname)) |
| 1439 | ;; must bind help-form directly around call to |
| 1440 | ;; dired-query |
| 1441 | (help-form rename-regexp-help-form)) |
| 1442 | (if to |
| 1443 | (and (dired-query 'rename-regexp-query |
| 1444 | operation-prompt |
| 1445 | from |
| 1446 | to) |
| 1447 | to) |
| 1448 | (dired-log "%s: %s did not match regexp %s\n" |
| 1449 | operation from regexp))))) |
| 1450 | ;; not whole-path, replace non-directory part only |
| 1451 | (function |
| 1452 | (lambda (from) |
| 1453 | (let* ((new (dired-string-replace-match |
| 1454 | regexp (file-name-nondirectory from) newname)) |
| 1455 | (to (and new ; nil means there was no match |
| 1456 | (expand-file-name new |
| 1457 | (file-name-directory from)))) |
| 1458 | (help-form rename-regexp-help-form)) |
| 1459 | (if to |
| 1460 | (and (dired-query 'rename-regexp-query |
| 1461 | operation-prompt |
| 1462 | (dired-make-relative from) |
| 1463 | (dired-make-relative to)) |
| 1464 | to) |
| 1465 | (dired-log "%s: %s did not match regexp %s\n" |
| 1466 | operation (file-name-nondirectory from) regexp))))))) |
| 1467 | rename-regexp-query) |
| 1468 | (dired-create-files |
| 1469 | file-creator operation fn-list regexp-name-constructor marker-char))) |
| 1470 | |
| 1471 | (defun dired-mark-read-regexp (operation) |
| 1472 | ;; Prompt user about performing OPERATION. |
| 1473 | ;; Read and return list of: regexp newname arg whole-path. |
| 1474 | (let* ((whole-path |
| 1475 | (equal 0 (prefix-numeric-value current-prefix-arg))) |
| 1476 | (arg |
| 1477 | (if whole-path nil current-prefix-arg)) |
| 1478 | (regexp |
| 1479 | (dired-read-regexp |
| 1480 | (concat (if whole-path "Path " "") operation " from (regexp): "))) |
| 1481 | (newname |
| 1482 | (read-string |
| 1483 | (concat (if whole-path "Path " "") operation " " regexp " to: ")))) |
| 1484 | (list regexp newname arg whole-path))) |
| 1485 | |
| 1486 | ;;;###autoload |
| 1487 | (defun dired-do-rename-regexp (regexp newname &optional arg whole-path) |
| 1488 | "Rename selected files whose names match REGEXP to NEWNAME. |
| 1489 | |
| 1490 | With non-zero prefix argument ARG, the command operates on the next ARG |
| 1491 | files. Otherwise, it operates on all the marked files, or the current |
| 1492 | file if none are marked. |
| 1493 | |
| 1494 | As each match is found, the user must type a character saying |
| 1495 | what to do with it. For directions, type \\[help-command] at that time. |
| 1496 | NEWNAME may contain \\=\\<n> or \\& as in `query-replace-regexp'. |
| 1497 | REGEXP defaults to the last regexp used. |
| 1498 | |
| 1499 | With a zero prefix arg, renaming by regexp affects the absolute file name. |
| 1500 | Normally, only the non-directory part of the file name is used and changed." |
| 1501 | (interactive (dired-mark-read-regexp "Rename")) |
| 1502 | (dired-do-create-files-regexp |
| 1503 | (function dired-rename-file) |
| 1504 | "Rename" arg regexp newname whole-path dired-keep-marker-rename)) |
| 1505 | |
| 1506 | ;;;###autoload |
| 1507 | (defun dired-do-copy-regexp (regexp newname &optional arg whole-path) |
| 1508 | "Copy selected files whose names match REGEXP to NEWNAME. |
| 1509 | See function `dired-do-rename-regexp' for more info." |
| 1510 | (interactive (dired-mark-read-regexp "Copy")) |
| 1511 | (let ((dired-recursive-copies nil)) ; No recursive copies. |
| 1512 | (dired-do-create-files-regexp |
| 1513 | (function dired-copy-file) |
| 1514 | (if dired-copy-preserve-time "Copy [-p]" "Copy") |
| 1515 | arg regexp newname whole-path dired-keep-marker-copy))) |
| 1516 | |
| 1517 | ;;;###autoload |
| 1518 | (defun dired-do-hardlink-regexp (regexp newname &optional arg whole-path) |
| 1519 | "Hardlink selected files whose names match REGEXP to NEWNAME. |
| 1520 | See function `dired-do-rename-regexp' for more info." |
| 1521 | (interactive (dired-mark-read-regexp "HardLink")) |
| 1522 | (dired-do-create-files-regexp |
| 1523 | (function add-name-to-file) |
| 1524 | "HardLink" arg regexp newname whole-path dired-keep-marker-hardlink)) |
| 1525 | |
| 1526 | ;;;###autoload |
| 1527 | (defun dired-do-symlink-regexp (regexp newname &optional arg whole-path) |
| 1528 | "Symlink selected files whose names match REGEXP to NEWNAME. |
| 1529 | See function `dired-do-rename-regexp' for more info." |
| 1530 | (interactive (dired-mark-read-regexp "SymLink")) |
| 1531 | (dired-do-create-files-regexp |
| 1532 | (function make-symbolic-link) |
| 1533 | "SymLink" arg regexp newname whole-path dired-keep-marker-symlink)) |
| 1534 | |
| 1535 | (defun dired-create-files-non-directory |
| 1536 | (file-creator basename-constructor operation arg) |
| 1537 | ;; Perform FILE-CREATOR on the non-directory part of marked files |
| 1538 | ;; using function BASENAME-CONSTRUCTOR, with query for each file. |
| 1539 | ;; OPERATION like in dired-create-files, ARG as in dired-get-marked-files. |
| 1540 | (let (rename-non-directory-query) |
| 1541 | (dired-create-files |
| 1542 | file-creator |
| 1543 | operation |
| 1544 | (dired-get-marked-files nil arg) |
| 1545 | (function |
| 1546 | (lambda (from) |
| 1547 | (let ((to (concat (file-name-directory from) |
| 1548 | (funcall basename-constructor |
| 1549 | (file-name-nondirectory from))))) |
| 1550 | (and (let ((help-form (format "\ |
| 1551 | Type SPC or `y' to %s one file, DEL or `n' to skip to next, |
| 1552 | `!' to %s all remaining matches with no more questions." |
| 1553 | (downcase operation) |
| 1554 | (downcase operation)))) |
| 1555 | (dired-query 'rename-non-directory-query |
| 1556 | (concat operation " `%s' to `%s'") |
| 1557 | (dired-make-relative from) |
| 1558 | (dired-make-relative to))) |
| 1559 | to)))) |
| 1560 | dired-keep-marker-rename))) |
| 1561 | |
| 1562 | (defun dired-rename-non-directory (basename-constructor operation arg) |
| 1563 | (dired-create-files-non-directory |
| 1564 | (function dired-rename-file) |
| 1565 | basename-constructor operation arg)) |
| 1566 | |
| 1567 | ;;;###autoload |
| 1568 | (defun dired-upcase (&optional arg) |
| 1569 | "Rename all marked (or next ARG) files to upper case." |
| 1570 | (interactive "P") |
| 1571 | (dired-rename-non-directory (function upcase) "Rename upcase" arg)) |
| 1572 | |
| 1573 | ;;;###autoload |
| 1574 | (defun dired-downcase (&optional arg) |
| 1575 | "Rename all marked (or next ARG) files to lower case." |
| 1576 | (interactive "P") |
| 1577 | (dired-rename-non-directory (function downcase) "Rename downcase" arg)) |
| 1578 | |
| 1579 | ;;;###end dired-re.el |
| 1580 | \f |
| 1581 | ;;; 13K |
| 1582 | ;;;###begin dired-ins.el |
| 1583 | |
| 1584 | ;;;###autoload |
| 1585 | (defun dired-maybe-insert-subdir (dirname &optional |
| 1586 | switches no-error-if-not-dir-p) |
| 1587 | "Insert this subdirectory into the same dired buffer. |
| 1588 | If it is already present, just move to it (type \\[dired-do-redisplay] to refresh), |
| 1589 | else inserts it at its natural place (as `ls -lR' would have done). |
| 1590 | With a prefix arg, you may edit the ls switches used for this listing. |
| 1591 | You can add `R' to the switches to expand the whole tree starting at |
| 1592 | this subdirectory. |
| 1593 | This function takes some pains to conform to `ls -lR' output." |
| 1594 | (interactive |
| 1595 | (list (dired-get-filename) |
| 1596 | (if current-prefix-arg |
| 1597 | (read-string "Switches for listing: " dired-actual-switches)))) |
| 1598 | (let ((opoint (point))) |
| 1599 | ;; We don't need a marker for opoint as the subdir is always |
| 1600 | ;; inserted *after* opoint. |
| 1601 | (setq dirname (file-name-as-directory dirname)) |
| 1602 | (or (and (not switches) |
| 1603 | (dired-goto-subdir dirname)) |
| 1604 | (dired-insert-subdir dirname switches no-error-if-not-dir-p)) |
| 1605 | ;; Push mark so that it's easy to find back. Do this after the |
| 1606 | ;; insert message so that the user sees the `Mark set' message. |
| 1607 | (push-mark opoint))) |
| 1608 | |
| 1609 | ;;;###autoload |
| 1610 | (defun dired-insert-subdir (dirname &optional switches no-error-if-not-dir-p) |
| 1611 | "Insert this subdirectory into the same dired buffer. |
| 1612 | If it is already present, overwrites previous entry, |
| 1613 | else inserts it at its natural place (as `ls -lR' would have done). |
| 1614 | With a prefix arg, you may edit the `ls' switches used for this listing. |
| 1615 | You can add `R' to the switches to expand the whole tree starting at |
| 1616 | this subdirectory. |
| 1617 | This function takes some pains to conform to `ls -lR' output." |
| 1618 | ;; NO-ERROR-IF-NOT-DIR-P needed for special filesystems like |
| 1619 | ;; Prospero where dired-ls does the right thing, but |
| 1620 | ;; file-directory-p has not been redefined. |
| 1621 | (interactive |
| 1622 | (list (dired-get-filename) |
| 1623 | (if current-prefix-arg |
| 1624 | (read-string "Switches for listing: " dired-actual-switches)))) |
| 1625 | (setq dirname (file-name-as-directory (expand-file-name dirname))) |
| 1626 | (dired-insert-subdir-validate dirname switches) |
| 1627 | (or no-error-if-not-dir-p |
| 1628 | (file-directory-p dirname) |
| 1629 | (error "Attempt to insert a non-directory: %s" dirname)) |
| 1630 | (let ((elt (assoc dirname dired-subdir-alist)) |
| 1631 | switches-have-R mark-alist case-fold-search buffer-read-only) |
| 1632 | ;; case-fold-search is nil now, so we can test for capital `R': |
| 1633 | (if (setq switches-have-R (and switches (string-match "R" switches))) |
| 1634 | ;; avoid duplicated subdirs |
| 1635 | (setq mark-alist (dired-kill-tree dirname t))) |
| 1636 | (if elt |
| 1637 | ;; If subdir is already present, remove it and remember its marks |
| 1638 | (setq mark-alist (nconc (dired-insert-subdir-del elt) mark-alist)) |
| 1639 | (dired-insert-subdir-newpos dirname)) ; else compute new position |
| 1640 | (dired-insert-subdir-doupdate |
| 1641 | dirname elt (dired-insert-subdir-doinsert dirname switches)) |
| 1642 | (if switches-have-R (dired-build-subdir-alist switches)) |
| 1643 | (dired-initial-position dirname) |
| 1644 | (save-excursion (dired-mark-remembered mark-alist)))) |
| 1645 | |
| 1646 | ;; This is a separate function for dired-vms. |
| 1647 | (defun dired-insert-subdir-validate (dirname &optional switches) |
| 1648 | ;; Check that it is valid to insert DIRNAME with SWITCHES. |
| 1649 | ;; Signal an error if invalid (e.g. user typed `i' on `..'). |
| 1650 | (or (dired-in-this-tree dirname (expand-file-name default-directory)) |
| 1651 | (error "%s: not in this directory tree" dirname)) |
| 1652 | (if switches |
| 1653 | (let (case-fold-search) |
| 1654 | (mapcar |
| 1655 | (function |
| 1656 | (lambda (x) |
| 1657 | (or (eq (null (string-match x switches)) |
| 1658 | (null (string-match x dired-actual-switches))) |
| 1659 | (error "Can't have dirs with and without -%s switches together" |
| 1660 | x)))) |
| 1661 | ;; all switches that make a difference to dired-get-filename: |
| 1662 | '("F" "b"))))) |
| 1663 | |
| 1664 | (defun dired-alist-add (dir new-marker) |
| 1665 | ;; Add new DIR at NEW-MARKER. Sort alist. |
| 1666 | (dired-alist-add-1 dir new-marker) |
| 1667 | (dired-alist-sort)) |
| 1668 | |
| 1669 | (defun dired-alist-sort () |
| 1670 | ;; Keep the alist sorted on buffer position. |
| 1671 | (setq dired-subdir-alist |
| 1672 | (sort dired-subdir-alist |
| 1673 | (function (lambda (elt1 elt2) |
| 1674 | (> (dired-get-subdir-min elt1) |
| 1675 | (dired-get-subdir-min elt2))))))) |
| 1676 | |
| 1677 | (defun dired-kill-tree (dirname &optional remember-marks) |
| 1678 | "Kill all proper subdirs of DIRNAME, excluding DIRNAME itself. |
| 1679 | With optional arg REMEMBER-MARKS, return an alist of marked files." |
| 1680 | (interactive "DKill tree below directory: ") |
| 1681 | (setq dirname (expand-file-name dirname)) |
| 1682 | (let ((s-alist dired-subdir-alist) dir m-alist) |
| 1683 | (while s-alist |
| 1684 | (setq dir (car (car s-alist)) |
| 1685 | s-alist (cdr s-alist)) |
| 1686 | (if (and (not (string-equal dir dirname)) |
| 1687 | (dired-in-this-tree dir dirname) |
| 1688 | (dired-goto-subdir dir)) |
| 1689 | (setq m-alist (nconc (dired-kill-subdir remember-marks) m-alist)))) |
| 1690 | m-alist)) |
| 1691 | |
| 1692 | (defun dired-insert-subdir-newpos (new-dir) |
| 1693 | ;; Find pos for new subdir, according to tree order. |
| 1694 | ;;(goto-char (point-max)) |
| 1695 | (let ((alist dired-subdir-alist) elt dir pos new-pos) |
| 1696 | (while alist |
| 1697 | (setq elt (car alist) |
| 1698 | alist (cdr alist) |
| 1699 | dir (car elt) |
| 1700 | pos (dired-get-subdir-min elt)) |
| 1701 | (if (dired-tree-lessp dir new-dir) |
| 1702 | ;; Insert NEW-DIR after DIR |
| 1703 | (setq new-pos (dired-get-subdir-max elt) |
| 1704 | alist nil))) |
| 1705 | (goto-char new-pos)) |
| 1706 | ;; want a separating newline between subdirs |
| 1707 | (or (eobp) |
| 1708 | (forward-line -1)) |
| 1709 | (insert "\n") |
| 1710 | (point)) |
| 1711 | |
| 1712 | (defun dired-insert-subdir-del (element) |
| 1713 | ;; Erase an already present subdir (given by ELEMENT) from buffer. |
| 1714 | ;; Move to that buffer position. Return a mark-alist. |
| 1715 | (let ((begin-marker (dired-get-subdir-min element))) |
| 1716 | (goto-char begin-marker) |
| 1717 | ;; Are at beginning of subdir (and inside it!). Now determine its end: |
| 1718 | (goto-char (dired-subdir-max)) |
| 1719 | (or (eobp);; want a separating newline _between_ subdirs: |
| 1720 | (forward-char -1)) |
| 1721 | (prog1 |
| 1722 | (dired-remember-marks begin-marker (point)) |
| 1723 | (delete-region begin-marker (point))))) |
| 1724 | |
| 1725 | (defun dired-insert-subdir-doinsert (dirname switches) |
| 1726 | ;; Insert ls output after point and put point on the correct |
| 1727 | ;; position for the subdir alist. |
| 1728 | ;; Return the boundary of the inserted text (as list of BEG and END). |
| 1729 | (let ((begin (point)) end) |
| 1730 | (message "Reading directory %s..." dirname) |
| 1731 | (let ((dired-actual-switches |
| 1732 | (or switches |
| 1733 | (dired-replace-in-string "R" "" dired-actual-switches)))) |
| 1734 | (if (equal dirname (car (car (reverse dired-subdir-alist)))) |
| 1735 | ;; top level directory may contain wildcards: |
| 1736 | (dired-readin-insert dired-directory) |
| 1737 | (let ((opoint (point))) |
| 1738 | (insert-directory dirname dired-actual-switches nil t) |
| 1739 | (dired-insert-set-properties opoint (point))))) |
| 1740 | (message "Reading directory %s...done" dirname) |
| 1741 | (setq end (point-marker)) |
| 1742 | (indent-rigidly begin end 2) |
| 1743 | ;; call dired-insert-headerline afterwards, as under VMS dired-ls |
| 1744 | ;; does insert the headerline itself and the insert function just |
| 1745 | ;; moves point. |
| 1746 | ;; Need a marker for END as this inserts text. |
| 1747 | (goto-char begin) |
| 1748 | (if (not (looking-at "^ /.*:$")) |
| 1749 | (dired-insert-headerline dirname)) |
| 1750 | ;; point is now like in dired-build-subdir-alist |
| 1751 | (prog1 |
| 1752 | (list begin (marker-position end)) |
| 1753 | (set-marker end nil)))) |
| 1754 | |
| 1755 | (defun dired-insert-subdir-doupdate (dirname elt beg-end) |
| 1756 | ;; Point is at the correct subdir alist position for ELT, |
| 1757 | ;; BEG-END is the subdir-region (as list of begin and end). |
| 1758 | (if elt ; subdir was already present |
| 1759 | ;; update its position (should actually be unchanged) |
| 1760 | (set-marker (dired-get-subdir-min elt) (point-marker)) |
| 1761 | (dired-alist-add dirname (point-marker))) |
| 1762 | ;; The hook may depend on the subdir-alist containing the just |
| 1763 | ;; inserted subdir, so run it after dired-alist-add: |
| 1764 | (if dired-after-readin-hook |
| 1765 | (save-excursion |
| 1766 | (let ((begin (nth 0 beg-end)) |
| 1767 | (end (nth 1 beg-end))) |
| 1768 | (goto-char begin) |
| 1769 | (save-restriction |
| 1770 | (narrow-to-region begin end) |
| 1771 | ;; hook may add or delete lines, but the subdir boundary |
| 1772 | ;; marker floats |
| 1773 | (run-hooks 'dired-after-readin-hook)))))) |
| 1774 | |
| 1775 | (defun dired-tree-lessp (dir1 dir2) |
| 1776 | ;; Lexicographic order on file name components, like `ls -lR': |
| 1777 | ;; DIR1 < DIR2 iff DIR1 comes *before* DIR2 in an `ls -lR' listing, |
| 1778 | ;; i.e., iff DIR1 is a (grand)parent dir of DIR2, |
| 1779 | ;; or DIR1 and DIR2 are in the same parentdir and their last |
| 1780 | ;; components are string-lessp. |
| 1781 | ;; Thus ("/usr/" "/usr/bin") and ("/usr/a/" "/usr/b/") are tree-lessp. |
| 1782 | ;; string-lessp could arguably be replaced by file-newer-than-file-p |
| 1783 | ;; if dired-actual-switches contained `t'. |
| 1784 | (setq dir1 (file-name-as-directory dir1) |
| 1785 | dir2 (file-name-as-directory dir2)) |
| 1786 | (let ((components-1 (dired-split "/" dir1)) |
| 1787 | (components-2 (dired-split "/" dir2))) |
| 1788 | (while (and components-1 |
| 1789 | components-2 |
| 1790 | (equal (car components-1) (car components-2))) |
| 1791 | (setq components-1 (cdr components-1) |
| 1792 | components-2 (cdr components-2))) |
| 1793 | (let ((c1 (car components-1)) |
| 1794 | (c2 (car components-2))) |
| 1795 | |
| 1796 | (cond ((and c1 c2) |
| 1797 | (string-lessp c1 c2)) |
| 1798 | ((and (null c1) (null c2)) |
| 1799 | nil) ; they are equal, not lessp |
| 1800 | ((null c1) ; c2 is a subdir of c1: c1<c2 |
| 1801 | t) |
| 1802 | ((null c2) ; c1 is a subdir of c2: c1>c2 |
| 1803 | nil) |
| 1804 | (t (error "This can't happen")))))) |
| 1805 | |
| 1806 | ;; There should be a builtin split function - inverse to mapconcat. |
| 1807 | (defun dired-split (pat str &optional limit) |
| 1808 | "Splitting on regexp PAT, turn string STR into a list of substrings. |
| 1809 | Optional third arg LIMIT (>= 1) is a limit to the length of the |
| 1810 | resulting list. |
| 1811 | Thus, if SEP is a regexp that only matches itself, |
| 1812 | |
| 1813 | (mapconcat 'identity (dired-split SEP STRING) SEP) |
| 1814 | |
| 1815 | is always equal to STRING." |
| 1816 | (let* ((start (string-match pat str)) |
| 1817 | (result (list (substring str 0 start))) |
| 1818 | (count 1) |
| 1819 | (end (if start (match-end 0)))) |
| 1820 | (if end ; else nothing left |
| 1821 | (while (and (or (not (integerp limit)) |
| 1822 | (< count limit)) |
| 1823 | (string-match pat str end)) |
| 1824 | (setq start (match-beginning 0) |
| 1825 | count (1+ count) |
| 1826 | result (cons (substring str end start) result) |
| 1827 | end (match-end 0) |
| 1828 | start end) |
| 1829 | )) |
| 1830 | (if (and (or (not (integerp limit)) |
| 1831 | (< count limit)) |
| 1832 | end) ; else nothing left |
| 1833 | (setq result |
| 1834 | (cons (substring str end) result))) |
| 1835 | (nreverse result))) |
| 1836 | \f |
| 1837 | ;;; moving by subdirectories |
| 1838 | |
| 1839 | ;;;###autoload |
| 1840 | (defun dired-prev-subdir (arg &optional no-error-if-not-found no-skip) |
| 1841 | "Go to previous subdirectory, regardless of level. |
| 1842 | When called interactively and not on a subdir line, go to this subdir's line." |
| 1843 | ;;(interactive "p") |
| 1844 | (interactive |
| 1845 | (list (if current-prefix-arg |
| 1846 | (prefix-numeric-value current-prefix-arg) |
| 1847 | ;; if on subdir start already, don't stay there! |
| 1848 | (if (dired-get-subdir) 1 0)))) |
| 1849 | (dired-next-subdir (- arg) no-error-if-not-found no-skip)) |
| 1850 | |
| 1851 | (defun dired-subdir-min () |
| 1852 | (save-excursion |
| 1853 | (if (not (dired-prev-subdir 0 t t)) |
| 1854 | (error "Not in a subdir!") |
| 1855 | (point)))) |
| 1856 | |
| 1857 | ;;;###autoload |
| 1858 | (defun dired-goto-subdir (dir) |
| 1859 | "Go to end of header line of DIR in this dired buffer. |
| 1860 | Return value of point on success, otherwise return nil. |
| 1861 | The next char is either \\n, or \\r if DIR is hidden." |
| 1862 | (interactive |
| 1863 | (prog1 ; let push-mark display its message |
| 1864 | (list (expand-file-name |
| 1865 | (completing-read "Goto in situ directory: " ; prompt |
| 1866 | dired-subdir-alist ; table |
| 1867 | nil ; predicate |
| 1868 | t ; require-match |
| 1869 | (dired-current-directory)))) |
| 1870 | (push-mark))) |
| 1871 | (setq dir (file-name-as-directory dir)) |
| 1872 | (let ((elt (assoc dir dired-subdir-alist))) |
| 1873 | (and elt |
| 1874 | (goto-char (dired-get-subdir-min elt)) |
| 1875 | ;; dired-subdir-hidden-p and dired-add-entry depend on point being |
| 1876 | ;; at either \r or \n after this function succeeds. |
| 1877 | (progn (skip-chars-forward "^\r\n") |
| 1878 | (point))))) |
| 1879 | \f |
| 1880 | ;;;###autoload |
| 1881 | (defun dired-mark-subdir-files () |
| 1882 | "Mark all files except `.' and `..' in current subdirectory. |
| 1883 | If the Dired buffer shows multiple directories, this command |
| 1884 | marks the files listed in the subdirectory that point is in." |
| 1885 | (interactive) |
| 1886 | (let ((p-min (dired-subdir-min))) |
| 1887 | (dired-mark-files-in-region p-min (dired-subdir-max)))) |
| 1888 | |
| 1889 | ;;;###autoload |
| 1890 | (defun dired-kill-subdir (&optional remember-marks) |
| 1891 | "Remove all lines of current subdirectory. |
| 1892 | Lower levels are unaffected." |
| 1893 | ;; With optional REMEMBER-MARKS, return a mark-alist. |
| 1894 | (interactive) |
| 1895 | (let ((beg (dired-subdir-min)) |
| 1896 | (end (dired-subdir-max)) |
| 1897 | buffer-read-only cur-dir) |
| 1898 | (setq cur-dir (dired-current-directory)) |
| 1899 | (if (equal cur-dir default-directory) |
| 1900 | (error "Attempt to kill top level directory")) |
| 1901 | (prog1 |
| 1902 | (if remember-marks (dired-remember-marks beg end)) |
| 1903 | (delete-region beg end) |
| 1904 | (if (eobp) ; don't leave final blank line |
| 1905 | (delete-char -1)) |
| 1906 | (dired-unsubdir cur-dir)))) |
| 1907 | |
| 1908 | (defun dired-unsubdir (dir) |
| 1909 | ;; Remove DIR from the alist |
| 1910 | (setq dired-subdir-alist |
| 1911 | (delq (assoc dir dired-subdir-alist) dired-subdir-alist))) |
| 1912 | |
| 1913 | ;;;###autoload |
| 1914 | (defun dired-tree-up (arg) |
| 1915 | "Go up ARG levels in the dired tree." |
| 1916 | (interactive "p") |
| 1917 | (let ((dir (dired-current-directory))) |
| 1918 | (while (>= arg 1) |
| 1919 | (setq arg (1- arg) |
| 1920 | dir (file-name-directory (directory-file-name dir)))) |
| 1921 | ;;(setq dir (expand-file-name dir)) |
| 1922 | (or (dired-goto-subdir dir) |
| 1923 | (error "Cannot go up to %s - not in this tree" dir)))) |
| 1924 | |
| 1925 | ;;;###autoload |
| 1926 | (defun dired-tree-down () |
| 1927 | "Go down in the dired tree." |
| 1928 | (interactive) |
| 1929 | (let ((dir (dired-current-directory)) ; has slash |
| 1930 | pos case-fold-search) ; filenames are case sensitive |
| 1931 | (let ((rest (reverse dired-subdir-alist)) elt) |
| 1932 | (while rest |
| 1933 | (setq elt (car rest) |
| 1934 | rest (cdr rest)) |
| 1935 | (if (dired-in-this-tree (directory-file-name (car elt)) dir) |
| 1936 | (setq rest nil |
| 1937 | pos (dired-goto-subdir (car elt)))))) |
| 1938 | (if pos |
| 1939 | (goto-char pos) |
| 1940 | (error "At the bottom")))) |
| 1941 | \f |
| 1942 | ;;; hiding |
| 1943 | |
| 1944 | (defun dired-unhide-subdir () |
| 1945 | (let (buffer-read-only) |
| 1946 | (subst-char-in-region (dired-subdir-min) (dired-subdir-max) ?\r ?\n))) |
| 1947 | |
| 1948 | (defun dired-hide-check () |
| 1949 | (or selective-display |
| 1950 | (error "selective-display must be t for subdir hiding to work!"))) |
| 1951 | |
| 1952 | (defun dired-subdir-hidden-p (dir) |
| 1953 | (and selective-display |
| 1954 | (save-excursion |
| 1955 | (dired-goto-subdir dir) |
| 1956 | (looking-at "\r")))) |
| 1957 | |
| 1958 | ;;;###autoload |
| 1959 | (defun dired-hide-subdir (arg) |
| 1960 | "Hide or unhide the current subdirectory and move to next directory. |
| 1961 | Optional prefix arg is a repeat factor. |
| 1962 | Use \\[dired-hide-all] to (un)hide all directories." |
| 1963 | (interactive "p") |
| 1964 | (dired-hide-check) |
| 1965 | (while (>= (setq arg (1- arg)) 0) |
| 1966 | (let* ((cur-dir (dired-current-directory)) |
| 1967 | (hidden-p (dired-subdir-hidden-p cur-dir)) |
| 1968 | (elt (assoc cur-dir dired-subdir-alist)) |
| 1969 | (end-pos (1- (dired-get-subdir-max elt))) |
| 1970 | buffer-read-only) |
| 1971 | ;; keep header line visible, hide rest |
| 1972 | (goto-char (dired-get-subdir-min elt)) |
| 1973 | (skip-chars-forward "^\n\r") |
| 1974 | (if hidden-p |
| 1975 | (subst-char-in-region (point) end-pos ?\r ?\n) |
| 1976 | (subst-char-in-region (point) end-pos ?\n ?\r))) |
| 1977 | (dired-next-subdir 1 t))) |
| 1978 | |
| 1979 | ;;;###autoload |
| 1980 | (defun dired-hide-all (arg) |
| 1981 | "Hide all subdirectories, leaving only their header lines. |
| 1982 | If there is already something hidden, make everything visible again. |
| 1983 | Use \\[dired-hide-subdir] to (un)hide a particular subdirectory." |
| 1984 | (interactive "P") |
| 1985 | (dired-hide-check) |
| 1986 | (let (buffer-read-only) |
| 1987 | (if (save-excursion |
| 1988 | (goto-char (point-min)) |
| 1989 | (search-forward "\r" nil t)) |
| 1990 | ;; unhide - bombs on \r in filenames |
| 1991 | (subst-char-in-region (point-min) (point-max) ?\r ?\n) |
| 1992 | ;; hide |
| 1993 | (let ((pos (point-max)) ; pos of end of last directory |
| 1994 | (alist dired-subdir-alist)) |
| 1995 | (while alist ; while there are dirs before pos |
| 1996 | (subst-char-in-region (dired-get-subdir-min (car alist)) ; pos of prev dir |
| 1997 | (save-excursion |
| 1998 | (goto-char pos) ; current dir |
| 1999 | ;; we're somewhere on current dir's line |
| 2000 | (forward-line -1) |
| 2001 | (point)) |
| 2002 | ?\n ?\r) |
| 2003 | (setq pos (dired-get-subdir-min (car alist))) ; prev dir gets current dir |
| 2004 | (setq alist (cdr alist))))))) |
| 2005 | |
| 2006 | ;;;###end dired-ins.el |
| 2007 | |
| 2008 | \f |
| 2009 | ;; Functions for searching in tags style among marked files. |
| 2010 | |
| 2011 | ;;;###autoload |
| 2012 | (defun dired-do-search (regexp) |
| 2013 | "Search through all marked files for a match for REGEXP. |
| 2014 | Stops when a match is found. |
| 2015 | To continue searching for next match, use command \\[tags-loop-continue]." |
| 2016 | (interactive "sSearch marked files (regexp): ") |
| 2017 | (tags-search regexp '(dired-get-marked-files))) |
| 2018 | |
| 2019 | ;;;###autoload |
| 2020 | (defun dired-do-query-replace-regexp (from to &optional delimited) |
| 2021 | "Do `query-replace-regexp' of FROM with TO, on all marked files. |
| 2022 | Third arg DELIMITED (prefix arg) means replace only word-delimited matches. |
| 2023 | If you exit (\\[keyboard-quit], RET or q), you can resume the query replace |
| 2024 | with the command \\[tags-loop-continue]." |
| 2025 | (interactive |
| 2026 | "sQuery replace in marked files (regexp): \nsQuery replace %s by: \nP") |
| 2027 | (tags-query-replace from to delimited '(dired-get-marked-files))) |
| 2028 | \f |
| 2029 | ;;;###autoload |
| 2030 | (defun dired-show-file-type (file &optional deref-symlinks) |
| 2031 | "Print the type of FILE, according to the `file' command. |
| 2032 | If FILE is a symbolic link and the optional argument DEREF-SYMLINKS is |
| 2033 | true then the type of the file linked to by FILE is printed instead." |
| 2034 | (interactive (list (dired-get-filename t) current-prefix-arg)) |
| 2035 | (with-temp-buffer |
| 2036 | (if deref-symlinks |
| 2037 | (call-process "file" nil t t "-L" file) |
| 2038 | (call-process "file" nil t t file)) |
| 2039 | (when (bolp) |
| 2040 | (backward-delete-char 1)) |
| 2041 | (message (buffer-string)))) |
| 2042 | |
| 2043 | (provide 'dired-aux) |
| 2044 | |
| 2045 | ;;; dired-aux.el ends here |