| 1 | ;;; mule.el --- basic commands for mulitilingual environment |
| 2 | |
| 3 | ;; Copyright (C) 1995 Free Software Foundation, Inc. |
| 4 | ;; Copyright (C) 1995 Electrotechnical Laboratory, JAPAN. |
| 5 | |
| 6 | ;; Keywords: mule, multilingual, character set, coding system |
| 7 | |
| 8 | ;; This file is part of GNU Emacs. |
| 9 | |
| 10 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 11 | ;; it under the terms of the GNU General Public License as published by |
| 12 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 13 | ;; any later version. |
| 14 | |
| 15 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 16 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 17 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 18 | ;; GNU General Public License for more details. |
| 19 | |
| 20 | ;; You should have received a copy of the GNU General Public License |
| 21 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 22 | ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, |
| 23 | ;; Boston, MA 02111-1307, USA. |
| 24 | |
| 25 | ;;; Code: |
| 26 | |
| 27 | (defconst mule-version "3.0 (MOMIJINOGA)" "\ |
| 28 | Version number and name of this version of MULE (multilingual environment).") |
| 29 | |
| 30 | (defconst mule-version-date "1998.1.1" "\ |
| 31 | Distribution date of this version of MULE (multilingual environment).") |
| 32 | |
| 33 | (defun load-with-code-conversion (fullname file &optional noerror nomessage) |
| 34 | "Execute a file of Lisp code named FILE whose absolute path is FULLNAME. |
| 35 | The FILE is decoded before evaluation if necessary. |
| 36 | If optional second arg NOERROR is non-nil, |
| 37 | report no error if FILE doesn't exist. |
| 38 | Print messages at start and end of loading unless |
| 39 | optional third arg NOMESSAGE is non-nil. |
| 40 | Return t if file exists." |
| 41 | (if (null (file-readable-p fullname)) |
| 42 | (and (null noerror) |
| 43 | (signal 'file-error (list "Cannot open load file" file))) |
| 44 | ;; Read file with code conversion, and then eval. |
| 45 | (let* ((buffer |
| 46 | ;; To avoid any autoloading, set default-major-mode to |
| 47 | ;; fundamental-mode. |
| 48 | (let ((default-major-mode 'fundamental-mode)) |
| 49 | ;; We can't use `generate-new-buffer' because files.el |
| 50 | ;; is not yet loaded. |
| 51 | (get-buffer-create (generate-new-buffer-name " *load*")))) |
| 52 | (load-in-progress t)) |
| 53 | (or nomessage (message "Loading %s..." file)) |
| 54 | (unwind-protect |
| 55 | (progn |
| 56 | (save-excursion |
| 57 | (set-buffer buffer) |
| 58 | (insert-file-contents fullname) |
| 59 | ;; We must set `buffer-file-name' for `eval-buffer' and |
| 60 | ;; `load-history'. |
| 61 | (setq buffer-file-name file) |
| 62 | ;; Make `kill-buffer' quiet. |
| 63 | (set-buffer-modified-p nil)) |
| 64 | ;; Eval in the original buffer. |
| 65 | (eval-buffer buffer)) |
| 66 | (kill-buffer buffer)) |
| 67 | (let ((hook (assoc file after-load-alist))) |
| 68 | (if hook |
| 69 | (mapcar (function eval) (cdr hook)))) |
| 70 | (or nomessage noninteractive |
| 71 | (message "Loading %s...done" file)) |
| 72 | t))) |
| 73 | |
| 74 | ;; API (Application Program Interface) for charsets. |
| 75 | |
| 76 | ;; Return t if OBJ is a quoted symbol. |
| 77 | (defsubst quoted-symbol-p (obj) |
| 78 | (and (listp obj) (eq (car obj) 'quote))) |
| 79 | |
| 80 | (defsubst charsetp (object) |
| 81 | "T is OBJECT is a charset." |
| 82 | (and (symbolp object) (vectorp (get object 'charset)))) |
| 83 | |
| 84 | (defsubst charset-info (charset) |
| 85 | "Return a vector of information of CHARSET. |
| 86 | The elements of the vector are: |
| 87 | CHARSET-ID, BYTES, DIMENSION, CHARS, WIDTH, DIRECTION, |
| 88 | LEADING-CODE-BASE, LEADING-CODE-EXT, |
| 89 | ISO-FINAL-CHAR, ISO-GRAPHIC-PLANE, |
| 90 | REVERSE-CHARSET, SHORT-NAME, LONG-NAME, DESCRIPTION, |
| 91 | PLIST, |
| 92 | where |
| 93 | CHARSET-ID (integer) is the identification number of the charset. |
| 94 | DIMENSION (integer) is the number of bytes to represent a character of |
| 95 | the charset: 1 or 2. |
| 96 | CHARS (integer) is the number of characters in a dimension: 94 or 96. |
| 97 | BYTE (integer) is the length of multi-byte form of a character in |
| 98 | the charset: one of 1, 2, 3, and 4. |
| 99 | WIDTH (integer) is the number of columns a character in the charset |
| 100 | occupies on the screen: one of 0, 1, and 2. |
| 101 | DIRECTION (integer) is the rendering direction of characters in the |
| 102 | charset when rendering. If 0, render from right to left, else |
| 103 | render from left to right. |
| 104 | LEADING-CODE-BASE (integer) is the base leading-code for the |
| 105 | charset. |
| 106 | LEADING-CODE-EXT (integer) is the extended leading-code for the |
| 107 | charset. All charsets of less than 0xA0 has the value 0. |
| 108 | ISO-FINAL-CHAR (character) is the final character of the |
| 109 | corresponding ISO 2022 charset. |
| 110 | ISO-GRAPHIC-PLANE (integer) is the graphic plane to be invoked |
| 111 | while encoding to variants of ISO 2022 coding system, one of the |
| 112 | following: 0/graphic-plane-left(GL), 1/graphic-plane-right(GR). |
| 113 | REVERSE-CHARSET (integer) is the charset which differs only in |
| 114 | LEFT-TO-RIGHT value from the charset. If there's no such a |
| 115 | charset, the value is -1. |
| 116 | SHORT-NAME (string) is the short name to refer to the charset. |
| 117 | LONG-NAME (string) is the long name to refer to the charset |
| 118 | DESCRIPTION (string) is the description string of the charset. |
| 119 | PLIST (property list) may contain any type of information a user |
| 120 | want to put and get by functions `put-charset-property' and |
| 121 | `get-charset-property' respectively." |
| 122 | (get charset 'charset)) |
| 123 | |
| 124 | (defmacro charset-id (charset) |
| 125 | "Return charset identification number of CHARSET." |
| 126 | (if (and (listp charset) (eq (car charset) 'quote)) |
| 127 | (aref (charset-info (nth 1 charset)) 0) |
| 128 | `(aref (charset-info ,charset) 0))) |
| 129 | |
| 130 | (defmacro charset-bytes (charset) |
| 131 | (if (quoted-symbol-p charset) |
| 132 | (aref (charset-info (nth 1 charset)) 1) |
| 133 | `(aref (charset-info ,charset) 1))) |
| 134 | |
| 135 | (defmacro charset-dimension (charset) |
| 136 | (if (quoted-symbol-p charset) |
| 137 | (aref (charset-info (nth 1 charset)) 2) |
| 138 | `(aref (charset-info ,charset) 2))) |
| 139 | |
| 140 | (defmacro charset-chars (charset) |
| 141 | (if (quoted-symbol-p charset) |
| 142 | (aref (charset-info (nth 1 charset)) 3) |
| 143 | `(aref (charset-info ,charset) 3))) |
| 144 | |
| 145 | (defmacro charset-width (charset) |
| 146 | (if (quoted-symbol-p charset) |
| 147 | (aref (charset-info (nth 1 charset)) 4) |
| 148 | `(aref (charset-info ,charset) 4))) |
| 149 | |
| 150 | (defmacro charset-direction (charset) |
| 151 | (if (quoted-symbol-p charset) |
| 152 | (aref (charset-info (nth 1 charset)) 5) |
| 153 | `(aref (charset-info ,charset) 5))) |
| 154 | |
| 155 | (defmacro charset-iso-final-char (charset) |
| 156 | (if (quoted-symbol-p charset) |
| 157 | (aref (charset-info (nth 1 charset)) 8) |
| 158 | `(aref (charset-info ,charset) 8))) |
| 159 | |
| 160 | (defmacro charset-iso-graphic-plane (charset) |
| 161 | (if (quoted-symbol-p charset) |
| 162 | (aref (charset-info (nth 1 charset)) 9) |
| 163 | `(aref (charset-info ,charset) 9))) |
| 164 | |
| 165 | (defmacro charset-reverse-charset (charset) |
| 166 | (if (quoted-symbol-p charset) |
| 167 | (aref (charset-info (nth 1 charset)) 10) |
| 168 | `(aref (charset-info ,charset) 10))) |
| 169 | |
| 170 | (defmacro charset-short-name (charset) |
| 171 | (if (quoted-symbol-p charset) |
| 172 | (aref (charset-info (nth 1 charset)) 11) |
| 173 | `(aref (charset-info ,charset) 11))) |
| 174 | |
| 175 | (defmacro charset-long-name (charset) |
| 176 | (if (quoted-symbol-p charset) |
| 177 | (aref (charset-info (nth 1 charset)) 12) |
| 178 | `(aref (charset-info ,charset) 12))) |
| 179 | |
| 180 | (defmacro charset-description (charset) |
| 181 | (if (quoted-symbol-p charset) |
| 182 | (aref (charset-info (nth 1 charset)) 13) |
| 183 | `(aref (charset-info ,charset) 13))) |
| 184 | |
| 185 | (defmacro charset-plist (charset) |
| 186 | (if (quoted-symbol-p charset) |
| 187 | `(aref ,(charset-info (nth 1 charset)) 14) |
| 188 | `(aref (charset-info ,charset) 14))) |
| 189 | |
| 190 | (defun set-charset-plist (charset plist) |
| 191 | (aset (charset-info charset) 14 plist)) |
| 192 | |
| 193 | (defmacro make-char (charset &optional c1 c2) |
| 194 | "Return a character of CHARSET and position-codes CODE1 and CODE2. |
| 195 | CODE1 and CODE2 are optional, but if you don't supply |
| 196 | sufficient position-codes, return a generic character which stands for |
| 197 | all characters or group of characters in the character sets. |
| 198 | A generic character can be used to index a char table (e.g. syntax-table)." |
| 199 | (if (quoted-symbol-p charset) |
| 200 | `(make-char-internal ,(charset-id (nth 1 charset)) ,c1 ,c2) |
| 201 | `(make-char-internal (charset-id ,charset) ,c1 ,c2))) |
| 202 | |
| 203 | (defmacro charset-list () |
| 204 | "Return list of charsets ever defined." |
| 205 | 'charset-list) |
| 206 | |
| 207 | (defsubst generic-char-p (char) |
| 208 | "Return t if and only if CHAR is a generic character. |
| 209 | See also the documentation of make-char." |
| 210 | (let ((l (split-char char))) |
| 211 | (and (or (= (nth 1 l) 0) (eq (nth 2 l) 0)) |
| 212 | (not (eq (car l) 'composition))))) |
| 213 | |
| 214 | ;; Coding-system staffs |
| 215 | |
| 216 | ;; Coding-system object is a symbol that has the property |
| 217 | ;; `coding-system' and `eol-type'. |
| 218 | ;; |
| 219 | ;; The value of the property `coding-system' is a coding-vector of the |
| 220 | ;; format: [TYPE MNEMONIC DOCSTRING NOT-USED-NOW FLAGS]. |
| 221 | ;; See comments in src/coding.c for more detail. The property value |
| 222 | ;; may be another coding-system, in which case, the coding-vector |
| 223 | ;; should be taken from that coding-system. |
| 224 | ;; |
| 225 | ;; The value of the property `eol-type' is integer 0..2 or a vector of |
| 226 | ;; length 3. The integer value 0, 1, and 2 indicate the format of |
| 227 | ;; end-of-line LF, CRLF, and CR respectively. The vector value |
| 228 | ;; indicates that the format of end-of-line should be detected |
| 229 | ;; automatically. Nth element of the vector is the subsidiary |
| 230 | ;; coding-system whose `eol-type' property is integer value. |
| 231 | ;; |
| 232 | ;; Coding-system may also have properties `post-read-conversion' and |
| 233 | ;; `pre-write-conversion and the values are functions. |
| 234 | ;; |
| 235 | ;; The function in `post-read-conversion' is called after some text is |
| 236 | ;; inserted and decoded along the coding-system and before any |
| 237 | ;; functions in `after-insert-functions' are called. The arguments to |
| 238 | ;; this function is the same as those of a function in |
| 239 | ;; `after-insert-functions', i.e. LENGTH of a text while putting point |
| 240 | ;; at the head of the text to be decoded |
| 241 | ;; |
| 242 | ;; The function in `pre-write-conversion' is called after all |
| 243 | ;; functions in `write-region-annotate-functions' and |
| 244 | ;; `buffer-file-format' are called, and before the text is encoded by |
| 245 | ;; the coding-system. The arguments to this function is the same as |
| 246 | ;; those of a function in `write-region-annotate-functions', i.e. FROM |
| 247 | ;; and TO specifying region of a text. |
| 248 | |
| 249 | (defsubst coding-vector-type (vec) (aref vec 0)) |
| 250 | (defsubst coding-vector-mnemonic (vec) (aref vec 1)) |
| 251 | (defsubst coding-vector-docstring (vec) (aref vec 2)) |
| 252 | (defsubst coding-vector-flags (vec) (aref vec 4)) |
| 253 | |
| 254 | ;; Return type of CODING-SYSTEM. |
| 255 | (defun coding-system-type (coding-system) |
| 256 | (check-coding-system coding-system) |
| 257 | (let ((vec (coding-system-vector coding-system))) |
| 258 | (if vec (coding-vector-type vec)))) |
| 259 | |
| 260 | ;; Return mnemonic character of CODING-SYSTEM. |
| 261 | (defun coding-system-mnemonic (coding-system) |
| 262 | (check-coding-system coding-system) |
| 263 | (let ((vec (coding-system-vector coding-system))) |
| 264 | (if vec (coding-vector-mnemonic vec) |
| 265 | ?-))) |
| 266 | |
| 267 | ;; Return docstring of CODING-SYSTEM. |
| 268 | (defun coding-system-docstring (coding-system) |
| 269 | (check-coding-system coding-system) |
| 270 | (let ((vec (coding-system-vector coding-system))) |
| 271 | (if vec (coding-vector-docstring vec)))) |
| 272 | |
| 273 | ;; Return flags of CODING-SYSTEM. |
| 274 | (defun coding-system-flags (coding-system) |
| 275 | (check-coding-system coding-system) |
| 276 | (let ((vec (coding-system-vector coding-system))) |
| 277 | (if vec (coding-vector-flags vec)))) |
| 278 | |
| 279 | ;; Return eol-type of CODING-SYSTEM. |
| 280 | (defun coding-system-eoltype (coding-system) |
| 281 | (check-coding-system coding-system) |
| 282 | (and coding-system |
| 283 | (or (get coding-system 'eol-type) |
| 284 | (coding-system-eoltype (get coding-system 'coding-system))))) |
| 285 | |
| 286 | ;; Return mnemonic character of eol-type of CODING-SYSTEM. |
| 287 | (defun coding-system-eoltype-mnemonic (coding-system) |
| 288 | (let ((eol-type (coding-system-eoltype coding-system))) |
| 289 | (cond ((vectorp eol-type) eol-mnemonic-undecided) |
| 290 | ((eq eol-type 0) eol-mnemonic-unix) |
| 291 | ((eq eol-type 1) eol-mnemonic-unix) |
| 292 | ((eq eol-type 2) eol-mnemonic-unix) |
| 293 | (t ?-)))) |
| 294 | |
| 295 | ;; Return function for post-read-conversion of CODING-SYSTEM. |
| 296 | (defun coding-system-post-read-conversion (coding-system) |
| 297 | (and coding-system |
| 298 | (symbolp coding-system) |
| 299 | (or (get coding-system 'post-read-conversion) |
| 300 | (coding-system-post-read-conversion |
| 301 | (get coding-system 'coding-system))))) |
| 302 | |
| 303 | ;; Return function for pre-write-conversion of CODING-SYSTEM. |
| 304 | (defun coding-system-pre-write-conversion (coding-system) |
| 305 | (and coding-system |
| 306 | (symbolp coding-system) |
| 307 | (or (get coding-system 'pre-write-conversion) |
| 308 | (coding-system-pre-write-conversion |
| 309 | (get coding-system 'coding-system))))) |
| 310 | |
| 311 | (defun make-coding-system (coding-system type mnemonic docstring |
| 312 | &optional flags) |
| 313 | "Define a new CODING-SYSTEM (symbol). |
| 314 | Remaining arguments are TYPE, MNEMONIC, DOCSTRING, and FLAGS (optional). |
| 315 | TYPE is an integer value indicating the type of coding-system as follows: |
| 316 | 0: Emacs internal format, |
| 317 | 1: Shift-JIS (or MS-Kanji) used mainly on Japanese PC, |
| 318 | 2: ISO-2022 including many variants, |
| 319 | 3: Big5 used mainly on Chinese PC, |
| 320 | 4: private, CCL programs provide encoding/decoding algorithm. |
| 321 | MNEMONIC is a character to be displayed on mode line for the coding-system. |
| 322 | DOCSTRING is a documentation string for the coding-system. |
| 323 | FLAGS specifies more precise information of each TYPE. |
| 324 | If TYPE is 2 (ISO-2022), FLAGS should be a list of: |
| 325 | CHARSET0, CHARSET1, CHARSET2, CHARSET3, SHORT-FORM, |
| 326 | ASCII-EOL, ASCII-CNTL, SEVEN, LOCKING-SHIFT, SINGLE-SHIFT, |
| 327 | USE-ROMAN, USE-OLDJIS, NO-ISO6429, INIT-BOL, DESIGNATION-BOL. |
| 328 | CHARSETn are character sets initially designated to Gn graphic registers. |
| 329 | If CHARSETn is nil, Gn is never used. |
| 330 | If CHARSETn is t, Gn can be used but nothing designated initially. |
| 331 | If CHARSETn is a list of character sets, those character sets are |
| 332 | designated to Gn on output, but nothing designated to Gn initially. |
| 333 | SHORT-FORM non-nil means use short designation sequence on output. |
| 334 | ASCII-EOL non-nil means designate ASCII to g0 at end of line on output. |
| 335 | ASCII-CNTL non-nil means designate ASCII to g0 before control codes and |
| 336 | SPACE on output. |
| 337 | SEVEN non-nil means use 7-bit code only on output. |
| 338 | LOCKING-SHIFT non-nil means use locking-shift. |
| 339 | SINGLE-SHIFT non-nil means use single-shift. |
| 340 | USE-ROMAN non-nil means designate JIS0201-1976-Roman instead of ASCII. |
| 341 | USE-OLDJIS non-nil means designate JIS0208-1976 instead of JIS0208-1983. |
| 342 | NO-ISO6429 non-nil means not use ISO6429's direction specification. |
| 343 | INIT-BOL non-nil means any designation state is assumed to be reset |
| 344 | to initial at each beginning of line on output. |
| 345 | DESIGNATION-BOL non-nil means designation sequences should be placed |
| 346 | at beginning of line on output. |
| 347 | If TYPE is 4 (private), FLAGS should be a cons of CCL programs, |
| 348 | for encoding and decoding. See the documentation of CCL for more detail." |
| 349 | |
| 350 | ;; At first, set a value of `coding-system' property. |
| 351 | (let ((coding-vector (make-vector 5 nil))) |
| 352 | (aset coding-vector 0 type) |
| 353 | (aset coding-vector 1 |
| 354 | ;; MNEMONIC must be a printable character. |
| 355 | (if (and (> mnemonic ? ) (< mnemonic 127)) mnemonic ? )) |
| 356 | (aset coding-vector 2 (if (stringp docstring) docstring "")) |
| 357 | (aset coding-vector 3 nil) ; obsolete element |
| 358 | (cond ((eq type 2) ; ISO2022 |
| 359 | (let ((i 0) |
| 360 | (vec (make-vector 32 nil))) |
| 361 | (while (< i 4) |
| 362 | (let ((charset (car flags))) |
| 363 | (or (not charset) (eq charset t) (charsetp charset) |
| 364 | (if (not (listp charset)) |
| 365 | (error "Invalid charset: %s" charset) |
| 366 | (let (elt l) |
| 367 | (while charset |
| 368 | (setq elt (car charset)) |
| 369 | (or (not elt) (eq elt t) (charsetp elt) |
| 370 | (error "Invalid charset: %s" elt)) |
| 371 | (setq l (cons elt l)) |
| 372 | (setq charset (cdr charset))) |
| 373 | (setq charset (nreverse l))))) |
| 374 | (aset vec i charset)) |
| 375 | (setq flags (cdr flags) i (1+ i))) |
| 376 | (while (and (< i 32) flags) |
| 377 | (aset vec i (car flags)) |
| 378 | (setq flags (cdr flags) i (1+ i))) |
| 379 | (aset coding-vector 4 vec))) |
| 380 | ((eq type 4) ; private |
| 381 | (if (and (consp flags) |
| 382 | (vectorp (car flags)) |
| 383 | (vectorp (cdr flags))) |
| 384 | (aset coding-vector 4 flags) |
| 385 | (error "Invalid FLAGS argument for TYPE 4 (CCL)"))) |
| 386 | (t (aset coding-vector 4 flags))) |
| 387 | (put coding-system 'coding-system coding-vector)) |
| 388 | |
| 389 | ;; Next, set a value of `eol-type' property. The value is a vector |
| 390 | ;; of subsidiary coding-systems, each corresponds to a coding-system |
| 391 | ;; for the detected end-of-line format. |
| 392 | (let ((codings (vector (intern (format "%s-unix" coding-system)) |
| 393 | (intern (format "%s-dos" coding-system)) |
| 394 | (intern (format "%s-mac" coding-system)))) |
| 395 | (i 0)) |
| 396 | (while (< i 3) |
| 397 | (put (aref codings i) 'coding-system coding-system) |
| 398 | (put (aref codings i) 'eol-type i) |
| 399 | (setq i (1+ i))) |
| 400 | (put coding-system 'eol-type codings)) |
| 401 | ) |
| 402 | |
| 403 | (defun define-coding-system-alias (symbol new-symbol) |
| 404 | "Define NEW-SYMBOL as the same coding system as SYMBOL." |
| 405 | (check-coding-system symbol) |
| 406 | (put new-symbol 'coding-system symbol) |
| 407 | (let ((eol-type (coding-system-eoltype symbol))) |
| 408 | (if (vectorp eol-type) |
| 409 | (let* ((name (symbol-name new-symbol)) |
| 410 | (new-eol-type (vector (intern (concat name "-unix")) |
| 411 | (intern (concat name "-dos")) |
| 412 | (intern (concat name "-mac"))))) |
| 413 | (define-coding-system-alias (aref eol-type 0) (aref new-eol-type 0)) |
| 414 | (define-coding-system-alias (aref eol-type 1) (aref new-eol-type 1)) |
| 415 | (define-coding-system-alias (aref eol-type 2) (aref new-eol-type 2)) |
| 416 | (setq eol-type new-eol-type))) |
| 417 | (put new-symbol 'eol-type eol-type))) |
| 418 | |
| 419 | (defvar buffer-file-coding-system nil |
| 420 | "Coding-system of the file which the current-buffer is visiting.") |
| 421 | (make-variable-buffer-local 'buffer-file-coding-system) |
| 422 | ;; This value should not be reset by changing major mode. |
| 423 | (put 'buffer-file-coding-system 'permanent-local t) |
| 424 | |
| 425 | (defun set-buffer-file-coding-system (coding-system &optional force) |
| 426 | "Set buffer-file-coding-system of the current buffer to CODING-SYSTEM. |
| 427 | If eol-type of the current buffer-file-coding-system is an integer value N, and |
| 428 | eol-type of CODING-SYSTEM is a vector, the Nth element of the vector is used |
| 429 | instead of CODING-SYSTEM itself. |
| 430 | Optional prefix argument FORCE non-nil means CODING-SYSTEM is set |
| 431 | regardless of eol-type of the current buffer-file-coding-system." |
| 432 | (interactive "zBuffer-file-coding-system: \nP") |
| 433 | (check-coding-system coding-system) |
| 434 | (if (null force) |
| 435 | (let ((x (coding-system-eoltype buffer-file-coding-system)) |
| 436 | (y (coding-system-eoltype coding-system))) |
| 437 | (if (and (numberp x) (>= x 0) (<= x 2) (vectorp y)) |
| 438 | (setq coding-system (aref y x))))) |
| 439 | (setq buffer-file-coding-system coding-system) |
| 440 | (set-buffer-modified-p t) |
| 441 | (force-mode-line-update)) |
| 442 | |
| 443 | (defun set-current-process-coding-system (input output) |
| 444 | (interactive |
| 445 | "zCoding-system for process input: \nzCoding-system for process output: ") |
| 446 | (let ((proc (get-buffer-process (current-buffer)))) |
| 447 | (if (null proc) |
| 448 | (error "no process") |
| 449 | (check-coding-system input) |
| 450 | (check-coding-system output) |
| 451 | (set-process-coding-system proc input output))) |
| 452 | (force-mode-line-update)) |
| 453 | |
| 454 | (defvar default-process-coding-system (cons nil nil) |
| 455 | "Cons of default values used to read from and write to process.") |
| 456 | |
| 457 | (defun set-coding-priority (arg) |
| 458 | "Set priority of coding-category according to LIST. |
| 459 | LIST is a list of coding-categories ordered by priority." |
| 460 | (let (l) |
| 461 | ;; Put coding-categories listed in ARG to L while checking the |
| 462 | ;; validity. We assume that `coding-category-list' contains whole |
| 463 | ;; coding-categories. |
| 464 | (while arg |
| 465 | (if (null (memq (car arg) coding-category-list)) |
| 466 | (error "Invalid element in argument: %s" (car arg))) |
| 467 | (setq l (cons (car arg) l)) |
| 468 | (setq arg (cdr arg))) |
| 469 | ;; Put coding-category not listed in ARG to L. |
| 470 | (while coding-category-list |
| 471 | (if (null (memq (car coding-category-list) l)) |
| 472 | (setq l (cons (car coding-category-list) l))) |
| 473 | (setq coding-category-list (cdr coding-category-list))) |
| 474 | ;; Update `coding-category-list' and return it. |
| 475 | (setq coding-category-list (nreverse l)))) |
| 476 | |
| 477 | ;;; FILE I/O |
| 478 | |
| 479 | ;; Set buffer-file-coding-system of the current buffer after some text |
| 480 | ;; is inserted. |
| 481 | (defun after-insert-file-set-buffer-file-coding-system (inserted) |
| 482 | (if last-coding-system-used |
| 483 | (let ((coding-system |
| 484 | (find-new-buffer-file-coding-system last-coding-system-used)) |
| 485 | (modified-p (buffer-modified-p))) |
| 486 | (if coding-system |
| 487 | (set-buffer-file-coding-system coding-system)) |
| 488 | (set-buffer-modified-p modified-p))) |
| 489 | nil) |
| 490 | |
| 491 | (setq after-insert-file-functions |
| 492 | (cons 'after-insert-file-set-buffer-file-coding-system |
| 493 | after-insert-file-functions)) |
| 494 | |
| 495 | ;; The coding-vector and eol-type of coding-system returned is decided |
| 496 | ;; independently in the following order. |
| 497 | ;; 1. That of buffer-file-coding-system locally bound. |
| 498 | ;; 2. That of CODING. |
| 499 | |
| 500 | (defun find-new-buffer-file-coding-system (coding) |
| 501 | "Return a coding system for a buffer when a file of CODING is inserted. |
| 502 | The local variable `buffer-file-coding-system' of the current buffer |
| 503 | is set to the returned value. |
| 504 | Return nil if there's no need of setting new buffer-file-coding-system." |
| 505 | (let (local-coding local-eol |
| 506 | found-eol |
| 507 | new-coding new-eol) |
| 508 | (if (null coding) |
| 509 | ;; Nothing found about coding. |
| 510 | nil |
| 511 | |
| 512 | ;; Get information of the current local value of |
| 513 | ;; `buffer-file-coding-system' in LOCAL-EOL and LOCAL-CODING. |
| 514 | (if (local-variable-p 'buffer-file-coding-system) |
| 515 | ;; Something already set locally. |
| 516 | (progn |
| 517 | (setq local-eol (coding-system-eoltype buffer-file-coding-system)) |
| 518 | (if (null (numberp local-eol)) |
| 519 | ;; But eol-type is not yet set. |
| 520 | (setq local-eol nil)) |
| 521 | (if (null (eq (coding-system-type buffer-file-coding-system) t)) |
| 522 | ;; This is not `undecided'. |
| 523 | (progn |
| 524 | (setq local-coding buffer-file-coding-system) |
| 525 | (while (symbolp (get local-coding 'coding-system)) |
| 526 | (setq local-coding (get local-coding 'coding-system)))) |
| 527 | ))) |
| 528 | |
| 529 | (if (and local-eol local-coding) |
| 530 | ;; The current buffer has already set full coding-system, we |
| 531 | ;; had better not change it. |
| 532 | nil |
| 533 | |
| 534 | (setq found-eol (coding-system-eoltype coding)) |
| 535 | (if (null (numberp found-eol)) |
| 536 | ;; But eol-type is not found. |
| 537 | (setq found-eol nil)) |
| 538 | (if (eq (coding-system-type coding) t) |
| 539 | ;; This is `undecided', which means nothing found except |
| 540 | ;; for eol-type. |
| 541 | (setq coding nil)) |
| 542 | |
| 543 | ;; The local setting takes precedence over the found one. |
| 544 | (setq new-coding (or local-coding coding)) |
| 545 | (setq new-eol (or local-eol found-eol)) |
| 546 | (if (and (numberp new-eol) |
| 547 | (vectorp (coding-system-eoltype new-coding))) |
| 548 | (setq new-coding |
| 549 | (aref (coding-system-eoltype new-coding) new-eol))) |
| 550 | new-coding)))) |
| 551 | |
| 552 | (defun make-unification-table (&rest args) |
| 553 | "Make a unification table (char table) from arguments. |
| 554 | Each argument is a list of the form (FROM . TO), |
| 555 | where FROM is a character to be unified to TO. |
| 556 | |
| 557 | FROM can be a generic character (see make-char). In this case, TO is |
| 558 | a generic character containing the same number of charcters or a |
| 559 | oridinal character. If FROM and TO are both generic characters, all |
| 560 | characters belonging to FROM are unified to characters belonging to TO |
| 561 | without changing their position code(s)." |
| 562 | (let ((table (make-char-table 'character-unification-table)) |
| 563 | revlist) |
| 564 | (while args |
| 565 | (let ((elts (car args))) |
| 566 | (while elts |
| 567 | (let* ((from (car (car elts))) |
| 568 | (from-i 0) ; degree of freedom of FROM |
| 569 | (from-rev (nreverse (split-char from))) |
| 570 | (to (cdr (car elts))) |
| 571 | (to-i 0) ; degree of freedom of TO |
| 572 | (to-rev (nreverse (split-char to)))) |
| 573 | ;; Check numbers of heading 0s in FROM-REV and TO-REV. |
| 574 | (while (eq (car from-rev) 0) |
| 575 | (setq from-i (1+ from-i) from-rev (cdr from-rev))) |
| 576 | (while (eq (car to-rev) 0) |
| 577 | (setq to-i (1+ to-i) to-rev (cdr to-rev))) |
| 578 | (if (and (/= from-i to-i) (/= to-i 0)) |
| 579 | (error "Invalid character pair (%d . %d)" from to)) |
| 580 | ;; If we have already unified TO to TO-ALT, FROM should |
| 581 | ;; also be unified to TO-ALT. But, this is only if TO is |
| 582 | ;; a generic character or TO-ALT is not a generic |
| 583 | ;; character. |
| 584 | (let ((to-alt (aref table to))) |
| 585 | (if (and to-alt |
| 586 | (or (> to-i 0) (not (generic-char-p to-alt)))) |
| 587 | (setq to to-alt))) |
| 588 | (if (> from-i 0) |
| 589 | (set-char-table-default table from to) |
| 590 | (aset table from to)) |
| 591 | ;; If we have already unified some chars to FROM, they |
| 592 | ;; should also be unified to TO. |
| 593 | (let ((l (assq from revlist))) |
| 594 | (if l |
| 595 | (let ((ch (car l))) |
| 596 | (setcar l to) |
| 597 | (setq l (cdr l)) |
| 598 | (while l |
| 599 | (aset table ch to) |
| 600 | (setq l (cdr l)) )))) |
| 601 | ;; Now update REVLIST. |
| 602 | (let ((l (assq to revlist))) |
| 603 | (if l |
| 604 | (setcdr l (cons from (cdr l))) |
| 605 | (setq revlist (cons (list to from) revlist))))) |
| 606 | (setq elts (cdr elts)))) |
| 607 | (setq args (cdr args))) |
| 608 | ;; Return TABLE just created. |
| 609 | table)) |
| 610 | |
| 611 | ;;; Initialize some variables. |
| 612 | |
| 613 | (put 'use-default-ascent 'char-table-extra-slots 0) |
| 614 | (setq use-default-ascent (make-char-table 'use-default-ascent)) |
| 615 | |
| 616 | ;;; |
| 617 | (provide 'mule) |
| 618 | |
| 619 | ;;; mule.el ends here |