| 1 | ;;; server.el --- Lisp code for GNU Emacs running as server process |
| 2 | |
| 3 | ;; Copyright (C) 1986, 87, 92, 94, 95, 96, 97, 98, 99, 2000, 2001 |
| 4 | ;; Free Software Foundation, Inc. |
| 5 | |
| 6 | ;; Author: William Sommerfeld <wesommer@athena.mit.edu> |
| 7 | ;; Maintainer: FSF |
| 8 | ;; Keywords: processes |
| 9 | |
| 10 | ;; Changes by peck@sun.com and by rms. |
| 11 | |
| 12 | ;; This file is part of GNU Emacs. |
| 13 | |
| 14 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 15 | ;; it under the terms of the GNU General Public License as published by |
| 16 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 17 | ;; any later version. |
| 18 | |
| 19 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 20 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 21 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 22 | ;; GNU General Public License for more details. |
| 23 | |
| 24 | ;; You should have received a copy of the GNU General Public License |
| 25 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 26 | ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, |
| 27 | ;; Boston, MA 02111-1307, USA. |
| 28 | |
| 29 | ;;; Commentary: |
| 30 | |
| 31 | ;; This Lisp code is run in Emacs when it is to operate as |
| 32 | ;; a server for other processes. |
| 33 | |
| 34 | ;; Load this library and do M-x server-edit to enable Emacs as a server. |
| 35 | ;; Emacs runs the program ../arch-lib/emacsserver as a subprocess |
| 36 | ;; for communication with clients. If there are no client buffers to edit, |
| 37 | ;; server-edit acts like (switch-to-buffer (other-buffer)) |
| 38 | |
| 39 | ;; When some other program runs "the editor" to edit a file, |
| 40 | ;; "the editor" can be the Emacs client program ../lib-src/emacsclient. |
| 41 | ;; This program transmits the file names to Emacs through |
| 42 | ;; the server subprocess, and Emacs visits them and lets you edit them. |
| 43 | |
| 44 | ;; Note that any number of clients may dispatch files to emacs to be edited. |
| 45 | |
| 46 | ;; When you finish editing a Server buffer, again call server-edit |
| 47 | ;; to mark that buffer as done for the client and switch to the next |
| 48 | ;; Server buffer. When all the buffers for a client have been edited |
| 49 | ;; and exited with server-edit, the client "editor" will return |
| 50 | ;; to the program that invoked it. |
| 51 | |
| 52 | ;; Your editing commands and Emacs's display output go to and from |
| 53 | ;; the terminal in the usual way. Thus, server operation is possible |
| 54 | ;; only when Emacs can talk to the terminal at the time you invoke |
| 55 | ;; the client. This is possible in four cases: |
| 56 | |
| 57 | ;; 1. On a window system, where Emacs runs in one window and the |
| 58 | ;; program that wants to use "the editor" runs in another. |
| 59 | |
| 60 | ;; 2. On a multi-terminal system, where Emacs runs on one terminal and the |
| 61 | ;; program that wants to use "the editor" runs on another. |
| 62 | |
| 63 | ;; 3. When the program that wants to use "the editor" is running |
| 64 | ;; as a subprocess of Emacs. |
| 65 | |
| 66 | ;; 4. On a system with job control, when Emacs is suspended, the program |
| 67 | ;; that wants to use "the editor" will stop and display |
| 68 | ;; "Waiting for Emacs...". It can then be suspended, and Emacs can be |
| 69 | ;; brought into the foreground for editing. When done editing, Emacs is |
| 70 | ;; suspended again, and the client program is brought into the foreground. |
| 71 | |
| 72 | ;; The buffer local variable "server-buffer-clients" lists |
| 73 | ;; the clients who are waiting for this buffer to be edited. |
| 74 | ;; The global variable "server-clients" lists all the waiting clients, |
| 75 | ;; and which files are yet to be edited for each. |
| 76 | |
| 77 | ;;; Code: |
| 78 | \f |
| 79 | (defgroup server nil |
| 80 | "Emacs running as a server process." |
| 81 | :group 'external) |
| 82 | |
| 83 | (defcustom server-program (expand-file-name "emacsserver" exec-directory) |
| 84 | "*The program to use as the edit server." |
| 85 | :group 'server |
| 86 | :type 'string) |
| 87 | |
| 88 | (defcustom server-visit-hook nil |
| 89 | "*List of hooks to call when visiting a file for the Emacs server." |
| 90 | :group 'server |
| 91 | :type '(repeat function)) |
| 92 | |
| 93 | (defcustom server-switch-hook nil |
| 94 | "*List of hooks to call when switching to a buffer for the Emacs server." |
| 95 | :group 'server |
| 96 | :type '(repeat function)) |
| 97 | |
| 98 | (defcustom server-done-hook nil |
| 99 | "*List of hooks to call when done editing a buffer for the Emacs server." |
| 100 | :group 'server |
| 101 | :type '(repeat function)) |
| 102 | |
| 103 | (defvar server-process nil |
| 104 | "The current server process") |
| 105 | |
| 106 | (defvar server-previous-string "") |
| 107 | |
| 108 | (defvar server-clients nil |
| 109 | "List of current server clients. |
| 110 | Each element is (CLIENTID BUFFERS...) where CLIENTID is a string |
| 111 | that can be given to the server process to identify a client. |
| 112 | When a buffer is marked as \"done\", it is removed from this list.") |
| 113 | |
| 114 | (defvar server-buffer-clients nil |
| 115 | "List of client ids for clients requesting editing of current buffer.") |
| 116 | (make-variable-buffer-local 'server-buffer-clients) |
| 117 | ;; Changing major modes should not erase this local. |
| 118 | (put 'server-buffer-clients 'permanent-local t) |
| 119 | |
| 120 | (defvar server-window nil |
| 121 | "*The window to use for selecting Emacs server buffers. |
| 122 | If nil, use the selected window. |
| 123 | If it is a frame, use the frame's selected window.") |
| 124 | |
| 125 | (defcustom server-temp-file-regexp "^/tmp/Re\\|/draft$" |
| 126 | "*Regexp which should match filenames of temporary files |
| 127 | which are deleted and reused after each edit |
| 128 | by the programs that invoke the Emacs server." |
| 129 | :group 'server |
| 130 | :type 'regexp) |
| 131 | |
| 132 | (defcustom server-kill-new-buffers t |
| 133 | "*Whether to kill buffers when done with them. |
| 134 | If non-nil, kill a buffer unless it already existed before editing |
| 135 | it with Emacs server. If nil, kill only buffers as specified by |
| 136 | `server-temp-file-regexp'. |
| 137 | Please note that only buffers are killed that still have a client, |
| 138 | i.e. buffers visited which \"emacsclient --no-wait\" are never killed in |
| 139 | this way." |
| 140 | :group 'server |
| 141 | :type 'boolean |
| 142 | :version "21.1") |
| 143 | |
| 144 | (or (assq 'server-buffer-clients minor-mode-alist) |
| 145 | (setq minor-mode-alist (cons '(server-buffer-clients " Server") minor-mode-alist))) |
| 146 | |
| 147 | (defvar server-existing-buffer nil |
| 148 | "Non-nil means a buffer existed before the Emacs server was asked visit it. |
| 149 | This means that the server should not kill the buffer when you say you |
| 150 | are done with it in the server. This variable is local in each buffer |
| 151 | where it is set.") |
| 152 | (make-variable-buffer-local 'server-existing-buffer) |
| 153 | |
| 154 | ;; If a *server* buffer exists, |
| 155 | ;; write STRING to it for logging purposes. |
| 156 | (defun server-log (string) |
| 157 | (if (get-buffer "*server*") |
| 158 | (save-excursion |
| 159 | (set-buffer "*server*") |
| 160 | (goto-char (point-max)) |
| 161 | (insert (current-time-string) " " string) |
| 162 | (or (bolp) (newline))))) |
| 163 | |
| 164 | (defun server-sentinel (proc msg) |
| 165 | (cond ((eq (process-status proc) 'exit) |
| 166 | (server-log (message "Server subprocess exited"))) |
| 167 | ((eq (process-status proc) 'signal) |
| 168 | (server-log (message "Server subprocess killed"))))) |
| 169 | |
| 170 | ;;;###autoload |
| 171 | (defun server-start (&optional leave-dead) |
| 172 | "Allow this Emacs process to be a server for client processes. |
| 173 | This starts a server communications subprocess through which |
| 174 | client \"editors\" can send your editing commands to this Emacs job. |
| 175 | To use the server, set up the program `emacsclient' in the |
| 176 | Emacs distribution as your standard \"editor\". |
| 177 | |
| 178 | Prefix arg means just kill any existing server communications subprocess." |
| 179 | (interactive "P") |
| 180 | ;; kill it dead! |
| 181 | (if server-process |
| 182 | (progn |
| 183 | (set-process-sentinel server-process nil) |
| 184 | (condition-case () (delete-process server-process) (error nil)))) |
| 185 | ;; Delete the socket files made by previous server invocations. |
| 186 | (let* ((sysname (system-name)) |
| 187 | (dot-index (string-match "\\." sysname))) |
| 188 | (condition-case () |
| 189 | (delete-file (format "~/.emacs-server-%s" sysname)) |
| 190 | (error nil)) |
| 191 | (condition-case () |
| 192 | (delete-file (format "/tmp/esrv%d-%s" (user-uid) sysname)) |
| 193 | (error nil)) |
| 194 | ;; In case the server file name was made with a domainless hostname, |
| 195 | ;; try deleting that name too. |
| 196 | (if dot-index |
| 197 | (let ((shortname (substring sysname 0 dot-index))) |
| 198 | (condition-case () |
| 199 | (delete-file (format "~/.emacs-server-%s" shortname)) |
| 200 | (error nil)) |
| 201 | (condition-case () |
| 202 | (delete-file (format "/tmp/esrv%d-%s" (user-uid) shortname)) |
| 203 | (error nil))))) |
| 204 | ;; If this Emacs already had a server, clear out associated status. |
| 205 | (while server-clients |
| 206 | (let ((buffer (nth 1 (car server-clients)))) |
| 207 | (server-buffer-done buffer))) |
| 208 | (if leave-dead |
| 209 | nil |
| 210 | (if server-process |
| 211 | (server-log (message "Restarting server"))) |
| 212 | ;; Using a pty is wasteful, and the separate session causes |
| 213 | ;; annoyance sometimes (some systems kill idle sessions). |
| 214 | (let ((process-connection-type nil)) |
| 215 | (setq server-process (start-process "server" nil server-program))) |
| 216 | (set-process-sentinel server-process 'server-sentinel) |
| 217 | (set-process-filter server-process 'server-process-filter) |
| 218 | ;; We must receive file names without being decoded. Those are |
| 219 | ;; decoded by server-process-filter accoding to |
| 220 | ;; file-name-coding-system. |
| 221 | (set-process-coding-system server-process 'raw-text 'raw-text) |
| 222 | (process-kill-without-query server-process))) |
| 223 | \f |
| 224 | ;Process a request from the server to edit some files. |
| 225 | ;Format of STRING is "Client: CLIENTID PATH PATH PATH... \n" |
| 226 | (defun server-process-filter (proc string) |
| 227 | (server-log string) |
| 228 | (setq string (concat server-previous-string string)) |
| 229 | ;; If the input is multiple lines, |
| 230 | ;; process each line individually. |
| 231 | (while (string-match "\n" string) |
| 232 | (let ((request (substring string 0 (match-beginning 0))) |
| 233 | (coding-system (and default-enable-multibyte-characters |
| 234 | (or file-name-coding-system |
| 235 | default-file-name-coding-system))) |
| 236 | client nowait |
| 237 | (files nil) |
| 238 | (lineno 1) |
| 239 | (columnno 0)) |
| 240 | ;; Remove this line from STRING. |
| 241 | (setq string (substring string (match-end 0))) |
| 242 | (if (string-match "^Error: " request) |
| 243 | (message "Server error: %s" (substring request (match-end 0))) |
| 244 | (if (string-match "^Client: " request) |
| 245 | (progn |
| 246 | (setq request (substring request (match-end 0))) |
| 247 | (setq client (list (substring request 0 (string-match " " request)))) |
| 248 | (setq request (substring request (match-end 0))) |
| 249 | (while (string-match "[^ ]+ " request) |
| 250 | (let ((arg |
| 251 | (substring request (match-beginning 0) (1- (match-end 0)))) |
| 252 | (pos 0)) |
| 253 | (setq request (substring request (match-end 0))) |
| 254 | (if (string-match "\\`-nowait" arg) |
| 255 | (setq nowait t) |
| 256 | (cond |
| 257 | ;; ARG is a line number option. |
| 258 | ((string-match "\\`\\+[0-9]+\\'" arg) |
| 259 | (setq lineno (string-to-int (substring arg 1)))) |
| 260 | ;; ARG is line number:column option. |
| 261 | ((string-match "\\`+\\([0-9]+\\):\\([0-9]+\\)\\'" arg) |
| 262 | (setq lineno (string-to-int (match-string 1 arg)) |
| 263 | columnno (string-to-int (match-string 2 arg)))) |
| 264 | (t |
| 265 | ;; ARG is a file name. |
| 266 | ;; Collapse multiple slashes to single slashes. |
| 267 | (setq arg (command-line-normalize-file-name arg)) |
| 268 | ;; Undo the quoting that emacsclient does |
| 269 | ;; for certain special characters. |
| 270 | (while (string-match "&." arg pos) |
| 271 | (setq pos (1+ (match-beginning 0))) |
| 272 | (let ((nextchar (aref arg pos))) |
| 273 | (cond ((= nextchar ?&) |
| 274 | (setq arg (replace-match "&" t t arg))) |
| 275 | ((= nextchar ?-) |
| 276 | (setq arg (replace-match "-" t t arg))) |
| 277 | (t |
| 278 | (setq arg (replace-match " " t t arg)))))) |
| 279 | ;; Now decode the file name if necessary. |
| 280 | (if coding-system |
| 281 | (setq arg (decode-coding-string arg coding-system))) |
| 282 | (setq files |
| 283 | (cons (list arg lineno columnno) |
| 284 | files)) |
| 285 | (setq lineno 1) |
| 286 | (setq columnno 0)))))) |
| 287 | (run-hooks 'pre-command-hook) |
| 288 | (server-visit-files files client nowait) |
| 289 | (run-hooks 'post-command-hook) |
| 290 | ;; CLIENT is now a list (CLIENTNUM BUFFERS...) |
| 291 | (if (null (cdr client)) |
| 292 | ;; This client is empty; get rid of it immediately. |
| 293 | (progn |
| 294 | (send-string server-process |
| 295 | (format "Close: %s Done\n" (car client))) |
| 296 | (server-log (format "Close empty client: %s Done\n" (car client)))) |
| 297 | ;; We visited some buffer for this client. |
| 298 | (or nowait |
| 299 | (setq server-clients (cons client server-clients))) |
| 300 | (server-switch-buffer (nth 1 client)) |
| 301 | (run-hooks 'server-switch-hook) |
| 302 | (message (substitute-command-keys |
| 303 | "When done with a buffer, type \\[server-edit]")))))))) |
| 304 | ;; Save for later any partial line that remains. |
| 305 | (setq server-previous-string string)) |
| 306 | |
| 307 | (defun server-visit-files (files client &optional nowait) |
| 308 | "Finds FILES and returns the list CLIENT with the buffers nconc'd. |
| 309 | FILES is an alist whose elements are (FILENAME LINENUMBER COLUMNNUMBER). |
| 310 | NOWAIT non-nil means this client is not waiting for the results, |
| 311 | so don't mark these buffers specially, just visit them normally." |
| 312 | ;; Bind last-nonmenu-event to force use of keyboard, not mouse, for queries. |
| 313 | (let (client-record (last-nonmenu-event t) (obuf (current-buffer))) |
| 314 | ;; Restore the current buffer afterward, but not using save-excursion, |
| 315 | ;; because we don't want to save point in this buffer |
| 316 | ;; if it happens to be one of those specified by the server. |
| 317 | (unwind-protect |
| 318 | (while files |
| 319 | ;; If there is an existing buffer modified or the file is |
| 320 | ;; modified, revert it. If there is an existing buffer with |
| 321 | ;; deleted file, offer to write it. |
| 322 | (let* ((filen (car (car files))) |
| 323 | (obuf (get-file-buffer filen))) |
| 324 | (push filen file-name-history) |
| 325 | (if (and obuf (set-buffer obuf)) |
| 326 | (progn |
| 327 | (cond ((file-exists-p filen) |
| 328 | (if (or (not (verify-visited-file-modtime obuf)) |
| 329 | (buffer-modified-p obuf)) |
| 330 | (revert-buffer t nil))) |
| 331 | (t |
| 332 | (if (y-or-n-p |
| 333 | (concat "File no longer exists: " |
| 334 | filen |
| 335 | ", write buffer to file? ")) |
| 336 | (write-file filen)))) |
| 337 | (setq server-existing-buffer t) |
| 338 | (goto-line (nth 1 (car files)))) |
| 339 | (set-buffer (find-file-noselect filen)) |
| 340 | (goto-line (nth 1 (car files))) |
| 341 | (let ((column-number (nth 2 (car files)))) |
| 342 | (when (> column-number 0) |
| 343 | (move-to-column (1- column-number)))) |
| 344 | (run-hooks 'server-visit-hook))) |
| 345 | (if (not nowait) |
| 346 | (setq server-buffer-clients |
| 347 | (cons (car client) server-buffer-clients))) |
| 348 | (setq client-record (cons (current-buffer) client-record)) |
| 349 | (setq files (cdr files))) |
| 350 | (set-buffer obuf)) |
| 351 | (nconc client client-record))) |
| 352 | \f |
| 353 | (defun server-buffer-done (buffer &optional for-killing) |
| 354 | "Mark BUFFER as \"done\" for its client(s). |
| 355 | This buries the buffer, then returns a list of the form (NEXT-BUFFER KILLED). |
| 356 | NEXT-BUFFER is another server buffer, as a suggestion for what to select next, |
| 357 | or nil. KILLED is t if we killed BUFFER |
| 358 | \(typically, because it was visiting a temp file)." |
| 359 | (let ((running (eq (process-status server-process) 'run)) |
| 360 | (next-buffer nil) |
| 361 | (killed nil) |
| 362 | (first t) |
| 363 | (old-clients server-clients)) |
| 364 | (while old-clients |
| 365 | (let ((client (car old-clients))) |
| 366 | (or next-buffer |
| 367 | (setq next-buffer (nth 1 (memq buffer client)))) |
| 368 | (delq buffer client) |
| 369 | ;; Delete all dead buffers from CLIENT. |
| 370 | (let ((tail client)) |
| 371 | (while tail |
| 372 | (and (bufferp (car tail)) |
| 373 | (null (buffer-name (car tail))) |
| 374 | (delq (car tail) client)) |
| 375 | (setq tail (cdr tail)))) |
| 376 | ;; If client now has no pending buffers, |
| 377 | ;; tell it that it is done, and forget it entirely. |
| 378 | (if (cdr client) nil |
| 379 | (if running |
| 380 | (progn |
| 381 | ;; Don't send emacsserver two commands in close succession. |
| 382 | ;; It cannot handle that. |
| 383 | (or first (sit-for 1)) |
| 384 | (setq first nil) |
| 385 | (send-string server-process |
| 386 | (format "Close: %s Done\n" (car client))) |
| 387 | (server-log (format "Close: %s Done\n" (car client))))) |
| 388 | (setq server-clients (delq client server-clients)))) |
| 389 | (setq old-clients (cdr old-clients))) |
| 390 | (if (and (bufferp buffer) (buffer-name buffer)) |
| 391 | ;; We may or may not kill this buffer; |
| 392 | ;; if we do, do not call server-buffer-done recursively |
| 393 | ;; from kill-buffer-hook. |
| 394 | (let ((server-kill-buffer-running t)) |
| 395 | (save-excursion |
| 396 | (set-buffer buffer) |
| 397 | (setq server-buffer-clients nil) |
| 398 | (run-hooks 'server-done-hook)) |
| 399 | ;; Notice whether server-done-hook killed the buffer. |
| 400 | (if (null (buffer-name buffer)) |
| 401 | (setq killed t) |
| 402 | ;; Don't bother killing or burying the buffer |
| 403 | ;; when we are called from kill-buffer. |
| 404 | (unless for-killing |
| 405 | (when (and (not killed) |
| 406 | server-kill-new-buffers |
| 407 | (with-current-buffer buffer |
| 408 | (not server-existing-buffer))) |
| 409 | (setq killed t) |
| 410 | (bury-buffer buffer) |
| 411 | (kill-buffer buffer)) |
| 412 | (unless killed |
| 413 | (if (server-temp-file-p buffer) |
| 414 | (progn |
| 415 | (kill-buffer buffer) |
| 416 | (setq killed t)) |
| 417 | (bury-buffer buffer))))))) |
| 418 | (list next-buffer killed))) |
| 419 | |
| 420 | (defun server-temp-file-p (buffer) |
| 421 | "Return non-nil if BUFFER contains a file considered temporary. |
| 422 | These are files whose names suggest they are repeatedly |
| 423 | reused to pass information to another program. |
| 424 | |
| 425 | The variable `server-temp-file-regexp' controls which filenames |
| 426 | are considered temporary." |
| 427 | (and (buffer-file-name buffer) |
| 428 | (string-match server-temp-file-regexp (buffer-file-name buffer)))) |
| 429 | |
| 430 | (defun server-done () |
| 431 | "Offer to save current buffer, mark it as \"done\" for clients. |
| 432 | This kills or buries the buffer, then returns a list |
| 433 | of the form (NEXT-BUFFER KILLED). NEXT-BUFFER is another server buffer, |
| 434 | as a suggestion for what to select next, or nil. |
| 435 | KILLED is t if we killed BUFFER, which happens if it was created |
| 436 | specifically for the clients and did not exist before their request for it." |
| 437 | (let ((buffer (current-buffer))) |
| 438 | (if server-buffer-clients |
| 439 | (progn |
| 440 | (if (server-temp-file-p buffer) |
| 441 | ;; For a temp file, save, and do make a non-numeric backup |
| 442 | ;; (unless make-backup-files is nil). |
| 443 | (let ((version-control nil) |
| 444 | (buffer-backed-up nil)) |
| 445 | (save-buffer)) |
| 446 | (if (and (buffer-modified-p) |
| 447 | buffer-file-name |
| 448 | (y-or-n-p (concat "Save file " buffer-file-name "? "))) |
| 449 | (save-buffer buffer))) |
| 450 | (server-buffer-done buffer))))) |
| 451 | |
| 452 | ;; Ask before killing a server buffer. |
| 453 | ;; It was suggested to release its client instead, |
| 454 | ;; but I think that is dangerous--the client would proceed |
| 455 | ;; using whatever is on disk in that file. -- rms. |
| 456 | (defun server-kill-buffer-query-function () |
| 457 | (or (not server-buffer-clients) |
| 458 | (yes-or-no-p (format "Buffer `%s' still has clients; kill it? " |
| 459 | (buffer-name (current-buffer)))))) |
| 460 | |
| 461 | (add-hook 'kill-buffer-query-functions |
| 462 | 'server-kill-buffer-query-function) |
| 463 | |
| 464 | (defun server-kill-emacs-query-function () |
| 465 | (let (live-client |
| 466 | (tail server-clients)) |
| 467 | ;; See if any clients have any buffers that are still alive. |
| 468 | (while tail |
| 469 | (if (memq t (mapcar 'stringp (mapcar 'buffer-name (cdr (car tail))))) |
| 470 | (setq live-client t)) |
| 471 | (setq tail (cdr tail))) |
| 472 | (or (not live-client) |
| 473 | (yes-or-no-p "Server buffers still have clients; exit anyway? ")))) |
| 474 | |
| 475 | (add-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function) |
| 476 | |
| 477 | (defvar server-kill-buffer-running nil |
| 478 | "Non-nil while `server-kill-buffer' or `server-buffer-done' is running.") |
| 479 | |
| 480 | ;; When a buffer is killed, inform the clients. |
| 481 | (add-hook 'kill-buffer-hook 'server-kill-buffer) |
| 482 | (defun server-kill-buffer () |
| 483 | ;; Prevent infinite recursion if user has made server-done-hook |
| 484 | ;; call kill-buffer. |
| 485 | (or server-kill-buffer-running |
| 486 | (and server-buffer-clients |
| 487 | (let ((server-kill-buffer-running t)) |
| 488 | (when server-process |
| 489 | (server-buffer-done (current-buffer) t)))))) |
| 490 | \f |
| 491 | (defun server-edit (&optional arg) |
| 492 | "Switch to next server editing buffer; say \"Done\" for current buffer. |
| 493 | If a server buffer is current, it is marked \"done\" and optionally saved. |
| 494 | The buffer is also killed if it did not exist before the clients asked for it. |
| 495 | When all of a client's buffers are marked as \"done\", the client is notified. |
| 496 | |
| 497 | Temporary files such as MH <draft> files are always saved and backed up, |
| 498 | no questions asked. (The variable `make-backup-files', if nil, still |
| 499 | inhibits a backup; you can set it locally in a particular buffer to |
| 500 | prevent a backup for it.) The variable `server-temp-file-regexp' controls |
| 501 | which filenames are considered temporary. |
| 502 | |
| 503 | If invoked with a prefix argument, or if there is no server process running, |
| 504 | starts server process and that is all. Invoked by \\[server-edit]." |
| 505 | (interactive "P") |
| 506 | (if (or arg |
| 507 | (not server-process) |
| 508 | (memq (process-status server-process) '(signal exit))) |
| 509 | (server-start nil) |
| 510 | (apply 'server-switch-buffer (server-done)))) |
| 511 | |
| 512 | (defun server-switch-buffer (&optional next-buffer killed-one) |
| 513 | "Switch to another buffer, preferably one that has a client. |
| 514 | Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it." |
| 515 | ;; KILLED-ONE is t in a recursive call |
| 516 | ;; if we have already killed one temp-file server buffer. |
| 517 | ;; This means we should avoid the final "switch to some other buffer" |
| 518 | ;; since we've already effectively done that. |
| 519 | (cond ((and (windowp server-window) |
| 520 | (window-live-p server-window)) |
| 521 | (select-window server-window)) |
| 522 | ((framep server-window) |
| 523 | (if (not (frame-live-p server-window)) |
| 524 | (setq server-window (make-frame))) |
| 525 | (select-window (frame-selected-window server-window)))) |
| 526 | (if (window-minibuffer-p (selected-window)) |
| 527 | (select-window (next-window nil 'nomini 0))) |
| 528 | ;; Move to a non-dedicated window, if we have one. |
| 529 | (when (window-dedicated-p (selected-window)) |
| 530 | (select-window (get-window-with-predicate |
| 531 | (lambda (w) (not (window-dedicated-p w))) |
| 532 | 'nomini 'visible (selected-window)))) |
| 533 | (set-window-dedicated-p (selected-window) nil) |
| 534 | (if next-buffer |
| 535 | (if (and (bufferp next-buffer) |
| 536 | (buffer-name next-buffer)) |
| 537 | (switch-to-buffer next-buffer) |
| 538 | ;; If NEXT-BUFFER is a dead buffer, |
| 539 | ;; remove the server records for it |
| 540 | ;; and try the next surviving server buffer. |
| 541 | (apply 'server-switch-buffer |
| 542 | (server-buffer-done next-buffer))) |
| 543 | (if server-clients |
| 544 | (server-switch-buffer (nth 1 (car server-clients)) killed-one) |
| 545 | (if (not killed-one) |
| 546 | (switch-to-buffer (other-buffer)))))) |
| 547 | |
| 548 | (global-set-key "\C-x#" 'server-edit) |
| 549 | |
| 550 | (defun server-unload-hook () |
| 551 | (remove-hook 'kill-buffer-query-functions 'server-kill-buffer-query-function) |
| 552 | (remove-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function) |
| 553 | (remove-hook 'kill-buffer-hook 'server-kill-buffer)) |
| 554 | \f |
| 555 | (provide 'server) |
| 556 | |
| 557 | ;;; server.el ends here |