| 1 | ;;; simple.el --- basic editing commands for Emacs |
| 2 | |
| 3 | ;; Copyright (C) 1985, 1986, 1987, 1993 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; This file is part of GNU Emacs. |
| 6 | |
| 7 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 8 | ;; it under the terms of the GNU General Public License as published by |
| 9 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 10 | ;; any later version. |
| 11 | |
| 12 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 13 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 14 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 15 | ;; GNU General Public License for more details. |
| 16 | |
| 17 | ;; You should have received a copy of the GNU General Public License |
| 18 | ;; along with GNU Emacs; see the file COPYING. If not, write to |
| 19 | ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA. |
| 20 | |
| 21 | ;;; Commentary: |
| 22 | |
| 23 | ;; A grab-bag of basic Emacs commands not specifically related to some |
| 24 | ;; major mode or to file-handling. |
| 25 | |
| 26 | ;;; Code: |
| 27 | |
| 28 | (defun open-line (arg) |
| 29 | "Insert a newline and leave point before it. |
| 30 | If there is a fill prefix, insert the fill prefix on the new line |
| 31 | if the line would have been empty. |
| 32 | With arg N, insert N newlines." |
| 33 | (interactive "*p") |
| 34 | (let* ((do-fill-prefix (and fill-prefix (bolp))) |
| 35 | (flag (and (null do-fill-prefix) (bolp) (not (bobp))))) |
| 36 | ;; If this is a simple case, and we are at the beginning of a line, |
| 37 | ;; actually insert the newline *before* the preceding newline |
| 38 | ;; instead of after. That makes better display behavior. |
| 39 | (if flag |
| 40 | (progn |
| 41 | ;; If undo is enabled, don't let this hack be visible: |
| 42 | ;; record the real value of point as the place to move back to |
| 43 | ;; if we undo this insert. |
| 44 | (if (and buffer-undo-list (not (eq buffer-undo-list t))) |
| 45 | (setq buffer-undo-list (cons (point) buffer-undo-list))) |
| 46 | (forward-char -1))) |
| 47 | (while (> arg 0) |
| 48 | (save-excursion |
| 49 | (insert ?\n)) |
| 50 | (if do-fill-prefix (insert fill-prefix)) |
| 51 | (setq arg (1- arg))) |
| 52 | (if flag (forward-char 1)))) |
| 53 | |
| 54 | (defun split-line () |
| 55 | "Split current line, moving portion beyond point vertically down." |
| 56 | (interactive "*") |
| 57 | (skip-chars-forward " \t") |
| 58 | (let ((col (current-column)) |
| 59 | (pos (point))) |
| 60 | (insert ?\n) |
| 61 | (indent-to col 0) |
| 62 | (goto-char pos))) |
| 63 | |
| 64 | (defun quoted-insert (arg) |
| 65 | "Read next input character and insert it. |
| 66 | This is useful for inserting control characters. |
| 67 | You may also type up to 3 octal digits, to insert a character with that code. |
| 68 | |
| 69 | In overwrite mode, this function inserts the character anyway, and |
| 70 | does not handle octal digits specially. This means that if you use |
| 71 | overwrite as your normal editing mode, you can use this function to |
| 72 | insert characters when necessary. |
| 73 | |
| 74 | In binary overwrite mode, this function does overwrite, and octal |
| 75 | digits are interpreted as a character code. This is supposed to make |
| 76 | this function useful in editing binary files." |
| 77 | (interactive "*p") |
| 78 | (let ((char (if (or (not overwrite-mode) |
| 79 | (eq overwrite-mode 'overwrite-mode-binary)) |
| 80 | (read-quoted-char) |
| 81 | (read-char)))) |
| 82 | (if (eq overwrite-mode 'overwrite-mode-binary) |
| 83 | (delete-char arg)) |
| 84 | (insert-char char arg))) |
| 85 | |
| 86 | (defun delete-indentation (&optional arg) |
| 87 | "Join this line to previous and fix up whitespace at join. |
| 88 | If there is a fill prefix, delete it from the beginning of this line. |
| 89 | With argument, join this line to following line." |
| 90 | (interactive "*P") |
| 91 | (beginning-of-line) |
| 92 | (if arg (forward-line 1)) |
| 93 | (if (eq (preceding-char) ?\n) |
| 94 | (progn |
| 95 | (delete-region (point) (1- (point))) |
| 96 | ;; If the second line started with the fill prefix, |
| 97 | ;; delete the prefix. |
| 98 | (if (and fill-prefix |
| 99 | (<= (+ (point) (length fill-prefix)) (point-max)) |
| 100 | (string= fill-prefix |
| 101 | (buffer-substring (point) |
| 102 | (+ (point) (length fill-prefix))))) |
| 103 | (delete-region (point) (+ (point) (length fill-prefix)))) |
| 104 | (fixup-whitespace)))) |
| 105 | |
| 106 | (defun fixup-whitespace () |
| 107 | "Fixup white space between objects around point. |
| 108 | Leave one space or none, according to the context." |
| 109 | (interactive "*") |
| 110 | (save-excursion |
| 111 | (delete-horizontal-space) |
| 112 | (if (or (looking-at "^\\|\\s)") |
| 113 | (save-excursion (forward-char -1) |
| 114 | (looking-at "$\\|\\s(\\|\\s'"))) |
| 115 | nil |
| 116 | (insert ?\ )))) |
| 117 | |
| 118 | (defun delete-horizontal-space () |
| 119 | "Delete all spaces and tabs around point." |
| 120 | (interactive "*") |
| 121 | (skip-chars-backward " \t") |
| 122 | (delete-region (point) (progn (skip-chars-forward " \t") (point)))) |
| 123 | |
| 124 | (defun just-one-space () |
| 125 | "Delete all spaces and tabs around point, leaving one space." |
| 126 | (interactive "*") |
| 127 | (skip-chars-backward " \t") |
| 128 | (if (= (following-char) ? ) |
| 129 | (forward-char 1) |
| 130 | (insert ? )) |
| 131 | (delete-region (point) (progn (skip-chars-forward " \t") (point)))) |
| 132 | |
| 133 | (defun delete-blank-lines () |
| 134 | "On blank line, delete all surrounding blank lines, leaving just one. |
| 135 | On isolated blank line, delete that one. |
| 136 | On nonblank line, delete all blank lines that follow it." |
| 137 | (interactive "*") |
| 138 | (let (thisblank singleblank) |
| 139 | (save-excursion |
| 140 | (beginning-of-line) |
| 141 | (setq thisblank (looking-at "[ \t]*$")) |
| 142 | ;; Set singleblank if there is just one blank line here. |
| 143 | (setq singleblank |
| 144 | (and thisblank |
| 145 | (not (looking-at "[ \t]*\n[ \t]*$")) |
| 146 | (or (bobp) |
| 147 | (progn (forward-line -1) |
| 148 | (not (looking-at "[ \t]*$"))))))) |
| 149 | ;; Delete preceding blank lines, and this one too if it's the only one. |
| 150 | (if thisblank |
| 151 | (progn |
| 152 | (beginning-of-line) |
| 153 | (if singleblank (forward-line 1)) |
| 154 | (delete-region (point) |
| 155 | (if (re-search-backward "[^ \t\n]" nil t) |
| 156 | (progn (forward-line 1) (point)) |
| 157 | (point-min))))) |
| 158 | ;; Delete following blank lines, unless the current line is blank |
| 159 | ;; and there are no following blank lines. |
| 160 | (if (not (and thisblank singleblank)) |
| 161 | (save-excursion |
| 162 | (end-of-line) |
| 163 | (forward-line 1) |
| 164 | (delete-region (point) |
| 165 | (if (re-search-forward "[^ \t\n]" nil t) |
| 166 | (progn (beginning-of-line) (point)) |
| 167 | (point-max))))) |
| 168 | ;; Handle the special case where point is followed by newline and eob. |
| 169 | ;; Delete the line, leaving point at eob. |
| 170 | (if (looking-at "^[ \t]*\n\\'") |
| 171 | (delete-region (point) (point-max))))) |
| 172 | |
| 173 | (defun back-to-indentation () |
| 174 | "Move point to the first non-whitespace character on this line." |
| 175 | (interactive) |
| 176 | (beginning-of-line 1) |
| 177 | (skip-chars-forward " \t")) |
| 178 | |
| 179 | (defun newline-and-indent () |
| 180 | "Insert a newline, then indent according to major mode. |
| 181 | Indentation is done using the value of `indent-line-function'. |
| 182 | In programming language modes, this is the same as TAB. |
| 183 | In some text modes, where TAB inserts a tab, this command indents to the |
| 184 | column specified by the variable `left-margin'." |
| 185 | (interactive "*") |
| 186 | (delete-region (point) (progn (skip-chars-backward " \t") (point))) |
| 187 | (newline) |
| 188 | (indent-according-to-mode)) |
| 189 | |
| 190 | (defun reindent-then-newline-and-indent () |
| 191 | "Reindent current line, insert newline, then indent the new line. |
| 192 | Indentation of both lines is done according to the current major mode, |
| 193 | which means calling the current value of `indent-line-function'. |
| 194 | In programming language modes, this is the same as TAB. |
| 195 | In some text modes, where TAB inserts a tab, this indents to the |
| 196 | column specified by the variable `left-margin'." |
| 197 | (interactive "*") |
| 198 | (save-excursion |
| 199 | (delete-region (point) (progn (skip-chars-backward " \t") (point))) |
| 200 | (indent-according-to-mode)) |
| 201 | (newline) |
| 202 | (indent-according-to-mode)) |
| 203 | |
| 204 | ;; Internal subroutine of delete-char |
| 205 | (defun kill-forward-chars (arg) |
| 206 | (if (listp arg) (setq arg (car arg))) |
| 207 | (if (eq arg '-) (setq arg -1)) |
| 208 | (kill-region (point) (+ (point) arg))) |
| 209 | |
| 210 | ;; Internal subroutine of backward-delete-char |
| 211 | (defun kill-backward-chars (arg) |
| 212 | (if (listp arg) (setq arg (car arg))) |
| 213 | (if (eq arg '-) (setq arg -1)) |
| 214 | (kill-region (point) (- (point) arg))) |
| 215 | |
| 216 | (defun backward-delete-char-untabify (arg &optional killp) |
| 217 | "Delete characters backward, changing tabs into spaces. |
| 218 | Delete ARG chars, and kill (save in kill ring) if KILLP is non-nil. |
| 219 | Interactively, ARG is the prefix arg (default 1) |
| 220 | and KILLP is t if prefix arg is was specified." |
| 221 | (interactive "*p\nP") |
| 222 | (let ((count arg)) |
| 223 | (save-excursion |
| 224 | (while (and (> count 0) (not (bobp))) |
| 225 | (if (= (preceding-char) ?\t) |
| 226 | (let ((col (current-column))) |
| 227 | (forward-char -1) |
| 228 | (setq col (- col (current-column))) |
| 229 | (insert-char ?\ col) |
| 230 | (delete-char 1))) |
| 231 | (forward-char -1) |
| 232 | (setq count (1- count))))) |
| 233 | (delete-backward-char arg killp) |
| 234 | ;; In overwrite mode, back over columns while clearing them out, |
| 235 | ;; unless at end of line. |
| 236 | (and overwrite-mode (not (eolp)) |
| 237 | (save-excursion (insert-char ?\ arg)))) |
| 238 | |
| 239 | (defun zap-to-char (arg char) |
| 240 | "Kill up to and including ARG'th occurrence of CHAR. |
| 241 | Goes backward if ARG is negative; error if CHAR not found." |
| 242 | (interactive "p\ncZap to char: ") |
| 243 | (kill-region (point) (progn |
| 244 | (search-forward (char-to-string char) nil nil arg) |
| 245 | ; (goto-char (if (> arg 0) (1- (point)) (1+ (point)))) |
| 246 | (point)))) |
| 247 | |
| 248 | (defun beginning-of-buffer (&optional arg) |
| 249 | "Move point to the beginning of the buffer; leave mark at previous position. |
| 250 | With arg N, put point N/10 of the way from the true beginning. |
| 251 | |
| 252 | Don't use this command in Lisp programs! |
| 253 | \(goto-char (point-min)) is faster and avoids clobbering the mark." |
| 254 | (interactive "P") |
| 255 | (push-mark) |
| 256 | (goto-char (if arg |
| 257 | (if (> (buffer-size) 10000) |
| 258 | ;; Avoid overflow for large buffer sizes! |
| 259 | (* (prefix-numeric-value arg) |
| 260 | (/ (buffer-size) 10)) |
| 261 | (/ (+ 10 (* (buffer-size) (prefix-numeric-value arg))) 10)) |
| 262 | (point-min))) |
| 263 | (if arg (forward-line 1))) |
| 264 | |
| 265 | (defun end-of-buffer (&optional arg) |
| 266 | "Move point to the end of the buffer; leave mark at previous position. |
| 267 | With arg N, put point N/10 of the way from the true end. |
| 268 | |
| 269 | Don't use this command in Lisp programs! |
| 270 | \(goto-char (point-max)) is faster and avoids clobbering the mark." |
| 271 | (interactive "P") |
| 272 | (push-mark) |
| 273 | (goto-char (if arg |
| 274 | (- (1+ (buffer-size)) |
| 275 | (if (> (buffer-size) 10000) |
| 276 | ;; Avoid overflow for large buffer sizes! |
| 277 | (* (prefix-numeric-value arg) |
| 278 | (/ (buffer-size) 10)) |
| 279 | (/ (* (buffer-size) (prefix-numeric-value arg)) 10))) |
| 280 | (point-max))) |
| 281 | ;; If we went to a place in the middle of the buffer, |
| 282 | ;; adjust it to the beginning of a line. |
| 283 | (if arg (forward-line 1) |
| 284 | ;; If the end of the buffer is not already on the screen, |
| 285 | ;; then scroll specially to put it near, but not at, the bottom. |
| 286 | (if (let ((old-point (point))) |
| 287 | (save-excursion |
| 288 | (goto-char (window-start)) |
| 289 | (vertical-motion (window-height)) |
| 290 | (< (point) old-point))) |
| 291 | (recenter -3)))) |
| 292 | |
| 293 | (defun mark-whole-buffer () |
| 294 | "Put point at beginning and mark at end of buffer. |
| 295 | You probably should not use this function in Lisp programs; |
| 296 | it is usually a mistake for a Lisp function to use any subroutine |
| 297 | that uses or sets the mark." |
| 298 | (interactive) |
| 299 | (push-mark (point)) |
| 300 | (push-mark (point-max) nil t) |
| 301 | (goto-char (point-min))) |
| 302 | |
| 303 | (defun count-lines-region (start end) |
| 304 | "Print number of lines and charcters in the region." |
| 305 | (interactive "r") |
| 306 | (message "Region has %d lines, %d characters" |
| 307 | (count-lines start end) (- end start))) |
| 308 | |
| 309 | (defun what-line () |
| 310 | "Print the current line number (in the buffer) of point." |
| 311 | (interactive) |
| 312 | (save-restriction |
| 313 | (widen) |
| 314 | (save-excursion |
| 315 | (beginning-of-line) |
| 316 | (message "Line %d" |
| 317 | (1+ (count-lines 1 (point))))))) |
| 318 | |
| 319 | (defun count-lines (start end) |
| 320 | "Return number of lines between START and END. |
| 321 | This is usually the number of newlines between them, |
| 322 | but can be one more if START is not equal to END |
| 323 | and the greater of them is not at the start of a line." |
| 324 | (save-match-data |
| 325 | (save-excursion |
| 326 | (save-restriction |
| 327 | (narrow-to-region start end) |
| 328 | (goto-char (point-min)) |
| 329 | (if (eq selective-display t) |
| 330 | (let ((done 0)) |
| 331 | (while (re-search-forward "[\n\C-m]" nil t 40) |
| 332 | (setq done (+ 40 done))) |
| 333 | (while (re-search-forward "[\n\C-m]" nil t 1) |
| 334 | (setq done (+ 1 done))) |
| 335 | done) |
| 336 | (- (buffer-size) (forward-line (buffer-size)))))))) |
| 337 | |
| 338 | (defun what-cursor-position () |
| 339 | "Print info on cursor position (on screen and within buffer)." |
| 340 | (interactive) |
| 341 | (let* ((char (following-char)) |
| 342 | (beg (point-min)) |
| 343 | (end (point-max)) |
| 344 | (pos (point)) |
| 345 | (total (buffer-size)) |
| 346 | (percent (if (> total 50000) |
| 347 | ;; Avoid overflow from multiplying by 100! |
| 348 | (/ (+ (/ total 200) (1- pos)) (max (/ total 100) 1)) |
| 349 | (/ (+ (/ total 2) (* 100 (1- pos))) (max total 1)))) |
| 350 | (hscroll (if (= (window-hscroll) 0) |
| 351 | "" |
| 352 | (format " Hscroll=%d" (window-hscroll)))) |
| 353 | (col (current-column))) |
| 354 | (if (= pos end) |
| 355 | (if (or (/= beg 1) (/= end (1+ total))) |
| 356 | (message "point=%d of %d(%d%%) <%d - %d> column %d %s" |
| 357 | pos total percent beg end col hscroll) |
| 358 | (message "point=%d of %d(%d%%) column %d %s" |
| 359 | pos total percent col hscroll)) |
| 360 | (if (or (/= beg 1) (/= end (1+ total))) |
| 361 | (message "Char: %s (0%o) point=%d of %d(%d%%) <%d - %d> column %d %s" |
| 362 | (single-key-description char) char pos total percent beg end col hscroll) |
| 363 | (message "Char: %s (0%o) point=%d of %d(%d%%) column %d %s" |
| 364 | (single-key-description char) char pos total percent col hscroll))))) |
| 365 | |
| 366 | (defun fundamental-mode () |
| 367 | "Major mode not specialized for anything in particular. |
| 368 | Other major modes are defined by comparison with this one." |
| 369 | (interactive) |
| 370 | (kill-all-local-variables)) |
| 371 | |
| 372 | (defvar read-expression-map (copy-keymap minibuffer-local-map) |
| 373 | "Minibuffer keymap used for reading Lisp expressions.") |
| 374 | (define-key read-expression-map "\M-\t" 'lisp-complete-symbol) |
| 375 | |
| 376 | (put 'eval-expression 'disabled t) |
| 377 | |
| 378 | ;; We define this, rather than making eval interactive, |
| 379 | ;; for the sake of completion of names like eval-region, eval-current-buffer. |
| 380 | (defun eval-expression (expression) |
| 381 | "Evaluate EXPRESSION and print value in minibuffer. |
| 382 | Value is also consed on to front of the variable `values'." |
| 383 | (interactive (list (read-from-minibuffer "Eval: " |
| 384 | nil read-expression-map t))) |
| 385 | (setq values (cons (eval expression) values)) |
| 386 | (prin1 (car values) t)) |
| 387 | |
| 388 | (defun edit-and-eval-command (prompt command) |
| 389 | "Prompting with PROMPT, let user edit COMMAND and eval result. |
| 390 | COMMAND is a Lisp expression. Let user edit that expression in |
| 391 | the minibuffer, then read and evaluate the result." |
| 392 | (let ((command (read-from-minibuffer prompt |
| 393 | (prin1-to-string command) |
| 394 | read-expression-map t))) |
| 395 | ;; Add edited command to command history, unless redundant. |
| 396 | (or (equal command (car command-history)) |
| 397 | (setq command-history (cons command command-history))) |
| 398 | (eval command))) |
| 399 | |
| 400 | (defun repeat-complex-command (arg) |
| 401 | "Edit and re-evaluate last complex command, or ARGth from last. |
| 402 | A complex command is one which used the minibuffer. |
| 403 | The command is placed in the minibuffer as a Lisp form for editing. |
| 404 | The result is executed, repeating the command as changed. |
| 405 | If the command has been changed or is not the most recent previous command |
| 406 | it is added to the front of the command history. |
| 407 | You can use the minibuffer history commands \\<minibuffer-local-map>\\[next-history-element] and \\[previous-history-element] |
| 408 | to get different commands to edit and resubmit." |
| 409 | (interactive "p") |
| 410 | (let ((elt (nth (1- arg) command-history)) |
| 411 | (minibuffer-history-position arg) |
| 412 | (minibuffer-history-sexp-flag t) |
| 413 | newcmd) |
| 414 | (if elt |
| 415 | (progn |
| 416 | (setq newcmd (read-from-minibuffer "Redo: " |
| 417 | (prin1-to-string elt) |
| 418 | read-expression-map |
| 419 | t |
| 420 | (cons 'command-history |
| 421 | arg))) |
| 422 | ;; If command was added to command-history as a string, |
| 423 | ;; get rid of that. We want only evallable expressions there. |
| 424 | (if (stringp (car command-history)) |
| 425 | (setq command-history (cdr command-history))) |
| 426 | ;; If command to be redone does not match front of history, |
| 427 | ;; add it to the history. |
| 428 | (or (equal newcmd (car command-history)) |
| 429 | (setq command-history (cons newcmd command-history))) |
| 430 | (eval newcmd)) |
| 431 | (ding)))) |
| 432 | \f |
| 433 | (defvar minibuffer-history nil |
| 434 | "Default minibuffer history list. |
| 435 | This is used for all minibuffer input |
| 436 | except when an alternate history list is specified.") |
| 437 | (defvar minibuffer-history-sexp-flag nil |
| 438 | "Nonzero when doing history operations on `command-history'. |
| 439 | More generally, indicates that the history list being acted on |
| 440 | contains expressions rather than strings.") |
| 441 | (setq minibuffer-history-variable 'minibuffer-history) |
| 442 | (setq minibuffer-history-position nil) |
| 443 | (defvar minibuffer-history-search-history nil) |
| 444 | |
| 445 | (mapcar |
| 446 | (lambda (key-and-command) |
| 447 | (mapcar |
| 448 | (lambda (keymap-and-completionp) |
| 449 | ;; Arg is (KEYMAP-SYMBOL . COMPLETION-MAP-P). |
| 450 | ;; If the cdr of KEY-AND-COMMAND (the command) is a cons, |
| 451 | ;; its car is used if COMPLETION-MAP-P is nil, its cdr if it is t. |
| 452 | (define-key (symbol-value (car keymap-and-completionp)) |
| 453 | (car key-and-command) |
| 454 | (let ((command (cdr key-and-command))) |
| 455 | (if (consp command) |
| 456 | ;; (and ... nil) => ... turns back on the completion-oriented |
| 457 | ;; history commands which rms turned off since they seem to |
| 458 | ;; do things he doesn't like. |
| 459 | (if (and (cdr keymap-and-completionp) nil) ;XXX turned off |
| 460 | (progn (error "EMACS BUG!") (cdr command)) |
| 461 | (car command)) |
| 462 | command)))) |
| 463 | '((minibuffer-local-map . nil) |
| 464 | (minibuffer-local-ns-map . nil) |
| 465 | (minibuffer-local-completion-map . t) |
| 466 | (minibuffer-local-must-match-map . t) |
| 467 | (read-expression-map . nil)))) |
| 468 | '(("\en" . (next-history-element . next-complete-history-element)) |
| 469 | ([next] . (next-history-element . next-complete-history-element)) |
| 470 | ("\ep" . (previous-history-element . previous-complete-history-element)) |
| 471 | ([prior] . (previous-history-element . previous-complete-history-element)) |
| 472 | ("\er" . previous-matching-history-element) |
| 473 | ("\es" . next-matching-history-element))) |
| 474 | |
| 475 | (defun previous-matching-history-element (regexp n) |
| 476 | "Find the previous history element that matches REGEXP. |
| 477 | \(Previous history elements refer to earlier actions.) |
| 478 | With prefix argument N, search for Nth previous match. |
| 479 | If N is negative, find the next or Nth next match." |
| 480 | (interactive |
| 481 | (let* ((enable-recursive-minibuffers t) |
| 482 | (minibuffer-history-sexp-flag nil) |
| 483 | (regexp (read-from-minibuffer "Previous element matching (regexp): " |
| 484 | nil |
| 485 | minibuffer-local-map |
| 486 | nil |
| 487 | 'minibuffer-history-search-history))) |
| 488 | ;; Use the last regexp specified, by default, if input is empty. |
| 489 | (list (if (string= regexp "") |
| 490 | (setcar minibuffer-history-search-history |
| 491 | (nth 1 minibuffer-history-search-history)) |
| 492 | regexp) |
| 493 | (prefix-numeric-value current-prefix-arg)))) |
| 494 | (let ((history (symbol-value minibuffer-history-variable)) |
| 495 | prevpos |
| 496 | (pos minibuffer-history-position)) |
| 497 | (while (/= n 0) |
| 498 | (setq prevpos pos) |
| 499 | (setq pos (min (max 1 (+ pos (if (< n 0) -1 1))) (length history))) |
| 500 | (if (= pos prevpos) |
| 501 | (error (if (= pos 1) |
| 502 | "No later matching history item" |
| 503 | "No earlier matching history item"))) |
| 504 | (if (string-match regexp |
| 505 | (if minibuffer-history-sexp-flag |
| 506 | (prin1-to-string (nth (1- pos) history)) |
| 507 | (nth (1- pos) history))) |
| 508 | (setq n (+ n (if (< n 0) 1 -1))))) |
| 509 | (setq minibuffer-history-position pos) |
| 510 | (erase-buffer) |
| 511 | (let ((elt (nth (1- pos) history))) |
| 512 | (insert (if minibuffer-history-sexp-flag |
| 513 | (prin1-to-string elt) |
| 514 | elt))) |
| 515 | (goto-char (point-min))) |
| 516 | (if (or (eq (car (car command-history)) 'previous-matching-history-element) |
| 517 | (eq (car (car command-history)) 'next-matching-history-element)) |
| 518 | (setq command-history (cdr command-history)))) |
| 519 | |
| 520 | (defun next-matching-history-element (regexp n) |
| 521 | "Find the next history element that matches REGEXP. |
| 522 | \(The next history element refers to a more recent action.) |
| 523 | With prefix argument N, search for Nth next match. |
| 524 | If N is negative, find the previous or Nth previous match." |
| 525 | (interactive |
| 526 | (let* ((enable-recursive-minibuffers t) |
| 527 | (minibuffer-history-sexp-flag nil) |
| 528 | (regexp (read-from-minibuffer "Next element matching (regexp): " |
| 529 | nil |
| 530 | minibuffer-local-map |
| 531 | nil |
| 532 | 'minibuffer-history-search-history))) |
| 533 | ;; Use the last regexp specified, by default, if input is empty. |
| 534 | (list (if (string= regexp "") |
| 535 | (setcar minibuffer-history-search-history |
| 536 | (nth 1 minibuffer-history-search-history)) |
| 537 | regexp) |
| 538 | (prefix-numeric-value current-prefix-arg)))) |
| 539 | (previous-matching-history-element regexp (- n))) |
| 540 | |
| 541 | (defun next-history-element (n) |
| 542 | "Insert the next element of the minibuffer history into the minibuffer." |
| 543 | (interactive "p") |
| 544 | (let ((narg (min (max 1 (- minibuffer-history-position n)) |
| 545 | (length (symbol-value minibuffer-history-variable))))) |
| 546 | (if (= minibuffer-history-position narg) |
| 547 | (error (if (= minibuffer-history-position 1) |
| 548 | "End of history; no next item" |
| 549 | "Beginning of history; no preceding item")) |
| 550 | (erase-buffer) |
| 551 | (setq minibuffer-history-position narg) |
| 552 | (let ((elt (nth (1- minibuffer-history-position) |
| 553 | (symbol-value minibuffer-history-variable)))) |
| 554 | (insert |
| 555 | (if minibuffer-history-sexp-flag |
| 556 | (prin1-to-string elt) |
| 557 | elt))) |
| 558 | (goto-char (point-min))))) |
| 559 | |
| 560 | (defun previous-history-element (n) |
| 561 | "Inserts the previous element of the minibuffer history into the minibuffer." |
| 562 | (interactive "p") |
| 563 | (next-history-element (- n))) |
| 564 | |
| 565 | (defun next-complete-history-element (n) |
| 566 | "\ |
| 567 | Get previous element of history which is a completion of minibuffer contents." |
| 568 | (interactive "p") |
| 569 | (let ((point-at-start (point))) |
| 570 | (next-matching-history-element |
| 571 | (concat "^" (regexp-quote (buffer-substring (point-min) (point)))) n) |
| 572 | ;; next-matching-history-element always puts us at (point-min). |
| 573 | ;; Move to the position we were at before changing the buffer contents. |
| 574 | ;; This is still sensical, because the text before point has not changed. |
| 575 | (goto-char point-at-start))) |
| 576 | |
| 577 | (defun previous-complete-history-element (n) |
| 578 | "Get next element of history which is a completion of minibuffer contents." |
| 579 | (interactive "p") |
| 580 | (next-complete-history-element (- n))) |
| 581 | \f |
| 582 | (defun goto-line (arg) |
| 583 | "Goto line ARG, counting from line 1 at beginning of buffer." |
| 584 | (interactive "NGoto line: ") |
| 585 | (save-restriction |
| 586 | (widen) |
| 587 | (goto-char 1) |
| 588 | (if (eq selective-display t) |
| 589 | (re-search-forward "[\n\C-m]" nil 'end (1- arg)) |
| 590 | (forward-line (1- arg))))) |
| 591 | |
| 592 | ;Put this on C-x u, so we can force that rather than C-_ into startup msg |
| 593 | (define-function 'advertised-undo 'undo) |
| 594 | |
| 595 | (defun undo (&optional arg) |
| 596 | "Undo some previous changes. |
| 597 | Repeat this command to undo more changes. |
| 598 | A numeric argument serves as a repeat count." |
| 599 | (interactive "*p") |
| 600 | (let ((modified (buffer-modified-p))) |
| 601 | (or (eq (selected-window) (minibuffer-window)) |
| 602 | (message "Undo!")) |
| 603 | (or (eq last-command 'undo) |
| 604 | (progn (undo-start) |
| 605 | (undo-more 1))) |
| 606 | (setq this-command 'undo) |
| 607 | (undo-more (or arg 1)) |
| 608 | (and modified (not (buffer-modified-p)) |
| 609 | (delete-auto-save-file-if-necessary)))) |
| 610 | |
| 611 | (defun undo-start () |
| 612 | "Set `pending-undo-list' to the front of the undo list. |
| 613 | The next call to `undo-more' will undo the most recently made change." |
| 614 | (if (eq buffer-undo-list t) |
| 615 | (error "No undo information in this buffer")) |
| 616 | (setq pending-undo-list buffer-undo-list)) |
| 617 | |
| 618 | (defun undo-more (count) |
| 619 | "Undo back N undo-boundaries beyond what was already undone recently. |
| 620 | Call `undo-start' to get ready to undo recent changes, |
| 621 | then call `undo-more' one or more times to undo them." |
| 622 | (or pending-undo-list |
| 623 | (error "No further undo information")) |
| 624 | (setq pending-undo-list (primitive-undo count pending-undo-list))) |
| 625 | |
| 626 | (defvar last-shell-command "") |
| 627 | (defvar last-shell-command-on-region "") |
| 628 | |
| 629 | (defun shell-command (command &optional flag) |
| 630 | "Execute string COMMAND in inferior shell; display output, if any. |
| 631 | If COMMAND ends in ampersand, execute it asynchronously. |
| 632 | |
| 633 | Optional second arg non-nil (prefix arg, if interactive) |
| 634 | means insert output in current buffer after point (leave mark after it). |
| 635 | This cannot be done asynchronously." |
| 636 | (interactive (list (read-string "Shell command: " last-shell-command) |
| 637 | current-prefix-arg)) |
| 638 | (if flag |
| 639 | (progn (barf-if-buffer-read-only) |
| 640 | (push-mark) |
| 641 | ;; We do not use -f for csh; we will not support broken use of |
| 642 | ;; .cshrcs. Even the BSD csh manual says to use |
| 643 | ;; "if ($?prompt) exit" before things which are not useful |
| 644 | ;; non-interactively. Besides, if someone wants their other |
| 645 | ;; aliases for shell commands then they can still have them. |
| 646 | (call-process shell-file-name nil t nil |
| 647 | "-c" command) |
| 648 | (exchange-point-and-mark)) |
| 649 | ;; Preserve the match data in case called from a program. |
| 650 | (let ((data (match-data))) |
| 651 | (unwind-protect |
| 652 | (if (string-match "[ \t]*&[ \t]*$" command) |
| 653 | ;; Command ending with ampersand means asynchronous. |
| 654 | (let ((buffer (get-buffer-create "*shell-command*")) |
| 655 | (directory default-directory) |
| 656 | proc) |
| 657 | ;; Remove the ampersand. |
| 658 | (setq command (substring command 0 (match-beginning 0))) |
| 659 | ;; If will kill a process, query first. |
| 660 | (setq proc (get-buffer-process buffer)) |
| 661 | (if proc |
| 662 | (if (yes-or-no-p "A command is running. Kill it? ") |
| 663 | (kill-process proc) |
| 664 | (error "Shell command in progress"))) |
| 665 | (save-excursion |
| 666 | (set-buffer buffer) |
| 667 | (erase-buffer) |
| 668 | (display-buffer buffer) |
| 669 | (setq default-directory directory) |
| 670 | (setq proc (start-process "Shell" buffer |
| 671 | shell-file-name "-c" command)) |
| 672 | (setq mode-line-process '(": %s")) |
| 673 | (set-process-sentinel proc 'shell-command-sentinel) |
| 674 | (set-process-filter proc 'shell-command-filter) |
| 675 | )) |
| 676 | (shell-command-on-region (point) (point) command nil)) |
| 677 | (store-match-data data))))) |
| 678 | |
| 679 | ;; We have a sentinel to prevent insertion of a termination message |
| 680 | ;; in the buffer itself. |
| 681 | (defun shell-command-sentinel (process signal) |
| 682 | (if (memq (process-status process) '(exit signal)) |
| 683 | (progn |
| 684 | (message "%s: %s." |
| 685 | (car (cdr (cdr (process-command process)))) |
| 686 | (substring signal 0 -1)) |
| 687 | (save-excursion |
| 688 | (set-buffer (process-buffer process)) |
| 689 | (setq mode-line-process nil)) |
| 690 | (delete-process process)))) |
| 691 | |
| 692 | (defun shell-command-filter (proc string) |
| 693 | ;; Do save-excursion by hand so that we can leave point numerically unchanged |
| 694 | ;; despite an insertion immediately after it. |
| 695 | (let* ((obuf (current-buffer)) |
| 696 | (buffer (process-buffer proc)) |
| 697 | opoint |
| 698 | (window (get-buffer-window buffer)) |
| 699 | (pos (window-start window))) |
| 700 | (unwind-protect |
| 701 | (progn |
| 702 | (set-buffer buffer) |
| 703 | (setq opoint (point)) |
| 704 | (goto-char (point-max)) |
| 705 | (insert-before-markers string)) |
| 706 | ;; insert-before-markers moved this marker: set it back. |
| 707 | (set-window-start window pos) |
| 708 | ;; Finish our save-excursion. |
| 709 | (goto-char opoint) |
| 710 | (set-buffer obuf)))) |
| 711 | |
| 712 | (defun shell-command-on-region (start end command &optional flag interactive) |
| 713 | "Execute string COMMAND in inferior shell with region as input. |
| 714 | Normally display output (if any) in temp buffer `*Shell Command Output*'; |
| 715 | Prefix arg means replace the region with it. |
| 716 | Noninteractive args are START, END, COMMAND, FLAG. |
| 717 | Noninteractively FLAG means insert output in place of text from START to END, |
| 718 | and put point at the end, but don't alter the mark. |
| 719 | |
| 720 | If the output is one line, it is displayed in the echo area, |
| 721 | but it is nonetheless available in buffer `*Shell Command Output*' |
| 722 | even though that buffer is not automatically displayed. If there is no output |
| 723 | or output is inserted in the current buffer then `*Shell Command Output*' is |
| 724 | deleted." |
| 725 | (interactive (list (region-beginning) (region-end) |
| 726 | (read-string "Shell command on region: " |
| 727 | last-shell-command-on-region) |
| 728 | current-prefix-arg |
| 729 | (prefix-numeric-value current-prefix-arg))) |
| 730 | (if flag |
| 731 | ;; Replace specified region with output from command. |
| 732 | (let ((swap (and interactive (< (point) (mark))))) |
| 733 | ;; Don't muck with mark |
| 734 | ;; unless called interactively. |
| 735 | (and interactive (push-mark)) |
| 736 | (call-process-region start end shell-file-name t t nil |
| 737 | "-c" command) |
| 738 | (if (get-buffer "*Shell Command Output*") |
| 739 | (kill-buffer "*Shell Command Output*")) |
| 740 | (and interactive swap (exchange-point-and-mark))) |
| 741 | ;; No prefix argument: put the output in a temp buffer, |
| 742 | ;; replacing its entire contents. |
| 743 | (let ((buffer (get-buffer-create "*Shell Command Output*"))) |
| 744 | (if (eq buffer (current-buffer)) |
| 745 | ;; If the input is the same buffer as the output, |
| 746 | ;; delete everything but the specified region, |
| 747 | ;; then replace that region with the output. |
| 748 | (progn (delete-region end (point-max)) |
| 749 | (delete-region (point-min) start) |
| 750 | (call-process-region (point-min) (point-max) |
| 751 | shell-file-name t t nil |
| 752 | "-c" command)) |
| 753 | ;; Clear the output buffer, then run the command with output there. |
| 754 | (save-excursion |
| 755 | (set-buffer buffer) |
| 756 | (erase-buffer)) |
| 757 | (call-process-region start end shell-file-name |
| 758 | nil buffer nil |
| 759 | "-c" command)) |
| 760 | ;; Report the amount of output. |
| 761 | (let ((lines (save-excursion |
| 762 | (set-buffer buffer) |
| 763 | (if (= (buffer-size) 0) |
| 764 | 0 |
| 765 | (count-lines (point-min) (point-max)))))) |
| 766 | (cond ((= lines 0) |
| 767 | (message "(Shell command completed with no output)") |
| 768 | (kill-buffer "*Shell Command Output*")) |
| 769 | ((= lines 1) |
| 770 | (message "%s" |
| 771 | (save-excursion |
| 772 | (set-buffer buffer) |
| 773 | (goto-char (point-min)) |
| 774 | (buffer-substring (point) |
| 775 | (progn (end-of-line) (point)))))) |
| 776 | (t |
| 777 | (set-window-start (display-buffer buffer) 1))))))) |
| 778 | \f |
| 779 | (defun universal-argument () |
| 780 | "Begin a numeric argument for the following command. |
| 781 | Digits or minus sign following \\[universal-argument] make up the numeric argument. |
| 782 | \\[universal-argument] following the digits or minus sign ends the argument. |
| 783 | \\[universal-argument] without digits or minus sign provides 4 as argument. |
| 784 | Repeating \\[universal-argument] without digits or minus sign |
| 785 | multiplies the argument by 4 each time." |
| 786 | (interactive nil) |
| 787 | (let ((factor 4) |
| 788 | key) |
| 789 | ;; (describe-arg (list factor) 1) |
| 790 | (setq key (read-key-sequence nil t)) |
| 791 | (while (equal (key-binding key) 'universal-argument) |
| 792 | (setq factor (* 4 factor)) |
| 793 | ;; (describe-arg (list factor) 1) |
| 794 | (setq key (read-key-sequence nil t))) |
| 795 | (prefix-arg-internal key factor nil))) |
| 796 | |
| 797 | (defun prefix-arg-internal (key factor value) |
| 798 | (let ((sign 1)) |
| 799 | (if (and (numberp value) (< value 0)) |
| 800 | (setq sign -1 value (- value))) |
| 801 | (if (eq value '-) |
| 802 | (setq sign -1 value nil)) |
| 803 | ;; (describe-arg value sign) |
| 804 | (while (equal key "-") |
| 805 | (setq sign (- sign) factor nil) |
| 806 | ;; (describe-arg value sign) |
| 807 | (setq key (read-key-sequence nil t))) |
| 808 | (while (and (stringp key) |
| 809 | (= (length key) 1) |
| 810 | (not (string< key "0")) |
| 811 | (not (string< "9" key))) |
| 812 | (setq value (+ (* (if (numberp value) value 0) 10) |
| 813 | (- (aref key 0) ?0)) |
| 814 | factor nil) |
| 815 | ;; (describe-arg value sign) |
| 816 | (setq key (read-key-sequence nil t))) |
| 817 | (setq prefix-arg |
| 818 | (cond (factor (list factor)) |
| 819 | ((numberp value) (* value sign)) |
| 820 | ((= sign -1) '-))) |
| 821 | ;; Calling universal-argument after digits |
| 822 | ;; terminates the argument but is ignored. |
| 823 | (if (eq (key-binding key) 'universal-argument) |
| 824 | (progn |
| 825 | (describe-arg value sign) |
| 826 | (setq key (read-key-sequence nil t)))) |
| 827 | (setq unread-command-events (listify-key-sequence key)))) |
| 828 | |
| 829 | (defun describe-arg (value sign) |
| 830 | (cond ((numberp value) |
| 831 | (message "Arg: %d" (* value sign))) |
| 832 | ((consp value) |
| 833 | (message "Arg: [%d]" (car value))) |
| 834 | ((< sign 0) |
| 835 | (message "Arg: -")))) |
| 836 | |
| 837 | (defun digit-argument (arg) |
| 838 | "Part of the numeric argument for the next command. |
| 839 | \\[universal-argument] following digits or minus sign ends the argument." |
| 840 | (interactive "P") |
| 841 | (prefix-arg-internal (char-to-string (logand last-command-char ?\177)) |
| 842 | nil arg)) |
| 843 | |
| 844 | (defun negative-argument (arg) |
| 845 | "Begin a negative numeric argument for the next command. |
| 846 | \\[universal-argument] following digits or minus sign ends the argument." |
| 847 | (interactive "P") |
| 848 | (prefix-arg-internal "-" nil arg)) |
| 849 | \f |
| 850 | (defun forward-to-indentation (arg) |
| 851 | "Move forward ARG lines and position at first nonblank character." |
| 852 | (interactive "p") |
| 853 | (forward-line arg) |
| 854 | (skip-chars-forward " \t")) |
| 855 | |
| 856 | (defun backward-to-indentation (arg) |
| 857 | "Move backward ARG lines and position at first nonblank character." |
| 858 | (interactive "p") |
| 859 | (forward-line (- arg)) |
| 860 | (skip-chars-forward " \t")) |
| 861 | |
| 862 | (defvar kill-whole-line nil |
| 863 | "*If non-nil, `kill-line' with no arg at beg of line kills the whole line.") |
| 864 | |
| 865 | (defun kill-line (&optional arg) |
| 866 | "Kill the rest of the current line; if no nonblanks there, kill thru newline. |
| 867 | With prefix argument, kill that many lines from point. |
| 868 | Negative arguments kill lines backward. |
| 869 | |
| 870 | When calling from a program, nil means \"no arg\", |
| 871 | a number counts as a prefix arg. |
| 872 | |
| 873 | If `kill-whole-line' is non-nil, then kill the whole line |
| 874 | when given no argument at the beginning of a line." |
| 875 | (interactive "P") |
| 876 | (kill-region (point) |
| 877 | ;; Don't shift point before doing the delete; that way, |
| 878 | ;; undo will record the right position of point. |
| 879 | (save-excursion |
| 880 | (if arg |
| 881 | (forward-line (prefix-numeric-value arg)) |
| 882 | (if (eobp) |
| 883 | (signal 'end-of-buffer nil)) |
| 884 | (if (or (looking-at "[ \t]*$") (and kill-whole-line (bolp))) |
| 885 | (forward-line 1) |
| 886 | (end-of-line))) |
| 887 | (point)))) |
| 888 | \f |
| 889 | ;;;; Window system cut and paste hooks. |
| 890 | |
| 891 | (defvar interprogram-cut-function nil |
| 892 | "Function to call to make a killed region available to other programs. |
| 893 | |
| 894 | Most window systems provide some sort of facility for cutting and |
| 895 | pasting text between the windows of different programs. On startup, |
| 896 | this variable is set to a function which emacs will call whenever text |
| 897 | is put in the kill ring to make the new kill available to other |
| 898 | programs. |
| 899 | |
| 900 | The function takes one argument, TEXT, which is a string containing |
| 901 | the text which should be made available.") |
| 902 | |
| 903 | (defvar interprogram-paste-function nil |
| 904 | "Function to call to get text cut from other programs. |
| 905 | |
| 906 | Most window systems provide some sort of facility for cutting and |
| 907 | pasting text between the windows of different programs. On startup, |
| 908 | this variable is set to a function which emacs will call to obtain |
| 909 | text that other programs have provided for pasting. |
| 910 | |
| 911 | The function should be called with no arguments. If the function |
| 912 | returns nil, then no other program has provided such text, and the top |
| 913 | of the Emacs kill ring should be used. If the function returns a |
| 914 | string, that string should be put in the kill ring as the latest kill. |
| 915 | |
| 916 | Note that the function should return a string only if a program other |
| 917 | than Emacs has provided a string for pasting; if Emacs provided the |
| 918 | most recent string, the function should return nil. If it is |
| 919 | difficult to tell whether Emacs or some other program provided the |
| 920 | current string, it is probably good enough to return nil if the string |
| 921 | is equal (according to `string=') to the last text Emacs provided.") |
| 922 | |
| 923 | |
| 924 | \f |
| 925 | ;;;; The kill ring data structure. |
| 926 | |
| 927 | (defvar kill-ring nil |
| 928 | "List of killed text sequences. |
| 929 | Since the kill ring is supposed to interact nicely with cut-and-paste |
| 930 | facilities offered by window systems, use of this variable should |
| 931 | interact nicely with `interprogram-cut-function' and |
| 932 | `interprogram-paste-function'. The functions `kill-new', |
| 933 | `kill-append', and `current-kill' are supposed to implement this |
| 934 | interaction; you may want to use them instead of manipulating the kill |
| 935 | ring directly.") |
| 936 | |
| 937 | (defconst kill-ring-max 30 |
| 938 | "*Maximum length of kill ring before oldest elements are thrown away.") |
| 939 | |
| 940 | (defvar kill-ring-yank-pointer nil |
| 941 | "The tail of the kill ring whose car is the last thing yanked.") |
| 942 | |
| 943 | (defun kill-new (string) |
| 944 | "Make STRING the latest kill in the kill ring. |
| 945 | Set the kill-ring-yank pointer to point to it. |
| 946 | If `interprogram-cut-function' is non-nil, apply it to STRING." |
| 947 | (setq kill-ring (cons string kill-ring)) |
| 948 | (if (> (length kill-ring) kill-ring-max) |
| 949 | (setcdr (nthcdr (1- kill-ring-max) kill-ring) nil)) |
| 950 | (setq kill-ring-yank-pointer kill-ring) |
| 951 | (if interprogram-cut-function |
| 952 | (funcall interprogram-cut-function string))) |
| 953 | |
| 954 | (defun kill-append (string before-p) |
| 955 | "Append STRING to the end of the latest kill in the kill ring. |
| 956 | If BEFORE-P is non-nil, prepend STRING to the kill. |
| 957 | If `interprogram-cut-function' is set, pass the resulting kill to |
| 958 | it." |
| 959 | (setcar kill-ring |
| 960 | (if before-p |
| 961 | (concat string (car kill-ring)) |
| 962 | (concat (car kill-ring) string))) |
| 963 | (if interprogram-cut-function |
| 964 | (funcall interprogram-cut-function (car kill-ring)))) |
| 965 | |
| 966 | (defun current-kill (n &optional do-not-move) |
| 967 | "Rotate the yanking point by N places, and then return that kill. |
| 968 | If N is zero, `interprogram-paste-function' is set, and calling it |
| 969 | returns a string, then that string is added to the front of the |
| 970 | kill ring and returned as the latest kill. |
| 971 | If optional arg DO-NOT-MOVE is non-nil, then don't actually move the |
| 972 | yanking point; just return the Nth kill forward." |
| 973 | (let ((interprogram-paste (and (= n 0) |
| 974 | interprogram-paste-function |
| 975 | (funcall interprogram-paste-function)))) |
| 976 | (if interprogram-paste |
| 977 | (progn |
| 978 | ;; Disable the interprogram cut function when we add the new |
| 979 | ;; text to the kill ring, so Emacs doesn't try to own the |
| 980 | ;; selection, with identical text. |
| 981 | (let ((interprogram-cut-function nil)) |
| 982 | (kill-new interprogram-paste)) |
| 983 | interprogram-paste) |
| 984 | (or kill-ring (error "Kill ring is empty")) |
| 985 | (let* ((length (length kill-ring)) |
| 986 | (ARGth-kill-element |
| 987 | (nthcdr (% (+ n (- length (length kill-ring-yank-pointer))) |
| 988 | length) |
| 989 | kill-ring))) |
| 990 | (or do-not-move |
| 991 | (setq kill-ring-yank-pointer ARGth-kill-element)) |
| 992 | (car ARGth-kill-element))))) |
| 993 | |
| 994 | |
| 995 | \f |
| 996 | ;;;; Commands for manipulating the kill ring. |
| 997 | |
| 998 | (defun kill-region (beg end) |
| 999 | "Kill between point and mark. |
| 1000 | The text is deleted but saved in the kill ring. |
| 1001 | The command \\[yank] can retrieve it from there. |
| 1002 | \(If you want to kill and then yank immediately, use \\[copy-region-as-kill].) |
| 1003 | If the buffer is read-only, Emacs will beep and refrain from deleting |
| 1004 | the text, but put the text in the kill ring anyway. This means that |
| 1005 | you can use the killing commands to copy text from a read-only buffer. |
| 1006 | |
| 1007 | This is the primitive for programs to kill text (as opposed to deleting it). |
| 1008 | Supply two arguments, character numbers indicating the stretch of text |
| 1009 | to be killed. |
| 1010 | Any command that calls this function is a \"kill command\". |
| 1011 | If the previous command was also a kill command, |
| 1012 | the text killed this time appends to the text killed last time |
| 1013 | to make one entry in the kill ring." |
| 1014 | (interactive "r") |
| 1015 | (cond |
| 1016 | |
| 1017 | ;; If the buffer is read-only, we should beep, in case the person |
| 1018 | ;; just isn't aware of this. However, there's no harm in putting |
| 1019 | ;; the region's text in the kill ring, anyway. |
| 1020 | (buffer-read-only |
| 1021 | (copy-region-as-kill beg end) |
| 1022 | ;; This should always barf, and give us the correct error. |
| 1023 | (barf-if-buffer-read-only)) |
| 1024 | |
| 1025 | ;; In certain cases, we can arrange for the undo list and the kill |
| 1026 | ;; ring to share the same string object. This code does that. |
| 1027 | ((not (or (eq buffer-undo-list t) |
| 1028 | (eq last-command 'kill-region) |
| 1029 | (eq beg end))) |
| 1030 | ;; Don't let the undo list be truncated before we can even access it. |
| 1031 | (let ((undo-strong-limit (+ (- (max beg end) (min beg end)) 100))) |
| 1032 | (delete-region beg end) |
| 1033 | ;; Take the same string recorded for undo |
| 1034 | ;; and put it in the kill-ring. |
| 1035 | (kill-new (car (car buffer-undo-list))) |
| 1036 | (setq this-command 'kill-region))) |
| 1037 | |
| 1038 | (t |
| 1039 | (copy-region-as-kill beg end) |
| 1040 | (delete-region beg end)))) |
| 1041 | |
| 1042 | (defun copy-region-as-kill (beg end) |
| 1043 | "Save the region as if killed, but don't kill it. |
| 1044 | If `interprogram-cut-function' is non-nil, also save the text for a window |
| 1045 | system cut and paste." |
| 1046 | (interactive "r") |
| 1047 | (if (eq last-command 'kill-region) |
| 1048 | (kill-append (buffer-substring beg end) (< end beg)) |
| 1049 | (kill-new (buffer-substring beg end))) |
| 1050 | (setq this-command 'kill-region) |
| 1051 | nil) |
| 1052 | |
| 1053 | (defun kill-ring-save (beg end) |
| 1054 | "Save the region as if killed, but don't kill it. |
| 1055 | This command is similar to copy-region-as-kill, except that it gives |
| 1056 | visual feedback indicating the extent of the region being copied. |
| 1057 | If `interprogram-cut-function' is non-nil, also save the text for a window |
| 1058 | system cut and paste." |
| 1059 | (interactive "r") |
| 1060 | (copy-region-as-kill beg end) |
| 1061 | (if (interactive-p) |
| 1062 | (let ((other-end (if (= (point) beg) end beg)) |
| 1063 | (opoint (point)) |
| 1064 | ;; Inhibit quitting so we can make a quit here |
| 1065 | ;; look like a C-g typed as a command. |
| 1066 | (inhibit-quit t)) |
| 1067 | (if (pos-visible-in-window-p other-end (selected-window)) |
| 1068 | (progn |
| 1069 | ;; Swap point and mark. |
| 1070 | (set-marker (mark-marker) (point) (current-buffer)) |
| 1071 | (goto-char other-end) |
| 1072 | (sit-for 1) |
| 1073 | ;; Swap back. |
| 1074 | (set-marker (mark-marker) other-end (current-buffer)) |
| 1075 | (goto-char opoint) |
| 1076 | ;; If user quit, deactivate the mark |
| 1077 | ;; as C-g would as a command. |
| 1078 | (and quit-flag transient-mark-mode mark-active |
| 1079 | (progn |
| 1080 | (message "foo") |
| 1081 | (setq mark-active nil) |
| 1082 | (run-hooks 'deactivate-mark-hook)))) |
| 1083 | (let* ((killed-text (current-kill 0)) |
| 1084 | (message-len (min (length killed-text) 40))) |
| 1085 | (if (= (point) beg) |
| 1086 | ;; Don't say "killed"; that is misleading. |
| 1087 | (message "Saved text until \"%s\"" |
| 1088 | (substring killed-text (- message-len))) |
| 1089 | (message "Saved text from \"%s\"" |
| 1090 | (substring killed-text 0 message-len)))))))) |
| 1091 | |
| 1092 | (defun append-next-kill () |
| 1093 | "Cause following command, if it kills, to append to previous kill." |
| 1094 | (interactive) |
| 1095 | (if (interactive-p) |
| 1096 | (progn |
| 1097 | (setq this-command 'kill-region) |
| 1098 | (message "If the next command is a kill, it will append")) |
| 1099 | (setq last-command 'kill-region))) |
| 1100 | |
| 1101 | (defun yank-pop (arg) |
| 1102 | "Replace just-yanked stretch of killed text with a different stretch. |
| 1103 | This command is allowed only immediately after a `yank' or a `yank-pop'. |
| 1104 | At such a time, the region contains a stretch of reinserted |
| 1105 | previously-killed text. `yank-pop' deletes that text and inserts in its |
| 1106 | place a different stretch of killed text. |
| 1107 | |
| 1108 | With no argument, the previous kill is inserted. |
| 1109 | With argument N, insert the Nth previous kill. |
| 1110 | If N is negative, this is a more recent kill. |
| 1111 | |
| 1112 | The sequence of kills wraps around, so that after the oldest one |
| 1113 | comes the newest one." |
| 1114 | (interactive "*p") |
| 1115 | (if (not (eq last-command 'yank)) |
| 1116 | (error "Previous command was not a yank")) |
| 1117 | (setq this-command 'yank) |
| 1118 | (let ((before (< (point) (mark t)))) |
| 1119 | (delete-region (point) (mark t)) |
| 1120 | (set-marker (mark-marker) (point) (current-buffer)) |
| 1121 | (insert (current-kill arg)) |
| 1122 | (if before |
| 1123 | ;; This is like exchange-point-and-mark, but doesn't activate the mark. |
| 1124 | ;; It is cleaner to avoid activation, even though the command |
| 1125 | ;; loop would deactivate the mark because we inserted text. |
| 1126 | (goto-char (prog1 (mark t) |
| 1127 | (set-marker (mark-marker) (point) (current-buffer)))))) |
| 1128 | nil) |
| 1129 | |
| 1130 | (defun yank (&optional arg) |
| 1131 | "Reinsert the last stretch of killed text. |
| 1132 | More precisely, reinsert the stretch of killed text most recently |
| 1133 | killed OR yanked. Put point at end, and set mark at beginning. |
| 1134 | With just C-u as argument, same but put point at beginning (and mark at end). |
| 1135 | With argument N, reinsert the Nth most recently killed stretch of killed |
| 1136 | text. |
| 1137 | See also the command \\[yank-pop]." |
| 1138 | (interactive "*P") |
| 1139 | (push-mark (point)) |
| 1140 | (insert (current-kill (cond |
| 1141 | ((listp arg) 0) |
| 1142 | ((eq arg '-) -1) |
| 1143 | (t (1- arg))))) |
| 1144 | (if (consp arg) |
| 1145 | ;; This is like exchange-point-and-mark, but doesn't activate the mark. |
| 1146 | ;; It is cleaner to avoid activation, even though the command |
| 1147 | ;; loop would deactivate the mark because we inserted text. |
| 1148 | (goto-char (prog1 (mark t) |
| 1149 | (set-marker (mark-marker) (point) (current-buffer))))) |
| 1150 | nil) |
| 1151 | |
| 1152 | (defun rotate-yank-pointer (arg) |
| 1153 | "Rotate the yanking point in the kill ring. |
| 1154 | With argument, rotate that many kills forward (or backward, if negative)." |
| 1155 | (interactive "p") |
| 1156 | (current-kill arg)) |
| 1157 | |
| 1158 | \f |
| 1159 | (defun insert-buffer (buffer) |
| 1160 | "Insert after point the contents of BUFFER. |
| 1161 | Puts mark after the inserted text. |
| 1162 | BUFFER may be a buffer or a buffer name." |
| 1163 | (interactive (list (progn (barf-if-buffer-read-only) |
| 1164 | (read-buffer "Insert buffer: " (other-buffer) t)))) |
| 1165 | (or (bufferp buffer) |
| 1166 | (setq buffer (get-buffer buffer))) |
| 1167 | (let (start end newmark) |
| 1168 | (save-excursion |
| 1169 | (save-excursion |
| 1170 | (set-buffer buffer) |
| 1171 | (setq start (point-min) end (point-max))) |
| 1172 | (insert-buffer-substring buffer start end) |
| 1173 | (setq newmark (point))) |
| 1174 | (push-mark newmark)) |
| 1175 | nil) |
| 1176 | |
| 1177 | (defun append-to-buffer (buffer start end) |
| 1178 | "Append to specified buffer the text of the region. |
| 1179 | It is inserted into that buffer before its point. |
| 1180 | |
| 1181 | When calling from a program, give three arguments: |
| 1182 | BUFFER (or buffer name), START and END. |
| 1183 | START and END specify the portion of the current buffer to be copied." |
| 1184 | (interactive |
| 1185 | (list (read-buffer "Append to buffer: " (other-buffer nil t) t))) |
| 1186 | (let ((oldbuf (current-buffer))) |
| 1187 | (save-excursion |
| 1188 | (set-buffer (get-buffer-create buffer)) |
| 1189 | (insert-buffer-substring oldbuf start end)))) |
| 1190 | |
| 1191 | (defun prepend-to-buffer (buffer start end) |
| 1192 | "Prepend to specified buffer the text of the region. |
| 1193 | It is inserted into that buffer after its point. |
| 1194 | |
| 1195 | When calling from a program, give three arguments: |
| 1196 | BUFFER (or buffer name), START and END. |
| 1197 | START and END specify the portion of the current buffer to be copied." |
| 1198 | (interactive "BPrepend to buffer: \nr") |
| 1199 | (let ((oldbuf (current-buffer))) |
| 1200 | (save-excursion |
| 1201 | (set-buffer (get-buffer-create buffer)) |
| 1202 | (save-excursion |
| 1203 | (insert-buffer-substring oldbuf start end))))) |
| 1204 | |
| 1205 | (defun copy-to-buffer (buffer start end) |
| 1206 | "Copy to specified buffer the text of the region. |
| 1207 | It is inserted into that buffer, replacing existing text there. |
| 1208 | |
| 1209 | When calling from a program, give three arguments: |
| 1210 | BUFFER (or buffer name), START and END. |
| 1211 | START and END specify the portion of the current buffer to be copied." |
| 1212 | (interactive "BCopy to buffer: \nr") |
| 1213 | (let ((oldbuf (current-buffer))) |
| 1214 | (save-excursion |
| 1215 | (set-buffer (get-buffer-create buffer)) |
| 1216 | (erase-buffer) |
| 1217 | (save-excursion |
| 1218 | (insert-buffer-substring oldbuf start end))))) |
| 1219 | \f |
| 1220 | (defun mark (&optional force) |
| 1221 | "Return this buffer's mark value as integer, or nil if no active mark now. |
| 1222 | If optional argument FORCE is non-nil, access the mark value |
| 1223 | even if the mark is not currently active. |
| 1224 | |
| 1225 | If you are using this in an editing command, you are most likely making |
| 1226 | a mistake; see the documentation of `set-mark'." |
| 1227 | (if (or force mark-active) |
| 1228 | (marker-position (mark-marker)) |
| 1229 | (error "The mark is not currently active"))) |
| 1230 | |
| 1231 | (defun set-mark (pos) |
| 1232 | "Set this buffer's mark to POS. Don't use this function! |
| 1233 | That is to say, don't use this function unless you want |
| 1234 | the user to see that the mark has moved, and you want the previous |
| 1235 | mark position to be lost. |
| 1236 | |
| 1237 | Normally, when a new mark is set, the old one should go on the stack. |
| 1238 | This is why most applications should use push-mark, not set-mark. |
| 1239 | |
| 1240 | Novice Emacs Lisp programmers often try to use the mark for the wrong |
| 1241 | purposes. The mark saves a location for the user's convenience. |
| 1242 | Most editing commands should not alter the mark. |
| 1243 | To remember a location for internal use in the Lisp program, |
| 1244 | store it in a Lisp variable. Example: |
| 1245 | |
| 1246 | (let ((beg (point))) (forward-line 1) (delete-region beg (point)))." |
| 1247 | |
| 1248 | (setq mark-active t) |
| 1249 | (run-hooks 'activate-mark-hook) |
| 1250 | (set-marker (mark-marker) pos (current-buffer))) |
| 1251 | |
| 1252 | (defvar mark-ring nil |
| 1253 | "The list of saved former marks of the current buffer, |
| 1254 | most recent first.") |
| 1255 | (make-variable-buffer-local 'mark-ring) |
| 1256 | |
| 1257 | (defconst mark-ring-max 16 |
| 1258 | "*Maximum size of mark ring. Start discarding off end if gets this big.") |
| 1259 | |
| 1260 | (defun set-mark-command (arg) |
| 1261 | "Set mark at where point is, or jump to mark. |
| 1262 | With no prefix argument, set mark, and push old mark position on mark ring. |
| 1263 | With argument, jump to mark, and pop a new position for mark off the ring. |
| 1264 | |
| 1265 | Novice Emacs Lisp programmers often try to use the mark for the wrong |
| 1266 | purposes. See the documentation of `set-mark' for more information." |
| 1267 | (interactive "P") |
| 1268 | (if (null arg) |
| 1269 | (progn |
| 1270 | (push-mark nil nil t)) |
| 1271 | (if (null (mark t)) |
| 1272 | (error "No mark set in this buffer") |
| 1273 | (goto-char (mark t)) |
| 1274 | (pop-mark)))) |
| 1275 | |
| 1276 | (defun push-mark (&optional location nomsg activate) |
| 1277 | "Set mark at LOCATION (point, by default) and push old mark on mark ring. |
| 1278 | Display `Mark set' unless the optional second arg NOMSG is non-nil. |
| 1279 | In Transient Mark mode, activate mark if optional third arg ACTIVATE non-nil. |
| 1280 | |
| 1281 | Novice Emacs Lisp programmers often try to use the mark for the wrong |
| 1282 | purposes. See the documentation of `set-mark' for more information. |
| 1283 | |
| 1284 | In Transient Mark mode, this does not activate the mark." |
| 1285 | (if (null (mark t)) |
| 1286 | nil |
| 1287 | (setq mark-ring (cons (copy-marker (mark-marker)) mark-ring)) |
| 1288 | (if (> (length mark-ring) mark-ring-max) |
| 1289 | (progn |
| 1290 | (move-marker (car (nthcdr mark-ring-max mark-ring)) nil) |
| 1291 | (setcdr (nthcdr (1- mark-ring-max) mark-ring) nil)))) |
| 1292 | (set-marker (mark-marker) (or location (point)) (current-buffer)) |
| 1293 | (or nomsg executing-macro (> (minibuffer-depth) 0) |
| 1294 | (message "Mark set")) |
| 1295 | (if (or activate (not transient-mark-mode)) |
| 1296 | (set-mark (mark t))) |
| 1297 | nil) |
| 1298 | |
| 1299 | (defun pop-mark () |
| 1300 | "Pop off mark ring into the buffer's actual mark. |
| 1301 | Does not set point. Does nothing if mark ring is empty." |
| 1302 | (if mark-ring |
| 1303 | (progn |
| 1304 | (setq mark-ring (nconc mark-ring (list (copy-marker (mark-marker))))) |
| 1305 | (set-marker (mark-marker) (+ 0 (car mark-ring)) (current-buffer)) |
| 1306 | (if transient-mark-mode |
| 1307 | (setq mark-active nil)) |
| 1308 | (move-marker (car mark-ring) nil) |
| 1309 | (if (null (mark t)) (ding)) |
| 1310 | (setq mark-ring (cdr mark-ring))))) |
| 1311 | |
| 1312 | (define-function 'exchange-dot-and-mark 'exchange-point-and-mark) |
| 1313 | (defun exchange-point-and-mark () |
| 1314 | "Put the mark where point is now, and point where the mark is now. |
| 1315 | This command works even when the mark is not active, |
| 1316 | and it reactivates the mark." |
| 1317 | (interactive nil) |
| 1318 | (let ((omark (mark t))) |
| 1319 | (if (null omark) |
| 1320 | (error "No mark set in this buffer")) |
| 1321 | (set-mark (point)) |
| 1322 | (goto-char omark) |
| 1323 | nil)) |
| 1324 | |
| 1325 | (defun transient-mark-mode (arg) |
| 1326 | "Toggle Transient Mark mode. |
| 1327 | With arg, turn Transient Mark mode on if and only if arg is positive. |
| 1328 | |
| 1329 | In Transient Mark mode, changing the buffer \"deactivates\" the mark. |
| 1330 | While the mark is active, the region is highlighted." |
| 1331 | (interactive "P") |
| 1332 | (setq transient-mark-mode |
| 1333 | (if (null arg) |
| 1334 | (not transient-mark-mode) |
| 1335 | (> (prefix-numeric-value arg) 0)))) |
| 1336 | \f |
| 1337 | (defvar next-line-add-newlines t |
| 1338 | "*If non-nil, `next-line' inserts newline to avoid `end of buffer' error.") |
| 1339 | |
| 1340 | (defun next-line (arg) |
| 1341 | "Move cursor vertically down ARG lines. |
| 1342 | If there is no character in the target line exactly under the current column, |
| 1343 | the cursor is positioned after the character in that line which spans this |
| 1344 | column, or at the end of the line if it is not long enough. |
| 1345 | If there is no line in the buffer after this one, behavior depends on the |
| 1346 | value of next-line-add-newlines. If non-nil, a newline character is inserted |
| 1347 | to create a line and the cursor moves to that line, otherwise the cursor is |
| 1348 | moved to the end of the buffer (if already at the end of the buffer, an error |
| 1349 | is signaled). |
| 1350 | |
| 1351 | The command \\[set-goal-column] can be used to create |
| 1352 | a semipermanent goal column to which this command always moves. |
| 1353 | Then it does not try to move vertically. This goal column is stored |
| 1354 | in `goal-column', which is nil when there is none. |
| 1355 | |
| 1356 | If you are thinking of using this in a Lisp program, consider |
| 1357 | using `forward-line' instead. It is usually easier to use |
| 1358 | and more reliable (no dependence on goal column, etc.)." |
| 1359 | (interactive "p") |
| 1360 | (let ((opoint (point))) |
| 1361 | (if next-line-add-newlines |
| 1362 | (if (/= arg 1) |
| 1363 | (line-move arg) |
| 1364 | (forward-line 1) |
| 1365 | (if (or (= opoint (point)) (not (eq (preceding-char) ?\n))) |
| 1366 | (insert ?\n) |
| 1367 | (goto-char opoint) |
| 1368 | (line-move arg))) |
| 1369 | (if (eobp) |
| 1370 | (signal 'end-of-buffer nil)) |
| 1371 | (line-move arg) |
| 1372 | (if (= opoint (point)) |
| 1373 | (end-of-line)))) |
| 1374 | nil) |
| 1375 | |
| 1376 | (defun previous-line (arg) |
| 1377 | "Move cursor vertically up ARG lines. |
| 1378 | If there is no character in the target line exactly over the current column, |
| 1379 | the cursor is positioned after the character in that line which spans this |
| 1380 | column, or at the end of the line if it is not long enough. |
| 1381 | |
| 1382 | The command \\[set-goal-column] can be used to create |
| 1383 | a semipermanent goal column to which this command always moves. |
| 1384 | Then it does not try to move vertically. |
| 1385 | |
| 1386 | If you are thinking of using this in a Lisp program, consider using |
| 1387 | `forward-line' with a negative argument instead. It is usually easier |
| 1388 | to use and more reliable (no dependence on goal column, etc.)." |
| 1389 | (interactive "p") |
| 1390 | (line-move (- arg)) |
| 1391 | nil) |
| 1392 | |
| 1393 | (defconst track-eol nil |
| 1394 | "*Non-nil means vertical motion starting at end of line keeps to ends of lines. |
| 1395 | This means moving to the end of each line moved onto. |
| 1396 | The beginning of a blank line does not count as the end of a line.") |
| 1397 | |
| 1398 | (defvar goal-column nil |
| 1399 | "*Semipermanent goal column for vertical motion, as set by \\[set-goal-column], or nil.") |
| 1400 | (make-variable-buffer-local 'goal-column) |
| 1401 | |
| 1402 | (defvar temporary-goal-column 0 |
| 1403 | "Current goal column for vertical motion. |
| 1404 | It is the column where point was |
| 1405 | at the start of current run of vertical motion commands. |
| 1406 | When the `track-eol' feature is doing its job, the value is 9999.") |
| 1407 | |
| 1408 | (defun line-move (arg) |
| 1409 | (if (not (or (eq last-command 'next-line) |
| 1410 | (eq last-command 'previous-line))) |
| 1411 | (setq temporary-goal-column |
| 1412 | (if (and track-eol (eolp) |
| 1413 | ;; Don't count beg of empty line as end of line |
| 1414 | ;; unless we just did explicit end-of-line. |
| 1415 | (or (not (bolp)) (eq last-command 'end-of-line))) |
| 1416 | 9999 |
| 1417 | (current-column)))) |
| 1418 | (if (not (integerp selective-display)) |
| 1419 | (forward-line arg) |
| 1420 | ;; Move by arg lines, but ignore invisible ones. |
| 1421 | (while (> arg 0) |
| 1422 | (vertical-motion 1) |
| 1423 | (forward-char -1) |
| 1424 | (forward-line 1) |
| 1425 | (setq arg (1- arg))) |
| 1426 | (while (< arg 0) |
| 1427 | (vertical-motion -1) |
| 1428 | (beginning-of-line) |
| 1429 | (setq arg (1+ arg)))) |
| 1430 | (move-to-column (or goal-column temporary-goal-column)) |
| 1431 | nil) |
| 1432 | |
| 1433 | ;;; Many people have said they rarely use this feature, and often type |
| 1434 | ;;; it by accident. Maybe it shouldn't even be on a key. |
| 1435 | (put 'set-goal-column 'disabled t) |
| 1436 | |
| 1437 | (defun set-goal-column (arg) |
| 1438 | "Set the current horizontal position as a goal for \\[next-line] and \\[previous-line]. |
| 1439 | Those commands will move to this position in the line moved to |
| 1440 | rather than trying to keep the same horizontal position. |
| 1441 | With a non-nil argument, clears out the goal column |
| 1442 | so that \\[next-line] and \\[previous-line] resume vertical motion. |
| 1443 | The goal column is stored in the variable `goal-column'." |
| 1444 | (interactive "P") |
| 1445 | (if arg |
| 1446 | (progn |
| 1447 | (setq goal-column nil) |
| 1448 | (message "No goal column")) |
| 1449 | (setq goal-column (current-column)) |
| 1450 | (message (substitute-command-keys |
| 1451 | "Goal column %d (use \\[set-goal-column] with an arg to unset it)") |
| 1452 | goal-column)) |
| 1453 | nil) |
| 1454 | \f |
| 1455 | ;;; Partial support for horizontal autoscrolling. Someday, this feature |
| 1456 | ;;; will be built into the C level and all the (hscroll-point-visible) calls |
| 1457 | ;;; will go away. |
| 1458 | |
| 1459 | (defvar hscroll-step 0 |
| 1460 | "*The number of columns to try scrolling a window by when point moves out. |
| 1461 | If that fails to bring point back on frame, point is centered instead. |
| 1462 | If this is zero, point is always centered after it moves off frame.") |
| 1463 | |
| 1464 | (defun hscroll-point-visible () |
| 1465 | "Scrolls the window horizontally to make point visible." |
| 1466 | (let* ((min (window-hscroll)) |
| 1467 | (max (- (+ min (window-width)) 2)) |
| 1468 | (here (current-column)) |
| 1469 | (delta (if (zerop hscroll-step) (/ (window-width) 2) hscroll-step)) |
| 1470 | ) |
| 1471 | (if (< here min) |
| 1472 | (scroll-right (max 0 (+ (- min here) delta))) |
| 1473 | (if (>= here max) |
| 1474 | (scroll-left (- (- here min) delta)) |
| 1475 | )))) |
| 1476 | |
| 1477 | ;; rms: (1) The definitions of arrow keys should not simply restate |
| 1478 | ;; what keys they are. The arrow keys should run the ordinary commands. |
| 1479 | ;; (2) The arrow keys are just one of many common ways of moving point |
| 1480 | ;; within a line. Real horizontal autoscrolling would be a good feature, |
| 1481 | ;; but supporting it only for arrow keys is too incomplete to be desirable. |
| 1482 | |
| 1483 | ;;;;; Make arrow keys do the right thing for improved terminal support |
| 1484 | ;;;;; When we implement true horizontal autoscrolling, right-arrow and |
| 1485 | ;;;;; left-arrow can lose the (if truncate-lines ...) clause and become |
| 1486 | ;;;;; aliases. These functions are bound to the corresponding keyboard |
| 1487 | ;;;;; events in loaddefs.el. |
| 1488 | |
| 1489 | ;;(defun right-arrow (arg) |
| 1490 | ;; "Move right one character on the screen (with prefix ARG, that many chars). |
| 1491 | ;;Scroll right if needed to keep point horizontally onscreen." |
| 1492 | ;; (interactive "P") |
| 1493 | ;; (forward-char arg) |
| 1494 | ;; (hscroll-point-visible)) |
| 1495 | |
| 1496 | ;;(defun left-arrow (arg) |
| 1497 | ;; "Move left one character on the screen (with prefix ARG, that many chars). |
| 1498 | ;;Scroll left if needed to keep point horizontally onscreen." |
| 1499 | ;; (interactive "P") |
| 1500 | ;; (backward-char arg) |
| 1501 | ;; (hscroll-point-visible)) |
| 1502 | \f |
| 1503 | (defun transpose-chars (arg) |
| 1504 | "Interchange characters around point, moving forward one character. |
| 1505 | With prefix arg ARG, effect is to take character before point |
| 1506 | and drag it forward past ARG other characters (backward if ARG negative). |
| 1507 | If no argument and at end of line, the previous two chars are exchanged." |
| 1508 | (interactive "*P") |
| 1509 | (and (null arg) (eolp) (forward-char -1)) |
| 1510 | (transpose-subr 'forward-char (prefix-numeric-value arg))) |
| 1511 | |
| 1512 | (defun transpose-words (arg) |
| 1513 | "Interchange words around point, leaving point at end of them. |
| 1514 | With prefix arg ARG, effect is to take word before or around point |
| 1515 | and drag it forward past ARG other words (backward if ARG negative). |
| 1516 | If ARG is zero, the words around or after point and around or after mark |
| 1517 | are interchanged." |
| 1518 | (interactive "*p") |
| 1519 | (transpose-subr 'forward-word arg)) |
| 1520 | |
| 1521 | (defun transpose-sexps (arg) |
| 1522 | "Like \\[transpose-words] but applies to sexps. |
| 1523 | Does not work on a sexp that point is in the middle of |
| 1524 | if it is a list or string." |
| 1525 | (interactive "*p") |
| 1526 | (transpose-subr 'forward-sexp arg)) |
| 1527 | |
| 1528 | (defun transpose-lines (arg) |
| 1529 | "Exchange current line and previous line, leaving point after both. |
| 1530 | With argument ARG, takes previous line and moves it past ARG lines. |
| 1531 | With argument 0, interchanges line point is in with line mark is in." |
| 1532 | (interactive "*p") |
| 1533 | (transpose-subr (function |
| 1534 | (lambda (arg) |
| 1535 | (if (= arg 1) |
| 1536 | (progn |
| 1537 | ;; Move forward over a line, |
| 1538 | ;; but create a newline if none exists yet. |
| 1539 | (end-of-line) |
| 1540 | (if (eobp) |
| 1541 | (newline) |
| 1542 | (forward-char 1))) |
| 1543 | (forward-line arg)))) |
| 1544 | arg)) |
| 1545 | |
| 1546 | (defun transpose-subr (mover arg) |
| 1547 | (let (start1 end1 start2 end2) |
| 1548 | (if (= arg 0) |
| 1549 | (progn |
| 1550 | (save-excursion |
| 1551 | (funcall mover 1) |
| 1552 | (setq end2 (point)) |
| 1553 | (funcall mover -1) |
| 1554 | (setq start2 (point)) |
| 1555 | (goto-char (mark)) |
| 1556 | (funcall mover 1) |
| 1557 | (setq end1 (point)) |
| 1558 | (funcall mover -1) |
| 1559 | (setq start1 (point)) |
| 1560 | (transpose-subr-1)) |
| 1561 | (exchange-point-and-mark))) |
| 1562 | (while (> arg 0) |
| 1563 | (funcall mover -1) |
| 1564 | (setq start1 (point)) |
| 1565 | (funcall mover 1) |
| 1566 | (setq end1 (point)) |
| 1567 | (funcall mover 1) |
| 1568 | (setq end2 (point)) |
| 1569 | (funcall mover -1) |
| 1570 | (setq start2 (point)) |
| 1571 | (transpose-subr-1) |
| 1572 | (goto-char end2) |
| 1573 | (setq arg (1- arg))) |
| 1574 | (while (< arg 0) |
| 1575 | (funcall mover -1) |
| 1576 | (setq start2 (point)) |
| 1577 | (funcall mover -1) |
| 1578 | (setq start1 (point)) |
| 1579 | (funcall mover 1) |
| 1580 | (setq end1 (point)) |
| 1581 | (funcall mover 1) |
| 1582 | (setq end2 (point)) |
| 1583 | (transpose-subr-1) |
| 1584 | (setq arg (1+ arg))))) |
| 1585 | |
| 1586 | (defun transpose-subr-1 () |
| 1587 | (if (> (min end1 end2) (max start1 start2)) |
| 1588 | (error "Don't have two things to transpose")) |
| 1589 | (let ((word1 (buffer-substring start1 end1)) |
| 1590 | (word2 (buffer-substring start2 end2))) |
| 1591 | (delete-region start2 end2) |
| 1592 | (goto-char start2) |
| 1593 | (insert word1) |
| 1594 | (goto-char (if (< start1 start2) start1 |
| 1595 | (+ start1 (- (length word1) (length word2))))) |
| 1596 | (delete-char (length word1)) |
| 1597 | (insert word2))) |
| 1598 | \f |
| 1599 | (defconst comment-column 32 |
| 1600 | "*Column to indent right-margin comments to. |
| 1601 | Setting this variable automatically makes it local to the current buffer. |
| 1602 | Each mode establishes a different default value for this variable; you |
| 1603 | can the value for a particular mode using that mode's hook.") |
| 1604 | (make-variable-buffer-local 'comment-column) |
| 1605 | |
| 1606 | (defconst comment-start nil |
| 1607 | "*String to insert to start a new comment, or nil if no comment syntax defined.") |
| 1608 | |
| 1609 | (defconst comment-start-skip nil |
| 1610 | "*Regexp to match the start of a comment plus everything up to its body. |
| 1611 | If there are any \\(...\\) pairs, the comment delimiter text is held to begin |
| 1612 | at the place matched by the close of the first pair.") |
| 1613 | |
| 1614 | (defconst comment-end "" |
| 1615 | "*String to insert to end a new comment. |
| 1616 | Should be an empty string if comments are terminated by end-of-line.") |
| 1617 | |
| 1618 | (defconst comment-indent-hook nil |
| 1619 | "Obsolete variable for function to compute desired indentation for a comment. |
| 1620 | This function is called with no args with point at the beginning of |
| 1621 | the comment's starting delimiter.") |
| 1622 | |
| 1623 | (defconst comment-indent-function |
| 1624 | '(lambda () comment-column) |
| 1625 | "Function to compute desired indentation for a comment. |
| 1626 | This function is called with no args with point at the beginning of |
| 1627 | the comment's starting delimiter.") |
| 1628 | |
| 1629 | (defun indent-for-comment () |
| 1630 | "Indent this line's comment to comment column, or insert an empty comment." |
| 1631 | (interactive "*") |
| 1632 | (beginning-of-line 1) |
| 1633 | (if (null comment-start) |
| 1634 | (error "No comment syntax defined") |
| 1635 | (let* ((eolpos (save-excursion (end-of-line) (point))) |
| 1636 | cpos indent begpos) |
| 1637 | (if (re-search-forward comment-start-skip eolpos 'move) |
| 1638 | (progn (setq cpos (point-marker)) |
| 1639 | ;; Find the start of the comment delimiter. |
| 1640 | ;; If there were paren-pairs in comment-start-skip, |
| 1641 | ;; position at the end of the first pair. |
| 1642 | (if (match-end 1) |
| 1643 | (goto-char (match-end 1)) |
| 1644 | ;; If comment-start-skip matched a string with |
| 1645 | ;; internal whitespace (not final whitespace) then |
| 1646 | ;; the delimiter start at the end of that |
| 1647 | ;; whitespace. Otherwise, it starts at the |
| 1648 | ;; beginning of what was matched. |
| 1649 | (skip-syntax-backward " " (match-beginning 0)) |
| 1650 | (skip-syntax-backward "^ " (match-beginning 0))))) |
| 1651 | (setq begpos (point)) |
| 1652 | ;; Compute desired indent. |
| 1653 | (if (= (current-column) |
| 1654 | (setq indent (if comment-indent-hook |
| 1655 | (funcall comment-indent-hook) |
| 1656 | (funcall comment-indent-function)))) |
| 1657 | (goto-char begpos) |
| 1658 | ;; If that's different from current, change it. |
| 1659 | (skip-chars-backward " \t") |
| 1660 | (delete-region (point) begpos) |
| 1661 | (indent-to indent)) |
| 1662 | ;; An existing comment? |
| 1663 | (if cpos |
| 1664 | (progn (goto-char cpos) |
| 1665 | (set-marker cpos nil)) |
| 1666 | ;; No, insert one. |
| 1667 | (insert comment-start) |
| 1668 | (save-excursion |
| 1669 | (insert comment-end)))))) |
| 1670 | |
| 1671 | (defun set-comment-column (arg) |
| 1672 | "Set the comment column based on point. |
| 1673 | With no arg, set the comment column to the current column. |
| 1674 | With just minus as arg, kill any comment on this line. |
| 1675 | With any other arg, set comment column to indentation of the previous comment |
| 1676 | and then align or create a comment on this line at that column." |
| 1677 | (interactive "P") |
| 1678 | (if (eq arg '-) |
| 1679 | (kill-comment nil) |
| 1680 | (if arg |
| 1681 | (progn |
| 1682 | (save-excursion |
| 1683 | (beginning-of-line) |
| 1684 | (re-search-backward comment-start-skip) |
| 1685 | (beginning-of-line) |
| 1686 | (re-search-forward comment-start-skip) |
| 1687 | (goto-char (match-beginning 0)) |
| 1688 | (setq comment-column (current-column)) |
| 1689 | (message "Comment column set to %d" comment-column)) |
| 1690 | (indent-for-comment)) |
| 1691 | (setq comment-column (current-column)) |
| 1692 | (message "Comment column set to %d" comment-column)))) |
| 1693 | |
| 1694 | (defun kill-comment (arg) |
| 1695 | "Kill the comment on this line, if any. |
| 1696 | With argument, kill comments on that many lines starting with this one." |
| 1697 | ;; this function loses in a lot of situations. it incorrectly recognises |
| 1698 | ;; comment delimiters sometimes (ergo, inside a string), doesn't work |
| 1699 | ;; with multi-line comments, can kill extra whitespace if comment wasn't |
| 1700 | ;; through end-of-line, et cetera. |
| 1701 | (interactive "P") |
| 1702 | (or comment-start-skip (error "No comment syntax defined")) |
| 1703 | (let ((count (prefix-numeric-value arg)) endc) |
| 1704 | (while (> count 0) |
| 1705 | (save-excursion |
| 1706 | (end-of-line) |
| 1707 | (setq endc (point)) |
| 1708 | (beginning-of-line) |
| 1709 | (and (string< "" comment-end) |
| 1710 | (setq endc |
| 1711 | (progn |
| 1712 | (re-search-forward (regexp-quote comment-end) endc 'move) |
| 1713 | (skip-chars-forward " \t") |
| 1714 | (point)))) |
| 1715 | (beginning-of-line) |
| 1716 | (if (re-search-forward comment-start-skip endc t) |
| 1717 | (progn |
| 1718 | (goto-char (match-beginning 0)) |
| 1719 | (skip-chars-backward " \t") |
| 1720 | (kill-region (point) endc) |
| 1721 | ;; to catch comments a line beginnings |
| 1722 | (indent-according-to-mode)))) |
| 1723 | (if arg (forward-line 1)) |
| 1724 | (setq count (1- count))))) |
| 1725 | |
| 1726 | (defun comment-region (beg end &optional arg) |
| 1727 | "Comment the region; third arg numeric means use ARG comment characters. |
| 1728 | If ARG is negative, delete that many comment characters instead. |
| 1729 | Comments are terminated on each line, even for syntax in which newline does |
| 1730 | not end the comment. Blank lines do not get comments." |
| 1731 | ;; if someone wants it to only put a comment-start at the beginning and |
| 1732 | ;; comment-end at the end then typing it, C-x C-x, closing it, C-x C-x |
| 1733 | ;; is easy enough. No option is made here for other than commenting |
| 1734 | ;; every line. |
| 1735 | (interactive "r\np") |
| 1736 | (or comment-start (error "No comment syntax is defined")) |
| 1737 | (if (> beg end) (let (mid) (setq mid beg beg end end mid))) |
| 1738 | (save-excursion |
| 1739 | (save-restriction |
| 1740 | (let ((cs comment-start) (ce comment-end)) |
| 1741 | (cond ((not arg) (setq arg 1)) |
| 1742 | ((> arg 1) |
| 1743 | (while (> (setq arg (1- arg)) 0) |
| 1744 | (setq cs (concat cs comment-start) |
| 1745 | ce (concat ce comment-end))))) |
| 1746 | (narrow-to-region beg end) |
| 1747 | (goto-char beg) |
| 1748 | (while (not (eobp)) |
| 1749 | (if (< arg 0) |
| 1750 | (let ((count arg)) |
| 1751 | (while (and (> 1 (setq count (1+ count))) |
| 1752 | (looking-at (regexp-quote cs))) |
| 1753 | (delete-char (length cs))) |
| 1754 | (if (string= "" ce) () |
| 1755 | (setq count arg) |
| 1756 | (while (> 1 (setq count (1+ count))) |
| 1757 | (end-of-line) |
| 1758 | ;; this is questionable if comment-end ends in whitespace |
| 1759 | ;; that is pretty brain-damaged though |
| 1760 | (skip-chars-backward " \t") |
| 1761 | (backward-char (length ce)) |
| 1762 | (if (looking-at (regexp-quote ce)) |
| 1763 | (delete-char (length ce))))) |
| 1764 | (forward-line 1)) |
| 1765 | (if (looking-at "[ \t]*$") () |
| 1766 | (insert cs) |
| 1767 | (if (string= "" ce) () |
| 1768 | (end-of-line) |
| 1769 | (insert ce))) |
| 1770 | (search-forward "\n" nil 'move))))))) |
| 1771 | \f |
| 1772 | (defun backward-word (arg) |
| 1773 | "Move backward until encountering the end of a word. |
| 1774 | With argument, do this that many times. |
| 1775 | In programs, it is faster to call `forward-word' with negative arg." |
| 1776 | (interactive "p") |
| 1777 | (forward-word (- arg))) |
| 1778 | |
| 1779 | (defun mark-word (arg) |
| 1780 | "Set mark arg words away from point." |
| 1781 | (interactive "p") |
| 1782 | (push-mark |
| 1783 | (save-excursion |
| 1784 | (forward-word arg) |
| 1785 | (point)) |
| 1786 | nil t)) |
| 1787 | |
| 1788 | (defun kill-word (arg) |
| 1789 | "Kill characters forward until encountering the end of a word. |
| 1790 | With argument, do this that many times." |
| 1791 | (interactive "p") |
| 1792 | (kill-region (point) (save-excursion (forward-word arg) (point)))) |
| 1793 | |
| 1794 | (defun backward-kill-word (arg) |
| 1795 | "Kill characters backward until encountering the end of a word. |
| 1796 | With argument, do this that many times." |
| 1797 | (interactive "p") |
| 1798 | (kill-word (- arg))) |
| 1799 | |
| 1800 | (defun current-word () |
| 1801 | "Return the word point is on as a string, if it's between two |
| 1802 | word-constituent characters. If not, but it immediately follows one, |
| 1803 | move back first. Otherwise, if point precedes a word constituent, |
| 1804 | move forward first. Otherwise, move backwards until a word constituent |
| 1805 | is found and get that word; if you reach a newline first, move forward |
| 1806 | instead." |
| 1807 | (interactive) |
| 1808 | (save-excursion |
| 1809 | (let ((oldpoint (point)) (start (point)) (end (point))) |
| 1810 | (skip-syntax-backward "w_") (setq start (point)) |
| 1811 | (goto-char oldpoint) |
| 1812 | (skip-syntax-forward "w_") (setq end (point)) |
| 1813 | (if (and (eq start oldpoint) (eq end oldpoint)) |
| 1814 | (progn |
| 1815 | (skip-syntax-backward "^w_" |
| 1816 | (save-excursion (beginning-of-line) (point))) |
| 1817 | (if (eq (preceding-char) ?\n) |
| 1818 | (progn |
| 1819 | (skip-syntax-forward "^w_") |
| 1820 | (setq start (point)) |
| 1821 | (skip-syntax-forward "w_") |
| 1822 | (setq end (point))) |
| 1823 | (setq end (point)) |
| 1824 | (skip-syntax-backward "w_") |
| 1825 | (setq start (point))))) |
| 1826 | (buffer-substring start end)))) |
| 1827 | \f |
| 1828 | (defconst fill-prefix nil |
| 1829 | "*String for filling to insert at front of new line, or nil for none. |
| 1830 | Setting this variable automatically makes it local to the current buffer.") |
| 1831 | (make-variable-buffer-local 'fill-prefix) |
| 1832 | |
| 1833 | (defconst auto-fill-inhibit-regexp nil |
| 1834 | "*Regexp to match lines which should not be auto-filled.") |
| 1835 | |
| 1836 | (defun do-auto-fill () |
| 1837 | (let (give-up) |
| 1838 | (or (and auto-fill-inhibit-regexp |
| 1839 | (save-excursion (beginning-of-line) |
| 1840 | (looking-at auto-fill-inhibit-regexp))) |
| 1841 | (while (and (not give-up) (> (current-column) fill-column)) |
| 1842 | (let ((fill-point |
| 1843 | (let ((opoint (point))) |
| 1844 | (save-excursion |
| 1845 | (move-to-column (1+ fill-column)) |
| 1846 | (skip-chars-backward "^ \t\n") |
| 1847 | (if (bolp) |
| 1848 | (re-search-forward "[ \t]" opoint t)) |
| 1849 | (skip-chars-backward " \t") |
| 1850 | (point))))) |
| 1851 | ;; If there is a space on the line before fill-point, |
| 1852 | ;; and nonspaces precede it, break the line there. |
| 1853 | (if (save-excursion |
| 1854 | (goto-char fill-point) |
| 1855 | (not (bolp))) |
| 1856 | ;; If point is at the fill-point, do not `save-excursion'. |
| 1857 | ;; Otherwise, if a comment prefix or fill-prefix is inserted, |
| 1858 | ;; point will end up before it rather than after it. |
| 1859 | (if (save-excursion |
| 1860 | (skip-chars-backward " \t") |
| 1861 | (= (point) fill-point)) |
| 1862 | (indent-new-comment-line) |
| 1863 | (save-excursion |
| 1864 | (goto-char fill-point) |
| 1865 | (indent-new-comment-line))) |
| 1866 | ;; No place to break => stop trying. |
| 1867 | (setq give-up t))))))) |
| 1868 | |
| 1869 | (defconst comment-multi-line nil |
| 1870 | "*Non-nil means \\[indent-new-comment-line] should continue same comment |
| 1871 | on new line, with no new terminator or starter. |
| 1872 | This is obsolete because you might as well use \\[newline-and-indent].") |
| 1873 | |
| 1874 | (defun indent-new-comment-line () |
| 1875 | "Break line at point and indent, continuing comment if presently within one. |
| 1876 | The body of the continued comment is indented under the previous comment line. |
| 1877 | |
| 1878 | This command is intended for styles where you write a comment per line, |
| 1879 | starting a new comment (and terminating it if necessary) on each line. |
| 1880 | If you want to continue one comment across several lines, use \\[newline-and-indent]." |
| 1881 | (interactive "*") |
| 1882 | (let (comcol comstart) |
| 1883 | (skip-chars-backward " \t") |
| 1884 | (delete-region (point) |
| 1885 | (progn (skip-chars-forward " \t") |
| 1886 | (point))) |
| 1887 | (insert ?\n) |
| 1888 | (if (not comment-multi-line) |
| 1889 | (save-excursion |
| 1890 | (if (and comment-start-skip |
| 1891 | (let ((opoint (point))) |
| 1892 | (forward-line -1) |
| 1893 | (re-search-forward comment-start-skip opoint t))) |
| 1894 | ;; The old line is a comment. |
| 1895 | ;; Set WIN to the pos of the comment-start. |
| 1896 | ;; But if the comment is empty, look at preceding lines |
| 1897 | ;; to find one that has a nonempty comment. |
| 1898 | (let ((win (match-beginning 0))) |
| 1899 | (while (and (eolp) (not (bobp)) |
| 1900 | (let (opoint) |
| 1901 | (beginning-of-line) |
| 1902 | (setq opoint (point)) |
| 1903 | (forward-line -1) |
| 1904 | (re-search-forward comment-start-skip opoint t))) |
| 1905 | (setq win (match-beginning 0))) |
| 1906 | ;; Indent this line like what we found. |
| 1907 | (goto-char win) |
| 1908 | (setq comcol (current-column)) |
| 1909 | (setq comstart (buffer-substring (point) (match-end 0))))))) |
| 1910 | (if comcol |
| 1911 | (let ((comment-column comcol) |
| 1912 | (comment-start comstart) |
| 1913 | (comment-end comment-end)) |
| 1914 | (and comment-end (not (equal comment-end "")) |
| 1915 | ; (if (not comment-multi-line) |
| 1916 | (progn |
| 1917 | (forward-char -1) |
| 1918 | (insert comment-end) |
| 1919 | (forward-char 1)) |
| 1920 | ; (setq comment-column (+ comment-column (length comment-start)) |
| 1921 | ; comment-start "") |
| 1922 | ; ) |
| 1923 | ) |
| 1924 | (if (not (eolp)) |
| 1925 | (setq comment-end "")) |
| 1926 | (insert ?\n) |
| 1927 | (forward-char -1) |
| 1928 | (indent-for-comment) |
| 1929 | (save-excursion |
| 1930 | ;; Make sure we delete the newline inserted above. |
| 1931 | (end-of-line) |
| 1932 | (delete-char 1))) |
| 1933 | (if fill-prefix |
| 1934 | (insert fill-prefix) |
| 1935 | (indent-according-to-mode))))) |
| 1936 | |
| 1937 | (defun auto-fill-mode (&optional arg) |
| 1938 | "Toggle auto-fill mode. |
| 1939 | With arg, turn auto-fill mode on if and only if arg is positive. |
| 1940 | In auto-fill mode, inserting a space at a column beyond fill-column |
| 1941 | automatically breaks the line at a previous space." |
| 1942 | (interactive "P") |
| 1943 | (prog1 (setq auto-fill-function |
| 1944 | (if (if (null arg) |
| 1945 | (not auto-fill-function) |
| 1946 | (> (prefix-numeric-value arg) 0)) |
| 1947 | 'do-auto-fill |
| 1948 | nil)) |
| 1949 | ;; update mode-line |
| 1950 | (set-buffer-modified-p (buffer-modified-p)))) |
| 1951 | |
| 1952 | (defun turn-on-auto-fill () |
| 1953 | "Unconditionally turn on Auto Fill mode." |
| 1954 | (auto-fill-mode 1)) |
| 1955 | |
| 1956 | (defun set-fill-column (arg) |
| 1957 | "Set `fill-column' to current column, or to argument if given. |
| 1958 | The variable `fill-column' has a separate value for each buffer." |
| 1959 | (interactive "P") |
| 1960 | (setq fill-column (if (integerp arg) arg (current-column))) |
| 1961 | (message "fill-column set to %d" fill-column)) |
| 1962 | \f |
| 1963 | (defun set-selective-display (arg) |
| 1964 | "Set `selective-display' to ARG; clear it if no arg. |
| 1965 | When the value of `selective-display' is a number > 0, |
| 1966 | lines whose indentation is >= that value are not displayed. |
| 1967 | The variable `selective-display' has a separate value for each buffer." |
| 1968 | (interactive "P") |
| 1969 | (if (eq selective-display t) |
| 1970 | (error "selective-display already in use for marked lines")) |
| 1971 | (let ((current-vpos |
| 1972 | (save-restriction |
| 1973 | (narrow-to-region (point-min) (point)) |
| 1974 | (goto-char (window-start)) |
| 1975 | (vertical-motion (window-height))))) |
| 1976 | (setq selective-display |
| 1977 | (and arg (prefix-numeric-value arg))) |
| 1978 | (recenter current-vpos)) |
| 1979 | (set-window-start (selected-window) (window-start (selected-window))) |
| 1980 | (princ "selective-display set to " t) |
| 1981 | (prin1 selective-display t) |
| 1982 | (princ "." t)) |
| 1983 | |
| 1984 | (defconst overwrite-mode-textual " Ovwrt" |
| 1985 | "The string displayed in the mode line when in overwrite mode.") |
| 1986 | (defconst overwrite-mode-binary " Bin Ovwrt" |
| 1987 | "The string displayed in the mode line when in binary overwrite mode.") |
| 1988 | |
| 1989 | (defun overwrite-mode (arg) |
| 1990 | "Toggle overwrite mode. |
| 1991 | With arg, turn overwrite mode on iff arg is positive. |
| 1992 | In overwrite mode, printing characters typed in replace existing text |
| 1993 | on a one-for-one basis, rather than pushing it to the right. At the |
| 1994 | end of a line, such characters extend the line. Before a tab, |
| 1995 | such characters insert until the tab is filled in. |
| 1996 | \\[quoted-insert] still inserts characters in overwrite mode; this |
| 1997 | is supposed to make it easier to insert characters when necessary." |
| 1998 | (interactive "P") |
| 1999 | (setq overwrite-mode |
| 2000 | (if (if (null arg) (not overwrite-mode) |
| 2001 | (> (prefix-numeric-value arg) 0)) |
| 2002 | 'overwrite-mode-textual)) |
| 2003 | (force-mode-line-update)) |
| 2004 | |
| 2005 | (defun binary-overwrite-mode (arg) |
| 2006 | "Toggle binary overwrite mode. |
| 2007 | With arg, turn binary overwrite mode on iff arg is positive. |
| 2008 | In binary overwrite mode, printing characters typed in replace |
| 2009 | existing text. Newlines are not treated specially, so typing at the |
| 2010 | end of a line joins the line to the next, with the typed character |
| 2011 | between them. Typing before a tab character simply replaces the tab |
| 2012 | with the character typed. |
| 2013 | \\[quoted-insert] replaces the text at the cursor, just as ordinary |
| 2014 | typing characters do. |
| 2015 | |
| 2016 | Note that binary overwrite mode is not its own minor mode; it is a |
| 2017 | specialization of overwrite-mode, entered by setting the |
| 2018 | `overwrite-mode' variable to `overwrite-mode-binary'." |
| 2019 | (interactive "P") |
| 2020 | (setq overwrite-mode |
| 2021 | (if (if (null arg) |
| 2022 | (not (eq overwrite-mode 'overwrite-mode-binary)) |
| 2023 | (> (prefix-numeric-value arg) 0)) |
| 2024 | 'overwrite-mode-binary)) |
| 2025 | (force-mode-line-update)) |
| 2026 | \f |
| 2027 | (defvar line-number-mode nil |
| 2028 | "*Non-nil means display line number in mode line.") |
| 2029 | |
| 2030 | (defun line-number-mode (arg) |
| 2031 | "Toggle Line Number mode. |
| 2032 | With arg, turn Line Number mode on iff arg is positive. |
| 2033 | When Line Number mode is enabled, the line number appears |
| 2034 | in the mode line." |
| 2035 | (interactive "P") |
| 2036 | (setq line-number-mode |
| 2037 | (if (null arg) (not line-number-mode) |
| 2038 | (> (prefix-numeric-value arg) 0))) |
| 2039 | (force-mode-line-update)) |
| 2040 | |
| 2041 | (defvar blink-matching-paren t |
| 2042 | "*Non-nil means show matching open-paren when close-paren is inserted.") |
| 2043 | |
| 2044 | (defconst blink-matching-paren-distance 12000 |
| 2045 | "*If non-nil, is maximum distance to search for matching open-paren.") |
| 2046 | |
| 2047 | (defun blink-matching-open () |
| 2048 | "Move cursor momentarily to the beginning of the sexp before point." |
| 2049 | (interactive) |
| 2050 | (and (> (point) (1+ (point-min))) |
| 2051 | (/= (char-syntax (char-after (- (point) 2))) ?\\ ) |
| 2052 | blink-matching-paren |
| 2053 | (let* ((oldpos (point)) |
| 2054 | (blinkpos) |
| 2055 | (mismatch)) |
| 2056 | (save-excursion |
| 2057 | (save-restriction |
| 2058 | (if blink-matching-paren-distance |
| 2059 | (narrow-to-region (max (point-min) |
| 2060 | (- (point) blink-matching-paren-distance)) |
| 2061 | oldpos)) |
| 2062 | (condition-case () |
| 2063 | (setq blinkpos (scan-sexps oldpos -1)) |
| 2064 | (error nil))) |
| 2065 | (and blinkpos (/= (char-syntax (char-after blinkpos)) |
| 2066 | ?\$) |
| 2067 | (setq mismatch |
| 2068 | (/= (char-after (1- oldpos)) |
| 2069 | (logand (lsh (aref (syntax-table) |
| 2070 | (char-after blinkpos)) |
| 2071 | -8) |
| 2072 | 255)))) |
| 2073 | (if mismatch (setq blinkpos nil)) |
| 2074 | (if blinkpos |
| 2075 | (progn |
| 2076 | (goto-char blinkpos) |
| 2077 | (if (pos-visible-in-window-p) |
| 2078 | (sit-for 1) |
| 2079 | (goto-char blinkpos) |
| 2080 | (message |
| 2081 | "Matches %s" |
| 2082 | (if (save-excursion |
| 2083 | (skip-chars-backward " \t") |
| 2084 | (not (bolp))) |
| 2085 | (buffer-substring (progn (beginning-of-line) (point)) |
| 2086 | (1+ blinkpos)) |
| 2087 | (buffer-substring blinkpos |
| 2088 | (progn |
| 2089 | (forward-char 1) |
| 2090 | (skip-chars-forward "\n \t") |
| 2091 | (end-of-line) |
| 2092 | (point))))))) |
| 2093 | (cond (mismatch |
| 2094 | (message "Mismatched parentheses")) |
| 2095 | ((not blink-matching-paren-distance) |
| 2096 | (message "Unmatched parenthesis")))))))) |
| 2097 | |
| 2098 | ;Turned off because it makes dbx bomb out. |
| 2099 | (setq blink-paren-function 'blink-matching-open) |
| 2100 | |
| 2101 | ;; This executes C-g typed while Emacs is waiting for a command. |
| 2102 | ;; Quitting out of a program does not go through here; |
| 2103 | ;; that happens in the QUIT macro at the C code level. |
| 2104 | (defun keyboard-quit () |
| 2105 | "Signal a quit condition. |
| 2106 | During execution of Lisp code, this character causes a quit directly. |
| 2107 | At top-level, as an editor command, this simply beeps." |
| 2108 | (interactive) |
| 2109 | (and transient-mark-mode mark-active |
| 2110 | (progn |
| 2111 | (setq mark-active nil) |
| 2112 | (run-hooks 'deactivate-mark-hook))) |
| 2113 | (signal 'quit nil)) |
| 2114 | |
| 2115 | (define-key global-map "\C-g" 'keyboard-quit) |
| 2116 | \f |
| 2117 | (defun set-variable (var val) |
| 2118 | "Set VARIABLE to VALUE. VALUE is a Lisp object. |
| 2119 | When using this interactively, supply a Lisp expression for VALUE. |
| 2120 | If you want VALUE to be a string, you must surround it with doublequotes. |
| 2121 | |
| 2122 | If VARIABLE has a `variable-interactive' property, that is used as if |
| 2123 | it were the arg to `interactive' (which see) to interactively read the value." |
| 2124 | (interactive |
| 2125 | (let* ((var (read-variable "Set variable: ")) |
| 2126 | (minibuffer-help-form |
| 2127 | '(funcall myhelp)) |
| 2128 | (myhelp |
| 2129 | (function |
| 2130 | (lambda () |
| 2131 | (with-output-to-temp-buffer "*Help*" |
| 2132 | (prin1 var) |
| 2133 | (princ "\nDocumentation:\n") |
| 2134 | (princ (substring (documentation-property var 'variable-documentation) |
| 2135 | 1)) |
| 2136 | (if (boundp var) |
| 2137 | (let ((print-length 20)) |
| 2138 | (princ "\n\nCurrent value: ") |
| 2139 | (prin1 (symbol-value var)))) |
| 2140 | nil))))) |
| 2141 | (list var |
| 2142 | (let ((prop (get var 'variable-interactive))) |
| 2143 | (if prop |
| 2144 | ;; Use VAR's `variable-interactive' property |
| 2145 | ;; as an interactive spec for prompting. |
| 2146 | (call-interactively (list 'lambda '(arg) |
| 2147 | (list 'interactive prop) |
| 2148 | 'arg)) |
| 2149 | (eval-minibuffer (format "Set %s to value: " var))))))) |
| 2150 | (set var val)) |
| 2151 | |
| 2152 | ;;; simple.el ends here |