| 1 | ;;; ehelp.el --- bindings for electric-help mode |
| 2 | |
| 3 | ;; Copyright (C) 1986, 1995 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Maintainer: FSF |
| 6 | ;; Keywords: help, extensions |
| 7 | |
| 8 | ;; This file is part of GNU Emacs. |
| 9 | |
| 10 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 11 | ;; it under the terms of the GNU General Public License as published by |
| 12 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 13 | ;; any later version. |
| 14 | |
| 15 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 16 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 17 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 18 | ;; GNU General Public License for more details. |
| 19 | |
| 20 | ;; You should have received a copy of the GNU General Public License |
| 21 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 22 | ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, |
| 23 | ;; Boston, MA 02111-1307, USA. |
| 24 | |
| 25 | ;;; Commentary: |
| 26 | |
| 27 | ;; This package provides a pre-packaged `Electric Help Mode' for |
| 28 | ;; browsing on-line help screens. There is one entry point, |
| 29 | ;; `with-electric-help'; all you have to give it is a no-argument |
| 30 | ;; function that generates the actual text of the help into the current |
| 31 | ;; buffer. |
| 32 | |
| 33 | ;; To make this the default, you must do |
| 34 | ;; (require 'ehelp) |
| 35 | ;; (define-key global-map "\C-h" 'ehelp-command) |
| 36 | ;; (define-key global-map [help] 'ehelp-command) |
| 37 | ;; (define-key global-map [f1] 'ehelp-command) |
| 38 | |
| 39 | ;;; Code: |
| 40 | |
| 41 | (require 'electric) |
| 42 | (defvar electric-help-map () |
| 43 | "Keymap defining commands available in `electric-help-mode'.") |
| 44 | |
| 45 | (defvar electric-help-form-to-execute nil) |
| 46 | |
| 47 | (put 'electric-help-undefined 'suppress-keymap t) |
| 48 | (if electric-help-map |
| 49 | () |
| 50 | (let ((map (make-keymap))) |
| 51 | ;; allow all non-self-inserting keys - search, scroll, etc, but |
| 52 | ;; let M-x and C-x exit ehelp mode and retain buffer: |
| 53 | (suppress-keymap map) |
| 54 | (define-key map "\C-u" 'electric-help-undefined) |
| 55 | (define-key map [?\C-0] 'electric-help-undefined) |
| 56 | (define-key map [?\C-1] 'electric-help-undefined) |
| 57 | (define-key map [?\C-2] 'electric-help-undefined) |
| 58 | (define-key map [?\C-3] 'electric-help-undefined) |
| 59 | (define-key map [?\C-4] 'electric-help-undefined) |
| 60 | (define-key map [?\C-5] 'electric-help-undefined) |
| 61 | (define-key map [?\C-6] 'electric-help-undefined) |
| 62 | (define-key map [?\C-7] 'electric-help-undefined) |
| 63 | (define-key map [?\C-8] 'electric-help-undefined) |
| 64 | (define-key map [?\C-9] 'electric-help-undefined) |
| 65 | (define-key map (char-to-string help-char) 'electric-help-help) |
| 66 | (define-key map "?" 'electric-help-help) |
| 67 | (define-key map " " 'scroll-up) |
| 68 | (define-key map "\^?" 'scroll-down) |
| 69 | (define-key map "." 'beginning-of-buffer) |
| 70 | (define-key map "<" 'beginning-of-buffer) |
| 71 | (define-key map ">" 'end-of-buffer) |
| 72 | ;(define-key map "\C-g" 'electric-help-exit) |
| 73 | (define-key map "q" 'electric-help-exit) |
| 74 | (define-key map "Q" 'electric-help-exit) |
| 75 | ;;a better key than this? |
| 76 | (define-key map "r" 'electric-help-retain) |
| 77 | (define-key map "R" 'electric-help-retain) |
| 78 | (define-key map "\ex" 'electric-help-execute-extended) |
| 79 | (define-key map "\C-x" 'electric-help-ctrl-x-prefix) |
| 80 | |
| 81 | (setq electric-help-map map))) |
| 82 | |
| 83 | (defun electric-help-mode () |
| 84 | "`with-electric-help' temporarily places its buffer in this mode. |
| 85 | \(On exit from `with-electric-help', the buffer is put in `default-major-mode'.)" |
| 86 | (setq buffer-read-only t) |
| 87 | (setq mode-name "Help") |
| 88 | (setq major-mode 'help) |
| 89 | (setq mode-line-buffer-identification '(" Help: %b")) |
| 90 | (use-local-map electric-help-map) |
| 91 | (add-hook 'mouse-leave-buffer-hook 'electric-help-retain) |
| 92 | (view-mode -1) |
| 93 | ;; this is done below in with-electric-help |
| 94 | ;(run-hooks 'electric-help-mode-hook) |
| 95 | ) |
| 96 | |
| 97 | ;;;###autoload |
| 98 | (defun with-electric-help (thunk &optional buffer noerase minheight) |
| 99 | "Pop up an \"electric\" help buffer. |
| 100 | The arguments are THUNK &optional BUFFER NOERASE MINHEIGHT. |
| 101 | THUNK is a function of no arguments which is called to initialize the |
| 102 | contents of BUFFER. BUFFER defaults to `*Help*'. BUFFER will be |
| 103 | erased before THUNK is called unless NOERASE is non-nil. THUNK will |
| 104 | be called while BUFFER is current and with `standard-output' bound to |
| 105 | the buffer specified by BUFFER. |
| 106 | |
| 107 | If THUNK returns nil, we display BUFFER starting at the top, and |
| 108 | shrink the window to fit. If THUNK returns non-nil, we don't do those things. |
| 109 | |
| 110 | After THUNK has been called, this function \"electrically\" pops up a window |
| 111 | in which BUFFER is displayed and allows the user to scroll through that buffer |
| 112 | in electric-help-mode. The window's height will be at least MINHEIGHT if |
| 113 | this value is non-nil. |
| 114 | |
| 115 | If THUNK returns nil, we display BUFFER starting at the top, and |
| 116 | shrink the window to fit. If THUNK returns non-nil, we don't do those |
| 117 | things. |
| 118 | |
| 119 | When the user exits (with `electric-help-exit', or otherwise) the help |
| 120 | buffer's window disappears (i.e., we use `save-window-excursion') |
| 121 | BUFFER is put into `default-major-mode' (or `fundamental-mode') when we exit." |
| 122 | (setq buffer (get-buffer-create (or buffer "*Help*"))) |
| 123 | (let ((one (one-window-p t)) |
| 124 | (config (current-window-configuration)) |
| 125 | (bury nil) |
| 126 | (electric-help-form-to-execute nil)) |
| 127 | (unwind-protect |
| 128 | (save-excursion |
| 129 | (if one (goto-char (window-start (selected-window)))) |
| 130 | (let ((pop-up-windows t)) |
| 131 | (pop-to-buffer buffer)) |
| 132 | (save-excursion |
| 133 | (set-buffer buffer) |
| 134 | (if (and minheight (< (window-height) minheight)) |
| 135 | (enlarge-window (- minheight (window-height)))) |
| 136 | (electric-help-mode) |
| 137 | (setq buffer-read-only nil) |
| 138 | (or noerase |
| 139 | (erase-buffer))) |
| 140 | (let ((standard-output buffer)) |
| 141 | (if (not (funcall thunk)) |
| 142 | (progn |
| 143 | (set-buffer buffer) |
| 144 | (set-buffer-modified-p nil) |
| 145 | (goto-char (point-min)) |
| 146 | (if one (shrink-window-if-larger-than-buffer (selected-window)))))) |
| 147 | (set-buffer buffer) |
| 148 | (run-hooks 'electric-help-mode-hook) |
| 149 | (setq buffer-read-only t) |
| 150 | (if (eq (car-safe (electric-help-command-loop)) |
| 151 | 'retain) |
| 152 | (setq config (current-window-configuration)) |
| 153 | (setq bury t))) |
| 154 | (message "") |
| 155 | (set-buffer buffer) |
| 156 | (setq buffer-read-only nil) |
| 157 | (condition-case () |
| 158 | (funcall (or default-major-mode 'fundamental-mode)) |
| 159 | (error nil)) |
| 160 | (set-window-configuration config) |
| 161 | (if bury |
| 162 | (progn |
| 163 | ;;>> Perhaps this shouldn't be done. |
| 164 | ;; so that when we say "Press space to bury" we mean it |
| 165 | (replace-buffer-in-windows buffer) |
| 166 | ;; must do this outside of save-window-excursion |
| 167 | (bury-buffer buffer))) |
| 168 | (eval electric-help-form-to-execute)))) |
| 169 | |
| 170 | (defun electric-help-command-loop () |
| 171 | (catch 'exit |
| 172 | (if (pos-visible-in-window-p (point-max)) |
| 173 | (progn (message "%s" (substitute-command-keys "<<< Press Space to bury the help buffer, Press \\[electric-help-retain] to retain it >>>")) |
| 174 | (if (equal (setq unread-command-events (list (read-event))) |
| 175 | '(?\ )) |
| 176 | (progn (setq unread-command-events nil) |
| 177 | (throw 'exit t))))) |
| 178 | (let (up down both neither |
| 179 | (standard (and (eq (key-binding " ") |
| 180 | 'scroll-up) |
| 181 | (eq (key-binding "\^?") |
| 182 | 'scroll-down) |
| 183 | (eq (key-binding "q") |
| 184 | 'electric-help-exit) |
| 185 | (eq (key-binding "r") |
| 186 | 'electric-help-retain)))) |
| 187 | (Electric-command-loop |
| 188 | 'exit |
| 189 | (function (lambda () |
| 190 | (sit-for 0) ;necessary if last command was end-of-buffer or |
| 191 | ;beginning-of-buffer - otherwise pos-visible-in-window-p |
| 192 | ;will yield a wrong result. |
| 193 | (let ((min (pos-visible-in-window-p (point-min))) |
| 194 | (max (pos-visible-in-window-p (point-max)))) |
| 195 | (cond (isearch-mode 'noprompt) |
| 196 | ((and min max) |
| 197 | (cond (standard "Press q to exit, r to retain ") |
| 198 | (neither) |
| 199 | (t (setq neither (substitute-command-keys "Press \\[electric-help-exit] to exit, \\[electric-help-retain] to retain "))))) |
| 200 | (min |
| 201 | (cond (standard "Press SPC to scroll, q to exit, r to retain ") |
| 202 | (up) |
| 203 | (t (setq up (substitute-command-keys "Press \\[scroll-up] to scroll, \\[electric-help-exit] to exit, \\[electric-help-retain] to retain "))))) |
| 204 | (max |
| 205 | (cond (standard "Press DEL to scroll back, q to exit, r to retain ") |
| 206 | (down) |
| 207 | (t (setq down (substitute-command-keys "Press \\[scroll-down] to scroll back, \\[electric-help-exit] to exit, \\[electric-help-retain] to retain "))))) |
| 208 | (t |
| 209 | (cond (standard "Press SPC to scroll, DEL to scroll back, q to exit, r to retain ") |
| 210 | (both) |
| 211 | (t (setq both (substitute-command-keys "Press \\[scroll-up] to scroll, \\[scroll-down] to scroll back, \\[electric-help-exit] to exit, \\[electric-help-retain] to retain "))))))))) |
| 212 | t)))) |
| 213 | |
| 214 | |
| 215 | \f |
| 216 | ;(defun electric-help-scroll-up (arg) |
| 217 | ; ">>>Doc" |
| 218 | ; (interactive "P") |
| 219 | ; (if (and (null arg) (pos-visible-in-window-p (point-max))) |
| 220 | ; (electric-help-exit) |
| 221 | ; (scroll-up arg))) |
| 222 | |
| 223 | (defun electric-help-exit () |
| 224 | ">>>Doc" |
| 225 | (interactive) |
| 226 | (throw 'exit t)) |
| 227 | |
| 228 | (defun electric-help-retain () |
| 229 | "Exit `electric-help', retaining the current window/buffer configuration. |
| 230 | \(The *Help* buffer will not be selected, but \\[switch-to-buffer-other-window] RET |
| 231 | will select it.)" |
| 232 | (interactive) |
| 233 | ;; Make sure that we don't throw twice, even if two events cause |
| 234 | ;; calling this function: |
| 235 | (if (memq 'electric-help-retain mouse-leave-buffer-hook) |
| 236 | (progn |
| 237 | (remove-hook 'mouse-leave-buffer-hook 'electric-help-retain) |
| 238 | (throw 'exit '(retain))))) |
| 239 | |
| 240 | |
| 241 | (defun electric-help-undefined () |
| 242 | (interactive) |
| 243 | (error "%s is undefined -- Press %s to exit" |
| 244 | (mapconcat 'single-key-description (this-command-keys) " ") |
| 245 | (if (eq (key-binding "q") 'electric-help-exit) |
| 246 | "q" |
| 247 | (substitute-command-keys "\\[electric-help-exit]")))) |
| 248 | |
| 249 | |
| 250 | ;>>> this needs to be hairified (recursive help, anybody?) |
| 251 | (defun electric-help-help () |
| 252 | (interactive) |
| 253 | (if (and (eq (key-binding "q") 'electric-help-exit) |
| 254 | (eq (key-binding " ") 'scroll-up) |
| 255 | (eq (key-binding "\^?") 'scroll-down) |
| 256 | (eq (key-binding "r") 'electric-help-retain)) |
| 257 | (message "SPC scrolls up, DEL scrolls down, q exits burying help buffer, r exits") |
| 258 | (message "%s" (substitute-command-keys "\\[scroll-up] scrolls up, \\[scroll-down] scrolls down, \\[electric-help-exit] exits burying help buffer, \\[electric-help-retain] exits"))) |
| 259 | (sit-for 2)) |
| 260 | |
| 261 | \f |
| 262 | ;;;###autoload |
| 263 | (defun electric-helpify (fun &optional name) |
| 264 | (let ((name (or name "*Help*"))) |
| 265 | (if (save-window-excursion |
| 266 | ;; kludge-o-rama |
| 267 | (let* ((p (symbol-function 'print-help-return-message)) |
| 268 | (b (get-buffer name)) |
| 269 | (m (buffer-modified-p b))) |
| 270 | (and b (not (get-buffer-window b)) |
| 271 | (setq b nil)) |
| 272 | (unwind-protect |
| 273 | (progn |
| 274 | (message "%s..." (capitalize (symbol-name fun))) |
| 275 | ;; with-output-to-temp-buffer marks the buffer as unmodified. |
| 276 | ;; kludging excessively and relying on that as some sort |
| 277 | ;; of indication leads to the following abomination... |
| 278 | ;;>> This would be doable without such icky kludges if either |
| 279 | ;;>> (a) there were a function to read the interactive |
| 280 | ;;>> args for a command and return a list of those args. |
| 281 | ;;>> (To which one would then just apply the command) |
| 282 | ;;>> (The only problem with this is that interactive-p |
| 283 | ;;>> would break, but that is such a misfeature in |
| 284 | ;;>> any case that I don't care) |
| 285 | ;;>> It is easy to do this for emacs-lisp functions; |
| 286 | ;;>> the only problem is getting the interactive spec |
| 287 | ;;>> for subrs |
| 288 | ;;>> (b) there were a function which returned a |
| 289 | ;;>> modification-tick for a buffer. One could tell |
| 290 | ;;>> whether a buffer had changed by whether the |
| 291 | ;;>> modification-tick were different. |
| 292 | ;;>> (Presumably there would have to be a way to either |
| 293 | ;;>> restore the tick to some previous value, or to |
| 294 | ;;>> suspend updating of the tick in order to allow |
| 295 | ;;>> things like momentary-string-display) |
| 296 | (and b |
| 297 | (save-excursion |
| 298 | (set-buffer b) |
| 299 | (set-buffer-modified-p t))) |
| 300 | (fset 'print-help-return-message 'ignore) |
| 301 | (call-interactively fun) |
| 302 | (and (get-buffer name) |
| 303 | (get-buffer-window (get-buffer name)) |
| 304 | (or (not b) |
| 305 | (not (eq b (get-buffer name))) |
| 306 | (not (buffer-modified-p b))))) |
| 307 | (fset 'print-help-return-message p) |
| 308 | (and b (buffer-name b) |
| 309 | (save-excursion |
| 310 | (set-buffer b) |
| 311 | (set-buffer-modified-p m)))))) |
| 312 | (with-electric-help 'ignore name t)))) |
| 313 | |
| 314 | \f |
| 315 | |
| 316 | ;; This is to be bound to M-x in ehelp mode. Retains ehelp buffer and then |
| 317 | ;; continues with execute-extended-command. |
| 318 | (defun electric-help-execute-extended (prefixarg) |
| 319 | (interactive "p") |
| 320 | (setq electric-help-form-to-execute '(execute-extended-command nil)) |
| 321 | (electric-help-retain)) |
| 322 | |
| 323 | ;; This is to be buond to C-x in ehelp mode. Retains ehelp buffer and then |
| 324 | ;; continues with ctrl-x prefix. |
| 325 | (defun electric-help-ctrl-x-prefix (prefixarg) |
| 326 | (interactive "p") |
| 327 | (setq electric-help-form-to-execute '(progn (message nil) (setq unread-command-char ?\C-x))) |
| 328 | (electric-help-retain)) |
| 329 | |
| 330 | \f |
| 331 | (defun electric-describe-key () |
| 332 | (interactive) |
| 333 | (electric-helpify 'describe-key)) |
| 334 | |
| 335 | (defun electric-describe-mode () |
| 336 | (interactive) |
| 337 | (electric-helpify 'describe-mode)) |
| 338 | |
| 339 | (defun electric-view-lossage () |
| 340 | (interactive) |
| 341 | (electric-helpify 'view-lossage)) |
| 342 | |
| 343 | ;(defun electric-help-for-help () |
| 344 | ; "See help-for-help" |
| 345 | ; (interactive) |
| 346 | ; ) |
| 347 | |
| 348 | (defun electric-describe-function () |
| 349 | (interactive) |
| 350 | (electric-helpify 'describe-function)) |
| 351 | |
| 352 | (defun electric-describe-variable () |
| 353 | (interactive) |
| 354 | (electric-helpify 'describe-variable)) |
| 355 | |
| 356 | (defun electric-describe-bindings () |
| 357 | (interactive) |
| 358 | (electric-helpify 'describe-bindings)) |
| 359 | |
| 360 | (defun electric-describe-syntax () |
| 361 | (interactive) |
| 362 | (electric-helpify 'describe-syntax)) |
| 363 | |
| 364 | (defun electric-command-apropos () |
| 365 | (interactive) |
| 366 | (electric-helpify 'command-apropos "*Apropos*")) |
| 367 | |
| 368 | ;(define-key help-map "a" 'electric-command-apropos) |
| 369 | |
| 370 | (defun electric-apropos () |
| 371 | (interactive) |
| 372 | (electric-helpify 'apropos)) |
| 373 | |
| 374 | \f |
| 375 | ;;;; ehelp-map |
| 376 | |
| 377 | (defvar ehelp-map ()) |
| 378 | (if ehelp-map |
| 379 | nil |
| 380 | (let ((map (copy-keymap help-map))) |
| 381 | (substitute-key-definition 'apropos 'electric-apropos map) |
| 382 | (substitute-key-definition 'command-apropos 'electric-command-apropos map) |
| 383 | (substitute-key-definition 'describe-key 'electric-describe-key map) |
| 384 | (substitute-key-definition 'describe-mode 'electric-describe-mode map) |
| 385 | (substitute-key-definition 'view-lossage 'electric-view-lossage map) |
| 386 | (substitute-key-definition 'describe-function 'electric-describe-function map) |
| 387 | (substitute-key-definition 'describe-variable 'electric-describe-variable map) |
| 388 | (substitute-key-definition 'describe-bindings 'electric-describe-bindings map) |
| 389 | (substitute-key-definition 'describe-syntax 'electric-describe-syntax map) |
| 390 | |
| 391 | (setq ehelp-map map) |
| 392 | (fset 'ehelp-command map))) |
| 393 | |
| 394 | (provide 'ehelp) |
| 395 | |
| 396 | ;;; ehelp.el ends here |