| 1 | ;;; replace.el --- replace commands for Emacs. |
| 2 | |
| 3 | ;; Copyright (C) 1985, 86, 87, 92, 94, 96, 1997 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; This file is part of GNU Emacs. |
| 6 | |
| 7 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 8 | ;; it under the terms of the GNU General Public License as published by |
| 9 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 10 | ;; any later version. |
| 11 | |
| 12 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 13 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 14 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 15 | ;; GNU General Public License for more details. |
| 16 | |
| 17 | ;; You should have received a copy of the GNU General Public License |
| 18 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 19 | ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, |
| 20 | ;; Boston, MA 02111-1307, USA. |
| 21 | |
| 22 | ;;; Commentary: |
| 23 | |
| 24 | ;; This package supplies the string and regular-expression replace functions |
| 25 | ;; documented in the Emacs user's manual. |
| 26 | |
| 27 | ;;; Code: |
| 28 | |
| 29 | (defcustom case-replace t |
| 30 | "*Non-nil means query-replace should preserve case in replacements." |
| 31 | :type 'boolean |
| 32 | :group 'matching) |
| 33 | |
| 34 | (defvar query-replace-history nil) |
| 35 | |
| 36 | (defvar query-replace-interactive nil |
| 37 | "Non-nil means `query-replace' uses the last search string. |
| 38 | That becomes the \"string to replace\".") |
| 39 | |
| 40 | (defun query-replace-read-args (string regexp-flag) |
| 41 | (let (from to) |
| 42 | (if query-replace-interactive |
| 43 | (setq from (car (if regexp-flag regexp-search-ring search-ring))) |
| 44 | (setq from (read-from-minibuffer (format "%s: " string) |
| 45 | nil nil nil |
| 46 | 'query-replace-history nil t))) |
| 47 | (setq to (read-from-minibuffer (format "%s %s with: " string from) |
| 48 | nil nil nil |
| 49 | 'query-replace-history nil t)) |
| 50 | (list from to current-prefix-arg))) |
| 51 | |
| 52 | (defun query-replace (from-string to-string &optional arg) |
| 53 | "Replace some occurrences of FROM-STRING with TO-STRING. |
| 54 | As each match is found, the user must type a character saying |
| 55 | what to do with it. For directions, type \\[help-command] at that time. |
| 56 | |
| 57 | In Transient Mark mode, if the mark is active, operate on the contents |
| 58 | of the region. Otherwise, operate from point to the end of the buffer. |
| 59 | |
| 60 | If `query-replace-interactive' is non-nil, the last incremental search |
| 61 | string is used as FROM-STRING--you don't have to specify it with the |
| 62 | minibuffer. |
| 63 | |
| 64 | Preserves case in each replacement if `case-replace' and `case-fold-search' |
| 65 | are non-nil and FROM-STRING has no uppercase letters. |
| 66 | \(Preserving case means that if the string matched is all caps, or capitalized, |
| 67 | then its replacement is upcased or capitalized.) |
| 68 | |
| 69 | Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace |
| 70 | only matches surrounded by word boundaries. |
| 71 | |
| 72 | To customize possible responses, change the \"bindings\" in `query-replace-map'." |
| 73 | (interactive (query-replace-read-args "Query replace" nil)) |
| 74 | (perform-replace from-string to-string t nil arg)) |
| 75 | |
| 76 | (define-key esc-map "%" 'query-replace) |
| 77 | |
| 78 | (defun query-replace-regexp (regexp to-string &optional arg) |
| 79 | "Replace some things after point matching REGEXP with TO-STRING. |
| 80 | As each match is found, the user must type a character saying |
| 81 | what to do with it. For directions, type \\[help-command] at that time. |
| 82 | |
| 83 | In Transient Mark mode, if the mark is active, operate on the contents |
| 84 | of the region. Otherwise, operate from point to the end of the buffer. |
| 85 | |
| 86 | If `query-replace-interactive' is non-nil, the last incremental search |
| 87 | regexp is used as REGEXP--you don't have to specify it with the |
| 88 | minibuffer. |
| 89 | |
| 90 | Preserves case in each replacement if `case-replace' and `case-fold-search' |
| 91 | are non-nil and REGEXP has no uppercase letters. |
| 92 | Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace |
| 93 | only matches surrounded by word boundaries. |
| 94 | In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP, |
| 95 | and `\\=\\N' (where N is a digit) stands for |
| 96 | whatever what matched the Nth `\\(...\\)' in REGEXP." |
| 97 | (interactive (query-replace-read-args "Query replace regexp" t)) |
| 98 | (perform-replace regexp to-string t t arg)) |
| 99 | |
| 100 | (defun map-query-replace-regexp (regexp to-strings &optional arg) |
| 101 | "Replace some matches for REGEXP with various strings, in rotation. |
| 102 | The second argument TO-STRINGS contains the replacement strings, separated |
| 103 | by spaces. This command works like `query-replace-regexp' except |
| 104 | that each successive replacement uses the next successive replacement string, |
| 105 | wrapping around from the last such string to the first. |
| 106 | |
| 107 | In Transient Mark mode, if the mark is active, operate on the contents |
| 108 | of the region. Otherwise, operate from point to the end of the buffer. |
| 109 | |
| 110 | Non-interactively, TO-STRINGS may be a list of replacement strings. |
| 111 | |
| 112 | If `query-replace-interactive' is non-nil, the last incremental search |
| 113 | regexp is used as REGEXP--you don't have to specify it with the minibuffer. |
| 114 | |
| 115 | A prefix argument N says to use each replacement string N times |
| 116 | before rotating to the next." |
| 117 | (interactive |
| 118 | (let (from to) |
| 119 | (setq from (if query-replace-interactive |
| 120 | (car regexp-search-ring) |
| 121 | (read-from-minibuffer "Map query replace (regexp): " |
| 122 | nil nil nil |
| 123 | 'query-replace-history nil t))) |
| 124 | (setq to (read-from-minibuffer |
| 125 | (format "Query replace %s with (space-separated strings): " |
| 126 | from) |
| 127 | nil nil nil |
| 128 | 'query-replace-history nil t)) |
| 129 | (list from to current-prefix-arg))) |
| 130 | (let (replacements) |
| 131 | (if (listp to-strings) |
| 132 | (setq replacements to-strings) |
| 133 | (while (/= (length to-strings) 0) |
| 134 | (if (string-match " " to-strings) |
| 135 | (setq replacements |
| 136 | (append replacements |
| 137 | (list (substring to-strings 0 |
| 138 | (string-match " " to-strings)))) |
| 139 | to-strings (substring to-strings |
| 140 | (1+ (string-match " " to-strings)))) |
| 141 | (setq replacements (append replacements (list to-strings)) |
| 142 | to-strings "")))) |
| 143 | (perform-replace regexp replacements t t nil arg))) |
| 144 | |
| 145 | (defun replace-string (from-string to-string &optional delimited) |
| 146 | "Replace occurrences of FROM-STRING with TO-STRING. |
| 147 | Preserve case in each match if `case-replace' and `case-fold-search' |
| 148 | are non-nil and FROM-STRING has no uppercase letters. |
| 149 | \(Preserving case means that if the string matched is all caps, or capitalized, |
| 150 | then its replacement is upcased or capitalized.) |
| 151 | |
| 152 | In Transient Mark mode, if the mark is active, operate on the contents |
| 153 | of the region. Otherwise, operate from point to the end of the buffer. |
| 154 | |
| 155 | Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace |
| 156 | only matches surrounded by word boundaries. |
| 157 | |
| 158 | If `query-replace-interactive' is non-nil, the last incremental search |
| 159 | string is used as FROM-STRING--you don't have to specify it with the |
| 160 | minibuffer. |
| 161 | |
| 162 | This function is usually the wrong thing to use in a Lisp program. |
| 163 | What you probably want is a loop like this: |
| 164 | (while (search-forward FROM-STRING nil t) |
| 165 | (replace-match TO-STRING nil t)) |
| 166 | which will run faster and will not set the mark or print anything. |
| 167 | \(You may need a more complex loop if FROM-STRING can match the null string |
| 168 | and TO-STRING is also null.)" |
| 169 | (interactive (query-replace-read-args "Replace string" nil)) |
| 170 | (perform-replace from-string to-string nil nil delimited)) |
| 171 | |
| 172 | (defun replace-regexp (regexp to-string &optional delimited) |
| 173 | "Replace things after point matching REGEXP with TO-STRING. |
| 174 | Preserve case in each match if `case-replace' and `case-fold-search' |
| 175 | are non-nil and REGEXP has no uppercase letters. |
| 176 | Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace |
| 177 | only matches surrounded by word boundaries. |
| 178 | In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP, |
| 179 | and `\\=\\N' (where N is a digit) stands for |
| 180 | whatever what matched the Nth `\\(...\\)' in REGEXP. |
| 181 | |
| 182 | In Transient Mark mode, if the mark is active, operate on the contents |
| 183 | of the region. Otherwise, operate from point to the end of the buffer. |
| 184 | |
| 185 | If `query-replace-interactive' is non-nil, the last incremental search |
| 186 | regexp is used as REGEXP--you don't have to specify it with the minibuffer. |
| 187 | |
| 188 | This function is usually the wrong thing to use in a Lisp program. |
| 189 | What you probably want is a loop like this: |
| 190 | (while (re-search-forward REGEXP nil t) |
| 191 | (replace-match TO-STRING nil nil)) |
| 192 | which will run faster and will not set the mark or print anything." |
| 193 | (interactive (query-replace-read-args "Replace regexp" t)) |
| 194 | (perform-replace regexp to-string nil t delimited)) |
| 195 | \f |
| 196 | (defvar regexp-history nil |
| 197 | "History list for some commands that read regular expressions.") |
| 198 | |
| 199 | (defalias 'delete-non-matching-lines 'keep-lines) |
| 200 | (defun keep-lines (regexp) |
| 201 | "Delete all lines except those containing matches for REGEXP. |
| 202 | A match split across lines preserves all the lines it lies in. |
| 203 | Applies to all lines after point." |
| 204 | (interactive (list (read-from-minibuffer |
| 205 | "Keep lines (containing match for regexp): " |
| 206 | nil nil nil 'regexp-history nil t))) |
| 207 | (save-excursion |
| 208 | (or (bolp) (forward-line 1)) |
| 209 | (let ((start (point))) |
| 210 | (while (not (eobp)) |
| 211 | ;; Start is first char not preserved by previous match. |
| 212 | (if (not (re-search-forward regexp nil 'move)) |
| 213 | (delete-region start (point-max)) |
| 214 | (let ((end (save-excursion (goto-char (match-beginning 0)) |
| 215 | (beginning-of-line) |
| 216 | (point)))) |
| 217 | ;; Now end is first char preserved by the new match. |
| 218 | (if (< start end) |
| 219 | (delete-region start end)))) |
| 220 | (setq start (save-excursion (forward-line 1) |
| 221 | (point))) |
| 222 | ;; If the match was empty, avoid matching again at same place. |
| 223 | (and (not (eobp)) (= (match-beginning 0) (match-end 0)) |
| 224 | (forward-char 1)))))) |
| 225 | |
| 226 | (defalias 'delete-matching-lines 'flush-lines) |
| 227 | (defun flush-lines (regexp) |
| 228 | "Delete lines containing matches for REGEXP. |
| 229 | If a match is split across lines, all the lines it lies in are deleted. |
| 230 | Applies to lines after point." |
| 231 | (interactive (list (read-from-minibuffer |
| 232 | "Flush lines (containing match for regexp): " |
| 233 | nil nil nil 'regexp-history nil t))) |
| 234 | (save-excursion |
| 235 | (while (and (not (eobp)) |
| 236 | (re-search-forward regexp nil t)) |
| 237 | (delete-region (save-excursion (goto-char (match-beginning 0)) |
| 238 | (beginning-of-line) |
| 239 | (point)) |
| 240 | (progn (forward-line 1) (point)))))) |
| 241 | |
| 242 | (defalias 'count-matches 'how-many) |
| 243 | (defun how-many (regexp) |
| 244 | "Print number of matches for REGEXP following point." |
| 245 | (interactive (list(read-from-minibuffer |
| 246 | "How many matches for (regexp): " |
| 247 | nil nil nil 'regexp-history nil t))) |
| 248 | (let ((count 0) opoint) |
| 249 | (save-excursion |
| 250 | (while (and (not (eobp)) |
| 251 | (progn (setq opoint (point)) |
| 252 | (re-search-forward regexp nil t))) |
| 253 | (if (= opoint (point)) |
| 254 | (forward-char 1) |
| 255 | (setq count (1+ count)))) |
| 256 | (message "%d occurrences" count)))) |
| 257 | \f |
| 258 | (defvar occur-mode-map ()) |
| 259 | (if occur-mode-map |
| 260 | () |
| 261 | (setq occur-mode-map (make-sparse-keymap)) |
| 262 | (define-key occur-mode-map [mouse-2] 'occur-mode-mouse-goto) |
| 263 | (define-key occur-mode-map "\C-c\C-c" 'occur-mode-goto-occurrence) |
| 264 | (define-key occur-mode-map "\C-m" 'occur-mode-goto-occurrence) |
| 265 | (define-key occur-mode-map "\M-n" 'occur-next) |
| 266 | (define-key occur-mode-map "\M-p" 'occur-prev) |
| 267 | (define-key occur-mode-map "g" 'revert-buffer)) |
| 268 | |
| 269 | |
| 270 | (defvar occur-buffer nil |
| 271 | "Name of buffer for last occur.") |
| 272 | |
| 273 | |
| 274 | (defvar occur-nlines nil |
| 275 | "Number of lines of context to show around matching line.") |
| 276 | |
| 277 | (defvar occur-command-arguments nil |
| 278 | "Arguments that were given to `occur' when it made this buffer.") |
| 279 | |
| 280 | (put 'occur-mode 'mode-class 'special) |
| 281 | |
| 282 | (defun occur-mode () |
| 283 | "Major mode for output from \\[occur]. |
| 284 | \\<occur-mode-map>Move point to one of the items in this buffer, then use |
| 285 | \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to. |
| 286 | Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it. |
| 287 | |
| 288 | \\{occur-mode-map}" |
| 289 | (kill-all-local-variables) |
| 290 | (use-local-map occur-mode-map) |
| 291 | (setq major-mode 'occur-mode) |
| 292 | (setq mode-name "Occur") |
| 293 | (make-local-variable 'revert-buffer-function) |
| 294 | (setq revert-buffer-function 'occur-revert-function) |
| 295 | (make-local-variable 'occur-buffer) |
| 296 | (make-local-variable 'occur-nlines) |
| 297 | (make-local-variable 'occur-command-arguments) |
| 298 | (run-hooks 'occur-mode-hook)) |
| 299 | |
| 300 | ;; Handle revert-buffer for *Occur* buffers. |
| 301 | (defun occur-revert-function (ignore1 ignore2) |
| 302 | (let ((args occur-command-arguments )) |
| 303 | (save-excursion |
| 304 | (set-buffer occur-buffer) |
| 305 | (apply 'occur args)))) |
| 306 | |
| 307 | (defun occur-mode-mouse-goto (event) |
| 308 | "In Occur mode, go to the occurrence whose line you click on." |
| 309 | (interactive "e") |
| 310 | (let (buffer pos) |
| 311 | (save-excursion |
| 312 | (set-buffer (window-buffer (posn-window (event-end event)))) |
| 313 | (save-excursion |
| 314 | (goto-char (posn-point (event-end event))) |
| 315 | (setq pos (occur-mode-find-occurrence)) |
| 316 | (setq buffer occur-buffer))) |
| 317 | (pop-to-buffer buffer) |
| 318 | (goto-char (marker-position pos)))) |
| 319 | |
| 320 | (defun occur-mode-find-occurrence () |
| 321 | (if (or (null occur-buffer) |
| 322 | (null (buffer-name occur-buffer))) |
| 323 | (progn |
| 324 | (setq occur-buffer nil) |
| 325 | (error "Buffer in which occurrences were found is deleted"))) |
| 326 | (let ((pos (get-text-property (point) 'occur))) |
| 327 | (if (null pos) |
| 328 | (error "No occurrence on this line") |
| 329 | pos))) |
| 330 | |
| 331 | (defun occur-mode-goto-occurrence () |
| 332 | "Go to the occurrence the current line describes." |
| 333 | (interactive) |
| 334 | (let ((pos (occur-mode-find-occurrence))) |
| 335 | (pop-to-buffer occur-buffer) |
| 336 | (goto-char (marker-position pos)))) |
| 337 | |
| 338 | (defun occur-next (&optional n) |
| 339 | "Move to the Nth (default 1) next match in the *Occur* buffer." |
| 340 | (interactive "p") |
| 341 | (if (not n) (setq n 1)) |
| 342 | (let ((r)) |
| 343 | (while (> n 0) |
| 344 | (if (get-text-property (point) 'occur-point) |
| 345 | (forward-char 1)) |
| 346 | (setq r (next-single-property-change (point) 'occur-point)) |
| 347 | (if r |
| 348 | (goto-char r) |
| 349 | (error "no more matches")) |
| 350 | (setq n (1- n))))) |
| 351 | |
| 352 | |
| 353 | |
| 354 | (defun occur-prev (&optional n) |
| 355 | "Move to the Nth (default 1) previous match in the *Occur* buffer." |
| 356 | (interactive "p") |
| 357 | (if (not n) (setq n 1)) |
| 358 | (let ((r)) |
| 359 | (while (> n 0) |
| 360 | |
| 361 | (setq r (get-text-property (point) 'occur-point)) |
| 362 | (if r (forward-char -1)) |
| 363 | |
| 364 | (setq r (previous-single-property-change (point) 'occur-point)) |
| 365 | (if r |
| 366 | (goto-char (- r 1)) |
| 367 | (error "no earlier matches")) |
| 368 | |
| 369 | (setq n (1- n))))) |
| 370 | \f |
| 371 | (defcustom list-matching-lines-default-context-lines 0 |
| 372 | "*Default number of context lines to include around a `list-matching-lines' |
| 373 | match. A negative number means to include that many lines before the match. |
| 374 | A positive number means to include that many lines both before and after." |
| 375 | :type 'integer |
| 376 | :group 'matching) |
| 377 | |
| 378 | (defalias 'list-matching-lines 'occur) |
| 379 | |
| 380 | (defvar list-matching-lines-face 'bold |
| 381 | "*Face used by M-x list-matching-lines to show the text that matches. |
| 382 | If the value is nil, don't highlight the matching portions specially.") |
| 383 | |
| 384 | (defun occur (regexp &optional nlines) |
| 385 | "Show all lines in the current buffer containing a match for REGEXP. |
| 386 | |
| 387 | If a match spreads across multiple lines, all those lines are shown. |
| 388 | |
| 389 | Each line is displayed with NLINES lines before and after, or -NLINES |
| 390 | before if NLINES is negative. |
| 391 | NLINES defaults to `list-matching-lines-default-context-lines'. |
| 392 | Interactively it is the prefix arg. |
| 393 | |
| 394 | The lines are shown in a buffer named `*Occur*'. |
| 395 | It serves as a menu to find any of the occurrences in this buffer. |
| 396 | \\<occur-mode-map>\\[describe-mode] in that buffer will explain how. |
| 397 | |
| 398 | If REGEXP contains upper case characters (excluding those preceded by `\\'), |
| 399 | the matching is case-sensitive." |
| 400 | (interactive |
| 401 | (list (let* ((default (car regexp-history)) |
| 402 | (input |
| 403 | (read-from-minibuffer |
| 404 | (if default |
| 405 | (format "List lines matching regexp (default `%s'): " |
| 406 | default) |
| 407 | "List lines matching regexp: ") |
| 408 | nil nil nil 'regexp-history default t))) |
| 409 | (set-text-properties 0 (length input) nil input) |
| 410 | input) |
| 411 | current-prefix-arg)) |
| 412 | (let ((nlines (if nlines |
| 413 | (prefix-numeric-value nlines) |
| 414 | list-matching-lines-default-context-lines)) |
| 415 | (first t) |
| 416 | ;;flag to prevent printing separator for first match |
| 417 | (occur-num-matches 0) |
| 418 | (buffer (current-buffer)) |
| 419 | (dir default-directory) |
| 420 | (linenum 1) |
| 421 | (prevpos |
| 422 | ;;position of most recent match |
| 423 | (point-min)) |
| 424 | (case-fold-search (and case-fold-search |
| 425 | (isearch-no-upper-case-p regexp t))) |
| 426 | (final-context-start |
| 427 | ;; Marker to the start of context immediately following |
| 428 | ;; the matched text in *Occur*. |
| 429 | (make-marker))) |
| 430 | ;;; (save-excursion |
| 431 | ;;; (beginning-of-line) |
| 432 | ;;; (setq linenum (1+ (count-lines (point-min) (point)))) |
| 433 | ;;; (setq prevpos (point))) |
| 434 | (save-excursion |
| 435 | (goto-char (point-min)) |
| 436 | ;; Check first whether there are any matches at all. |
| 437 | (if (not (re-search-forward regexp nil t)) |
| 438 | (message "No matches for `%s'" regexp) |
| 439 | ;; Back up, so the search loop below will find the first match. |
| 440 | (goto-char (match-beginning 0)) |
| 441 | (with-output-to-temp-buffer "*Occur*" |
| 442 | (save-excursion |
| 443 | (set-buffer standard-output) |
| 444 | (setq default-directory dir) |
| 445 | ;; We will insert the number of lines, and "lines", later. |
| 446 | (insert " matching ") |
| 447 | (let ((print-escape-newlines t)) |
| 448 | (prin1 regexp)) |
| 449 | (insert " in buffer " (buffer-name buffer) ?. ?\n) |
| 450 | (occur-mode) |
| 451 | (setq occur-buffer buffer) |
| 452 | (setq occur-nlines nlines) |
| 453 | (setq occur-command-arguments |
| 454 | (list regexp nlines))) |
| 455 | (if (eq buffer standard-output) |
| 456 | (goto-char (point-max))) |
| 457 | (save-excursion |
| 458 | ;; Find next match, but give up if prev match was at end of buffer. |
| 459 | (while (and (not (= prevpos (point-max))) |
| 460 | (re-search-forward regexp nil t)) |
| 461 | (goto-char (match-beginning 0)) |
| 462 | (beginning-of-line) |
| 463 | (save-match-data |
| 464 | (setq linenum (+ linenum (count-lines prevpos (point))))) |
| 465 | (setq prevpos (point)) |
| 466 | (goto-char (match-end 0)) |
| 467 | (let* ((start |
| 468 | ;;start point of text in source buffer to be put |
| 469 | ;;into *Occur* |
| 470 | (save-excursion |
| 471 | (goto-char (match-beginning 0)) |
| 472 | (forward-line (if (< nlines 0) |
| 473 | nlines |
| 474 | (- nlines))) |
| 475 | (point))) |
| 476 | (end |
| 477 | ;; end point of text in source buffer to be put |
| 478 | ;; into *Occur* |
| 479 | (save-excursion |
| 480 | (goto-char (match-end 0)) |
| 481 | (if (> nlines 0) |
| 482 | (forward-line (1+ nlines)) |
| 483 | (forward-line 1)) |
| 484 | (point))) |
| 485 | (match-beg |
| 486 | ;; Amount of context before matching text |
| 487 | (- (match-beginning 0) start)) |
| 488 | (match-len |
| 489 | ;; Length of matching text |
| 490 | (- (match-end 0) (match-beginning 0))) |
| 491 | (tag (format "%5d" linenum)) |
| 492 | (empty (make-string (length tag) ?\ )) |
| 493 | tem |
| 494 | insertion-start |
| 495 | ;; Number of lines of context to show for current match. |
| 496 | occur-marker |
| 497 | ;; Marker pointing to end of match in source buffer. |
| 498 | (text-beg |
| 499 | ;; Marker pointing to start of text for one |
| 500 | ;; match in *Occur*. |
| 501 | (make-marker)) |
| 502 | (text-end |
| 503 | ;; Marker pointing to end of text for one match |
| 504 | ;; in *Occur*. |
| 505 | (make-marker)) |
| 506 | ) |
| 507 | (save-excursion |
| 508 | (setq occur-marker (make-marker)) |
| 509 | (set-marker occur-marker (point)) |
| 510 | (set-buffer standard-output) |
| 511 | (setq occur-num-matches (1+ occur-num-matches)) |
| 512 | (or first (zerop nlines) |
| 513 | (insert "--------\n")) |
| 514 | (setq first nil) |
| 515 | |
| 516 | ;; Insert matching text including context lines from |
| 517 | ;; source buffer into *Occur* |
| 518 | (set-marker text-beg (point)) |
| 519 | (setq insertion-start (point)) |
| 520 | (insert-buffer-substring buffer start end) |
| 521 | (or (and (/= (+ start match-beg) end) |
| 522 | (with-current-buffer buffer |
| 523 | (eq (char-before end) ?\n))) |
| 524 | (insert "\n")) |
| 525 | (set-marker final-context-start |
| 526 | (+ (- (point) (- end (match-end 0))) |
| 527 | (if (save-excursion |
| 528 | (set-buffer buffer) |
| 529 | (save-excursion |
| 530 | (goto-char (match-end 0)) |
| 531 | (end-of-line) |
| 532 | (bolp))) |
| 533 | 1 0))) |
| 534 | (set-marker text-end (point)) |
| 535 | |
| 536 | ;; Highlight text that was matched. |
| 537 | (if list-matching-lines-face |
| 538 | (put-text-property |
| 539 | (+ (marker-position text-beg) match-beg) |
| 540 | (+ (marker-position text-beg) match-beg match-len) |
| 541 | 'face list-matching-lines-face)) |
| 542 | |
| 543 | ;; `occur-point' property is used by occur-next and |
| 544 | ;; occur-prev to move between matching lines. |
| 545 | (put-text-property |
| 546 | (+ (marker-position text-beg) match-beg match-len) |
| 547 | (+ (marker-position text-beg) match-beg match-len 1) |
| 548 | 'occur-point t) |
| 549 | |
| 550 | ;; Now go back to the start of the matching text |
| 551 | ;; adding the space and colon to the start of each line. |
| 552 | (goto-char insertion-start) |
| 553 | ;; Insert space and colon for lines of context before match. |
| 554 | (setq tem (if (< linenum nlines) |
| 555 | (- nlines linenum) |
| 556 | nlines)) |
| 557 | (while (> tem 0) |
| 558 | (insert empty ?:) |
| 559 | (forward-line 1) |
| 560 | (setq tem (1- tem))) |
| 561 | |
| 562 | ;; Insert line number and colon for the lines of |
| 563 | ;; matching text. |
| 564 | (let ((this-linenum linenum)) |
| 565 | (while (< (point) final-context-start) |
| 566 | (if (null tag) |
| 567 | (setq tag (format "%5d" this-linenum))) |
| 568 | (insert tag ?:) |
| 569 | (forward-line 1) |
| 570 | (setq tag nil) |
| 571 | (setq this-linenum (1+ this-linenum))) |
| 572 | (while (and (not (eobp)) (<= (point) final-context-start)) |
| 573 | (insert empty ?:) |
| 574 | (forward-line 1) |
| 575 | (setq this-linenum (1+ this-linenum)))) |
| 576 | |
| 577 | ;; Insert space and colon for lines of context after match. |
| 578 | (while (and (< (point) (point-max)) (< tem nlines)) |
| 579 | (insert empty ?:) |
| 580 | (forward-line 1) |
| 581 | (setq tem (1+ tem))) |
| 582 | |
| 583 | ;; Add text properties. The `occur' prop is used to |
| 584 | ;; store the marker of the matching text in the |
| 585 | ;; source buffer. |
| 586 | (put-text-property (marker-position text-beg) |
| 587 | (- (marker-position text-end) 1) |
| 588 | 'mouse-face 'highlight) |
| 589 | (put-text-property (marker-position text-beg) |
| 590 | (marker-position text-end) |
| 591 | 'occur occur-marker) |
| 592 | (goto-char (point-max))) |
| 593 | (forward-line 1))) |
| 594 | (set-buffer standard-output) |
| 595 | ;; Go back to top of *Occur* and finish off by printing the |
| 596 | ;; number of matching lines. |
| 597 | (goto-char (point-min)) |
| 598 | (let ((message-string |
| 599 | (if (= occur-num-matches 1) |
| 600 | "1 line" |
| 601 | (format "%d lines" occur-num-matches)))) |
| 602 | (insert message-string) |
| 603 | (if (interactive-p) |
| 604 | (message "%s matched" message-string))))))))) |
| 605 | \f |
| 606 | ;; It would be nice to use \\[...], but there is no reasonable way |
| 607 | ;; to make that display both SPC and Y. |
| 608 | (defconst query-replace-help |
| 609 | "Type Space or `y' to replace one match, Delete or `n' to skip to next, |
| 610 | RET or `q' to exit, Period to replace one match and exit, |
| 611 | Comma to replace but not move point immediately, |
| 612 | C-r to enter recursive edit (\\[exit-recursive-edit] to get out again), |
| 613 | C-w to delete match and recursive edit, |
| 614 | C-l to clear the screen, redisplay, and offer same replacement again, |
| 615 | ! to replace all remaining matches with no more questions, |
| 616 | ^ to move point back to previous match." |
| 617 | "Help message while in query-replace") |
| 618 | |
| 619 | (defvar query-replace-map (make-sparse-keymap) |
| 620 | "Keymap that defines the responses to questions in `query-replace'. |
| 621 | The \"bindings\" in this map are not commands; they are answers. |
| 622 | The valid answers include `act', `skip', `act-and-show', |
| 623 | `exit', `act-and-exit', `edit', `delete-and-edit', `recenter', |
| 624 | `automatic', `backup', `exit-prefix', and `help'.") |
| 625 | |
| 626 | (define-key query-replace-map " " 'act) |
| 627 | (define-key query-replace-map "\d" 'skip) |
| 628 | (define-key query-replace-map [delete] 'skip) |
| 629 | (define-key query-replace-map [backspace] 'skip) |
| 630 | (define-key query-replace-map "y" 'act) |
| 631 | (define-key query-replace-map "n" 'skip) |
| 632 | (define-key query-replace-map "Y" 'act) |
| 633 | (define-key query-replace-map "N" 'skip) |
| 634 | (define-key query-replace-map "," 'act-and-show) |
| 635 | (define-key query-replace-map "q" 'exit) |
| 636 | (define-key query-replace-map "\r" 'exit) |
| 637 | (define-key query-replace-map [return] 'exit) |
| 638 | (define-key query-replace-map "." 'act-and-exit) |
| 639 | (define-key query-replace-map "\C-r" 'edit) |
| 640 | (define-key query-replace-map "\C-w" 'delete-and-edit) |
| 641 | (define-key query-replace-map "\C-l" 'recenter) |
| 642 | (define-key query-replace-map "!" 'automatic) |
| 643 | (define-key query-replace-map "^" 'backup) |
| 644 | (define-key query-replace-map "\C-h" 'help) |
| 645 | (define-key query-replace-map [f1] 'help) |
| 646 | (define-key query-replace-map [help] 'help) |
| 647 | (define-key query-replace-map "?" 'help) |
| 648 | (define-key query-replace-map "\C-g" 'quit) |
| 649 | (define-key query-replace-map "\C-]" 'quit) |
| 650 | (define-key query-replace-map "\e" 'exit-prefix) |
| 651 | (define-key query-replace-map [escape] 'exit-prefix) |
| 652 | |
| 653 | (defun perform-replace (from-string replacements |
| 654 | query-flag regexp-flag delimited-flag |
| 655 | &optional repeat-count map) |
| 656 | "Subroutine of `query-replace'. Its complexity handles interactive queries. |
| 657 | Don't use this in your own program unless you want to query and set the mark |
| 658 | just as `query-replace' does. Instead, write a simple loop like this: |
| 659 | (while (re-search-forward \"foo[ \t]+bar\" nil t) |
| 660 | (replace-match \"foobar\" nil nil)) |
| 661 | which will run faster and probably do exactly what you want." |
| 662 | (or map (setq map query-replace-map)) |
| 663 | (and query-flag minibuffer-auto-raise |
| 664 | (raise-frame (window-frame (minibuffer-window)))) |
| 665 | (let ((nocasify (not (and case-fold-search case-replace |
| 666 | (string-equal from-string |
| 667 | (downcase from-string))))) |
| 668 | (literal (not regexp-flag)) |
| 669 | (search-function (if regexp-flag 're-search-forward 'search-forward)) |
| 670 | (search-string from-string) |
| 671 | (real-match-data nil) ; the match data for the current match |
| 672 | (next-replacement nil) |
| 673 | (replacement-index 0) |
| 674 | (keep-going t) |
| 675 | (stack nil) |
| 676 | (next-rotate-count 0) |
| 677 | (replace-count 0) |
| 678 | (nonempty-match nil) |
| 679 | |
| 680 | ;; If non-nil, it is marker saying where in the buffer to stop. |
| 681 | (limit nil) |
| 682 | |
| 683 | ;; Data for the next match. If a cons, it has the same format as |
| 684 | ;; (match-data); otherwise it is t if a match is possible at point. |
| 685 | (match-again t) |
| 686 | |
| 687 | (message |
| 688 | (if query-flag |
| 689 | (substitute-command-keys |
| 690 | "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) ")))) |
| 691 | |
| 692 | ;; If region is active, in Transient Mark mode, operate on region. |
| 693 | (if (and transient-mark-mode mark-active) |
| 694 | (progn |
| 695 | (setq limit (copy-marker (region-end))) |
| 696 | (goto-char (region-beginning)) |
| 697 | (deactivate-mark))) |
| 698 | (if (stringp replacements) |
| 699 | (setq next-replacement replacements) |
| 700 | (or repeat-count (setq repeat-count 1))) |
| 701 | (if delimited-flag |
| 702 | (setq search-function 're-search-forward |
| 703 | search-string (concat "\\b" |
| 704 | (if regexp-flag from-string |
| 705 | (regexp-quote from-string)) |
| 706 | "\\b"))) |
| 707 | (push-mark) |
| 708 | (undo-boundary) |
| 709 | (unwind-protect |
| 710 | ;; Loop finding occurrences that perhaps should be replaced. |
| 711 | (while (and keep-going |
| 712 | (not (eobp)) |
| 713 | ;; Use the next match if it is already known; |
| 714 | ;; otherwise, search for a match after moving forward |
| 715 | ;; one char if progress is required. |
| 716 | (setq real-match-data |
| 717 | (if (consp match-again) |
| 718 | (progn (goto-char (nth 1 match-again)) |
| 719 | match-again) |
| 720 | (and (or match-again |
| 721 | (progn |
| 722 | (forward-char 1) |
| 723 | (not (eobp)))) |
| 724 | (funcall search-function search-string limit t) |
| 725 | ;; For speed, use only integers and |
| 726 | ;; reuse the list used last time. |
| 727 | (match-data t real-match-data))))) |
| 728 | |
| 729 | ;; Record whether the match is nonempty, to avoid an infinite loop |
| 730 | ;; repeatedly matching the same empty string. |
| 731 | (setq nonempty-match |
| 732 | (/= (nth 0 real-match-data) (nth 1 real-match-data))) |
| 733 | |
| 734 | ;; If the match is empty, record that the next one can't be adjacent. |
| 735 | ;; Otherwise, if matching a regular expression, do the next |
| 736 | ;; match now, since the replacement for this match may |
| 737 | ;; affect whether the next match is adjacent to this one. |
| 738 | (setq match-again |
| 739 | (and nonempty-match |
| 740 | (or (not regexp-flag) |
| 741 | (and (looking-at search-string) |
| 742 | (match-data))))) |
| 743 | |
| 744 | ;; If time for a change, advance to next replacement string. |
| 745 | (if (and (listp replacements) |
| 746 | (= next-rotate-count replace-count)) |
| 747 | (progn |
| 748 | (setq next-rotate-count |
| 749 | (+ next-rotate-count repeat-count)) |
| 750 | (setq next-replacement (nth replacement-index replacements)) |
| 751 | (setq replacement-index (% (1+ replacement-index) (length replacements))))) |
| 752 | (if (not query-flag) |
| 753 | (progn |
| 754 | (store-match-data real-match-data) |
| 755 | (replace-match next-replacement nocasify literal) |
| 756 | (setq replace-count (1+ replace-count))) |
| 757 | (undo-boundary) |
| 758 | (let (done replaced key def) |
| 759 | ;; Loop reading commands until one of them sets done, |
| 760 | ;; which means it has finished handling this occurrence. |
| 761 | (while (not done) |
| 762 | (store-match-data real-match-data) |
| 763 | (replace-highlight (match-beginning 0) (match-end 0)) |
| 764 | ;; Bind message-log-max so we don't fill up the message log |
| 765 | ;; with a bunch of identical messages. |
| 766 | (let ((message-log-max nil)) |
| 767 | (message message from-string next-replacement)) |
| 768 | (setq key (read-event)) |
| 769 | ;; Necessary in case something happens during read-event |
| 770 | ;; that clobbers the match data. |
| 771 | (store-match-data real-match-data) |
| 772 | (setq key (vector key)) |
| 773 | (setq def (lookup-key map key)) |
| 774 | ;; Restore the match data while we process the command. |
| 775 | (cond ((eq def 'help) |
| 776 | (with-output-to-temp-buffer "*Help*" |
| 777 | (princ |
| 778 | (concat "Query replacing " |
| 779 | (if regexp-flag "regexp " "") |
| 780 | from-string " with " |
| 781 | next-replacement ".\n\n" |
| 782 | (substitute-command-keys |
| 783 | query-replace-help))) |
| 784 | (save-excursion |
| 785 | (set-buffer standard-output) |
| 786 | (help-mode)))) |
| 787 | ((eq def 'exit) |
| 788 | (setq keep-going nil) |
| 789 | (setq done t)) |
| 790 | ((eq def 'backup) |
| 791 | (if stack |
| 792 | (let ((elt (car stack))) |
| 793 | (goto-char (car elt)) |
| 794 | (setq replaced (eq t (cdr elt))) |
| 795 | (or replaced |
| 796 | (store-match-data (cdr elt))) |
| 797 | (setq stack (cdr stack))) |
| 798 | (message "No previous match") |
| 799 | (ding 'no-terminate) |
| 800 | (sit-for 1))) |
| 801 | ((eq def 'act) |
| 802 | (or replaced |
| 803 | (progn |
| 804 | (replace-match next-replacement nocasify literal) |
| 805 | (setq replace-count (1+ replace-count)))) |
| 806 | (setq done t replaced t)) |
| 807 | ((eq def 'act-and-exit) |
| 808 | (or replaced |
| 809 | (progn |
| 810 | (replace-match next-replacement nocasify literal) |
| 811 | (setq replace-count (1+ replace-count)))) |
| 812 | (setq keep-going nil) |
| 813 | (setq done t replaced t)) |
| 814 | ((eq def 'act-and-show) |
| 815 | (if (not replaced) |
| 816 | (progn |
| 817 | (replace-match next-replacement nocasify literal) |
| 818 | (setq replace-count (1+ replace-count)) |
| 819 | (setq replaced t)))) |
| 820 | ((eq def 'automatic) |
| 821 | (or replaced |
| 822 | (progn |
| 823 | (replace-match next-replacement nocasify literal) |
| 824 | (setq replace-count (1+ replace-count)))) |
| 825 | (setq done t query-flag nil replaced t)) |
| 826 | ((eq def 'skip) |
| 827 | (setq done t)) |
| 828 | ((eq def 'recenter) |
| 829 | (recenter nil)) |
| 830 | ((eq def 'edit) |
| 831 | (store-match-data |
| 832 | (prog1 (match-data) |
| 833 | (save-excursion (recursive-edit)))) |
| 834 | ;; Before we make the replacement, |
| 835 | ;; decide whether the search string |
| 836 | ;; can match again just after this match. |
| 837 | (if (and regexp-flag nonempty-match) |
| 838 | (setq match-again (and (looking-at search-string) |
| 839 | (match-data))))) |
| 840 | ((eq def 'delete-and-edit) |
| 841 | (delete-region (match-beginning 0) (match-end 0)) |
| 842 | (store-match-data |
| 843 | (prog1 (match-data) |
| 844 | (save-excursion (recursive-edit)))) |
| 845 | (setq replaced t)) |
| 846 | ;; Note: we do not need to treat `exit-prefix' |
| 847 | ;; specially here, since we reread |
| 848 | ;; any unrecognized character. |
| 849 | (t |
| 850 | (setq this-command 'mode-exited) |
| 851 | (setq keep-going nil) |
| 852 | (setq unread-command-events |
| 853 | (append (listify-key-sequence key) |
| 854 | unread-command-events)) |
| 855 | (setq done t)))) |
| 856 | ;; Record previous position for ^ when we move on. |
| 857 | ;; Change markers to numbers in the match data |
| 858 | ;; since lots of markers slow down editing. |
| 859 | (setq stack |
| 860 | (cons (cons (point) |
| 861 | (or replaced (match-data t))) |
| 862 | stack))))) |
| 863 | (replace-dehighlight)) |
| 864 | (or unread-command-events |
| 865 | (message "Replaced %d occurrence%s" |
| 866 | replace-count |
| 867 | (if (= replace-count 1) "" "s"))) |
| 868 | (and keep-going stack))) |
| 869 | |
| 870 | (defcustom query-replace-highlight t |
| 871 | "*Non-nil means to highlight words during query replacement." |
| 872 | :type 'boolean |
| 873 | :group 'matching) |
| 874 | |
| 875 | (defvar replace-overlay nil) |
| 876 | |
| 877 | (defun replace-dehighlight () |
| 878 | (and replace-overlay |
| 879 | (progn |
| 880 | (delete-overlay replace-overlay) |
| 881 | (setq replace-overlay nil)))) |
| 882 | |
| 883 | (defun replace-highlight (start end) |
| 884 | (and query-replace-highlight |
| 885 | (progn |
| 886 | (or replace-overlay |
| 887 | (progn |
| 888 | (setq replace-overlay (make-overlay start end)) |
| 889 | (overlay-put replace-overlay 'face |
| 890 | (if (internal-find-face 'query-replace) |
| 891 | 'query-replace 'region)))) |
| 892 | (move-overlay replace-overlay start end (current-buffer))))) |
| 893 | |
| 894 | ;;; replace.el ends here |