| 1 | ;;; ffap.el --- find file (or url) at point |
| 2 | |
| 3 | ;; Copyright (C) 1995-1997, 2000-2013 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Author: Michelangelo Grigni <mic@mathcs.emory.edu> |
| 6 | ;; Maintainer: FSF |
| 7 | ;; Created: 29 Mar 1993 |
| 8 | ;; Keywords: files, hypermedia, matching, mouse, convenience |
| 9 | ;; X-URL: ftp://ftp.mathcs.emory.edu/pub/mic/emacs/ |
| 10 | |
| 11 | ;; This file is part of GNU Emacs. |
| 12 | |
| 13 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 14 | ;; it under the terms of the GNU General Public License as published by |
| 15 | ;; the Free Software Foundation, either version 3 of the License, or |
| 16 | ;; (at your option) any later version. |
| 17 | |
| 18 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 19 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 20 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 21 | ;; GNU General Public License for more details. |
| 22 | |
| 23 | ;; You should have received a copy of the GNU General Public License |
| 24 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 25 | |
| 26 | \f |
| 27 | ;;; Commentary: |
| 28 | ;; |
| 29 | ;; Command find-file-at-point replaces find-file. With a prefix, it |
| 30 | ;; behaves exactly like find-file. Without a prefix, it first tries |
| 31 | ;; to guess a default file or URL from the text around the point |
| 32 | ;; (`ffap-require-prefix' swaps these behaviors). This is useful for |
| 33 | ;; following references in situations such as mail or news buffers, |
| 34 | ;; README's, MANIFEST's, and so on. Submit bugs or suggestions with |
| 35 | ;; M-x ffap-bug. |
| 36 | ;; |
| 37 | ;; For the default installation, add this line to your init file: |
| 38 | ;; |
| 39 | ;; (ffap-bindings) ; do default key bindings |
| 40 | ;; |
| 41 | ;; ffap-bindings makes the following global key bindings: |
| 42 | ;; |
| 43 | ;; C-x C-f find-file-at-point (abbreviated as ffap) |
| 44 | ;; C-x C-r ffap-read-only |
| 45 | ;; C-x C-v ffap-alternate-file |
| 46 | ;; |
| 47 | ;; C-x d dired-at-point |
| 48 | ;; C-x C-d ffap-list-directory |
| 49 | ;; |
| 50 | ;; C-x 4 f ffap-other-window |
| 51 | ;; C-x 4 r ffap-read-only-other-window |
| 52 | ;; C-x 4 d ffap-dired-other-window |
| 53 | ;; |
| 54 | ;; C-x 5 f ffap-other-frame |
| 55 | ;; C-x 5 r ffap-read-only-other-frame |
| 56 | ;; C-x 5 d ffap-dired-other-frame |
| 57 | ;; |
| 58 | ;; S-mouse-3 ffap-at-mouse |
| 59 | ;; C-S-mouse-3 ffap-menu |
| 60 | ;; |
| 61 | ;; ffap-bindings also adds hooks to make the following local bindings |
| 62 | ;; in vm, gnus, and rmail: |
| 63 | ;; |
| 64 | ;; M-l ffap-next, or ffap-gnus-next in gnus (l == "link") |
| 65 | ;; M-m ffap-menu, or ffap-gnus-menu in gnus (m == "menu") |
| 66 | ;; |
| 67 | ;; If you do not like these bindings, modify the variable |
| 68 | ;; `ffap-bindings', or write your own. |
| 69 | ;; |
| 70 | ;; If you use ange-ftp, browse-url, complete, efs, or w3, it is best |
| 71 | ;; to load or autoload them before ffap. If you use ff-paths, load it |
| 72 | ;; afterwards. Try apropos {C-h a ffap RET} to get a list of the many |
| 73 | ;; option variables. In particular, if ffap is slow, try these: |
| 74 | ;; |
| 75 | ;; (setq ffap-alist nil) ; faster, dumber prompting |
| 76 | ;; (setq ffap-machine-p-known 'accept) ; no pinging |
| 77 | ;; (setq ffap-url-regexp nil) ; disable URL features in ffap |
| 78 | ;; (setq ffap-shell-prompt-regexp nil) ; disable shell prompt stripping |
| 79 | ;; |
| 80 | ;; ffap uses `browse-url' (if found, else `w3-fetch') to fetch URL's. |
| 81 | ;; For a hairier `ffap-url-fetcher', try ffap-url.el (same ftp site). |
| 82 | ;; Also, you can add `ffap-menu-rescan' to various hooks to fontify |
| 83 | ;; the file and URL references within a buffer. |
| 84 | |
| 85 | \f |
| 86 | ;;; Change Log: |
| 87 | ;; |
| 88 | ;; The History and Contributors moved to ffap.LOG (same ftp site), |
| 89 | ;; which also has some old examples and commentary from ffap 1.5. |
| 90 | |
| 91 | \f |
| 92 | ;;; Todo list: |
| 93 | ;; * use kpsewhich |
| 94 | ;; * let "/dir/file#key" jump to key (tag or regexp) in /dir/file |
| 95 | ;; * find file of symbol if TAGS is loaded (like above) |
| 96 | ;; * break long menus into multiple panes (like imenu?) |
| 97 | ;; * notice node in "(dired)Virtual Dired" (quotes, parentheses, whitespace) |
| 98 | ;; * notice "machine.dom blah blah blah dir/file" (how?) |
| 99 | ;; * as w3 becomes standard, rewrite to rely more on its functions |
| 100 | ;; * regexp options for ffap-string-at-point, like font-lock (MCOOK) |
| 101 | ;; * v19: could replace `ffap-locate-file' with a quieter `locate-library' |
| 102 | ;; * handle "$(VAR)" in Makefiles |
| 103 | ;; * use the font-lock machinery |
| 104 | |
| 105 | \f |
| 106 | ;;; Code: |
| 107 | |
| 108 | (require 'url-parse) |
| 109 | |
| 110 | (define-obsolete-variable-alias 'ffap-version 'emacs-version "23.2") |
| 111 | |
| 112 | (defgroup ffap nil |
| 113 | "Find file or URL at point." |
| 114 | ;; Dead 2009/07/05. |
| 115 | ;; :link '(url-link :tag "URL" "ftp://ftp.mathcs.emory.edu/pub/mic/emacs/") |
| 116 | :group 'matching |
| 117 | :group 'convenience) |
| 118 | |
| 119 | ;; The code is organized in pages, separated by formfeed characters. |
| 120 | ;; See the next two pages for standard customization ideas. |
| 121 | |
| 122 | \f |
| 123 | ;;; User Variables: |
| 124 | |
| 125 | (defun ffap-symbol-value (sym &optional default) |
| 126 | "Return value of symbol SYM, if bound, or DEFAULT otherwise." |
| 127 | (if (boundp sym) (symbol-value sym) default)) |
| 128 | |
| 129 | (defcustom ffap-shell-prompt-regexp |
| 130 | ;; This used to test for some shell prompts that don't have a space |
| 131 | ;; after them. The common root shell prompt (#) is not listed since it |
| 132 | ;; also doubles up as a valid URL character. |
| 133 | "[$%><]*" |
| 134 | "Paths matching this regexp are stripped off the shell prompt. |
| 135 | If nil, ffap doesn't do shell prompt stripping." |
| 136 | :type '(choice (const :tag "Disable" nil) |
| 137 | (const :tag "Standard" "[$%><]*") |
| 138 | regexp) |
| 139 | :group 'ffap) |
| 140 | |
| 141 | (defcustom ffap-ftp-regexp "\\`/[^/:]+:" |
| 142 | "File names matching this regexp are treated as remote ffap. |
| 143 | If nil, ffap neither recognizes nor generates such names." |
| 144 | :type '(choice (const :tag "Disable" nil) |
| 145 | (const :tag "Standard" "\\`/[^/:]+:") |
| 146 | regexp) |
| 147 | :group 'ffap) |
| 148 | |
| 149 | (defcustom ffap-url-unwrap-local t |
| 150 | "If non-nil, convert some URLs to local file names before prompting. |
| 151 | Only \"file:\" and \"ftp:\" URLs are converted, and only if they |
| 152 | do not specify a host, or the host is either \"localhost\" or |
| 153 | equal to `system-name'." |
| 154 | :type 'boolean |
| 155 | :group 'ffap) |
| 156 | |
| 157 | (defcustom ffap-url-unwrap-remote '("ftp") |
| 158 | "If non-nil, convert URLs to remote file names before prompting. |
| 159 | If the value is a list of strings, that specifies a list of URL |
| 160 | schemes (e.g. \"ftp\"); in that case, only convert those URLs." |
| 161 | :type '(choice (repeat string) boolean) |
| 162 | :group 'ffap |
| 163 | :version "24.3") |
| 164 | |
| 165 | (defcustom ffap-ftp-default-user "anonymous" |
| 166 | "User name in ftp file names generated by `ffap-host-to-path'. |
| 167 | Note this name may be omitted if it equals the default |
| 168 | \(either `efs-default-user' or `ange-ftp-default-user'\)." |
| 169 | :type 'string |
| 170 | :group 'ffap) |
| 171 | |
| 172 | (defcustom ffap-rfs-regexp |
| 173 | ;; Remote file access built into file system? HP rfa or Andrew afs: |
| 174 | "\\`/\\(afs\\|net\\)/." |
| 175 | ;; afs only: (and (file-exists-p "/afs") "\\`/afs/.") |
| 176 | "Matching file names are treated as remote. Use nil to disable." |
| 177 | :type 'regexp |
| 178 | :group 'ffap) |
| 179 | |
| 180 | (defvar ffap-url-regexp |
| 181 | ;; Could just use `url-nonrelative-link' of w3, if loaded. |
| 182 | ;; This regexp is not exhaustive, it just matches common cases. |
| 183 | (concat |
| 184 | "\\(" |
| 185 | "news\\(post\\)?:\\|mailto:\\|file:" ; no host ok |
| 186 | "\\|" |
| 187 | "\\(ftp\\|https?\\|telnet\\|gopher\\|www\\|wais\\)://" ; needs host |
| 188 | "\\)." ; require one more character |
| 189 | ) |
| 190 | "Regexp matching URLs. Use nil to disable URL features in ffap.") |
| 191 | |
| 192 | (defcustom ffap-foo-at-bar-prefix "mailto" |
| 193 | "Presumed URL prefix type of strings like \"<foo.9z@bar>\". |
| 194 | Sensible values are nil, \"news\", or \"mailto\"." |
| 195 | :type '(choice (const "mailto") |
| 196 | (const "news") |
| 197 | (const :tag "Disable" nil) |
| 198 | ;; string -- possible, but not really useful |
| 199 | ) |
| 200 | :group 'ffap) |
| 201 | |
| 202 | \f |
| 203 | ;;; Peanut Gallery (More User Variables): |
| 204 | ;; |
| 205 | ;; Users of ffap occasionally suggest new features. If I consider |
| 206 | ;; those features interesting but not clear winners (a matter of |
| 207 | ;; personal taste) I try to leave options to enable them. Read |
| 208 | ;; through this section for features that you like, put an appropriate |
| 209 | ;; enabler in your init file. |
| 210 | |
| 211 | (defcustom ffap-dired-wildcards "[*?][^/]*\\'" |
| 212 | "A regexp matching filename wildcard characters, or nil. |
| 213 | |
| 214 | If `find-file-at-point' gets a filename matching this pattern, |
| 215 | and `ffap-pass-wildcards-to-dired' is nil, it passes it on to |
| 216 | `find-file' with non-nil WILDCARDS argument, which expands |
| 217 | wildcards and visits multiple files. To visit a file whose name |
| 218 | contains wildcard characters you can suppress wildcard expansion |
| 219 | by setting `find-file-wildcards'. If `find-file-at-point' gets a |
| 220 | filename matching this pattern and `ffap-pass-wildcards-to-dired' |
| 221 | is non-nil, it passes it on to `dired'. |
| 222 | |
| 223 | If `dired-at-point' gets a filename matching this pattern, |
| 224 | it passes it on to `dired'." |
| 225 | :type '(choice (const :tag "Disable" nil) |
| 226 | (const :tag "Enable" "[*?][^/]*\\'") |
| 227 | ;; regexp -- probably not useful |
| 228 | ) |
| 229 | :group 'ffap) |
| 230 | |
| 231 | (defcustom ffap-pass-wildcards-to-dired nil |
| 232 | "If non-nil, pass filenames matching `ffap-dired-wildcards' to dired." |
| 233 | :type 'boolean |
| 234 | :group 'ffap) |
| 235 | |
| 236 | (defcustom ffap-newfile-prompt nil |
| 237 | ;; Suggestion from RHOGEE, 11 Jul 1994. Disabled, I think this is |
| 238 | ;; better handled by `find-file-not-found-hooks'. |
| 239 | "Whether `find-file-at-point' prompts about a nonexistent file." |
| 240 | :type 'boolean |
| 241 | :group 'ffap) |
| 242 | |
| 243 | (defcustom ffap-require-prefix nil |
| 244 | ;; Suggestion from RHOGEE, 20 Oct 1994. |
| 245 | "If set, reverses the prefix argument to `find-file-at-point'. |
| 246 | This is nil so neophytes notice ffap. Experts may prefer to disable |
| 247 | ffap most of the time." |
| 248 | :type 'boolean |
| 249 | :group 'ffap) |
| 250 | |
| 251 | (defcustom ffap-file-finder 'find-file |
| 252 | "The command called by `find-file-at-point' to find a file." |
| 253 | :type 'function |
| 254 | :group 'ffap |
| 255 | :risky t) |
| 256 | |
| 257 | (defcustom ffap-directory-finder 'dired |
| 258 | "The command called by `dired-at-point' to find a directory." |
| 259 | :type 'function |
| 260 | :group 'ffap |
| 261 | :risky t) |
| 262 | |
| 263 | (defcustom ffap-url-fetcher |
| 264 | (if (fboundp 'browse-url) |
| 265 | 'browse-url ; rely on browse-url-browser-function |
| 266 | 'w3-fetch) |
| 267 | ;; Remote control references: |
| 268 | ;; http://www.ncsa.uiuc.edu/SDG/Software/XMosaic/remote-control.html |
| 269 | ;; http://home.netscape.com/newsref/std/x-remote.html |
| 270 | "A function of one argument, called by ffap to fetch an URL. |
| 271 | Reasonable choices are `w3-fetch' or a `browse-url-*' function. |
| 272 | For a fancy alternative, get `ffap-url.el'." |
| 273 | :type '(choice (const w3-fetch) |
| 274 | (const browse-url) ; in recent versions of browse-url |
| 275 | (const browse-url-netscape) |
| 276 | (const browse-url-mosaic) |
| 277 | function) |
| 278 | :group 'ffap |
| 279 | :risky t) |
| 280 | |
| 281 | (defcustom ffap-next-regexp |
| 282 | ;; If you want ffap-next to find URL's only, try this: |
| 283 | ;; (and ffap-url-regexp (string-match "\\\\`" ffap-url-regexp) |
| 284 | ;; (concat "\\<" (substring ffap-url-regexp 2)))) |
| 285 | ;; |
| 286 | ;; It pays to put a big fancy regexp here, since ffap-guesser is |
| 287 | ;; much more time-consuming than regexp searching: |
| 288 | "[/:.~[:alpha:]]/\\|@[[:alpha:]][-[:alnum:]]*\\." |
| 289 | "Regular expression governing movements of `ffap-next'." |
| 290 | :type 'regexp |
| 291 | :group 'ffap) |
| 292 | |
| 293 | (defcustom dired-at-point-require-prefix nil |
| 294 | "If non-nil, reverse the prefix argument to `dired-at-point'. |
| 295 | This is nil so neophytes notice FFAP. Experts may prefer to |
| 296 | disable FFAP most of the time." |
| 297 | :type 'boolean |
| 298 | :group 'ffap |
| 299 | :version "20.3") |
| 300 | |
| 301 | \f |
| 302 | ;;; Compatibility: |
| 303 | ;; |
| 304 | ;; This version of ffap supports only the Emacs it is distributed in. |
| 305 | ;; See the ftp site for a more general version. The following |
| 306 | ;; functions are necessary "leftovers" from the more general version. |
| 307 | |
| 308 | (defun ffap-mouse-event () ; current mouse event, or nil |
| 309 | (and (listp last-nonmenu-event) last-nonmenu-event)) |
| 310 | (defun ffap-event-buffer (event) |
| 311 | (window-buffer (car (event-start event)))) |
| 312 | |
| 313 | \f |
| 314 | ;;; Find Next Thing in buffer (`ffap-next'): |
| 315 | ;; |
| 316 | ;; Original ffap-next-url (URL's only) from RPECK 30 Mar 1995. Since |
| 317 | ;; then, broke it up into ffap-next-guess (noninteractive) and |
| 318 | ;; ffap-next (a command). It now work on files as well as url's. |
| 319 | |
| 320 | (defvar ffap-next-guess nil |
| 321 | "Last value returned by `ffap-next-guess'.") |
| 322 | |
| 323 | (defvar ffap-string-at-point-region '(1 1) |
| 324 | "List (BEG END), last region returned by `ffap-string-at-point'.") |
| 325 | |
| 326 | (defun ffap-next-guess (&optional back lim) |
| 327 | "Move point to next file or URL, and return it as a string. |
| 328 | If nothing is found, leave point at limit and return nil. |
| 329 | Optional BACK argument makes search backwards. |
| 330 | Optional LIM argument limits the search. |
| 331 | Only considers strings that match `ffap-next-regexp'." |
| 332 | (or lim (setq lim (if back (point-min) (point-max)))) |
| 333 | (let (guess) |
| 334 | (while (not (or guess (eq (point) lim))) |
| 335 | (funcall (if back 're-search-backward 're-search-forward) |
| 336 | ffap-next-regexp lim 'move) |
| 337 | (setq guess (ffap-guesser))) |
| 338 | ;; Go to end, so we do not get same guess twice: |
| 339 | (goto-char (nth (if back 0 1) ffap-string-at-point-region)) |
| 340 | (setq ffap-next-guess guess))) |
| 341 | |
| 342 | ;;;###autoload |
| 343 | (defun ffap-next (&optional back wrap) |
| 344 | "Search buffer for next file or URL, and run ffap. |
| 345 | Optional argument BACK says to search backwards. |
| 346 | Optional argument WRAP says to try wrapping around if necessary. |
| 347 | Interactively: use a single prefix to search backwards, |
| 348 | double prefix to wrap forward, triple to wrap backwards. |
| 349 | Actual search is done by `ffap-next-guess'." |
| 350 | (interactive |
| 351 | (cdr (assq (prefix-numeric-value current-prefix-arg) |
| 352 | '((1) (4 t) (16 nil t) (64 t t))))) |
| 353 | (let ((pt (point)) |
| 354 | (guess (ffap-next-guess back))) |
| 355 | ;; Try wraparound if necessary: |
| 356 | (and (not guess) wrap |
| 357 | (goto-char (if back (point-max) (point-min))) |
| 358 | (setq guess (ffap-next-guess back pt))) |
| 359 | (if guess |
| 360 | (progn |
| 361 | (sit-for 0) ; display point movement |
| 362 | (find-file-at-point (ffap-prompter guess))) |
| 363 | (goto-char pt) ; restore point |
| 364 | (message "No %sfiles or URL's found" |
| 365 | (if wrap "" "more "))))) |
| 366 | |
| 367 | (defun ffap-next-url (&optional back wrap) |
| 368 | "Like `ffap-next', but search with `ffap-url-regexp'." |
| 369 | (interactive) |
| 370 | (let ((ffap-next-regexp ffap-url-regexp)) |
| 371 | (if (called-interactively-p 'interactive) |
| 372 | (call-interactively 'ffap-next) |
| 373 | (ffap-next back wrap)))) |
| 374 | |
| 375 | \f |
| 376 | ;;; Machines (`ffap-machine-p'): |
| 377 | |
| 378 | ;; I cannot decide a "best" strategy here, so these are variables. In |
| 379 | ;; particular, if `Pinging...' is broken or takes too long on your |
| 380 | ;; machine, try setting these all to accept or reject. |
| 381 | (defcustom ffap-machine-p-local 'reject ; this happens often |
| 382 | "What `ffap-machine-p' does with hostnames that have no domain. |
| 383 | Value should be a symbol, one of `ping', `accept', and `reject'." |
| 384 | :type '(choice (const ping) |
| 385 | (const accept) |
| 386 | (const reject)) |
| 387 | :group 'ffap) |
| 388 | (defcustom ffap-machine-p-known 'ping ; `accept' for higher speed |
| 389 | "What `ffap-machine-p' does with hostnames that have a known domain. |
| 390 | Value should be a symbol, one of `ping', `accept', and `reject'. |
| 391 | See `mail-extr.el' for the known domains." |
| 392 | :type '(choice (const ping) |
| 393 | (const accept) |
| 394 | (const reject)) |
| 395 | :group 'ffap) |
| 396 | (defcustom ffap-machine-p-unknown 'reject |
| 397 | "What `ffap-machine-p' does with hostnames that have an unknown domain. |
| 398 | Value should be a symbol, one of `ping', `accept', and `reject'. |
| 399 | See `mail-extr.el' for the known domains." |
| 400 | :type '(choice (const ping) |
| 401 | (const accept) |
| 402 | (const reject)) |
| 403 | :group 'ffap) |
| 404 | |
| 405 | (defun ffap-what-domain (domain) |
| 406 | ;; Like what-domain in mail-extr.el, returns string or nil. |
| 407 | (require 'mail-extr) |
| 408 | (let ((ob (or (ffap-symbol-value 'mail-extr-all-top-level-domains) |
| 409 | (ffap-symbol-value 'all-top-level-domains)))) ; XEmacs |
| 410 | (and ob (get (intern-soft (downcase domain) ob) 'domain-name)))) |
| 411 | |
| 412 | (defun ffap-machine-p (host &optional service quiet strategy) |
| 413 | "Decide whether HOST is the name of a real, reachable machine. |
| 414 | Depending on the domain (none, known, or unknown), follow the strategy |
| 415 | named by the variable `ffap-machine-p-local', `ffap-machine-p-known', |
| 416 | or `ffap-machine-p-unknown'. Pinging uses `open-network-stream'. |
| 417 | Optional SERVICE specifies the port used \(default \"discard\"\). |
| 418 | Optional QUIET flag suppresses the \"Pinging...\" message. |
| 419 | Optional STRATEGY overrides the three variables above. |
| 420 | Returned values: |
| 421 | t means that HOST answered. |
| 422 | 'accept means the relevant variable told us to accept. |
| 423 | \"mesg\" means HOST exists, but does not respond for some reason." |
| 424 | ;; Try some (Emory local): |
| 425 | ;; (ffap-machine-p "ftp" nil nil 'ping) |
| 426 | ;; (ffap-machine-p "nonesuch" nil nil 'ping) |
| 427 | ;; (ffap-machine-p "ftp.mathcs.emory.edu" nil nil 'ping) |
| 428 | ;; (ffap-machine-p "mathcs" 5678 nil 'ping) |
| 429 | ;; (ffap-machine-p "foo.bonk" nil nil 'ping) |
| 430 | ;; (ffap-machine-p "foo.bonk.com" nil nil 'ping) |
| 431 | (if (or (string-match "[^-[:alnum:].]" host) ; Invalid chars (?) |
| 432 | (not (string-match "[^0-9]" host))) ; 1: a number? 2: quick reject |
| 433 | nil |
| 434 | (let* ((domain |
| 435 | (and (string-match "\\.[^.]*$" host) |
| 436 | (downcase (substring host (1+ (match-beginning 0)))))) |
| 437 | (what-domain (if domain (ffap-what-domain domain) "Local"))) |
| 438 | (or strategy |
| 439 | (setq strategy |
| 440 | (cond ((not domain) ffap-machine-p-local) |
| 441 | ((not what-domain) ffap-machine-p-unknown) |
| 442 | (t ffap-machine-p-known)))) |
| 443 | (cond |
| 444 | ((eq strategy 'accept) 'accept) |
| 445 | ((eq strategy 'reject) nil) |
| 446 | ((not (fboundp 'open-network-stream)) nil) |
| 447 | ;; assume (eq strategy 'ping) |
| 448 | (t |
| 449 | (or quiet |
| 450 | (if (stringp what-domain) |
| 451 | (message "Pinging %s (%s)..." host what-domain) |
| 452 | (message "Pinging %s ..." host))) |
| 453 | (condition-case error |
| 454 | (progn |
| 455 | (delete-process |
| 456 | (open-network-stream |
| 457 | "ffap-machine-p" nil host (or service "discard"))) |
| 458 | t) |
| 459 | (error |
| 460 | (let ((mesg (car (cdr error)))) |
| 461 | (cond |
| 462 | ;; v18: |
| 463 | ((string-match "^Unknown host" mesg) nil) |
| 464 | ((string-match "not responding$" mesg) mesg) |
| 465 | ;; v19: |
| 466 | ;; (file-error "connection failed" "permission denied" |
| 467 | ;; "nonesuch" "ffap-machine-p") |
| 468 | ;; (file-error "connection failed" "host is unreachable" |
| 469 | ;; "gopher.house.gov" "ffap-machine-p") |
| 470 | ;; (file-error "connection failed" "address already in use" |
| 471 | ;; "ftp.uu.net" "ffap-machine-p") |
| 472 | ((equal mesg "connection failed") |
| 473 | (if (equal (nth 2 error) "permission denied") |
| 474 | nil ; host does not exist |
| 475 | ;; Other errors mean the host exists: |
| 476 | (nth 2 error))) |
| 477 | ;; Could be "Unknown service": |
| 478 | (t (signal (car error) (cdr error)))))))))))) |
| 479 | |
| 480 | \f |
| 481 | ;;; Possibly Remote Resources: |
| 482 | |
| 483 | (defun ffap-replace-file-component (fullname name) |
| 484 | "In remote FULLNAME, replace path with NAME. May return nil." |
| 485 | ;; Use efs if loaded, but do not load it otherwise. |
| 486 | (if (fboundp 'efs-replace-path-component) |
| 487 | (funcall 'efs-replace-path-component fullname name) |
| 488 | (and (stringp fullname) |
| 489 | (stringp name) |
| 490 | (concat (file-remote-p fullname) name)))) |
| 491 | ;; (ffap-replace-file-component "/who@foo.com:/whatever" "/new") |
| 492 | |
| 493 | (defun ffap-file-suffix (file) |
| 494 | "Return trailing `.foo' suffix of FILE, or nil if none." |
| 495 | (let ((pos (string-match "\\.[^./]*\\'" file))) |
| 496 | (and pos (substring file pos nil)))) |
| 497 | |
| 498 | (defvar ffap-compression-suffixes '(".gz" ".Z") ; .z is mostly dead |
| 499 | "List of suffixes tried by `ffap-file-exists-string'.") |
| 500 | |
| 501 | (defun ffap-file-exists-string (file &optional nomodify) |
| 502 | ;; Early jka-compr versions modified file-exists-p to return the |
| 503 | ;; filename, maybe modified by adding a suffix like ".gz". That |
| 504 | ;; broke the interface of file-exists-p, so it was later dropped. |
| 505 | ;; Here we document and simulate the old behavior. |
| 506 | "Return FILE (maybe modified) if the file exists, else nil. |
| 507 | When using jka-compr (a.k.a. `auto-compression-mode'), the returned |
| 508 | name may have a suffix added from `ffap-compression-suffixes'. |
| 509 | The optional NOMODIFY argument suppresses the extra search." |
| 510 | (cond |
| 511 | ((not file) nil) ; quietly reject nil |
| 512 | ((file-exists-p file) file) ; try unmodified first |
| 513 | ;; three reasons to suppress search: |
| 514 | (nomodify nil) |
| 515 | ((not (rassq 'jka-compr-handler file-name-handler-alist)) nil) |
| 516 | ((member (ffap-file-suffix file) ffap-compression-suffixes) nil) |
| 517 | (t ; ok, do the search |
| 518 | (let ((list ffap-compression-suffixes) try ret) |
| 519 | (while list |
| 520 | (if (file-exists-p (setq try (concat file (car list)))) |
| 521 | (setq ret try list nil) |
| 522 | (setq list (cdr list)))) |
| 523 | ret)))) |
| 524 | |
| 525 | (defun ffap-file-remote-p (filename) |
| 526 | "If FILENAME looks remote, return it (maybe slightly improved)." |
| 527 | ;; (ffap-file-remote-p "/user@foo.bar.com:/pub") |
| 528 | ;; (ffap-file-remote-p "/cssun.mathcs.emory.edu://dir") |
| 529 | ;; (ffap-file-remote-p "/ffap.el:80") |
| 530 | (or (and ffap-ftp-regexp |
| 531 | (string-match ffap-ftp-regexp filename) |
| 532 | ;; Convert "/host.com://dir" to "/host:/dir", to handle a dying |
| 533 | ;; practice of advertising ftp files as "host.dom://filename". |
| 534 | (if (string-match "//" filename) |
| 535 | ;; (replace-match "/" nil nil filename) |
| 536 | (concat (substring filename 0 (1+ (match-beginning 0))) |
| 537 | (substring filename (match-end 0))) |
| 538 | filename)) |
| 539 | (and ffap-rfs-regexp |
| 540 | (string-match ffap-rfs-regexp filename) |
| 541 | filename))) |
| 542 | |
| 543 | (defun ffap-machine-at-point () |
| 544 | "Return machine name at point if it exists, or nil." |
| 545 | (let ((mach (ffap-string-at-point 'machine))) |
| 546 | (and (ffap-machine-p mach) mach))) |
| 547 | |
| 548 | (defsubst ffap-host-to-filename (host) |
| 549 | "Convert HOST to something like \"/USER@HOST:\" or \"/HOST:\". |
| 550 | Looks at `ffap-ftp-default-user', returns \"\" for \"localhost\"." |
| 551 | (if (equal host "localhost") |
| 552 | "" |
| 553 | (let ((user ffap-ftp-default-user)) |
| 554 | ;; Avoid including the user if it is same as default: |
| 555 | (if (or (equal user (ffap-symbol-value 'ange-ftp-default-user)) |
| 556 | (equal user (ffap-symbol-value 'efs-default-user))) |
| 557 | (setq user nil)) |
| 558 | (concat "/" user (and user "@") host ":")))) |
| 559 | |
| 560 | (defun ffap-fixup-machine (mach) |
| 561 | ;; Convert a hostname into an url, an ftp file name, or nil. |
| 562 | (cond |
| 563 | ((not (and ffap-url-regexp (stringp mach))) nil) |
| 564 | ;; gopher.well.com |
| 565 | ((string-match "\\`gopher[-.]" mach) ; or "info"? |
| 566 | (concat "gopher://" mach "/")) |
| 567 | ;; www.ncsa.uiuc.edu |
| 568 | ((and (string-match "\\`w\\(ww\\|eb\\)[-.]" mach)) |
| 569 | (concat "http://" mach "/")) |
| 570 | ;; More cases? Maybe "telnet:" for archie? |
| 571 | (ffap-ftp-regexp (ffap-host-to-filename mach)) |
| 572 | )) |
| 573 | |
| 574 | (defvar ffap-newsgroup-regexp "^[[:lower:]]+\\.[-+[:lower:]_0-9.]+$" |
| 575 | "Strings not matching this fail `ffap-newsgroup-p'.") |
| 576 | (defvar ffap-newsgroup-heads ; entirely inadequate |
| 577 | '("alt" "comp" "gnu" "misc" "news" "sci" "soc" "talk") |
| 578 | "Used by `ffap-newsgroup-p' if gnus is not running.") |
| 579 | |
| 580 | (defun ffap-newsgroup-p (string) |
| 581 | "Return STRING if it looks like a newsgroup name, else nil." |
| 582 | (and |
| 583 | (string-match ffap-newsgroup-regexp string) |
| 584 | (let ((htbs '(gnus-active-hashtb gnus-newsrc-hashtb gnus-killed-hashtb)) |
| 585 | (heads ffap-newsgroup-heads) |
| 586 | htb ret) |
| 587 | (while htbs |
| 588 | (setq htb (car htbs) htbs (cdr htbs)) |
| 589 | (condition-case nil |
| 590 | (progn |
| 591 | ;; errs: htb symbol may be unbound, or not a hash-table. |
| 592 | ;; gnus-gethash is just a macro for intern-soft. |
| 593 | (and (symbol-value htb) |
| 594 | (intern-soft string (symbol-value htb)) |
| 595 | (setq ret string htbs nil)) |
| 596 | ;; If we made it this far, gnus is running, so ignore "heads": |
| 597 | (setq heads nil)) |
| 598 | (error nil))) |
| 599 | (or ret (not heads) |
| 600 | (let ((head (string-match "\\`\\([[:lower:]]+\\)\\." string))) |
| 601 | (and head (setq head (substring string 0 (match-end 1))) |
| 602 | (member head heads) |
| 603 | (setq ret string)))) |
| 604 | ;; Is there ever a need to modify string as a newsgroup name? |
| 605 | ret))) |
| 606 | |
| 607 | (defsubst ffap-url-p (string) |
| 608 | "If STRING looks like an URL, return it (maybe improved), else nil." |
| 609 | (when (and (stringp string) ffap-url-regexp) |
| 610 | (let* ((case-fold-search t) |
| 611 | (match (string-match ffap-url-regexp string))) |
| 612 | (cond ((eq match 0) string) |
| 613 | (match (substring string match)))))) |
| 614 | |
| 615 | ;; Broke these out of ffap-fixup-url, for use of ffap-url package. |
| 616 | (defun ffap-url-unwrap-local (url) |
| 617 | "Return URL as a local file name, or nil." |
| 618 | (let* ((obj (url-generic-parse-url url)) |
| 619 | (host (url-host obj)) |
| 620 | (filename (car (url-path-and-query obj)))) |
| 621 | (when (and (member (url-type obj) '("ftp" "file")) |
| 622 | (member host `("" "localhost" ,(system-name)))) |
| 623 | ;; On Windows, "file:///C:/foo" should unwrap to "C:/foo" |
| 624 | (if (and (memq system-type '(ms-dos windows-nt cygwin)) |
| 625 | (string-match "\\`/[a-zA-Z]:" filename)) |
| 626 | (substring filename 1) |
| 627 | filename)))) |
| 628 | |
| 629 | (defun ffap-url-unwrap-remote (url) |
| 630 | "Return URL as a remote file name, or nil." |
| 631 | (let* ((obj (url-generic-parse-url url)) |
| 632 | (scheme (url-type obj)) |
| 633 | (valid-schemes (if (listp ffap-url-unwrap-remote) |
| 634 | ffap-url-unwrap-remote |
| 635 | '("ftp"))) |
| 636 | (host (url-host obj)) |
| 637 | (port (url-port-if-non-default obj)) |
| 638 | (user (url-user obj)) |
| 639 | (filename (car (url-path-and-query obj)))) |
| 640 | (when (and (member scheme valid-schemes) |
| 641 | (string-match "\\`[a-zA-Z][-a-zA-Z0-9+.]*\\'" scheme) |
| 642 | (not (equal host ""))) |
| 643 | (concat "/" scheme ":" |
| 644 | (if user (concat user "@")) |
| 645 | host |
| 646 | (if port (concat "#" (number-to-string port))) |
| 647 | ":" filename)))) |
| 648 | |
| 649 | (defun ffap-fixup-url (url) |
| 650 | "Clean up URL and return it, maybe as a file name." |
| 651 | (cond |
| 652 | ((not (stringp url)) nil) |
| 653 | ((and ffap-url-unwrap-local (ffap-url-unwrap-local url))) |
| 654 | ((and ffap-url-unwrap-remote (ffap-url-unwrap-remote url))) |
| 655 | (url))) |
| 656 | |
| 657 | \f |
| 658 | ;;; File Name Handling: |
| 659 | ;; |
| 660 | ;; The upcoming ffap-alist actions need various utilities to prepare |
| 661 | ;; and search directories. Too many features here. |
| 662 | |
| 663 | ;; (defun ffap-last (l) (while (cdr l) (setq l (cdr l))) l) |
| 664 | ;; (defun ffap-splice (func inlist) |
| 665 | ;; "Equivalent to (apply 'nconc (mapcar FUNC INLIST)), but less consing." |
| 666 | ;; (let* ((head (cons 17 nil)) (last head)) |
| 667 | ;; (while inlist |
| 668 | ;; (setcdr last (funcall func (car inlist))) |
| 669 | ;; (setq last (ffap-last last) inlist (cdr inlist))) |
| 670 | ;; (cdr head))) |
| 671 | |
| 672 | (defun ffap-list-env (env &optional empty) |
| 673 | "Return a list of strings parsed from environment variable ENV. |
| 674 | Optional EMPTY is the default list if \(getenv ENV\) is undefined, and |
| 675 | also is substituted for the first empty-string component, if there is one. |
| 676 | Uses `path-separator' to separate the path into substrings." |
| 677 | ;; We cannot use parse-colon-path (files.el), since it kills |
| 678 | ;; "//" entries using file-name-as-directory. |
| 679 | ;; Similar: dired-split, TeX-split-string, and RHOGEE's psg-list-env |
| 680 | ;; in ff-paths and bib-cite. The EMPTY arg may help mimic kpathsea. |
| 681 | (if (or empty (getenv env)) ; should return something |
| 682 | (let ((start 0) match dir ret) |
| 683 | (setq env (concat (getenv env) path-separator)) |
| 684 | (while (setq match (string-match path-separator env start)) |
| 685 | (setq dir (substring env start match) start (1+ match)) |
| 686 | ;;(and (file-directory-p dir) (not (member dir ret)) ...) |
| 687 | (setq ret (cons dir ret))) |
| 688 | (setq ret (nreverse ret)) |
| 689 | (and empty (setq match (member "" ret)) |
| 690 | (progn ; allow string or list here |
| 691 | (setcdr match (append (cdr-safe empty) (cdr match))) |
| 692 | (setcar match (or (car-safe empty) empty)))) |
| 693 | ret))) |
| 694 | |
| 695 | (defun ffap-reduce-path (path) |
| 696 | "Remove duplicates and non-directories from PATH list." |
| 697 | (let (ret tem) |
| 698 | (while path |
| 699 | (setq tem path path (cdr path)) |
| 700 | (if (equal (car tem) ".") (setcar tem "")) |
| 701 | (or (member (car tem) ret) |
| 702 | (not (file-directory-p (car tem))) |
| 703 | (progn (setcdr tem ret) (setq ret tem)))) |
| 704 | (nreverse ret))) |
| 705 | |
| 706 | (defun ffap-all-subdirs (dir &optional depth) |
| 707 | "Return list of all subdirectories under DIR, starting with itself. |
| 708 | Directories beginning with \".\" are ignored, and directory symlinks |
| 709 | are listed but never searched (to avoid loops). |
| 710 | Optional DEPTH limits search depth." |
| 711 | (and (file-exists-p dir) |
| 712 | (ffap-all-subdirs-loop (expand-file-name dir) (or depth -1)))) |
| 713 | |
| 714 | (defun ffap-all-subdirs-loop (dir depth) ; internal |
| 715 | (setq depth (1- depth)) |
| 716 | (cons dir |
| 717 | (and (not (eq depth -1)) |
| 718 | (apply 'nconc |
| 719 | (mapcar |
| 720 | (function |
| 721 | (lambda (d) |
| 722 | (cond |
| 723 | ((not (file-directory-p d)) nil) |
| 724 | ((file-symlink-p d) (list d)) |
| 725 | (t (ffap-all-subdirs-loop d depth))))) |
| 726 | (directory-files dir t "\\`[^.]") |
| 727 | ))))) |
| 728 | |
| 729 | (defvar ffap-kpathsea-depth 1 |
| 730 | "Bound on depth of subdirectory search in `ffap-kpathsea-expand-path'. |
| 731 | Set to 0 to avoid all searching, or nil for no limit.") |
| 732 | |
| 733 | (defun ffap-kpathsea-expand-path (path) |
| 734 | "Replace each \"//\"-suffixed dir in PATH by a list of its subdirs. |
| 735 | The subdirs begin with the original directory, and the depth of the |
| 736 | search is bounded by `ffap-kpathsea-depth'. This is intended to mimic |
| 737 | kpathsea, a library used by some versions of TeX." |
| 738 | (apply 'nconc |
| 739 | (mapcar |
| 740 | (function |
| 741 | (lambda (dir) |
| 742 | (if (string-match "[^/]//\\'" dir) |
| 743 | (ffap-all-subdirs (substring dir 0 -2) ffap-kpathsea-depth) |
| 744 | (list dir)))) |
| 745 | path))) |
| 746 | |
| 747 | (defun ffap-locate-file (file nosuffix path) |
| 748 | ;; The current version of locate-library could almost replace this, |
| 749 | ;; except it does not let us override the suffix list. The |
| 750 | ;; compression-suffixes search moved to ffap-file-exists-string. |
| 751 | "A generic path-searching function. |
| 752 | Returns the name of file in PATH, or nil. |
| 753 | Optional NOSUFFIX, if nil or t, is like the fourth argument |
| 754 | for `load': whether to try the suffixes (\".elc\" \".el\" \"\"). |
| 755 | If a nonempty list, it is a list of suffixes to try instead. |
| 756 | PATH is a list of directories. |
| 757 | |
| 758 | This uses `ffap-file-exists-string', which may try adding suffixes from |
| 759 | `ffap-compression-suffixes'." |
| 760 | (if (file-name-absolute-p file) |
| 761 | (setq path (list (file-name-directory file)) |
| 762 | file (file-name-nondirectory file))) |
| 763 | (let ((dir-ok (equal "" (file-name-nondirectory file))) |
| 764 | (suffixes-to-try |
| 765 | (cond |
| 766 | ((consp nosuffix) nosuffix) |
| 767 | (nosuffix '("")) |
| 768 | (t '(".elc" ".el" "")))) |
| 769 | suffixes try found) |
| 770 | (while path |
| 771 | (setq suffixes suffixes-to-try) |
| 772 | (while suffixes |
| 773 | (setq try (ffap-file-exists-string |
| 774 | (expand-file-name |
| 775 | (concat file (car suffixes)) (car path)))) |
| 776 | (if (and try (or dir-ok (not (file-directory-p try)))) |
| 777 | (setq found try suffixes nil path nil) |
| 778 | (setq suffixes (cdr suffixes)))) |
| 779 | (setq path (cdr path))) |
| 780 | found)) |
| 781 | |
| 782 | \f |
| 783 | ;;; Action List (`ffap-alist'): |
| 784 | ;; |
| 785 | ;; These search actions depend on the major-mode or regexps matching |
| 786 | ;; the current name. The little functions and their variables are |
| 787 | ;; deferred to the next section, at some loss of "code locality". A |
| 788 | ;; good example of featuritis. Trim this list for speed. |
| 789 | |
| 790 | (defvar ffap-alist |
| 791 | '( |
| 792 | ("" . ffap-completable) ; completion, slow on some systems |
| 793 | ("\\.info\\'" . ffap-info) ; gzip.info |
| 794 | ("\\`info/" . ffap-info-2) ; info/emacs |
| 795 | ("\\`[-[:lower:]]+\\'" . ffap-info-3) ; (emacs)Top [only in the parentheses] |
| 796 | ("\\.elc?\\'" . ffap-el) ; simple.el, simple.elc |
| 797 | (emacs-lisp-mode . ffap-el-mode) ; rmail, gnus, simple, custom |
| 798 | ;; (lisp-interaction-mode . ffap-el-mode) ; maybe |
| 799 | (finder-mode . ffap-el-mode) ; type {C-h p} and try it |
| 800 | (help-mode . ffap-el-mode) ; maybe useful |
| 801 | (c++-mode . ffap-c-mode) ; search ffap-c-path |
| 802 | (cc-mode . ffap-c-mode) ; same |
| 803 | ("\\.\\([chCH]\\|cc\\|hh\\)\\'" . ffap-c-mode) ; stdio.h |
| 804 | (fortran-mode . ffap-fortran-mode) ; FORTRAN requested by MDB |
| 805 | ("\\.[fF]\\'" . ffap-fortran-mode) |
| 806 | (tex-mode . ffap-tex-mode) ; search ffap-tex-path |
| 807 | (latex-mode . ffap-latex-mode) ; similar |
| 808 | ("\\.\\(tex\\|sty\\|doc\\|cls\\)\\'" . ffap-tex) |
| 809 | ("\\.bib\\'" . ffap-bib) ; search ffap-bib-path |
| 810 | ("\\`\\." . ffap-home) ; .emacs, .bashrc, .profile |
| 811 | ("\\`~/" . ffap-lcd) ; |~/misc/ffap.el.Z| |
| 812 | ;; This used to have a blank, but ffap-string-at-point doesn't |
| 813 | ;; handle blanks. |
| 814 | ;; http://lists.gnu.org/archive/html/emacs-devel/2008-01/msg01058.html |
| 815 | ("\\`[Rr][Ff][Cc][-#]?\\([0-9]+\\)" ; no $ |
| 816 | . ffap-rfc) ; "100% RFC2100 compliant" |
| 817 | (dired-mode . ffap-dired) ; maybe in a subdirectory |
| 818 | ) |
| 819 | "Alist of \(KEY . FUNCTION\) pairs parsed by `ffap-file-at-point'. |
| 820 | If string NAME at point (maybe \"\") is not a file or URL, these pairs |
| 821 | specify actions to try creating such a string. A pair matches if either |
| 822 | KEY is a symbol, and it equals `major-mode', or |
| 823 | KEY is a string, it should match NAME as a regexp. |
| 824 | On a match, \(FUNCTION NAME\) is called and should return a file, an |
| 825 | URL, or nil. If nil, search the alist for further matches.") |
| 826 | |
| 827 | (put 'ffap-alist 'risky-local-variable t) |
| 828 | |
| 829 | ;; Example `ffap-alist' modifications: |
| 830 | ;; |
| 831 | ;; (setq ffap-alist ; remove a feature in `ffap-alist' |
| 832 | ;; (delete (assoc 'c-mode ffap-alist) ffap-alist)) |
| 833 | ;; |
| 834 | ;; (setq ffap-alist ; add something to `ffap-alist' |
| 835 | ;; (cons |
| 836 | ;; (cons "^YSN[0-9]+$" |
| 837 | ;; (defun ffap-ysn (name) |
| 838 | ;; (concat |
| 839 | ;; "http://www.physics.uiuc.edu/" |
| 840 | ;; "ysn/httpd/htdocs/ysnarchive/issuefiles/" |
| 841 | ;; (substring name 3) ".html"))) |
| 842 | ;; ffap-alist)) |
| 843 | |
| 844 | \f |
| 845 | ;;; Action Definitions: |
| 846 | ;; |
| 847 | ;; Define various default members of `ffap-alist'. |
| 848 | |
| 849 | (defun ffap-completable (name) |
| 850 | (let* ((dir (or (file-name-directory name) default-directory)) |
| 851 | (cmp (file-name-completion (file-name-nondirectory name) dir))) |
| 852 | (and cmp (concat dir cmp)))) |
| 853 | |
| 854 | (defun ffap-home (name) (ffap-locate-file name t '("~"))) |
| 855 | |
| 856 | (defun ffap-info (name) |
| 857 | (ffap-locate-file |
| 858 | name '("" ".info") |
| 859 | (or (ffap-symbol-value 'Info-directory-list) |
| 860 | (ffap-symbol-value 'Info-default-directory-list) |
| 861 | ))) |
| 862 | |
| 863 | (defun ffap-info-2 (name) (ffap-info (substring name 5))) |
| 864 | |
| 865 | (defun ffap-info-3 (name) |
| 866 | ;; This ignores the node! "(emacs)Top" same as "(emacs)Intro" |
| 867 | (and (equal (ffap-string-around) "()") (ffap-info name))) |
| 868 | |
| 869 | (defun ffap-el (name) (ffap-locate-file name t load-path)) |
| 870 | |
| 871 | (defun ffap-el-mode (name) |
| 872 | ;; If name == "foo.el" we will skip it, since ffap-el already |
| 873 | ;; searched for it once. (This assumes the default ffap-alist.) |
| 874 | (and (not (string-match "\\.el\\'" name)) |
| 875 | (ffap-locate-file name '(".el") load-path))) |
| 876 | |
| 877 | ;; FIXME this duplicates the logic of Man-header-file-path. |
| 878 | ;; There should be a single central variable or function for this. |
| 879 | ;; See also (bug#10702): |
| 880 | ;; cc-search-directories, semantic-c-dependency-system-include-path, |
| 881 | ;; semantic-gcc-setup |
| 882 | (defvar ffap-c-path |
| 883 | (let ((arch (with-temp-buffer |
| 884 | (when (eq 0 (ignore-errors |
| 885 | (call-process "gcc" nil '(t nil) nil |
| 886 | "-print-multiarch"))) |
| 887 | (goto-char (point-min)) |
| 888 | (buffer-substring (point) (line-end-position))))) |
| 889 | (base '("/usr/include" "/usr/local/include"))) |
| 890 | (if (zerop (length arch)) |
| 891 | base |
| 892 | (append base (list (expand-file-name arch "/usr/include"))))) |
| 893 | "List of directories to search for include files.") |
| 894 | |
| 895 | (defun ffap-c-mode (name) |
| 896 | (ffap-locate-file name t ffap-c-path)) |
| 897 | |
| 898 | (defvar ffap-fortran-path '("../include" "/usr/include")) |
| 899 | |
| 900 | (defun ffap-fortran-mode (name) |
| 901 | (ffap-locate-file name t ffap-fortran-path)) |
| 902 | |
| 903 | (defvar ffap-tex-path |
| 904 | t ; delayed initialization |
| 905 | "Path where `ffap-tex-mode' looks for TeX files. |
| 906 | If t, `ffap-tex-init' will initialize this when needed.") |
| 907 | |
| 908 | (defun ffap-tex-init () |
| 909 | ;; Compute ffap-tex-path if it is now t. |
| 910 | (and (eq t ffap-tex-path) |
| 911 | ;; this may be slow, so say something |
| 912 | (message "Initializing ffap-tex-path ...") |
| 913 | (setq ffap-tex-path |
| 914 | (ffap-reduce-path |
| 915 | (cons |
| 916 | "." |
| 917 | (ffap-kpathsea-expand-path |
| 918 | (append |
| 919 | (ffap-list-env "TEXINPUTS") |
| 920 | ;; (ffap-list-env "BIBINPUTS") |
| 921 | (ffap-symbol-value |
| 922 | 'TeX-macro-global ; AUCTeX |
| 923 | '("/usr/local/lib/tex/macros" |
| 924 | "/usr/local/lib/tex/inputs"))))))))) |
| 925 | |
| 926 | (defun ffap-tex-mode (name) |
| 927 | (ffap-tex-init) |
| 928 | (ffap-locate-file name '(".tex" "") ffap-tex-path)) |
| 929 | |
| 930 | (defun ffap-latex-mode (name) |
| 931 | (ffap-tex-init) |
| 932 | ;; only rare need for "" |
| 933 | (ffap-locate-file name '(".cls" ".sty" ".tex" "") ffap-tex-path)) |
| 934 | |
| 935 | (defun ffap-tex (name) |
| 936 | (ffap-tex-init) |
| 937 | (ffap-locate-file name t ffap-tex-path)) |
| 938 | |
| 939 | (defvar ffap-bib-path |
| 940 | (ffap-list-env "BIBINPUTS" |
| 941 | (ffap-reduce-path |
| 942 | '( |
| 943 | ;; a few wild guesses, need better |
| 944 | "/usr/local/lib/tex/macros/bib" ; Solaris? |
| 945 | "/usr/lib/texmf/bibtex/bib" ; Linux? |
| 946 | )))) |
| 947 | |
| 948 | (defun ffap-bib (name) |
| 949 | (ffap-locate-file name t ffap-bib-path)) |
| 950 | |
| 951 | (defun ffap-dired (name) |
| 952 | (let ((pt (point)) try) |
| 953 | (save-excursion |
| 954 | (and (progn |
| 955 | (beginning-of-line) |
| 956 | (looking-at " *[-d]r[-w][-x][-r][-w][-x][-r][-w][-x] ")) |
| 957 | (re-search-backward "^ *$" nil t) |
| 958 | (re-search-forward "^ *\\([^ \t\n:]*\\):\n *total " pt t) |
| 959 | (file-exists-p |
| 960 | (setq try |
| 961 | (expand-file-name |
| 962 | name |
| 963 | (buffer-substring |
| 964 | (match-beginning 1) (match-end 1))))) |
| 965 | try)))) |
| 966 | |
| 967 | ;; Maybe a "Lisp Code Directory" reference: |
| 968 | (defun ffap-lcd (name) |
| 969 | ;; FIXME: Is this still in use? |
| 970 | (and |
| 971 | (or |
| 972 | ;; lisp-dir-apropos output buffer: |
| 973 | (string-match "Lisp Code Dir" (buffer-name)) |
| 974 | ;; Inside an LCD entry like |~/misc/ffap.el.Z|, |
| 975 | ;; or maybe the holy LCD-Datafile itself: |
| 976 | (member (ffap-string-around) '("||" "|\n"))) |
| 977 | (concat |
| 978 | ;; lispdir.el may not be loaded yet: |
| 979 | (ffap-host-to-filename |
| 980 | (ffap-symbol-value 'elisp-archive-host |
| 981 | "archive.cis.ohio-state.edu")) |
| 982 | (file-name-as-directory |
| 983 | (ffap-symbol-value 'elisp-archive-directory |
| 984 | "/pub/gnu/emacs/elisp-archive/")) |
| 985 | (substring name 2)))) |
| 986 | |
| 987 | (defcustom ffap-rfc-path |
| 988 | (concat (ffap-host-to-filename "ftp.rfc-editor.org") "/in-notes/rfc%s.txt") |
| 989 | "A `format' string making a filename for RFC documents. |
| 990 | This can be an ange-ftp or tramp remote filename to download, or |
| 991 | a local filename if you have full set of RFCs locally. See also |
| 992 | `ffap-rfc-directories'." |
| 993 | :type 'string |
| 994 | :version "23.1" |
| 995 | :group 'ffap) |
| 996 | |
| 997 | (defcustom ffap-rfc-directories nil |
| 998 | "A list of directories to look for RFC files. |
| 999 | If a given RFC isn't in these then `ffap-rfc-path' is offered." |
| 1000 | :type '(repeat directory) |
| 1001 | :version "23.1" |
| 1002 | :group 'ffap) |
| 1003 | |
| 1004 | (defun ffap-rfc (name) |
| 1005 | (let ((num (match-string 1 name))) |
| 1006 | (or (ffap-locate-file (format "rfc%s.txt" num) t ffap-rfc-directories) |
| 1007 | (format ffap-rfc-path num)))) |
| 1008 | |
| 1009 | \f |
| 1010 | ;;; At-Point Functions: |
| 1011 | |
| 1012 | (defvar ffap-string-at-point-mode-alist |
| 1013 | '( |
| 1014 | ;; The default, used when the `major-mode' is not found. |
| 1015 | ;; Slightly controversial decisions: |
| 1016 | ;; * strip trailing "@" and ":" |
| 1017 | ;; * no commas (good for latex) |
| 1018 | (file "--:\\\\$+<>@-Z_[:alpha:]~*?" "<@" "@>;.,!:") |
| 1019 | ;; An url, or maybe a email/news message-id: |
| 1020 | (url "--:=&?$+@-Z_[:alpha:]~#,%;*" "^[:alnum:]" ":;.,!?") |
| 1021 | ;; Find a string that does *not* contain a colon: |
| 1022 | (nocolon "--9$+<>@-Z_[:alpha:]~" "<@" "@>;.,!?") |
| 1023 | ;; A machine: |
| 1024 | (machine "-[:alnum:]." "" ".") |
| 1025 | ;; Mathematica paths: allow backquotes |
| 1026 | (math-mode ",-:$+<>@-Z_[:lower:]~`" "<" "@>;.,!?`:") |
| 1027 | ) |
| 1028 | "Alist of \(MODE CHARS BEG END\), where MODE is a symbol, |
| 1029 | possibly a major-mode name, or one of the symbol |
| 1030 | `file', `url', `machine', and `nocolon'. |
| 1031 | `ffap-string-at-point' uses the data fields as follows: |
| 1032 | 1. find a maximal string of CHARS around point, |
| 1033 | 2. strip BEG chars before point from the beginning, |
| 1034 | 3. Strip END chars after point from the end.") |
| 1035 | |
| 1036 | (defvar ffap-string-at-point nil |
| 1037 | ;; Added at suggestion of RHOGEE (for ff-paths), 7/24/95. |
| 1038 | "Last string returned by `ffap-string-at-point'.") |
| 1039 | |
| 1040 | (defun ffap-string-at-point (&optional mode) |
| 1041 | "Return a string of characters from around point. |
| 1042 | MODE (defaults to value of `major-mode') is a symbol used to look up string |
| 1043 | syntax parameters in `ffap-string-at-point-mode-alist'. |
| 1044 | If MODE is not found, we use `file' instead of MODE. |
| 1045 | If the region is active, return a string from the region. |
| 1046 | Sets `ffap-string-at-point' and `ffap-string-at-point-region'." |
| 1047 | (let* ((args |
| 1048 | (cdr |
| 1049 | (or (assq (or mode major-mode) ffap-string-at-point-mode-alist) |
| 1050 | (assq 'file ffap-string-at-point-mode-alist)))) |
| 1051 | (pt (point)) |
| 1052 | (str |
| 1053 | (if (and transient-mark-mode mark-active) |
| 1054 | (buffer-substring |
| 1055 | (setcar ffap-string-at-point-region (region-beginning)) |
| 1056 | (setcar (cdr ffap-string-at-point-region) (region-end))) |
| 1057 | (buffer-substring |
| 1058 | (save-excursion |
| 1059 | (skip-chars-backward (car args)) |
| 1060 | (skip-chars-forward (nth 1 args) pt) |
| 1061 | (setcar ffap-string-at-point-region (point))) |
| 1062 | (save-excursion |
| 1063 | (skip-chars-forward (car args)) |
| 1064 | (skip-chars-backward (nth 2 args) pt) |
| 1065 | (setcar (cdr ffap-string-at-point-region) (point))))))) |
| 1066 | (set-text-properties 0 (length str) nil str) |
| 1067 | (setq ffap-string-at-point str))) |
| 1068 | |
| 1069 | (defun ffap-string-around () |
| 1070 | ;; Sometimes useful to decide how to treat a string. |
| 1071 | "Return string of two chars around last `ffap-string-at-point'. |
| 1072 | Assumes the buffer has not changed." |
| 1073 | (save-excursion |
| 1074 | (format "%c%c" |
| 1075 | (progn |
| 1076 | (goto-char (car ffap-string-at-point-region)) |
| 1077 | (preceding-char)) ; maybe 0 |
| 1078 | (progn |
| 1079 | (goto-char (nth 1 ffap-string-at-point-region)) |
| 1080 | (following-char)) ; maybe 0 |
| 1081 | ))) |
| 1082 | |
| 1083 | (defun ffap-copy-string-as-kill (&optional mode) |
| 1084 | ;; Requested by MCOOK. Useful? |
| 1085 | "Call `ffap-string-at-point', and copy result to `kill-ring'." |
| 1086 | (interactive) |
| 1087 | (let ((str (ffap-string-at-point mode))) |
| 1088 | (if (equal "" str) |
| 1089 | (message "No string found around point.") |
| 1090 | (kill-new str) |
| 1091 | ;; Older: (apply 'copy-region-as-kill ffap-string-at-point-region) |
| 1092 | (message "Copied to kill ring: %s" str)))) |
| 1093 | |
| 1094 | ;; External. |
| 1095 | (declare-function w3-view-this-url "ext:w3" (&optional no-show)) |
| 1096 | |
| 1097 | (defun ffap-url-at-point () |
| 1098 | "Return URL from around point if it exists, or nil." |
| 1099 | ;; Could use w3's url-get-url-at-point instead. Both handle "URL:", |
| 1100 | ;; ignore non-relative links, trim punctuation. The other will |
| 1101 | ;; actually look back if point is in whitespace, but I would rather |
| 1102 | ;; ffap be less aggressive in such situations. |
| 1103 | (when ffap-url-regexp |
| 1104 | (or (and (eq major-mode 'w3-mode) ; In a w3 buffer button? |
| 1105 | (w3-view-this-url t)) |
| 1106 | ;; Is there a reason not to strip trailing colon? |
| 1107 | (let ((name (ffap-string-at-point 'url))) |
| 1108 | (cond |
| 1109 | ((string-match "^url:" name) (setq name (substring name 4))) |
| 1110 | ((and (string-match "\\`[^:</>@]+@[^:</>@]+[[:alnum:]]\\'" name) |
| 1111 | ;; "foo@bar": could be "mailto" or "news" (a Message-ID). |
| 1112 | ;; Without "<>" it must be "mailto". Otherwise could be |
| 1113 | ;; either, so consult `ffap-foo-at-bar-prefix'. |
| 1114 | (let ((prefix (if (and (equal (ffap-string-around) "<>") |
| 1115 | ;; Expect some odd characters: |
| 1116 | (string-match "[$.0-9].*[$.0-9].*@" name)) |
| 1117 | ;; Could be news: |
| 1118 | ffap-foo-at-bar-prefix |
| 1119 | "mailto"))) |
| 1120 | (and prefix (setq name (concat prefix ":" name)))))) |
| 1121 | ((ffap-newsgroup-p name) (setq name (concat "news:" name))) |
| 1122 | ((and (string-match "\\`[[:alnum:]]+\\'" name) ; <mic> <root> <nobody> |
| 1123 | (equal (ffap-string-around) "<>") |
| 1124 | ;; (ffap-user-p name): |
| 1125 | (not (string-match "~" (expand-file-name (concat "~" name))))) |
| 1126 | (setq name (concat "mailto:" name))) |
| 1127 | ((ffap-url-p name))))))) |
| 1128 | |
| 1129 | (defvar ffap-gopher-regexp |
| 1130 | "^.*\\<\\(Type\\|Name\\|Path\\|Host\\|Port\\) *= *\\(.*\\) *$" |
| 1131 | "Regexp matching a line in a gopher bookmark (maybe indented). |
| 1132 | The two subexpressions are the KEY and VALUE.") |
| 1133 | |
| 1134 | (defun ffap-gopher-at-point () |
| 1135 | "If point is inside a gopher bookmark block, return its URL." |
| 1136 | ;; `gopher-parse-bookmark' from gopher.el is not so robust |
| 1137 | (save-excursion |
| 1138 | (beginning-of-line) |
| 1139 | (if (looking-at ffap-gopher-regexp) |
| 1140 | (progn |
| 1141 | (while (and (looking-at ffap-gopher-regexp) (not (bobp))) |
| 1142 | (forward-line -1)) |
| 1143 | (or (looking-at ffap-gopher-regexp) (forward-line 1)) |
| 1144 | (let ((type "1") path host (port "70")) |
| 1145 | (while (looking-at ffap-gopher-regexp) |
| 1146 | (let ((var (intern |
| 1147 | (downcase |
| 1148 | (buffer-substring (match-beginning 1) |
| 1149 | (match-end 1))))) |
| 1150 | (val (buffer-substring (match-beginning 2) |
| 1151 | (match-end 2)))) |
| 1152 | (set var val) |
| 1153 | (forward-line 1))) |
| 1154 | (if (and path (string-match "^ftp:.*@" path)) |
| 1155 | (concat "ftp://" |
| 1156 | (substring path 4 (1- (match-end 0))) |
| 1157 | (substring path (match-end 0))) |
| 1158 | (and (= (length type) 1) |
| 1159 | host;; (ffap-machine-p host) |
| 1160 | (concat "gopher://" host |
| 1161 | (if (equal port "70") "" (concat ":" port)) |
| 1162 | "/" type path)))))))) |
| 1163 | |
| 1164 | (defvar ffap-ftp-sans-slash-regexp |
| 1165 | (and |
| 1166 | ffap-ftp-regexp |
| 1167 | ;; Note: by now, we know it is not an url. |
| 1168 | ;; Icky regexp avoids: default: 123: foo::bar cs:pub |
| 1169 | ;; It does match on: mic@cs: cs:/pub mathcs.emory.edu: (point at end) |
| 1170 | "\\`\\([^:@]+@[^:@]+:\\|[^@.:]+\\.[^@:]+:\\|[^:]+:[~/]\\)\\([^:]\\|\\'\\)") |
| 1171 | "Strings matching this are coerced to ftp file names by ffap. |
| 1172 | That is, ffap just prepends \"/\". Set to nil to disable.") |
| 1173 | |
| 1174 | (defun ffap-file-at-point () |
| 1175 | "Return filename from around point if it exists, or nil. |
| 1176 | Existence test is skipped for names that look remote. |
| 1177 | If the filename is not obvious, it also tries `ffap-alist', |
| 1178 | which may actually result in an URL rather than a filename." |
| 1179 | ;; Note: this function does not need to look for url's, just |
| 1180 | ;; filenames. On the other hand, it is responsible for converting |
| 1181 | ;; a pseudo-url "site.com://dir" to an ftp file name |
| 1182 | (let* ((case-fold-search t) ; url prefixes are case-insensitive |
| 1183 | (data (match-data)) |
| 1184 | (string (ffap-string-at-point)) ; uses mode alist |
| 1185 | (name |
| 1186 | (or (condition-case nil |
| 1187 | (and (not (string-match "//" string)) ; foo.com://bar |
| 1188 | (substitute-in-file-name string)) |
| 1189 | (error nil)) |
| 1190 | string)) |
| 1191 | (abs (file-name-absolute-p name)) |
| 1192 | (default-directory default-directory) |
| 1193 | (oname name)) |
| 1194 | (unwind-protect |
| 1195 | (cond |
| 1196 | ;; Immediate rejects (/ and // and /* are too common in C/C++): |
| 1197 | ((member name '("" "/" "//" "/*" ".")) nil) |
| 1198 | ;; Immediately test local filenames. If default-directory is |
| 1199 | ;; remote, you probably already have a connection. |
| 1200 | ((and (not abs) (ffap-file-exists-string name))) |
| 1201 | ;; Try stripping off line numbers; good for compilation/grep output. |
| 1202 | ((and (not abs) (string-match ":[0-9]" name) |
| 1203 | (ffap-file-exists-string (substring name 0 (match-beginning 0))))) |
| 1204 | ;; Try stripping off prominent (non-root - #) shell prompts |
| 1205 | ;; if the ffap-shell-prompt-regexp is non-nil. |
| 1206 | ((and ffap-shell-prompt-regexp |
| 1207 | (not abs) (string-match ffap-shell-prompt-regexp name) |
| 1208 | (ffap-file-exists-string (substring name (match-end 0))))) |
| 1209 | ;; Accept remote names without actual checking (too slow): |
| 1210 | ((and abs (ffap-file-remote-p name))) |
| 1211 | ;; Ok, not remote, try the existence test even if it is absolute: |
| 1212 | ((and abs (ffap-file-exists-string name))) |
| 1213 | ;; Try stripping off line numbers. |
| 1214 | ((and abs (string-match ":[0-9]" name) |
| 1215 | (ffap-file-exists-string (substring name 0 (match-beginning 0))))) |
| 1216 | ;; If it contains a colon, get rid of it (and return if exists) |
| 1217 | ((and (string-match path-separator name) |
| 1218 | (setq name (ffap-string-at-point 'nocolon)) |
| 1219 | (ffap-file-exists-string name))) |
| 1220 | ;; File does not exist, try the alist: |
| 1221 | ((let ((alist ffap-alist) tem try case-fold-search) |
| 1222 | (while (and alist (not try)) |
| 1223 | (setq tem (car alist) alist (cdr alist)) |
| 1224 | (if (or (eq major-mode (car tem)) |
| 1225 | (and (stringp (car tem)) |
| 1226 | (string-match (car tem) name))) |
| 1227 | (and (setq try |
| 1228 | (condition-case nil |
| 1229 | (funcall (cdr tem) name) |
| 1230 | (error nil))) |
| 1231 | (setq try (or |
| 1232 | (ffap-url-p try) ; not a file! |
| 1233 | (ffap-file-remote-p try) |
| 1234 | (ffap-file-exists-string try)))))) |
| 1235 | try)) |
| 1236 | ;; Try adding a leading "/" (common omission in ftp file names). |
| 1237 | ;; Note that this uses oname, which still has any colon part. |
| 1238 | ;; This should have a lower priority than the alist stuff, |
| 1239 | ;; else it matches things like "ffap.el:1234:56:Warning". |
| 1240 | ((and (not abs) |
| 1241 | ffap-ftp-sans-slash-regexp |
| 1242 | (string-match ffap-ftp-sans-slash-regexp oname) |
| 1243 | (ffap-file-remote-p (concat "/" oname)))) |
| 1244 | ;; Alist failed? Try to guess an active remote connection |
| 1245 | ;; from buffer variables, and try once more, both as an |
| 1246 | ;; absolute and relative file name on that remote host. |
| 1247 | ((let* (ffap-rfs-regexp ; suppress |
| 1248 | (remote-dir |
| 1249 | (cond |
| 1250 | ((ffap-file-remote-p default-directory)) |
| 1251 | ((and (eq major-mode 'internal-ange-ftp-mode) |
| 1252 | (string-match "^\\*ftp \\(.*\\)@\\(.*\\)\\*$" |
| 1253 | (buffer-name))) |
| 1254 | (concat "/" (substring (buffer-name) 5 -1) ":")) |
| 1255 | ;; This is too often a bad idea: |
| 1256 | ;;((and (eq major-mode 'w3-mode) |
| 1257 | ;; (stringp url-current-server)) |
| 1258 | ;; (host-to-ange-path url-current-server)) |
| 1259 | ))) |
| 1260 | (and remote-dir |
| 1261 | (or |
| 1262 | (and (string-match "\\`\\(/?~?ftp\\)/" name) |
| 1263 | (ffap-file-exists-string |
| 1264 | (ffap-replace-file-component |
| 1265 | remote-dir (substring name (match-end 1))))) |
| 1266 | (ffap-file-exists-string |
| 1267 | (ffap-replace-file-component remote-dir name)))))) |
| 1268 | ((and ffap-dired-wildcards |
| 1269 | (string-match ffap-dired-wildcards name) |
| 1270 | abs |
| 1271 | (ffap-file-exists-string (file-name-directory |
| 1272 | (directory-file-name name))) |
| 1273 | name)) |
| 1274 | ;; Try all parent directories by deleting the trailing directory |
| 1275 | ;; name until existing directory is found or name stops changing |
| 1276 | ((let ((dir name)) |
| 1277 | (while (and dir |
| 1278 | (not (ffap-file-exists-string dir)) |
| 1279 | (not (equal dir (setq dir (file-name-directory |
| 1280 | (directory-file-name dir))))))) |
| 1281 | (ffap-file-exists-string dir))) |
| 1282 | ) |
| 1283 | (set-match-data data)))) |
| 1284 | \f |
| 1285 | ;;; Prompting (`ffap-read-file-or-url'): |
| 1286 | ;; |
| 1287 | ;; We want to complete filenames as in read-file-name, but also url's |
| 1288 | ;; which read-file-name-internal would truncate at the "//" string. |
| 1289 | ;; The solution here is to replace read-file-name-internal with |
| 1290 | ;; `ffap-read-file-or-url-internal', which checks the minibuffer |
| 1291 | ;; contents before attempting to complete filenames. |
| 1292 | |
| 1293 | (defun ffap-read-file-or-url (prompt guess) |
| 1294 | "Read file or URL from minibuffer, with PROMPT and initial GUESS." |
| 1295 | (or guess (setq guess default-directory)) |
| 1296 | (let (dir) |
| 1297 | ;; Tricky: guess may have or be a local directory, like "w3/w3.elc" |
| 1298 | ;; or "w3/" or "../el/ffap.el" or "../../../" |
| 1299 | (unless (ffap-url-p guess) |
| 1300 | (unless (ffap-file-remote-p guess) |
| 1301 | (setq guess |
| 1302 | (abbreviate-file-name (expand-file-name guess)))) |
| 1303 | (setq dir (file-name-directory guess))) |
| 1304 | (let ((minibuffer-completing-file-name t) |
| 1305 | (completion-ignore-case read-file-name-completion-ignore-case) |
| 1306 | (fnh-elem (cons ffap-url-regexp 'url-file-handler))) |
| 1307 | ;; Explain to `rfn-eshadow' that we can use URLs here. |
| 1308 | (push fnh-elem file-name-handler-alist) |
| 1309 | (unwind-protect |
| 1310 | (setq guess |
| 1311 | (let ((default-directory (if dir (expand-file-name dir) |
| 1312 | default-directory))) |
| 1313 | (completing-read |
| 1314 | prompt |
| 1315 | 'ffap-read-file-or-url-internal |
| 1316 | nil |
| 1317 | nil |
| 1318 | (if dir (cons guess (length dir)) guess) |
| 1319 | (list 'file-name-history) |
| 1320 | (and buffer-file-name |
| 1321 | (abbreviate-file-name buffer-file-name))))) |
| 1322 | ;; Remove the special handler manually. We used to just let-bind |
| 1323 | ;; file-name-handler-alist to preserve its value, but that caused |
| 1324 | ;; other modifications to be lost (e.g. when Tramp gets loaded |
| 1325 | ;; during the completing-read call). |
| 1326 | (setq file-name-handler-alist (delq fnh-elem file-name-handler-alist)))) |
| 1327 | (or (ffap-url-p guess) |
| 1328 | (substitute-in-file-name guess)))) |
| 1329 | |
| 1330 | (defun ffap-read-url-internal (string pred action) |
| 1331 | "Complete URLs from history, treating given string as valid." |
| 1332 | (let ((hist (ffap-symbol-value 'url-global-history-hash-table))) |
| 1333 | (cond |
| 1334 | ((not action) |
| 1335 | (or (try-completion string hist pred) string)) |
| 1336 | ((eq action t) |
| 1337 | (or (all-completions string hist pred) (list string))) |
| 1338 | ;; action == lambda, documented where? Tests whether string is a |
| 1339 | ;; valid "match". Let us always say yes. |
| 1340 | (t t)))) |
| 1341 | |
| 1342 | (defun ffap-read-file-or-url-internal (string pred action) |
| 1343 | (let ((url (ffap-url-p string))) |
| 1344 | (if url |
| 1345 | (ffap-read-url-internal url pred action) |
| 1346 | (read-file-name-internal (or string default-directory) pred action)))) |
| 1347 | |
| 1348 | ;; The rest of this page is just to work with package complete.el. |
| 1349 | ;; This code assumes that you load ffap.el after complete.el. |
| 1350 | ;; |
| 1351 | ;; We must inform complete about whether our completion function |
| 1352 | ;; will do filename style completion. |
| 1353 | |
| 1354 | \f |
| 1355 | ;;; Highlighting (`ffap-highlight'): |
| 1356 | |
| 1357 | (defvar ffap-highlight t |
| 1358 | "If non-nil, ffap highlights the current buffer substring.") |
| 1359 | |
| 1360 | (defface ffap |
| 1361 | '((t :inherit highlight)) |
| 1362 | "Face used to highlight the current buffer substring." |
| 1363 | :group 'ffap |
| 1364 | :version "22.1") |
| 1365 | |
| 1366 | (defvar ffap-highlight-overlay nil |
| 1367 | "Overlay used by `ffap-highlight'.") |
| 1368 | |
| 1369 | (defun ffap-highlight (&optional remove) |
| 1370 | "If `ffap-highlight' is set, highlight the guess in this buffer. |
| 1371 | That is, the last buffer substring found by `ffap-string-at-point'. |
| 1372 | Optional argument REMOVE means to remove any such highlighting. |
| 1373 | Uses the face `ffap' if it is defined, or else `highlight'." |
| 1374 | (cond |
| 1375 | (remove |
| 1376 | (and ffap-highlight-overlay |
| 1377 | (delete-overlay ffap-highlight-overlay)) |
| 1378 | ) |
| 1379 | ((not ffap-highlight) nil) |
| 1380 | (ffap-highlight-overlay |
| 1381 | (move-overlay |
| 1382 | ffap-highlight-overlay |
| 1383 | (car ffap-string-at-point-region) |
| 1384 | (nth 1 ffap-string-at-point-region) |
| 1385 | (current-buffer))) |
| 1386 | (t |
| 1387 | (setq ffap-highlight-overlay |
| 1388 | (apply 'make-overlay ffap-string-at-point-region)) |
| 1389 | (overlay-put ffap-highlight-overlay 'face 'ffap)))) |
| 1390 | |
| 1391 | \f |
| 1392 | ;;; Main Entrance (`find-file-at-point' == `ffap'): |
| 1393 | |
| 1394 | (defun ffap-guesser () |
| 1395 | "Return file or URL or nil, guessed from text around point." |
| 1396 | (or (and ffap-url-regexp |
| 1397 | (ffap-fixup-url (or (ffap-url-at-point) |
| 1398 | (ffap-gopher-at-point)))) |
| 1399 | (ffap-file-at-point) ; may yield url! |
| 1400 | (ffap-fixup-machine (ffap-machine-at-point)))) |
| 1401 | |
| 1402 | (defun ffap-prompter (&optional guess) |
| 1403 | ;; Does guess and prompt step for find-file-at-point. |
| 1404 | ;; Extra complication for the temporary highlighting. |
| 1405 | (unwind-protect |
| 1406 | ;; This catch will let ffap-alist entries do their own prompting |
| 1407 | ;; and then maybe skip over this prompt (ff-paths, for example). |
| 1408 | (catch 'ffap-prompter |
| 1409 | (ffap-read-file-or-url |
| 1410 | (if ffap-url-regexp "Find file or URL: " "Find file: ") |
| 1411 | (prog1 |
| 1412 | (let ((mark-active nil)) |
| 1413 | ;; Don't use the region here, since it can be something |
| 1414 | ;; completely unwieldy. If the user wants that, she could |
| 1415 | ;; use M-w before and then C-y. --Stef |
| 1416 | (setq guess (or guess (ffap-guesser)))) ; using ffap-alist here |
| 1417 | (and guess (ffap-highlight)) |
| 1418 | ))) |
| 1419 | (ffap-highlight t))) |
| 1420 | |
| 1421 | ;;;###autoload |
| 1422 | (defun find-file-at-point (&optional filename) |
| 1423 | "Find FILENAME, guessing a default from text around point. |
| 1424 | If `ffap-url-regexp' is not nil, the FILENAME may also be an URL. |
| 1425 | With a prefix, this command behaves exactly like `ffap-file-finder'. |
| 1426 | If `ffap-require-prefix' is set, the prefix meaning is reversed. |
| 1427 | See also the variables `ffap-dired-wildcards', `ffap-newfile-prompt', |
| 1428 | and the functions `ffap-file-at-point' and `ffap-url-at-point'." |
| 1429 | (interactive) |
| 1430 | (if (and (called-interactively-p 'interactive) |
| 1431 | (if ffap-require-prefix (not current-prefix-arg) |
| 1432 | current-prefix-arg)) |
| 1433 | ;; Do exactly the ffap-file-finder command, even the prompting: |
| 1434 | (let (current-prefix-arg) ; we already interpreted it |
| 1435 | (call-interactively ffap-file-finder)) |
| 1436 | (or filename (setq filename (ffap-prompter))) |
| 1437 | (let ((url (ffap-url-p filename))) |
| 1438 | (cond |
| 1439 | (url |
| 1440 | (let (current-prefix-arg) |
| 1441 | (funcall ffap-url-fetcher url))) |
| 1442 | ((and ffap-pass-wildcards-to-dired |
| 1443 | ffap-dired-wildcards |
| 1444 | (string-match ffap-dired-wildcards filename)) |
| 1445 | (funcall ffap-directory-finder filename)) |
| 1446 | ((and ffap-dired-wildcards |
| 1447 | (string-match ffap-dired-wildcards filename) |
| 1448 | find-file-wildcards |
| 1449 | ;; Check if it's find-file that supports wildcards arg |
| 1450 | (memq ffap-file-finder '(find-file find-alternate-file))) |
| 1451 | (funcall ffap-file-finder (expand-file-name filename) t)) |
| 1452 | ((or (not ffap-newfile-prompt) |
| 1453 | (file-exists-p filename) |
| 1454 | (y-or-n-p "File does not exist, create buffer? ")) |
| 1455 | (funcall ffap-file-finder |
| 1456 | ;; expand-file-name fixes "~/~/.emacs" bug sent by CHUCKR. |
| 1457 | (expand-file-name filename))) |
| 1458 | ;; User does not want to find a non-existent file: |
| 1459 | ((signal 'file-error (list "Opening file buffer" |
| 1460 | "no such file or directory" |
| 1461 | filename))))))) |
| 1462 | |
| 1463 | ;; Shortcut: allow {M-x ffap} rather than {M-x find-file-at-point}. |
| 1464 | ;;;###autoload |
| 1465 | (defalias 'ffap 'find-file-at-point) |
| 1466 | |
| 1467 | \f |
| 1468 | ;;; Menu support (`ffap-menu'): |
| 1469 | |
| 1470 | (defcustom ffap-menu-regexp nil |
| 1471 | "If non-nil, regexp overriding `ffap-next-regexp' in `ffap-menu'. |
| 1472 | Make this more restrictive for faster menu building. |
| 1473 | For example, try \":/\" for URL (and some ftp) references." |
| 1474 | :type '(choice (const nil) regexp) |
| 1475 | :group 'ffap) |
| 1476 | |
| 1477 | (defvar ffap-menu-alist nil |
| 1478 | "Buffer local cache of menu presented by `ffap-menu'.") |
| 1479 | (make-variable-buffer-local 'ffap-menu-alist) |
| 1480 | |
| 1481 | (defvar ffap-menu-text-plist |
| 1482 | (cond |
| 1483 | ((display-mouse-p) '(face bold mouse-face highlight)) ; keymap <mousy-map> |
| 1484 | (t nil)) |
| 1485 | "Text properties applied to strings found by `ffap-menu-rescan'. |
| 1486 | These properties may be used to fontify the menu references.") |
| 1487 | |
| 1488 | ;;;###autoload |
| 1489 | (defun ffap-menu (&optional rescan) |
| 1490 | "Put up a menu of files and URLs mentioned in this buffer. |
| 1491 | Then set mark, jump to choice, and try to fetch it. The menu is |
| 1492 | cached in `ffap-menu-alist', and rebuilt by `ffap-menu-rescan'. |
| 1493 | The optional RESCAN argument \(a prefix, interactively\) forces |
| 1494 | a rebuild. Searches with `ffap-menu-regexp'." |
| 1495 | (interactive "P") |
| 1496 | ;; (require 'imenu) -- no longer used, but roughly emulated |
| 1497 | (if (or (not ffap-menu-alist) rescan |
| 1498 | ;; or if the first entry is wrong: |
| 1499 | (and ffap-menu-alist |
| 1500 | (let ((first (car ffap-menu-alist))) |
| 1501 | (save-excursion |
| 1502 | (goto-char (cdr first)) |
| 1503 | (not (equal (car first) (ffap-guesser))))))) |
| 1504 | (ffap-menu-rescan)) |
| 1505 | ;; Tail recursive: |
| 1506 | (ffap-menu-ask |
| 1507 | (if ffap-url-regexp "Find file or URL" "Find file") |
| 1508 | (cons (cons "*Rescan Buffer*" -1) ffap-menu-alist) |
| 1509 | 'ffap-menu-cont)) |
| 1510 | |
| 1511 | (defun ffap-menu-cont (choice) ; continuation of ffap-menu |
| 1512 | (if (< (cdr choice) 0) |
| 1513 | (ffap-menu t) ; *Rescan* |
| 1514 | (push-mark) |
| 1515 | (goto-char (cdr choice)) |
| 1516 | ;; Momentary highlight: |
| 1517 | (unwind-protect |
| 1518 | (progn |
| 1519 | (and ffap-highlight (ffap-guesser) (ffap-highlight)) |
| 1520 | (sit-for 0) ; display |
| 1521 | (find-file-at-point (car choice))) |
| 1522 | (ffap-highlight t)))) |
| 1523 | |
| 1524 | (defun ffap-menu-ask (title alist cont) |
| 1525 | "Prompt from a menu of choices, and then apply some action. |
| 1526 | Arguments are TITLE, ALIST, and CONT \(a continuation function\). |
| 1527 | This uses either a menu or the minibuffer depending on invocation. |
| 1528 | The TITLE string is used as either the prompt or menu title. |
| 1529 | Each ALIST entry looks like (STRING . DATA) and defines one choice. |
| 1530 | Function CONT is applied to the entry chosen by the user." |
| 1531 | ;; Note: this function is used with a different continuation |
| 1532 | ;; by the ffap-url add-on package. |
| 1533 | ;; Could try rewriting to use easymenu.el or lmenu.el. |
| 1534 | (let (choice) |
| 1535 | (cond |
| 1536 | ;; Emacs mouse: |
| 1537 | ((and (fboundp 'x-popup-menu) (ffap-mouse-event)) |
| 1538 | (setq choice |
| 1539 | (x-popup-menu |
| 1540 | t |
| 1541 | (list "" (cons title |
| 1542 | (mapcar (lambda (i) (cons (car i) i)) |
| 1543 | alist)))))) |
| 1544 | ;; minibuffer with completion buffer: |
| 1545 | (t |
| 1546 | (let ((minibuffer-setup-hook 'minibuffer-completion-help)) |
| 1547 | ;; Bug: prompting may assume unique strings, no "". |
| 1548 | (setq choice |
| 1549 | (completing-read |
| 1550 | (format "%s (default %s): " title (car (car alist))) |
| 1551 | alist nil t |
| 1552 | ;; (cons (car (car alist)) 0) |
| 1553 | nil))) |
| 1554 | (sit-for 0) ; redraw original screen |
| 1555 | ;; Convert string to its entry, or else the default: |
| 1556 | (setq choice (or (assoc choice alist) (car alist))))) |
| 1557 | (if choice |
| 1558 | (funcall cont choice) |
| 1559 | (message "No choice made!") ; possible with menus |
| 1560 | nil))) |
| 1561 | |
| 1562 | (defun ffap-menu-rescan () |
| 1563 | "Search buffer for `ffap-menu-regexp' to build `ffap-menu-alist'. |
| 1564 | Applies `ffap-menu-text-plist' text properties at all matches." |
| 1565 | (interactive) |
| 1566 | (let ((ffap-next-regexp (or ffap-menu-regexp ffap-next-regexp)) |
| 1567 | (range (- (point-max) (point-min))) |
| 1568 | (mod (buffer-modified-p)) ; was buffer modified? |
| 1569 | ;; inhibit-read-only works on read-only text properties |
| 1570 | ;; as well as read-only buffers. |
| 1571 | (inhibit-read-only t) ; to set text-properties |
| 1572 | item |
| 1573 | ;; Avoid repeated searches of the *mode-alist: |
| 1574 | (major-mode (if (assq major-mode ffap-string-at-point-mode-alist) |
| 1575 | major-mode |
| 1576 | 'file))) |
| 1577 | (setq ffap-menu-alist nil) |
| 1578 | (unwind-protect |
| 1579 | (save-excursion |
| 1580 | (goto-char (point-min)) |
| 1581 | (while (setq item (ffap-next-guess)) |
| 1582 | (setq ffap-menu-alist (cons (cons item (point)) ffap-menu-alist)) |
| 1583 | (add-text-properties (car ffap-string-at-point-region) (point) |
| 1584 | ffap-menu-text-plist) |
| 1585 | (message "Scanning...%2d%% <%s>" |
| 1586 | (/ (* 100 (- (point) (point-min))) range) item))) |
| 1587 | (or mod (restore-buffer-modified-p nil)))) |
| 1588 | (message "Scanning...done") |
| 1589 | ;; Remove duplicates. |
| 1590 | (setq ffap-menu-alist ; sort by item |
| 1591 | (sort ffap-menu-alist |
| 1592 | (function |
| 1593 | (lambda (a b) (string-lessp (car a) (car b)))))) |
| 1594 | (let ((ptr ffap-menu-alist)) ; remove duplicates |
| 1595 | (while (cdr ptr) |
| 1596 | (if (equal (car (car ptr)) (car (car (cdr ptr)))) |
| 1597 | (setcdr ptr (cdr (cdr ptr))) |
| 1598 | (setq ptr (cdr ptr))))) |
| 1599 | (setq ffap-menu-alist ; sort by position |
| 1600 | (sort ffap-menu-alist |
| 1601 | (function |
| 1602 | (lambda (a b) (< (cdr a) (cdr b))))))) |
| 1603 | |
| 1604 | \f |
| 1605 | ;;; Mouse Support (`ffap-at-mouse'): |
| 1606 | ;; |
| 1607 | ;; See the suggested binding in ffap-bindings (near eof). |
| 1608 | |
| 1609 | (defvar ffap-at-mouse-fallback nil ; ffap-menu? too time-consuming |
| 1610 | "Command invoked by `ffap-at-mouse' if nothing found at click, or nil. |
| 1611 | Ignored when `ffap-at-mouse' is called programmatically.") |
| 1612 | (put 'ffap-at-mouse-fallback 'risky-local-variable t) |
| 1613 | |
| 1614 | ;;;###autoload |
| 1615 | (defun ffap-at-mouse (e) |
| 1616 | "Find file or URL guessed from text around mouse click. |
| 1617 | Interactively, calls `ffap-at-mouse-fallback' if no guess is found. |
| 1618 | Return value: |
| 1619 | * if a guess string is found, return it (after finding it) |
| 1620 | * if the fallback is called, return whatever it returns |
| 1621 | * otherwise, nil" |
| 1622 | (interactive "e") |
| 1623 | (let ((guess |
| 1624 | ;; Maybe less surprising without the save-excursion? |
| 1625 | (save-excursion |
| 1626 | (mouse-set-point e) |
| 1627 | ;; Would prefer to do nothing unless click was *on* text. How |
| 1628 | ;; to tell that the click was beyond the end of current line? |
| 1629 | (ffap-guesser)))) |
| 1630 | (cond |
| 1631 | (guess |
| 1632 | (set-buffer (ffap-event-buffer e)) |
| 1633 | (ffap-highlight) |
| 1634 | (unwind-protect |
| 1635 | (progn |
| 1636 | (sit-for 0) ; display |
| 1637 | (message "Finding `%s'" guess) |
| 1638 | (find-file-at-point guess) |
| 1639 | guess) ; success: return non-nil |
| 1640 | (ffap-highlight t))) |
| 1641 | ((called-interactively-p 'interactive) |
| 1642 | (if ffap-at-mouse-fallback |
| 1643 | (call-interactively ffap-at-mouse-fallback) |
| 1644 | (message "No file or URL found at mouse click.") |
| 1645 | nil)) ; no fallback, return nil |
| 1646 | ;; failure: return nil |
| 1647 | ))) |
| 1648 | |
| 1649 | \f |
| 1650 | ;;; ffap-other-*, ffap-read-only-*, ffap-alternate-* commands: |
| 1651 | |
| 1652 | ;; There could be a real `ffap-noselect' function, but we would need |
| 1653 | ;; at least two new user variables, and there is no w3-fetch-noselect. |
| 1654 | ;; So instead, we just fake it with a slow save-window-excursion. |
| 1655 | |
| 1656 | (defun ffap-other-window () |
| 1657 | "Like `ffap', but put buffer in another window. |
| 1658 | Only intended for interactive use." |
| 1659 | (interactive) |
| 1660 | (let (value) |
| 1661 | (switch-to-buffer-other-window |
| 1662 | (save-window-excursion |
| 1663 | (setq value (call-interactively 'ffap)) |
| 1664 | (unless (or (bufferp value) (bufferp (car-safe value))) |
| 1665 | (setq value (current-buffer))) |
| 1666 | (current-buffer))) |
| 1667 | value)) |
| 1668 | |
| 1669 | (defun ffap-other-frame () |
| 1670 | "Like `ffap', but put buffer in another frame. |
| 1671 | Only intended for interactive use." |
| 1672 | (interactive) |
| 1673 | ;; Extra code works around dedicated windows (noted by JENS, 7/96): |
| 1674 | (let* ((win (selected-window)) |
| 1675 | (wdp (window-dedicated-p win)) |
| 1676 | value) |
| 1677 | (unwind-protect |
| 1678 | (progn |
| 1679 | (set-window-dedicated-p win nil) |
| 1680 | (switch-to-buffer-other-frame |
| 1681 | (save-window-excursion |
| 1682 | (setq value (call-interactively 'ffap)) |
| 1683 | (unless (or (bufferp value) (bufferp (car-safe value))) |
| 1684 | (setq value (current-buffer))) |
| 1685 | (current-buffer)))) |
| 1686 | (set-window-dedicated-p win wdp)) |
| 1687 | value)) |
| 1688 | |
| 1689 | (defun ffap--toggle-read-only (buffer-or-list) |
| 1690 | (dolist (buffer (if (listp buffer-or-list) |
| 1691 | buffer-or-list |
| 1692 | (list buffer-or-list))) |
| 1693 | (with-current-buffer buffer |
| 1694 | (read-only-mode 1)))) |
| 1695 | |
| 1696 | (defun ffap-read-only () |
| 1697 | "Like `ffap', but mark buffer as read-only. |
| 1698 | Only intended for interactive use." |
| 1699 | (interactive) |
| 1700 | (let ((value (call-interactively 'ffap))) |
| 1701 | (unless (or (bufferp value) (bufferp (car-safe value))) |
| 1702 | (setq value (current-buffer))) |
| 1703 | (ffap--toggle-read-only value) |
| 1704 | value)) |
| 1705 | |
| 1706 | (defun ffap-read-only-other-window () |
| 1707 | "Like `ffap', but put buffer in another window and mark as read-only. |
| 1708 | Only intended for interactive use." |
| 1709 | (interactive) |
| 1710 | (let ((value (ffap-other-window))) |
| 1711 | (ffap--toggle-read-only value) |
| 1712 | value)) |
| 1713 | |
| 1714 | (defun ffap-read-only-other-frame () |
| 1715 | "Like `ffap', but put buffer in another frame and mark as read-only. |
| 1716 | Only intended for interactive use." |
| 1717 | (interactive) |
| 1718 | (let ((value (ffap-other-frame))) |
| 1719 | (ffap--toggle-read-only value) |
| 1720 | value)) |
| 1721 | |
| 1722 | (defun ffap-alternate-file () |
| 1723 | "Like `ffap' and `find-alternate-file'. |
| 1724 | Only intended for interactive use." |
| 1725 | (interactive) |
| 1726 | (let ((ffap-file-finder 'find-alternate-file)) |
| 1727 | (call-interactively 'ffap))) |
| 1728 | |
| 1729 | (defun ffap-alternate-file-other-window () |
| 1730 | "Like `ffap' and `find-alternate-file-other-window'. |
| 1731 | Only intended for interactive use." |
| 1732 | (interactive) |
| 1733 | (let ((ffap-file-finder 'find-alternate-file-other-window)) |
| 1734 | (call-interactively 'ffap))) |
| 1735 | |
| 1736 | (defun ffap-literally () |
| 1737 | "Like `ffap' and `find-file-literally'. |
| 1738 | Only intended for interactive use." |
| 1739 | (interactive) |
| 1740 | (let ((ffap-file-finder 'find-file-literally)) |
| 1741 | (call-interactively 'ffap))) |
| 1742 | |
| 1743 | (defalias 'find-file-literally-at-point 'ffap-literally) |
| 1744 | |
| 1745 | \f |
| 1746 | ;;; Bug Reporter: |
| 1747 | |
| 1748 | (define-obsolete-function-alias 'ffap-bug 'report-emacs-bug "23.1") |
| 1749 | (define-obsolete-function-alias 'ffap-submit-bug 'report-emacs-bug "23.1") |
| 1750 | |
| 1751 | \f |
| 1752 | ;;; Hooks for Gnus, VM, Rmail: |
| 1753 | ;; |
| 1754 | ;; If you do not like these bindings, write versions with whatever |
| 1755 | ;; bindings you would prefer. |
| 1756 | |
| 1757 | (defun ffap-ro-mode-hook () |
| 1758 | "Bind `ffap-next' and `ffap-menu' to M-l and M-m, resp." |
| 1759 | (local-set-key "\M-l" 'ffap-next) |
| 1760 | (local-set-key "\M-m" 'ffap-menu)) |
| 1761 | |
| 1762 | (defun ffap-gnus-hook () |
| 1763 | "Bind `ffap-gnus-next' and `ffap-gnus-menu' to M-l and M-m, resp." |
| 1764 | (set (make-local-variable 'ffap-foo-at-bar-prefix) "news") ; message-id's |
| 1765 | ;; Note "l", "L", "m", "M" are taken: |
| 1766 | (local-set-key "\M-l" 'ffap-gnus-next) |
| 1767 | (local-set-key "\M-m" 'ffap-gnus-menu)) |
| 1768 | |
| 1769 | (defvar gnus-summary-buffer) |
| 1770 | (defvar gnus-article-buffer) |
| 1771 | |
| 1772 | ;; This code is called from gnus. |
| 1773 | (declare-function gnus-summary-select-article "gnus-sum" |
| 1774 | (&optional all-headers force pseudo article)) |
| 1775 | |
| 1776 | (declare-function gnus-configure-windows "gnus-win" |
| 1777 | (setting &optional force)) |
| 1778 | |
| 1779 | (defun ffap-gnus-wrapper (form) ; used by both commands below |
| 1780 | (and (eq (current-buffer) (get-buffer gnus-summary-buffer)) |
| 1781 | (gnus-summary-select-article)) ; get article of current line |
| 1782 | ;; Preserve selected buffer, but do not do save-window-excursion, |
| 1783 | ;; since we want to see any window created by the form. Temporarily |
| 1784 | ;; select the article buffer, so we can see any point movement. |
| 1785 | (let ((sb (window-buffer (selected-window)))) |
| 1786 | (gnus-configure-windows 'article) |
| 1787 | (pop-to-buffer gnus-article-buffer) |
| 1788 | (widen) |
| 1789 | ;; Skip headers for ffap-gnus-next (which will wrap around) |
| 1790 | (if (eq (point) (point-min)) (search-forward "\n\n" nil t)) |
| 1791 | (unwind-protect |
| 1792 | (eval form) |
| 1793 | (pop-to-buffer sb)))) |
| 1794 | |
| 1795 | (defun ffap-gnus-next () |
| 1796 | "Run `ffap-next' in the gnus article buffer." |
| 1797 | (interactive) (ffap-gnus-wrapper '(ffap-next nil t))) |
| 1798 | |
| 1799 | (defun ffap-gnus-menu () |
| 1800 | "Run `ffap-menu' in the gnus article buffer." |
| 1801 | (interactive) (ffap-gnus-wrapper '(ffap-menu))) |
| 1802 | |
| 1803 | \f |
| 1804 | |
| 1805 | ;;;###autoload |
| 1806 | (defun dired-at-point (&optional filename) |
| 1807 | "Start Dired, defaulting to file at point. See `ffap'. |
| 1808 | If `dired-at-point-require-prefix' is set, the prefix meaning is reversed." |
| 1809 | (interactive) |
| 1810 | (if (and (called-interactively-p 'interactive) |
| 1811 | (if dired-at-point-require-prefix |
| 1812 | (not current-prefix-arg) |
| 1813 | current-prefix-arg)) |
| 1814 | (let (current-prefix-arg) ; already interpreted |
| 1815 | (call-interactively ffap-directory-finder)) |
| 1816 | (or filename (setq filename (dired-at-point-prompter))) |
| 1817 | (let ((url (ffap-url-p filename))) |
| 1818 | (cond |
| 1819 | (url |
| 1820 | (funcall ffap-url-fetcher url)) |
| 1821 | ((and ffap-dired-wildcards |
| 1822 | (string-match ffap-dired-wildcards filename)) |
| 1823 | (funcall ffap-directory-finder filename)) |
| 1824 | ((file-exists-p filename) |
| 1825 | (if (file-directory-p filename) |
| 1826 | (funcall ffap-directory-finder |
| 1827 | (expand-file-name filename)) |
| 1828 | (funcall ffap-directory-finder |
| 1829 | (concat (expand-file-name filename) "*")))) |
| 1830 | ((and (file-writable-p |
| 1831 | (or (file-name-directory (directory-file-name filename)) |
| 1832 | filename)) |
| 1833 | (y-or-n-p "Directory does not exist, create it? ")) |
| 1834 | (make-directory filename) |
| 1835 | (funcall ffap-directory-finder filename)) |
| 1836 | ((error "No such file or directory `%s'" filename)))))) |
| 1837 | |
| 1838 | (defun dired-at-point-prompter (&optional guess) |
| 1839 | ;; Does guess and prompt step for find-file-at-point. |
| 1840 | ;; Extra complication for the temporary highlighting. |
| 1841 | (unwind-protect |
| 1842 | (ffap-read-file-or-url |
| 1843 | (cond |
| 1844 | ((eq ffap-directory-finder 'list-directory) |
| 1845 | "List directory (brief): ") |
| 1846 | (ffap-url-regexp "Dired file or URL: ") |
| 1847 | (t "Dired file: ")) |
| 1848 | (prog1 |
| 1849 | (setq guess |
| 1850 | (let ((guess (or guess (ffap-guesser)))) |
| 1851 | (cond |
| 1852 | ((null guess) nil) |
| 1853 | ((ffap-url-p guess)) |
| 1854 | ((ffap-file-remote-p guess) |
| 1855 | guess) |
| 1856 | ((progn |
| 1857 | (setq guess (abbreviate-file-name |
| 1858 | (expand-file-name guess))) |
| 1859 | ;; Interpret local directory as a directory. |
| 1860 | (file-directory-p guess)) |
| 1861 | (file-name-as-directory guess)) |
| 1862 | ;; Get directory component from local files. |
| 1863 | ((file-regular-p guess) |
| 1864 | (file-name-directory guess)) |
| 1865 | (guess)))) |
| 1866 | (and guess (ffap-highlight)))) |
| 1867 | (ffap-highlight t))) |
| 1868 | \f |
| 1869 | ;;; ffap-dired-other-*, ffap-list-directory commands: |
| 1870 | |
| 1871 | (defun ffap-dired-other-window () |
| 1872 | "Like `dired-at-point', but put buffer in another window. |
| 1873 | Only intended for interactive use." |
| 1874 | (interactive) |
| 1875 | (let (value) |
| 1876 | (switch-to-buffer-other-window |
| 1877 | (save-window-excursion |
| 1878 | (setq value (call-interactively 'dired-at-point)) |
| 1879 | (current-buffer))) |
| 1880 | value)) |
| 1881 | |
| 1882 | (defun ffap-dired-other-frame () |
| 1883 | "Like `dired-at-point', but put buffer in another frame. |
| 1884 | Only intended for interactive use." |
| 1885 | (interactive) |
| 1886 | ;; Extra code works around dedicated windows (noted by JENS, 7/96): |
| 1887 | (let* ((win (selected-window)) |
| 1888 | (wdp (window-dedicated-p win)) |
| 1889 | value) |
| 1890 | (unwind-protect |
| 1891 | (progn |
| 1892 | (set-window-dedicated-p win nil) |
| 1893 | (switch-to-buffer-other-frame |
| 1894 | (save-window-excursion |
| 1895 | (setq value (call-interactively 'dired-at-point)) |
| 1896 | (current-buffer)))) |
| 1897 | (set-window-dedicated-p win wdp)) |
| 1898 | value)) |
| 1899 | |
| 1900 | (defun ffap-list-directory () |
| 1901 | "Like `dired-at-point' and `list-directory'. |
| 1902 | Only intended for interactive use." |
| 1903 | (interactive) |
| 1904 | (let ((ffap-directory-finder 'list-directory)) |
| 1905 | (call-interactively 'dired-at-point))) |
| 1906 | |
| 1907 | \f |
| 1908 | ;;; Hooks to put in `file-name-at-point-functions': |
| 1909 | |
| 1910 | ;;;###autoload |
| 1911 | (defun ffap-guess-file-name-at-point () |
| 1912 | "Try to get a file name at point. |
| 1913 | This hook is intended to be put in `file-name-at-point-functions'." |
| 1914 | (let ((guess (ffap-guesser))) |
| 1915 | (when (stringp guess) |
| 1916 | (let ((url (ffap-url-p guess))) |
| 1917 | (or url |
| 1918 | (progn |
| 1919 | (unless (ffap-file-remote-p guess) |
| 1920 | (setq guess |
| 1921 | (abbreviate-file-name (expand-file-name guess)))) |
| 1922 | (if (file-directory-p guess) |
| 1923 | (file-name-as-directory guess) |
| 1924 | guess))))))) |
| 1925 | \f |
| 1926 | ;;; Offer default global bindings (`ffap-bindings'): |
| 1927 | |
| 1928 | (defvar ffap-bindings |
| 1929 | '((global-set-key [S-mouse-3] 'ffap-at-mouse) |
| 1930 | (global-set-key [C-S-mouse-3] 'ffap-menu) |
| 1931 | |
| 1932 | (global-set-key "\C-x\C-f" 'find-file-at-point) |
| 1933 | (global-set-key "\C-x\C-r" 'ffap-read-only) |
| 1934 | (global-set-key "\C-x\C-v" 'ffap-alternate-file) |
| 1935 | |
| 1936 | (global-set-key "\C-x4f" 'ffap-other-window) |
| 1937 | (global-set-key "\C-x5f" 'ffap-other-frame) |
| 1938 | (global-set-key "\C-x4r" 'ffap-read-only-other-window) |
| 1939 | (global-set-key "\C-x5r" 'ffap-read-only-other-frame) |
| 1940 | |
| 1941 | (global-set-key "\C-xd" 'dired-at-point) |
| 1942 | (global-set-key "\C-x4d" 'ffap-dired-other-window) |
| 1943 | (global-set-key "\C-x5d" 'ffap-dired-other-frame) |
| 1944 | (global-set-key "\C-x\C-d" 'ffap-list-directory) |
| 1945 | |
| 1946 | (add-hook 'gnus-summary-mode-hook 'ffap-gnus-hook) |
| 1947 | (add-hook 'gnus-article-mode-hook 'ffap-gnus-hook) |
| 1948 | (add-hook 'vm-mode-hook 'ffap-ro-mode-hook) |
| 1949 | (add-hook 'rmail-mode-hook 'ffap-ro-mode-hook)) |
| 1950 | "List of binding forms evaluated by function `ffap-bindings'. |
| 1951 | A reasonable ffap installation needs just this one line: |
| 1952 | (ffap-bindings) |
| 1953 | Of course if you do not like these bindings, just roll your own!") |
| 1954 | |
| 1955 | ;;;###autoload |
| 1956 | (defun ffap-bindings () |
| 1957 | "Evaluate the forms in variable `ffap-bindings'." |
| 1958 | (interactive) |
| 1959 | (eval (cons 'progn ffap-bindings))) |
| 1960 | |
| 1961 | \f |
| 1962 | (provide 'ffap) |
| 1963 | |
| 1964 | ;;; ffap.el ends here |