| 1 | dnl Autoconf script for GNU Emacs |
| 2 | dnl To rebuild the `configure' script from this, execute the command |
| 3 | dnl autoconf |
| 4 | dnl in the directory containing this script. |
| 5 | dnl If you changed any AC_DEFINES, also run autoheader. |
| 6 | dnl |
| 7 | dnl Copyright (C) 1994-1996, 1999-2014 Free Software Foundation, Inc. |
| 8 | dnl |
| 9 | dnl This file is part of GNU Emacs. |
| 10 | dnl |
| 11 | dnl GNU Emacs is free software: you can redistribute it and/or modify |
| 12 | dnl it under the terms of the GNU General Public License as published by |
| 13 | dnl the Free Software Foundation, either version 3 of the License, or |
| 14 | dnl (at your option) any later version. |
| 15 | dnl |
| 16 | dnl GNU Emacs is distributed in the hope that it will be useful, |
| 17 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 18 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 19 | dnl GNU General Public License for more details. |
| 20 | dnl |
| 21 | dnl You should have received a copy of the GNU General Public License |
| 22 | dnl along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 23 | |
| 24 | AC_PREREQ(2.65) |
| 25 | AC_INIT(emacs, 24.3.50) |
| 26 | |
| 27 | dnl We get MINGW64 with MSYS2 |
| 28 | if test "x$MSYSTEM" = "xMINGW32" -o "x$MSYSTEM" = "xMINGW64" |
| 29 | then |
| 30 | . $srcdir/nt/mingw-cfg.site |
| 31 | |
| 32 | case $srcdir in |
| 33 | /* | ?:*) |
| 34 | # srcdir is an absolute path. In this case, force the format |
| 35 | # "/c/foo/bar", to simplify later conversions to native Windows |
| 36 | # format ("c:/foo/bar") |
| 37 | srcdir=`cd "${srcdir}" && pwd -W` |
| 38 | srcdir="/${srcdir:0:1}${srcdir:2}" |
| 39 | ;; |
| 40 | esac |
| 41 | fi |
| 42 | |
| 43 | dnl Set emacs_config_options to the options of 'configure', quoted for the shell, |
| 44 | dnl and then quoted again for a C string. Separate options with spaces. |
| 45 | dnl Add some environment variables, if they were passed via the environment |
| 46 | dnl rather than on the command-line. |
| 47 | emacs_config_options= |
| 48 | optsep= |
| 49 | dnl This is the documented way to record the args passed to configure, |
| 50 | dnl rather than $ac_configure_args. |
| 51 | for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do |
| 52 | case $opt in |
| 53 | -n | --no-create | --no-recursion) |
| 54 | continue ;; |
| 55 | CFLAGS | CPPFLAGS | LDFLAGS) |
| 56 | eval 'test "${'$opt'+set}" = set' || continue |
| 57 | case " $*" in |
| 58 | *" $opt="*) continue ;; |
| 59 | esac |
| 60 | eval opt=$opt=\$$opt ;; |
| 61 | esac |
| 62 | |
| 63 | emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~' |
| 64 | case $opt in |
| 65 | *[["$emacs_shell_specials"]]*) |
| 66 | case $opt in |
| 67 | *\'*) |
| 68 | emacs_quote_apostrophes="s/'/'\\\\''/g" |
| 69 | opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;; |
| 70 | esac |
| 71 | opt="'$opt'" |
| 72 | case $opt in |
| 73 | *[['"\\']]*) |
| 74 | emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/' |
| 75 | opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;; |
| 76 | esac ;; |
| 77 | esac |
| 78 | AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"]) |
| 79 | optsep=' ' |
| 80 | done |
| 81 | |
| 82 | AC_CONFIG_HEADERS(src/config.h:src/config.in) |
| 83 | AC_CONFIG_SRCDIR(src/lisp.h) |
| 84 | AC_CONFIG_AUX_DIR(build-aux) |
| 85 | |
| 86 | xcsdkdir= |
| 87 | AC_CHECK_PROGS(XCRUN, [xcrun]) |
| 88 | if test -n "$XCRUN"; then |
| 89 | if test -z "$MAKE"; then |
| 90 | dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with |
| 91 | dnl SET_MAKE and with the usual MAKE variable that 'make' itself uses. |
| 92 | AC_CHECK_PROG([MAKE_PROG], [make], [yes]) |
| 93 | if test -z "$MAKE_PROG"; then |
| 94 | MAKE="$XCRUN MAKE" |
| 95 | export MAKE |
| 96 | xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null` |
| 97 | fi |
| 98 | fi |
| 99 | fi |
| 100 | |
| 101 | dnl Fairly arbitrary, older versions might work too. |
| 102 | AM_INIT_AUTOMAKE(1.11) |
| 103 | |
| 104 | dnl Support for --program-prefix, --program-suffix and |
| 105 | dnl --program-transform-name options |
| 106 | AC_ARG_PROGRAM |
| 107 | |
| 108 | dnl It is important that variables on the RHS not be expanded here, |
| 109 | dnl hence the single quotes. This is per the GNU coding standards, see |
| 110 | dnl (autoconf) Installation Directory Variables |
| 111 | dnl See also epaths.h below. |
| 112 | lispdir='${datadir}/emacs/${version}/lisp' |
| 113 | standardlisppath='${lispdir}' |
| 114 | locallisppath='${datadir}/emacs/${version}/site-lisp:'\ |
| 115 | '${datadir}/emacs/site-lisp' |
| 116 | lisppath='${locallisppath}:${standardlisppath}' |
| 117 | etcdir='${datadir}/emacs/${version}/etc' |
| 118 | archlibdir='${libexecdir}/emacs/${version}/${configuration}' |
| 119 | etcdocdir='${datadir}/emacs/${version}/etc' |
| 120 | gamedir='${localstatedir}/games/emacs' |
| 121 | |
| 122 | dnl Special option to disable the most of other options. |
| 123 | AC_ARG_WITH(all, |
| 124 | [AS_HELP_STRING([--without-all], |
| 125 | [omit almost all features and build |
| 126 | small executable with minimal dependencies])], |
| 127 | [with_features=$withval], |
| 128 | [with_features=yes]) |
| 129 | |
| 130 | dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING) |
| 131 | dnl Create a new --with option that defaults to being disabled. |
| 132 | dnl NAME is the base name of the option. The shell variable with_NAME |
| 133 | dnl will be set to either the user's value (if the option is |
| 134 | dnl specified; 'yes' for a plain --with-NAME) or to 'no' (if the |
| 135 | dnl option is not specified). Note that the shell variable name is |
| 136 | dnl constructed as autoconf does, by replacing non-alphanumeric |
| 137 | dnl characters with "_". |
| 138 | dnl HELP-STRING is the help text for the option. |
| 139 | AC_DEFUN([OPTION_DEFAULT_OFF], [dnl |
| 140 | AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl |
| 141 | m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl |
| 142 | ])dnl |
| 143 | |
| 144 | dnl OPTION_DEFAULT_ON(NAME, HELP-STRING) |
| 145 | dnl Create a new --with option that defaults to $with_features. |
| 146 | dnl NAME is the base name of the option. The shell variable with_NAME |
| 147 | dnl will be set either to 'no' (for a plain --without-NAME) or to |
| 148 | dnl 'yes' (if the option is not specified). Note that the shell |
| 149 | dnl variable name is constructed as autoconf does, by replacing |
| 150 | dnl non-alphanumeric characters with "_". |
| 151 | dnl HELP-STRING is the help text for the option. |
| 152 | AC_DEFUN([OPTION_DEFAULT_ON], [dnl |
| 153 | AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl |
| 154 | m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl |
| 155 | ])dnl |
| 156 | |
| 157 | OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail]) |
| 158 | if test "$with_pop" = yes; then |
| 159 | AC_DEFINE(MAIL_USE_POP) |
| 160 | fi |
| 161 | AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl |
| 162 | |
| 163 | OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP]) |
| 164 | if test "$with_kerberos" != no; then |
| 165 | AC_DEFINE(KERBEROS) |
| 166 | fi |
| 167 | AH_TEMPLATE(KERBEROS, |
| 168 | [Define to support Kerberos-authenticated POP mail retrieval.])dnl |
| 169 | |
| 170 | OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP]) |
| 171 | if test "${with_kerberos5}" != no; then |
| 172 | if test "${with_kerberos}" = no; then |
| 173 | with_kerberos=yes |
| 174 | AC_DEFINE(KERBEROS) |
| 175 | fi |
| 176 | AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.]) |
| 177 | fi |
| 178 | |
| 179 | OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host]) |
| 180 | dnl FIXME hesiod support may not be present, so it seems like an error |
| 181 | dnl to define, or at least use, this unconditionally. |
| 182 | if test "$with_hesiod" != no; then |
| 183 | AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.]) |
| 184 | fi |
| 185 | |
| 186 | OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes]) |
| 187 | if test "$with_mmdf" != no; then |
| 188 | AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.]) |
| 189 | fi |
| 190 | |
| 191 | OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading]) |
| 192 | if test "$with_mail_unlink" != no; then |
| 193 | AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.]) |
| 194 | fi |
| 195 | |
| 196 | AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME], |
| 197 | [string giving default POP mail host])], |
| 198 | AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.])) |
| 199 | |
| 200 | AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE], |
| 201 | [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no; |
| 202 | default yes). Only for GNU/Linux, FreeBSD, NetBSD, MinGW.])], |
| 203 | [ case "${withval}" in |
| 204 | yes|no|alsa|oss|bsd-ossaudio) val=$withval ;; |
| 205 | *) AC_MSG_ERROR([`--with-sound=$withval' is invalid; |
| 206 | this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.]) |
| 207 | ;; |
| 208 | esac |
| 209 | with_sound=$val |
| 210 | ], |
| 211 | [with_sound=$with_features]) |
| 212 | |
| 213 | dnl FIXME currently it is not the last. |
| 214 | dnl This should be the last --with option, because --with-x is |
| 215 | dnl added later on when we find the file name of X, and it's best to |
| 216 | dnl keep them together visually. |
| 217 | AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT], |
| 218 | [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])], |
| 219 | [ case "${withval}" in |
| 220 | y | ye | yes ) val=gtk ;; |
| 221 | n | no ) val=no ;; |
| 222 | l | lu | luc | luci | lucid ) val=lucid ;; |
| 223 | a | at | ath | athe | athen | athena ) val=athena ;; |
| 224 | m | mo | mot | moti | motif ) val=motif ;; |
| 225 | g | gt | gtk ) val=gtk ;; |
| 226 | gtk2 ) val=gtk2 ;; |
| 227 | gtk3 ) val=gtk3 ;; |
| 228 | * ) |
| 229 | AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid; |
| 230 | this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk', |
| 231 | `gtk2' or `gtk3'. `yes' and `gtk' are synonyms. |
| 232 | `athena' and `lucid' are synonyms.]) |
| 233 | ;; |
| 234 | esac |
| 235 | with_x_toolkit=$val |
| 236 | ]) |
| 237 | |
| 238 | OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)]) |
| 239 | if test "$with_wide_int" = yes; then |
| 240 | AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.]) |
| 241 | fi |
| 242 | |
| 243 | dnl _ON results in a '--without' option in the --help output, so |
| 244 | dnl the help text should refer to "don't compile", etc. |
| 245 | OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support]) |
| 246 | OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support]) |
| 247 | OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support]) |
| 248 | OPTION_DEFAULT_ON([gif],[don't compile with GIF image support]) |
| 249 | OPTION_DEFAULT_ON([png],[don't compile with PNG image support]) |
| 250 | OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support]) |
| 251 | OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support]) |
| 252 | OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support]) |
| 253 | |
| 254 | OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts]) |
| 255 | OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support]) |
| 256 | OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping]) |
| 257 | |
| 258 | OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars]) |
| 259 | OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d]) |
| 260 | OPTION_DEFAULT_ON([xim],[don't use X11 XIM]) |
| 261 | OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system]) |
| 262 | OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build]) |
| 263 | |
| 264 | OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console]) |
| 265 | OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support]) |
| 266 | OPTION_DEFAULT_ON([gconf],[don't compile with GConf support]) |
| 267 | OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support]) |
| 268 | OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support]) |
| 269 | OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support]) |
| 270 | OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support]) |
| 271 | |
| 272 | AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB], |
| 273 | [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])], |
| 274 | [ case "${withval}" in |
| 275 | y | ye | yes ) val=yes ;; |
| 276 | n | no ) val=no ;; |
| 277 | g | gf | gfi | gfil | gfile ) val=gfile ;; |
| 278 | i | in | ino | inot | inoti | inotif | inotify ) val=inotify ;; |
| 279 | w | w3 | w32 ) val=w32 ;; |
| 280 | * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid; |
| 281 | this option's value should be `yes', `no', `gfile', `inotify' or `w32'. |
| 282 | `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep, |
| 283 | otherwise for the first of `gfile' or `inotify' that is usable.]) |
| 284 | ;; |
| 285 | esac |
| 286 | with_file_notification=$val |
| 287 | ], |
| 288 | [with_file_notification=$with_features]) |
| 289 | |
| 290 | ## For the times when you want to build Emacs but don't have |
| 291 | ## a suitable makeinfo, and can live without the manuals. |
| 292 | dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html |
| 293 | OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals]) |
| 294 | |
| 295 | ## Makefile.in needs the cache file name. |
| 296 | AC_SUBST(cache_file) |
| 297 | |
| 298 | ## This is an option because I do not know if all info/man support |
| 299 | ## compressed files, nor how to test if they do so. |
| 300 | OPTION_DEFAULT_ON([compress-install], |
| 301 | [don't compress some files (.el, .info, etc.) when installing. Equivalent to: |
| 302 | make GZIP_PROG= install]) |
| 303 | |
| 304 | AC_ARG_WITH([pkg-config-prog],dnl |
| 305 | [AS_HELP_STRING([--with-pkg-config-prog=FILENAME], |
| 306 | [file name of pkg-config for finding GTK and librsvg])]) |
| 307 | if test "X${with_pkg_config_prog}" != X; then |
| 308 | if test "${with_pkg_config_prog}" != yes; then |
| 309 | PKG_CONFIG="${with_pkg_config_prog}" |
| 310 | fi |
| 311 | fi |
| 312 | |
| 313 | AC_ARG_WITH(gameuser,dnl |
| 314 | [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])]) |
| 315 | test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \ |
| 316 | && gameuser="${with_gameuser}" |
| 317 | test "X$gameuser" = X && gameuser=games |
| 318 | |
| 319 | AC_ARG_WITH([gnustep-conf],dnl |
| 320 | [AS_HELP_STRING([--with-gnustep-conf=FILENAME], |
| 321 | [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])]) |
| 322 | test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \ |
| 323 | GNUSTEP_CONFIG_FILE="${with_gnustep_conf}" |
| 324 | test "X$GNUSTEP_CONFIG_FILE" = "X" && \ |
| 325 | GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf |
| 326 | |
| 327 | AC_ARG_ENABLE(ns-self-contained, |
| 328 | [AS_HELP_STRING([--disable-ns-self-contained], |
| 329 | [disable self contained build under NeXTstep])], |
| 330 | EN_NS_SELF_CONTAINED=$enableval, |
| 331 | EN_NS_SELF_CONTAINED=yes) |
| 332 | |
| 333 | AC_ARG_ENABLE(locallisppath, |
| 334 | [AS_HELP_STRING([--enable-locallisppath=PATH], |
| 335 | [directories Emacs should search for lisp files specific |
| 336 | to this site])], |
| 337 | if test "${enableval}" = "no"; then |
| 338 | locallisppath= |
| 339 | elif test "${enableval}" != "yes"; then |
| 340 | locallisppath=${enableval} |
| 341 | fi) |
| 342 | |
| 343 | AC_ARG_ENABLE(checking, |
| 344 | [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@], |
| 345 | [enable expensive run-time checks. With LIST, |
| 346 | enable only specific categories of checks. |
| 347 | Categories are: all,yes,no. |
| 348 | Flags are: stringbytes, stringoverrun, stringfreelist, |
| 349 | xmallocoverrun, conslist, glyphs])], |
| 350 | [ac_checking_flags="${enableval}"],[]) |
| 351 | IFS="${IFS= }"; ac_save_IFS="$IFS"; IFS="$IFS," |
| 352 | for check in $ac_checking_flags |
| 353 | do |
| 354 | case $check in |
| 355 | # these set all the flags to specific states |
| 356 | yes) ac_enable_checking=1 ;; |
| 357 | no) ac_enable_checking= ; |
| 358 | ac_gc_check_stringbytes= ; |
| 359 | ac_gc_check_string_overrun= ; |
| 360 | ac_gc_check_string_free_list= ; |
| 361 | ac_xmalloc_overrun= ; |
| 362 | ac_gc_check_cons_list= ; |
| 363 | ac_glyphs_debug= ;; |
| 364 | all) ac_enable_checking=1 ; |
| 365 | ac_gc_check_stringbytes=1 ; |
| 366 | ac_gc_check_string_overrun=1 ; |
| 367 | ac_gc_check_string_free_list=1 ; |
| 368 | ac_xmalloc_overrun=1 ; |
| 369 | ac_gc_check_cons_list=1 ; |
| 370 | ac_glyphs_debug=1 ;; |
| 371 | # these enable particular checks |
| 372 | stringbytes) ac_gc_check_stringbytes=1 ;; |
| 373 | stringoverrun) ac_gc_check_string_overrun=1 ;; |
| 374 | stringfreelist) ac_gc_check_string_free_list=1 ;; |
| 375 | xmallocoverrun) ac_xmalloc_overrun=1 ;; |
| 376 | conslist) ac_gc_check_cons_list=1 ;; |
| 377 | glyphs) ac_glyphs_debug=1 ;; |
| 378 | *) AC_MSG_ERROR(unknown check category $check) ;; |
| 379 | esac |
| 380 | done |
| 381 | IFS="$ac_save_IFS" |
| 382 | |
| 383 | if test x$ac_enable_checking != x ; then |
| 384 | AC_DEFINE(ENABLE_CHECKING, 1, |
| 385 | [Define to 1 if expensive run-time data type and consistency checks are enabled.]) |
| 386 | fi |
| 387 | if test x$ac_gc_check_stringbytes != x ; then |
| 388 | AC_DEFINE(GC_CHECK_STRING_BYTES, 1, |
| 389 | [Define this temporarily to hunt a bug. If defined, the size of |
| 390 | strings is redundantly recorded in sdata structures so that it can |
| 391 | be compared to the sizes recorded in Lisp strings.]) |
| 392 | fi |
| 393 | if test x$ac_gc_check_string_overrun != x ; then |
| 394 | AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1, |
| 395 | [Define this to check for short string overrun.]) |
| 396 | fi |
| 397 | if test x$ac_gc_check_string_free_list != x ; then |
| 398 | AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1, |
| 399 | [Define this to check the string free list.]) |
| 400 | fi |
| 401 | if test x$ac_xmalloc_overrun != x ; then |
| 402 | AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1, |
| 403 | [Define this to check for malloc buffer overrun.]) |
| 404 | fi |
| 405 | if test x$ac_gc_check_cons_list != x ; then |
| 406 | AC_DEFINE(GC_CHECK_CONS_LIST, 1, |
| 407 | [Define this to check for errors in cons list.]) |
| 408 | fi |
| 409 | if test x$ac_glyphs_debug != x ; then |
| 410 | AC_DEFINE(GLYPH_DEBUG, 1, |
| 411 | [Define this to enable glyphs debugging code.]) |
| 412 | fi |
| 413 | |
| 414 | AC_ARG_ENABLE(check-lisp-object-type, |
| 415 | [AS_HELP_STRING([--enable-check-lisp-object-type], |
| 416 | [enable compile time checks for the Lisp_Object data type. |
| 417 | This is useful for development for catching certain types of bugs.])], |
| 418 | if test "${enableval}" != "no"; then |
| 419 | AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1, |
| 420 | [Define this to enable compile time checks for the Lisp_Object data type.]) |
| 421 | fi) |
| 422 | |
| 423 | |
| 424 | dnl The name of this option is unfortunate. It predates, and has no |
| 425 | dnl relation to, the "sampling-based elisp profiler" added in 24.3. |
| 426 | dnl Actually, it stops it working. |
| 427 | dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html |
| 428 | AC_ARG_ENABLE(profiling, |
| 429 | [AS_HELP_STRING([--enable-profiling], |
| 430 | [build emacs with low-level, gprof profiling support. |
| 431 | Mainly useful for debugging Emacs itself. May not work on |
| 432 | all platforms. Stops profiler.el working.])], |
| 433 | [ac_enable_profiling="${enableval}"],[]) |
| 434 | if test x$ac_enable_profiling != x ; then |
| 435 | PROFILING_CFLAGS="-DPROFILING=1 -pg" |
| 436 | else |
| 437 | PROFILING_CFLAGS= |
| 438 | fi |
| 439 | AC_SUBST(PROFILING_CFLAGS) |
| 440 | |
| 441 | AC_ARG_ENABLE(autodepend, |
| 442 | [AS_HELP_STRING([--enable-autodepend], |
| 443 | [automatically generate dependencies to .h-files. |
| 444 | Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is |
| 445 | found])], |
| 446 | [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes]) |
| 447 | |
| 448 | AC_ARG_ENABLE(gtk-deprecation-warnings, |
| 449 | [AS_HELP_STRING([--enable-gtk-deprecation-warnings], |
| 450 | [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])], |
| 451 | [ac_enable_gtk_deprecation_warnings="${enableval}"],[]) |
| 452 | |
| 453 | ### Canonicalize the configuration name. |
| 454 | |
| 455 | AC_CANONICAL_HOST |
| 456 | canonical=$host |
| 457 | configuration=${host_alias-${build_alias-$host}} |
| 458 | |
| 459 | dnl This used to use changequote, but, apart from `changequote is evil' |
| 460 | dnl per the autoconf manual, we can speed up autoconf somewhat by quoting |
| 461 | dnl the great gob of text. Thus it's not processed for possible expansion. |
| 462 | dnl Just make sure the brackets remain balanced. |
| 463 | dnl |
| 464 | dnl Since Emacs can't find matching pairs of quotes, boundaries are |
| 465 | dnl indicated by comments. |
| 466 | dnl quotation begins |
| 467 | [ |
| 468 | |
| 469 | ### If you add support for a new configuration, add code to this |
| 470 | ### switch statement to recognize your configuration name and select |
| 471 | ### the appropriate opsys. |
| 472 | |
| 473 | ### As far as handling version numbers on operating systems is |
| 474 | ### concerned, make sure things will fail in a fixable way. If |
| 475 | ### /etc/MACHINES doesn't say anything about version numbers, be |
| 476 | ### prepared to handle anything reasonably. If version numbers |
| 477 | ### matter, be sure /etc/MACHINES says something about it. |
| 478 | |
| 479 | opsys='' unported=no |
| 480 | case "${canonical}" in |
| 481 | |
| 482 | ## GNU/Linux and similar ports |
| 483 | *-*-linux* ) |
| 484 | opsys=gnu-linux |
| 485 | ;; |
| 486 | |
| 487 | ## FreeBSD ports |
| 488 | *-*-freebsd* ) |
| 489 | opsys=freebsd |
| 490 | ;; |
| 491 | |
| 492 | ## DragonFly ports |
| 493 | *-*-dragonfly* ) |
| 494 | opsys=dragonfly |
| 495 | ;; |
| 496 | |
| 497 | ## FreeBSD kernel + glibc based userland |
| 498 | *-*-kfreebsd*gnu* ) |
| 499 | opsys=gnu-kfreebsd |
| 500 | ;; |
| 501 | |
| 502 | ## NetBSD ports |
| 503 | *-*-netbsd* ) |
| 504 | opsys=netbsd |
| 505 | ;; |
| 506 | |
| 507 | ## OpenBSD ports |
| 508 | *-*-openbsd* ) |
| 509 | opsys=openbsd |
| 510 | ;; |
| 511 | |
| 512 | ## Apple Darwin / Mac OS X |
| 513 | *-apple-darwin* ) |
| 514 | case "${canonical}" in |
| 515 | i[3456]86-* ) ;; |
| 516 | powerpc-* ) ;; |
| 517 | x86_64-* ) ;; |
| 518 | * ) unported=yes ;; |
| 519 | esac |
| 520 | opsys=darwin |
| 521 | ## Use fink packages if available. |
| 522 | ## FIXME find a better way to do this: http://debbugs.gnu.org/11507 |
| 523 | ## if test -d /sw/include && test -d /sw/lib; then |
| 524 | ## GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib" |
| 525 | ## NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS} |
| 526 | ## fi |
| 527 | ;; |
| 528 | |
| 529 | ## Cygwin ports |
| 530 | *-*-cygwin ) |
| 531 | opsys=cygwin |
| 532 | ;; |
| 533 | |
| 534 | ## HP 9000 series 700 and 800, running HP/UX |
| 535 | hppa*-hp-hpux10.2* ) |
| 536 | opsys=hpux10-20 |
| 537 | ;; |
| 538 | hppa*-hp-hpux1[1-9]* ) |
| 539 | opsys=hpux11 |
| 540 | CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS" |
| 541 | ;; |
| 542 | |
| 543 | ## IBM machines |
| 544 | rs6000-ibm-aix4.[23]* ) |
| 545 | opsys=aix4-2 |
| 546 | ;; |
| 547 | powerpc-ibm-aix4.[23]* ) |
| 548 | opsys=aix4-2 |
| 549 | ;; |
| 550 | rs6000-ibm-aix[56]* ) |
| 551 | opsys=aix4-2 |
| 552 | ;; |
| 553 | powerpc-ibm-aix[56]* ) |
| 554 | opsys=aix4-2 |
| 555 | ;; |
| 556 | |
| 557 | ## Silicon Graphics machines |
| 558 | ## Iris 4D |
| 559 | mips-sgi-irix6.5 ) |
| 560 | opsys=irix6-5 |
| 561 | # Without defining _LANGUAGE_C, things get masked out in the headers |
| 562 | # so that, for instance, grepping for `free' in stdlib.h fails and |
| 563 | # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m). |
| 564 | NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C" |
| 565 | ;; |
| 566 | |
| 567 | ## Suns |
| 568 | *-sun-solaris* \ |
| 569 | | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \ |
| 570 | | x86_64-*-solaris2* | x86_64-*-sunos5*) |
| 571 | case "${canonical}" in |
| 572 | i[3456]86-*-* ) ;; |
| 573 | amd64-*-*|x86_64-*-*) ;; |
| 574 | sparc* ) ;; |
| 575 | * ) unported=yes ;; |
| 576 | esac |
| 577 | case "${canonical}" in |
| 578 | *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* ) |
| 579 | opsys=sol2-10 |
| 580 | emacs_check_sunpro_c=yes |
| 581 | ;; |
| 582 | *-sunos5.6* | *-solaris2.6* ) |
| 583 | opsys=sol2-6 |
| 584 | RANLIB="ar -ts" |
| 585 | ;; |
| 586 | *-sunos5.[7-9]* | *-solaris2.[7-9]* ) |
| 587 | opsys=sol2-6 |
| 588 | emacs_check_sunpro_c=yes |
| 589 | ;; |
| 590 | esac |
| 591 | ## Watch out for a compiler that we know will not work. |
| 592 | case "${canonical}" in |
| 593 | *-solaris* | *-sunos5* ) |
| 594 | if [ "x$CC" = x/usr/ucb/cc ]; then |
| 595 | ## /usr/ucb/cc doesn't work; |
| 596 | ## we should find some other compiler that does work. |
| 597 | unset CC |
| 598 | fi |
| 599 | ;; |
| 600 | *) ;; |
| 601 | esac |
| 602 | ;; |
| 603 | |
| 604 | ## Intel 386 machines where we don't care about the manufacturer. |
| 605 | i[3456]86-*-* ) |
| 606 | case "${canonical}" in |
| 607 | *-darwin* ) opsys=darwin ;; |
| 608 | *-mingw32 ) |
| 609 | opsys=mingw32 |
| 610 | # MinGW overrides and adds some system headers in nt/inc. |
| 611 | GCC_TEST_OPTIONS="-I $srcdir/nt/inc" |
| 612 | ;; |
| 613 | *-sysv4.2uw* ) opsys=unixware ;; |
| 614 | *-sysv5uw* ) opsys=unixware ;; |
| 615 | *-sysv5OpenUNIX* ) opsys=unixware ;; |
| 616 | ## Otherwise, we'll fall through to the generic opsys code at the bottom. |
| 617 | esac |
| 618 | ;; |
| 619 | |
| 620 | # MinGW64 |
| 621 | x86_64-*-* ) |
| 622 | case "${canonical}" in |
| 623 | *-mingw32 ) |
| 624 | opsys=mingw32 |
| 625 | # MinGW overrides and adds some system headers in nt/inc. |
| 626 | GCC_TEST_OPTIONS="-I $srcdir/nt/inc" |
| 627 | ;; |
| 628 | ## Otherwise, we'll fall through to the generic opsys code at the bottom. |
| 629 | esac |
| 630 | ;; |
| 631 | |
| 632 | * ) |
| 633 | unported=yes |
| 634 | ;; |
| 635 | esac |
| 636 | |
| 637 | ### If the code above didn't choose an operating system, just choose |
| 638 | ### an operating system based on the configuration name. You really |
| 639 | ### only want to use this when you have no idea what the right |
| 640 | ### operating system is; if you know what operating systems a machine |
| 641 | ### runs, it's cleaner to make it explicit in the case statement |
| 642 | ### above. |
| 643 | if test x"${opsys}" = x; then |
| 644 | case "${canonical}" in |
| 645 | *-gnu* ) opsys=gnu ;; |
| 646 | * ) |
| 647 | unported=yes |
| 648 | ;; |
| 649 | esac |
| 650 | fi |
| 651 | |
| 652 | ] |
| 653 | dnl quotation ends |
| 654 | |
| 655 | if test $unported = yes; then |
| 656 | AC_MSG_ERROR([Emacs does not support building on `${canonical}' systems. |
| 657 | If you think it should, please send a report to bug-gnu-emacs@gnu.org. |
| 658 | Check `etc/MACHINES' for recognized configuration names.]) |
| 659 | fi |
| 660 | |
| 661 | |
| 662 | #### Choose a compiler. |
| 663 | |
| 664 | dnl Sets GCC=yes if using gcc. |
| 665 | AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"]) |
| 666 | if test -n "$XCRUN"; then |
| 667 | AC_CHECK_PROGS(AR, [ar "$XCRUN ar"]) |
| 668 | test -n "$AR" && export AR |
| 669 | fi |
| 670 | |
| 671 | AM_PROG_CC_C_O |
| 672 | |
| 673 | if test x$GCC = xyes; then |
| 674 | test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS" |
| 675 | else |
| 676 | test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS" |
| 677 | fi |
| 678 | |
| 679 | dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the |
| 680 | dnl alternative to lib/gnulib.mk, so as to avoid generating header files |
| 681 | dnl that clash with MinGW. |
| 682 | AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"]) |
| 683 | |
| 684 | # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it. |
| 685 | AC_DEFUN([gl_CRYPTO_CHECK]) |
| 686 | # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW, |
| 687 | # as we don't use them. |
| 688 | AC_DEFUN([gl_FCNTL_O_FLAGS]) |
| 689 | # Avoid gnulib's threadlib module, as we do threads our own way. |
| 690 | AC_DEFUN([gl_THREADLIB]) |
| 691 | |
| 692 | # Initialize gnulib right after choosing the compiler. |
| 693 | dnl Amongst other things, this sets AR and ARFLAGS. |
| 694 | gl_EARLY |
| 695 | |
| 696 | if test "$ac_test_CFLAGS" != set; then |
| 697 | # It's helpful to have C macros available to GDB, so prefer -g3 to -g |
| 698 | # if -g3 works and the user does not specify CFLAGS. |
| 699 | # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains. |
| 700 | case $CFLAGS in |
| 701 | '-g') |
| 702 | emacs_g3_CFLAGS='-g3';; |
| 703 | '-g -O2') |
| 704 | emacs_g3_CFLAGS='-g3 -O2';; |
| 705 | *) |
| 706 | emacs_g3_CFLAGS='';; |
| 707 | esac |
| 708 | if test -n "$emacs_g3_CFLAGS"; then |
| 709 | emacs_save_CFLAGS=$CFLAGS |
| 710 | CFLAGS=$emacs_g3_CFLAGS |
| 711 | AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS], |
| 712 | [emacs_cv_prog_cc_g3], |
| 713 | [AC_LINK_IFELSE([AC_LANG_PROGRAM()], |
| 714 | [emacs_cv_prog_cc_g3=yes], |
| 715 | [emacs_cv_prog_cc_g3=no])]) |
| 716 | if test $emacs_cv_prog_cc_g3 != yes; then |
| 717 | CFLAGS=$emacs_save_CFLAGS |
| 718 | fi |
| 719 | if test $opsys = mingw32; then |
| 720 | CFLAGS="$CFLAGS -gdwarf-2" |
| 721 | fi |
| 722 | fi |
| 723 | |
| 724 | case $CFLAGS in |
| 725 | *-O*) ;; |
| 726 | *) |
| 727 | # No optimization flag was inferred for this non-GCC compiler. |
| 728 | # Try -O. This is needed for xlc on AIX; see Bug#14258. |
| 729 | emacs_save_CFLAGS=$CFLAGS |
| 730 | test -z "$CFLAGS" || CFLAGS="$CFLAGS " |
| 731 | CFLAGS=${CFLAGS}-O |
| 732 | AC_CACHE_CHECK([whether $CC accepts -O], |
| 733 | [emacs_cv_prog_cc_o], |
| 734 | [AC_LINK_IFELSE([AC_LANG_PROGRAM()], |
| 735 | [emacs_cv_prog_cc_o=yes], |
| 736 | [emacs_cv_prog_cc_o=no])]) |
| 737 | if test $emacs_cv_prog_cc_o != yes; then |
| 738 | CFLAGS=$emacs_save_CFLAGS |
| 739 | fi ;; |
| 740 | esac |
| 741 | fi |
| 742 | |
| 743 | AC_ARG_ENABLE([gcc-warnings], |
| 744 | [AS_HELP_STRING([--enable-gcc-warnings], |
| 745 | [turn on lots of GCC warnings/errors. This is intended for |
| 746 | developers, and may generate false alarms when used |
| 747 | with older or non-GNU development tools.])], |
| 748 | [case $enableval in |
| 749 | yes|no) ;; |
| 750 | *) AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;; |
| 751 | esac |
| 752 | gl_gcc_warnings=$enableval], |
| 753 | [gl_gcc_warnings=no] |
| 754 | ) |
| 755 | |
| 756 | AC_ARG_ENABLE(link-time-optimization, |
| 757 | [AS_HELP_STRING([--enable-link-time-optimization], |
| 758 | [build emacs with link-time optimization. |
| 759 | This is supported only for GCC since 4.5.0.])], |
| 760 | if test "${enableval}" != "no"; then |
| 761 | AC_MSG_CHECKING([whether link-time optimization is supported]) |
| 762 | ac_lto_supported=no |
| 763 | if test x$GCC = xyes; then |
| 764 | CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null` |
| 765 | if test x$CPUS != x; then |
| 766 | LTO="-flto=$CPUS" |
| 767 | else |
| 768 | LTO="-flto" |
| 769 | fi |
| 770 | old_CFLAGS=$CFLAGS |
| 771 | CFLAGS="$CFLAGS $LTO" |
| 772 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], |
| 773 | [ac_lto_supported=yes], [ac_lto_supported=no]) |
| 774 | CFLAGS="$old_CFLAGS" |
| 775 | fi |
| 776 | AC_MSG_RESULT([$ac_lto_supported]) |
| 777 | if test "$ac_lto_supported" = "yes"; then |
| 778 | CFLAGS="$CFLAGS $LTO" |
| 779 | fi |
| 780 | fi) |
| 781 | |
| 782 | # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found]) |
| 783 | # ------------------------------------------------ |
| 784 | # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND. |
| 785 | # Otherwise, run RUN-IF-NOT-FOUND. |
| 786 | AC_DEFUN([gl_GCC_VERSION_IFELSE], |
| 787 | [AC_PREPROC_IFELSE( |
| 788 | [AC_LANG_PROGRAM( |
| 789 | [[ |
| 790 | #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__) |
| 791 | /* ok */ |
| 792 | #else |
| 793 | # error "your version of gcc is older than $1.$2" |
| 794 | #endif |
| 795 | ]]), |
| 796 | ], [$3], [$4]) |
| 797 | ] |
| 798 | ) |
| 799 | |
| 800 | # clang is unduly picky about some things. |
| 801 | AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang], |
| 802 | [AC_COMPILE_IFELSE( |
| 803 | [AC_LANG_PROGRAM([[ |
| 804 | #ifndef __clang__ |
| 805 | #error "not clang" |
| 806 | #endif |
| 807 | ]])], |
| 808 | [emacs_cv_clang=yes], |
| 809 | [emacs_cv_clang=no])]) |
| 810 | |
| 811 | # When compiling with GCC, prefer -isystem to -I when including system |
| 812 | # include files, to avoid generating useless diagnostics for the files. |
| 813 | if test "$gl_gcc_warnings" != yes; then |
| 814 | isystem='-I' |
| 815 | if test "$emacs_cv_clang" = yes |
| 816 | then |
| 817 | # Turn off some warnings if supported. |
| 818 | gl_WARN_ADD([-Wno-switch]) |
| 819 | gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare]) |
| 820 | gl_WARN_ADD([-Wno-pointer-sign]) |
| 821 | fi |
| 822 | else |
| 823 | isystem='-isystem ' |
| 824 | |
| 825 | # This, $nw, is the list of warnings we disable. |
| 826 | nw= |
| 827 | |
| 828 | case $with_x_toolkit in |
| 829 | lucid | athena | motif) |
| 830 | # Old toolkits mishandle 'const'. |
| 831 | nw="$nw -Wwrite-strings" |
| 832 | ;; |
| 833 | *) |
| 834 | gl_WARN_ADD([-Werror], [WERROR_CFLAGS]) |
| 835 | ;; |
| 836 | esac |
| 837 | AC_SUBST([WERROR_CFLAGS]) |
| 838 | |
| 839 | nw="$nw -Wsystem-headers" # Don't let system headers trigger warnings |
| 840 | nw="$nw -Woverlength-strings" # Not a problem these days |
| 841 | nw="$nw -Wlogical-op" # any use of fwrite provokes this |
| 842 | nw="$nw -Wformat-nonliteral" # we do this a lot |
| 843 | nw="$nw -Wvla" # warnings in gettext.h |
| 844 | nw="$nw -Wnested-externs" # use of XARGMATCH/verify_function__ |
| 845 | nw="$nw -Wswitch-default" # Too many warnings for now |
| 846 | nw="$nw -Winline" # OK to ignore 'inline' |
| 847 | nw="$nw -Wjump-misses-init" # We sometimes safely jump over init. |
| 848 | nw="$nw -Wstrict-overflow" # OK to optimize assuming that |
| 849 | # signed overflow has undefined behavior |
| 850 | nw="$nw -Wsync-nand" # irrelevant here, and provokes ObjC warning |
| 851 | nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations |
| 852 | nw="$nw -Wbad-function-cast" # These casts are no worse than others. |
| 853 | |
| 854 | # Emacs doesn't care about shadowing; see |
| 855 | # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>. |
| 856 | nw="$nw -Wshadow" |
| 857 | |
| 858 | # Emacs's use of alloca inhibits protecting the stack. |
| 859 | nw="$nw -Wstack-protector" |
| 860 | |
| 861 | # The following line should be removable at some point. |
| 862 | nw="$nw -Wsuggest-attribute=pure" |
| 863 | |
| 864 | # This part is merely for shortening the command line, |
| 865 | # since -Wno-FOO needs to be added below regardless. |
| 866 | nw="$nw -Wmissing-field-initializers" |
| 867 | nw="$nw -Wswitch" |
| 868 | nw="$nw -Wtype-limits" |
| 869 | nw="$nw -Wunused-parameter" |
| 870 | |
| 871 | if test $emacs_cv_clang = yes; then |
| 872 | nw="$nw -Wcast-align" |
| 873 | fi |
| 874 | |
| 875 | gl_MANYWARN_ALL_GCC([ws]) |
| 876 | gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw]) |
| 877 | for w in $ws; do |
| 878 | gl_WARN_ADD([$w]) |
| 879 | done |
| 880 | gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one |
| 881 | gl_WARN_ADD([-Wno-sign-compare]) # Too many warnings for now |
| 882 | gl_WARN_ADD([-Wno-type-limits]) # Too many warnings for now |
| 883 | gl_WARN_ADD([-Wno-switch]) # Too many warnings for now |
| 884 | gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now |
| 885 | gl_WARN_ADD([-Wno-format-nonliteral]) |
| 886 | |
| 887 | # In spite of excluding -Wlogical-op above, it is enabled, as of |
| 888 | # gcc 4.5.0 20090517. |
| 889 | gl_WARN_ADD([-Wno-logical-op]) |
| 890 | |
| 891 | # More things that clang is unduly picky about. |
| 892 | if test $emacs_cv_clang = yes; then |
| 893 | gl_WARN_ADD([-Wno-format-extra-args]) |
| 894 | gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare]) |
| 895 | gl_WARN_ADD([-Wno-unused-command-line-argument]) |
| 896 | gl_WARN_ADD([-Wno-unused-value]) |
| 897 | fi |
| 898 | |
| 899 | AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.]) |
| 900 | AH_VERBATIM([FORTIFY_SOURCE], |
| 901 | [/* Enable compile-time and run-time bounds-checking, and some warnings, |
| 902 | without upsetting glibc 2.15+. */ |
| 903 | #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__ |
| 904 | # define _FORTIFY_SOURCE 2 |
| 905 | #endif |
| 906 | ]) |
| 907 | AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks]) |
| 908 | |
| 909 | # We use a slightly smaller set of warning options for lib/. |
| 910 | # Remove the following and save the result in GNULIB_WARN_CFLAGS. |
| 911 | nw= |
| 912 | nw="$nw -Wunused-macros" |
| 913 | |
| 914 | gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw]) |
| 915 | AC_SUBST([GNULIB_WARN_CFLAGS]) |
| 916 | fi |
| 917 | |
| 918 | |
| 919 | |
| 920 | dnl Some other nice autoconf tests. |
| 921 | dnl These are commented out, since gl_EARLY and/or Autoconf already does them. |
| 922 | dnl AC_PROG_INSTALL |
| 923 | dnl AC_PROG_MKDIR_P |
| 924 | dnl if test "x$RANLIB" = x; then |
| 925 | dnl AC_PROG_RANLIB |
| 926 | dnl fi |
| 927 | |
| 928 | |
| 929 | dnl Sadly, AC_PROG_LN_S is too restrictive. It also tests whether links |
| 930 | dnl can be made to directories. This is not relevant for our usage, and |
| 931 | dnl excludes some cases that work fine for us. Eg MS Windows or files |
| 932 | dnl hosted on AFS, both examples where simple links work, but links to |
| 933 | dnl directories fail. We use a cut-down version instead. |
| 934 | dnl AC_PROG_LN_S |
| 935 | |
| 936 | AC_MSG_CHECKING([whether ln -s works for files in the same directory]) |
| 937 | rm -f conf$$ conf$$.file |
| 938 | |
| 939 | LN_S_FILEONLY='cp -p' |
| 940 | |
| 941 | if (echo >conf$$.file) 2>/dev/null; then |
| 942 | if ln -s conf$$.file conf$$ 2>/dev/null; then |
| 943 | LN_S_FILEONLY='ln -s' |
| 944 | elif ln conf$$.file conf$$ 2>/dev/null; then |
| 945 | LN_S_FILEONLY=ln |
| 946 | fi |
| 947 | fi |
| 948 | |
| 949 | rm -f conf$$ conf$$.file |
| 950 | |
| 951 | if test "$LN_S_FILEONLY" = "ln -s"; then |
| 952 | AC_MSG_RESULT([yes]) |
| 953 | else |
| 954 | AC_MSG_RESULT([no, using $LN_S_FILEONLY]) |
| 955 | fi |
| 956 | |
| 957 | AC_SUBST(LN_S_FILEONLY) |
| 958 | |
| 959 | |
| 960 | dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln' |
| 961 | dnl doesn't support links to directories, as in "ln file dir". But that |
| 962 | dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs |
| 963 | dnl executables at "make install" time. |
| 964 | dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html |
| 965 | dnl for more details. |
| 966 | if test "$opsys" = "mingw32"; then |
| 967 | LN_S="ln" |
| 968 | fi |
| 969 | |
| 970 | AC_PATH_PROG(INSTALL_INFO, install-info, :, |
| 971 | $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin) |
| 972 | dnl Don't use GZIP, which is used by gzip for additional parameters. |
| 973 | AC_PATH_PROG(GZIP_PROG, gzip) |
| 974 | |
| 975 | test $with_compress_install != yes && test -n "$GZIP_PROG" && \ |
| 976 | GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)" |
| 977 | |
| 978 | if test $opsys = gnu-linux; then |
| 979 | AC_PATH_PROG(PAXCTL, paxctl,, |
| 980 | [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin]) |
| 981 | if test "X$PAXCTL" != X; then |
| 982 | AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header]) |
| 983 | AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], |
| 984 | [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes) |
| 985 | else AC_MSG_RESULT(no); PAXCTL=""; fi]) |
| 986 | fi |
| 987 | |
| 988 | if test "${SETFATTR+set}" != set; then |
| 989 | AC_CACHE_CHECK([for setfattr], |
| 990 | [emacs_cv_prog_setfattr], |
| 991 | [touch conftest.tmp |
| 992 | if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then |
| 993 | emacs_cv_prog_setfattr=yes |
| 994 | else |
| 995 | emacs_cv_prog_setfattr=no |
| 996 | fi]) |
| 997 | if test "$emacs_cv_prog_setfattr" = yes; then |
| 998 | SETFATTR=setfattr |
| 999 | else |
| 1000 | SETFATTR= |
| 1001 | fi |
| 1002 | rm -f conftest.tmp |
| 1003 | AC_SUBST([SETFATTR]) |
| 1004 | fi |
| 1005 | fi |
| 1006 | |
| 1007 | ## Need makeinfo >= 4.7 (?) to build the manuals. |
| 1008 | AC_PATH_PROG(MAKEINFO, makeinfo, no) |
| 1009 | dnl By this stage, configure has already checked for egrep and set EGREP, |
| 1010 | dnl or exited with an error if no egrep was found. |
| 1011 | if test "$MAKEINFO" != "no"; then |
| 1012 | case ` |
| 1013 | $MAKEINFO --version 2> /dev/null | |
| 1014 | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)' |
| 1015 | ` in |
| 1016 | '') MAKEINFO=no;; |
| 1017 | esac |
| 1018 | fi |
| 1019 | |
| 1020 | ## Makeinfo is unusual. For a released Emacs, the manuals are |
| 1021 | ## pre-built, and not deleted by the normal clean rules. makeinfo is |
| 1022 | ## therefore in the category of "special tools" not normally required, which |
| 1023 | ## configure does not have to check for (eg autoconf itself). |
| 1024 | ## In a repository checkout on the other hand, the manuals are not included. |
| 1025 | ## So makeinfo is a requirement to build from the repository, and configure |
| 1026 | ## should test for it as it does for any other build requirement. |
| 1027 | ## We use the presence of $srcdir/info/emacs to distinguish a release, |
| 1028 | ## with pre-built manuals, from a repository checkout. |
| 1029 | HAVE_MAKEINFO=yes |
| 1030 | |
| 1031 | if test "$MAKEINFO" = "no"; then |
| 1032 | MAKEINFO=makeinfo |
| 1033 | if test "x${with_makeinfo}" = "xno"; then |
| 1034 | HAVE_MAKEINFO=no |
| 1035 | elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then |
| 1036 | AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your |
| 1037 | source tree does not seem to have pre-built manuals in the `info' directory. |
| 1038 | Either install a suitable version of makeinfo, or re-run configure |
| 1039 | with the `--without-makeinfo' option to build without the manuals.] ) |
| 1040 | fi |
| 1041 | fi |
| 1042 | AC_SUBST(HAVE_MAKEINFO) |
| 1043 | |
| 1044 | dnl Just so that there is only a single place we need to edit. |
| 1045 | INFO_EXT=.info |
| 1046 | INFO_OPTS=--no-split |
| 1047 | AC_SUBST(INFO_EXT) |
| 1048 | AC_SUBST(INFO_OPTS) |
| 1049 | |
| 1050 | if test $opsys = mingw32; then |
| 1051 | DOCMISC_W32=efaq-w32 |
| 1052 | else |
| 1053 | DOCMISC_W32= |
| 1054 | fi |
| 1055 | AC_SUBST(DOCMISC_W32) |
| 1056 | |
| 1057 | dnl Add our options to ac_link now, after it is set up. |
| 1058 | |
| 1059 | if test x$GCC = xyes; then |
| 1060 | test "x$GCC_LINK_TEST_OPTIONS" != x && \ |
| 1061 | ac_link="$ac_link $GCC_LINK_TEST_OPTIONS" |
| 1062 | else |
| 1063 | test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \ |
| 1064 | ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS" |
| 1065 | fi |
| 1066 | |
| 1067 | dnl We need -znocombreloc if we're using a relatively recent GNU ld. |
| 1068 | dnl If we can link with the flag, it shouldn't do any harm anyhow. |
| 1069 | dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.) |
| 1070 | dnl Treat GCC specially since it just gives a non-fatal `unrecognized option' |
| 1071 | dnl if not built to support GNU ld. |
| 1072 | |
| 1073 | dnl For a long time, -znocombreloc was added to LDFLAGS rather than |
| 1074 | dnl LD_SWITCH_SYSTEM_TEMACS. That is: |
| 1075 | dnl * inappropriate, as LDFLAGS is a user option but this is essential. |
| 1076 | dnl Eg "make LDFLAGS=... all" could run into problems, |
| 1077 | dnl http://bugs.debian.org/684788 |
| 1078 | dnl * unnecessary, since temacs is the only thing that actually needs it. |
| 1079 | dnl Indeed this is where it was originally, prior to: |
| 1080 | dnl http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html |
| 1081 | late_LDFLAGS="$LDFLAGS" |
| 1082 | if test x$GCC = xyes; then |
| 1083 | LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc" |
| 1084 | else |
| 1085 | LDFLAGS_NOCOMBRELOC="-znocombreloc" |
| 1086 | fi |
| 1087 | |
| 1088 | LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC" |
| 1089 | |
| 1090 | AC_MSG_CHECKING([for -znocombreloc]) |
| 1091 | AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], |
| 1092 | [AC_MSG_RESULT(yes)], |
| 1093 | LDFLAGS_NOCOMBRELOC= |
| 1094 | [AC_MSG_RESULT(no)]) |
| 1095 | |
| 1096 | LDFLAGS="$late_LDFLAGS" |
| 1097 | |
| 1098 | AC_CACHE_CHECK([whether addresses are sanitized], |
| 1099 | [emacs_cv_sanitize_address], |
| 1100 | [AC_COMPILE_IFELSE( |
| 1101 | [AC_LANG_PROGRAM( |
| 1102 | [[#ifndef __has_feature |
| 1103 | #define __has_feature(f) 0 |
| 1104 | #endif |
| 1105 | #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer) |
| 1106 | #else |
| 1107 | #error "Addresses are not sanitized." |
| 1108 | #endif |
| 1109 | ]])], |
| 1110 | [emacs_cv_sanitize_address=yes], |
| 1111 | [emacs_cv_sanitize_address=no])]) |
| 1112 | |
| 1113 | dnl The function dump-emacs will not be defined and temacs will do |
| 1114 | dnl (load "loadup") automatically unless told otherwise. |
| 1115 | test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no |
| 1116 | case "$opsys" in |
| 1117 | your-opsys-here) CANNOT_DUMP=yes ;; |
| 1118 | esac |
| 1119 | |
| 1120 | if test "$CANNOT_DUMP" = "yes"; then |
| 1121 | AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.]) |
| 1122 | elif test "$emacs_cv_sanitize_address" = yes; then |
| 1123 | AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]]) |
| 1124 | fi |
| 1125 | |
| 1126 | AC_SUBST(CANNOT_DUMP) |
| 1127 | |
| 1128 | |
| 1129 | UNEXEC_OBJ=unexelf.o |
| 1130 | case "$opsys" in |
| 1131 | # MSDOS uses unexcoff.o |
| 1132 | aix4-2) |
| 1133 | UNEXEC_OBJ=unexaix.o |
| 1134 | ;; |
| 1135 | cygwin) |
| 1136 | UNEXEC_OBJ=unexcw.o |
| 1137 | ;; |
| 1138 | darwin) |
| 1139 | UNEXEC_OBJ=unexmacosx.o |
| 1140 | ;; |
| 1141 | hpux10-20 | hpux11) |
| 1142 | UNEXEC_OBJ=unexhp9k800.o |
| 1143 | ;; |
| 1144 | mingw32) |
| 1145 | UNEXEC_OBJ=unexw32.o |
| 1146 | ;; |
| 1147 | sol2-10) |
| 1148 | # Use the Solaris dldump() function, called from unexsol.c, to dump |
| 1149 | # emacs, instead of the generic ELF dump code found in unexelf.c. |
| 1150 | # The resulting binary has a complete symbol table, and is better |
| 1151 | # for debugging and other observability tools (debuggers, pstack, etc). |
| 1152 | # |
| 1153 | # If you encounter a problem using dldump(), please consider sending |
| 1154 | # a message to the OpenSolaris tools-linking mailing list: |
| 1155 | # http://mail.opensolaris.org/mailman/listinfo/tools-linking |
| 1156 | # |
| 1157 | # It is likely that dldump() works with older Solaris too, but this has |
| 1158 | # not been tested, so for now this change is for Solaris 10 or newer. |
| 1159 | UNEXEC_OBJ=unexsol.o |
| 1160 | ;; |
| 1161 | esac |
| 1162 | |
| 1163 | LD_SWITCH_SYSTEM= |
| 1164 | case "$opsys" in |
| 1165 | freebsd|dragonfly) |
| 1166 | ## Let `ld' find image libs and similar things in /usr/local/lib. |
| 1167 | ## The system compiler, GCC, has apparently been modified to not |
| 1168 | ## look there, contrary to what a stock GCC would do. |
| 1169 | ### It's not our place to do this. See bug#10313#17. |
| 1170 | ### LD_SWITCH_SYSTEM=-L/usr/local/lib |
| 1171 | : |
| 1172 | ;; |
| 1173 | |
| 1174 | gnu-linux) |
| 1175 | ## cpp test was "ifdef __mips__", but presumably this is equivalent... |
| 1176 | case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac |
| 1177 | ;; |
| 1178 | |
| 1179 | netbsd) |
| 1180 | ### It's not our place to do this. See bug#10313#17. |
| 1181 | ### LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib" |
| 1182 | : |
| 1183 | ;; |
| 1184 | |
| 1185 | openbsd) |
| 1186 | ## Han Boetes <han@boetes.org> says this is necessary, |
| 1187 | ## otherwise Emacs dumps core on elf systems. |
| 1188 | LD_SWITCH_SYSTEM="-Z" |
| 1189 | ;; |
| 1190 | esac |
| 1191 | AC_SUBST(LD_SWITCH_SYSTEM) |
| 1192 | |
| 1193 | ac_link="$ac_link $LD_SWITCH_SYSTEM" |
| 1194 | |
| 1195 | ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH, |
| 1196 | ## which has not been defined yet. When this was handled with cpp, |
| 1197 | ## it was expanded to null when configure sourced the s/*.h file. |
| 1198 | ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles. |
| 1199 | ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS |
| 1200 | ## (or somesuch), but because it is supposed to go at the _front_ |
| 1201 | ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way. |
| 1202 | ## Compare with the gnu-linux case below, which added to the end |
| 1203 | ## of LD_SWITCH_SYSTEM, and so can instead go at the front of |
| 1204 | ## LD_SWITCH_SYSTEM_TEMACS. |
| 1205 | case "$opsys" in |
| 1206 | netbsd|openbsd) |
| 1207 | LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;; |
| 1208 | esac |
| 1209 | |
| 1210 | |
| 1211 | C_SWITCH_MACHINE= |
| 1212 | case $canonical in |
| 1213 | alpha*) |
| 1214 | AC_CHECK_DECL([__ELF__]) |
| 1215 | if test "$ac_cv_have_decl___ELF__" = "yes"; then |
| 1216 | ## With ELF, make sure that all common symbols get allocated to in the |
| 1217 | ## data section. Otherwise, the dump of temacs may miss variables in |
| 1218 | ## the shared library that have been initialized. For example, with |
| 1219 | ## GNU libc, __malloc_initialized would normally be resolved to the |
| 1220 | ## shared library's .bss section, which is fatal. |
| 1221 | if test "x$GCC" = "xyes"; then |
| 1222 | C_SWITCH_MACHINE="-fno-common" |
| 1223 | else |
| 1224 | AC_MSG_ERROR([Non-GCC compilers are not supported.]) |
| 1225 | fi |
| 1226 | else |
| 1227 | dnl This was the unexalpha.c case. Removed in 24.1, 2010-07-24, |
| 1228 | dnl albeit under the mistaken assumption that said file |
| 1229 | dnl was no longer used. |
| 1230 | AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.]) |
| 1231 | fi |
| 1232 | ;; |
| 1233 | esac |
| 1234 | AC_SUBST(C_SWITCH_MACHINE) |
| 1235 | |
| 1236 | AC_SUBST(UNEXEC_OBJ) |
| 1237 | |
| 1238 | C_SWITCH_SYSTEM= |
| 1239 | ## Some programs in src produce warnings saying certain subprograms |
| 1240 | ## are too complex and need a MAXMEM value greater than 2000 for |
| 1241 | ## additional optimization. --nils@exp-math.uni-essen.de |
| 1242 | test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \ |
| 1243 | C_SWITCH_SYSTEM="-ma -qmaxmem=4000" |
| 1244 | if test "$opsys" = "mingw32"; then |
| 1245 | case "$canonical" in |
| 1246 | x86_64-*-mingw32) C_SWITCH_SYSTEM="-mtune=generic" ;; |
| 1247 | *) C_SWITCH_SYSTEM="-mtune=pentium4" ;; |
| 1248 | esac |
| 1249 | fi |
| 1250 | ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems. |
| 1251 | ## It is redundant in glibc2, since we define _GNU_SOURCE. |
| 1252 | AC_SUBST(C_SWITCH_SYSTEM) |
| 1253 | |
| 1254 | |
| 1255 | LIBS_SYSTEM= |
| 1256 | case "$opsys" in |
| 1257 | ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2. |
| 1258 | aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;; |
| 1259 | |
| 1260 | freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;; |
| 1261 | |
| 1262 | hpux*) LIBS_SYSTEM="-l:libdld.sl" ;; |
| 1263 | |
| 1264 | sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;; |
| 1265 | |
| 1266 | ## Motif needs -lgen. |
| 1267 | unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;; |
| 1268 | esac |
| 1269 | |
| 1270 | AC_SUBST(LIBS_SYSTEM) |
| 1271 | |
| 1272 | ### Make sure subsequent tests use flags consistent with the build flags. |
| 1273 | |
| 1274 | if test x"${OVERRIDE_CPPFLAGS}" != x; then |
| 1275 | CPPFLAGS="${OVERRIDE_CPPFLAGS}" |
| 1276 | else |
| 1277 | CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS" |
| 1278 | fi |
| 1279 | |
| 1280 | # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better. |
| 1281 | AC_DEFUN([AC_TYPE_SIZE_T]) |
| 1282 | # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them. |
| 1283 | AC_DEFUN([AC_TYPE_UID_T]) |
| 1284 | |
| 1285 | |
| 1286 | LIB_MATH=-lm |
| 1287 | dnl Current possibilities handled by sed (aix4-2 -> aix, |
| 1288 | dnl gnu-linux -> gnu/linux, etc.): |
| 1289 | dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix. |
| 1290 | dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt. |
| 1291 | SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'` |
| 1292 | |
| 1293 | case $opsys in |
| 1294 | cygwin ) |
| 1295 | LIB_MATH= |
| 1296 | ;; |
| 1297 | darwin ) |
| 1298 | ## Adding -lm confuses the dynamic linker, so omit it. |
| 1299 | LIB_MATH= |
| 1300 | ;; |
| 1301 | freebsd | dragonfly ) |
| 1302 | SYSTEM_TYPE=berkeley-unix |
| 1303 | ;; |
| 1304 | gnu-linux | gnu-kfreebsd ) |
| 1305 | ;; |
| 1306 | hpux10-20 | hpux11 ) |
| 1307 | ;; |
| 1308 | mingw32 ) |
| 1309 | LIB_MATH= |
| 1310 | SYSTEM_TYPE=windows-nt |
| 1311 | ;; |
| 1312 | dnl NB this may be adjusted below. |
| 1313 | netbsd | openbsd ) |
| 1314 | SYSTEM_TYPE=berkeley-unix |
| 1315 | ;; |
| 1316 | |
| 1317 | sol2* | unixware ) |
| 1318 | SYSTEM_TYPE=usg-unix-v |
| 1319 | ;; |
| 1320 | |
| 1321 | esac |
| 1322 | |
| 1323 | AC_SUBST(LIB_MATH) |
| 1324 | AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE", |
| 1325 | [The type of system you are compiling for; sets `system-type'.]) |
| 1326 | |
| 1327 | |
| 1328 | pre_PKG_CONFIG_CFLAGS=$CFLAGS |
| 1329 | pre_PKG_CONFIG_LIBS=$LIBS |
| 1330 | |
| 1331 | AC_PATH_PROG(PKG_CONFIG, pkg-config, no) |
| 1332 | |
| 1333 | dnl This function definition taken from Gnome 2.0 |
| 1334 | dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not) |
| 1335 | dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page |
| 1336 | dnl also defines GSTUFF_PKG_ERRORS on error |
| 1337 | AC_DEFUN([PKG_CHECK_MODULES], [ |
| 1338 | succeeded=no |
| 1339 | |
| 1340 | if test "$PKG_CONFIG" = "no" ; then |
| 1341 | ifelse([$4], , [AC_MSG_ERROR([ |
| 1342 | *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog. Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4]) |
| 1343 | else |
| 1344 | PKG_CONFIG_MIN_VERSION=0.9.0 |
| 1345 | if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then |
| 1346 | AC_MSG_CHECKING(for $2) |
| 1347 | |
| 1348 | if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD && |
| 1349 | $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` && |
| 1350 | $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then |
| 1351 | edit_cflags=" |
| 1352 | s,///*,/,g |
| 1353 | s/^/ / |
| 1354 | s/ -I/ $isystem/g |
| 1355 | s/^ // |
| 1356 | " |
| 1357 | $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"` |
| 1358 | $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'` |
| 1359 | AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS']) |
| 1360 | succeeded=yes |
| 1361 | else |
| 1362 | AC_MSG_RESULT(no) |
| 1363 | $1_CFLAGS="" |
| 1364 | $1_LIBS="" |
| 1365 | ## If we have a custom action on failure, don't print errors, but |
| 1366 | ## do set a variable so people can do so. Do it in a subshell |
| 1367 | ## to capture any diagnostics in invoking pkg-config. |
| 1368 | $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1` |
| 1369 | ifelse([$4], ,echo "$$1_PKG_ERRORS",) |
| 1370 | fi |
| 1371 | |
| 1372 | AC_SUBST($1_CFLAGS) |
| 1373 | AC_SUBST($1_LIBS) |
| 1374 | else |
| 1375 | echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer." |
| 1376 | echo "*** See http://www.freedesktop.org/software/pkgconfig" |
| 1377 | fi |
| 1378 | fi |
| 1379 | |
| 1380 | if test $succeeded = yes; then |
| 1381 | ifelse([$3], , :, [$3]) |
| 1382 | else |
| 1383 | ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4]) |
| 1384 | fi |
| 1385 | ]) |
| 1386 | |
| 1387 | HAVE_SOUND=no |
| 1388 | if test "${with_sound}" != "no"; then |
| 1389 | # Sound support for GNU/Linux, the free BSDs, and MinGW. |
| 1390 | AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h], |
| 1391 | have_sound_header=yes, [], [ |
| 1392 | #ifdef __MINGW32__ |
| 1393 | #define WIN32_LEAN_AND_MEAN |
| 1394 | #include <windows.h> |
| 1395 | #endif |
| 1396 | ]) |
| 1397 | test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \ |
| 1398 | AC_MSG_ERROR([OSS sound support requested but not found.]) |
| 1399 | |
| 1400 | if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then |
| 1401 | # Emulation library used on NetBSD. |
| 1402 | AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=) |
| 1403 | test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \ |
| 1404 | AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.]) |
| 1405 | dnl FIXME? If we did find ossaudio, should we set with_sound=bsd-ossaudio? |
| 1406 | dnl Traditionally, we go on to check for alsa too. Does that make sense? |
| 1407 | fi |
| 1408 | AC_SUBST(LIBSOUND) |
| 1409 | |
| 1410 | if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then |
| 1411 | ALSA_REQUIRED=1.0.0 |
| 1412 | ALSA_MODULES="alsa >= $ALSA_REQUIRED" |
| 1413 | PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no) |
| 1414 | if test $HAVE_ALSA = yes; then |
| 1415 | SAVE_CFLAGS="$CFLAGS" |
| 1416 | SAVE_LIBS="$LIBS" |
| 1417 | CFLAGS="$ALSA_CFLAGS $CFLAGS" |
| 1418 | LIBS="$ALSA_LIBS $LIBS" |
| 1419 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])], |
| 1420 | emacs_alsa_normal=yes, |
| 1421 | emacs_alsa_normal=no) |
| 1422 | if test "$emacs_alsa_normal" != yes; then |
| 1423 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]], |
| 1424 | [[snd_lib_error_set_handler (0);]])], |
| 1425 | emacs_alsa_subdir=yes, |
| 1426 | emacs_alsa_subdir=no) |
| 1427 | if test "$emacs_alsa_subdir" != yes; then |
| 1428 | AC_MSG_ERROR([pkg-config found alsa, but it does not compile. See config.log for error messages.]) |
| 1429 | fi |
| 1430 | ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE" |
| 1431 | fi |
| 1432 | |
| 1433 | CFLAGS="$SAVE_CFLAGS" |
| 1434 | LIBS="$SAVE_LIBS" |
| 1435 | LIBSOUND="$LIBSOUND $ALSA_LIBS" |
| 1436 | CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS" |
| 1437 | AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.]) |
| 1438 | elif test "${with_sound}" = "alsa"; then |
| 1439 | AC_MSG_ERROR([ALSA sound support requested but not found.]) |
| 1440 | fi |
| 1441 | fi dnl with_sound = alsa|yes |
| 1442 | |
| 1443 | dnl Define HAVE_SOUND if we have sound support. We know it works and |
| 1444 | dnl compiles only on the specified platforms. For others, it |
| 1445 | dnl probably doesn't make sense to try. |
| 1446 | dnl FIXME So surely we should bypass this whole section if not using |
| 1447 | dnl one of these platforms? |
| 1448 | if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then |
| 1449 | case "$opsys" in |
| 1450 | dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__ |
| 1451 | dnl Adjust the --with-sound help text if you change this. |
| 1452 | gnu-linux|freebsd|netbsd|mingw32) |
| 1453 | AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.]) |
| 1454 | HAVE_SOUND=yes |
| 1455 | ;; |
| 1456 | esac |
| 1457 | fi |
| 1458 | |
| 1459 | AC_SUBST(CFLAGS_SOUND) |
| 1460 | fi |
| 1461 | |
| 1462 | dnl checks for header files |
| 1463 | AC_CHECK_HEADERS_ONCE( |
| 1464 | sys/systeminfo.h |
| 1465 | coff.h pty.h |
| 1466 | sys/resource.h |
| 1467 | sys/utsname.h pwd.h utmp.h util.h) |
| 1468 | |
| 1469 | AC_MSG_CHECKING(if personality LINUX32 can be set) |
| 1470 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])], |
| 1471 | emacs_cv_personality_linux32=yes, |
| 1472 | emacs_cv_personality_linux32=no) |
| 1473 | AC_MSG_RESULT($emacs_cv_personality_linux32) |
| 1474 | |
| 1475 | if test $emacs_cv_personality_linux32 = yes; then |
| 1476 | AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1, |
| 1477 | [Define to 1 if personality LINUX32 can be set.]) |
| 1478 | fi |
| 1479 | |
| 1480 | dnl On Solaris 8 there's a compilation warning for term.h because |
| 1481 | dnl it doesn't define `bool'. |
| 1482 | AC_CHECK_HEADERS(term.h, , , -) |
| 1483 | AC_HEADER_TIME |
| 1484 | AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h> |
| 1485 | ]]) |
| 1486 | if test $ac_cv_have_decl_sys_siglist != yes; then |
| 1487 | # For Tru64, at least: |
| 1488 | AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h> |
| 1489 | ]]) |
| 1490 | fi |
| 1491 | AC_HEADER_SYS_WAIT |
| 1492 | |
| 1493 | AC_CHECK_HEADERS_ONCE(sys/socket.h) |
| 1494 | AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT |
| 1495 | #if HAVE_SYS_SOCKET_H |
| 1496 | #include <sys/socket.h> |
| 1497 | #endif]) |
| 1498 | AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT |
| 1499 | #if HAVE_SYS_SOCKET_H |
| 1500 | #include <sys/socket.h> |
| 1501 | #endif]) |
| 1502 | AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT |
| 1503 | #if HAVE_SYS_SOCKET_H |
| 1504 | #include <sys/socket.h> |
| 1505 | #endif]) |
| 1506 | |
| 1507 | dnl checks for structure members |
| 1508 | AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr, |
| 1509 | struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr, |
| 1510 | struct ifreq.ifr_addr, |
| 1511 | struct ifreq.ifr_addr.sa_len], , , |
| 1512 | [AC_INCLUDES_DEFAULT |
| 1513 | #if HAVE_SYS_SOCKET_H |
| 1514 | #include <sys/socket.h> |
| 1515 | #endif |
| 1516 | #if HAVE_NET_IF_H |
| 1517 | #include <net/if.h> |
| 1518 | #endif]) |
| 1519 | |
| 1520 | dnl Check for endianness. |
| 1521 | dnl AC_C_BIGENDIAN is done by gnulib. |
| 1522 | |
| 1523 | dnl check for Make feature |
| 1524 | dnl AC_PROG_MAKE_SET is done by Automake. |
| 1525 | |
| 1526 | DEPFLAGS= |
| 1527 | MKDEPDIR=":" |
| 1528 | deps_frag=deps.mk |
| 1529 | dnl check for GNU Make if we have GCC and autodepend is on. |
| 1530 | if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then |
| 1531 | AC_MSG_CHECKING([whether we are using GNU Make]) |
| 1532 | HAVE_GNU_MAKE=no |
| 1533 | testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'` |
| 1534 | if test "x$testval" != x; then |
| 1535 | HAVE_GNU_MAKE=yes |
| 1536 | else |
| 1537 | ac_enable_autodepend=no |
| 1538 | fi |
| 1539 | AC_MSG_RESULT([$HAVE_GNU_MAKE]) |
| 1540 | if test $HAVE_GNU_MAKE = yes; then |
| 1541 | AC_MSG_CHECKING([whether gcc understands -MMD -MF]) |
| 1542 | SAVE_CFLAGS="$CFLAGS" |
| 1543 | CFLAGS="$CFLAGS -MMD -MF deps.d -MP" |
| 1544 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no) |
| 1545 | CFLAGS="$SAVE_CFLAGS" |
| 1546 | test -f deps.d || ac_enable_autodepend=no |
| 1547 | rm -rf deps.d |
| 1548 | AC_MSG_RESULT([$ac_enable_autodepend]) |
| 1549 | fi |
| 1550 | if test $ac_enable_autodepend = yes; then |
| 1551 | DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP' |
| 1552 | ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe. |
| 1553 | MKDEPDIR='${MKDIR_P} ${DEPDIR}' |
| 1554 | deps_frag=autodeps.mk |
| 1555 | fi |
| 1556 | fi |
| 1557 | deps_frag=$srcdir/src/$deps_frag |
| 1558 | AC_SUBST(MKDEPDIR) |
| 1559 | AC_SUBST(DEPFLAGS) |
| 1560 | AC_SUBST_FILE(deps_frag) |
| 1561 | |
| 1562 | |
| 1563 | lisp_frag=$srcdir/src/lisp.mk |
| 1564 | AC_SUBST_FILE(lisp_frag) |
| 1565 | |
| 1566 | |
| 1567 | dnl checks for operating system services |
| 1568 | AC_SYS_LONG_FILE_NAMES |
| 1569 | |
| 1570 | #### Choose a window system. |
| 1571 | |
| 1572 | ## We leave window_system equal to none if |
| 1573 | ## we end up building without one. Any new window system should |
| 1574 | ## set window_system to an appropriate value and add objects to |
| 1575 | ## window-system-specific substs. |
| 1576 | |
| 1577 | window_system=none |
| 1578 | AC_PATH_X |
| 1579 | if test "$no_x" != yes; then |
| 1580 | window_system=x11 |
| 1581 | fi |
| 1582 | |
| 1583 | LD_SWITCH_X_SITE_RPATH= |
| 1584 | if test "${x_libraries}" != NONE; then |
| 1585 | if test -n "${x_libraries}"; then |
| 1586 | LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"` |
| 1587 | LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"` |
| 1588 | fi |
| 1589 | x_default_search_path="" |
| 1590 | x_search_path=${x_libraries} |
| 1591 | if test -z "${x_search_path}"; then |
| 1592 | x_search_path=/usr/lib |
| 1593 | fi |
| 1594 | for x_library in `echo ${x_search_path}: | \ |
| 1595 | sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do |
| 1596 | x_search_path="\ |
| 1597 | ${x_library}/X11/%L/%T/%N%C%S:\ |
| 1598 | ${x_library}/X11/%l/%T/%N%C%S:\ |
| 1599 | ${x_library}/X11/%T/%N%C%S:\ |
| 1600 | ${x_library}/X11/%L/%T/%N%S:\ |
| 1601 | ${x_library}/X11/%l/%T/%N%S:\ |
| 1602 | ${x_library}/X11/%T/%N%S" |
| 1603 | if test x"${x_default_search_path}" = x; then |
| 1604 | x_default_search_path=${x_search_path} |
| 1605 | else |
| 1606 | x_default_search_path="${x_search_path}:${x_default_search_path}" |
| 1607 | fi |
| 1608 | done |
| 1609 | fi |
| 1610 | AC_SUBST(LD_SWITCH_X_SITE_RPATH) |
| 1611 | |
| 1612 | if test "${x_includes}" != NONE && test -n "${x_includes}"; then |
| 1613 | C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"` |
| 1614 | fi |
| 1615 | |
| 1616 | if test x"${x_includes}" = x; then |
| 1617 | bitmapdir=/usr/include/X11/bitmaps |
| 1618 | else |
| 1619 | # accumulate include directories that have X11 bitmap subdirectories |
| 1620 | bmd_acc="dummyval" |
| 1621 | for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do |
| 1622 | if test -d "${bmd}/X11/bitmaps"; then |
| 1623 | bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps" |
| 1624 | fi |
| 1625 | if test -d "${bmd}/bitmaps"; then |
| 1626 | bmd_acc="${bmd_acc}:${bmd}/bitmaps" |
| 1627 | fi |
| 1628 | done |
| 1629 | if test ${bmd_acc} != "dummyval"; then |
| 1630 | bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"` |
| 1631 | fi |
| 1632 | fi |
| 1633 | |
| 1634 | HAVE_NS=no |
| 1635 | NS_IMPL_COCOA=no |
| 1636 | NS_IMPL_GNUSTEP=no |
| 1637 | tmp_CPPFLAGS="$CPPFLAGS" |
| 1638 | tmp_CFLAGS="$CFLAGS" |
| 1639 | CPPFLAGS="$CPPFLAGS -x objective-c" |
| 1640 | CFLAGS="$CFLAGS -x objective-c" |
| 1641 | GNU_OBJC_CFLAGS= |
| 1642 | LIBS_GNUSTEP= |
| 1643 | if test "${with_ns}" != no; then |
| 1644 | if test "${opsys}" = darwin; then |
| 1645 | NS_IMPL_COCOA=yes |
| 1646 | ns_appdir=`pwd`/nextstep/Emacs.app |
| 1647 | ns_appbindir=${ns_appdir}/Contents/MacOS |
| 1648 | ns_appresdir=${ns_appdir}/Contents/Resources |
| 1649 | ns_appsrc=Cocoa/Emacs.base |
| 1650 | elif test -f $GNUSTEP_CONFIG_FILE; then |
| 1651 | NS_IMPL_GNUSTEP=yes |
| 1652 | ns_appdir=`pwd`/nextstep/Emacs.app |
| 1653 | ns_appbindir=${ns_appdir} |
| 1654 | ns_appresdir=${ns_appdir}/Resources |
| 1655 | ns_appsrc=GNUstep/Emacs.base |
| 1656 | dnl FIXME sourcing this several times in subshells seems inefficient. |
| 1657 | GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)" |
| 1658 | GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)" |
| 1659 | dnl I seemed to need these as well with GNUstep-startup 0.25. |
| 1660 | GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)" |
| 1661 | GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)" |
| 1662 | test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \ |
| 1663 | GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}" |
| 1664 | test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \ |
| 1665 | GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}" |
| 1666 | CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}" |
| 1667 | CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}" |
| 1668 | LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}" |
| 1669 | LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread" |
| 1670 | dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1. |
| 1671 | dnl If they had chosen to either define it or not, we could have |
| 1672 | dnl just used AC_CHECK_DECL here. |
| 1673 | AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS, |
| 1674 | emacs_cv_objc_exceptions, |
| 1675 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]], |
| 1676 | [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0 |
| 1677 | 1; |
| 1678 | #else |
| 1679 | fail; |
| 1680 | #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) ) |
| 1681 | if test $emacs_cv_objc_exceptions = yes; then |
| 1682 | dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers. |
| 1683 | AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1, |
| 1684 | [Define if GNUstep uses ObjC exceptions.]) |
| 1685 | GNU_OBJC_CFLAGS="-fobjc-exceptions" |
| 1686 | fi |
| 1687 | fi |
| 1688 | |
| 1689 | dnl This is only used while we test the NS headers, it gets reset below. |
| 1690 | CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS" |
| 1691 | |
| 1692 | AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes], |
| 1693 | [AC_MSG_ERROR([`--with-ns' was specified, but the include |
| 1694 | files are missing or cannot be compiled.])]) |
| 1695 | |
| 1696 | macfont_file="" |
| 1697 | if test "${NS_IMPL_COCOA}" = "yes"; then |
| 1698 | AC_MSG_CHECKING([for OSX 10.4 or newer]) |
| 1699 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>], |
| 1700 | [ |
| 1701 | #ifdef MAC_OS_X_VERSION_MAX_ALLOWED |
| 1702 | #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040 |
| 1703 | ; /* OK */ |
| 1704 | #else |
| 1705 | #error "OSX 10.4 or newer required" |
| 1706 | #endif |
| 1707 | #endif |
| 1708 | ])], |
| 1709 | ns_osx_have_104=yes, |
| 1710 | ns_osx_have_104=no) |
| 1711 | AC_MSG_RESULT([$ns_osx_have_104]) |
| 1712 | |
| 1713 | if test $ns_osx_have_104 = no; then |
| 1714 | AC_MSG_ERROR([`OSX 10.4 or newer is required']); |
| 1715 | fi |
| 1716 | AC_MSG_CHECKING([for OSX 10.5 or newer]) |
| 1717 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>], |
| 1718 | [ |
| 1719 | #ifdef MAC_OS_X_VERSION_MAX_ALLOWED |
| 1720 | #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1050 |
| 1721 | ; /* OK */ |
| 1722 | #else |
| 1723 | #error "OSX 10.5 not found" |
| 1724 | #endif |
| 1725 | #endif |
| 1726 | ])], |
| 1727 | ns_osx_have_105=yes, |
| 1728 | ns_osx_have_105=no) |
| 1729 | AC_MSG_RESULT([$ns_osx_have_105]) |
| 1730 | if test $ns_osx_have_105 = yes; then |
| 1731 | macfont_file="macfont.o" |
| 1732 | fi |
| 1733 | fi |
| 1734 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>], |
| 1735 | [NSInteger i;])], |
| 1736 | ns_have_nsinteger=yes, |
| 1737 | ns_have_nsinteger=no) |
| 1738 | if test $ns_have_nsinteger = yes; then |
| 1739 | AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.]) |
| 1740 | fi |
| 1741 | fi |
| 1742 | |
| 1743 | AC_SUBST(LIBS_GNUSTEP) |
| 1744 | |
| 1745 | INSTALL_ARCH_INDEP_EXTRA=install-etc |
| 1746 | ns_self_contained=no |
| 1747 | NS_OBJ= |
| 1748 | NS_OBJC_OBJ= |
| 1749 | if test "${HAVE_NS}" = yes; then |
| 1750 | if test "$with_toolkit_scroll_bars" = "no"; then |
| 1751 | AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.]) |
| 1752 | fi |
| 1753 | |
| 1754 | window_system=nextstep |
| 1755 | # set up packaging dirs |
| 1756 | if test "${EN_NS_SELF_CONTAINED}" = yes; then |
| 1757 | ns_self_contained=yes |
| 1758 | prefix=${ns_appresdir} |
| 1759 | exec_prefix=${ns_appbindir} |
| 1760 | dnl This one isn't really used, only archlibdir is. |
| 1761 | libexecdir="\${ns_appbindir}/libexec" |
| 1762 | archlibdir="\${ns_appbindir}/libexec" |
| 1763 | etcdocdir="\${ns_appresdir}/etc" |
| 1764 | etcdir="\${ns_appresdir}/etc" |
| 1765 | dnl FIXME maybe set datarootdir instead. |
| 1766 | dnl That would also get applications, icons, man. |
| 1767 | infodir="\${ns_appresdir}/info" |
| 1768 | mandir="\${ns_appresdir}/man" |
| 1769 | lispdir="\${ns_appresdir}/lisp" |
| 1770 | INSTALL_ARCH_INDEP_EXTRA= |
| 1771 | fi |
| 1772 | |
| 1773 | NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o $macfont_file" |
| 1774 | fi |
| 1775 | CFLAGS="$tmp_CFLAGS" |
| 1776 | CPPFLAGS="$tmp_CPPFLAGS" |
| 1777 | AC_SUBST(INSTALL_ARCH_INDEP_EXTRA) |
| 1778 | AC_SUBST(ns_self_contained) |
| 1779 | AC_SUBST(NS_OBJ) |
| 1780 | AC_SUBST(NS_OBJC_OBJ) |
| 1781 | |
| 1782 | HAVE_W32=no |
| 1783 | W32_OBJ= |
| 1784 | W32_LIBS= |
| 1785 | EMACSRES= |
| 1786 | CLIENTRES= |
| 1787 | CLIENTW= |
| 1788 | W32_RES_LINK= |
| 1789 | EMACS_MANIFEST= |
| 1790 | UPDATE_MANIFEST= |
| 1791 | if test "${with_w32}" != no; then |
| 1792 | case "${opsys}" in |
| 1793 | cygwin) |
| 1794 | AC_CHECK_HEADER([windows.h], [HAVE_W32=yes], |
| 1795 | [AC_MSG_ERROR([`--with-w32' was specified, but windows.h |
| 1796 | cannot be found.])]) |
| 1797 | ;; |
| 1798 | mingw32) |
| 1799 | ## Using --with-w32 with MinGW is a no-op, but we allow it. |
| 1800 | ;; |
| 1801 | *) |
| 1802 | AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.]) |
| 1803 | ;; |
| 1804 | esac |
| 1805 | fi |
| 1806 | |
| 1807 | if test "${opsys}" = "mingw32"; then |
| 1808 | AC_MSG_CHECKING([whether Windows API headers are recent enough]) |
| 1809 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ |
| 1810 | #include <windows.h> |
| 1811 | #include <usp10.h>]], |
| 1812 | [[PIMAGE_NT_HEADERS pHeader; |
| 1813 | PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])], |
| 1814 | [emacs_cv_w32api=yes |
| 1815 | HAVE_W32=yes], |
| 1816 | emacs_cv_w32api=no) |
| 1817 | AC_MSG_RESULT($emacs_cv_w32api) |
| 1818 | if test "${emacs_cv_w32api}" = "no"; then |
| 1819 | AC_MSG_ERROR([the Windows API headers are too old to support this build.]) |
| 1820 | fi |
| 1821 | fi |
| 1822 | |
| 1823 | FIRSTFILE_OBJ= |
| 1824 | NTDIR= |
| 1825 | LIBS_ECLIENT= |
| 1826 | LIB_WSOCK32= |
| 1827 | NTLIB= |
| 1828 | CM_OBJ="cm.o" |
| 1829 | XARGS_LIMIT= |
| 1830 | if test "${HAVE_W32}" = "yes"; then |
| 1831 | AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.]) |
| 1832 | AC_CHECK_TOOL(WINDRES, [windres], |
| 1833 | [AC_MSG_ERROR([No resource compiler found.])]) |
| 1834 | W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o" |
| 1835 | W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o" |
| 1836 | EMACSRES="emacs.res" |
| 1837 | case "$canonical" in |
| 1838 | x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;; |
| 1839 | *) EMACS_MANIFEST="emacs-x86.manifest" ;; |
| 1840 | esac |
| 1841 | UPDATE_MANIFEST=update-game-score.exe.manifest |
| 1842 | if test "${opsys}" = "cygwin"; then |
| 1843 | W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32" |
| 1844 | W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool" |
| 1845 | # Tell the linker that emacs.res is an object (which we compile from |
| 1846 | # the rc file), not a linker script. |
| 1847 | W32_RES_LINK="-Wl,emacs.res" |
| 1848 | else |
| 1849 | W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o" |
| 1850 | W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32" |
| 1851 | W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10" |
| 1852 | W32_RES_LINK="\$(EMACSRES)" |
| 1853 | CLIENTRES="emacsclient.res" |
| 1854 | CLIENTW="emacsclientw\$(EXEEXT)" |
| 1855 | FIRSTFILE_OBJ=firstfile.o |
| 1856 | NTDIR=nt |
| 1857 | CM_OBJ= |
| 1858 | LIBS_ECLIENT="-lcomctl32" |
| 1859 | LIB_WSOCK32="-lwsock32" |
| 1860 | NTLIB="ntlib.$ac_objext" |
| 1861 | XARGS_LIMIT="-s 10000" |
| 1862 | fi |
| 1863 | fi |
| 1864 | AC_SUBST(W32_OBJ) |
| 1865 | AC_SUBST(W32_LIBS) |
| 1866 | AC_SUBST(EMACSRES) |
| 1867 | AC_SUBST(EMACS_MANIFEST) |
| 1868 | AC_SUBST(UPDATE_MANIFEST) |
| 1869 | AC_SUBST(CLIENTRES) |
| 1870 | AC_SUBST(CLIENTW) |
| 1871 | AC_SUBST(W32_RES_LINK) |
| 1872 | AC_SUBST(FIRSTFILE_OBJ) |
| 1873 | AC_SUBST(NTDIR) |
| 1874 | AC_SUBST(CM_OBJ) |
| 1875 | AC_SUBST(LIBS_ECLIENT) |
| 1876 | AC_SUBST(LIB_WSOCK32) |
| 1877 | AC_SUBST(NTLIB) |
| 1878 | AC_SUBST(XARGS_LIMIT) |
| 1879 | |
| 1880 | if test "${HAVE_W32}" = "yes"; then |
| 1881 | window_system=w32 |
| 1882 | with_xft=no |
| 1883 | fi |
| 1884 | |
| 1885 | ## $window_system is now set to the window system we will |
| 1886 | ## ultimately use. |
| 1887 | |
| 1888 | if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then |
| 1889 | # Too many warnings for now. |
| 1890 | nw= |
| 1891 | nw="$nw -Wsuggest-attribute=const" |
| 1892 | nw="$nw -Wsuggest-attribute=noreturn" |
| 1893 | gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw]) |
| 1894 | |
| 1895 | gl_WARN_ADD([-Wno-unused-variable]) |
| 1896 | gl_WARN_ADD([-Wno-unused-but-set-variable]) |
| 1897 | gl_WARN_ADD([-Wno-unused-but-set-parameter]) |
| 1898 | fi |
| 1899 | |
| 1900 | term_header= |
| 1901 | HAVE_X_WINDOWS=no |
| 1902 | HAVE_X11=no |
| 1903 | USE_X_TOOLKIT=none |
| 1904 | |
| 1905 | case "${window_system}" in |
| 1906 | x11 ) |
| 1907 | HAVE_X_WINDOWS=yes |
| 1908 | HAVE_X11=yes |
| 1909 | term_header=xterm.h |
| 1910 | case "${with_x_toolkit}" in |
| 1911 | athena | lucid ) USE_X_TOOLKIT=LUCID ;; |
| 1912 | motif ) USE_X_TOOLKIT=MOTIF ;; |
| 1913 | gtk ) with_gtk=yes |
| 1914 | term_header=gtkutil.h |
| 1915 | dnl Don't set this for GTK. A lot of tests below assumes Xt when |
| 1916 | dnl USE_X_TOOLKIT is set. |
| 1917 | USE_X_TOOLKIT=none ;; |
| 1918 | gtk2 ) with_gtk2=yes |
| 1919 | term_header=gtkutil.h |
| 1920 | USE_X_TOOLKIT=none ;; |
| 1921 | gtk3 ) with_gtk3=yes |
| 1922 | term_header=gtkutil.h |
| 1923 | USE_X_TOOLKIT=none ;; |
| 1924 | no ) USE_X_TOOLKIT=none ;; |
| 1925 | dnl If user did not say whether to use a toolkit, make this decision later: |
| 1926 | dnl use the toolkit if we have gtk, or X11R5 or newer. |
| 1927 | * ) USE_X_TOOLKIT=maybe ;; |
| 1928 | esac |
| 1929 | ;; |
| 1930 | nextstep ) |
| 1931 | term_header=nsterm.h |
| 1932 | ;; |
| 1933 | w32 ) |
| 1934 | term_header=w32term.h |
| 1935 | ;; |
| 1936 | esac |
| 1937 | |
| 1938 | if test "$window_system" = none && test "X$with_x" != "Xno"; then |
| 1939 | AC_CHECK_PROG(HAVE_XSERVER, X, true, false) |
| 1940 | if test "$HAVE_XSERVER" = true || |
| 1941 | test -n "$DISPLAY" || |
| 1942 | test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then |
| 1943 | AC_MSG_ERROR([You seem to be running X, but no X development libraries |
| 1944 | were found. You should install the relevant development files for X |
| 1945 | and for the toolkit you want, such as Gtk+ or Motif. Also make |
| 1946 | sure you have development files for image handling, i.e. |
| 1947 | tiff, gif, jpeg, png and xpm. |
| 1948 | If you are sure you want Emacs compiled without X window support, pass |
| 1949 | --without-x |
| 1950 | to configure.]) |
| 1951 | fi |
| 1952 | fi |
| 1953 | |
| 1954 | # Does the opsystem file prohibit the use of the GNU malloc? |
| 1955 | # Assume not, until told otherwise. |
| 1956 | GNU_MALLOC=yes |
| 1957 | |
| 1958 | AC_CACHE_CHECK( |
| 1959 | [whether malloc is Doug Lea style], |
| 1960 | [emacs_cv_var_doug_lea_malloc], |
| 1961 | [emacs_cv_var_doug_lea_malloc=no |
| 1962 | dnl Hooks do not work with address sanitization. |
| 1963 | if test "$emacs_cv_sanitize_address" != yes; then |
| 1964 | AC_LINK_IFELSE( |
| 1965 | [AC_LANG_PROGRAM( |
| 1966 | [[#include <malloc.h> |
| 1967 | static void hook (void) {}]], |
| 1968 | [[malloc_set_state (malloc_get_state ()); |
| 1969 | __after_morecore_hook = hook; |
| 1970 | __malloc_initialize_hook = hook;]])], |
| 1971 | [emacs_cv_var_doug_lea_malloc=yes])]) |
| 1972 | fi |
| 1973 | doug_lea_malloc=$emacs_cv_var_doug_lea_malloc |
| 1974 | |
| 1975 | system_malloc=$emacs_cv_sanitize_address |
| 1976 | case "$opsys" in |
| 1977 | ## darwin ld insists on the use of malloc routines in the System framework. |
| 1978 | darwin|sol2-10) system_malloc=yes ;; |
| 1979 | esac |
| 1980 | |
| 1981 | GMALLOC_OBJ= |
| 1982 | if test "${system_malloc}" = "yes"; then |
| 1983 | AC_DEFINE([SYSTEM_MALLOC], 1, |
| 1984 | [Define to 1 to use the system memory allocator, even if it is not |
| 1985 | Doug Lea style.]) |
| 1986 | GNU_MALLOC=no |
| 1987 | GNU_MALLOC_reason=" |
| 1988 | (The GNU allocators don't work with this system configuration.)" |
| 1989 | VMLIMIT_OBJ= |
| 1990 | else |
| 1991 | test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o |
| 1992 | VMLIMIT_OBJ=vm-limit.o |
| 1993 | |
| 1994 | AC_CHECK_HEADERS([sys/vlimit.h]) |
| 1995 | AC_CACHE_CHECK([for data_start], [emacs_cv_data_start], |
| 1996 | [AC_LINK_IFELSE( |
| 1997 | [AC_LANG_PROGRAM( |
| 1998 | [[extern char data_start[]; char ch;]], |
| 1999 | [[return data_start < &ch;]])], |
| 2000 | [emacs_cv_data_start=yes], |
| 2001 | [emacs_cv_data_start=no])]) |
| 2002 | if test $emacs_cv_data_start = yes; then |
| 2003 | AC_DEFINE([HAVE_DATA_START], 1, |
| 2004 | [Define to 1 if data_start is the address of the start |
| 2005 | of the main data segment.]) |
| 2006 | fi |
| 2007 | fi |
| 2008 | AC_SUBST(GMALLOC_OBJ) |
| 2009 | AC_SUBST(VMLIMIT_OBJ) |
| 2010 | |
| 2011 | if test "$doug_lea_malloc" = "yes" ; then |
| 2012 | if test "$GNU_MALLOC" = yes ; then |
| 2013 | GNU_MALLOC_reason=" |
| 2014 | (Using Doug Lea's new malloc from the GNU C Library.)" |
| 2015 | fi |
| 2016 | AC_DEFINE(DOUG_LEA_MALLOC, 1, |
| 2017 | [Define to 1 if the system memory allocator is Doug Lea style, |
| 2018 | with malloc hooks and malloc_set_state.]) |
| 2019 | |
| 2020 | ## Use mmap directly for allocating larger buffers. |
| 2021 | ## FIXME this comes from src/s/{gnu,gnu-linux}.h: |
| 2022 | ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif |
| 2023 | ## Does the AC_FUNC_MMAP test below make this check unnecessary? |
| 2024 | case "$opsys" in |
| 2025 | gnu*) REL_ALLOC=no ;; |
| 2026 | esac |
| 2027 | fi |
| 2028 | |
| 2029 | if test x"${REL_ALLOC}" = x; then |
| 2030 | REL_ALLOC=${GNU_MALLOC} |
| 2031 | fi |
| 2032 | |
| 2033 | use_mmap_for_buffers=no |
| 2034 | case "$opsys" in |
| 2035 | cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;; |
| 2036 | esac |
| 2037 | |
| 2038 | AC_FUNC_MMAP |
| 2039 | if test $use_mmap_for_buffers = yes; then |
| 2040 | AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.]) |
| 2041 | REL_ALLOC=no |
| 2042 | fi |
| 2043 | |
| 2044 | LIBS="$LIBS_SYSTEM $LIBS" |
| 2045 | |
| 2046 | dnl If found, this adds -ldnet to LIBS, which Autoconf uses for checks. |
| 2047 | AC_CHECK_LIB(dnet, dnet_ntoa) |
| 2048 | dnl This causes -lresolv to get used in subsequent tests, |
| 2049 | dnl which causes failures on some systems such as HPUX 9. |
| 2050 | dnl AC_CHECK_LIB(resolv, gethostbyname) |
| 2051 | |
| 2052 | dnl FIXME replace main with a function we actually want from this library. |
| 2053 | AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd") |
| 2054 | |
| 2055 | dnl Check if pthreads is available. |
| 2056 | LIB_PTHREAD= |
| 2057 | AC_CHECK_HEADERS_ONCE(pthread.h) |
| 2058 | if test "$ac_cv_header_pthread_h"; then |
| 2059 | dnl gmalloc.c uses pthread_atfork, which is not available on older-style |
| 2060 | dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely |
| 2061 | dnl testing for pthread_self if Emacs uses gmalloc.c. |
| 2062 | if test "$GMALLOC_OBJ" = gmalloc.o; then |
| 2063 | emacs_pthread_function=pthread_atfork |
| 2064 | else |
| 2065 | emacs_pthread_function=pthread_self |
| 2066 | fi |
| 2067 | AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes) |
| 2068 | fi |
| 2069 | if test "$HAVE_PTHREAD" = yes; then |
| 2070 | case "${canonical}" in |
| 2071 | *-hpux*) ;; |
| 2072 | *) LIB_PTHREAD="-lpthread" |
| 2073 | LIBS="$LIB_PTHREAD $LIBS" ;; |
| 2074 | esac |
| 2075 | AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).]) |
| 2076 | fi |
| 2077 | AC_SUBST([LIB_PTHREAD]) |
| 2078 | |
| 2079 | AC_CHECK_LIB(pthreads, cma_open) |
| 2080 | |
| 2081 | ## Note: when using cpp in s/aix4.2.h, this definition depended on |
| 2082 | ## HAVE_LIBPTHREADS. That was not defined earlier in configure when |
| 2083 | ## the system file was sourced. Hence the value of LIBS_SYSTEM |
| 2084 | ## added to LIBS in configure would never contain the pthreads part, |
| 2085 | ## but the value used in Makefiles might. FIXME? |
| 2086 | ## |
| 2087 | ## -lpthreads seems to be necessary for Xlib in X11R6, and should |
| 2088 | ## be harmless on older versions of X where it happens to exist. |
| 2089 | test "$opsys" = "aix4-2" && \ |
| 2090 | test $ac_cv_lib_pthreads_cma_open = yes && \ |
| 2091 | LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads" |
| 2092 | |
| 2093 | dnl Check for need for bigtoc support on IBM AIX |
| 2094 | |
| 2095 | case ${host_os} in |
| 2096 | aix*) |
| 2097 | AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [ |
| 2098 | case $GCC in |
| 2099 | yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;; |
| 2100 | *) gdb_cv_bigtoc=-bbigtoc ;; |
| 2101 | esac |
| 2102 | |
| 2103 | LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc |
| 2104 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=]) |
| 2105 | ]) |
| 2106 | ;; |
| 2107 | esac |
| 2108 | |
| 2109 | # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets |
| 2110 | # used for the tests that follow. We set them back to REAL_CFLAGS and |
| 2111 | # REAL_CPPFLAGS later on. |
| 2112 | |
| 2113 | REAL_CFLAGS="$CFLAGS" |
| 2114 | REAL_CPPFLAGS="$CPPFLAGS" |
| 2115 | |
| 2116 | if test "${HAVE_X11}" = "yes"; then |
| 2117 | DEFS="$C_SWITCH_X_SITE $DEFS" |
| 2118 | LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE" |
| 2119 | LIBS="-lX11 $LIBS" |
| 2120 | CFLAGS="$C_SWITCH_X_SITE $CFLAGS" |
| 2121 | CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS" |
| 2122 | |
| 2123 | # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests. |
| 2124 | # This is handled by LD_SWITCH_X_SITE_RPATH during the real build, |
| 2125 | # but it's more convenient here to set LD_RUN_PATH since this |
| 2126 | # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH. |
| 2127 | if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then |
| 2128 | LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH |
| 2129 | export LD_RUN_PATH |
| 2130 | fi |
| 2131 | |
| 2132 | if test "${opsys}" = "gnu-linux"; then |
| 2133 | AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link) |
| 2134 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], |
| 2135 | [[XOpenDisplay ("foo");]])], |
| 2136 | [xgnu_linux_first_failure=no], |
| 2137 | [xgnu_linux_first_failure=yes]) |
| 2138 | if test "${xgnu_linux_first_failure}" = "yes"; then |
| 2139 | OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE" |
| 2140 | OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE" |
| 2141 | OLD_CPPFLAGS="$CPPFLAGS" |
| 2142 | OLD_LIBS="$LIBS" |
| 2143 | LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout" |
| 2144 | C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout" |
| 2145 | CPPFLAGS="$CPPFLAGS -b i486-linuxaout" |
| 2146 | LIBS="$LIBS -b i486-linuxaout" |
| 2147 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], |
| 2148 | [[XOpenDisplay ("foo");]])], |
| 2149 | [xgnu_linux_second_failure=no], |
| 2150 | [xgnu_linux_second_failure=yes]) |
| 2151 | if test "${xgnu_linux_second_failure}" = "yes"; then |
| 2152 | # If we get the same failure with -b, there is no use adding -b. |
| 2153 | # So take it out. This plays safe. |
| 2154 | LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE" |
| 2155 | C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE" |
| 2156 | CPPFLAGS="$OLD_CPPFLAGS" |
| 2157 | LIBS="$OLD_LIBS" |
| 2158 | AC_MSG_RESULT(no) |
| 2159 | else |
| 2160 | AC_MSG_RESULT(yes) |
| 2161 | fi |
| 2162 | else |
| 2163 | AC_MSG_RESULT(no) |
| 2164 | fi |
| 2165 | fi |
| 2166 | |
| 2167 | # Reportedly, some broken Solaris systems have XKBlib.h but are missing |
| 2168 | # header files included from there. |
| 2169 | AC_MSG_CHECKING(for Xkb) |
| 2170 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h> |
| 2171 | #include <X11/XKBlib.h>]], |
| 2172 | [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])], |
| 2173 | emacs_xkb=yes, emacs_xkb=no) |
| 2174 | AC_MSG_RESULT($emacs_xkb) |
| 2175 | if test $emacs_xkb = yes; then |
| 2176 | AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.]) |
| 2177 | fi |
| 2178 | |
| 2179 | AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \ |
| 2180 | XScreenNumberOfScreen) |
| 2181 | fi |
| 2182 | |
| 2183 | if test "${window_system}" = "x11"; then |
| 2184 | AC_MSG_CHECKING(X11 version 6) |
| 2185 | AC_CACHE_VAL(emacs_cv_x11_version_6, |
| 2186 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], |
| 2187 | [[#if XlibSpecificationRelease < 6 |
| 2188 | fail; |
| 2189 | #endif |
| 2190 | ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)]) |
| 2191 | if test $emacs_cv_x11_version_6 = yes; then |
| 2192 | AC_MSG_RESULT(6 or newer) |
| 2193 | AC_DEFINE(HAVE_X11R6, 1, |
| 2194 | [Define to 1 if you have the X11R6 or newer version of Xlib.]) |
| 2195 | AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.]) |
| 2196 | ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style |
| 2197 | ## XIM support. |
| 2198 | case "$opsys" in |
| 2199 | sol2-*) : ;; |
| 2200 | *) AC_DEFINE(HAVE_X11R6_XIM, 1, |
| 2201 | [Define if you have usable X11R6-style XIM support.]) |
| 2202 | ;; |
| 2203 | esac |
| 2204 | else |
| 2205 | AC_MSG_RESULT(before 6) |
| 2206 | fi |
| 2207 | fi |
| 2208 | |
| 2209 | |
| 2210 | ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified. |
| 2211 | HAVE_RSVG=no |
| 2212 | if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then |
| 2213 | if test "${with_rsvg}" != "no"; then |
| 2214 | RSVG_REQUIRED=2.11.0 |
| 2215 | RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED" |
| 2216 | |
| 2217 | PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :) |
| 2218 | AC_SUBST(RSVG_CFLAGS) |
| 2219 | AC_SUBST(RSVG_LIBS) |
| 2220 | |
| 2221 | if test $HAVE_RSVG = yes; then |
| 2222 | AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.]) |
| 2223 | CFLAGS="$CFLAGS $RSVG_CFLAGS" |
| 2224 | # Windows loads librsvg dynamically |
| 2225 | if test "${opsys}" = "mingw32"; then |
| 2226 | RSVG_LIBS= |
| 2227 | fi |
| 2228 | LIBS="$RSVG_LIBS $LIBS" |
| 2229 | fi |
| 2230 | fi |
| 2231 | fi |
| 2232 | |
| 2233 | HAVE_IMAGEMAGICK=no |
| 2234 | if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then |
| 2235 | if test "${with_imagemagick}" != "no"; then |
| 2236 | ## 6.2.8 is the earliest version known to work, but earlier versions |
| 2237 | ## might work - let us know if you find one. |
| 2238 | ## 6.0.7 does not work. See bug#7955. |
| 2239 | ## 6.8.2 makes Emacs crash; see Bug#13867. |
| 2240 | IMAGEMAGICK_MODULE="Wand >= 6.2.8 Wand != 6.8.2" |
| 2241 | PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :) |
| 2242 | AC_SUBST(IMAGEMAGICK_CFLAGS) |
| 2243 | AC_SUBST(IMAGEMAGICK_LIBS) |
| 2244 | |
| 2245 | if test $HAVE_IMAGEMAGICK = yes; then |
| 2246 | AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.]) |
| 2247 | CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS" |
| 2248 | LIBS="$IMAGEMAGICK_LIBS $LIBS" |
| 2249 | AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers) |
| 2250 | fi |
| 2251 | fi |
| 2252 | fi |
| 2253 | |
| 2254 | |
| 2255 | HAVE_GTK=no |
| 2256 | GTK_OBJ= |
| 2257 | gtk_term_header=$term_header |
| 2258 | check_gtk2=no |
| 2259 | gtk3_pkg_errors= |
| 2260 | if test "${opsys}" != "mingw32"; then |
| 2261 | if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then |
| 2262 | GLIB_REQUIRED=2.28 |
| 2263 | GTK_REQUIRED=3.0 |
| 2264 | GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED" |
| 2265 | |
| 2266 | dnl Checks for libraries. |
| 2267 | PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no) |
| 2268 | if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then |
| 2269 | AC_MSG_ERROR($GTK_PKG_ERRORS) |
| 2270 | fi |
| 2271 | if test "$pkg_check_gtk" = "yes"; then |
| 2272 | AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.]) |
| 2273 | GTK_OBJ=emacsgtkfixed.o |
| 2274 | gtk_term_header=gtkutil.h |
| 2275 | USE_GTK_TOOLKIT="GTK3" |
| 2276 | if test "x$ac_enable_gtk_deprecation_warnings" = x; then |
| 2277 | AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1], |
| 2278 | [Define to 1 to disable GTK+/GDK deprecation warnings.]) |
| 2279 | AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1], |
| 2280 | [Define to 1 to disable Glib deprecation warnings.]) |
| 2281 | fi |
| 2282 | else |
| 2283 | check_gtk2=yes |
| 2284 | gtk3_pkg_errors="$GTK_PKG_ERRORS " |
| 2285 | fi |
| 2286 | fi |
| 2287 | |
| 2288 | if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then |
| 2289 | GLIB_REQUIRED=2.10 |
| 2290 | GTK_REQUIRED=2.10 |
| 2291 | GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED" |
| 2292 | |
| 2293 | dnl Checks for libraries. |
| 2294 | PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no) |
| 2295 | if test "$pkg_check_gtk" = "no" && |
| 2296 | { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; } |
| 2297 | then |
| 2298 | AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS) |
| 2299 | fi |
| 2300 | test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2" |
| 2301 | fi |
| 2302 | fi |
| 2303 | |
| 2304 | if test x"$pkg_check_gtk" = xyes; then |
| 2305 | |
| 2306 | AC_SUBST(GTK_LIBS) |
| 2307 | C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS" |
| 2308 | CFLAGS="$CFLAGS $GTK_CFLAGS" |
| 2309 | LIBS="$GTK_LIBS $LIBS" |
| 2310 | dnl Try to compile a simple GTK program. |
| 2311 | AC_MSG_CHECKING([whether GTK compiles]) |
| 2312 | GTK_COMPILES=no |
| 2313 | AC_LINK_IFELSE( |
| 2314 | [AC_LANG_PROGRAM( |
| 2315 | [[/* Check the Gtk and Glib APIs. */ |
| 2316 | #include <gtk/gtk.h> |
| 2317 | #include <glib-object.h> |
| 2318 | static void |
| 2319 | callback (GObject *go, GParamSpec *spec, gpointer user_data) |
| 2320 | {} |
| 2321 | ]], |
| 2322 | [[ |
| 2323 | GtkSettings *gs = 0; |
| 2324 | /* Use G_CALLBACK to make sure function pointers can be cast to void *; |
| 2325 | strict C prohibits this. Use gtk_main_iteration to test that the |
| 2326 | libraries are there. */ |
| 2327 | if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC, |
| 2328 | 0, 0, 0, G_CALLBACK (callback), 0)) |
| 2329 | gtk_main_iteration (); |
| 2330 | ]])], |
| 2331 | [GTK_COMPILES=yes]) |
| 2332 | AC_MSG_RESULT([$GTK_COMPILES]) |
| 2333 | if test "${GTK_COMPILES}" != "yes"; then |
| 2334 | GTK_OBJ= |
| 2335 | if test "$USE_X_TOOLKIT" != "maybe"; then |
| 2336 | AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log. Maybe some x11-devel files missing?]); |
| 2337 | fi |
| 2338 | else |
| 2339 | HAVE_GTK=yes |
| 2340 | AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.]) |
| 2341 | GTK_OBJ="gtkutil.o $GTK_OBJ" |
| 2342 | term_header=$gtk_term_header |
| 2343 | USE_X_TOOLKIT=none |
| 2344 | if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then |
| 2345 | : |
| 2346 | else |
| 2347 | AC_MSG_WARN([[Your version of Gtk+ will have problems with |
| 2348 | closing open displays. This is no problem if you just use |
| 2349 | one display, but if you use more than one and close one of them |
| 2350 | Emacs may crash.]]) |
| 2351 | sleep 3 |
| 2352 | fi |
| 2353 | fi |
| 2354 | |
| 2355 | fi |
| 2356 | AC_SUBST(GTK_OBJ) |
| 2357 | |
| 2358 | |
| 2359 | if test "${HAVE_GTK}" = "yes"; then |
| 2360 | |
| 2361 | dnl GTK scrollbars resemble toolkit scrollbars a lot, so to avoid |
| 2362 | dnl a lot if #ifdef:s, say we have toolkit scrollbars. |
| 2363 | if test "$with_toolkit_scroll_bars" != no; then |
| 2364 | with_toolkit_scroll_bars=yes |
| 2365 | fi |
| 2366 | |
| 2367 | dnl Check if we have the old file selection dialog declared and |
| 2368 | dnl in the link library. In 2.x it may be in the library, |
| 2369 | dnl but not declared if deprecated featured has been selected out. |
| 2370 | dnl AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION. |
| 2371 | HAVE_GTK_FILE_SELECTION=no |
| 2372 | AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes, |
| 2373 | HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT |
| 2374 | #include <gtk/gtk.h>]) |
| 2375 | if test "$HAVE_GTK_FILE_SELECTION" = yes; then |
| 2376 | AC_CHECK_FUNCS(gtk_file_selection_new) |
| 2377 | fi |
| 2378 | |
| 2379 | dnl Same as above for gtk_handle_box. |
| 2380 | HAVE_GTK_HANDLE_BOX=no |
| 2381 | AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes, |
| 2382 | HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT |
| 2383 | #include <gtk/gtk.h>]) |
| 2384 | if test "$HAVE_GTK_HANDLE_BOX" = yes; then |
| 2385 | AC_CHECK_FUNCS(gtk_handle_box_new) |
| 2386 | fi |
| 2387 | |
| 2388 | dnl Same as above for gtk_tearoff_menu_item. |
| 2389 | HAVE_GTK_TEAROFF_MENU_ITEM=no |
| 2390 | AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes, |
| 2391 | HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT |
| 2392 | #include <gtk/gtk.h>]) |
| 2393 | if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then |
| 2394 | AC_CHECK_FUNCS(gtk_tearoff_menu_item_new) |
| 2395 | fi |
| 2396 | |
| 2397 | dnl Check for functions introduced in 2.14 and later. |
| 2398 | AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \ |
| 2399 | gtk_dialog_get_action_area gtk_widget_get_sensitive \ |
| 2400 | gtk_widget_get_mapped gtk_adjustment_get_page_size \ |
| 2401 | gtk_orientable_set_orientation \ |
| 2402 | gtk_window_set_has_resize_grip) |
| 2403 | |
| 2404 | term_header=gtkutil.h |
| 2405 | fi |
| 2406 | |
| 2407 | dnl D-Bus has been tested under GNU/Linux only. Must be adapted for |
| 2408 | dnl other platforms. |
| 2409 | HAVE_DBUS=no |
| 2410 | DBUS_OBJ= |
| 2411 | if test "${with_dbus}" = "yes"; then |
| 2412 | PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no) |
| 2413 | if test "$HAVE_DBUS" = yes; then |
| 2414 | LIBS="$LIBS $DBUS_LIBS" |
| 2415 | AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.]) |
| 2416 | dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1. |
| 2417 | dnl dbus_type_is_valid and dbus_validate_* have been introduced in |
| 2418 | dnl D-Bus 1.5.12. |
| 2419 | AC_CHECK_FUNCS(dbus_watch_get_unix_fd \ |
| 2420 | dbus_type_is_valid \ |
| 2421 | dbus_validate_bus_name \ |
| 2422 | dbus_validate_path \ |
| 2423 | dbus_validate_interface \ |
| 2424 | dbus_validate_member) |
| 2425 | DBUS_OBJ=dbusbind.o |
| 2426 | fi |
| 2427 | fi |
| 2428 | AC_SUBST(DBUS_OBJ) |
| 2429 | |
| 2430 | dnl GSettings has been tested under GNU/Linux only. |
| 2431 | HAVE_GSETTINGS=no |
| 2432 | if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then |
| 2433 | PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no) |
| 2434 | if test "$HAVE_GSETTINGS" = "yes"; then |
| 2435 | AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.]) |
| 2436 | SETTINGS_CFLAGS="$GSETTINGS_CFLAGS" |
| 2437 | SETTINGS_LIBS="$GSETTINGS_LIBS" |
| 2438 | fi |
| 2439 | fi |
| 2440 | |
| 2441 | dnl GConf has been tested under GNU/Linux only. |
| 2442 | dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6. |
| 2443 | HAVE_GCONF=no |
| 2444 | if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then |
| 2445 | PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no) |
| 2446 | if test "$HAVE_GCONF" = yes; then |
| 2447 | AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.]) |
| 2448 | dnl Newer GConf doesn't link with g_objects, so this is not defined. |
| 2449 | SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS" |
| 2450 | SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS" |
| 2451 | fi |
| 2452 | fi |
| 2453 | |
| 2454 | if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then |
| 2455 | PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no) |
| 2456 | if test "$HAVE_GOBJECT" = "yes"; then |
| 2457 | SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS" |
| 2458 | SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS" |
| 2459 | fi |
| 2460 | SAVE_CFLAGS="$CFLAGS" |
| 2461 | SAVE_LIBS="$LIBS" |
| 2462 | CFLAGS="$SETTINGS_CFLAGS $CFLAGS" |
| 2463 | LIBS="$SETTINGS_LIBS $LIBS" |
| 2464 | CFLAGS="$SAVE_CFLAGS" |
| 2465 | LIBS="$SAVE_LIBS" |
| 2466 | fi |
| 2467 | AC_SUBST(SETTINGS_CFLAGS) |
| 2468 | AC_SUBST(SETTINGS_LIBS) |
| 2469 | |
| 2470 | |
| 2471 | dnl SELinux is available for GNU/Linux only. |
| 2472 | HAVE_LIBSELINUX=no |
| 2473 | LIBSELINUX_LIBS= |
| 2474 | if test "${with_selinux}" = "yes"; then |
| 2475 | AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no) |
| 2476 | if test "$HAVE_LIBSELINUX" = yes; then |
| 2477 | AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.]) |
| 2478 | LIBSELINUX_LIBS=-lselinux |
| 2479 | fi |
| 2480 | fi |
| 2481 | AC_SUBST(LIBSELINUX_LIBS) |
| 2482 | |
| 2483 | HAVE_GNUTLS=no |
| 2484 | HAVE_GNUTLS3=no |
| 2485 | if test "${with_gnutls}" = "yes" ; then |
| 2486 | PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.0.0], HAVE_GNUTLS3=yes, HAVE_GNUTLS3=no) |
| 2487 | if test "${HAVE_GNUTLS3}" = "yes"; then |
| 2488 | AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.]) |
| 2489 | HAVE_GNUTLS="yes" |
| 2490 | else |
| 2491 | PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no) |
| 2492 | fi |
| 2493 | if test "${HAVE_GNUTLS}" = "yes"; then |
| 2494 | AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.]) |
| 2495 | fi |
| 2496 | |
| 2497 | # Windows loads GnuTLS dynamically |
| 2498 | if test "${opsys}" = "mingw32"; then |
| 2499 | LIBGNUTLS_LIBS= |
| 2500 | else |
| 2501 | CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS" |
| 2502 | LIBS="$LIBGNUTLS_LIBS $LIBS" |
| 2503 | fi |
| 2504 | fi |
| 2505 | |
| 2506 | AC_SUBST(LIBGNUTLS_LIBS) |
| 2507 | AC_SUBST(LIBGNUTLS_CFLAGS) |
| 2508 | |
| 2509 | NOTIFY_OBJ= |
| 2510 | NOTIFY_SUMMARY=no |
| 2511 | |
| 2512 | dnl FIXME? Don't auto-detect on NS, but do allow someone to specify |
| 2513 | dnl a particular library. This doesn't make much sense? |
| 2514 | if test "${with_ns}" = yes && test ${with_file_notification} = yes; then |
| 2515 | with_file_notification=no |
| 2516 | fi |
| 2517 | |
| 2518 | dnl MS Windows native file monitor is available for mingw32 only. |
| 2519 | case $with_file_notification,$opsys in |
| 2520 | w32,* | yes,mingw32) |
| 2521 | AC_CHECK_HEADER(windows.h) |
| 2522 | if test "$ac_cv_header_windows_h" = yes ; then |
| 2523 | AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.]) |
| 2524 | NOTIFY_OBJ=w32notify.o |
| 2525 | NOTIFY_SUMMARY="yes (w32)" |
| 2526 | fi ;; |
| 2527 | esac |
| 2528 | |
| 2529 | dnl g_file_monitor exists since glib 2.18. G_FILE_MONITOR_EVENT_MOVED |
| 2530 | dnl has been added in glib 2.24. It has been tested under |
| 2531 | dnl GNU/Linux only. We take precedence over inotify, but this makes |
| 2532 | dnl only sense when glib has been compiled with inotify support. How |
| 2533 | dnl to check? |
| 2534 | case $with_file_notification,$NOTIFY_OBJ in |
| 2535 | gfile, | yes,) |
| 2536 | PKG_CHECK_MODULES(GFILENOTIFY, gio-2.0 >= 2.24, HAVE_GFILENOTIFY=yes, HAVE_GFILENOTIFY=no) |
| 2537 | if test "$HAVE_GFILENOTIFY" = "yes"; then |
| 2538 | AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.]) |
| 2539 | NOTIFY_OBJ=gfilenotify.o |
| 2540 | NOTIFY_SUMMARY="yes -lgio (gfile)" |
| 2541 | fi ;; |
| 2542 | esac |
| 2543 | |
| 2544 | dnl inotify is only available on GNU/Linux. |
| 2545 | case $with_file_notification,$NOTIFY_OBJ in |
| 2546 | inotify, | yes,) |
| 2547 | AC_CHECK_HEADER(sys/inotify.h) |
| 2548 | if test "$ac_cv_header_sys_inotify_h" = yes ; then |
| 2549 | AC_CHECK_FUNC(inotify_init1) |
| 2550 | if test "$ac_cv_func_inotify_init1" = yes; then |
| 2551 | AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.]) |
| 2552 | NOTIFY_OBJ=inotify.o |
| 2553 | NOTIFY_SUMMARY="yes -lglibc (inotify)" |
| 2554 | fi |
| 2555 | fi ;; |
| 2556 | esac |
| 2557 | |
| 2558 | case $with_file_notification,$NOTIFY_OBJ in |
| 2559 | yes,* | no,* | *,?*) ;; |
| 2560 | *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;; |
| 2561 | esac |
| 2562 | |
| 2563 | if test -n "$NOTIFY_OBJ"; then |
| 2564 | AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.]) |
| 2565 | fi |
| 2566 | AC_SUBST(NOTIFY_OBJ) |
| 2567 | AC_SUBST(GFILENOTIFY_CFLAGS) |
| 2568 | AC_SUBST(GFILENOTIFY_LIBS) |
| 2569 | |
| 2570 | dnl Do not put whitespace before the #include statements below. |
| 2571 | dnl Older compilers (eg sunos4 cc) choke on it. |
| 2572 | HAVE_XAW3D=no |
| 2573 | LUCID_LIBW= |
| 2574 | if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then |
| 2575 | if test "$with_xaw3d" != no; then |
| 2576 | AC_CACHE_VAL(emacs_cv_xaw3d, |
| 2577 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[ |
| 2578 | #include <X11/Intrinsic.h> |
| 2579 | #include <X11/Xaw3d/Simple.h>]], |
| 2580 | [[]])], |
| 2581 | [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, |
| 2582 | emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)], |
| 2583 | emacs_cv_xaw3d=no)]) |
| 2584 | else |
| 2585 | emacs_cv_xaw3d=no |
| 2586 | fi |
| 2587 | if test $emacs_cv_xaw3d = yes; then |
| 2588 | AC_MSG_CHECKING(for xaw3d) |
| 2589 | AC_MSG_RESULT([yes; using Lucid toolkit]) |
| 2590 | USE_X_TOOLKIT=LUCID |
| 2591 | HAVE_XAW3D=yes |
| 2592 | LUCID_LIBW=-lXaw3d |
| 2593 | AC_DEFINE(HAVE_XAW3D, 1, |
| 2594 | [Define to 1 if you have the Xaw3d library (-lXaw3d).]) |
| 2595 | else |
| 2596 | AC_MSG_CHECKING(for xaw3d) |
| 2597 | AC_MSG_RESULT(no) |
| 2598 | AC_MSG_CHECKING(for libXaw) |
| 2599 | AC_CACHE_VAL(emacs_cv_xaw, |
| 2600 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[ |
| 2601 | #include <X11/Intrinsic.h> |
| 2602 | #include <X11/Xaw/Simple.h>]], |
| 2603 | [[]])], |
| 2604 | emacs_cv_xaw=yes, |
| 2605 | emacs_cv_xaw=no)]) |
| 2606 | if test $emacs_cv_xaw = yes; then |
| 2607 | AC_MSG_RESULT([yes; using Lucid toolkit]) |
| 2608 | USE_X_TOOLKIT=LUCID |
| 2609 | LUCID_LIBW=-lXaw |
| 2610 | elif test x"${USE_X_TOOLKIT}" = xLUCID; then |
| 2611 | AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files]) |
| 2612 | else |
| 2613 | AC_MSG_ERROR([No X toolkit could be found. |
| 2614 | If you are sure you want Emacs compiled without an X toolkit, pass |
| 2615 | --with-x-toolkit=no |
| 2616 | to configure. Otherwise, install the development libraries for the toolkit |
| 2617 | that you want to use (e.g. Gtk+) and re-run configure.]) |
| 2618 | fi |
| 2619 | fi |
| 2620 | fi |
| 2621 | |
| 2622 | X_TOOLKIT_TYPE=$USE_X_TOOLKIT |
| 2623 | |
| 2624 | LIBXTR6= |
| 2625 | if test "${USE_X_TOOLKIT}" != "none"; then |
| 2626 | AC_MSG_CHECKING(X11 toolkit version) |
| 2627 | AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6, |
| 2628 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]], |
| 2629 | [[#if XtSpecificationRelease < 6 |
| 2630 | fail; |
| 2631 | #endif |
| 2632 | ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)]) |
| 2633 | HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6 |
| 2634 | if test $emacs_cv_x11_toolkit_version_6 = yes; then |
| 2635 | AC_MSG_RESULT(6 or newer) |
| 2636 | AC_DEFINE(HAVE_X11XTR6, 1, |
| 2637 | [Define to 1 if you have the X11R6 or newer version of Xt.]) |
| 2638 | LIBXTR6="-lSM -lICE" |
| 2639 | case "$opsys" in |
| 2640 | ## Use libw.a along with X11R6 Xt. |
| 2641 | unixware) LIBXTR6="$LIBXTR6 -lw" ;; |
| 2642 | esac |
| 2643 | else |
| 2644 | AC_MSG_RESULT(before 6) |
| 2645 | fi |
| 2646 | |
| 2647 | dnl If using toolkit, check whether libXmu.a exists. |
| 2648 | dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link. |
| 2649 | OLDLIBS="$LIBS" |
| 2650 | if test x$HAVE_X11XTR6 = xyes; then |
| 2651 | LIBS="-lXt -lSM -lICE $LIBS" |
| 2652 | else |
| 2653 | LIBS="-lXt $LIBS" |
| 2654 | fi |
| 2655 | AC_CHECK_LIB(Xmu, XmuConvertStandardSelection) |
| 2656 | test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS" |
| 2657 | dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below. |
| 2658 | fi |
| 2659 | AC_SUBST(LIBXTR6) |
| 2660 | |
| 2661 | dnl FIXME the logic here seems weird, but this is what cpp was doing. |
| 2662 | dnl Why not just test for libxmu in the normal way? |
| 2663 | LIBXMU=-lXmu |
| 2664 | case $opsys in |
| 2665 | ## These systems don't supply Xmu. |
| 2666 | hpux* | aix4-2 ) |
| 2667 | test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU= |
| 2668 | ;; |
| 2669 | mingw32 ) |
| 2670 | LIBXMU= |
| 2671 | ;; |
| 2672 | esac |
| 2673 | AC_SUBST(LIBXMU) |
| 2674 | |
| 2675 | # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D. |
| 2676 | if test "${HAVE_X11}" = "yes"; then |
| 2677 | if test "${USE_X_TOOLKIT}" != "none"; then |
| 2678 | AC_CHECK_LIB(Xext, XShapeQueryExtension) |
| 2679 | fi |
| 2680 | fi |
| 2681 | |
| 2682 | LIBXP= |
| 2683 | if test "${USE_X_TOOLKIT}" = "MOTIF"; then |
| 2684 | # OpenMotif may be installed in such a way on some GNU/Linux systems. |
| 2685 | if test -d /usr/include/openmotif; then |
| 2686 | CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS" |
| 2687 | emacs_cv_openmotif=yes |
| 2688 | case "$canonical" in |
| 2689 | x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) |
| 2690 | test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS" |
| 2691 | ;; |
| 2692 | *) |
| 2693 | test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS" |
| 2694 | esac |
| 2695 | else |
| 2696 | emacs_cv_openmotif=no |
| 2697 | fi |
| 2698 | AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1, |
| 2699 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]], |
| 2700 | [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1) |
| 2701 | int x = 5; |
| 2702 | #else |
| 2703 | Motif version prior to 2.1. |
| 2704 | #endif]])], |
| 2705 | emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)]) |
| 2706 | if test $emacs_cv_motif_version_2_1 = yes; then |
| 2707 | AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp) |
| 2708 | if test x$emacs_cv_openmotif = xyes; then |
| 2709 | REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS" |
| 2710 | fi |
| 2711 | else |
| 2712 | AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif, |
| 2713 | # We put this in CFLAGS temporarily to precede other -I options |
| 2714 | # that might be in CFLAGS temporarily. |
| 2715 | # We put this in CPPFLAGS where it precedes the other -I options. |
| 2716 | OLD_CPPFLAGS=$CPPFLAGS |
| 2717 | OLD_CFLAGS=$CFLAGS |
| 2718 | CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS" |
| 2719 | CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS" |
| 2720 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]], |
| 2721 | [[int x = 5;]])], |
| 2722 | emacs_cv_lesstif=yes, emacs_cv_lesstif=no)]) |
| 2723 | if test $emacs_cv_lesstif = yes; then |
| 2724 | # Make sure this -I option remains in CPPFLAGS after it is set |
| 2725 | # back to REAL_CPPFLAGS. |
| 2726 | # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not |
| 2727 | # have those other -I options anyway. Ultimately, having this |
| 2728 | # directory ultimately in CPPFLAGS will be enough. |
| 2729 | REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS" |
| 2730 | LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS" |
| 2731 | else |
| 2732 | CFLAGS=$OLD_CFLAGS |
| 2733 | CPPFLAGS=$OLD_CPPFLAGS |
| 2734 | fi |
| 2735 | fi |
| 2736 | AC_CHECK_HEADER([Xm/BulletinB.h], [], |
| 2737 | [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])]) |
| 2738 | fi |
| 2739 | |
| 2740 | dnl Use toolkit scroll bars if configured for GTK or X toolkit and either |
| 2741 | dnl using Motif or Xaw3d is available, and unless |
| 2742 | dnl --with-toolkit-scroll-bars=no was specified. |
| 2743 | |
| 2744 | AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS, |
| 2745 | [Define to 1 if we should use toolkit scroll bars.])dnl |
| 2746 | USE_TOOLKIT_SCROLL_BARS=no |
| 2747 | if test "${with_toolkit_scroll_bars}" != "no"; then |
| 2748 | if test "${USE_X_TOOLKIT}" != "none"; then |
| 2749 | if test "${USE_X_TOOLKIT}" = "MOTIF"; then |
| 2750 | AC_DEFINE(USE_TOOLKIT_SCROLL_BARS) |
| 2751 | HAVE_XAW3D=no |
| 2752 | USE_TOOLKIT_SCROLL_BARS=yes |
| 2753 | elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then |
| 2754 | AC_DEFINE(USE_TOOLKIT_SCROLL_BARS) |
| 2755 | USE_TOOLKIT_SCROLL_BARS=yes |
| 2756 | fi |
| 2757 | elif test "${HAVE_GTK}" = "yes"; then |
| 2758 | AC_DEFINE(USE_TOOLKIT_SCROLL_BARS) |
| 2759 | USE_TOOLKIT_SCROLL_BARS=yes |
| 2760 | elif test "${HAVE_NS}" = "yes"; then |
| 2761 | AC_DEFINE(USE_TOOLKIT_SCROLL_BARS) |
| 2762 | USE_TOOLKIT_SCROLL_BARS=yes |
| 2763 | elif test "${HAVE_W32}" = "yes"; then |
| 2764 | AC_DEFINE(USE_TOOLKIT_SCROLL_BARS) |
| 2765 | USE_TOOLKIT_SCROLL_BARS=yes |
| 2766 | fi |
| 2767 | fi |
| 2768 | |
| 2769 | dnl See if XIM is available. |
| 2770 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ |
| 2771 | #include <X11/Xlib.h> |
| 2772 | #include <X11/Xresource.h>]], |
| 2773 | [[XIMProc callback;]])], |
| 2774 | [HAVE_XIM=yes |
| 2775 | AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])], |
| 2776 | HAVE_XIM=no) |
| 2777 | |
| 2778 | dnl `--with-xim' now controls only the initial value of use_xim at run time. |
| 2779 | |
| 2780 | if test "${with_xim}" != "no"; then |
| 2781 | AC_DEFINE(USE_XIM, 1, |
| 2782 | [Define to 1 if we should use XIM, if it is available.]) |
| 2783 | fi |
| 2784 | |
| 2785 | |
| 2786 | if test "${HAVE_XIM}" != "no"; then |
| 2787 | late_CFLAGS=$CFLAGS |
| 2788 | if test "$GCC" = yes; then |
| 2789 | CFLAGS="$CFLAGS --pedantic-errors" |
| 2790 | fi |
| 2791 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ |
| 2792 | #include <X11/Xlib.h> |
| 2793 | #include <X11/Xresource.h>]], |
| 2794 | [[Display *display; |
| 2795 | XrmDatabase db; |
| 2796 | char *res_name; |
| 2797 | char *res_class; |
| 2798 | XIMProc callback; |
| 2799 | XPointer *client_data; |
| 2800 | #ifndef __GNUC__ |
| 2801 | /* If we're not using GCC, it's probably not XFree86, and this is |
| 2802 | probably right, but we can't use something like --pedantic-errors. */ |
| 2803 | extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*, |
| 2804 | char*, XIMProc, XPointer*); |
| 2805 | #endif |
| 2806 | (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback, |
| 2807 | client_data);]])], |
| 2808 | [emacs_cv_arg6_star=yes]) |
| 2809 | AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6, |
| 2810 | [Define to the type of the 6th arg of XRegisterIMInstantiateCallback, |
| 2811 | either XPointer or XPointer*.])dnl |
| 2812 | if test "$emacs_cv_arg6_star" = yes; then |
| 2813 | AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*]) |
| 2814 | else |
| 2815 | AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer]) |
| 2816 | fi |
| 2817 | CFLAGS=$late_CFLAGS |
| 2818 | fi |
| 2819 | |
| 2820 | ### Start of font-backend (under any platform) section. |
| 2821 | # (nothing here yet -- this is a placeholder) |
| 2822 | ### End of font-backend (under any platform) section. |
| 2823 | |
| 2824 | ### Start of font-backend (under X11) section. |
| 2825 | if test "${HAVE_X11}" = "yes"; then |
| 2826 | PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no) |
| 2827 | |
| 2828 | ## Use -lXft if available, unless `--with-xft=no'. |
| 2829 | HAVE_XFT=maybe |
| 2830 | if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then |
| 2831 | with_xft="no"; |
| 2832 | fi |
| 2833 | if test "x${with_xft}" != "xno"; then |
| 2834 | |
| 2835 | PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no) |
| 2836 | ## Because xftfont.c uses XRenderQueryExtension, we also |
| 2837 | ## need to link to -lXrender. |
| 2838 | HAVE_XRENDER=no |
| 2839 | AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes) |
| 2840 | if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then |
| 2841 | OLD_CPPFLAGS="$CPPFLAGS" |
| 2842 | OLD_CFLAGS="$CFLAGS" |
| 2843 | OLD_LIBS="$LIBS" |
| 2844 | CPPFLAGS="$CPPFLAGS $XFT_CFLAGS" |
| 2845 | CFLAGS="$CFLAGS $XFT_CFLAGS" |
| 2846 | XFT_LIBS="-lXrender $XFT_LIBS" |
| 2847 | LIBS="$XFT_LIBS $LIBS" |
| 2848 | AC_CHECK_HEADER(X11/Xft/Xft.h, |
| 2849 | AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , , |
| 2850 | [[#include <X11/X.h>]]) |
| 2851 | |
| 2852 | if test "${HAVE_XFT}" = "yes"; then |
| 2853 | AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.]) |
| 2854 | AC_SUBST(XFT_LIBS) |
| 2855 | C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS" |
| 2856 | else |
| 2857 | CPPFLAGS="$OLD_CPPFLAGS" |
| 2858 | CFLAGS="$OLD_CFLAGS" |
| 2859 | LIBS="$OLD_LIBS" |
| 2860 | fi # "${HAVE_XFT}" = "yes" |
| 2861 | fi # "$HAVE_XFT" != no |
| 2862 | fi # "x${with_xft}" != "xno" |
| 2863 | |
| 2864 | ## We used to allow building with FreeType and without Xft. |
| 2865 | ## However, the ftx font backend driver is not in good shape. |
| 2866 | if test "$HAVE_XFT" != "yes"; then |
| 2867 | dnl For the "Does Emacs use" message at the end. |
| 2868 | HAVE_XFT=no |
| 2869 | HAVE_FREETYPE=no |
| 2870 | else |
| 2871 | dnl Strict linkers fail with |
| 2872 | dnl ftfont.o: undefined reference to symbol 'FT_New_Face' |
| 2873 | dnl if -lfreetype is not specified. |
| 2874 | dnl The following is needed to set FREETYPE_LIBS. |
| 2875 | PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, |
| 2876 | HAVE_FREETYPE=no) |
| 2877 | |
| 2878 | test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype) |
| 2879 | fi |
| 2880 | |
| 2881 | HAVE_LIBOTF=no |
| 2882 | if test "${HAVE_FREETYPE}" = "yes"; then |
| 2883 | AC_DEFINE(HAVE_FREETYPE, 1, |
| 2884 | [Define to 1 if using the freetype and fontconfig libraries.]) |
| 2885 | if test "${with_libotf}" != "no"; then |
| 2886 | PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes, |
| 2887 | HAVE_LIBOTF=no) |
| 2888 | if test "$HAVE_LIBOTF" = "yes"; then |
| 2889 | AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.]) |
| 2890 | AC_CHECK_LIB(otf, OTF_get_variation_glyphs, |
| 2891 | HAVE_OTF_GET_VARIATION_GLYPHS=yes, |
| 2892 | HAVE_OTF_GET_VARIATION_GLYPHS=no) |
| 2893 | if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then |
| 2894 | AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1, |
| 2895 | [Define to 1 if libotf has OTF_get_variation_glyphs.]) |
| 2896 | fi |
| 2897 | fi |
| 2898 | fi |
| 2899 | dnl FIXME should there be an error if HAVE_FREETYPE != yes? |
| 2900 | dnl Does the new font backend require it, or can it work without it? |
| 2901 | fi |
| 2902 | |
| 2903 | HAVE_M17N_FLT=no |
| 2904 | if test "${HAVE_LIBOTF}" = yes; then |
| 2905 | if test "${with_m17n_flt}" != "no"; then |
| 2906 | PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no) |
| 2907 | if test "$HAVE_M17N_FLT" = "yes"; then |
| 2908 | AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.]) |
| 2909 | fi |
| 2910 | fi |
| 2911 | fi |
| 2912 | else |
| 2913 | HAVE_XFT=no |
| 2914 | HAVE_FREETYPE=no |
| 2915 | HAVE_LIBOTF=no |
| 2916 | HAVE_M17N_FLT=no |
| 2917 | fi |
| 2918 | |
| 2919 | ### End of font-backend (under X11) section. |
| 2920 | |
| 2921 | AC_SUBST(FREETYPE_CFLAGS) |
| 2922 | AC_SUBST(FREETYPE_LIBS) |
| 2923 | AC_SUBST(FONTCONFIG_CFLAGS) |
| 2924 | AC_SUBST(FONTCONFIG_LIBS) |
| 2925 | AC_SUBST(LIBOTF_CFLAGS) |
| 2926 | AC_SUBST(LIBOTF_LIBS) |
| 2927 | AC_SUBST(M17N_FLT_CFLAGS) |
| 2928 | AC_SUBST(M17N_FLT_LIBS) |
| 2929 | |
| 2930 | ### Use -lXpm if available, unless `--with-xpm=no'. |
| 2931 | ### mingw32 doesn't use -lXpm, since it loads the library dynamically. |
| 2932 | HAVE_XPM=no |
| 2933 | LIBXPM= |
| 2934 | if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then |
| 2935 | if test "${with_xpm}" != "no"; then |
| 2936 | SAVE_CPPFLAGS="$CPPFLAGS" |
| 2937 | SAVE_LDFLAGS="$LDFLAGS" |
| 2938 | CPPFLAGS="$CPPFLAGS -I/usr/include/noX" |
| 2939 | LDFLAGS="$LDFLAGS -L/usr/lib/noX" |
| 2940 | AC_CHECK_HEADER(X11/xpm.h, |
| 2941 | [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)]) |
| 2942 | if test "${HAVE_XPM}" = "yes"; then |
| 2943 | AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define) |
| 2944 | AC_EGREP_CPP(no_return_alloc_pixels, |
| 2945 | [#include "X11/xpm.h" |
| 2946 | #ifndef XpmReturnAllocPixels |
| 2947 | no_return_alloc_pixels |
| 2948 | #endif |
| 2949 | ], HAVE_XPM=no, HAVE_XPM=yes) |
| 2950 | |
| 2951 | if test "${HAVE_XPM}" = "yes"; then |
| 2952 | REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX" |
| 2953 | AC_MSG_RESULT(yes) |
| 2954 | else |
| 2955 | AC_MSG_RESULT(no) |
| 2956 | CPPFLAGS="$SAVE_CPPFLAGS" |
| 2957 | LDFLAGS="$SAVE_LDFLAGS" |
| 2958 | fi |
| 2959 | fi |
| 2960 | fi |
| 2961 | |
| 2962 | if test "${HAVE_XPM}" = "yes"; then |
| 2963 | AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).]) |
| 2964 | LIBXPM=-lXpm |
| 2965 | fi |
| 2966 | fi |
| 2967 | |
| 2968 | if test "${HAVE_X11}" = "yes"; then |
| 2969 | if test "${with_xpm}" != "no"; then |
| 2970 | AC_CHECK_HEADER(X11/xpm.h, |
| 2971 | [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)]) |
| 2972 | if test "${HAVE_XPM}" = "yes"; then |
| 2973 | AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define) |
| 2974 | AC_EGREP_CPP(no_return_alloc_pixels, |
| 2975 | [#include "X11/xpm.h" |
| 2976 | #ifndef XpmReturnAllocPixels |
| 2977 | no_return_alloc_pixels |
| 2978 | #endif |
| 2979 | ], HAVE_XPM=no, HAVE_XPM=yes) |
| 2980 | |
| 2981 | if test "${HAVE_XPM}" = "yes"; then |
| 2982 | AC_MSG_RESULT(yes) |
| 2983 | else |
| 2984 | AC_MSG_RESULT(no) |
| 2985 | fi |
| 2986 | fi |
| 2987 | fi |
| 2988 | |
| 2989 | if test "${HAVE_XPM}" = "yes"; then |
| 2990 | AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).]) |
| 2991 | LIBXPM=-lXpm |
| 2992 | fi |
| 2993 | fi |
| 2994 | |
| 2995 | ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's |
| 2996 | ### slightly different requirements wrt image libraries (it doesn't |
| 2997 | ### use -lXpm because it loads the xpm shared library dynamically at |
| 2998 | ### run time). |
| 2999 | if test "${opsys}" = "mingw32"; then |
| 3000 | if test "${with_xpm}" != "no"; then |
| 3001 | AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [ |
| 3002 | #define FOR_MSW 1]) |
| 3003 | fi |
| 3004 | |
| 3005 | if test "${HAVE_XPM}" = "yes"; then |
| 3006 | AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).]) |
| 3007 | fi |
| 3008 | fi |
| 3009 | |
| 3010 | AC_SUBST(LIBXPM) |
| 3011 | |
| 3012 | ### Use -ljpeg if available, unless `--with-jpeg=no'. |
| 3013 | ### mingw32 doesn't use -ljpeg, since it loads the library dynamically. |
| 3014 | HAVE_JPEG=no |
| 3015 | LIBJPEG= |
| 3016 | if test "${opsys}" = "mingw32"; then |
| 3017 | if test "${with_jpeg}" != "no"; then |
| 3018 | dnl Checking for jpeglib.h can lose because of a redefinition of |
| 3019 | dnl HAVE_STDLIB_H. |
| 3020 | AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no) |
| 3021 | fi |
| 3022 | AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl |
| 3023 | if test "${HAVE_JPEG}" = "yes"; then |
| 3024 | AC_DEFINE(HAVE_JPEG) |
| 3025 | AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])], |
| 3026 | [#include <jpeglib.h> |
| 3027 | version=JPEG_LIB_VERSION |
| 3028 | ], |
| 3029 | [AC_DEFINE(HAVE_JPEG)], |
| 3030 | [AC_MSG_WARN([libjpeg found, but not version 6b or later]) |
| 3031 | HAVE_JPEG=no]) |
| 3032 | fi |
| 3033 | elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then |
| 3034 | if test "${with_jpeg}" != "no"; then |
| 3035 | dnl Checking for jpeglib.h can lose because of a redefinition of |
| 3036 | dnl HAVE_STDLIB_H. |
| 3037 | AC_CHECK_HEADER(jerror.h, |
| 3038 | [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)]) |
| 3039 | fi |
| 3040 | |
| 3041 | AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl |
| 3042 | if test "${HAVE_JPEG}" = "yes"; then |
| 3043 | AC_DEFINE(HAVE_JPEG) |
| 3044 | AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])], |
| 3045 | [#include <jpeglib.h> |
| 3046 | version=JPEG_LIB_VERSION |
| 3047 | ], |
| 3048 | [AC_DEFINE(HAVE_JPEG)], |
| 3049 | [AC_MSG_WARN([libjpeg found, but not version 6b or later]) |
| 3050 | HAVE_JPEG=no]) |
| 3051 | fi |
| 3052 | if test "${HAVE_JPEG}" = "yes"; then |
| 3053 | LIBJPEG=-ljpeg |
| 3054 | fi |
| 3055 | fi |
| 3056 | AC_SUBST(LIBJPEG) |
| 3057 | |
| 3058 | ### Use -lpng if available, unless `--with-png=no'. |
| 3059 | ### mingw32 doesn't use -lpng, since it loads the library dynamically. |
| 3060 | HAVE_PNG=no |
| 3061 | LIBPNG= |
| 3062 | if test "${opsys}" = "mingw32"; then |
| 3063 | if test "${with_png}" != "no"; then |
| 3064 | AC_CHECK_HEADER(png.h, HAVE_PNG=yes, HAVE_PNG=no) |
| 3065 | fi |
| 3066 | if test "${HAVE_PNG}" = "yes"; then |
| 3067 | AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).]) |
| 3068 | |
| 3069 | AC_CHECK_DECL(png_longjmp, |
| 3070 | [], |
| 3071 | [AC_DEFINE(PNG_DEPSTRUCT, [], |
| 3072 | [Define to empty to suppress deprecation warnings when building |
| 3073 | with --enable-gcc-warnings and with libpng versions before 1.5, |
| 3074 | which lack png_longjmp.])], |
| 3075 | [[#ifdef HAVE_LIBPNG_PNG_H |
| 3076 | # include <libpng/png.h> |
| 3077 | #else |
| 3078 | # include <png.h> |
| 3079 | #endif |
| 3080 | ]]) |
| 3081 | fi |
| 3082 | elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then |
| 3083 | if test "${with_png}" != "no"; then |
| 3084 | # Debian unstable as of July 2003 has multiple libpngs, and puts png.h |
| 3085 | # in /usr/include/libpng. |
| 3086 | AC_CHECK_HEADERS(png.h libpng/png.h, break) |
| 3087 | if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then |
| 3088 | AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm) |
| 3089 | fi |
| 3090 | fi |
| 3091 | |
| 3092 | if test "${HAVE_PNG}" = "yes"; then |
| 3093 | AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).]) |
| 3094 | LIBPNG="-lpng -lz -lm" |
| 3095 | |
| 3096 | AC_CHECK_DECL(png_longjmp, |
| 3097 | [], |
| 3098 | [AC_DEFINE(PNG_DEPSTRUCT, [], |
| 3099 | [Define to empty to suppress deprecation warnings when building |
| 3100 | with --enable-gcc-warnings and with libpng versions before 1.5, |
| 3101 | which lack png_longjmp.])], |
| 3102 | [[#ifdef HAVE_LIBPNG_PNG_H |
| 3103 | # include <libpng/png.h> |
| 3104 | #else |
| 3105 | # include <png.h> |
| 3106 | #endif |
| 3107 | ]]) |
| 3108 | fi |
| 3109 | fi |
| 3110 | AC_SUBST(LIBPNG) |
| 3111 | |
| 3112 | HAVE_ZLIB=no |
| 3113 | LIBZ= |
| 3114 | if test "${with_zlib}" != "no"; then |
| 3115 | OLIBS=$LIBS |
| 3116 | AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes]) |
| 3117 | LIBS=$OLIBS |
| 3118 | case $ac_cv_search_inflateEnd in |
| 3119 | -*) LIBZ=$ac_cv_search_inflateEnd ;; |
| 3120 | esac |
| 3121 | fi |
| 3122 | if test "${HAVE_ZLIB}" = "yes"; then |
| 3123 | AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).]) |
| 3124 | ### mingw32 doesn't use -lz, since it loads the library dynamically. |
| 3125 | if test "${opsys}" = "mingw32"; then |
| 3126 | LIBZ= |
| 3127 | fi |
| 3128 | fi |
| 3129 | AC_SUBST(LIBZ) |
| 3130 | |
| 3131 | |
| 3132 | ### Use -ltiff if available, unless `--with-tiff=no'. |
| 3133 | ### mingw32 doesn't use -ltiff, since it loads the library dynamically. |
| 3134 | HAVE_TIFF=no |
| 3135 | LIBTIFF= |
| 3136 | if test "${opsys}" = "mingw32"; then |
| 3137 | if test "${with_tiff}" != "no"; then |
| 3138 | AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no) |
| 3139 | fi |
| 3140 | if test "${HAVE_TIFF}" = "yes"; then |
| 3141 | AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).]) |
| 3142 | fi |
| 3143 | elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then |
| 3144 | if test "${with_tiff}" != "no"; then |
| 3145 | AC_CHECK_HEADER(tiffio.h, |
| 3146 | [tifflibs="-lz -lm" |
| 3147 | # At least one tiff package requires the jpeg library. |
| 3148 | if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi |
| 3149 | AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)]) |
| 3150 | fi |
| 3151 | |
| 3152 | if test "${HAVE_TIFF}" = "yes"; then |
| 3153 | AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).]) |
| 3154 | dnl FIXME -lz -lm, as per libpng? |
| 3155 | LIBTIFF=-ltiff |
| 3156 | fi |
| 3157 | fi |
| 3158 | AC_SUBST(LIBTIFF) |
| 3159 | |
| 3160 | ### Use -lgif or -lungif if available, unless `--with-gif=no'. |
| 3161 | ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically. |
| 3162 | HAVE_GIF=no |
| 3163 | LIBGIF= |
| 3164 | if test "${opsys}" = "mingw32"; then |
| 3165 | if test "${with_gif}" != "no"; then |
| 3166 | AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no) |
| 3167 | fi |
| 3168 | if test "${HAVE_GIF}" = "yes"; then |
| 3169 | AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.]) |
| 3170 | fi |
| 3171 | elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \ |
| 3172 | || test "${HAVE_W32}" = "yes"; then |
| 3173 | AC_CHECK_HEADER(gif_lib.h, |
| 3174 | # EGifPutExtensionLast only exists from version libungif-4.1.0b1. |
| 3175 | # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast. |
| 3176 | [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes, |
| 3177 | [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])]) |
| 3178 | |
| 3179 | if test "$HAVE_GIF" = yes; then |
| 3180 | LIBGIF=-lgif |
| 3181 | elif test "$HAVE_GIF" = maybe; then |
| 3182 | # If gif_lib.h but no libgif, try libungif. |
| 3183 | AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no) |
| 3184 | test "$HAVE_GIF" = yes && LIBGIF=-lungif |
| 3185 | fi |
| 3186 | |
| 3187 | if test "${HAVE_GIF}" = "yes"; then |
| 3188 | AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.]) |
| 3189 | fi |
| 3190 | fi |
| 3191 | AC_SUBST(LIBGIF) |
| 3192 | |
| 3193 | dnl Check for required libraries. |
| 3194 | if test "${HAVE_X11}" = "yes"; then |
| 3195 | MISSING="" |
| 3196 | WITH_NO="" |
| 3197 | test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" && |
| 3198 | MISSING="libXpm" && WITH_NO="--with-xpm=no" |
| 3199 | test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" && |
| 3200 | MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no" |
| 3201 | test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" && |
| 3202 | MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no" |
| 3203 | test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" && |
| 3204 | MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no" |
| 3205 | test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" && |
| 3206 | MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no" |
| 3207 | |
| 3208 | if test "X${MISSING}" != X; then |
| 3209 | AC_MSG_ERROR([The following required libraries were not found: |
| 3210 | $MISSING |
| 3211 | Maybe some development libraries/packages are missing? |
| 3212 | If you don't want to link with them give |
| 3213 | $WITH_NO |
| 3214 | as options to configure]) |
| 3215 | fi |
| 3216 | fi |
| 3217 | |
| 3218 | ### Use -lgpm if available, unless `--with-gpm=no'. |
| 3219 | HAVE_GPM=no |
| 3220 | LIBGPM= |
| 3221 | if test "${with_gpm}" != "no"; then |
| 3222 | AC_CHECK_HEADER(gpm.h, |
| 3223 | [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)]) |
| 3224 | |
| 3225 | if test "${HAVE_GPM}" = "yes"; then |
| 3226 | AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).]) |
| 3227 | LIBGPM=-lgpm |
| 3228 | fi |
| 3229 | fi |
| 3230 | AC_SUBST(LIBGPM) |
| 3231 | |
| 3232 | dnl Check for malloc/malloc.h on darwin |
| 3233 | AC_CHECK_HEADERS_ONCE(malloc/malloc.h) |
| 3234 | |
| 3235 | GNUSTEP_CFLAGS= |
| 3236 | ### Use NeXTstep API to implement GUI. |
| 3237 | if test "${HAVE_NS}" = "yes"; then |
| 3238 | AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.]) |
| 3239 | if test "${NS_IMPL_COCOA}" = "yes"; then |
| 3240 | AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.]) |
| 3241 | fi |
| 3242 | if test "${NS_IMPL_GNUSTEP}" = "yes"; then |
| 3243 | AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.]) |
| 3244 | # See also .m.o rule in Makefile.in */ |
| 3245 | # FIXME: are all these flags really needed? Document here why. */ |
| 3246 | GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}" |
| 3247 | ## Extra CFLAGS applied to src/*.m files. |
| 3248 | GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE" |
| 3249 | fi |
| 3250 | OTHER_FILES=ns-app |
| 3251 | fi |
| 3252 | |
| 3253 | ### Use session management (-lSM -lICE) if available |
| 3254 | HAVE_X_SM=no |
| 3255 | LIBXSM= |
| 3256 | if test "${HAVE_X11}" = "yes"; then |
| 3257 | AC_CHECK_HEADER(X11/SM/SMlib.h, |
| 3258 | [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)]) |
| 3259 | |
| 3260 | if test "${HAVE_X_SM}" = "yes"; then |
| 3261 | AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).]) |
| 3262 | LIBXSM="-lSM -lICE" |
| 3263 | case "$LIBS" in |
| 3264 | *-lSM*) ;; |
| 3265 | *) LIBS="$LIBXSM $LIBS" ;; |
| 3266 | esac |
| 3267 | fi |
| 3268 | fi |
| 3269 | AC_SUBST(LIBXSM) |
| 3270 | |
| 3271 | ### Use XRandr (-lXrandr) if available |
| 3272 | HAVE_XRANDR=no |
| 3273 | if test "${HAVE_X11}" = "yes"; then |
| 3274 | XRANDR_REQUIRED=1.2.2 |
| 3275 | XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED" |
| 3276 | PKG_CHECK_MODULES(XRANDR, $XRANDR_MODULES, HAVE_XRANDR=yes, HAVE_XRANDR=no) |
| 3277 | if test $HAVE_XRANDR = no; then |
| 3278 | # Test old way in case pkg-config doesn't have it (older machines). |
| 3279 | AC_CHECK_HEADER(X11/extensions/Xrandr.h, |
| 3280 | [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)]) |
| 3281 | if test $HAVE_XRANDR = yes; then |
| 3282 | XRANDR_LIBS=-lXrandr |
| 3283 | AC_SUBST(XRANDR_LIBS) |
| 3284 | fi |
| 3285 | fi |
| 3286 | if test $HAVE_XRANDR = yes; then |
| 3287 | SAVE_CFLAGS="$CFLAGS" |
| 3288 | SAVE_LIBS="$LIBS" |
| 3289 | CFLAGS="$XRANDR_CFLAGS $CFLAGS" |
| 3290 | LIBS="$XRANDR_LIBS $LIBS" |
| 3291 | AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent) |
| 3292 | CFLAGS="$SAVE_CFLAGS" |
| 3293 | LIBS="$SAVE_LIBS" |
| 3294 | |
| 3295 | AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.]) |
| 3296 | fi |
| 3297 | fi |
| 3298 | |
| 3299 | ### Use Xinerama (-lXinerama) if available |
| 3300 | HAVE_XINERAMA=no |
| 3301 | if test "${HAVE_X11}" = "yes"; then |
| 3302 | XINERAMA_REQUIRED=1.0.2 |
| 3303 | XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED" |
| 3304 | PKG_CHECK_MODULES(XINERAMA, $XINERAMA_MODULES, HAVE_XINERAMA=yes, |
| 3305 | HAVE_XINERAMA=no) |
| 3306 | if test $HAVE_XINERAMA = no; then |
| 3307 | # Test old way in case pkg-config doesn't have it (older machines). |
| 3308 | AC_CHECK_HEADER(X11/extensions/Xinerama.h, |
| 3309 | [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)]) |
| 3310 | if test $HAVE_XINERAMA = yes; then |
| 3311 | XINERAMA_LIBS=-lXinerama |
| 3312 | AC_SUBST(XINERAMA_LIBS) |
| 3313 | fi |
| 3314 | fi |
| 3315 | if test $HAVE_XINERAMA = yes; then |
| 3316 | AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.]) |
| 3317 | fi |
| 3318 | fi |
| 3319 | |
| 3320 | |
| 3321 | ### Use libxml (-lxml2) if available |
| 3322 | ### mingw32 doesn't use -lxml2, since it loads the library dynamically. |
| 3323 | HAVE_LIBXML2=no |
| 3324 | if test "${with_xml2}" != "no"; then |
| 3325 | ### I'm not sure what the version number should be, so I just guessed. |
| 3326 | PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no) |
| 3327 | # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc. |
| 3328 | if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then |
| 3329 | SAVE_CPPFLAGS="$CPPFLAGS" |
| 3330 | CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2" |
| 3331 | AC_CHECK_HEADER(libxml/HTMLparser.h, |
| 3332 | [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, , |
| 3333 | [#include <libxml/HTMLparser.h>])]) |
| 3334 | CPPFLAGS="$SAVE_CPPFLAGS" |
| 3335 | if test "${HAVE_LIBXML2}" = "yes"; then |
| 3336 | LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'" |
| 3337 | LIBXML2_LIBS="-lxml2" |
| 3338 | fi |
| 3339 | fi |
| 3340 | if test "${HAVE_LIBXML2}" = "yes"; then |
| 3341 | if test "${opsys}" != "mingw32"; then |
| 3342 | LIBS="$LIBXML2_LIBS $LIBS" |
| 3343 | AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no) |
| 3344 | else |
| 3345 | LIBXML2_LIBS="" |
| 3346 | fi |
| 3347 | if test "${HAVE_LIBXML2}" = "yes"; then |
| 3348 | AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).]) |
| 3349 | else |
| 3350 | LIBXML2_LIBS="" |
| 3351 | LIBXML2_CFLAGS="" |
| 3352 | fi |
| 3353 | fi |
| 3354 | fi |
| 3355 | AC_SUBST(LIBXML2_LIBS) |
| 3356 | AC_SUBST(LIBXML2_CFLAGS) |
| 3357 | |
| 3358 | # If netdb.h doesn't declare h_errno, we must declare it by hand. |
| 3359 | # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c. |
| 3360 | if test "${opsys}" = "mingw32"; then |
| 3361 | emacs_cv_netdb_declares_h_errno=yes |
| 3362 | fi |
| 3363 | AC_CACHE_CHECK(whether netdb declares h_errno, |
| 3364 | emacs_cv_netdb_declares_h_errno, |
| 3365 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], |
| 3366 | [[return h_errno;]])], |
| 3367 | emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)]) |
| 3368 | if test $emacs_cv_netdb_declares_h_errno = yes; then |
| 3369 | AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.]) |
| 3370 | fi |
| 3371 | |
| 3372 | # sqrt and other floating-point functions such as fmod and frexp |
| 3373 | # are found in -lm on most systems, but mingw32 doesn't use -lm. |
| 3374 | if test "${opsys}" != "mingw32"; then |
| 3375 | AC_CHECK_LIB(m, sqrt) |
| 3376 | fi |
| 3377 | |
| 3378 | # Check for mail-locking functions in a "mail" library. Probably this should |
| 3379 | # have the same check as for liblockfile below. |
| 3380 | AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no) |
| 3381 | if test $have_mail = yes; then |
| 3382 | LIBS_MAIL=-lmail |
| 3383 | LIBS="$LIBS_MAIL $LIBS" |
| 3384 | AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).]) |
| 3385 | else |
| 3386 | LIBS_MAIL= |
| 3387 | fi |
| 3388 | dnl Debian, at least: |
| 3389 | AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no) |
| 3390 | if test $have_lockfile = yes; then |
| 3391 | LIBS_MAIL=-llockfile |
| 3392 | LIBS="$LIBS_MAIL $LIBS" |
| 3393 | AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).]) |
| 3394 | else |
| 3395 | # If we have the shared liblockfile, assume we must use it for mail |
| 3396 | # locking (e.g. Debian). If we couldn't link against liblockfile |
| 3397 | # (no liblockfile.a installed), ensure that we don't need to. |
| 3398 | dnl This works for files generally, not just executables. |
| 3399 | dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf? |
| 3400 | AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no, |
| 3401 | /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH) |
| 3402 | if test $ac_cv_prog_liblockfile = yes; then |
| 3403 | AC_MSG_ERROR([Shared liblockfile found but can't link against it. |
| 3404 | This probably means that movemail could lose mail. |
| 3405 | There may be a `development' package to install containing liblockfile.]) |
| 3406 | fi |
| 3407 | fi |
| 3408 | AC_CHECK_HEADERS_ONCE(maillock.h) |
| 3409 | AC_SUBST(LIBS_MAIL) |
| 3410 | |
| 3411 | ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to |
| 3412 | ## interlock access to the mail spool. The alternative is a lock file named |
| 3413 | ## /usr/spool/mail/$USER.lock. |
| 3414 | mail_lock=no |
| 3415 | case "$opsys" in |
| 3416 | aix4-2) mail_lock="lockf" ;; |
| 3417 | |
| 3418 | gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;; |
| 3419 | |
| 3420 | ## On GNU/Linux systems, both methods are used by various mail programs. |
| 3421 | ## I assume most people are using newer mailers that have heard of flock. |
| 3422 | ## Change this if you need to. |
| 3423 | ## Debian contains a patch which says: ``On Debian/GNU/Linux systems, |
| 3424 | ## configure gets the right answers, and that means *NOT* using flock. |
| 3425 | ## Using flock is guaranteed to be the wrong thing. See Debian Policy |
| 3426 | ## for details.'' and then uses `#ifdef DEBIAN'. Unfortunately the |
| 3427 | ## Debian maintainer hasn't provided a clean fix for Emacs. |
| 3428 | ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and |
| 3429 | ## HAVE_MAILLOCK_H are defined, so the following appears to be the |
| 3430 | ## correct logic. -- fx |
| 3431 | ## We must check for HAVE_LIBLOCKFILE too, as movemail does. |
| 3432 | ## liblockfile is a Free Software replacement for libmail, used on |
| 3433 | ## Debian systems and elsewhere. -rfr. |
| 3434 | gnu-*) |
| 3435 | mail_lock="flock" |
| 3436 | if test $have_mail = yes || test $have_lockfile = yes; then |
| 3437 | test $ac_cv_header_maillock_h = yes && mail_lock=no |
| 3438 | fi |
| 3439 | ;; |
| 3440 | |
| 3441 | mingw32) |
| 3442 | mail_lock="none-needed" ;; |
| 3443 | esac |
| 3444 | |
| 3445 | BLESSMAIL_TARGET= |
| 3446 | case "$mail_lock" in |
| 3447 | flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;; |
| 3448 | |
| 3449 | lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;; |
| 3450 | |
| 3451 | none-needed) ;; |
| 3452 | |
| 3453 | *) BLESSMAIL_TARGET="need-blessmail" ;; |
| 3454 | esac |
| 3455 | AC_SUBST(BLESSMAIL_TARGET) |
| 3456 | |
| 3457 | |
| 3458 | AC_CHECK_FUNCS(accept4 gethostname \ |
| 3459 | getrusage get_current_dir_name \ |
| 3460 | lrand48 \ |
| 3461 | select getpagesize setlocale \ |
| 3462 | getrlimit setrlimit shutdown getaddrinfo \ |
| 3463 | strsignal setitimer \ |
| 3464 | sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \ |
| 3465 | gai_strerror getline getdelim sync \ |
| 3466 | getpwent endpwent getgrent endgrent \ |
| 3467 | touchlock \ |
| 3468 | cfmakeraw cfsetspeed copysign __executable_start log2) |
| 3469 | |
| 3470 | dnl No need to check for aligned_alloc and posix_memalign if using |
| 3471 | dnl gmalloc.o, as it supplies them. Don't use these functions on |
| 3472 | dnl Darwin as they are incompatible with unexmacosx.c. |
| 3473 | if test -z "$GMALLOC_OBJ" && test "$opsys" != darwin; then |
| 3474 | AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break]) |
| 3475 | fi |
| 3476 | |
| 3477 | ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines |
| 3478 | ## has a broken `rint' in some library versions including math library |
| 3479 | ## version number A.09.05. |
| 3480 | ## You can fix the math library by installing patch number PHSS_4630. |
| 3481 | ## But we can fix it more reliably for Emacs by just not using rint. |
| 3482 | ## We also skip HAVE_RANDOM - see comments in src/conf_post.h. |
| 3483 | case $opsys in |
| 3484 | hpux*) : ;; |
| 3485 | *) AC_CHECK_FUNCS(random rint) ;; |
| 3486 | esac |
| 3487 | |
| 3488 | dnl Cannot use AC_CHECK_FUNCS |
| 3489 | AC_CACHE_CHECK([for __builtin_unwind_init], |
| 3490 | emacs_cv_func___builtin_unwind_init, |
| 3491 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])], |
| 3492 | emacs_cv_func___builtin_unwind_init=yes, |
| 3493 | emacs_cv_func___builtin_unwind_init=no)]) |
| 3494 | if test $emacs_cv_func___builtin_unwind_init = yes; then |
| 3495 | AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1, |
| 3496 | [Define to 1 if you have the `__builtin_unwind_init' function.]) |
| 3497 | fi |
| 3498 | |
| 3499 | AC_CHECK_HEADERS_ONCE(sys/un.h) |
| 3500 | |
| 3501 | AC_FUNC_FSEEKO |
| 3502 | |
| 3503 | # UNIX98 PTYs. |
| 3504 | AC_CHECK_FUNCS(grantpt) |
| 3505 | |
| 3506 | # PTY-related GNU extensions. |
| 3507 | AC_CHECK_FUNCS(getpt posix_openpt) |
| 3508 | |
| 3509 | # Check this now, so that we will NOT find the above functions in ncurses. |
| 3510 | # That is because we have not set up to link ncurses in lib-src. |
| 3511 | # It's better to believe a function is not available |
| 3512 | # than to expect to find it in ncurses. |
| 3513 | # Also we need tputs and friends to be able to build at all. |
| 3514 | AC_MSG_CHECKING([for library containing tputs]) |
| 3515 | # Run a test program that contains a call to tputs, a call that is |
| 3516 | # never executed. This tests whether a pre-'main' dynamic linker |
| 3517 | # works with the library. It's too much trouble to actually call |
| 3518 | # tputs in the test program, due to portability hassles. When |
| 3519 | # cross-compiling, assume the test program will run if it links. |
| 3520 | AC_DEFUN([tputs_link_source], [ |
| 3521 | AC_LANG_SOURCE( |
| 3522 | [[extern void tputs (const char *, int, int (*)(int)); |
| 3523 | int main (int argc, char **argv) |
| 3524 | { |
| 3525 | if (argc == 10000) |
| 3526 | tputs (argv[0], 0, 0); |
| 3527 | return 0; |
| 3528 | }]]) |
| 3529 | ]) |
| 3530 | if test "${opsys}" = "mingw32"; then |
| 3531 | msg='none required' |
| 3532 | else |
| 3533 | # Maybe curses should be tried earlier? |
| 3534 | # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35 |
| 3535 | for tputs_library in '' tinfo ncurses terminfo termcap curses; do |
| 3536 | OLIBS=$LIBS |
| 3537 | if test -z "$tputs_library"; then |
| 3538 | LIBS_TERMCAP= |
| 3539 | msg='none required' |
| 3540 | else |
| 3541 | LIBS_TERMCAP=-l$tputs_library |
| 3542 | msg=$LIBS_TERMCAP |
| 3543 | LIBS="$LIBS_TERMCAP $LIBS" |
| 3544 | fi |
| 3545 | AC_RUN_IFELSE([tputs_link_source], [], [msg=no], |
| 3546 | [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])]) |
| 3547 | LIBS=$OLIBS |
| 3548 | if test "X$msg" != Xno; then |
| 3549 | break |
| 3550 | fi |
| 3551 | done |
| 3552 | fi |
| 3553 | AC_MSG_RESULT([$msg]) |
| 3554 | if test "X$msg" = Xno; then |
| 3555 | AC_MSG_ERROR([The required function `tputs' was not found in any library. |
| 3556 | The following libraries were tried (in order): |
| 3557 | libtinfo, libncurses, libterminfo, libtermcap, libcurses |
| 3558 | Please try installing whichever of these libraries is most appropriate |
| 3559 | for your system, together with its header files. |
| 3560 | For example, a libncurses-dev(el) or similar package.]) |
| 3561 | fi |
| 3562 | |
| 3563 | ## Use termcap instead of terminfo? |
| 3564 | ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500. |
| 3565 | TERMINFO=yes |
| 3566 | ## FIXME? In the cases below where we unconditionally set |
| 3567 | ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo, |
| 3568 | ## if that was found above to have tputs. |
| 3569 | ## Should we use the gnu* logic everywhere? |
| 3570 | case "$opsys" in |
| 3571 | ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2. |
| 3572 | ## The ncurses library has been moved out of the System framework in |
| 3573 | ## Mac OS X 10.2. So if configure detects it, set the command-line |
| 3574 | ## option to use it. |
| 3575 | darwin) LIBS_TERMCAP="-lncurses" ;; |
| 3576 | |
| 3577 | gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;; |
| 3578 | |
| 3579 | freebsd) |
| 3580 | AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo]) |
| 3581 | AC_CACHE_VAL(emacs_cv_freebsd_terminfo, |
| 3582 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]], |
| 3583 | [[#if __FreeBSD_version < 400000 |
| 3584 | fail; |
| 3585 | #endif |
| 3586 | ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)]) |
| 3587 | |
| 3588 | AC_MSG_RESULT($emacs_cv_freebsd_terminfo) |
| 3589 | |
| 3590 | if test $emacs_cv_freebsd_terminfo = yes; then |
| 3591 | LIBS_TERMCAP="-lncurses" |
| 3592 | else |
| 3593 | TERMINFO=no |
| 3594 | LIBS_TERMCAP="-ltermcap" |
| 3595 | fi |
| 3596 | ;; |
| 3597 | |
| 3598 | mingw32) |
| 3599 | TERMINFO=no |
| 3600 | LIBS_TERMCAP= |
| 3601 | ;; |
| 3602 | |
| 3603 | netbsd) |
| 3604 | if test "x$LIBS_TERMCAP" != "x-lterminfo"; then |
| 3605 | TERMINFO=no |
| 3606 | LIBS_TERMCAP="-ltermcap" |
| 3607 | fi |
| 3608 | ;; |
| 3609 | |
| 3610 | openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;; |
| 3611 | |
| 3612 | ## hpux: Make sure we get select from libc rather than from libcurses |
| 3613 | ## because libcurses on HPUX 10.10 has a broken version of select. |
| 3614 | ## We used to use -lc -lcurses, but this may be cleaner. |
| 3615 | ## FIXME? But TERMINFO = yes on hpux (it used to be explicitly |
| 3616 | # set that way, now it uses the default). Isn't this a contradiction? |
| 3617 | hpux*) LIBS_TERMCAP="-ltermcap" ;; |
| 3618 | |
| 3619 | esac |
| 3620 | |
| 3621 | TERMCAP_OBJ=tparam.o |
| 3622 | if test $TERMINFO = yes; then |
| 3623 | AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.]) |
| 3624 | TERMCAP_OBJ=terminfo.o |
| 3625 | fi |
| 3626 | if test "X$LIBS_TERMCAP" = "X-lncurses"; then |
| 3627 | AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.]) |
| 3628 | fi |
| 3629 | AC_SUBST(LIBS_TERMCAP) |
| 3630 | AC_SUBST(TERMCAP_OBJ) |
| 3631 | |
| 3632 | |
| 3633 | # Do we have res_init, for detecting changes in /etc/resolv.conf? |
| 3634 | # On Darwin, res_init appears not to be useful: see bug#562 and |
| 3635 | # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html |
| 3636 | resolv=no |
| 3637 | |
| 3638 | if test $opsys != darwin; then |
| 3639 | |
| 3640 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h> |
| 3641 | #include <arpa/nameser.h> |
| 3642 | #include <resolv.h>]], |
| 3643 | [[return res_init();]])], |
| 3644 | have_res_init=yes, have_res_init=no) |
| 3645 | if test "$have_res_init" = no; then |
| 3646 | OLIBS="$LIBS" |
| 3647 | LIBS="$LIBS -lresolv" |
| 3648 | AC_MSG_CHECKING(for res_init with -lresolv) |
| 3649 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h> |
| 3650 | #include <arpa/nameser.h> |
| 3651 | #include <resolv.h>]], |
| 3652 | [[return res_init();]])], |
| 3653 | have_res_init=yes, have_res_init=no) |
| 3654 | AC_MSG_RESULT($have_res_init) |
| 3655 | if test "$have_res_init" = yes ; then |
| 3656 | resolv=yes |
| 3657 | fi |
| 3658 | LIBS="$OLIBS" |
| 3659 | fi |
| 3660 | |
| 3661 | if test "$have_res_init" = yes; then |
| 3662 | AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.]) |
| 3663 | fi |
| 3664 | fi dnl !darwin |
| 3665 | |
| 3666 | # Do we need the Hesiod library to provide the support routines? |
| 3667 | dnl FIXME? Should we be skipping this on Darwin too? |
| 3668 | LIBHESIOD= |
| 3669 | if test "$with_hesiod" != no ; then |
| 3670 | # Don't set $LIBS here -- see comments above. FIXME which comments? |
| 3671 | AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, , |
| 3672 | [AC_CHECK_LIB(resolv, res_send, resolv=yes, |
| 3673 | [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])]) |
| 3674 | if test "$resolv" = yes ; then |
| 3675 | RESOLVLIB=-lresolv |
| 3676 | else |
| 3677 | RESOLVLIB= |
| 3678 | fi |
| 3679 | AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost, |
| 3680 | hesiod=yes, :, $RESOLVLIB)]) |
| 3681 | |
| 3682 | if test x"$hesiod" = xyes; then |
| 3683 | LIBHESIOD=-lhesiod |
| 3684 | fi |
| 3685 | fi |
| 3686 | AC_SUBST(LIBHESIOD) |
| 3687 | |
| 3688 | # Do we need libresolv (due to res_init or Hesiod)? |
| 3689 | if test "$resolv" = yes && test $opsys != darwin; then |
| 3690 | LIBRESOLV=-lresolv |
| 3691 | else |
| 3692 | LIBRESOLV= |
| 3693 | fi |
| 3694 | AC_SUBST(LIBRESOLV) |
| 3695 | |
| 3696 | # These tell us which Kerberos-related libraries to use. |
| 3697 | COM_ERRLIB= |
| 3698 | CRYPTOLIB= |
| 3699 | KRB5LIB= |
| 3700 | DESLIB= |
| 3701 | KRB4LIB= |
| 3702 | |
| 3703 | if test "${with_kerberos}" != no; then |
| 3704 | AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no) |
| 3705 | if test $have_com_err = yes; then |
| 3706 | COM_ERRLIB=-lcom_err |
| 3707 | LIBS="$COM_ERRLIB $LIBS" |
| 3708 | fi |
| 3709 | AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no) |
| 3710 | if test $have_crypto = yes; then |
| 3711 | CRYPTOLIB=-lcrypto |
| 3712 | LIBS="$CRYPTOLIB $LIBS" |
| 3713 | fi |
| 3714 | AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no) |
| 3715 | if test $have_k5crypto = yes; then |
| 3716 | CRYPTOLIB=-lk5crypto |
| 3717 | LIBS="$CRYPTOLIB $LIBS" |
| 3718 | fi |
| 3719 | AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no) |
| 3720 | if test $have_krb5=yes; then |
| 3721 | KRB5LIB=-lkrb5 |
| 3722 | LIBS="$KRB5LIB $LIBS" |
| 3723 | fi |
| 3724 | dnl FIXME Simplify. Does not match 22 logic, thanks to default_off? |
| 3725 | if test "${with_kerberos5}" = no; then |
| 3726 | AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no ) |
| 3727 | if test $have_des425 = yes; then |
| 3728 | DESLIB=-ldes425 |
| 3729 | LIBS="$DESLIB $LIBS" |
| 3730 | else |
| 3731 | AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no) |
| 3732 | if test $have_des = yes; then |
| 3733 | DESLIB=-ldes |
| 3734 | LIBS="$DESLIB $LIBS" |
| 3735 | fi |
| 3736 | fi |
| 3737 | AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no) |
| 3738 | if test $have_krb4 = yes; then |
| 3739 | KRB4LIB=-lkrb4 |
| 3740 | LIBS="$KRB4LIB $LIBS" |
| 3741 | else |
| 3742 | AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no) |
| 3743 | if test $have_krb = yes; then |
| 3744 | KRB4LIB=-lkrb |
| 3745 | LIBS="$KRB4LIB $LIBS" |
| 3746 | fi |
| 3747 | fi |
| 3748 | fi |
| 3749 | |
| 3750 | if test "${with_kerberos5}" != no; then |
| 3751 | AC_CHECK_HEADERS(krb5.h, |
| 3752 | [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,, |
| 3753 | [#include <krb5.h>])]) |
| 3754 | else |
| 3755 | AC_CHECK_HEADERS(krb.h,, |
| 3756 | [AC_CHECK_HEADERS(kerberosIV/krb.h,, |
| 3757 | [AC_CHECK_HEADERS(kerberos/krb.h)])]) |
| 3758 | fi |
| 3759 | AC_CHECK_HEADERS(com_err.h) |
| 3760 | fi |
| 3761 | |
| 3762 | AC_SUBST(COM_ERRLIB) |
| 3763 | AC_SUBST(CRYPTOLIB) |
| 3764 | AC_SUBST(KRB5LIB) |
| 3765 | AC_SUBST(DESLIB) |
| 3766 | AC_SUBST(KRB4LIB) |
| 3767 | |
| 3768 | AC_CHECK_HEADERS(valgrind/valgrind.h) |
| 3769 | |
| 3770 | AC_CHECK_FUNCS_ONCE(tzset) |
| 3771 | AC_MSG_CHECKING(whether localtime caches TZ) |
| 3772 | AC_CACHE_VAL(emacs_cv_localtime_cache, |
| 3773 | [if test x$ac_cv_func_tzset = xyes; then |
| 3774 | AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h> |
| 3775 | char TZ_GMT0[] = "TZ=GMT0"; |
| 3776 | char TZ_PST8[] = "TZ=PST8"; |
| 3777 | main() |
| 3778 | { |
| 3779 | time_t now = time ((time_t *) 0); |
| 3780 | int hour_GMT0, hour_unset; |
| 3781 | if (putenv (TZ_GMT0) != 0) |
| 3782 | exit (1); |
| 3783 | hour_GMT0 = localtime (&now)->tm_hour; |
| 3784 | unsetenv("TZ"); |
| 3785 | hour_unset = localtime (&now)->tm_hour; |
| 3786 | if (putenv (TZ_PST8) != 0) |
| 3787 | exit (1); |
| 3788 | if (localtime (&now)->tm_hour == hour_GMT0) |
| 3789 | exit (1); |
| 3790 | unsetenv("TZ"); |
| 3791 | if (localtime (&now)->tm_hour != hour_unset) |
| 3792 | exit (1); |
| 3793 | exit (0); |
| 3794 | }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes, |
| 3795 | [# If we have tzset, assume the worst when cross-compiling. |
| 3796 | emacs_cv_localtime_cache=yes]) |
| 3797 | else |
| 3798 | # If we lack tzset, report that localtime does not cache TZ, |
| 3799 | # since we can't invalidate the cache if we don't have tzset. |
| 3800 | emacs_cv_localtime_cache=no |
| 3801 | fi])dnl |
| 3802 | AC_MSG_RESULT($emacs_cv_localtime_cache) |
| 3803 | if test $emacs_cv_localtime_cache = yes; then |
| 3804 | AC_DEFINE(LOCALTIME_CACHE, 1, |
| 3805 | [Define to 1 if localtime caches TZ.]) |
| 3806 | fi |
| 3807 | |
| 3808 | ok_so_far=yes |
| 3809 | AC_CHECK_FUNC(socket, , ok_so_far=no) |
| 3810 | if test $ok_so_far = yes; then |
| 3811 | AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no) |
| 3812 | fi |
| 3813 | if test $ok_so_far = yes; then |
| 3814 | AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no) |
| 3815 | fi |
| 3816 | if test $ok_so_far = yes; then |
| 3817 | dnl Fixme: Not used. Should this be HAVE_SOCKETS? |
| 3818 | AC_DEFINE(HAVE_INET_SOCKETS, 1, |
| 3819 | [Define to 1 if you have inet sockets.]) |
| 3820 | fi |
| 3821 | |
| 3822 | dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69). |
| 3823 | dnl This can be removed once we assume Autoconf 2.70. |
| 3824 | case $canonical in |
| 3825 | *-solaris2.4 | *-solaris2.4.*) |
| 3826 | dnl Disable the Autoconf-generated vfork test. |
| 3827 | : ${ac_cv_func_vfork_works=no};; |
| 3828 | esac |
| 3829 | |
| 3830 | AC_FUNC_FORK |
| 3831 | |
| 3832 | AC_CHECK_FUNCS(snprintf) |
| 3833 | |
| 3834 | dnl Check this late. It depends on what other libraries (lrsvg, Gtk+ etc) |
| 3835 | dnl Emacs uses. |
| 3836 | XGSELOBJ= |
| 3837 | AC_MSG_CHECKING([whether GLib is linked in]) |
| 3838 | AC_LINK_IFELSE([AC_LANG_PROGRAM( |
| 3839 | [[#include <glib.h> |
| 3840 | ]], |
| 3841 | [[g_print ("Hello world");]])], |
| 3842 | [links_glib=yes], |
| 3843 | [links_glib=no]) |
| 3844 | AC_MSG_RESULT([$links_glib]) |
| 3845 | if test "${links_glib}" = "yes"; then |
| 3846 | AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.]) |
| 3847 | if test "$HAVE_NS" = no;then |
| 3848 | XGSELOBJ=xgselect.o |
| 3849 | fi |
| 3850 | fi |
| 3851 | AC_SUBST(XGSELOBJ) |
| 3852 | |
| 3853 | dnl Adapted from Haible's version. |
| 3854 | AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset, |
| 3855 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], |
| 3856 | [[char* cs = nl_langinfo(CODESET);]])], |
| 3857 | emacs_cv_langinfo_codeset=yes, |
| 3858 | emacs_cv_langinfo_codeset=no) |
| 3859 | ]) |
| 3860 | if test $emacs_cv_langinfo_codeset = yes; then |
| 3861 | AC_DEFINE(HAVE_LANGINFO_CODESET, 1, |
| 3862 | [Define if you have <langinfo.h> and nl_langinfo(CODESET).]) |
| 3863 | fi |
| 3864 | |
| 3865 | AC_TYPE_MBSTATE_T |
| 3866 | |
| 3867 | AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr, |
| 3868 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])], |
| 3869 | emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)]) |
| 3870 | if test "$emacs_cv_c_restrict_arr" = yes; then |
| 3871 | AC_DEFINE(__restrict_arr, __restrict, |
| 3872 | [Define to compiler's equivalent of C99 restrict keyword in array |
| 3873 | declarations. Define as empty for no equivalent.]) |
| 3874 | fi |
| 3875 | |
| 3876 | dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear |
| 3877 | dnl how the tty code is related to POSIX and/or other versions of termios. |
| 3878 | dnl The following looks like a useful start. |
| 3879 | dnl |
| 3880 | dnl AC_SYS_POSIX_TERMIOS |
| 3881 | dnl if test $ac_cv_sys_posix_termios = yes; then |
| 3882 | dnl AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions |
| 3883 | dnl and macros for terminal control.]) |
| 3884 | dnl AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.]) |
| 3885 | dnl fi |
| 3886 | |
| 3887 | dnl Turned on June 1996 supposing nobody will mind it. |
| 3888 | dnl MinGW emulates passwd database, so this feature doesn't make sense there. |
| 3889 | if test "${opsys}" != "mingw32"; then |
| 3890 | AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that & |
| 3891 | in the full name stands for the login id.]) |
| 3892 | fi |
| 3893 | |
| 3894 | dnl Every platform that uses configure supports this. |
| 3895 | dnl There is a create-lockfiles option you can |
| 3896 | dnl customize if you do not want the lock files to be written. |
| 3897 | dnl So it is not clear that this #define still needs to exist. |
| 3898 | AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written, |
| 3899 | so that Emacs can tell instantly when you try to modify a file that |
| 3900 | someone else has modified in his/her Emacs.]) |
| 3901 | |
| 3902 | dnl Everybody supports this, except MS. |
| 3903 | dnl Seems like the kind of thing we should be testing for, though. |
| 3904 | ## Note: PTYs are broken on darwin <6. Use at your own risk. |
| 3905 | if test "${opsys}" != "mingw32"; then |
| 3906 | AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.]) |
| 3907 | fi |
| 3908 | |
| 3909 | dnl Everybody supports this, except MS-DOS. |
| 3910 | dnl Seems like the kind of thing we should be testing for, though. |
| 3911 | dnl Compare with HAVE_INET_SOCKETS (which is unused...) above. |
| 3912 | AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports |
| 3913 | 4.2-compatible sockets.]) |
| 3914 | |
| 3915 | AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".]) |
| 3916 | |
| 3917 | AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get |
| 3918 | a null file, or a data sink.]) |
| 3919 | if test "${opsys}" = "mingw32"; then |
| 3920 | AC_DEFINE(NULL_DEVICE, ["NUL:"]) |
| 3921 | else |
| 3922 | AC_DEFINE(NULL_DEVICE, ["/dev/null"]) |
| 3923 | fi |
| 3924 | |
| 3925 | if test "${opsys}" = "mingw32"; then |
| 3926 | SEPCHAR=';' |
| 3927 | else |
| 3928 | SEPCHAR=':' |
| 3929 | fi |
| 3930 | AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.]) |
| 3931 | dnl This is for MinGW, and is used in test/automated/Makefile.in. |
| 3932 | dnl The MSYS Bash has heuristics for replacing ':' with ';' when it |
| 3933 | dnl decides that a command-line argument to be passed to a MinGW program |
| 3934 | dnl is a PATH-style list of directories. But that heuristics plays it |
| 3935 | dnl safe, and only does the replacement when it is _absolutely_ sure it |
| 3936 | dnl sees a colon-separated list of file names; e.g. ":." is left alone, |
| 3937 | dnl which breaks in-tree builds. So we do this manually instead. |
| 3938 | dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always |
| 3939 | dnl be computed as ':' in MSYS Bash. |
| 3940 | AC_SUBST(SEPCHAR) |
| 3941 | |
| 3942 | dnl Everybody supports this, except MS-DOS. |
| 3943 | AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.]) |
| 3944 | |
| 3945 | AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.]) |
| 3946 | |
| 3947 | |
| 3948 | AC_DEFINE(DIRECTORY_SEP, ['/'], |
| 3949 | [Character that separates directories in a file name.]) |
| 3950 | |
| 3951 | if test "${opsys}" = "mingw32"; then |
| 3952 | AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')], |
| 3953 | [Returns true if character is a device separator.]) |
| 3954 | |
| 3955 | AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')], |
| 3956 | [Returns true if character is a directory separator.]) |
| 3957 | |
| 3958 | AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))], |
| 3959 | [Returns true if character is any form of separator.]) |
| 3960 | else |
| 3961 | AC_DEFINE(IS_DEVICE_SEP(_c_), 0, |
| 3962 | [Returns true if character is a device separator.]) |
| 3963 | |
| 3964 | AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)], |
| 3965 | [Returns true if character is a directory separator.]) |
| 3966 | |
| 3967 | AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))], |
| 3968 | [Returns true if character is any form of separator.]) |
| 3969 | fi |
| 3970 | |
| 3971 | AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.]) |
| 3972 | |
| 3973 | case $opsys in |
| 3974 | aix4-2) |
| 3975 | dnl Unfortunately without libXmu we cannot support EditRes. |
| 3976 | if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then |
| 3977 | AC_DEFINE(NO_EDITRES, 1) |
| 3978 | fi |
| 3979 | ;; |
| 3980 | |
| 3981 | hpux*) |
| 3982 | dnl Assar Westerlund <assar@sics.se> says this is necessary for |
| 3983 | dnl HP-UX 10.20, and that it works for HP-UX 0 as well. |
| 3984 | AC_DEFINE(NO_EDITRES, 1) |
| 3985 | ;; |
| 3986 | esac |
| 3987 | |
| 3988 | |
| 3989 | case $opsys in |
| 3990 | irix6-5 | sol2* | unixware ) |
| 3991 | dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments; |
| 3992 | dnl instead, there's a system variable _sys_nsig. Unfortunately, we |
| 3993 | dnl need the constant to dimension an array. So wire in the appropriate |
| 3994 | dnl value here. |
| 3995 | AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.]) |
| 3996 | ;; |
| 3997 | esac |
| 3998 | |
| 3999 | emacs_broken_SIGIO=no |
| 4000 | |
| 4001 | case $opsys in |
| 4002 | dnl SIGIO exists, but the feature doesn't work in the way Emacs needs. |
| 4003 | dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>. |
| 4004 | hpux* | irix6-5 | openbsd | sol2* | unixware ) |
| 4005 | emacs_broken_SIGIO=yes |
| 4006 | ;; |
| 4007 | |
| 4008 | aix4-2) |
| 4009 | dnl On AIX Emacs uses the gmalloc.c malloc implementation. But given |
| 4010 | dnl the way this system works, libc functions that return malloced |
| 4011 | dnl memory use the libc malloc implementation. Calling xfree or |
| 4012 | dnl xrealloc on the results of such functions results in a crash. |
| 4013 | dnl |
| 4014 | dnl One solution for this could be to define SYSTEM_MALLOC in configure, |
| 4015 | dnl but that does not currently work on this system. |
| 4016 | dnl |
| 4017 | dnl It is possible to completely override the malloc implementation on |
| 4018 | dnl AIX, but that involves putting the malloc functions in a shared |
| 4019 | dnl library and setting the MALLOCTYPE environment variable to point to |
| 4020 | dnl that shared library. |
| 4021 | dnl |
| 4022 | dnl Emacs currently calls xrealloc on the results of get_current_dir name, |
| 4023 | dnl to avoid a crash just use the Emacs implementation for that function. |
| 4024 | dnl |
| 4025 | dnl FIXME We could change the AC_CHECK_FUNCS call near the start |
| 4026 | dnl of this file, so that we do not check for get_current_dir_name |
| 4027 | dnl on AIX. But that might be fragile if something else ends |
| 4028 | dnl up testing for get_current_dir_name as a dependency. |
| 4029 | AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if |
| 4030 | get_current_dir_name should not be used.]) |
| 4031 | ;; |
| 4032 | |
| 4033 | freebsd) |
| 4034 | dnl Circumvent a bug in FreeBSD. In the following sequence of |
| 4035 | dnl writes/reads on a PTY, read(2) returns bogus data: |
| 4036 | dnl |
| 4037 | dnl write(2) 1022 bytes |
| 4038 | dnl write(2) 954 bytes, get EAGAIN |
| 4039 | dnl read(2) 1024 bytes in process_read_output |
| 4040 | dnl read(2) 11 bytes in process_read_output |
| 4041 | dnl |
| 4042 | dnl That is, read(2) returns more bytes than have ever been written |
| 4043 | dnl successfully. The 1033 bytes read are the 1022 bytes written |
| 4044 | dnl successfully after processing (for example with CRs added if the |
| 4045 | dnl terminal is set up that way which it is here). The same bytes will |
| 4046 | dnl be seen again in a later read(2), without the CRs. |
| 4047 | AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to |
| 4048 | work around an issue when reading from a PTY.]) |
| 4049 | ;; |
| 4050 | esac |
| 4051 | |
| 4052 | case $opsys in |
| 4053 | gnu-* | sol2-10 ) |
| 4054 | dnl FIXME Can't we test if this exists (eg /proc/$$)? |
| 4055 | AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.]) |
| 4056 | ;; |
| 4057 | esac |
| 4058 | |
| 4059 | case $opsys in |
| 4060 | darwin | dragonfly | freebsd | netbsd | openbsd ) |
| 4061 | AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to |
| 4062 | close a pty to make it a controlling terminal (it is already a |
| 4063 | controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).]) |
| 4064 | ;; |
| 4065 | esac |
| 4066 | |
| 4067 | dnl FIXME Surely we can test for this rather than hard-code it. |
| 4068 | case $opsys in |
| 4069 | netbsd | openbsd) sound_device="/dev/audio" ;; |
| 4070 | *) sound_device="/dev/dsp" ;; |
| 4071 | esac |
| 4072 | |
| 4073 | dnl Used in sound.c |
| 4074 | AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device", |
| 4075 | [Name of the default sound device.]) |
| 4076 | |
| 4077 | |
| 4078 | dnl Emacs can read input using SIGIO and buffering characters itself, |
| 4079 | dnl or using CBREAK mode and making C-g cause SIGINT. |
| 4080 | dnl The choice is controlled by the variable interrupt_input. |
| 4081 | dnl |
| 4082 | dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO) |
| 4083 | dnl |
| 4084 | dnl Emacs uses the presence of the USABLE_SIGIO macro |
| 4085 | dnl to indicate whether or not signal-driven I/O is possible. It uses |
| 4086 | dnl INTERRUPT_INPUT to decide whether to use it by default. |
| 4087 | dnl |
| 4088 | dnl SIGIO can be used only on systems that implement it (4.2 and 4.3). |
| 4089 | dnl CBREAK mode has two disadvantages |
| 4090 | dnl 1) At least in 4.2, it is impossible to handle the Meta key properly. |
| 4091 | dnl I hear that in system V this problem does not exist. |
| 4092 | dnl 2) Control-G causes output to be discarded. |
| 4093 | dnl I do not know whether this can be fixed in system V. |
| 4094 | dnl |
| 4095 | dnl Another method of doing input is planned but not implemented. |
| 4096 | dnl It would have Emacs fork off a separate process |
| 4097 | dnl to read the input and send it to the true Emacs process |
| 4098 | dnl through a pipe. |
| 4099 | case $opsys in |
| 4100 | darwin | gnu-linux | gnu-kfreebsd ) |
| 4101 | AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.]) |
| 4102 | ;; |
| 4103 | esac |
| 4104 | |
| 4105 | |
| 4106 | dnl If the system's imake configuration file defines `NeedWidePrototypes' |
| 4107 | dnl as `NO', we must define NARROWPROTO manually. Such a define is |
| 4108 | dnl generated in the Makefile generated by `xmkmf'. If we don't define |
| 4109 | dnl NARROWPROTO, we will see the wrong function prototypes for X functions |
| 4110 | dnl taking float or double parameters. |
| 4111 | case $opsys in |
| 4112 | cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd) |
| 4113 | AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration |
| 4114 | file defines `NeedWidePrototypes' as `NO'.]) |
| 4115 | ;; |
| 4116 | esac |
| 4117 | |
| 4118 | |
| 4119 | dnl Used in process.c, this must be a loop, even if it only runs once. |
| 4120 | dnl (Except on SGI; see below. Take that, clarity and consistency!) |
| 4121 | AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.]) |
| 4122 | dnl Only used if !PTY_ITERATION. Iterate from FIRST_PTY_LETTER to z, |
| 4123 | dnl trying suffixes 0-16. |
| 4124 | AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of |
| 4125 | first PTY, if PTYs are supported.]) |
| 4126 | AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.]) |
| 4127 | AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control |
| 4128 | end of a PTY, if non-standard.]) |
| 4129 | AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty |
| 4130 | end of a PTY, if non-standard.]) |
| 4131 | |
| 4132 | case $opsys in |
| 4133 | aix4-2 ) |
| 4134 | AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)]) |
| 4135 | dnl You allocate a pty by opening /dev/ptc to get the master side. |
| 4136 | dnl To get the name of the slave side, you just ttyname() the master side. |
| 4137 | AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");]) |
| 4138 | AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));]) |
| 4139 | ;; |
| 4140 | |
| 4141 | cygwin ) |
| 4142 | AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)]) |
| 4143 | dnl multi-line AC_DEFINEs are hard. :( |
| 4144 | AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)]) |
| 4145 | AC_DEFINE(PTY_NAME_SPRINTF, []) |
| 4146 | AC_DEFINE(PTY_TTY_NAME_SPRINTF, []) |
| 4147 | ;; |
| 4148 | |
| 4149 | dnl FIXME? Maybe use same as freebsd - see bug#12040. |
| 4150 | darwin ) |
| 4151 | AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)]) |
| 4152 | dnl Not used, because PTY_ITERATION is defined. |
| 4153 | AC_DEFINE(FIRST_PTY_LETTER, ['p']) |
| 4154 | dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8. |
| 4155 | dnl But we don't have to block SIGCHLD because it is blocked in the |
| 4156 | dnl implementation of grantpt. |
| 4157 | AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)]) |
| 4158 | AC_DEFINE(PTY_NAME_SPRINTF, []) |
| 4159 | AC_DEFINE(PTY_TTY_NAME_SPRINTF, []) |
| 4160 | ;; |
| 4161 | |
| 4162 | gnu | openbsd ) |
| 4163 | AC_DEFINE(FIRST_PTY_LETTER, ['p']) |
| 4164 | ;; |
| 4165 | |
| 4166 | gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd ) |
| 4167 | dnl if HAVE_GRANTPT |
| 4168 | if test "x$ac_cv_func_grantpt" = xyes; then |
| 4169 | AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.]) |
| 4170 | AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)]) |
| 4171 | dnl Note that grantpt and unlockpt may fork. We must block SIGCHLD |
| 4172 | dnl to prevent sigchld_handler from intercepting the child's death. |
| 4173 | AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }]) |
| 4174 | dnl if HAVE_POSIX_OPENPT |
| 4175 | if test "x$ac_cv_func_posix_openpt" = xyes; then |
| 4176 | AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)]) |
| 4177 | AC_DEFINE(PTY_NAME_SPRINTF, []) |
| 4178 | dnl if HAVE_GETPT |
| 4179 | elif test "x$ac_cv_func_getpt" = xyes; then |
| 4180 | AC_DEFINE(PTY_OPEN, [fd = getpt ()]) |
| 4181 | AC_DEFINE(PTY_NAME_SPRINTF, []) |
| 4182 | else |
| 4183 | AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");]) |
| 4184 | fi |
| 4185 | else |
| 4186 | AC_DEFINE(FIRST_PTY_LETTER, ['p']) |
| 4187 | fi |
| 4188 | ;; |
| 4189 | |
| 4190 | hpux*) |
| 4191 | AC_DEFINE(FIRST_PTY_LETTER, ['p']) |
| 4192 | AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);]) |
| 4193 | AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);]) |
| 4194 | ;; |
| 4195 | |
| 4196 | irix6-5 ) |
| 4197 | dnl It looks like this cannot be right, because it is not a loop. |
| 4198 | dnl However, process.c actually does this: |
| 4199 | dnl # ifndef __sgi |
| 4200 | dnl continue; |
| 4201 | dnl # else |
| 4202 | dnl return -1; |
| 4203 | dnl # endif |
| 4204 | dnl which presumably makes it OK, since irix == sgi (?). |
| 4205 | dnl FIXME it seems like this special treatment is unnecessary? |
| 4206 | dnl Why can't irix use a single-trip loop like eg cygwin? |
| 4207 | AC_DEFINE(PTY_ITERATION, []) |
| 4208 | dnl Not used, because PTY_ITERATION is defined. |
| 4209 | AC_DEFINE(FIRST_PTY_LETTER, ['q']) |
| 4210 | AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }]) |
| 4211 | dnl No need to get the pty name at all. |
| 4212 | AC_DEFINE(PTY_NAME_SPRINTF, []) |
| 4213 | dnl No need to use sprintf to get the tty name--we get that from _getpty. |
| 4214 | AC_DEFINE(PTY_TTY_NAME_SPRINTF, []) |
| 4215 | ;; |
| 4216 | |
| 4217 | sol2* ) |
| 4218 | dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler() |
| 4219 | dnl from intercepting that death. If any child but grantpt's should die |
| 4220 | dnl within, it should be caught after sigrelse(2). |
| 4221 | AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }]) |
| 4222 | ;; |
| 4223 | |
| 4224 | unixware ) |
| 4225 | dnl Comments are as per sol2*. |
| 4226 | AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }]) |
| 4227 | ;; |
| 4228 | esac |
| 4229 | |
| 4230 | |
| 4231 | case $opsys in |
| 4232 | sol2* | unixware ) |
| 4233 | dnl This change means that we don't loop through allocate_pty too |
| 4234 | dnl many times in the (rare) event of a failure. |
| 4235 | AC_DEFINE(FIRST_PTY_LETTER, ['z']) |
| 4236 | AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");]) |
| 4237 | dnl Push various streams modules onto a PTY channel. Used in process.c. |
| 4238 | AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.]) |
| 4239 | ;; |
| 4240 | esac |
| 4241 | |
| 4242 | |
| 4243 | AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by |
| 4244 | "typing" a signal character on the pty.]) |
| 4245 | |
| 4246 | case $opsys in |
| 4247 | dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX. |
| 4248 | dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX. |
| 4249 | aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin ) |
| 4250 | AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1) |
| 4251 | ;; |
| 4252 | |
| 4253 | dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works. |
| 4254 | dnl FIXME Does gnu-kfreebsd have linux/version.h? It seems unlikely... |
| 4255 | gnu-linux | gnu-kfreebsd ) |
| 4256 | |
| 4257 | AC_MSG_CHECKING([for signals via characters]) |
| 4258 | AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[ |
| 4259 | #include <linux/version.h> |
| 4260 | #if LINUX_VERSION_CODE < 0x20400 |
| 4261 | # error "Linux version too old" |
| 4262 | #endif |
| 4263 | ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no) |
| 4264 | |
| 4265 | AC_MSG_RESULT([$emacs_signals_via_chars]) |
| 4266 | test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1) |
| 4267 | ;; |
| 4268 | esac |
| 4269 | |
| 4270 | |
| 4271 | dnl Used in lisp.h, emacs.c, vm-limit.c |
| 4272 | dnl NEWS.18 describes this as "a number which contains |
| 4273 | dnl the high bits to be inclusive or'ed with pointers that are unpacked." |
| 4274 | AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers |
| 4275 | stored in a Lisp_Object.]) |
| 4276 | dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT. |
| 4277 | |
| 4278 | case $opsys in |
| 4279 | aix*) |
| 4280 | dnl This works with 32-bit executables; Emacs doesn't support 64-bit. |
| 4281 | AC_DEFINE(DATA_SEG_BITS, [0x20000000]) |
| 4282 | ;; |
| 4283 | hpux*) |
| 4284 | dnl The data segment on this machine always starts at address 0x40000000. |
| 4285 | AC_DEFINE(DATA_SEG_BITS, [0x40000000]) |
| 4286 | ;; |
| 4287 | irix6-5) |
| 4288 | AC_DEFINE(DATA_SEG_BITS, [0x10000000]) |
| 4289 | ;; |
| 4290 | esac |
| 4291 | |
| 4292 | |
| 4293 | AH_TEMPLATE(TAB3, [Undocumented.]) |
| 4294 | |
| 4295 | case $opsys in |
| 4296 | darwin) AC_DEFINE(TAB3, OXTABS) ;; |
| 4297 | |
| 4298 | gnu | dragonfly | freebsd | netbsd | openbsd ) |
| 4299 | AC_DEFINE(TABDLY, OXTABS, [Undocumented.]) |
| 4300 | AC_DEFINE(TAB3, OXTABS) |
| 4301 | ;; |
| 4302 | |
| 4303 | gnu-linux | gnu-kfreebsd ) |
| 4304 | AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[ |
| 4305 | #ifndef __ia64__ |
| 4306 | # error "not ia64" |
| 4307 | #endif |
| 4308 | ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(), |
| 4309 | [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)], |
| 4310 | [Mark a secondary stack, like the register stack on the ia64.]), []) |
| 4311 | ;; |
| 4312 | |
| 4313 | hpux*) |
| 4314 | AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call |
| 4315 | run_time_remap; for HPUX.]) |
| 4316 | ;; |
| 4317 | esac |
| 4318 | |
| 4319 | |
| 4320 | dnl This won't be used automatically yet. We also need to know, at least, |
| 4321 | dnl that the stack is continuous. |
| 4322 | AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all |
| 4323 | registers relevant for conservative garbage collection in the jmp_buf.]) |
| 4324 | |
| 4325 | |
| 4326 | case $opsys in |
| 4327 | dnl Not all the architectures are tested, but there are Debian packages |
| 4328 | dnl for SCM and/or Guile on them, so the technique must work. See also |
| 4329 | dnl comments in alloc.c concerning setjmp and gcc. |
| 4330 | dnl Fixme: it's probably safe to just use the GCC conditional below. |
| 4331 | gnu-linux | gnu-kfreebsd ) |
| 4332 | AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[ |
| 4333 | #if defined __i386__ || defined __sparc__ || defined __mc68000__ \ |
| 4334 | || defined __alpha__ || defined __mips__ || defined __s390__ \ |
| 4335 | || defined __arm__ || defined __powerpc__ || defined __amd64__ \ |
| 4336 | || defined __ia64__ || defined __sh__ |
| 4337 | /* ok */ |
| 4338 | #else |
| 4339 | # error "setjmp not known to work on this arch" |
| 4340 | #endif |
| 4341 | ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1)) |
| 4342 | ;; |
| 4343 | esac |
| 4344 | |
| 4345 | |
| 4346 | if test x$GCC = xyes; then |
| 4347 | dnl GC_SETJMP_WORKS is nearly always appropriate for GCC. |
| 4348 | AC_DEFINE(GC_SETJMP_WORKS, 1) |
| 4349 | else |
| 4350 | case $opsys in |
| 4351 | dnl irix: Tested on Irix 6.5. SCM worked on earlier versions. |
| 4352 | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* ) |
| 4353 | AC_DEFINE(GC_SETJMP_WORKS, 1) |
| 4354 | ;; |
| 4355 | esac |
| 4356 | fi dnl GCC? |
| 4357 | |
| 4358 | dnl In a weird quirk, MS runtime uses _setjmp and longjmp. |
| 4359 | AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp], |
| 4360 | [AC_LINK_IFELSE( |
| 4361 | [AC_LANG_PROGRAM( |
| 4362 | [[#include <setjmp.h> |
| 4363 | #ifdef __MINGW32__ |
| 4364 | # define _longjmp longjmp |
| 4365 | #endif |
| 4366 | ]], |
| 4367 | [[jmp_buf j; |
| 4368 | if (! _setjmp (j)) |
| 4369 | _longjmp (j, 1);]])], |
| 4370 | [emacs_cv_func__setjmp=yes], |
| 4371 | [emacs_cv_func__setjmp=no])]) |
| 4372 | if test $emacs_cv_func__setjmp = yes; then |
| 4373 | AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.]) |
| 4374 | else |
| 4375 | AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp], |
| 4376 | [AC_LINK_IFELSE( |
| 4377 | [AC_LANG_PROGRAM( |
| 4378 | [[#include <setjmp.h> |
| 4379 | ]], |
| 4380 | [[sigjmp_buf j; |
| 4381 | if (! sigsetjmp (j, 1)) |
| 4382 | siglongjmp (j, 1);]])], |
| 4383 | [emacs_cv_func_sigsetjmp=yes], |
| 4384 | [emacs_cv_func_sigsetjmp=no])]) |
| 4385 | if test $emacs_cv_func_sigsetjmp = yes; then |
| 4386 | AC_DEFINE([HAVE_SIGSETJMP], 1, |
| 4387 | [Define to 1 if sigsetjmp and siglongjmp work. |
| 4388 | The value of this symbol is irrelevant if HAVE__SETJMP is defined.]) |
| 4389 | fi |
| 4390 | fi |
| 4391 | |
| 4392 | case $opsys in |
| 4393 | sol2* | unixware ) |
| 4394 | dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY |
| 4395 | dnl subprocesses the usual way. But TIOCSIGNAL does work for PTYs, |
| 4396 | dnl and this is all we need. |
| 4397 | AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.]) |
| 4398 | ;; |
| 4399 | esac |
| 4400 | |
| 4401 | |
| 4402 | case $opsys in |
| 4403 | hpux* | sol2* ) |
| 4404 | dnl Used in xfaces.c. |
| 4405 | AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on |
| 4406 | some systems, where it requires time.h.]) |
| 4407 | ;; |
| 4408 | esac |
| 4409 | |
| 4410 | |
| 4411 | dnl Define symbols to identify the version of Unix this is. |
| 4412 | dnl Define all the symbols that apply correctly. |
| 4413 | AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.]) |
| 4414 | AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.]) |
| 4415 | AH_TEMPLATE(USG, [Define if the system is compatible with System III.]) |
| 4416 | AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.]) |
| 4417 | |
| 4418 | case $opsys in |
| 4419 | aix4-2) |
| 4420 | AC_DEFINE(USG, []) |
| 4421 | dnl This symbol should be defined on AIX Version 3 ??????? |
| 4422 | AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[ |
| 4423 | #ifndef _AIX |
| 4424 | # error "_AIX not defined" |
| 4425 | #endif |
| 4426 | ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.])) |
| 4427 | ;; |
| 4428 | |
| 4429 | cygwin) |
| 4430 | AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.]) |
| 4431 | ;; |
| 4432 | |
| 4433 | darwin) |
| 4434 | dnl Not __APPLE__, as this may not be defined on non-OSX Darwin. |
| 4435 | dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to |
| 4436 | dnl distinguish OS X from pure Darwin. |
| 4437 | AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.]) |
| 4438 | ;; |
| 4439 | |
| 4440 | gnu-linux | gnu-kfreebsd ) |
| 4441 | AC_DEFINE(USG, []) |
| 4442 | AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.]) |
| 4443 | ;; |
| 4444 | |
| 4445 | hpux*) |
| 4446 | AC_DEFINE(USG, []) |
| 4447 | AC_DEFINE(HPUX, [], [Define if the system is HPUX.]) |
| 4448 | ;; |
| 4449 | |
| 4450 | irix6-5) |
| 4451 | AC_DEFINE(USG, []) |
| 4452 | AC_DEFINE(USG5_4, []) |
| 4453 | AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.]) |
| 4454 | ;; |
| 4455 | |
| 4456 | mingw32) |
| 4457 | AC_DEFINE(DOS_NT, []) |
| 4458 | AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.]) |
| 4459 | if test "x$ac_enable_checking" != "x" ; then |
| 4460 | AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.]) |
| 4461 | fi |
| 4462 | ;; |
| 4463 | |
| 4464 | sol2*) |
| 4465 | AC_DEFINE(USG, []) |
| 4466 | AC_DEFINE(USG5_4, []) |
| 4467 | AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.]) |
| 4468 | ;; |
| 4469 | |
| 4470 | unixware) |
| 4471 | AC_DEFINE(USG, []) |
| 4472 | AC_DEFINE(USG5_4, []) |
| 4473 | ;; |
| 4474 | esac |
| 4475 | |
| 4476 | AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD], |
| 4477 | [case $opsys in |
| 4478 | aix4-2) |
| 4479 | dnl BUILD 9008 - FIONREAD problem still exists in X-Windows. |
| 4480 | emacs_cv_usable_FIONREAD=no |
| 4481 | ;; |
| 4482 | |
| 4483 | mingw32) |
| 4484 | emacs_cv_usable_FIONREAD=yes |
| 4485 | ;; |
| 4486 | |
| 4487 | *) |
| 4488 | AC_COMPILE_IFELSE( |
| 4489 | [AC_LANG_PROGRAM([[#include <sys/types.h> |
| 4490 | #include <sys/ioctl.h> |
| 4491 | #ifdef USG5_4 |
| 4492 | # include <sys/filio.h> |
| 4493 | #endif |
| 4494 | ]], |
| 4495 | [[int foo = ioctl (0, FIONREAD, &foo);]])], |
| 4496 | [emacs_cv_usable_FIONREAD=yes], |
| 4497 | [emacs_cv_usable_FIONREAD=no]) |
| 4498 | ;; |
| 4499 | esac]) |
| 4500 | if test $emacs_cv_usable_FIONREAD = yes; then |
| 4501 | AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.]) |
| 4502 | |
| 4503 | if test $emacs_broken_SIGIO = no; then |
| 4504 | AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO], |
| 4505 | [AC_COMPILE_IFELSE( |
| 4506 | [AC_LANG_PROGRAM([[#include <fcntl.h> |
| 4507 | #include <signal.h> |
| 4508 | ]], |
| 4509 | [[int foo = SIGIO | F_SETFL | FASYNC;]])], |
| 4510 | [emacs_cv_usable_SIGIO=yes], |
| 4511 | [emacs_cv_usable_SIGIO=no])], |
| 4512 | [emacs_cv_usable_SIGIO=yes], |
| 4513 | [emacs_cv_usable_SIGIO=no]) |
| 4514 | if test $emacs_cv_usable_SIGIO = yes; then |
| 4515 | AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.]) |
| 4516 | fi |
| 4517 | fi |
| 4518 | fi |
| 4519 | |
| 4520 | |
| 4521 | case $opsys in |
| 4522 | dnl Emacs supplies its own malloc, but glib calls posix_memalign, |
| 4523 | dnl and on Cygwin prior to version 1.7.24 that becomes the |
| 4524 | dnl Cygwin-supplied posix_memalign. As malloc is not the Cygwin |
| 4525 | dnl malloc, the Cygwin posix_memalign always returns ENOSYS. A |
| 4526 | dnl workaround is to set G_SLICE=always-malloc. This is no longer |
| 4527 | dnl needed starting with cygwin-1.7.24, and it is no longer |
| 4528 | dnl effective starting with glib-2.36. */ |
| 4529 | cygwin) |
| 4530 | AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the |
| 4531 | G_SLICE environment variable to "always-malloc" at startup.]) |
| 4532 | ;; |
| 4533 | |
| 4534 | hpux11) |
| 4535 | dnl It works to open the pty's tty in the parent (Emacs), then |
| 4536 | dnl close and reopen it in the child. |
| 4537 | AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it |
| 4538 | works to open a pty's tty in the parent process, then close and |
| 4539 | reopen it in the child.]) |
| 4540 | ;; |
| 4541 | |
| 4542 | irix6-5) |
| 4543 | AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should |
| 4544 | use VSUSP instead of VSWTCH.]) |
| 4545 | ;; |
| 4546 | |
| 4547 | sol2-10) |
| 4548 | AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes |
| 4549 | on Solaris.]) |
| 4550 | ;; |
| 4551 | esac |
| 4552 | |
| 4553 | # Set up the CFLAGS for real compilation, so we can substitute it. |
| 4554 | CFLAGS="$REAL_CFLAGS" |
| 4555 | CPPFLAGS="$REAL_CPPFLAGS" |
| 4556 | |
| 4557 | ## Hack to detect a buggy GCC version. |
| 4558 | if test "x$GCC" = xyes \ |
| 4559 | && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \ |
| 4560 | && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \ |
| 4561 | && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then |
| 4562 | AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.]) |
| 4563 | fi |
| 4564 | |
| 4565 | version=$PACKAGE_VERSION |
| 4566 | |
| 4567 | copyright="Copyright (C) 2014 Free Software Foundation, Inc." |
| 4568 | AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"], |
| 4569 | [Short copyright string for this version of Emacs.]) |
| 4570 | AC_SUBST(copyright) |
| 4571 | |
| 4572 | ### Specify what sort of things we'll be editing into Makefile and config.h. |
| 4573 | ### Use configuration here uncanonicalized to avoid exceeding size limits. |
| 4574 | AC_SUBST(version) |
| 4575 | AC_SUBST(configuration) |
| 4576 | ## Unused? |
| 4577 | AC_SUBST(canonical) |
| 4578 | AC_SUBST(srcdir) |
| 4579 | AC_SUBST(prefix) |
| 4580 | AC_SUBST(exec_prefix) |
| 4581 | AC_SUBST(bindir) |
| 4582 | AC_SUBST(datadir) |
| 4583 | AC_SUBST(sharedstatedir) |
| 4584 | AC_SUBST(libexecdir) |
| 4585 | AC_SUBST(mandir) |
| 4586 | AC_SUBST(infodir) |
| 4587 | AC_SUBST(lispdir) |
| 4588 | AC_SUBST(standardlisppath) |
| 4589 | AC_SUBST(locallisppath) |
| 4590 | AC_SUBST(lisppath) |
| 4591 | AC_SUBST(x_default_search_path) |
| 4592 | AC_SUBST(etcdir) |
| 4593 | AC_SUBST(archlibdir) |
| 4594 | AC_SUBST(etcdocdir) |
| 4595 | AC_SUBST(bitmapdir) |
| 4596 | AC_SUBST(gamedir) |
| 4597 | AC_SUBST(gameuser) |
| 4598 | ## FIXME? Nothing uses @LD_SWITCH_X_SITE@. |
| 4599 | ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the |
| 4600 | ## end of LIBX_BASE, but nothing ever set it. |
| 4601 | AC_SUBST(LD_SWITCH_X_SITE) |
| 4602 | AC_SUBST(C_SWITCH_X_SITE) |
| 4603 | AC_SUBST(GNUSTEP_CFLAGS) |
| 4604 | AC_SUBST(CFLAGS) |
| 4605 | ## Used in lwlib/Makefile.in. |
| 4606 | AC_SUBST(X_TOOLKIT_TYPE) |
| 4607 | AC_SUBST(ns_appdir) |
| 4608 | AC_SUBST(ns_appbindir) |
| 4609 | AC_SUBST(ns_appresdir) |
| 4610 | AC_SUBST(ns_appsrc) |
| 4611 | AC_SUBST(GNU_OBJC_CFLAGS) |
| 4612 | AC_SUBST(OTHER_FILES) |
| 4613 | |
| 4614 | if test -n "${term_header}"; then |
| 4615 | AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}", |
| 4616 | [Define to the header for the built-in window system.]) |
| 4617 | fi |
| 4618 | |
| 4619 | AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}", |
| 4620 | [Define to the canonical Emacs configuration name.]) |
| 4621 | AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}", |
| 4622 | [Define to the options passed to configure.]) |
| 4623 | AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure |
| 4624 | define this to include extra configuration information.]) |
| 4625 | |
| 4626 | case $opsys in |
| 4627 | mingw32) |
| 4628 | AC_DEFINE(config_opsysfile, <ms-w32.h>, []) |
| 4629 | ;; |
| 4630 | esac |
| 4631 | |
| 4632 | XMENU_OBJ= |
| 4633 | XOBJ= |
| 4634 | FONT_OBJ= |
| 4635 | if test "${HAVE_X_WINDOWS}" = "yes" ; then |
| 4636 | AC_DEFINE(HAVE_X_WINDOWS, 1, |
| 4637 | [Define to 1 if you want to use the X window system.]) |
| 4638 | XMENU_OBJ=xmenu.o |
| 4639 | XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o" |
| 4640 | FONT_OBJ=xfont.o |
| 4641 | if test "$HAVE_XFT" = "yes"; then |
| 4642 | FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o" |
| 4643 | elif test "$HAVE_FREETYPE" = "yes"; then |
| 4644 | FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o" |
| 4645 | fi |
| 4646 | AC_SUBST(FONT_OBJ) |
| 4647 | fi |
| 4648 | AC_SUBST(XMENU_OBJ) |
| 4649 | AC_SUBST(XOBJ) |
| 4650 | AC_SUBST(FONT_OBJ) |
| 4651 | |
| 4652 | WIDGET_OBJ= |
| 4653 | MOTIF_LIBW= |
| 4654 | if test "${USE_X_TOOLKIT}" != "none" ; then |
| 4655 | WIDGET_OBJ=widget.o |
| 4656 | AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.]) |
| 4657 | if test "${USE_X_TOOLKIT}" = "LUCID"; then |
| 4658 | AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.]) |
| 4659 | elif test "${USE_X_TOOLKIT}" = "MOTIF"; then |
| 4660 | AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.]) |
| 4661 | MOTIF_LIBW=-lXm |
| 4662 | case "$opsys" in |
| 4663 | gnu-linux) |
| 4664 | ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed. |
| 4665 | MOTIF_LIBW="$MOTIF_LIBW -lXpm" |
| 4666 | ;; |
| 4667 | |
| 4668 | unixware) |
| 4669 | ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov> |
| 4670 | ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2. |
| 4671 | MOTIF_LIBW="MOTIF_LIBW -lXimp" |
| 4672 | ;; |
| 4673 | |
| 4674 | aix4-2) |
| 4675 | ## olson@mcs.anl.gov says -li18n is needed by -lXm. |
| 4676 | MOTIF_LIBW="$MOTIF_LIBW -li18n" |
| 4677 | ;; |
| 4678 | esac |
| 4679 | MOTIF_LIBW="$MOTIF_LIBW $LIBXP" |
| 4680 | fi |
| 4681 | fi |
| 4682 | AC_SUBST(WIDGET_OBJ) |
| 4683 | |
| 4684 | TOOLKIT_LIBW= |
| 4685 | case "$USE_X_TOOLKIT" in |
| 4686 | MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;; |
| 4687 | LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;; |
| 4688 | none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;; |
| 4689 | esac |
| 4690 | AC_SUBST(TOOLKIT_LIBW) |
| 4691 | |
| 4692 | if test "${opsys}" != "mingw32"; then |
| 4693 | if test "$USE_X_TOOLKIT" = "none"; then |
| 4694 | LIBXT_OTHER="\$(LIBXSM)" |
| 4695 | else |
| 4696 | LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext" |
| 4697 | fi |
| 4698 | fi |
| 4699 | AC_SUBST(LIBXT_OTHER) |
| 4700 | |
| 4701 | if test "${HAVE_X11}" = "yes" ; then |
| 4702 | AC_DEFINE(HAVE_X11, 1, |
| 4703 | [Define to 1 if you want to use version 11 of X windows.]) |
| 4704 | LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)" |
| 4705 | else |
| 4706 | LIBX_OTHER= |
| 4707 | fi |
| 4708 | AC_SUBST(LIBX_OTHER) |
| 4709 | |
| 4710 | if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then |
| 4711 | LIBXMENU= |
| 4712 | elif test "$USE_X_TOOLKIT" = none; then |
| 4713 | LIBXMENU='$(oldXMenudir)/libXMenu11.a' |
| 4714 | else |
| 4715 | LIBXMENU='$(lwlibdir)/liblw.a' |
| 4716 | fi |
| 4717 | AC_SUBST(LIBXMENU) |
| 4718 | |
| 4719 | if test "${GNU_MALLOC}" = "yes" ; then |
| 4720 | AC_DEFINE(GNU_MALLOC, 1, |
| 4721 | [Define to 1 if you want to use the GNU memory allocator.]) |
| 4722 | fi |
| 4723 | |
| 4724 | RALLOC_OBJ= |
| 4725 | if test "${REL_ALLOC}" = "yes" ; then |
| 4726 | AC_DEFINE(REL_ALLOC, 1, |
| 4727 | [Define REL_ALLOC if you want to use the relocating allocator for |
| 4728 | buffer space.]) |
| 4729 | |
| 4730 | test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o |
| 4731 | fi |
| 4732 | AC_SUBST(RALLOC_OBJ) |
| 4733 | |
| 4734 | if test "$opsys" = "cygwin"; then |
| 4735 | CYGWIN_OBJ="sheap.o cygw32.o" |
| 4736 | ## Cygwin differs because of its unexec(). |
| 4737 | PRE_ALLOC_OBJ= |
| 4738 | POST_ALLOC_OBJ=lastfile.o |
| 4739 | elif test "$opsys" = "mingw32"; then |
| 4740 | CYGWIN_OBJ= |
| 4741 | PRE_ALLOC_OBJ= |
| 4742 | POST_ALLOC_OBJ=lastfile.o |
| 4743 | else |
| 4744 | CYGWIN_OBJ= |
| 4745 | PRE_ALLOC_OBJ=lastfile.o |
| 4746 | POST_ALLOC_OBJ= |
| 4747 | fi |
| 4748 | AC_SUBST(CYGWIN_OBJ) |
| 4749 | AC_SUBST(PRE_ALLOC_OBJ) |
| 4750 | AC_SUBST(POST_ALLOC_OBJ) |
| 4751 | |
| 4752 | dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE' |
| 4753 | dnl verbatim defined above. The tricky name is apropos, as this hack |
| 4754 | dnl makes Fortify go sour! |
| 4755 | AH_VERBATIM([FORTIFY_SOUR], |
| 4756 | [/* Without the following workaround, Emacs runs slowly on OS X 10.8. |
| 4757 | The workaround disables some useful run-time checking, so it |
| 4758 | should be conditional to the platforms with the performance bug. |
| 4759 | Perhaps Apple will fix this some day; also see m4/extern-inline.m4. */ |
| 4760 | #if defined __APPLE__ && defined __GNUC__ |
| 4761 | # ifndef _DONT_USE_CTYPE_INLINE_ |
| 4762 | # define _DONT_USE_CTYPE_INLINE_ |
| 4763 | # endif |
| 4764 | # ifndef _FORTIFY_SOURCE |
| 4765 | # define _FORTIFY_SOURCE 0 |
| 4766 | # endif |
| 4767 | #endif |
| 4768 | ]) |
| 4769 | |
| 4770 | # Configure gnulib. Although this does not affect CFLAGS or LIBS permanently. |
| 4771 | # it temporarily reverts them to their pre-pkg-config values, |
| 4772 | # because gnulib needs to work with both src (which uses the |
| 4773 | # pkg-config stuff) and lib-src (which does not). For example, gnulib |
| 4774 | # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt, |
| 4775 | # and it therefore needs to run in an environment where LIBS does not |
| 4776 | # already contain -lrt merely because 'pkg-config --libs' printed '-lrt' |
| 4777 | # for some package unrelated to lib-src. |
| 4778 | SAVE_CFLAGS=$CFLAGS |
| 4779 | SAVE_LIBS=$LIBS |
| 4780 | CFLAGS=$pre_PKG_CONFIG_CFLAGS |
| 4781 | LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS" |
| 4782 | gl_ASSERT_NO_GNULIB_POSIXCHECK |
| 4783 | gl_ASSERT_NO_GNULIB_TESTS |
| 4784 | gl_INIT |
| 4785 | CFLAGS=$SAVE_CFLAGS |
| 4786 | LIBS=$SAVE_LIBS |
| 4787 | |
| 4788 | if test "${opsys}" = "mingw32"; then |
| 4789 | CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc" |
| 4790 | # Remove unneeded switches from the value of CC that goes to Makefiles |
| 4791 | CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"` |
| 4792 | fi |
| 4793 | |
| 4794 | case "$opsys" in |
| 4795 | aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;; |
| 4796 | |
| 4797 | darwin) |
| 4798 | ## The -headerpad option tells ld (see man page) to leave room at the |
| 4799 | ## end of the header for adding load commands. Needed for dumping. |
| 4800 | ## 0x690 is the total size of 30 segment load commands (at 56 |
| 4801 | ## each); under Cocoa 31 commands are required. |
| 4802 | if test "$HAVE_NS" = "yes"; then |
| 4803 | libs_nsgui="-framework AppKit" |
| 4804 | if test "$NS_IMPL_COCOA" = "yes"; then |
| 4805 | libs_nsgui="$libs_nsgui -framework IOKit" |
| 4806 | fi |
| 4807 | headerpad_extra=6C8 |
| 4808 | else |
| 4809 | libs_nsgui= |
| 4810 | headerpad_extra=690 |
| 4811 | fi |
| 4812 | LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra" |
| 4813 | |
| 4814 | ## This is here because src/Makefile.in did some extra fiddling around |
| 4815 | ## with LD_SWITCH_SYSTEM. It seems cleaner to put this in |
| 4816 | ## LD_SWITCH_SYSTEM_TEMACS instead, |
| 4817 | test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \ |
| 4818 | LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS" |
| 4819 | ;; |
| 4820 | |
| 4821 | ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to |
| 4822 | ## find X at run-time. |
| 4823 | ## When handled by cpp, this was in LD_SWITCH_SYSTEM. However, at the |
| 4824 | ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH |
| 4825 | ## had not yet been defined and was expanded to null. Hence LD_SWITCH_SYSTEM |
| 4826 | ## had different values in configure (in ac_link) and src/Makefile.in. |
| 4827 | ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS. |
| 4828 | gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;; |
| 4829 | |
| 4830 | mingw32) |
| 4831 | ## MinGW64 does not prepend an underscore to symbols, so we must |
| 4832 | ## pass a different -entry switch to linker. FIXME: It is better |
| 4833 | ## to make the entry points the same by changing unexw32.c. |
| 4834 | case "$canonical" in |
| 4835 | x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;; |
| 4836 | *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;; |
| 4837 | esac |
| 4838 | ;; |
| 4839 | |
| 4840 | openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;; |
| 4841 | |
| 4842 | *) LD_SWITCH_SYSTEM_TEMACS= ;; |
| 4843 | esac |
| 4844 | |
| 4845 | if test x$ac_enable_profiling != x ; then |
| 4846 | case $opsys in |
| 4847 | *freebsd | gnu-linux) ;; |
| 4848 | *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;; |
| 4849 | esac |
| 4850 | fi |
| 4851 | |
| 4852 | LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS" |
| 4853 | |
| 4854 | AC_SUBST(LD_SWITCH_SYSTEM_TEMACS) |
| 4855 | |
| 4856 | ## MinGW-specific post-link processing of temacs. |
| 4857 | TEMACS_POST_LINK=":" |
| 4858 | ADDSECTION= |
| 4859 | EMACS_HEAPSIZE= |
| 4860 | if test "${opsys}" = "mingw32"; then |
| 4861 | TEMACS_POST_LINK="\$(MINGW_TEMACS_POST_LINK)" |
| 4862 | ADDSECTION="../nt/addsection\$(EXEEXT)" |
| 4863 | ## Preload heap size of temacs.exe in MB. |
| 4864 | case "$canonical" in |
| 4865 | x86_64-*-*) EMACS_HEAPSIZE=42 ;; |
| 4866 | *) EMACS_HEAPSIZE=27 ;; |
| 4867 | esac |
| 4868 | fi |
| 4869 | |
| 4870 | AC_SUBST(ADDSECTION) |
| 4871 | AC_SUBST(TEMACS_POST_LINK) |
| 4872 | AC_SUBST(EMACS_HEAPSIZE) |
| 4873 | |
| 4874 | ## Common for all window systems |
| 4875 | if test "$window_system" != "none"; then |
| 4876 | AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.]) |
| 4877 | WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o" |
| 4878 | fi |
| 4879 | |
| 4880 | AC_SUBST(WINDOW_SYSTEM_OBJ) |
| 4881 | |
| 4882 | AH_TOP([/* GNU Emacs site configuration template file. |
| 4883 | |
| 4884 | Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2014 |
| 4885 | Free Software Foundation, Inc. |
| 4886 | |
| 4887 | This file is part of GNU Emacs. |
| 4888 | |
| 4889 | GNU Emacs is free software: you can redistribute it and/or modify |
| 4890 | it under the terms of the GNU General Public License as published by |
| 4891 | the Free Software Foundation, either version 3 of the License, or |
| 4892 | (at your option) any later version. |
| 4893 | |
| 4894 | GNU Emacs is distributed in the hope that it will be useful, |
| 4895 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 4896 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 4897 | GNU General Public License for more details. |
| 4898 | |
| 4899 | You should have received a copy of the GNU General Public License |
| 4900 | along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. */ |
| 4901 | |
| 4902 | |
| 4903 | /* No code in Emacs #includes config.h twice, but some bits of code |
| 4904 | intended to work with other packages as well (like gmalloc.c) |
| 4905 | think they can include it as many times as they like. */ |
| 4906 | #ifndef EMACS_CONFIG_H |
| 4907 | #define EMACS_CONFIG_H |
| 4908 | ])dnl |
| 4909 | |
| 4910 | AH_BOTTOM([#include <conf_post.h> |
| 4911 | |
| 4912 | #endif /* EMACS_CONFIG_H */ |
| 4913 | |
| 4914 | /* |
| 4915 | Local Variables: |
| 4916 | mode: c |
| 4917 | End: |
| 4918 | */ |
| 4919 | ])dnl |
| 4920 | |
| 4921 | #### Report on what we decided to do. |
| 4922 | #### Report GTK as a toolkit, even if it doesn't use Xt. |
| 4923 | #### It makes printing result more understandable as using GTK sets |
| 4924 | #### toolkit_scroll_bars to yes by default. |
| 4925 | if test "${HAVE_GTK}" = "yes"; then |
| 4926 | USE_X_TOOLKIT="$USE_GTK_TOOLKIT" |
| 4927 | fi |
| 4928 | |
| 4929 | if test $USE_ACL -ne 0; then |
| 4930 | acl_summary="yes $LIB_ACL" |
| 4931 | else |
| 4932 | acl_summary=no |
| 4933 | fi |
| 4934 | |
| 4935 | echo " |
| 4936 | Configured for \`${canonical}'. |
| 4937 | |
| 4938 | Where should the build process find the source code? ${srcdir} |
| 4939 | What compiler should emacs be built with? ${CC} ${CFLAGS} |
| 4940 | Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason} |
| 4941 | Should Emacs use a relocating allocator for buffers? ${REL_ALLOC} |
| 4942 | Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers |
| 4943 | What window system should Emacs use? ${window_system} |
| 4944 | What toolkit should Emacs use? ${USE_X_TOOLKIT}" |
| 4945 | |
| 4946 | if test -n "${x_includes}"; then |
| 4947 | echo " Where do we find X Windows header files? ${x_includes}" |
| 4948 | else |
| 4949 | echo " Where do we find X Windows header files? Standard dirs" |
| 4950 | fi |
| 4951 | if test -n "${x_libraries}"; then |
| 4952 | echo " Where do we find X Windows libraries? ${x_libraries}" |
| 4953 | else |
| 4954 | echo " Where do we find X Windows libraries? Standard dirs" |
| 4955 | fi |
| 4956 | |
| 4957 | echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}" |
| 4958 | echo " Does Emacs use -lXpm? ${HAVE_XPM}" |
| 4959 | echo " Does Emacs use -ljpeg? ${HAVE_JPEG}" |
| 4960 | echo " Does Emacs use -ltiff? ${HAVE_TIFF}" |
| 4961 | echo " Does Emacs use a gif library? ${HAVE_GIF} $LIBGIF" |
| 4962 | echo " Does Emacs use -lpng? ${HAVE_PNG}" |
| 4963 | echo " Does Emacs use -lrsvg-2? ${HAVE_RSVG}" |
| 4964 | echo " Does Emacs use imagemagick? ${HAVE_IMAGEMAGICK}" |
| 4965 | |
| 4966 | echo " Does Emacs support sound? ${HAVE_SOUND}" |
| 4967 | |
| 4968 | echo " Does Emacs use -lgpm? ${HAVE_GPM}" |
| 4969 | echo " Does Emacs use -ldbus? ${HAVE_DBUS}" |
| 4970 | echo " Does Emacs use -lgconf? ${HAVE_GCONF}" |
| 4971 | echo " Does Emacs use GSettings? ${HAVE_GSETTINGS}" |
| 4972 | echo " Does Emacs use a file notification library? ${NOTIFY_SUMMARY}" |
| 4973 | echo " Does Emacs use access control lists? ${acl_summary}" |
| 4974 | echo " Does Emacs use -lselinux? ${HAVE_LIBSELINUX}" |
| 4975 | echo " Does Emacs use -lgnutls? ${HAVE_GNUTLS}" |
| 4976 | echo " Does Emacs use -lxml2? ${HAVE_LIBXML2}" |
| 4977 | |
| 4978 | echo " Does Emacs use -lfreetype? ${HAVE_FREETYPE}" |
| 4979 | echo " Does Emacs use -lm17n-flt? ${HAVE_M17N_FLT}" |
| 4980 | echo " Does Emacs use -lotf? ${HAVE_LIBOTF}" |
| 4981 | echo " Does Emacs use -lxft? ${HAVE_XFT}" |
| 4982 | echo " Does Emacs directly use zlib? ${HAVE_ZLIB}" |
| 4983 | |
| 4984 | echo " Does Emacs use toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}" |
| 4985 | echo |
| 4986 | |
| 4987 | if test -n "${EMACSDATA}"; then |
| 4988 | echo " Environment variable EMACSDATA set to: $EMACSDATA" |
| 4989 | fi |
| 4990 | if test -n "${EMACSDOC}"; then |
| 4991 | echo " Environment variable EMACSDOC set to: $EMACSDOC" |
| 4992 | fi |
| 4993 | |
| 4994 | echo |
| 4995 | |
| 4996 | if test "$HAVE_NS" = "yes"; then |
| 4997 | echo |
| 4998 | echo "You must run \"${MAKE-make} install\" in order to test the built application. |
| 4999 | The installed application will go to nextstep/Emacs.app and can be |
| 5000 | run or moved from there." |
| 5001 | if test "$EN_NS_SELF_CONTAINED" = "yes"; then |
| 5002 | echo "The application will be fully self-contained." |
| 5003 | else |
| 5004 | echo "The lisp resources for the application will be installed under ${prefix}. |
| 5005 | You may need to run \"${MAKE-make} install\" with sudo. The application will fail |
| 5006 | to run if these resources are not installed." |
| 5007 | fi |
| 5008 | echo |
| 5009 | fi |
| 5010 | |
| 5011 | if test "${opsys}" = "cygwin"; then |
| 5012 | case `uname -r` in |
| 5013 | 1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]]) |
| 5014 | echo |
| 5015 | ;; |
| 5016 | esac |
| 5017 | fi |
| 5018 | |
| 5019 | # Remove any trailing slashes in these variables. |
| 5020 | [test "${prefix}" != NONE && |
| 5021 | prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'` |
| 5022 | test "${exec_prefix}" != NONE && |
| 5023 | exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`] |
| 5024 | |
| 5025 | if test "$HAVE_NS" = "yes"; then |
| 5026 | if test "$NS_IMPL_GNUSTEP" = yes; then |
| 5027 | AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \ |
| 5028 | nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in]) |
| 5029 | ns_check_file=Resources/Info-gnustep.plist |
| 5030 | else |
| 5031 | AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \ |
| 5032 | nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in]) |
| 5033 | ns_check_file=Contents/Info.plist |
| 5034 | fi |
| 5035 | AC_SUBST(ns_check_file) |
| 5036 | fi |
| 5037 | |
| 5038 | dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES. |
| 5039 | dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory |
| 5040 | dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable |
| 5041 | dnl (else you get "no `Makefile.am' found for any configure output"). |
| 5042 | dnl This will work, but you get a config.status that is not quite right |
| 5043 | dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html). |
| 5044 | dnl That doesn't have any obvious consequences for Emacs, but on the whole |
| 5045 | dnl it seems better to just live with the duplication. |
| 5046 | SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile" |
| 5047 | |
| 5048 | AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \ |
| 5049 | doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \ |
| 5050 | doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \ |
| 5051 | leim/Makefile nextstep/Makefile nt/Makefile]) |
| 5052 | |
| 5053 | dnl test/ is not present in release tarfiles. |
| 5054 | opt_makefile=test/automated/Makefile |
| 5055 | |
| 5056 | if test -f "$srcdir/$opt_makefile.in"; then |
| 5057 | SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile" |
| 5058 | dnl Again, it's best not to use a variable. Though you can add |
| 5059 | dnl ", [], [opt_makefile='$opt_makefile']" and it should work. |
| 5060 | AC_CONFIG_FILES([test/automated/Makefile]) |
| 5061 | fi |
| 5062 | |
| 5063 | |
| 5064 | dnl The admin/ directory used to be excluded from tarfiles. |
| 5065 | if test -d $srcdir/admin; then |
| 5066 | SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile" |
| 5067 | AC_CONFIG_FILES([admin/unidata/Makefile]) |
| 5068 | AC_CONFIG_FILES([admin/grammars/Makefile]) |
| 5069 | fi dnl -d admin |
| 5070 | |
| 5071 | |
| 5072 | SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'` |
| 5073 | |
| 5074 | AC_SUBST(SUBDIR_MAKEFILES_IN) |
| 5075 | |
| 5076 | dnl You might wonder (I did) why epaths.h is generated by running make, |
| 5077 | dnl rather than just letting configure generate it from epaths.in. |
| 5078 | dnl One reason is that the various paths are not fully expanded (see above); |
| 5079 | dnl eg gamedir=${prefix}/var/games/emacs. |
| 5080 | dnl Secondly, the GNU Coding standards require that one should be able |
| 5081 | dnl to run `make prefix=/some/where/else' and override the values set |
| 5082 | dnl by configure. This also explains the `move-if-change' test and |
| 5083 | dnl the use of force in the `epaths-force' rule in Makefile.in. |
| 5084 | AC_CONFIG_COMMANDS([src/epaths.h], [ |
| 5085 | if test "${opsys}" = "mingw32"; then |
| 5086 | ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32 |
| 5087 | else |
| 5088 | ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force |
| 5089 | fi |
| 5090 | ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"]) |
| 5091 | |
| 5092 | dnl NB we have to cheat and use the ac_... version because abs_top_srcdir |
| 5093 | dnl is not yet set, sigh. Or we could use ../$srcdir/src/.gdbinit, |
| 5094 | dnl or a symlink? |
| 5095 | AC_CONFIG_COMMANDS([src/.gdbinit], [ |
| 5096 | if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then |
| 5097 | echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit |
| 5098 | fi |
| 5099 | ]) |
| 5100 | |
| 5101 | AC_OUTPUT |