| 1 | ;;; autoinsert.el --- automatic mode-dependent insertion of text into new files |
| 2 | |
| 3 | ;; Copyright (C) 1985-1987, 1994-1995, 1998, 2000-2014 Free Software |
| 4 | ;; Foundation, Inc. |
| 5 | |
| 6 | ;; Author: Charlie Martin <crm@cs.duke.edu> |
| 7 | ;; Adapted-By: Daniel Pfeiffer <occitan@esperanto.org> |
| 8 | ;; Keywords: convenience |
| 9 | ;; Maintainer: emacs-devel@gnu.org |
| 10 | |
| 11 | ;; This file is part of GNU Emacs. |
| 12 | |
| 13 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 14 | ;; it under the terms of the GNU General Public License as published by |
| 15 | ;; the Free Software Foundation, either version 3 of the License, or |
| 16 | ;; (at your option) any later version. |
| 17 | |
| 18 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 19 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 20 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 21 | ;; GNU General Public License for more details. |
| 22 | |
| 23 | ;; You should have received a copy of the GNU General Public License |
| 24 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 25 | |
| 26 | ;;; Commentary: |
| 27 | |
| 28 | ;; The following defines an association list for text to be |
| 29 | ;; automatically inserted when a new file is created, and a function |
| 30 | ;; which automatically inserts these files; the idea is to insert |
| 31 | ;; default text much as the mode is automatically set using |
| 32 | ;; auto-mode-alist. |
| 33 | ;; |
| 34 | ;; To use: |
| 35 | ;; (add-hook 'find-file-hook 'auto-insert) |
| 36 | ;; setq auto-insert-directory to an appropriate slash-terminated value |
| 37 | ;; |
| 38 | ;; You can also customize the variable `auto-insert-mode' to load the |
| 39 | ;; package. Alternatively, add the following to your init file: |
| 40 | ;; (auto-insert-mode 1) |
| 41 | ;; |
| 42 | ;; Author: Charlie Martin |
| 43 | ;; Department of Computer Science and |
| 44 | ;; National Biomedical Simulation Resource |
| 45 | ;; Box 3709 |
| 46 | ;; Duke University Medical Center |
| 47 | ;; Durham, NC 27710 |
| 48 | ;; (crm@cs.duke.edu,mcnc!duke!crm) |
| 49 | |
| 50 | ;;; Code: |
| 51 | |
| 52 | (defgroup auto-insert nil |
| 53 | "Automatic mode-dependent insertion of text into new files." |
| 54 | :prefix "auto-insert-" |
| 55 | :group 'files |
| 56 | :group 'convenience |
| 57 | :link '(custom-manual "(autotype) Autoinserting")) |
| 58 | |
| 59 | |
| 60 | (defcustom auto-insert 'not-modified |
| 61 | "Controls automatic insertion into newly found empty files. |
| 62 | Possible values: |
| 63 | nil do nothing |
| 64 | t insert if possible |
| 65 | other insert if possible, but mark as unmodified. |
| 66 | Insertion is possible when something appropriate is found in |
| 67 | `auto-insert-alist'. When the insertion is marked as unmodified, you can |
| 68 | save it with \\[write-file] RET. |
| 69 | This variable is used when the function `auto-insert' is called, e.g. |
| 70 | when you do (add-hook 'find-file-hook 'auto-insert). |
| 71 | With \\[auto-insert], this is always treated as if it were t." |
| 72 | :type '(choice (const :tag "Insert if possible" t) |
| 73 | (const :tag "Do nothing" nil) |
| 74 | (other :tag "insert if possible, mark as unmodified." |
| 75 | not-modified)) |
| 76 | :group 'auto-insert) |
| 77 | |
| 78 | (defcustom auto-insert-query 'function |
| 79 | "Non-nil means ask user before auto-inserting. |
| 80 | When this is `function', only ask when called non-interactively." |
| 81 | :type '(choice (const :tag "Don't ask" nil) |
| 82 | (const :tag "Ask if called non-interactively" function) |
| 83 | (other :tag "Ask" t)) |
| 84 | :group 'auto-insert) |
| 85 | |
| 86 | (defcustom auto-insert-prompt "Perform %s auto-insertion? " |
| 87 | "Prompt to use when querying whether to auto-insert. |
| 88 | If this contains a %s, that will be replaced by the matching rule." |
| 89 | :type 'string |
| 90 | :group 'auto-insert) |
| 91 | |
| 92 | |
| 93 | (defcustom auto-insert-alist |
| 94 | '((("\\.\\([Hh]\\|hh\\|hpp\\)\\'" . "C / C++ header") |
| 95 | (upcase (concat (file-name-nondirectory |
| 96 | (file-name-sans-extension buffer-file-name)) |
| 97 | "_" |
| 98 | (file-name-extension buffer-file-name))) |
| 99 | "#ifndef " str \n |
| 100 | "#define " str "\n\n" |
| 101 | _ "\n\n#endif") |
| 102 | |
| 103 | (("\\.\\([Cc]\\|cc\\|cpp\\)\\'" . "C / C++ program") |
| 104 | nil |
| 105 | "#include \"" |
| 106 | (let ((stem (file-name-sans-extension buffer-file-name))) |
| 107 | (cond ((file-exists-p (concat stem ".h")) |
| 108 | (file-name-nondirectory (concat stem ".h"))) |
| 109 | ((file-exists-p (concat stem ".hh")) |
| 110 | (file-name-nondirectory (concat stem ".hh"))))) |
| 111 | & ?\" | -10) |
| 112 | |
| 113 | (("[Mm]akefile\\'" . "Makefile") . "makefile.inc") |
| 114 | |
| 115 | (html-mode . (lambda () (sgml-tag "html"))) |
| 116 | |
| 117 | (plain-tex-mode . "tex-insert.tex") |
| 118 | (bibtex-mode . "tex-insert.tex") |
| 119 | (latex-mode |
| 120 | ;; should try to offer completing read for these |
| 121 | "options, RET: " |
| 122 | "\\documentclass[" str & ?\] | -1 |
| 123 | ?{ (read-string "class: ") "}\n" |
| 124 | ("package, %s: " |
| 125 | "\\usepackage[" (read-string "options, RET: ") & ?\] | -1 ?{ str "}\n") |
| 126 | _ "\n\\begin{document}\n" _ |
| 127 | "\n\\end{document}") |
| 128 | |
| 129 | (("/bin/.*[^/]\\'" . "Shell-Script mode magic number") . |
| 130 | (lambda () |
| 131 | (if (eq major-mode (default-value 'major-mode)) |
| 132 | (sh-mode)))) |
| 133 | |
| 134 | (ada-mode . ada-header) |
| 135 | |
| 136 | (("\\.[1-9]\\'" . "Man page skeleton") |
| 137 | "Short description: " |
| 138 | ".\\\" Copyright (C), " (format-time-string "%Y") " " |
| 139 | (getenv "ORGANIZATION") | (progn user-full-name) |
| 140 | " |
| 141 | .\\\" You may distribute this file under the terms of the GNU Free |
| 142 | .\\\" Documentation License. |
| 143 | .TH " (file-name-base) |
| 144 | " " (file-name-extension (buffer-file-name)) |
| 145 | " " (format-time-string "%Y-%m-%d ") |
| 146 | "\n.SH NAME\n" |
| 147 | (file-name-base) |
| 148 | " \\- " str |
| 149 | "\n.SH SYNOPSIS |
| 150 | .B " (file-name-base) |
| 151 | "\n" |
| 152 | _ |
| 153 | " |
| 154 | .SH DESCRIPTION |
| 155 | .SH OPTIONS |
| 156 | .SH FILES |
| 157 | .SH \"SEE ALSO\" |
| 158 | .SH BUGS |
| 159 | .SH AUTHOR |
| 160 | " (user-full-name) |
| 161 | '(if (search-backward "&" (line-beginning-position) t) |
| 162 | (replace-match (capitalize (user-login-name)) t t)) |
| 163 | '(end-of-line 1) " <" (progn user-mail-address) ">\n") |
| 164 | |
| 165 | (("\\.el\\'" . "Emacs Lisp header") |
| 166 | "Short description: " |
| 167 | ";;; " (file-name-nondirectory (buffer-file-name)) " --- " str |
| 168 | (make-string (max 2 (- 80 (current-column) 27)) ?\s) |
| 169 | "-*- lexical-binding: t; -*-" '(setq lexical-binding t) |
| 170 | " |
| 171 | |
| 172 | ;; Copyright (C) " (format-time-string "%Y") " " |
| 173 | (getenv "ORGANIZATION") | (progn user-full-name) " |
| 174 | |
| 175 | ;; Author: " (user-full-name) |
| 176 | '(if (search-backward "&" (line-beginning-position) t) |
| 177 | (replace-match (capitalize (user-login-name)) t t)) |
| 178 | '(end-of-line 1) " <" (progn user-mail-address) "> |
| 179 | ;; Keywords: " |
| 180 | '(require 'finder) |
| 181 | ;;'(setq v1 (apply 'vector (mapcar 'car finder-known-keywords))) |
| 182 | '(setq v1 (mapcar (lambda (x) (list (symbol-name (car x)))) |
| 183 | finder-known-keywords) |
| 184 | v2 (mapconcat (lambda (x) (format "%12s: %s" (car x) (cdr x))) |
| 185 | finder-known-keywords |
| 186 | "\n")) |
| 187 | ((let ((minibuffer-help-form v2)) |
| 188 | (completing-read "Keyword, C-h: " v1 nil t)) |
| 189 | str ", ") & -2 " |
| 190 | |
| 191 | \;; This program is free software; you can redistribute it and/or modify |
| 192 | \;; it under the terms of the GNU General Public License as published by |
| 193 | \;; the Free Software Foundation, either version 3 of the License, or |
| 194 | \;; (at your option) any later version. |
| 195 | |
| 196 | \;; This program is distributed in the hope that it will be useful, |
| 197 | \;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 198 | \;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 199 | \;; GNU General Public License for more details. |
| 200 | |
| 201 | \;; You should have received a copy of the GNU General Public License |
| 202 | \;; along with this program. If not, see <http://www.gnu.org/licenses/>. |
| 203 | |
| 204 | \;;; Commentary: |
| 205 | |
| 206 | \;; " _ " |
| 207 | |
| 208 | \;;; Code: |
| 209 | |
| 210 | |
| 211 | |
| 212 | \(provide '" |
| 213 | (file-name-base) |
| 214 | ") |
| 215 | \;;; " (file-name-nondirectory (buffer-file-name)) " ends here\n") |
| 216 | (("\\.texi\\(nfo\\)?\\'" . "Texinfo file skeleton") |
| 217 | "Title: " |
| 218 | "\\input texinfo @c -*-texinfo-*- |
| 219 | @c %**start of header |
| 220 | @setfilename " |
| 221 | (file-name-base) ".info\n" |
| 222 | "@settitle " str " |
| 223 | @c %**end of header |
| 224 | @copying\n" |
| 225 | (setq short-description (read-string "Short description: ")) |
| 226 | ".\n\n" |
| 227 | "Copyright @copyright{} " (format-time-string "%Y") " " |
| 228 | (getenv "ORGANIZATION") | (progn user-full-name) " |
| 229 | |
| 230 | @quotation |
| 231 | Permission is granted to copy, distribute and/or modify this document |
| 232 | under the terms of the GNU Free Documentation License, Version 1.3 |
| 233 | or any later version published by the Free Software Foundation; |
| 234 | with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. |
| 235 | A copy of the license is included in the section entitled ``GNU |
| 236 | Free Documentation License''. |
| 237 | |
| 238 | A copy of the license is also available from the Free Software |
| 239 | Foundation Web site at @url{http://www.gnu.org/licenses/fdl.html}. |
| 240 | |
| 241 | @end quotation |
| 242 | |
| 243 | The document was typeset with |
| 244 | @uref{http://www.texinfo.org/, GNU Texinfo}. |
| 245 | |
| 246 | @end copying |
| 247 | |
| 248 | @titlepage |
| 249 | @title " str " |
| 250 | @subtitle " short-description " |
| 251 | @author " (getenv "ORGANIZATION") | (progn user-full-name) |
| 252 | " <" (progn user-mail-address) "> |
| 253 | @page |
| 254 | @vskip 0pt plus 1filll |
| 255 | @insertcopying |
| 256 | @end titlepage |
| 257 | |
| 258 | @c Output the table of the contents at the beginning. |
| 259 | @contents |
| 260 | |
| 261 | @ifnottex |
| 262 | @node Top |
| 263 | @top " str " |
| 264 | |
| 265 | @insertcopying |
| 266 | @end ifnottex |
| 267 | |
| 268 | @c Generate the nodes for this menu with `C-c C-u C-m'. |
| 269 | @menu |
| 270 | @end menu |
| 271 | |
| 272 | @c Update all node entries with `C-c C-u C-n'. |
| 273 | @c Insert new nodes with `C-c C-c n'. |
| 274 | @node Chapter One |
| 275 | @chapter Chapter One |
| 276 | |
| 277 | " _ " |
| 278 | |
| 279 | @node Copying This Manual |
| 280 | @appendix Copying This Manual |
| 281 | |
| 282 | @menu |
| 283 | * GNU Free Documentation License:: License for copying this manual. |
| 284 | @end menu |
| 285 | |
| 286 | @c Get fdl.texi from http://www.gnu.org/licenses/fdl.html |
| 287 | @include fdl.texi |
| 288 | |
| 289 | @node Index |
| 290 | @unnumbered Index |
| 291 | |
| 292 | @printindex cp |
| 293 | |
| 294 | @bye |
| 295 | |
| 296 | @c " (file-name-nondirectory (buffer-file-name)) " ends here\n")) |
| 297 | "A list specifying text to insert by default into a new file. |
| 298 | Elements look like (CONDITION . ACTION) or ((CONDITION . DESCRIPTION) . ACTION). |
| 299 | CONDITION may be a regexp that must match the new file's name, or it may be |
| 300 | a symbol that must match the major mode for this element to apply. |
| 301 | Only the first matching element is effective. |
| 302 | Optional DESCRIPTION is a string for filling `auto-insert-prompt'. |
| 303 | ACTION may be a skeleton to insert (see `skeleton-insert'), an absolute |
| 304 | file-name or one relative to `auto-insert-directory' or a function to call. |
| 305 | ACTION may also be a vector containing several successive single actions as |
| 306 | described above, e.g. [\"header.insert\" date-and-author-update]." |
| 307 | :type 'sexp |
| 308 | :group 'auto-insert) |
| 309 | |
| 310 | |
| 311 | ;; Establish a default value for auto-insert-directory |
| 312 | (defcustom auto-insert-directory "~/insert/" |
| 313 | "Directory from which auto-inserted files are taken. |
| 314 | The value must be an absolute directory name; |
| 315 | thus, on a GNU or Unix system, it must end in a slash." |
| 316 | :type 'directory |
| 317 | :group 'auto-insert) |
| 318 | |
| 319 | |
| 320 | ;;;###autoload |
| 321 | (defun auto-insert () |
| 322 | "Insert default contents into new files if variable `auto-insert' is non-nil. |
| 323 | Matches the visited file name against the elements of `auto-insert-alist'." |
| 324 | (interactive) |
| 325 | (and (not buffer-read-only) |
| 326 | (or (eq this-command 'auto-insert) |
| 327 | (and auto-insert |
| 328 | (bobp) (eobp))) |
| 329 | (let ((alist auto-insert-alist) |
| 330 | case-fold-search cond desc action) |
| 331 | (goto-char 1) |
| 332 | ;; find first matching alist entry |
| 333 | (while alist |
| 334 | (if (atom (setq cond (car (car alist)))) |
| 335 | (setq desc cond) |
| 336 | (setq desc (cdr cond) |
| 337 | cond (car cond))) |
| 338 | (if (if (symbolp cond) |
| 339 | (eq cond major-mode) |
| 340 | (and buffer-file-name |
| 341 | (string-match cond buffer-file-name))) |
| 342 | (setq action (cdr (car alist)) |
| 343 | alist nil) |
| 344 | (setq alist (cdr alist)))) |
| 345 | |
| 346 | ;; Now, if we found something, do it |
| 347 | (and action |
| 348 | (or (not (stringp action)) |
| 349 | (file-readable-p (expand-file-name |
| 350 | action auto-insert-directory))) |
| 351 | (or (not auto-insert-query) |
| 352 | (if (eq auto-insert-query 'function) |
| 353 | (eq this-command 'auto-insert)) |
| 354 | (y-or-n-p (format auto-insert-prompt desc))) |
| 355 | (mapc |
| 356 | (lambda (action) |
| 357 | (if (stringp action) |
| 358 | (if (file-readable-p |
| 359 | (setq action (expand-file-name |
| 360 | action auto-insert-directory))) |
| 361 | (insert-file-contents action)) |
| 362 | (save-window-excursion |
| 363 | ;; make buffer visible before skeleton or function |
| 364 | ;; which might ask the user for something |
| 365 | (switch-to-buffer (current-buffer)) |
| 366 | (if (and (consp action) |
| 367 | (not (eq (car action) 'lambda))) |
| 368 | (skeleton-insert action) |
| 369 | (funcall action))))) |
| 370 | (if (vectorp action) |
| 371 | action |
| 372 | (vector action)))) |
| 373 | (and (buffer-modified-p) |
| 374 | (not (eq this-command 'auto-insert)) |
| 375 | (set-buffer-modified-p (eq auto-insert t))))) |
| 376 | ;; Return nil so that it could be used in |
| 377 | ;; `find-file-not-found-hooks', though that's probably inadvisable. |
| 378 | nil) |
| 379 | |
| 380 | |
| 381 | ;;;###autoload |
| 382 | (defun define-auto-insert (condition action &optional after) |
| 383 | "Associate CONDITION with (additional) ACTION in `auto-insert-alist'. |
| 384 | Optional AFTER means to insert action after all existing actions for CONDITION, |
| 385 | or if CONDITION had no actions, after all other CONDITIONs." |
| 386 | (let ((elt (assoc condition auto-insert-alist))) |
| 387 | (if elt |
| 388 | (setcdr elt |
| 389 | (if (vectorp (cdr elt)) |
| 390 | (vconcat (if after (cdr elt)) |
| 391 | (if (vectorp action) action (vector action)) |
| 392 | (if after () (cdr elt))) |
| 393 | (if after |
| 394 | (vector (cdr elt) action) |
| 395 | (vector action (cdr elt))))) |
| 396 | (if after |
| 397 | (nconc auto-insert-alist (list (cons condition action))) |
| 398 | (push (cons condition action) auto-insert-alist))))) |
| 399 | |
| 400 | ;;;###autoload |
| 401 | (define-minor-mode auto-insert-mode |
| 402 | "Toggle Auto-insert mode, a global minor mode. |
| 403 | With a prefix argument ARG, enable Auto-insert mode if ARG is |
| 404 | positive, and disable it otherwise. If called from Lisp, enable |
| 405 | the mode if ARG is omitted or nil. |
| 406 | |
| 407 | When Auto-insert mode is enabled, when new files are created you can |
| 408 | insert a template for the file depending on the mode of the buffer." |
| 409 | :global t :group 'auto-insert |
| 410 | (if auto-insert-mode |
| 411 | (add-hook 'find-file-hook 'auto-insert) |
| 412 | (remove-hook 'find-file-hook 'auto-insert))) |
| 413 | |
| 414 | (provide 'autoinsert) |
| 415 | |
| 416 | ;;; autoinsert.el ends here |