| 1 | ;;; derived.el -- allow inheritance of major modes. |
| 2 | ;;; (formerly mode-clone.el) |
| 3 | |
| 4 | ;; Copyright (C) 1993, 1994 Free Software Foundation, Inc. |
| 5 | |
| 6 | ;; Author: David Megginson (dmeggins@aix1.uottawa.ca) |
| 7 | ;; Maintainer: FSF |
| 8 | |
| 9 | ;; This file is part of GNU Emacs. |
| 10 | |
| 11 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 12 | ;; it under the terms of the GNU General Public License as published by |
| 13 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 14 | ;; any later version. |
| 15 | |
| 16 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 17 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 18 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 19 | ;; GNU General Public License for more details. |
| 20 | |
| 21 | ;; You should have received a copy of the GNU General Public License |
| 22 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 23 | ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, |
| 24 | ;; Boston, MA 02111-1307, USA. |
| 25 | \f |
| 26 | ;;; Commentary: |
| 27 | |
| 28 | ;; GNU Emacs is already, in a sense, object oriented -- each object |
| 29 | ;; (buffer) belongs to a class (major mode), and that class defines |
| 30 | ;; the relationship between messages (input events) and methods |
| 31 | ;; (commands) by means of a keymap. |
| 32 | ;; |
| 33 | ;; The only thing missing is a good scheme of inheritance. It is |
| 34 | ;; possible to simulate a single level of inheritance with generous |
| 35 | ;; use of hooks and a bit of work -- sgml-mode, for example, also runs |
| 36 | ;; the hooks for text-mode, and keymaps can inherit from other keymaps |
| 37 | ;; -- but generally, each major mode ends up reinventing the wheel. |
| 38 | ;; Ideally, someone should redesign all of Emacs's major modes to |
| 39 | ;; follow a more conventional object-oriented system: when defining a |
| 40 | ;; new major mode, the user should need only to name the existing mode |
| 41 | ;; it is most similar to, then list the (few) differences. |
| 42 | ;; |
| 43 | ;; In the mean time, this package offers most of the advantages of |
| 44 | ;; full inheritance with the existing major modes. The macro |
| 45 | ;; `define-derived-mode' allows the user to make a variant of an existing |
| 46 | ;; major mode, with its own keymap. The new mode will inherit the key |
| 47 | ;; bindings of its parent, and will, in fact, run its parent first |
| 48 | ;; every time it is called. For example, the commands |
| 49 | ;; |
| 50 | ;; (define-derived-mode hypertext-mode text-mode "Hypertext" |
| 51 | ;; "Major mode for hypertext.\n\n\\{hypertext-mode-map}" |
| 52 | ;; (setq case-fold-search nil)) |
| 53 | ;; |
| 54 | ;; (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link) |
| 55 | ;; |
| 56 | ;; will create a function `hypertext-mode' with its own (sparse) |
| 57 | ;; keymap `hypertext-mode-map.' The command M-x hypertext-mode will |
| 58 | ;; perform the following actions: |
| 59 | ;; |
| 60 | ;; - run the command (text-mode) to get its default setup |
| 61 | ;; - replace the current keymap with 'hypertext-mode-map,' which will |
| 62 | ;; inherit from 'text-mode-map'. |
| 63 | ;; - replace the current syntax table with |
| 64 | ;; 'hypertext-mode-syntax-table', which will borrow its defaults |
| 65 | ;; from the current text-mode-syntax-table. |
| 66 | ;; - replace the current abbrev table with |
| 67 | ;; 'hypertext-mode-abbrev-table', which will borrow its defaults |
| 68 | ;; from the current text-mode-abbrev table |
| 69 | ;; - change the mode line to read "Hypertext" |
| 70 | ;; - assign the value 'hypertext-mode' to the 'major-mode' variable |
| 71 | ;; - run the body of commands provided in the macro -- in this case, |
| 72 | ;; set the local variable `case-fold-search' to nil. |
| 73 | ;; - **run the command (hypertext-mode-setup), which is empty by |
| 74 | ;; default, but may be redefined by the user to contain special |
| 75 | ;; commands (ie. setting local variables like 'outline-regexp') |
| 76 | ;; **NOTE: do not use this option -- it will soon be obsolete. |
| 77 | ;; - run anything assigned to 'hypertext-mode-hooks' (obsolete, but |
| 78 | ;; supported for the sake of compatibility). |
| 79 | ;; |
| 80 | ;; The advantages of this system are threefold. First, text mode is |
| 81 | ;; untouched -- if you had added the new keystroke to `text-mode-map,' |
| 82 | ;; possibly using hooks, you would have added it to all text buffers |
| 83 | ;; -- here, it appears only in hypertext buffers, where it makes |
| 84 | ;; sense. Second, it is possible to build even further, and make |
| 85 | ;; a derived mode from a derived mode. The commands |
| 86 | ;; |
| 87 | ;; (define-derived-mode html-mode hypertext-mode "HTML") |
| 88 | ;; [various key definitions] |
| 89 | ;; |
| 90 | ;; will add a new major mode for HTML with very little fuss. |
| 91 | ;; |
| 92 | ;; Note also the function `derived-mode-class,' which returns the non-derived |
| 93 | ;; major mode which a derived mode is based on (ie. NOT necessarily the |
| 94 | ;; immediate parent). |
| 95 | ;; |
| 96 | ;; (derived-mode-class 'text-mode) ==> text-mode |
| 97 | ;; (derived-mode-class 'hypertext-mode) ==> text-mode |
| 98 | ;; (derived-mode-class 'html-mode) ==> text-mode |
| 99 | \f |
| 100 | ;;; Code: |
| 101 | |
| 102 | ;; PUBLIC: define a new major mode which inherits from an existing one. |
| 103 | |
| 104 | ;;;###autoload |
| 105 | (defmacro define-derived-mode (child parent name &optional docstring &rest body) |
| 106 | "Create a new mode as a variant of an existing mode. |
| 107 | |
| 108 | The arguments to this command are as follow: |
| 109 | |
| 110 | CHILD: the name of the command for the derived mode. |
| 111 | PARENT: the name of the command for the parent mode (ie. text-mode). |
| 112 | NAME: a string which will appear in the status line (ie. \"Hypertext\") |
| 113 | DOCSTRING: an optional documentation string--if you do not supply one, |
| 114 | the function will attempt to invent something useful. |
| 115 | BODY: forms to execute just before running the |
| 116 | hooks for the new mode. |
| 117 | |
| 118 | Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode: |
| 119 | |
| 120 | (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\") |
| 121 | |
| 122 | You could then make new key bindings for `LaTeX-thesis-mode-map' |
| 123 | without changing regular LaTeX mode. In this example, BODY is empty, |
| 124 | and DOCSTRING is generated by default. |
| 125 | |
| 126 | On a more complicated level, the following command uses sgml-mode as |
| 127 | the parent, and then sets the variable `case-fold-search' to nil: |
| 128 | |
| 129 | (define-derived-mode article-mode sgml-mode \"Article\" |
| 130 | \"Major mode for editing technical articles.\" |
| 131 | (setq case-fold-search nil)) |
| 132 | |
| 133 | Note that if the documentation string had been left out, it would have |
| 134 | been generated automatically, with a reference to the keymap." |
| 135 | |
| 136 | ; Some trickiness, since what |
| 137 | ; appears to be the docstring |
| 138 | ; may really be the first |
| 139 | ; element of the body. |
| 140 | (if (and docstring (not (stringp docstring))) |
| 141 | (progn (setq body (cons docstring body)) |
| 142 | (setq docstring nil))) |
| 143 | (setq docstring (or docstring (derived-mode-make-docstring parent child))) |
| 144 | |
| 145 | (` (progn |
| 146 | (derived-mode-init-mode-variables (quote (, child))) |
| 147 | (defun (, child) () |
| 148 | (, docstring) |
| 149 | (interactive) |
| 150 | ; Run the parent. |
| 151 | ((, parent)) |
| 152 | ; Identify special modes. |
| 153 | (if (get (quote (, parent)) 'special) |
| 154 | (put (quote (, child)) 'special t)) |
| 155 | ; Identify the child mode. |
| 156 | (setq major-mode (quote (, child))) |
| 157 | (setq mode-name (, name)) |
| 158 | ; Set up maps and tables. |
| 159 | (derived-mode-set-keymap (quote (, child))) |
| 160 | (derived-mode-set-syntax-table (quote (, child))) |
| 161 | (derived-mode-set-abbrev-table (quote (, child))) |
| 162 | ; Splice in the body (if any). |
| 163 | (,@ body) |
| 164 | ;;; ; Run the setup function, if |
| 165 | ;;; ; any -- this will soon be |
| 166 | ;;; ; obsolete. |
| 167 | ;;; (derived-mode-run-setup-function (quote (, child))) |
| 168 | ; Run the hooks, if any. |
| 169 | (derived-mode-run-hooks (quote (, child))))))) |
| 170 | |
| 171 | |
| 172 | ;; PUBLIC: find the ultimate class of a derived mode. |
| 173 | |
| 174 | (defun derived-mode-class (mode) |
| 175 | "Find the class of a major mode. |
| 176 | A mode's class is the first ancestor which is NOT a derived mode. |
| 177 | Use the `derived-mode-parent' property of the symbol to trace backwards." |
| 178 | (while (get mode 'derived-mode-parent) |
| 179 | (setq mode (get mode 'derived-mode-parent))) |
| 180 | mode) |
| 181 | |
| 182 | \f |
| 183 | ;; Inline functions to construct various names from a mode name. |
| 184 | |
| 185 | (defsubst derived-mode-setup-function-name (mode) |
| 186 | "Construct a setup-function name based on a mode name." |
| 187 | (intern (concat (symbol-name mode) "-setup"))) |
| 188 | |
| 189 | (defsubst derived-mode-hooks-name (mode) |
| 190 | "Construct a hooks name based on a mode name." |
| 191 | (intern (concat (symbol-name mode) "-hooks"))) |
| 192 | |
| 193 | (defsubst derived-mode-map-name (mode) |
| 194 | "Construct a map name based on a mode name." |
| 195 | (intern (concat (symbol-name mode) "-map"))) |
| 196 | |
| 197 | (defsubst derived-mode-syntax-table-name (mode) |
| 198 | "Construct a syntax-table name based on a mode name." |
| 199 | (intern (concat (symbol-name mode) "-syntax-table"))) |
| 200 | |
| 201 | (defsubst derived-mode-abbrev-table-name (mode) |
| 202 | "Construct an abbrev-table name based on a mode name." |
| 203 | (intern (concat (symbol-name mode) "-abbrev-table"))) |
| 204 | |
| 205 | \f |
| 206 | ;; Utility functions for defining a derived mode. |
| 207 | |
| 208 | ;;;###autoload |
| 209 | (defun derived-mode-init-mode-variables (mode) |
| 210 | "Initialise variables for a new mode. |
| 211 | Right now, if they don't already exist, set up a blank keymap, an |
| 212 | empty syntax table, and an empty abbrev table -- these will be merged |
| 213 | the first time the mode is used." |
| 214 | |
| 215 | (if (boundp (derived-mode-map-name mode)) |
| 216 | t |
| 217 | (eval (` (defvar (, (derived-mode-map-name mode)) |
| 218 | (make-sparse-keymap) |
| 219 | (, (format "Keymap for %s." mode))))) |
| 220 | (put (derived-mode-map-name mode) 'derived-mode-unmerged t)) |
| 221 | |
| 222 | (if (boundp (derived-mode-syntax-table-name mode)) |
| 223 | t |
| 224 | (eval (` (defvar (, (derived-mode-syntax-table-name mode)) |
| 225 | ;; Make a syntax table which doesn't specify anything |
| 226 | ;; for any char. Valid data will be merged in by |
| 227 | ;; derived-mode-merge-syntax-tables. |
| 228 | (make-char-table 'syntax-table nil) |
| 229 | (, (format "Syntax table for %s." mode))))) |
| 230 | (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t)) |
| 231 | |
| 232 | (if (boundp (derived-mode-abbrev-table-name mode)) |
| 233 | t |
| 234 | (eval (` (defvar (, (derived-mode-abbrev-table-name mode)) |
| 235 | (progn (define-abbrev-table (derived-mode-abbrev-table-name mode) nil) |
| 236 | (make-abbrev-table)) |
| 237 | (, (format "Abbrev table for %s." mode))))))) |
| 238 | |
| 239 | (defun derived-mode-make-docstring (parent child) |
| 240 | "Construct a docstring for a new mode if none is provided." |
| 241 | |
| 242 | (format "This major mode is a variant of `%s', created by `define-derived-mode'. |
| 243 | It inherits all of the parent's attributes, but has its own keymap, |
| 244 | abbrev table and syntax table: |
| 245 | |
| 246 | `%s-map' and `%s-syntax-table' |
| 247 | |
| 248 | which more-or-less shadow |
| 249 | |
| 250 | `%s-map' and `%s-syntax-table' |
| 251 | |
| 252 | \\{%s-map}" parent child child parent parent child)) |
| 253 | |
| 254 | \f |
| 255 | ;; Utility functions for running a derived mode. |
| 256 | |
| 257 | (defun derived-mode-set-keymap (mode) |
| 258 | "Set the keymap of the new mode, maybe merging with the parent." |
| 259 | (let* ((map-name (derived-mode-map-name mode)) |
| 260 | (new-map (eval map-name)) |
| 261 | (old-map (current-local-map))) |
| 262 | (and old-map |
| 263 | (get map-name 'derived-mode-unmerged) |
| 264 | (derived-mode-merge-keymaps old-map new-map)) |
| 265 | (put map-name 'derived-mode-unmerged nil) |
| 266 | (use-local-map new-map))) |
| 267 | |
| 268 | (defun derived-mode-set-syntax-table (mode) |
| 269 | "Set the syntax table of the new mode, maybe merging with the parent." |
| 270 | (let* ((table-name (derived-mode-syntax-table-name mode)) |
| 271 | (old-table (syntax-table)) |
| 272 | (new-table (eval table-name))) |
| 273 | (if (get table-name 'derived-mode-unmerged) |
| 274 | (derived-mode-merge-syntax-tables old-table new-table)) |
| 275 | (put table-name 'derived-mode-unmerged nil) |
| 276 | (set-syntax-table new-table))) |
| 277 | |
| 278 | (defun derived-mode-set-abbrev-table (mode) |
| 279 | "Set the abbrev table if it exists. |
| 280 | Always merge its parent into it, since the merge is non-destructive." |
| 281 | (let* ((table-name (derived-mode-abbrev-table-name mode)) |
| 282 | (old-table local-abbrev-table) |
| 283 | (new-table (eval table-name))) |
| 284 | (derived-mode-merge-abbrev-tables old-table new-table) |
| 285 | (setq local-abbrev-table new-table))) |
| 286 | |
| 287 | ;;;(defun derived-mode-run-setup-function (mode) |
| 288 | ;;; "Run the setup function if it exists." |
| 289 | |
| 290 | ;;; (let ((fname (derived-mode-setup-function-name mode))) |
| 291 | ;;; (if (fboundp fname) |
| 292 | ;;; (funcall fname)))) |
| 293 | |
| 294 | (defun derived-mode-run-hooks (mode) |
| 295 | "Run the hooks if they exist." |
| 296 | |
| 297 | (let ((hooks-name (derived-mode-hooks-name mode))) |
| 298 | (if (boundp hooks-name) |
| 299 | (run-hooks hooks-name)))) |
| 300 | |
| 301 | ;; Functions to merge maps and tables. |
| 302 | |
| 303 | (defun derived-mode-merge-keymaps (old new) |
| 304 | "Merge an old keymap into a new one. |
| 305 | The old keymap is set to be the last cdr of the new one, so that there will |
| 306 | be automatic inheritance." |
| 307 | (let ((tail new)) |
| 308 | ;; Scan the NEW map for prefix keys. |
| 309 | (while (consp tail) |
| 310 | (and (consp (car tail)) |
| 311 | (let* ((key (vector (car (car tail)))) |
| 312 | (subnew (lookup-key new key)) |
| 313 | (subold (lookup-key old key))) |
| 314 | ;; If KEY is a prefix key in both OLD and NEW, merge them. |
| 315 | (and (keymapp subnew) (keymapp subold) |
| 316 | (derived-mode-merge-keymaps subold subnew)))) |
| 317 | (and (vectorp (car tail)) |
| 318 | ;; Search a vector of ASCII char bindings for prefix keys. |
| 319 | (let ((i (1- (length (car tail))))) |
| 320 | (while (>= i 0) |
| 321 | (let* ((key (vector i)) |
| 322 | (subnew (lookup-key new key)) |
| 323 | (subold (lookup-key old key))) |
| 324 | ;; If KEY is a prefix key in both OLD and NEW, merge them. |
| 325 | (and (keymapp subnew) (keymapp subold) |
| 326 | (derived-mode-merge-keymaps subold subnew))) |
| 327 | (setq i (1- i))))) |
| 328 | (setq tail (cdr tail)))) |
| 329 | (setcdr (nthcdr (1- (length new)) new) old)) |
| 330 | |
| 331 | (defun derived-mode-merge-syntax-tables (old new) |
| 332 | "Merge an old syntax table into a new one. |
| 333 | Where the new table already has an entry, nothing is copied from the old one." |
| 334 | (set-char-table-parent new old)) |
| 335 | |
| 336 | ;; Merge an old abbrev table into a new one. |
| 337 | ;; This function requires internal knowledge of how abbrev tables work, |
| 338 | ;; presuming that they are obarrays with the abbrev as the symbol, the expansion |
| 339 | ;; as the value of the symbol, and the hook as the function definition. |
| 340 | (defun derived-mode-merge-abbrev-tables (old new) |
| 341 | (if old |
| 342 | (mapatoms |
| 343 | (function |
| 344 | (lambda (symbol) |
| 345 | (or (intern-soft (symbol-name symbol) new) |
| 346 | (define-abbrev new (symbol-name symbol) |
| 347 | (symbol-value symbol) (symbol-function symbol))))) |
| 348 | old))) |
| 349 | |
| 350 | (provide 'derived) |
| 351 | |
| 352 | ;;; derived.el ends here |