| 1 | ;;; replace.el --- replace commands for Emacs. |
| 2 | |
| 3 | ;; Copyright (C) 1985, 1986, 1987, 1992 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; This file is part of GNU Emacs. |
| 6 | |
| 7 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 8 | ;; it under the terms of the GNU General Public License as published by |
| 9 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 10 | ;; any later version. |
| 11 | |
| 12 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 13 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 14 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 15 | ;; GNU General Public License for more details. |
| 16 | |
| 17 | ;; You should have received a copy of the GNU General Public License |
| 18 | ;; along with GNU Emacs; see the file COPYING. If not, write to |
| 19 | ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA. |
| 20 | |
| 21 | ;;; Commentary: |
| 22 | |
| 23 | ;; This package supplies the string and regular-expression replace functions |
| 24 | ;; documented in the Emacs user's manual. |
| 25 | |
| 26 | ;;; Code: |
| 27 | |
| 28 | (defconst case-replace t "\ |
| 29 | *Non-nil means query-replace should preserve case in replacements.") |
| 30 | |
| 31 | (defvar query-replace-history nil) |
| 32 | |
| 33 | (defun query-replace-read-args (string) |
| 34 | (let (from to) |
| 35 | (setq from (read-from-minibuffer (format "%s: " string) |
| 36 | nil nil nil |
| 37 | 'query-replace-history)) |
| 38 | (setq to (read-from-minibuffer (format "%s %s with: " string from) |
| 39 | nil nil nil |
| 40 | 'query-replace-history)) |
| 41 | (list from to current-prefix-arg))) |
| 42 | |
| 43 | (defun query-replace (from-string to-string &optional arg) |
| 44 | "Replace some occurrences of FROM-STRING with TO-STRING. |
| 45 | As each match is found, the user must type a character saying |
| 46 | what to do with it. For directions, type \\[help-command] at that time. |
| 47 | |
| 48 | Preserves case in each replacement if case-replace and case-fold-search |
| 49 | are non-nil and FROM-STRING has no uppercase letters. |
| 50 | Third arg DELIMITED (prefix arg if interactive) non-nil means replace |
| 51 | only matches surrounded by word boundaries. |
| 52 | |
| 53 | To customize possible responses, change the \"bindings\" in `query-replace-map'." |
| 54 | (interactive (query-replace-read-args "Query replace")) |
| 55 | (perform-replace from-string to-string t nil arg) |
| 56 | (or unread-command-events (message "Done"))) |
| 57 | (define-key esc-map "%" 'query-replace) |
| 58 | |
| 59 | (defun query-replace-regexp (regexp to-string &optional arg) |
| 60 | "Replace some things after point matching REGEXP with TO-STRING. |
| 61 | As each match is found, the user must type a character saying |
| 62 | what to do with it. For directions, type \\[help-command] at that time. |
| 63 | |
| 64 | Preserves case in each replacement if case-replace and case-fold-search |
| 65 | are non-nil and REGEXP has no uppercase letters. |
| 66 | Third arg DELIMITED (prefix arg if interactive) non-nil means replace |
| 67 | only matches surrounded by word boundaries. |
| 68 | In TO-STRING, \\& means insert what matched REGEXP, |
| 69 | and \\=\\<n> means insert what matched <n>th \\(...\\) in REGEXP." |
| 70 | (interactive (query-replace-read-args "Query replace regexp")) |
| 71 | (perform-replace regexp to-string t t arg) |
| 72 | (or unread-command-events (message "Done"))) |
| 73 | |
| 74 | (defun map-query-replace-regexp (regexp to-strings &optional arg) |
| 75 | "Replace some matches for REGEXP with various strings, in rotation. |
| 76 | The second argument TO-STRINGS contains the replacement strings, separated |
| 77 | by spaces. This command works like `query-replace-regexp' except |
| 78 | that each successive replacement uses the next successive replacement string, |
| 79 | wrapping around from the last such string to the first. |
| 80 | |
| 81 | Non-interactively, TO-STRINGS may be a list of replacement strings. |
| 82 | |
| 83 | A prefix argument N says to use each replacement string N times |
| 84 | before rotating to the next." |
| 85 | (interactive |
| 86 | (let (from to) |
| 87 | (setq from (read-from-minibuffer "Map query replace (regexp): " |
| 88 | nil nil nil |
| 89 | 'query-replace-history)) |
| 90 | (setq to (read-from-minibuffer |
| 91 | (format "Query replace %s with (space-separated strings): " |
| 92 | from) |
| 93 | nil nil nil |
| 94 | 'query-replace-history)) |
| 95 | (list from to current-prefix-arg))) |
| 96 | (let (replacements) |
| 97 | (if (listp to-strings) |
| 98 | (setq replacements to-strings) |
| 99 | (while (/= (length to-strings) 0) |
| 100 | (if (string-match " " to-strings) |
| 101 | (setq replacements |
| 102 | (append replacements |
| 103 | (list (substring to-strings 0 |
| 104 | (string-match " " to-strings)))) |
| 105 | to-strings (substring to-strings |
| 106 | (1+ (string-match " " to-strings)))) |
| 107 | (setq replacements (append replacements (list to-strings)) |
| 108 | to-strings "")))) |
| 109 | (perform-replace regexp replacements t t nil arg)) |
| 110 | (or unread-command-events (message "Done"))) |
| 111 | |
| 112 | (defun replace-string (from-string to-string &optional delimited) |
| 113 | "Replace occurrences of FROM-STRING with TO-STRING. |
| 114 | Preserve case in each match if `case-replace' and `case-fold-search' |
| 115 | are non-nil and FROM-STRING has no uppercase letters. |
| 116 | Third arg DELIMITED (prefix arg if interactive) non-nil means replace |
| 117 | only matches surrounded by word boundaries. |
| 118 | |
| 119 | This function is usually the wrong thing to use in a Lisp program. |
| 120 | What you probably want is a loop like this: |
| 121 | (while (search-forward OLD-STRING nil t) |
| 122 | (replace-match REPLACEMENT nil t)) |
| 123 | which will run faster and will not set the mark or print anything." |
| 124 | (interactive (query-replace-read-args "Replace string")) |
| 125 | (perform-replace from-string to-string nil nil delimited) |
| 126 | (or unread-command-events (message "Done"))) |
| 127 | |
| 128 | (defun replace-regexp (regexp to-string &optional delimited) |
| 129 | "Replace things after point matching REGEXP with TO-STRING. |
| 130 | Preserve case in each match if case-replace and case-fold-search |
| 131 | are non-nil and REGEXP has no uppercase letters. |
| 132 | Third arg DELIMITED (prefix arg if interactive) non-nil means replace |
| 133 | only matches surrounded by word boundaries. |
| 134 | In TO-STRING, \\& means insert what matched REGEXP, |
| 135 | and \\=\\<n> means insert what matched <n>th \\(...\\) in REGEXP. |
| 136 | |
| 137 | This function is usually the wrong thing to use in a Lisp program. |
| 138 | What you probably want is a loop like this: |
| 139 | (while (re-search-forward REGEXP nil t) |
| 140 | (replace-match REPLACEMENT nil nil)) |
| 141 | which will run faster and will not set the mark or print anything." |
| 142 | (interactive (query-replace-read-args "Replace regexp")) |
| 143 | (perform-replace regexp to-string nil t delimited) |
| 144 | (or unread-command-events (message "Done"))) |
| 145 | |
| 146 | (fset 'delete-non-matching-lines 'keep-lines) |
| 147 | (defun keep-lines (regexp) |
| 148 | "Delete all lines except those containing matches for REGEXP. |
| 149 | A match split across lines preserves all the lines it lies in. |
| 150 | Applies to all lines after point." |
| 151 | (interactive "sKeep lines (containing match for regexp): ") |
| 152 | (save-excursion |
| 153 | (or (bolp) (forward-line 1)) |
| 154 | (let ((start (point))) |
| 155 | (while (not (eobp)) |
| 156 | ;; Start is first char not preserved by previous match. |
| 157 | (if (not (re-search-forward regexp nil 'move)) |
| 158 | (delete-region start (point-max)) |
| 159 | (let ((end (save-excursion (goto-char (match-beginning 0)) |
| 160 | (beginning-of-line) |
| 161 | (point)))) |
| 162 | ;; Now end is first char preserved by the new match. |
| 163 | (if (< start end) |
| 164 | (delete-region start end)))) |
| 165 | (setq start (save-excursion (forward-line 1) |
| 166 | (point))) |
| 167 | ;; If the match was empty, avoid matching again at same place. |
| 168 | (and (not (eobp)) (= (match-beginning 0) (match-end 0)) |
| 169 | (forward-char 1)))))) |
| 170 | |
| 171 | (fset 'delete-matching-lines 'flush-lines) |
| 172 | (defun flush-lines (regexp) |
| 173 | "Delete lines containing matches for REGEXP. |
| 174 | If a match is split across lines, all the lines it lies in are deleted. |
| 175 | Applies to lines after point." |
| 176 | (interactive "sFlush lines (containing match for regexp): ") |
| 177 | (save-excursion |
| 178 | (while (and (not (eobp)) |
| 179 | (re-search-forward regexp nil t)) |
| 180 | (delete-region (save-excursion (goto-char (match-beginning 0)) |
| 181 | (beginning-of-line) |
| 182 | (point)) |
| 183 | (progn (forward-line 1) (point)))))) |
| 184 | |
| 185 | (fset 'count-matches 'how-many) |
| 186 | (defun how-many (regexp) |
| 187 | "Print number of matches for REGEXP following point." |
| 188 | (interactive "sHow many matches for (regexp): ") |
| 189 | (let ((count 0) opoint) |
| 190 | (save-excursion |
| 191 | (while (and (not (eobp)) |
| 192 | (progn (setq opoint (point)) |
| 193 | (re-search-forward regexp nil t))) |
| 194 | (if (= opoint (point)) |
| 195 | (forward-char 1) |
| 196 | (setq count (1+ count)))) |
| 197 | (message "%d occurrences" count)))) |
| 198 | |
| 199 | (defvar occur-mode-map ()) |
| 200 | (if occur-mode-map |
| 201 | () |
| 202 | (setq occur-mode-map (make-sparse-keymap)) |
| 203 | (define-key occur-mode-map "\C-c\C-c" 'occur-mode-goto-occurrence)) |
| 204 | |
| 205 | (defvar occur-buffer nil) |
| 206 | (defvar occur-nlines nil) |
| 207 | (defvar occur-pos-list nil) |
| 208 | (defvar occur-last-string "") |
| 209 | |
| 210 | (defun occur-mode () |
| 211 | "Major mode for output from \\[occur]. |
| 212 | Move point to one of the occurrences in this buffer, |
| 213 | then use \\[occur-mode-goto-occurrence] to go to the same occurrence |
| 214 | in the buffer that the occurrences were found in. |
| 215 | \\{occur-mode-map}" |
| 216 | (kill-all-local-variables) |
| 217 | (use-local-map occur-mode-map) |
| 218 | (setq major-mode 'occur-mode) |
| 219 | (setq mode-name "Occur") |
| 220 | (make-local-variable 'occur-buffer) |
| 221 | (make-local-variable 'occur-nlines) |
| 222 | (make-local-variable 'occur-pos-list)) |
| 223 | |
| 224 | (defun occur-mode-goto-occurrence () |
| 225 | "Go to the line this occurrence was found in, in the buffer it was found in." |
| 226 | (interactive) |
| 227 | (if (or (null occur-buffer) |
| 228 | (null (buffer-name occur-buffer))) |
| 229 | (progn |
| 230 | (setq occur-buffer nil |
| 231 | occur-pos-list nil) |
| 232 | (error "Buffer in which occurrences were found is deleted"))) |
| 233 | (let* ((occur-number (save-excursion |
| 234 | (beginning-of-line) |
| 235 | (/ (1- (count-lines (point-min) |
| 236 | (save-excursion |
| 237 | (beginning-of-line) |
| 238 | (point)))) |
| 239 | (cond ((< occur-nlines 0) |
| 240 | (- 2 occur-nlines)) |
| 241 | ((> occur-nlines 0) |
| 242 | (+ 2 (* 2 occur-nlines))) |
| 243 | (t 1))))) |
| 244 | (pos (nth occur-number occur-pos-list))) |
| 245 | (pop-to-buffer occur-buffer) |
| 246 | (goto-char (marker-position pos)))) |
| 247 | |
| 248 | (defvar list-matching-lines-default-context-lines 0 |
| 249 | "*Default number of context lines to include around a `list-matching-lines' |
| 250 | match. A negative number means to include that many lines before the match. |
| 251 | A positive number means to include that many lines both before and after.") |
| 252 | |
| 253 | (fset 'list-matching-lines 'occur) |
| 254 | |
| 255 | (defun occur (regexp &optional nlines) |
| 256 | "Show all lines in the current buffer containing a match for REGEXP. |
| 257 | Interactively, REGEXP defaults to the last REGEXP |
| 258 | used interactively with \\[occur]. |
| 259 | |
| 260 | If a match spreads across multiple lines, all those lines are shown. |
| 261 | |
| 262 | Each line is displayed with NLINES lines before and after, or -NLINES |
| 263 | before if NLINES is negative. |
| 264 | NLINES defaults to `list-matching-lines-default-context-lines'. |
| 265 | Interactively it is the prefix arg. |
| 266 | |
| 267 | The lines are shown in a buffer named *Occur*. |
| 268 | It serves as a menu to find any of the occurrences in this buffer. |
| 269 | \\[describe-mode] in that buffer will explain how." |
| 270 | (interactive (list (setq occur-last-string |
| 271 | (read-string "List lines matching regexp: " |
| 272 | occur-last-string)) |
| 273 | current-prefix-arg)) |
| 274 | (setq nlines (if nlines (prefix-numeric-value nlines) |
| 275 | list-matching-lines-default-context-lines)) |
| 276 | (let ((first t) |
| 277 | (buffer (current-buffer)) |
| 278 | (linenum 1) |
| 279 | (prevpos (point-min)) |
| 280 | (final-context-start (make-marker))) |
| 281 | ;;; (save-excursion |
| 282 | ;;; (beginning-of-line) |
| 283 | ;;; (setq linenum (1+ (count-lines (point-min) (point)))) |
| 284 | ;;; (setq prevpos (point))) |
| 285 | (with-output-to-temp-buffer "*Occur*" |
| 286 | (save-excursion |
| 287 | (set-buffer standard-output) |
| 288 | (insert "Lines matching ") |
| 289 | (prin1 regexp) |
| 290 | (insert " in buffer " (buffer-name buffer) ?. ?\n) |
| 291 | (occur-mode) |
| 292 | (setq occur-buffer buffer) |
| 293 | (setq occur-nlines nlines) |
| 294 | (setq occur-pos-list ())) |
| 295 | (if (eq buffer standard-output) |
| 296 | (goto-char (point-max))) |
| 297 | (save-excursion |
| 298 | (beginning-of-buffer) |
| 299 | ;; Find next match, but give up if prev match was at end of buffer. |
| 300 | (while (and (not (= prevpos (point-max))) |
| 301 | (re-search-forward regexp nil t)) |
| 302 | (goto-char (match-beginning 0)) |
| 303 | (beginning-of-line) |
| 304 | (setq linenum (+ linenum (count-lines prevpos (point)))) |
| 305 | (setq prevpos (point)) |
| 306 | (goto-char (match-end 0)) |
| 307 | (let* ((start (save-excursion |
| 308 | (goto-char (match-beginning 0)) |
| 309 | (forward-line (if (< nlines 0) nlines (- nlines))) |
| 310 | (point))) |
| 311 | (end (save-excursion |
| 312 | (goto-char (match-end 0)) |
| 313 | (if (> nlines 0) |
| 314 | (forward-line (1+ nlines)) |
| 315 | (forward-line 1)) |
| 316 | (point))) |
| 317 | (tag (format "%3d" linenum)) |
| 318 | (empty (make-string (length tag) ?\ )) |
| 319 | tem) |
| 320 | (save-excursion |
| 321 | (setq tem (make-marker)) |
| 322 | (set-marker tem (point)) |
| 323 | (set-buffer standard-output) |
| 324 | (setq occur-pos-list (cons tem occur-pos-list)) |
| 325 | (or first (zerop nlines) |
| 326 | (insert "--------\n")) |
| 327 | (setq first nil) |
| 328 | (insert-buffer-substring buffer start end) |
| 329 | (backward-char (- end start)) |
| 330 | (setq tem nlines) |
| 331 | (while (> tem 0) |
| 332 | (insert empty ?:) |
| 333 | (forward-line 1) |
| 334 | (setq tem (1- tem))) |
| 335 | (let ((this-linenum linenum)) |
| 336 | (set-marker final-context-start |
| 337 | (+ (point) (- (match-end 0) (match-beginning 0)))) |
| 338 | (while (< (point) final-context-start) |
| 339 | (if (null tag) |
| 340 | (setq tag (format "%3d" this-linenum))) |
| 341 | (insert tag ?:) |
| 342 | (setq tag nil) |
| 343 | (forward-line 1) |
| 344 | (setq this-linenum (1+ this-linenum)))) |
| 345 | (while (< tem nlines) |
| 346 | (insert empty ?:) |
| 347 | (forward-line 1) |
| 348 | (setq tem (1+ tem)))) |
| 349 | (forward-line 1))) |
| 350 | (set-buffer standard-output) |
| 351 | ;; Put positions in increasing order to go with buffer. |
| 352 | (setq occur-pos-list (nreverse occur-pos-list)) |
| 353 | (if (interactive-p) |
| 354 | (message "%d matching lines." (length occur-pos-list))))))) |
| 355 | \f |
| 356 | ;; It would be nice to use \\[...], but there is no reasonable way |
| 357 | ;; to make that display both SPC and Y. |
| 358 | (defconst query-replace-help |
| 359 | "Type Space or `y' to replace one match, Delete or `n' to skip to next, |
| 360 | ESC or `q' to exit, Period to replace one match and exit, |
| 361 | Comma to replace but not move point immediately, |
| 362 | C-r to enter recursive edit (\\[exit-recursive-edit] to get out again), |
| 363 | C-w to delete match and recursive edit, |
| 364 | C-l to clear the screen, redisplay, and offer same replacement again, |
| 365 | ! to replace all remaining matches with no more questions, |
| 366 | ^ to move point back to previous match." |
| 367 | "Help message while in query-replace") |
| 368 | |
| 369 | (defvar query-replace-map (make-sparse-keymap) |
| 370 | "Keymap that defines the responses to questions in `query-replace'. |
| 371 | The \"bindings\" in this map are not commands; they are answers. |
| 372 | The valid answers include `act', `skip', `act-and-show', |
| 373 | `exit', `act-and-exit', `edit', `delete-and-edit', `recenter', |
| 374 | `automatic', `backup', and `help'.") |
| 375 | |
| 376 | (define-key query-replace-map " " 'act) |
| 377 | (define-key query-replace-map "\d" 'skip) |
| 378 | (define-key query-replace-map [delete] 'skip) |
| 379 | (define-key query-replace-map "y" 'act) |
| 380 | (define-key query-replace-map "n" 'skip) |
| 381 | (define-key query-replace-map "," 'act-and-show) |
| 382 | (define-key query-replace-map "\e" 'exit) |
| 383 | (define-key query-replace-map "q" 'exit) |
| 384 | (define-key query-replace-map "." 'act-and-exit) |
| 385 | (define-key query-replace-map "\C-r" 'edit) |
| 386 | (define-key query-replace-map "\C-w" 'delete-and-edit) |
| 387 | (define-key query-replace-map "\C-l" 'recenter) |
| 388 | (define-key query-replace-map "!" 'automatic) |
| 389 | (define-key query-replace-map "^" 'backup) |
| 390 | (define-key query-replace-map "\C-h" 'help) |
| 391 | (define-key query-replace-map "?" 'help) |
| 392 | (define-key query-replace-map "\C-g" 'quit) |
| 393 | (define-key query-replace-map "\C-]" 'quit) |
| 394 | |
| 395 | (defun perform-replace (from-string replacements |
| 396 | query-flag regexp-flag delimited-flag |
| 397 | &optional repeat-count map) |
| 398 | "Subroutine of `query-replace'. Its complexity handles interactive queries. |
| 399 | Don't use this in your own program unless you want to query and set the mark |
| 400 | just as `query-replace' does. Instead, write a simple loop like this: |
| 401 | (while (re-search-forward \"foo[ \t]+bar\" nil t) |
| 402 | (replace-match \"foobar\" nil nil)) |
| 403 | which will run faster and do exactly what you probably want." |
| 404 | (or map (setq map query-replace-map)) |
| 405 | (let ((nocasify (not (and case-fold-search case-replace |
| 406 | (string-equal from-string |
| 407 | (downcase from-string))))) |
| 408 | (literal (not regexp-flag)) |
| 409 | (search-function (if regexp-flag 're-search-forward 'search-forward)) |
| 410 | (search-string from-string) |
| 411 | (real-match-data nil) ; the match data for the current match |
| 412 | (next-replacement nil) |
| 413 | (replacement-index 0) |
| 414 | (keep-going t) |
| 415 | (stack nil) |
| 416 | (next-rotate-count 0) |
| 417 | (replace-count 0) |
| 418 | (lastrepl nil) ;Position after last match considered. |
| 419 | (match-again t)) |
| 420 | (if (stringp replacements) |
| 421 | (setq next-replacement replacements) |
| 422 | (or repeat-count (setq repeat-count 1))) |
| 423 | (if delimited-flag |
| 424 | (setq search-function 're-search-forward |
| 425 | search-string (concat "\\b" |
| 426 | (if regexp-flag from-string |
| 427 | (regexp-quote from-string)) |
| 428 | "\\b"))) |
| 429 | (push-mark) |
| 430 | (undo-boundary) |
| 431 | ;; Loop finding occurrences that perhaps should be replaced. |
| 432 | (while (and keep-going |
| 433 | (not (eobp)) |
| 434 | (funcall search-function search-string nil t) |
| 435 | ;; If the search string matches immediately after |
| 436 | ;; the previous match, but it did not match there |
| 437 | ;; before the replacement was done, ignore the match. |
| 438 | (if (or (eq lastrepl (point)) |
| 439 | (and regexp-flag |
| 440 | (eq lastrepl (match-beginning 0)) |
| 441 | (not match-again))) |
| 442 | (if (eobp) |
| 443 | nil |
| 444 | ;; Don't replace the null string |
| 445 | ;; right after end of previous replacement. |
| 446 | (forward-char 1) |
| 447 | (funcall search-function search-string nil t)) |
| 448 | t)) |
| 449 | |
| 450 | ;; Save the data associated with the real match. |
| 451 | (setq real-match-data (match-data)) |
| 452 | |
| 453 | ;; Before we make the replacement, decide whether the search string |
| 454 | ;; can match again just after this match. |
| 455 | (if regexp-flag |
| 456 | (setq match-again (looking-at search-string))) |
| 457 | ;; If time for a change, advance to next replacement string. |
| 458 | (if (and (listp replacements) |
| 459 | (= next-rotate-count replace-count)) |
| 460 | (progn |
| 461 | (setq next-rotate-count |
| 462 | (+ next-rotate-count repeat-count)) |
| 463 | (setq next-replacement (nth replacement-index replacements)) |
| 464 | (setq replacement-index (% (1+ replacement-index) (length replacements))))) |
| 465 | (if (not query-flag) |
| 466 | (progn |
| 467 | (store-match-data real-match-data) |
| 468 | (replace-match next-replacement nocasify literal) |
| 469 | (setq replace-count (1+ replace-count))) |
| 470 | (undo-boundary) |
| 471 | (let (done replaced key def) |
| 472 | ;; Loop reading commands until one of them sets done, |
| 473 | ;; which means it has finished handling this occurrence. |
| 474 | (while (not done) |
| 475 | (message "Query replacing %s with %s: " |
| 476 | from-string next-replacement) |
| 477 | (setq key (vector (read-event))) |
| 478 | (setq def (lookup-key map key)) |
| 479 | ;; Restore the match data while we process the command. |
| 480 | (store-match-data real-match-data) |
| 481 | (cond ((eq def 'help) |
| 482 | (with-output-to-temp-buffer "*Help*" |
| 483 | (princ |
| 484 | (concat "Query replacing " |
| 485 | (if regexp-flag "regexp " "") |
| 486 | from-string " with " |
| 487 | next-replacement ".\n\n" |
| 488 | (substitute-command-keys |
| 489 | query-replace-help))))) |
| 490 | ((eq def 'exit) |
| 491 | (setq keep-going nil) |
| 492 | (setq done t)) |
| 493 | ((eq def 'backup) |
| 494 | (let ((elt (car stack))) |
| 495 | (goto-char (car elt)) |
| 496 | (setq replaced (eq t (cdr elt))) |
| 497 | (or replaced |
| 498 | (store-match-data (cdr elt))) |
| 499 | (setq stack (cdr stack)))) |
| 500 | ((eq def 'act) |
| 501 | (or replaced |
| 502 | (replace-match next-replacement nocasify literal)) |
| 503 | (setq done t replaced t)) |
| 504 | ((eq def 'act-and-exit) |
| 505 | (or replaced |
| 506 | (replace-match next-replacement nocasify literal)) |
| 507 | (setq keep-going nil) |
| 508 | (setq done t replaced t)) |
| 509 | ((eq def 'act-and-show) |
| 510 | (if (not replaced) |
| 511 | (progn |
| 512 | (replace-match next-replacement nocasify literal) |
| 513 | (setq replaced t)))) |
| 514 | ((eq def 'automatic) |
| 515 | (or replaced |
| 516 | (replace-match next-replacement nocasify literal)) |
| 517 | (setq done t query-flag nil replaced t)) |
| 518 | ((eq def 'skip) |
| 519 | (setq done t)) |
| 520 | ((eq def 'recenter) |
| 521 | (recenter nil)) |
| 522 | ((eq def 'edit) |
| 523 | (store-match-data |
| 524 | (prog1 (match-data) |
| 525 | (save-excursion (recursive-edit)))) |
| 526 | ;; Before we make the replacement, |
| 527 | ;; decide whether the search string |
| 528 | ;; can match again just after this match. |
| 529 | (if regexp-flag |
| 530 | (setq match-again (looking-at search-string)))) |
| 531 | ((eq def 'delete-and-edit) |
| 532 | (delete-region (match-beginning 0) (match-end 0)) |
| 533 | (store-match-data |
| 534 | (prog1 (match-data) |
| 535 | (save-excursion (recursive-edit)))) |
| 536 | (setq replaced t)) |
| 537 | (t |
| 538 | (setq keep-going nil) |
| 539 | (setq unread-command-events |
| 540 | (append (listify-key-sequence key) |
| 541 | unread-command-events)) |
| 542 | (setq done t)))) |
| 543 | ;; Record previous position for ^ when we move on. |
| 544 | ;; Change markers to numbers in the match data |
| 545 | ;; since lots of markers slow down editing. |
| 546 | (setq stack |
| 547 | (cons (cons (point) |
| 548 | (or replaced |
| 549 | (mapcar |
| 550 | (function (lambda (elt) |
| 551 | (and elt |
| 552 | (marker-position elt)))) |
| 553 | (match-data)))) |
| 554 | stack)) |
| 555 | (if replaced (setq replace-count (1+ replace-count))))) |
| 556 | (setq lastrepl (point))) |
| 557 | (and keep-going stack))) |
| 558 | |
| 559 | ;;; replace.el ends here |