| 1 | ;;; macros.el --- non-primitive commands for keyboard macros |
| 2 | |
| 3 | ;; Copyright (C) 1985-1987, 1992, 1994-1995, 2001-2012 |
| 4 | ;; Free Software Foundation, Inc. |
| 5 | |
| 6 | ;; Maintainer: FSF |
| 7 | ;; Keywords: abbrev |
| 8 | ;; Package: emacs |
| 9 | |
| 10 | ;; This file is part of GNU Emacs. |
| 11 | |
| 12 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 13 | ;; it under the terms of the GNU General Public License as published by |
| 14 | ;; the Free Software Foundation, either version 3 of the License, or |
| 15 | ;; (at your option) any later version. |
| 16 | |
| 17 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 18 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 19 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 20 | ;; GNU General Public License for more details. |
| 21 | |
| 22 | ;; You should have received a copy of the GNU General Public License |
| 23 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 24 | |
| 25 | ;;; Commentary: |
| 26 | |
| 27 | ;; Extension commands for keyboard macros. These permit you to assign |
| 28 | ;; a name to the last-defined keyboard macro, expand and insert the |
| 29 | ;; lisp corresponding to a macro, query the user from within a macro, |
| 30 | ;; or apply a macro to each line in the reason. |
| 31 | |
| 32 | ;;; Code: |
| 33 | |
| 34 | ;;;###autoload |
| 35 | (defun name-last-kbd-macro (symbol) |
| 36 | "Assign a name to the last keyboard macro defined. |
| 37 | Argument SYMBOL is the name to define. |
| 38 | The symbol's function definition becomes the keyboard macro string. |
| 39 | Such a \"function\" cannot be called from Lisp, but it is a valid editor command." |
| 40 | (interactive "SName for last kbd macro: ") |
| 41 | (or last-kbd-macro |
| 42 | (error "No keyboard macro defined")) |
| 43 | (and (fboundp symbol) |
| 44 | (not (stringp (symbol-function symbol))) |
| 45 | (not (vectorp (symbol-function symbol))) |
| 46 | (error "Function %s is already defined and not a keyboard macro" |
| 47 | symbol)) |
| 48 | (if (string-equal symbol "") |
| 49 | (error "No command name given")) |
| 50 | (fset symbol last-kbd-macro)) |
| 51 | |
| 52 | ;;;###autoload |
| 53 | (defun insert-kbd-macro (macroname &optional keys) |
| 54 | "Insert in buffer the definition of kbd macro NAME, as Lisp code. |
| 55 | Optional second arg KEYS means also record the keys it is on |
| 56 | \(this is the prefix argument, when calling interactively). |
| 57 | |
| 58 | This Lisp code will, when executed, define the kbd macro with the same |
| 59 | definition it has now. If you say to record the keys, the Lisp code |
| 60 | will also rebind those keys to the macro. Only global key bindings |
| 61 | are recorded since executing this Lisp code always makes global |
| 62 | bindings. |
| 63 | |
| 64 | To save a kbd macro, visit a file of Lisp code such as your `~/.emacs', |
| 65 | use this command, and then save the file." |
| 66 | (interactive (list (intern (completing-read "Insert kbd macro (name): " |
| 67 | obarray |
| 68 | (lambda (elt) |
| 69 | (and (fboundp elt) |
| 70 | (or (stringp (symbol-function elt)) |
| 71 | (vectorp (symbol-function elt)) |
| 72 | (get elt 'kmacro)))) |
| 73 | t)) |
| 74 | current-prefix-arg)) |
| 75 | (let (definition) |
| 76 | (if (string= (symbol-name macroname) "") |
| 77 | (progn |
| 78 | (setq macroname 'last-kbd-macro definition last-kbd-macro) |
| 79 | (insert "(setq ")) |
| 80 | (setq definition (symbol-function macroname)) |
| 81 | (insert "(fset '")) |
| 82 | (prin1 macroname (current-buffer)) |
| 83 | (insert "\n ") |
| 84 | (if (stringp definition) |
| 85 | (let ((beg (point)) end) |
| 86 | (prin1 definition (current-buffer)) |
| 87 | (setq end (point-marker)) |
| 88 | (goto-char beg) |
| 89 | (while (< (point) end) |
| 90 | (let ((char (following-char))) |
| 91 | (cond ((= char 0) |
| 92 | (delete-region (point) (1+ (point))) |
| 93 | (insert "\\C-@")) |
| 94 | ((< char 27) |
| 95 | (delete-region (point) (1+ (point))) |
| 96 | (insert "\\C-" (+ 96 char))) |
| 97 | ((= char ?\C-\\) |
| 98 | (delete-region (point) (1+ (point))) |
| 99 | (insert "\\C-\\\\")) |
| 100 | ((< char 32) |
| 101 | (delete-region (point) (1+ (point))) |
| 102 | (insert "\\C-" (+ 64 char))) |
| 103 | ((< char 127) |
| 104 | (forward-char 1)) |
| 105 | ((= char 127) |
| 106 | (delete-region (point) (1+ (point))) |
| 107 | (insert "\\C-?")) |
| 108 | ((= char 128) |
| 109 | (delete-region (point) (1+ (point))) |
| 110 | (insert "\\M-\\C-@")) |
| 111 | ((= char (aref "\M-\C-\\" 0)) |
| 112 | (delete-region (point) (1+ (point))) |
| 113 | (insert "\\M-\\C-\\\\")) |
| 114 | ((< char 155) |
| 115 | (delete-region (point) (1+ (point))) |
| 116 | (insert "\\M-\\C-" (- char 32))) |
| 117 | ((< char 160) |
| 118 | (delete-region (point) (1+ (point))) |
| 119 | (insert "\\M-\\C-" (- char 64))) |
| 120 | ((= char (aref "\M-\\" 0)) |
| 121 | (delete-region (point) (1+ (point))) |
| 122 | (insert "\\M-\\\\")) |
| 123 | ((< char 255) |
| 124 | (delete-region (point) (1+ (point))) |
| 125 | (insert "\\M-" (- char 128))) |
| 126 | ((= char 255) |
| 127 | (delete-region (point) (1+ (point))) |
| 128 | (insert "\\M-\\C-?")))))) |
| 129 | (if (vectorp definition) |
| 130 | (let ((len (length definition)) (i 0) char) |
| 131 | (while (< i len) |
| 132 | (insert (if (zerop i) ?\[ ?\s)) |
| 133 | (setq char (aref definition i) |
| 134 | i (1+ i)) |
| 135 | (if (not (numberp char)) |
| 136 | (prin1 char (current-buffer)) |
| 137 | (princ (prin1-char char) (current-buffer)))) |
| 138 | (insert ?\])) |
| 139 | (prin1 definition (current-buffer)))) |
| 140 | (insert ")\n") |
| 141 | (if keys |
| 142 | (let ((keys (where-is-internal (symbol-function macroname) |
| 143 | '(keymap)))) |
| 144 | (while keys |
| 145 | (insert "(global-set-key ") |
| 146 | (prin1 (car keys) (current-buffer)) |
| 147 | (insert " '") |
| 148 | (prin1 macroname (current-buffer)) |
| 149 | (insert ")\n") |
| 150 | (setq keys (cdr keys))))))) |
| 151 | |
| 152 | ;;;###autoload |
| 153 | (defun kbd-macro-query (flag) |
| 154 | "Query user during kbd macro execution. |
| 155 | With prefix argument, enters recursive edit, reading keyboard |
| 156 | commands even within a kbd macro. You can give different commands |
| 157 | each time the macro executes. |
| 158 | Without prefix argument, asks whether to continue running the macro. |
| 159 | Your options are: \\<query-replace-map> |
| 160 | \\[act] Finish this iteration normally and continue with the next. |
| 161 | \\[skip] Skip the rest of this iteration, and start the next. |
| 162 | \\[exit] Stop the macro entirely right now. |
| 163 | \\[recenter] Redisplay the screen, then ask again. |
| 164 | \\[edit] Enter recursive edit; ask again when you exit from that." |
| 165 | (interactive "P") |
| 166 | (or executing-kbd-macro |
| 167 | defining-kbd-macro |
| 168 | (error "Not defining or executing kbd macro")) |
| 169 | (if flag |
| 170 | (let (executing-kbd-macro defining-kbd-macro) |
| 171 | (recursive-edit)) |
| 172 | (if (not executing-kbd-macro) |
| 173 | nil |
| 174 | (let ((loop t) |
| 175 | (msg (substitute-command-keys |
| 176 | "Proceed with macro?\\<query-replace-map>\ |
| 177 | (\\[act], \\[skip], \\[exit], \\[recenter], \\[edit]) "))) |
| 178 | (while loop |
| 179 | (let ((key (let ((executing-kbd-macro nil) |
| 180 | (defining-kbd-macro nil)) |
| 181 | (message "%s" msg) |
| 182 | (read-event))) |
| 183 | def) |
| 184 | (setq key (vector key)) |
| 185 | (setq def (lookup-key query-replace-map key)) |
| 186 | (cond ((eq def 'act) |
| 187 | (setq loop nil)) |
| 188 | ((eq def 'skip) |
| 189 | (setq loop nil) |
| 190 | (setq executing-kbd-macro "")) |
| 191 | ((eq def 'exit) |
| 192 | (setq loop nil) |
| 193 | (setq executing-kbd-macro t)) |
| 194 | ((eq def 'recenter) |
| 195 | (recenter nil)) |
| 196 | ((eq def 'edit) |
| 197 | (let (executing-kbd-macro defining-kbd-macro) |
| 198 | (recursive-edit))) |
| 199 | ((eq def 'quit) |
| 200 | (setq quit-flag t)) |
| 201 | (t |
| 202 | (or (eq def 'help) |
| 203 | (ding)) |
| 204 | (with-output-to-temp-buffer "*Help*" |
| 205 | (princ |
| 206 | (substitute-command-keys |
| 207 | "Specify how to proceed with keyboard macro execution. |
| 208 | Possibilities: \\<query-replace-map> |
| 209 | \\[act] Finish this iteration normally and continue with the next. |
| 210 | \\[skip] Skip the rest of this iteration, and start the next. |
| 211 | \\[exit] Stop the macro entirely right now. |
| 212 | \\[recenter] Redisplay the screen, then ask again. |
| 213 | \\[edit] Enter recursive edit; ask again when you exit from that.")) |
| 214 | (with-current-buffer standard-output |
| 215 | (help-mode))))))))))) |
| 216 | |
| 217 | ;;;###autoload |
| 218 | (defun apply-macro-to-region-lines (top bottom &optional macro) |
| 219 | "Apply last keyboard macro to all lines in the region. |
| 220 | For each line that begins in the region, move to the beginning of |
| 221 | the line, and run the last keyboard macro. |
| 222 | |
| 223 | When called from lisp, this function takes two arguments TOP and |
| 224 | BOTTOM, describing the current region. TOP must be before BOTTOM. |
| 225 | The optional third argument MACRO specifies a keyboard macro to |
| 226 | execute. |
| 227 | |
| 228 | This is useful for quoting or unquoting included text, adding and |
| 229 | removing comments, or producing tables where the entries are regular. |
| 230 | |
| 231 | For example, in Usenet articles, sections of text quoted from another |
| 232 | author are indented, or have each line start with `>'. To quote a |
| 233 | section of text, define a keyboard macro which inserts `>', put point |
| 234 | and mark at opposite ends of the quoted section, and use |
| 235 | `\\[apply-macro-to-region-lines]' to mark the entire section. |
| 236 | |
| 237 | Suppose you wanted to build a keyword table in C where each entry |
| 238 | looked like this: |
| 239 | |
| 240 | { \"foo\", foo_data, foo_function }, |
| 241 | { \"bar\", bar_data, bar_function }, |
| 242 | { \"baz\", baz_data, baz_function }, |
| 243 | |
| 244 | You could enter the names in this format: |
| 245 | |
| 246 | foo |
| 247 | bar |
| 248 | baz |
| 249 | |
| 250 | and write a macro to massage a word into a table entry: |
| 251 | |
| 252 | \\C-x ( |
| 253 | \\M-d { \"\\C-y\", \\C-y_data, \\C-y_function }, |
| 254 | \\C-x ) |
| 255 | |
| 256 | and then select the region of un-tablified names and use |
| 257 | `\\[apply-macro-to-region-lines]' to build the table from the names." |
| 258 | (interactive "r") |
| 259 | (or macro |
| 260 | (progn |
| 261 | (if (null last-kbd-macro) |
| 262 | (error "No keyboard macro has been defined")) |
| 263 | (setq macro last-kbd-macro))) |
| 264 | (save-excursion |
| 265 | (let ((end-marker (copy-marker bottom)) |
| 266 | next-line-marker) |
| 267 | (goto-char top) |
| 268 | (if (not (bolp)) |
| 269 | (forward-line 1)) |
| 270 | (setq next-line-marker (point-marker)) |
| 271 | (while (< next-line-marker end-marker) |
| 272 | (goto-char next-line-marker) |
| 273 | (save-excursion |
| 274 | (forward-line 1) |
| 275 | (set-marker next-line-marker (point))) |
| 276 | (save-excursion |
| 277 | (let ((mark-active nil)) |
| 278 | (execute-kbd-macro macro)))) |
| 279 | (set-marker end-marker nil) |
| 280 | (set-marker next-line-marker nil)))) |
| 281 | |
| 282 | ;;;###autoload (define-key ctl-x-map "q" 'kbd-macro-query) |
| 283 | |
| 284 | (provide 'macros) |
| 285 | |
| 286 | ;;; macros.el ends here |