| 1 | dnl Autoconf script for GNU Emacs |
| 2 | dnl To rebuild the `configure' script from this, execute the command |
| 3 | dnl autoconf |
| 4 | dnl in the directory containing this script. |
| 5 | dnl If you changed any AC_DEFINES, also run autoheader. |
| 6 | dnl |
| 7 | dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc. |
| 8 | dnl |
| 9 | dnl This file is part of GNU Emacs. |
| 10 | dnl |
| 11 | dnl GNU Emacs is free software: you can redistribute it and/or modify |
| 12 | dnl it under the terms of the GNU General Public License as published by |
| 13 | dnl the Free Software Foundation, either version 3 of the License, or |
| 14 | dnl (at your option) any later version. |
| 15 | dnl |
| 16 | dnl GNU Emacs is distributed in the hope that it will be useful, |
| 17 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 18 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 19 | dnl GNU General Public License for more details. |
| 20 | dnl |
| 21 | dnl You should have received a copy of the GNU General Public License |
| 22 | dnl along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 23 | |
| 24 | AC_PREREQ(2.65) |
| 25 | AC_INIT(emacs, 24.0.92) |
| 26 | AC_CONFIG_HEADER(src/config.h:src/config.in) |
| 27 | AC_CONFIG_SRCDIR(src/lisp.h) |
| 28 | AC_CONFIG_AUX_DIR(build-aux) |
| 29 | AM_INIT_AUTOMAKE |
| 30 | |
| 31 | dnl Support for --program-prefix, --program-suffix and |
| 32 | dnl --program-transform-name options |
| 33 | AC_ARG_PROGRAM |
| 34 | |
| 35 | dnl It is important that variables on the RHS not be expanded here, |
| 36 | dnl hence the single quotes. This is per the GNU coding standards, see |
| 37 | dnl (autoconf) Installation Directory Variables |
| 38 | dnl See also epaths.h below. |
| 39 | lispdir='${datadir}/emacs/${version}/lisp' |
| 40 | locallisppath='${datadir}/emacs/${version}/site-lisp:'\ |
| 41 | '${datadir}/emacs/site-lisp' |
| 42 | lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim' |
| 43 | etcdir='${datadir}/emacs/${version}/etc' |
| 44 | archlibdir='${libexecdir}/emacs/${version}/${configuration}' |
| 45 | docdir='${datadir}/emacs/${version}/etc' |
| 46 | gamedir='${localstatedir}/games/emacs' |
| 47 | |
| 48 | dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING) |
| 49 | dnl Create a new --with option that defaults to being disabled. |
| 50 | dnl NAME is the base name of the option. The shell variable with_NAME |
| 51 | dnl will be set to either the user's value (if the option is |
| 52 | dnl specified; 'yes' for a plain --with-NAME) or to 'no' (if the |
| 53 | dnl option is not specified). Note that the shell variable name is |
| 54 | dnl constructed as autoconf does, by replacing non-alphanumeric |
| 55 | dnl characters with "_". |
| 56 | dnl HELP-STRING is the help text for the option. |
| 57 | AC_DEFUN([OPTION_DEFAULT_OFF], [dnl |
| 58 | AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl |
| 59 | m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl |
| 60 | ])dnl |
| 61 | |
| 62 | dnl OPTION_DEFAULT_ON(NAME, HELP-STRING) |
| 63 | dnl Create a new --with option that defaults to being enabled. NAME |
| 64 | dnl is the base name of the option. The shell variable with_NAME |
| 65 | dnl will be set either to 'no' (for a plain --without-NAME) or to |
| 66 | dnl 'yes' (if the option is not specified). Note that the shell |
| 67 | dnl variable name is constructed as autoconf does, by replacing |
| 68 | dnl non-alphanumeric characters with "_". |
| 69 | dnl HELP-STRING is the help text for the option. |
| 70 | AC_DEFUN([OPTION_DEFAULT_ON], [dnl |
| 71 | AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl |
| 72 | m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl |
| 73 | ])dnl |
| 74 | |
| 75 | OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail]) |
| 76 | if test "$with_pop" = yes; then |
| 77 | AC_DEFINE(MAIL_USE_POP) |
| 78 | fi |
| 79 | AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl |
| 80 | |
| 81 | OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP]) |
| 82 | if test "$with_kerberos" != no; then |
| 83 | AC_DEFINE(KERBEROS) |
| 84 | fi |
| 85 | AH_TEMPLATE(KERBEROS, |
| 86 | [Define to support Kerberos-authenticated POP mail retrieval.])dnl |
| 87 | |
| 88 | OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP]) |
| 89 | if test "${with_kerberos5}" != no; then |
| 90 | if test "${with_kerberos}" = no; then |
| 91 | with_kerberos=yes |
| 92 | AC_DEFINE(KERBEROS) |
| 93 | fi |
| 94 | AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.]) |
| 95 | fi |
| 96 | |
| 97 | OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host]) |
| 98 | dnl FIXME hesiod support may not be present, so it seems like an error |
| 99 | dnl to define, or at least use, this unconditionally. |
| 100 | if test "$with_hesiod" != no; then |
| 101 | AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.]) |
| 102 | fi |
| 103 | |
| 104 | OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes]) |
| 105 | if test "$with_mmdf" != no; then |
| 106 | AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.]) |
| 107 | fi |
| 108 | |
| 109 | OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading]) |
| 110 | if test "$with_mail_unlink" != no; then |
| 111 | AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.]) |
| 112 | fi |
| 113 | |
| 114 | AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME], |
| 115 | [string giving default POP mail host])], |
| 116 | AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.])) |
| 117 | |
| 118 | OPTION_DEFAULT_ON([sound],[don't compile with sound support]) |
| 119 | |
| 120 | OPTION_DEFAULT_ON([sync-input],[process async input synchronously]) |
| 121 | if test "$with_sync_input" = yes; then |
| 122 | AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.]) |
| 123 | fi |
| 124 | |
| 125 | dnl FIXME currently it is not the last. |
| 126 | dnl This should be the last --with option, because --with-x is |
| 127 | dnl added later on when we find the path of X, and it's best to |
| 128 | dnl keep them together visually. |
| 129 | AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT], |
| 130 | [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])], |
| 131 | [ case "${withval}" in |
| 132 | y | ye | yes ) val=gtk ;; |
| 133 | n | no ) val=no ;; |
| 134 | l | lu | luc | luci | lucid ) val=lucid ;; |
| 135 | a | at | ath | athe | athen | athena ) val=athena ;; |
| 136 | m | mo | mot | moti | motif ) val=motif ;; |
| 137 | g | gt | gtk ) val=gtk ;; |
| 138 | gtk3 ) val=gtk3 ;; |
| 139 | * ) |
| 140 | AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid; |
| 141 | this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or |
| 142 | `gtk3'. `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.]) |
| 143 | ;; |
| 144 | esac |
| 145 | with_x_toolkit=$val |
| 146 | ]) |
| 147 | |
| 148 | OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)]) |
| 149 | if test "$with_wide_int" = yes; then |
| 150 | AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.]) |
| 151 | fi |
| 152 | |
| 153 | dnl _ON results in a '--without' option in the --help output, so |
| 154 | dnl the help text should refer to "don't compile", etc. |
| 155 | OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support]) |
| 156 | OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support]) |
| 157 | OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support]) |
| 158 | OPTION_DEFAULT_ON([gif],[don't compile with GIF image support]) |
| 159 | OPTION_DEFAULT_ON([png],[don't compile with PNG image support]) |
| 160 | OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support]) |
| 161 | OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support]) |
| 162 | OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support]) |
| 163 | |
| 164 | OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts]) |
| 165 | OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support]) |
| 166 | OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping]) |
| 167 | |
| 168 | OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars]) |
| 169 | OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d]) |
| 170 | OPTION_DEFAULT_ON([xim],[don't use X11 XIM]) |
| 171 | OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system]) |
| 172 | |
| 173 | OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console]) |
| 174 | OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support]) |
| 175 | OPTION_DEFAULT_ON([gconf],[don't compile with GConf support]) |
| 176 | OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support]) |
| 177 | OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support]) |
| 178 | OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support]) |
| 179 | |
| 180 | ## For the times when you want to build Emacs but don't have |
| 181 | ## a suitable makeinfo, and can live without the manuals. |
| 182 | dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html |
| 183 | OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals]) |
| 184 | |
| 185 | ## Makefile.in needs the cache file name. |
| 186 | AC_SUBST(cache_file) |
| 187 | |
| 188 | ## This is an option because I do not know if all info/man support |
| 189 | ## compressed files, nor how to test if they do so. |
| 190 | OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages]) |
| 191 | if test $with_compress_info = yes; then |
| 192 | GZIP_INFO=yes |
| 193 | else |
| 194 | GZIP_INFO= |
| 195 | fi |
| 196 | AC_SUBST(GZIP_INFO) |
| 197 | |
| 198 | AC_ARG_WITH([pkg-config-prog],dnl |
| 199 | [AS_HELP_STRING([--with-pkg-config-prog=PATH], |
| 200 | [path to pkg-config for finding GTK and librsvg])]) |
| 201 | if test "X${with_pkg_config_prog}" != X; then |
| 202 | if test "${with_pkg_config_prog}" != yes; then |
| 203 | PKG_CONFIG="${with_pkg_config_prog}" |
| 204 | fi |
| 205 | fi |
| 206 | |
| 207 | CRT_DIR= |
| 208 | AC_ARG_WITH([crt-dir],dnl |
| 209 | [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc. |
| 210 | The default is /usr/lib, or /usr/lib64 on some platforms.])]) |
| 211 | CRT_DIR="${with_crt_dir}" |
| 212 | |
| 213 | AC_ARG_WITH(gameuser,dnl |
| 214 | [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])]) |
| 215 | test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \ |
| 216 | && gameuser="${with_gameuser}" |
| 217 | test "X$gameuser" = X && gameuser=games |
| 218 | |
| 219 | AC_ARG_WITH([gnustep-conf],dnl |
| 220 | [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])]) |
| 221 | test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \ |
| 222 | GNUSTEP_CONFIG_FILE="${with_gnustep_conf}" |
| 223 | test "X$GNUSTEP_CONFIG_FILE" = "X" && \ |
| 224 | GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf |
| 225 | |
| 226 | AC_ARG_ENABLE(ns-self-contained, |
| 227 | [AS_HELP_STRING([--disable-ns-self-contained], |
| 228 | [disable self contained build under NeXTstep])], |
| 229 | EN_NS_SELF_CONTAINED=$enableval, |
| 230 | EN_NS_SELF_CONTAINED=yes) |
| 231 | |
| 232 | AC_ARG_ENABLE(asserts, |
| 233 | [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])], |
| 234 | USE_XASSERTS=$enableval, |
| 235 | USE_XASSERTS=no) |
| 236 | |
| 237 | AC_ARG_ENABLE(maintainer-mode, |
| 238 | [AS_HELP_STRING([--disable-maintainer-mode], |
| 239 | [disable make rules and dependencies not useful (and sometimes |
| 240 | confusing) to the casual installer])], |
| 241 | USE_MAINTAINER_MODE=$enableval, |
| 242 | USE_MAINTAINER_MODE=yes) |
| 243 | if test $USE_MAINTAINER_MODE = yes; then |
| 244 | MAINT= |
| 245 | else |
| 246 | MAINT=# |
| 247 | fi |
| 248 | AC_SUBST(MAINT) |
| 249 | |
| 250 | AC_ARG_ENABLE(locallisppath, |
| 251 | [AS_HELP_STRING([--enable-locallisppath=PATH], |
| 252 | [directories Emacs should search for lisp files specific |
| 253 | to this site])], |
| 254 | if test "${enableval}" = "no"; then |
| 255 | locallisppath= |
| 256 | elif test "${enableval}" != "yes"; then |
| 257 | locallisppath=${enableval} |
| 258 | fi) |
| 259 | |
| 260 | AC_ARG_ENABLE(checking, |
| 261 | [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@], |
| 262 | [enable expensive run-time checks. With LIST, |
| 263 | enable only specific categories of checks. |
| 264 | Categories are: all,yes,no. |
| 265 | Flags are: stringbytes, stringoverrun, stringfreelist, |
| 266 | xmallocoverrun, conslist])], |
| 267 | [ac_checking_flags="${enableval}"],[]) |
| 268 | IFS="${IFS= }"; ac_save_IFS="$IFS"; IFS="$IFS," |
| 269 | for check in $ac_checking_flags |
| 270 | do |
| 271 | case $check in |
| 272 | # these set all the flags to specific states |
| 273 | yes) ac_enable_checking=1 ;; |
| 274 | no) ac_enable_checking= ; |
| 275 | ac_gc_check_stringbytes= ; |
| 276 | ac_gc_check_string_overrun= ; |
| 277 | ac_gc_check_string_free_list= ; |
| 278 | ac_xmalloc_overrun= ; |
| 279 | ac_gc_check_cons_list= ;; |
| 280 | all) ac_enable_checking=1 ; |
| 281 | ac_gc_check_stringbytes=1 ; |
| 282 | ac_gc_check_string_overrun=1 ; |
| 283 | ac_gc_check_string_free_list=1 ; |
| 284 | ac_xmalloc_overrun=1 ; |
| 285 | ac_gc_check_cons_list=1 ;; |
| 286 | # these enable particular checks |
| 287 | stringbytes) ac_gc_check_stringbytes=1 ;; |
| 288 | stringoverrun) ac_gc_check_string_overrun=1 ;; |
| 289 | stringfreelist) ac_gc_check_string_free_list=1 ;; |
| 290 | xmallocoverrun) ac_xmalloc_overrun=1 ;; |
| 291 | conslist) ac_gc_check_cons_list=1 ;; |
| 292 | *) AC_MSG_ERROR(unknown check category $check) ;; |
| 293 | esac |
| 294 | done |
| 295 | IFS="$ac_save_IFS" |
| 296 | |
| 297 | if test x$ac_enable_checking != x ; then |
| 298 | AC_DEFINE(ENABLE_CHECKING, 1, |
| 299 | [Enable expensive run-time checking of data types?]) |
| 300 | fi |
| 301 | if test x$ac_gc_check_stringbytes != x ; then |
| 302 | AC_DEFINE(GC_CHECK_STRING_BYTES, 1, |
| 303 | [Define this temporarily to hunt a bug. If defined, the size of |
| 304 | strings is redundantly recorded in sdata structures so that it can |
| 305 | be compared to the sizes recorded in Lisp strings.]) |
| 306 | fi |
| 307 | if test x$ac_gc_check_string_overrun != x ; then |
| 308 | AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1, |
| 309 | [Define this to check for short string overrun.]) |
| 310 | fi |
| 311 | if test x$ac_gc_check_string_free_list != x ; then |
| 312 | AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1, |
| 313 | [Define this to check the string free list.]) |
| 314 | fi |
| 315 | if test x$ac_xmalloc_overrun != x ; then |
| 316 | AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1, |
| 317 | [Define this to check for malloc buffer overrun.]) |
| 318 | fi |
| 319 | if test x$ac_gc_check_cons_list != x ; then |
| 320 | AC_DEFINE(GC_CHECK_CONS_LIST, 1, |
| 321 | [Define this to check for errors in cons list.]) |
| 322 | fi |
| 323 | |
| 324 | AC_ARG_ENABLE(use-lisp-union-type, |
| 325 | [AS_HELP_STRING([--enable-use-lisp-union-type], |
| 326 | [use a union for the Lisp_Object data type. |
| 327 | This is only useful for development for catching certain types of bugs.])], |
| 328 | if test "${enableval}" != "no"; then |
| 329 | AC_DEFINE(USE_LISP_UNION_TYPE, 1, |
| 330 | [Define this to use a lisp union for the Lisp_Object data type.]) |
| 331 | fi) |
| 332 | |
| 333 | |
| 334 | AC_ARG_ENABLE(profiling, |
| 335 | [AS_HELP_STRING([--enable-profiling], |
| 336 | [build emacs with profiling support. |
| 337 | This might not work on all platforms])], |
| 338 | [ac_enable_profiling="${enableval}"],[]) |
| 339 | if test x$ac_enable_profiling != x ; then |
| 340 | PROFILING_CFLAGS="-DPROFILING=1 -pg" |
| 341 | else |
| 342 | PROFILING_CFLAGS= |
| 343 | fi |
| 344 | AC_SUBST(PROFILING_CFLAGS) |
| 345 | |
| 346 | AC_ARG_ENABLE(autodepend, |
| 347 | [AS_HELP_STRING([--enable-autodepend], |
| 348 | [automatically generate dependencies to .h-files. |
| 349 | Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is |
| 350 | found])], |
| 351 | [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes]) |
| 352 | |
| 353 | #### Make srcdir absolute, if it isn't already. It's important to |
| 354 | #### avoid running the path through pwd unnecessarily, since pwd can |
| 355 | #### give you automounter prefixes, which can go away. We do all this |
| 356 | #### so Emacs can find its files when run uninstalled. |
| 357 | ## Make sure CDPATH doesn't affect cd (in case PWD is relative). |
| 358 | unset CDPATH |
| 359 | case "${srcdir}" in |
| 360 | /* ) ;; |
| 361 | . ) |
| 362 | ## We may be able to use the $PWD environment variable to make this |
| 363 | ## absolute. But sometimes PWD is inaccurate. |
| 364 | ## Note: we used to use ${PWD} at the end instead of `pwd`, |
| 365 | ## but that tested only for a well-formed and valid PWD, |
| 366 | ## it did not object when PWD was well-formed and valid but just wrong. |
| 367 | if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`" ; |
| 368 | then |
| 369 | srcdir="$PWD" |
| 370 | else |
| 371 | srcdir="`(cd ${srcdir}; pwd)`" |
| 372 | fi |
| 373 | ;; |
| 374 | * ) srcdir="`(cd ${srcdir}; pwd)`" ;; |
| 375 | esac |
| 376 | |
| 377 | #### Given the configuration name, set machfile and opsysfile to the |
| 378 | #### names of the m/*.h and s/*.h files we should use. |
| 379 | |
| 380 | ### Canonicalize the configuration name. |
| 381 | |
| 382 | AC_CANONICAL_HOST |
| 383 | canonical=$host |
| 384 | configuration=${host_alias-${build_alias-$host}} |
| 385 | |
| 386 | dnl This used to use changequote, but, apart from `changequote is evil' |
| 387 | dnl per the autoconf manual, we can speed up autoconf somewhat by quoting |
| 388 | dnl the great gob of text. Thus it's not processed for possible expansion. |
| 389 | dnl Just make sure the brackets remain balanced. |
| 390 | dnl |
| 391 | dnl Since Emacs can't find matching pairs of quotes, boundaries are |
| 392 | dnl indicated by comments. |
| 393 | dnl quotation begins |
| 394 | [ |
| 395 | |
| 396 | ### If you add support for a new configuration, add code to this |
| 397 | ### switch statement to recognize your configuration name and select |
| 398 | ### the appropriate operating system and machine description files. |
| 399 | |
| 400 | ### You would hope that you could choose an m/*.h file pretty much |
| 401 | ### based on the machine portion of the configuration name, and an s/*.h |
| 402 | ### file based on the operating system portion. However, it turns out |
| 403 | ### that each m/*.h file is pretty manufacturer-specific - for |
| 404 | ### example mips.h is MIPS |
| 405 | ### So we basically have to have a special case for each |
| 406 | ### configuration name. |
| 407 | ### |
| 408 | ### As far as handling version numbers on operating systems is |
| 409 | ### concerned, make sure things will fail in a fixable way. If |
| 410 | ### /etc/MACHINES doesn't say anything about version numbers, be |
| 411 | ### prepared to handle anything reasonably. If version numbers |
| 412 | ### matter, be sure /etc/MACHINES says something about it. |
| 413 | |
| 414 | machine='' opsys='' unported=no |
| 415 | case "${canonical}" in |
| 416 | |
| 417 | ## GNU/Linux and similar ports |
| 418 | *-*-linux* ) |
| 419 | opsys=gnu-linux |
| 420 | case ${canonical} in |
| 421 | alpha*) machine=alpha ;; |
| 422 | s390x-*) machine=ibms390x ;; |
| 423 | powerpc*) machine=macppc ;; |
| 424 | sparc*) machine=sparc ;; |
| 425 | ia64*) machine=ia64 ;; |
| 426 | m68k*) machine=m68k ;; |
| 427 | x86_64*) machine=amdx86-64 ;; |
| 428 | esac |
| 429 | ;; |
| 430 | |
| 431 | ## FreeBSD ports |
| 432 | *-*-freebsd* ) |
| 433 | opsys=freebsd |
| 434 | case "${canonical}" in |
| 435 | alpha*) machine=alpha ;; |
| 436 | amd64-*|x86_64-*) machine=amdx86-64 ;; |
| 437 | ia64-*) machine=ia64 ;; |
| 438 | i[3456]86-*) machine=intel386 ;; |
| 439 | powerpc-*) machine=macppc ;; |
| 440 | sparc-*) machine=sparc ;; |
| 441 | sparc64-*) machine=sparc ;; |
| 442 | esac |
| 443 | ;; |
| 444 | |
| 445 | ## FreeBSD kernel + glibc based userland |
| 446 | *-*-kfreebsd*gnu* ) |
| 447 | opsys=gnu-kfreebsd |
| 448 | case "${canonical}" in |
| 449 | alpha*) machine=alpha ;; |
| 450 | amd64-*|x86_64-*) machine=amdx86-64 ;; |
| 451 | ia64-*) machine=ia64 ;; |
| 452 | i[3456]86-*) machine=intel386 ;; |
| 453 | powerpc-*) machine=macppc ;; |
| 454 | sparc-*) machine=sparc ;; |
| 455 | sparc64-*) machine=sparc ;; |
| 456 | esac |
| 457 | ;; |
| 458 | |
| 459 | ## NetBSD ports |
| 460 | *-*-netbsd* ) |
| 461 | opsys=netbsd |
| 462 | case "${canonical}" in |
| 463 | alpha*) machine=alpha ;; |
| 464 | x86_64-*) machine=amdx86-64 ;; |
| 465 | i[3456]86-*) machine=intel386 ;; |
| 466 | m68k-*) machine=m68k ;; |
| 467 | powerpc-*) machine=macppc ;; |
| 468 | sparc*-) machine=sparc ;; |
| 469 | vax-*) machine=vax ;; |
| 470 | esac |
| 471 | ;; |
| 472 | |
| 473 | ## OpenBSD ports |
| 474 | *-*-openbsd* ) |
| 475 | opsys=openbsd |
| 476 | case "${canonical}" in |
| 477 | alpha*) machine=alpha ;; |
| 478 | x86_64-*) machine=amdx86-64 ;; |
| 479 | i386-*) machine=intel386 ;; |
| 480 | powerpc-*) machine=macppc ;; |
| 481 | sparc*) machine=sparc ;; |
| 482 | vax-*) machine=vax ;; |
| 483 | esac |
| 484 | ;; |
| 485 | |
| 486 | ## Apple Darwin / Mac OS X |
| 487 | *-apple-darwin* ) |
| 488 | case "${canonical}" in |
| 489 | i[3456]86-* ) machine=intel386 ;; |
| 490 | powerpc-* ) machine=macppc ;; |
| 491 | x86_64-* ) machine=amdx86-64 ;; |
| 492 | * ) unported=yes ;; |
| 493 | esac |
| 494 | opsys=darwin |
| 495 | # Define CPP as follows to make autoconf work correctly. |
| 496 | CPP="${CC-cc} -E -no-cpp-precomp" |
| 497 | # Use fink packages if available. |
| 498 | if test -d /sw/include && test -d /sw/lib; then |
| 499 | GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib" |
| 500 | CPP="${CPP} ${GCC_TEST_OPTIONS}" |
| 501 | NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS} |
| 502 | fi |
| 503 | ;; |
| 504 | |
| 505 | ## HP 9000 series 700 and 800, running HP/UX |
| 506 | hppa*-hp-hpux10.2* ) |
| 507 | opsys=hpux10-20 |
| 508 | ;; |
| 509 | hppa*-hp-hpux1[1-9]* ) |
| 510 | opsys=hpux11 |
| 511 | CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS" |
| 512 | ;; |
| 513 | |
| 514 | ## IBM machines |
| 515 | rs6000-ibm-aix4.[23]* ) |
| 516 | machine=ibmrs6000 opsys=aix4-2 |
| 517 | ;; |
| 518 | powerpc-ibm-aix4.[23]* ) |
| 519 | machine=ibmrs6000 opsys=aix4-2 |
| 520 | ;; |
| 521 | rs6000-ibm-aix[56]* ) |
| 522 | machine=ibmrs6000 opsys=aix4-2 |
| 523 | ;; |
| 524 | powerpc-ibm-aix[56]* ) |
| 525 | machine=ibmrs6000 opsys=aix4-2 |
| 526 | ;; |
| 527 | |
| 528 | ## Silicon Graphics machines |
| 529 | ## Iris 4D |
| 530 | mips-sgi-irix6.5 ) |
| 531 | opsys=irix6-5 |
| 532 | # Without defining _LANGUAGE_C, things get masked out in the headers |
| 533 | # so that, for instance, grepping for `free' in stdlib.h fails and |
| 534 | # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m). |
| 535 | NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C" |
| 536 | NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C" |
| 537 | ;; |
| 538 | |
| 539 | ## Suns |
| 540 | *-sun-solaris* \ |
| 541 | | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \ |
| 542 | | x86_64-*-solaris2* | x86_64-*-sunos5*) |
| 543 | case "${canonical}" in |
| 544 | i[3456]86-*-* ) machine=intel386 ;; |
| 545 | amd64-*-*|x86_64-*-*) machine=amdx86-64 ;; |
| 546 | sparc* ) machine=sparc ;; |
| 547 | * ) unported=yes ;; |
| 548 | esac |
| 549 | case "${canonical}" in |
| 550 | *-sunos5.6* | *-solaris2.6* ) |
| 551 | opsys=sol2-6 |
| 552 | NON_GNU_CPP=/usr/ccs/lib/cpp |
| 553 | RANLIB="ar -ts" |
| 554 | ;; |
| 555 | *-sunos5.[7-9]* | *-solaris2.[7-9]* ) |
| 556 | opsys=sol2-6 |
| 557 | emacs_check_sunpro_c=yes |
| 558 | NON_GNU_CPP=/usr/ccs/lib/cpp |
| 559 | ;; |
| 560 | *-sunos5* | *-solaris* ) |
| 561 | opsys=sol2-10 |
| 562 | emacs_check_sunpro_c=yes |
| 563 | NON_GNU_CPP=/usr/ccs/lib/cpp |
| 564 | ;; |
| 565 | esac |
| 566 | ## Watch out for a compiler that we know will not work. |
| 567 | case "${canonical}" in |
| 568 | *-solaris* | *-sunos5* ) |
| 569 | if [ "x$CC" = x/usr/ucb/cc ]; then |
| 570 | ## /usr/ucb/cc doesn't work; |
| 571 | ## we should find some other compiler that does work. |
| 572 | unset CC |
| 573 | fi |
| 574 | ;; |
| 575 | *) ;; |
| 576 | esac |
| 577 | ;; |
| 578 | |
| 579 | ## Intel 386 machines where we don't care about the manufacturer. |
| 580 | i[3456]86-*-* ) |
| 581 | machine=intel386 |
| 582 | case "${canonical}" in |
| 583 | *-cygwin ) opsys=cygwin ;; |
| 584 | *-darwin* ) opsys=darwin |
| 585 | CPP="${CC-cc} -E -no-cpp-precomp" |
| 586 | ;; |
| 587 | *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;; |
| 588 | *-sysv5uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;; |
| 589 | *-sysv5OpenUNIX* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;; |
| 590 | ## Otherwise, we'll fall through to the generic opsys code at the bottom. |
| 591 | esac |
| 592 | ;; |
| 593 | |
| 594 | * ) |
| 595 | unported=yes |
| 596 | ;; |
| 597 | esac |
| 598 | |
| 599 | ### If the code above didn't choose an operating system, just choose |
| 600 | ### an operating system based on the configuration name. You really |
| 601 | ### only want to use this when you have no idea what the right |
| 602 | ### operating system is; if you know what operating systems a machine |
| 603 | ### runs, it's cleaner to make it explicit in the case statement |
| 604 | ### above. |
| 605 | if test x"${opsys}" = x; then |
| 606 | case "${canonical}" in |
| 607 | *-gnu* ) opsys=gnu ;; |
| 608 | * ) |
| 609 | unported=yes |
| 610 | ;; |
| 611 | esac |
| 612 | fi |
| 613 | |
| 614 | ] |
| 615 | dnl quotation ends |
| 616 | |
| 617 | if test $unported = yes; then |
| 618 | AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems. |
| 619 | Check `etc/MACHINES' for recognized configuration names.]) |
| 620 | fi |
| 621 | |
| 622 | if test -n "$machine"; then |
| 623 | machfile="m/${machine}.h" |
| 624 | else |
| 625 | machfile= |
| 626 | fi |
| 627 | opsysfile="s/${opsys}.h" |
| 628 | |
| 629 | |
| 630 | #### Choose a compiler. |
| 631 | test -n "$CC" && cc_specified=yes |
| 632 | |
| 633 | # Save the value of CFLAGS that the user specified. |
| 634 | SPECIFIED_CFLAGS="$CFLAGS" |
| 635 | |
| 636 | dnl Sets GCC=yes if using gcc. |
| 637 | AC_PROG_CC |
| 638 | AM_PROG_CC_C_O |
| 639 | |
| 640 | # Initialize gnulib right after verifying that the C compiler works. |
| 641 | gl_EARLY |
| 642 | |
| 643 | # On Suns, sometimes $CPP names a directory. |
| 644 | if test -n "$CPP" && test -d "$CPP"; then |
| 645 | CPP= |
| 646 | fi |
| 647 | |
| 648 | ## If not using gcc, and on Solaris, and no CPP specified, see if |
| 649 | ## using a Sun compiler, which needs -Xs to prevent whitespace. |
| 650 | if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \ |
| 651 | test x"$CPP" = x; then |
| 652 | AC_MSG_CHECKING([whether we are using a Sun C compiler]) |
| 653 | AC_CACHE_VAL(emacs_cv_sunpro_c, |
| 654 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], |
| 655 | [[#ifndef __SUNPRO_C |
| 656 | fail; |
| 657 | #endif |
| 658 | ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)]) |
| 659 | AC_MSG_RESULT($emacs_cv_sunpro_c) |
| 660 | |
| 661 | if test x"$emacs_cv_sunpro_c" = xyes; then |
| 662 | NON_GNU_CPP="$CC -E -Xs" |
| 663 | fi |
| 664 | fi |
| 665 | |
| 666 | #### Some systems specify a CPP to use unless we are using GCC. |
| 667 | #### Now that we know whether we are using GCC, we can decide whether |
| 668 | #### to use that one. |
| 669 | if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x |
| 670 | then |
| 671 | CPP="$NON_GNU_CPP" |
| 672 | fi |
| 673 | |
| 674 | #### Some systems specify a CC to use unless we are using GCC. |
| 675 | #### Now that we know whether we are using GCC, we can decide whether |
| 676 | #### to use that one. |
| 677 | if test "x$NON_GNU_CC" != x && test x$GCC != xyes && |
| 678 | test x$cc_specified != xyes |
| 679 | then |
| 680 | CC="$NON_GNU_CC" |
| 681 | fi |
| 682 | |
| 683 | if test x$GCC = xyes; then |
| 684 | test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS" |
| 685 | else |
| 686 | test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS" |
| 687 | fi |
| 688 | |
| 689 | ### Use -Wdeclaration-after-statement if the compiler supports it |
| 690 | AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement]) |
| 691 | SAVE_CFLAGS="$CFLAGS" |
| 692 | CFLAGS="$CFLAGS -Wdeclaration-after-statement" |
| 693 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no) |
| 694 | if test $has_option = yes; then |
| 695 | C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH" |
| 696 | fi |
| 697 | AC_MSG_RESULT($has_option) |
| 698 | CFLAGS="$SAVE_CFLAGS" |
| 699 | unset has_option |
| 700 | unset SAVE_CFLAGS |
| 701 | |
| 702 | ### Use -Wold-style-definition if the compiler supports it |
| 703 | # This can be removed when conversion to standard C is finished. |
| 704 | AC_MSG_CHECKING([whether gcc understands -Wold-style-definition]) |
| 705 | SAVE_CFLAGS="$CFLAGS" |
| 706 | CFLAGS="$CFLAGS -Wold-style-definition" |
| 707 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no) |
| 708 | if test $has_option = yes; then |
| 709 | C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH" |
| 710 | fi |
| 711 | AC_MSG_RESULT($has_option) |
| 712 | CFLAGS="$SAVE_CFLAGS" |
| 713 | unset has_option |
| 714 | unset SAVE_CFLAGS |
| 715 | |
| 716 | ### Use -Wimplicit-function-declaration if the compiler supports it |
| 717 | AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration]) |
| 718 | SAVE_CFLAGS="$CFLAGS" |
| 719 | CFLAGS="$CFLAGS -Wimplicit-function-declaration" |
| 720 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no) |
| 721 | if test $has_option = yes; then |
| 722 | C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH" |
| 723 | fi |
| 724 | AC_MSG_RESULT($has_option) |
| 725 | CFLAGS="$SAVE_CFLAGS" |
| 726 | unset has_option |
| 727 | unset SAVE_CFLAGS |
| 728 | |
| 729 | AC_SUBST(C_WARNINGS_SWITCH) |
| 730 | |
| 731 | |
| 732 | #### Some other nice autoconf tests. |
| 733 | |
| 734 | dnl checks for programs |
| 735 | AC_PROG_CPP |
| 736 | AC_PROG_INSTALL |
| 737 | if test "x$RANLIB" = x; then |
| 738 | AC_PROG_RANLIB |
| 739 | fi |
| 740 | |
| 741 | ## Although we're running on an amd64 kernel, we're actually compiling for |
| 742 | ## the x86 architecture. The user should probably have provided an |
| 743 | ## explicit --build to `configure', but if everything else than the kernel |
| 744 | ## is running in i386 mode, we can help them out. |
| 745 | if test "$machine" = "amdx86-64"; then |
| 746 | AC_CHECK_DECL([i386]) |
| 747 | if test "$ac_cv_have_decl_i386" = "yes"; then |
| 748 | canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'` |
| 749 | machine=intel386 |
| 750 | machfile="m/${machine}.h" |
| 751 | fi |
| 752 | fi |
| 753 | |
| 754 | AC_PATH_PROG(INSTALL_INFO, install-info) |
| 755 | AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin) |
| 756 | AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin) |
| 757 | dnl Don't use GZIP, which is used by gzip for additional parameters. |
| 758 | AC_PATH_PROG(GZIP_PROG, gzip) |
| 759 | |
| 760 | |
| 761 | ## Need makeinfo >= 4.6 (?) to build the manuals. |
| 762 | AC_PATH_PROG(MAKEINFO, makeinfo, no) |
| 763 | dnl By this stage, configure has already checked for egrep and set EGREP, |
| 764 | dnl or exited with an error if no egrep was found. |
| 765 | if test "$MAKEINFO" != "no" && \ |
| 766 | test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then |
| 767 | MAKEINFO=no |
| 768 | fi |
| 769 | |
| 770 | ## Makeinfo is unusual. For a released Emacs, the manuals are |
| 771 | ## pre-built, and not deleted by the normal clean rules. makeinfo is |
| 772 | ## therefore in the category of "special tools" not normally required, which |
| 773 | ## configure does not have to check for (eg autoconf itself). |
| 774 | ## In a Bazaar checkout on the other hand, the manuals are not included. |
| 775 | ## So makeinfo is a requirement to build from Bazaar, and configure |
| 776 | ## should test for it as it does for any other build requirement. |
| 777 | ## We use the presence of $srcdir/info/emacs to distinguish a release, |
| 778 | ## with pre-built manuals, from a Bazaar checkout. |
| 779 | HAVE_MAKEINFO=yes |
| 780 | |
| 781 | if test "$MAKEINFO" = "no"; then |
| 782 | MAKEINFO=makeinfo |
| 783 | if test "x${with_makeinfo}" = "xno"; then |
| 784 | HAVE_MAKEINFO=no |
| 785 | elif test ! -e $srcdir/info/emacs; then |
| 786 | AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your |
| 787 | source tree does not seem to have pre-built manuals in the `info' directory. |
| 788 | Either install a suitable version of makeinfo, or re-run configure |
| 789 | with the `--without-makeinfo' option to build without the manuals.] ) |
| 790 | fi |
| 791 | fi |
| 792 | AC_SUBST(HAVE_MAKEINFO) |
| 793 | |
| 794 | dnl Add our options to ac_link now, after it is set up. |
| 795 | |
| 796 | if test x$GCC = xyes; then |
| 797 | test "x$GCC_LINK_TEST_OPTIONS" != x && \ |
| 798 | ac_link="$ac_link $GCC_LINK_TEST_OPTIONS" |
| 799 | else |
| 800 | test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \ |
| 801 | ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS" |
| 802 | fi |
| 803 | |
| 804 | dnl We need -znocombreloc if we're using a relatively recent GNU ld. |
| 805 | dnl If we can link with the flag, it shouldn't do any harm anyhow. |
| 806 | dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.) |
| 807 | dnl Treat GCC specially since it just gives a non-fatal `unrecognized option' |
| 808 | dnl if not built to support GNU ld. |
| 809 | |
| 810 | late_LDFLAGS=$LDFLAGS |
| 811 | if test x$GCC = xyes; then |
| 812 | LDFLAGS="$LDFLAGS -Wl,-znocombreloc" |
| 813 | else |
| 814 | LDFLAGS="$LDFLAGS -znocombreloc" |
| 815 | fi |
| 816 | |
| 817 | AC_MSG_CHECKING([for -znocombreloc]) |
| 818 | AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], |
| 819 | [AC_MSG_RESULT(yes)], |
| 820 | LDFLAGS=$late_LDFLAGS |
| 821 | [AC_MSG_RESULT(no)]) |
| 822 | |
| 823 | |
| 824 | # The value of CPP is a quoted variable reference, so we need to do this |
| 825 | # to get its actual value... |
| 826 | CPP=`eval "echo $CPP"` |
| 827 | |
| 828 | |
| 829 | dnl The function dump-emacs will not be defined and temacs will do |
| 830 | dnl (load "loadup") automatically unless told otherwise. |
| 831 | test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no |
| 832 | case "$opsys" in |
| 833 | your-opsys-here) CANNOT_DUMP=yes ;; |
| 834 | esac |
| 835 | |
| 836 | test "$CANNOT_DUMP" = "yes" && \ |
| 837 | AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.]) |
| 838 | |
| 839 | AC_SUBST(CANNOT_DUMP) |
| 840 | |
| 841 | |
| 842 | UNEXEC_OBJ=unexelf.o |
| 843 | case "$opsys" in |
| 844 | # MSDOS uses unexcoff.o |
| 845 | # MSWindows uses unexw32.o |
| 846 | aix4-2) |
| 847 | UNEXEC_OBJ=unexaix.o |
| 848 | ;; |
| 849 | cygwin) |
| 850 | UNEXEC_OBJ=unexcw.o |
| 851 | ;; |
| 852 | darwin) |
| 853 | UNEXEC_OBJ=unexmacosx.o |
| 854 | ;; |
| 855 | hpux10-20 | hpux11) |
| 856 | UNEXEC_OBJ=unexhp9k800.o |
| 857 | ;; |
| 858 | sol2-10) |
| 859 | # Use the Solaris dldump() function, called from unexsol.c, to dump |
| 860 | # emacs, instead of the generic ELF dump code found in unexelf.c. |
| 861 | # The resulting binary has a complete symbol table, and is better |
| 862 | # for debugging and other observability tools (debuggers, pstack, etc). |
| 863 | # |
| 864 | # If you encounter a problem using dldump(), please consider sending |
| 865 | # a message to the OpenSolaris tools-linking mailing list: |
| 866 | # http://mail.opensolaris.org/mailman/listinfo/tools-linking |
| 867 | # |
| 868 | # It is likely that dldump() works with older Solaris too, but this has |
| 869 | # not been tested, so for now this change is for Solaris 10 or newer. |
| 870 | UNEXEC_OBJ=unexsol.o |
| 871 | ;; |
| 872 | esac |
| 873 | |
| 874 | LD_SWITCH_SYSTEM= |
| 875 | case "$opsys" in |
| 876 | freebsd) |
| 877 | ## Let `ld' find image libs and similar things in /usr/local/lib. |
| 878 | ## The system compiler, GCC, has apparently been modified to not |
| 879 | ## look there, contrary to what a stock GCC would do. |
| 880 | LD_SWITCH_SYSTEM=-L/usr/local/lib |
| 881 | ;; |
| 882 | |
| 883 | gnu-linux) |
| 884 | ## cpp test was "ifdef __mips__", but presumably this is equivalent... |
| 885 | case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac |
| 886 | ;; |
| 887 | |
| 888 | netbsd) |
| 889 | LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib" |
| 890 | ;; |
| 891 | |
| 892 | openbsd) |
| 893 | ## Han Boetes <han@mijncomputer.nl> says this is necessary, |
| 894 | ## otherwise Emacs dumps core on elf systems. |
| 895 | LD_SWITCH_SYSTEM="-Z" |
| 896 | ;; |
| 897 | esac |
| 898 | AC_SUBST(LD_SWITCH_SYSTEM) |
| 899 | |
| 900 | ac_link="$ac_link $LD_SWITCH_SYSTEM" |
| 901 | |
| 902 | ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX, |
| 903 | ## which has not been defined yet. When this was handled with cpp, |
| 904 | ## it was expanded to null when configure sourced the s/*.h file. |
| 905 | ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles. |
| 906 | ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS |
| 907 | ## (or somesuch), but because it is supposed to go at the _front_ |
| 908 | ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way. |
| 909 | ## Compare with the gnu-linux case below, which added to the end |
| 910 | ## of LD_SWITCH_SYSTEM, and so can instead go at the front of |
| 911 | ## LD_SWITCH_SYSTEM_TEMACS. |
| 912 | case "$opsys" in |
| 913 | netbsd|openbsd) |
| 914 | ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R. |
| 915 | LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;; |
| 916 | esac |
| 917 | |
| 918 | |
| 919 | C_SWITCH_MACHINE= |
| 920 | if test "$machine" = "alpha"; then |
| 921 | AC_CHECK_DECL([__ELF__]) |
| 922 | if test "$ac_cv_have_decl___ELF__" = "yes"; then |
| 923 | ## With ELF, make sure that all common symbols get allocated to in the |
| 924 | ## data section. Otherwise, the dump of temacs may miss variables in |
| 925 | ## the shared library that have been initialized. For example, with |
| 926 | ## GNU libc, __malloc_initialized would normally be resolved to the |
| 927 | ## shared library's .bss section, which is fatal. |
| 928 | if test "x$GCC" = "xyes"; then |
| 929 | C_SWITCH_MACHINE="-fno-common" |
| 930 | else |
| 931 | AC_MSG_ERROR([What gives? Fix me if DEC Unix supports ELF now.]) |
| 932 | fi |
| 933 | else |
| 934 | UNEXEC_OBJ=unexalpha.o |
| 935 | fi |
| 936 | fi |
| 937 | AC_SUBST(C_SWITCH_MACHINE) |
| 938 | |
| 939 | AC_SUBST(UNEXEC_OBJ) |
| 940 | |
| 941 | C_SWITCH_SYSTEM= |
| 942 | ## Some programs in src produce warnings saying certain subprograms |
| 943 | ## are too complex and need a MAXMEM value greater than 2000 for |
| 944 | ## additional optimization. --nils@exp-math.uni-essen.de |
| 945 | test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \ |
| 946 | C_SWITCH_SYSTEM="-ma -qmaxmem=4000" |
| 947 | ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems. |
| 948 | ## It is redundant in glibc2, since we define _GNU_SOURCE. |
| 949 | AC_SUBST(C_SWITCH_SYSTEM) |
| 950 | |
| 951 | |
| 952 | LIBS_SYSTEM= |
| 953 | case "$opsys" in |
| 954 | ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2. |
| 955 | aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;; |
| 956 | |
| 957 | freebsd) LIBS_SYSTEM="-lutil" ;; |
| 958 | |
| 959 | hpux*) LIBS_SYSTEM="-l:libdld.sl" ;; |
| 960 | |
| 961 | sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;; |
| 962 | |
| 963 | ## Motif needs -lgen. |
| 964 | unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;; |
| 965 | esac |
| 966 | AC_SUBST(LIBS_SYSTEM) |
| 967 | |
| 968 | |
| 969 | ### Make sure subsequent tests use flags consistent with the build flags. |
| 970 | |
| 971 | if test x"${OVERRIDE_CPPFLAGS}" != x; then |
| 972 | CPPFLAGS="${OVERRIDE_CPPFLAGS}" |
| 973 | else |
| 974 | CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS" |
| 975 | fi |
| 976 | |
| 977 | # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better. |
| 978 | AC_DEFUN([AC_TYPE_SIZE_T]) |
| 979 | # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them. |
| 980 | AC_DEFUN([AC_TYPE_UID_T]) |
| 981 | |
| 982 | dnl Do this early because it can frob feature test macros for Unix-98 &c. |
| 983 | AC_SYS_LARGEFILE |
| 984 | |
| 985 | |
| 986 | LIB_MATH=-lm |
| 987 | LIB_STANDARD= |
| 988 | START_FILES= |
| 989 | |
| 990 | dnl NB do not use CRT_DIR unquoted here, since it might not be set yet. |
| 991 | case $opsys in |
| 992 | cygwin ) |
| 993 | LIB_MATH= |
| 994 | START_FILES='pre-crt0.o' |
| 995 | ;; |
| 996 | darwin ) |
| 997 | ## Adding -lm confuses the dynamic linker, so omit it. |
| 998 | LIB_MATH= |
| 999 | START_FILES='pre-crt0.o' |
| 1000 | ;; |
| 1001 | freebsd ) |
| 1002 | LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o' |
| 1003 | START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o' |
| 1004 | ;; |
| 1005 | gnu-linux | gnu-kfreebsd ) |
| 1006 | LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o' |
| 1007 | START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o' |
| 1008 | ;; |
| 1009 | hpux10-20 | hpux11 ) |
| 1010 | LIB_STANDARD=-lc |
| 1011 | START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o' |
| 1012 | ;; |
| 1013 | dnl NB this may be adjusted below. |
| 1014 | netbsd | openbsd ) |
| 1015 | LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o' |
| 1016 | START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o' |
| 1017 | ;; |
| 1018 | esac |
| 1019 | |
| 1020 | AC_SUBST(LIB_MATH) |
| 1021 | AC_SUBST(START_FILES) |
| 1022 | |
| 1023 | dnl Not all platforms use crtn.o files. Check if the current one does. |
| 1024 | crt_files= |
| 1025 | |
| 1026 | for file in x $LIB_STANDARD $START_FILES; do |
| 1027 | case "$file" in |
| 1028 | *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;; |
| 1029 | esac |
| 1030 | done |
| 1031 | |
| 1032 | if test "x$crt_files" != x; then |
| 1033 | |
| 1034 | ## If user specified a crt-dir, use that unconditionally. |
| 1035 | crt_gcc=no |
| 1036 | |
| 1037 | if test "X$CRT_DIR" = "X"; then |
| 1038 | |
| 1039 | CRT_DIR=/usr/lib # default |
| 1040 | |
| 1041 | case "$canonical" in |
| 1042 | x86_64-*-linux-gnu* | s390x-*-linux-gnu*) |
| 1043 | ## On x86-64 and s390x GNU/Linux distributions, the standard library |
| 1044 | ## can be in a variety of places. We only try /usr/lib64 and /usr/lib. |
| 1045 | ## For anything else (eg /usr/lib32), it is up the user to specify |
| 1046 | ## the location (bug#5655). |
| 1047 | ## Test for crtn.o, not just the directory, because sometimes the |
| 1048 | ## directory exists but does not have the relevant files (bug#1287). |
| 1049 | ## FIXME better to test for binary compatibility somehow. |
| 1050 | test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64 |
| 1051 | ;; |
| 1052 | |
| 1053 | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;; |
| 1054 | esac |
| 1055 | |
| 1056 | case "$opsys" in |
| 1057 | hpux10-20) CRT_DIR=/lib ;; |
| 1058 | esac |
| 1059 | |
| 1060 | test "x${GCC}" = xyes && crt_gcc=yes |
| 1061 | |
| 1062 | fi # CRT_DIR = "" |
| 1063 | |
| 1064 | crt_missing= |
| 1065 | |
| 1066 | for file in $crt_files; do |
| 1067 | |
| 1068 | ## If we're using gcc, try to determine it automatically by asking |
| 1069 | ## gcc. [If this doesn't work, CRT_DIR will remain at the |
| 1070 | ## system-dependent default from above.] |
| 1071 | if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then |
| 1072 | |
| 1073 | crt_file=`$CC --print-file-name=$file 2>/dev/null` |
| 1074 | case "$crt_file" in |
| 1075 | */*) |
| 1076 | CRT_DIR=`AS_DIRNAME(["$crt_file"])` |
| 1077 | ;; |
| 1078 | esac |
| 1079 | fi |
| 1080 | |
| 1081 | dnl We expect all the files to be in a single directory, so after the |
| 1082 | dnl first there is no point asking gcc. |
| 1083 | crt_gcc=no |
| 1084 | |
| 1085 | test -e $CRT_DIR/$file || crt_missing="$crt_missing $file" |
| 1086 | done # $crt_files |
| 1087 | |
| 1088 | test "x$crt_missing" = x || \ |
| 1089 | AC_MSG_ERROR([Required file(s) not found:$crt_missing |
| 1090 | Try using the --with-crt-dir option.]) |
| 1091 | |
| 1092 | fi # crt_files != "" |
| 1093 | |
| 1094 | AC_SUBST(CRT_DIR) |
| 1095 | |
| 1096 | case $opsys in |
| 1097 | netbsd | openbsd ) |
| 1098 | if test -f $CRT_DIR/crti.o; then |
| 1099 | |
| 1100 | test -f $CRT_DIR/crtn.o || \ |
| 1101 | AC_MSG_ERROR([Required file not found: crtn.o]) |
| 1102 | |
| 1103 | LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o' |
| 1104 | START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o' |
| 1105 | fi |
| 1106 | ;; |
| 1107 | esac |
| 1108 | |
| 1109 | |
| 1110 | dnl This function definition taken from Gnome 2.0 |
| 1111 | dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not) |
| 1112 | dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page |
| 1113 | dnl also defines GSTUFF_PKG_ERRORS on error |
| 1114 | AC_DEFUN([PKG_CHECK_MODULES], [ |
| 1115 | succeeded=no |
| 1116 | |
| 1117 | AC_PATH_PROG(PKG_CONFIG, pkg-config, no) |
| 1118 | |
| 1119 | if test "$PKG_CONFIG" = "no" ; then |
| 1120 | ifelse([$4], , [AC_MSG_ERROR([ |
| 1121 | *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog. Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4]) |
| 1122 | else |
| 1123 | PKG_CONFIG_MIN_VERSION=0.9.0 |
| 1124 | if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then |
| 1125 | AC_MSG_CHECKING(for $2) |
| 1126 | |
| 1127 | if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then |
| 1128 | AC_MSG_RESULT(yes) |
| 1129 | succeeded=yes |
| 1130 | |
| 1131 | AC_MSG_CHECKING($1_CFLAGS) |
| 1132 | $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'` |
| 1133 | AC_MSG_RESULT($$1_CFLAGS) |
| 1134 | |
| 1135 | AC_MSG_CHECKING($1_LIBS) |
| 1136 | $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'` |
| 1137 | AC_MSG_RESULT($$1_LIBS) |
| 1138 | else |
| 1139 | AC_MSG_RESULT(no) |
| 1140 | $1_CFLAGS="" |
| 1141 | $1_LIBS="" |
| 1142 | ## If we have a custom action on failure, don't print errors, but |
| 1143 | ## do set a variable so people can do so. |
| 1144 | $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"` |
| 1145 | ifelse([$4], ,echo $$1_PKG_ERRORS,) |
| 1146 | fi |
| 1147 | |
| 1148 | AC_SUBST($1_CFLAGS) |
| 1149 | AC_SUBST($1_LIBS) |
| 1150 | else |
| 1151 | echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer." |
| 1152 | echo "*** See http://www.freedesktop.org/software/pkgconfig" |
| 1153 | fi |
| 1154 | fi |
| 1155 | |
| 1156 | if test $succeeded = yes; then |
| 1157 | ifelse([$3], , :, [$3]) |
| 1158 | else |
| 1159 | ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4]) |
| 1160 | fi |
| 1161 | ]) |
| 1162 | |
| 1163 | |
| 1164 | if test "${with_sound}" != "no"; then |
| 1165 | # Sound support for GNU/Linux and the free BSDs. |
| 1166 | AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h, |
| 1167 | have_sound_header=yes) |
| 1168 | # Emulation library used on NetBSD. |
| 1169 | AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=) |
| 1170 | AC_SUBST(LIBSOUND) |
| 1171 | |
| 1172 | ALSA_REQUIRED=1.0.0 |
| 1173 | ALSA_MODULES="alsa >= $ALSA_REQUIRED" |
| 1174 | PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no) |
| 1175 | if test $HAVE_ALSA = yes; then |
| 1176 | SAVE_CFLAGS="$CFLAGS" |
| 1177 | SAVE_LIBS="$LIBS" |
| 1178 | CFLAGS="$ALSA_CFLAGS $CFLAGS" |
| 1179 | LIBS="$ALSA_LIBS $LIBS" |
| 1180 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])], |
| 1181 | emacs_alsa_normal=yes, |
| 1182 | emacs_alsa_normal=no) |
| 1183 | if test "$emacs_alsa_normal" != yes; then |
| 1184 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]], |
| 1185 | [[snd_lib_error_set_handler (0);]])], |
| 1186 | emacs_alsa_subdir=yes, |
| 1187 | emacs_alsa_subdir=no) |
| 1188 | if test "$emacs_alsa_subdir" != yes; then |
| 1189 | AC_MSG_ERROR([pkg-config found alsa, but it does not compile. See config.log for error messages.]) |
| 1190 | fi |
| 1191 | ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE" |
| 1192 | fi |
| 1193 | |
| 1194 | CFLAGS="$SAVE_CFLAGS" |
| 1195 | LIBS="$SAVE_LIBS" |
| 1196 | LIBSOUND="$LIBSOUND $ALSA_LIBS" |
| 1197 | CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS" |
| 1198 | AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.]) |
| 1199 | fi |
| 1200 | |
| 1201 | dnl Define HAVE_SOUND if we have sound support. We know it works and |
| 1202 | dnl compiles only on the specified platforms. For others, it |
| 1203 | dnl probably doesn't make sense to try. |
| 1204 | if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then |
| 1205 | case "$opsys" in |
| 1206 | dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__ |
| 1207 | gnu-linux|freebsd|netbsd) |
| 1208 | AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.]) |
| 1209 | ;; |
| 1210 | esac |
| 1211 | fi |
| 1212 | |
| 1213 | AC_SUBST(CFLAGS_SOUND) |
| 1214 | fi |
| 1215 | |
| 1216 | dnl checks for header files |
| 1217 | AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \ |
| 1218 | linux/version.h sys/systeminfo.h \ |
| 1219 | stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \ |
| 1220 | sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \ |
| 1221 | sys/utsname.h pwd.h utmp.h dirent.h util.h) |
| 1222 | |
| 1223 | AC_MSG_CHECKING(if personality LINUX32 can be set) |
| 1224 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])], |
| 1225 | emacs_cv_personality_linux32=yes, |
| 1226 | emacs_cv_personality_linux32=no) |
| 1227 | AC_MSG_RESULT($emacs_cv_personality_linux32) |
| 1228 | |
| 1229 | if test $emacs_cv_personality_linux32 = yes; then |
| 1230 | AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1, |
| 1231 | [Define to 1 if personality LINUX32 can be set.]) |
| 1232 | fi |
| 1233 | |
| 1234 | dnl On Solaris 8 there's a compilation warning for term.h because |
| 1235 | dnl it doesn't define `bool'. |
| 1236 | AC_CHECK_HEADERS(term.h, , , -) |
| 1237 | AC_HEADER_TIME |
| 1238 | AC_CHECK_DECLS([sys_siglist]) |
| 1239 | if test $ac_cv_have_decl_sys_siglist != yes; then |
| 1240 | # For Tru64, at least: |
| 1241 | AC_CHECK_DECLS([__sys_siglist]) |
| 1242 | if test $ac_cv_have_decl___sys_siglist = yes; then |
| 1243 | AC_DEFINE(sys_siglist, __sys_siglist, |
| 1244 | [Define to any substitute for sys_siglist.]) |
| 1245 | fi |
| 1246 | fi |
| 1247 | AC_HEADER_SYS_WAIT |
| 1248 | |
| 1249 | dnl Some systems have utime.h but don't declare the struct anyplace. |
| 1250 | AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf, |
| 1251 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME |
| 1252 | #include <sys/time.h> |
| 1253 | #include <time.h> |
| 1254 | #else |
| 1255 | #ifdef HAVE_SYS_TIME_H |
| 1256 | #include <sys/time.h> |
| 1257 | #else |
| 1258 | #include <time.h> |
| 1259 | #endif |
| 1260 | #endif |
| 1261 | #ifdef HAVE_UTIME_H |
| 1262 | #include <utime.h> |
| 1263 | #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])], |
| 1264 | emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no)) |
| 1265 | if test $emacs_cv_struct_utimbuf = yes; then |
| 1266 | AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.]) |
| 1267 | fi |
| 1268 | |
| 1269 | dnl Check for speed_t typedef. |
| 1270 | AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t, |
| 1271 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])], |
| 1272 | emacs_cv_speed_t=yes, emacs_cv_speed_t=no)]) |
| 1273 | if test $emacs_cv_speed_t = yes; then |
| 1274 | AC_DEFINE(HAVE_SPEED_T, 1, |
| 1275 | [Define to 1 if `speed_t' is declared by <termios.h>.]) |
| 1276 | fi |
| 1277 | |
| 1278 | AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval, |
| 1279 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME |
| 1280 | #include <sys/time.h> |
| 1281 | #include <time.h> |
| 1282 | #else |
| 1283 | #ifdef HAVE_SYS_TIME_H |
| 1284 | #include <sys/time.h> |
| 1285 | #else |
| 1286 | #include <time.h> |
| 1287 | #endif |
| 1288 | #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])], |
| 1289 | emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no)) |
| 1290 | HAVE_TIMEVAL=$emacs_cv_struct_timeval |
| 1291 | if test $emacs_cv_struct_timeval = yes; then |
| 1292 | AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.]) |
| 1293 | fi |
| 1294 | |
| 1295 | AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception, |
| 1296 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], |
| 1297 | [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])], |
| 1298 | emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no)) |
| 1299 | HAVE_EXCEPTION=$emacs_cv_struct_exception |
| 1300 | if test $emacs_cv_struct_exception != yes; then |
| 1301 | AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.]) |
| 1302 | fi |
| 1303 | |
| 1304 | AC_CHECK_HEADERS(sys/socket.h) |
| 1305 | AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT |
| 1306 | #if HAVE_SYS_SOCKET_H |
| 1307 | #include <sys/socket.h> |
| 1308 | #endif]) |
| 1309 | AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT |
| 1310 | #if HAVE_SYS_SOCKET_H |
| 1311 | #include <sys/socket.h> |
| 1312 | #endif]) |
| 1313 | AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT |
| 1314 | #if HAVE_SYS_SOCKET_H |
| 1315 | #include <sys/socket.h> |
| 1316 | #endif]) |
| 1317 | AC_CHECK_FUNCS(getifaddrs freeifaddrs) |
| 1318 | |
| 1319 | dnl checks for structure members |
| 1320 | AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr, |
| 1321 | struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr, |
| 1322 | struct ifreq.ifr_addr, |
| 1323 | struct ifreq.ifr_addr.sa_len], , , |
| 1324 | [AC_INCLUDES_DEFAULT |
| 1325 | #if HAVE_SYS_SOCKET_H |
| 1326 | #include <sys/socket.h> |
| 1327 | #endif |
| 1328 | #if HAVE_NET_IF_H |
| 1329 | #include <net/if.h> |
| 1330 | #endif]) |
| 1331 | |
| 1332 | dnl checks for compiler characteristics |
| 1333 | |
| 1334 | dnl Testing __STDC__ to determine prototype support isn't good enough. |
| 1335 | dnl DEC C, for instance, doesn't define it with default options, and |
| 1336 | dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile |
| 1337 | dnl and void *. |
| 1338 | AC_C_PROTOTYPES |
| 1339 | AC_C_VOLATILE |
| 1340 | AC_C_CONST |
| 1341 | AC_CACHE_CHECK([for void * support], emacs_cv_void_star, |
| 1342 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])], |
| 1343 | emacs_cv_void_star=yes, emacs_cv_void_star=no)]) |
| 1344 | if test $emacs_cv_void_star = yes; then |
| 1345 | AC_DEFINE(POINTER_TYPE, void) |
| 1346 | else |
| 1347 | AC_DEFINE(POINTER_TYPE, char) |
| 1348 | fi |
| 1349 | AH_TEMPLATE(POINTER_TYPE, |
| 1350 | [Define as `void' if your compiler accepts `void *'; otherwise |
| 1351 | define as `char'.])dnl |
| 1352 | |
| 1353 | dnl Check for endianness. |
| 1354 | AC_C_BIGENDIAN |
| 1355 | |
| 1356 | AC_CACHE_CHECK([for __attribute__ ((__aligned__ (expr)))], |
| 1357 | [emacs_cv_attribute_aligned], |
| 1358 | [AC_COMPILE_IFELSE( |
| 1359 | [AC_LANG_PROGRAM( |
| 1360 | [[char __attribute__ ((__aligned__ (1 << 3))) c;]], |
| 1361 | [[]])], |
| 1362 | [emacs_cv_attribute_aligned=yes], |
| 1363 | [emacs_cv_attribute_aligned=no])]) |
| 1364 | if test $emacs_cv_attribute_aligned = yes; then |
| 1365 | AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1, |
| 1366 | [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.]) |
| 1367 | fi |
| 1368 | |
| 1369 | dnl check for Make feature |
| 1370 | AC_PROG_MAKE_SET |
| 1371 | |
| 1372 | DEPFLAGS= |
| 1373 | MKDEPDIR=":" |
| 1374 | deps_frag=deps.mk |
| 1375 | dnl check for GNU Make if we have GCC and autodepend is on. |
| 1376 | if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then |
| 1377 | AC_MSG_CHECKING([whether we are using GNU Make]) |
| 1378 | HAVE_GNU_MAKE=no |
| 1379 | testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'` |
| 1380 | if test "x$testval" != x; then |
| 1381 | HAVE_GNU_MAKE=yes |
| 1382 | else |
| 1383 | ac_enable_autodepend=no |
| 1384 | fi |
| 1385 | AC_MSG_RESULT([$HAVE_GNU_MAKE]) |
| 1386 | if test $HAVE_GNU_MAKE = yes; then |
| 1387 | AC_MSG_CHECKING([whether gcc understands -MMD -MF]) |
| 1388 | SAVE_CFLAGS="$CFLAGS" |
| 1389 | CFLAGS="$CFLAGS -MMD -MF deps.d -MP" |
| 1390 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no) |
| 1391 | CFLAGS="$SAVE_CFLAGS" |
| 1392 | test -f deps.d || ac_enable_autodepend=no |
| 1393 | rm -rf deps.d |
| 1394 | AC_MSG_RESULT([$ac_enable_autodepend]) |
| 1395 | fi |
| 1396 | if test $ac_enable_autodepend = yes; then |
| 1397 | DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP' |
| 1398 | ## In parallel builds, another make might create depdir between |
| 1399 | ## the first test and mkdir, so stick another test on the end. |
| 1400 | ## Or use install-sh -d? mkdir -p is not portable. |
| 1401 | MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}' |
| 1402 | deps_frag=autodeps.mk |
| 1403 | fi |
| 1404 | fi |
| 1405 | deps_frag=$srcdir/src/$deps_frag |
| 1406 | AC_SUBST(MKDEPDIR) |
| 1407 | AC_SUBST(DEPFLAGS) |
| 1408 | AC_SUBST_FILE(deps_frag) |
| 1409 | |
| 1410 | |
| 1411 | lisp_frag=$srcdir/src/lisp.mk |
| 1412 | AC_SUBST_FILE(lisp_frag) |
| 1413 | |
| 1414 | |
| 1415 | dnl checks for operating system services |
| 1416 | AC_SYS_LONG_FILE_NAMES |
| 1417 | |
| 1418 | #### Choose a window system. |
| 1419 | |
| 1420 | AC_PATH_X |
| 1421 | if test "$no_x" = yes; then |
| 1422 | window_system=none |
| 1423 | else |
| 1424 | window_system=x11 |
| 1425 | fi |
| 1426 | |
| 1427 | ## Workaround for bug in autoconf <= 2.62. |
| 1428 | ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html |
| 1429 | ## No need to do anything special for these standard directories. |
| 1430 | if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then |
| 1431 | |
| 1432 | x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'` |
| 1433 | |
| 1434 | fi |
| 1435 | |
| 1436 | LD_SWITCH_X_SITE_AUX= |
| 1437 | LD_SWITCH_X_SITE_AUX_RPATH= |
| 1438 | if test "${x_libraries}" != NONE; then |
| 1439 | if test -n "${x_libraries}"; then |
| 1440 | LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"` |
| 1441 | LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"` |
| 1442 | LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'` |
| 1443 | fi |
| 1444 | x_default_search_path="" |
| 1445 | x_search_path=${x_libraries} |
| 1446 | if test -z "${x_search_path}"; then |
| 1447 | x_search_path=/usr/lib |
| 1448 | fi |
| 1449 | for x_library in `echo ${x_search_path}: | \ |
| 1450 | sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do |
| 1451 | x_search_path="\ |
| 1452 | ${x_library}/X11/%L/%T/%N%C%S:\ |
| 1453 | ${x_library}/X11/%l/%T/%N%C%S:\ |
| 1454 | ${x_library}/X11/%T/%N%C%S:\ |
| 1455 | ${x_library}/X11/%L/%T/%N%S:\ |
| 1456 | ${x_library}/X11/%l/%T/%N%S:\ |
| 1457 | ${x_library}/X11/%T/%N%S" |
| 1458 | if test x"${x_default_search_path}" = x; then |
| 1459 | x_default_search_path=${x_search_path} |
| 1460 | else |
| 1461 | x_default_search_path="${x_search_path}:${x_default_search_path}" |
| 1462 | fi |
| 1463 | done |
| 1464 | fi |
| 1465 | AC_SUBST(LD_SWITCH_X_SITE_AUX) |
| 1466 | AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH) |
| 1467 | |
| 1468 | if test "${x_includes}" != NONE && test -n "${x_includes}"; then |
| 1469 | C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"` |
| 1470 | fi |
| 1471 | |
| 1472 | if test x"${x_includes}" = x; then |
| 1473 | bitmapdir=/usr/include/X11/bitmaps |
| 1474 | else |
| 1475 | # accumulate include directories that have X11 bitmap subdirectories |
| 1476 | bmd_acc="dummyval" |
| 1477 | for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do |
| 1478 | if test -d "${bmd}/X11/bitmaps"; then |
| 1479 | bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps" |
| 1480 | fi |
| 1481 | if test -d "${bmd}/bitmaps"; then |
| 1482 | bmd_acc="${bmd_acc}:${bmd}/bitmaps" |
| 1483 | fi |
| 1484 | done |
| 1485 | if test ${bmd_acc} != "dummyval"; then |
| 1486 | bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"` |
| 1487 | fi |
| 1488 | fi |
| 1489 | |
| 1490 | HAVE_NS=no |
| 1491 | NS_IMPL_COCOA=no |
| 1492 | NS_IMPL_GNUSTEP=no |
| 1493 | tmp_CPPFLAGS="$CPPFLAGS" |
| 1494 | tmp_CFLAGS="$CFLAGS" |
| 1495 | CPPFLAGS="$CPPFLAGS -x objective-c" |
| 1496 | CFLAGS="$CFLAGS -x objective-c" |
| 1497 | TEMACS_LDFLAGS2="\${LDFLAGS}" |
| 1498 | GNU_OBJC_CFLAGS= |
| 1499 | dnl I don't think it's especially important, but src/Makefile.in |
| 1500 | dnl (now the only user of ns_appdir) used to go to the trouble of adding a |
| 1501 | dnl trailing "/" to it, so now we do it here. |
| 1502 | if test "${with_ns}" != no; then |
| 1503 | if test "${opsys}" = darwin; then |
| 1504 | NS_IMPL_COCOA=yes |
| 1505 | ns_appdir=`pwd`/nextstep/Emacs.app |
| 1506 | ns_appbindir=${ns_appdir}/Contents/MacOS/ |
| 1507 | ns_appresdir=${ns_appdir}/Contents/Resources |
| 1508 | ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base |
| 1509 | elif test -f $GNUSTEP_CONFIG_FILE; then |
| 1510 | NS_IMPL_GNUSTEP=yes |
| 1511 | ns_appdir=`pwd`/nextstep/Emacs.app |
| 1512 | ns_appbindir=${ns_appdir}/ |
| 1513 | ns_appresdir=${ns_appdir}/Resources |
| 1514 | ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base |
| 1515 | dnl FIXME sourcing this several times in subshells seems inefficient. |
| 1516 | GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)" |
| 1517 | GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)" |
| 1518 | dnl I seemed to need these as well with GNUstep-startup 0.25. |
| 1519 | GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)" |
| 1520 | GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)" |
| 1521 | test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \ |
| 1522 | GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}" |
| 1523 | test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \ |
| 1524 | GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}" |
| 1525 | CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}" |
| 1526 | CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}" |
| 1527 | LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}" |
| 1528 | LIB_STANDARD= |
| 1529 | START_FILES= |
| 1530 | TEMACS_LDFLAGS2= |
| 1531 | dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1. |
| 1532 | dnl If they had chosen to either define it or not, we could have |
| 1533 | dnl just used AC_CHECK_DECL here. |
| 1534 | AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS, |
| 1535 | emacs_cv_objc_exceptions, |
| 1536 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]], |
| 1537 | [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0 |
| 1538 | 1; |
| 1539 | #else |
| 1540 | fail; |
| 1541 | #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) ) |
| 1542 | if test $emacs_cv_objc_exceptions = yes; then |
| 1543 | dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers. |
| 1544 | AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1, |
| 1545 | [Define if GNUstep uses ObjC exceptions.]) |
| 1546 | GNU_OBJC_CFLAGS="-fobjc-exceptions" |
| 1547 | fi |
| 1548 | fi |
| 1549 | |
| 1550 | dnl This is only used while we test the NS headers, it gets reset below. |
| 1551 | CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS" |
| 1552 | |
| 1553 | AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes], |
| 1554 | [AC_MSG_ERROR([`--with-ns' was specified, but the include |
| 1555 | files are missing or cannot be compiled.])]) |
| 1556 | NS_HAVE_NSINTEGER=yes |
| 1557 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>], |
| 1558 | [NSInteger i;])], |
| 1559 | ns_have_nsinteger=yes, |
| 1560 | ns_have_nsinteger=no) |
| 1561 | if test $ns_have_nsinteger = no; then |
| 1562 | NS_HAVE_NSINTEGER=no |
| 1563 | fi |
| 1564 | fi |
| 1565 | AC_SUBST(TEMACS_LDFLAGS2) |
| 1566 | |
| 1567 | ns_frag=/dev/null |
| 1568 | NS_OBJ= |
| 1569 | NS_OBJC_OBJ= |
| 1570 | if test "${HAVE_NS}" = yes; then |
| 1571 | window_system=nextstep |
| 1572 | with_xft=no |
| 1573 | # set up packaging dirs |
| 1574 | if test "${EN_NS_SELF_CONTAINED}" = yes; then |
| 1575 | prefix=${ns_appresdir} |
| 1576 | exec_prefix=${ns_appbindir} |
| 1577 | libexecdir=${ns_appbindir}/libexec |
| 1578 | fi |
| 1579 | ns_frag=$srcdir/src/ns.mk |
| 1580 | NS_OBJ="fontset.o fringe.o image.o" |
| 1581 | NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o" |
| 1582 | fi |
| 1583 | CFLAGS="$tmp_CFLAGS" |
| 1584 | CPPFLAGS="$tmp_CPPFLAGS" |
| 1585 | AC_SUBST(NS_OBJ) |
| 1586 | AC_SUBST(NS_OBJC_OBJ) |
| 1587 | AC_SUBST(LIB_STANDARD) |
| 1588 | AC_SUBST_FILE(ns_frag) |
| 1589 | |
| 1590 | case "${window_system}" in |
| 1591 | x11 ) |
| 1592 | HAVE_X_WINDOWS=yes |
| 1593 | HAVE_X11=yes |
| 1594 | case "${with_x_toolkit}" in |
| 1595 | athena | lucid ) USE_X_TOOLKIT=LUCID ;; |
| 1596 | motif ) USE_X_TOOLKIT=MOTIF ;; |
| 1597 | gtk ) with_gtk=yes |
| 1598 | dnl Don't set this for GTK. A lot of tests below assumes Xt when |
| 1599 | dnl USE_X_TOOLKIT is set. |
| 1600 | USE_X_TOOLKIT=none ;; |
| 1601 | gtk3 ) with_gtk3=yes |
| 1602 | USE_X_TOOLKIT=none ;; |
| 1603 | no ) USE_X_TOOLKIT=none ;; |
| 1604 | dnl If user did not say whether to use a toolkit, make this decision later: |
| 1605 | dnl use the toolkit if we have gtk, or X11R5 or newer. |
| 1606 | * ) USE_X_TOOLKIT=maybe ;; |
| 1607 | esac |
| 1608 | ;; |
| 1609 | nextstep | none ) |
| 1610 | HAVE_X_WINDOWS=no |
| 1611 | HAVE_X11=no |
| 1612 | USE_X_TOOLKIT=none |
| 1613 | ;; |
| 1614 | esac |
| 1615 | |
| 1616 | if test "$window_system" = none && test "X$with_x" != "Xno"; then |
| 1617 | AC_CHECK_PROG(HAVE_XSERVER, X, true, false) |
| 1618 | if test "$HAVE_XSERVER" = true || |
| 1619 | test -n "$DISPLAY" || |
| 1620 | test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then |
| 1621 | AC_MSG_ERROR([You seem to be running X, but no X development libraries |
| 1622 | were found. You should install the relevant development files for X |
| 1623 | and for the toolkit you want, such as Gtk+, Lesstif or Motif. Also make |
| 1624 | sure you have development files for image handling, i.e. |
| 1625 | tiff, gif, jpeg, png and xpm. |
| 1626 | If you are sure you want Emacs compiled without X window support, pass |
| 1627 | --without-x |
| 1628 | to configure.]) |
| 1629 | fi |
| 1630 | fi |
| 1631 | |
| 1632 | ### If we're using X11, we should use the X menu package. |
| 1633 | HAVE_MENUS=no |
| 1634 | case ${HAVE_X11} in |
| 1635 | yes ) HAVE_MENUS=yes ;; |
| 1636 | esac |
| 1637 | |
| 1638 | # Do the opsystem or machine files prohibit the use of the GNU malloc? |
| 1639 | # Assume not, until told otherwise. |
| 1640 | GNU_MALLOC=yes |
| 1641 | doug_lea_malloc=yes |
| 1642 | AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no) |
| 1643 | AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no) |
| 1644 | AC_CACHE_CHECK(whether __after_morecore_hook exists, |
| 1645 | emacs_cv_var___after_morecore_hook, |
| 1646 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])], |
| 1647 | emacs_cv_var___after_morecore_hook=yes, |
| 1648 | emacs_cv_var___after_morecore_hook=no)]) |
| 1649 | if test $emacs_cv_var___after_morecore_hook = no; then |
| 1650 | doug_lea_malloc=no |
| 1651 | fi |
| 1652 | |
| 1653 | |
| 1654 | dnl See comments in aix4-2.h about maybe using system malloc there. |
| 1655 | system_malloc=no |
| 1656 | case "$opsys" in |
| 1657 | ## darwin ld insists on the use of malloc routines in the System framework. |
| 1658 | darwin|sol2-10) system_malloc=yes ;; |
| 1659 | esac |
| 1660 | |
| 1661 | if test "${system_malloc}" = "yes"; then |
| 1662 | AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.]) |
| 1663 | GNU_MALLOC=no |
| 1664 | GNU_MALLOC_reason=" |
| 1665 | (The GNU allocators don't work with this system configuration.)" |
| 1666 | GMALLOC_OBJ= |
| 1667 | VMLIMIT_OBJ= |
| 1668 | else |
| 1669 | test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o |
| 1670 | VMLIMIT_OBJ=vm-limit.o |
| 1671 | fi |
| 1672 | AC_SUBST(GMALLOC_OBJ) |
| 1673 | AC_SUBST(VMLIMIT_OBJ) |
| 1674 | |
| 1675 | if test "$doug_lea_malloc" = "yes" ; then |
| 1676 | if test "$GNU_MALLOC" = yes ; then |
| 1677 | GNU_MALLOC_reason=" |
| 1678 | (Using Doug Lea's new malloc from the GNU C Library.)" |
| 1679 | fi |
| 1680 | AC_DEFINE(DOUG_LEA_MALLOC, 1, |
| 1681 | [Define to 1 if you are using the GNU C Library.]) |
| 1682 | |
| 1683 | ## Use mmap directly for allocating larger buffers. |
| 1684 | ## FIXME this comes from src/s/{gnu,gnu-linux}.h: |
| 1685 | ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif |
| 1686 | ## Does the AC_FUNC_MMAP test below make this check unnecessary? |
| 1687 | case "$opsys" in |
| 1688 | gnu*) REL_ALLOC=no ;; |
| 1689 | esac |
| 1690 | fi |
| 1691 | |
| 1692 | if test x"${REL_ALLOC}" = x; then |
| 1693 | REL_ALLOC=${GNU_MALLOC} |
| 1694 | fi |
| 1695 | |
| 1696 | use_mmap_for_buffers=no |
| 1697 | case "$opsys" in |
| 1698 | cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;; |
| 1699 | esac |
| 1700 | |
| 1701 | AC_FUNC_MMAP |
| 1702 | if test $use_mmap_for_buffers = yes; then |
| 1703 | AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.]) |
| 1704 | REL_ALLOC=no |
| 1705 | fi |
| 1706 | |
| 1707 | LIBS="$LIBS_SYSTEM $LIBS" |
| 1708 | |
| 1709 | dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks, |
| 1710 | dnl and also adds -ldnet to LIBS, which Autoconf uses for checks. |
| 1711 | AC_CHECK_LIB(dnet, dnet_ntoa) |
| 1712 | dnl This causes -lresolv to get used in subsequent tests, |
| 1713 | dnl which causes failures on some systems such as HPUX 9. |
| 1714 | dnl AC_CHECK_LIB(resolv, gethostbyname) |
| 1715 | |
| 1716 | dnl FIXME replace main with a function we actually want from this library. |
| 1717 | AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd") |
| 1718 | |
| 1719 | dnl Check if pthreads is available. |
| 1720 | LIB_PTHREAD= |
| 1721 | AC_CHECK_HEADERS(pthread.h) |
| 1722 | if test "$ac_cv_header_pthread_h"; then |
| 1723 | dnl gmalloc.c uses pthread_atfork, which is not available on older-style |
| 1724 | dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely |
| 1725 | dnl testing for pthread_self if Emacs uses gmalloc.c. |
| 1726 | if test "$GMALLOC_OBJ" = gmalloc.o; then |
| 1727 | emacs_pthread_function=pthread_atfork |
| 1728 | else |
| 1729 | emacs_pthread_function=pthread_self |
| 1730 | fi |
| 1731 | AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes) |
| 1732 | fi |
| 1733 | if test "$HAVE_PTHREAD" = yes; then |
| 1734 | case "${canonical}" in |
| 1735 | *-hpux*) ;; |
| 1736 | *) LIB_PTHREAD="-lpthread" |
| 1737 | LIBS="$LIB_PTHREAD $LIBS" ;; |
| 1738 | esac |
| 1739 | AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).]) |
| 1740 | fi |
| 1741 | AC_SUBST([LIB_PTHREAD]) |
| 1742 | |
| 1743 | AC_CHECK_LIB(pthreads, cma_open) |
| 1744 | |
| 1745 | ## Note: when using cpp in s/aix4.2.h, this definition depended on |
| 1746 | ## HAVE_LIBPTHREADS. That was not defined earlier in configure when |
| 1747 | ## the system file was sourced. Hence the value of LIBS_SYSTEM |
| 1748 | ## added to LIBS in configure would never contain the pthreads part, |
| 1749 | ## but the value used in Makefiles might. FIXME? |
| 1750 | ## |
| 1751 | ## -lpthreads seems to be necessary for Xlib in X11R6, and should |
| 1752 | ## be harmless on older versions of X where it happens to exist. |
| 1753 | test "$opsys" = "aix4-2" && \ |
| 1754 | test $ac_cv_lib_pthreads_cma_open = yes && \ |
| 1755 | LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads" |
| 1756 | |
| 1757 | dnl Check for need for bigtoc support on IBM AIX |
| 1758 | |
| 1759 | case ${host_os} in |
| 1760 | aix*) |
| 1761 | AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [ |
| 1762 | case $GCC in |
| 1763 | yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;; |
| 1764 | *) gdb_cv_bigtoc=-bbigtoc ;; |
| 1765 | esac |
| 1766 | |
| 1767 | LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc |
| 1768 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=]) |
| 1769 | ]) |
| 1770 | ;; |
| 1771 | esac |
| 1772 | |
| 1773 | # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets |
| 1774 | # used for the tests that follow. We set them back to REAL_CFLAGS and |
| 1775 | # REAL_CPPFLAGS later on. |
| 1776 | |
| 1777 | REAL_CFLAGS="$CFLAGS" |
| 1778 | REAL_CPPFLAGS="$CPPFLAGS" |
| 1779 | |
| 1780 | if test "${HAVE_X11}" = "yes"; then |
| 1781 | DEFS="$C_SWITCH_X_SITE $DEFS" |
| 1782 | LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE" |
| 1783 | LIBS="-lX11 $LIBS" |
| 1784 | CFLAGS="$C_SWITCH_X_SITE $CFLAGS" |
| 1785 | CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS" |
| 1786 | |
| 1787 | # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests. |
| 1788 | # This is handled by LD_SWITCH_X_SITE_AUX during the real build, |
| 1789 | # but it's more convenient here to set LD_RUN_PATH |
| 1790 | # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX. |
| 1791 | if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then |
| 1792 | LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH |
| 1793 | export LD_RUN_PATH |
| 1794 | fi |
| 1795 | |
| 1796 | if test "${opsys}" = "gnu-linux"; then |
| 1797 | AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link) |
| 1798 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], |
| 1799 | [[XOpenDisplay ("foo");]])], |
| 1800 | [xgnu_linux_first_failure=no], |
| 1801 | [xgnu_linux_first_failure=yes]) |
| 1802 | if test "${xgnu_linux_first_failure}" = "yes"; then |
| 1803 | OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE" |
| 1804 | OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE" |
| 1805 | OLD_CPPFLAGS="$CPPFLAGS" |
| 1806 | OLD_LIBS="$LIBS" |
| 1807 | LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout" |
| 1808 | C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout" |
| 1809 | CPPFLAGS="$CPPFLAGS -b i486-linuxaout" |
| 1810 | LIBS="$LIBS -b i486-linuxaout" |
| 1811 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], |
| 1812 | [[XOpenDisplay ("foo");]])], |
| 1813 | [xgnu_linux_second_failure=no], |
| 1814 | [xgnu_linux_second_failure=yes]) |
| 1815 | if test "${xgnu_linux_second_failure}" = "yes"; then |
| 1816 | # If we get the same failure with -b, there is no use adding -b. |
| 1817 | # So take it out. This plays safe. |
| 1818 | LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE" |
| 1819 | C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE" |
| 1820 | CPPFLAGS="$OLD_CPPFLAGS" |
| 1821 | LIBS="$OLD_LIBS" |
| 1822 | AC_MSG_RESULT(no) |
| 1823 | else |
| 1824 | AC_MSG_RESULT(yes) |
| 1825 | fi |
| 1826 | else |
| 1827 | AC_MSG_RESULT(no) |
| 1828 | fi |
| 1829 | fi |
| 1830 | |
| 1831 | # Reportedly, some broken Solaris systems have XKBlib.h but are missing |
| 1832 | # header files included from there. |
| 1833 | AC_MSG_CHECKING(for Xkb) |
| 1834 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h> |
| 1835 | #include <X11/XKBlib.h>]], |
| 1836 | [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])], |
| 1837 | emacs_xkb=yes, emacs_xkb=no) |
| 1838 | AC_MSG_RESULT($emacs_xkb) |
| 1839 | if test $emacs_xkb = yes; then |
| 1840 | AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.]) |
| 1841 | fi |
| 1842 | |
| 1843 | AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \ |
| 1844 | XScreenNumberOfScreen XSetWMProtocols) |
| 1845 | fi |
| 1846 | |
| 1847 | if test "${window_system}" = "x11"; then |
| 1848 | AC_MSG_CHECKING(X11 version 6) |
| 1849 | AC_CACHE_VAL(emacs_cv_x11_version_6, |
| 1850 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], |
| 1851 | [[#if XlibSpecificationRelease < 6 |
| 1852 | fail; |
| 1853 | #endif |
| 1854 | ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)]) |
| 1855 | if test $emacs_cv_x11_version_6 = yes; then |
| 1856 | AC_MSG_RESULT(6 or newer) |
| 1857 | AC_DEFINE(HAVE_X11R6, 1, |
| 1858 | [Define to 1 if you have the X11R6 or newer version of Xlib.]) |
| 1859 | AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.]) |
| 1860 | ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style |
| 1861 | ## XIM support. |
| 1862 | case "$opsys" in |
| 1863 | sol2-*) : ;; |
| 1864 | *) AC_DEFINE(HAVE_X11R6_XIM, 1, |
| 1865 | [Define if you have usable X11R6-style XIM support.]) |
| 1866 | ;; |
| 1867 | esac |
| 1868 | else |
| 1869 | AC_MSG_RESULT(before 6) |
| 1870 | fi |
| 1871 | fi |
| 1872 | |
| 1873 | |
| 1874 | ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified. |
| 1875 | HAVE_RSVG=no |
| 1876 | if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then |
| 1877 | if test "${with_rsvg}" != "no"; then |
| 1878 | RSVG_REQUIRED=2.11.0 |
| 1879 | RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED" |
| 1880 | |
| 1881 | PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :) |
| 1882 | AC_SUBST(RSVG_CFLAGS) |
| 1883 | AC_SUBST(RSVG_LIBS) |
| 1884 | |
| 1885 | if test $HAVE_RSVG = yes; then |
| 1886 | AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.]) |
| 1887 | CFLAGS="$CFLAGS $RSVG_CFLAGS" |
| 1888 | LIBS="$RSVG_LIBS $LIBS" |
| 1889 | fi |
| 1890 | fi |
| 1891 | fi |
| 1892 | |
| 1893 | HAVE_IMAGEMAGICK=no |
| 1894 | if test "${HAVE_X11}" = "yes"; then |
| 1895 | if test "${with_imagemagick}" != "no"; then |
| 1896 | ## 6.2.8 is the earliest version known to work, but earlier versions |
| 1897 | ## might work - let us know if you find one. |
| 1898 | ## 6.0.7 does not work. See bug#7955. |
| 1899 | IMAGEMAGICK_MODULE="Wand >= 6.2.8" |
| 1900 | PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :) |
| 1901 | AC_SUBST(IMAGEMAGICK_CFLAGS) |
| 1902 | AC_SUBST(IMAGEMAGICK_LIBS) |
| 1903 | |
| 1904 | if test $HAVE_IMAGEMAGICK = yes; then |
| 1905 | AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.]) |
| 1906 | CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS" |
| 1907 | LIBS="$IMAGEMAGICK_LIBS $LIBS" |
| 1908 | AC_CHECK_FUNCS(MagickExportImagePixels) |
| 1909 | fi |
| 1910 | fi |
| 1911 | fi |
| 1912 | |
| 1913 | |
| 1914 | HAVE_GTK=no |
| 1915 | GTK_OBJ= |
| 1916 | if test "${with_gtk3}" = "yes"; then |
| 1917 | GLIB_REQUIRED=2.28 |
| 1918 | GTK_REQUIRED=3.0 |
| 1919 | GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED" |
| 1920 | |
| 1921 | dnl Checks for libraries. |
| 1922 | PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no) |
| 1923 | if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then |
| 1924 | AC_MSG_ERROR($GTK_PKG_ERRORS) |
| 1925 | fi |
| 1926 | AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.]) |
| 1927 | GTK_OBJ=emacsgtkfixed.o |
| 1928 | fi |
| 1929 | |
| 1930 | if test "$pkg_check_gtk" != "yes"; then |
| 1931 | HAVE_GTK=no |
| 1932 | if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then |
| 1933 | GLIB_REQUIRED=2.10 |
| 1934 | GTK_REQUIRED=2.10 |
| 1935 | GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED" |
| 1936 | |
| 1937 | dnl Checks for libraries. |
| 1938 | PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no) |
| 1939 | if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then |
| 1940 | AC_MSG_ERROR($GTK_PKG_ERRORS) |
| 1941 | fi |
| 1942 | fi |
| 1943 | fi |
| 1944 | |
| 1945 | if test x"$pkg_check_gtk" = xyes; then |
| 1946 | |
| 1947 | AC_SUBST(GTK_CFLAGS) |
| 1948 | AC_SUBST(GTK_LIBS) |
| 1949 | C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS" |
| 1950 | CFLAGS="$CFLAGS $GTK_CFLAGS" |
| 1951 | LIBS="$GTK_LIBS $LIBS" |
| 1952 | dnl Try to compile a simple GTK program. |
| 1953 | GTK_COMPILES=no |
| 1954 | AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes) |
| 1955 | if test "${GTK_COMPILES}" != "yes"; then |
| 1956 | if test "$USE_X_TOOLKIT" != "maybe"; then |
| 1957 | AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log. Maybe some x11-devel files missing?]); |
| 1958 | fi |
| 1959 | else |
| 1960 | HAVE_GTK=yes |
| 1961 | AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.]) |
| 1962 | GTK_OBJ="gtkutil.o $GTK_OBJ" |
| 1963 | USE_X_TOOLKIT=none |
| 1964 | if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then |
| 1965 | : |
| 1966 | else |
| 1967 | AC_MSG_WARN([[Your version of Gtk+ will have problems with |
| 1968 | closing open displays. This is no problem if you just use |
| 1969 | one display, but if you use more than one and close one of them |
| 1970 | Emacs may crash.]]) |
| 1971 | sleep 3 |
| 1972 | fi |
| 1973 | fi |
| 1974 | |
| 1975 | fi |
| 1976 | AC_SUBST(GTK_OBJ) |
| 1977 | |
| 1978 | |
| 1979 | if test "${HAVE_GTK}" = "yes"; then |
| 1980 | |
| 1981 | dnl GTK scrollbars resemble toolkit scrollbars a lot, so to avoid |
| 1982 | dnl a lot if #ifdef:s, say we have toolkit scrollbars. |
| 1983 | if test "$with_toolkit_scroll_bars" != no; then |
| 1984 | with_toolkit_scroll_bars=yes |
| 1985 | fi |
| 1986 | |
| 1987 | dnl Check if we have the old file selection dialog declared and |
| 1988 | dnl in the link library. In 2.x it may be in the library, |
| 1989 | dnl but not declared if deprecated featured has been selected out. |
| 1990 | dnl AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION. |
| 1991 | HAVE_GTK_FILE_SELECTION=no |
| 1992 | AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes, |
| 1993 | HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT |
| 1994 | #include <gtk/gtk.h>]) |
| 1995 | if test "$HAVE_GTK_FILE_SELECTION" = yes; then |
| 1996 | AC_CHECK_FUNCS(gtk_file_selection_new) |
| 1997 | fi |
| 1998 | |
| 1999 | |
| 2000 | dnl Check for functions introduced in 2.14 and later. |
| 2001 | AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \ |
| 2002 | gtk_dialog_get_action_area gtk_widget_get_sensitive \ |
| 2003 | gtk_widget_get_mapped gtk_adjustment_get_page_size \ |
| 2004 | gtk_orientable_set_orientation \ |
| 2005 | gtk_window_set_has_resize_grip) |
| 2006 | fi |
| 2007 | |
| 2008 | dnl D-Bus has been tested under GNU/Linux only. Must be adapted for |
| 2009 | dnl other platforms. Support for higher D-Bus versions than 1.0 is |
| 2010 | dnl also not configured. |
| 2011 | HAVE_DBUS=no |
| 2012 | DBUS_OBJ= |
| 2013 | if test "${with_dbus}" = "yes"; then |
| 2014 | PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no) |
| 2015 | if test "$HAVE_DBUS" = yes; then |
| 2016 | LIBS="$LIBS $DBUS_LIBS" |
| 2017 | AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.]) |
| 2018 | AC_CHECK_FUNCS([dbus_watch_get_unix_fd]) |
| 2019 | DBUS_OBJ=dbusbind.o |
| 2020 | fi |
| 2021 | fi |
| 2022 | AC_SUBST(DBUS_OBJ) |
| 2023 | |
| 2024 | dnl GSettings has been tested under GNU/Linux only. |
| 2025 | HAVE_GSETTINGS=no |
| 2026 | if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then |
| 2027 | PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no) |
| 2028 | if test "$HAVE_GSETTINGS" = "yes"; then |
| 2029 | AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.]) |
| 2030 | SETTINGS_CFLAGS="$GSETTINGS_CFLAGS" |
| 2031 | SETTINGS_LIBS="$GSETTINGS_LIBS" |
| 2032 | fi |
| 2033 | fi |
| 2034 | |
| 2035 | dnl GConf has been tested under GNU/Linux only. |
| 2036 | dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6. |
| 2037 | HAVE_GCONF=no |
| 2038 | if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then |
| 2039 | PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no) |
| 2040 | if test "$HAVE_GCONF" = yes; then |
| 2041 | AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.]) |
| 2042 | dnl Newer GConf doesn't link with g_objects, so this is not defined. |
| 2043 | SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS" |
| 2044 | SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS" |
| 2045 | fi |
| 2046 | fi |
| 2047 | |
| 2048 | if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then |
| 2049 | SAVE_CFLAGS="$CFLAGS" |
| 2050 | SAVE_LIBS="$LIBS" |
| 2051 | CFLAGS="$SETTINGS_CFLAGS $CFLAGS" |
| 2052 | LIBS="$SETTINGS_LIBS $LIBS" |
| 2053 | AC_CHECK_FUNCS([g_type_init]) |
| 2054 | CFLAGS="$SAVE_CFLAGS" |
| 2055 | LIBS="$SAVE_LIBS" |
| 2056 | fi |
| 2057 | AC_SUBST(SETTINGS_CFLAGS) |
| 2058 | AC_SUBST(SETTINGS_LIBS) |
| 2059 | |
| 2060 | |
| 2061 | dnl SELinux is available for GNU/Linux only. |
| 2062 | HAVE_LIBSELINUX=no |
| 2063 | LIBSELINUX_LIBS= |
| 2064 | if test "${with_selinux}" = "yes"; then |
| 2065 | AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no) |
| 2066 | if test "$HAVE_LIBSELINUX" = yes; then |
| 2067 | AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.]) |
| 2068 | LIBSELINUX_LIBS=-lselinux |
| 2069 | fi |
| 2070 | fi |
| 2071 | AC_SUBST(LIBSELINUX_LIBS) |
| 2072 | |
| 2073 | HAVE_GNUTLS=no |
| 2074 | HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no |
| 2075 | if test "${with_gnutls}" = "yes" ; then |
| 2076 | PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no) |
| 2077 | if test "${HAVE_GNUTLS}" = "yes"; then |
| 2078 | AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.]) |
| 2079 | fi |
| 2080 | |
| 2081 | CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS" |
| 2082 | LIBS="$LIBGNUTLS_LIBS $LIBS" |
| 2083 | AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes) |
| 2084 | |
| 2085 | if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then |
| 2086 | AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.]) |
| 2087 | fi |
| 2088 | fi |
| 2089 | |
| 2090 | AC_SUBST(LIBGNUTLS_LIBS) |
| 2091 | AC_SUBST(LIBGNUTLS_CFLAGS) |
| 2092 | |
| 2093 | dnl Do not put whitespace before the #include statements below. |
| 2094 | dnl Older compilers (eg sunos4 cc) choke on it. |
| 2095 | HAVE_XAW3D=no |
| 2096 | LUCID_LIBW= |
| 2097 | if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then |
| 2098 | if test "$with_xaw3d" != no; then |
| 2099 | AC_MSG_CHECKING(for xaw3d) |
| 2100 | AC_CACHE_VAL(emacs_cv_xaw3d, |
| 2101 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[ |
| 2102 | #include <X11/Intrinsic.h> |
| 2103 | #include <X11/Xaw3d/Simple.h>]], |
| 2104 | [[]])], |
| 2105 | [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, |
| 2106 | emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)], |
| 2107 | emacs_cv_xaw3d=no)]) |
| 2108 | else |
| 2109 | emacs_cv_xaw3d=no |
| 2110 | fi |
| 2111 | if test $emacs_cv_xaw3d = yes; then |
| 2112 | AC_MSG_RESULT([yes; using Lucid toolkit]) |
| 2113 | USE_X_TOOLKIT=LUCID |
| 2114 | HAVE_XAW3D=yes |
| 2115 | LUCID_LIBW=-lXaw3d |
| 2116 | AC_DEFINE(HAVE_XAW3D, 1, |
| 2117 | [Define to 1 if you have the Xaw3d library (-lXaw3d).]) |
| 2118 | else |
| 2119 | AC_MSG_RESULT(no) |
| 2120 | AC_MSG_CHECKING(for libXaw) |
| 2121 | AC_CACHE_VAL(emacs_cv_xaw, |
| 2122 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[ |
| 2123 | #include <X11/Intrinsic.h> |
| 2124 | #include <X11/Xaw/Simple.h>]], |
| 2125 | [[]])], |
| 2126 | emacs_cv_xaw=yes, |
| 2127 | emacs_cv_xaw=no)]) |
| 2128 | if test $emacs_cv_xaw = yes; then |
| 2129 | AC_MSG_RESULT([yes; using Lucid toolkit]) |
| 2130 | USE_X_TOOLKIT=LUCID |
| 2131 | LUCID_LIBW=-lXaw |
| 2132 | elif test x"${USE_X_TOOLKIT}" = xLUCID; then |
| 2133 | AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files]) |
| 2134 | else |
| 2135 | AC_MSG_ERROR([No X toolkit could be found. |
| 2136 | If you are sure you want Emacs compiled without an X toolkit, pass |
| 2137 | --with-x-toolkit=no |
| 2138 | to configure. Otherwise, install the development libraries for the toolkit |
| 2139 | that you want to use (e.g. Gtk+) and re-run configure.]) |
| 2140 | fi |
| 2141 | fi |
| 2142 | fi |
| 2143 | |
| 2144 | X_TOOLKIT_TYPE=$USE_X_TOOLKIT |
| 2145 | |
| 2146 | LIBXTR6= |
| 2147 | if test "${USE_X_TOOLKIT}" != "none"; then |
| 2148 | AC_MSG_CHECKING(X11 toolkit version) |
| 2149 | AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6, |
| 2150 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]], |
| 2151 | [[#if XtSpecificationRelease < 6 |
| 2152 | fail; |
| 2153 | #endif |
| 2154 | ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)]) |
| 2155 | HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6 |
| 2156 | if test $emacs_cv_x11_toolkit_version_6 = yes; then |
| 2157 | AC_MSG_RESULT(6 or newer) |
| 2158 | AC_DEFINE(HAVE_X11XTR6, 1, |
| 2159 | [Define to 1 if you have the X11R6 or newer version of Xt.]) |
| 2160 | LIBXTR6="-lSM -lICE" |
| 2161 | case "$opsys" in |
| 2162 | ## Use libw.a along with X11R6 Xt. |
| 2163 | unixware) LIBXTR6="$LIBXTR6 -lw" ;; |
| 2164 | esac |
| 2165 | else |
| 2166 | AC_MSG_RESULT(before 6) |
| 2167 | fi |
| 2168 | |
| 2169 | dnl If using toolkit, check whether libXmu.a exists. |
| 2170 | dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link. |
| 2171 | OLDLIBS="$LIBS" |
| 2172 | if test x$HAVE_X11XTR6 = xyes; then |
| 2173 | LIBS="-lXt -lSM -lICE $LIBS" |
| 2174 | else |
| 2175 | LIBS="-lXt $LIBS" |
| 2176 | fi |
| 2177 | AC_CHECK_LIB(Xmu, XmuConvertStandardSelection) |
| 2178 | test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS" |
| 2179 | fi |
| 2180 | AC_SUBST(LIBXTR6) |
| 2181 | |
| 2182 | dnl FIXME the logic here seems weird, but this is what cpp was doing. |
| 2183 | dnl Why not just test for libxmu in the normal way? |
| 2184 | LIBXMU=-lXmu |
| 2185 | case $opsys in |
| 2186 | ## These systems don't supply Xmu. |
| 2187 | hpux* | aix4-2 ) |
| 2188 | test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU= |
| 2189 | ;; |
| 2190 | esac |
| 2191 | AC_SUBST(LIBXMU) |
| 2192 | |
| 2193 | # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D. |
| 2194 | if test "${HAVE_X11}" = "yes"; then |
| 2195 | if test "${USE_X_TOOLKIT}" != "none"; then |
| 2196 | AC_CHECK_LIB(Xext, XShapeQueryExtension) |
| 2197 | fi |
| 2198 | fi |
| 2199 | |
| 2200 | LIBXP= |
| 2201 | if test "${USE_X_TOOLKIT}" = "MOTIF"; then |
| 2202 | AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1, |
| 2203 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]], |
| 2204 | [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1) |
| 2205 | int x = 5; |
| 2206 | #else |
| 2207 | Motif version prior to 2.1. |
| 2208 | #endif]])], |
| 2209 | emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)]) |
| 2210 | if test $emacs_cv_motif_version_2_1 = yes; then |
| 2211 | AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp) |
| 2212 | else |
| 2213 | AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif, |
| 2214 | # We put this in CFLAGS temporarily to precede other -I options |
| 2215 | # that might be in CFLAGS temporarily. |
| 2216 | # We put this in CPPFLAGS where it precedes the other -I options. |
| 2217 | OLD_CPPFLAGS=$CPPFLAGS |
| 2218 | OLD_CFLAGS=$CFLAGS |
| 2219 | CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS" |
| 2220 | CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS" |
| 2221 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]], |
| 2222 | [[int x = 5;]])], |
| 2223 | emacs_cv_lesstif=yes, emacs_cv_lesstif=no)]) |
| 2224 | if test $emacs_cv_lesstif = yes; then |
| 2225 | # Make sure this -I option remains in CPPFLAGS after it is set |
| 2226 | # back to REAL_CPPFLAGS. |
| 2227 | # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not |
| 2228 | # have those other -I options anyway. Ultimately, having this |
| 2229 | # directory ultimately in CPPFLAGS will be enough. |
| 2230 | REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS" |
| 2231 | LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS" |
| 2232 | else |
| 2233 | CFLAGS=$OLD_CFLAGS |
| 2234 | CPPFLAGS=$OLD_CPPFLAGS |
| 2235 | fi |
| 2236 | fi |
| 2237 | fi |
| 2238 | |
| 2239 | dnl Use toolkit scroll bars if configured for GTK or X toolkit and either |
| 2240 | dnl using Motif or Xaw3d is available, and unless |
| 2241 | dnl --with-toolkit-scroll-bars=no was specified. |
| 2242 | |
| 2243 | AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS, |
| 2244 | [Define to 1 if we should use toolkit scroll bars.])dnl |
| 2245 | USE_TOOLKIT_SCROLL_BARS=no |
| 2246 | if test "${with_toolkit_scroll_bars}" != "no"; then |
| 2247 | if test "${USE_X_TOOLKIT}" != "none"; then |
| 2248 | if test "${USE_X_TOOLKIT}" = "MOTIF"; then |
| 2249 | AC_DEFINE(USE_TOOLKIT_SCROLL_BARS) |
| 2250 | HAVE_XAW3D=no |
| 2251 | USE_TOOLKIT_SCROLL_BARS=yes |
| 2252 | elif test "${HAVE_XAW3D}" = "yes"; then |
| 2253 | AC_DEFINE(USE_TOOLKIT_SCROLL_BARS) |
| 2254 | USE_TOOLKIT_SCROLL_BARS=yes |
| 2255 | fi |
| 2256 | elif test "${HAVE_GTK}" = "yes"; then |
| 2257 | AC_DEFINE(USE_TOOLKIT_SCROLL_BARS) |
| 2258 | USE_TOOLKIT_SCROLL_BARS=yes |
| 2259 | elif test "${HAVE_NS}" = "yes"; then |
| 2260 | AC_DEFINE(USE_TOOLKIT_SCROLL_BARS) |
| 2261 | USE_TOOLKIT_SCROLL_BARS=yes |
| 2262 | fi |
| 2263 | fi |
| 2264 | |
| 2265 | dnl See if XIM is available. |
| 2266 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ |
| 2267 | #include <X11/Xlib.h> |
| 2268 | #include <X11/Xresource.h>]], |
| 2269 | [[XIMProc callback;]])], |
| 2270 | [HAVE_XIM=yes |
| 2271 | AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])], |
| 2272 | HAVE_XIM=no) |
| 2273 | |
| 2274 | dnl `--with-xim' now controls only the initial value of use_xim at run time. |
| 2275 | |
| 2276 | if test "${with_xim}" != "no"; then |
| 2277 | AC_DEFINE(USE_XIM, 1, |
| 2278 | [Define to 1 if we should use XIM, if it is available.]) |
| 2279 | fi |
| 2280 | |
| 2281 | |
| 2282 | if test "${HAVE_XIM}" != "no"; then |
| 2283 | late_CFLAGS=$CFLAGS |
| 2284 | if test "$GCC" = yes; then |
| 2285 | CFLAGS="$CFLAGS --pedantic-errors" |
| 2286 | fi |
| 2287 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ |
| 2288 | #include <X11/Xlib.h> |
| 2289 | #include <X11/Xresource.h>]], |
| 2290 | [[Display *display; |
| 2291 | XrmDatabase db; |
| 2292 | char *res_name; |
| 2293 | char *res_class; |
| 2294 | XIMProc callback; |
| 2295 | XPointer *client_data; |
| 2296 | #ifndef __GNUC__ |
| 2297 | /* If we're not using GCC, it's probably not XFree86, and this is |
| 2298 | probably right, but we can't use something like --pedantic-errors. */ |
| 2299 | extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*, |
| 2300 | char*, XIMProc, XPointer*); |
| 2301 | #endif |
| 2302 | (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback, |
| 2303 | client_data);]])], |
| 2304 | [emacs_cv_arg6_star=yes]) |
| 2305 | AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6, |
| 2306 | [Define to the type of the 6th arg of XRegisterIMInstantiateCallback, |
| 2307 | either XPointer or XPointer*.])dnl |
| 2308 | if test "$emacs_cv_arg6_star" = yes; then |
| 2309 | AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*]) |
| 2310 | else |
| 2311 | AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer]) |
| 2312 | fi |
| 2313 | CFLAGS=$late_CFLAGS |
| 2314 | fi |
| 2315 | |
| 2316 | ### Start of font-backend (under any platform) section. |
| 2317 | # (nothing here yet -- this is a placeholder) |
| 2318 | ### End of font-backend (under any platform) section. |
| 2319 | |
| 2320 | ### Start of font-backend (under X11) section. |
| 2321 | if test "${HAVE_X11}" = "yes"; then |
| 2322 | PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no) |
| 2323 | |
| 2324 | ## Use -lXft if available, unless `--with-xft=no'. |
| 2325 | HAVE_XFT=maybe |
| 2326 | if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then |
| 2327 | with_xft="no"; |
| 2328 | fi |
| 2329 | if test "x${with_xft}" != "xno"; then |
| 2330 | |
| 2331 | PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no) |
| 2332 | ## Because xftfont.c uses XRenderQueryExtension, we also |
| 2333 | ## need to link to -lXrender. |
| 2334 | HAVE_XRENDER=no |
| 2335 | AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes) |
| 2336 | if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then |
| 2337 | OLD_CPPFLAGS="$CPPFLAGS" |
| 2338 | OLD_CFLAGS="$CFLAGS" |
| 2339 | OLD_LIBS="$LIBS" |
| 2340 | CPPFLAGS="$CPPFLAGS $XFT_CFLAGS" |
| 2341 | CFLAGS="$CFLAGS $XFT_CFLAGS" |
| 2342 | XFT_LIBS="-lXrender $XFT_LIBS" |
| 2343 | LIBS="$XFT_LIBS $LIBS" |
| 2344 | AC_CHECK_HEADER(X11/Xft/Xft.h, |
| 2345 | AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS)) |
| 2346 | |
| 2347 | if test "${HAVE_XFT}" = "yes"; then |
| 2348 | AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.]) |
| 2349 | AC_SUBST(XFT_LIBS) |
| 2350 | C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS" |
| 2351 | else |
| 2352 | CPPFLAGS="$OLD_CPPFLAGS" |
| 2353 | CFLAGS="$OLD_CFLAGS" |
| 2354 | LIBS="$OLD_LIBS" |
| 2355 | fi # "${HAVE_XFT}" = "yes" |
| 2356 | fi # "$HAVE_XFT" != no |
| 2357 | fi # "x${with_xft}" != "xno" |
| 2358 | |
| 2359 | ## We used to allow building with FreeType and without Xft. |
| 2360 | ## However, the ftx font backend driver is not in good shape. |
| 2361 | if test "$HAVE_XFT" != "yes"; then |
| 2362 | dnl For the "Does Emacs use" message at the end. |
| 2363 | HAVE_XFT=no |
| 2364 | HAVE_FREETYPE=no |
| 2365 | else |
| 2366 | dnl Strict linkers fail with |
| 2367 | dnl ftfont.o: undefined reference to symbol 'FT_New_Face' |
| 2368 | dnl if -lfreetype is not specified. |
| 2369 | dnl The following is needed to set FREETYPE_LIBS. |
| 2370 | PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, |
| 2371 | HAVE_FREETYPE=no) |
| 2372 | |
| 2373 | test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype) |
| 2374 | fi |
| 2375 | |
| 2376 | HAVE_LIBOTF=no |
| 2377 | if test "${HAVE_FREETYPE}" = "yes"; then |
| 2378 | AC_DEFINE(HAVE_FREETYPE, 1, |
| 2379 | [Define to 1 if using the freetype and fontconfig libraries.]) |
| 2380 | if test "${with_libotf}" != "no"; then |
| 2381 | PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes, |
| 2382 | HAVE_LIBOTF=no) |
| 2383 | if test "$HAVE_LIBOTF" = "yes"; then |
| 2384 | AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.]) |
| 2385 | AC_CHECK_LIB(otf, OTF_get_variation_glyphs, |
| 2386 | HAVE_OTF_GET_VARIATION_GLYPHS=yes, |
| 2387 | HAVE_OTF_GET_VARIATION_GLYPHS=no) |
| 2388 | if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then |
| 2389 | AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1, |
| 2390 | [Define to 1 if libotf has OTF_get_variation_glyphs.]) |
| 2391 | fi |
| 2392 | fi |
| 2393 | fi |
| 2394 | dnl FIXME should there be an error if HAVE_FREETYPE != yes? |
| 2395 | dnl Does the new font backend require it, or can it work without it? |
| 2396 | fi |
| 2397 | |
| 2398 | HAVE_M17N_FLT=no |
| 2399 | if test "${HAVE_LIBOTF}" = yes; then |
| 2400 | if test "${with_m17n_flt}" != "no"; then |
| 2401 | PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no) |
| 2402 | if test "$HAVE_M17N_FLT" = "yes"; then |
| 2403 | AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.]) |
| 2404 | fi |
| 2405 | fi |
| 2406 | fi |
| 2407 | else |
| 2408 | HAVE_XFT=no |
| 2409 | HAVE_FREETYPE=no |
| 2410 | HAVE_LIBOTF=no |
| 2411 | HAVE_M17N_FLT=no |
| 2412 | fi |
| 2413 | |
| 2414 | ### End of font-backend (under X11) section. |
| 2415 | |
| 2416 | AC_SUBST(FREETYPE_CFLAGS) |
| 2417 | AC_SUBST(FREETYPE_LIBS) |
| 2418 | AC_SUBST(FONTCONFIG_CFLAGS) |
| 2419 | AC_SUBST(FONTCONFIG_LIBS) |
| 2420 | AC_SUBST(LIBOTF_CFLAGS) |
| 2421 | AC_SUBST(LIBOTF_LIBS) |
| 2422 | AC_SUBST(M17N_FLT_CFLAGS) |
| 2423 | AC_SUBST(M17N_FLT_LIBS) |
| 2424 | |
| 2425 | ### Use -lXpm if available, unless `--with-xpm=no'. |
| 2426 | HAVE_XPM=no |
| 2427 | LIBXPM= |
| 2428 | if test "${HAVE_X11}" = "yes"; then |
| 2429 | if test "${with_xpm}" != "no"; then |
| 2430 | AC_CHECK_HEADER(X11/xpm.h, |
| 2431 | [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)]) |
| 2432 | if test "${HAVE_XPM}" = "yes"; then |
| 2433 | AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define) |
| 2434 | AC_EGREP_CPP(no_return_alloc_pixels, |
| 2435 | [#include "X11/xpm.h" |
| 2436 | #ifndef XpmReturnAllocPixels |
| 2437 | no_return_alloc_pixels |
| 2438 | #endif |
| 2439 | ], HAVE_XPM=no, HAVE_XPM=yes) |
| 2440 | |
| 2441 | if test "${HAVE_XPM}" = "yes"; then |
| 2442 | AC_MSG_RESULT(yes) |
| 2443 | else |
| 2444 | AC_MSG_RESULT(no) |
| 2445 | fi |
| 2446 | fi |
| 2447 | fi |
| 2448 | |
| 2449 | if test "${HAVE_XPM}" = "yes"; then |
| 2450 | AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).]) |
| 2451 | LIBXPM=-lXpm |
| 2452 | fi |
| 2453 | fi |
| 2454 | AC_SUBST(LIBXPM) |
| 2455 | |
| 2456 | ### Use -ljpeg if available, unless `--with-jpeg=no'. |
| 2457 | HAVE_JPEG=no |
| 2458 | LIBJPEG= |
| 2459 | if test "${HAVE_X11}" = "yes"; then |
| 2460 | if test "${with_jpeg}" != "no"; then |
| 2461 | dnl Checking for jpeglib.h can lose because of a redefinition of |
| 2462 | dnl HAVE_STDLIB_H. |
| 2463 | AC_CHECK_HEADER(jerror.h, |
| 2464 | [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)]) |
| 2465 | fi |
| 2466 | |
| 2467 | AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl |
| 2468 | if test "${HAVE_JPEG}" = "yes"; then |
| 2469 | AC_DEFINE(HAVE_JPEG) |
| 2470 | AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])], |
| 2471 | [#include <jpeglib.h> |
| 2472 | version=JPEG_LIB_VERSION |
| 2473 | ], |
| 2474 | [AC_DEFINE(HAVE_JPEG)], |
| 2475 | [AC_MSG_WARN([libjpeg found, but not version 6b or later]) |
| 2476 | HAVE_JPEG=no]) |
| 2477 | fi |
| 2478 | if test "${HAVE_JPEG}" = "yes"; then |
| 2479 | LIBJPEG=-ljpeg |
| 2480 | fi |
| 2481 | fi |
| 2482 | AC_SUBST(LIBJPEG) |
| 2483 | |
| 2484 | ### Use -lpng if available, unless `--with-png=no'. |
| 2485 | HAVE_PNG=no |
| 2486 | LIBPNG= |
| 2487 | if test "${HAVE_X11}" = "yes"; then |
| 2488 | if test "${with_png}" != "no"; then |
| 2489 | # Debian unstable as of July 2003 has multiple libpngs, and puts png.h |
| 2490 | # in /usr/include/libpng. |
| 2491 | AC_CHECK_HEADERS(png.h libpng/png.h) |
| 2492 | if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then |
| 2493 | AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm) |
| 2494 | fi |
| 2495 | fi |
| 2496 | |
| 2497 | if test "${HAVE_PNG}" = "yes"; then |
| 2498 | AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).]) |
| 2499 | LIBPNG="-lpng -lz -lm" |
| 2500 | fi |
| 2501 | fi |
| 2502 | AC_SUBST(LIBPNG) |
| 2503 | |
| 2504 | ### Use -ltiff if available, unless `--with-tiff=no'. |
| 2505 | HAVE_TIFF=no |
| 2506 | LIBTIFF= |
| 2507 | if test "${HAVE_X11}" = "yes"; then |
| 2508 | if test "${with_tiff}" != "no"; then |
| 2509 | AC_CHECK_HEADER(tiffio.h, |
| 2510 | [tifflibs="-lz -lm" |
| 2511 | # At least one tiff package requires the jpeg library. |
| 2512 | if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi |
| 2513 | AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)]) |
| 2514 | fi |
| 2515 | |
| 2516 | if test "${HAVE_TIFF}" = "yes"; then |
| 2517 | AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).]) |
| 2518 | dnl FIXME -lz -lm, as per libpng? |
| 2519 | LIBTIFF=-ltiff |
| 2520 | fi |
| 2521 | fi |
| 2522 | AC_SUBST(LIBTIFF) |
| 2523 | |
| 2524 | ### Use -lgif or -lungif if available, unless `--with-gif=no'. |
| 2525 | HAVE_GIF=no |
| 2526 | LIBGIF= |
| 2527 | if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then |
| 2528 | AC_CHECK_HEADER(gif_lib.h, |
| 2529 | # EGifPutExtensionLast only exists from version libungif-4.1.0b1. |
| 2530 | # Earlier versions can crash Emacs. |
| 2531 | [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)]) |
| 2532 | |
| 2533 | if test "$HAVE_GIF" = yes; then |
| 2534 | LIBGIF=-lgif |
| 2535 | elif test "$HAVE_GIF" = maybe; then |
| 2536 | # If gif_lib.h but no libgif, try libungif. |
| 2537 | AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no) |
| 2538 | test "$HAVE_GIF" = yes && LIBGIF=-lungif |
| 2539 | fi |
| 2540 | |
| 2541 | if test "${HAVE_GIF}" = "yes"; then |
| 2542 | AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.]) |
| 2543 | fi |
| 2544 | fi |
| 2545 | AC_SUBST(LIBGIF) |
| 2546 | |
| 2547 | dnl Check for required libraries. |
| 2548 | if test "${HAVE_X11}" = "yes"; then |
| 2549 | MISSING="" |
| 2550 | WITH_NO="" |
| 2551 | test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" && |
| 2552 | MISSING="libXpm" && WITH_NO="--with-xpm=no" |
| 2553 | test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" && |
| 2554 | MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no" |
| 2555 | test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" && |
| 2556 | MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no" |
| 2557 | test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" && |
| 2558 | MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no" |
| 2559 | test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" && |
| 2560 | MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no" |
| 2561 | |
| 2562 | if test "X${MISSING}" != X; then |
| 2563 | AC_MSG_ERROR([The following required libraries were not found: |
| 2564 | $MISSING |
| 2565 | Maybe some development libraries/packages are missing? |
| 2566 | If you don't want to link with them give |
| 2567 | $WITH_NO |
| 2568 | as options to configure]) |
| 2569 | fi |
| 2570 | fi |
| 2571 | |
| 2572 | ### Use -lgpm if available, unless `--with-gpm=no'. |
| 2573 | HAVE_GPM=no |
| 2574 | LIBGPM= |
| 2575 | if test "${with_gpm}" != "no"; then |
| 2576 | AC_CHECK_HEADER(gpm.h, |
| 2577 | [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)]) |
| 2578 | |
| 2579 | if test "${HAVE_GPM}" = "yes"; then |
| 2580 | AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).]) |
| 2581 | LIBGPM=-lgpm |
| 2582 | fi |
| 2583 | fi |
| 2584 | AC_SUBST(LIBGPM) |
| 2585 | |
| 2586 | dnl Check for malloc/malloc.h on darwin |
| 2587 | AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])]) |
| 2588 | |
| 2589 | C_SWITCH_X_SYSTEM= |
| 2590 | ### Use NeXTstep API to implement GUI. |
| 2591 | if test "${HAVE_NS}" = "yes"; then |
| 2592 | AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.]) |
| 2593 | if test "${NS_IMPL_COCOA}" = "yes"; then |
| 2594 | AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.]) |
| 2595 | fi |
| 2596 | if test "${NS_IMPL_GNUSTEP}" = "yes"; then |
| 2597 | AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.]) |
| 2598 | # See also .m.o rule in Makefile.in */ |
| 2599 | # FIXME: are all these flags really needed? Document here why. */ |
| 2600 | dnl FIXME this should be renamed to GNUSTEP_CFLAGS, and only |
| 2601 | dnl used in src/Makefile.in. |
| 2602 | C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}" |
| 2603 | ## Extra CFLAGS applied to src/*.m files. |
| 2604 | GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE" |
| 2605 | fi |
| 2606 | if test "${NS_HAVE_NSINTEGER}" = "yes"; then |
| 2607 | AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.]) |
| 2608 | fi |
| 2609 | # We also have mouse menus. |
| 2610 | HAVE_MENUS=yes |
| 2611 | OTHER_FILES=ns-app |
| 2612 | fi |
| 2613 | |
| 2614 | |
| 2615 | ### Use session management (-lSM -lICE) if available |
| 2616 | HAVE_X_SM=no |
| 2617 | LIBXSM= |
| 2618 | if test "${HAVE_X11}" = "yes"; then |
| 2619 | AC_CHECK_HEADER(X11/SM/SMlib.h, |
| 2620 | [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)]) |
| 2621 | |
| 2622 | if test "${HAVE_X_SM}" = "yes"; then |
| 2623 | AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).]) |
| 2624 | LIBXSM="-lSM -lICE" |
| 2625 | case "$LIBS" in |
| 2626 | *-lSM*) ;; |
| 2627 | *) LIBS="$LIBXSM $LIBS" ;; |
| 2628 | esac |
| 2629 | fi |
| 2630 | fi |
| 2631 | AC_SUBST(LIBXSM) |
| 2632 | |
| 2633 | ### Use libxml (-lxml2) if available |
| 2634 | HAVE_LIBXML2=no |
| 2635 | if test "${with_xml2}" != "no"; then |
| 2636 | ### I'm not sure what the version number should be, so I just guessed. |
| 2637 | PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no) |
| 2638 | if test "${HAVE_LIBXML2}" = "yes"; then |
| 2639 | LIBS="$LIBXML2_LIBS $LIBS" |
| 2640 | AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no) |
| 2641 | if test "${HAVE_LIBXML2}" = "yes"; then |
| 2642 | AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).]) |
| 2643 | else |
| 2644 | LIBXML2_LIBS="" |
| 2645 | LIBXML2_CFLAGS="" |
| 2646 | fi |
| 2647 | fi |
| 2648 | fi |
| 2649 | AC_SUBST(LIBXML2_LIBS) |
| 2650 | AC_SUBST(LIBXML2_CFLAGS) |
| 2651 | |
| 2652 | # If netdb.h doesn't declare h_errno, we must declare it by hand. |
| 2653 | AC_CACHE_CHECK(whether netdb declares h_errno, |
| 2654 | emacs_cv_netdb_declares_h_errno, |
| 2655 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], |
| 2656 | [[return h_errno;]])], |
| 2657 | emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)]) |
| 2658 | if test $emacs_cv_netdb_declares_h_errno = yes; then |
| 2659 | AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.]) |
| 2660 | fi |
| 2661 | |
| 2662 | # fmod, logb, and frexp are found in -lm on most systems. |
| 2663 | # On HPUX 9.01, -lm does not contain logb, so check for sqrt. |
| 2664 | AC_CHECK_LIB(m, sqrt) |
| 2665 | |
| 2666 | # Check for mail-locking functions in a "mail" library. Probably this should |
| 2667 | # have the same check as for liblockfile below. |
| 2668 | AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no) |
| 2669 | if test $have_mail = yes; then |
| 2670 | LIBS_MAIL=-lmail |
| 2671 | LIBS="$LIBS_MAIL $LIBS" |
| 2672 | AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).]) |
| 2673 | else |
| 2674 | LIBS_MAIL= |
| 2675 | fi |
| 2676 | dnl Debian, at least: |
| 2677 | AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no) |
| 2678 | if test $have_lockfile = yes; then |
| 2679 | LIBS_MAIL=-llockfile |
| 2680 | LIBS="$LIBS_MAIL $LIBS" |
| 2681 | AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).]) |
| 2682 | else |
| 2683 | # If we have the shared liblockfile, assume we must use it for mail |
| 2684 | # locking (e.g. Debian). If we couldn't link against liblockfile |
| 2685 | # (no liblockfile.a installed), ensure that we don't need to. |
| 2686 | dnl This works for files generally, not just executables. |
| 2687 | dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf? |
| 2688 | AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no, |
| 2689 | /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH) |
| 2690 | if test $ac_cv_prog_liblockfile = yes; then |
| 2691 | AC_MSG_ERROR([Shared liblockfile found but can't link against it. |
| 2692 | This probably means that movemail could lose mail. |
| 2693 | There may be a `development' package to install containing liblockfile.]) |
| 2694 | fi |
| 2695 | fi |
| 2696 | AC_CHECK_FUNCS(touchlock) |
| 2697 | AC_CHECK_HEADERS(maillock.h) |
| 2698 | AC_SUBST(LIBS_MAIL) |
| 2699 | |
| 2700 | ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to |
| 2701 | ## interlock access to the mail spool. The alternative is a lock file named |
| 2702 | ## /usr/spool/mail/$USER.lock. |
| 2703 | mail_lock=no |
| 2704 | case "$opsys" in |
| 2705 | aix4-2) mail_lock="lockf" ;; |
| 2706 | |
| 2707 | gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;; |
| 2708 | |
| 2709 | ## On GNU/Linux systems, both methods are used by various mail programs. |
| 2710 | ## I assume most people are using newer mailers that have heard of flock. |
| 2711 | ## Change this if you need to. |
| 2712 | ## Debian contains a patch which says: ``On Debian/GNU/Linux systems, |
| 2713 | ## configure gets the right answers, and that means *NOT* using flock. |
| 2714 | ## Using flock is guaranteed to be the wrong thing. See Debian Policy |
| 2715 | ## for details.'' and then uses `#ifdef DEBIAN'. Unfortunately the |
| 2716 | ## Debian maintainer hasn't provided a clean fix for Emacs. |
| 2717 | ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and |
| 2718 | ## HAVE_MAILLOCK_H are defined, so the following appears to be the |
| 2719 | ## correct logic. -- fx |
| 2720 | ## We must check for HAVE_LIBLOCKFILE too, as movemail does. |
| 2721 | ## liblockfile is a Free Software replacement for libmail, used on |
| 2722 | ## Debian systems and elsewhere. -rfr. |
| 2723 | gnu-*) |
| 2724 | mail_lock="flock" |
| 2725 | if test $have_mail = yes || test $have_lockfile = yes; then |
| 2726 | test $ac_cv_header_maillock_h = yes && mail_lock=no |
| 2727 | fi |
| 2728 | ;; |
| 2729 | esac |
| 2730 | |
| 2731 | BLESSMAIL_TARGET= |
| 2732 | case "$mail_lock" in |
| 2733 | flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;; |
| 2734 | |
| 2735 | lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;; |
| 2736 | |
| 2737 | *) BLESSMAIL_TARGET="need-blessmail" ;; |
| 2738 | esac |
| 2739 | AC_SUBST(BLESSMAIL_TARGET) |
| 2740 | |
| 2741 | |
| 2742 | AC_CHECK_FUNCS(gethostname getdomainname \ |
| 2743 | rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \ |
| 2744 | random lrand48 logb frexp fmod rint cbrt ftime setsid \ |
| 2745 | strerror fpathconf select euidaccess getpagesize tzset setlocale \ |
| 2746 | utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \ |
| 2747 | __fpending mblen mbrlen mbsinit strsignal setitimer ualarm \ |
| 2748 | sendto recvfrom getsockopt setsockopt getsockname getpeername \ |
| 2749 | gai_strerror mkstemp getline getdelim mremap fsync sync \ |
| 2750 | difftime mempcpy mblen mbrlen posix_memalign \ |
| 2751 | cfmakeraw cfsetspeed copysign __executable_start) |
| 2752 | |
| 2753 | dnl Cannot use AC_CHECK_FUNCS |
| 2754 | AC_CACHE_CHECK([for __builtin_unwind_init], |
| 2755 | emacs_cv_func___builtin_unwind_init, |
| 2756 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])], |
| 2757 | emacs_cv_func___builtin_unwind_init=yes, |
| 2758 | emacs_cv_func___builtin_unwind_init=no)]) |
| 2759 | if test $emacs_cv_func___builtin_unwind_init = yes; then |
| 2760 | AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1, |
| 2761 | [Define to 1 if you have the `__builtin_unwind_init' function.]) |
| 2762 | fi |
| 2763 | |
| 2764 | AC_CHECK_HEADERS(sys/un.h) |
| 2765 | |
| 2766 | AC_FUNC_FSEEKO |
| 2767 | |
| 2768 | AC_FUNC_GETPGRP |
| 2769 | |
| 2770 | # UNIX98 PTYs. |
| 2771 | AC_CHECK_FUNCS(grantpt) |
| 2772 | |
| 2773 | # PTY-related GNU extensions. |
| 2774 | AC_CHECK_FUNCS(getpt) |
| 2775 | |
| 2776 | # Check this now, so that we will NOT find the above functions in ncurses. |
| 2777 | # That is because we have not set up to link ncurses in lib-src. |
| 2778 | # It's better to believe a function is not available |
| 2779 | # than to expect to find it in ncurses. |
| 2780 | # Also we need tputs and friends to be able to build at all. |
| 2781 | have_tputs_et_al=true |
| 2782 | # Maybe curses should be tried earlier? |
| 2783 | # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35 |
| 2784 | AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap curses], , have_tputs_et_al=false) |
| 2785 | if test "$have_tputs_et_al" != true; then |
| 2786 | AC_MSG_ERROR([The required function `tputs' was not found in any library. |
| 2787 | These libraries were tried: libncurses, libterminfo, libtermcap, libcurses. |
| 2788 | Please try installing whichever of these libraries is most appropriate |
| 2789 | for your system, together with its header files. |
| 2790 | For example, a libncurses-dev(el) or similar package.]) |
| 2791 | fi |
| 2792 | # Must define this when any termcap library is found. |
| 2793 | AC_DEFINE(HAVE_LIBNCURSES, 1, |
| 2794 | [Define to 1 if you have the `ncurses' library (-lncurses).]) |
| 2795 | ## FIXME This was the cpp logic, but I am not sure it is right. |
| 2796 | ## The above test has not necessarily found libncurses. |
| 2797 | HAVE_LIBNCURSES=yes |
| 2798 | |
| 2799 | ## Use terminfo instead of termcap? |
| 2800 | ## Note only system files NOT using terminfo are: |
| 2801 | ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and |
| 2802 | ## darwin|gnu without ncurses. |
| 2803 | TERMINFO=no |
| 2804 | LIBS_TERMCAP= |
| 2805 | case "$opsys" in |
| 2806 | ## cygwin: Fewer environment variables to go wrong, more terminal types. |
| 2807 | ## hpux10-20: Use the system provided termcap(3) library. |
| 2808 | ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this |
| 2809 | ## is necessary. Otherwise Emacs dumps core when run -nw. |
| 2810 | aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;; |
| 2811 | |
| 2812 | ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2. |
| 2813 | ## The ncurses library has been moved out of the System framework in |
| 2814 | ## Mac OS X 10.2. So if configure detects it, set the command-line |
| 2815 | ## option to use it. |
| 2816 | darwin|gnu*) |
| 2817 | ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.) |
| 2818 | if test "x$HAVE_LIBNCURSES" = "xyes"; then |
| 2819 | TERMINFO=yes |
| 2820 | LIBS_TERMCAP="-lncurses" |
| 2821 | fi |
| 2822 | ;; |
| 2823 | |
| 2824 | freebsd) |
| 2825 | AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo]) |
| 2826 | AC_CACHE_VAL(emacs_cv_freebsd_terminfo, |
| 2827 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]], |
| 2828 | [[#if __FreeBSD_version < 400000 |
| 2829 | fail; |
| 2830 | #endif |
| 2831 | ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)]) |
| 2832 | |
| 2833 | AC_MSG_RESULT($emacs_cv_freebsd_terminfo) |
| 2834 | |
| 2835 | if test $emacs_cv_freebsd_terminfo = yes; then |
| 2836 | TERMINFO=yes |
| 2837 | LIBS_TERMCAP="-lncurses" |
| 2838 | else |
| 2839 | LIBS_TERMCAP="-ltermcap" |
| 2840 | fi |
| 2841 | ;; |
| 2842 | |
| 2843 | netbsd) |
| 2844 | if test $ac_cv_search_tputs = -lterminfo; then |
| 2845 | TERMINFO=yes |
| 2846 | LIBS_TERMCAP="-lterminfo" |
| 2847 | else |
| 2848 | LIBS_TERMCAP="-ltermcap" |
| 2849 | fi |
| 2850 | ;; |
| 2851 | |
| 2852 | esac |
| 2853 | |
| 2854 | case "$opsys" in |
| 2855 | ## hpux: Make sure we get select from libc rather than from libcurses |
| 2856 | ## because libcurses on HPUX 10.10 has a broken version of select. |
| 2857 | ## We used to use -lc -lcurses, but this may be cleaner. |
| 2858 | hpux*) LIBS_TERMCAP="-ltermcap" ;; |
| 2859 | |
| 2860 | openbsd) LIBS_TERMCAP="-lncurses" ;; |
| 2861 | |
| 2862 | ## Must use system termcap, if we use any termcap. It does special things. |
| 2863 | sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;; |
| 2864 | esac |
| 2865 | |
| 2866 | TERMCAP_OBJ=tparam.o |
| 2867 | if test $TERMINFO = yes; then |
| 2868 | AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.]) |
| 2869 | |
| 2870 | ## Default used to be -ltermcap. Add a case above if need something else. |
| 2871 | test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses" |
| 2872 | |
| 2873 | TERMCAP_OBJ=terminfo.o |
| 2874 | fi |
| 2875 | AC_SUBST(LIBS_TERMCAP) |
| 2876 | AC_SUBST(TERMCAP_OBJ) |
| 2877 | |
| 2878 | |
| 2879 | # Do we have res_init, for detecting changes in /etc/resolv.conf? |
| 2880 | resolv=no |
| 2881 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h> |
| 2882 | #include <arpa/nameser.h> |
| 2883 | #include <resolv.h>]], |
| 2884 | [[return res_init();]])], |
| 2885 | have_res_init=yes, have_res_init=no) |
| 2886 | if test "$have_res_init" = no; then |
| 2887 | OLIBS="$LIBS" |
| 2888 | LIBS="$LIBS -lresolv" |
| 2889 | AC_MSG_CHECKING(for res_init with -lresolv) |
| 2890 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h> |
| 2891 | #include <arpa/nameser.h> |
| 2892 | #include <resolv.h>]], |
| 2893 | [[return res_init();]])], |
| 2894 | have_res_init=yes, have_res_init=no) |
| 2895 | AC_MSG_RESULT($have_res_init) |
| 2896 | if test "$have_res_init" = yes ; then |
| 2897 | resolv=yes |
| 2898 | fi |
| 2899 | LIBS="$OLIBS" |
| 2900 | fi |
| 2901 | |
| 2902 | if test "$have_res_init" = yes; then |
| 2903 | AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.]) |
| 2904 | fi |
| 2905 | |
| 2906 | # Do we need the Hesiod library to provide the support routines? |
| 2907 | LIBHESIOD= |
| 2908 | if test "$with_hesiod" != no ; then |
| 2909 | # Don't set $LIBS here -- see comments above. FIXME which comments? |
| 2910 | AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, , |
| 2911 | [AC_CHECK_LIB(resolv, res_send, resolv=yes, |
| 2912 | [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])]) |
| 2913 | if test "$resolv" = yes ; then |
| 2914 | RESOLVLIB=-lresolv |
| 2915 | else |
| 2916 | RESOLVLIB= |
| 2917 | fi |
| 2918 | AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost, |
| 2919 | hesiod=yes, :, $RESOLVLIB)]) |
| 2920 | |
| 2921 | if test x"$hesiod" = xyes; then |
| 2922 | AC_DEFINE(HAVE_LIBHESIOD, 1, |
| 2923 | [Define to 1 if you have the hesiod library (-lhesiod).]) |
| 2924 | LIBHESIOD=-lhesiod |
| 2925 | fi |
| 2926 | fi |
| 2927 | AC_SUBST(LIBHESIOD) |
| 2928 | |
| 2929 | # Do we need libresolv (due to res_init or Hesiod)? |
| 2930 | if test "$resolv" = yes ; then |
| 2931 | AC_DEFINE(HAVE_LIBRESOLV, 1, |
| 2932 | [Define to 1 if you have the resolv library (-lresolv).]) |
| 2933 | LIBRESOLV=-lresolv |
| 2934 | else |
| 2935 | LIBRESOLV= |
| 2936 | fi |
| 2937 | AC_SUBST(LIBRESOLV) |
| 2938 | |
| 2939 | # These tell us which Kerberos-related libraries to use. |
| 2940 | COM_ERRLIB= |
| 2941 | CRYPTOLIB= |
| 2942 | KRB5LIB= |
| 2943 | DESLIB= |
| 2944 | KRB4LIB= |
| 2945 | |
| 2946 | if test "${with_kerberos}" != no; then |
| 2947 | AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no) |
| 2948 | if test $have_com_err = yes; then |
| 2949 | COM_ERRLIB=-lcom_err |
| 2950 | LIBS="$COM_ERRLIB $LIBS" |
| 2951 | AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).]) |
| 2952 | fi |
| 2953 | AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no) |
| 2954 | if test $have_crypto = yes; then |
| 2955 | CRYPTOLIB=-lcrypto |
| 2956 | LIBS="$CRYPTOLIB $LIBS" |
| 2957 | AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).]) |
| 2958 | fi |
| 2959 | AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no) |
| 2960 | if test $have_k5crypto = yes; then |
| 2961 | CRYPTOLIB=-lk5crypto |
| 2962 | LIBS="$CRYPTOLIB $LIBS" |
| 2963 | AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).]) |
| 2964 | fi |
| 2965 | AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no) |
| 2966 | if test $have_krb5=yes; then |
| 2967 | KRB5LIB=-lkrb5 |
| 2968 | LIBS="$KRB5LIB $LIBS" |
| 2969 | AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).]) |
| 2970 | fi |
| 2971 | dnl FIXME Simplify. Does not match 22 logic, thanks to default_off? |
| 2972 | if test "${with_kerberos5}" = no; then |
| 2973 | AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no ) |
| 2974 | if test $have_des425 = yes; then |
| 2975 | DESLIB=-ldes425 |
| 2976 | LIBS="$DESLIB $LIBS" |
| 2977 | AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).]) |
| 2978 | else |
| 2979 | AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no) |
| 2980 | if test $have_des = yes; then |
| 2981 | DESLIB=-ldes |
| 2982 | LIBS="$DESLIB $LIBS" |
| 2983 | AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).]) |
| 2984 | fi |
| 2985 | fi |
| 2986 | AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no) |
| 2987 | if test $have_krb4 = yes; then |
| 2988 | KRB4LIB=-lkrb4 |
| 2989 | LIBS="$KRB4LIB $LIBS" |
| 2990 | AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).]) |
| 2991 | else |
| 2992 | AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no) |
| 2993 | if test $have_krb = yes; then |
| 2994 | KRB4LIB=-lkrb |
| 2995 | LIBS="$KRB4LIB $LIBS" |
| 2996 | AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).]) |
| 2997 | fi |
| 2998 | fi |
| 2999 | fi |
| 3000 | |
| 3001 | if test "${with_kerberos5}" != no; then |
| 3002 | AC_CHECK_HEADERS(krb5.h, |
| 3003 | [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,, |
| 3004 | [#include <krb5.h>])]) |
| 3005 | else |
| 3006 | AC_CHECK_HEADERS(des.h,, |
| 3007 | [AC_CHECK_HEADERS(kerberosIV/des.h,, |
| 3008 | [AC_CHECK_HEADERS(kerberos/des.h)])]) |
| 3009 | AC_CHECK_HEADERS(krb.h,, |
| 3010 | [AC_CHECK_HEADERS(kerberosIV/krb.h,, |
| 3011 | [AC_CHECK_HEADERS(kerberos/krb.h)])]) |
| 3012 | fi |
| 3013 | AC_CHECK_HEADERS(com_err.h) |
| 3014 | fi |
| 3015 | |
| 3016 | AC_SUBST(COM_ERRLIB) |
| 3017 | AC_SUBST(CRYPTOLIB) |
| 3018 | AC_SUBST(KRB5LIB) |
| 3019 | AC_SUBST(DESLIB) |
| 3020 | AC_SUBST(KRB4LIB) |
| 3021 | |
| 3022 | AC_MSG_CHECKING(whether localtime caches TZ) |
| 3023 | AC_CACHE_VAL(emacs_cv_localtime_cache, |
| 3024 | [if test x$ac_cv_func_tzset = xyes; then |
| 3025 | AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h> |
| 3026 | char TZ_GMT0[] = "TZ=GMT0"; |
| 3027 | char TZ_PST8[] = "TZ=PST8"; |
| 3028 | main() |
| 3029 | { |
| 3030 | time_t now = time ((time_t *) 0); |
| 3031 | int hour_GMT0, hour_unset; |
| 3032 | if (putenv (TZ_GMT0) != 0) |
| 3033 | exit (1); |
| 3034 | hour_GMT0 = localtime (&now)->tm_hour; |
| 3035 | unsetenv("TZ"); |
| 3036 | hour_unset = localtime (&now)->tm_hour; |
| 3037 | if (putenv (TZ_PST8) != 0) |
| 3038 | exit (1); |
| 3039 | if (localtime (&now)->tm_hour == hour_GMT0) |
| 3040 | exit (1); |
| 3041 | unsetenv("TZ"); |
| 3042 | if (localtime (&now)->tm_hour != hour_unset) |
| 3043 | exit (1); |
| 3044 | exit (0); |
| 3045 | }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes, |
| 3046 | [# If we have tzset, assume the worst when cross-compiling. |
| 3047 | emacs_cv_localtime_cache=yes]) |
| 3048 | else |
| 3049 | # If we lack tzset, report that localtime does not cache TZ, |
| 3050 | # since we can't invalidate the cache if we don't have tzset. |
| 3051 | emacs_cv_localtime_cache=no |
| 3052 | fi])dnl |
| 3053 | AC_MSG_RESULT($emacs_cv_localtime_cache) |
| 3054 | if test $emacs_cv_localtime_cache = yes; then |
| 3055 | AC_DEFINE(LOCALTIME_CACHE, 1, |
| 3056 | [Define to 1 if localtime caches TZ.]) |
| 3057 | fi |
| 3058 | |
| 3059 | if test "x$HAVE_TIMEVAL" = xyes; then |
| 3060 | AC_CHECK_FUNCS(gettimeofday) |
| 3061 | if test $ac_cv_func_gettimeofday = yes; then |
| 3062 | AC_CACHE_CHECK(whether gettimeofday can accept two arguments, |
| 3063 | emacs_cv_gettimeofday_two_arguments, |
| 3064 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ |
| 3065 | #ifdef TIME_WITH_SYS_TIME |
| 3066 | #include <sys/time.h> |
| 3067 | #include <time.h> |
| 3068 | #else |
| 3069 | #ifdef HAVE_SYS_TIME_H |
| 3070 | #include <sys/time.h> |
| 3071 | #else |
| 3072 | #include <time.h> |
| 3073 | #endif |
| 3074 | #endif]], |
| 3075 | [[struct timeval time; |
| 3076 | gettimeofday (&time, 0);]])], |
| 3077 | emacs_cv_gettimeofday_two_arguments=yes, |
| 3078 | emacs_cv_gettimeofday_two_arguments=no)]) |
| 3079 | if test $emacs_cv_gettimeofday_two_arguments = no; then |
| 3080 | AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1, |
| 3081 | [Define to 1 if gettimeofday accepts only one argument.]) |
| 3082 | fi |
| 3083 | fi |
| 3084 | fi |
| 3085 | |
| 3086 | ok_so_far=yes |
| 3087 | AC_CHECK_FUNC(socket, , ok_so_far=no) |
| 3088 | if test $ok_so_far = yes; then |
| 3089 | AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no) |
| 3090 | fi |
| 3091 | if test $ok_so_far = yes; then |
| 3092 | AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no) |
| 3093 | fi |
| 3094 | if test $ok_so_far = yes; then |
| 3095 | dnl Fixme: Not used. Should this be HAVE_SOCKETS? |
| 3096 | AC_DEFINE(HAVE_INET_SOCKETS, 1, |
| 3097 | [Define to 1 if you have inet sockets.]) |
| 3098 | fi |
| 3099 | |
| 3100 | if test -f /usr/lpp/X11/bin/smt.exp; then |
| 3101 | AC_DEFINE(HAVE_AIX_SMT_EXP, 1, |
| 3102 | [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.]) |
| 3103 | fi |
| 3104 | |
| 3105 | AC_MSG_CHECKING(whether system supports dynamic ptys) |
| 3106 | if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then |
| 3107 | AC_MSG_RESULT(yes) |
| 3108 | AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.]) |
| 3109 | else |
| 3110 | AC_MSG_RESULT(no) |
| 3111 | fi |
| 3112 | |
| 3113 | AC_FUNC_FORK |
| 3114 | |
| 3115 | AC_CHECK_FUNCS(snprintf) |
| 3116 | |
| 3117 | dnl Adapted from Haible's version. |
| 3118 | AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset, |
| 3119 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], |
| 3120 | [[char* cs = nl_langinfo(CODESET);]])], |
| 3121 | emacs_cv_langinfo_codeset=yes, |
| 3122 | emacs_cv_langinfo_codeset=no) |
| 3123 | ]) |
| 3124 | if test $emacs_cv_langinfo_codeset = yes; then |
| 3125 | AC_DEFINE(HAVE_LANGINFO_CODESET, 1, |
| 3126 | [Define if you have <langinfo.h> and nl_langinfo(CODESET).]) |
| 3127 | fi |
| 3128 | |
| 3129 | AC_TYPE_MBSTATE_T |
| 3130 | |
| 3131 | AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr, |
| 3132 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])], |
| 3133 | emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)]) |
| 3134 | if test "$emacs_cv_c_restrict_arr" = yes; then |
| 3135 | AC_DEFINE(__restrict_arr, __restrict, |
| 3136 | [Define to compiler's equivalent of C99 restrict keyword in array |
| 3137 | declarations. Define as empty for no equivalent.]) |
| 3138 | fi |
| 3139 | |
| 3140 | dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear |
| 3141 | dnl how the tty code is related to POSIX and/or other versions of termios. |
| 3142 | dnl The following looks like a useful start. |
| 3143 | dnl |
| 3144 | dnl AC_SYS_POSIX_TERMIOS |
| 3145 | dnl if test $ac_cv_sys_posix_termios = yes; then |
| 3146 | dnl AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions |
| 3147 | dnl and macros for terminal control.]) |
| 3148 | dnl AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.]) |
| 3149 | dnl fi |
| 3150 | |
| 3151 | # Set up the CFLAGS for real compilation, so we can substitute it. |
| 3152 | CFLAGS="$REAL_CFLAGS" |
| 3153 | CPPFLAGS="$REAL_CPPFLAGS" |
| 3154 | |
| 3155 | ## Hack to detect a buggy GCC version. |
| 3156 | if test "x$GCC" = xyes \ |
| 3157 | && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \ |
| 3158 | && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \ |
| 3159 | && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then |
| 3160 | AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.]) |
| 3161 | fi |
| 3162 | |
| 3163 | version=$PACKAGE_VERSION |
| 3164 | |
| 3165 | ### Specify what sort of things we'll be editing into Makefile and config.h. |
| 3166 | ### Use configuration here uncanonicalized to avoid exceeding size limits. |
| 3167 | AC_SUBST(version) |
| 3168 | AC_SUBST(configuration) |
| 3169 | ## Unused? |
| 3170 | AC_SUBST(canonical) |
| 3171 | AC_SUBST(srcdir) |
| 3172 | AC_SUBST(prefix) |
| 3173 | AC_SUBST(exec_prefix) |
| 3174 | AC_SUBST(bindir) |
| 3175 | AC_SUBST(datadir) |
| 3176 | AC_SUBST(sharedstatedir) |
| 3177 | AC_SUBST(libexecdir) |
| 3178 | AC_SUBST(mandir) |
| 3179 | AC_SUBST(infodir) |
| 3180 | AC_SUBST(lispdir) |
| 3181 | AC_SUBST(locallisppath) |
| 3182 | AC_SUBST(lisppath) |
| 3183 | AC_SUBST(x_default_search_path) |
| 3184 | AC_SUBST(etcdir) |
| 3185 | AC_SUBST(archlibdir) |
| 3186 | AC_SUBST(docdir) |
| 3187 | AC_SUBST(bitmapdir) |
| 3188 | AC_SUBST(gamedir) |
| 3189 | AC_SUBST(gameuser) |
| 3190 | ## FIXME? Nothing uses @LD_SWITCH_X_SITE@. |
| 3191 | ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the |
| 3192 | ## end of LIBX_BASE, but nothing ever set it. |
| 3193 | AC_SUBST(LD_SWITCH_X_SITE) |
| 3194 | AC_SUBST(C_SWITCH_X_SITE) |
| 3195 | AC_SUBST(C_SWITCH_X_SYSTEM) |
| 3196 | AC_SUBST(CFLAGS) |
| 3197 | ## Used in lwlib/Makefile.in. |
| 3198 | AC_SUBST(X_TOOLKIT_TYPE) |
| 3199 | if test -n "${machfile}"; then |
| 3200 | M_FILE="\$(srcdir)/${machfile}" |
| 3201 | else |
| 3202 | M_FILE= |
| 3203 | fi |
| 3204 | S_FILE="\$(srcdir)/${opsysfile}" |
| 3205 | AC_SUBST(M_FILE) |
| 3206 | AC_SUBST(S_FILE) |
| 3207 | AC_SUBST(ns_appdir) |
| 3208 | AC_SUBST(ns_appbindir) |
| 3209 | AC_SUBST(ns_appresdir) |
| 3210 | AC_SUBST(ns_appsrc) |
| 3211 | AC_SUBST(GNU_OBJC_CFLAGS) |
| 3212 | AC_SUBST(OTHER_FILES) |
| 3213 | |
| 3214 | AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}", |
| 3215 | [Define to the canonical Emacs configuration name.]) |
| 3216 | AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}", |
| 3217 | [Define to the options passed to configure.]) |
| 3218 | if test -n "$machfile"; then |
| 3219 | AC_DEFINE_UNQUOTED(config_machfile, "${machfile}", |
| 3220 | [Define to the used machine dependent file.]) |
| 3221 | fi |
| 3222 | AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}", |
| 3223 | [Define to the used os dependent file.]) |
| 3224 | |
| 3225 | XMENU_OBJ= |
| 3226 | XOBJ= |
| 3227 | FONT_OBJ= |
| 3228 | if test "${HAVE_X_WINDOWS}" = "yes" ; then |
| 3229 | AC_DEFINE(HAVE_X_WINDOWS, 1, |
| 3230 | [Define to 1 if you want to use the X window system.]) |
| 3231 | XMENU_OBJ=xmenu.o |
| 3232 | XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o" |
| 3233 | FONT_OBJ=xfont.o |
| 3234 | if test "$HAVE_XFT" = "yes"; then |
| 3235 | FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o" |
| 3236 | elif test "$HAVE_FREETYPE" = "yes"; then |
| 3237 | FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o" |
| 3238 | fi |
| 3239 | AC_SUBST(FONT_OBJ) |
| 3240 | fi |
| 3241 | AC_SUBST(XMENU_OBJ) |
| 3242 | AC_SUBST(XOBJ) |
| 3243 | AC_SUBST(FONT_OBJ) |
| 3244 | |
| 3245 | WIDGET_OBJ= |
| 3246 | MOTIF_LIBW= |
| 3247 | if test "${USE_X_TOOLKIT}" != "none" ; then |
| 3248 | WIDGET_OBJ=widget.o |
| 3249 | AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.]) |
| 3250 | if test "${USE_X_TOOLKIT}" = "LUCID"; then |
| 3251 | AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.]) |
| 3252 | elif test "${USE_X_TOOLKIT}" = "MOTIF"; then |
| 3253 | AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.]) |
| 3254 | MOTIF_LIBW=-lXm |
| 3255 | case "$opsys" in |
| 3256 | gnu-linux) |
| 3257 | ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed. |
| 3258 | MOTIF_LIBW="$MOTIF_LIBW -lXpm" |
| 3259 | ;; |
| 3260 | |
| 3261 | unixware) |
| 3262 | ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov> |
| 3263 | ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2. |
| 3264 | MOTIF_LIBW="MOTIF_LIBW -lXimp" |
| 3265 | ;; |
| 3266 | |
| 3267 | aix4-2) |
| 3268 | ## olson@mcs.anl.gov says -li18n is needed by -lXm. |
| 3269 | MOTIF_LIBW="$MOTIF_LIBW -li18n" |
| 3270 | ;; |
| 3271 | esac |
| 3272 | MOTIF_LIBW="$MOTIF_LIBW $LIBXP" |
| 3273 | fi |
| 3274 | fi |
| 3275 | AC_SUBST(WIDGET_OBJ) |
| 3276 | |
| 3277 | TOOLKIT_LIBW= |
| 3278 | case "$USE_X_TOOLKIT" in |
| 3279 | MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;; |
| 3280 | LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;; |
| 3281 | none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;; |
| 3282 | esac |
| 3283 | AC_SUBST(TOOLKIT_LIBW) |
| 3284 | |
| 3285 | if test "$USE_X_TOOLKIT" = "none"; then |
| 3286 | LIBXT_OTHER="\$(LIBXSM)" |
| 3287 | OLDXMENU_TARGET="really-oldXMenu" |
| 3288 | else |
| 3289 | LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext" |
| 3290 | OLDXMENU_TARGET="really-lwlib" |
| 3291 | fi |
| 3292 | AC_SUBST(LIBXT_OTHER) |
| 3293 | |
| 3294 | ## The X Menu stuff is present in the X10 distribution, but missing |
| 3295 | ## from X11. If we have X10, just use the installed library; |
| 3296 | ## otherwise, use our own copy. |
| 3297 | if test "${HAVE_X11}" = "yes" ; then |
| 3298 | AC_DEFINE(HAVE_X11, 1, |
| 3299 | [Define to 1 if you want to use version 11 of X windows. |
| 3300 | Otherwise, Emacs expects to use version 10.]) |
| 3301 | |
| 3302 | if test "$USE_X_TOOLKIT" = "none"; then |
| 3303 | OLDXMENU="\${oldXMenudir}/libXMenu11.a" |
| 3304 | else |
| 3305 | OLDXMENU="\${lwlibdir}/liblw.a" |
| 3306 | fi |
| 3307 | LIBXMENU="\$(OLDXMENU)" |
| 3308 | LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)" |
| 3309 | OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}" |
| 3310 | else |
| 3311 | ## For a syntactically valid Makefile; not actually used for anything. |
| 3312 | ## See comments in src/Makefile.in. |
| 3313 | OLDXMENU=nothing |
| 3314 | ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?). |
| 3315 | if test "${HAVE_X_WINDOWS}" = "yes"; then |
| 3316 | LIBXMENU="-lXMenu" |
| 3317 | else |
| 3318 | LIBXMENU= |
| 3319 | fi |
| 3320 | LIBX_OTHER= |
| 3321 | OLDXMENU_DEPS= |
| 3322 | fi |
| 3323 | |
| 3324 | if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then |
| 3325 | OLDXMENU_TARGET= |
| 3326 | OLDXMENU=nothing |
| 3327 | LIBXMENU= |
| 3328 | OLDXMENU_DEPS= |
| 3329 | fi |
| 3330 | |
| 3331 | AC_SUBST(OLDXMENU_TARGET) |
| 3332 | AC_SUBST(OLDXMENU) |
| 3333 | AC_SUBST(LIBXMENU) |
| 3334 | AC_SUBST(LIBX_OTHER) |
| 3335 | AC_SUBST(OLDXMENU_DEPS) |
| 3336 | |
| 3337 | if test "${HAVE_MENUS}" = "yes" ; then |
| 3338 | AC_DEFINE(HAVE_MENUS, 1, |
| 3339 | [Define to 1 if you have mouse menus. |
| 3340 | (This is automatic if you use X, but the option to specify it remains.) |
| 3341 | It is also defined with other window systems that support xmenu.c.]) |
| 3342 | fi |
| 3343 | |
| 3344 | if test "${GNU_MALLOC}" = "yes" ; then |
| 3345 | AC_DEFINE(GNU_MALLOC, 1, |
| 3346 | [Define to 1 if you want to use the GNU memory allocator.]) |
| 3347 | fi |
| 3348 | |
| 3349 | RALLOC_OBJ= |
| 3350 | if test "${REL_ALLOC}" = "yes" ; then |
| 3351 | AC_DEFINE(REL_ALLOC, 1, |
| 3352 | [Define REL_ALLOC if you want to use the relocating allocator for |
| 3353 | buffer space.]) |
| 3354 | |
| 3355 | test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o |
| 3356 | fi |
| 3357 | AC_SUBST(RALLOC_OBJ) |
| 3358 | |
| 3359 | if test "$opsys" = "cygwin"; then |
| 3360 | CYGWIN_OBJ="sheap.o" |
| 3361 | ## Cygwin differs because of its unexec(). |
| 3362 | PRE_ALLOC_OBJ= |
| 3363 | POST_ALLOC_OBJ=lastfile.o |
| 3364 | else |
| 3365 | CYGWIN_OBJ= |
| 3366 | PRE_ALLOC_OBJ=lastfile.o |
| 3367 | POST_ALLOC_OBJ= |
| 3368 | fi |
| 3369 | AC_SUBST(CYGWIN_OBJ) |
| 3370 | AC_SUBST(PRE_ALLOC_OBJ) |
| 3371 | AC_SUBST(POST_ALLOC_OBJ) |
| 3372 | |
| 3373 | # Configure gnulib here, now that we know LIBS. |
| 3374 | gl_ASSERT_NO_GNULIB_POSIXCHECK |
| 3375 | gl_ASSERT_NO_GNULIB_TESTS |
| 3376 | gl_INIT |
| 3377 | |
| 3378 | case "$opsys" in |
| 3379 | aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;; |
| 3380 | |
| 3381 | darwin) |
| 3382 | ## The -headerpad option tells ld (see man page) to leave room at the |
| 3383 | ## end of the header for adding load commands. Needed for dumping. |
| 3384 | ## 0x690 is the total size of 30 segment load commands (at 56 |
| 3385 | ## each); under Cocoa 31 commands are required. |
| 3386 | if test "$HAVE_NS" = "yes"; then |
| 3387 | libs_nsgui="-framework AppKit" |
| 3388 | headerpad_extra=6C8 |
| 3389 | else |
| 3390 | libs_nsgui= |
| 3391 | headerpad_extra=690 |
| 3392 | fi |
| 3393 | LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra" |
| 3394 | |
| 3395 | ## This is here because src/Makefile.in did some extra fiddling around |
| 3396 | ## with LD_SWITCH_SYSTEM. The cpp logic was: |
| 3397 | ## #ifndef LD_SWITCH_SYSTEM |
| 3398 | ## #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF))) |
| 3399 | ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to: |
| 3400 | ## not using gcc, darwin system not on an alpha (ie darwin, since |
| 3401 | ## darwin + alpha does not occur). |
| 3402 | ## Because this was done in src/Makefile.in, the resulting part of |
| 3403 | ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link). |
| 3404 | ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS, |
| 3405 | ## rather than LD_SWITCH_SYSTEM. |
| 3406 | test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \ |
| 3407 | LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS" |
| 3408 | ;; |
| 3409 | |
| 3410 | ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time. |
| 3411 | ## When handled by cpp, this was in LD_SWITCH_SYSTEM. However, at |
| 3412 | ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX |
| 3413 | ## had not yet been defined and was expanded to null. Hence LD_SWITCH_SYSTEM |
| 3414 | ## had different values in configure (in ac_link) and src/Makefile.in. |
| 3415 | ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS. |
| 3416 | gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;; |
| 3417 | |
| 3418 | *) LD_SWITCH_SYSTEM_TEMACS= ;; |
| 3419 | esac |
| 3420 | |
| 3421 | if test "$NS_IMPL_GNUSTEP" = "yes"; then |
| 3422 | LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread" |
| 3423 | fi |
| 3424 | |
| 3425 | AC_SUBST(LD_SWITCH_SYSTEM_TEMACS) |
| 3426 | |
| 3427 | |
| 3428 | LD_FIRSTFLAG= |
| 3429 | ORDINARY_LINK= |
| 3430 | case "$opsys" in |
| 3431 | ## gnu: GNU needs its own crt0. |
| 3432 | aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;; |
| 3433 | |
| 3434 | ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the |
| 3435 | ## library search parth, i.e. it won't search /usr/lib for libc and |
| 3436 | ## friends. Using -nostartfiles instead avoids this problem, and |
| 3437 | ## will also work on earlier NetBSD releases. |
| 3438 | netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;; |
| 3439 | |
| 3440 | ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says |
| 3441 | ## MkLinux/LinuxPPC needs this. |
| 3442 | ## ibms390x only supports opsys = gnu-linux so it can be added here. |
| 3443 | gnu-*) |
| 3444 | case "$machine" in |
| 3445 | macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;; |
| 3446 | esac |
| 3447 | ;; |
| 3448 | esac |
| 3449 | |
| 3450 | |
| 3451 | if test "x$ORDINARY_LINK" = "xyes"; then |
| 3452 | |
| 3453 | LD_FIRSTFLAG="" |
| 3454 | AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.]) |
| 3455 | |
| 3456 | ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are: |
| 3457 | ## freebsd, gnu-* not on macppc|ibms390x. |
| 3458 | elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then |
| 3459 | |
| 3460 | ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure |
| 3461 | ## places that are difficult to figure out at make time. Fortunately, |
| 3462 | ## these same versions allow you to pass arbitrary flags on to the |
| 3463 | ## linker, so there is no reason not to use it as a linker. |
| 3464 | ## |
| 3465 | ## Well, it is not quite perfect. The "-nostdlib" keeps GCC from |
| 3466 | ## searching for libraries in its internal directories, so we have to |
| 3467 | ## ask GCC explicitly where to find libgcc.a (LIB_GCC below). |
| 3468 | LD_FIRSTFLAG="-nostdlib" |
| 3469 | fi |
| 3470 | |
| 3471 | ## FIXME? What setting of EDIT_LDFLAGS should this have? |
| 3472 | test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic" |
| 3473 | |
| 3474 | AC_SUBST(LD_FIRSTFLAG) |
| 3475 | |
| 3476 | |
| 3477 | ## FIXME? The logic here is not precisely the same as that above. |
| 3478 | ## There is no check here for a pre-defined LD_FIRSTFLAG. |
| 3479 | ## Should we only be setting LIB_GCC if LD ~ -nostdlib? |
| 3480 | LIB_GCC= |
| 3481 | if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then |
| 3482 | |
| 3483 | case "$opsys" in |
| 3484 | freebsd|netbsd|openbsd) LIB_GCC= ;; |
| 3485 | |
| 3486 | gnu-*) |
| 3487 | ## armin76@gentoo.org reported that the lgcc_s flag is necessary to |
| 3488 | ## build on ARM EABI under GNU/Linux. (Bug#5518) |
| 3489 | case $host_cpu in |
| 3490 | arm*) |
| 3491 | LIB_GCC="-lgcc_s" |
| 3492 | ;; |
| 3493 | *) |
| 3494 | ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then |
| 3495 | ## immediately undefine it again and redefine it to empty. |
| 3496 | ## Was the C_SWITCH_X_SITE part really necessary? |
| 3497 | ## LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name` |
| 3498 | LIB_GCC= |
| 3499 | ;; |
| 3500 | esac |
| 3501 | ;; |
| 3502 | |
| 3503 | ## Ask GCC where to find libgcc.a. |
| 3504 | *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;; |
| 3505 | esac |
| 3506 | fi dnl if $GCC |
| 3507 | AC_SUBST(LIB_GCC) |
| 3508 | |
| 3509 | |
| 3510 | ## If we're using X11/GNUstep, define some consequences. |
| 3511 | if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then |
| 3512 | AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.]) |
| 3513 | AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.]) |
| 3514 | fi |
| 3515 | |
| 3516 | |
| 3517 | AH_TOP([/* GNU Emacs site configuration template file. |
| 3518 | |
| 3519 | Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012 |
| 3520 | Free Software Foundation, Inc. |
| 3521 | |
| 3522 | This file is part of GNU Emacs. |
| 3523 | |
| 3524 | GNU Emacs is free software: you can redistribute it and/or modify |
| 3525 | it under the terms of the GNU General Public License as published by |
| 3526 | the Free Software Foundation, either version 3 of the License, or |
| 3527 | (at your option) any later version. |
| 3528 | |
| 3529 | GNU Emacs is distributed in the hope that it will be useful, |
| 3530 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 3531 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 3532 | GNU General Public License for more details. |
| 3533 | |
| 3534 | You should have received a copy of the GNU General Public License |
| 3535 | along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. */ |
| 3536 | |
| 3537 | |
| 3538 | /* No code in Emacs #includes config.h twice, but some bits of code |
| 3539 | intended to work with other packages as well (like gmalloc.c) |
| 3540 | think they can include it as many times as they like. */ |
| 3541 | #ifndef EMACS_CONFIG_H |
| 3542 | #define EMACS_CONFIG_H |
| 3543 | ])dnl |
| 3544 | |
| 3545 | AH_BOTTOM([ |
| 3546 | /* On AIX 3 this must be included before any other include file. */ |
| 3547 | #include <alloca.h> |
| 3548 | #if ! HAVE_ALLOCA |
| 3549 | # error "alloca not available on this machine" |
| 3550 | #endif |
| 3551 | |
| 3552 | /* Define AMPERSAND_FULL_NAME if you use the convention |
| 3553 | that & in the full name stands for the login id. */ |
| 3554 | /* Turned on June 1996 supposing nobody will mind it. */ |
| 3555 | #define AMPERSAND_FULL_NAME |
| 3556 | |
| 3557 | /* `subprocesses' should be defined if you want to |
| 3558 | have code for asynchronous subprocesses |
| 3559 | (as used in M-x compile and M-x shell). |
| 3560 | Only MSDOS does not support this (it overrides |
| 3561 | this in its config_opsysfile below). */ |
| 3562 | |
| 3563 | #define subprocesses |
| 3564 | |
| 3565 | /* Include the os and machine dependent files. */ |
| 3566 | #include config_opsysfile |
| 3567 | #ifdef config_machfile |
| 3568 | # include config_machfile |
| 3569 | #endif |
| 3570 | |
| 3571 | /* GNUstep needs a bit more pure memory. Of the existing knobs, |
| 3572 | SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems. |
| 3573 | (There is probably a better place to do this, but right now the |
| 3574 | Cocoa side does this in s/darwin.h and we cannot parallel this |
| 3575 | exactly since GNUstep is multi-OS. */ |
| 3576 | #if defined HAVE_NS && defined NS_IMPL_GNUSTEP |
| 3577 | # define SYSTEM_PURESIZE_EXTRA 30000 |
| 3578 | #endif |
| 3579 | |
| 3580 | #ifdef emacs /* Don't do this for lib-src. */ |
| 3581 | /* Tell regex.c to use a type compatible with Emacs. */ |
| 3582 | #define RE_TRANSLATE_TYPE Lisp_Object |
| 3583 | #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C) |
| 3584 | #ifdef make_number |
| 3585 | /* If make_number is a macro, use it. */ |
| 3586 | #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0))) |
| 3587 | #else |
| 3588 | /* If make_number is a function, avoid it. */ |
| 3589 | #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0)) |
| 3590 | #endif |
| 3591 | #endif |
| 3592 | |
| 3593 | /* These default definitions are good for almost all machines. |
| 3594 | Any exceptions should override them in m/MACHINE.h. |
| 3595 | They must be usable in preprocessor conditionals. */ |
| 3596 | |
| 3597 | #ifndef BITS_PER_CHAR |
| 3598 | #define BITS_PER_CHAR 8 |
| 3599 | #endif |
| 3600 | |
| 3601 | #ifndef BITS_PER_SHORT |
| 3602 | #define BITS_PER_SHORT 16 |
| 3603 | #endif |
| 3604 | |
| 3605 | #ifndef BITS_PER_INT |
| 3606 | #define BITS_PER_INT 32 |
| 3607 | #endif |
| 3608 | |
| 3609 | #ifndef BITS_PER_LONG |
| 3610 | #ifdef _LP64 |
| 3611 | #define BITS_PER_LONG 64 |
| 3612 | #else |
| 3613 | #define BITS_PER_LONG 32 |
| 3614 | #endif |
| 3615 | #endif |
| 3616 | |
| 3617 | #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT |
| 3618 | #define BITS_PER_LONG_LONG 64 |
| 3619 | #endif |
| 3620 | |
| 3621 | /* Define if the compiler supports function prototypes. It may do so but |
| 3622 | not define __STDC__ (e.g. DEC C by default) or may define it as zero. */ |
| 3623 | #undef PROTOTYPES |
| 3624 | |
| 3625 | #include <string.h> |
| 3626 | #include <stdlib.h> |
| 3627 | |
| 3628 | #if defined __GNUC__ && (__GNUC__ > 2 \ |
| 3629 | || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5)) |
| 3630 | #define NO_RETURN __attribute__ ((__noreturn__)) |
| 3631 | #else |
| 3632 | #define NO_RETURN /* nothing */ |
| 3633 | #endif |
| 3634 | |
| 3635 | #if __GNUC__ >= 3 /* On GCC 3.0 we might get a warning. */ |
| 3636 | #define NO_INLINE __attribute__((noinline)) |
| 3637 | #else |
| 3638 | #define NO_INLINE |
| 3639 | #endif |
| 3640 | |
| 3641 | #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1)) |
| 3642 | #define EXTERNALLY_VISIBLE __attribute__((externally_visible)) |
| 3643 | #else |
| 3644 | #define EXTERNALLY_VISIBLE |
| 3645 | #endif |
| 3646 | |
| 3647 | #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7) |
| 3648 | # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec)) |
| 3649 | #else |
| 3650 | # define ATTRIBUTE_FORMAT(spec) /* empty */ |
| 3651 | #endif |
| 3652 | |
| 3653 | #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4) |
| 3654 | # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \ |
| 3655 | ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument)) |
| 3656 | #else |
| 3657 | # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \ |
| 3658 | ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument)) |
| 3659 | #endif |
| 3660 | |
| 3661 | /* Some versions of GNU/Linux define noinline in their headers. */ |
| 3662 | #ifdef noinline |
| 3663 | #undef noinline |
| 3664 | #endif |
| 3665 | |
| 3666 | /* These won't be used automatically yet. We also need to know, at least, |
| 3667 | that the stack is continuous. */ |
| 3668 | #ifdef __GNUC__ |
| 3669 | # ifndef GC_SETJMP_WORKS |
| 3670 | /* GC_SETJMP_WORKS is nearly always appropriate for GCC. */ |
| 3671 | # define GC_SETJMP_WORKS 1 |
| 3672 | # endif |
| 3673 | #endif |
| 3674 | |
| 3675 | #endif /* EMACS_CONFIG_H */ |
| 3676 | |
| 3677 | /* |
| 3678 | Local Variables: |
| 3679 | mode: c |
| 3680 | End: |
| 3681 | */ |
| 3682 | ])dnl |
| 3683 | |
| 3684 | #### Report on what we decided to do. |
| 3685 | #### Report GTK as a toolkit, even if it doesn't use Xt. |
| 3686 | #### It makes printing result more understandable as using GTK sets |
| 3687 | #### toolkit_scroll_bars to yes by default. |
| 3688 | if test "${HAVE_GTK}" = "yes"; then |
| 3689 | USE_X_TOOLKIT=GTK |
| 3690 | fi |
| 3691 | |
| 3692 | and_machfile= |
| 3693 | if test -n "$machfile"; then |
| 3694 | and_machfile=" and \`${machfile}'" |
| 3695 | fi |
| 3696 | |
| 3697 | echo " |
| 3698 | Configured for \`${canonical}'. |
| 3699 | |
| 3700 | Where should the build process find the source code? ${srcdir} |
| 3701 | What operating system and machine description files should Emacs use? |
| 3702 | \`${opsysfile}'${and_machfile} |
| 3703 | What compiler should emacs be built with? ${CC} ${CFLAGS} |
| 3704 | Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason} |
| 3705 | Should Emacs use a relocating allocator for buffers? ${REL_ALLOC} |
| 3706 | Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers |
| 3707 | What window system should Emacs use? ${window_system} |
| 3708 | What toolkit should Emacs use? ${USE_X_TOOLKIT}" |
| 3709 | |
| 3710 | if test -n "${x_includes}"; then |
| 3711 | echo " Where do we find X Windows header files? ${x_includes}" |
| 3712 | else |
| 3713 | echo " Where do we find X Windows header files? Standard dirs" |
| 3714 | fi |
| 3715 | if test -n "${x_libraries}"; then |
| 3716 | echo " Where do we find X Windows libraries? ${x_libraries}" |
| 3717 | else |
| 3718 | echo " Where do we find X Windows libraries? Standard dirs" |
| 3719 | fi |
| 3720 | |
| 3721 | echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}" |
| 3722 | echo " Does Emacs use -lXpm? ${HAVE_XPM}" |
| 3723 | echo " Does Emacs use -ljpeg? ${HAVE_JPEG}" |
| 3724 | echo " Does Emacs use -ltiff? ${HAVE_TIFF}" |
| 3725 | echo " Does Emacs use a gif library? ${HAVE_GIF} $LIBGIF" |
| 3726 | echo " Does Emacs use -lpng? ${HAVE_PNG}" |
| 3727 | echo " Does Emacs use -lrsvg-2? ${HAVE_RSVG}" |
| 3728 | echo " Does Emacs use imagemagick? ${HAVE_IMAGEMAGICK}" |
| 3729 | |
| 3730 | echo " Does Emacs use -lgpm? ${HAVE_GPM}" |
| 3731 | echo " Does Emacs use -ldbus? ${HAVE_DBUS}" |
| 3732 | echo " Does Emacs use -lgconf? ${HAVE_GCONF}" |
| 3733 | echo " Does Emacs use GSettings? ${HAVE_GSETTINGS}" |
| 3734 | echo " Does Emacs use -lselinux? ${HAVE_LIBSELINUX}" |
| 3735 | echo " Does Emacs use -lgnutls? ${HAVE_GNUTLS}" |
| 3736 | echo " Does Emacs use -lxml2? ${HAVE_LIBXML2}" |
| 3737 | |
| 3738 | echo " Does Emacs use -lfreetype? ${HAVE_FREETYPE}" |
| 3739 | echo " Does Emacs use -lm17n-flt? ${HAVE_M17N_FLT}" |
| 3740 | echo " Does Emacs use -lotf? ${HAVE_LIBOTF}" |
| 3741 | echo " Does Emacs use -lxft? ${HAVE_XFT}" |
| 3742 | |
| 3743 | echo " Does Emacs use toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}" |
| 3744 | echo |
| 3745 | |
| 3746 | if test -n "${EMACSDATA}"; then |
| 3747 | echo " Environment variable EMACSDATA set to: $EMACSDATA" |
| 3748 | fi |
| 3749 | if test -n "${EMACSDOC}"; then |
| 3750 | echo " Environment variable EMACSDOC set to: $EMACSDOC" |
| 3751 | fi |
| 3752 | |
| 3753 | if test $USE_XASSERTS = yes; then |
| 3754 | echo " Compiling with asserts turned on." |
| 3755 | CPPFLAGS="$CPPFLAGS -DXASSERTS=1" |
| 3756 | fi |
| 3757 | |
| 3758 | echo |
| 3759 | |
| 3760 | if test "$HAVE_NS" = "yes"; then |
| 3761 | echo |
| 3762 | echo "You must run \"${MAKE-make} install\" in order to test the built application. |
| 3763 | The installed application will go to nextstep/Emacs.app and can be |
| 3764 | run or moved from there." |
| 3765 | if test "$EN_NS_SELF_CONTAINED" = "yes"; then |
| 3766 | echo "The application will be fully self-contained." |
| 3767 | else |
| 3768 | echo "The lisp resources for the application will be installed under ${prefix}. |
| 3769 | You may need to run \"${MAKE-make} install\" with sudo. The application will fail |
| 3770 | to run if these resources are not installed." |
| 3771 | fi |
| 3772 | echo |
| 3773 | fi |
| 3774 | |
| 3775 | |
| 3776 | # Remove any trailing slashes in these variables. |
| 3777 | [test "${prefix}" != NONE && |
| 3778 | prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'` |
| 3779 | test "${exec_prefix}" != NONE && |
| 3780 | exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`] |
| 3781 | |
| 3782 | dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES. |
| 3783 | dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory |
| 3784 | dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable |
| 3785 | dnl (else you get "no `Makefile.am' found for any configure output"). |
| 3786 | dnl This will work, but you get a config.status that is not quite right |
| 3787 | dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html). |
| 3788 | dnl That doesn't have any obvious consequences for Emacs, but on the whole |
| 3789 | dnl it seems better to just live with the duplication. |
| 3790 | SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile" |
| 3791 | |
| 3792 | AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \ |
| 3793 | doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \ |
| 3794 | doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \ |
| 3795 | leim/Makefile]) |
| 3796 | |
| 3797 | dnl test/ is not present in release tarfiles. |
| 3798 | opt_makefile=test/automated/Makefile |
| 3799 | |
| 3800 | if test -f $srcdir/${opt_makefile}.in; then |
| 3801 | SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile" |
| 3802 | dnl Again, it's best not to use a variable. Though you can add |
| 3803 | dnl ", [], [opt_makefile='$opt_makefile']" and it should work. |
| 3804 | AC_CONFIG_FILES([test/automated/Makefile]) |
| 3805 | fi |
| 3806 | |
| 3807 | SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'` |
| 3808 | |
| 3809 | AC_SUBST(SUBDIR_MAKEFILES_IN) |
| 3810 | |
| 3811 | dnl Make the necessary directories, if they don't exist. |
| 3812 | AC_CONFIG_COMMANDS([mkdirs], [ |
| 3813 | for dir in etc lisp ; do |
| 3814 | test -d ${dir} || mkdir ${dir} |
| 3815 | done |
| 3816 | ]) |
| 3817 | |
| 3818 | dnl You might wonder (I did) why epaths.h is generated by running make, |
| 3819 | dnl rather than just letting configure generate it from epaths.in. |
| 3820 | dnl One reason is that the various paths are not fully expanded (see above); |
| 3821 | dnl eg gamedir=${prefix}/var/games/emacs. |
| 3822 | dnl Secondly, the GNU Coding standards require that one should be able |
| 3823 | dnl to run `make prefix=/some/where/else' and override the values set |
| 3824 | dnl by configure. This also explains the `move-if-change' test and |
| 3825 | dnl the use of force in the `epaths-force' rule in Makefile.in. |
| 3826 | AC_CONFIG_COMMANDS([epaths], [ |
| 3827 | echo creating src/epaths.h |
| 3828 | ${MAKE-make} epaths-force |
| 3829 | ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"]) |
| 3830 | |
| 3831 | AC_CONFIG_COMMANDS([gdbinit], [ |
| 3832 | if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then |
| 3833 | echo creating src/.gdbinit |
| 3834 | echo source $srcdir/src/.gdbinit > src/.gdbinit |
| 3835 | fi |
| 3836 | ]) |
| 3837 | |
| 3838 | AC_OUTPUT |
| 3839 | |
| 3840 | dnl configure.in ends here |