| 1 | # c-strtod.m4 serial 15 |
| 2 | |
| 3 | # Copyright (C) 2004-2006, 2009-2014 Free Software Foundation, Inc. |
| 4 | # This file is free software; the Free Software Foundation |
| 5 | # gives unlimited permission to copy and/or distribute it, |
| 6 | # with or without modifications, as long as this notice is preserved. |
| 7 | |
| 8 | # Written by Paul Eggert. |
| 9 | |
| 10 | AC_DEFUN([gl_C99_STRTOLD], |
| 11 | [ |
| 12 | AC_CACHE_CHECK([whether strtold conforms to C99], |
| 13 | [gl_cv_func_c99_strtold], |
| 14 | [AC_LINK_IFELSE( |
| 15 | [AC_LANG_PROGRAM( |
| 16 | [[/* On HP-UX before 11.23, strtold returns a struct instead of |
| 17 | long double. Reject implementations like that, by requiring |
| 18 | compatibility with the C99 prototype. */ |
| 19 | #include <stdlib.h> |
| 20 | static long double (*p) (char const *, char **) = strtold; |
| 21 | static long double |
| 22 | test (char const *nptr, char **endptr) |
| 23 | { |
| 24 | long double r; |
| 25 | r = strtold (nptr, endptr); |
| 26 | return r; |
| 27 | }]], |
| 28 | [[return test ("1.0", NULL) != 1 || p ("1.0", NULL) != 1;]])], |
| 29 | [gl_cv_func_c99_strtold=yes], |
| 30 | [gl_cv_func_c99_strtold=no])]) |
| 31 | if test $gl_cv_func_c99_strtold = yes; then |
| 32 | AC_DEFINE([HAVE_C99_STRTOLD], [1], [Define to 1 if strtold conforms to C99.]) |
| 33 | fi |
| 34 | ]) |
| 35 | |
| 36 | dnl Prerequisites of lib/c-strtod.c. |
| 37 | AC_DEFUN([gl_C_STRTOD], |
| 38 | [ |
| 39 | AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS]) |
| 40 | AC_CHECK_FUNCS([strtod_l]) |
| 41 | ]) |
| 42 | |
| 43 | dnl Prerequisites of lib/c-strtold.c. |
| 44 | AC_DEFUN([gl_C_STRTOLD], |
| 45 | [ |
| 46 | AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS]) |
| 47 | AC_REQUIRE([gl_C99_STRTOLD]) |
| 48 | AC_CHECK_FUNCS([strtold_l]) |
| 49 | ]) |