| 1 | ;;; imenu.el --- framework for mode-specific buffer indexes -*- lexical-binding: t -*- |
| 2 | |
| 3 | ;; Copyright (C) 1994-1998, 2001-2013 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Author: Ake Stenhoff <etxaksf@aom.ericsson.se> |
| 6 | ;; Lars Lindberg <lli@sypro.cap.se> |
| 7 | ;; Maintainer: FSF |
| 8 | ;; Created: 8 Feb 1994 |
| 9 | ;; Keywords: tools convenience |
| 10 | |
| 11 | ;; This file is part of GNU Emacs. |
| 12 | |
| 13 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 14 | ;; it under the terms of the GNU General Public License as published by |
| 15 | ;; the Free Software Foundation, either version 3 of the License, or |
| 16 | ;; (at your option) any later version. |
| 17 | |
| 18 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 19 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 20 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 21 | ;; GNU General Public License for more details. |
| 22 | |
| 23 | ;; You should have received a copy of the GNU General Public License |
| 24 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 25 | |
| 26 | ;;; Commentary: |
| 27 | |
| 28 | ;; Purpose of this package: |
| 29 | ;; To present a framework for mode-specific buffer indexes. |
| 30 | ;; A buffer index is an alist of names and buffer positions. |
| 31 | ;; For instance all functions in a C-file and their positions. |
| 32 | ;; |
| 33 | ;; It is documented in the Emacs Lisp manual. |
| 34 | ;; |
| 35 | ;; How it works: |
| 36 | |
| 37 | ;; A mode-specific function is called to generate the index. It is |
| 38 | ;; then presented to the user, who can choose from this index. |
| 39 | ;; |
| 40 | ;; The package comes with a set of example functions for how to |
| 41 | ;; utilize this package. |
| 42 | |
| 43 | ;; There are *examples* for index gathering functions/regular |
| 44 | ;; expressions for C/C++ and Lisp/Emacs Lisp but it is easy to |
| 45 | ;; customize for other modes. A function for jumping to the chosen |
| 46 | ;; index position is also supplied. |
| 47 | |
| 48 | ;;; History: |
| 49 | ;; Thanks go to |
| 50 | ;; [simon] - Simon Leinen simon@lia.di.epfl.ch |
| 51 | ;; [dean] - Dean Andrews ada@unison.com |
| 52 | ;; [alon] - Alon Albert al@mercury.co.il |
| 53 | ;; [greg] - Greg Thompson gregt@porsche.visix.COM |
| 54 | ;; [wolfgang] - Wolfgang Bangerth zcg51122@rpool1.rus.uni-stuttgart.de |
| 55 | ;; [kai] - Kai Grossjohann grossjoh@linus.informatik.uni-dortmund.de |
| 56 | ;; [david] - David M. Smith dsmith@stats.adelaide.edu.au |
| 57 | ;; [christian] - Christian Egli Christian.Egli@hcsd.hac.com |
| 58 | ;; [karl] - Karl Fogel kfogel@floss.life.uiuc.edu |
| 59 | |
| 60 | ;;; Code: |
| 61 | |
| 62 | (eval-when-compile (require 'cl-lib)) |
| 63 | |
| 64 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 65 | ;;; |
| 66 | ;;; Customizable variables |
| 67 | ;;; |
| 68 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 69 | |
| 70 | (defgroup imenu nil |
| 71 | "Mode-specific buffer indexes." |
| 72 | :group 'matching |
| 73 | :group 'frames |
| 74 | :group 'convenience |
| 75 | :link '(custom-manual "(elisp)Imenu")) |
| 76 | |
| 77 | (defcustom imenu-use-markers t |
| 78 | "Non-nil means use markers instead of integers for Imenu buffer positions. |
| 79 | |
| 80 | Setting this to nil makes Imenu work a little faster but editing the |
| 81 | buffer will make the generated index positions wrong. |
| 82 | |
| 83 | This might not yet be honored by all index-building functions." |
| 84 | :type 'boolean |
| 85 | :group 'imenu) |
| 86 | |
| 87 | |
| 88 | (defcustom imenu-max-item-length 60 |
| 89 | "If a number, truncate Imenu entries to that length." |
| 90 | :type '(choice integer |
| 91 | (const :tag "Unlimited")) |
| 92 | :group 'imenu) |
| 93 | |
| 94 | (defcustom imenu-auto-rescan nil |
| 95 | "Non-nil means Imenu should always rescan the buffers." |
| 96 | :type 'boolean |
| 97 | :group 'imenu) |
| 98 | |
| 99 | (defcustom imenu-auto-rescan-maxout 60000 |
| 100 | "Imenu auto-rescan is disabled in buffers larger than this size (in bytes). |
| 101 | This variable is buffer-local." |
| 102 | :type 'integer |
| 103 | :group 'imenu) |
| 104 | |
| 105 | (defvar imenu-always-use-completion-buffer-p nil) |
| 106 | (make-obsolete-variable 'imenu-always-use-completion-buffer-p |
| 107 | 'imenu-use-popup-menu "22.1") |
| 108 | |
| 109 | (defcustom imenu-use-popup-menu |
| 110 | (if imenu-always-use-completion-buffer-p |
| 111 | (not (eq imenu-always-use-completion-buffer-p 'never)) |
| 112 | 'on-mouse) |
| 113 | "Use a popup menu rather than a minibuffer prompt. |
| 114 | If nil, always use a minibuffer prompt. |
| 115 | If t, always use a popup menu, |
| 116 | If `on-mouse' use a popup menu when `imenu' was invoked with the mouse." |
| 117 | :type '(choice (const :tag "On Mouse" on-mouse) |
| 118 | (const :tag "Never" nil) |
| 119 | (other :tag "Always" t)) |
| 120 | :group 'imenu) |
| 121 | |
| 122 | (defcustom imenu-eager-completion-buffer |
| 123 | (not (eq imenu-always-use-completion-buffer-p 'never)) |
| 124 | "If non-nil, eagerly popup the completion buffer." |
| 125 | :type 'boolean |
| 126 | :group 'imenu |
| 127 | :version "22.1") |
| 128 | |
| 129 | (defcustom imenu-after-jump-hook nil |
| 130 | "Hooks called after jumping to a place in the buffer. |
| 131 | |
| 132 | Useful things to use here include `reposition-window', `recenter', and |
| 133 | \(lambda () (recenter 0)) to show at top of screen." |
| 134 | :type 'hook |
| 135 | :group 'imenu) |
| 136 | |
| 137 | ;;;###autoload |
| 138 | (defcustom imenu-sort-function nil |
| 139 | "The function to use for sorting the index mouse-menu. |
| 140 | |
| 141 | Affects only the mouse index menu. |
| 142 | |
| 143 | Set this to nil if you don't want any sorting (faster). |
| 144 | The items in the menu are then presented in the order they were found |
| 145 | in the buffer. |
| 146 | |
| 147 | Set it to `imenu--sort-by-name' if you want alphabetic sorting. |
| 148 | |
| 149 | The function should take two arguments and return t if the first |
| 150 | element should come before the second. The arguments are cons cells; |
| 151 | \(NAME . POSITION). Look at `imenu--sort-by-name' for an example." |
| 152 | :type '(choice (const :tag "No sorting" nil) |
| 153 | (const :tag "Sort by name" imenu--sort-by-name) |
| 154 | (function :tag "Another function")) |
| 155 | :group 'imenu) |
| 156 | |
| 157 | (defcustom imenu-max-items 25 |
| 158 | "Maximum number of elements in a mouse menu for Imenu." |
| 159 | :type 'integer |
| 160 | :group 'imenu) |
| 161 | |
| 162 | ;; No longer used. KFS 2004-10-27 |
| 163 | ;; (defcustom imenu-scanning-message "Scanning buffer for index (%3d%%)" |
| 164 | ;; "Progress message during the index scanning of the buffer. |
| 165 | ;; If non-nil, user gets a message during the scanning of the buffer. |
| 166 | ;; |
| 167 | ;; Relevant only if the mode-specific function that creates the buffer |
| 168 | ;; index use `imenu-progress-message', and not useful if that is fast, in |
| 169 | ;; which case you might as well set this to nil." |
| 170 | ;; :type '(choice string |
| 171 | ;; (const :tag "None" nil)) |
| 172 | ;; :group 'imenu) |
| 173 | |
| 174 | (defcustom imenu-space-replacement "." |
| 175 | "The replacement string for spaces in index names. |
| 176 | Used when presenting the index in a completion buffer to make the |
| 177 | names work as tokens." |
| 178 | :type '(choice string (const nil)) |
| 179 | :group 'imenu) |
| 180 | |
| 181 | (defcustom imenu-level-separator ":" |
| 182 | "The separator between index names of different levels. |
| 183 | Used for making mouse-menu titles and for flattening nested indexes |
| 184 | with name concatenation." |
| 185 | :type 'string |
| 186 | :group 'imenu) |
| 187 | |
| 188 | ;;;###autoload |
| 189 | (defvar imenu-generic-expression nil |
| 190 | "List of definition matchers for creating an Imenu index. |
| 191 | Each element of this list should have the form |
| 192 | |
| 193 | (MENU-TITLE REGEXP INDEX [FUNCTION] [ARGUMENTS...]) |
| 194 | |
| 195 | MENU-TITLE should be nil (in which case the matches for this |
| 196 | element are put in the top level of the buffer index) or a |
| 197 | string (which specifies the title of a submenu into which the |
| 198 | matches are put). |
| 199 | REGEXP is a regular expression matching a definition construct |
| 200 | which is to be displayed in the menu. REGEXP may also be a |
| 201 | function, called without arguments. It is expected to search |
| 202 | backwards. It must return true and set `match-data' if it finds |
| 203 | another element. |
| 204 | INDEX is an integer specifying which subexpression of REGEXP |
| 205 | matches the definition's name; this subexpression is displayed as |
| 206 | the menu item. |
| 207 | FUNCTION, if present, specifies a function to call when the index |
| 208 | item is selected by the user. This function is called with |
| 209 | arguments consisting of the item name, the buffer position, and |
| 210 | the ARGUMENTS. |
| 211 | |
| 212 | The variable `imenu-case-fold-search' determines whether or not |
| 213 | the regexp matches are case sensitive, and `imenu-syntax-alist' |
| 214 | can be used to alter the syntax table for the search. |
| 215 | |
| 216 | If non-nil this pattern is passed to `imenu--generic-function' to |
| 217 | create a buffer index. |
| 218 | |
| 219 | For example, see the value of `fortran-imenu-generic-expression' |
| 220 | used by `fortran-mode' with `imenu-syntax-alist' set locally to |
| 221 | give the characters which normally have \"symbol\" syntax |
| 222 | \"word\" syntax during matching.") |
| 223 | ;;;###autoload(put 'imenu-generic-expression 'risky-local-variable t) |
| 224 | |
| 225 | ;;;###autoload |
| 226 | (make-variable-buffer-local 'imenu-generic-expression) |
| 227 | |
| 228 | ;;;; Hooks |
| 229 | |
| 230 | ;;;###autoload |
| 231 | (defvar imenu-create-index-function 'imenu-default-create-index-function |
| 232 | "The function to use for creating an index alist of the current buffer. |
| 233 | |
| 234 | It should be a function that takes no arguments and returns |
| 235 | an index alist of the current buffer. The function is |
| 236 | called within a `save-excursion'. |
| 237 | |
| 238 | See `imenu--index-alist' for the format of the buffer index alist.") |
| 239 | ;;;###autoload |
| 240 | (make-variable-buffer-local 'imenu-create-index-function) |
| 241 | |
| 242 | ;;;###autoload |
| 243 | (defvar imenu-prev-index-position-function 'beginning-of-defun |
| 244 | "Function for finding the next index position. |
| 245 | |
| 246 | If `imenu-create-index-function' is set to |
| 247 | `imenu-default-create-index-function', then you must set this variable |
| 248 | to a function that will find the next index, looking backwards in the |
| 249 | file. |
| 250 | |
| 251 | The function should leave point at the place to be connected to the |
| 252 | index and it should return nil when it doesn't find another index.") |
| 253 | ;;;###autoload |
| 254 | (make-variable-buffer-local 'imenu-prev-index-position-function) |
| 255 | |
| 256 | ;;;###autoload |
| 257 | (defvar imenu-extract-index-name-function nil |
| 258 | "Function for extracting the index item name, given a position. |
| 259 | |
| 260 | This function is called after `imenu-prev-index-position-function' |
| 261 | finds a position for an index item, with point at that position. |
| 262 | It should return the name for that index item.") |
| 263 | ;;;###autoload |
| 264 | (make-variable-buffer-local 'imenu-extract-index-name-function) |
| 265 | |
| 266 | ;;;###autoload |
| 267 | (defvar imenu-name-lookup-function nil |
| 268 | "Function to compare string with index item. |
| 269 | |
| 270 | This function will be called with two strings, and should return |
| 271 | non-nil if they match. |
| 272 | |
| 273 | If nil, comparison is done with `string='. |
| 274 | Set this to some other function for more advanced comparisons, |
| 275 | such as \"begins with\" or \"name matches and number of |
| 276 | arguments match\".") |
| 277 | ;;;###autoload |
| 278 | (make-variable-buffer-local 'imenu-name-lookup-function) |
| 279 | |
| 280 | ;;;###autoload |
| 281 | (defvar imenu-default-goto-function 'imenu-default-goto-function |
| 282 | "The default function called when selecting an Imenu item. |
| 283 | The function in this variable is called when selecting a normal index-item.") |
| 284 | ;;;###autoload |
| 285 | (make-variable-buffer-local 'imenu-default-goto-function) |
| 286 | |
| 287 | |
| 288 | (defun imenu--subalist-p (item) |
| 289 | (and (consp (cdr item)) (listp (cadr item)) |
| 290 | (not (eq (car (cadr item)) 'lambda)))) |
| 291 | |
| 292 | (defmacro imenu-progress-message (_prevpos &optional _relpos _reverse) |
| 293 | "Macro to display a progress message. |
| 294 | RELPOS is the relative position to display. |
| 295 | If RELPOS is nil, then the relative position in the buffer |
| 296 | is calculated. |
| 297 | PREVPOS is the variable in which we store the last position displayed." |
| 298 | |
| 299 | ;; Made obsolete/empty, as computers are now faster than the eye, and |
| 300 | ;; it had problems updating the messages correctly, and could shadow |
| 301 | ;; more important messages/prompts in the minibuffer. KFS 2004-10-27. |
| 302 | |
| 303 | ;; `(and |
| 304 | ;; imenu-scanning-message |
| 305 | ;; (let ((pos ,(if relpos |
| 306 | ;; relpos |
| 307 | ;; `(imenu--relative-position ,reverse)))) |
| 308 | ;; (if ,(if relpos t |
| 309 | ;; `(> pos (+ 5 ,prevpos))) |
| 310 | ;; (progn |
| 311 | ;; (message imenu-scanning-message pos) |
| 312 | ;; (setq ,prevpos pos))))) |
| 313 | ) |
| 314 | |
| 315 | |
| 316 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 317 | ;;;; |
| 318 | ;;;; Some examples of functions utilizing the framework of this |
| 319 | ;;;; package. |
| 320 | ;;;; |
| 321 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 322 | |
| 323 | ;; FIXME: This was the only imenu-example-* definition actually used, |
| 324 | ;; by cperl-mode.el. Now cperl-mode has its own copy, so these can |
| 325 | ;; all be removed. |
| 326 | (defun imenu-example--name-and-position () |
| 327 | "Return the current/previous sexp and its (beginning) location. |
| 328 | Don't move point." |
| 329 | (declare (obsolete "use your own function instead." "23.2")) |
| 330 | (save-excursion |
| 331 | (forward-sexp -1) |
| 332 | ;; [ydi] modified for imenu-use-markers |
| 333 | (let ((beg (if imenu-use-markers (point-marker) (point))) |
| 334 | (end (progn (forward-sexp) (point)))) |
| 335 | (cons (buffer-substring beg end) |
| 336 | beg)))) |
| 337 | |
| 338 | ;;; |
| 339 | ;;; Lisp |
| 340 | ;;; |
| 341 | |
| 342 | (defun imenu-example--lisp-extract-index-name () |
| 343 | ;; Example of a candidate for `imenu-extract-index-name-function'. |
| 344 | ;; This will generate a flat index of definitions in a lisp file. |
| 345 | (declare (obsolete nil "23.2")) |
| 346 | (save-match-data |
| 347 | (and (looking-at "(def") |
| 348 | (condition-case nil |
| 349 | (progn |
| 350 | (down-list 1) |
| 351 | (forward-sexp 2) |
| 352 | (let ((beg (point)) |
| 353 | (end (progn (forward-sexp -1) (point)))) |
| 354 | (buffer-substring beg end))) |
| 355 | (error nil))))) |
| 356 | |
| 357 | (defun imenu-example--create-lisp-index () |
| 358 | ;; Example of a candidate for `imenu-create-index-function'. |
| 359 | ;; It will generate a nested index of definitions. |
| 360 | (declare (obsolete nil "23.2")) |
| 361 | (let ((index-alist '()) |
| 362 | (index-var-alist '()) |
| 363 | (index-type-alist '()) |
| 364 | (index-unknown-alist '())) |
| 365 | (goto-char (point-max)) |
| 366 | ;; Search for the function |
| 367 | (while (beginning-of-defun) |
| 368 | (save-match-data |
| 369 | (and (looking-at "(def") |
| 370 | (save-excursion |
| 371 | (down-list 1) |
| 372 | (cond |
| 373 | ((looking-at "def\\(var\\|const\\)") |
| 374 | (forward-sexp 2) |
| 375 | (push (imenu-example--name-and-position) |
| 376 | index-var-alist)) |
| 377 | ((looking-at "def\\(un\\|subst\\|macro\\|advice\\)") |
| 378 | (forward-sexp 2) |
| 379 | (push (imenu-example--name-and-position) |
| 380 | index-alist)) |
| 381 | ((looking-at "def\\(type\\|struct\\|class\\|ine-condition\\)") |
| 382 | (forward-sexp 2) |
| 383 | (if (= (char-after (1- (point))) ?\)) |
| 384 | (progn |
| 385 | (forward-sexp -1) |
| 386 | (down-list 1) |
| 387 | (forward-sexp 1))) |
| 388 | (push (imenu-example--name-and-position) |
| 389 | index-type-alist)) |
| 390 | (t |
| 391 | (forward-sexp 2) |
| 392 | (push (imenu-example--name-and-position) |
| 393 | index-unknown-alist))))))) |
| 394 | (and index-var-alist |
| 395 | (push (cons "Variables" index-var-alist) |
| 396 | index-alist)) |
| 397 | (and index-type-alist |
| 398 | (push (cons "Types" index-type-alist) |
| 399 | index-alist)) |
| 400 | (and index-unknown-alist |
| 401 | (push (cons "Syntax-unknown" index-unknown-alist) |
| 402 | index-alist)) |
| 403 | index-alist)) |
| 404 | |
| 405 | ;; Regular expression to find C functions |
| 406 | (defvar imenu-example--function-name-regexp-c |
| 407 | (concat |
| 408 | "^[a-zA-Z0-9]+[ \t]?" ; type specs; there can be no |
| 409 | "\\([a-zA-Z0-9_*]+[ \t]+\\)?" ; more than 3 tokens, right? |
| 410 | "\\([a-zA-Z0-9_*]+[ \t]+\\)?" |
| 411 | "\\([*&]+[ \t]*\\)?" ; pointer |
| 412 | "\\([a-zA-Z0-9_*]+\\)[ \t]*(" ; name |
| 413 | )) |
| 414 | |
| 415 | (defun imenu-example--create-c-index (&optional regexp) |
| 416 | (declare (obsolete nil "23.2")) |
| 417 | (let ((index-alist '()) |
| 418 | char) |
| 419 | (goto-char (point-min)) |
| 420 | ;; Search for the function |
| 421 | (save-match-data |
| 422 | (while (re-search-forward |
| 423 | (or regexp imenu-example--function-name-regexp-c) |
| 424 | nil t) |
| 425 | (backward-up-list 1) |
| 426 | (save-excursion |
| 427 | (goto-char (scan-sexps (point) 1)) |
| 428 | (setq char (following-char))) |
| 429 | ;; Skip this function name if it is a prototype declaration. |
| 430 | (if (not (eq char ?\;)) |
| 431 | (push (imenu-example--name-and-position) index-alist)))) |
| 432 | (nreverse index-alist))) |
| 433 | |
| 434 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 435 | ;;; |
| 436 | ;;; Internal variables |
| 437 | ;;; |
| 438 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 439 | |
| 440 | ;; The item to use in the index for rescanning the buffer. |
| 441 | (defconst imenu--rescan-item '("*Rescan*" . -99)) |
| 442 | |
| 443 | ;; The latest buffer index. |
| 444 | (defvar-local imenu--index-alist nil |
| 445 | "The buffer index alist computed for this buffer in Imenu. |
| 446 | |
| 447 | Simple elements in the alist look like (INDEX-NAME . POSITION). |
| 448 | POSITION is the buffer position of the item; to go to the item |
| 449 | is simply to move point to that position. |
| 450 | |
| 451 | Special elements look like (INDEX-NAME POSITION FUNCTION ARGUMENTS...). |
| 452 | To \"go to\" a special element means applying FUNCTION |
| 453 | to INDEX-NAME, POSITION, and the ARGUMENTS. |
| 454 | |
| 455 | A nested sub-alist element looks like (INDEX-NAME SUB-ALIST). |
| 456 | The function `imenu--subalist-p' tests an element and returns t |
| 457 | if it is a sub-alist. |
| 458 | |
| 459 | There is one simple element with negative POSITION; selecting that |
| 460 | element recalculates the buffer's index alist.") |
| 461 | ;;;###autoload(put 'imenu--index-alist 'risky-local-variable t) |
| 462 | |
| 463 | (defvar-local imenu--last-menubar-index-alist nil |
| 464 | "The latest buffer index alist used to update the menu bar menu.") |
| 465 | |
| 466 | (defvar imenu--history-list nil |
| 467 | ;; Making this buffer local caused it not to work! |
| 468 | "History list for 'jump-to-function-in-buffer'.") |
| 469 | |
| 470 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 471 | ;;; |
| 472 | ;;; Internal support functions |
| 473 | ;;; |
| 474 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 475 | |
| 476 | (defun imenu--sort-by-name (item1 item2) |
| 477 | "Comparison function to sort items depending on their index name. |
| 478 | An item looks like (NAME . POSITION)." |
| 479 | (string-lessp (car item1) (car item2))) |
| 480 | |
| 481 | (defun imenu--sort-by-position (item1 item2) |
| 482 | (< (cdr item1) (cdr item2))) |
| 483 | |
| 484 | (defun imenu--relative-position (&optional reverse) |
| 485 | "Support function to calculate relative position in buffer. |
| 486 | Beginning of buffer is 0 and end of buffer is 100 |
| 487 | If REVERSE is non-nil then the beginning is 100 and the end is 0." |
| 488 | (let ((pos (point)) |
| 489 | (total (buffer-size))) |
| 490 | (and reverse (setq pos (- total pos))) |
| 491 | (if (> total 50000) |
| 492 | ;; Avoid overflow from multiplying by 100! |
| 493 | (/ (1- pos) (max (/ total 100) 1)) |
| 494 | (/ (* 100 (1- pos)) (max total 1))))) |
| 495 | |
| 496 | (defun imenu--split (list n) |
| 497 | "Split LIST into sublists of max length N. |
| 498 | Example (imenu--split '(1 2 3 4 5 6 7 8) 3)-> '((1 2 3) (4 5 6) (7 8)) |
| 499 | The returned list DOES NOT share structure with LIST." |
| 500 | (let ((remain list) |
| 501 | (result '()) |
| 502 | (sublist '()) |
| 503 | (i 0)) |
| 504 | (while remain |
| 505 | (push (pop remain) sublist) |
| 506 | (cl-incf i) |
| 507 | (and (= i n) |
| 508 | ;; We have finished a sublist |
| 509 | (progn (push (nreverse sublist) result) |
| 510 | (setq i 0) |
| 511 | (setq sublist '())))) |
| 512 | ;; There might be a sublist (if the length of LIST mod n is != 0) |
| 513 | ;; that has to be added to the result list. |
| 514 | (and sublist |
| 515 | (push (nreverse sublist) result)) |
| 516 | (nreverse result))) |
| 517 | |
| 518 | (defun imenu--split-menu (menulist title) |
| 519 | "Split the alist MENULIST into a nested alist, if it is long enough. |
| 520 | In any case, add TITLE to the front of the alist. |
| 521 | If IMENU--RESCAN-ITEM is present in MENULIST, it is moved to the |
| 522 | beginning of the returned alist. |
| 523 | The returned alist DOES NOT share structure with MENULIST." |
| 524 | (let ((menulist (copy-sequence menulist)) |
| 525 | keep-at-top) |
| 526 | (if (memq imenu--rescan-item menulist) |
| 527 | (setq keep-at-top (list imenu--rescan-item) |
| 528 | menulist (delq imenu--rescan-item menulist))) |
| 529 | (dolist (item menulist) |
| 530 | (when (imenu--subalist-p item) |
| 531 | (push item keep-at-top) |
| 532 | (setq menulist (delq item menulist)))) |
| 533 | (if imenu-sort-function |
| 534 | (setq menulist (sort menulist imenu-sort-function))) |
| 535 | (if (> (length menulist) imenu-max-items) |
| 536 | (setq menulist |
| 537 | (mapcar |
| 538 | (lambda (menu) |
| 539 | (cons (format "From: %s" (caar menu)) menu)) |
| 540 | (imenu--split menulist imenu-max-items)))) |
| 541 | (cons title |
| 542 | (nconc (nreverse keep-at-top) menulist)))) |
| 543 | |
| 544 | (defun imenu--split-submenus (alist) |
| 545 | "Split up each long alist that are nested within ALIST into nested alists. |
| 546 | Return a split and sorted copy of ALIST. The returned alist DOES |
| 547 | NOT share structure with ALIST." |
| 548 | (mapcar (lambda (elt) |
| 549 | (if (imenu--subalist-p elt) |
| 550 | (imenu--split-menu (cdr elt) (car elt)) |
| 551 | elt)) |
| 552 | alist)) |
| 553 | |
| 554 | (defun imenu--truncate-items (menulist) |
| 555 | "Truncate all strings in MENULIST to `imenu-max-item-length'." |
| 556 | (mapcar (lambda (item) |
| 557 | (cond |
| 558 | ((consp (cdr item)) |
| 559 | (imenu--truncate-items (cdr item))) |
| 560 | ;; truncate if necessary |
| 561 | ((and (numberp imenu-max-item-length) |
| 562 | (> (length (car item)) imenu-max-item-length)) |
| 563 | (setcar item (substring (car item) 0 imenu-max-item-length))))) |
| 564 | menulist)) |
| 565 | |
| 566 | |
| 567 | (defun imenu--make-index-alist (&optional noerror) |
| 568 | "Create an index alist for the definitions in the current buffer. |
| 569 | This works by using the hook function `imenu-create-index-function'. |
| 570 | Report an error if the list is empty unless NOERROR is supplied and |
| 571 | non-nil. |
| 572 | |
| 573 | See `imenu--index-alist' for the format of the index alist." |
| 574 | (or (and imenu--index-alist |
| 575 | (or (not imenu-auto-rescan) |
| 576 | (and imenu-auto-rescan |
| 577 | (> (buffer-size) imenu-auto-rescan-maxout)))) |
| 578 | ;; Get the index; truncate if necessary |
| 579 | (progn |
| 580 | (setq imenu--index-alist |
| 581 | (save-excursion |
| 582 | (save-restriction |
| 583 | (widen) |
| 584 | (funcall imenu-create-index-function)))) |
| 585 | (imenu--truncate-items imenu--index-alist))) |
| 586 | (or imenu--index-alist noerror |
| 587 | (user-error "No items suitable for an index found in this buffer")) |
| 588 | (or imenu--index-alist |
| 589 | (setq imenu--index-alist (list nil))) |
| 590 | ;; Add a rescan option to the index. |
| 591 | (cons imenu--rescan-item imenu--index-alist)) |
| 592 | |
| 593 | (defvar imenu--cleanup-seen nil) |
| 594 | |
| 595 | (defun imenu--cleanup (&optional alist) |
| 596 | "Find all markers in ALIST and make them point nowhere. |
| 597 | If ALIST is nil (the normal case), use `imenu--index-alist'. |
| 598 | Non-nil arguments are in recursive calls." |
| 599 | ;; If alist is provided use that list. |
| 600 | ;; If not, empty the table of lists already seen |
| 601 | ;; and use imenu--index-alist. |
| 602 | (if alist |
| 603 | (setq imenu--cleanup-seen (cons alist imenu--cleanup-seen)) |
| 604 | (setq alist imenu--index-alist imenu--cleanup-seen (list alist))) |
| 605 | |
| 606 | (when alist |
| 607 | (dolist (item alist) |
| 608 | (cond |
| 609 | ((markerp (cdr item)) (set-marker (cdr item) nil)) |
| 610 | ;; Don't process one alist twice. |
| 611 | ((memq (cdr item) imenu--cleanup-seen)) |
| 612 | ((imenu--subalist-p item) (imenu--cleanup (cdr item))))) |
| 613 | t)) |
| 614 | |
| 615 | (defun imenu--create-keymap (title alist &optional cmd) |
| 616 | `(keymap ,title |
| 617 | ,@(mapcar |
| 618 | (lambda (item) |
| 619 | `(,(car item) ,(car item) |
| 620 | ,@(cond |
| 621 | ((imenu--subalist-p item) |
| 622 | (imenu--create-keymap (car item) (cdr item) cmd)) |
| 623 | (t |
| 624 | `(lambda () (interactive) |
| 625 | ,(if cmd `(,cmd ',item) (list 'quote item))))))) |
| 626 | alist))) |
| 627 | |
| 628 | (defun imenu--in-alist (str alist) |
| 629 | "Check whether the string STR is contained in multi-level ALIST." |
| 630 | (let (elt head tail res) |
| 631 | (setq res nil) |
| 632 | (while alist |
| 633 | (setq elt (car alist) |
| 634 | tail (cdr elt) |
| 635 | alist (cdr alist) |
| 636 | head (car elt)) |
| 637 | ;; A nested ALIST element looks like |
| 638 | ;; (INDEX-NAME (INDEX-NAME . INDEX-POSITION) ...) |
| 639 | ;; while a bottom-level element looks like |
| 640 | ;; (INDEX-NAME . INDEX-POSITION) |
| 641 | ;; We are only interested in the bottom-level elements, so we need to |
| 642 | ;; recurse if TAIL is a list. |
| 643 | (cond ((listp tail) |
| 644 | (if (setq res (imenu--in-alist str tail)) |
| 645 | (setq alist nil))) |
| 646 | ((if imenu-name-lookup-function |
| 647 | (funcall imenu-name-lookup-function str head) |
| 648 | (string= str head)) |
| 649 | (setq alist nil res elt)))) |
| 650 | res)) |
| 651 | |
| 652 | (defvar imenu-syntax-alist nil |
| 653 | "Alist of syntax table modifiers to use while in `imenu--generic-function'. |
| 654 | |
| 655 | The car of the assocs may be either a character or a string and the |
| 656 | cdr is a syntax description appropriate for `modify-syntax-entry'. For |
| 657 | a string, all the characters in the string get the specified syntax. |
| 658 | |
| 659 | This is typically used to give word syntax to characters which |
| 660 | normally have symbol syntax to simplify `imenu-expression' |
| 661 | and speed-up matching.") |
| 662 | ;;;###autoload |
| 663 | (make-variable-buffer-local 'imenu-syntax-alist) |
| 664 | |
| 665 | (defun imenu-default-create-index-function () |
| 666 | "Default function to create an index alist of the current buffer. |
| 667 | |
| 668 | The most general method is to move point to end of buffer, then repeatedly call |
| 669 | `imenu-prev-index-position-function' and `imenu-extract-index-name-function'. |
| 670 | All the results returned by the latter are gathered into an index alist. |
| 671 | This method is used if those two variables are non-nil. |
| 672 | |
| 673 | The alternate method, which is the one most often used, is to call |
| 674 | `imenu--generic-function' with `imenu-generic-expression' as argument." |
| 675 | ;; These should really be done by setting imenu-create-index-function |
| 676 | ;; in these major modes. But save that change for later. |
| 677 | (cond ((and imenu-prev-index-position-function |
| 678 | imenu-extract-index-name-function) |
| 679 | (let ((index-alist '()) (pos (point)) |
| 680 | name) |
| 681 | (goto-char (point-max)) |
| 682 | ;; Search for the function |
| 683 | (while (funcall imenu-prev-index-position-function) |
| 684 | (when (= pos (point)) |
| 685 | (error "Infinite loop at %s:%d: imenu-prev-index-position-function does not move point" (buffer-name) pos)) |
| 686 | (setq pos (point)) |
| 687 | (save-excursion |
| 688 | (setq name (funcall imenu-extract-index-name-function))) |
| 689 | (and (stringp name) |
| 690 | ;; [ydi] updated for imenu-use-markers |
| 691 | (push (cons name (if imenu-use-markers (point-marker) (point))) |
| 692 | index-alist))) |
| 693 | index-alist)) |
| 694 | ;; Use generic expression if possible. |
| 695 | ((and imenu-generic-expression) |
| 696 | (imenu--generic-function imenu-generic-expression)) |
| 697 | (t |
| 698 | (user-error "This buffer cannot use `imenu-default-create-index-function'")))) |
| 699 | |
| 700 | ;;; |
| 701 | ;;; Generic index gathering function. |
| 702 | ;;; |
| 703 | |
| 704 | (defvar imenu-case-fold-search t |
| 705 | "Defines whether `imenu--generic-function' should fold case when matching. |
| 706 | |
| 707 | This variable should be set (only) by initialization code |
| 708 | for modes which use `imenu--generic-function'. If it is not set, but |
| 709 | `font-lock-defaults' is set, then font-lock's setting is used.") |
| 710 | ;;;###autoload |
| 711 | (make-variable-buffer-local 'imenu-case-fold-search) |
| 712 | |
| 713 | ;; This function can be called with quitting disabled, |
| 714 | ;; so it needs to be careful never to loop! |
| 715 | (defun imenu--generic-function (patterns) |
| 716 | "Return an index alist of the current buffer based on PATTERNS. |
| 717 | PATTERNS should be an alist which has the same form as |
| 718 | `imenu-generic-expression'. |
| 719 | |
| 720 | The return value is an alist of the form |
| 721 | (INDEX-NAME . INDEX-POSITION) |
| 722 | or |
| 723 | (INDEX-NAME INDEX-POSITION FUNCTION ARGUMENTS...) |
| 724 | The return value may also consist of nested index alists like: |
| 725 | (INDEX-NAME . INDEX-ALIST) |
| 726 | depending on PATTERNS." |
| 727 | (let ((index-alist (list 'dummy)) |
| 728 | (case-fold-search (if (or (local-variable-p 'imenu-case-fold-search) |
| 729 | (not (local-variable-p 'font-lock-defaults))) |
| 730 | imenu-case-fold-search |
| 731 | (nth 2 font-lock-defaults))) |
| 732 | (old-table (syntax-table)) |
| 733 | (table (copy-syntax-table (syntax-table))) |
| 734 | (slist imenu-syntax-alist)) |
| 735 | ;; Modify the syntax table used while matching regexps. |
| 736 | (dolist (syn slist) |
| 737 | ;; The character(s) to modify may be a single char or a string. |
| 738 | (if (numberp (car syn)) |
| 739 | (modify-syntax-entry (car syn) (cdr syn) table) |
| 740 | (mapc (lambda (c) |
| 741 | (modify-syntax-entry c (cdr syn) table)) |
| 742 | (car syn)))) |
| 743 | (goto-char (point-max)) |
| 744 | (unwind-protect ; for syntax table |
| 745 | (save-match-data |
| 746 | (set-syntax-table table) |
| 747 | |
| 748 | ;; map over the elements of imenu-generic-expression |
| 749 | ;; (typically functions, variables ...) |
| 750 | (dolist (pat patterns) |
| 751 | (let ((menu-title (car pat)) |
| 752 | (regexp (nth 1 pat)) |
| 753 | (index (nth 2 pat)) |
| 754 | (function (nth 3 pat)) |
| 755 | (rest (nthcdr 4 pat)) |
| 756 | start beg) |
| 757 | ;; Go backwards for convenience of adding items in order. |
| 758 | (goto-char (point-max)) |
| 759 | (while (and (if (functionp regexp) |
| 760 | (funcall regexp) |
| 761 | (and |
| 762 | (re-search-backward regexp nil t) |
| 763 | ;; Do not count invisible definitions. |
| 764 | (let ((invis (invisible-p (point)))) |
| 765 | (or (not invis) |
| 766 | (progn |
| 767 | (while (and invis |
| 768 | (not (bobp))) |
| 769 | (setq invis (not (re-search-backward |
| 770 | regexp nil 'move)))) |
| 771 | (not invis)))))) |
| 772 | ;; Exit the loop if we get an empty match, |
| 773 | ;; because it means a bad regexp was specified. |
| 774 | (not (= (match-beginning 0) (match-end 0)))) |
| 775 | (setq start (point)) |
| 776 | ;; Record the start of the line in which the match starts. |
| 777 | ;; That's the official position of this definition. |
| 778 | (goto-char (match-beginning index)) |
| 779 | (beginning-of-line) |
| 780 | (setq beg (point)) |
| 781 | ;; Add this sort of submenu only when we've found an |
| 782 | ;; item for it, avoiding empty, duff menus. |
| 783 | (unless (assoc menu-title index-alist) |
| 784 | (push (list menu-title) index-alist)) |
| 785 | (if imenu-use-markers |
| 786 | (setq beg (copy-marker beg))) |
| 787 | (let ((item |
| 788 | (if function |
| 789 | (nconc (list (match-string-no-properties index) |
| 790 | beg function) |
| 791 | rest) |
| 792 | (cons (match-string-no-properties index) |
| 793 | beg))) |
| 794 | ;; This is the desired submenu, |
| 795 | ;; starting with its title (or nil). |
| 796 | (menu (assoc menu-title index-alist))) |
| 797 | ;; Insert the item unless it is already present. |
| 798 | (unless (member item (cdr menu)) |
| 799 | (setcdr menu |
| 800 | (cons item (cdr menu))))) |
| 801 | ;; Go to the start of the match, to make sure we |
| 802 | ;; keep making progress backwards. |
| 803 | (goto-char start)))) |
| 804 | (set-syntax-table old-table))) |
| 805 | ;; Sort each submenu by position. |
| 806 | ;; This is in case one submenu gets items from two different regexps. |
| 807 | (dolist (item index-alist) |
| 808 | (when (listp item) |
| 809 | (setcdr item (sort (cdr item) 'imenu--sort-by-position)))) |
| 810 | (let ((main-element (assq nil index-alist))) |
| 811 | (nconc (delq main-element (delq 'dummy index-alist)) |
| 812 | (cdr main-element))))) |
| 813 | |
| 814 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 815 | ;;; |
| 816 | ;;; The main functions for this package! |
| 817 | ;;; |
| 818 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 819 | |
| 820 | ;; See also info-lookup-find-item |
| 821 | (defun imenu-find-default (guess completions) |
| 822 | "Fuzzily find an item based on GUESS inside the alist COMPLETIONS." |
| 823 | (catch 'found |
| 824 | (let ((case-fold-search t)) |
| 825 | (if (assoc guess completions) guess |
| 826 | (dolist (re (list (concat "\\`" (regexp-quote guess) "\\'") |
| 827 | (concat "\\`" (regexp-quote guess)) |
| 828 | (concat (regexp-quote guess) "\\'") |
| 829 | (regexp-quote guess))) |
| 830 | (dolist (x completions) |
| 831 | (if (string-match re (car x)) (throw 'found (car x))))))))) |
| 832 | |
| 833 | (defun imenu--completion-buffer (index-alist &optional prompt) |
| 834 | "Let the user select from INDEX-ALIST in a completion buffer with PROMPT. |
| 835 | |
| 836 | Return one of the entries in index-alist or nil." |
| 837 | ;; Create a list for this buffer only when needed. |
| 838 | (let ((name (thing-at-point 'symbol)) |
| 839 | choice |
| 840 | (prepared-index-alist |
| 841 | (if (not imenu-space-replacement) index-alist |
| 842 | (mapcar |
| 843 | (lambda (item) |
| 844 | (cons (subst-char-in-string ?\s (aref imenu-space-replacement 0) |
| 845 | (car item)) |
| 846 | (cdr item))) |
| 847 | index-alist)))) |
| 848 | (when (stringp name) |
| 849 | (setq name (or (imenu-find-default name prepared-index-alist) name))) |
| 850 | (cond (prompt) |
| 851 | ((and name (imenu--in-alist name prepared-index-alist)) |
| 852 | (setq prompt (format "Index item (default %s): " name))) |
| 853 | (t (setq prompt "Index item: "))) |
| 854 | (let ((minibuffer-setup-hook minibuffer-setup-hook)) |
| 855 | ;; Display the completion buffer. |
| 856 | (if (not imenu-eager-completion-buffer) |
| 857 | (add-hook 'minibuffer-setup-hook 'minibuffer-completion-help)) |
| 858 | (setq name (completing-read prompt |
| 859 | prepared-index-alist |
| 860 | nil t nil 'imenu--history-list name))) |
| 861 | |
| 862 | (when (stringp name) |
| 863 | (setq choice (assoc name prepared-index-alist)) |
| 864 | (if (imenu--subalist-p choice) |
| 865 | (imenu--completion-buffer (cdr choice) prompt) |
| 866 | choice)))) |
| 867 | |
| 868 | (defun imenu--mouse-menu (index-alist event &optional title) |
| 869 | "Let the user select from a buffer index from a mouse menu. |
| 870 | |
| 871 | INDEX-ALIST is the buffer index and EVENT is a mouse event. |
| 872 | |
| 873 | Returns t for rescan and otherwise an element or subelement of INDEX-ALIST." |
| 874 | (setq index-alist (imenu--split-submenus index-alist)) |
| 875 | (let* ((menu (imenu--split-menu index-alist (or title (buffer-name)))) |
| 876 | (map (imenu--create-keymap (car menu) |
| 877 | (cdr (if (< 1 (length (cdr menu))) |
| 878 | menu |
| 879 | (car (cdr menu))))))) |
| 880 | (popup-menu map event))) |
| 881 | |
| 882 | (defun imenu-choose-buffer-index (&optional prompt alist) |
| 883 | "Let the user select from a buffer index and return the chosen index. |
| 884 | |
| 885 | If the user originally activated this function with the mouse, a mouse |
| 886 | menu is used. Otherwise a completion buffer is used and the user is |
| 887 | prompted with PROMPT. |
| 888 | |
| 889 | If you call this function with index alist ALIST, then it lets the user |
| 890 | select from ALIST. |
| 891 | |
| 892 | With no index alist ALIST, it calls `imenu--make-index-alist' to |
| 893 | create the index alist. |
| 894 | |
| 895 | If `imenu-use-popup-menu' is nil, then the completion buffer |
| 896 | is always used, no matter if the mouse was used or not. |
| 897 | |
| 898 | The returned value is of the form (INDEX-NAME . INDEX-POSITION)." |
| 899 | (let (index-alist |
| 900 | (mouse-triggered (listp last-nonmenu-event)) |
| 901 | (result t)) |
| 902 | ;; If selected by mouse, see to that the window where the mouse is |
| 903 | ;; really is selected. |
| 904 | (and mouse-triggered |
| 905 | (not (equal last-nonmenu-event '(menu-bar))) |
| 906 | (let ((window (posn-window (event-start last-nonmenu-event)))) |
| 907 | (or (framep window) (null window) (select-window window)))) |
| 908 | ;; Create a list for this buffer only when needed. |
| 909 | (while (eq result t) |
| 910 | (setq index-alist (if alist alist (imenu--make-index-alist))) |
| 911 | (setq result |
| 912 | (if (and imenu-use-popup-menu |
| 913 | (or (eq imenu-use-popup-menu t) mouse-triggered)) |
| 914 | (imenu--mouse-menu index-alist last-nonmenu-event) |
| 915 | (imenu--completion-buffer index-alist prompt))) |
| 916 | (and (equal result imenu--rescan-item) |
| 917 | (imenu--cleanup) |
| 918 | (setq result t imenu--index-alist nil))) |
| 919 | result)) |
| 920 | |
| 921 | ;;;###autoload |
| 922 | (defun imenu-add-to-menubar (name) |
| 923 | "Add an `imenu' entry to the menu bar for the current buffer. |
| 924 | NAME is a string used to name the menu bar item. |
| 925 | See the command `imenu' for more information." |
| 926 | (interactive "sImenu menu item name: ") |
| 927 | (if (or (and imenu-prev-index-position-function |
| 928 | imenu-extract-index-name-function) |
| 929 | imenu-generic-expression |
| 930 | (not (eq imenu-create-index-function |
| 931 | 'imenu-default-create-index-function))) |
| 932 | (unless (and (current-local-map) |
| 933 | (keymapp (lookup-key (current-local-map) [menu-bar index]))) |
| 934 | (let ((newmap (make-sparse-keymap))) |
| 935 | (set-keymap-parent newmap (current-local-map)) |
| 936 | (setq imenu--last-menubar-index-alist nil) |
| 937 | (define-key newmap [menu-bar index] |
| 938 | `(menu-item ,name ,(make-sparse-keymap "Imenu"))) |
| 939 | (use-local-map newmap) |
| 940 | (add-hook 'menu-bar-update-hook 'imenu-update-menubar))) |
| 941 | (user-error "The mode `%s' does not support Imenu" |
| 942 | (format-mode-line mode-name)))) |
| 943 | |
| 944 | ;;;###autoload |
| 945 | (defun imenu-add-menubar-index () |
| 946 | "Add an Imenu \"Index\" entry on the menu bar for the current buffer. |
| 947 | |
| 948 | A trivial interface to `imenu-add-to-menubar' suitable for use in a hook." |
| 949 | (interactive) |
| 950 | (imenu-add-to-menubar "Index")) |
| 951 | |
| 952 | (defvar imenu-buffer-menubar nil) |
| 953 | |
| 954 | (defvar-local imenu-menubar-modified-tick 0 |
| 955 | "The value of (buffer-chars-modified-tick) as of the last call |
| 956 | to `imenu-update-menubar'.") |
| 957 | |
| 958 | (defun imenu-update-menubar () |
| 959 | (when (and (current-local-map) |
| 960 | (keymapp (lookup-key (current-local-map) [menu-bar index])) |
| 961 | (/= (buffer-chars-modified-tick) imenu-menubar-modified-tick)) |
| 962 | (setq imenu-menubar-modified-tick (buffer-chars-modified-tick)) |
| 963 | (let ((index-alist (imenu--make-index-alist t))) |
| 964 | ;; Don't bother updating if the index-alist has not changed |
| 965 | ;; since the last time we did it. |
| 966 | (unless (equal index-alist imenu--last-menubar-index-alist) |
| 967 | (let (menu menu1 old) |
| 968 | (setq imenu--last-menubar-index-alist index-alist) |
| 969 | (setq index-alist (imenu--split-submenus index-alist)) |
| 970 | (setq menu (imenu--split-menu index-alist |
| 971 | (buffer-name))) |
| 972 | (setq menu1 (imenu--create-keymap (car menu) |
| 973 | (cdr (if (< 1 (length (cdr menu))) |
| 974 | menu |
| 975 | (car (cdr menu)))) |
| 976 | 'imenu--menubar-select)) |
| 977 | (setq old (lookup-key (current-local-map) [menu-bar index])) |
| 978 | ;; This should never happen, but in some odd cases, potentially, |
| 979 | ;; lookup-key may return a dynamically composed keymap. |
| 980 | (if (keymapp (cadr old)) (setq old (cadr old))) |
| 981 | (setcdr old (cdr menu1))))))) |
| 982 | |
| 983 | (defun imenu--menubar-select (item) |
| 984 | "Use Imenu to select the function or variable named in this menu ITEM." |
| 985 | (if (equal item imenu--rescan-item) |
| 986 | (progn |
| 987 | (imenu--cleanup) |
| 988 | ;; Make sure imenu-update-menubar redoes everything. |
| 989 | (setq imenu-menubar-modified-tick -1) |
| 990 | (setq imenu--index-alist nil) |
| 991 | (setq imenu--last-menubar-index-alist nil) |
| 992 | (imenu-update-menubar) |
| 993 | t) |
| 994 | (imenu item) |
| 995 | nil)) |
| 996 | |
| 997 | (defun imenu-default-goto-function (_name position &optional _rest) |
| 998 | "Move to the given position. |
| 999 | |
| 1000 | NAME is ignored. POSITION is where to move. REST is also ignored. |
| 1001 | The ignored args just make this function have the same interface as a |
| 1002 | function placed in a special index-item." |
| 1003 | (if (or (< position (point-min)) |
| 1004 | (> position (point-max))) |
| 1005 | ;; widen if outside narrowing |
| 1006 | (widen)) |
| 1007 | (goto-char position)) |
| 1008 | |
| 1009 | ;;;###autoload |
| 1010 | (defun imenu (index-item) |
| 1011 | "Jump to a place in the buffer chosen using a buffer menu or mouse menu. |
| 1012 | INDEX-ITEM specifies the position. See `imenu-choose-buffer-index' |
| 1013 | for more information." |
| 1014 | (interactive (list (imenu-choose-buffer-index))) |
| 1015 | ;; Convert a string to an alist element. |
| 1016 | (if (stringp index-item) |
| 1017 | (setq index-item (assoc index-item (imenu--make-index-alist)))) |
| 1018 | (when index-item |
| 1019 | (push-mark nil t) |
| 1020 | (let* ((is-special-item (listp (cdr index-item))) |
| 1021 | (function |
| 1022 | (if is-special-item |
| 1023 | (nth 2 index-item) imenu-default-goto-function)) |
| 1024 | (position (if is-special-item |
| 1025 | (cadr index-item) (cdr index-item))) |
| 1026 | (rest (if is-special-item (cddr index-item)))) |
| 1027 | (apply function (car index-item) position rest)) |
| 1028 | (run-hooks 'imenu-after-jump-hook))) |
| 1029 | |
| 1030 | (provide 'imenu) |
| 1031 | |
| 1032 | ;;; imenu.el ends here |