| 1 | ;;; dired-aux.el --- less commonly used parts of dired -*-byte-compile-dynamic: t;-*- |
| 2 | |
| 3 | ;; Copyright (C) 1985, 1986, 1992, 1994, 1998, 2000, 2001, 2002, 2003, |
| 4 | ;; 2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc. |
| 5 | |
| 6 | ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>. |
| 7 | ;; Maintainer: FSF |
| 8 | ;; Keywords: files |
| 9 | |
| 10 | ;; This file is part of GNU Emacs. |
| 11 | |
| 12 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 13 | ;; it under the terms of the GNU General Public License as published by |
| 14 | ;; the Free Software Foundation, either version 3 of the License, or |
| 15 | ;; (at your option) any later version. |
| 16 | |
| 17 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 18 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 19 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 20 | ;; GNU General Public License for more details. |
| 21 | |
| 22 | ;; You should have received a copy of the GNU General Public License |
| 23 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 24 | |
| 25 | ;;; Commentary: |
| 26 | |
| 27 | ;; The parts of dired mode not normally used. This is a space-saving hack |
| 28 | ;; to avoid having to load a large mode when all that's wanted are a few |
| 29 | ;; functions. |
| 30 | |
| 31 | ;; Rewritten in 1990/1991 to add tree features, file marking and |
| 32 | ;; sorting by Sebastian Kremer <sk@thp.uni-koeln.de>. |
| 33 | ;; Finished up by rms in 1992. |
| 34 | |
| 35 | ;;; Code: |
| 36 | |
| 37 | ;; We need macros in dired.el to compile properly, |
| 38 | ;; and we call subroutines in it too. |
| 39 | (require 'dired) |
| 40 | |
| 41 | (defvar dired-create-files-failures nil |
| 42 | "Variable where `dired-create-files' records failing file names. |
| 43 | Functions that operate recursively can store additional names |
| 44 | into this list; they also should call `dired-log' to log the errors.") |
| 45 | |
| 46 | ;;; 15K |
| 47 | ;;;###begin dired-cmd.el |
| 48 | ;; Diffing and compressing |
| 49 | |
| 50 | (defconst dired-star-subst-regexp "\\(^\\|[ \t]\\)\\*\\([ \t]\\|$\\)") |
| 51 | (defconst dired-quark-subst-regexp "\\(^\\|[ \t]\\)\\?\\([ \t]\\|$\\)") |
| 52 | |
| 53 | ;;;###autoload |
| 54 | (defun dired-diff (file &optional switches) |
| 55 | "Compare file at point with file FILE using `diff'. |
| 56 | FILE defaults to the file at the mark. (That's the mark set by |
| 57 | \\[set-mark-command], not by Dired's \\[dired-mark] command.) |
| 58 | The prompted-for file is the first file given to `diff'. |
| 59 | With prefix arg, prompt for second argument SWITCHES, |
| 60 | which is options for `diff'." |
| 61 | (interactive |
| 62 | (let ((current (dired-get-filename t)) |
| 63 | (default (if (mark t) |
| 64 | (save-excursion (goto-char (mark t)) |
| 65 | (dired-get-filename t t))))) |
| 66 | (if (or (equal default current) |
| 67 | (and (not (equal (dired-dwim-target-directory) |
| 68 | (dired-current-directory))) |
| 69 | (not mark-active))) |
| 70 | (setq default nil)) |
| 71 | (require 'diff) |
| 72 | (list (read-file-name (format "Diff %s with%s: " |
| 73 | current |
| 74 | (if default |
| 75 | (concat " (default " default ")") |
| 76 | "")) |
| 77 | (if default |
| 78 | (dired-current-directory) |
| 79 | (dired-dwim-target-directory)) |
| 80 | default t) |
| 81 | (if current-prefix-arg |
| 82 | (read-string "Options for diff: " |
| 83 | (if (stringp diff-switches) |
| 84 | diff-switches |
| 85 | (mapconcat 'identity diff-switches " "))))))) |
| 86 | (diff file (dired-get-filename t) switches)) |
| 87 | |
| 88 | ;;;###autoload |
| 89 | (defun dired-backup-diff (&optional switches) |
| 90 | "Diff this file with its backup file or vice versa. |
| 91 | Uses the latest backup, if there are several numerical backups. |
| 92 | If this file is a backup, diff it with its original. |
| 93 | The backup file is the first file given to `diff'. |
| 94 | With prefix arg, prompt for argument SWITCHES which is options for `diff'." |
| 95 | (interactive |
| 96 | (if current-prefix-arg |
| 97 | (list (read-string "Options for diff: " |
| 98 | (if (stringp diff-switches) |
| 99 | diff-switches |
| 100 | (mapconcat 'identity diff-switches " ")))) |
| 101 | nil)) |
| 102 | (diff-backup (dired-get-filename) switches)) |
| 103 | |
| 104 | ;;;###autoload |
| 105 | (defun dired-compare-directories (dir2 predicate) |
| 106 | "Mark files with different file attributes in two dired buffers. |
| 107 | Compare file attributes of files in the current directory |
| 108 | with file attributes in directory DIR2 using PREDICATE on pairs of files |
| 109 | with the same name. Mark files for which PREDICATE returns non-nil. |
| 110 | Mark files with different names if PREDICATE is nil (or interactively |
| 111 | with empty input at the predicate prompt). |
| 112 | |
| 113 | PREDICATE is a Lisp expression that can refer to the following variables: |
| 114 | |
| 115 | size1, size2 - file size in bytes |
| 116 | mtime1, mtime2 - last modification time in seconds, as a float |
| 117 | fa1, fa2 - list of file attributes |
| 118 | returned by function `file-attributes' |
| 119 | |
| 120 | where 1 refers to attribute of file in the current dired buffer |
| 121 | and 2 to attribute of file in second dired buffer. |
| 122 | |
| 123 | Examples of PREDICATE: |
| 124 | |
| 125 | (> mtime1 mtime2) - mark newer files |
| 126 | (not (= size1 size2)) - mark files with different sizes |
| 127 | (not (string= (nth 8 fa1) (nth 8 fa2))) - mark files with different modes |
| 128 | (not (and (= (nth 2 fa1) (nth 2 fa2)) - mark files with different UID |
| 129 | (= (nth 3 fa1) (nth 3 fa2)))) and GID." |
| 130 | (interactive |
| 131 | (list (read-directory-name (format "Compare %s with: " |
| 132 | (dired-current-directory)) |
| 133 | (dired-dwim-target-directory) |
| 134 | (dired-dwim-target-directory)) |
| 135 | (read-from-minibuffer "Mark if (lisp expr or RET): " nil nil t nil "nil"))) |
| 136 | (let* ((dir1 (dired-current-directory)) |
| 137 | (file-alist1 (dired-files-attributes dir1)) |
| 138 | (file-alist2 (dired-files-attributes dir2)) |
| 139 | file-list1 file-list2) |
| 140 | (setq file-alist1 (delq (assoc "." file-alist1) file-alist1)) |
| 141 | (setq file-alist1 (delq (assoc ".." file-alist1) file-alist1)) |
| 142 | (setq file-alist2 (delq (assoc "." file-alist2) file-alist2)) |
| 143 | (setq file-alist2 (delq (assoc ".." file-alist2) file-alist2)) |
| 144 | (setq file-list1 (mapcar |
| 145 | 'cadr |
| 146 | (dired-file-set-difference |
| 147 | file-alist1 file-alist2 |
| 148 | predicate)) |
| 149 | file-list2 (mapcar |
| 150 | 'cadr |
| 151 | (dired-file-set-difference |
| 152 | file-alist2 file-alist1 |
| 153 | predicate))) |
| 154 | (dired-fun-in-all-buffers |
| 155 | dir1 nil |
| 156 | (lambda () |
| 157 | (dired-mark-if |
| 158 | (member (dired-get-filename nil t) file-list1) nil))) |
| 159 | (dired-fun-in-all-buffers |
| 160 | dir2 nil |
| 161 | (lambda () |
| 162 | (dired-mark-if |
| 163 | (member (dired-get-filename nil t) file-list2) nil))) |
| 164 | (message "Marked in dir1: %s files, in dir2: %s files" |
| 165 | (length file-list1) |
| 166 | (length file-list2)))) |
| 167 | |
| 168 | (defun dired-file-set-difference (list1 list2 predicate) |
| 169 | "Combine LIST1 and LIST2 using a set-difference operation. |
| 170 | The result list contains all file items that appear in LIST1 but not LIST2. |
| 171 | This is a non-destructive function; it makes a copy of the data if necessary |
| 172 | to avoid corrupting the original LIST1 and LIST2. |
| 173 | PREDICATE (see `dired-compare-directories') is an additional match |
| 174 | condition. Two file items are considered to match if they are equal |
| 175 | *and* PREDICATE evaluates to t." |
| 176 | (if (or (null list1) (null list2)) |
| 177 | list1 |
| 178 | (let (res) |
| 179 | (dolist (file1 list1) |
| 180 | (unless (let ((list list2)) |
| 181 | (while (and list |
| 182 | (not (let* ((file2 (car list)) |
| 183 | (fa1 (car (cddr file1))) |
| 184 | (fa2 (car (cddr file2))) |
| 185 | (size1 (nth 7 fa1)) |
| 186 | (size2 (nth 7 fa2)) |
| 187 | (mtime1 (float-time (nth 5 fa1))) |
| 188 | (mtime2 (float-time (nth 5 fa2)))) |
| 189 | (and |
| 190 | (equal (car file1) (car file2)) |
| 191 | (not (eval predicate)))))) |
| 192 | (setq list (cdr list))) |
| 193 | list) |
| 194 | (setq res (cons file1 res)))) |
| 195 | (nreverse res)))) |
| 196 | |
| 197 | (defun dired-files-attributes (dir) |
| 198 | "Return a list of all file names and attributes from DIR. |
| 199 | List has a form of (file-name full-file-name (attribute-list))" |
| 200 | (mapcar |
| 201 | (lambda (file-name) |
| 202 | (let ((full-file-name (expand-file-name file-name dir))) |
| 203 | (list file-name |
| 204 | full-file-name |
| 205 | (file-attributes full-file-name)))) |
| 206 | (directory-files dir))) |
| 207 | \f |
| 208 | |
| 209 | (defun dired-touch-initial (files) |
| 210 | "Create initial input value for `touch' command." |
| 211 | (let (initial) |
| 212 | (while files |
| 213 | (let ((current (nth 5 (file-attributes (car files))))) |
| 214 | (if (and initial (not (equal initial current))) |
| 215 | (setq initial (current-time) files nil) |
| 216 | (setq initial current)) |
| 217 | (setq files (cdr files)))) |
| 218 | (format-time-string "%Y%m%d%H%M.%S" initial))) |
| 219 | |
| 220 | (defun dired-do-chxxx (attribute-name program op-symbol arg) |
| 221 | ;; Change file attributes (mode, group, owner, timestamp) of marked files and |
| 222 | ;; refresh their file lines. |
| 223 | ;; ATTRIBUTE-NAME is a string describing the attribute to the user. |
| 224 | ;; PROGRAM is the program used to change the attribute. |
| 225 | ;; OP-SYMBOL is the type of operation (for use in dired-mark-pop-up). |
| 226 | ;; ARG describes which files to use, as in dired-get-marked-files. |
| 227 | (let* ((files (dired-get-marked-files t arg)) |
| 228 | (new-attribute |
| 229 | (dired-mark-read-string |
| 230 | (concat "Change " attribute-name " of %s to: ") |
| 231 | (if (eq op-symbol 'touch) (dired-touch-initial files)) |
| 232 | op-symbol arg files)) |
| 233 | (operation (concat program " " new-attribute)) |
| 234 | failures) |
| 235 | (setq failures |
| 236 | (dired-bunch-files 10000 |
| 237 | (function dired-check-process) |
| 238 | (append |
| 239 | (list operation program) |
| 240 | (if (eq op-symbol 'touch) |
| 241 | '("-t") nil) |
| 242 | (list new-attribute) |
| 243 | (if (string-match "gnu" system-configuration) |
| 244 | '("--") nil)) |
| 245 | files)) |
| 246 | (dired-do-redisplay arg);; moves point if ARG is an integer |
| 247 | (if failures |
| 248 | (dired-log-summary |
| 249 | (format "%s: error" operation) |
| 250 | nil)))) |
| 251 | |
| 252 | ;;;###autoload |
| 253 | (defun dired-do-chmod (&optional arg) |
| 254 | "Change the mode of the marked (or next ARG) files. |
| 255 | Symbolic modes like `g+w' are allowed." |
| 256 | (interactive "P") |
| 257 | (let* ((files (dired-get-marked-files t arg)) |
| 258 | (modestr (and (stringp (car files)) |
| 259 | (nth 8 (file-attributes (car files))))) |
| 260 | (default |
| 261 | (and (stringp modestr) |
| 262 | (string-match "^.\\(...\\)\\(...\\)\\(...\\)$" modestr) |
| 263 | (replace-regexp-in-string |
| 264 | "-" "" |
| 265 | (format "u=%s,g=%s,o=%s" |
| 266 | (match-string 1 modestr) |
| 267 | (match-string 2 modestr) |
| 268 | (match-string 3 modestr))))) |
| 269 | (modes (dired-mark-read-string |
| 270 | "Change mode of %s to: " nil |
| 271 | 'chmod arg files default)) |
| 272 | (num-modes (if (string-match "^[0-7]+" modes) |
| 273 | (string-to-number modes 8)))) |
| 274 | (dolist (file files) |
| 275 | (set-file-modes |
| 276 | file |
| 277 | (if num-modes num-modes |
| 278 | (file-modes-symbolic-to-number modes (file-modes file))))) |
| 279 | (dired-do-redisplay arg))) |
| 280 | |
| 281 | ;;;###autoload |
| 282 | (defun dired-do-chgrp (&optional arg) |
| 283 | "Change the group of the marked (or next ARG) files." |
| 284 | (interactive "P") |
| 285 | (if (memq system-type '(ms-dos windows-nt)) |
| 286 | (error "chgrp not supported on this system")) |
| 287 | (dired-do-chxxx "Group" "chgrp" 'chgrp arg)) |
| 288 | |
| 289 | ;;;###autoload |
| 290 | (defun dired-do-chown (&optional arg) |
| 291 | "Change the owner of the marked (or next ARG) files." |
| 292 | (interactive "P") |
| 293 | (if (memq system-type '(ms-dos windows-nt)) |
| 294 | (error "chown not supported on this system")) |
| 295 | (dired-do-chxxx "Owner" dired-chown-program 'chown arg)) |
| 296 | |
| 297 | ;;;###autoload |
| 298 | (defun dired-do-touch (&optional arg) |
| 299 | "Change the timestamp of the marked (or next ARG) files. |
| 300 | This calls touch." |
| 301 | (interactive "P") |
| 302 | (dired-do-chxxx "Timestamp" dired-touch-program 'touch arg)) |
| 303 | |
| 304 | ;; Process all the files in FILES in batches of a convenient size, |
| 305 | ;; by means of (FUNCALL FUNCTION ARGS... SOME-FILES...). |
| 306 | ;; Batches are chosen to need less than MAX chars for the file names, |
| 307 | ;; allowing 3 extra characters of separator per file name. |
| 308 | (defun dired-bunch-files (max function args files) |
| 309 | (let (pending |
| 310 | past |
| 311 | (pending-length 0) |
| 312 | failures) |
| 313 | ;; Accumulate files as long as they fit in MAX chars, |
| 314 | ;; then process the ones accumulated so far. |
| 315 | (while files |
| 316 | (let* ((thisfile (car files)) |
| 317 | (thislength (+ (length thisfile) 3)) |
| 318 | (rest (cdr files))) |
| 319 | ;; If we have at least 1 pending file |
| 320 | ;; and this file won't fit in the length limit, process now. |
| 321 | (if (and pending (> (+ thislength pending-length) max)) |
| 322 | (setq pending (nreverse pending) |
| 323 | ;; The elements of PENDING are now in forward order. |
| 324 | ;; Do the operation and record failures. |
| 325 | failures (nconc (apply function (append args pending)) |
| 326 | failures) |
| 327 | ;; Transfer the elemens of PENDING onto PAST |
| 328 | ;; and clear it out. Now PAST contains the first N files |
| 329 | ;; specified (for some N), and FILES contains the rest. |
| 330 | past (nconc past pending) |
| 331 | pending nil |
| 332 | pending-length 0)) |
| 333 | ;; Do (setq pending (cons thisfile pending)) |
| 334 | ;; but reuse the cons that was in `files'. |
| 335 | (setcdr files pending) |
| 336 | (setq pending files) |
| 337 | (setq pending-length (+ thislength pending-length)) |
| 338 | (setq files rest))) |
| 339 | (setq pending (nreverse pending)) |
| 340 | (prog1 |
| 341 | (nconc (apply function (append args pending)) |
| 342 | failures) |
| 343 | ;; Now the original list FILES has been put back as it was. |
| 344 | (nconc past pending)))) |
| 345 | |
| 346 | ;;;###autoload |
| 347 | (defun dired-do-print (&optional arg) |
| 348 | "Print the marked (or next ARG) files. |
| 349 | Uses the shell command coming from variables `lpr-command' and |
| 350 | `lpr-switches' as default." |
| 351 | (interactive "P") |
| 352 | (let* ((file-list (dired-get-marked-files t arg)) |
| 353 | (command (dired-mark-read-string |
| 354 | "Print %s with: " |
| 355 | (mapconcat 'identity |
| 356 | (cons lpr-command |
| 357 | (if (stringp lpr-switches) |
| 358 | (list lpr-switches) |
| 359 | lpr-switches)) |
| 360 | " ") |
| 361 | 'print arg file-list))) |
| 362 | (dired-run-shell-command (dired-shell-stuff-it command file-list nil)))) |
| 363 | |
| 364 | ;; Read arguments for a marked-files command that wants a string |
| 365 | ;; that is not a file name, |
| 366 | ;; perhaps popping up the list of marked files. |
| 367 | ;; ARG is the prefix arg and indicates whether the files came from |
| 368 | ;; marks (ARG=nil) or a repeat factor (integerp ARG). |
| 369 | ;; If the current file was used, the list has but one element and ARG |
| 370 | ;; does not matter. (It is non-nil, non-integer in that case, namely '(4)). |
| 371 | |
| 372 | (defun dired-mark-read-string (prompt initial op-symbol arg files &optional default) |
| 373 | ;; PROMPT for a string, with INITIAL input and DEFAULT value. |
| 374 | ;; Other args are used to give user feedback and pop-up: |
| 375 | ;; OP-SYMBOL of command, prefix ARG, marked FILES. |
| 376 | (dired-mark-pop-up |
| 377 | nil op-symbol files |
| 378 | (function read-string) |
| 379 | (format prompt (dired-mark-prompt arg files)) initial nil default)) |
| 380 | \f |
| 381 | ;;; Cleaning a directory: flagging some backups for deletion. |
| 382 | |
| 383 | (defvar dired-file-version-alist) |
| 384 | |
| 385 | ;;;###autoload |
| 386 | (defun dired-clean-directory (keep) |
| 387 | "Flag numerical backups for deletion. |
| 388 | Spares `dired-kept-versions' latest versions, and `kept-old-versions' oldest. |
| 389 | Positive prefix arg KEEP overrides `dired-kept-versions'; |
| 390 | Negative prefix arg KEEP overrides `kept-old-versions' with KEEP made positive. |
| 391 | |
| 392 | To clear the flags on these files, you can use \\[dired-flag-backup-files] |
| 393 | with a prefix argument." |
| 394 | (interactive "P") |
| 395 | (setq keep (if keep (prefix-numeric-value keep) dired-kept-versions)) |
| 396 | (let ((early-retention (if (< keep 0) (- keep) kept-old-versions)) |
| 397 | (late-retention (if (<= keep 0) dired-kept-versions keep)) |
| 398 | (dired-file-version-alist ())) |
| 399 | (message "Cleaning numerical backups (keeping %d late, %d old)..." |
| 400 | late-retention early-retention) |
| 401 | ;; Look at each file. |
| 402 | ;; If the file has numeric backup versions, |
| 403 | ;; put on dired-file-version-alist an element of the form |
| 404 | ;; (FILENAME . VERSION-NUMBER-LIST) |
| 405 | (dired-map-dired-file-lines (function dired-collect-file-versions)) |
| 406 | ;; Sort each VERSION-NUMBER-LIST, |
| 407 | ;; and remove the versions not to be deleted. |
| 408 | (let ((fval dired-file-version-alist)) |
| 409 | (while fval |
| 410 | (let* ((sorted-v-list (cons 'q (sort (cdr (car fval)) '<))) |
| 411 | (v-count (length sorted-v-list))) |
| 412 | (if (> v-count (+ early-retention late-retention)) |
| 413 | (rplacd (nthcdr early-retention sorted-v-list) |
| 414 | (nthcdr (- v-count late-retention) |
| 415 | sorted-v-list))) |
| 416 | (rplacd (car fval) |
| 417 | (cdr sorted-v-list))) |
| 418 | (setq fval (cdr fval)))) |
| 419 | ;; Look at each file. If it is a numeric backup file, |
| 420 | ;; find it in a VERSION-NUMBER-LIST and maybe flag it for deletion. |
| 421 | (dired-map-dired-file-lines (function dired-trample-file-versions)) |
| 422 | (message "Cleaning numerical backups...done"))) |
| 423 | |
| 424 | ;;; Subroutines of dired-clean-directory. |
| 425 | |
| 426 | (defun dired-map-dired-file-lines (fun) |
| 427 | ;; Perform FUN with point at the end of each non-directory line. |
| 428 | ;; FUN takes one argument, the absolute filename. |
| 429 | (save-excursion |
| 430 | (let (file buffer-read-only) |
| 431 | (goto-char (point-min)) |
| 432 | (while (not (eobp)) |
| 433 | (save-excursion |
| 434 | (and (not (looking-at dired-re-dir)) |
| 435 | (not (eolp)) |
| 436 | (setq file (dired-get-filename nil t)) ; nil on non-file |
| 437 | (progn (end-of-line) |
| 438 | (funcall fun file)))) |
| 439 | (forward-line 1))))) |
| 440 | |
| 441 | (defun dired-collect-file-versions (fn) |
| 442 | (let ((fn (file-name-sans-versions fn))) |
| 443 | ;; Only do work if this file is not already in the alist. |
| 444 | (if (assoc fn dired-file-version-alist) |
| 445 | nil |
| 446 | ;; If it looks like file FN has versions, return a list of the versions. |
| 447 | ;;That is a list of strings which are file names. |
| 448 | ;;The caller may want to flag some of these files for deletion. |
| 449 | (let* ((base-versions |
| 450 | (concat (file-name-nondirectory fn) ".~")) |
| 451 | (backup-extract-version-start (length base-versions)) |
| 452 | (possibilities (file-name-all-completions |
| 453 | base-versions |
| 454 | (file-name-directory fn))) |
| 455 | (versions (mapcar 'backup-extract-version possibilities))) |
| 456 | (if versions |
| 457 | (setq dired-file-version-alist |
| 458 | (cons (cons fn versions) |
| 459 | dired-file-version-alist))))))) |
| 460 | |
| 461 | (defun dired-trample-file-versions (fn) |
| 462 | (let* ((start-vn (string-match "\\.~[0-9]+~$" fn)) |
| 463 | base-version-list) |
| 464 | (and start-vn |
| 465 | (setq base-version-list ; there was a base version to which |
| 466 | (assoc (substring fn 0 start-vn) ; this looks like a |
| 467 | dired-file-version-alist)) ; subversion |
| 468 | (not (memq (string-to-number (substring fn (+ 2 start-vn))) |
| 469 | base-version-list)) ; this one doesn't make the cut |
| 470 | (progn (beginning-of-line) |
| 471 | (delete-char 1) |
| 472 | (insert dired-del-marker))))) |
| 473 | \f |
| 474 | ;;; Shell commands |
| 475 | |
| 476 | (declare-function mailcap-file-default-commands "mailcap" (files)) |
| 477 | |
| 478 | (defun minibuffer-default-add-dired-shell-commands () |
| 479 | "Return a list of all commands associted with current dired files. |
| 480 | This function is used to add all related commands retieved by `mailcap' |
| 481 | to the end of the list of defaults just after the default value." |
| 482 | (interactive) |
| 483 | (let ((commands (and (boundp 'files) (require 'mailcap nil t) |
| 484 | (mailcap-file-default-commands files)))) |
| 485 | (if (listp minibuffer-default) |
| 486 | (append minibuffer-default commands) |
| 487 | (cons minibuffer-default commands)))) |
| 488 | |
| 489 | ;; This is an extra function so that you can redefine it, e.g., to use gmhist. |
| 490 | (defun dired-read-shell-command (prompt arg files) |
| 491 | "Read a dired shell command prompting with PROMPT (using read-shell-command). |
| 492 | ARG is the prefix arg and may be used to indicate in the prompt which |
| 493 | FILES are affected." |
| 494 | (minibuffer-with-setup-hook |
| 495 | (lambda () |
| 496 | (set (make-local-variable 'minibuffer-default-add-function) |
| 497 | 'minibuffer-default-add-dired-shell-commands)) |
| 498 | (dired-mark-pop-up |
| 499 | nil 'shell files |
| 500 | #'read-shell-command |
| 501 | (format prompt (dired-mark-prompt arg files)) |
| 502 | nil nil))) |
| 503 | |
| 504 | ;;;###autoload |
| 505 | (defun dired-do-async-shell-command (command &optional arg file-list) |
| 506 | "Run a shell command COMMAND on the marked files asynchronously. |
| 507 | |
| 508 | Like `dired-do-shell-command' but if COMMAND doesn't end in ampersand, |
| 509 | adds `* &' surrounded by whitespace and executes the command asynchronously. |
| 510 | The output appears in the buffer `*Async Shell Command*'." |
| 511 | (interactive |
| 512 | (let ((files (dired-get-marked-files t current-prefix-arg))) |
| 513 | (list |
| 514 | ;; Want to give feedback whether this file or marked files are used: |
| 515 | (dired-read-shell-command "& on %s: " current-prefix-arg files) |
| 516 | current-prefix-arg |
| 517 | files))) |
| 518 | (unless (string-match "[*?][ \t]*\\'" command) |
| 519 | (setq command (concat command " *"))) |
| 520 | (unless (string-match "&[ \t]*\\'" command) |
| 521 | (setq command (concat command " &"))) |
| 522 | (dired-do-shell-command command arg file-list)) |
| 523 | |
| 524 | ;; The in-background argument is only needed in Emacs 18 where |
| 525 | ;; shell-command doesn't understand an appended ampersand `&'. |
| 526 | ;;;###autoload |
| 527 | (defun dired-do-shell-command (command &optional arg file-list) |
| 528 | "Run a shell command COMMAND on the marked files. |
| 529 | If no files are marked or a specific numeric prefix arg is given, |
| 530 | the next ARG files are used. Just \\[universal-argument] means the current file. |
| 531 | The prompt mentions the file(s) or the marker, as appropriate. |
| 532 | |
| 533 | If there is a `*' in COMMAND, surrounded by whitespace, this runs |
| 534 | COMMAND just once with the entire file list substituted there. |
| 535 | |
| 536 | If there is no `*', but there is a `?' in COMMAND, surrounded by |
| 537 | whitespace, this runs COMMAND on each file individually with the |
| 538 | file name substituted for `?'. |
| 539 | |
| 540 | Otherwise, this runs COMMAND on each file individually with the |
| 541 | file name added at the end of COMMAND (separated by a space). |
| 542 | |
| 543 | `*' and `?' when not surrounded by whitespace have no special |
| 544 | significance for `dired-do-shell-command', and are passed through |
| 545 | normally to the shell, but you must confirm first. To pass `*' by |
| 546 | itself to the shell as a wildcard, type `*\"\"'. |
| 547 | |
| 548 | If COMMAND produces output, it goes to a separate buffer. |
| 549 | |
| 550 | This feature does not try to redisplay Dired buffers afterward, as |
| 551 | there's no telling what files COMMAND may have changed. |
| 552 | Type \\[dired-do-redisplay] to redisplay the marked files. |
| 553 | |
| 554 | When COMMAND runs, its working directory is the top-level directory of |
| 555 | the Dired buffer, so output files usually are created there instead of |
| 556 | in a subdir. |
| 557 | |
| 558 | In a noninteractive call (from Lisp code), you must specify |
| 559 | the list of file names explicitly with the FILE-LIST argument, which |
| 560 | can be produced by `dired-get-marked-files', for example." |
| 561 | ;;Functions dired-run-shell-command and dired-shell-stuff-it do the |
| 562 | ;;actual work and can be redefined for customization. |
| 563 | (interactive |
| 564 | (let ((files (dired-get-marked-files t current-prefix-arg))) |
| 565 | (list |
| 566 | ;; Want to give feedback whether this file or marked files are used: |
| 567 | (dired-read-shell-command (concat "! on " |
| 568 | "%s: ") |
| 569 | current-prefix-arg |
| 570 | files) |
| 571 | current-prefix-arg |
| 572 | files))) |
| 573 | (let* ((on-each (not (string-match dired-star-subst-regexp command))) |
| 574 | (subst (not (string-match dired-quark-subst-regexp command))) |
| 575 | (star (not (string-match "\\*" command))) |
| 576 | (qmark (not (string-match "\\?" command)))) |
| 577 | ;; Get confirmation for wildcards that may have been meant |
| 578 | ;; to control substitution of a file name or the file name list. |
| 579 | (if (cond ((not (or on-each subst)) |
| 580 | (error "You can not combine `*' and `?' substitution marks")) |
| 581 | ((and star (not on-each)) |
| 582 | (y-or-n-p "Confirm--do you mean to use `*' as a wildcard? ")) |
| 583 | ((and qmark (not subst)) |
| 584 | (y-or-n-p "Confirm--do you mean to use `?' as a wildcard? ")) |
| 585 | (t)) |
| 586 | (if on-each |
| 587 | (dired-bunch-files |
| 588 | (- 10000 (length command)) |
| 589 | (function (lambda (&rest files) |
| 590 | (dired-run-shell-command |
| 591 | (dired-shell-stuff-it command files t arg)))) |
| 592 | nil |
| 593 | file-list) |
| 594 | ;; execute the shell command |
| 595 | (dired-run-shell-command |
| 596 | (dired-shell-stuff-it command file-list nil arg)))))) |
| 597 | |
| 598 | ;; Might use {,} for bash or csh: |
| 599 | (defvar dired-mark-prefix "" |
| 600 | "Prepended to marked files in dired shell commands.") |
| 601 | (defvar dired-mark-postfix "" |
| 602 | "Appended to marked files in dired shell commands.") |
| 603 | (defvar dired-mark-separator " " |
| 604 | "Separates marked files in dired shell commands.") |
| 605 | |
| 606 | (defun dired-shell-stuff-it (command file-list on-each &optional raw-arg) |
| 607 | ;; "Make up a shell command line from COMMAND and FILE-LIST. |
| 608 | ;; If ON-EACH is t, COMMAND should be applied to each file, else |
| 609 | ;; simply concat all files and apply COMMAND to this. |
| 610 | ;; FILE-LIST's elements will be quoted for the shell." |
| 611 | ;; Might be redefined for smarter things and could then use RAW-ARG |
| 612 | ;; (coming from interactive P and currently ignored) to decide what to do. |
| 613 | ;; Smart would be a way to access basename or extension of file names. |
| 614 | (let ((stuff-it |
| 615 | (if (or (string-match dired-star-subst-regexp command) |
| 616 | (string-match dired-quark-subst-regexp command)) |
| 617 | (lambda (x) |
| 618 | (let ((retval command)) |
| 619 | (while (string-match |
| 620 | "\\(^\\|[ \t]\\)\\([*?]\\)\\([ \t]\\|$\\)" retval) |
| 621 | (setq retval (replace-match x t t retval 2))) |
| 622 | retval)) |
| 623 | (lambda (x) (concat command dired-mark-separator x))))) |
| 624 | (if on-each |
| 625 | (mapconcat stuff-it (mapcar 'shell-quote-argument file-list) ";") |
| 626 | (let ((files (mapconcat 'shell-quote-argument |
| 627 | file-list dired-mark-separator))) |
| 628 | (if (> (length file-list) 1) |
| 629 | (setq files (concat dired-mark-prefix files dired-mark-postfix))) |
| 630 | (funcall stuff-it files))))) |
| 631 | |
| 632 | ;; This is an extra function so that it can be redefined by ange-ftp. |
| 633 | ;;;###autoload |
| 634 | (defun dired-run-shell-command (command) |
| 635 | (let ((handler |
| 636 | (find-file-name-handler (directory-file-name default-directory) |
| 637 | 'shell-command))) |
| 638 | (if handler (apply handler 'shell-command (list command)) |
| 639 | (shell-command command))) |
| 640 | ;; Return nil for sake of nconc in dired-bunch-files. |
| 641 | nil) |
| 642 | \f |
| 643 | |
| 644 | (defun dired-check-process (msg program &rest arguments) |
| 645 | ; "Display MSG while running PROGRAM, and check for output. |
| 646 | ;Remaining arguments are strings passed as command arguments to PROGRAM. |
| 647 | ; On error, insert output |
| 648 | ; in a log buffer and return the offending ARGUMENTS or PROGRAM. |
| 649 | ; Caller can cons up a list of failed args. |
| 650 | ;Else returns nil for success." |
| 651 | (let (err-buffer err (dir default-directory)) |
| 652 | (message "%s..." msg) |
| 653 | (save-excursion |
| 654 | ;; Get a clean buffer for error output: |
| 655 | (setq err-buffer (get-buffer-create " *dired-check-process output*")) |
| 656 | (set-buffer err-buffer) |
| 657 | (erase-buffer) |
| 658 | (setq default-directory dir ; caller's default-directory |
| 659 | err (not (eq 0 (apply 'process-file program nil t nil arguments)))) |
| 660 | (if err |
| 661 | (progn |
| 662 | (dired-log (concat program " " (prin1-to-string arguments) "\n")) |
| 663 | (dired-log err-buffer) |
| 664 | (or arguments program t)) |
| 665 | (kill-buffer err-buffer) |
| 666 | (message "%s...done" msg) |
| 667 | nil)))) |
| 668 | \f |
| 669 | ;; Commands that delete or redisplay part of the dired buffer. |
| 670 | |
| 671 | (defun dired-kill-line (&optional arg) |
| 672 | (interactive "P") |
| 673 | (setq arg (prefix-numeric-value arg)) |
| 674 | (let (buffer-read-only file) |
| 675 | (while (/= 0 arg) |
| 676 | (setq file (dired-get-filename nil t)) |
| 677 | (if (not file) |
| 678 | (error "Can only kill file lines") |
| 679 | (save-excursion (and file |
| 680 | (dired-goto-subdir file) |
| 681 | (dired-kill-subdir))) |
| 682 | (delete-region (progn (beginning-of-line) (point)) |
| 683 | (progn (forward-line 1) (point))) |
| 684 | (if (> arg 0) |
| 685 | (setq arg (1- arg)) |
| 686 | (setq arg (1+ arg)) |
| 687 | (forward-line -1)))) |
| 688 | (dired-move-to-filename))) |
| 689 | |
| 690 | ;;;###autoload |
| 691 | (defun dired-do-kill-lines (&optional arg fmt) |
| 692 | "Kill all marked lines (not the files). |
| 693 | With a prefix argument, kill that many lines starting with the current line. |
| 694 | \(A negative argument kills backward.) |
| 695 | If you use this command with a prefix argument to kill the line |
| 696 | for a file that is a directory, which you have inserted in the |
| 697 | Dired buffer as a subdirectory, then it deletes that subdirectory |
| 698 | from the buffer as well. |
| 699 | To kill an entire subdirectory \(without killing its line in the |
| 700 | parent directory), go to its directory header line and use this |
| 701 | command with a prefix argument (the value does not matter)." |
| 702 | ;; Returns count of killed lines. FMT="" suppresses message. |
| 703 | (interactive "P") |
| 704 | (if arg |
| 705 | (if (dired-get-subdir) |
| 706 | (dired-kill-subdir) |
| 707 | (dired-kill-line arg)) |
| 708 | (save-excursion |
| 709 | (goto-char (point-min)) |
| 710 | (let (buffer-read-only |
| 711 | (count 0) |
| 712 | (regexp (dired-marker-regexp))) |
| 713 | (while (and (not (eobp)) |
| 714 | (re-search-forward regexp nil t)) |
| 715 | (setq count (1+ count)) |
| 716 | (delete-region (progn (beginning-of-line) (point)) |
| 717 | (progn (forward-line 1) (point)))) |
| 718 | (or (equal "" fmt) |
| 719 | (message (or fmt "Killed %d line%s.") count (dired-plural-s count))) |
| 720 | count)))) |
| 721 | |
| 722 | ;;;###end dired-cmd.el |
| 723 | \f |
| 724 | ;;; 30K |
| 725 | ;;;###begin dired-cp.el |
| 726 | |
| 727 | (defun dired-compress () |
| 728 | ;; Compress or uncompress the current file. |
| 729 | ;; Return nil for success, offending filename else. |
| 730 | (let* (buffer-read-only |
| 731 | (from-file (dired-get-filename)) |
| 732 | (new-file (dired-compress-file from-file))) |
| 733 | (if new-file |
| 734 | (let ((start (point))) |
| 735 | ;; Remove any preexisting entry for the name NEW-FILE. |
| 736 | (condition-case nil |
| 737 | (dired-remove-entry new-file) |
| 738 | (error nil)) |
| 739 | (goto-char start) |
| 740 | ;; Now replace the current line with an entry for NEW-FILE. |
| 741 | (dired-update-file-line new-file) nil) |
| 742 | (dired-log (concat "Failed to compress" from-file)) |
| 743 | from-file))) |
| 744 | |
| 745 | (defvar dired-compress-file-suffixes |
| 746 | '(("\\.gz\\'" "" "gunzip") |
| 747 | ("\\.tgz\\'" ".tar" "gunzip") |
| 748 | ("\\.Z\\'" "" "uncompress") |
| 749 | ;; For .z, try gunzip. It might be an old gzip file, |
| 750 | ;; or it might be from compact? pack? (which?) but gunzip handles both. |
| 751 | ("\\.z\\'" "" "gunzip") |
| 752 | ("\\.dz\\'" "" "dictunzip") |
| 753 | ("\\.tbz\\'" ".tar" "bunzip2") |
| 754 | ("\\.bz2\\'" "" "bunzip2") |
| 755 | ;; This item controls naming for compression. |
| 756 | ("\\.tar\\'" ".tgz" nil)) |
| 757 | "Control changes in file name suffixes for compression and uncompression. |
| 758 | Each element specifies one transformation rule, and has the form: |
| 759 | (REGEXP NEW-SUFFIX PROGRAM) |
| 760 | The rule applies when the old file name matches REGEXP. |
| 761 | The new file name is computed by deleting the part that matches REGEXP |
| 762 | (as well as anything after that), then adding NEW-SUFFIX in its place. |
| 763 | If PROGRAM is non-nil, the rule is an uncompression rule, |
| 764 | and uncompression is done by running PROGRAM. |
| 765 | Otherwise, the rule is a compression rule, and compression is done with gzip.") |
| 766 | |
| 767 | ;;;###autoload |
| 768 | (defun dired-compress-file (file) |
| 769 | ;; Compress or uncompress FILE. |
| 770 | ;; Return the name of the compressed or uncompressed file. |
| 771 | ;; Return nil if no change in files. |
| 772 | (let ((handler (find-file-name-handler file 'dired-compress-file)) |
| 773 | suffix newname |
| 774 | (suffixes dired-compress-file-suffixes)) |
| 775 | ;; See if any suffix rule matches this file name. |
| 776 | (while suffixes |
| 777 | (let (case-fold-search) |
| 778 | (if (string-match (car (car suffixes)) file) |
| 779 | (setq suffix (car suffixes) suffixes nil)) |
| 780 | (setq suffixes (cdr suffixes)))) |
| 781 | ;; If so, compute desired new name. |
| 782 | (if suffix |
| 783 | (setq newname (concat (substring file 0 (match-beginning 0)) |
| 784 | (nth 1 suffix)))) |
| 785 | (cond (handler |
| 786 | (funcall handler 'dired-compress-file file)) |
| 787 | ((file-symlink-p file) |
| 788 | nil) |
| 789 | ((and suffix (nth 2 suffix)) |
| 790 | ;; We found an uncompression rule. |
| 791 | (if (not (dired-check-process (concat "Uncompressing " file) |
| 792 | (nth 2 suffix) file)) |
| 793 | newname)) |
| 794 | (t |
| 795 | ;;; We don't recognize the file as compressed, so compress it. |
| 796 | ;;; Try gzip; if we don't have that, use compress. |
| 797 | (condition-case nil |
| 798 | (let ((out-name (concat file ".gz"))) |
| 799 | (and (or (not (file-exists-p out-name)) |
| 800 | (y-or-n-p |
| 801 | (format "File %s already exists. Really compress? " |
| 802 | out-name))) |
| 803 | (not (dired-check-process (concat "Compressing " file) |
| 804 | "gzip" "-f" file)) |
| 805 | (or (file-exists-p out-name) |
| 806 | (setq out-name (concat file ".z"))) |
| 807 | ;; Rename the compressed file to NEWNAME |
| 808 | ;; if it hasn't got that name already. |
| 809 | (if (and newname (not (equal newname out-name))) |
| 810 | (progn |
| 811 | (rename-file out-name newname t) |
| 812 | newname) |
| 813 | out-name))) |
| 814 | (file-error |
| 815 | (if (not (dired-check-process (concat "Compressing " file) |
| 816 | "compress" "-f" file)) |
| 817 | ;; Don't use NEWNAME with `compress'. |
| 818 | (concat file ".Z")))))))) |
| 819 | \f |
| 820 | (defun dired-mark-confirm (op-symbol arg) |
| 821 | ;; Request confirmation from the user that the operation described |
| 822 | ;; by OP-SYMBOL is to be performed on the marked files. |
| 823 | ;; Confirmation consists in a y-or-n question with a file list |
| 824 | ;; pop-up unless OP-SYMBOL is a member of `dired-no-confirm'. |
| 825 | ;; The files used are determined by ARG (as in dired-get-marked-files). |
| 826 | (or (eq dired-no-confirm t) |
| 827 | (memq op-symbol dired-no-confirm) |
| 828 | ;; Pass t for DISTINGUISH-ONE-MARKED so that a single file which |
| 829 | ;; is marked pops up a window. That will help the user see |
| 830 | ;; it isn't the current line file. |
| 831 | (let ((files (dired-get-marked-files t arg nil t)) |
| 832 | (string (if (eq op-symbol 'compress) "Compress or uncompress" |
| 833 | (capitalize (symbol-name op-symbol))))) |
| 834 | (dired-mark-pop-up nil op-symbol files (function y-or-n-p) |
| 835 | (concat string " " |
| 836 | (dired-mark-prompt arg files) "? "))))) |
| 837 | |
| 838 | (defun dired-map-over-marks-check (fun arg op-symbol &optional show-progress) |
| 839 | ; "Map FUN over marked files (with second ARG like in dired-map-over-marks) |
| 840 | ; and display failures. |
| 841 | |
| 842 | ; FUN takes zero args. It returns non-nil (the offending object, e.g. |
| 843 | ; the short form of the filename) for a failure and probably logs a |
| 844 | ; detailed error explanation using function `dired-log'. |
| 845 | |
| 846 | ; OP-SYMBOL is a symbol describing the operation performed (e.g. |
| 847 | ; `compress'). It is used with `dired-mark-pop-up' to prompt the user |
| 848 | ; (e.g. with `Compress * [2 files]? ') and to display errors (e.g. |
| 849 | ; `Failed to compress 1 of 2 files - type W to see why ("foo")') |
| 850 | |
| 851 | ; SHOW-PROGRESS if non-nil means redisplay dired after each file." |
| 852 | (if (dired-mark-confirm op-symbol arg) |
| 853 | (let* ((total-list;; all of FUN's return values |
| 854 | (dired-map-over-marks (funcall fun) arg show-progress)) |
| 855 | (total (length total-list)) |
| 856 | (failures (delq nil total-list)) |
| 857 | (count (length failures)) |
| 858 | (string (if (eq op-symbol 'compress) "Compress or uncompress" |
| 859 | (capitalize (symbol-name op-symbol))))) |
| 860 | (if (not failures) |
| 861 | (message "%s: %d file%s." |
| 862 | string total (dired-plural-s total)) |
| 863 | ;; end this bunch of errors: |
| 864 | (dired-log-summary |
| 865 | (format "Failed to %s %d of %d file%s" |
| 866 | (downcase string) count total (dired-plural-s total)) |
| 867 | failures))))) |
| 868 | |
| 869 | (defvar dired-query-alist |
| 870 | '((?\y . y) (?\040 . y) ; `y' or SPC means accept once |
| 871 | (?n . n) (?\177 . n) ; `n' or DEL skips once |
| 872 | (?! . yes) ; `!' accepts rest |
| 873 | (?q . no) (?\e . no) ; `q' or ESC skips rest |
| 874 | ;; None of these keys quit - use C-g for that. |
| 875 | )) |
| 876 | |
| 877 | ;;;###autoload |
| 878 | (defun dired-query (qs-var qs-prompt &rest qs-args) |
| 879 | ;; Query user and return nil or t. |
| 880 | ;; Store answer in symbol VAR (which must initially be bound to nil). |
| 881 | ;; Format PROMPT with ARGS. |
| 882 | ;; Binding variable help-form will help the user who types the help key. |
| 883 | (let* ((char (symbol-value qs-var)) |
| 884 | (action (cdr (assoc char dired-query-alist)))) |
| 885 | (cond ((eq 'yes action) |
| 886 | t) ; accept, and don't ask again |
| 887 | ((eq 'no action) |
| 888 | nil) ; skip, and don't ask again |
| 889 | (t;; no lasting effects from last time we asked - ask now |
| 890 | (let ((qprompt (concat qs-prompt |
| 891 | (if help-form |
| 892 | (format " [Type yn!q or %s] " |
| 893 | (key-description |
| 894 | (char-to-string help-char))) |
| 895 | " [Type y, n, q or !] "))) |
| 896 | result elt) |
| 897 | ;; Actually it looks nicer without cursor-in-echo-area - you can |
| 898 | ;; look at the dired buffer instead of at the prompt to decide. |
| 899 | (apply 'message qprompt qs-args) |
| 900 | (setq char (set qs-var (read-char))) |
| 901 | (while (not (setq elt (assoc char dired-query-alist))) |
| 902 | (message "Invalid char - type %c for help." help-char) |
| 903 | (ding) |
| 904 | (sit-for 1) |
| 905 | (apply 'message qprompt qs-args) |
| 906 | (setq char (set qs-var (read-char)))) |
| 907 | ;; Display the question with the answer. |
| 908 | (message "%s" (concat (apply 'format qprompt qs-args) |
| 909 | (char-to-string char))) |
| 910 | (memq (cdr elt) '(t y yes))))))) |
| 911 | \f |
| 912 | ;;;###autoload |
| 913 | (defun dired-do-compress (&optional arg) |
| 914 | "Compress or uncompress marked (or next ARG) files." |
| 915 | (interactive "P") |
| 916 | (dired-map-over-marks-check (function dired-compress) arg 'compress t)) |
| 917 | |
| 918 | ;; Commands for Emacs Lisp files - load and byte compile |
| 919 | |
| 920 | (defun dired-byte-compile () |
| 921 | ;; Return nil for success, offending file name else. |
| 922 | (let* ((filename (dired-get-filename)) |
| 923 | elc-file buffer-read-only failure) |
| 924 | (condition-case err |
| 925 | (save-excursion (byte-compile-file filename)) |
| 926 | (error |
| 927 | (setq failure err))) |
| 928 | (setq elc-file (byte-compile-dest-file filename)) |
| 929 | (or (file-exists-p elc-file) |
| 930 | (setq failure t)) |
| 931 | (if failure |
| 932 | (progn |
| 933 | (dired-log "Byte compile error for %s:\n%s\n" filename failure) |
| 934 | (dired-make-relative filename)) |
| 935 | (dired-remove-file elc-file) |
| 936 | (forward-line) ; insert .elc after its .el file |
| 937 | (dired-add-file elc-file) |
| 938 | nil))) |
| 939 | |
| 940 | ;;;###autoload |
| 941 | (defun dired-do-byte-compile (&optional arg) |
| 942 | "Byte compile marked (or next ARG) Emacs Lisp files." |
| 943 | (interactive "P") |
| 944 | (dired-map-over-marks-check (function dired-byte-compile) arg 'byte-compile t)) |
| 945 | |
| 946 | (defun dired-load () |
| 947 | ;; Return nil for success, offending file name else. |
| 948 | (let ((file (dired-get-filename)) failure) |
| 949 | (condition-case err |
| 950 | (load file nil nil t) |
| 951 | (error (setq failure err))) |
| 952 | (if (not failure) |
| 953 | nil |
| 954 | (dired-log "Load error for %s:\n%s\n" file failure) |
| 955 | (dired-make-relative file)))) |
| 956 | |
| 957 | ;;;###autoload |
| 958 | (defun dired-do-load (&optional arg) |
| 959 | "Load the marked (or next ARG) Emacs Lisp files." |
| 960 | (interactive "P") |
| 961 | (dired-map-over-marks-check (function dired-load) arg 'load t)) |
| 962 | |
| 963 | ;;;###autoload |
| 964 | (defun dired-do-redisplay (&optional arg test-for-subdir) |
| 965 | "Redisplay all marked (or next ARG) files. |
| 966 | If on a subdir line, redisplay that subdirectory. In that case, |
| 967 | a prefix arg lets you edit the `ls' switches used for the new listing. |
| 968 | |
| 969 | Dired remembers switches specified with a prefix arg, so that reverting |
| 970 | the buffer will not reset them. However, using `dired-undo' to re-insert |
| 971 | or delete subdirectories can bypass this machinery. Hence, you sometimes |
| 972 | may have to reset some subdirectory switches after a `dired-undo'. |
| 973 | You can reset all subdirectory switches to the default using |
| 974 | \\<dired-mode-map>\\[dired-reset-subdir-switches]. |
| 975 | See Info node `(emacs)Subdir switches' for more details." |
| 976 | ;; Moves point if the next ARG files are redisplayed. |
| 977 | (interactive "P\np") |
| 978 | (if (and test-for-subdir (dired-get-subdir)) |
| 979 | (let* ((dir (dired-get-subdir)) |
| 980 | (switches (cdr (assoc-string dir dired-switches-alist)))) |
| 981 | (dired-insert-subdir |
| 982 | dir |
| 983 | (when arg |
| 984 | (read-string "Switches for listing: " |
| 985 | (or switches |
| 986 | dired-subdir-switches |
| 987 | dired-actual-switches))))) |
| 988 | (message "Redisplaying...") |
| 989 | ;; message much faster than making dired-map-over-marks show progress |
| 990 | (dired-uncache |
| 991 | (if (consp dired-directory) (car dired-directory) dired-directory)) |
| 992 | (dired-map-over-marks (let ((fname (dired-get-filename))) |
| 993 | (message "Redisplaying... %s" fname) |
| 994 | (dired-update-file-line fname)) |
| 995 | arg) |
| 996 | (dired-move-to-filename) |
| 997 | (message "Redisplaying...done"))) |
| 998 | |
| 999 | (defun dired-reset-subdir-switches () |
| 1000 | "Set `dired-switches-alist' to nil and revert dired buffer." |
| 1001 | (interactive) |
| 1002 | (setq dired-switches-alist nil) |
| 1003 | (revert-buffer)) |
| 1004 | \f |
| 1005 | (defun dired-update-file-line (file) |
| 1006 | ;; Delete the current line, and insert an entry for FILE. |
| 1007 | ;; If FILE is nil, then just delete the current line. |
| 1008 | ;; Keeps any marks that may be present in column one (doing this |
| 1009 | ;; here is faster than with dired-add-entry's optional arg). |
| 1010 | ;; Does not update other dired buffers. Use dired-relist-entry for that. |
| 1011 | (beginning-of-line) |
| 1012 | (let ((char (following-char)) (opoint (point)) |
| 1013 | (buffer-read-only)) |
| 1014 | (delete-region (point) (progn (forward-line 1) (point))) |
| 1015 | (if file |
| 1016 | (progn |
| 1017 | (dired-add-entry file nil t) |
| 1018 | ;; Replace space by old marker without moving point. |
| 1019 | ;; Faster than goto+insdel inside a save-excursion? |
| 1020 | (subst-char-in-region opoint (1+ opoint) ?\040 char)))) |
| 1021 | (dired-move-to-filename)) |
| 1022 | |
| 1023 | ;;;###autoload |
| 1024 | (defun dired-add-file (filename &optional marker-char) |
| 1025 | (dired-fun-in-all-buffers |
| 1026 | (file-name-directory filename) (file-name-nondirectory filename) |
| 1027 | (function dired-add-entry) filename marker-char)) |
| 1028 | |
| 1029 | (defun dired-add-entry (filename &optional marker-char relative) |
| 1030 | ;; Add a new entry for FILENAME, optionally marking it |
| 1031 | ;; with MARKER-CHAR (a character, else dired-marker-char is used). |
| 1032 | ;; Note that this adds the entry `out of order' if files sorted by |
| 1033 | ;; time, etc. |
| 1034 | ;; At least this version inserts in the right subdirectory (if present). |
| 1035 | ;; And it skips "." or ".." (see `dired-trivial-filenames'). |
| 1036 | ;; Hidden subdirs are exposed if a file is added there. |
| 1037 | (setq filename (directory-file-name filename)) |
| 1038 | ;; Entry is always for files, even if they happen to also be directories |
| 1039 | (let* ((opoint (point)) |
| 1040 | (cur-dir (dired-current-directory)) |
| 1041 | (orig-file-name filename) |
| 1042 | (directory (if relative cur-dir (file-name-directory filename))) |
| 1043 | reason) |
| 1044 | (setq filename |
| 1045 | (if relative |
| 1046 | (file-relative-name filename directory) |
| 1047 | (file-name-nondirectory filename)) |
| 1048 | reason |
| 1049 | (catch 'not-found |
| 1050 | (if (string= directory cur-dir) |
| 1051 | (progn |
| 1052 | (skip-chars-forward "^\r\n") |
| 1053 | (if (eq (following-char) ?\r) |
| 1054 | (dired-unhide-subdir)) |
| 1055 | ;; We are already where we should be, except when |
| 1056 | ;; point is before the subdir line or its total line. |
| 1057 | (let ((p (dired-after-subdir-garbage cur-dir))) |
| 1058 | (if (< (point) p) |
| 1059 | (goto-char p)))) |
| 1060 | ;; else try to find correct place to insert |
| 1061 | (if (dired-goto-subdir directory) |
| 1062 | (progn ;; unhide if necessary |
| 1063 | (if (looking-at "\r") ;; point is at end of subdir line |
| 1064 | (dired-unhide-subdir)) |
| 1065 | ;; found - skip subdir and `total' line |
| 1066 | ;; and uninteresting files like . and .. |
| 1067 | ;; This better not moves into the next subdir! |
| 1068 | (dired-goto-next-nontrivial-file)) |
| 1069 | ;; not found |
| 1070 | (throw 'not-found "Subdir not found"))) |
| 1071 | (let (buffer-read-only opoint) |
| 1072 | (beginning-of-line) |
| 1073 | (setq opoint (point)) |
| 1074 | ;; Don't expand `.'. Show just the file name within directory. |
| 1075 | (let ((default-directory directory)) |
| 1076 | (dired-insert-directory directory |
| 1077 | (concat dired-actual-switches "d") |
| 1078 | (list filename))) |
| 1079 | (goto-char opoint) |
| 1080 | ;; Put in desired marker char. |
| 1081 | (when marker-char |
| 1082 | (let ((dired-marker-char |
| 1083 | (if (integerp marker-char) marker-char dired-marker-char))) |
| 1084 | (dired-mark nil))) |
| 1085 | ;; Compensate for a bug in ange-ftp. |
| 1086 | ;; It inserts the file's absolute name, rather than |
| 1087 | ;; the relative one. That may be hard to fix since it |
| 1088 | ;; is probably controlled by something in ftp. |
| 1089 | (goto-char opoint) |
| 1090 | (let ((inserted-name (dired-get-filename 'verbatim))) |
| 1091 | (if (file-name-directory inserted-name) |
| 1092 | (let (props) |
| 1093 | (end-of-line) |
| 1094 | (forward-char (- (length inserted-name))) |
| 1095 | (setq props (text-properties-at (point))) |
| 1096 | (delete-char (length inserted-name)) |
| 1097 | (let ((pt (point))) |
| 1098 | (insert filename) |
| 1099 | (set-text-properties pt (point) props)) |
| 1100 | (forward-char 1)) |
| 1101 | (forward-line 1))) |
| 1102 | (forward-line -1) |
| 1103 | (if dired-after-readin-hook ;; the subdir-alist is not affected... |
| 1104 | (save-excursion ;; ...so we can run it right now: |
| 1105 | (save-restriction |
| 1106 | (beginning-of-line) |
| 1107 | (narrow-to-region (point) (save-excursion |
| 1108 | (forward-line 1) (point))) |
| 1109 | (run-hooks 'dired-after-readin-hook)))) |
| 1110 | (dired-move-to-filename)) |
| 1111 | ;; return nil if all went well |
| 1112 | nil)) |
| 1113 | (if reason ; don't move away on failure |
| 1114 | (goto-char opoint)) |
| 1115 | (not reason))) ; return t on success, nil else |
| 1116 | |
| 1117 | (defun dired-after-subdir-garbage (dir) |
| 1118 | ;; Return pos of first file line of DIR, skipping header and total |
| 1119 | ;; or wildcard lines. |
| 1120 | ;; Important: never moves into the next subdir. |
| 1121 | ;; DIR is assumed to be unhidden. |
| 1122 | (save-excursion |
| 1123 | (or (dired-goto-subdir dir) (error "This cannot happen")) |
| 1124 | (forward-line 1) |
| 1125 | (while (and (not (eolp)) ; don't cross subdir boundary |
| 1126 | (not (dired-move-to-filename))) |
| 1127 | (forward-line 1)) |
| 1128 | (point))) |
| 1129 | |
| 1130 | ;;;###autoload |
| 1131 | (defun dired-remove-file (file) |
| 1132 | (dired-fun-in-all-buffers |
| 1133 | (file-name-directory file) (file-name-nondirectory file) |
| 1134 | (function dired-remove-entry) file)) |
| 1135 | |
| 1136 | (defun dired-remove-entry (file) |
| 1137 | (save-excursion |
| 1138 | (and (dired-goto-file file) |
| 1139 | (let (buffer-read-only) |
| 1140 | (delete-region (progn (beginning-of-line) (point)) |
| 1141 | (save-excursion (forward-line 1) (point))))))) |
| 1142 | |
| 1143 | ;;;###autoload |
| 1144 | (defun dired-relist-file (file) |
| 1145 | "Create or update the line for FILE in all Dired buffers it would belong in." |
| 1146 | (dired-fun-in-all-buffers (file-name-directory file) |
| 1147 | (file-name-nondirectory file) |
| 1148 | (function dired-relist-entry) file)) |
| 1149 | |
| 1150 | (defun dired-relist-entry (file) |
| 1151 | ;; Relist the line for FILE, or just add it if it did not exist. |
| 1152 | ;; FILE must be an absolute file name. |
| 1153 | (let (buffer-read-only marker) |
| 1154 | ;; If cursor is already on FILE's line delete-region will cause |
| 1155 | ;; save-excursion to fail because of floating makers, |
| 1156 | ;; moving point to beginning of line. Sigh. |
| 1157 | (save-excursion |
| 1158 | (and (dired-goto-file file) |
| 1159 | (delete-region (progn (beginning-of-line) |
| 1160 | (setq marker (following-char)) |
| 1161 | (point)) |
| 1162 | (save-excursion (forward-line 1) (point)))) |
| 1163 | (setq file (directory-file-name file)) |
| 1164 | (dired-add-entry file (if (eq ?\040 marker) nil marker))))) |
| 1165 | \f |
| 1166 | ;;; Copy, move/rename, making hard and symbolic links |
| 1167 | |
| 1168 | (defcustom dired-backup-overwrite nil |
| 1169 | "Non-nil if Dired should ask about making backups before overwriting files. |
| 1170 | Special value `always' suppresses confirmation." |
| 1171 | :type '(choice (const :tag "off" nil) |
| 1172 | (const :tag "suppress" always) |
| 1173 | (other :tag "ask" t)) |
| 1174 | :group 'dired) |
| 1175 | |
| 1176 | ;; This is a fluid var used in dired-handle-overwrite. It should be |
| 1177 | ;; let-bound whenever dired-copy-file etc are called. See |
| 1178 | ;; dired-create-files for an example. |
| 1179 | (defvar dired-overwrite-confirmed) |
| 1180 | |
| 1181 | (defun dired-handle-overwrite (to) |
| 1182 | ;; Save old version of file TO that is to be overwritten. |
| 1183 | ;; `dired-overwrite-confirmed' and `overwrite-backup-query' are fluid vars |
| 1184 | ;; from dired-create-files. |
| 1185 | (let (backup) |
| 1186 | (when (and dired-backup-overwrite |
| 1187 | dired-overwrite-confirmed |
| 1188 | (setq backup (car (find-backup-file-name to))) |
| 1189 | (or (eq 'always dired-backup-overwrite) |
| 1190 | (dired-query 'overwrite-backup-query |
| 1191 | "Make backup for existing file `%s'? " |
| 1192 | to))) |
| 1193 | (rename-file to backup 0) ; confirm overwrite of old backup |
| 1194 | (dired-relist-entry backup)))) |
| 1195 | |
| 1196 | ;;;###autoload |
| 1197 | (defun dired-copy-file (from to ok-flag) |
| 1198 | (dired-handle-overwrite to) |
| 1199 | (dired-copy-file-recursive from to ok-flag dired-copy-preserve-time t |
| 1200 | dired-recursive-copies)) |
| 1201 | |
| 1202 | (declare-function make-symbolic-link "fileio.c") |
| 1203 | |
| 1204 | (defun dired-copy-file-recursive (from to ok-flag &optional |
| 1205 | preserve-time top recursive) |
| 1206 | (let ((attrs (file-attributes from)) |
| 1207 | dirfailed) |
| 1208 | (if (and recursive |
| 1209 | (eq t (car attrs)) |
| 1210 | (or (eq recursive 'always) |
| 1211 | (yes-or-no-p (format "Recursive copies of %s? " from)))) |
| 1212 | ;; This is a directory. |
| 1213 | (let ((mode (file-modes from)) |
| 1214 | (files |
| 1215 | (condition-case err |
| 1216 | (directory-files from nil dired-re-no-dot) |
| 1217 | (file-error |
| 1218 | (push (dired-make-relative from) |
| 1219 | dired-create-files-failures) |
| 1220 | (dired-log "Copying error for %s:\n%s\n" from err) |
| 1221 | (setq dirfailed t) |
| 1222 | nil)))) |
| 1223 | (if (eq recursive 'top) (setq recursive 'always)) ; Don't ask any more. |
| 1224 | (unless dirfailed |
| 1225 | (if (file-exists-p to) |
| 1226 | (or top (dired-handle-overwrite to)) |
| 1227 | (condition-case err |
| 1228 | ;; We used to call set-file-modes here, but on some |
| 1229 | ;; Linux kernels, that returns an error on vfat |
| 1230 | ;; filesystems |
| 1231 | (let ((default-mode (default-file-modes))) |
| 1232 | (unwind-protect |
| 1233 | (progn |
| 1234 | (set-default-file-modes #o700) |
| 1235 | (make-directory to)) |
| 1236 | (set-default-file-modes default-mode))) |
| 1237 | (file-error |
| 1238 | (push (dired-make-relative from) |
| 1239 | dired-create-files-failures) |
| 1240 | (setq files nil) |
| 1241 | (dired-log "Copying error for %s:\n%s\n" from err))))) |
| 1242 | (dolist (file files) |
| 1243 | (let ((thisfrom (expand-file-name file from)) |
| 1244 | (thisto (expand-file-name file to))) |
| 1245 | ;; Catch errors copying within a directory, |
| 1246 | ;; and report them through the dired log mechanism |
| 1247 | ;; just as our caller will do for the top level files. |
| 1248 | (condition-case err |
| 1249 | (dired-copy-file-recursive |
| 1250 | thisfrom thisto |
| 1251 | ok-flag preserve-time nil recursive) |
| 1252 | (file-error |
| 1253 | (push (dired-make-relative thisfrom) |
| 1254 | dired-create-files-failures) |
| 1255 | (dired-log "Copying error for %s:\n%s\n" thisfrom err))))) |
| 1256 | (when (file-directory-p to) |
| 1257 | (set-file-modes to mode))) |
| 1258 | ;; Not a directory. |
| 1259 | (or top (dired-handle-overwrite to)) |
| 1260 | (condition-case err |
| 1261 | (if (stringp (car attrs)) |
| 1262 | ;; It is a symlink |
| 1263 | (make-symbolic-link (car attrs) to ok-flag) |
| 1264 | (copy-file from to ok-flag dired-copy-preserve-time)) |
| 1265 | (file-date-error |
| 1266 | (push (dired-make-relative from) |
| 1267 | dired-create-files-failures) |
| 1268 | (dired-log "Can't set date on %s:\n%s\n" from err)))))) |
| 1269 | |
| 1270 | ;;;###autoload |
| 1271 | (defun dired-rename-file (file newname ok-if-already-exists) |
| 1272 | (dired-handle-overwrite newname) |
| 1273 | (rename-file file newname ok-if-already-exists) ; error is caught in -create-files |
| 1274 | ;; Silently rename the visited file of any buffer visiting this file. |
| 1275 | (and (get-file-buffer file) |
| 1276 | (with-current-buffer (get-file-buffer file) |
| 1277 | (set-visited-file-name newname nil t))) |
| 1278 | (dired-remove-file file) |
| 1279 | ;; See if it's an inserted subdir, and rename that, too. |
| 1280 | (dired-rename-subdir file newname)) |
| 1281 | |
| 1282 | (defun dired-rename-subdir (from-dir to-dir) |
| 1283 | (setq from-dir (file-name-as-directory from-dir) |
| 1284 | to-dir (file-name-as-directory to-dir)) |
| 1285 | (dired-fun-in-all-buffers from-dir nil |
| 1286 | (function dired-rename-subdir-1) from-dir to-dir) |
| 1287 | ;; Update visited file name of all affected buffers |
| 1288 | (let ((expanded-from-dir (expand-file-name from-dir)) |
| 1289 | (blist (buffer-list))) |
| 1290 | (while blist |
| 1291 | (save-excursion |
| 1292 | (set-buffer (car blist)) |
| 1293 | (if (and buffer-file-name |
| 1294 | (dired-in-this-tree buffer-file-name expanded-from-dir)) |
| 1295 | (let ((modflag (buffer-modified-p)) |
| 1296 | (to-file (dired-replace-in-string |
| 1297 | (concat "^" (regexp-quote from-dir)) |
| 1298 | to-dir |
| 1299 | buffer-file-name))) |
| 1300 | (set-visited-file-name to-file) |
| 1301 | (set-buffer-modified-p modflag)))) |
| 1302 | (setq blist (cdr blist))))) |
| 1303 | |
| 1304 | (defun dired-rename-subdir-1 (dir to) |
| 1305 | ;; Rename DIR to TO in headerlines and dired-subdir-alist, if DIR or |
| 1306 | ;; one of its subdirectories is expanded in this buffer. |
| 1307 | (let ((expanded-dir (expand-file-name dir)) |
| 1308 | (alist dired-subdir-alist) |
| 1309 | (elt nil)) |
| 1310 | (while alist |
| 1311 | (setq elt (car alist) |
| 1312 | alist (cdr alist)) |
| 1313 | (if (dired-in-this-tree (car elt) expanded-dir) |
| 1314 | ;; ELT's subdir is affected by the rename |
| 1315 | (dired-rename-subdir-2 elt dir to))) |
| 1316 | (if (equal dir default-directory) |
| 1317 | ;; if top level directory was renamed, lots of things have to be |
| 1318 | ;; updated: |
| 1319 | (progn |
| 1320 | (dired-unadvertise dir) ; we no longer dired DIR... |
| 1321 | (setq default-directory to |
| 1322 | dired-directory (expand-file-name;; this is correct |
| 1323 | ;; with and without wildcards |
| 1324 | (file-name-nondirectory dired-directory) |
| 1325 | to)) |
| 1326 | (let ((new-name (file-name-nondirectory |
| 1327 | (directory-file-name dired-directory)))) |
| 1328 | ;; try to rename buffer, but just leave old name if new |
| 1329 | ;; name would already exist (don't try appending "<%d>") |
| 1330 | (or (get-buffer new-name) |
| 1331 | (rename-buffer new-name))) |
| 1332 | ;; ... we dired TO now: |
| 1333 | (dired-advertise))))) |
| 1334 | |
| 1335 | (defun dired-rename-subdir-2 (elt dir to) |
| 1336 | ;; Update the headerline and dired-subdir-alist element, as well as |
| 1337 | ;; dired-switches-alist element, of directory described by |
| 1338 | ;; alist-element ELT to reflect the moving of DIR to TO. Thus, ELT |
| 1339 | ;; describes either DIR itself or a subdir of DIR. |
| 1340 | (save-excursion |
| 1341 | (let ((regexp (regexp-quote (directory-file-name dir))) |
| 1342 | (newtext (directory-file-name to)) |
| 1343 | buffer-read-only) |
| 1344 | (goto-char (dired-get-subdir-min elt)) |
| 1345 | ;; Update subdir headerline in buffer |
| 1346 | (if (not (looking-at dired-subdir-regexp)) |
| 1347 | (error "%s not found where expected - dired-subdir-alist broken?" |
| 1348 | dir) |
| 1349 | (goto-char (match-beginning 1)) |
| 1350 | (if (re-search-forward regexp (match-end 1) t) |
| 1351 | (replace-match newtext t t) |
| 1352 | (error "Expected to find `%s' in headerline of %s" dir (car elt)))) |
| 1353 | ;; Update buffer-local dired-subdir-alist and dired-switches-alist |
| 1354 | (let ((cons (assoc-string (car elt) dired-switches-alist)) |
| 1355 | (cur-dir (dired-normalize-subdir |
| 1356 | (dired-replace-in-string regexp newtext (car elt))))) |
| 1357 | (setcar elt cur-dir) |
| 1358 | (when cons (setcar cons cur-dir)))))) |
| 1359 | \f |
| 1360 | ;; The basic function for half a dozen variations on cp/mv/ln/ln -s. |
| 1361 | (defun dired-create-files (file-creator operation fn-list name-constructor |
| 1362 | &optional marker-char) |
| 1363 | |
| 1364 | ;; Create a new file for each from a list of existing files. The user |
| 1365 | ;; is queried, dired buffers are updated, and at the end a success or |
| 1366 | ;; failure message is displayed |
| 1367 | |
| 1368 | ;; FILE-CREATOR must accept three args: oldfile newfile ok-if-already-exists |
| 1369 | |
| 1370 | ;; It is called for each file and must create newfile, the entry of |
| 1371 | ;; which will be added. The user will be queried if the file already |
| 1372 | ;; exists. If oldfile is removed by FILE-CREATOR (i.e, it is a |
| 1373 | ;; rename), it is FILE-CREATOR's responsibility to update dired |
| 1374 | ;; buffers. FILE-CREATOR must abort by signaling a file-error if it |
| 1375 | ;; could not create newfile. The error is caught and logged. |
| 1376 | |
| 1377 | ;; OPERATION (a capitalized string, e.g. `Copy') describes the |
| 1378 | ;; operation performed. It is used for error logging. |
| 1379 | |
| 1380 | ;; FN-LIST is the list of files to copy (full absolute file names). |
| 1381 | |
| 1382 | ;; NAME-CONSTRUCTOR returns a newfile for every oldfile, or nil to |
| 1383 | ;; skip. If it skips files for other reasons than a direct user |
| 1384 | ;; query, it is supposed to tell why (using dired-log). |
| 1385 | |
| 1386 | ;; Optional MARKER-CHAR is a character with which to mark every |
| 1387 | ;; newfile's entry, or t to use the current marker character if the |
| 1388 | ;; oldfile was marked. |
| 1389 | |
| 1390 | (let (dired-create-files-failures failures |
| 1391 | skipped (success-count 0) (total (length fn-list))) |
| 1392 | (let (to overwrite-query |
| 1393 | overwrite-backup-query) ; for dired-handle-overwrite |
| 1394 | (dolist (from fn-list) |
| 1395 | (setq to (funcall name-constructor from)) |
| 1396 | (if (equal to from) |
| 1397 | (progn |
| 1398 | (setq to nil) |
| 1399 | (dired-log "Cannot %s to same file: %s\n" |
| 1400 | (downcase operation) from))) |
| 1401 | (if (not to) |
| 1402 | (setq skipped (cons (dired-make-relative from) skipped)) |
| 1403 | (let* ((overwrite (file-exists-p to)) |
| 1404 | (dired-overwrite-confirmed ; for dired-handle-overwrite |
| 1405 | (and overwrite |
| 1406 | (let ((help-form '(format "\ |
| 1407 | Type SPC or `y' to overwrite file `%s', |
| 1408 | DEL or `n' to skip to next, |
| 1409 | ESC or `q' to not overwrite any of the remaining files, |
| 1410 | `!' to overwrite all remaining files with no more questions." to))) |
| 1411 | (dired-query 'overwrite-query |
| 1412 | "Overwrite `%s'?" to)))) |
| 1413 | ;; must determine if FROM is marked before file-creator |
| 1414 | ;; gets a chance to delete it (in case of a move). |
| 1415 | (actual-marker-char |
| 1416 | (cond ((integerp marker-char) marker-char) |
| 1417 | (marker-char (dired-file-marker from)) ; slow |
| 1418 | (t nil)))) |
| 1419 | (condition-case err |
| 1420 | (progn |
| 1421 | (funcall file-creator from to dired-overwrite-confirmed) |
| 1422 | (if overwrite |
| 1423 | ;; If we get here, file-creator hasn't been aborted |
| 1424 | ;; and the old entry (if any) has to be deleted |
| 1425 | ;; before adding the new entry. |
| 1426 | (dired-remove-file to)) |
| 1427 | (setq success-count (1+ success-count)) |
| 1428 | (message "%s: %d of %d" operation success-count total) |
| 1429 | (dired-add-file to actual-marker-char)) |
| 1430 | (file-error ; FILE-CREATOR aborted |
| 1431 | (progn |
| 1432 | (push (dired-make-relative from) |
| 1433 | failures) |
| 1434 | (dired-log "%s `%s' to `%s' failed:\n%s\n" |
| 1435 | operation from to err)))))))) |
| 1436 | (cond |
| 1437 | (dired-create-files-failures |
| 1438 | (setq failures (nconc failures dired-create-files-failures)) |
| 1439 | (dired-log-summary |
| 1440 | (format "%s failed for %d file%s in %d requests" |
| 1441 | operation (length failures) |
| 1442 | (dired-plural-s (length failures)) |
| 1443 | total) |
| 1444 | failures)) |
| 1445 | (failures |
| 1446 | (dired-log-summary |
| 1447 | (format "%s failed for %d of %d file%s" |
| 1448 | operation (length failures) |
| 1449 | total (dired-plural-s total)) |
| 1450 | failures)) |
| 1451 | (skipped |
| 1452 | (dired-log-summary |
| 1453 | (format "%s: %d of %d file%s skipped" |
| 1454 | operation (length skipped) total |
| 1455 | (dired-plural-s total)) |
| 1456 | skipped)) |
| 1457 | (t |
| 1458 | (message "%s: %s file%s" |
| 1459 | operation success-count (dired-plural-s success-count))))) |
| 1460 | (dired-move-to-filename)) |
| 1461 | \f |
| 1462 | (defun dired-do-create-files (op-symbol file-creator operation arg |
| 1463 | &optional marker-char op1 |
| 1464 | how-to) |
| 1465 | "Create a new file for each marked file. |
| 1466 | Prompts user for target, which is a directory in which to create |
| 1467 | the new files. Target may also be a plain file if only one marked |
| 1468 | file exists. The way the default for the target directory is |
| 1469 | computed depends on the value of `dired-dwim-target-directory'. |
| 1470 | OP-SYMBOL is the symbol for the operation. Function `dired-mark-pop-up' |
| 1471 | will determine whether pop-ups are appropriate for this OP-SYMBOL. |
| 1472 | FILE-CREATOR and OPERATION as in `dired-create-files'. |
| 1473 | ARG as in `dired-get-marked-files'. |
| 1474 | Optional arg MARKER-CHAR as in `dired-create-files'. |
| 1475 | Optional arg OP1 is an alternate form for OPERATION if there is |
| 1476 | only one file. |
| 1477 | Optional arg HOW-TO determiness how to treat the target. |
| 1478 | If HOW-TO is nil, use `file-directory-p' to determine if the |
| 1479 | target is a directory. If so, the marked file(s) are created |
| 1480 | inside that directory. Otherwise, the target is a plain file; |
| 1481 | an error is raised unless there is exactly one marked file. |
| 1482 | If HOW-TO is t, target is always treated as a plain file. |
| 1483 | Otherwise, HOW-TO should be a function of one argument, TARGET. |
| 1484 | If its return value is nil, TARGET is regarded as a plain file. |
| 1485 | If it return value is a list, TARGET is a generalized |
| 1486 | directory (e.g. some sort of archive). The first element of |
| 1487 | this list must be a function with at least four arguments: |
| 1488 | operation - as OPERATION above. |
| 1489 | rfn-list - list of the relative names for the marked files. |
| 1490 | fn-list - list of the absolute names for the marked files. |
| 1491 | target - the name of the target itself. |
| 1492 | The rest of into-dir are optional arguments. |
| 1493 | For any other return value, TARGET is treated as a directory." |
| 1494 | (or op1 (setq op1 operation)) |
| 1495 | (let* ((fn-list (dired-get-marked-files nil arg)) |
| 1496 | (rfn-list (mapcar (function dired-make-relative) fn-list)) |
| 1497 | (dired-one-file ; fluid variable inside dired-create-files |
| 1498 | (and (consp fn-list) (null (cdr fn-list)) (car fn-list))) |
| 1499 | (target-dir (dired-dwim-target-directory)) |
| 1500 | (default (and dired-one-file |
| 1501 | (expand-file-name (file-name-nondirectory (car fn-list)) |
| 1502 | target-dir))) |
| 1503 | (target (expand-file-name ; fluid variable inside dired-create-files |
| 1504 | (dired-mark-read-file-name |
| 1505 | (concat (if dired-one-file op1 operation) " %s to: ") |
| 1506 | target-dir op-symbol arg rfn-list default))) |
| 1507 | (into-dir (cond ((null how-to) |
| 1508 | ;; Allow DOS/Windows users to change the letter |
| 1509 | ;; case of a directory. If we don't test these |
| 1510 | ;; conditions up front, file-directory-p below |
| 1511 | ;; will return t because the filesystem is |
| 1512 | ;; case-insensitive, and Emacs will try to move |
| 1513 | ;; foo -> foo/foo, which fails. |
| 1514 | (if (and (memq system-type '(ms-dos windows-nt cygwin)) |
| 1515 | (eq op-symbol 'move) |
| 1516 | dired-one-file |
| 1517 | (string= (downcase |
| 1518 | (expand-file-name (car fn-list))) |
| 1519 | (downcase |
| 1520 | (expand-file-name target))) |
| 1521 | (not (string= |
| 1522 | (file-name-nondirectory (car fn-list)) |
| 1523 | (file-name-nondirectory target)))) |
| 1524 | nil |
| 1525 | (file-directory-p target))) |
| 1526 | ((eq how-to t) nil) |
| 1527 | (t (funcall how-to target))))) |
| 1528 | (if (and (consp into-dir) (functionp (car into-dir))) |
| 1529 | (apply (car into-dir) operation rfn-list fn-list target (cdr into-dir)) |
| 1530 | (if (not (or dired-one-file into-dir)) |
| 1531 | (error "Marked %s: target must be a directory: %s" operation target)) |
| 1532 | ;; rename-file bombs when moving directories unless we do this: |
| 1533 | (or into-dir (setq target (directory-file-name target))) |
| 1534 | (dired-create-files |
| 1535 | file-creator operation fn-list |
| 1536 | (if into-dir ; target is a directory |
| 1537 | ;; This function uses fluid variable target when called |
| 1538 | ;; inside dired-create-files: |
| 1539 | (function |
| 1540 | (lambda (from) |
| 1541 | (expand-file-name (file-name-nondirectory from) target))) |
| 1542 | (function (lambda (from) target))) |
| 1543 | marker-char)))) |
| 1544 | |
| 1545 | ;; Read arguments for a marked-files command that wants a file name, |
| 1546 | ;; perhaps popping up the list of marked files. |
| 1547 | ;; ARG is the prefix arg and indicates whether the files came from |
| 1548 | ;; marks (ARG=nil) or a repeat factor (integerp ARG). |
| 1549 | ;; If the current file was used, the list has but one element and ARG |
| 1550 | ;; does not matter. (It is non-nil, non-integer in that case, namely '(4)). |
| 1551 | ;; DEFAULT is the default value to return if the user just hits RET; |
| 1552 | ;; if it is omitted or nil, then the name of the directory is used. |
| 1553 | |
| 1554 | (defun dired-mark-read-file-name (prompt dir op-symbol arg files |
| 1555 | &optional default) |
| 1556 | (dired-mark-pop-up |
| 1557 | nil op-symbol files |
| 1558 | (function read-file-name) |
| 1559 | (format prompt (dired-mark-prompt arg files)) dir default)) |
| 1560 | |
| 1561 | (defun dired-dwim-target-directory () |
| 1562 | ;; Try to guess which target directory the user may want. |
| 1563 | ;; If there is a dired buffer displayed in the next window, use |
| 1564 | ;; its current subdir, else use current subdir of this dired buffer. |
| 1565 | (let ((this-dir (and (eq major-mode 'dired-mode) |
| 1566 | (dired-current-directory)))) |
| 1567 | ;; non-dired buffer may want to profit from this function, e.g. vm-uudecode |
| 1568 | (if dired-dwim-target |
| 1569 | (let* ((other-buf (window-buffer (next-window))) |
| 1570 | (other-dir (save-excursion |
| 1571 | (set-buffer other-buf) |
| 1572 | (and (eq major-mode 'dired-mode) |
| 1573 | (dired-current-directory))))) |
| 1574 | (or other-dir this-dir)) |
| 1575 | this-dir))) |
| 1576 | \f |
| 1577 | ;;;###autoload |
| 1578 | (defun dired-create-directory (directory) |
| 1579 | "Create a directory called DIRECTORY." |
| 1580 | (interactive |
| 1581 | (list (read-file-name "Create directory: " (dired-current-directory)))) |
| 1582 | (let* ((expanded (directory-file-name (expand-file-name directory))) |
| 1583 | (try expanded) new) |
| 1584 | ;; Find the topmost nonexistent parent dir (variable `new') |
| 1585 | (while (and try (not (file-exists-p try)) (not (equal new try))) |
| 1586 | (setq new try |
| 1587 | try (directory-file-name (file-name-directory try)))) |
| 1588 | (make-directory expanded t) |
| 1589 | (when new |
| 1590 | (dired-add-file new) |
| 1591 | (dired-move-to-filename)))) |
| 1592 | |
| 1593 | (defun dired-into-dir-with-symlinks (target) |
| 1594 | (and (file-directory-p target) |
| 1595 | (not (file-symlink-p target)))) |
| 1596 | ;; This may not always be what you want, especially if target is your |
| 1597 | ;; home directory and it happens to be a symbolic link, as is often the |
| 1598 | ;; case with NFS and automounters. Or if you want to make symlinks |
| 1599 | ;; into directories that themselves are only symlinks, also quite |
| 1600 | ;; common. |
| 1601 | |
| 1602 | ;; So we don't use this function as value for HOW-TO in |
| 1603 | ;; dired-do-symlink, which has the minor disadvantage of |
| 1604 | ;; making links *into* a symlinked-dir, when you really wanted to |
| 1605 | ;; *overwrite* that symlink. In that (rare, I guess) case, you'll |
| 1606 | ;; just have to remove that symlink by hand before making your marked |
| 1607 | ;; symlinks. |
| 1608 | |
| 1609 | (defvar dired-copy-how-to-fn nil |
| 1610 | "nil or a function used by `dired-do-copy' to determine target. |
| 1611 | See HOW-TO argument for `dired-do-create-files'.") |
| 1612 | |
| 1613 | ;;;###autoload |
| 1614 | (defun dired-do-copy (&optional arg) |
| 1615 | "Copy all marked (or next ARG) files, or copy the current file. |
| 1616 | This normally preserves the last-modified date when copying. |
| 1617 | When operating on just the current file, you specify the new name. |
| 1618 | When operating on multiple or marked files, you specify a directory, |
| 1619 | and new copies of these files are made in that directory |
| 1620 | with the same names that the files currently have. The default |
| 1621 | suggested for the target directory depends on the value of |
| 1622 | `dired-dwim-target', which see. |
| 1623 | |
| 1624 | This command copies symbolic links by creating new ones, |
| 1625 | like `cp -d'." |
| 1626 | (interactive "P") |
| 1627 | (let ((dired-recursive-copies dired-recursive-copies)) |
| 1628 | (dired-do-create-files 'copy (function dired-copy-file) |
| 1629 | "Copy" |
| 1630 | arg dired-keep-marker-copy |
| 1631 | nil dired-copy-how-to-fn))) |
| 1632 | |
| 1633 | ;;;###autoload |
| 1634 | (defun dired-do-symlink (&optional arg) |
| 1635 | "Make symbolic links to current file or all marked (or next ARG) files. |
| 1636 | When operating on just the current file, you specify the new name. |
| 1637 | When operating on multiple or marked files, you specify a directory |
| 1638 | and new symbolic links are made in that directory |
| 1639 | with the same names that the files currently have. The default |
| 1640 | suggested for the target directory depends on the value of |
| 1641 | `dired-dwim-target', which see. |
| 1642 | |
| 1643 | For relative symlinks, use \\[dired-do-relsymlink]." |
| 1644 | (interactive "P") |
| 1645 | (dired-do-create-files 'symlink (function make-symbolic-link) |
| 1646 | "Symlink" arg dired-keep-marker-symlink)) |
| 1647 | |
| 1648 | ;;;###autoload |
| 1649 | (defun dired-do-hardlink (&optional arg) |
| 1650 | "Add names (hard links) current file or all marked (or next ARG) files. |
| 1651 | When operating on just the current file, you specify the new name. |
| 1652 | When operating on multiple or marked files, you specify a directory |
| 1653 | and new hard links are made in that directory |
| 1654 | with the same names that the files currently have. The default |
| 1655 | suggested for the target directory depends on the value of |
| 1656 | `dired-dwim-target', which see." |
| 1657 | (interactive "P") |
| 1658 | (dired-do-create-files 'hardlink (function dired-hardlink) |
| 1659 | "Hardlink" arg dired-keep-marker-hardlink)) |
| 1660 | |
| 1661 | (defun dired-hardlink (file newname &optional ok-if-already-exists) |
| 1662 | (dired-handle-overwrite newname) |
| 1663 | ;; error is caught in -create-files |
| 1664 | (add-name-to-file file newname ok-if-already-exists) |
| 1665 | ;; Update the link count |
| 1666 | (dired-relist-file file)) |
| 1667 | |
| 1668 | ;;;###autoload |
| 1669 | (defun dired-do-rename (&optional arg) |
| 1670 | "Rename current file or all marked (or next ARG) files. |
| 1671 | When renaming just the current file, you specify the new name. |
| 1672 | When renaming multiple or marked files, you specify a directory. |
| 1673 | This command also renames any buffers that are visiting the files. |
| 1674 | The default suggested for the target directory depends on the value |
| 1675 | of `dired-dwim-target', which see." |
| 1676 | (interactive "P") |
| 1677 | (dired-do-create-files 'move (function dired-rename-file) |
| 1678 | "Move" arg dired-keep-marker-rename "Rename")) |
| 1679 | ;;;###end dired-cp.el |
| 1680 | \f |
| 1681 | ;;; 5K |
| 1682 | ;;;###begin dired-re.el |
| 1683 | (defun dired-do-create-files-regexp |
| 1684 | (file-creator operation arg regexp newname &optional whole-name marker-char) |
| 1685 | ;; Create a new file for each marked file using regexps. |
| 1686 | ;; FILE-CREATOR and OPERATION as in dired-create-files. |
| 1687 | ;; ARG as in dired-get-marked-files. |
| 1688 | ;; Matches each marked file against REGEXP and constructs the new |
| 1689 | ;; filename from NEWNAME (like in function replace-match). |
| 1690 | ;; Optional arg WHOLE-NAME means match/replace the whole file name |
| 1691 | ;; instead of only the non-directory part of the file. |
| 1692 | ;; Optional arg MARKER-CHAR as in dired-create-files. |
| 1693 | (let* ((fn-list (dired-get-marked-files nil arg)) |
| 1694 | (fn-count (length fn-list)) |
| 1695 | (operation-prompt (concat operation " `%s' to `%s'?")) |
| 1696 | (rename-regexp-help-form (format "\ |
| 1697 | Type SPC or `y' to %s one match, DEL or `n' to skip to next, |
| 1698 | `!' to %s all remaining matches with no more questions." |
| 1699 | (downcase operation) |
| 1700 | (downcase operation))) |
| 1701 | (regexp-name-constructor |
| 1702 | ;; Function to construct new filename using REGEXP and NEWNAME: |
| 1703 | (if whole-name ; easy (but rare) case |
| 1704 | (function |
| 1705 | (lambda (from) |
| 1706 | (let ((to (dired-string-replace-match regexp from newname)) |
| 1707 | ;; must bind help-form directly around call to |
| 1708 | ;; dired-query |
| 1709 | (help-form rename-regexp-help-form)) |
| 1710 | (if to |
| 1711 | (and (dired-query 'rename-regexp-query |
| 1712 | operation-prompt |
| 1713 | from |
| 1714 | to) |
| 1715 | to) |
| 1716 | (dired-log "%s: %s did not match regexp %s\n" |
| 1717 | operation from regexp))))) |
| 1718 | ;; not whole-name, replace non-directory part only |
| 1719 | (function |
| 1720 | (lambda (from) |
| 1721 | (let* ((new (dired-string-replace-match |
| 1722 | regexp (file-name-nondirectory from) newname)) |
| 1723 | (to (and new ; nil means there was no match |
| 1724 | (expand-file-name new |
| 1725 | (file-name-directory from)))) |
| 1726 | (help-form rename-regexp-help-form)) |
| 1727 | (if to |
| 1728 | (and (dired-query 'rename-regexp-query |
| 1729 | operation-prompt |
| 1730 | (dired-make-relative from) |
| 1731 | (dired-make-relative to)) |
| 1732 | to) |
| 1733 | (dired-log "%s: %s did not match regexp %s\n" |
| 1734 | operation (file-name-nondirectory from) regexp))))))) |
| 1735 | rename-regexp-query) |
| 1736 | (dired-create-files |
| 1737 | file-creator operation fn-list regexp-name-constructor marker-char))) |
| 1738 | |
| 1739 | (defun dired-mark-read-regexp (operation) |
| 1740 | ;; Prompt user about performing OPERATION. |
| 1741 | ;; Read and return list of: regexp newname arg whole-name. |
| 1742 | (let* ((whole-name |
| 1743 | (equal 0 (prefix-numeric-value current-prefix-arg))) |
| 1744 | (arg |
| 1745 | (if whole-name nil current-prefix-arg)) |
| 1746 | (regexp |
| 1747 | (dired-read-regexp |
| 1748 | (concat (if whole-name "Abs. " "") operation " from (regexp): "))) |
| 1749 | (newname |
| 1750 | (read-string |
| 1751 | (concat (if whole-name "Abs. " "") operation " " regexp " to: ")))) |
| 1752 | (list regexp newname arg whole-name))) |
| 1753 | |
| 1754 | ;;;###autoload |
| 1755 | (defun dired-do-rename-regexp (regexp newname &optional arg whole-name) |
| 1756 | "Rename selected files whose names match REGEXP to NEWNAME. |
| 1757 | |
| 1758 | With non-zero prefix argument ARG, the command operates on the next ARG |
| 1759 | files. Otherwise, it operates on all the marked files, or the current |
| 1760 | file if none are marked. |
| 1761 | |
| 1762 | As each match is found, the user must type a character saying |
| 1763 | what to do with it. For directions, type \\[help-command] at that time. |
| 1764 | NEWNAME may contain \\=\\<n> or \\& as in `query-replace-regexp'. |
| 1765 | REGEXP defaults to the last regexp used. |
| 1766 | |
| 1767 | With a zero prefix arg, renaming by regexp affects the absolute file name. |
| 1768 | Normally, only the non-directory part of the file name is used and changed." |
| 1769 | (interactive (dired-mark-read-regexp "Rename")) |
| 1770 | (dired-do-create-files-regexp |
| 1771 | (function dired-rename-file) |
| 1772 | "Rename" arg regexp newname whole-name dired-keep-marker-rename)) |
| 1773 | |
| 1774 | ;;;###autoload |
| 1775 | (defun dired-do-copy-regexp (regexp newname &optional arg whole-name) |
| 1776 | "Copy selected files whose names match REGEXP to NEWNAME. |
| 1777 | See function `dired-do-rename-regexp' for more info." |
| 1778 | (interactive (dired-mark-read-regexp "Copy")) |
| 1779 | (let ((dired-recursive-copies nil)) ; No recursive copies. |
| 1780 | (dired-do-create-files-regexp |
| 1781 | (function dired-copy-file) |
| 1782 | (if dired-copy-preserve-time "Copy [-p]" "Copy") |
| 1783 | arg regexp newname whole-name dired-keep-marker-copy))) |
| 1784 | |
| 1785 | ;;;###autoload |
| 1786 | (defun dired-do-hardlink-regexp (regexp newname &optional arg whole-name) |
| 1787 | "Hardlink selected files whose names match REGEXP to NEWNAME. |
| 1788 | See function `dired-do-rename-regexp' for more info." |
| 1789 | (interactive (dired-mark-read-regexp "HardLink")) |
| 1790 | (dired-do-create-files-regexp |
| 1791 | (function add-name-to-file) |
| 1792 | "HardLink" arg regexp newname whole-name dired-keep-marker-hardlink)) |
| 1793 | |
| 1794 | ;;;###autoload |
| 1795 | (defun dired-do-symlink-regexp (regexp newname &optional arg whole-name) |
| 1796 | "Symlink selected files whose names match REGEXP to NEWNAME. |
| 1797 | See function `dired-do-rename-regexp' for more info." |
| 1798 | (interactive (dired-mark-read-regexp "SymLink")) |
| 1799 | (dired-do-create-files-regexp |
| 1800 | (function make-symbolic-link) |
| 1801 | "SymLink" arg regexp newname whole-name dired-keep-marker-symlink)) |
| 1802 | |
| 1803 | (defun dired-create-files-non-directory |
| 1804 | (file-creator basename-constructor operation arg) |
| 1805 | ;; Perform FILE-CREATOR on the non-directory part of marked files |
| 1806 | ;; using function BASENAME-CONSTRUCTOR, with query for each file. |
| 1807 | ;; OPERATION like in dired-create-files, ARG as in dired-get-marked-files. |
| 1808 | (let (rename-non-directory-query) |
| 1809 | (dired-create-files |
| 1810 | file-creator |
| 1811 | operation |
| 1812 | (dired-get-marked-files nil arg) |
| 1813 | (function |
| 1814 | (lambda (from) |
| 1815 | (let ((to (concat (file-name-directory from) |
| 1816 | (funcall basename-constructor |
| 1817 | (file-name-nondirectory from))))) |
| 1818 | (and (let ((help-form (format "\ |
| 1819 | Type SPC or `y' to %s one file, DEL or `n' to skip to next, |
| 1820 | `!' to %s all remaining matches with no more questions." |
| 1821 | (downcase operation) |
| 1822 | (downcase operation)))) |
| 1823 | (dired-query 'rename-non-directory-query |
| 1824 | (concat operation " `%s' to `%s'") |
| 1825 | (dired-make-relative from) |
| 1826 | (dired-make-relative to))) |
| 1827 | to)))) |
| 1828 | dired-keep-marker-rename))) |
| 1829 | |
| 1830 | (defun dired-rename-non-directory (basename-constructor operation arg) |
| 1831 | (dired-create-files-non-directory |
| 1832 | (function dired-rename-file) |
| 1833 | basename-constructor operation arg)) |
| 1834 | |
| 1835 | ;;;###autoload |
| 1836 | (defun dired-upcase (&optional arg) |
| 1837 | "Rename all marked (or next ARG) files to upper case." |
| 1838 | (interactive "P") |
| 1839 | (dired-rename-non-directory (function upcase) "Rename upcase" arg)) |
| 1840 | |
| 1841 | ;;;###autoload |
| 1842 | (defun dired-downcase (&optional arg) |
| 1843 | "Rename all marked (or next ARG) files to lower case." |
| 1844 | (interactive "P") |
| 1845 | (dired-rename-non-directory (function downcase) "Rename downcase" arg)) |
| 1846 | |
| 1847 | ;;;###end dired-re.el |
| 1848 | \f |
| 1849 | ;;; 13K |
| 1850 | ;;;###begin dired-ins.el |
| 1851 | |
| 1852 | ;;;###autoload |
| 1853 | (defun dired-maybe-insert-subdir (dirname &optional |
| 1854 | switches no-error-if-not-dir-p) |
| 1855 | "Insert this subdirectory into the same dired buffer. |
| 1856 | If it is already present, just move to it (type \\[dired-do-redisplay] to refresh), |
| 1857 | else inserts it at its natural place (as `ls -lR' would have done). |
| 1858 | With a prefix arg, you may edit the ls switches used for this listing. |
| 1859 | You can add `R' to the switches to expand the whole tree starting at |
| 1860 | this subdirectory. |
| 1861 | This function takes some pains to conform to `ls -lR' output. |
| 1862 | |
| 1863 | Dired remembers switches specified with a prefix arg, so that reverting |
| 1864 | the buffer will not reset them. However, using `dired-undo' to re-insert |
| 1865 | or delete subdirectories can bypass this machinery. Hence, you sometimes |
| 1866 | may have to reset some subdirectory switches after a `dired-undo'. |
| 1867 | You can reset all subdirectory switches to the default using |
| 1868 | \\<dired-mode-map>\\[dired-reset-subdir-switches]. |
| 1869 | See Info node `(emacs)Subdir switches' for more details." |
| 1870 | (interactive |
| 1871 | (list (dired-get-filename) |
| 1872 | (if current-prefix-arg |
| 1873 | (read-string "Switches for listing: " |
| 1874 | (or dired-subdir-switches dired-actual-switches))))) |
| 1875 | (let ((opoint (point))) |
| 1876 | ;; We don't need a marker for opoint as the subdir is always |
| 1877 | ;; inserted *after* opoint. |
| 1878 | (setq dirname (file-name-as-directory dirname)) |
| 1879 | (or (and (not switches) |
| 1880 | (dired-goto-subdir dirname)) |
| 1881 | (dired-insert-subdir dirname switches no-error-if-not-dir-p)) |
| 1882 | ;; Push mark so that it's easy to find back. Do this after the |
| 1883 | ;; insert message so that the user sees the `Mark set' message. |
| 1884 | (push-mark opoint))) |
| 1885 | |
| 1886 | ;;;###autoload |
| 1887 | (defun dired-insert-subdir (dirname &optional switches no-error-if-not-dir-p) |
| 1888 | "Insert this subdirectory into the same dired buffer. |
| 1889 | If it is already present, overwrites previous entry, |
| 1890 | else inserts it at its natural place (as `ls -lR' would have done). |
| 1891 | With a prefix arg, you may edit the `ls' switches used for this listing. |
| 1892 | You can add `R' to the switches to expand the whole tree starting at |
| 1893 | this subdirectory. |
| 1894 | This function takes some pains to conform to `ls -lR' output." |
| 1895 | ;; NO-ERROR-IF-NOT-DIR-P needed for special filesystems like |
| 1896 | ;; Prospero where dired-ls does the right thing, but |
| 1897 | ;; file-directory-p has not been redefined. |
| 1898 | (interactive |
| 1899 | (list (dired-get-filename) |
| 1900 | (if current-prefix-arg |
| 1901 | (read-string "Switches for listing: " |
| 1902 | (or dired-subdir-switches dired-actual-switches))))) |
| 1903 | (setq dirname (file-name-as-directory (expand-file-name dirname))) |
| 1904 | (or no-error-if-not-dir-p |
| 1905 | (file-directory-p dirname) |
| 1906 | (error "Attempt to insert a non-directory: %s" dirname)) |
| 1907 | (let ((elt (assoc dirname dired-subdir-alist)) |
| 1908 | (cons (assoc-string dirname dired-switches-alist)) |
| 1909 | (modflag (buffer-modified-p)) |
| 1910 | (old-switches switches) |
| 1911 | switches-have-R mark-alist case-fold-search buffer-read-only) |
| 1912 | (and (not switches) cons (setq switches (cdr cons))) |
| 1913 | (dired-insert-subdir-validate dirname switches) |
| 1914 | ;; case-fold-search is nil now, so we can test for capital `R': |
| 1915 | (if (setq switches-have-R (and switches (string-match "R" switches))) |
| 1916 | ;; avoid duplicated subdirs |
| 1917 | (setq mark-alist (dired-kill-tree dirname t))) |
| 1918 | (if elt |
| 1919 | ;; If subdir is already present, remove it and remember its marks |
| 1920 | (setq mark-alist (nconc (dired-insert-subdir-del elt) mark-alist)) |
| 1921 | (dired-insert-subdir-newpos dirname)) ; else compute new position |
| 1922 | (dired-insert-subdir-doupdate |
| 1923 | dirname elt (dired-insert-subdir-doinsert dirname switches)) |
| 1924 | (when old-switches |
| 1925 | (if cons |
| 1926 | (setcdr cons switches) |
| 1927 | (push (cons dirname switches) dired-switches-alist))) |
| 1928 | (when switches-have-R |
| 1929 | (dired-build-subdir-alist switches) |
| 1930 | (setq switches (dired-replace-in-string "R" "" switches)) |
| 1931 | (dolist (cur-ass dired-subdir-alist) |
| 1932 | (let ((cur-dir (car cur-ass))) |
| 1933 | (and (dired-in-this-tree cur-dir dirname) |
| 1934 | (let ((cur-cons (assoc-string cur-dir dired-switches-alist))) |
| 1935 | (if cur-cons |
| 1936 | (setcdr cur-cons switches) |
| 1937 | (push (cons cur-dir switches) dired-switches-alist))))))) |
| 1938 | (dired-initial-position dirname) |
| 1939 | (save-excursion (dired-mark-remembered mark-alist)) |
| 1940 | (restore-buffer-modified-p modflag))) |
| 1941 | |
| 1942 | (defun dired-insert-subdir-validate (dirname &optional switches) |
| 1943 | ;; Check that it is valid to insert DIRNAME with SWITCHES. |
| 1944 | ;; Signal an error if invalid (e.g. user typed `i' on `..'). |
| 1945 | (or (dired-in-this-tree dirname (expand-file-name default-directory)) |
| 1946 | (error "%s: not in this directory tree" dirname)) |
| 1947 | (let ((real-switches (or switches dired-subdir-switches))) |
| 1948 | (when real-switches |
| 1949 | (let (case-fold-search) |
| 1950 | (mapcar |
| 1951 | (function |
| 1952 | (lambda (x) |
| 1953 | (or (eq (null (string-match x real-switches)) |
| 1954 | (null (string-match x dired-actual-switches))) |
| 1955 | (error |
| 1956 | "Can't have dirs with and without -%s switches together" x)))) |
| 1957 | ;; all switches that make a difference to dired-get-filename: |
| 1958 | '("F" "b")))))) |
| 1959 | |
| 1960 | (defun dired-alist-add (dir new-marker) |
| 1961 | ;; Add new DIR at NEW-MARKER. Sort alist. |
| 1962 | (dired-alist-add-1 dir new-marker) |
| 1963 | (dired-alist-sort)) |
| 1964 | |
| 1965 | (defun dired-alist-sort () |
| 1966 | ;; Keep the alist sorted on buffer position. |
| 1967 | (setq dired-subdir-alist |
| 1968 | (sort dired-subdir-alist |
| 1969 | (function (lambda (elt1 elt2) |
| 1970 | (> (dired-get-subdir-min elt1) |
| 1971 | (dired-get-subdir-min elt2))))))) |
| 1972 | |
| 1973 | (defun dired-kill-tree (dirname &optional remember-marks kill-root) |
| 1974 | "Kill all proper subdirs of DIRNAME, excluding DIRNAME itself. |
| 1975 | Interactively, you can kill DIRNAME as well by using a prefix argument. |
| 1976 | In interactive use, the command prompts for DIRNAME. |
| 1977 | |
| 1978 | When called from Lisp, if REMEMBER-MARKS is non-nil, return an alist |
| 1979 | of marked files. If KILL-ROOT is non-nil, kill DIRNAME as well." |
| 1980 | (interactive "DKill tree below directory: \ni\nP") |
| 1981 | (setq dirname (file-name-as-directory (expand-file-name dirname))) |
| 1982 | (let ((s-alist dired-subdir-alist) dir m-alist) |
| 1983 | (while s-alist |
| 1984 | (setq dir (car (car s-alist)) |
| 1985 | s-alist (cdr s-alist)) |
| 1986 | (and (or kill-root (not (string-equal dir dirname))) |
| 1987 | (dired-in-this-tree dir dirname) |
| 1988 | (dired-goto-subdir dir) |
| 1989 | (setq m-alist (nconc (dired-kill-subdir remember-marks) m-alist)))) |
| 1990 | m-alist)) |
| 1991 | |
| 1992 | (defun dired-insert-subdir-newpos (new-dir) |
| 1993 | ;; Find pos for new subdir, according to tree order. |
| 1994 | ;;(goto-char (point-max)) |
| 1995 | (let ((alist dired-subdir-alist) elt dir pos new-pos) |
| 1996 | (while alist |
| 1997 | (setq elt (car alist) |
| 1998 | alist (cdr alist) |
| 1999 | dir (car elt) |
| 2000 | pos (dired-get-subdir-min elt)) |
| 2001 | (if (dired-tree-lessp dir new-dir) |
| 2002 | ;; Insert NEW-DIR after DIR |
| 2003 | (setq new-pos (dired-get-subdir-max elt) |
| 2004 | alist nil))) |
| 2005 | (goto-char new-pos)) |
| 2006 | ;; want a separating newline between subdirs |
| 2007 | (or (eobp) |
| 2008 | (forward-line -1)) |
| 2009 | (insert "\n") |
| 2010 | (point)) |
| 2011 | |
| 2012 | (defun dired-insert-subdir-del (element) |
| 2013 | ;; Erase an already present subdir (given by ELEMENT) from buffer. |
| 2014 | ;; Move to that buffer position. Return a mark-alist. |
| 2015 | (let ((begin-marker (dired-get-subdir-min element))) |
| 2016 | (goto-char begin-marker) |
| 2017 | ;; Are at beginning of subdir (and inside it!). Now determine its end: |
| 2018 | (goto-char (dired-subdir-max)) |
| 2019 | (or (eobp);; want a separating newline _between_ subdirs: |
| 2020 | (forward-char -1)) |
| 2021 | (prog1 |
| 2022 | (dired-remember-marks begin-marker (point)) |
| 2023 | (delete-region begin-marker (point))))) |
| 2024 | |
| 2025 | (defun dired-insert-subdir-doinsert (dirname switches) |
| 2026 | ;; Insert ls output after point. |
| 2027 | ;; Return the boundary of the inserted text (as list of BEG and END). |
| 2028 | (save-excursion |
| 2029 | (let ((begin (point))) |
| 2030 | (let ((dired-actual-switches |
| 2031 | (or switches |
| 2032 | dired-subdir-switches |
| 2033 | (dired-replace-in-string "R" "" dired-actual-switches)))) |
| 2034 | (if (equal dirname (car (car (last dired-subdir-alist)))) |
| 2035 | ;; If doing the top level directory of the buffer, |
| 2036 | ;; redo it as specified in dired-directory. |
| 2037 | (dired-readin-insert) |
| 2038 | (dired-insert-directory dirname dired-actual-switches nil nil t))) |
| 2039 | (list begin (point))))) |
| 2040 | |
| 2041 | (defun dired-insert-subdir-doupdate (dirname elt beg-end) |
| 2042 | ;; Point is at the correct subdir alist position for ELT, |
| 2043 | ;; BEG-END is the subdir-region (as list of begin and end). |
| 2044 | (if elt ; subdir was already present |
| 2045 | ;; update its position (should actually be unchanged) |
| 2046 | (set-marker (dired-get-subdir-min elt) (point-marker)) |
| 2047 | (dired-alist-add dirname (point-marker))) |
| 2048 | ;; The hook may depend on the subdir-alist containing the just |
| 2049 | ;; inserted subdir, so run it after dired-alist-add: |
| 2050 | (if dired-after-readin-hook |
| 2051 | (save-excursion |
| 2052 | (let ((begin (nth 0 beg-end)) |
| 2053 | (end (nth 1 beg-end))) |
| 2054 | (goto-char begin) |
| 2055 | (save-restriction |
| 2056 | (narrow-to-region begin end) |
| 2057 | ;; hook may add or delete lines, but the subdir boundary |
| 2058 | ;; marker floats |
| 2059 | (run-hooks 'dired-after-readin-hook)))))) |
| 2060 | |
| 2061 | (defun dired-tree-lessp (dir1 dir2) |
| 2062 | ;; Lexicographic order on file name components, like `ls -lR': |
| 2063 | ;; DIR1 < DIR2 if DIR1 comes *before* DIR2 in an `ls -lR' listing, |
| 2064 | ;; i.e., if DIR1 is a (grand)parent dir of DIR2, |
| 2065 | ;; or DIR1 and DIR2 are in the same parentdir and their last |
| 2066 | ;; components are string-lessp. |
| 2067 | ;; Thus ("/usr/" "/usr/bin") and ("/usr/a/" "/usr/b/") are tree-lessp. |
| 2068 | ;; string-lessp could arguably be replaced by file-newer-than-file-p |
| 2069 | ;; if dired-actual-switches contained `t'. |
| 2070 | (setq dir1 (file-name-as-directory dir1) |
| 2071 | dir2 (file-name-as-directory dir2)) |
| 2072 | (let ((components-1 (dired-split "/" dir1)) |
| 2073 | (components-2 (dired-split "/" dir2))) |
| 2074 | (while (and components-1 |
| 2075 | components-2 |
| 2076 | (equal (car components-1) (car components-2))) |
| 2077 | (setq components-1 (cdr components-1) |
| 2078 | components-2 (cdr components-2))) |
| 2079 | (let ((c1 (car components-1)) |
| 2080 | (c2 (car components-2))) |
| 2081 | |
| 2082 | (cond ((and c1 c2) |
| 2083 | (string-lessp c1 c2)) |
| 2084 | ((and (null c1) (null c2)) |
| 2085 | nil) ; they are equal, not lessp |
| 2086 | ((null c1) ; c2 is a subdir of c1: c1<c2 |
| 2087 | t) |
| 2088 | ((null c2) ; c1 is a subdir of c2: c1>c2 |
| 2089 | nil) |
| 2090 | (t (error "This can't happen")))))) |
| 2091 | |
| 2092 | ;; There should be a builtin split function - inverse to mapconcat. |
| 2093 | (defun dired-split (pat str &optional limit) |
| 2094 | "Splitting on regexp PAT, turn string STR into a list of substrings. |
| 2095 | Optional third arg LIMIT (>= 1) is a limit to the length of the |
| 2096 | resulting list. |
| 2097 | Thus, if SEP is a regexp that only matches itself, |
| 2098 | |
| 2099 | (mapconcat 'identity (dired-split SEP STRING) SEP) |
| 2100 | |
| 2101 | is always equal to STRING." |
| 2102 | (let* ((start (string-match pat str)) |
| 2103 | (result (list (substring str 0 start))) |
| 2104 | (count 1) |
| 2105 | (end (if start (match-end 0)))) |
| 2106 | (if end ; else nothing left |
| 2107 | (while (and (or (not (integerp limit)) |
| 2108 | (< count limit)) |
| 2109 | (string-match pat str end)) |
| 2110 | (setq start (match-beginning 0) |
| 2111 | count (1+ count) |
| 2112 | result (cons (substring str end start) result) |
| 2113 | end (match-end 0) |
| 2114 | start end) |
| 2115 | )) |
| 2116 | (if (and (or (not (integerp limit)) |
| 2117 | (< count limit)) |
| 2118 | end) ; else nothing left |
| 2119 | (setq result |
| 2120 | (cons (substring str end) result))) |
| 2121 | (nreverse result))) |
| 2122 | \f |
| 2123 | ;;; moving by subdirectories |
| 2124 | |
| 2125 | ;;;###autoload |
| 2126 | (defun dired-prev-subdir (arg &optional no-error-if-not-found no-skip) |
| 2127 | "Go to previous subdirectory, regardless of level. |
| 2128 | When called interactively and not on a subdir line, go to this subdir's line." |
| 2129 | ;;(interactive "p") |
| 2130 | (interactive |
| 2131 | (list (if current-prefix-arg |
| 2132 | (prefix-numeric-value current-prefix-arg) |
| 2133 | ;; if on subdir start already, don't stay there! |
| 2134 | (if (dired-get-subdir) 1 0)))) |
| 2135 | (dired-next-subdir (- arg) no-error-if-not-found no-skip)) |
| 2136 | |
| 2137 | (defun dired-subdir-min () |
| 2138 | (save-excursion |
| 2139 | (if (not (dired-prev-subdir 0 t t)) |
| 2140 | (error "Not in a subdir!") |
| 2141 | (point)))) |
| 2142 | |
| 2143 | ;;;###autoload |
| 2144 | (defun dired-goto-subdir (dir) |
| 2145 | "Go to end of header line of DIR in this dired buffer. |
| 2146 | Return value of point on success, otherwise return nil. |
| 2147 | The next char is either \\n, or \\r if DIR is hidden." |
| 2148 | (interactive |
| 2149 | (prog1 ; let push-mark display its message |
| 2150 | (list (expand-file-name |
| 2151 | (completing-read "Goto in situ directory: " ; prompt |
| 2152 | dired-subdir-alist ; table |
| 2153 | nil ; predicate |
| 2154 | t ; require-match |
| 2155 | (dired-current-directory)))) |
| 2156 | (push-mark))) |
| 2157 | (setq dir (file-name-as-directory dir)) |
| 2158 | (let ((elt (assoc dir dired-subdir-alist))) |
| 2159 | (and elt |
| 2160 | (goto-char (dired-get-subdir-min elt)) |
| 2161 | ;; dired-subdir-hidden-p and dired-add-entry depend on point being |
| 2162 | ;; at either \r or \n after this function succeeds. |
| 2163 | (progn (skip-chars-forward "^\r\n") |
| 2164 | (point))))) |
| 2165 | \f |
| 2166 | ;;;###autoload |
| 2167 | (defun dired-mark-subdir-files () |
| 2168 | "Mark all files except `.' and `..' in current subdirectory. |
| 2169 | If the Dired buffer shows multiple directories, this command |
| 2170 | marks the files listed in the subdirectory that point is in." |
| 2171 | (interactive) |
| 2172 | (let ((p-min (dired-subdir-min))) |
| 2173 | (dired-mark-files-in-region p-min (dired-subdir-max)))) |
| 2174 | |
| 2175 | ;;;###autoload |
| 2176 | (defun dired-kill-subdir (&optional remember-marks) |
| 2177 | "Remove all lines of current subdirectory. |
| 2178 | Lower levels are unaffected." |
| 2179 | ;; With optional REMEMBER-MARKS, return a mark-alist. |
| 2180 | (interactive) |
| 2181 | (let* ((beg (dired-subdir-min)) |
| 2182 | (end (dired-subdir-max)) |
| 2183 | (modflag (buffer-modified-p)) |
| 2184 | (cur-dir (dired-current-directory)) |
| 2185 | (cons (assoc-string cur-dir dired-switches-alist)) |
| 2186 | buffer-read-only) |
| 2187 | (if (equal cur-dir default-directory) |
| 2188 | (error "Attempt to kill top level directory")) |
| 2189 | (prog1 |
| 2190 | (if remember-marks (dired-remember-marks beg end)) |
| 2191 | (delete-region beg end) |
| 2192 | (if (eobp) ; don't leave final blank line |
| 2193 | (delete-char -1)) |
| 2194 | (dired-unsubdir cur-dir) |
| 2195 | (when cons |
| 2196 | (setq dired-switches-alist (delete cons dired-switches-alist))) |
| 2197 | (restore-buffer-modified-p modflag)))) |
| 2198 | |
| 2199 | (defun dired-unsubdir (dir) |
| 2200 | ;; Remove DIR from the alist |
| 2201 | (setq dired-subdir-alist |
| 2202 | (delq (assoc dir dired-subdir-alist) dired-subdir-alist))) |
| 2203 | |
| 2204 | ;;;###autoload |
| 2205 | (defun dired-tree-up (arg) |
| 2206 | "Go up ARG levels in the dired tree." |
| 2207 | (interactive "p") |
| 2208 | (let ((dir (dired-current-directory))) |
| 2209 | (while (>= arg 1) |
| 2210 | (setq arg (1- arg) |
| 2211 | dir (file-name-directory (directory-file-name dir)))) |
| 2212 | ;;(setq dir (expand-file-name dir)) |
| 2213 | (or (dired-goto-subdir dir) |
| 2214 | (error "Cannot go up to %s - not in this tree" dir)))) |
| 2215 | |
| 2216 | ;;;###autoload |
| 2217 | (defun dired-tree-down () |
| 2218 | "Go down in the dired tree." |
| 2219 | (interactive) |
| 2220 | (let ((dir (dired-current-directory)) ; has slash |
| 2221 | pos case-fold-search) ; filenames are case sensitive |
| 2222 | (let ((rest (reverse dired-subdir-alist)) elt) |
| 2223 | (while rest |
| 2224 | (setq elt (car rest) |
| 2225 | rest (cdr rest)) |
| 2226 | (if (dired-in-this-tree (directory-file-name (car elt)) dir) |
| 2227 | (setq rest nil |
| 2228 | pos (dired-goto-subdir (car elt)))))) |
| 2229 | (if pos |
| 2230 | (goto-char pos) |
| 2231 | (error "At the bottom")))) |
| 2232 | \f |
| 2233 | ;;; hiding |
| 2234 | |
| 2235 | (defun dired-unhide-subdir () |
| 2236 | (let (buffer-read-only) |
| 2237 | (subst-char-in-region (dired-subdir-min) (dired-subdir-max) ?\r ?\n))) |
| 2238 | |
| 2239 | (defun dired-hide-check () |
| 2240 | (or selective-display |
| 2241 | (error "selective-display must be t for subdir hiding to work!"))) |
| 2242 | |
| 2243 | (defun dired-subdir-hidden-p (dir) |
| 2244 | (and selective-display |
| 2245 | (save-excursion |
| 2246 | (dired-goto-subdir dir) |
| 2247 | (looking-at "\r")))) |
| 2248 | |
| 2249 | ;;;###autoload |
| 2250 | (defun dired-hide-subdir (arg) |
| 2251 | "Hide or unhide the current subdirectory and move to next directory. |
| 2252 | Optional prefix arg is a repeat factor. |
| 2253 | Use \\[dired-hide-all] to (un)hide all directories." |
| 2254 | (interactive "p") |
| 2255 | (dired-hide-check) |
| 2256 | (let ((modflag (buffer-modified-p))) |
| 2257 | (while (>= (setq arg (1- arg)) 0) |
| 2258 | (let* ((cur-dir (dired-current-directory)) |
| 2259 | (hidden-p (dired-subdir-hidden-p cur-dir)) |
| 2260 | (elt (assoc cur-dir dired-subdir-alist)) |
| 2261 | (end-pos (1- (dired-get-subdir-max elt))) |
| 2262 | buffer-read-only) |
| 2263 | ;; keep header line visible, hide rest |
| 2264 | (goto-char (dired-get-subdir-min elt)) |
| 2265 | (skip-chars-forward "^\n\r") |
| 2266 | (if hidden-p |
| 2267 | (subst-char-in-region (point) end-pos ?\r ?\n) |
| 2268 | (subst-char-in-region (point) end-pos ?\n ?\r))) |
| 2269 | (dired-next-subdir 1 t)) |
| 2270 | (restore-buffer-modified-p modflag))) |
| 2271 | |
| 2272 | ;;;###autoload |
| 2273 | (defun dired-hide-all (arg) |
| 2274 | "Hide all subdirectories, leaving only their header lines. |
| 2275 | If there is already something hidden, make everything visible again. |
| 2276 | Use \\[dired-hide-subdir] to (un)hide a particular subdirectory." |
| 2277 | (interactive "P") |
| 2278 | (dired-hide-check) |
| 2279 | (let ((modflag (buffer-modified-p)) |
| 2280 | buffer-read-only) |
| 2281 | (if (save-excursion |
| 2282 | (goto-char (point-min)) |
| 2283 | (search-forward "\r" nil t)) |
| 2284 | ;; unhide - bombs on \r in filenames |
| 2285 | (subst-char-in-region (point-min) (point-max) ?\r ?\n) |
| 2286 | ;; hide |
| 2287 | (let ((pos (point-max)) ; pos of end of last directory |
| 2288 | (alist dired-subdir-alist)) |
| 2289 | (while alist ; while there are dirs before pos |
| 2290 | (subst-char-in-region (dired-get-subdir-min (car alist)) ; pos of prev dir |
| 2291 | (save-excursion |
| 2292 | (goto-char pos) ; current dir |
| 2293 | ;; we're somewhere on current dir's line |
| 2294 | (forward-line -1) |
| 2295 | (point)) |
| 2296 | ?\n ?\r) |
| 2297 | (setq pos (dired-get-subdir-min (car alist))) ; prev dir gets current dir |
| 2298 | (setq alist (cdr alist))))) |
| 2299 | (restore-buffer-modified-p modflag))) |
| 2300 | |
| 2301 | ;;;###end dired-ins.el |
| 2302 | |
| 2303 | \f |
| 2304 | ;; Search only in file names in the Dired buffer. |
| 2305 | |
| 2306 | (defcustom dired-isearch-filenames nil |
| 2307 | "Non-nil to Isearch in file names only. |
| 2308 | If t, Isearch in Dired always matches only file names. |
| 2309 | If `dwim', Isearch matches file names when initial point position is on |
| 2310 | a file name. Otherwise, it searches the whole buffer without restrictions." |
| 2311 | :type '(choice (const :tag "No restrictions" nil) |
| 2312 | (const :tag "When point is on a file name initially, search file names" dwim) |
| 2313 | (const :tag "Always search in file names" t)) |
| 2314 | :group 'dired |
| 2315 | :version "23.1") |
| 2316 | |
| 2317 | (defvar dired-isearch-filter-predicate-orig nil) |
| 2318 | |
| 2319 | (defun dired-isearch-filenames-toggle () |
| 2320 | "Toggle file names searching on or off. |
| 2321 | When on, Isearch skips matches outside file names using the predicate |
| 2322 | `dired-isearch-filter-filenames' that matches only at file names. |
| 2323 | When off, it uses the original predicate." |
| 2324 | (interactive) |
| 2325 | (setq isearch-filter-predicate |
| 2326 | (if (eq isearch-filter-predicate 'dired-isearch-filter-filenames) |
| 2327 | dired-isearch-filter-predicate-orig |
| 2328 | 'dired-isearch-filter-filenames)) |
| 2329 | (setq isearch-success t isearch-adjusted t) |
| 2330 | (isearch-update)) |
| 2331 | |
| 2332 | ;;;###autoload |
| 2333 | (defun dired-isearch-filenames-setup () |
| 2334 | "Set up isearch to search in Dired file names. |
| 2335 | Intended to be added to `isearch-mode-hook'." |
| 2336 | (when (or (eq dired-isearch-filenames t) |
| 2337 | (and (eq dired-isearch-filenames 'dwim) |
| 2338 | (get-text-property (point) 'dired-filename))) |
| 2339 | (setq isearch-message-prefix-add "filename ") |
| 2340 | (define-key isearch-mode-map "\M-sf" 'dired-isearch-filenames-toggle) |
| 2341 | (setq dired-isearch-filter-predicate-orig |
| 2342 | (default-value 'isearch-filter-predicate)) |
| 2343 | (setq-default isearch-filter-predicate 'dired-isearch-filter-filenames) |
| 2344 | (add-hook 'isearch-mode-end-hook 'dired-isearch-filenames-end nil t))) |
| 2345 | |
| 2346 | (defun dired-isearch-filenames-end () |
| 2347 | "Clean up the Dired file name search after terminating isearch." |
| 2348 | (setq isearch-message-prefix-add nil) |
| 2349 | (define-key isearch-mode-map "\M-sf" nil) |
| 2350 | (setq-default isearch-filter-predicate dired-isearch-filter-predicate-orig) |
| 2351 | (remove-hook 'isearch-mode-end-hook 'dired-isearch-filenames-end t)) |
| 2352 | |
| 2353 | (defun dired-isearch-filter-filenames (beg end) |
| 2354 | "Test whether the current search hit is a visible file name. |
| 2355 | Return non-nil if the text from BEG to END is part of a file |
| 2356 | name (has the text property `dired-filename') and is visible." |
| 2357 | (and (isearch-filter-visible beg end) |
| 2358 | (if dired-isearch-filenames |
| 2359 | (text-property-not-all (min beg end) (max beg end) |
| 2360 | 'dired-filename nil) |
| 2361 | t))) |
| 2362 | |
| 2363 | ;;;###autoload |
| 2364 | (defun dired-isearch-filenames () |
| 2365 | "Search for a string using Isearch only in file names in the Dired buffer." |
| 2366 | (interactive) |
| 2367 | (let ((dired-isearch-filenames t)) |
| 2368 | (isearch-forward))) |
| 2369 | |
| 2370 | ;;;###autoload |
| 2371 | (defun dired-isearch-filenames-regexp () |
| 2372 | "Search for a regexp using Isearch only in file names in the Dired buffer." |
| 2373 | (interactive) |
| 2374 | (let ((dired-isearch-filenames t)) |
| 2375 | (isearch-forward-regexp))) |
| 2376 | |
| 2377 | \f |
| 2378 | ;; Functions for searching in tags style among marked files. |
| 2379 | |
| 2380 | ;;;###autoload |
| 2381 | (defun dired-do-isearch () |
| 2382 | "Search for a string through all marked files using Isearch." |
| 2383 | (interactive) |
| 2384 | (multi-isearch-files |
| 2385 | (dired-get-marked-files nil nil 'dired-nondirectory-p))) |
| 2386 | |
| 2387 | ;;;###autoload |
| 2388 | (defun dired-do-isearch-regexp () |
| 2389 | "Search for a regexp through all marked files using Isearch." |
| 2390 | (interactive) |
| 2391 | (multi-isearch-files-regexp |
| 2392 | (dired-get-marked-files nil nil 'dired-nondirectory-p))) |
| 2393 | |
| 2394 | ;;;###autoload |
| 2395 | (defun dired-do-search (regexp) |
| 2396 | "Search through all marked files for a match for REGEXP. |
| 2397 | Stops when a match is found. |
| 2398 | To continue searching for next match, use command \\[tags-loop-continue]." |
| 2399 | (interactive "sSearch marked files (regexp): ") |
| 2400 | (tags-search regexp '(dired-get-marked-files nil nil 'dired-nondirectory-p))) |
| 2401 | |
| 2402 | ;;;###autoload |
| 2403 | (defun dired-do-query-replace-regexp (from to &optional delimited) |
| 2404 | "Do `query-replace-regexp' of FROM with TO, on all marked files. |
| 2405 | Third arg DELIMITED (prefix arg) means replace only word-delimited matches. |
| 2406 | If you exit (\\[keyboard-quit], RET or q), you can resume the query replace |
| 2407 | with the command \\[tags-loop-continue]." |
| 2408 | (interactive |
| 2409 | (let ((common |
| 2410 | (query-replace-read-args |
| 2411 | "Query replace regexp in marked files" t t))) |
| 2412 | (list (nth 0 common) (nth 1 common) (nth 2 common)))) |
| 2413 | (dolist (file (dired-get-marked-files nil nil 'dired-nondirectory-p)) |
| 2414 | (let ((buffer (get-file-buffer file))) |
| 2415 | (if (and buffer (with-current-buffer buffer |
| 2416 | buffer-read-only)) |
| 2417 | (error "File `%s' is visited read-only" file)))) |
| 2418 | (tags-query-replace from to delimited |
| 2419 | '(dired-get-marked-files nil nil 'dired-nondirectory-p))) |
| 2420 | |
| 2421 | (defun dired-nondirectory-p (file) |
| 2422 | (not (file-directory-p file))) |
| 2423 | \f |
| 2424 | ;;;###autoload |
| 2425 | (defun dired-show-file-type (file &optional deref-symlinks) |
| 2426 | "Print the type of FILE, according to the `file' command. |
| 2427 | If FILE is a symbolic link and the optional argument DEREF-SYMLINKS is |
| 2428 | true then the type of the file linked to by FILE is printed instead." |
| 2429 | (interactive (list (dired-get-filename t) current-prefix-arg)) |
| 2430 | (with-temp-buffer |
| 2431 | (if deref-symlinks |
| 2432 | (call-process "file" nil t t "-L" "--" file) |
| 2433 | (call-process "file" nil t t "--" file)) |
| 2434 | (when (bolp) |
| 2435 | (backward-delete-char 1)) |
| 2436 | (message "%s" (buffer-string)))) |
| 2437 | |
| 2438 | (provide 'dired-aux) |
| 2439 | |
| 2440 | ;; arch-tag: 4b508de9-a153-423d-8d3f-a1bbd86f4f60 |
| 2441 | ;;; dired-aux.el ends here |