| 1 | ;;; compare-w.el --- compare text between windows for Emacs. |
| 2 | |
| 3 | ;; Copyright (C) 1986, 1989, 1993 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Maintainer: FSF |
| 6 | |
| 7 | ;; This file is part of GNU Emacs. |
| 8 | |
| 9 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 10 | ;; it under the terms of the GNU General Public License as published by |
| 11 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 12 | ;; any later version. |
| 13 | |
| 14 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 15 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 16 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 17 | ;; GNU General Public License for more details. |
| 18 | |
| 19 | ;; You should have received a copy of the GNU General Public License |
| 20 | ;; along with GNU Emacs; see the file COPYING. If not, write to |
| 21 | ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA. |
| 22 | |
| 23 | ;;; Commentary: |
| 24 | |
| 25 | ;; This package provides one entry point, compare-windows. It compares |
| 26 | ;; text starting from point in two adjacent windows, advancing point |
| 27 | ;; until it finds a difference. Option variables permit you to ignore |
| 28 | ;; whitespace differences, or case differences, or both. |
| 29 | |
| 30 | ;;; Code: |
| 31 | |
| 32 | (defvar compare-windows-whitespace "[ \t\n]+" |
| 33 | "*Regexp that defines whitespace sequences for \\[compare-windows]. |
| 34 | Changes in whitespace are optionally ignored. |
| 35 | |
| 36 | The value of `compare-windows-whitespace' may instead be a function; this |
| 37 | function is called in each buffer, with point at the current scanning point. |
| 38 | The function's job is to categorize any whitespace around (including before) |
| 39 | point; it should also advance past any whitespace. |
| 40 | |
| 41 | The function is passed one argument, the point where `compare-windows' |
| 42 | was originally called; it should not consider any text before that point. |
| 43 | If the function returns the same value for both buffers, then the |
| 44 | whitespace is considered to match, and is skipped.") |
| 45 | |
| 46 | (defvar compare-ignore-case nil |
| 47 | "*Non-nil means \\[compare-windows] ignores case differences.") |
| 48 | |
| 49 | ;;;###autoload |
| 50 | (defun compare-windows (ignore-whitespace) |
| 51 | "Compare text in current window with text in next window. |
| 52 | Compares the text starting at point in each window, |
| 53 | moving over text in each one as far as they match. |
| 54 | |
| 55 | This command pushes the mark in each window |
| 56 | at the prior location of point in that window. |
| 57 | If both windows display the same buffer, |
| 58 | the mark is pushed twice in that buffer: |
| 59 | first in the other window, then in the selected window. |
| 60 | |
| 61 | A prefix arg means ignore changes in whitespace. |
| 62 | The variable `compare-windows-whitespace' controls how whitespace is skipped. |
| 63 | If `compare-ignore-case' is non-nil, changes in case are also ignored." |
| 64 | (interactive "P") |
| 65 | (let* (p1 p2 maxp1 maxp2 b1 b2 w2 |
| 66 | success size |
| 67 | (opoint1 (point)) |
| 68 | opoint2 |
| 69 | (skip-whitespace (if ignore-whitespace |
| 70 | compare-windows-whitespace))) |
| 71 | (setq p1 (point) b1 (current-buffer)) |
| 72 | (setq w2 (next-window (selected-window))) |
| 73 | (if (eq w2 (selected-window)) |
| 74 | (error "No other window")) |
| 75 | (setq p2 (window-point w2) |
| 76 | b2 (window-buffer w2)) |
| 77 | (setq opoint2 p2) |
| 78 | (setq maxp1 (point-max)) |
| 79 | (save-excursion |
| 80 | (set-buffer b2) |
| 81 | (push-mark p2 t) |
| 82 | (setq maxp2 (point-max))) |
| 83 | (push-mark) |
| 84 | |
| 85 | (setq success t) |
| 86 | (while success |
| 87 | (setq success nil) |
| 88 | ;; if interrupted, show how far we've gotten |
| 89 | (goto-char p1) |
| 90 | (set-window-point w2 p2) |
| 91 | |
| 92 | ;; If both buffers have whitespace next to point, |
| 93 | ;; optionally skip over it. |
| 94 | |
| 95 | (and skip-whitespace |
| 96 | (save-excursion |
| 97 | (let (p1a p2a w1 w2 result1 result2) |
| 98 | (setq result1 |
| 99 | (if (stringp skip-whitespace) |
| 100 | (compare-windows-skip-whitespace opoint1) |
| 101 | (funcall skip-whitespace opoint1))) |
| 102 | (setq p1a (point)) |
| 103 | (set-buffer b2) |
| 104 | (goto-char p2) |
| 105 | (setq result2 |
| 106 | (if (stringp skip-whitespace) |
| 107 | (compare-windows-skip-whitespace opoint2) |
| 108 | (funcall skip-whitespace opoint2))) |
| 109 | (setq p2a (point)) |
| 110 | (if (or (stringp skip-whitespace) |
| 111 | (and result1 result2 (eq result1 result2))) |
| 112 | (setq p1 p1a |
| 113 | p2 p2a))))) |
| 114 | |
| 115 | ;; Try advancing comparing 1000 chars at a time. |
| 116 | ;; When that fails, go 500 chars at a time, and so on. |
| 117 | (let ((size 1000) |
| 118 | success-1 |
| 119 | (case-fold-search compare-ignore-case)) |
| 120 | (while (> size 0) |
| 121 | (setq success-1 t) |
| 122 | ;; Try comparing SIZE chars at a time, repeatedly, till that fails. |
| 123 | (while success-1 |
| 124 | (setq size (min size (- maxp1 p1) (- maxp2 p2))) |
| 125 | (setq success-1 |
| 126 | (and (> size 0) |
| 127 | (= 0 (compare-buffer-substrings b2 p2 (+ size p2) |
| 128 | b1 p1 (+ size p1))))) |
| 129 | (if success-1 |
| 130 | (setq p1 (+ p1 size) p2 (+ p2 size) |
| 131 | success t))) |
| 132 | ;; If SIZE chars don't match, try fewer. |
| 133 | (setq size (/ size 2))))) |
| 134 | |
| 135 | (goto-char p1) |
| 136 | (set-window-point w2 p2) |
| 137 | (if (= (point) opoint1) |
| 138 | (ding)))) |
| 139 | |
| 140 | ;; Move forward over whatever might be called whitespace. |
| 141 | ;; compare-windows-whitespace is a regexp that matches whitespace. |
| 142 | ;; Match it at various starting points before the original point |
| 143 | ;; and find the latest point at which a match ends. |
| 144 | ;; Don't try starting points before START, though. |
| 145 | ;; Value is non-nil if whitespace is found. |
| 146 | |
| 147 | ;; If there is whitespace before point, but none after, |
| 148 | ;; then return t, but don't advance point. |
| 149 | (defun compare-windows-skip-whitespace (start) |
| 150 | (let ((end (point)) |
| 151 | (beg (point)) |
| 152 | (opoint (point))) |
| 153 | (while (or (and (looking-at compare-windows-whitespace) |
| 154 | (<= end (match-end 0)) |
| 155 | ;; This match goes past END, so advance END. |
| 156 | (progn (setq end (match-end 0)) |
| 157 | (> (point) start))) |
| 158 | (and (/= (point) start) |
| 159 | ;; Consider at least the char before point, |
| 160 | ;; unless it is also before START. |
| 161 | (= (point) opoint))) |
| 162 | ;; keep going back until whitespace |
| 163 | ;; doesn't extend to or past end |
| 164 | (forward-char -1)) |
| 165 | (setq beg (point)) |
| 166 | (goto-char end) |
| 167 | (or (/= beg opoint) |
| 168 | (/= end opoint)))) |
| 169 | |
| 170 | (provide 'compare-w) |
| 171 | |
| 172 | ;;; compare-w.el ends here |