| 1 | ;;; comint.el --- general command interpreter in a window stuff -*- lexical-binding: t -*- |
| 2 | |
| 3 | ;; Copyright (C) 1988, 1990, 1992-2012 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Author: Olin Shivers <shivers@cs.cmu.edu> |
| 6 | ;; Simon Marshall <simon@gnu.org> |
| 7 | ;; Maintainer: FSF |
| 8 | ;; Keywords: processes |
| 9 | ;; Package: emacs |
| 10 | |
| 11 | ;; This file is part of GNU Emacs. |
| 12 | |
| 13 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 14 | ;; it under the terms of the GNU General Public License as published by |
| 15 | ;; the Free Software Foundation, either version 3 of the License, or |
| 16 | ;; (at your option) any later version. |
| 17 | |
| 18 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 19 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 20 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 21 | ;; GNU General Public License for more details. |
| 22 | |
| 23 | ;; You should have received a copy of the GNU General Public License |
| 24 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 25 | |
| 26 | ;;; Commentary: |
| 27 | |
| 28 | ;; This file defines a general command-interpreter-in-a-buffer package |
| 29 | ;; (comint mode). The idea is that you can build specific process-in-a-buffer |
| 30 | ;; modes on top of comint mode -- e.g., Lisp, shell, scheme, T, soar, .... |
| 31 | ;; This way, all these specific packages share a common base functionality, |
| 32 | ;; and a common set of bindings, which makes them easier to use (and |
| 33 | ;; saves code, implementation time, etc., etc.). |
| 34 | |
| 35 | ;; Several packages are already defined using comint mode: |
| 36 | ;; - shell.el defines a shell-in-a-buffer mode. |
| 37 | ;; - cmulisp.el defines a simple lisp-in-a-buffer mode. |
| 38 | ;; |
| 39 | ;; - The file cmuscheme.el defines a scheme-in-a-buffer mode. |
| 40 | ;; - The file tea.el tunes scheme and inferior-scheme modes for T. |
| 41 | ;; - The file soar.el tunes Lisp and inferior-lisp modes for Soar. |
| 42 | ;; - cmutex.el defines TeX and LaTeX modes that invoke TeX, LaTeX, BibTeX, |
| 43 | ;; previewers, and printers from within Emacs. |
| 44 | ;; - background.el allows csh-like job control inside Emacs. |
| 45 | ;; It is pretty easy to make new derived modes for other processes. |
| 46 | |
| 47 | ;; For documentation on the functionality provided by Comint mode, and |
| 48 | ;; the hooks available for customizing it, see the comments below. |
| 49 | ;; For further information on the standard derived modes (shell, |
| 50 | ;; inferior-lisp, inferior-scheme, ...), see the relevant source files. |
| 51 | |
| 52 | ;; For hints on converting existing process modes (e.g., tex-mode, |
| 53 | ;; background, dbx, gdb, kermit, prolog, telnet) to use comint-mode |
| 54 | ;; instead of shell-mode, see the notes at the end of this file. |
| 55 | |
| 56 | \f |
| 57 | ;; Brief Command Documentation: |
| 58 | ;;============================================================================ |
| 59 | ;; Comint Mode Commands: (common to all derived modes, like shell & cmulisp |
| 60 | ;; mode) |
| 61 | ;; |
| 62 | ;; M-p comint-previous-input Cycle backwards in input history |
| 63 | ;; M-n comint-next-input Cycle forwards |
| 64 | ;; M-r comint-history-isearch-backward-regexp Isearch input regexp backward |
| 65 | ;; M-C-l comint-show-output Show last batch of process output |
| 66 | ;; RET comint-send-input |
| 67 | ;; C-d comint-delchar-or-maybe-eof Delete char unless at end of buff |
| 68 | ;; C-c C-a comint-bol-or-process-mark First time, move point to bol; |
| 69 | ;; second time, move to process-mark. |
| 70 | ;; C-c C-u comint-kill-input ^u |
| 71 | ;; C-c C-w backward-kill-word ^w |
| 72 | ;; C-c C-c comint-interrupt-subjob ^c |
| 73 | ;; C-c C-z comint-stop-subjob ^z |
| 74 | ;; C-c C-\ comint-quit-subjob ^\ |
| 75 | ;; C-c C-o comint-delete-output Delete last batch of process output |
| 76 | ;; C-c C-r comint-show-output Show last batch of process output |
| 77 | ;; C-c C-l comint-dynamic-list-input-ring List input history |
| 78 | ;; |
| 79 | ;; Not bound by default in comint-mode (some are in shell mode) |
| 80 | ;; comint-run Run a program under comint-mode |
| 81 | ;; send-invisible Read a line w/o echo, and send to proc |
| 82 | ;; comint-dynamic-complete-filename Complete filename at point. |
| 83 | ;; comint-dynamic-list-filename-completions List completions in help buffer. |
| 84 | ;; comint-replace-by-expanded-filename Expand and complete filename at point; |
| 85 | ;; replace with expanded/completed name. |
| 86 | ;; comint-replace-by-expanded-history Expand history at point; |
| 87 | ;; replace with expanded name. |
| 88 | ;; comint-magic-space Expand history and add (a) space(s). |
| 89 | ;; comint-kill-subjob No mercy. |
| 90 | ;; comint-show-maximum-output Show as much output as possible. |
| 91 | ;; comint-continue-subjob Send CONT signal to buffer's process |
| 92 | ;; group. Useful if you accidentally |
| 93 | ;; suspend your process (with C-c C-z). |
| 94 | ;; comint-get-next-from-history Fetch successive input history lines |
| 95 | ;; comint-accumulate Combine lines to send them together |
| 96 | ;; as input. |
| 97 | ;; comint-goto-process-mark Move point to where process-mark is. |
| 98 | ;; comint-set-process-mark Set process-mark to point. |
| 99 | |
| 100 | ;; comint-mode-hook is the Comint mode hook. Basically for your keybindings. |
| 101 | |
| 102 | ;;; Code: |
| 103 | |
| 104 | (eval-when-compile (require 'cl)) |
| 105 | (require 'ring) |
| 106 | \f |
| 107 | ;; Buffer Local Variables: |
| 108 | ;;============================================================================ |
| 109 | ;; Comint mode buffer local variables: |
| 110 | ;; comint-prompt-regexp string comint-bol uses to match prompt |
| 111 | ;; comint-delimiter-argument-list list For delimiters and arguments |
| 112 | ;; comint-last-input-start marker Handy if inferior always echoes |
| 113 | ;; comint-last-input-end marker For comint-delete-output command |
| 114 | ;; comint-input-ring-size integer For the input history |
| 115 | ;; comint-input-ring ring mechanism |
| 116 | ;; comint-input-ring-index number ... |
| 117 | ;; comint-save-input-ring-index number ... |
| 118 | ;; comint-input-autoexpand symbol ... |
| 119 | ;; comint-input-ignoredups boolean ... |
| 120 | ;; comint-dynamic-complete-functions hook For the completion mechanism |
| 121 | ;; comint-completion-fignore list ... |
| 122 | ;; comint-file-name-chars string ... |
| 123 | ;; comint-file-name-quote-list list ... |
| 124 | ;; comint-get-old-input function Hooks for specific |
| 125 | ;; comint-input-filter-functions hook process-in-a-buffer |
| 126 | ;; comint-output-filter-functions hook function modes. |
| 127 | ;; comint-preoutput-filter-functions hook |
| 128 | ;; comint-input-filter function ... |
| 129 | ;; comint-input-sender function ... |
| 130 | ;; comint-eol-on-send boolean ... |
| 131 | ;; comint-process-echoes boolean ... |
| 132 | ;; comint-scroll-to-bottom-on-input symbol For scroll behavior |
| 133 | ;; comint-move-point-for-output symbol ... |
| 134 | ;; comint-scroll-show-maximum-output boolean ... |
| 135 | ;; comint-accum-marker maker For comint-accumulate |
| 136 | ;; |
| 137 | ;; Comint mode non-buffer local variables: |
| 138 | ;; comint-completion-addsuffix boolean/cons For file name |
| 139 | ;; comint-completion-autolist boolean completion behavior |
| 140 | ;; comint-completion-recexact boolean ... |
| 141 | |
| 142 | (defgroup comint nil |
| 143 | "General command interpreter in a window stuff." |
| 144 | :group 'processes) |
| 145 | |
| 146 | (defgroup comint-completion nil |
| 147 | "Completion facilities in comint." |
| 148 | :group 'comint) |
| 149 | |
| 150 | (defgroup comint-source nil |
| 151 | "Source finding facilities in comint." |
| 152 | :prefix "comint-" |
| 153 | :group 'comint) |
| 154 | |
| 155 | (defvar comint-prompt-regexp "^" |
| 156 | "Regexp to recognize prompts in the inferior process. |
| 157 | Defaults to \"^\", the null string at BOL. |
| 158 | |
| 159 | This variable is only used if the variable |
| 160 | `comint-use-prompt-regexp' is non-nil. |
| 161 | |
| 162 | Good choices: |
| 163 | Canonical Lisp: \"^[^> \\n]*>+:? *\" (Lucid, franz, kcl, T, cscheme, oaklisp) |
| 164 | Lucid Common Lisp: \"^\\\\(>\\\\|\\\\(->\\\\)+\\\\) *\" |
| 165 | franz: \"^\\\\(->\\\\|<[0-9]*>:\\\\) *\" |
| 166 | kcl: \"^>+ *\" |
| 167 | shell: \"^[^#$%>\\n]*[#$%>] *\" |
| 168 | T: \"^>+ *\" |
| 169 | |
| 170 | This is a good thing to set in mode hooks.") |
| 171 | |
| 172 | (defcustom comint-prompt-read-only nil |
| 173 | "If non-nil, the comint prompt is read only. |
| 174 | The read only region includes the newline before the prompt. |
| 175 | This does not affect existing prompts. |
| 176 | Certain derived modes may override this option. |
| 177 | |
| 178 | If you set this option to t, then the safe way to temporarily |
| 179 | override the read-only-ness of comint prompts is to call |
| 180 | `comint-kill-whole-line' or `comint-kill-region' with no |
| 181 | narrowing in effect. This way you will be certain that none of |
| 182 | the remaining prompts will be accidentally messed up. You may |
| 183 | wish to put something like the following in your `.emacs' file: |
| 184 | |
| 185 | \(add-hook 'comint-mode-hook |
| 186 | (lambda () |
| 187 | (define-key comint-mode-map \"\\C-w\" 'comint-kill-region) |
| 188 | (define-key comint-mode-map [C-S-backspace] |
| 189 | 'comint-kill-whole-line))) |
| 190 | |
| 191 | If you sometimes use comint-mode on text-only terminals or with `emacs -nw', |
| 192 | you might wish to use another binding for `comint-kill-whole-line'." |
| 193 | :type 'boolean |
| 194 | :group 'comint |
| 195 | :version "22.1") |
| 196 | |
| 197 | (defvar comint-delimiter-argument-list () |
| 198 | "List of characters to recognize as separate arguments in input. |
| 199 | Strings comprising a character in this list will separate the arguments |
| 200 | surrounding them, and also be regarded as arguments in their own right (unlike |
| 201 | whitespace). See `comint-arguments'. |
| 202 | Defaults to the empty list. |
| 203 | |
| 204 | For shells, a good value is (?\\| ?& ?< ?> ?\\( ?\\) ?;). |
| 205 | |
| 206 | This is a good thing to set in mode hooks.") |
| 207 | |
| 208 | (defcustom comint-input-autoexpand nil |
| 209 | "If non-nil, expand input command history references on completion. |
| 210 | This mirrors the optional behavior of tcsh (its autoexpand and histlist). |
| 211 | |
| 212 | If the value is `input', then the expansion is seen on input. |
| 213 | If the value is `history', then the expansion is only when inserting |
| 214 | into the buffer's input ring. See also `comint-magic-space' and |
| 215 | `comint-dynamic-complete'. |
| 216 | |
| 217 | This variable is buffer-local." |
| 218 | :type '(choice (const :tag "off" nil) |
| 219 | (const input) |
| 220 | (const history) |
| 221 | (other :tag "on" t)) |
| 222 | :group 'comint) |
| 223 | |
| 224 | (defface comint-highlight-input '((t (:weight bold))) |
| 225 | "Face to use to highlight user input." |
| 226 | :group 'comint) |
| 227 | |
| 228 | (defface comint-highlight-prompt |
| 229 | '((t :inherit minibuffer-prompt)) |
| 230 | "Face to use to highlight prompts." |
| 231 | :group 'comint) |
| 232 | |
| 233 | (defcustom comint-input-ignoredups nil |
| 234 | "If non-nil, don't add input matching the last on the input ring. |
| 235 | This mirrors the optional behavior of bash. |
| 236 | |
| 237 | This variable is buffer-local." |
| 238 | :type 'boolean |
| 239 | :group 'comint) |
| 240 | |
| 241 | (defcustom comint-input-ring-file-name nil |
| 242 | "If non-nil, name of the file to read/write input history. |
| 243 | See also `comint-read-input-ring' and `comint-write-input-ring'. |
| 244 | `comint-mode' makes this a buffer-local variable. You probably want |
| 245 | to set this in a mode hook, rather than customize the default value." |
| 246 | :type '(choice (const :tag "nil" nil) |
| 247 | file) |
| 248 | :group 'comint) |
| 249 | |
| 250 | (defcustom comint-scroll-to-bottom-on-input nil |
| 251 | "Controls whether input to interpreter causes window to scroll. |
| 252 | If nil, then do not scroll. If t or `all', scroll all windows showing buffer. |
| 253 | If `this', scroll only the selected window. |
| 254 | |
| 255 | The default is nil. |
| 256 | |
| 257 | See `comint-preinput-scroll-to-bottom'. This variable is buffer-local." |
| 258 | :type '(choice (const :tag "off" nil) |
| 259 | (const t) |
| 260 | (const all) |
| 261 | (const this)) |
| 262 | :group 'comint) |
| 263 | |
| 264 | (defcustom comint-move-point-for-output nil |
| 265 | "Controls whether interpreter output moves point to the end of the output. |
| 266 | If nil, then output never moves point to the output. |
| 267 | (If the output occurs at point, it is inserted before point.) |
| 268 | If t or `all', move point in all windows showing the buffer. |
| 269 | If `this', move point only the selected window. |
| 270 | If `others', move point only in other windows, not in the selected window. |
| 271 | |
| 272 | The default is nil. |
| 273 | |
| 274 | See the variable `comint-scroll-show-maximum-output' and the function |
| 275 | `comint-postoutput-scroll-to-bottom'. |
| 276 | This variable is buffer-local in all Comint buffers." |
| 277 | :type '(choice (const :tag "off" nil) |
| 278 | (const t) |
| 279 | (const all) |
| 280 | (const this) |
| 281 | (const others)) |
| 282 | :group 'comint) |
| 283 | |
| 284 | (defvaralias 'comint-scroll-to-bottom-on-output 'comint-move-point-for-output) |
| 285 | |
| 286 | (defcustom comint-scroll-show-maximum-output t |
| 287 | "Controls how to scroll due to interpreter output. |
| 288 | This variable applies when point is at the end of the buffer |
| 289 | \(either because it was originally there, or because |
| 290 | `comint-move-point-for-output' said to move it there) |
| 291 | and output from the subprocess is inserted. |
| 292 | |
| 293 | Non-nil means scroll so that the window is full of text |
| 294 | and point is on the last line. A value of nil |
| 295 | means don't do anything special--scroll normally. |
| 296 | |
| 297 | See also the variable `comint-move-point-for-output' and the function |
| 298 | `comint-postoutput-scroll-to-bottom'. |
| 299 | This variable is buffer-local in all Comint buffers." |
| 300 | :type 'boolean |
| 301 | :group 'comint) |
| 302 | |
| 303 | (defcustom comint-buffer-maximum-size 1024 |
| 304 | "The maximum size in lines for Comint buffers. |
| 305 | Comint buffers are truncated from the top to be no greater than this number, if |
| 306 | the function `comint-truncate-buffer' is on `comint-output-filter-functions'." |
| 307 | :type 'integer |
| 308 | :group 'comint) |
| 309 | |
| 310 | (defcustom comint-input-ring-size 500 |
| 311 | "Size of the input history ring in `comint-mode'." |
| 312 | :type 'integer |
| 313 | :group 'comint |
| 314 | :version "23.2") |
| 315 | |
| 316 | (defvar comint-input-ring-separator "\n" |
| 317 | "Separator between commands in the history file.") |
| 318 | |
| 319 | (defvar comint-input-history-ignore "^#" |
| 320 | "Regexp for history entries that should be ignored when Comint initializes.") |
| 321 | |
| 322 | (defcustom comint-process-echoes nil |
| 323 | "If non-nil, assume that the subprocess echoes any input. |
| 324 | If so, delete one copy of the input so that only one copy eventually |
| 325 | appears in the buffer. |
| 326 | |
| 327 | This variable is buffer-local." |
| 328 | :type 'boolean |
| 329 | :group 'comint) |
| 330 | |
| 331 | ;; AIX puts the name of the person being su'd to in front of the prompt. |
| 332 | ;; kinit prints a prompt like `Password for devnull@GNU.ORG: '. |
| 333 | ;; ksu prints a prompt like `Kerberos password for devnull/root@GNU.ORG: '. |
| 334 | ;; ssh-add prints a prompt like `Enter passphrase: '. |
| 335 | ;; plink prints a prompt like `Passphrase for key "root@GNU.ORG": '. |
| 336 | ;; Ubuntu's sudo prompts like `[sudo] password for user:' |
| 337 | ;; Some implementations of passwd use "Password (again)" as the 2nd prompt. |
| 338 | ;; Something called "perforce" uses "Enter password:". |
| 339 | ;; See M-x comint-testsuite--test-comint-password-prompt-regexp. |
| 340 | (defcustom comint-password-prompt-regexp |
| 341 | (concat |
| 342 | "\\(^ *\\|" |
| 343 | (regexp-opt |
| 344 | '("Enter" "enter" "Enter same" "enter same" "Enter the" "enter the" |
| 345 | "Old" "old" "New" "new" "'s" "login" |
| 346 | "Kerberos" "CVS" "UNIX" " SMB" "LDAP" "[sudo]" "Repeat" "Bad") t) |
| 347 | " +\\)" |
| 348 | (regexp-opt |
| 349 | '("password" "Password" "passphrase" "Passphrase" |
| 350 | "pass phrase" "Pass phrase" "Response")) |
| 351 | "\\(?:\\(?:, try\\)? *again\\| (empty for no passphrase)\\| (again)\\)?\ |
| 352 | \\(?: for [^:]+\\)?:\\s *\\'") |
| 353 | "Regexp matching prompts for passwords in the inferior process. |
| 354 | This is used by `comint-watch-for-password-prompt'." |
| 355 | :version "24.1" |
| 356 | :type 'regexp |
| 357 | :group 'comint) |
| 358 | |
| 359 | ;; Here are the per-interpreter hooks. |
| 360 | (defvar comint-get-old-input (function comint-get-old-input-default) |
| 361 | "Function that returns old text in Comint mode. |
| 362 | This function is called when return is typed while the point is in old |
| 363 | text. It returns the text to be submitted as process input. The |
| 364 | default is `comint-get-old-input-default', which either grabs the |
| 365 | current input field or grabs the current line and strips off leading |
| 366 | text matching `comint-prompt-regexp', depending on the value of |
| 367 | `comint-use-prompt-regexp'.") |
| 368 | |
| 369 | (defvar comint-dynamic-complete-functions |
| 370 | '(comint-c-a-p-replace-by-expanded-history comint-filename-completion) |
| 371 | "List of functions called to perform completion. |
| 372 | Works like `completion-at-point-functions'. |
| 373 | See also `comint-dynamic-complete'. |
| 374 | |
| 375 | This is a good thing to set in mode hooks.") |
| 376 | |
| 377 | (defvar comint-input-filter |
| 378 | (function (lambda (str) (not (string-match "\\`\\s *\\'" str)))) |
| 379 | "Predicate for filtering additions to input history. |
| 380 | Takes one argument, the input. If non-nil, the input may be saved on the input |
| 381 | history list. Default is to save anything that isn't all whitespace.") |
| 382 | |
| 383 | (defvar comint-input-filter-functions '() |
| 384 | "Abnormal hook run before input is sent to the process. |
| 385 | These functions get one argument, a string containing the text to send.") |
| 386 | |
| 387 | ;;;###autoload |
| 388 | (defvar comint-output-filter-functions '(comint-postoutput-scroll-to-bottom comint-watch-for-password-prompt) |
| 389 | "Functions to call after output is inserted into the buffer. |
| 390 | One possible function is `comint-postoutput-scroll-to-bottom'. |
| 391 | These functions get one argument, a string containing the text as originally |
| 392 | inserted. Note that this might not be the same as the buffer contents between |
| 393 | `comint-last-output-start' and the buffer's `process-mark', if other filter |
| 394 | functions have already modified the buffer. |
| 395 | |
| 396 | See also `comint-preoutput-filter-functions'. |
| 397 | |
| 398 | You can use `add-hook' to add functions to this list |
| 399 | either globally or locally.") |
| 400 | |
| 401 | (defvar comint-input-sender-no-newline nil |
| 402 | "Non-nil directs the `comint-input-sender' function not to send a newline.") |
| 403 | |
| 404 | (defvar comint-input-sender (function comint-simple-send) |
| 405 | "Function to actually send to PROCESS the STRING submitted by user. |
| 406 | Usually this is just `comint-simple-send', but if your mode needs to |
| 407 | massage the input string, put a different function here. |
| 408 | `comint-simple-send' just sends the string plus a newline. |
| 409 | \(If `comint-input-sender-no-newline' is non-nil, it omits the newline.) |
| 410 | This is called from the user command `comint-send-input'.") |
| 411 | |
| 412 | (defcustom comint-eol-on-send t |
| 413 | "Non-nil means go to the end of the line before sending input. |
| 414 | See `comint-send-input'." |
| 415 | :type 'boolean |
| 416 | :group 'comint) |
| 417 | |
| 418 | (define-obsolete-variable-alias 'comint-use-prompt-regexp-instead-of-fields |
| 419 | 'comint-use-prompt-regexp "22.1") |
| 420 | |
| 421 | ;; Note: If it is decided to purge comint-prompt-regexp from the source |
| 422 | ;; entirely, searching for uses of this variable will help to identify |
| 423 | ;; places that need attention. |
| 424 | (defcustom comint-use-prompt-regexp nil |
| 425 | "If non-nil, use `comint-prompt-regexp' to recognize prompts. |
| 426 | If nil, then program output and user-input are given different `field' |
| 427 | properties, which Emacs commands can use to distinguish them (in |
| 428 | particular, common movement commands such as `beginning-of-line' |
| 429 | respect field boundaries in a natural way)." |
| 430 | :type 'boolean |
| 431 | :group 'comint) |
| 432 | |
| 433 | (defcustom comint-mode-hook nil |
| 434 | "Hook run upon entry to `comint-mode'. |
| 435 | This is run before the process is cranked up." |
| 436 | :type 'hook |
| 437 | :group 'comint) |
| 438 | |
| 439 | (defcustom comint-exec-hook '() |
| 440 | "Hook run each time a process is exec'd by `comint-exec'. |
| 441 | This is called after the process is cranked up. It is useful for things that |
| 442 | must be done each time a process is executed in a Comint mode buffer (e.g., |
| 443 | `(process-kill-without-query)'). In contrast, the `comint-mode-hook' is only |
| 444 | executed once when the buffer is created." |
| 445 | :type 'hook |
| 446 | :group 'comint) |
| 447 | |
| 448 | (defvar comint-mode-map |
| 449 | (let ((map (make-sparse-keymap))) |
| 450 | ;; Keys: |
| 451 | (define-key map "\ep" 'comint-previous-input) |
| 452 | (define-key map "\en" 'comint-next-input) |
| 453 | (define-key map [C-up] 'comint-previous-input) |
| 454 | (define-key map [C-down] 'comint-next-input) |
| 455 | (define-key map "\er" 'comint-history-isearch-backward-regexp) |
| 456 | (define-key map [?\C-c ?\M-r] 'comint-previous-matching-input-from-input) |
| 457 | (define-key map [?\C-c ?\M-s] 'comint-next-matching-input-from-input) |
| 458 | (define-key map "\e\C-l" 'comint-show-output) |
| 459 | (define-key map "\C-m" 'comint-send-input) |
| 460 | (define-key map "\C-d" 'comint-delchar-or-maybe-eof) |
| 461 | ;; The following two are standardly aliased to C-d, |
| 462 | ;; but they should never do EOF, just delete. |
| 463 | (define-key map [delete] 'delete-char) |
| 464 | (define-key map [kp-delete] 'delete-char) |
| 465 | (define-key map "\C-c " 'comint-accumulate) |
| 466 | (define-key map "\C-c\C-x" 'comint-get-next-from-history) |
| 467 | (define-key map "\C-c\C-a" 'comint-bol-or-process-mark) |
| 468 | (define-key map "\C-c\C-u" 'comint-kill-input) |
| 469 | (define-key map "\C-c\C-w" 'backward-kill-word) |
| 470 | (define-key map "\C-c\C-c" 'comint-interrupt-subjob) |
| 471 | (define-key map "\C-c\C-z" 'comint-stop-subjob) |
| 472 | (define-key map "\C-c\C-\\" 'comint-quit-subjob) |
| 473 | (define-key map "\C-c\C-m" 'comint-copy-old-input) |
| 474 | (define-key map "\C-c\C-o" 'comint-delete-output) |
| 475 | (define-key map "\C-c\C-r" 'comint-show-output) |
| 476 | (define-key map "\C-c\C-e" 'comint-show-maximum-output) |
| 477 | (define-key map "\C-c\C-l" 'comint-dynamic-list-input-ring) |
| 478 | (define-key map "\C-c\C-n" 'comint-next-prompt) |
| 479 | (define-key map "\C-c\C-p" 'comint-previous-prompt) |
| 480 | (define-key map "\C-c\C-d" 'comint-send-eof) |
| 481 | (define-key map "\C-c\C-s" 'comint-write-output) |
| 482 | (define-key map "\C-c." 'comint-insert-previous-argument) |
| 483 | ;; Mouse Buttons: |
| 484 | (define-key map [mouse-2] 'comint-insert-input) |
| 485 | ;; Menu bars: |
| 486 | ;; completion: |
| 487 | (define-key map [menu-bar completion] |
| 488 | (cons "Complete" (make-sparse-keymap "Complete"))) |
| 489 | (define-key map [menu-bar completion complete-expand] |
| 490 | '("Expand File Name" . comint-replace-by-expanded-filename)) |
| 491 | (define-key map [menu-bar completion complete-listing] |
| 492 | '("File Completion Listing" . comint-dynamic-list-filename-completions)) |
| 493 | (define-key map [menu-bar completion complete-file] |
| 494 | '("Complete File Name" . comint-dynamic-complete-filename)) |
| 495 | (define-key map [menu-bar completion complete] |
| 496 | '("Complete at Point" . completion-at-point)) |
| 497 | ;; Input history: |
| 498 | (define-key map [menu-bar inout] |
| 499 | (cons "In/Out" (make-sparse-keymap "In/Out"))) |
| 500 | (define-key map [menu-bar inout delete-output] |
| 501 | '("Delete Current Output Group" . comint-delete-output)) |
| 502 | (define-key map [menu-bar inout append-output-to-file] |
| 503 | '("Append Current Output Group to File" . comint-append-output-to-file)) |
| 504 | (define-key map [menu-bar inout write-output] |
| 505 | '("Write Current Output Group to File" . comint-write-output)) |
| 506 | (define-key map [menu-bar inout next-prompt] |
| 507 | '("Forward Output Group" . comint-next-prompt)) |
| 508 | (define-key map [menu-bar inout previous-prompt] |
| 509 | '("Backward Output Group" . comint-previous-prompt)) |
| 510 | (define-key map [menu-bar inout show-maximum-output] |
| 511 | '("Show Maximum Output" . comint-show-maximum-output)) |
| 512 | (define-key map [menu-bar inout show-output] |
| 513 | '("Show Current Output Group" . comint-show-output)) |
| 514 | (define-key map [menu-bar inout kill-input] |
| 515 | '("Kill Current Input" . comint-kill-input)) |
| 516 | (define-key map [menu-bar inout copy-input] |
| 517 | '("Copy Old Input" . comint-copy-old-input)) |
| 518 | (define-key map [menu-bar inout history-isearch-backward-regexp] |
| 519 | '("Isearch Input Regexp Backward..." . comint-history-isearch-backward-regexp)) |
| 520 | (define-key map [menu-bar inout history-isearch-backward] |
| 521 | '("Isearch Input String Backward..." . comint-history-isearch-backward)) |
| 522 | (define-key map [menu-bar inout forward-matching-history] |
| 523 | '("Forward Matching Input..." . comint-forward-matching-input)) |
| 524 | (define-key map [menu-bar inout backward-matching-history] |
| 525 | '("Backward Matching Input..." . comint-backward-matching-input)) |
| 526 | (define-key map [menu-bar inout next-matching-history] |
| 527 | '("Next Matching Input..." . comint-next-matching-input)) |
| 528 | (define-key map [menu-bar inout previous-matching-history] |
| 529 | '("Previous Matching Input..." . comint-previous-matching-input)) |
| 530 | (define-key map [menu-bar inout next-matching-history-from-input] |
| 531 | '("Next Matching Current Input" . comint-next-matching-input-from-input)) |
| 532 | (define-key map [menu-bar inout previous-matching-history-from-input] |
| 533 | '("Previous Matching Current Input" . comint-previous-matching-input-from-input)) |
| 534 | (define-key map [menu-bar inout next-history] |
| 535 | '("Next Input" . comint-next-input)) |
| 536 | (define-key map [menu-bar inout previous-history] |
| 537 | '("Previous Input" . comint-previous-input)) |
| 538 | (define-key map [menu-bar inout list-history] |
| 539 | '("List Input History" . comint-dynamic-list-input-ring)) |
| 540 | (define-key map [menu-bar inout expand-history] |
| 541 | '("Expand History Before Point" . comint-replace-by-expanded-history)) |
| 542 | ;; Signals |
| 543 | (let ((signals-map (make-sparse-keymap "Signals"))) |
| 544 | (define-key map [menu-bar signals] (cons "Signals" signals-map)) |
| 545 | (define-key signals-map [eof] '("EOF" . comint-send-eof)) |
| 546 | (define-key signals-map [kill] '("KILL" . comint-kill-subjob)) |
| 547 | (define-key signals-map [quit] '("QUIT" . comint-quit-subjob)) |
| 548 | (define-key signals-map [cont] '("CONT" . comint-continue-subjob)) |
| 549 | (define-key signals-map [stop] '("STOP" . comint-stop-subjob)) |
| 550 | (define-key signals-map [break] '("BREAK" . comint-interrupt-subjob))) |
| 551 | ;; Put them in the menu bar: |
| 552 | (setq menu-bar-final-items (append '(completion inout signals) |
| 553 | menu-bar-final-items)) |
| 554 | map)) |
| 555 | |
| 556 | ;; Fixme: Is this still relevant? |
| 557 | (defvar comint-ptyp t |
| 558 | "Non-nil if communications via pty; false if by pipe. Buffer local. |
| 559 | This is to work around a bug in Emacs process signaling.") |
| 560 | |
| 561 | (defvar comint-input-ring nil) |
| 562 | (defvar comint-last-input-start nil) |
| 563 | (defvar comint-last-input-end nil) |
| 564 | (defvar comint-last-output-start nil) |
| 565 | (defvar comint-input-ring-index nil |
| 566 | "Index of last matched history element.") |
| 567 | (defvar comint-matching-input-from-input-string "" |
| 568 | "Input previously used to match input history.") |
| 569 | (defvar comint-save-input-ring-index nil |
| 570 | "Last input ring index which you copied. |
| 571 | This is to support the command \\[comint-get-next-from-history].") |
| 572 | |
| 573 | (defvar comint-accum-marker nil |
| 574 | "Non-nil if you are accumulating input lines to send as input together. |
| 575 | The command \\[comint-accumulate] sets this.") |
| 576 | |
| 577 | (defvar comint-stored-incomplete-input nil |
| 578 | "Stored input for history cycling.") |
| 579 | |
| 580 | (put 'comint-replace-by-expanded-history 'menu-enable 'comint-input-autoexpand) |
| 581 | (put 'comint-input-ring 'permanent-local t) |
| 582 | (put 'comint-input-ring-index 'permanent-local t) |
| 583 | (put 'comint-save-input-ring-index 'permanent-local t) |
| 584 | (put 'comint-input-autoexpand 'permanent-local t) |
| 585 | (put 'comint-input-filter-functions 'permanent-local t) |
| 586 | (put 'comint-output-filter-functions 'permanent-local t) |
| 587 | (put 'comint-preoutput-filter-functions 'permanent-local t) |
| 588 | (put 'comint-scroll-to-bottom-on-input 'permanent-local t) |
| 589 | (put 'comint-move-point-for-output 'permanent-local t) |
| 590 | (put 'comint-scroll-show-maximum-output 'permanent-local t) |
| 591 | (put 'comint-ptyp 'permanent-local t) |
| 592 | |
| 593 | (put 'comint-mode 'mode-class 'special) |
| 594 | |
| 595 | (define-derived-mode comint-mode fundamental-mode "Comint" |
| 596 | "Major mode for interacting with an inferior interpreter. |
| 597 | Interpreter name is same as buffer name, sans the asterisks. |
| 598 | Return at end of buffer sends line as input. |
| 599 | Return not at end copies rest of line to end and sends it. |
| 600 | Setting variable `comint-eol-on-send' means jump to the end of the line |
| 601 | before submitting new input. |
| 602 | |
| 603 | This mode is customized to create major modes such as Inferior Lisp |
| 604 | mode, Shell mode, etc. This can be done by setting the hooks |
| 605 | `comint-input-filter-functions', `comint-input-filter', `comint-input-sender' |
| 606 | and `comint-get-old-input' to appropriate functions, and the variable |
| 607 | `comint-prompt-regexp' to the appropriate regular expression. |
| 608 | |
| 609 | The mode maintains an input history of size `comint-input-ring-size'. |
| 610 | You can access this with the commands \\[comint-next-input], |
| 611 | \\[comint-previous-input], and \\[comint-dynamic-list-input-ring]. |
| 612 | Input ring history expansion can be achieved with the commands |
| 613 | \\[comint-replace-by-expanded-history] or \\[comint-magic-space]. |
| 614 | Input ring expansion is controlled by the variable `comint-input-autoexpand', |
| 615 | and addition is controlled by the variable `comint-input-ignoredups'. |
| 616 | |
| 617 | Commands with no default key bindings include `send-invisible', |
| 618 | `comint-dynamic-complete', `comint-dynamic-list-filename-completions', and |
| 619 | `comint-magic-space'. |
| 620 | |
| 621 | Input to, and output from, the subprocess can cause the window to scroll to |
| 622 | the end of the buffer. See variables `comint-output-filter-functions', |
| 623 | `comint-preoutput-filter-functions', `comint-scroll-to-bottom-on-input', |
| 624 | and `comint-move-point-for-output'. |
| 625 | |
| 626 | If you accidentally suspend your process, use \\[comint-continue-subjob] |
| 627 | to continue it. |
| 628 | |
| 629 | \\{comint-mode-map} |
| 630 | |
| 631 | Entry to this mode runs the hooks on `comint-mode-hook'." |
| 632 | (setq mode-line-process '(":%s")) |
| 633 | (set (make-local-variable 'window-point-insertion-type) t) |
| 634 | (set (make-local-variable 'comint-last-input-start) (point-min-marker)) |
| 635 | (set (make-local-variable 'comint-last-input-end) (point-min-marker)) |
| 636 | (set (make-local-variable 'comint-last-output-start) (make-marker)) |
| 637 | (make-local-variable 'comint-last-prompt-overlay) |
| 638 | (make-local-variable 'comint-prompt-regexp) ; Don't set; default |
| 639 | (make-local-variable 'comint-input-ring-size) ; ...to global val. |
| 640 | (make-local-variable 'comint-input-ring) |
| 641 | (make-local-variable 'comint-input-ring-file-name) |
| 642 | (or (and (boundp 'comint-input-ring) comint-input-ring) |
| 643 | (setq comint-input-ring (make-ring comint-input-ring-size))) |
| 644 | (make-local-variable 'comint-input-ring-index) |
| 645 | (make-local-variable 'comint-save-input-ring-index) |
| 646 | (or (and (boundp 'comint-input-ring-index) comint-input-ring-index) |
| 647 | (setq comint-input-ring-index nil)) |
| 648 | (or (and (boundp 'comint-save-input-ring-index) comint-save-input-ring-index) |
| 649 | (setq comint-save-input-ring-index nil)) |
| 650 | (make-local-variable 'comint-matching-input-from-input-string) |
| 651 | (make-local-variable 'comint-input-autoexpand) |
| 652 | (make-local-variable 'comint-input-ignoredups) |
| 653 | (make-local-variable 'comint-delimiter-argument-list) |
| 654 | (make-local-variable 'comint-completion-fignore) |
| 655 | (make-local-variable 'comint-get-old-input) |
| 656 | (make-local-variable 'comint-input-filter) |
| 657 | (make-local-variable 'comint-input-sender) |
| 658 | (make-local-variable 'comint-eol-on-send) |
| 659 | (make-local-variable 'comint-scroll-to-bottom-on-input) |
| 660 | (make-local-variable 'comint-move-point-for-output) |
| 661 | (make-local-variable 'comint-scroll-show-maximum-output) |
| 662 | (make-local-variable 'comint-stored-incomplete-input) |
| 663 | ;; Following disabled because it seems to break the case when |
| 664 | ;; comint-scroll-show-maximum-output is nil, and no-one can remember |
| 665 | ;; what the original problem was. If there are problems with point |
| 666 | ;; not going to the end, consider re-enabling this. |
| 667 | ;; http://lists.gnu.org/archive/html/emacs-devel/2007-08/msg00827.html |
| 668 | ;; |
| 669 | ;; This makes it really work to keep point at the bottom. |
| 670 | ;; (make-local-variable 'scroll-conservatively) |
| 671 | ;; (setq scroll-conservatively 10000) |
| 672 | (add-hook 'pre-command-hook 'comint-preinput-scroll-to-bottom t t) |
| 673 | (make-local-variable 'comint-ptyp) |
| 674 | (make-local-variable 'comint-process-echoes) |
| 675 | (make-local-variable 'comint-file-name-chars) |
| 676 | (make-local-variable 'comint-file-name-quote-list) |
| 677 | ;; dir tracking on remote files |
| 678 | (set (make-local-variable 'comint-file-name-prefix) |
| 679 | (or (file-remote-p default-directory) "")) |
| 680 | (make-local-variable 'comint-accum-marker) |
| 681 | (setq comint-accum-marker (make-marker)) |
| 682 | (make-local-variable 'font-lock-defaults) |
| 683 | (setq font-lock-defaults '(nil t)) |
| 684 | (add-hook 'change-major-mode-hook 'font-lock-defontify nil t) |
| 685 | (add-hook 'isearch-mode-hook 'comint-history-isearch-setup nil t) |
| 686 | (add-hook 'completion-at-point-functions 'comint-completion-at-point nil t) |
| 687 | ;; This behavior is not useful in comint buffers, and is annoying |
| 688 | (set (make-local-variable 'next-line-add-newlines) nil)) |
| 689 | |
| 690 | (defun comint-check-proc (buffer) |
| 691 | "Return non-nil if there is a living process associated w/buffer BUFFER. |
| 692 | Living means the status is `open', `run', or `stop'. |
| 693 | BUFFER can be either a buffer or the name of one." |
| 694 | (let ((proc (get-buffer-process buffer))) |
| 695 | (and proc (memq (process-status proc) '(open run stop))))) |
| 696 | |
| 697 | ;;;###autoload |
| 698 | (defun make-comint-in-buffer (name buffer program &optional startfile &rest switches) |
| 699 | "Make a Comint process NAME in BUFFER, running PROGRAM. |
| 700 | If BUFFER is nil, it defaults to NAME surrounded by `*'s. |
| 701 | PROGRAM should be either a string denoting an executable program to create |
| 702 | via `start-file-process', or a cons pair of the form (HOST . SERVICE) denoting |
| 703 | a TCP connection to be opened via `open-network-stream'. If there is already |
| 704 | a running process in that buffer, it is not restarted. Optional fourth arg |
| 705 | STARTFILE is the name of a file, whose contents are sent to the |
| 706 | process as its initial input. |
| 707 | |
| 708 | If PROGRAM is a string, any more args are arguments to PROGRAM. |
| 709 | |
| 710 | Returns the (possibly newly created) process buffer." |
| 711 | (or (fboundp 'start-file-process) |
| 712 | (error "Multi-processing is not supported for this system")) |
| 713 | (setq buffer (get-buffer-create (or buffer (concat "*" name "*")))) |
| 714 | ;; If no process, or nuked process, crank up a new one and put buffer in |
| 715 | ;; comint mode. Otherwise, leave buffer and existing process alone. |
| 716 | (unless (comint-check-proc buffer) |
| 717 | (with-current-buffer buffer |
| 718 | (unless (derived-mode-p 'comint-mode) |
| 719 | (comint-mode))) ; Install local vars, mode, keymap, ... |
| 720 | (comint-exec buffer name program startfile switches)) |
| 721 | buffer) |
| 722 | |
| 723 | ;;;###autoload |
| 724 | (defun make-comint (name program &optional startfile &rest switches) |
| 725 | "Make a Comint process NAME in a buffer, running PROGRAM. |
| 726 | The name of the buffer is made by surrounding NAME with `*'s. |
| 727 | PROGRAM should be either a string denoting an executable program to create |
| 728 | via `start-file-process', or a cons pair of the form (HOST . SERVICE) denoting |
| 729 | a TCP connection to be opened via `open-network-stream'. If there is already |
| 730 | a running process in that buffer, it is not restarted. Optional third arg |
| 731 | STARTFILE is the name of a file, whose contents are sent to the |
| 732 | process as its initial input. |
| 733 | |
| 734 | If PROGRAM is a string, any more args are arguments to PROGRAM. |
| 735 | |
| 736 | Returns the (possibly newly created) process buffer." |
| 737 | (apply #'make-comint-in-buffer name nil program startfile switches)) |
| 738 | |
| 739 | ;;;###autoload |
| 740 | (defun comint-run (program) |
| 741 | "Run PROGRAM in a Comint buffer and switch to it. |
| 742 | The buffer name is made by surrounding the file name of PROGRAM with `*'s. |
| 743 | The file name is used to make a symbol name, such as `comint-sh-hook', and any |
| 744 | hooks on this symbol are run in the buffer. |
| 745 | See `make-comint' and `comint-exec'." |
| 746 | (interactive "sRun program: ") |
| 747 | (let ((name (file-name-nondirectory program))) |
| 748 | (switch-to-buffer (make-comint name program)) |
| 749 | (run-hooks (intern-soft (concat "comint-" name "-hook"))))) |
| 750 | |
| 751 | (defun comint-exec (buffer name command startfile switches) |
| 752 | "Start up a process named NAME in buffer BUFFER for Comint modes. |
| 753 | Runs the given COMMAND with SWITCHES, and initial input from STARTFILE. |
| 754 | Blasts any old process running in the buffer. Doesn't set the buffer mode. |
| 755 | You can use this to cheaply run a series of processes in the same Comint |
| 756 | buffer. The hook `comint-exec-hook' is run after each exec." |
| 757 | (with-current-buffer buffer |
| 758 | (let ((proc (get-buffer-process buffer))) ; Blast any old process. |
| 759 | (if proc (delete-process proc))) |
| 760 | ;; Crank up a new process |
| 761 | (let ((proc |
| 762 | (if (consp command) |
| 763 | (open-network-stream name buffer (car command) (cdr command)) |
| 764 | (comint-exec-1 name buffer command switches)))) |
| 765 | (set-process-filter proc 'comint-output-filter) |
| 766 | (make-local-variable 'comint-ptyp) |
| 767 | (setq comint-ptyp process-connection-type) ; t if pty, nil if pipe. |
| 768 | ;; Jump to the end, and set the process mark. |
| 769 | (goto-char (point-max)) |
| 770 | (set-marker (process-mark proc) (point)) |
| 771 | ;; Feed it the startfile. |
| 772 | (cond (startfile |
| 773 | ;;This is guaranteed to wait long enough |
| 774 | ;;but has bad results if the comint does not prompt at all |
| 775 | ;; (while (= size (buffer-size)) |
| 776 | ;; (sleep-for 1)) |
| 777 | ;;I hope 1 second is enough! |
| 778 | (sleep-for 1) |
| 779 | (goto-char (point-max)) |
| 780 | (insert-file-contents startfile) |
| 781 | (setq startfile (buffer-substring (point) (point-max))) |
| 782 | (delete-region (point) (point-max)) |
| 783 | (comint-send-string proc startfile))) |
| 784 | (run-hooks 'comint-exec-hook) |
| 785 | buffer))) |
| 786 | |
| 787 | ;; This auxiliary function cranks up the process for comint-exec in |
| 788 | ;; the appropriate environment. |
| 789 | |
| 790 | (defun comint-exec-1 (name buffer command switches) |
| 791 | (let ((process-environment |
| 792 | (nconc |
| 793 | ;; If using termcap, we specify `emacs' as the terminal type |
| 794 | ;; because that lets us specify a width. |
| 795 | ;; If using terminfo, we specify `dumb' because that is |
| 796 | ;; a defined terminal type. `emacs' is not a defined terminal type |
| 797 | ;; and there is no way for us to define it here. |
| 798 | ;; Some programs that use terminfo get very confused |
| 799 | ;; if TERM is not a valid terminal type. |
| 800 | ;; ;; There is similar code in compile.el. |
| 801 | (if (and (boundp 'system-uses-terminfo) system-uses-terminfo) |
| 802 | (list "TERM=dumb" "TERMCAP=" |
| 803 | (format "COLUMNS=%d" (window-width))) |
| 804 | (list "TERM=emacs" |
| 805 | (format "TERMCAP=emacs:co#%d:tc=unknown:" (window-width)))) |
| 806 | (unless (getenv "EMACS") |
| 807 | (list "EMACS=t")) |
| 808 | (list (format "INSIDE_EMACS=%s,comint" emacs-version)) |
| 809 | process-environment)) |
| 810 | (default-directory |
| 811 | (if (file-accessible-directory-p default-directory) |
| 812 | default-directory |
| 813 | "/")) |
| 814 | proc decoding encoding changed) |
| 815 | (let ((exec-path (if (and command (file-name-directory command)) |
| 816 | ;; If the command has slashes, make sure we |
| 817 | ;; first look relative to the current directory. |
| 818 | (cons default-directory exec-path) exec-path))) |
| 819 | (setq proc (apply 'start-file-process name buffer command switches))) |
| 820 | ;; Some file name handler cannot start a process, fe ange-ftp. |
| 821 | (unless (processp proc) (error "No process started")) |
| 822 | (let ((coding-systems (process-coding-system proc))) |
| 823 | (setq decoding (car coding-systems) |
| 824 | encoding (cdr coding-systems))) |
| 825 | ;; Even if start-file-process left the coding system for encoding data |
| 826 | ;; sent from the process undecided, we had better use the same one |
| 827 | ;; as what we use for decoding. But, we should suppress EOL |
| 828 | ;; conversion. |
| 829 | (if (and decoding (not encoding)) |
| 830 | (setq encoding (coding-system-change-eol-conversion decoding 'unix) |
| 831 | changed t)) |
| 832 | (if changed |
| 833 | (set-process-coding-system proc decoding encoding)) |
| 834 | proc)) |
| 835 | |
| 836 | (defun comint-insert-input (event) |
| 837 | "In a Comint buffer, set the current input to the previous input at point. |
| 838 | If there is no previous input at point, run the command specified |
| 839 | by the global keymap (usually `mouse-yank-at-click')." |
| 840 | (interactive "e") |
| 841 | ;; Don't set the mouse here, since it may otherwise change the behavior |
| 842 | ;; of the command on which we fallback if there's no field at point. |
| 843 | ;; (mouse-set-point event) |
| 844 | (let ((pos (posn-point (event-end event))) |
| 845 | field input) |
| 846 | (with-selected-window (posn-window (event-end event)) |
| 847 | ;; If pos is at the very end of a field, the mouse-click was |
| 848 | ;; probably outside (to the right) of the field. |
| 849 | (and (< pos (field-end pos)) |
| 850 | (< (field-end pos) (point-max)) |
| 851 | (progn (setq field (field-at-pos pos)) |
| 852 | (setq input (field-string-no-properties pos))))) |
| 853 | (if (or (null input) (null comint-accum-marker) field) |
| 854 | ;; Fall back to the global definition if (i) the selected |
| 855 | ;; buffer is not a comint buffer (which can happen if a |
| 856 | ;; non-comint window was selected and we clicked in a comint |
| 857 | ;; window), or (ii) there is no input at POS. |
| 858 | (let* ((keys (this-command-keys)) |
| 859 | (last-key (and (vectorp keys) (aref keys (1- (length keys))))) |
| 860 | (fun (and last-key (lookup-key global-map (vector last-key))))) |
| 861 | (and fun (not (eq fun 'comint-insert-input)) |
| 862 | (call-interactively fun))) |
| 863 | (with-selected-window (posn-window (event-end event)) |
| 864 | ;; Otherwise, insert the previous input. |
| 865 | (goto-char (point-max)) |
| 866 | ;; First delete any old unsent input at the end |
| 867 | (delete-region |
| 868 | (or (marker-position comint-accum-marker) |
| 869 | (process-mark (get-buffer-process (current-buffer)))) |
| 870 | (point)) |
| 871 | ;; Insert the input at point |
| 872 | (insert input))))) |
| 873 | \f |
| 874 | ;; Input history processing in a buffer |
| 875 | ;; =========================================================================== |
| 876 | ;; Useful input history functions, courtesy of the Ergo group. |
| 877 | |
| 878 | ;; Eleven commands: |
| 879 | ;; comint-dynamic-list-input-ring List history in help buffer. |
| 880 | ;; comint-previous-input Previous input... |
| 881 | ;; comint-previous-matching-input ...matching a string. |
| 882 | ;; comint-previous-matching-input-from-input ... matching the current input. |
| 883 | ;; comint-next-input Next input... |
| 884 | ;; comint-next-matching-input ...matching a string. |
| 885 | ;; comint-next-matching-input-from-input ... matching the current input. |
| 886 | ;; comint-backward-matching-input Backwards input... |
| 887 | ;; comint-forward-matching-input ...matching a string. |
| 888 | ;; comint-replace-by-expanded-history Expand history at point; |
| 889 | ;; replace with expanded history. |
| 890 | ;; comint-magic-space Expand history and insert space. |
| 891 | ;; |
| 892 | ;; Three functions: |
| 893 | ;; comint-read-input-ring Read into comint-input-ring... |
| 894 | ;; comint-write-input-ring Write to comint-input-ring-file-name. |
| 895 | ;; comint-replace-by-expanded-history-before-point Workhorse function. |
| 896 | |
| 897 | (defun comint-read-input-ring (&optional silent) |
| 898 | "Set the buffer's `comint-input-ring' from a history file. |
| 899 | The name of the file is given by the variable `comint-input-ring-file-name'. |
| 900 | The history ring is of size `comint-input-ring-size', regardless of file size. |
| 901 | If `comint-input-ring-file-name' is nil this function does nothing. |
| 902 | |
| 903 | If the optional argument SILENT is non-nil, we say nothing about a |
| 904 | failure to read the history file. |
| 905 | |
| 906 | This function is useful for major mode commands and mode hooks. |
| 907 | |
| 908 | The commands stored in the history file are separated by the |
| 909 | `comint-input-ring-separator', and entries that match |
| 910 | `comint-input-history-ignore' are ignored. The most recent command |
| 911 | comes last. |
| 912 | |
| 913 | See also `comint-input-ignoredups' and `comint-write-input-ring'." |
| 914 | (cond ((or (null comint-input-ring-file-name) |
| 915 | (equal comint-input-ring-file-name "")) |
| 916 | nil) |
| 917 | ((not (file-readable-p comint-input-ring-file-name)) |
| 918 | (or silent |
| 919 | (message "Cannot read history file %s" |
| 920 | comint-input-ring-file-name))) |
| 921 | (t |
| 922 | (let* ((file comint-input-ring-file-name) |
| 923 | (count 0) |
| 924 | (size comint-input-ring-size) |
| 925 | (ring (make-ring size))) |
| 926 | (with-temp-buffer |
| 927 | (insert-file-contents file) |
| 928 | ;; Save restriction in case file is already visited... |
| 929 | ;; Watch for those date stamps in history files! |
| 930 | (goto-char (point-max)) |
| 931 | (let (start end history) |
| 932 | (while (and (< count size) |
| 933 | (re-search-backward comint-input-ring-separator |
| 934 | nil t) |
| 935 | (setq end (match-beginning 0))) |
| 936 | (setq start |
| 937 | (if (re-search-backward comint-input-ring-separator |
| 938 | nil t) |
| 939 | (match-end 0) |
| 940 | (point-min))) |
| 941 | (setq history (buffer-substring start end)) |
| 942 | (goto-char start) |
| 943 | (if (and (not (string-match comint-input-history-ignore |
| 944 | history)) |
| 945 | (or (null comint-input-ignoredups) |
| 946 | (ring-empty-p ring) |
| 947 | (not (string-equal (ring-ref ring 0) |
| 948 | history)))) |
| 949 | (progn |
| 950 | (ring-insert-at-beginning ring history) |
| 951 | (setq count (1+ count))))))) |
| 952 | (setq comint-input-ring ring |
| 953 | comint-input-ring-index nil))))) |
| 954 | |
| 955 | (defun comint-write-input-ring () |
| 956 | "Writes the buffer's `comint-input-ring' to a history file. |
| 957 | The name of the file is given by the variable `comint-input-ring-file-name'. |
| 958 | The original contents of the file are lost if `comint-input-ring' is not empty. |
| 959 | If `comint-input-ring-file-name' is nil this function does nothing. |
| 960 | |
| 961 | Useful within process sentinels. |
| 962 | |
| 963 | See also `comint-read-input-ring'." |
| 964 | (cond ((or (null comint-input-ring-file-name) |
| 965 | (equal comint-input-ring-file-name "") |
| 966 | (null comint-input-ring) (ring-empty-p comint-input-ring)) |
| 967 | nil) |
| 968 | ((not (file-writable-p comint-input-ring-file-name)) |
| 969 | (message "Cannot write history file %s" comint-input-ring-file-name)) |
| 970 | (t |
| 971 | (let* ((history-buf (get-buffer-create " *Temp Input History*")) |
| 972 | (ring comint-input-ring) |
| 973 | (file comint-input-ring-file-name) |
| 974 | (index (ring-length ring))) |
| 975 | ;; Write it all out into a buffer first. Much faster, but messier, |
| 976 | ;; than writing it one line at a time. |
| 977 | (with-current-buffer history-buf |
| 978 | (erase-buffer) |
| 979 | (while (> index 0) |
| 980 | (setq index (1- index)) |
| 981 | (insert (ring-ref ring index) comint-input-ring-separator)) |
| 982 | (write-region (buffer-string) nil file nil 'no-message) |
| 983 | (kill-buffer nil)))))) |
| 984 | |
| 985 | |
| 986 | (defvar comint-dynamic-list-input-ring-window-conf) |
| 987 | |
| 988 | (defun comint-dynamic-list-input-ring-select () |
| 989 | "Choose the input history entry that point is in or next to." |
| 990 | (interactive) |
| 991 | (let ((buffer completion-reference-buffer) |
| 992 | beg end completion) |
| 993 | (if (and (not (eobp)) (get-text-property (point) 'mouse-face)) |
| 994 | (setq end (point) beg (1+ (point)))) |
| 995 | (if (and (not (bobp)) (get-text-property (1- (point)) 'mouse-face)) |
| 996 | (setq end (1- (point)) beg (point))) |
| 997 | (if (null beg) |
| 998 | (error "No history entry here")) |
| 999 | (setq beg (previous-single-property-change beg 'mouse-face)) |
| 1000 | (setq end (or (next-single-property-change end 'mouse-face) (point-max))) |
| 1001 | (setq completion (buffer-substring beg end)) |
| 1002 | (set-window-configuration comint-dynamic-list-input-ring-window-conf) |
| 1003 | (choose-completion-string completion buffer))) |
| 1004 | |
| 1005 | (defun comint-dynamic-list-input-ring () |
| 1006 | "Display a list of recent inputs entered into the current buffer." |
| 1007 | (interactive) |
| 1008 | (if (or (not (ring-p comint-input-ring)) |
| 1009 | (ring-empty-p comint-input-ring)) |
| 1010 | (message "No history") |
| 1011 | (let ((history nil) |
| 1012 | (history-buffer " *Input History*") |
| 1013 | (conf (current-window-configuration))) |
| 1014 | ;; We have to build up a list ourselves from the ring vector. |
| 1015 | (dotimes (index (ring-length comint-input-ring)) |
| 1016 | (push (ring-ref comint-input-ring index) history)) |
| 1017 | ;; Show them most-recent-first. |
| 1018 | (setq history (nreverse history)) |
| 1019 | ;; Change "completion" to "history reference" |
| 1020 | ;; to make the display accurate. |
| 1021 | (with-output-to-temp-buffer history-buffer |
| 1022 | (display-completion-list history) |
| 1023 | (set-buffer history-buffer) |
| 1024 | (let ((keymap (make-sparse-keymap))) |
| 1025 | (set-keymap-parent keymap (current-local-map)) |
| 1026 | (define-key keymap "\C-m" 'comint-dynamic-list-input-ring-select) |
| 1027 | (use-local-map keymap)) |
| 1028 | (forward-line 3) |
| 1029 | (while (search-backward "completion" nil 'move) |
| 1030 | (replace-match "history reference"))) |
| 1031 | (sit-for 0) |
| 1032 | (message "Hit space to flush") |
| 1033 | (setq comint-dynamic-list-input-ring-window-conf conf) |
| 1034 | (let ((ch (read-event))) |
| 1035 | (if (eq ch ?\s) |
| 1036 | (set-window-configuration conf) |
| 1037 | (setq unread-command-events (list ch))))))) |
| 1038 | |
| 1039 | |
| 1040 | (defun comint-regexp-arg (prompt) |
| 1041 | "Return list of regexp and prefix arg using PROMPT." |
| 1042 | (let* (;; Don't clobber this. |
| 1043 | (last-command last-command) |
| 1044 | (regexp (read-from-minibuffer prompt nil nil nil |
| 1045 | 'minibuffer-history-search-history))) |
| 1046 | ;; If the user didn't enter anything, nothing is added to m-h-s-h. |
| 1047 | ;; Use the previous search regexp, if there is one. |
| 1048 | (list (if (string-equal regexp "") |
| 1049 | (or (car minibuffer-history-search-history) |
| 1050 | regexp) |
| 1051 | regexp) |
| 1052 | (prefix-numeric-value current-prefix-arg)))) |
| 1053 | |
| 1054 | (defun comint-search-arg (arg) |
| 1055 | ;; First make sure there is a ring and that we are after the process mark |
| 1056 | (cond ((not (comint-after-pmark-p)) |
| 1057 | (error "Not at command line")) |
| 1058 | ((or (null comint-input-ring) |
| 1059 | (ring-empty-p comint-input-ring)) |
| 1060 | (error "Empty input ring")) |
| 1061 | ((zerop arg) |
| 1062 | ;; arg of zero resets search from beginning, and uses arg of 1 |
| 1063 | (setq comint-input-ring-index nil) |
| 1064 | 1) |
| 1065 | (t |
| 1066 | arg))) |
| 1067 | |
| 1068 | (defun comint-restore-input () |
| 1069 | "Restore unfinished input." |
| 1070 | (interactive) |
| 1071 | (when comint-input-ring-index |
| 1072 | (comint-delete-input) |
| 1073 | (when (> (length comint-stored-incomplete-input) 0) |
| 1074 | (insert comint-stored-incomplete-input) |
| 1075 | (message "Input restored")) |
| 1076 | (setq comint-input-ring-index nil))) |
| 1077 | |
| 1078 | (defun comint-search-start (arg) |
| 1079 | "Index to start a directional search, starting at `comint-input-ring-index'." |
| 1080 | (if comint-input-ring-index |
| 1081 | ;; If a search is running, offset by 1 in direction of arg |
| 1082 | (mod (+ comint-input-ring-index (if (> arg 0) 1 -1)) |
| 1083 | (ring-length comint-input-ring)) |
| 1084 | ;; For a new search, start from beginning or end, as appropriate |
| 1085 | (if (>= arg 0) |
| 1086 | 0 ; First elt for forward search |
| 1087 | (1- (ring-length comint-input-ring))))) ; Last elt for backward search |
| 1088 | |
| 1089 | (defun comint-previous-input-string (arg) |
| 1090 | "Return the string ARG places along the input ring. |
| 1091 | Moves relative to `comint-input-ring-index'." |
| 1092 | (ring-ref comint-input-ring (if comint-input-ring-index |
| 1093 | (mod (+ arg comint-input-ring-index) |
| 1094 | (ring-length comint-input-ring)) |
| 1095 | arg))) |
| 1096 | |
| 1097 | (defun comint-previous-input (arg) |
| 1098 | "Cycle backwards through input history, saving input." |
| 1099 | (interactive "*p") |
| 1100 | (if (and comint-input-ring-index |
| 1101 | (or ;; leaving the "end" of the ring |
| 1102 | (and (< arg 0) ; going down |
| 1103 | (eq comint-input-ring-index 0)) |
| 1104 | (and (> arg 0) ; going up |
| 1105 | (eq comint-input-ring-index |
| 1106 | (1- (ring-length comint-input-ring))))) |
| 1107 | comint-stored-incomplete-input) |
| 1108 | (comint-restore-input) |
| 1109 | (comint-previous-matching-input "." arg))) |
| 1110 | |
| 1111 | (defun comint-next-input (arg) |
| 1112 | "Cycle forwards through input history." |
| 1113 | (interactive "*p") |
| 1114 | (comint-previous-input (- arg))) |
| 1115 | |
| 1116 | (defun comint-previous-matching-input-string (regexp arg) |
| 1117 | "Return the string matching REGEXP ARG places along the input ring. |
| 1118 | Moves relative to `comint-input-ring-index'." |
| 1119 | (let* ((pos (comint-previous-matching-input-string-position regexp arg))) |
| 1120 | (if pos (ring-ref comint-input-ring pos)))) |
| 1121 | |
| 1122 | (defun comint-previous-matching-input-string-position (regexp arg &optional start) |
| 1123 | "Return the index matching REGEXP ARG places along the input ring. |
| 1124 | Moves relative to START, or `comint-input-ring-index'." |
| 1125 | (if (or (not (ring-p comint-input-ring)) |
| 1126 | (ring-empty-p comint-input-ring)) |
| 1127 | (error "No history")) |
| 1128 | (let* ((len (ring-length comint-input-ring)) |
| 1129 | (motion (if (> arg 0) 1 -1)) |
| 1130 | (n (mod (- (or start (comint-search-start arg)) motion) len)) |
| 1131 | (tried-each-ring-item nil) |
| 1132 | (prev nil)) |
| 1133 | ;; Do the whole search as many times as the argument says. |
| 1134 | (while (and (/= arg 0) (not tried-each-ring-item)) |
| 1135 | ;; Step once. |
| 1136 | (setq prev n |
| 1137 | n (mod (+ n motion) len)) |
| 1138 | ;; If we haven't reached a match, step some more. |
| 1139 | (while (and (< n len) (not tried-each-ring-item) |
| 1140 | (not (string-match regexp (ring-ref comint-input-ring n)))) |
| 1141 | (setq n (mod (+ n motion) len) |
| 1142 | ;; If we have gone all the way around in this search. |
| 1143 | tried-each-ring-item (= n prev))) |
| 1144 | (setq arg (if (> arg 0) (1- arg) (1+ arg)))) |
| 1145 | ;; Now that we know which ring element to use, if we found it, return that. |
| 1146 | (if (string-match regexp (ring-ref comint-input-ring n)) |
| 1147 | n))) |
| 1148 | |
| 1149 | (defun comint-delete-input () |
| 1150 | "Delete all input between accumulation or process mark and point." |
| 1151 | (delete-region |
| 1152 | ;; Can't use kill-region as it sets this-command |
| 1153 | (or (marker-position comint-accum-marker) |
| 1154 | (process-mark (get-buffer-process (current-buffer)))) |
| 1155 | (point-max))) |
| 1156 | |
| 1157 | (defun comint-previous-matching-input (regexp n) |
| 1158 | "Search backwards through input history for match for REGEXP. |
| 1159 | \(Previous history elements are earlier commands.) |
| 1160 | With prefix argument N, search for Nth previous match. |
| 1161 | If N is negative, find the next or Nth next match." |
| 1162 | (interactive (comint-regexp-arg "Previous input matching (regexp): ")) |
| 1163 | (setq n (comint-search-arg n)) |
| 1164 | (let ((pos (comint-previous-matching-input-string-position regexp n))) |
| 1165 | ;; Has a match been found? |
| 1166 | (if (null pos) |
| 1167 | (error "Not found") |
| 1168 | ;; If leaving the edit line, save partial input |
| 1169 | (if (null comint-input-ring-index) ;not yet on ring |
| 1170 | (setq comint-stored-incomplete-input |
| 1171 | (funcall comint-get-old-input))) |
| 1172 | (setq comint-input-ring-index pos) |
| 1173 | (message "History item: %d" (1+ pos)) |
| 1174 | (comint-delete-input) |
| 1175 | (insert (ring-ref comint-input-ring pos))))) |
| 1176 | |
| 1177 | (defun comint-next-matching-input (regexp n) |
| 1178 | "Search forwards through input history for match for REGEXP. |
| 1179 | \(Later history elements are more recent commands.) |
| 1180 | With prefix argument N, search for Nth following match. |
| 1181 | If N is negative, find the previous or Nth previous match." |
| 1182 | (interactive (comint-regexp-arg "Next input matching (regexp): ")) |
| 1183 | (comint-previous-matching-input regexp (- n))) |
| 1184 | |
| 1185 | (defun comint-previous-matching-input-from-input (n) |
| 1186 | "Search backwards through input history for match for current input. |
| 1187 | \(Previous history elements are earlier commands.) |
| 1188 | With prefix argument N, search for Nth previous match. |
| 1189 | If N is negative, search forwards for the -Nth following match." |
| 1190 | (interactive "p") |
| 1191 | (if (not (memq last-command '(comint-previous-matching-input-from-input |
| 1192 | comint-next-matching-input-from-input))) |
| 1193 | ;; Starting a new search |
| 1194 | (setq comint-matching-input-from-input-string |
| 1195 | (buffer-substring |
| 1196 | (or (marker-position comint-accum-marker) |
| 1197 | (process-mark (get-buffer-process (current-buffer)))) |
| 1198 | (point)) |
| 1199 | comint-input-ring-index nil)) |
| 1200 | (comint-previous-matching-input |
| 1201 | (concat "^" (regexp-quote comint-matching-input-from-input-string)) |
| 1202 | n)) |
| 1203 | |
| 1204 | (defun comint-next-matching-input-from-input (n) |
| 1205 | "Search forwards through input history for match for current input. |
| 1206 | \(Following history elements are more recent commands.) |
| 1207 | With prefix argument N, search for Nth following match. |
| 1208 | If N is negative, search backwards for the -Nth previous match." |
| 1209 | (interactive "p") |
| 1210 | (comint-previous-matching-input-from-input (- n))) |
| 1211 | |
| 1212 | |
| 1213 | (defun comint-replace-by-expanded-history (&optional silent start) |
| 1214 | "Expand input command history references before point. |
| 1215 | Expansion is dependent on the value of `comint-input-autoexpand'. |
| 1216 | |
| 1217 | This function depends on the buffer's idea of the input history, which may not |
| 1218 | match the command interpreter's idea, assuming it has one. |
| 1219 | |
| 1220 | Assumes history syntax is like typical Un*x shells'. However, since Emacs |
| 1221 | cannot know the interpreter's idea of input line numbers, assuming it has one, |
| 1222 | it cannot expand absolute input line number references. |
| 1223 | |
| 1224 | If the optional argument SILENT is non-nil, never complain |
| 1225 | even if history reference seems erroneous. |
| 1226 | |
| 1227 | If the optional argument START is non-nil, that specifies the |
| 1228 | start of the text to scan for history references, rather |
| 1229 | than the logical beginning of line. |
| 1230 | |
| 1231 | See `comint-magic-space' and `comint-replace-by-expanded-history-before-point'. |
| 1232 | |
| 1233 | Returns t if successful." |
| 1234 | (interactive) |
| 1235 | (let ((f (comint-c-a-p-replace-by-expanded-history silent start))) |
| 1236 | (if f (funcall f)))) |
| 1237 | |
| 1238 | (defun comint-c-a-p-replace-by-expanded-history (&optional silent start) |
| 1239 | "Expand input command history at point. |
| 1240 | For use on `completion-at-point-functions'." |
| 1241 | (if (and comint-input-autoexpand |
| 1242 | (if comint-use-prompt-regexp |
| 1243 | ;; Use comint-prompt-regexp |
| 1244 | (save-excursion |
| 1245 | (beginning-of-line) |
| 1246 | (looking-at (concat comint-prompt-regexp "!\\|\\^"))) |
| 1247 | ;; Use input fields. User input that hasn't been entered |
| 1248 | ;; yet, at the end of the buffer, has a nil `field' property. |
| 1249 | (and (null (get-char-property (point) 'field)) |
| 1250 | (string-match "!\\|^\\^" (field-string)))) |
| 1251 | (catch 'dry-run |
| 1252 | (comint-replace-by-expanded-history-before-point |
| 1253 | silent start 'dry-run))) |
| 1254 | (lambda () |
| 1255 | ;; Looks like there might be history references in the command. |
| 1256 | (let ((previous-modified-tick (buffer-modified-tick))) |
| 1257 | (comint-replace-by-expanded-history-before-point silent start) |
| 1258 | (/= previous-modified-tick (buffer-modified-tick)))))) |
| 1259 | |
| 1260 | |
| 1261 | (defun comint-replace-by-expanded-history-before-point |
| 1262 | (silent &optional start dry-run) |
| 1263 | "Expand directory stack reference before point. |
| 1264 | See `comint-replace-by-expanded-history'. Returns t if successful. |
| 1265 | |
| 1266 | If the optional argument START is non-nil, that specifies the |
| 1267 | start of the text to scan for history references, rather |
| 1268 | than the logical beginning of line. |
| 1269 | |
| 1270 | If DRY-RUN is non-nil, throw to DRY-RUN before performing any |
| 1271 | actual side-effect." |
| 1272 | (save-excursion |
| 1273 | (let ((toend (- (line-end-position) (point))) |
| 1274 | (start (or start (comint-line-beginning-position)))) |
| 1275 | (goto-char start) |
| 1276 | (while (progn |
| 1277 | (skip-chars-forward "^!^" (- (line-end-position) toend)) |
| 1278 | (< (point) (- (line-end-position) toend))) |
| 1279 | ;; This seems a bit complex. We look for references such as !!, !-num, |
| 1280 | ;; !foo, !?foo, !{bar}, !?{bar}, ^oh, ^my^, ^god^it, ^never^ends^. |
| 1281 | ;; If that wasn't enough, the plings can be suffixed with argument |
| 1282 | ;; range specifiers. |
| 1283 | ;; Argument ranges are complex too, so we hive off the input line, |
| 1284 | ;; referenced with plings, with the range string to `comint-args'. |
| 1285 | (setq comint-input-ring-index nil) |
| 1286 | (cond ((or (= (preceding-char) ?\\) |
| 1287 | (comint-within-quotes start (point))) |
| 1288 | ;; The history is quoted, or we're in quotes. |
| 1289 | (goto-char (1+ (point)))) |
| 1290 | ((looking-at "![0-9]+\\($\\|[^-]\\)") |
| 1291 | ;; We cannot know the interpreter's idea of input line numbers. |
| 1292 | (if dry-run (throw dry-run 'message)) |
| 1293 | (goto-char (match-end 0)) |
| 1294 | (message "Absolute reference cannot be expanded")) |
| 1295 | ((looking-at "!-\\([0-9]+\\)\\(:?[0-9^$*-]+\\)?") |
| 1296 | ;; Just a number of args from `number' lines backward. |
| 1297 | (if dry-run (throw dry-run 'history)) |
| 1298 | (let ((number (1- (string-to-number |
| 1299 | (buffer-substring (match-beginning 1) |
| 1300 | (match-end 1)))))) |
| 1301 | (if (<= number (ring-length comint-input-ring)) |
| 1302 | (progn |
| 1303 | (replace-match |
| 1304 | (comint-args (comint-previous-input-string number) |
| 1305 | (match-beginning 2) (match-end 2)) |
| 1306 | t t) |
| 1307 | (setq comint-input-ring-index number) |
| 1308 | (message "History item: %d" (1+ number))) |
| 1309 | (goto-char (match-end 0)) |
| 1310 | (message "Relative reference exceeds input history size")))) |
| 1311 | ((or (looking-at "!!?:?\\([0-9^$*-]+\\)") (looking-at "!!")) |
| 1312 | ;; Just a number of args from the previous input line. |
| 1313 | (if dry-run (throw dry-run 'expand)) |
| 1314 | (replace-match (comint-args (comint-previous-input-string 0) |
| 1315 | (match-beginning 1) (match-end 1)) |
| 1316 | t t) |
| 1317 | (message "History item: previous")) |
| 1318 | ((looking-at |
| 1319 | "!\\??\\({\\(.+\\)}\\|\\(\\sw+\\)\\)\\(:?[0-9^$*-]+\\)?") |
| 1320 | ;; Most recent input starting with or containing (possibly |
| 1321 | ;; protected) string, maybe just a number of args. Phew. |
| 1322 | (if dry-run (throw dry-run 'expand)) |
| 1323 | (let* ((mb1 (match-beginning 1)) (me1 (match-end 1)) |
| 1324 | (mb2 (match-beginning 2)) (me2 (match-end 2)) |
| 1325 | (exp (buffer-substring (or mb2 mb1) (or me2 me1))) |
| 1326 | (pref (if (save-match-data (looking-at "!\\?")) "" "^")) |
| 1327 | (pos (save-match-data |
| 1328 | (comint-previous-matching-input-string-position |
| 1329 | (concat pref (regexp-quote exp)) 1)))) |
| 1330 | (if (null pos) |
| 1331 | (progn |
| 1332 | (goto-char (match-end 0)) |
| 1333 | (or silent |
| 1334 | (progn (message "Not found") |
| 1335 | (ding)))) |
| 1336 | (setq comint-input-ring-index pos) |
| 1337 | (replace-match |
| 1338 | (comint-args (ring-ref comint-input-ring pos) |
| 1339 | (match-beginning 4) (match-end 4)) |
| 1340 | t t) |
| 1341 | (message "History item: %d" (1+ pos))))) |
| 1342 | ((looking-at "\\^\\([^^]+\\)\\^?\\([^^]*\\)\\^?") |
| 1343 | ;; Quick substitution on the previous input line. |
| 1344 | (if dry-run (throw dry-run 'expand)) |
| 1345 | (let ((old (buffer-substring (match-beginning 1) (match-end 1))) |
| 1346 | (new (buffer-substring (match-beginning 2) (match-end 2))) |
| 1347 | (pos nil)) |
| 1348 | (replace-match (comint-previous-input-string 0) t t) |
| 1349 | (setq pos (point)) |
| 1350 | (goto-char (match-beginning 0)) |
| 1351 | (if (not (search-forward old pos t)) |
| 1352 | (or silent |
| 1353 | (error "Not found")) |
| 1354 | (replace-match new t t) |
| 1355 | (message "History item: substituted")))) |
| 1356 | (t |
| 1357 | (forward-char 1))))) |
| 1358 | nil)) |
| 1359 | |
| 1360 | |
| 1361 | (defun comint-magic-space (arg) |
| 1362 | "Expand input history references before point and insert ARG spaces. |
| 1363 | A useful command to bind to SPC. See `comint-replace-by-expanded-history'." |
| 1364 | (interactive "p") |
| 1365 | (comint-replace-by-expanded-history) |
| 1366 | (self-insert-command arg)) |
| 1367 | \f |
| 1368 | ;; Isearch in comint input history |
| 1369 | |
| 1370 | (defcustom comint-history-isearch nil |
| 1371 | "Non-nil to Isearch in input history only, not in comint buffer output. |
| 1372 | If t, usual Isearch keys like `C-r' and `C-M-r' in comint mode search |
| 1373 | in the input history. |
| 1374 | If `dwim', Isearch keys search in the input history only when initial |
| 1375 | point position is at the comint command line. When starting Isearch |
| 1376 | from other parts of the comint buffer, they search in the comint buffer. |
| 1377 | If nil, Isearch operates on the whole comint buffer." |
| 1378 | :type '(choice (const :tag "Don't search in input history" nil) |
| 1379 | (const :tag "When point is on command line initially, search history" dwim) |
| 1380 | (const :tag "Always search in input history" t)) |
| 1381 | :group 'comint |
| 1382 | :version "23.2") |
| 1383 | |
| 1384 | (defun comint-history-isearch-backward () |
| 1385 | "Search for a string backward in input history using Isearch." |
| 1386 | (interactive) |
| 1387 | (let ((comint-history-isearch t)) |
| 1388 | (isearch-backward))) |
| 1389 | |
| 1390 | (defun comint-history-isearch-backward-regexp () |
| 1391 | "Search for a regular expression backward in input history using Isearch." |
| 1392 | (interactive) |
| 1393 | (let ((comint-history-isearch t)) |
| 1394 | (isearch-backward-regexp))) |
| 1395 | |
| 1396 | (defvar comint-history-isearch-message-overlay nil) |
| 1397 | (make-variable-buffer-local 'comint-history-isearch-message-overlay) |
| 1398 | |
| 1399 | (defun comint-history-isearch-setup () |
| 1400 | "Set up a comint for using Isearch to search the input history. |
| 1401 | Intended to be added to `isearch-mode-hook' in `comint-mode'." |
| 1402 | (when (or (eq comint-history-isearch t) |
| 1403 | (and (eq comint-history-isearch 'dwim) |
| 1404 | ;; Point is at command line. |
| 1405 | (comint-after-pmark-p))) |
| 1406 | (setq isearch-message-prefix-add "history ") |
| 1407 | (set (make-local-variable 'isearch-search-fun-function) |
| 1408 | 'comint-history-isearch-search) |
| 1409 | (set (make-local-variable 'isearch-message-function) |
| 1410 | 'comint-history-isearch-message) |
| 1411 | (set (make-local-variable 'isearch-wrap-function) |
| 1412 | 'comint-history-isearch-wrap) |
| 1413 | (set (make-local-variable 'isearch-push-state-function) |
| 1414 | 'comint-history-isearch-push-state) |
| 1415 | (add-hook 'isearch-mode-end-hook 'comint-history-isearch-end nil t))) |
| 1416 | |
| 1417 | (defun comint-history-isearch-end () |
| 1418 | "Clean up the comint after terminating Isearch in comint." |
| 1419 | (if comint-history-isearch-message-overlay |
| 1420 | (delete-overlay comint-history-isearch-message-overlay)) |
| 1421 | (setq isearch-message-prefix-add nil) |
| 1422 | (setq isearch-search-fun-function nil) |
| 1423 | (setq isearch-message-function nil) |
| 1424 | (setq isearch-wrap-function nil) |
| 1425 | (setq isearch-push-state-function nil) |
| 1426 | (remove-hook 'isearch-mode-end-hook 'comint-history-isearch-end t)) |
| 1427 | |
| 1428 | (defun comint-goto-input (pos) |
| 1429 | "Put input history item of the absolute history position POS." |
| 1430 | ;; If leaving the edit line, save partial unfinished input. |
| 1431 | (if (null comint-input-ring-index) |
| 1432 | (setq comint-stored-incomplete-input |
| 1433 | (funcall comint-get-old-input))) |
| 1434 | (setq comint-input-ring-index pos) |
| 1435 | (comint-delete-input) |
| 1436 | (if (and pos (not (ring-empty-p comint-input-ring))) |
| 1437 | (insert (ring-ref comint-input-ring pos)) |
| 1438 | ;; Restore partial unfinished input. |
| 1439 | (when (> (length comint-stored-incomplete-input) 0) |
| 1440 | (insert comint-stored-incomplete-input)))) |
| 1441 | |
| 1442 | (defun comint-history-isearch-search () |
| 1443 | "Return the proper search function, for Isearch in input history." |
| 1444 | (cond |
| 1445 | (isearch-word |
| 1446 | (if isearch-forward 'word-search-forward 'word-search-backward)) |
| 1447 | (t |
| 1448 | (lambda (string bound noerror) |
| 1449 | (let ((search-fun |
| 1450 | ;; Use standard functions to search within comint text |
| 1451 | (cond |
| 1452 | (isearch-regexp |
| 1453 | (if isearch-forward 're-search-forward 're-search-backward)) |
| 1454 | (t |
| 1455 | (if isearch-forward 'search-forward 'search-backward)))) |
| 1456 | found) |
| 1457 | ;; Avoid lazy-highlighting matches in the comint prompt and in the |
| 1458 | ;; output when searching forward. Lazy-highlight calls this lambda |
| 1459 | ;; with the bound arg, so skip the prompt and the output. |
| 1460 | (if (and bound isearch-forward (not (comint-after-pmark-p))) |
| 1461 | (goto-char (process-mark (get-buffer-process (current-buffer))))) |
| 1462 | (or |
| 1463 | ;; 1. First try searching in the initial comint text |
| 1464 | (funcall search-fun string |
| 1465 | (if isearch-forward bound (comint-line-beginning-position)) |
| 1466 | noerror) |
| 1467 | ;; 2. If the above search fails, start putting next/prev history |
| 1468 | ;; elements in the comint successively, and search the string |
| 1469 | ;; in them. Do this only when bound is nil (i.e. not while |
| 1470 | ;; lazy-highlighting search strings in the current comint text). |
| 1471 | (unless bound |
| 1472 | (condition-case nil |
| 1473 | (progn |
| 1474 | (while (not found) |
| 1475 | (cond (isearch-forward |
| 1476 | ;; Signal an error here explicitly, because |
| 1477 | ;; `comint-next-input' doesn't signal an error. |
| 1478 | (when (null comint-input-ring-index) |
| 1479 | (error "End of history; no next item")) |
| 1480 | (comint-next-input 1) |
| 1481 | (goto-char (comint-line-beginning-position))) |
| 1482 | (t |
| 1483 | ;; Signal an error here explicitly, because |
| 1484 | ;; `comint-previous-input' doesn't signal an error. |
| 1485 | (when (eq comint-input-ring-index |
| 1486 | (1- (ring-length comint-input-ring))) |
| 1487 | (error "Beginning of history; no preceding item")) |
| 1488 | (comint-previous-input 1) |
| 1489 | (goto-char (point-max)))) |
| 1490 | (setq isearch-barrier (point) isearch-opoint (point)) |
| 1491 | ;; After putting the next/prev history element, search |
| 1492 | ;; the string in them again, until comint-next-input |
| 1493 | ;; or comint-previous-input raises an error at the |
| 1494 | ;; beginning/end of history. |
| 1495 | (setq found (funcall search-fun string |
| 1496 | (unless isearch-forward |
| 1497 | ;; For backward search, don't search |
| 1498 | ;; in the comint prompt |
| 1499 | (comint-line-beginning-position)) |
| 1500 | noerror))) |
| 1501 | ;; Return point of the new search result |
| 1502 | (point)) |
| 1503 | ;; Return nil on the error "no next/preceding item" |
| 1504 | (error nil))))))))) |
| 1505 | |
| 1506 | (defun comint-history-isearch-message (&optional c-q-hack ellipsis) |
| 1507 | "Display the input history search prompt. |
| 1508 | If there are no search errors, this function displays an overlay with |
| 1509 | the Isearch prompt which replaces the original comint prompt. |
| 1510 | Otherwise, it displays the standard Isearch message returned from |
| 1511 | `isearch-message'." |
| 1512 | (if (not (and isearch-success (not isearch-error))) |
| 1513 | ;; Use standard function `isearch-message' when not in comint prompt, |
| 1514 | ;; or search fails, or has an error (like incomplete regexp). |
| 1515 | ;; This function displays isearch message in the echo area, |
| 1516 | ;; so it's possible to see what is wrong in the search string. |
| 1517 | (isearch-message c-q-hack ellipsis) |
| 1518 | ;; Otherwise, put the overlay with the standard isearch prompt over |
| 1519 | ;; the initial comint prompt. |
| 1520 | (if (overlayp comint-history-isearch-message-overlay) |
| 1521 | (move-overlay comint-history-isearch-message-overlay |
| 1522 | (save-excursion (forward-line 0) (point)) |
| 1523 | (comint-line-beginning-position)) |
| 1524 | (setq comint-history-isearch-message-overlay |
| 1525 | (make-overlay (save-excursion (forward-line 0) (point)) |
| 1526 | (comint-line-beginning-position))) |
| 1527 | (overlay-put comint-history-isearch-message-overlay 'evaporate t)) |
| 1528 | (overlay-put comint-history-isearch-message-overlay |
| 1529 | 'display (isearch-message-prefix c-q-hack ellipsis)) |
| 1530 | ;; And clear any previous isearch message. |
| 1531 | (message ""))) |
| 1532 | |
| 1533 | (defun comint-history-isearch-wrap () |
| 1534 | "Wrap the input history search when search fails. |
| 1535 | Move point to the first history element for a forward search, |
| 1536 | or to the last history element for a backward search." |
| 1537 | (unless isearch-word |
| 1538 | ;; When `comint-history-isearch-search' fails on reaching the |
| 1539 | ;; beginning/end of the history, wrap the search to the first/last |
| 1540 | ;; input history element. |
| 1541 | (if isearch-forward |
| 1542 | (comint-goto-input (1- (ring-length comint-input-ring))) |
| 1543 | (comint-goto-input nil)) |
| 1544 | (setq isearch-success t)) |
| 1545 | (goto-char (if isearch-forward (comint-line-beginning-position) (point-max)))) |
| 1546 | |
| 1547 | (defun comint-history-isearch-push-state () |
| 1548 | "Save a function restoring the state of input history search. |
| 1549 | Save `comint-input-ring-index' to the additional state parameter |
| 1550 | in the search status stack." |
| 1551 | `(lambda (cmd) |
| 1552 | (comint-history-isearch-pop-state cmd ,comint-input-ring-index))) |
| 1553 | |
| 1554 | (defun comint-history-isearch-pop-state (_cmd hist-pos) |
| 1555 | "Restore the input history search state. |
| 1556 | Go to the history element by the absolute history position HIST-POS." |
| 1557 | (comint-goto-input hist-pos)) |
| 1558 | |
| 1559 | \f |
| 1560 | (defun comint-within-quotes (beg end) |
| 1561 | "Return t if the number of quotes between BEG and END is odd. |
| 1562 | Quotes are single and double." |
| 1563 | (let ((countsq (comint-how-many-region "\\(^\\|[^\\\\]\\)\'" beg end)) |
| 1564 | (countdq (comint-how-many-region "\\(^\\|[^\\\\]\\)\"" beg end))) |
| 1565 | (or (= (mod countsq 2) 1) (= (mod countdq 2) 1)))) |
| 1566 | |
| 1567 | (defun comint-how-many-region (regexp beg end) |
| 1568 | "Return number of matches for REGEXP from BEG to END." |
| 1569 | (let ((count 0)) |
| 1570 | (save-excursion |
| 1571 | (save-match-data |
| 1572 | (goto-char beg) |
| 1573 | (while (re-search-forward regexp end t) |
| 1574 | (setq count (1+ count))))) |
| 1575 | count)) |
| 1576 | |
| 1577 | (defun comint-args (string begin end) |
| 1578 | ;; From STRING, return the args depending on the range specified in the text |
| 1579 | ;; from BEGIN to END. If BEGIN is nil, assume all args. Ignore leading `:'. |
| 1580 | ;; Range can be x-y, x-, -y, where x/y can be [0-9], *, ^, $. |
| 1581 | (save-match-data |
| 1582 | (if (null begin) |
| 1583 | (comint-arguments string 0 nil) |
| 1584 | (let* ((range (buffer-substring |
| 1585 | (if (eq (char-after begin) ?:) (1+ begin) begin) end)) |
| 1586 | (nth (cond ((string-match "^[*^]" range) 1) |
| 1587 | ((string-match "^-" range) 0) |
| 1588 | ((string-equal range "$") nil) |
| 1589 | (t (string-to-number range)))) |
| 1590 | (mth (cond ((string-match "[-*$]$" range) nil) |
| 1591 | ((string-match "-" range) |
| 1592 | (string-to-number (substring range (match-end 0)))) |
| 1593 | (t nth)))) |
| 1594 | (comint-arguments string nth mth))))) |
| 1595 | |
| 1596 | (defun comint-delim-arg (arg) |
| 1597 | "Return a list of arguments from ARG. |
| 1598 | Break it up at the delimiters in `comint-delimiter-argument-list'. |
| 1599 | Returned list is backwards. |
| 1600 | |
| 1601 | Characters with non-nil values of the text property `literal' are |
| 1602 | assumed to have literal values (e.g., backslash-escaped |
| 1603 | characters), and are not considered to be delimiters." |
| 1604 | (if (null comint-delimiter-argument-list) |
| 1605 | (list arg) |
| 1606 | (let ((args nil) |
| 1607 | (pos 0) |
| 1608 | (len (length arg))) |
| 1609 | (while (< pos len) |
| 1610 | (let ((char (aref arg pos)) |
| 1611 | (start pos)) |
| 1612 | (if (and (memq char comint-delimiter-argument-list) |
| 1613 | ;; Ignore backslash-escaped characters. |
| 1614 | (not (get-text-property pos 'literal arg))) |
| 1615 | (while (and (< pos len) (eq (aref arg pos) char)) |
| 1616 | (setq pos (1+ pos))) |
| 1617 | (while (and (< pos len) |
| 1618 | (not (and (memq (aref arg pos) |
| 1619 | comint-delimiter-argument-list) |
| 1620 | (not (get-text-property |
| 1621 | pos 'literal arg))))) |
| 1622 | (setq pos (1+ pos)))) |
| 1623 | (setq args (cons (substring arg start pos) args)))) |
| 1624 | args))) |
| 1625 | |
| 1626 | (defun comint-arguments (string nth mth) |
| 1627 | "Return from STRING the NTH to MTH arguments. |
| 1628 | NTH and/or MTH can be nil, which means the last argument. |
| 1629 | Returned arguments are separated by single spaces. |
| 1630 | We assume whitespace separates arguments, except within quotes |
| 1631 | and except for a space or tab that immediately follows a backslash. |
| 1632 | Also, a run of one or more of a single character |
| 1633 | in `comint-delimiter-argument-list' is a separate argument. |
| 1634 | Argument 0 is the command name." |
| 1635 | ;; The first line handles ordinary characters and backslash-sequences |
| 1636 | ;; (except with w32 msdos-like shells, where backslashes are valid). |
| 1637 | ;; The second matches "-quoted strings. |
| 1638 | ;; The third matches '-quoted strings. |
| 1639 | ;; The fourth matches `-quoted strings. |
| 1640 | ;; This seems to fit the syntax of BASH 2.0. |
| 1641 | (let* ((backslash-escape (not (and (fboundp 'w32-shell-dos-semantics) |
| 1642 | (w32-shell-dos-semantics)))) |
| 1643 | (first (if backslash-escape |
| 1644 | "[^ \n\t\"'`\\]\\|\\(\\\\.\\)\\|" |
| 1645 | "[^ \n\t\"'`]+\\|")) |
| 1646 | (argpart (concat first |
| 1647 | "\\(\"\\([^\"\\]\\|\\\\.\\)*\"\\|\ |
| 1648 | '[^']*'\\|\ |
| 1649 | `[^`]*`\\)")) |
| 1650 | (quote-subexpr (if backslash-escape 2 1)) |
| 1651 | (args ()) (pos 0) |
| 1652 | (count 0) |
| 1653 | beg str quotes) |
| 1654 | ;; Build a list of all the args until we have as many as we want. |
| 1655 | (while (and (or (null mth) (<= count mth)) |
| 1656 | (string-match argpart string pos)) |
| 1657 | ;; Apply the `literal' text property to backslash-escaped |
| 1658 | ;; characters, so that `comint-delim-arg' won't break them up. |
| 1659 | (and backslash-escape |
| 1660 | (match-beginning 1) |
| 1661 | (put-text-property (match-beginning 1) (match-end 1) |
| 1662 | 'literal t string)) |
| 1663 | (if (and beg (= pos (match-beginning 0))) |
| 1664 | ;; It's contiguous, part of the same arg. |
| 1665 | (setq pos (match-end 0) |
| 1666 | quotes (or quotes (match-beginning quote-subexpr))) |
| 1667 | ;; It's a new separate arg. |
| 1668 | (if beg |
| 1669 | ;; Put the previous arg, if there was one, onto ARGS. |
| 1670 | (setq str (substring string beg pos) |
| 1671 | args (if quotes (cons str args) |
| 1672 | (nconc (comint-delim-arg str) args)))) |
| 1673 | (setq count (length args)) |
| 1674 | (setq quotes (match-beginning quote-subexpr)) |
| 1675 | (setq beg (match-beginning 0)) |
| 1676 | (setq pos (match-end 0)))) |
| 1677 | (if beg |
| 1678 | (setq str (substring string beg pos) |
| 1679 | args (if quotes (cons str args) |
| 1680 | (nconc (comint-delim-arg str) args)))) |
| 1681 | (setq count (length args)) |
| 1682 | (let ((n (or nth (1- count))) |
| 1683 | (m (if mth (1- (- count mth)) 0))) |
| 1684 | (mapconcat |
| 1685 | (function (lambda (a) a)) (nthcdr n (nreverse (nthcdr m args))) " ")))) |
| 1686 | \f |
| 1687 | ;; |
| 1688 | ;; Input processing stuff |
| 1689 | ;; |
| 1690 | (defun comint-add-to-input-history (cmd) |
| 1691 | "Add CMD to the input history. |
| 1692 | Ignore duplicates if `comint-input-ignoredups' is non-nil." |
| 1693 | (if (and (funcall comint-input-filter cmd) |
| 1694 | (or (null comint-input-ignoredups) |
| 1695 | (not (ring-p comint-input-ring)) |
| 1696 | (ring-empty-p comint-input-ring) |
| 1697 | (not (string-equal (ring-ref comint-input-ring 0) |
| 1698 | cmd)))) |
| 1699 | (ring-insert comint-input-ring cmd))) |
| 1700 | |
| 1701 | (defun comint-send-input (&optional no-newline artificial) |
| 1702 | "Send input to process. |
| 1703 | After the process output mark, sends all text from the process mark to |
| 1704 | point as input to the process. Before the process output mark, calls |
| 1705 | value of variable `comint-get-old-input' to retrieve old input, copies |
| 1706 | it to the process mark, and sends it. |
| 1707 | |
| 1708 | This command also sends and inserts a final newline, unless |
| 1709 | NO-NEWLINE is non-nil. |
| 1710 | |
| 1711 | Any history reference may be expanded depending on the value of the variable |
| 1712 | `comint-input-autoexpand'. The list of function names contained in the value |
| 1713 | of `comint-input-filter-functions' is called on the input before sending it. |
| 1714 | The input is entered into the input history ring, if the value of variable |
| 1715 | `comint-input-filter' returns non-nil when called on the input. |
| 1716 | |
| 1717 | If variable `comint-eol-on-send' is non-nil, then point is moved to the |
| 1718 | end of line before sending the input. |
| 1719 | |
| 1720 | After the input has been sent, if `comint-process-echoes' is non-nil, |
| 1721 | then `comint-send-input' waits to see if the process outputs a string |
| 1722 | matching the input, and if so, deletes that part of the output. |
| 1723 | If ARTIFICIAL is non-nil, it inhibits such deletion. |
| 1724 | Callers sending input not from the user should use ARTIFICIAL = t. |
| 1725 | |
| 1726 | The values of `comint-get-old-input', `comint-input-filter-functions', and |
| 1727 | `comint-input-filter' are chosen according to the command interpreter running |
| 1728 | in the buffer. E.g., |
| 1729 | |
| 1730 | If the interpreter is the csh, |
| 1731 | `comint-get-old-input' is the default: |
| 1732 | If `comint-use-prompt-regexp' is nil, then |
| 1733 | either return the current input field, if point is on an input |
| 1734 | field, or the current line, if point is on an output field. |
| 1735 | If `comint-use-prompt-regexp' is non-nil, then |
| 1736 | return the current line with any initial string matching the |
| 1737 | regexp `comint-prompt-regexp' removed. |
| 1738 | `comint-input-filter-functions' monitors input for \"cd\", \"pushd\", and |
| 1739 | \"popd\" commands. When it sees one, it cd's the buffer. |
| 1740 | `comint-input-filter' is the default: returns t if the input isn't all white |
| 1741 | space. |
| 1742 | |
| 1743 | If the Comint is Lucid Common Lisp, |
| 1744 | `comint-get-old-input' snarfs the sexp ending at point. |
| 1745 | `comint-input-filter-functions' does nothing. |
| 1746 | `comint-input-filter' returns nil if the input matches input-filter-regexp, |
| 1747 | which matches (1) all whitespace (2) :a, :c, etc. |
| 1748 | |
| 1749 | Similarly for Soar, Scheme, etc." |
| 1750 | (interactive) |
| 1751 | ;; Note that the input string does not include its terminal newline. |
| 1752 | (let ((proc (get-buffer-process (current-buffer)))) |
| 1753 | (if (not proc) (error "Current buffer has no process") |
| 1754 | (widen) |
| 1755 | (let* ((pmark (process-mark proc)) |
| 1756 | (intxt (if (>= (point) (marker-position pmark)) |
| 1757 | (progn (if comint-eol-on-send (end-of-line)) |
| 1758 | (buffer-substring pmark (point))) |
| 1759 | (let ((copy (funcall comint-get-old-input))) |
| 1760 | (goto-char pmark) |
| 1761 | (insert copy) |
| 1762 | copy))) |
| 1763 | (input (if (not (eq comint-input-autoexpand 'input)) |
| 1764 | ;; Just whatever's already there. |
| 1765 | intxt |
| 1766 | ;; Expand and leave it visible in buffer. |
| 1767 | (comint-replace-by-expanded-history t pmark) |
| 1768 | (buffer-substring pmark (point)))) |
| 1769 | (history (if (not (eq comint-input-autoexpand 'history)) |
| 1770 | input |
| 1771 | ;; This is messy 'cos ultimately the original |
| 1772 | ;; functions used do insertion, rather than return |
| 1773 | ;; strings. We have to expand, then insert back. |
| 1774 | (comint-replace-by-expanded-history t pmark) |
| 1775 | (let ((copy (buffer-substring pmark (point))) |
| 1776 | (start (point))) |
| 1777 | (insert input) |
| 1778 | (delete-region pmark start) |
| 1779 | copy)))) |
| 1780 | |
| 1781 | (unless no-newline |
| 1782 | (insert ?\n)) |
| 1783 | |
| 1784 | (comint-add-to-input-history history) |
| 1785 | |
| 1786 | (run-hook-with-args 'comint-input-filter-functions |
| 1787 | (if no-newline input |
| 1788 | (concat input "\n"))) |
| 1789 | |
| 1790 | (let ((beg (marker-position pmark)) |
| 1791 | (end (if no-newline (point) (1- (point)))) |
| 1792 | (inhibit-modification-hooks t)) |
| 1793 | (when (> end beg) |
| 1794 | (add-text-properties beg end |
| 1795 | '(front-sticky t |
| 1796 | font-lock-face comint-highlight-input)) |
| 1797 | (unless comint-use-prompt-regexp |
| 1798 | ;; Give old user input a field property of `input', to |
| 1799 | ;; distinguish it from both process output and unsent |
| 1800 | ;; input. The terminating newline is put into a special |
| 1801 | ;; `boundary' field to make cursor movement between input |
| 1802 | ;; and output fields smoother. |
| 1803 | (add-text-properties |
| 1804 | beg end |
| 1805 | '(mouse-face highlight |
| 1806 | help-echo "mouse-2: insert after prompt as new input")))) |
| 1807 | (unless (or no-newline comint-use-prompt-regexp) |
| 1808 | ;; Cover the terminating newline |
| 1809 | (add-text-properties end (1+ end) |
| 1810 | '(rear-nonsticky t |
| 1811 | field boundary |
| 1812 | inhibit-line-move-field-capture t)))) |
| 1813 | |
| 1814 | (comint-snapshot-last-prompt) |
| 1815 | |
| 1816 | (setq comint-save-input-ring-index comint-input-ring-index) |
| 1817 | (setq comint-input-ring-index nil) |
| 1818 | ;; Update the markers before we send the input |
| 1819 | ;; in case we get output amidst sending the input. |
| 1820 | (set-marker comint-last-input-start pmark) |
| 1821 | (set-marker comint-last-input-end (point)) |
| 1822 | (set-marker (process-mark proc) (point)) |
| 1823 | ;; clear the "accumulation" marker |
| 1824 | (set-marker comint-accum-marker nil) |
| 1825 | (let ((comint-input-sender-no-newline no-newline)) |
| 1826 | (funcall comint-input-sender proc input)) |
| 1827 | |
| 1828 | ;; Optionally delete echoed input (after checking it). |
| 1829 | (when (and comint-process-echoes (not artificial)) |
| 1830 | (let ((echo-len (- comint-last-input-end |
| 1831 | comint-last-input-start))) |
| 1832 | ;; Wait for all input to be echoed: |
| 1833 | (while (and (accept-process-output proc) |
| 1834 | (> (+ comint-last-input-end echo-len) |
| 1835 | (point-max)) |
| 1836 | (zerop |
| 1837 | (compare-buffer-substrings |
| 1838 | nil comint-last-input-start |
| 1839 | (- (point-max) echo-len) |
| 1840 | ;; Above difference is equivalent to |
| 1841 | ;; (+ comint-last-input-start |
| 1842 | ;; (- (point-max) comint-last-input-end)) |
| 1843 | nil comint-last-input-end (point-max))))) |
| 1844 | (if (and |
| 1845 | (<= (+ comint-last-input-end echo-len) |
| 1846 | (point-max)) |
| 1847 | (zerop |
| 1848 | (compare-buffer-substrings |
| 1849 | nil comint-last-input-start comint-last-input-end |
| 1850 | nil comint-last-input-end |
| 1851 | (+ comint-last-input-end echo-len)))) |
| 1852 | ;; Certain parts of the text to be deleted may have |
| 1853 | ;; been mistaken for prompts. We have to prevent |
| 1854 | ;; problems when `comint-prompt-read-only' is non-nil. |
| 1855 | (let ((inhibit-read-only t)) |
| 1856 | (delete-region comint-last-input-end |
| 1857 | (+ comint-last-input-end echo-len)) |
| 1858 | (when comint-prompt-read-only |
| 1859 | (save-excursion |
| 1860 | (goto-char comint-last-input-end) |
| 1861 | (comint-update-fence))))))) |
| 1862 | |
| 1863 | ;; This used to call comint-output-filter-functions, |
| 1864 | ;; but that scrolled the buffer in undesirable ways. |
| 1865 | (run-hook-with-args 'comint-output-filter-functions ""))))) |
| 1866 | |
| 1867 | (defvar comint-preoutput-filter-functions nil |
| 1868 | "List of functions to call before inserting Comint output into the buffer. |
| 1869 | Each function gets one argument, a string containing the text received |
| 1870 | from the subprocess. It should return the string to insert, perhaps |
| 1871 | the same string that was received, or perhaps a modified or transformed |
| 1872 | string. |
| 1873 | |
| 1874 | The functions on the list are called sequentially, and each one is |
| 1875 | given the string returned by the previous one. The string returned by |
| 1876 | the last function is the text that is actually inserted in the |
| 1877 | redirection buffer. |
| 1878 | |
| 1879 | You can use `add-hook' to add functions to this list |
| 1880 | either globally or locally.") |
| 1881 | |
| 1882 | (defvar comint-inhibit-carriage-motion nil |
| 1883 | "If nil, Comint will interpret `carriage control' characters in output. |
| 1884 | See `comint-carriage-motion' for details.") |
| 1885 | |
| 1886 | ;; When non-nil, this is an overlay over the last recognized prompt in |
| 1887 | ;; the buffer; it is used when highlighting the prompt. |
| 1888 | (defvar comint-last-prompt-overlay nil) |
| 1889 | |
| 1890 | (defun comint-snapshot-last-prompt () |
| 1891 | "`snapshot' any current `comint-last-prompt-overlay'. |
| 1892 | Freeze its attributes in place, even when more input comes along |
| 1893 | and moves the prompt overlay." |
| 1894 | (when comint-last-prompt-overlay |
| 1895 | (let ((inhibit-read-only t) |
| 1896 | (inhibit-modification-hooks t)) |
| 1897 | (add-text-properties (overlay-start comint-last-prompt-overlay) |
| 1898 | (overlay-end comint-last-prompt-overlay) |
| 1899 | (overlay-properties comint-last-prompt-overlay))))) |
| 1900 | |
| 1901 | (defun comint-carriage-motion (start end) |
| 1902 | "Interpret carriage control characters in the region from START to END. |
| 1903 | Translate carriage return/linefeed sequences to linefeeds. |
| 1904 | Make single carriage returns delete to the beginning of the line. |
| 1905 | Make backspaces delete the previous character." |
| 1906 | (save-excursion |
| 1907 | ;; We used to check the existence of \b and \r at first to avoid |
| 1908 | ;; calling save-match-data and save-restriction. But, such a |
| 1909 | ;; check is not necessary now because we don't use regexp search |
| 1910 | ;; nor save-restriction. Note that the buffer is already widen, |
| 1911 | ;; and calling narrow-to-region and widen are not that heavy. |
| 1912 | (goto-char start) |
| 1913 | (let* ((inhibit-field-text-motion t) |
| 1914 | (inhibit-read-only t) |
| 1915 | (lbeg (line-beginning-position)) |
| 1916 | delete-end ch) |
| 1917 | ;; If the preceding text is marked as "must-overwrite", record |
| 1918 | ;; it in delete-end. |
| 1919 | (when (and (> start (point-min)) |
| 1920 | (get-text-property (1- start) 'comint-must-overwrite)) |
| 1921 | (setq delete-end (point-marker)) |
| 1922 | (remove-text-properties lbeg start '(comint-must-overwrite nil))) |
| 1923 | (narrow-to-region lbeg end) |
| 1924 | ;; Handle BS, LF, and CR specially. |
| 1925 | (while (and (skip-chars-forward "^\b\n\r") (not (eobp))) |
| 1926 | (setq ch (following-char)) |
| 1927 | (cond ((= ch ?\b) ; CH = BS |
| 1928 | (delete-char 1) |
| 1929 | (if (> (point) lbeg) |
| 1930 | (delete-char -1))) |
| 1931 | ((= ch ?\n) |
| 1932 | (when delete-end ; CH = LF |
| 1933 | (if (< delete-end (point)) |
| 1934 | (delete-region lbeg delete-end)) |
| 1935 | (set-marker delete-end nil) |
| 1936 | (setq delete-end nil)) |
| 1937 | (forward-char 1) |
| 1938 | (setq lbeg (point))) |
| 1939 | (t ; CH = CR |
| 1940 | (delete-char 1) |
| 1941 | (if delete-end |
| 1942 | (when (< delete-end (point)) |
| 1943 | (delete-region lbeg delete-end) |
| 1944 | (move-marker delete-end (point))) |
| 1945 | (setq delete-end (point-marker)))))) |
| 1946 | (when delete-end |
| 1947 | (if (< delete-end (point)) |
| 1948 | ;; As there's a text after the last CR, make the current |
| 1949 | ;; line contain only that text. |
| 1950 | (delete-region lbeg delete-end) |
| 1951 | ;; Remember that the process output ends by CR, and thus we |
| 1952 | ;; must overwrite the contents of the current line next |
| 1953 | ;; time. |
| 1954 | (put-text-property lbeg delete-end 'comint-must-overwrite t)) |
| 1955 | (set-marker delete-end nil)) |
| 1956 | (widen)))) |
| 1957 | |
| 1958 | ;; The purpose of using this filter for comint processes |
| 1959 | ;; is to keep comint-last-input-end from moving forward |
| 1960 | ;; when output is inserted. |
| 1961 | (defun comint-output-filter (process string) |
| 1962 | (let ((oprocbuf (process-buffer process))) |
| 1963 | ;; First check for killed buffer or no input. |
| 1964 | (when (and string oprocbuf (buffer-name oprocbuf)) |
| 1965 | (with-current-buffer oprocbuf |
| 1966 | ;; Run preoutput filters |
| 1967 | (let ((functions comint-preoutput-filter-functions)) |
| 1968 | (while (and functions string) |
| 1969 | (if (eq (car functions) t) |
| 1970 | (let ((functions |
| 1971 | (default-value 'comint-preoutput-filter-functions))) |
| 1972 | (while (and functions string) |
| 1973 | (setq string (funcall (car functions) string)) |
| 1974 | (setq functions (cdr functions)))) |
| 1975 | (setq string (funcall (car functions) string))) |
| 1976 | (setq functions (cdr functions)))) |
| 1977 | |
| 1978 | ;; Insert STRING |
| 1979 | (let ((inhibit-read-only t) |
| 1980 | ;; The point should float after any insertion we do. |
| 1981 | (saved-point (copy-marker (point) t))) |
| 1982 | |
| 1983 | ;; We temporarily remove any buffer narrowing, in case the |
| 1984 | ;; process mark is outside of the restriction |
| 1985 | (save-restriction |
| 1986 | (widen) |
| 1987 | |
| 1988 | (goto-char (process-mark process)) |
| 1989 | (set-marker comint-last-output-start (point)) |
| 1990 | |
| 1991 | ;; insert-before-markers is a bad thing. XXX |
| 1992 | ;; Luckily we don't have to use it any more, we use |
| 1993 | ;; window-point-insertion-type instead. |
| 1994 | (insert string) |
| 1995 | |
| 1996 | ;; Advance process-mark |
| 1997 | (set-marker (process-mark process) (point)) |
| 1998 | |
| 1999 | (unless comint-inhibit-carriage-motion |
| 2000 | ;; Interpret any carriage motion characters (newline, backspace) |
| 2001 | (comint-carriage-motion comint-last-output-start (point))) |
| 2002 | |
| 2003 | ;; Run these hooks with point where the user had it. |
| 2004 | (goto-char saved-point) |
| 2005 | (run-hook-with-args 'comint-output-filter-functions string) |
| 2006 | (set-marker saved-point (point)) |
| 2007 | |
| 2008 | (goto-char (process-mark process)) ; in case a filter moved it |
| 2009 | |
| 2010 | (unless comint-use-prompt-regexp |
| 2011 | (let ((inhibit-read-only t) |
| 2012 | (inhibit-modification-hooks t)) |
| 2013 | (add-text-properties comint-last-output-start (point) |
| 2014 | '(front-sticky |
| 2015 | (field inhibit-line-move-field-capture) |
| 2016 | rear-nonsticky t |
| 2017 | field output |
| 2018 | inhibit-line-move-field-capture t)))) |
| 2019 | |
| 2020 | ;; Highlight the prompt, where we define `prompt' to mean |
| 2021 | ;; the most recent output that doesn't end with a newline. |
| 2022 | (let ((prompt-start (save-excursion (forward-line 0) (point))) |
| 2023 | (inhibit-read-only t) |
| 2024 | (inhibit-modification-hooks t)) |
| 2025 | (when comint-prompt-read-only |
| 2026 | (or (= (point-min) prompt-start) |
| 2027 | (get-text-property (1- prompt-start) 'read-only) |
| 2028 | (put-text-property |
| 2029 | (1- prompt-start) prompt-start 'read-only 'fence)) |
| 2030 | (add-text-properties |
| 2031 | prompt-start (point) |
| 2032 | '(read-only t rear-nonsticky t front-sticky (read-only)))) |
| 2033 | (unless (and (bolp) (null comint-last-prompt-overlay)) |
| 2034 | ;; Need to create or move the prompt overlay (in the case |
| 2035 | ;; where there is no prompt ((bolp) == t), we still do |
| 2036 | ;; this if there's already an existing overlay). |
| 2037 | (if comint-last-prompt-overlay |
| 2038 | ;; Just move an existing overlay |
| 2039 | (move-overlay comint-last-prompt-overlay |
| 2040 | prompt-start (point)) |
| 2041 | ;; Need to create the overlay |
| 2042 | (setq comint-last-prompt-overlay |
| 2043 | (make-overlay prompt-start (point))) |
| 2044 | (overlay-put comint-last-prompt-overlay |
| 2045 | 'font-lock-face 'comint-highlight-prompt)))) |
| 2046 | |
| 2047 | (goto-char saved-point))))))) |
| 2048 | |
| 2049 | (defun comint-preinput-scroll-to-bottom () |
| 2050 | "Go to the end of buffer in all windows showing it. |
| 2051 | Movement occurs if point in the selected window is not after the process mark, |
| 2052 | and `this-command' is an insertion command. Insertion commands recognized |
| 2053 | are `self-insert-command', `comint-magic-space', `yank', and `hilit-yank'. |
| 2054 | Depends on the value of `comint-scroll-to-bottom-on-input'. |
| 2055 | |
| 2056 | This function should be a pre-command hook." |
| 2057 | (if (and comint-scroll-to-bottom-on-input |
| 2058 | (memq this-command '(self-insert-command comint-magic-space yank |
| 2059 | hilit-yank))) |
| 2060 | (let* ((selected (selected-window)) |
| 2061 | (current (current-buffer)) |
| 2062 | (process (get-buffer-process current)) |
| 2063 | (scroll comint-scroll-to-bottom-on-input)) |
| 2064 | (if (and process (< (point) (process-mark process))) |
| 2065 | (if (eq scroll 'this) |
| 2066 | (goto-char (point-max)) |
| 2067 | (walk-windows |
| 2068 | (lambda (window) |
| 2069 | (if (and (eq (window-buffer window) current) |
| 2070 | (or (eq scroll t) (eq scroll 'all))) |
| 2071 | (progn |
| 2072 | (select-window window) |
| 2073 | (goto-char (point-max)) |
| 2074 | (select-window selected)))) |
| 2075 | nil t)))))) |
| 2076 | |
| 2077 | (defun comint-postoutput-scroll-to-bottom (_string) |
| 2078 | "Go to the end of buffer in some or all windows showing it. |
| 2079 | Does not scroll if the current line is the last line in the buffer. |
| 2080 | Depends on the value of `comint-move-point-for-output' and |
| 2081 | `comint-scroll-show-maximum-output'. |
| 2082 | |
| 2083 | This function should be in the list `comint-output-filter-functions'." |
| 2084 | (let* ((selected (selected-window)) |
| 2085 | (current (current-buffer)) |
| 2086 | (process (get-buffer-process current)) |
| 2087 | (scroll comint-move-point-for-output)) |
| 2088 | (unwind-protect |
| 2089 | (if process |
| 2090 | (walk-windows |
| 2091 | (lambda (window) |
| 2092 | (when (eq (window-buffer window) current) |
| 2093 | (select-window window) |
| 2094 | (if (and (< (point) (process-mark process)) |
| 2095 | (or (eq scroll t) (eq scroll 'all) |
| 2096 | ;; Maybe user wants point to jump to end. |
| 2097 | (and (eq scroll 'this) (eq selected window)) |
| 2098 | (and (eq scroll 'others) (not (eq selected window))) |
| 2099 | ;; If point was at the end, keep it at end. |
| 2100 | (and (marker-position comint-last-output-start) |
| 2101 | (>= (point) comint-last-output-start)))) |
| 2102 | (goto-char (process-mark process))) |
| 2103 | ;; Optionally scroll so that the text |
| 2104 | ;; ends at the bottom of the window. |
| 2105 | (if (and comint-scroll-show-maximum-output |
| 2106 | (= (point) (point-max))) |
| 2107 | (save-excursion |
| 2108 | (goto-char (point-max)) |
| 2109 | (recenter (- -1 scroll-margin)))) |
| 2110 | (select-window selected))) |
| 2111 | nil t)) |
| 2112 | (set-buffer current)))) |
| 2113 | |
| 2114 | (defun comint-truncate-buffer (&optional _string) |
| 2115 | "Truncate the buffer to `comint-buffer-maximum-size'. |
| 2116 | This function could be on `comint-output-filter-functions' or bound to a key." |
| 2117 | (interactive) |
| 2118 | (save-excursion |
| 2119 | (goto-char (process-mark (get-buffer-process (current-buffer)))) |
| 2120 | (forward-line (- comint-buffer-maximum-size)) |
| 2121 | (beginning-of-line) |
| 2122 | (let ((inhibit-read-only t)) |
| 2123 | (delete-region (point-min) (point))))) |
| 2124 | |
| 2125 | (defun comint-strip-ctrl-m (&optional _string) |
| 2126 | "Strip trailing `^M' characters from the current output group. |
| 2127 | This function could be on `comint-output-filter-functions' or bound to a key." |
| 2128 | (interactive) |
| 2129 | (let ((pmark (process-mark (get-buffer-process (current-buffer))))) |
| 2130 | (save-excursion |
| 2131 | (condition-case nil |
| 2132 | (goto-char |
| 2133 | (if (called-interactively-p 'interactive) |
| 2134 | comint-last-input-end comint-last-output-start)) |
| 2135 | (error nil)) |
| 2136 | (while (re-search-forward "\r+$" pmark t) |
| 2137 | (replace-match "" t t))))) |
| 2138 | (defalias 'shell-strip-ctrl-m 'comint-strip-ctrl-m) |
| 2139 | |
| 2140 | (defun comint-show-maximum-output () |
| 2141 | "Put the end of the buffer at the bottom of the window." |
| 2142 | (interactive) |
| 2143 | (goto-char (point-max)) |
| 2144 | (recenter (- -1 scroll-margin))) |
| 2145 | |
| 2146 | (defun comint-get-old-input-default () |
| 2147 | "Default for `comint-get-old-input'. |
| 2148 | If `comint-use-prompt-regexp' is nil, then either |
| 2149 | return the current input field, if point is on an input field, or the |
| 2150 | current line, if point is on an output field. |
| 2151 | If `comint-use-prompt-regexp' is non-nil, then return |
| 2152 | the current line with any initial string matching the regexp |
| 2153 | `comint-prompt-regexp' removed." |
| 2154 | (let (bof) |
| 2155 | (if (and (not comint-use-prompt-regexp) |
| 2156 | ;; Make sure we're in an input rather than output field. |
| 2157 | (null (get-char-property (setq bof (field-beginning)) 'field))) |
| 2158 | (field-string-no-properties bof) |
| 2159 | (comint-bol) |
| 2160 | (buffer-substring-no-properties (point) (line-end-position))))) |
| 2161 | |
| 2162 | (defun comint-copy-old-input () |
| 2163 | "Insert after prompt old input at point as new input to be edited. |
| 2164 | Calls `comint-get-old-input' to get old input." |
| 2165 | (interactive) |
| 2166 | (let ((input (funcall comint-get-old-input)) |
| 2167 | (process (get-buffer-process (current-buffer)))) |
| 2168 | (if (not process) |
| 2169 | (error "Current buffer has no process") |
| 2170 | (goto-char (process-mark process)) |
| 2171 | (insert input)))) |
| 2172 | |
| 2173 | (defun comint-skip-prompt () |
| 2174 | "Skip past the text matching regexp `comint-prompt-regexp'. |
| 2175 | If this takes us past the end of the current line, don't skip at all." |
| 2176 | (if (and (looking-at comint-prompt-regexp) |
| 2177 | (<= (match-end 0) (line-end-position))) |
| 2178 | (goto-char (match-end 0)))) |
| 2179 | |
| 2180 | (defun comint-after-pmark-p () |
| 2181 | "Return t if point is after the process output marker." |
| 2182 | (let ((pmark (process-mark (get-buffer-process (current-buffer))))) |
| 2183 | (<= (marker-position pmark) (point)))) |
| 2184 | |
| 2185 | (defun comint-simple-send (proc string) |
| 2186 | "Default function for sending to PROC input STRING. |
| 2187 | This just sends STRING plus a newline. To override this, |
| 2188 | set the hook `comint-input-sender'." |
| 2189 | (let ((send-string |
| 2190 | (if comint-input-sender-no-newline |
| 2191 | string |
| 2192 | ;; Sending as two separate strings does not work |
| 2193 | ;; on Windows, so concat the \n before sending. |
| 2194 | (concat string "\n")))) |
| 2195 | (comint-send-string proc send-string)) |
| 2196 | (if (and comint-input-sender-no-newline |
| 2197 | (not (string-equal string ""))) |
| 2198 | (process-send-eof))) |
| 2199 | |
| 2200 | (defun comint-line-beginning-position () |
| 2201 | "Return the buffer position of the beginning of the line, after any prompt. |
| 2202 | If `comint-use-prompt-regexp' is non-nil, then the prompt skip is done by |
| 2203 | skipping text matching the regular expression `comint-prompt-regexp', |
| 2204 | a buffer local variable." |
| 2205 | (if comint-use-prompt-regexp |
| 2206 | ;; Use comint-prompt-regexp |
| 2207 | (save-excursion |
| 2208 | (beginning-of-line) |
| 2209 | (comint-skip-prompt) |
| 2210 | (point)) |
| 2211 | ;; Use input fields. Note that, unlike the behavior of |
| 2212 | ;; `line-beginning-position' inside a field, this function will |
| 2213 | ;; return the position of the end of a prompt, even if the point is |
| 2214 | ;; already inside the prompt. In order to do this, it assumes that |
| 2215 | ;; if there are two fields on a line, then the first one is the |
| 2216 | ;; prompt, and the second one is an input field, and is front-sticky |
| 2217 | ;; (as input fields should be). |
| 2218 | (constrain-to-field (line-beginning-position) (line-end-position)))) |
| 2219 | |
| 2220 | (defun comint-bol (&optional arg) |
| 2221 | "Go to the beginning of line, then skip past the prompt, if any. |
| 2222 | If prefix argument is given (\\[universal-argument]) the prompt is not skipped. |
| 2223 | If `comint-use-prompt-regexp' is non-nil, then the prompt skip is done |
| 2224 | by skipping text matching the regular expression `comint-prompt-regexp', |
| 2225 | a buffer local variable." |
| 2226 | (interactive "P") |
| 2227 | (if arg |
| 2228 | ;; Unlike `beginning-of-line', forward-line ignores field boundaries |
| 2229 | (forward-line 0) |
| 2230 | (goto-char (comint-line-beginning-position)))) |
| 2231 | |
| 2232 | ;; For compatibility. |
| 2233 | (defun comint-read-noecho (prompt &optional _ignore) |
| 2234 | (read-passwd prompt)) |
| 2235 | |
| 2236 | ;; These three functions are for entering text you don't want echoed or |
| 2237 | ;; saved -- typically passwords to ftp, telnet, or somesuch. |
| 2238 | ;; Just enter m-x send-invisible and type in your line. |
| 2239 | |
| 2240 | (defun send-invisible (&optional prompt) |
| 2241 | "Read a string without echoing. |
| 2242 | Then send it to the process running in the current buffer. |
| 2243 | The string is sent using `comint-input-sender'. |
| 2244 | Security bug: your string can still be temporarily recovered with |
| 2245 | \\[view-lossage]; `clear-this-command-keys' can fix that." |
| 2246 | (interactive "P") ; Defeat snooping via C-x ESC ESC |
| 2247 | (let ((proc (get-buffer-process (current-buffer))) |
| 2248 | (prefix |
| 2249 | (if (eq (window-buffer (selected-window)) (current-buffer)) |
| 2250 | "" |
| 2251 | (format "(In buffer %s) " |
| 2252 | (current-buffer))))) |
| 2253 | (if proc |
| 2254 | (let ((str (read-passwd (concat prefix |
| 2255 | (or prompt "Non-echoed text: "))))) |
| 2256 | (if (stringp str) |
| 2257 | (progn |
| 2258 | (comint-snapshot-last-prompt) |
| 2259 | (funcall comint-input-sender proc str)) |
| 2260 | (message "Warning: text will be echoed"))) |
| 2261 | (error "Buffer %s has no process" (current-buffer))))) |
| 2262 | |
| 2263 | (defun comint-watch-for-password-prompt (string) |
| 2264 | "Prompt in the minibuffer for password and send without echoing. |
| 2265 | This function uses `send-invisible' to read and send a password to the buffer's |
| 2266 | process if STRING contains a password prompt defined by |
| 2267 | `comint-password-prompt-regexp'. |
| 2268 | |
| 2269 | This function could be in the list `comint-output-filter-functions'." |
| 2270 | (when (string-match comint-password-prompt-regexp string) |
| 2271 | (when (string-match "^[ \n\r\t\v\f\b\a]+" string) |
| 2272 | (setq string (replace-match "" t t string))) |
| 2273 | (send-invisible string))) |
| 2274 | \f |
| 2275 | ;; Low-level process communication |
| 2276 | |
| 2277 | (defun comint-send-string (process string) |
| 2278 | "Like `process-send-string', but also does extra bookkeeping for Comint mode." |
| 2279 | (if process |
| 2280 | (with-current-buffer (if (processp process) |
| 2281 | (process-buffer process) |
| 2282 | (get-buffer process)) |
| 2283 | (comint-snapshot-last-prompt)) |
| 2284 | (comint-snapshot-last-prompt)) |
| 2285 | (process-send-string process string)) |
| 2286 | |
| 2287 | (defun comint-send-region (process start end) |
| 2288 | "Like `process-send-region', but also does extra bookkeeping for Comint mode." |
| 2289 | (if process |
| 2290 | (with-current-buffer (if (processp process) |
| 2291 | (process-buffer process) |
| 2292 | (get-buffer process)) |
| 2293 | (comint-snapshot-last-prompt)) |
| 2294 | (comint-snapshot-last-prompt)) |
| 2295 | (process-send-region process start end)) |
| 2296 | |
| 2297 | \f |
| 2298 | ;; Random input hackage |
| 2299 | |
| 2300 | (defun comint-delete-output () |
| 2301 | "Delete all output from interpreter since last input. |
| 2302 | Does not delete the prompt." |
| 2303 | (interactive) |
| 2304 | (let ((proc (get-buffer-process (current-buffer))) |
| 2305 | (replacement nil) |
| 2306 | (inhibit-read-only t)) |
| 2307 | (save-excursion |
| 2308 | (let ((pmark (progn (goto-char (process-mark proc)) |
| 2309 | (forward-line 0) |
| 2310 | (point-marker)))) |
| 2311 | (delete-region comint-last-input-end pmark) |
| 2312 | (goto-char (process-mark proc)) |
| 2313 | (setq replacement (concat "*** output flushed ***\n" |
| 2314 | (buffer-substring pmark (point)))) |
| 2315 | (delete-region pmark (point)))) |
| 2316 | ;; Output message and put back prompt |
| 2317 | (comint-output-filter proc replacement))) |
| 2318 | |
| 2319 | (defun comint-write-output (filename &optional append mustbenew) |
| 2320 | "Write output from interpreter since last input to FILENAME. |
| 2321 | Any prompt at the end of the output is not written. |
| 2322 | |
| 2323 | If the optional argument APPEND (the prefix argument when interactive) |
| 2324 | is non-nil, the output is appended to the file instead. |
| 2325 | |
| 2326 | If the optional argument MUSTBENEW is non-nil, check for an existing |
| 2327 | file with the same name. If MUSTBENEW is `excl', that means to get an |
| 2328 | error if the file already exists; never overwrite. If MUSTBENEW is |
| 2329 | neither nil nor `excl', that means ask for confirmation before |
| 2330 | overwriting, but do go ahead and overwrite the file if the user |
| 2331 | confirms. When interactive, MUSTBENEW is nil when appending, and t |
| 2332 | otherwise." |
| 2333 | (interactive |
| 2334 | (list (read-file-name |
| 2335 | (if current-prefix-arg |
| 2336 | "Append output to file: " |
| 2337 | "Write output to file: ")) |
| 2338 | current-prefix-arg |
| 2339 | (not current-prefix-arg))) |
| 2340 | (save-excursion |
| 2341 | (goto-char (process-mark (get-buffer-process (current-buffer)))) |
| 2342 | (forward-line 0) |
| 2343 | (write-region comint-last-input-end (point) filename |
| 2344 | append nil nil mustbenew))) |
| 2345 | |
| 2346 | ;; This function exists for the benefit of the menu; from the keyboard, |
| 2347 | ;; users can just use `comint-write-output' with a prefix arg. |
| 2348 | (defun comint-append-output-to-file (filename) |
| 2349 | "Append output from interpreter since last input to FILENAME. |
| 2350 | Any prompt at the end of the output is not written." |
| 2351 | (interactive "fAppend output to file: ") |
| 2352 | (comint-write-output filename t)) |
| 2353 | |
| 2354 | (defun comint-show-output () |
| 2355 | "Display start of this batch of interpreter output at top of window. |
| 2356 | Sets mark to the value of point when this command is run." |
| 2357 | (interactive) |
| 2358 | (push-mark) |
| 2359 | (let ((pos (or (marker-position comint-last-input-end) (point-max)))) |
| 2360 | (cond (comint-use-prompt-regexp |
| 2361 | (goto-char pos) |
| 2362 | (beginning-of-line 0) |
| 2363 | (set-window-start (selected-window) (point)) |
| 2364 | (comint-skip-prompt)) |
| 2365 | (t |
| 2366 | (goto-char (field-beginning pos)) |
| 2367 | (set-window-start (selected-window) (point)))))) |
| 2368 | |
| 2369 | |
| 2370 | (defun comint-interrupt-subjob () |
| 2371 | "Interrupt the current subjob. |
| 2372 | This command also kills the pending input |
| 2373 | between the process mark and point." |
| 2374 | (interactive) |
| 2375 | (comint-skip-input) |
| 2376 | (interrupt-process nil comint-ptyp) |
| 2377 | ;; (process-send-string nil "\n") |
| 2378 | ) |
| 2379 | |
| 2380 | (defun comint-kill-subjob () |
| 2381 | "Send kill signal to the current subjob. |
| 2382 | This command also kills the pending input |
| 2383 | between the process mark and point." |
| 2384 | (interactive) |
| 2385 | (comint-skip-input) |
| 2386 | (kill-process nil comint-ptyp)) |
| 2387 | |
| 2388 | (defun comint-quit-subjob () |
| 2389 | "Send quit signal to the current subjob. |
| 2390 | This command also kills the pending input |
| 2391 | between the process mark and point." |
| 2392 | (interactive) |
| 2393 | (comint-skip-input) |
| 2394 | (quit-process nil comint-ptyp)) |
| 2395 | |
| 2396 | (defun comint-stop-subjob () |
| 2397 | "Stop the current subjob. |
| 2398 | This command also kills the pending input |
| 2399 | between the process mark and point. |
| 2400 | |
| 2401 | WARNING: if there is no current subjob, you can end up suspending |
| 2402 | the top-level process running in the buffer. If you accidentally do |
| 2403 | this, use \\[comint-continue-subjob] to resume the process. (This |
| 2404 | is not a problem with most shells, since they ignore this signal.)" |
| 2405 | (interactive) |
| 2406 | (comint-skip-input) |
| 2407 | (stop-process nil comint-ptyp)) |
| 2408 | |
| 2409 | (defun comint-continue-subjob () |
| 2410 | "Send CONT signal to process buffer's process group. |
| 2411 | Useful if you accidentally suspend the top-level process." |
| 2412 | (interactive) |
| 2413 | (continue-process nil comint-ptyp)) |
| 2414 | |
| 2415 | (defun comint-skip-input () |
| 2416 | "Skip all pending input, from last stuff output by interpreter to point. |
| 2417 | This means mark it as if it had been sent as input, without sending it." |
| 2418 | (let ((comint-input-sender 'ignore) |
| 2419 | (comint-input-filter-functions nil)) |
| 2420 | (comint-send-input t t)) |
| 2421 | (end-of-line) |
| 2422 | (let ((pos (point)) |
| 2423 | (marker (process-mark (get-buffer-process (current-buffer))))) |
| 2424 | (insert " " (key-description (this-command-keys))) |
| 2425 | (if (= marker pos) |
| 2426 | (set-marker marker (point))))) |
| 2427 | |
| 2428 | (defun comint-kill-input () |
| 2429 | "Kill all text from last stuff output by interpreter to point." |
| 2430 | (interactive) |
| 2431 | (let ((pmark (process-mark (get-buffer-process (current-buffer))))) |
| 2432 | (if (> (point) (marker-position pmark)) |
| 2433 | (kill-region pmark (point))))) |
| 2434 | |
| 2435 | (defun comint-delchar-or-maybe-eof (arg) |
| 2436 | "Delete ARG characters forward or send an EOF to subprocess. |
| 2437 | Sends an EOF only if point is at the end of the buffer and there is no input." |
| 2438 | (interactive "p") |
| 2439 | (let ((proc (get-buffer-process (current-buffer)))) |
| 2440 | (if (and (eobp) proc (= (point) (marker-position (process-mark proc)))) |
| 2441 | (comint-send-eof) |
| 2442 | (delete-char arg)))) |
| 2443 | |
| 2444 | (defun comint-send-eof () |
| 2445 | "Send an EOF to the current buffer's process." |
| 2446 | (interactive) |
| 2447 | (comint-send-input t t) |
| 2448 | (process-send-eof)) |
| 2449 | |
| 2450 | |
| 2451 | (defun comint-backward-matching-input (regexp n) |
| 2452 | "Search backward through buffer for input fields that match REGEXP. |
| 2453 | If `comint-use-prompt-regexp' is non-nil, then input fields are identified |
| 2454 | by lines that match `comint-prompt-regexp'. |
| 2455 | |
| 2456 | With prefix argument N, search for Nth previous match. |
| 2457 | If N is negative, find the next or Nth next match." |
| 2458 | (interactive (comint-regexp-arg "Backward input matching (regexp): ")) |
| 2459 | (if comint-use-prompt-regexp |
| 2460 | ;; Use comint-prompt-regexp |
| 2461 | (let* ((re (concat comint-prompt-regexp ".*" regexp)) |
| 2462 | (pos (save-excursion (end-of-line (if (> n 0) 0 1)) |
| 2463 | (if (re-search-backward re nil t n) |
| 2464 | (point))))) |
| 2465 | (if (null pos) |
| 2466 | (progn (message "Not found") |
| 2467 | (ding)) |
| 2468 | (goto-char pos) |
| 2469 | (comint-bol nil))) |
| 2470 | ;; Use input fields |
| 2471 | (let* ((dir (if (< n 0) -1 1)) |
| 2472 | (pos |
| 2473 | (save-excursion |
| 2474 | (while (/= n 0) |
| 2475 | (unless (re-search-backward regexp nil t dir) |
| 2476 | (error "Not found")) |
| 2477 | (unless (get-char-property (point) 'field) |
| 2478 | (setq n (- n dir)))) |
| 2479 | (field-beginning)))) |
| 2480 | (goto-char pos)))) |
| 2481 | |
| 2482 | |
| 2483 | (defun comint-forward-matching-input (regexp n) |
| 2484 | "Search forward through buffer for input fields that match REGEXP. |
| 2485 | If `comint-use-prompt-regexp' is non-nil, then input fields are identified |
| 2486 | by lines that match `comint-prompt-regexp'. |
| 2487 | |
| 2488 | With prefix argument N, search for Nth following match. |
| 2489 | If N is negative, find the previous or Nth previous match." |
| 2490 | (interactive (comint-regexp-arg "Forward input matching (regexp): ")) |
| 2491 | (comint-backward-matching-input regexp (- n))) |
| 2492 | |
| 2493 | |
| 2494 | (defun comint-next-prompt (n) |
| 2495 | "Move to end of Nth next prompt in the buffer. |
| 2496 | If `comint-use-prompt-regexp' is nil, then this means the beginning of |
| 2497 | the Nth next `input' field, otherwise, it means the Nth occurrence of |
| 2498 | text matching `comint-prompt-regexp'." |
| 2499 | (interactive "p") |
| 2500 | (if comint-use-prompt-regexp |
| 2501 | ;; Use comint-prompt-regexp |
| 2502 | (let ((paragraph-start comint-prompt-regexp)) |
| 2503 | (end-of-line (if (> n 0) 1 0)) |
| 2504 | (forward-paragraph n) |
| 2505 | (comint-skip-prompt)) |
| 2506 | ;; Use input fields |
| 2507 | (let ((pos (point)) |
| 2508 | (input-pos nil) |
| 2509 | prev-pos) |
| 2510 | (while (/= n 0) |
| 2511 | (setq prev-pos pos) |
| 2512 | (setq pos |
| 2513 | (if (> n 0) |
| 2514 | (next-single-char-property-change pos 'field) |
| 2515 | (previous-single-char-property-change pos 'field))) |
| 2516 | (cond ((or (null pos) (= pos prev-pos)) |
| 2517 | ;; Ran off the end of the buffer. |
| 2518 | (when (> n 0) |
| 2519 | ;; There's always an input field at the end of the |
| 2520 | ;; buffer, but it has a `field' property of nil. |
| 2521 | (setq input-pos (point-max))) |
| 2522 | ;; stop iterating |
| 2523 | (setq n 0)) |
| 2524 | ((null (get-char-property pos 'field)) |
| 2525 | (setq n (if (< n 0) (1+ n) (1- n))) |
| 2526 | (setq input-pos pos)))) |
| 2527 | (when input-pos |
| 2528 | (goto-char input-pos))))) |
| 2529 | |
| 2530 | |
| 2531 | (defun comint-previous-prompt (n) |
| 2532 | "Move to end of Nth previous prompt in the buffer. |
| 2533 | If `comint-use-prompt-regexp' is nil, then this means the beginning of |
| 2534 | the Nth previous `input' field, otherwise, it means the Nth occurrence of |
| 2535 | text matching `comint-prompt-regexp'." |
| 2536 | (interactive "p") |
| 2537 | (comint-next-prompt (- n))) |
| 2538 | |
| 2539 | ;; State used by `comint-insert-previous-argument' when cycling. |
| 2540 | (defvar comint-insert-previous-argument-last-start-pos nil) |
| 2541 | (make-variable-buffer-local 'comint-insert-previous-argument-last-start-pos) |
| 2542 | (defvar comint-insert-previous-argument-last-index nil) |
| 2543 | (make-variable-buffer-local 'comint-insert-previous-argument-last-index) |
| 2544 | |
| 2545 | ;; Needs fixing: |
| 2546 | ;; make comint-arguments understand negative indices as bash does |
| 2547 | (defun comint-insert-previous-argument (index) |
| 2548 | "Insert the INDEXth argument from the previous Comint command-line at point. |
| 2549 | Spaces are added at beginning and/or end of the inserted string if |
| 2550 | necessary to ensure that it's separated from adjacent arguments. |
| 2551 | Interactively, if no prefix argument is given, the last argument is inserted. |
| 2552 | Repeated interactive invocations will cycle through the same argument |
| 2553 | from progressively earlier commands (using the value of INDEX specified |
| 2554 | with the first command). |
| 2555 | This command is like `M-.' in bash." |
| 2556 | (interactive "P") |
| 2557 | (unless (null index) |
| 2558 | (setq index (prefix-numeric-value index))) |
| 2559 | (cond ((eq last-command this-command) |
| 2560 | ;; Delete last input inserted by this command. |
| 2561 | (delete-region comint-insert-previous-argument-last-start-pos (point)) |
| 2562 | (setq index comint-insert-previous-argument-last-index)) |
| 2563 | (t |
| 2564 | ;; This is a non-repeat invocation, so initialize state. |
| 2565 | (setq comint-input-ring-index nil) |
| 2566 | (setq comint-insert-previous-argument-last-index index) |
| 2567 | (when (null comint-insert-previous-argument-last-start-pos) |
| 2568 | ;; First usage; initialize to a marker |
| 2569 | (setq comint-insert-previous-argument-last-start-pos |
| 2570 | (make-marker))))) |
| 2571 | ;; Make sure we're not in the prompt, and add a beginning space if necessary. |
| 2572 | (if (<= (point) (comint-line-beginning-position)) |
| 2573 | (comint-bol) |
| 2574 | (just-one-space)) |
| 2575 | ;; Remember the beginning of what we insert, so we can delete it if |
| 2576 | ;; the command is repeated. |
| 2577 | (set-marker comint-insert-previous-argument-last-start-pos (point)) |
| 2578 | ;; Insert the argument. |
| 2579 | (let ((input-string (comint-previous-input-string 0))) |
| 2580 | (when (string-match "[ \t\n]*&" input-string) |
| 2581 | ;; strip terminating '&' |
| 2582 | (setq input-string (substring input-string 0 (match-beginning 0)))) |
| 2583 | (insert (comint-arguments input-string index index))) |
| 2584 | ;; Make next invocation return arg from previous input |
| 2585 | (setq comint-input-ring-index (1+ (or comint-input-ring-index 0))) |
| 2586 | ;; Add a terminating space if necessary. |
| 2587 | (unless (eolp) |
| 2588 | (just-one-space))) |
| 2589 | |
| 2590 | \f |
| 2591 | ;; Support editing with `comint-prompt-read-only' set to t. |
| 2592 | |
| 2593 | (defun comint-update-fence () |
| 2594 | "Update read-only status of newline before point. |
| 2595 | The `fence' read-only property is used to indicate that a newline |
| 2596 | is read-only for no other reason than to \"fence off\" a |
| 2597 | following front-sticky read-only region. This is used to |
| 2598 | implement comint read-only prompts. If the text after a newline |
| 2599 | changes, the read-only status of that newline may need updating. |
| 2600 | That is what this function does. |
| 2601 | |
| 2602 | This function does nothing if point is not at the beginning of a |
| 2603 | line, or is at the beginning of the accessible portion of the buffer. |
| 2604 | Otherwise, if the character after point has a front-sticky |
| 2605 | read-only property, then the preceding newline is given a |
| 2606 | read-only property of `fence', unless it already is read-only. |
| 2607 | If the character after point does not have a front-sticky |
| 2608 | read-only property, any read-only property of `fence' on the |
| 2609 | preceding newline is removed." |
| 2610 | (let* ((pt (point)) (lst (get-text-property pt 'front-sticky)) |
| 2611 | (inhibit-modification-hooks t)) |
| 2612 | (and (bolp) |
| 2613 | (not (bobp)) |
| 2614 | (if (and (get-text-property pt 'read-only) |
| 2615 | (if (listp lst) (memq 'read-only lst) t)) |
| 2616 | (unless (get-text-property (1- pt) 'read-only) |
| 2617 | (put-text-property (1- pt) pt 'read-only 'fence)) |
| 2618 | (when (eq (get-text-property (1- pt) 'read-only) 'fence) |
| 2619 | (remove-list-of-text-properties (1- pt) pt '(read-only))))))) |
| 2620 | |
| 2621 | (defun comint-kill-whole-line (&optional count) |
| 2622 | "Kill current line, ignoring read-only and field properties. |
| 2623 | With prefix arg COUNT, kill that many lines starting from the current line. |
| 2624 | If COUNT is negative, kill backward. Also kill the preceding newline, |
| 2625 | instead of the trailing one. \(This is meant to make \\[repeat] work well |
| 2626 | with negative arguments.) |
| 2627 | If COUNT is zero, kill current line but exclude the trailing newline. |
| 2628 | The read-only status of newlines is updated with `comint-update-fence', |
| 2629 | if necessary." |
| 2630 | (interactive "p") |
| 2631 | (let ((inhibit-read-only t) (inhibit-field-text-motion t)) |
| 2632 | (kill-whole-line count) |
| 2633 | (when (>= count 0) (comint-update-fence)))) |
| 2634 | |
| 2635 | (defun comint-kill-region (beg end &optional yank-handler) |
| 2636 | "Like `kill-region', but ignores read-only properties, if safe. |
| 2637 | This command assumes that the buffer contains read-only |
| 2638 | \"prompts\" which are regions with front-sticky read-only |
| 2639 | properties at the beginning of a line, with the preceding newline |
| 2640 | being read-only to protect the prompt. This is true of the |
| 2641 | comint prompts if `comint-prompt-read-only' is non-nil. This |
| 2642 | command will not delete the region if this would create mutilated |
| 2643 | or out of place prompts. That is, if any part of a prompt is |
| 2644 | deleted, the entire prompt must be deleted and all remaining |
| 2645 | prompts should stay at the beginning of a line. If this is not |
| 2646 | the case, this command just calls `kill-region' with all |
| 2647 | read-only properties intact. The read-only status of newlines is |
| 2648 | updated using `comint-update-fence', if necessary." |
| 2649 | (interactive "r") |
| 2650 | (save-excursion |
| 2651 | (let* ((true-beg (min beg end)) |
| 2652 | (true-end (max beg end)) |
| 2653 | (beg-bolp (progn (goto-char true-beg) (bolp))) |
| 2654 | (beg-lst (get-text-property true-beg 'front-sticky)) |
| 2655 | (beg-bad (and (get-text-property true-beg 'read-only) |
| 2656 | (if (listp beg-lst) (memq 'read-only beg-lst) t))) |
| 2657 | (end-bolp (progn (goto-char true-end) (bolp))) |
| 2658 | (end-lst (get-text-property true-end 'front-sticky)) |
| 2659 | (end-bad (and (get-text-property true-end 'read-only) |
| 2660 | (if (listp end-lst) (memq 'read-only end-lst) t)))) |
| 2661 | (if (or (and (not beg-bolp) (or beg-bad end-bad)) |
| 2662 | (and (not end-bolp) end-bad)) |
| 2663 | (kill-region beg end yank-handler) |
| 2664 | (let ((inhibit-read-only t)) |
| 2665 | (kill-region beg end yank-handler) |
| 2666 | (comint-update-fence)))))) |
| 2667 | (set-advertised-calling-convention 'comint-kill-region '(beg end) "23.3") |
| 2668 | |
| 2669 | \f |
| 2670 | ;; Support for source-file processing commands. |
| 2671 | ;;============================================================================ |
| 2672 | ;; Many command-interpreters (e.g., Lisp, Scheme, Soar) have |
| 2673 | ;; commands that process files of source text (e.g. loading or compiling |
| 2674 | ;; files). So the corresponding process-in-a-buffer modes have commands |
| 2675 | ;; for doing this (e.g., lisp-load-file). The functions below are useful |
| 2676 | ;; for defining these commands. |
| 2677 | ;; |
| 2678 | ;; Alas, these guys don't do exactly the right thing for Lisp, Scheme |
| 2679 | ;; and Soar, in that they don't know anything about file extensions. |
| 2680 | ;; So the compile/load interface gets the wrong default occasionally. |
| 2681 | ;; The load-file/compile-file default mechanism could be smarter -- it |
| 2682 | ;; doesn't know about the relationship between filename extensions and |
| 2683 | ;; whether the file is source or executable. If you compile foo.lisp |
| 2684 | ;; with compile-file, then the next load-file should use foo.bin for |
| 2685 | ;; the default, not foo.lisp. This is tricky to do right, particularly |
| 2686 | ;; because the extension for executable files varies so much (.o, .bin, |
| 2687 | ;; .lbin, .mo, .vo, .ao, ...). |
| 2688 | |
| 2689 | |
| 2690 | ;; COMINT-SOURCE-DEFAULT -- determines defaults for source-file processing |
| 2691 | ;; commands. |
| 2692 | ;; |
| 2693 | ;; COMINT-CHECK-SOURCE -- if FNAME is in a modified buffer, asks you if you |
| 2694 | ;; want to save the buffer before issuing any process requests to the command |
| 2695 | ;; interpreter. |
| 2696 | ;; |
| 2697 | ;; COMINT-GET-SOURCE -- used by the source-file processing commands to prompt |
| 2698 | ;; for the file to process. |
| 2699 | |
| 2700 | (defun comint-source-default (previous-dir/file source-modes) |
| 2701 | "Compute the defaults for `load-file' and `compile-file' commands. |
| 2702 | |
| 2703 | PREVIOUS-DIR/FILE is a pair (DIRECTORY . FILENAME) from the last |
| 2704 | source-file processing command, or nil if there hasn't been one yet. |
| 2705 | SOURCE-MODES is a list used to determine what buffers contain source |
| 2706 | files: if the major mode of the buffer is in SOURCE-MODES, it's source. |
| 2707 | Typically, (lisp-mode) or (scheme-mode). |
| 2708 | |
| 2709 | If the command is given while the cursor is inside a string, *and* |
| 2710 | the string is an existing filename, *and* the filename is not a directory, |
| 2711 | then the string is taken as default. This allows you to just position |
| 2712 | your cursor over a string that's a filename and have it taken as default. |
| 2713 | |
| 2714 | If the command is given in a file buffer whose major mode is in |
| 2715 | SOURCE-MODES, then the filename is the default file, and the |
| 2716 | file's directory is the default directory. |
| 2717 | |
| 2718 | If the buffer isn't a source file buffer (e.g., it's the process buffer), |
| 2719 | then the default directory & file are what was used in the last source-file |
| 2720 | processing command (i.e., PREVIOUS-DIR/FILE). If this is the first time |
| 2721 | the command has been run (PREVIOUS-DIR/FILE is nil), the default directory |
| 2722 | is the cwd, with no default file. (\"no default file\" = nil) |
| 2723 | |
| 2724 | SOURCE-MODES is typically going to be something like (tea-mode) |
| 2725 | for T programs, (lisp-mode) for Lisp programs, (soar-mode lisp-mode) |
| 2726 | for Soar programs, etc. |
| 2727 | |
| 2728 | The function returns a pair: (default-directory . default-file)." |
| 2729 | (cond ((and buffer-file-name (memq major-mode source-modes)) |
| 2730 | (cons (file-name-directory buffer-file-name) |
| 2731 | (file-name-nondirectory buffer-file-name))) |
| 2732 | (previous-dir/file) |
| 2733 | (t |
| 2734 | (cons default-directory nil)))) |
| 2735 | |
| 2736 | |
| 2737 | (defun comint-check-source (fname) |
| 2738 | "Check whether to save buffers visiting file FNAME. |
| 2739 | Prior to loading or compiling (or otherwise processing) a file (in the CMU |
| 2740 | process-in-a-buffer modes), this function can be called on the filename. |
| 2741 | If the file is loaded into a buffer, and the buffer is modified, the user |
| 2742 | is queried to see if he wants to save the buffer before proceeding with |
| 2743 | the load or compile." |
| 2744 | (let ((buff (get-file-buffer fname))) |
| 2745 | (if (and buff |
| 2746 | (buffer-modified-p buff) |
| 2747 | (y-or-n-p (format "Save buffer %s first? " (buffer-name buff)))) |
| 2748 | ;; save BUFF. |
| 2749 | (let ((old-buffer (current-buffer))) |
| 2750 | (set-buffer buff) |
| 2751 | (save-buffer) |
| 2752 | (set-buffer old-buffer))))) |
| 2753 | |
| 2754 | (defun comint-extract-string () |
| 2755 | "Return string around point, or nil." |
| 2756 | (let ((syntax (syntax-ppss))) |
| 2757 | (when (nth 3 syntax) |
| 2758 | (condition-case () |
| 2759 | (buffer-substring-no-properties (1+ (nth 8 syntax)) |
| 2760 | (progn (goto-char (nth 8 syntax)) |
| 2761 | (forward-sexp) |
| 2762 | (1- (point)))) |
| 2763 | (error nil))))) |
| 2764 | |
| 2765 | (defun comint-get-source (prompt prev-dir/file source-modes mustmatch-p) |
| 2766 | "Prompt for filenames in commands that process source files, |
| 2767 | e.g. loading or compiling a file. |
| 2768 | Provides a default, if there is one, and returns the result filename. |
| 2769 | |
| 2770 | See `comint-source-default' for more on determining defaults. |
| 2771 | |
| 2772 | PROMPT is the prompt string. PREV-DIR/FILE is the (DIRECTORY . FILE) pair |
| 2773 | from the last source processing command. SOURCE-MODES is a list of major |
| 2774 | modes used to determine what file buffers contain source files. (These |
| 2775 | two arguments are used for determining defaults.) If MUSTMATCH-P is true, |
| 2776 | then the filename reader will only accept a file that exists. |
| 2777 | |
| 2778 | A typical use: |
| 2779 | (interactive (comint-get-source \"Compile file: \" prev-lisp-dir/file |
| 2780 | '(lisp-mode) t))" |
| 2781 | (let* ((def (comint-source-default prev-dir/file source-modes)) |
| 2782 | (stringfile (comint-extract-string)) |
| 2783 | (sfile-p (and stringfile |
| 2784 | (condition-case () |
| 2785 | (file-exists-p stringfile) |
| 2786 | (error nil)) |
| 2787 | (not (file-directory-p stringfile)))) |
| 2788 | (defdir (if sfile-p (file-name-directory stringfile) |
| 2789 | (car def))) |
| 2790 | (deffile (if sfile-p (file-name-nondirectory stringfile) |
| 2791 | (cdr def))) |
| 2792 | (ans (read-file-name (if deffile (format "%s(default %s) " |
| 2793 | prompt deffile) |
| 2794 | prompt) |
| 2795 | defdir |
| 2796 | (concat defdir deffile) |
| 2797 | mustmatch-p))) |
| 2798 | (list (expand-file-name (substitute-in-file-name ans))))) |
| 2799 | |
| 2800 | ;; I am somewhat divided on this string-default feature. It seems |
| 2801 | ;; to violate the principle-of-least-astonishment, in that it makes |
| 2802 | ;; the default harder to predict, so you actually have to look and see |
| 2803 | ;; what the default really is before choosing it. This can trip you up. |
| 2804 | ;; On the other hand, it can be useful, I guess. I would appreciate feedback |
| 2805 | ;; on this. |
| 2806 | ;; -Olin |
| 2807 | |
| 2808 | \f |
| 2809 | ;; Simple process query facility. |
| 2810 | ;; =========================================================================== |
| 2811 | ;; This function is for commands that want to send a query to the process |
| 2812 | ;; and show the response to the user. For example, a command to get the |
| 2813 | ;; arglist for a Common Lisp function might send a "(arglist 'foo)" query |
| 2814 | ;; to an inferior Common Lisp process. |
| 2815 | ;; |
| 2816 | ;; This simple facility just sends strings to the inferior process and pops |
| 2817 | ;; up a window for the process buffer so you can see what the process |
| 2818 | ;; responds with. We don't do anything fancy like try to intercept what the |
| 2819 | ;; process responds with and put it in a pop-up window or on the message |
| 2820 | ;; line. We just display the buffer. Low tech. Simple. Works good. |
| 2821 | |
| 2822 | (defun comint-proc-query (proc str) |
| 2823 | "Send to the inferior process PROC the string STR. |
| 2824 | Pop-up but do not select a window for the inferior process so that |
| 2825 | its response can be seen." |
| 2826 | (let* ((proc-buf (process-buffer proc)) |
| 2827 | (proc-mark (process-mark proc))) |
| 2828 | (display-buffer proc-buf) |
| 2829 | (set-buffer proc-buf) ; but it's not the selected *window* |
| 2830 | (let ((proc-win (get-buffer-window proc-buf 0)) |
| 2831 | (proc-pt (marker-position proc-mark))) |
| 2832 | (comint-send-string proc str) ; send the query |
| 2833 | (accept-process-output proc) ; wait for some output |
| 2834 | ;; Try to position the proc window so you can see the answer. |
| 2835 | ;; This is bogus code. If you delete the (sit-for 0), it breaks. |
| 2836 | ;; I don't know why. Wizards invited to improve it. |
| 2837 | (unless (pos-visible-in-window-p proc-pt proc-win) |
| 2838 | (let ((opoint (window-point proc-win))) |
| 2839 | (set-window-point proc-win proc-mark) |
| 2840 | (sit-for 0) |
| 2841 | (if (not (pos-visible-in-window-p opoint proc-win)) |
| 2842 | (push-mark opoint) |
| 2843 | (set-window-point proc-win opoint))))))) |
| 2844 | |
| 2845 | \f |
| 2846 | ;; Filename/command/history completion in a buffer |
| 2847 | ;; =========================================================================== |
| 2848 | ;; Useful completion functions, courtesy of the Ergo group. |
| 2849 | |
| 2850 | ;; Six commands: |
| 2851 | ;; comint-dynamic-complete Complete or expand command, filename, |
| 2852 | ;; history at point. |
| 2853 | ;; comint-dynamic-complete-filename Complete filename at point. |
| 2854 | ;; comint-dynamic-list-filename-completions List completions in help buffer. |
| 2855 | ;; comint-replace-by-expanded-filename Expand and complete filename at point; |
| 2856 | ;; replace with expanded/completed name. |
| 2857 | |
| 2858 | ;; These are not installed in the comint-mode keymap. But they are |
| 2859 | ;; available for people who want them. Shell-mode installs them: |
| 2860 | ;; (define-key shell-mode-map "\t" 'comint-dynamic-complete) |
| 2861 | ;; (define-key shell-mode-map "\M-?" |
| 2862 | ;; 'comint-dynamic-list-filename-completions))) |
| 2863 | ;; |
| 2864 | ;; Commands like this are fine things to put in load hooks if you |
| 2865 | ;; want them present in specific modes. |
| 2866 | |
| 2867 | (defcustom comint-completion-autolist nil |
| 2868 | "If non-nil, automatically list possibilities on partial completion. |
| 2869 | This mirrors the optional behavior of tcsh." |
| 2870 | :type 'boolean |
| 2871 | :group 'comint-completion) |
| 2872 | |
| 2873 | (defcustom comint-completion-addsuffix t |
| 2874 | "If non-nil, add ` ' to file names. |
| 2875 | It can either be a string FILESUFFIX or a cons (DIRSUFFIX . FILESUFFIX) |
| 2876 | where DIRSUFFIX is ignored and FILESUFFIX is a string added on unambiguous |
| 2877 | or exact completion. |
| 2878 | This mirrors the optional behavior of tcsh." |
| 2879 | :type '(choice (const :tag "None" nil) |
| 2880 | (const :tag "Add SPC" t) |
| 2881 | (string :tag "File suffix") |
| 2882 | (cons :tag "Obsolete suffix pair" |
| 2883 | (string :tag "Ignored") |
| 2884 | (string :tag "File suffix"))) |
| 2885 | :group 'comint-completion) |
| 2886 | |
| 2887 | (defcustom comint-completion-recexact nil |
| 2888 | "If non-nil, use shortest completion if characters cannot be added. |
| 2889 | This mirrors the optional behavior of tcsh. |
| 2890 | |
| 2891 | A non-nil value is useful if `comint-completion-autolist' is non-nil too." |
| 2892 | :type 'boolean |
| 2893 | :group 'comint-completion) |
| 2894 | |
| 2895 | (defcustom comint-completion-fignore nil |
| 2896 | "List of suffixes to be disregarded during file completion. |
| 2897 | This mirrors the optional behavior of bash and tcsh. |
| 2898 | |
| 2899 | Note that this applies to `comint-dynamic-complete-filename' only." |
| 2900 | :type '(repeat (string :tag "Suffix")) |
| 2901 | :group 'comint-completion) |
| 2902 | |
| 2903 | ;;;###autoload |
| 2904 | (defvar comint-file-name-prefix (purecopy "") |
| 2905 | "Prefix prepended to absolute file names taken from process input. |
| 2906 | This is used by Comint's and shell's completion functions, and by shell's |
| 2907 | directory tracking functions.") |
| 2908 | |
| 2909 | (defvar comint-file-name-chars |
| 2910 | (if (memq system-type '(ms-dos windows-nt cygwin)) |
| 2911 | "~/A-Za-z0-9_^$!#%&{}@`'.,:()-" |
| 2912 | "[]~/A-Za-z0-9+@:_.$#%,={}-") |
| 2913 | "String of characters valid in a file name. |
| 2914 | Note that all non-ASCII characters are considered valid in a file name |
| 2915 | regardless of what this variable says. |
| 2916 | |
| 2917 | This is a good thing to set in mode hooks.") |
| 2918 | |
| 2919 | (defvar comint-file-name-quote-list nil |
| 2920 | "List of characters to quote with `\\' when in a file name. |
| 2921 | |
| 2922 | This is a good thing to set in mode hooks.") |
| 2923 | |
| 2924 | |
| 2925 | (defun comint-directory (directory) |
| 2926 | "Return expanded DIRECTORY, with `comint-file-name-prefix' if absolute." |
| 2927 | (expand-file-name (if (file-name-absolute-p directory) |
| 2928 | (concat comint-file-name-prefix directory) |
| 2929 | directory))) |
| 2930 | |
| 2931 | |
| 2932 | (defun comint-word (word-chars) |
| 2933 | "Return the word of WORD-CHARS at point, or nil if none is found. |
| 2934 | Word constituents are considered to be those in WORD-CHARS, which is like the |
| 2935 | inside of a \"[...]\" (see `skip-chars-forward'), plus all non-ASCII characters." |
| 2936 | (save-excursion |
| 2937 | (let ((here (point)) |
| 2938 | giveup) |
| 2939 | (while (not giveup) |
| 2940 | (let ((startpoint (point))) |
| 2941 | (skip-chars-backward (concat "\\\\" word-chars)) |
| 2942 | ;; Fixme: This isn't consistent with Bash, at least -- not |
| 2943 | ;; all non-ASCII chars should be word constituents. |
| 2944 | (if (and (> (- (point) 2) (point-min)) |
| 2945 | (= (char-after (- (point) 2)) ?\\)) |
| 2946 | (forward-char -2)) |
| 2947 | (if (and (> (- (point) 1) (point-min)) |
| 2948 | (>= (char-after (- (point) 1)) 128)) |
| 2949 | (forward-char -1)) |
| 2950 | (if (= (point) startpoint) |
| 2951 | (setq giveup t)))) |
| 2952 | ;; Set match-data to match the entire string. |
| 2953 | (when (< (point) here) |
| 2954 | (set-match-data (list (point) here)) |
| 2955 | (match-string 0))))) |
| 2956 | |
| 2957 | (defun comint-substitute-in-file-name (filename) |
| 2958 | "Return FILENAME with environment variables substituted. |
| 2959 | Supports additional environment variable syntax of the command |
| 2960 | interpreter (e.g., the percent notation of cmd.exe on Windows)." |
| 2961 | (let ((name (substitute-in-file-name filename))) |
| 2962 | (if (memq system-type '(ms-dos windows-nt)) |
| 2963 | (let (env-var-name |
| 2964 | env-var-val) |
| 2965 | (save-match-data |
| 2966 | (while (string-match "%\\([^\\\\/]*\\)%" name) |
| 2967 | (setq env-var-name (match-string 1 name)) |
| 2968 | (setq env-var-val (or (getenv env-var-name) "")) |
| 2969 | (setq name (replace-match env-var-val t t name)))))) |
| 2970 | name)) |
| 2971 | |
| 2972 | (defun comint--match-partial-filename () |
| 2973 | "Return the filename at point as-is, or nil if none is found. |
| 2974 | See `comint-word'." |
| 2975 | (comint-word comint-file-name-chars)) |
| 2976 | |
| 2977 | (defun comint--unquote&expand-filename (filename) |
| 2978 | ;; FIXME: The code below does unquote-then-expand which means that "\\$HOME" |
| 2979 | ;; gets expanded to the same as "$HOME" |
| 2980 | (comint-substitute-in-file-name |
| 2981 | (comint-unquote-filename filename))) |
| 2982 | |
| 2983 | (defun comint-match-partial-filename () |
| 2984 | "Return the unquoted&expanded filename at point, or nil if none is found. |
| 2985 | Environment variables are substituted. See `comint-word'." |
| 2986 | (let ((filename (comint--match-partial-filename))) |
| 2987 | (and filename (comint--unquote&expand-filename filename)))) |
| 2988 | |
| 2989 | (defun comint-quote-filename (filename) |
| 2990 | "Return FILENAME with magic characters quoted. |
| 2991 | Magic characters are those in `comint-file-name-quote-list'." |
| 2992 | (if (null comint-file-name-quote-list) |
| 2993 | filename |
| 2994 | (let ((regexp |
| 2995 | (format "[%s]" |
| 2996 | (mapconcat 'char-to-string comint-file-name-quote-list "")))) |
| 2997 | (save-match-data |
| 2998 | (let ((i 0)) |
| 2999 | (while (string-match regexp filename i) |
| 3000 | (setq filename (replace-match "\\\\\\&" nil nil filename)) |
| 3001 | (setq i (1+ (match-end 0))))) |
| 3002 | filename)))) |
| 3003 | |
| 3004 | (defun comint-unquote-filename (filename) |
| 3005 | "Return FILENAME with quoted characters unquoted." |
| 3006 | (if (null comint-file-name-quote-list) |
| 3007 | filename |
| 3008 | (save-match-data |
| 3009 | (replace-regexp-in-string "\\\\\\(.\\)" "\\1" filename t)))) |
| 3010 | |
| 3011 | (defun comint-completion-at-point () |
| 3012 | (run-hook-with-args-until-success 'comint-dynamic-complete-functions)) |
| 3013 | |
| 3014 | (define-obsolete-function-alias |
| 3015 | 'comint-dynamic-complete |
| 3016 | 'completion-at-point "24.1") |
| 3017 | |
| 3018 | (defun comint-dynamic-complete-filename () |
| 3019 | "Dynamically complete the filename at point. |
| 3020 | Completes if after a filename. |
| 3021 | This function is similar to `comint-replace-by-expanded-filename', except that |
| 3022 | it won't change parts of the filename already entered in the buffer; it just |
| 3023 | adds completion characters to the end of the filename. A completions listing |
| 3024 | may be shown in a separate buffer if completion is ambiguous. |
| 3025 | |
| 3026 | Completion is dependent on the value of `comint-completion-addsuffix', |
| 3027 | `comint-completion-recexact' and `comint-completion-fignore', and the timing of |
| 3028 | completions listing is dependent on the value of `comint-completion-autolist'. |
| 3029 | |
| 3030 | Returns t if successful." |
| 3031 | (interactive) |
| 3032 | (when (comint--match-partial-filename) |
| 3033 | (unless (window-minibuffer-p (selected-window)) |
| 3034 | (message "Completing file name...")) |
| 3035 | (let ((data (comint--complete-file-name-data))) |
| 3036 | (completion-in-region (nth 0 data) (nth 1 data) (nth 2 data))))) |
| 3037 | |
| 3038 | (defun comint-filename-completion () |
| 3039 | "Return completion data for filename at point, if any." |
| 3040 | (when (comint--match-partial-filename) |
| 3041 | (comint--complete-file-name-data))) |
| 3042 | |
| 3043 | ;; FIXME: comint--common-suffix, comint--common-quoted-suffix, and |
| 3044 | ;; comint--table-subvert don't fully solve the problem, since |
| 3045 | ;; selecting a file from *Completions* won't quote it, among several |
| 3046 | ;; other problems. |
| 3047 | |
| 3048 | (defun comint--common-suffix (s1 s2) |
| 3049 | (assert (not (or (string-match "\n" s1) (string-match "\n" s2)))) |
| 3050 | ;; Since S2 is expected to be the "unquoted/expanded" version of S1, |
| 3051 | ;; there shouldn't be any case difference, even if the completion is |
| 3052 | ;; case-insensitive. |
| 3053 | (let ((case-fold-search nil)) |
| 3054 | (string-match ".*?\\(.*\\)\n.*\\1\\'" (concat s1 "\n" s2)) |
| 3055 | (- (match-end 1) (match-beginning 1)))) |
| 3056 | |
| 3057 | (defun comint--common-quoted-suffix (s1 s2) |
| 3058 | ;; FIXME: Copied in pcomplete.el. |
| 3059 | "Find the common suffix between S1 and S2 where S1 is the expanded S2. |
| 3060 | S1 is expected to be the unquoted and expanded version of S1. |
| 3061 | Returns (PS1 . PS2), i.e. the shortest prefixes of S1 and S2, such that |
| 3062 | S1 = (concat PS1 SS1) and S2 = (concat PS2 SS2) and |
| 3063 | SS1 = (unquote SS2)." |
| 3064 | (let* ((cs (comint--common-suffix s1 s2)) |
| 3065 | (ss1 (substring s1 (- (length s1) cs))) |
| 3066 | (qss1 (comint-quote-filename ss1)) |
| 3067 | qc) |
| 3068 | (if (and (not (equal ss1 qss1)) |
| 3069 | (setq qc (comint-quote-filename (substring ss1 0 1))) |
| 3070 | (eq t (compare-strings s2 (- (length s2) cs (length qc) -1) |
| 3071 | (- (length s2) cs -1) |
| 3072 | qc nil nil))) |
| 3073 | ;; The difference found is just that one char is quoted in S2 |
| 3074 | ;; but not in S1, keep looking before this difference. |
| 3075 | (comint--common-quoted-suffix |
| 3076 | (substring s1 0 (- (length s1) cs)) |
| 3077 | (substring s2 0 (- (length s2) cs (length qc) -1))) |
| 3078 | (cons (substring s1 0 (- (length s1) cs)) |
| 3079 | (substring s2 0 (- (length s2) cs)))))) |
| 3080 | |
| 3081 | (defun comint--table-subvert (table s1 s2 &optional quote-fun unquote-fun) |
| 3082 | "Completion table that replaces the prefix S1 with S2 in STRING. |
| 3083 | The result is a completion table which completes strings of the |
| 3084 | form (concat S1 S) in the same way as TABLE completes strings of |
| 3085 | the form (concat S2 S)." |
| 3086 | (lambda (string pred action) |
| 3087 | (let* ((str (if (eq t (compare-strings string 0 (length s1) s1 nil nil |
| 3088 | completion-ignore-case)) |
| 3089 | (let ((rest (substring string (length s1)))) |
| 3090 | (concat s2 (if unquote-fun |
| 3091 | (funcall unquote-fun rest) rest))))) |
| 3092 | (res (if str (complete-with-action action table str pred)))) |
| 3093 | (when res |
| 3094 | (cond |
| 3095 | ((and (eq (car-safe action) 'boundaries)) |
| 3096 | (let ((beg (or (and (eq (car-safe res) 'boundaries) (cadr res)) 0))) |
| 3097 | (list* 'boundaries |
| 3098 | (max (length s1) |
| 3099 | ;; FIXME: Adjust because of quoting/unquoting. |
| 3100 | (+ beg (- (length s1) (length s2)))) |
| 3101 | (and (eq (car-safe res) 'boundaries) (cddr res))))) |
| 3102 | ((stringp res) |
| 3103 | (if (eq t (compare-strings res 0 (length s2) s2 nil nil |
| 3104 | completion-ignore-case)) |
| 3105 | (let ((rest (substring res (length s2)))) |
| 3106 | (concat s1 (if quote-fun (funcall quote-fun rest) rest))))) |
| 3107 | ((eq action t) |
| 3108 | (let ((bounds (completion-boundaries str table pred ""))) |
| 3109 | (if (>= (car bounds) (length s2)) |
| 3110 | (if quote-fun (mapcar quote-fun res) res) |
| 3111 | (let ((re (concat "\\`" |
| 3112 | (regexp-quote (substring s2 (car bounds)))))) |
| 3113 | (delq nil |
| 3114 | (mapcar (lambda (c) |
| 3115 | (if (string-match re c) |
| 3116 | (let ((str (substring c (match-end 0)))) |
| 3117 | (if quote-fun |
| 3118 | (funcall quote-fun str) str)))) |
| 3119 | res)))))) |
| 3120 | ;; E.g. action=nil and it's the only completion. |
| 3121 | (res)))))) |
| 3122 | |
| 3123 | (defun comint-completion-file-name-table (string pred action) |
| 3124 | (if (not (file-name-absolute-p string)) |
| 3125 | (completion-file-name-table string pred action) |
| 3126 | (cond |
| 3127 | ((memq action '(t lambda)) |
| 3128 | (completion-file-name-table |
| 3129 | (concat comint-file-name-prefix string) pred action)) |
| 3130 | ((null action) |
| 3131 | (let ((res (completion-file-name-table |
| 3132 | (concat comint-file-name-prefix string) pred action))) |
| 3133 | (if (and (stringp res) |
| 3134 | (string-match |
| 3135 | (concat "\\`" (regexp-quote comint-file-name-prefix)) |
| 3136 | res)) |
| 3137 | (substring res (match-end 0)) |
| 3138 | res))) |
| 3139 | (t (completion-file-name-table string pred action))))) |
| 3140 | |
| 3141 | (defun comint--complete-file-name-data () |
| 3142 | "Return the completion data for file name at point." |
| 3143 | (let* ((filesuffix (cond ((not comint-completion-addsuffix) "") |
| 3144 | ((stringp comint-completion-addsuffix) |
| 3145 | comint-completion-addsuffix) |
| 3146 | ((not (consp comint-completion-addsuffix)) " ") |
| 3147 | (t (cdr comint-completion-addsuffix)))) |
| 3148 | (filename (comint--match-partial-filename)) |
| 3149 | (filename-beg (if filename (match-beginning 0) (point))) |
| 3150 | (filename-end (if filename (match-end 0) (point))) |
| 3151 | (unquoted (if filename (comint--unquote&expand-filename filename) "")) |
| 3152 | (table |
| 3153 | (let ((prefixes (comint--common-quoted-suffix |
| 3154 | unquoted filename))) |
| 3155 | (comint--table-subvert |
| 3156 | #'comint-completion-file-name-table |
| 3157 | (cdr prefixes) (car prefixes) |
| 3158 | #'comint-quote-filename #'comint-unquote-filename)))) |
| 3159 | (nconc |
| 3160 | (list |
| 3161 | filename-beg filename-end |
| 3162 | (lambda (string pred action) |
| 3163 | (let ((completion-ignore-case read-file-name-completion-ignore-case) |
| 3164 | (completion-ignored-extensions comint-completion-fignore)) |
| 3165 | (complete-with-action action table string pred)))) |
| 3166 | (unless (zerop (length filesuffix)) |
| 3167 | (list :exit-function |
| 3168 | (lambda (_s finished) |
| 3169 | (when (memq finished '(sole finished)) |
| 3170 | (if (looking-at (regexp-quote filesuffix)) |
| 3171 | (goto-char (match-end 0)) |
| 3172 | (insert filesuffix))))))))) |
| 3173 | |
| 3174 | (defun comint-dynamic-complete-as-filename () |
| 3175 | "Dynamically complete at point as a filename. |
| 3176 | See `comint-dynamic-complete-filename'. Returns t if successful." |
| 3177 | (let ((data (comint--complete-file-name-data))) |
| 3178 | (completion-in-region (nth 0 data) (nth 1 data) (nth 2 data)))) |
| 3179 | (make-obsolete 'comint-dynamic-complete-as-filename |
| 3180 | 'comint-filename-completion "24.1") |
| 3181 | |
| 3182 | (defun comint-replace-by-expanded-filename () |
| 3183 | "Dynamically expand and complete the filename at point. |
| 3184 | Replace the filename with an expanded, canonicalized and |
| 3185 | completed replacement, i.e. substituting environment |
| 3186 | variables (e.g. $HOME), `~'s, `..', and `.', and making the |
| 3187 | filename absolute. For expansion see `expand-file-name' and |
| 3188 | `substitute-in-file-name'. For completion see |
| 3189 | `comint-dynamic-complete-filename'." |
| 3190 | (interactive) |
| 3191 | (let ((filename (comint-match-partial-filename))) |
| 3192 | (when filename |
| 3193 | (replace-match (expand-file-name filename) t t) |
| 3194 | (comint-dynamic-complete-filename)))) |
| 3195 | |
| 3196 | |
| 3197 | (defun comint-dynamic-simple-complete (stub candidates) |
| 3198 | "Dynamically complete STUB from CANDIDATES list. |
| 3199 | This function inserts completion characters at point by |
| 3200 | completing STUB from the strings in CANDIDATES. If completion is |
| 3201 | ambiguous, possibly show a completions listing in a separate |
| 3202 | buffer. |
| 3203 | |
| 3204 | Return nil if no completion was inserted. |
| 3205 | Return `sole' if completed with the only completion match. |
| 3206 | Return `shortest' if completed with the shortest match. |
| 3207 | Return `partial' if completed as far as possible. |
| 3208 | Return `listed' if a completion listing was shown. |
| 3209 | |
| 3210 | See also `comint-dynamic-complete-filename'." |
| 3211 | (let* ((completion-ignore-case (memq system-type '(ms-dos windows-nt cygwin))) |
| 3212 | (minibuffer-p (window-minibuffer-p (selected-window))) |
| 3213 | (suffix (cond ((not comint-completion-addsuffix) "") |
| 3214 | ((not (consp comint-completion-addsuffix)) " ") |
| 3215 | (t (cdr comint-completion-addsuffix)))) |
| 3216 | (completions (all-completions stub candidates))) |
| 3217 | (cond ((null completions) |
| 3218 | (if minibuffer-p |
| 3219 | (minibuffer-message "No completions of %s" stub) |
| 3220 | (message "No completions of %s" stub)) |
| 3221 | nil) |
| 3222 | ((= 1 (length completions)) ; Gotcha! |
| 3223 | (let ((completion (car completions))) |
| 3224 | (if (string-equal completion stub) |
| 3225 | (unless minibuffer-p |
| 3226 | (message "Sole completion")) |
| 3227 | (insert (substring completion (length stub))) |
| 3228 | (unless minibuffer-p |
| 3229 | (message "Completed"))) |
| 3230 | (insert suffix) |
| 3231 | 'sole)) |
| 3232 | (t ; There's no unique completion. |
| 3233 | (let ((completion (try-completion stub candidates))) |
| 3234 | ;; Insert the longest substring. |
| 3235 | (insert (substring completion (length stub))) |
| 3236 | (cond ((and comint-completion-recexact comint-completion-addsuffix |
| 3237 | (string-equal stub completion) |
| 3238 | (member completion completions)) |
| 3239 | ;; It's not unique, but user wants shortest match. |
| 3240 | (insert suffix) |
| 3241 | (unless minibuffer-p |
| 3242 | (message "Completed shortest")) |
| 3243 | 'shortest) |
| 3244 | ((or comint-completion-autolist |
| 3245 | (string-equal stub completion)) |
| 3246 | ;; It's not unique, list possible completions. |
| 3247 | (comint-dynamic-list-completions completions stub) |
| 3248 | 'listed) |
| 3249 | (t |
| 3250 | (unless minibuffer-p |
| 3251 | (message "Partially completed")) |
| 3252 | 'partial))))))) |
| 3253 | (make-obsolete 'comint-dynamic-simple-complete 'completion-in-region "24.1") |
| 3254 | |
| 3255 | |
| 3256 | (defun comint-dynamic-list-filename-completions () |
| 3257 | "Display a list of possible completions for the filename at point." |
| 3258 | (interactive) |
| 3259 | (let* ((data (comint--complete-file-name-data)) |
| 3260 | (minibuffer-completion-table (nth 2 data)) |
| 3261 | (minibuffer-completion-predicate nil) |
| 3262 | (ol (make-overlay (nth 0 data) (nth 1 data) nil nil t))) |
| 3263 | (overlay-put ol 'field 'completion) |
| 3264 | (unwind-protect |
| 3265 | (call-interactively 'minibuffer-completion-help) |
| 3266 | (delete-overlay ol)))) |
| 3267 | |
| 3268 | |
| 3269 | ;; This is bound locally in a *Completions* buffer to the list of |
| 3270 | ;; completions displayed, and is used to detect the case where the same |
| 3271 | ;; command is repeatedly used without the set of completions changing. |
| 3272 | (defvar comint-displayed-dynamic-completions nil) |
| 3273 | |
| 3274 | (defvar comint-dynamic-list-completions-config nil) |
| 3275 | |
| 3276 | (defun comint-dynamic-list-completions (completions &optional common-substring) |
| 3277 | "Display a list of sorted COMPLETIONS. |
| 3278 | The meaning of COMMON-SUBSTRING is the same as in `display-completion-list'. |
| 3279 | Typing SPC flushes the completions buffer." |
| 3280 | (let ((window (get-buffer-window "*Completions*" 0))) |
| 3281 | (setq completions (sort completions 'string-lessp)) |
| 3282 | (if (and (eq last-command this-command) |
| 3283 | window (window-live-p window) (window-buffer window) |
| 3284 | (buffer-name (window-buffer window)) |
| 3285 | ;; The above tests are not sufficient to detect the case where we |
| 3286 | ;; should scroll, because the top-level interactive command may |
| 3287 | ;; not have displayed a completions window the last time it was |
| 3288 | ;; invoked, and there may be such a window left over from a |
| 3289 | ;; previous completion command with a different set of |
| 3290 | ;; completions. To detect that case, we also test that the set |
| 3291 | ;; of displayed completions is in fact the same as the previously |
| 3292 | ;; displayed set. |
| 3293 | (equal completions |
| 3294 | (buffer-local-value 'comint-displayed-dynamic-completions |
| 3295 | (window-buffer window)))) |
| 3296 | ;; If this command was repeated, and |
| 3297 | ;; there's a fresh completion window with a live buffer, |
| 3298 | ;; and this command is repeated, scroll that window. |
| 3299 | (with-current-buffer (window-buffer window) |
| 3300 | (if (pos-visible-in-window-p (point-max) window) |
| 3301 | (set-window-start window (point-min)) |
| 3302 | (save-selected-window |
| 3303 | (select-window window) |
| 3304 | (scroll-up)))) |
| 3305 | |
| 3306 | ;; Display a completion list for the first time. |
| 3307 | (setq comint-dynamic-list-completions-config |
| 3308 | (current-window-configuration)) |
| 3309 | (with-output-to-temp-buffer "*Completions*" |
| 3310 | (display-completion-list completions common-substring)) |
| 3311 | (if (window-minibuffer-p (selected-window)) |
| 3312 | (minibuffer-message "Type space to flush; repeat completion command to scroll") |
| 3313 | (message "Type space to flush; repeat completion command to scroll"))) |
| 3314 | |
| 3315 | ;; Read the next key, to process SPC. |
| 3316 | (let (key first) |
| 3317 | (if (with-current-buffer (get-buffer "*Completions*") |
| 3318 | (set (make-local-variable 'comint-displayed-dynamic-completions) |
| 3319 | completions) |
| 3320 | (setq key (read-key-sequence nil) |
| 3321 | first (aref key 0)) |
| 3322 | (and (consp first) (consp (event-start first)) |
| 3323 | (eq (window-buffer (posn-window (event-start first))) |
| 3324 | (get-buffer "*Completions*")) |
| 3325 | (eq (key-binding key) 'mouse-choose-completion))) |
| 3326 | ;; If the user does mouse-choose-completion with the mouse, |
| 3327 | ;; execute the command, then delete the completion window. |
| 3328 | (progn |
| 3329 | (choose-completion first) |
| 3330 | (set-window-configuration comint-dynamic-list-completions-config)) |
| 3331 | (if (eq first ?\s) |
| 3332 | (set-window-configuration comint-dynamic-list-completions-config) |
| 3333 | (setq unread-command-events (listify-key-sequence key))))))) |
| 3334 | \f |
| 3335 | (defun comint-get-next-from-history () |
| 3336 | "After fetching a line from input history, this fetches the following line. |
| 3337 | In other words, this recalls the input line after the line you recalled last. |
| 3338 | You can use this to repeat a sequence of input lines." |
| 3339 | (interactive) |
| 3340 | (if comint-save-input-ring-index |
| 3341 | (progn |
| 3342 | (setq comint-input-ring-index (1+ comint-save-input-ring-index)) |
| 3343 | (comint-next-input 1)) |
| 3344 | (message "No previous history command"))) |
| 3345 | |
| 3346 | (defun comint-accumulate () |
| 3347 | "Accumulate a line to send as input along with more lines. |
| 3348 | This inserts a newline so that you can enter more text |
| 3349 | to be sent along with this line. Use \\[comint-send-input] |
| 3350 | to send all the accumulated input, at once. |
| 3351 | The entire accumulated text becomes one item in the input history |
| 3352 | when you send it." |
| 3353 | (interactive) |
| 3354 | (insert "\n") |
| 3355 | (set-marker comint-accum-marker (point)) |
| 3356 | (if comint-input-ring-index |
| 3357 | (setq comint-save-input-ring-index |
| 3358 | (- comint-input-ring-index 1)))) |
| 3359 | |
| 3360 | (defun comint-goto-process-mark () |
| 3361 | "Move point to the process mark. |
| 3362 | The process mark separates output, and input already sent, |
| 3363 | from input that has not yet been sent." |
| 3364 | (interactive) |
| 3365 | (let ((proc (or (get-buffer-process (current-buffer)) |
| 3366 | (error "Current buffer has no process")))) |
| 3367 | (goto-char (process-mark proc)) |
| 3368 | (when (called-interactively-p 'interactive) |
| 3369 | (message "Point is now at the process mark")))) |
| 3370 | |
| 3371 | (defun comint-bol-or-process-mark () |
| 3372 | "Move point to beginning of line (after prompt) or to the process mark. |
| 3373 | The first time you use this command, it moves to the beginning of the line |
| 3374 | \(but after the prompt, if any). If you repeat it again immediately, |
| 3375 | it moves point to the process mark. |
| 3376 | |
| 3377 | The process mark separates the process output, along with input already sent, |
| 3378 | from input that has not yet been sent. Ordinarily, the process mark |
| 3379 | is at the beginning of the current input line; but if you have |
| 3380 | used \\[comint-accumulate] to send multiple lines at once, |
| 3381 | the process mark is at the beginning of the accumulated input." |
| 3382 | (interactive) |
| 3383 | (if (not (eq last-command 'comint-bol-or-process-mark)) |
| 3384 | (comint-bol nil) |
| 3385 | (comint-goto-process-mark))) |
| 3386 | |
| 3387 | (defun comint-set-process-mark () |
| 3388 | "Set the process mark at point." |
| 3389 | (interactive) |
| 3390 | (let ((proc (or (get-buffer-process (current-buffer)) |
| 3391 | (error "Current buffer has no process")))) |
| 3392 | (set-marker (process-mark proc) (point)) |
| 3393 | (message "Process mark set"))) |
| 3394 | |
| 3395 | \f |
| 3396 | ;; Author: Peter Breton <pbreton@cs.umb.edu> |
| 3397 | |
| 3398 | ;; This little add-on for comint is intended to make it easy to get |
| 3399 | ;; output from currently active comint buffers into another buffer, |
| 3400 | ;; or buffers, and then go back to using the comint shell. |
| 3401 | ;; |
| 3402 | ;; My particular use is SQL interpreters; I want to be able to execute a |
| 3403 | ;; query using the process associated with a comint-buffer, and save that |
| 3404 | ;; somewhere else. Because the process might have state (for example, it |
| 3405 | ;; could be in an uncommitted transaction), just running starting a new |
| 3406 | ;; process and having it execute the query and then finish, would not |
| 3407 | ;; work. I'm sure there are other uses as well, although in many cases |
| 3408 | ;; starting a new process is the simpler, and thus preferable, approach. |
| 3409 | ;; |
| 3410 | ;; The basic implementation is as follows: comint-redirect changes the |
| 3411 | ;; preoutput filter functions (`comint-preoutput-filter-functions') to use |
| 3412 | ;; its own filter. The filter puts the output into the designated buffer, |
| 3413 | ;; or buffers, until it sees a regexp that tells it to stop (by default, |
| 3414 | ;; this is the prompt for the interpreter, `comint-prompt-regexp'). When it |
| 3415 | ;; sees the stop regexp, it restores the old filter functions, and runs |
| 3416 | ;; `comint-redirect-hook'. |
| 3417 | ;; |
| 3418 | ;; Each comint buffer may only use one redirection at a time, but any number |
| 3419 | ;; of different comint buffers may be simultaneously redirected. |
| 3420 | ;; |
| 3421 | ;; NOTE: It is EXTREMELY important that `comint-prompt-regexp' be set to the |
| 3422 | ;; correct prompt for your interpreter, or that you supply a regexp that says |
| 3423 | ;; when the redirection is finished. Otherwise, redirection will continue |
| 3424 | ;; indefinitely. The code now does a sanity check to ensure that it can find |
| 3425 | ;; a prompt in the comint buffer; however, it is still important to ensure that |
| 3426 | ;; this prompt is set correctly. |
| 3427 | ;; |
| 3428 | ;; XXX: This doesn't work so well unless `comint-prompt-regexp' is set; |
| 3429 | ;; perhaps it should prompt for a terminating string (with an |
| 3430 | ;; appropriate magic default by examining what we think is the prompt)? |
| 3431 | ;; |
| 3432 | ;; Fixme: look for appropriate fields, rather than regexp, if |
| 3433 | ;; `comint-use-prompt-regexp' is true. |
| 3434 | |
| 3435 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 3436 | ;; Variables |
| 3437 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 3438 | |
| 3439 | (defcustom comint-redirect-verbose nil |
| 3440 | "If non-nil, print messages each time the redirection filter is invoked. |
| 3441 | Also print a message when redirection is completed." |
| 3442 | :group 'comint |
| 3443 | :type 'boolean) |
| 3444 | |
| 3445 | ;; Directly analogous to comint-preoutput-filter-functions |
| 3446 | (defvar comint-redirect-filter-functions nil |
| 3447 | "List of functions to call before inserting redirected process output. |
| 3448 | Each function gets one argument, a string containing the text received |
| 3449 | from the subprocess. It should return the string to insert, perhaps |
| 3450 | the same string that was received, or perhaps a modified or transformed |
| 3451 | string. |
| 3452 | |
| 3453 | The functions on the list are called sequentially, and each one is given |
| 3454 | the string returned by the previous one. The string returned by the |
| 3455 | last function is the text that is actually inserted in the redirection buffer. |
| 3456 | |
| 3457 | You can use `add-hook' to add functions to this list |
| 3458 | either globally or locally.") |
| 3459 | |
| 3460 | ;; Internal variables |
| 3461 | |
| 3462 | (defvar comint-redirect-output-buffer nil |
| 3463 | "The buffer or list of buffers to put output into.") |
| 3464 | |
| 3465 | (defvar comint-redirect-finished-regexp nil |
| 3466 | "Regular expression that determines when to stop redirection in Comint. |
| 3467 | When the redirection filter function is given output that matches this regexp, |
| 3468 | the output is inserted as usual, and redirection is completed.") |
| 3469 | |
| 3470 | (defvar comint-redirect-insert-matching-regexp nil |
| 3471 | "If non-nil, the text that ends a redirection is included in it. |
| 3472 | More precisely, the text that matches `comint-redirect-finished-regexp' |
| 3473 | and therefore terminates an output redirection is inserted in the |
| 3474 | redirection target buffer, along with the preceding output.") |
| 3475 | |
| 3476 | (defvar comint-redirect-echo-input nil |
| 3477 | "Non-nil means echo input in the process buffer even during redirection.") |
| 3478 | |
| 3479 | (defvar comint-redirect-completed nil |
| 3480 | "Non-nil if redirection has completed in the current buffer.") |
| 3481 | |
| 3482 | (defvar comint-redirect-original-mode-line-process nil |
| 3483 | "Original mode line for redirected process.") |
| 3484 | |
| 3485 | (defvar comint-redirect-perform-sanity-check t |
| 3486 | "If non-nil, check that redirection is likely to complete successfully. |
| 3487 | More precisely, before starting a redirection, verify that the |
| 3488 | regular expression `comint-redirect-finished-regexp' that controls |
| 3489 | when to terminate it actually matches some text already in the process |
| 3490 | buffer. The idea is that this regular expression should match a prompt |
| 3491 | string, and that there ought to be at least one copy of your prompt string |
| 3492 | in the process buffer already.") |
| 3493 | |
| 3494 | (defvar comint-redirect-original-filter-function nil |
| 3495 | "The process filter that was in place when redirection is started. |
| 3496 | When redirection is completed, the process filter is restored to |
| 3497 | this value.") |
| 3498 | |
| 3499 | (defvar comint-redirect-subvert-readonly nil |
| 3500 | "Non-nil means `comint-redirect' can insert into read-only buffers. |
| 3501 | This works by binding `inhibit-read-only' around the insertion. |
| 3502 | This is useful, for instance, for insertion into Help mode buffers. |
| 3503 | You probably want to set it locally to the output buffer.") |
| 3504 | |
| 3505 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 3506 | ;; Functions |
| 3507 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 3508 | |
| 3509 | (defun comint-redirect-setup (output-buffer |
| 3510 | comint-buffer |
| 3511 | finished-regexp |
| 3512 | &optional echo-input) |
| 3513 | "Set up for output redirection. |
| 3514 | This function sets local variables that are used by `comint-redirect-filter' |
| 3515 | to perform redirection. |
| 3516 | |
| 3517 | Output from COMINT-BUFFER is redirected to OUTPUT-BUFFER, until something |
| 3518 | in the output matches FINISHED-REGEXP. |
| 3519 | |
| 3520 | If optional argument ECHO-INPUT is non-nil, output is echoed to the |
| 3521 | original Comint buffer. |
| 3522 | |
| 3523 | This function is called by `comint-redirect-send-command-to-process', |
| 3524 | and does not normally need to be invoked by the end user or programmer." |
| 3525 | (with-current-buffer comint-buffer |
| 3526 | |
| 3527 | (make-local-variable 'comint-redirect-original-mode-line-process) |
| 3528 | (setq comint-redirect-original-mode-line-process mode-line-process) |
| 3529 | |
| 3530 | (make-local-variable 'comint-redirect-output-buffer) |
| 3531 | (setq comint-redirect-output-buffer output-buffer) |
| 3532 | |
| 3533 | (make-local-variable 'comint-redirect-finished-regexp) |
| 3534 | (setq comint-redirect-finished-regexp finished-regexp) |
| 3535 | |
| 3536 | (make-local-variable 'comint-redirect-echo-input) |
| 3537 | (setq comint-redirect-echo-input echo-input) |
| 3538 | |
| 3539 | (make-local-variable 'comint-redirect-completed) |
| 3540 | (setq comint-redirect-completed nil) |
| 3541 | |
| 3542 | (setq mode-line-process |
| 3543 | (if mode-line-process |
| 3544 | (list (concat (elt mode-line-process 0) " Redirection")) |
| 3545 | (list ":%s Redirection"))))) |
| 3546 | |
| 3547 | (defun comint-redirect-cleanup () |
| 3548 | "End a Comint redirection. See `comint-redirect-send-command'." |
| 3549 | (interactive) |
| 3550 | ;; Restore the process filter |
| 3551 | (set-process-filter (get-buffer-process (current-buffer)) |
| 3552 | comint-redirect-original-filter-function) |
| 3553 | ;; Restore the mode line |
| 3554 | (setq mode-line-process comint-redirect-original-mode-line-process) |
| 3555 | ;; Set the completed flag |
| 3556 | (setq comint-redirect-completed t)) |
| 3557 | |
| 3558 | ;; Because the cleanup happens as a callback, it's not easy to guarantee |
| 3559 | ;; that it really occurs. |
| 3560 | (defalias 'comint-redirect-remove-redirection 'comint-redirect-cleanup) |
| 3561 | |
| 3562 | (defun comint-redirect-filter (process input-string) |
| 3563 | "Filter function which redirects output from PROCESS to a buffer or buffers. |
| 3564 | The variable `comint-redirect-output-buffer' says which buffer(s) to |
| 3565 | place output in. |
| 3566 | |
| 3567 | INPUT-STRING is the input from the Comint process. |
| 3568 | |
| 3569 | This function runs as a process filter, and does not need to be invoked by the |
| 3570 | end user." |
| 3571 | (and process |
| 3572 | (with-current-buffer (process-buffer process) |
| 3573 | (comint-redirect-preoutput-filter input-string) |
| 3574 | ;; If we have to echo output, give it to the original filter function |
| 3575 | (and comint-redirect-echo-input |
| 3576 | comint-redirect-original-filter-function |
| 3577 | (funcall comint-redirect-original-filter-function |
| 3578 | process input-string))))) |
| 3579 | |
| 3580 | |
| 3581 | (defun comint-redirect-preoutput-filter (input-string) |
| 3582 | "Comint filter function which redirects Comint output to a buffer or buffers. |
| 3583 | The variable `comint-redirect-output-buffer' says which buffer(s) to |
| 3584 | place output in. |
| 3585 | |
| 3586 | INPUT-STRING is the input from the Comint process. |
| 3587 | |
| 3588 | This function does not need to be invoked by the end user." |
| 3589 | (let ((output-buffer-list |
| 3590 | (if (listp comint-redirect-output-buffer) |
| 3591 | comint-redirect-output-buffer |
| 3592 | (list comint-redirect-output-buffer))) |
| 3593 | (filtered-input-string input-string)) |
| 3594 | |
| 3595 | ;; If there are any filter functions, give them a chance to modify |
| 3596 | ;; the string. |
| 3597 | (let ((functions comint-redirect-filter-functions)) |
| 3598 | (while (and functions filtered-input-string) |
| 3599 | (if (eq (car functions) t) |
| 3600 | ;; If a local value says "use the default value too", |
| 3601 | ;; do that. |
| 3602 | (let ((functions |
| 3603 | (default-value 'comint-redirect-filter-functions))) |
| 3604 | (while (and functions filtered-input-string) |
| 3605 | (setq filtered-input-string |
| 3606 | (funcall (car functions) filtered-input-string)) |
| 3607 | (setq functions (cdr functions)))) |
| 3608 | (setq filtered-input-string |
| 3609 | (funcall (car functions) filtered-input-string))) |
| 3610 | (setq functions (cdr functions)))) |
| 3611 | |
| 3612 | ;; Clobber `comint-redirect-finished-regexp' |
| 3613 | (or comint-redirect-insert-matching-regexp |
| 3614 | (and (string-match comint-redirect-finished-regexp filtered-input-string) |
| 3615 | (setq filtered-input-string |
| 3616 | (replace-match "" nil nil filtered-input-string)))) |
| 3617 | |
| 3618 | ;; Send output to all registered buffers |
| 3619 | (save-excursion |
| 3620 | (dolist (buf output-buffer-list) |
| 3621 | ;; Set this buffer to the output buffer |
| 3622 | (set-buffer (get-buffer-create buf)) |
| 3623 | ;; Go to the end of the buffer |
| 3624 | (goto-char (point-max)) |
| 3625 | ;; Insert the output |
| 3626 | (let ((inhibit-read-only comint-redirect-subvert-readonly)) |
| 3627 | (insert filtered-input-string)))) |
| 3628 | |
| 3629 | ;; Message |
| 3630 | (and comint-redirect-verbose |
| 3631 | (message "Redirected output to buffer(s) %s" |
| 3632 | (mapconcat 'identity output-buffer-list " "))) |
| 3633 | |
| 3634 | ;; If we see the prompt, tidy up |
| 3635 | ;; We'll look for the prompt in the original string, so nobody can |
| 3636 | ;; clobber it |
| 3637 | (and (string-match comint-redirect-finished-regexp input-string) |
| 3638 | (progn |
| 3639 | (and comint-redirect-verbose |
| 3640 | (message "Redirection completed")) |
| 3641 | (comint-redirect-cleanup) |
| 3642 | (run-hooks 'comint-redirect-hook))) |
| 3643 | ;; Echo input? |
| 3644 | (if comint-redirect-echo-input |
| 3645 | filtered-input-string |
| 3646 | ""))) |
| 3647 | |
| 3648 | ;;;###autoload |
| 3649 | (defun comint-redirect-send-command (command output-buffer echo &optional no-display) |
| 3650 | "Send COMMAND to process in current buffer, with output to OUTPUT-BUFFER. |
| 3651 | With prefix arg ECHO, echo output in process buffer. |
| 3652 | |
| 3653 | If NO-DISPLAY is non-nil, do not show the output buffer." |
| 3654 | (interactive "sCommand: \nBOutput Buffer: \nP") |
| 3655 | (let ((process (get-buffer-process (current-buffer)))) |
| 3656 | (if process |
| 3657 | (comint-redirect-send-command-to-process |
| 3658 | command output-buffer (current-buffer) echo no-display) |
| 3659 | (error "No process for current buffer")))) |
| 3660 | |
| 3661 | ;;;###autoload |
| 3662 | (defun comint-redirect-send-command-to-process |
| 3663 | (command output-buffer process echo &optional no-display) |
| 3664 | "Send COMMAND to PROCESS, with output to OUTPUT-BUFFER. |
| 3665 | With prefix arg, echo output in process buffer. |
| 3666 | |
| 3667 | If NO-DISPLAY is non-nil, do not show the output buffer." |
| 3668 | (interactive "sCommand: \nBOutput Buffer: \nbProcess Buffer: \nP") |
| 3669 | (let* (;; The process buffer |
| 3670 | (process-buffer (if (processp process) |
| 3671 | (process-buffer process) |
| 3672 | process)) |
| 3673 | (proc (get-buffer-process process-buffer))) |
| 3674 | ;; Change to the process buffer |
| 3675 | (with-current-buffer process-buffer |
| 3676 | |
| 3677 | ;; Make sure there's a prompt in the current process buffer |
| 3678 | (and comint-redirect-perform-sanity-check |
| 3679 | (save-excursion |
| 3680 | (goto-char (point-max)) |
| 3681 | (or (re-search-backward comint-prompt-regexp nil t) |
| 3682 | (error "No prompt found or `comint-prompt-regexp' not set properly")))) |
| 3683 | |
| 3684 | ;; Set up for redirection |
| 3685 | (comint-redirect-setup |
| 3686 | output-buffer |
| 3687 | (current-buffer) ; Comint Buffer |
| 3688 | comint-prompt-regexp ; Finished Regexp |
| 3689 | echo) ; Echo input |
| 3690 | |
| 3691 | ;; Set the filter |
| 3692 | (setq comint-redirect-original-filter-function ; Save the old filter |
| 3693 | (process-filter proc)) |
| 3694 | (set-process-filter proc 'comint-redirect-filter) |
| 3695 | |
| 3696 | ;; Send the command |
| 3697 | (process-send-string (current-buffer) (concat command "\n")) |
| 3698 | |
| 3699 | ;; Show the output |
| 3700 | (or no-display |
| 3701 | (display-buffer |
| 3702 | (get-buffer-create |
| 3703 | (if (listp output-buffer) |
| 3704 | (car output-buffer) |
| 3705 | output-buffer))))))) |
| 3706 | |
| 3707 | ;;;###autoload |
| 3708 | (defun comint-redirect-results-list (command regexp regexp-group) |
| 3709 | "Send COMMAND to current process. |
| 3710 | Return a list of expressions in the output which match REGEXP. |
| 3711 | REGEXP-GROUP is the regular expression group in REGEXP to use." |
| 3712 | (comint-redirect-results-list-from-process |
| 3713 | (get-buffer-process (current-buffer)) |
| 3714 | command regexp regexp-group)) |
| 3715 | |
| 3716 | ;;;###autoload |
| 3717 | (defun comint-redirect-results-list-from-process (process command regexp regexp-group) |
| 3718 | "Send COMMAND to PROCESS. |
| 3719 | Return a list of expressions in the output which match REGEXP. |
| 3720 | REGEXP-GROUP is the regular expression group in REGEXP to use." |
| 3721 | (let ((output-buffer " *Comint Redirect Work Buffer*") |
| 3722 | results) |
| 3723 | (with-current-buffer (get-buffer-create output-buffer) |
| 3724 | (erase-buffer) |
| 3725 | (comint-redirect-send-command-to-process command |
| 3726 | output-buffer process nil t) |
| 3727 | ;; Wait for the process to complete |
| 3728 | (set-buffer (process-buffer process)) |
| 3729 | (while (null comint-redirect-completed) |
| 3730 | (accept-process-output nil 1)) |
| 3731 | ;; Collect the output |
| 3732 | (set-buffer output-buffer) |
| 3733 | (goto-char (point-min)) |
| 3734 | ;; Skip past the command, if it was echoed |
| 3735 | (and (looking-at command) |
| 3736 | (forward-line)) |
| 3737 | (while (re-search-forward regexp nil t) |
| 3738 | (push (buffer-substring-no-properties |
| 3739 | (match-beginning regexp-group) |
| 3740 | (match-end regexp-group)) |
| 3741 | results)) |
| 3742 | results))) |
| 3743 | |
| 3744 | (dolist (x '("^Not at command line$" |
| 3745 | "^Empty input ring$" |
| 3746 | "^No history$" |
| 3747 | "^Not found$" ; Too common? |
| 3748 | "^Current buffer has no process$")) |
| 3749 | (add-to-list 'debug-ignored-errors x)) |
| 3750 | |
| 3751 | \f |
| 3752 | ;; Converting process modes to use comint mode |
| 3753 | ;; =========================================================================== |
| 3754 | ;; The code in the Emacs 19 distribution has all been modified to use comint |
| 3755 | ;; where needed. However, there are `third-party' packages out there that |
| 3756 | ;; still use the old shell mode. Here's a guide to conversion. |
| 3757 | ;; |
| 3758 | ;; Renaming variables |
| 3759 | ;; Most of the work is renaming variables and functions. These are the common |
| 3760 | ;; ones: |
| 3761 | ;; Local variables: |
| 3762 | ;; last-input-start comint-last-input-start |
| 3763 | ;; last-input-end comint-last-input-end |
| 3764 | ;; shell-prompt-pattern comint-prompt-regexp |
| 3765 | ;; shell-set-directory-error-hook <no equivalent> |
| 3766 | ;; Miscellaneous: |
| 3767 | ;; shell-set-directory <unnecessary> |
| 3768 | ;; shell-mode-map comint-mode-map |
| 3769 | ;; Commands: |
| 3770 | ;; shell-send-input comint-send-input |
| 3771 | ;; shell-send-eof comint-delchar-or-maybe-eof |
| 3772 | ;; kill-shell-input comint-kill-input |
| 3773 | ;; interrupt-shell-subjob comint-interrupt-subjob |
| 3774 | ;; stop-shell-subjob comint-stop-subjob |
| 3775 | ;; quit-shell-subjob comint-quit-subjob |
| 3776 | ;; kill-shell-subjob comint-kill-subjob |
| 3777 | ;; kill-output-from-shell comint-delete-output |
| 3778 | ;; show-output-from-shell comint-show-output |
| 3779 | ;; copy-last-shell-input Use comint-previous-input/comint-next-input |
| 3780 | ;; |
| 3781 | ;; SHELL-SET-DIRECTORY is gone, its functionality taken over by |
| 3782 | ;; SHELL-DIRECTORY-TRACKER, the shell mode's comint-input-filter-functions. |
| 3783 | ;; Comint mode does not provide functionality equivalent to |
| 3784 | ;; shell-set-directory-error-hook; it is gone. |
| 3785 | ;; |
| 3786 | ;; comint-last-input-start is provided for modes which want to munge |
| 3787 | ;; the buffer after input is sent, perhaps because the inferior |
| 3788 | ;; insists on echoing the input. The LAST-INPUT-START variable in |
| 3789 | ;; the old shell package was used to implement a history mechanism, |
| 3790 | ;; but you should think twice before using comint-last-input-start |
| 3791 | ;; for this; the input history ring often does the job better. |
| 3792 | ;; |
| 3793 | ;; If you are implementing some process-in-a-buffer mode, called foo-mode, do |
| 3794 | ;; *not* create the comint-mode local variables in your foo-mode function. |
| 3795 | ;; This is not modular. Instead, call comint-mode, and let *it* create the |
| 3796 | ;; necessary comint-specific local variables. Then create the |
| 3797 | ;; foo-mode-specific local variables in foo-mode. Set the buffer's keymap to |
| 3798 | ;; be foo-mode-map, and its mode to be foo-mode. Set the comint-mode hooks |
| 3799 | ;; (comint-{prompt-regexp, input-filter, input-filter-functions, |
| 3800 | ;; get-old-input) that need to be different from the defaults. Call |
| 3801 | ;; foo-mode-hook, and you're done. Don't run the comint-mode hook yourself; |
| 3802 | ;; comint-mode will take care of it. The following example, from shell.el, |
| 3803 | ;; is typical: |
| 3804 | ;; |
| 3805 | ;; (defvar shell-mode-map '()) |
| 3806 | ;; (cond ((not shell-mode-map) |
| 3807 | ;; (setq shell-mode-map (copy-keymap comint-mode-map)) |
| 3808 | ;; (define-key shell-mode-map "\C-c\C-f" 'shell-forward-command) |
| 3809 | ;; (define-key shell-mode-map "\C-c\C-b" 'shell-backward-command) |
| 3810 | ;; (define-key shell-mode-map "\t" 'comint-dynamic-complete) |
| 3811 | ;; (define-key shell-mode-map "\M-?" |
| 3812 | ;; 'comint-dynamic-list-filename-completions))) |
| 3813 | ;; |
| 3814 | ;; (defun shell-mode () |
| 3815 | ;; (interactive) |
| 3816 | ;; (comint-mode) |
| 3817 | ;; (setq comint-prompt-regexp shell-prompt-pattern) |
| 3818 | ;; (setq major-mode 'shell-mode) |
| 3819 | ;; (setq mode-name "Shell") |
| 3820 | ;; (use-local-map shell-mode-map) |
| 3821 | ;; (make-local-variable 'shell-directory-stack) |
| 3822 | ;; (setq shell-directory-stack nil) |
| 3823 | ;; (add-hook 'comint-input-filter-functions 'shell-directory-tracker) |
| 3824 | ;; (run-mode-hooks 'shell-mode-hook)) |
| 3825 | ;; |
| 3826 | ;; |
| 3827 | ;; Completion for comint-mode users |
| 3828 | ;; |
| 3829 | ;; For modes that use comint-mode, comint-dynamic-complete-functions is the |
| 3830 | ;; hook to add completion functions to. Functions on this list should return |
| 3831 | ;; the completion data according to the documentation of |
| 3832 | ;; `completion-at-point-functions' |
| 3833 | \f |
| 3834 | |
| 3835 | (provide 'comint) |
| 3836 | |
| 3837 | ;;; comint.el ends here |