| 1 | ;;; derived.el --- allow inheritance of major modes |
| 2 | ;;; (formerly mode-clone.el) |
| 3 | |
| 4 | ;; Copyright (C) 1993, 1994, 1999, 2003 Free Software Foundation, Inc. |
| 5 | |
| 6 | ;; Author: David Megginson (dmeggins@aix1.uottawa.ca) |
| 7 | ;; Maintainer: FSF |
| 8 | ;; Keywords: extensions |
| 9 | |
| 10 | ;; This file is part of GNU Emacs. |
| 11 | |
| 12 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 13 | ;; it under the terms of the GNU General Public License as published by |
| 14 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 15 | ;; any later version. |
| 16 | |
| 17 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 18 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 19 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 20 | ;; GNU General Public License for more details. |
| 21 | |
| 22 | ;; You should have received a copy of the GNU General Public License |
| 23 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 24 | ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, |
| 25 | ;; Boston, MA 02111-1307, USA. |
| 26 | \f |
| 27 | ;;; Commentary: |
| 28 | |
| 29 | ;; GNU Emacs is already, in a sense, object oriented -- each object |
| 30 | ;; (buffer) belongs to a class (major mode), and that class defines |
| 31 | ;; the relationship between messages (input events) and methods |
| 32 | ;; (commands) by means of a keymap. |
| 33 | ;; |
| 34 | ;; The only thing missing is a good scheme of inheritance. It is |
| 35 | ;; possible to simulate a single level of inheritance with generous |
| 36 | ;; use of hooks and a bit of work -- sgml-mode, for example, also runs |
| 37 | ;; the hooks for text-mode, and keymaps can inherit from other keymaps |
| 38 | ;; -- but generally, each major mode ends up reinventing the wheel. |
| 39 | ;; Ideally, someone should redesign all of Emacs's major modes to |
| 40 | ;; follow a more conventional object-oriented system: when defining a |
| 41 | ;; new major mode, the user should need only to name the existing mode |
| 42 | ;; it is most similar to, then list the (few) differences. |
| 43 | ;; |
| 44 | ;; In the mean time, this package offers most of the advantages of |
| 45 | ;; full inheritance with the existing major modes. The macro |
| 46 | ;; `define-derived-mode' allows the user to make a variant of an existing |
| 47 | ;; major mode, with its own keymap. The new mode will inherit the key |
| 48 | ;; bindings of its parent, and will, in fact, run its parent first |
| 49 | ;; every time it is called. For example, the commands |
| 50 | ;; |
| 51 | ;; (define-derived-mode hypertext-mode text-mode "Hypertext" |
| 52 | ;; "Major mode for hypertext.\n\n\\{hypertext-mode-map}" |
| 53 | ;; (setq case-fold-search nil)) |
| 54 | ;; |
| 55 | ;; (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link) |
| 56 | ;; |
| 57 | ;; will create a function `hypertext-mode' with its own (sparse) |
| 58 | ;; keymap `hypertext-mode-map.' The command M-x hypertext-mode will |
| 59 | ;; perform the following actions: |
| 60 | ;; |
| 61 | ;; - run the command (text-mode) to get its default setup |
| 62 | ;; - replace the current keymap with 'hypertext-mode-map,' which will |
| 63 | ;; inherit from 'text-mode-map'. |
| 64 | ;; - replace the current syntax table with |
| 65 | ;; 'hypertext-mode-syntax-table', which will borrow its defaults |
| 66 | ;; from the current text-mode-syntax-table. |
| 67 | ;; - replace the current abbrev table with |
| 68 | ;; 'hypertext-mode-abbrev-table', which will borrow its defaults |
| 69 | ;; from the current text-mode-abbrev table |
| 70 | ;; - change the mode line to read "Hypertext" |
| 71 | ;; - assign the value 'hypertext-mode' to the 'major-mode' variable |
| 72 | ;; - run the body of commands provided in the macro -- in this case, |
| 73 | ;; set the local variable `case-fold-search' to nil. |
| 74 | ;; |
| 75 | ;; The advantages of this system are threefold. First, text mode is |
| 76 | ;; untouched -- if you had added the new keystroke to `text-mode-map,' |
| 77 | ;; possibly using hooks, you would have added it to all text buffers |
| 78 | ;; -- here, it appears only in hypertext buffers, where it makes |
| 79 | ;; sense. Second, it is possible to build even further, and make |
| 80 | ;; a derived mode from a derived mode. The commands |
| 81 | ;; |
| 82 | ;; (define-derived-mode html-mode hypertext-mode "HTML") |
| 83 | ;; [various key definitions] |
| 84 | ;; |
| 85 | ;; will add a new major mode for HTML with very little fuss. |
| 86 | ;; |
| 87 | ;; Note also the function `derived-mode-p' which can tell if the current |
| 88 | ;; mode derives from another. In a hypertext-mode, buffer, for example, |
| 89 | ;; (derived-mode-p 'text-mode) would return non-nil. This should always |
| 90 | ;; be used in place of (eq major-mode 'text-mode). |
| 91 | \f |
| 92 | ;;; Code: |
| 93 | |
| 94 | (eval-when-compile (require 'cl)) |
| 95 | |
| 96 | ;;; PRIVATE: defsubst must be defined before they are first used |
| 97 | |
| 98 | (defsubst derived-mode-hook-name (mode) |
| 99 | "Construct the mode hook name based on mode name MODE." |
| 100 | (intern (concat (symbol-name mode) "-hook"))) |
| 101 | |
| 102 | (defsubst derived-mode-map-name (mode) |
| 103 | "Construct a map name based on a MODE name." |
| 104 | (intern (concat (symbol-name mode) "-map"))) |
| 105 | |
| 106 | (defsubst derived-mode-syntax-table-name (mode) |
| 107 | "Construct a syntax-table name based on a MODE name." |
| 108 | (intern (concat (symbol-name mode) "-syntax-table"))) |
| 109 | |
| 110 | (defsubst derived-mode-abbrev-table-name (mode) |
| 111 | "Construct an abbrev-table name based on a MODE name." |
| 112 | (intern (concat (symbol-name mode) "-abbrev-table"))) |
| 113 | |
| 114 | ;; PUBLIC: define a new major mode which inherits from an existing one. |
| 115 | |
| 116 | ;;;###autoload |
| 117 | (defmacro define-derived-mode (child parent name &optional docstring &rest body) |
| 118 | "Create a new mode as a variant of an existing mode. |
| 119 | |
| 120 | The arguments to this command are as follow: |
| 121 | |
| 122 | CHILD: the name of the command for the derived mode. |
| 123 | PARENT: the name of the command for the parent mode (e.g. `text-mode') |
| 124 | or nil if there is no parent. |
| 125 | NAME: a string which will appear in the status line (e.g. \"Hypertext\") |
| 126 | DOCSTRING: an optional documentation string--if you do not supply one, |
| 127 | the function will attempt to invent something useful. |
| 128 | BODY: forms to execute just before running the |
| 129 | hooks for the new mode. Do not use `interactive' here. |
| 130 | |
| 131 | BODY can start with a bunch of keyword arguments. The following keyword |
| 132 | arguments are currently understood: |
| 133 | :group GROUP |
| 134 | Declare the customization group that corresponds to this mode. |
| 135 | :syntax-table TABLE |
| 136 | Use TABLE instead of the default. |
| 137 | A nil value means to simply use the same syntax-table as the parent. |
| 138 | :abbrev-table TABLE |
| 139 | Use TABLE instead of the default. |
| 140 | A nil value means to simply use the same abbrev-table as the parent. |
| 141 | |
| 142 | Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode: |
| 143 | |
| 144 | (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\") |
| 145 | |
| 146 | You could then make new key bindings for `LaTeX-thesis-mode-map' |
| 147 | without changing regular LaTeX mode. In this example, BODY is empty, |
| 148 | and DOCSTRING is generated by default. |
| 149 | |
| 150 | On a more complicated level, the following command uses `sgml-mode' as |
| 151 | the parent, and then sets the variable `case-fold-search' to nil: |
| 152 | |
| 153 | (define-derived-mode article-mode sgml-mode \"Article\" |
| 154 | \"Major mode for editing technical articles.\" |
| 155 | (setq case-fold-search nil)) |
| 156 | |
| 157 | Note that if the documentation string had been left out, it would have |
| 158 | been generated automatically, with a reference to the keymap. |
| 159 | |
| 160 | The new mode runs the hook constructed by the function |
| 161 | `derived-mode-hook-name'." |
| 162 | (declare (debug (&define name symbolp sexp [&optional stringp] |
| 163 | [&rest keywordp sexp] def-body))) |
| 164 | |
| 165 | (when (and docstring (not (stringp docstring))) |
| 166 | ;; Some trickiness, since what appears to be the docstring may really be |
| 167 | ;; the first element of the body. |
| 168 | (push docstring body) |
| 169 | (setq docstring nil)) |
| 170 | |
| 171 | (when (eq parent 'fundamental-mode) (setq parent nil)) |
| 172 | |
| 173 | (let ((map (derived-mode-map-name child)) |
| 174 | (syntax (derived-mode-syntax-table-name child)) |
| 175 | (abbrev (derived-mode-abbrev-table-name child)) |
| 176 | (declare-abbrev t) |
| 177 | (declare-syntax t) |
| 178 | (hook (derived-mode-hook-name child)) |
| 179 | (group nil)) |
| 180 | |
| 181 | ;; Process the keyword args. |
| 182 | (while (keywordp (car body)) |
| 183 | (case (pop body) |
| 184 | (:group (setq group (pop body))) |
| 185 | (:abbrev-table (setq abbrev (pop body)) (setq declare-abbrev nil)) |
| 186 | (:syntax-table (setq syntax (pop body)) (setq declare-syntax nil)) |
| 187 | (t (pop body)))) |
| 188 | |
| 189 | (setq docstring (derived-mode-make-docstring |
| 190 | parent child docstring syntax abbrev)) |
| 191 | |
| 192 | `(progn |
| 193 | (defvar ,hook nil ,(format "Hook run when entering %s mode." name)) |
| 194 | (defvar ,map (make-sparse-keymap)) |
| 195 | ,(if declare-syntax |
| 196 | `(defvar ,syntax (make-syntax-table))) |
| 197 | ,(if declare-abbrev |
| 198 | `(defvar ,abbrev |
| 199 | (progn (define-abbrev-table ',abbrev nil) ,abbrev))) |
| 200 | (put ',child 'derived-mode-parent ',parent) |
| 201 | ,(if group `(put ',child 'custom-mode-group ,group)) |
| 202 | |
| 203 | (defun ,child () |
| 204 | ,docstring |
| 205 | (interactive) |
| 206 | ; Run the parent. |
| 207 | (delay-mode-hooks |
| 208 | |
| 209 | (,(or parent 'kill-all-local-variables)) |
| 210 | ; Identify the child mode. |
| 211 | (setq major-mode (quote ,child)) |
| 212 | (setq mode-name ,name) |
| 213 | ; Identify special modes. |
| 214 | ,(when parent |
| 215 | `(progn |
| 216 | (if (get (quote ,parent) 'mode-class) |
| 217 | (put (quote ,child) 'mode-class |
| 218 | (get (quote ,parent) 'mode-class))) |
| 219 | ; Set up maps and tables. |
| 220 | (unless (keymap-parent ,map) |
| 221 | (set-keymap-parent ,map (current-local-map))) |
| 222 | ,(when declare-syntax |
| 223 | `(let ((parent (char-table-parent ,syntax))) |
| 224 | (unless (and parent |
| 225 | (not (eq parent (standard-syntax-table)))) |
| 226 | (set-char-table-parent ,syntax (syntax-table))))))) |
| 227 | |
| 228 | (use-local-map ,map) |
| 229 | ,(when syntax `(set-syntax-table ,syntax)) |
| 230 | ,(when abbrev `(setq local-abbrev-table ,abbrev)) |
| 231 | ; Splice in the body (if any). |
| 232 | ,@body |
| 233 | ) |
| 234 | ;; Run the hooks, if any. |
| 235 | ;; Make the generated code work in older Emacs versions |
| 236 | ;; that do not yet have run-mode-hooks. |
| 237 | (if (fboundp 'run-mode-hooks) |
| 238 | (run-mode-hooks ',hook) |
| 239 | (run-hooks ',hook)))))) |
| 240 | |
| 241 | ;; PUBLIC: find the ultimate class of a derived mode. |
| 242 | |
| 243 | (defun derived-mode-class (mode) |
| 244 | "Find the class of a major MODE. |
| 245 | A mode's class is the first ancestor which is NOT a derived mode. |
| 246 | Use the `derived-mode-parent' property of the symbol to trace backwards. |
| 247 | Since major-modes might all derive from `fundamental-mode', this function |
| 248 | is not very useful." |
| 249 | (while (get mode 'derived-mode-parent) |
| 250 | (setq mode (get mode 'derived-mode-parent))) |
| 251 | mode) |
| 252 | (make-obsolete 'derived-mode-class 'derived-mode-p "22.1") |
| 253 | |
| 254 | \f |
| 255 | ;;; PRIVATE |
| 256 | |
| 257 | (defun derived-mode-make-docstring (parent child &optional |
| 258 | docstring syntax abbrev) |
| 259 | "Construct a docstring for a new mode if none is provided." |
| 260 | |
| 261 | (let ((map (derived-mode-map-name child)) |
| 262 | (hook (derived-mode-hook-name child))) |
| 263 | |
| 264 | (unless (stringp docstring) |
| 265 | ;; Use a default docstring. |
| 266 | (setq docstring |
| 267 | (if (null parent) |
| 268 | (format "Major-mode. |
| 269 | Uses keymap `%s', abbrev table `%s' and syntax-table `%s'." map abbrev syntax) |
| 270 | (format "Major mode derived from `%s' by `define-derived-mode'. |
| 271 | It inherits all of the parent's attributes, but has its own keymap, |
| 272 | abbrev table and syntax table: |
| 273 | |
| 274 | `%s', `%s' and `%s' |
| 275 | |
| 276 | which more-or-less shadow %s's corresponding tables." |
| 277 | parent map abbrev syntax parent)))) |
| 278 | |
| 279 | (unless (string-match (regexp-quote (symbol-name hook)) docstring) |
| 280 | ;; Make sure the docstring mentions the mode's hook. |
| 281 | (setq docstring |
| 282 | (concat docstring |
| 283 | (if (null parent) |
| 284 | "\n\nThis mode " |
| 285 | (concat |
| 286 | "\n\nIn addition to any hooks its parent mode " |
| 287 | (if (string-match (regexp-quote (format "`%s'" parent)) |
| 288 | docstring) nil |
| 289 | (format "`%s' " parent)) |
| 290 | "might have run,\nthis mode ")) |
| 291 | (format "runs the hook `%s'" hook) |
| 292 | ", as the final step\nduring initialization."))) |
| 293 | |
| 294 | (unless (string-match "\\\\[{[]" docstring) |
| 295 | ;; And don't forget to put the mode's keymap. |
| 296 | (setq docstring (concat docstring "\n\n\\{" (symbol-name map) "}"))) |
| 297 | |
| 298 | docstring)) |
| 299 | |
| 300 | \f |
| 301 | ;;; OBSOLETE |
| 302 | ;; The functions below are only provided for backward compatibility with |
| 303 | ;; code byte-compiled with versions of derived.el prior to Emacs-21. |
| 304 | |
| 305 | (defsubst derived-mode-setup-function-name (mode) |
| 306 | "Construct a setup-function name based on a MODE name." |
| 307 | (intern (concat (symbol-name mode) "-setup"))) |
| 308 | |
| 309 | \f |
| 310 | ;; Utility functions for defining a derived mode. |
| 311 | |
| 312 | ;;;###autoload |
| 313 | (defun derived-mode-init-mode-variables (mode) |
| 314 | "Initialise variables for a new MODE. |
| 315 | Right now, if they don't already exist, set up a blank keymap, an |
| 316 | empty syntax table, and an empty abbrev table -- these will be merged |
| 317 | the first time the mode is used." |
| 318 | |
| 319 | (if (boundp (derived-mode-map-name mode)) |
| 320 | t |
| 321 | (eval `(defvar ,(derived-mode-map-name mode) |
| 322 | (make-sparse-keymap) |
| 323 | ,(format "Keymap for %s." mode))) |
| 324 | (put (derived-mode-map-name mode) 'derived-mode-unmerged t)) |
| 325 | |
| 326 | (if (boundp (derived-mode-syntax-table-name mode)) |
| 327 | t |
| 328 | (eval `(defvar ,(derived-mode-syntax-table-name mode) |
| 329 | ;; Make a syntax table which doesn't specify anything |
| 330 | ;; for any char. Valid data will be merged in by |
| 331 | ;; derived-mode-merge-syntax-tables. |
| 332 | (make-char-table 'syntax-table nil) |
| 333 | ,(format "Syntax table for %s." mode))) |
| 334 | (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t)) |
| 335 | |
| 336 | (if (boundp (derived-mode-abbrev-table-name mode)) |
| 337 | t |
| 338 | (eval `(defvar ,(derived-mode-abbrev-table-name mode) |
| 339 | (progn |
| 340 | (define-abbrev-table (derived-mode-abbrev-table-name mode) nil) |
| 341 | (make-abbrev-table)) |
| 342 | ,(format "Abbrev table for %s." mode))))) |
| 343 | \f |
| 344 | ;; Utility functions for running a derived mode. |
| 345 | |
| 346 | (defun derived-mode-set-keymap (mode) |
| 347 | "Set the keymap of the new MODE, maybe merging with the parent." |
| 348 | (let* ((map-name (derived-mode-map-name mode)) |
| 349 | (new-map (eval map-name)) |
| 350 | (old-map (current-local-map))) |
| 351 | (and old-map |
| 352 | (get map-name 'derived-mode-unmerged) |
| 353 | (derived-mode-merge-keymaps old-map new-map)) |
| 354 | (put map-name 'derived-mode-unmerged nil) |
| 355 | (use-local-map new-map))) |
| 356 | |
| 357 | (defun derived-mode-set-syntax-table (mode) |
| 358 | "Set the syntax table of the new MODE, maybe merging with the parent." |
| 359 | (let* ((table-name (derived-mode-syntax-table-name mode)) |
| 360 | (old-table (syntax-table)) |
| 361 | (new-table (eval table-name))) |
| 362 | (if (get table-name 'derived-mode-unmerged) |
| 363 | (derived-mode-merge-syntax-tables old-table new-table)) |
| 364 | (put table-name 'derived-mode-unmerged nil) |
| 365 | (set-syntax-table new-table))) |
| 366 | |
| 367 | (defun derived-mode-set-abbrev-table (mode) |
| 368 | "Set the abbrev table for MODE if it exists. |
| 369 | Always merge its parent into it, since the merge is non-destructive." |
| 370 | (let* ((table-name (derived-mode-abbrev-table-name mode)) |
| 371 | (old-table local-abbrev-table) |
| 372 | (new-table (eval table-name))) |
| 373 | (derived-mode-merge-abbrev-tables old-table new-table) |
| 374 | (setq local-abbrev-table new-table))) |
| 375 | |
| 376 | ;;;(defun derived-mode-run-setup-function (mode) |
| 377 | ;;; "Run the setup function if it exists." |
| 378 | |
| 379 | ;;; (let ((fname (derived-mode-setup-function-name mode))) |
| 380 | ;;; (if (fboundp fname) |
| 381 | ;;; (funcall fname)))) |
| 382 | |
| 383 | (defun derived-mode-run-hooks (mode) |
| 384 | "Run the mode hook for MODE." |
| 385 | (let ((hooks-name (derived-mode-hook-name mode))) |
| 386 | (if (boundp hooks-name) |
| 387 | (run-hooks hooks-name)))) |
| 388 | |
| 389 | ;; Functions to merge maps and tables. |
| 390 | |
| 391 | (defun derived-mode-merge-keymaps (old new) |
| 392 | "Merge an OLD keymap into a NEW one. |
| 393 | The old keymap is set to be the last cdr of the new one, so that there will |
| 394 | be automatic inheritance." |
| 395 | ;; ?? Can this just use `set-keymap-parent'? |
| 396 | (let ((tail new)) |
| 397 | ;; Scan the NEW map for prefix keys. |
| 398 | (while (consp tail) |
| 399 | (and (consp (car tail)) |
| 400 | (let* ((key (vector (car (car tail)))) |
| 401 | (subnew (lookup-key new key)) |
| 402 | (subold (lookup-key old key))) |
| 403 | ;; If KEY is a prefix key in both OLD and NEW, merge them. |
| 404 | (and (keymapp subnew) (keymapp subold) |
| 405 | (derived-mode-merge-keymaps subold subnew)))) |
| 406 | (and (vectorp (car tail)) |
| 407 | ;; Search a vector of ASCII char bindings for prefix keys. |
| 408 | (let ((i (1- (length (car tail))))) |
| 409 | (while (>= i 0) |
| 410 | (let* ((key (vector i)) |
| 411 | (subnew (lookup-key new key)) |
| 412 | (subold (lookup-key old key))) |
| 413 | ;; If KEY is a prefix key in both OLD and NEW, merge them. |
| 414 | (and (keymapp subnew) (keymapp subold) |
| 415 | (derived-mode-merge-keymaps subold subnew))) |
| 416 | (setq i (1- i))))) |
| 417 | (setq tail (cdr tail)))) |
| 418 | (setcdr (nthcdr (1- (length new)) new) old)) |
| 419 | |
| 420 | (defun derived-mode-merge-syntax-tables (old new) |
| 421 | "Merge an OLD syntax table into a NEW one. |
| 422 | Where the new table already has an entry, nothing is copied from the old one." |
| 423 | (set-char-table-parent new old)) |
| 424 | |
| 425 | ;; Merge an old abbrev table into a new one. |
| 426 | ;; This function requires internal knowledge of how abbrev tables work, |
| 427 | ;; presuming that they are obarrays with the abbrev as the symbol, the expansion |
| 428 | ;; as the value of the symbol, and the hook as the function definition. |
| 429 | (defun derived-mode-merge-abbrev-tables (old new) |
| 430 | (if old |
| 431 | (mapatoms |
| 432 | (lambda (symbol) |
| 433 | (or (intern-soft (symbol-name symbol) new) |
| 434 | (define-abbrev new (symbol-name symbol) |
| 435 | (symbol-value symbol) (symbol-function symbol)))) |
| 436 | old))) |
| 437 | |
| 438 | (provide 'derived) |
| 439 | |
| 440 | ;;; arch-tag: 630be248-47d1-4f02-afa0-8207de0ebea0 |
| 441 | ;;; derived.el ends here |