| 1 | ;;; picture.el --- "Picture mode" -- editing using quarter-plane screen model |
| 2 | |
| 3 | ;; Copyright (C) 1985, 1994, 2001-2012 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Author: K. Shane Hartman |
| 6 | ;; Maintainer: FSF |
| 7 | ;; Keywords: convenience wp |
| 8 | |
| 9 | ;; This file is part of GNU Emacs. |
| 10 | |
| 11 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 12 | ;; it under the terms of the GNU General Public License as published by |
| 13 | ;; the Free Software Foundation, either version 3 of the License, or |
| 14 | ;; (at your option) any later version. |
| 15 | |
| 16 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 17 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 18 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 19 | ;; GNU General Public License for more details. |
| 20 | |
| 21 | ;; You should have received a copy of the GNU General Public License |
| 22 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 23 | |
| 24 | ;;; Commentary: |
| 25 | |
| 26 | ;; This code provides the picture-mode commands documented in the Emacs |
| 27 | ;; manual. The screen is treated as a semi-infinite quarter-plane with |
| 28 | ;; support for rectangle operations and `etch-a-sketch' character |
| 29 | ;; insertion in any of eight directions. |
| 30 | |
| 31 | ;;; Code: |
| 32 | |
| 33 | (defgroup picture nil |
| 34 | "Picture mode --- editing using quarter-plane screen model." |
| 35 | :prefix "picture-" |
| 36 | :group 'wp) |
| 37 | |
| 38 | (defcustom picture-rectangle-ctl ?+ |
| 39 | "Character `picture-draw-rectangle' uses for top left corners." |
| 40 | :type 'character |
| 41 | :group 'picture) |
| 42 | (defcustom picture-rectangle-ctr ?+ |
| 43 | "Character `picture-draw-rectangle' uses for top right corners." |
| 44 | :type 'character |
| 45 | :group 'picture) |
| 46 | (defcustom picture-rectangle-cbr ?+ |
| 47 | "Character `picture-draw-rectangle' uses for bottom right corners." |
| 48 | :type 'character |
| 49 | :group 'picture) |
| 50 | (defcustom picture-rectangle-cbl ?+ |
| 51 | "Character `picture-draw-rectangle' uses for bottom left corners." |
| 52 | :type 'character |
| 53 | :group 'picture) |
| 54 | (defcustom picture-rectangle-v ?| |
| 55 | "Character `picture-draw-rectangle' uses for vertical lines." |
| 56 | :type 'character |
| 57 | :group 'picture) |
| 58 | (defcustom picture-rectangle-h ?- |
| 59 | "Character `picture-draw-rectangle' uses for horizontal lines." |
| 60 | :type 'character |
| 61 | :group 'picture) |
| 62 | |
| 63 | |
| 64 | ;; Picture Movement Commands |
| 65 | |
| 66 | ;; When a cursor is on a wide-column character (e.g. Chinese, |
| 67 | ;; Japanese, Korean), this variable tells the desired current column |
| 68 | ;; which may be different from (current-column). |
| 69 | (defvar picture-desired-column 0) |
| 70 | |
| 71 | ;; If the value of picture-desired-column is far from the current |
| 72 | ;; column, or if the arg ADJUST-TO-CURRENT is non-nil, set it to the |
| 73 | ;; current column. Return the current column. |
| 74 | (defun picture-update-desired-column (adjust-to-current) |
| 75 | (let ((current-column (current-column))) |
| 76 | (if (or adjust-to-current |
| 77 | (< picture-desired-column (1- current-column)) |
| 78 | (> picture-desired-column (1+ current-column))) |
| 79 | (setq picture-desired-column current-column)) |
| 80 | current-column)) |
| 81 | |
| 82 | (defun picture-beginning-of-line (&optional arg) |
| 83 | "Position point at the beginning of the line. |
| 84 | With ARG not nil, move forward ARG - 1 lines first. |
| 85 | If scan reaches end of buffer, stop there without error." |
| 86 | (interactive "^P") |
| 87 | (if arg (forward-line (1- (prefix-numeric-value arg)))) |
| 88 | (beginning-of-line) |
| 89 | (setq picture-desired-column 0)) |
| 90 | |
| 91 | (defun picture-end-of-line (&optional arg) |
| 92 | "Position point after last non-blank character on current line. |
| 93 | With ARG not nil, move forward ARG - 1 lines first. |
| 94 | If scan reaches end of buffer, stop there without error." |
| 95 | (interactive "^P") |
| 96 | (if arg (forward-line (1- (prefix-numeric-value arg)))) |
| 97 | (beginning-of-line) |
| 98 | (skip-chars-backward " \t" (prog1 (point) (end-of-line))) |
| 99 | (setq picture-desired-column (current-column))) |
| 100 | |
| 101 | (defun picture-forward-column (arg &optional interactive) |
| 102 | "Move cursor right, making whitespace if necessary. |
| 103 | With argument, move that many columns." |
| 104 | (interactive "^p\nd") |
| 105 | (let (deactivate-mark) |
| 106 | (picture-update-desired-column interactive) |
| 107 | (setq picture-desired-column (max 0 (+ picture-desired-column arg))) |
| 108 | (let ((current-column (move-to-column picture-desired-column t))) |
| 109 | (if (and (> current-column picture-desired-column) |
| 110 | (< arg 0)) |
| 111 | ;; It seems that we have just tried to move to the right |
| 112 | ;; column of a multi-column character. |
| 113 | (forward-char -1))))) |
| 114 | |
| 115 | (defun picture-backward-column (arg &optional interactive) |
| 116 | "Move cursor left, making whitespace if necessary. |
| 117 | With argument, move that many columns." |
| 118 | (interactive "^p\nd") |
| 119 | (picture-update-desired-column interactive) |
| 120 | (picture-forward-column (- arg))) |
| 121 | |
| 122 | (defun picture-move-down (arg) |
| 123 | "Move vertically down, making whitespace if necessary. |
| 124 | With argument, move that many lines." |
| 125 | (interactive "^p") |
| 126 | (let (deactivate-mark) |
| 127 | (picture-update-desired-column nil) |
| 128 | (picture-newline arg) |
| 129 | (let ((current-column (move-to-column picture-desired-column t))) |
| 130 | (if (> current-column picture-desired-column) |
| 131 | (forward-char -1))))) |
| 132 | |
| 133 | (defvar picture-vertical-step 0 |
| 134 | "Amount to move vertically after text character in Picture mode.") |
| 135 | |
| 136 | (defvar picture-horizontal-step 1 |
| 137 | "Amount to move horizontally after text character in Picture mode.") |
| 138 | |
| 139 | (defun picture-move-up (arg) |
| 140 | "Move vertically up, making whitespace if necessary. |
| 141 | With argument, move that many lines." |
| 142 | (interactive "^p") |
| 143 | (picture-update-desired-column nil) |
| 144 | (picture-move-down (- arg))) |
| 145 | |
| 146 | (defun picture-movement-right () |
| 147 | "Move right after self-inserting character in Picture mode." |
| 148 | (interactive) |
| 149 | (picture-set-motion 0 1)) |
| 150 | |
| 151 | (defun picture-movement-left () |
| 152 | "Move left after self-inserting character in Picture mode." |
| 153 | (interactive) |
| 154 | (picture-set-motion 0 -1)) |
| 155 | |
| 156 | (defun picture-movement-up () |
| 157 | "Move up after self-inserting character in Picture mode." |
| 158 | (interactive) |
| 159 | (picture-set-motion -1 0)) |
| 160 | |
| 161 | (defun picture-movement-down () |
| 162 | "Move down after self-inserting character in Picture mode." |
| 163 | (interactive) |
| 164 | (picture-set-motion 1 0)) |
| 165 | |
| 166 | (defun picture-movement-nw (&optional arg) |
| 167 | "Move up and left after self-inserting character in Picture mode. |
| 168 | With prefix argument, move up and two-column left." |
| 169 | (interactive "P") |
| 170 | (picture-set-motion -1 (if arg -2 -1))) |
| 171 | |
| 172 | (defun picture-movement-ne (&optional arg) |
| 173 | "Move up and right after self-inserting character in Picture mode. |
| 174 | With prefix argument, move up and two-column right." |
| 175 | (interactive "P") |
| 176 | (picture-set-motion -1 (if arg 2 1))) |
| 177 | |
| 178 | (defun picture-movement-sw (&optional arg) |
| 179 | "Move down and left after self-inserting character in Picture mode. |
| 180 | With prefix argument, move down and two-column left." |
| 181 | (interactive "P") |
| 182 | (picture-set-motion 1 (if arg -2 -1))) |
| 183 | |
| 184 | (defun picture-movement-se (&optional arg) |
| 185 | "Move down and right after self-inserting character in Picture mode. |
| 186 | With prefix argument, move down and two-column right." |
| 187 | (interactive "P") |
| 188 | (picture-set-motion 1 (if arg 2 1))) |
| 189 | |
| 190 | (defun picture-set-motion (vert horiz) |
| 191 | "Set VERTICAL and HORIZONTAL increments for movement in Picture mode. |
| 192 | The mode line is updated to reflect the current direction." |
| 193 | (setq picture-vertical-step vert |
| 194 | picture-horizontal-step horiz) |
| 195 | (setq mode-name |
| 196 | (format "Picture:%s" |
| 197 | (nth (+ 2 (% horiz 3) (* 5 (1+ (% vert 2)))) |
| 198 | '(wnw nw up ne ene Left left none right Right |
| 199 | wsw sw down se ese)))) |
| 200 | (force-mode-line-update) |
| 201 | (message "")) |
| 202 | |
| 203 | (defun picture-move () |
| 204 | "Move in direction of `picture-vertical-step' and `picture-horizontal-step'." |
| 205 | (if (/= picture-vertical-step 0) |
| 206 | (picture-move-down picture-vertical-step)) |
| 207 | (if (/= picture-horizontal-step 0) |
| 208 | (picture-forward-column picture-horizontal-step))) |
| 209 | |
| 210 | (defun picture-motion (arg) |
| 211 | "Move point in direction of current picture motion in Picture mode. |
| 212 | With ARG do it that many times. Useful for delineating rectangles in |
| 213 | conjunction with diagonal picture motion. |
| 214 | Do \\[command-apropos] picture-movement to see commands which control motion." |
| 215 | (interactive "^p") |
| 216 | (picture-move-down (* arg picture-vertical-step)) |
| 217 | (picture-forward-column (* arg picture-horizontal-step))) |
| 218 | |
| 219 | (defun picture-motion-reverse (arg) |
| 220 | "Move point in direction opposite of current picture motion in Picture mode. |
| 221 | With ARG do it that many times. Useful for delineating rectangles in |
| 222 | conjunction with diagonal picture motion. |
| 223 | Do \\[command-apropos] picture-movement to see commands which control motion." |
| 224 | (interactive "^p") |
| 225 | (picture-motion (- arg))) |
| 226 | |
| 227 | (defun picture-mouse-set-point (event) |
| 228 | "Move point to the position of EVENT, making whitespace if necessary." |
| 229 | (interactive "e") |
| 230 | (let ((position (event-start event))) |
| 231 | (unless (posn-area position) ; Ignore EVENT unless in text area |
| 232 | (let* ((window (posn-window position)) |
| 233 | (frame (if (framep window) window (window-frame window))) |
| 234 | (pair (posn-x-y position)) |
| 235 | (start-pos (window-start window)) |
| 236 | (start-pair (posn-x-y (posn-at-point start-pos))) |
| 237 | (dx (- (car pair) (car start-pair))) |
| 238 | (dy (- (cdr pair) (cdr start-pair))) |
| 239 | (char-ht (frame-char-height frame)) |
| 240 | (spacing (when (display-graphic-p frame) |
| 241 | (or (with-current-buffer (window-buffer window) |
| 242 | line-spacing) |
| 243 | (frame-parameter frame 'line-spacing)))) |
| 244 | rows cols) |
| 245 | (cond ((floatp spacing) |
| 246 | (setq spacing (truncate (* spacing char-ht)))) |
| 247 | ((null spacing) |
| 248 | (setq spacing 0))) |
| 249 | (goto-char start-pos) |
| 250 | (picture-move-down (/ dy (+ char-ht spacing))) |
| 251 | (picture-forward-column (/ dx (frame-char-width frame))))))) |
| 252 | |
| 253 | \f |
| 254 | ;; Picture insertion and deletion. |
| 255 | |
| 256 | (defun picture-insert (ch arg) |
| 257 | (let* ((width (char-width ch)) |
| 258 | ;; We must be sure that the succeeding insertion won't delete |
| 259 | ;; the just inserted character. |
| 260 | (picture-horizontal-step |
| 261 | (if (and (= picture-vertical-step 0) |
| 262 | (> width 1) |
| 263 | (< (abs picture-horizontal-step) 2)) |
| 264 | (* picture-horizontal-step 2) |
| 265 | picture-horizontal-step))) |
| 266 | (while (> arg 0) |
| 267 | (setq arg (1- arg)) |
| 268 | (if (/= picture-desired-column (current-column)) |
| 269 | (move-to-column picture-desired-column t)) |
| 270 | (let ((col (+ picture-desired-column width))) |
| 271 | (or (eolp) |
| 272 | (let ((pos (point))) |
| 273 | (move-to-column col t) |
| 274 | (delete-region pos (point))))) |
| 275 | (insert ch) |
| 276 | (forward-char -1) |
| 277 | (picture-move)))) |
| 278 | |
| 279 | (defun picture-self-insert (arg) |
| 280 | "Insert this character in place of character previously at the cursor. |
| 281 | The cursor then moves in the direction you previously specified |
| 282 | with the commands `picture-movement-right', `picture-movement-up', etc. |
| 283 | Do \\[command-apropos] `picture-movement' to see those commands." |
| 284 | (interactive "p") |
| 285 | (picture-update-desired-column (not (eq this-command last-command))) |
| 286 | (picture-insert last-command-event arg)) ; Always a character in this case. |
| 287 | |
| 288 | (defun picture-clear-column (arg) |
| 289 | "Clear out ARG columns after point without moving." |
| 290 | (interactive "p") |
| 291 | (let* ((original-col (current-column)) |
| 292 | (target-col (max 0 (+ original-col arg))) |
| 293 | pos) |
| 294 | (move-to-column target-col t) |
| 295 | (setq pos (point)) |
| 296 | (move-to-column original-col) |
| 297 | (delete-region pos (point)) |
| 298 | (save-excursion |
| 299 | (indent-to (max target-col original-col)))) |
| 300 | (setq picture-desired-column (current-column))) |
| 301 | |
| 302 | (defun picture-backward-clear-column (arg) |
| 303 | "Clear out ARG columns before point, moving back over them." |
| 304 | (interactive "p") |
| 305 | (picture-clear-column (- arg))) |
| 306 | |
| 307 | (defun picture-clear-line (arg) |
| 308 | "Clear out rest of line; if at end of line, advance to next line. |
| 309 | Cleared-out line text goes into the kill ring, as do newlines that are |
| 310 | advanced over. With argument, clear out (and save in kill ring) that |
| 311 | many lines." |
| 312 | (interactive "P") |
| 313 | (if arg |
| 314 | (progn |
| 315 | (setq arg (prefix-numeric-value arg)) |
| 316 | (kill-line arg) |
| 317 | (newline (if (> arg 0) arg (- arg)))) |
| 318 | (if (looking-at "[ \t]*$") |
| 319 | (kill-ring-save (point) (progn (forward-line 1) (point))) |
| 320 | (kill-region (point) (progn (end-of-line) (point)))))) |
| 321 | |
| 322 | (defun picture-newline (arg) |
| 323 | "Move to the beginning of the following line. |
| 324 | With argument, moves that many lines (up, if negative argument); |
| 325 | always moves to the beginning of a line." |
| 326 | (interactive "^p") |
| 327 | (let ((start (point)) |
| 328 | (lines-left (forward-line arg))) |
| 329 | (if (and (eobp) |
| 330 | (> (point) start)) |
| 331 | (newline)) |
| 332 | (if (> lines-left 0) |
| 333 | (newline lines-left)))) |
| 334 | |
| 335 | (defun picture-open-line (arg) |
| 336 | "Insert an empty line after the current line. |
| 337 | With positive argument insert that many lines." |
| 338 | (interactive "p") |
| 339 | (save-excursion |
| 340 | (end-of-line) |
| 341 | (open-line arg))) |
| 342 | |
| 343 | (defun picture-duplicate-line () |
| 344 | "Insert a duplicate of the current line, below it." |
| 345 | (interactive) |
| 346 | (save-excursion |
| 347 | (let ((contents |
| 348 | (buffer-substring |
| 349 | (progn (beginning-of-line) (point)) |
| 350 | (progn (picture-newline 1) (point))))) |
| 351 | (forward-line -1) |
| 352 | (insert contents)))) |
| 353 | |
| 354 | ;; Like replace-match, but overwrites. |
| 355 | (defun picture-replace-match (newtext fixedcase literal) |
| 356 | (let (ocolumn change pos) |
| 357 | (goto-char (setq pos (match-end 0))) |
| 358 | (setq ocolumn (current-column)) |
| 359 | ;; Make the replacement and undo it, to see how it changes the length. |
| 360 | (let ((buffer-undo-list nil) |
| 361 | list1) |
| 362 | (replace-match newtext fixedcase literal) |
| 363 | (setq change (- (current-column) ocolumn)) |
| 364 | (setq list1 buffer-undo-list) |
| 365 | (while list1 |
| 366 | (setq list1 (primitive-undo 1 list1)))) |
| 367 | (goto-char pos) |
| 368 | (if (> change 0) |
| 369 | (delete-region (point) |
| 370 | (progn |
| 371 | (move-to-column (+ change (current-column)) t) |
| 372 | (point)))) |
| 373 | (replace-match newtext fixedcase literal) |
| 374 | (if (< change 0) |
| 375 | (insert-char ?\s (- change))))) |
| 376 | \f |
| 377 | ;; Picture Tabs |
| 378 | |
| 379 | (defcustom picture-tab-chars "!-~" |
| 380 | "A character set which controls behavior of commands. |
| 381 | \\[picture-set-tab-stops] and \\[picture-tab-search]. It is NOT a |
| 382 | regular expression, any regexp special characters will be quoted. |
| 383 | It defines a set of \"interesting characters\" to look for when setting |
| 384 | \(or searching for) tab stops, initially \"!-~\" (all printing characters). |
| 385 | For example, suppose that you are editing a table which is formatted thus: |
| 386 | | foo | bar + baz | 23 * |
| 387 | | bubbles | and + etc | 97 * |
| 388 | and that `picture-tab-chars' is \"|+*\". Then invoking |
| 389 | \\[picture-set-tab-stops] on either of the previous lines would result |
| 390 | in the following tab stops |
| 391 | : : : : |
| 392 | Another example - \"A-Za-z0-9\" would produce the tab stops |
| 393 | : : : : |
| 394 | |
| 395 | Note that if you want the character `-' to be in the set, it must be |
| 396 | included in a range or else appear in a context where it cannot be |
| 397 | taken for indicating a range (e.g. \"-A-Z\" declares the set to be the |
| 398 | letters `A' through `Z' and the character `-'). If you want the |
| 399 | character `\\' in the set it must be preceded by itself: \"\\\\\". |
| 400 | |
| 401 | The command \\[picture-tab-search] is defined to move beneath (or to) a |
| 402 | character belonging to this set independent of the tab stops list." |
| 403 | :type 'string |
| 404 | :group 'picture) |
| 405 | |
| 406 | (defun picture-set-tab-stops (&optional arg) |
| 407 | "Set value of `tab-stop-list' according to context of this line. |
| 408 | This controls the behavior of \\[picture-tab]. A tab stop is set at |
| 409 | every column occupied by an \"interesting character\" that is preceded |
| 410 | by whitespace. Interesting characters are defined by the variable |
| 411 | `picture-tab-chars', see its documentation for an example of usage. |
| 412 | With ARG, just (re)set `tab-stop-list' to its default value. The tab |
| 413 | stops computed are displayed in the minibuffer with `:' at each stop." |
| 414 | (interactive "P") |
| 415 | (save-excursion |
| 416 | (let (tabs) |
| 417 | (if arg |
| 418 | (setq tabs (default-value 'tab-stop-list)) |
| 419 | (let ((regexp (concat "[ \t]+[" (regexp-quote picture-tab-chars) "]"))) |
| 420 | (beginning-of-line) |
| 421 | (let ((bol (point))) |
| 422 | (end-of-line) |
| 423 | (while (re-search-backward regexp bol t) |
| 424 | (skip-chars-forward " \t") |
| 425 | (setq tabs (cons (current-column) tabs))) |
| 426 | (if (null tabs) |
| 427 | (error "No characters in set %s on this line" |
| 428 | (regexp-quote picture-tab-chars)))))) |
| 429 | (setq tab-stop-list tabs) |
| 430 | (let ((blurb (make-string (1+ (nth (1- (length tabs)) tabs)) ?\ ))) |
| 431 | (while tabs |
| 432 | (aset blurb (car tabs) ?:) |
| 433 | (setq tabs (cdr tabs))) |
| 434 | (message blurb))))) |
| 435 | |
| 436 | (defun picture-tab-search (&optional arg) |
| 437 | "Move to column beneath next interesting char in previous line. |
| 438 | With ARG move to column occupied by next interesting character in this |
| 439 | line. The character must be preceded by whitespace. |
| 440 | \"interesting characters\" are defined by variable `picture-tab-chars'. |
| 441 | If no such character is found, move to beginning of line." |
| 442 | (interactive "^P") |
| 443 | (let ((target (current-column))) |
| 444 | (save-excursion |
| 445 | (if (and (not arg) |
| 446 | (progn |
| 447 | (beginning-of-line) |
| 448 | (skip-chars-backward |
| 449 | (concat "^" (regexp-quote picture-tab-chars)) |
| 450 | (point-min)) |
| 451 | (not (bobp)))) |
| 452 | (move-to-column target)) |
| 453 | (if (re-search-forward |
| 454 | (concat "[ \t]+[" (regexp-quote picture-tab-chars) "]") |
| 455 | (line-end-position) |
| 456 | 'move) |
| 457 | (setq target (1- (current-column))) |
| 458 | (setq target nil))) |
| 459 | (if target |
| 460 | (move-to-column target t) |
| 461 | (beginning-of-line)))) |
| 462 | |
| 463 | (defun picture-tab (&optional arg) |
| 464 | "Tab transparently (just move point) to next tab stop. |
| 465 | With prefix arg, overwrite the traversed text with spaces. The tab stop |
| 466 | list can be changed by \\[picture-set-tab-stops] and \\[edit-tab-stops]. |
| 467 | See also documentation for variable `picture-tab-chars'." |
| 468 | (interactive "^P") |
| 469 | (let* ((opoint (point))) |
| 470 | (move-to-tab-stop) |
| 471 | (if arg |
| 472 | (let (indent-tabs-mode |
| 473 | (column (current-column))) |
| 474 | (delete-region opoint (point)) |
| 475 | (indent-to column))))) |
| 476 | \f |
| 477 | ;; Picture Rectangles |
| 478 | |
| 479 | (defvar picture-killed-rectangle nil |
| 480 | "Rectangle killed or copied by \\[picture-clear-rectangle] in Picture mode. |
| 481 | The contents can be retrieved by \\[picture-yank-rectangle]") |
| 482 | |
| 483 | (defun picture-clear-rectangle (start end &optional killp) |
| 484 | "Clear and save rectangle delineated by point and mark. |
| 485 | The rectangle is saved for yanking by \\[picture-yank-rectangle] and replaced |
| 486 | with whitespace. The previously saved rectangle, if any, is lost. With |
| 487 | prefix argument, the rectangle is actually killed, shifting remaining text." |
| 488 | (interactive "r\nP") |
| 489 | (setq picture-killed-rectangle (picture-snarf-rectangle start end killp))) |
| 490 | |
| 491 | (defun picture-clear-rectangle-to-register (start end register &optional killp) |
| 492 | "Clear rectangle delineated by point and mark into REGISTER. |
| 493 | The rectangle is saved in REGISTER and replaced with whitespace. With |
| 494 | prefix argument, the rectangle is actually killed, shifting remaining text." |
| 495 | (interactive "r\ncRectangle to register: \nP") |
| 496 | (set-register register (picture-snarf-rectangle start end killp))) |
| 497 | |
| 498 | (defun picture-snarf-rectangle (start end &optional killp) |
| 499 | (let ((column (current-column)) |
| 500 | (indent-tabs-mode nil)) |
| 501 | (prog1 (save-excursion |
| 502 | (if killp |
| 503 | (delete-extract-rectangle start end) |
| 504 | (prog1 (extract-rectangle start end) |
| 505 | (clear-rectangle start end)))) |
| 506 | (move-to-column column t)))) |
| 507 | |
| 508 | (defun picture-yank-rectangle (&optional insertp) |
| 509 | "Overlay rectangle saved by \\[picture-clear-rectangle] |
| 510 | The rectangle is positioned with upper left corner at point, overwriting |
| 511 | existing text. With prefix argument, the rectangle is inserted instead, |
| 512 | shifting existing text. Leaves mark at one corner of rectangle and |
| 513 | point at the other (diagonally opposed) corner." |
| 514 | (interactive "P") |
| 515 | (if (not (consp picture-killed-rectangle)) |
| 516 | (error "No rectangle saved") |
| 517 | (picture-insert-rectangle picture-killed-rectangle insertp))) |
| 518 | |
| 519 | (defun picture-yank-at-click (click arg) |
| 520 | "Insert the last killed rectangle at the position clicked on. |
| 521 | Also move point to one end of the text thus inserted (normally the end). |
| 522 | Prefix arguments are interpreted as with \\[yank]. |
| 523 | If `mouse-yank-at-point' is non-nil, insert at point |
| 524 | regardless of where you click." |
| 525 | (interactive "e\nP") |
| 526 | (or mouse-yank-at-point (mouse-set-point click)) |
| 527 | (picture-yank-rectangle arg)) |
| 528 | |
| 529 | (defun picture-yank-rectangle-from-register (register &optional insertp) |
| 530 | "Overlay rectangle saved in REGISTER. |
| 531 | The rectangle is positioned with upper left corner at point, overwriting |
| 532 | existing text. With prefix argument, the rectangle is |
| 533 | inserted instead, shifting existing text. Leaves mark at one corner |
| 534 | of rectangle and point at the other (diagonally opposed) corner." |
| 535 | (interactive "cRectangle from register: \nP") |
| 536 | (let ((rectangle (get-register register))) |
| 537 | (if (not (consp rectangle)) |
| 538 | (error "Register %c does not contain a rectangle" register) |
| 539 | (picture-insert-rectangle rectangle insertp)))) |
| 540 | |
| 541 | (defun picture-insert-rectangle (rectangle &optional insertp) |
| 542 | "Overlay RECTANGLE with upper left corner at point. |
| 543 | Optional argument INSERTP, if non-nil causes RECTANGLE to be inserted. |
| 544 | Leaves the region surrounding the rectangle." |
| 545 | (let ((indent-tabs-mode nil)) |
| 546 | (if (not insertp) |
| 547 | (save-excursion |
| 548 | (delete-rectangle (point) |
| 549 | (progn |
| 550 | (picture-forward-column (length (car rectangle))) |
| 551 | (picture-move-down (1- (length rectangle))) |
| 552 | (point))))) |
| 553 | (push-mark) |
| 554 | (insert-rectangle rectangle))) |
| 555 | |
| 556 | (defun picture-current-line () |
| 557 | "Return the vertical position of point. Top line is 1." |
| 558 | (+ (count-lines (point-min) (point)) |
| 559 | (if (= (current-column) 0) 1 0))) |
| 560 | |
| 561 | (defun picture-draw-rectangle (start end) |
| 562 | "Draw a rectangle around region." |
| 563 | (interactive "*r") ; start will be less than end |
| 564 | (let* ((sl (picture-current-line)) |
| 565 | (sc (current-column)) |
| 566 | (pvs picture-vertical-step) |
| 567 | (phs picture-horizontal-step) |
| 568 | (c1 (progn (goto-char start) (current-column))) |
| 569 | (r1 (picture-current-line)) |
| 570 | (c2 (progn (goto-char end) (current-column))) |
| 571 | (r2 (picture-current-line)) |
| 572 | (right (max c1 c2)) |
| 573 | (left (min c1 c2)) |
| 574 | (top (min r1 r2)) |
| 575 | (bottom (max r1 r2))) |
| 576 | (goto-char (point-min)) |
| 577 | (forward-line (1- top)) |
| 578 | (move-to-column left t) |
| 579 | (picture-update-desired-column t) |
| 580 | |
| 581 | (picture-movement-right) |
| 582 | (picture-insert picture-rectangle-ctl 1) |
| 583 | (picture-insert picture-rectangle-h (- right picture-desired-column)) |
| 584 | |
| 585 | (picture-movement-down) |
| 586 | (picture-insert picture-rectangle-ctr 1) |
| 587 | (picture-insert picture-rectangle-v (- bottom (picture-current-line))) |
| 588 | |
| 589 | (picture-movement-left) |
| 590 | (picture-insert picture-rectangle-cbr 1) |
| 591 | (picture-insert picture-rectangle-h (- picture-desired-column left)) |
| 592 | |
| 593 | (picture-movement-up) |
| 594 | (picture-insert picture-rectangle-cbl 1) |
| 595 | (picture-insert picture-rectangle-v (- (picture-current-line) top)) |
| 596 | |
| 597 | (picture-set-motion pvs phs) |
| 598 | (goto-char (point-min)) |
| 599 | (forward-line (1- sl)) |
| 600 | (move-to-column sc t))) |
| 601 | |
| 602 | \f |
| 603 | ;; Picture Keymap, entry and exit points. |
| 604 | |
| 605 | (defvar picture-mode-map nil) |
| 606 | |
| 607 | (defun picture-substitute (oldfun newfun) |
| 608 | (define-key picture-mode-map (vector 'remap oldfun) newfun)) |
| 609 | |
| 610 | (if (not picture-mode-map) |
| 611 | (progn |
| 612 | (setq picture-mode-map (make-keymap)) |
| 613 | (picture-substitute 'self-insert-command 'picture-self-insert) |
| 614 | (picture-substitute 'completion-separator-self-insert-command |
| 615 | 'picture-self-insert) |
| 616 | (picture-substitute 'completion-separator-self-insert-autofilling |
| 617 | 'picture-self-insert) |
| 618 | (picture-substitute 'forward-char 'picture-forward-column) |
| 619 | (picture-substitute 'backward-char 'picture-backward-column) |
| 620 | (picture-substitute 'delete-char 'picture-clear-column) |
| 621 | ;; There are two possibilities for what is normally on DEL. |
| 622 | (picture-substitute 'backward-delete-char-untabify 'picture-backward-clear-column) |
| 623 | (picture-substitute 'delete-backward-char 'picture-backward-clear-column) |
| 624 | (picture-substitute 'kill-line 'picture-clear-line) |
| 625 | (picture-substitute 'open-line 'picture-open-line) |
| 626 | (picture-substitute 'newline 'picture-newline) |
| 627 | (picture-substitute 'newline-and-indent 'picture-duplicate-line) |
| 628 | (picture-substitute 'next-line 'picture-move-down) |
| 629 | (picture-substitute 'previous-line 'picture-move-up) |
| 630 | (picture-substitute 'beginning-of-line 'picture-beginning-of-line) |
| 631 | (picture-substitute 'end-of-line 'picture-end-of-line) |
| 632 | (picture-substitute 'mouse-set-point 'picture-mouse-set-point) |
| 633 | |
| 634 | (define-key picture-mode-map "\C-c\C-d" 'delete-char) |
| 635 | (define-key picture-mode-map "\e\t" 'picture-toggle-tab-state) |
| 636 | (define-key picture-mode-map "\t" 'picture-tab) |
| 637 | (define-key picture-mode-map "\e\t" 'picture-tab-search) |
| 638 | (define-key picture-mode-map "\C-c\t" 'picture-set-tab-stops) |
| 639 | (define-key picture-mode-map "\C-c\C-k" 'picture-clear-rectangle) |
| 640 | (define-key picture-mode-map "\C-c\C-w" 'picture-clear-rectangle-to-register) |
| 641 | (define-key picture-mode-map "\C-c\C-y" 'picture-yank-rectangle) |
| 642 | (define-key picture-mode-map "\C-c\C-x" 'picture-yank-rectangle-from-register) |
| 643 | (define-key picture-mode-map "\C-c\C-r" 'picture-draw-rectangle) |
| 644 | (define-key picture-mode-map "\C-c\C-c" 'picture-mode-exit) |
| 645 | (define-key picture-mode-map "\C-c\C-f" 'picture-motion) |
| 646 | (define-key picture-mode-map "\C-c\C-b" 'picture-motion-reverse) |
| 647 | (define-key picture-mode-map "\C-c<" 'picture-movement-left) |
| 648 | (define-key picture-mode-map "\C-c>" 'picture-movement-right) |
| 649 | (define-key picture-mode-map "\C-c^" 'picture-movement-up) |
| 650 | (define-key picture-mode-map "\C-c." 'picture-movement-down) |
| 651 | (define-key picture-mode-map "\C-c`" 'picture-movement-nw) |
| 652 | (define-key picture-mode-map "\C-c'" 'picture-movement-ne) |
| 653 | (define-key picture-mode-map "\C-c/" 'picture-movement-sw) |
| 654 | (define-key picture-mode-map "\C-c\\" 'picture-movement-se) |
| 655 | (define-key picture-mode-map [(control ?c) left] 'picture-movement-left) |
| 656 | (define-key picture-mode-map [(control ?c) right] 'picture-movement-right) |
| 657 | (define-key picture-mode-map [(control ?c) up] 'picture-movement-up) |
| 658 | (define-key picture-mode-map [(control ?c) down] 'picture-movement-down) |
| 659 | (define-key picture-mode-map [(control ?c) home] 'picture-movement-nw) |
| 660 | (define-key picture-mode-map [(control ?c) prior] 'picture-movement-ne) |
| 661 | (define-key picture-mode-map [(control ?c) end] 'picture-movement-sw) |
| 662 | (define-key picture-mode-map [(control ?c) next] 'picture-movement-se))) |
| 663 | |
| 664 | (defcustom picture-mode-hook nil |
| 665 | "If non-nil, its value is called on entry to Picture mode. |
| 666 | Picture mode is invoked by the command \\[picture-mode]." |
| 667 | :type 'hook |
| 668 | :group 'picture) |
| 669 | |
| 670 | (defvar picture-mode-old-local-map) |
| 671 | (defvar picture-mode-old-mode-name) |
| 672 | (defvar picture-mode-old-major-mode) |
| 673 | (defvar picture-mode-old-truncate-lines) |
| 674 | |
| 675 | ;;;###autoload |
| 676 | (defun picture-mode () |
| 677 | "Switch to Picture mode, in which a quarter-plane screen model is used. |
| 678 | \\<picture-mode-map> |
| 679 | Printing characters replace instead of inserting themselves with motion |
| 680 | afterwards settable by these commands: |
| 681 | |
| 682 | Move left after insertion: \\[picture-movement-left] |
| 683 | Move right after insertion: \\[picture-movement-right] |
| 684 | Move up after insertion: \\[picture-movement-up] |
| 685 | Move down after insertion: \\[picture-movement-down] |
| 686 | |
| 687 | Move northwest (nw) after insertion: \\[picture-movement-nw] |
| 688 | Move northeast (ne) after insertion: \\[picture-movement-ne] |
| 689 | Move southwest (sw) after insertion: \\[picture-movement-sw] |
| 690 | Move southeast (se) after insertion: \\[picture-movement-se] |
| 691 | |
| 692 | Move westnorthwest (wnw) after insertion: C-u \\[picture-movement-nw] |
| 693 | Move eastnortheast (ene) after insertion: C-u \\[picture-movement-ne] |
| 694 | Move westsouthwest (wsw) after insertion: C-u \\[picture-movement-sw] |
| 695 | Move eastsoutheast (ese) after insertion: C-u \\[picture-movement-se] |
| 696 | |
| 697 | The current direction is displayed in the mode line. The initial |
| 698 | direction is right. Whitespace is inserted and tabs are changed to |
| 699 | spaces when required by movement. You can move around in the buffer |
| 700 | with these commands: |
| 701 | |
| 702 | Move vertically to SAME column in previous line: \\[picture-move-down] |
| 703 | Move vertically to SAME column in next line: \\[picture-move-up] |
| 704 | Move to column following last |
| 705 | non-whitespace character: \\[picture-end-of-line] |
| 706 | Move right, inserting spaces if required: \\[picture-forward-column] |
| 707 | Move left changing tabs to spaces if required: \\[picture-backward-column] |
| 708 | Move in direction of current picture motion: \\[picture-motion] |
| 709 | Move opposite to current picture motion: \\[picture-motion-reverse] |
| 710 | Move to beginning of next line: \\[next-line] |
| 711 | |
| 712 | You can edit tabular text with these commands: |
| 713 | |
| 714 | Move to column beneath (or at) next interesting |
| 715 | character (see variable `picture-tab-chars'): \\[picture-tab-search] |
| 716 | Move to next stop in tab stop list: \\[picture-tab] |
| 717 | Set tab stops according to context of this line: \\[picture-set-tab-stops] |
| 718 | (With ARG, resets tab stops to default value.) |
| 719 | Change the tab stop list: \\[edit-tab-stops] |
| 720 | |
| 721 | You can manipulate text with these commands: |
| 722 | Clear ARG columns after point without moving: \\[picture-clear-column] |
| 723 | Delete char at point: \\[delete-char] |
| 724 | Clear ARG columns backward: \\[picture-backward-clear-column] |
| 725 | Clear ARG lines, advancing over them: \\[picture-clear-line] |
| 726 | (the cleared text is saved in the kill ring) |
| 727 | Open blank line(s) beneath current line: \\[picture-open-line] |
| 728 | |
| 729 | You can manipulate rectangles with these commands: |
| 730 | Clear a rectangle and save it: \\[picture-clear-rectangle] |
| 731 | Clear a rectangle, saving in a named register: \\[picture-clear-rectangle-to-register] |
| 732 | Insert currently saved rectangle at point: \\[picture-yank-rectangle] |
| 733 | Insert rectangle from named register: \\[picture-yank-rectangle-from-register] |
| 734 | Draw a rectangular box around mark and point: \\[picture-draw-rectangle] |
| 735 | Copies a rectangle to a register: \\[copy-rectangle-to-register] |
| 736 | Undo effects of rectangle overlay commands: \\[undo] |
| 737 | |
| 738 | You can return to the previous mode with \\[picture-mode-exit], which |
| 739 | also strips trailing whitespace from every line. Stripping is suppressed |
| 740 | by supplying an argument. |
| 741 | |
| 742 | Entry to this mode calls the value of `picture-mode-hook' if non-nil. |
| 743 | |
| 744 | Note that Picture mode commands will work outside of Picture mode, but |
| 745 | they are not by default assigned to keys." |
| 746 | (interactive) |
| 747 | (if (eq major-mode 'picture-mode) |
| 748 | (error "You are already editing a picture") |
| 749 | (set (make-local-variable 'picture-mode-old-local-map) (current-local-map)) |
| 750 | (use-local-map picture-mode-map) |
| 751 | (set (make-local-variable 'picture-mode-old-mode-name) mode-name) |
| 752 | (set (make-local-variable 'picture-mode-old-major-mode) major-mode) |
| 753 | (setq major-mode 'picture-mode) |
| 754 | (set (make-local-variable 'picture-killed-rectangle) nil) |
| 755 | (set (make-local-variable 'tab-stop-list) (default-value 'tab-stop-list)) |
| 756 | (set (make-local-variable 'picture-tab-chars) |
| 757 | (default-value 'picture-tab-chars)) |
| 758 | (make-local-variable 'picture-vertical-step) |
| 759 | (make-local-variable 'picture-horizontal-step) |
| 760 | (set (make-local-variable 'picture-mode-old-truncate-lines) truncate-lines) |
| 761 | (setq truncate-lines t) |
| 762 | (picture-set-motion 0 1) |
| 763 | |
| 764 | ;; edit-picture-hook is what we used to run, picture-mode-hook is in doc. |
| 765 | (run-hooks 'edit-picture-hook 'picture-mode-hook) |
| 766 | (message "Type %s in this buffer to return it to %s mode." |
| 767 | (substitute-command-keys "\\[picture-mode-exit]") |
| 768 | picture-mode-old-mode-name))) |
| 769 | |
| 770 | ;;;###autoload |
| 771 | (defalias 'edit-picture 'picture-mode) |
| 772 | |
| 773 | (defun picture-mode-exit (&optional nostrip) |
| 774 | "Undo `picture-mode' and return to previous major mode. |
| 775 | With no argument, strip whitespace from end of every line in Picture buffer; |
| 776 | otherwise, just return to previous mode. |
| 777 | Runs `picture-mode-exit-hook' at the end." |
| 778 | (interactive "P") |
| 779 | (if (not (eq major-mode 'picture-mode)) |
| 780 | (error "You aren't editing a Picture") |
| 781 | (if (not nostrip) (delete-trailing-whitespace)) |
| 782 | (setq mode-name picture-mode-old-mode-name) |
| 783 | (use-local-map picture-mode-old-local-map) |
| 784 | (setq major-mode picture-mode-old-major-mode) |
| 785 | (kill-local-variable 'tab-stop-list) |
| 786 | (setq truncate-lines picture-mode-old-truncate-lines) |
| 787 | (force-mode-line-update) |
| 788 | (run-hooks 'picture-mode-exit-hook))) |
| 789 | |
| 790 | (provide 'picture) |
| 791 | |
| 792 | ;;; picture.el ends here |